code.delx.au - gnu-emacs/blob - lisp/vc/vc-hg.el

   1 ;;; vc-hg.el --- VC backend for the mercurial version control system  -*- lexical-binding: t -*-
   2
   3 ;; Copyright (C) 2006-2015 Free Software Foundation, Inc.
   4
   5 ;; Author: Ivan Kanis
   6 ;; Maintainer: emacs-devel@gnu.org
   7 ;; Keywords: vc tools
   8 ;; Package: vc
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; This is a mercurial version control backend
  28
  29 ;;; Thanks:
  30
  31 ;;; Bugs:
  32
  33 ;;; Installation:
  34
  35 ;;; Todo:
  36
  37 ;; 1) Implement the rest of the vc interface. See the comment at the
  38 ;; beginning of vc.el. The current status is:
  39
  40 ;; FUNCTION NAME                               STATUS
  41 ;; BACKEND PROPERTIES
  42 ;; * revision-granularity                      OK
  43 ;; STATE-QUERYING FUNCTIONS
  44 ;; * registered (file)                         OK
  45 ;; * state (file)                              OK
  46 ;; - dir-status-files (dir files uf)           OK
  47 ;; - dir-extra-headers (dir)                   OK
  48 ;; - dir-printer (fileinfo)                    OK
  49 ;; * working-revision (file)                   OK
  50 ;; * checkout-model (files)                    OK
  51 ;; - mode-line-string (file)                   NOT NEEDED
  52 ;; STATE-CHANGING FUNCTIONS
  53 ;; * register (files &optional rev comment)    OK
  54 ;; * create-repo ()                            OK
  55 ;; - responsible-p (file)                      OK
  56 ;; - receive-file (file rev)                   ?? PROBABLY NOT NEEDED
  57 ;; - unregister (file)                         OK
  58 ;; * checkin (files rev comment)               OK
  59 ;; * find-revision (file rev buffer)           OK
  60 ;; * checkout (file &optional rev)             OK
  61 ;; * revert (file &optional contents-done)     OK
  62 ;; - merge (file rev1 rev2)                    NEEDED
  63 ;; - merge-news (file)                         NEEDED
  64 ;; - steal-lock (file &optional revision)      NOT NEEDED
  65 ;; HISTORY FUNCTIONS
  66 ;; * print-log (files buffer &optional shortlog start-revision limit) OK
  67 ;; - log-view-mode ()                          OK
  68 ;; - show-log-entry (revision)                 NOT NEEDED, DEFAULT IS GOOD
  69 ;; - comment-history (file)                    NOT NEEDED
  70 ;; - update-changelog (files)                  NOT NEEDED
  71 ;; * diff (files &optional rev1 rev2 buffer)   OK
  72 ;; - revision-completion-table (files)         OK?
  73 ;; - annotate-command (file buf &optional rev) OK
  74 ;; - annotate-time ()                          OK
  75 ;; - annotate-current-time ()                  NOT NEEDED
  76 ;; - annotate-extract-revision-at-line ()      OK
  77 ;; TAG SYSTEM
  78 ;; - create-tag (dir name branchp)             OK
  79 ;; - retrieve-tag (dir name update)            OK FIXME UPDATE BUFFERS
  80 ;; MISCELLANEOUS
  81 ;; - make-version-backups-p (file)             ??
  82 ;; - previous-revision (file rev)              OK
  83 ;; - next-revision (file rev)                  OK
  84 ;; - check-headers ()                          ??
  85 ;; - delete-file (file)                        TEST IT
  86 ;; - rename-file (old new)                     OK
  87 ;; - find-file-hook ()                         added for bug#10709
  88
  89 ;; 2) Implement Stefan Monnier's advice:
  90 ;; vc-hg-registered and vc-hg-state
  91 ;; Both of those functions should be super extra careful to fail gracefully in
  92 ;; unexpected circumstances. The reason this is important is that any error
  93 ;; there will prevent the user from even looking at the file :-(
  94 ;; Ideally, just like in vc-arch and vc-cvs, checking that the file is under
  95 ;; mercurial's control and extracting the current revision should be done
  96 ;; without even using `hg' (this way even if you don't have `hg' installed,
  97 ;; Emacs is able to tell you this file is under mercurial's control).
  98
  99 ;;; History:
 100 ;;
 101
 102 ;;; Code:
 103
 104 (eval-when-compile
 105   (require 'cl-lib)
 106   (require 'vc)
 107   (require 'vc-dir))
 108
 109 ;;; Customization options
 110
 111 (defgroup vc-hg nil
 112   "VC Mercurial (hg) backend."
 113   :version "24.1"
 114   :group 'vc)
 115
 116 (defcustom vc-hg-global-switches nil
 117   "Global switches to pass to any Hg command."
 118   :type '(choice (const :tag "None" nil)
 119          (string :tag "Argument String")
 120          (repeat :tag "Argument List" :value ("") string))
 121   :version "22.2"
 122   :group 'vc-hg)
 123
 124 (defcustom vc-hg-diff-switches t ; Hg doesn't support common args like -u
 125   "String or list of strings specifying switches for Hg diff under VC.
 126 If nil, use the value of `vc-diff-switches'.  If t, use no switches."
 127   :type '(choice (const :tag "Unspecified" nil)
 128                  (const :tag "None" t)
 129                  (string :tag "Argument String")
 130                  (repeat :tag "Argument List" :value ("") string))
 131   :version "23.1"
 132   :group 'vc-hg)
 133
 134 (defcustom vc-hg-annotate-switches nil
 135   "String or list of strings specifying switches for hg annotate under VC.
 136 If nil, use the value of `vc-annotate-switches'.  If t, use no
 137 switches."
 138   :type '(choice (const :tag "Unspecified" nil)
 139                  (const :tag "None" t)
 140                  (string :tag "Argument String")
 141                  (repeat :tag "Argument List" :value ("") string))
 142   :version "25.1"
 143   :group 'vc-hg)
 144
 145 (defcustom vc-hg-program "hg"
 146   "Name of the Mercurial executable (excluding any arguments)."
 147   :type 'string
 148   :group 'vc-hg)
 149
 150 (defcustom vc-hg-root-log-format
 151   `(,(concat "{rev}:{ifeq(branch, 'default','', '{branch}')}"
 152              ":{bookmarks}:{tags}:{author|person}"
 153              " {date|shortdate} {desc|firstline}\\n")
 154     ,(concat "^\\(?:[+@o x|-]*\\)"      ;Graph data.
 155              "\\([0-9]+\\):\\([^:]*\\)"
 156              ":\\([^:]*\\):\\([^:]*\\):\\(.*?\\)"
 157              "[ \t]+\\([0-9]\\{4\\}-[0-9]\\{2\\}-[0-9]\\{2\\}\\)")
 158     ((1 'log-view-message-face)
 159      (2 'change-log-file)
 160      (3 'change-log-list)
 161      (4 'change-log-conditionals)
 162      (5 'change-log-name)
 163      (6 'change-log-date)))
 164   "Mercurial log template for `vc-hg-print-log' short format.
 165 This should be a list (TEMPLATE REGEXP KEYWORDS), where TEMPLATE
 166 is the \"--template\" argument string to pass to Mercurial,
 167 REGEXP is a regular expression matching the resulting Mercurial
 168 output, and KEYWORDS is a list of `font-lock-keywords' for
 169 highlighting the Log View buffer."
 170   :type '(list string string (repeat sexp))
 171   :group 'vc-hg
 172   :version "24.5")
 173
 174 \f
 175 ;;; Properties of the backend
 176
 177 (defvar vc-hg-history nil)
 178
 179 (defun vc-hg-revision-granularity () 'repository)
 180 (defun vc-hg-checkout-model (_files) 'implicit)
 181
 182 ;;; State querying functions
 183
 184 ;;;###autoload (defun vc-hg-registered (file)
 185 ;;;###autoload   "Return non-nil if FILE is registered with hg."
 186 ;;;###autoload   (if (vc-find-root file ".hg")       ; short cut
 187 ;;;###autoload       (progn
 188 ;;;###autoload         (load "vc-hg" nil t)
 189 ;;;###autoload         (vc-hg-registered file))))
 190
 191 ;; Modeled after the similar function in vc-bzr.el
 192 (defun vc-hg-registered (file)
 193   "Return non-nil if FILE is registered with hg."
 194   (when (vc-hg-root file)           ; short cut
 195     (let ((state (vc-hg-state file)))  ; expensive
 196       (and state (not (memq state '(ignored unregistered)))))))
 197
 198 (defun vc-hg-state (file)
 199   "Hg-specific version of `vc-state'."
 200   (setq file (expand-file-name file))
 201   (let*
 202       ((status nil)
 203        (default-directory (file-name-directory file))
 204        (out
 205         (with-output-to-string
 206           (with-current-buffer
 207               standard-output
 208             (setq status
 209                   (condition-case nil
 210                       ;; Ignore all errors.
 211                       (let ((process-environment
 212                              ;; Avoid localization of messages so we
 213                              ;; can parse the output.  Disable pager.
 214                              (append
 215                               (list "TERM=dumb" "LANGUAGE=C" "HGPLAIN=1")
 216                               process-environment)))
 217                         (process-file
 218                          vc-hg-program nil t nil
 219                          "--config" "alias.status=status"
 220                          "--config" "defaults.status="
 221                          "status" "-A" (file-relative-name file)))
 222                     ;; Some problem happened.  E.g. We can't find an `hg'
 223                     ;; executable.
 224                     (error nil)))))))
 225     (when (and (eq 0 status)
 226                (> (length out) 0)
 227                (null (string-match ".*: No such file or directory$" out)))
 228       (let ((state (aref out 0)))
 229         (cond
 230          ((eq state ?=) 'up-to-date)
 231          ((eq state ?A) 'added)
 232          ((eq state ?M) 'edited)
 233          ((eq state ?I) 'ignored)
 234          ((eq state ?R) 'removed)
 235          ((eq state ?!) 'missing)
 236          ((eq state ??) 'unregistered)
 237          ((eq state ?C) 'up-to-date) ;; Older mercurial versions use this.
 238          (t 'up-to-date))))))
 239
 240 (defun vc-hg-working-revision (file)
 241   "Hg-specific version of `vc-working-revision'."
 242   (or (ignore-errors
 243         (with-output-to-string
 244           (vc-hg-command standard-output 0 file
 245                          "parent" "--template" "{rev}")))
 246       "0"))
 247
 248 ;;; History functions
 249
 250 (defcustom vc-hg-log-switches nil
 251   "String or list of strings specifying switches for hg log under VC."
 252   :type '(choice (const :tag "None" nil)
 253                  (string :tag "Argument String")
 254                  (repeat :tag "Argument List" :value ("") string))
 255   :group 'vc-hg)
 256
 257 (autoload 'vc-setup-buffer "vc-dispatcher")
 258
 259 (defvar vc-hg-log-graph nil
 260   "If non-nil, use `--graph' in the short log output.")
 261
 262 (defvar vc-hg-log-format (concat "changeset:   {rev}:{node|short}\n"
 263                                  "{tags % 'tag:         {tag}\n'}"
 264                                  "{if(parents, 'parents:     {parents}\n')}"
 265                                  "user:        {author}\n"
 266                                  "Date:        {date|date}\n"
 267                                  "summary:     {desc}\n\n")
 268   "Mercurial log template for `vc-hg-print-log' long format.")
 269
 270 (defun vc-hg-print-log (files buffer &optional shortlog start-revision limit)
 271   "Print commit log associated with FILES into specified BUFFER.
 272 If SHORTLOG is non-nil, use a short format based on `vc-hg-root-log-format'.
 273 If START-REVISION is non-nil, it is the newest revision to show.
 274 If LIMIT is non-nil, show no more than this many entries."
 275   ;; `vc-do-command' creates the buffer, but we need it before running
 276   ;; the command.
 277   (vc-setup-buffer buffer)
 278   ;; If the buffer exists from a previous invocation it might be
 279   ;; read-only.
 280   (let ((inhibit-read-only t))
 281     (with-current-buffer
 282         buffer
 283       (apply 'vc-hg-command buffer 'async files "log"
 284              (nconc
 285               (when start-revision (list (format "-r%s:0" start-revision)))
 286               (when limit (list "-l" (format "%s" limit)))
 287               (if shortlog
 288                   `(,@(if vc-hg-log-graph '("--graph"))
 289                     "--template"
 290                     ,(car vc-hg-root-log-format))
 291                 `("--template" ,vc-hg-log-format))
 292               vc-hg-log-switches)))))
 293
 294 (defvar log-view-message-re)
 295 (defvar log-view-file-re)
 296 (defvar log-view-font-lock-keywords)
 297 (defvar log-view-per-file-logs)
 298 (defvar log-view-expanded-log-entry-function)
 299
 300 (define-derived-mode vc-hg-log-view-mode log-view-mode "Hg-Log-View"
 301   (require 'add-log) ;; we need the add-log faces
 302   (set (make-local-variable 'log-view-file-re) "\\`a\\`")
 303   (set (make-local-variable 'log-view-per-file-logs) nil)
 304   (set (make-local-variable 'log-view-message-re)
 305        (if (eq vc-log-view-type 'short)
 306            (cadr vc-hg-root-log-format)
 307          "^changeset:[ \t]*\\([0-9]+\\):\\(.+\\)"))
 308   ;; Allow expanding short log entries
 309   (when (eq vc-log-view-type 'short)
 310     (setq truncate-lines t)
 311     (set (make-local-variable 'log-view-expanded-log-entry-function)
 312          'vc-hg-expanded-log-entry))
 313   (set (make-local-variable 'log-view-font-lock-keywords)
 314        (if (eq vc-log-view-type 'short)
 315            (list (cons (nth 1 vc-hg-root-log-format)
 316                        (nth 2 vc-hg-root-log-format)))
 317          (append
 318           log-view-font-lock-keywords
 319           '(
 320             ;; Handle the case:
 321             ;; user: FirstName LastName <foo@bar>
 322             ("^user:[ \t]+\\([^<(]+?\\)[ \t]*[(<]\\([A-Za-z0-9_.+-]+@[A-Za-z0-9_.-]+\\)[>)]"
 323              (1 'change-log-name)
 324              (2 'change-log-email))
 325             ;; Handle the cases:
 326             ;; user: foo@bar
 327             ;; and
 328             ;; user: foo
 329             ("^user:[ \t]+\\([A-Za-z0-9_.+-]+\\(?:@[A-Za-z0-9_.-]+\\)?\\)"
 330              (1 'change-log-email))
 331             ("^date: \\(.+\\)" (1 'change-log-date))
 332             ("^tag: +\\([^ ]+\\)$" (1 'highlight))
 333             ("^summary:[ \t]+\\(.+\\)" (1 'log-view-message)))))))
 334
 335 (autoload 'vc-switches "vc")
 336
 337 (defun vc-hg-diff (files &optional oldvers newvers buffer async)
 338   "Get a difference report using hg between two revisions of FILES."
 339   (let* ((firstfile (car files))
 340          (working (and firstfile (vc-working-revision firstfile))))
 341     (when (and (equal oldvers working) (not newvers))
 342       (setq oldvers nil))
 343     (when (and (not oldvers) newvers)
 344       (setq oldvers working))
 345     (apply #'vc-hg-command
 346            (or buffer "*vc-diff*")
 347            (if async 'async nil)
 348            files "diff"
 349            (append
 350             (vc-switches 'hg 'diff)
 351             (when oldvers
 352               (if newvers
 353                   (list "-r" oldvers "-r" newvers)
 354                 (list "-r" oldvers)))))))
 355
 356 (defun vc-hg-expanded-log-entry (revision)
 357   (with-temp-buffer
 358     (vc-hg-command t nil nil "log" "-r" revision "--template" vc-hg-log-format)
 359     (goto-char (point-min))
 360     (unless (eobp)
 361       ;; Indent the expanded log entry.
 362       (indent-region (point-min) (point-max) 2)
 363       (goto-char (point-max))
 364       (buffer-string))))
 365
 366 (defun vc-hg-revision-table (files)
 367   (let ((default-directory (file-name-directory (car files))))
 368     (with-temp-buffer
 369       (vc-hg-command t nil files "log" "--template" "{rev} ")
 370       (split-string
 371        (buffer-substring-no-properties (point-min) (point-max))))))
 372
 373 ;; Modeled after the similar function in vc-cvs.el
 374 (defun vc-hg-revision-completion-table (files)
 375   (letrec ((table (lazy-completion-table
 376                    table (lambda () (vc-hg-revision-table files)))))
 377     table))
 378
 379 (defun vc-hg-annotate-command (file buffer &optional revision)
 380   "Execute \"hg annotate\" on FILE, inserting the contents in BUFFER.
 381 Optional arg REVISION is a revision to annotate from."
 382   (apply #'vc-hg-command buffer 0 file "annotate" "-d" "-n" "--follow"
 383          (append (vc-switches 'hg 'annotate)
 384                  (if revision (list (concat "-r" revision))))))
 385
 386 (declare-function vc-annotate-convert-time "vc-annotate" (&optional time))
 387
 388 ;; The format for one line output by "hg annotate -d -n" looks like this:
 389 ;;215 Wed Jun 20 21:22:58 2007 -0700: CONTENTS
 390 ;; i.e: VERSION_NUMBER DATE: CONTENTS
 391 ;; If the user has set the "--follow" option, the output looks like:
 392 ;;215 Wed Jun 20 21:22:58 2007 -0700 foo.c: CONTENTS
 393 ;; i.e. VERSION_NUMBER DATE FILENAME: CONTENTS
 394 (defconst vc-hg-annotate-re
 395   "^[ \t]*\\([0-9]+\\) \\(.\\{30\\}\\)\\(?:\\(: \\)\\|\\(?: +\\([^:\n]+\\(?::\\(?:[^: \n][^:\n]*\\)?\\)*\\): \\)\\)")
 396
 397 (defun vc-hg-annotate-time ()
 398   (when (looking-at vc-hg-annotate-re)
 399     (goto-char (match-end 0))
 400     (vc-annotate-convert-time
 401      (date-to-time (match-string-no-properties 2)))))
 402
 403 (defun vc-hg-annotate-extract-revision-at-line ()
 404   (save-excursion
 405     (beginning-of-line)
 406     (when (looking-at vc-hg-annotate-re)
 407       (if (match-beginning 3)
 408           (match-string-no-properties 1)
 409         (cons (match-string-no-properties 1)
 410       (expand-file-name (match-string-no-properties 4)
 411  (vc-hg-root default-directory)))))))
 412
 413 ;;; Tag system
 414
 415 (defun vc-hg-create-tag (dir name branchp)
 416   "Attach the tag NAME to the state of the working copy."
 417   (let ((default-directory dir))
 418     (and (vc-hg-command nil 0 nil "status")
 419          (vc-hg-command nil 0 nil (if branchp "bookmark" "tag") name))))
 420
 421 (defun vc-hg-retrieve-tag (dir name _update)
 422   "Retrieve the version tagged by NAME of all registered files at or below DIR."
 423   (let ((default-directory dir))
 424     (vc-hg-command nil 0 nil "update" name)
 425     ;; FIXME: update buffers if `update' is true
 426     ;; TODO: update *vc-change-log* buffer so can see @ if --graph
 427     ))
 428
 429 ;;; Miscellaneous
 430
 431 (defun vc-hg-previous-revision (_file rev)
 432   (let ((newrev (1- (string-to-number rev))))
 433     (when (>= newrev 0)
 434       (number-to-string newrev))))
 435
 436 (defun vc-hg-next-revision (_file rev)
 437   (let ((newrev (1+ (string-to-number rev)))
 438         (tip-revision
 439          (with-temp-buffer
 440            (vc-hg-command t 0 nil "tip" "--style=default")
 441            (goto-char (point-min))
 442            (re-search-forward "^changeset:[ \t]*\\([0-9]+\\):")
 443            (string-to-number (match-string-no-properties 1)))))
 444     ;; We don't want to exceed the maximum possible revision number, ie
 445     ;; the tip revision.
 446     (when (<= newrev tip-revision)
 447       (number-to-string newrev))))
 448
 449 ;; Modeled after the similar function in vc-bzr.el
 450 (defun vc-hg-delete-file (file)
 451   "Delete FILE and delete it in the hg repository."
 452   (condition-case ()
 453       (delete-file file)
 454     (file-error nil))
 455   (vc-hg-command nil 0 file "remove" "--after" "--force"))
 456
 457 ;; Modeled after the similar function in vc-bzr.el
 458 (defun vc-hg-rename-file (old new)
 459   "Rename file from OLD to NEW using `hg mv'."
 460   (vc-hg-command nil 0 new "mv" old))
 461
 462 (defun vc-hg-register (files &optional _comment)
 463   "Register FILES under hg. COMMENT is ignored."
 464   (vc-hg-command nil 0 files "add"))
 465
 466 (defun vc-hg-create-repo ()
 467   "Create a new Mercurial repository."
 468   (vc-hg-command nil 0 nil "init"))
 469
 470 (defalias 'vc-hg-responsible-p 'vc-hg-root)
 471
 472 (defun vc-hg-unregister (file)
 473   "Unregister FILE from hg."
 474   (vc-hg-command nil 0 file "forget"))
 475
 476 (declare-function log-edit-extract-headers "log-edit" (headers string))
 477
 478 (defun vc-hg-checkin (files comment &optional _rev)
 479   "Hg-specific version of `vc-backend-checkin'.
 480 REV is ignored."
 481   (apply 'vc-hg-command nil 0 files
 482          (nconc (list "commit" "-m")
 483                 (log-edit-extract-headers '(("Author" . "--user")
 484                                             ("Date" . "--date"))
 485                                           comment))))
 486
 487 (defun vc-hg-find-revision (file rev buffer)
 488   (let ((coding-system-for-read 'binary)
 489         (coding-system-for-write 'binary))
 490     (if rev
 491         (vc-hg-command buffer 0 file "cat" "-r" rev)
 492       (vc-hg-command buffer 0 file "cat"))))
 493
 494 (defun vc-hg-find-ignore-file (file)
 495   "Return the root directory of the repository of FILE."
 496   (expand-file-name ".hgignore"
 497                     (vc-hg-root file)))
 498
 499 ;; Modeled after the similar function in vc-bzr.el
 500 (defun vc-hg-checkout (file &optional rev)
 501   "Retrieve a revision of FILE.
 502 EDITABLE is ignored.
 503 REV is the revision to check out into WORKFILE."
 504   (let ((coding-system-for-read 'binary)
 505         (coding-system-for-write 'binary))
 506   (with-current-buffer (or (get-file-buffer file) (current-buffer))
 507     (if rev
 508         (vc-hg-command t 0 file "cat" "-r" rev)
 509       (vc-hg-command t 0 file "cat")))))
 510
 511 (defun vc-hg-resolve-when-done ()
 512   "Call \"hg resolve -m\" if the conflict markers have been removed."
 513   (save-excursion
 514     (goto-char (point-min))
 515     (unless (re-search-forward "^<<<<<<< " nil t)
 516       (vc-hg-command nil 0 buffer-file-name "resolve" "-m")
 517       ;; Remove the hook so that it is not called multiple times.
 518       (remove-hook 'after-save-hook 'vc-hg-resolve-when-done t))))
 519
 520 (defun vc-hg-find-file-hook ()
 521   (when (and buffer-file-name
 522              (file-exists-p (concat buffer-file-name ".orig"))
 523              ;; Hg does not seem to have a "conflict" status, eg
 524              ;; hg http://bz.selenic.com/show_bug.cgi?id=2724
 525              (memq (vc-file-getprop buffer-file-name 'vc-state)
 526                    '(edited conflict))
 527              ;; Maybe go on to check that "hg resolve -l" says "U"?
 528              ;; If "hg resolve -l" says there's a conflict but there are no
 529              ;; conflict markers, it's not clear what we should do.
 530              (save-excursion
 531                (goto-char (point-min))
 532                (re-search-forward "^<<<<<<< " nil t)))
 533     ;; Hg may not recognize "conflict" as a state, but we can do better.
 534     (vc-file-setprop buffer-file-name 'vc-state 'conflict)
 535     (smerge-start-session)
 536     (add-hook 'after-save-hook 'vc-hg-resolve-when-done nil t)
 537     (message "There are unresolved conflicts in this file")))
 538
 539
 540 ;; Modeled after the similar function in vc-bzr.el
 541 (defun vc-hg-revert (file &optional contents-done)
 542   (unless contents-done
 543     (with-temp-buffer (vc-hg-command t 0 file "revert"))))
 544
 545 ;;; Hg specific functionality.
 546
 547 (defvar vc-hg-extra-menu-map
 548   (let ((map (make-sparse-keymap)))
 549     map))
 550
 551 (defun vc-hg-extra-menu () vc-hg-extra-menu-map)
 552
 553 (defun vc-hg-extra-status-menu () vc-hg-extra-menu-map)
 554
 555 (defvar log-view-vc-backend)
 556
 557 (cl-defstruct (vc-hg-extra-fileinfo
 558             (:copier nil)
 559             (:constructor vc-hg-create-extra-fileinfo (rename-state extra-name))
 560             (:conc-name vc-hg-extra-fileinfo->))
 561   rename-state        ;; rename or copy state
 562   extra-name)         ;; original name for copies and rename targets, new name for
 563
 564 (declare-function vc-default-dir-printer "vc-dir" (backend fileentry))
 565
 566 (defun vc-hg-dir-printer (info)
 567   "Pretty-printer for the vc-dir-fileinfo structure."
 568   (let ((extra (vc-dir-fileinfo->extra info)))
 569     (vc-default-dir-printer 'Hg info)
 570     (when extra
 571       (insert (propertize
 572                (format "   (%s %s)"
 573                        (pcase (vc-hg-extra-fileinfo->rename-state extra)
 574                          (`copied "copied from")
 575                          (`renamed-from "renamed from")
 576                          (`renamed-to "renamed to"))
 577                        (vc-hg-extra-fileinfo->extra-name extra))
 578                'face 'font-lock-comment-face)))))
 579
 580 (defun vc-hg-after-dir-status (update-function)
 581   (let ((file nil)
 582         (translation '((?= . up-to-date)
 583                        (?C . up-to-date)
 584                        (?A . added)
 585                        (?R . removed)
 586                        (?M . edited)
 587                        (?I . ignored)
 588                        (?! . missing)
 589                        (?  . copy-rename-line)
 590                        (?? . unregistered)))
 591         (translated nil)
 592         (result nil)
 593         (last-added nil)
 594         (last-line-copy nil))
 595       (goto-char (point-min))
 596       (while (not (eobp))
 597         (setq translated (cdr (assoc (char-after) translation)))
 598         (setq file
 599               (buffer-substring-no-properties (+ (point) 2)
 600                                               (line-end-position)))
 601         (cond ((not translated)
 602                (setq last-line-copy nil))
 603               ((eq translated 'up-to-date)
 604                (setq last-line-copy nil))
 605               ((eq translated 'copy-rename-line)
 606                ;; For copied files the output looks like this:
 607                ;; A COPIED_FILE_NAME
 608                ;;   ORIGINAL_FILE_NAME
 609                (setf (nth 2 last-added)
 610                      (vc-hg-create-extra-fileinfo 'copied file))
 611                (setq last-line-copy t))
 612               ((and last-line-copy (eq translated 'removed))
 613                ;; For renamed files the output looks like this:
 614                ;; A NEW_FILE_NAME
 615                ;;   ORIGINAL_FILE_NAME
 616                ;; R ORIGINAL_FILE_NAME
 617                ;; We need to adjust the previous entry to not think it is a copy.
 618                (setf (vc-hg-extra-fileinfo->rename-state (nth 2 last-added))
 619                      'renamed-from)
 620                (push (list file translated
 621                            (vc-hg-create-extra-fileinfo
 622                             'renamed-to (nth 0 last-added))) result)
 623                (setq last-line-copy nil))
 624               (t
 625                (setq last-added (list file translated nil))
 626                (push last-added result)
 627                (setq last-line-copy nil)))
 628         (forward-line))
 629       (funcall update-function result)))
 630
 631 ;; Follows vc-hg-command (or vc-do-async-command), which uses vc-do-command
 632 ;; from vc-dispatcher.
 633 (declare-function vc-set-async-update "vc-dispatcher" (process-buffer))
 634
 635 (defun vc-hg-dir-status-files (dir files update-function)
 636   (apply 'vc-hg-command (current-buffer) 'async dir "status"
 637          (concat "-mardu" (if files "i"))
 638          "-C" files)
 639   (vc-run-delayed
 640     (vc-hg-after-dir-status update-function)))
 641
 642 (defun vc-hg-dir-extra-header (name &rest commands)
 643   (concat (propertize name 'face 'font-lock-type-face)
 644           (propertize
 645            (with-temp-buffer
 646              (apply 'vc-hg-command (current-buffer) 0 nil commands)
 647              (buffer-substring-no-properties (point-min) (1- (point-max))))
 648            'face 'font-lock-variable-name-face)))
 649
 650 (defun vc-hg-dir-extra-headers (dir)
 651   "Generate extra status headers for a Mercurial tree."
 652   (let ((default-directory dir))
 653     (concat
 654      (vc-hg-dir-extra-header "Root       : " "root") "\n"
 655      (vc-hg-dir-extra-header "Branch     : " "id" "-b") "\n"
 656      (vc-hg-dir-extra-header "Tags       : " "id" "-t") ; "\n"
 657      ;; these change after each commit
 658      ;; (vc-hg-dir-extra-header "Local num  : " "id" "-n") "\n"
 659      ;; (vc-hg-dir-extra-header "Global id  : " "id" "-i")
 660      )))
 661
 662 (defun vc-hg-log-incoming (buffer remote-location)
 663   (vc-hg-command buffer 1 nil "incoming" "-n" (unless (string= remote-location "")
 664                                                 remote-location)))
 665
 666 (defun vc-hg-log-outgoing (buffer remote-location)
 667   (vc-hg-command buffer 1 nil "outgoing" "-n" (unless (string= remote-location "")
 668                                                 remote-location)))
 669
 670 (defvar vc-hg-error-regexp-alist nil
 671   ;; 'hg pull' does not list modified files, so, for now, the only
 672   ;; benefit of `vc-compilation-mode' is that one can get rid of
 673   ;; *vc-hg* buffer with 'q' or 'z'.
 674   ;; TODO: call 'hg incoming' before pull/merge to get the list of
 675   ;;       modified files
 676   "Value of `compilation-error-regexp-alist' in *vc-hg* buffers.")
 677
 678 (autoload 'vc-do-async-command "vc-dispatcher")
 679 (autoload 'log-view-get-marked "log-view")
 680
 681 (defun vc-hg--pushpull (command prompt &optional obsolete)
 682   "Run COMMAND (a string; either push or pull) on the current Hg branch.
 683 If PROMPT is non-nil, prompt for the Hg command to run.
 684 If OBSOLETE is non-nil, behave like the old versions of the Hg push/pull
 685 commands, which only operated on marked files."
 686   (let (marked-list)
 687     ;; The `vc-hg-pull' and `vc-hg-push' commands existed before the
 688     ;; `pull'/`push' VC actions were implemented.
 689     ;; The following is for backwards compatibility.
 690     (if (and obsolete (setq marked-list (log-view-get-marked)))
 691         (apply #'vc-hg-command
 692                nil 0 nil
 693                command
 694                (apply 'nconc
 695                       (mapcar (lambda (arg) (list "-r" arg)) marked-list)))
 696       (let* ((root (vc-hg-root default-directory))
 697              (buffer (format "*vc-hg : %s*" (expand-file-name root)))
 698              (hg-program vc-hg-program)
 699              ;; Fixme: before updating the working copy to the latest
 700              ;; state, should check if it's visiting an old revision.
 701              (args (if (equal command "pull") '("-u"))))
 702         ;; If necessary, prompt for the exact command.
 703         ;; TODO if pushing, prompt if no default push location - cf bzr.
 704         (when prompt
 705           (setq args (split-string
 706                       (read-shell-command
 707                        (format "Hg %s command: " command)
 708                        (format "%s %s%s" hg-program command
 709                                (if (not args) ""
 710                                  (concat " " (mapconcat 'identity args " "))))
 711                        'vc-hg-history)
 712                       " " t))
 713           (setq hg-program (car  args)
 714                 command    (cadr args)
 715                 args       (cddr args)))
 716         (apply 'vc-do-async-command buffer root hg-program command args)
 717         (with-current-buffer buffer
 718           (vc-run-delayed (vc-compilation-mode 'hg)))
 719         (vc-set-async-update buffer)))))
 720
 721 (defun vc-hg-pull (prompt)
 722   "Issue a Mercurial pull command.
 723 If called interactively with a set of marked Log View buffers,
 724 call \"hg pull -r REVS\" to pull in the specified revisions REVS.
 725
 726 With a prefix argument or if PROMPT is non-nil, prompt for a
 727 specific Mercurial pull command.  The default is \"hg pull -u\",
 728 which fetches changesets from the default remote repository and
 729 then attempts to update the working directory."
 730   (interactive "P")
 731   (vc-hg--pushpull "pull" prompt (called-interactively-p 'interactive)))
 732
 733 (defun vc-hg-push (prompt)
 734   "Push changes from the current Mercurial branch.
 735 Normally, this runs \"hg push\".  If PROMPT is non-nil, prompt
 736 for the Hg command to run.
 737
 738 If called interactively with a set of marked Log View buffers,
 739 call \"hg push -r REVS\" to push the specified revisions REVS."
 740   (interactive "P")
 741   (vc-hg--pushpull "push" prompt (called-interactively-p 'interactive)))
 742
 743 (defun vc-hg-merge-branch ()
 744   "Merge incoming changes into the current working directory.
 745 This runs the command \"hg merge\"."
 746   (let* ((root (vc-hg-root default-directory))
 747          (buffer (format "*vc-hg : %s*" (expand-file-name root))))
 748     (apply 'vc-do-async-command buffer root vc-hg-program '("merge"))
 749     (with-current-buffer buffer (vc-run-delayed (vc-compilation-mode 'hg)))
 750     (vc-set-async-update buffer)))
 751
 752 ;;; Internal functions
 753
 754 (defun vc-hg-command (buffer okstatus file-or-list &rest flags)
 755   "A wrapper around `vc-do-command' for use in vc-hg.el.
 756 This function differs from vc-do-command in that it invokes
 757 `vc-hg-program', and passes `vc-hg-global-switches' to it before FLAGS."
 758   (apply 'vc-do-command (or buffer "*vc*") okstatus vc-hg-program file-or-list
 759          (if (stringp vc-hg-global-switches)
 760              (cons vc-hg-global-switches flags)
 761            (append vc-hg-global-switches
 762                    flags))))
 763
 764 (defun vc-hg-root (file)
 765   (vc-find-root file ".hg"))
 766
 767 (provide 'vc-hg)
 768
 769 ;;; vc-hg.el ends here