code.delx.au - gnu-emacs/blob - lisp/select.el

   1 ;;; select.el --- lisp portion of standard selection support
   2
   3 ;; Maintainer: FSF
   4 ;; Keywords: internal
   5
   6 ;; Copyright (C) 1993, 1994, 2001, 2002, 2003, 2004,
   7 ;;   2005, 2006, 2007, 2008 Free Software Foundation, Inc.
   8 ;; Based partially on earlier release by Lucid.
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 3, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  25 ;; Boston, MA 02110-1301, USA.
  26
  27 ;;; Commentary:
  28
  29 ;;; Code:
  30
  31 (defcustom selection-coding-system nil
  32   "Coding system for communicating with other X clients.
  33
  34 When sending text via selection and clipboard, if the target
  35 data-type matches with the type of this coding system, it is used
  36 for encoding the text.  Otherwise (including the case that this
  37 variable is nil), a proper coding system is used as below:
  38
  39 data-type       coding system
  40 ---------       -------------
  41 UTF8_STRING     utf-8
  42 COMPOUND_TEXT   compound-text-with-extensions
  43 STRING          iso-latin-1
  44 C_STRING        no-conversion
  45
  46 When receiving text, if this coding system is non-nil, it is used
  47 for decoding regardless of the data-type.  If this is nil, a
  48 proper coding system is used according to the data-type as above.
  49
  50 See also the documentation of the variable `x-select-request-type' how
  51 to control which data-type to request for receiving text.
  52
  53 The default value is nil."
  54   :type 'coding-system
  55   :group 'mule
  56   ;; Default was compound-text-with-extensions in 22.x (pre-unicode).
  57   :version "23.1"
  58   :set (lambda (symbol value)
  59          (set-selection-coding-system value)
  60          (set symbol value)))
  61
  62 (defvar next-selection-coding-system nil
  63   "Coding system for the next communication with other X clients.
  64 Usually, `selection-coding-system' is used for communicating with
  65 other X clients.  But, if this variable is set, it is used for
  66 the next communication only.  After the communication, this
  67 variable is set to nil.")
  68
  69 ;; This is for temporary compatibility with pre-release Emacs 19.
  70 (defalias 'x-selection 'x-get-selection)
  71 (defun x-get-selection (&optional type data-type)
  72   "Return the value of an X Windows selection.
  73 The argument TYPE (default `PRIMARY') says which selection,
  74 and the argument DATA-TYPE (default `STRING') says
  75 how to convert the data.
  76
  77 TYPE may be any symbol \(but nil stands for `PRIMARY').  However,
  78 only a few symbols are commonly used.  They conventionally have
  79 all upper-case names.  The most often used ones, in addition to
  80 `PRIMARY', are `SECONDARY' and `CLIPBOARD'.
  81
  82 DATA-TYPE is usually `STRING', but can also be one of the symbols
  83 in `selection-converter-alist', which see."
  84   (let ((data (x-get-selection-internal (or type 'PRIMARY)
  85                                         (or data-type 'STRING)))
  86         coding)
  87     (when (and (stringp data)
  88                (setq data-type (get-text-property 0 'foreign-selection data)))
  89       (setq coding (or next-selection-coding-system
  90                        selection-coding-system
  91                        (cond ((eq data-type 'UTF8_STRING)
  92                               'utf-8)
  93                              ((eq data-type 'COMPOUND-TEXT)
  94                               'compound-text-with-extensions)
  95                              ((eq data-type 'C_STRING)
  96                               nil)
  97                              ((eq data-type 'STRING)
  98                               'iso-8859-1)
  99                              (t
 100                               (error "Unknow selection data type: %S" type))))
 101             data (if coding (decode-coding-string data coding)
 102                    (string-to-multibyte data)))
 103       (setq next-selection-coding-system nil)
 104       (put-text-property 0 (length data) 'foreign-selection data-type data))
 105     data))
 106
 107 (defun x-get-clipboard ()
 108   "Return text pasted to the clipboard."
 109   (x-get-selection-internal 'CLIPBOARD 'STRING))
 110
 111 (defun x-set-selection (type data)
 112   "Make an X Windows selection of type TYPE and value DATA.
 113 The argument TYPE (nil means `PRIMARY') says which selection, and
 114 DATA specifies the contents.  TYPE must be a symbol.  \(It can also
 115 be a string, which stands for the symbol with that name, but this
 116 is considered obsolete.)  DATA may be a string, a symbol, an
 117 integer (or a cons of two integers or list of two integers).
 118
 119 The selection may also be a cons of two markers pointing to the same buffer,
 120 or an overlay.  In these cases, the selection is considered to be the text
 121 between the markers *at whatever time the selection is examined*.
 122 Thus, editing done in the buffer after you specify the selection
 123 can alter the effective value of the selection.
 124
 125 The data may also be a vector of valid non-vector selection values.
 126
 127 The return value is DATA.
 128
 129 Interactively, this command sets the primary selection.  Without
 130 prefix argument, it reads the selection in the minibuffer.  With
 131 prefix argument, it uses the text of the region as the selection value ."
 132   (interactive (if (not current-prefix-arg)
 133                    (list 'PRIMARY (read-string "Set text for pasting: "))
 134                  (list 'PRIMARY (buffer-substring (region-beginning) (region-end)))))
 135   ;; This is for temporary compatibility with pre-release Emacs 19.
 136   (if (stringp type)
 137       (setq type (intern type)))
 138   (or (x-valid-simple-selection-p data)
 139       (and (vectorp data)
 140            (let ((valid t)
 141                  (i (1- (length data))))
 142              (while (>= i 0)
 143                (or (x-valid-simple-selection-p (aref data i))
 144                    (setq valid nil))
 145                (setq i (1- i)))
 146              valid))
 147       (signal 'error (list "invalid selection" data)))
 148   (or type (setq type 'PRIMARY))
 149   (if data
 150       (x-own-selection-internal type data)
 151     (x-disown-selection-internal type))
 152   data)
 153
 154 (defun x-valid-simple-selection-p (data)
 155   (or (stringp data)
 156       (symbolp data)
 157       (integerp data)
 158       (and (consp data)
 159            (integerp (car data))
 160            (or (integerp (cdr data))
 161                (and (consp (cdr data))
 162                     (integerp (car (cdr data))))))
 163       (overlayp data)
 164       (and (consp data)
 165            (markerp (car data))
 166            (markerp (cdr data))
 167            (marker-buffer (car data))
 168            (marker-buffer (cdr data))
 169            (eq (marker-buffer (car data))
 170                (marker-buffer (cdr data)))
 171            (buffer-name (marker-buffer (car data)))
 172            (buffer-name (marker-buffer (cdr data))))))
 173 \f
 174 ;;; Cut Buffer support
 175
 176 (declare-function x-get-cut-buffer-internal "xselect.c")
 177
 178 (defun x-get-cut-buffer (&optional which-one)
 179   "Returns the value of one of the 8 X server cut-buffers.
 180 Optional arg WHICH-ONE should be a number from 0 to 7, defaulting to 0.
 181 Cut buffers are considered obsolete; you should use selections instead."
 182   (x-get-cut-buffer-internal
 183    (if which-one
 184        (aref [CUT_BUFFER0 CUT_BUFFER1 CUT_BUFFER2 CUT_BUFFER3
 185               CUT_BUFFER4 CUT_BUFFER5 CUT_BUFFER6 CUT_BUFFER7]
 186              which-one)
 187      'CUT_BUFFER0)))
 188
 189 (declare-function x-rotate-cut-buffers-internal "xselect.c")
 190 (declare-function x-store-cut-buffer-internal "xselect.c")
 191
 192 (defun x-set-cut-buffer (string &optional push)
 193   "Store STRING into the X server's primary cut buffer.
 194 If PUSH is non-nil, also rotate the cut buffers:
 195 this means the previous value of the primary cut buffer moves to the second
 196 cut buffer, and the second to the third, and so on (there are 8 buffers.)
 197 Cut buffers are considered obsolete; you should use selections instead."
 198   (or (stringp string) (signal 'wrong-type-argument (list 'string string)))
 199   (if push
 200       (x-rotate-cut-buffers-internal 1))
 201   (x-store-cut-buffer-internal 'CUT_BUFFER0 string))
 202
 203 \f
 204 ;;; Functions to convert the selection into various other selection types.
 205 ;;; Every selection type that Emacs handles is implemented this way, except
 206 ;;; for TIMESTAMP, which is a special case.
 207
 208 (defun xselect-convert-to-string (selection type value)
 209   (let (str coding)
 210     ;; Get the actual string from VALUE.
 211     (cond ((stringp value)
 212            (setq str value))
 213
 214           ((overlayp value)
 215            (save-excursion
 216              (or (buffer-name (overlay-buffer value))
 217                  (error "selection is in a killed buffer"))
 218              (set-buffer (overlay-buffer value))
 219              (setq str (buffer-substring (overlay-start value)
 220                                          (overlay-end value)))))
 221           ((and (consp value)
 222                 (markerp (car value))
 223                 (markerp (cdr value)))
 224            (or (eq (marker-buffer (car value)) (marker-buffer (cdr value)))
 225                (signal 'error
 226                        (list "markers must be in the same buffer"
 227                              (car value) (cdr value))))
 228            (save-excursion
 229              (set-buffer (or (marker-buffer (car value))
 230                              (error "selection is in a killed buffer")))
 231              (setq str (buffer-substring (car value) (cdr value))))))
 232
 233     (when str
 234       ;; If TYPE is nil, this is a local request, thus return STR as
 235       ;; is.  Otherwise, encode STR.
 236       (if (not type)
 237           str
 238         (setq coding (or next-selection-coding-system selection-coding-system))
 239         (if coding
 240             (setq coding (coding-system-base coding)))
 241         (let ((inhibit-read-only t))
 242           ;; Suppress producing escape sequences for compositions.
 243           (remove-text-properties 0 (length str) '(composition nil) str)
 244           (if (eq type 'TEXT)
 245               ;; TEXT is a polymorphic target.  We must select the
 246               ;; actual type from `UTF8_STRING', `COMPOUND_TEXT',
 247               ;; `STRING', and `C_STRING'.
 248               (if (not (multibyte-string-p str))
 249                   (setq type 'C_STRING)
 250                 (let (non-latin-1 non-unicode eight-bit)
 251                   (mapc #'(lambda (x)
 252                             (if (>= x #x100)
 253                                 (if (< x #x110000)
 254                                     (setq non-latin-1 t)
 255                                   (if (< x #x3FFF80)
 256                                       (setq non-unicode t)
 257                                     (setq eight-bit t)))))
 258                         str)
 259                   (setq type (if non-unicode 'COMPOUND_TEXT
 260                                (if non-latin-1 'UTF8_STRING
 261                                  (if eight-bit 'C_STRING 'STRING)))))))
 262           (cond
 263            ((eq type 'UTF8_STRING)
 264             (if (or (not coding)
 265                     (not (eq (coding-system-type coding) 'utf-8)))
 266                 (setq coding 'utf-8))
 267             (setq str (encode-coding-string str coding)))
 268
 269            ((eq type 'STRING)
 270             (if (or (not coding)
 271                     (not (eq (coding-system-type coding) 'charset)))
 272                 (setq coding 'iso-8859-1))
 273             (setq str (encode-coding-string str coding)))
 274
 275            ((eq type 'COMPOUND_TEXT)
 276             (if (or (not coding)
 277                     (not (eq (coding-system-type coding) 'iso-2022)))
 278                 (setq coding 'compound-text-with-extensions))
 279             (setq str (encode-coding-string str coding)))
 280
 281            ((eq type 'C_STRING)
 282             (setq str (string-make-unibyte str)))
 283
 284            (t
 285             (error "Unknow selection type: %S" type))
 286            )))
 287
 288       (setq next-selection-coding-system nil)
 289       (cons type str))))
 290
 291
 292 (defun xselect-convert-to-length (selection type value)
 293   (let ((value
 294          (cond ((stringp value)
 295                 (length value))
 296                ((overlayp value)
 297                 (abs (- (overlay-end value) (overlay-start value))))
 298                ((and (consp value)
 299                      (markerp (car value))
 300                      (markerp (cdr value)))
 301                 (or (eq (marker-buffer (car value))
 302                         (marker-buffer (cdr value)))
 303                     (signal 'error
 304                             (list "markers must be in the same buffer"
 305                                   (car value) (cdr value))))
 306                 (abs (- (car value) (cdr value)))))))
 307     (if value ; force it to be in 32-bit format.
 308         (cons (ash value -16) (logand value 65535))
 309       nil)))
 310
 311 (defun xselect-convert-to-targets (selection type value)
 312   ;; return a vector of atoms, but remove duplicates first.
 313   (let* ((all (cons 'TIMESTAMP (mapcar 'car selection-converter-alist)))
 314          (rest all))
 315     (while rest
 316       (cond ((memq (car rest) (cdr rest))
 317              (setcdr rest (delq (car rest) (cdr rest))))
 318             ((eq (car (cdr rest)) '_EMACS_INTERNAL)  ; shh, it's a secret
 319              (setcdr rest (cdr (cdr rest))))
 320             (t
 321              (setq rest (cdr rest)))))
 322     (apply 'vector all)))
 323
 324 (defun xselect-convert-to-delete (selection type value)
 325   (x-disown-selection-internal selection)
 326   ;; A return value of nil means that we do not know how to do this conversion,
 327   ;; and replies with an "error".  A return value of NULL means that we have
 328   ;; done the conversion (and any side-effects) but have no value to return.
 329   'NULL)
 330
 331 (defun xselect-convert-to-filename (selection type value)
 332   (cond ((overlayp value)
 333          (buffer-file-name (or (overlay-buffer value)
 334                                (error "selection is in a killed buffer"))))
 335         ((and (consp value)
 336               (markerp (car value))
 337               (markerp (cdr value)))
 338          (buffer-file-name (or (marker-buffer (car value))
 339                                (error "selection is in a killed buffer"))))
 340         (t nil)))
 341
 342 (defun xselect-convert-to-charpos (selection type value)
 343   (let (a b tmp)
 344     (cond ((cond ((overlayp value)
 345                   (setq a (overlay-start value)
 346                         b (overlay-end value)))
 347                  ((and (consp value)
 348                        (markerp (car value))
 349                        (markerp (cdr value)))
 350                   (setq a (car value)
 351                         b (cdr value))))
 352            (setq a (1- a) b (1- b)) ; zero-based
 353            (if (< b a) (setq tmp a a b b tmp))
 354            (cons 'SPAN
 355                  (vector (cons (ash a -16) (logand a 65535))
 356                          (cons (ash b -16) (logand b 65535))))))))
 357
 358 (defun xselect-convert-to-lineno (selection type value)
 359   (let (a b buf tmp)
 360     (cond ((cond ((and (consp value)
 361                        (markerp (car value))
 362                        (markerp (cdr value)))
 363                   (setq a (marker-position (car value))
 364                         b (marker-position (cdr value))
 365                         buf (marker-buffer (car value))))
 366                  ((overlayp value)
 367                   (setq buf (overlay-buffer value)
 368                         a (overlay-start value)
 369                         b (overlay-end value)))
 370                  )
 371            (save-excursion
 372              (set-buffer buf)
 373              (setq a (count-lines 1 a)
 374                    b (count-lines 1 b)))
 375            (if (< b a) (setq tmp a a b b tmp))
 376            (cons 'SPAN
 377                  (vector (cons (ash a -16) (logand a 65535))
 378                          (cons (ash b -16) (logand b 65535))))))))
 379
 380 (defun xselect-convert-to-colno (selection type value)
 381   (let (a b buf tmp)
 382     (cond ((cond ((and (consp value)
 383                        (markerp (car value))
 384                        (markerp (cdr value)))
 385                   (setq a (car value)
 386                         b (cdr value)
 387                         buf (marker-buffer a)))
 388                  ((overlayp value)
 389                   (setq buf (overlay-buffer value)
 390                         a (overlay-start value)
 391                         b (overlay-end value)))
 392                  )
 393            (save-excursion
 394              (set-buffer buf)
 395              (goto-char a)
 396              (setq a (current-column))
 397              (goto-char b)
 398              (setq b (current-column)))
 399            (if (< b a) (setq tmp a a b b tmp))
 400            (cons 'SPAN
 401                  (vector (cons (ash a -16) (logand a 65535))
 402                          (cons (ash b -16) (logand b 65535))))))))
 403
 404 (defun xselect-convert-to-os (selection type size)
 405   (symbol-name system-type))
 406
 407 (defun xselect-convert-to-host (selection type size)
 408   (system-name))
 409
 410 (defun xselect-convert-to-user (selection type size)
 411   (user-full-name))
 412
 413 (defun xselect-convert-to-class (selection type size)
 414   "Convert selection to class.
 415 This function returns the string \"Emacs\"."
 416   "Emacs")
 417
 418 ;; We do not try to determine the name Emacs was invoked with,
 419 ;; because it is not clean for a program's behavior to depend on that.
 420 (defun xselect-convert-to-name (selection type size)
 421   "Convert selection to name.
 422 This function returns the string \"emacs\"."
 423   "emacs")
 424
 425 (defun xselect-convert-to-integer (selection type value)
 426   (and (integerp value)
 427        (cons (ash value -16) (logand value 65535))))
 428
 429 (defun xselect-convert-to-atom (selection type value)
 430   (and (symbolp value) value))
 431
 432 (defun xselect-convert-to-identity (selection type value) ; used internally
 433   (vector value))
 434
 435 (setq selection-converter-alist
 436       '((TEXT . xselect-convert-to-string)
 437         (COMPOUND_TEXT . xselect-convert-to-string)
 438         (STRING . xselect-convert-to-string)
 439         (UTF8_STRING . xselect-convert-to-string)
 440         (TARGETS . xselect-convert-to-targets)
 441         (LENGTH . xselect-convert-to-length)
 442         (DELETE . xselect-convert-to-delete)
 443         (FILE_NAME . xselect-convert-to-filename)
 444         (CHARACTER_POSITION . xselect-convert-to-charpos)
 445         (LINE_NUMBER . xselect-convert-to-lineno)
 446         (COLUMN_NUMBER . xselect-convert-to-colno)
 447         (OWNER_OS . xselect-convert-to-os)
 448         (HOST_NAME . xselect-convert-to-host)
 449         (USER . xselect-convert-to-user)
 450         (CLASS . xselect-convert-to-class)
 451         (NAME . xselect-convert-to-name)
 452         (ATOM . xselect-convert-to-atom)
 453         (INTEGER . xselect-convert-to-integer)
 454         (_EMACS_INTERNAL . xselect-convert-to-identity)
 455         ))
 456
 457 (provide 'select)
 458
 459 ;; arch-tag: bb634f97-8a3b-4b0a-b940-f6e09982328c
 460 ;;; select.el ends here