code.delx.au - gnu-emacs/blob - lisp/progmodes/scheme.el

   1 ;;; scheme.el --- Scheme (and DSSSL) editing mode.
   2
   3 ;; Copyright (C) 1986, 87, 88, 97, 1998 Free Software Foundation, Inc.
   4
   5 ;; Author: Bill Rozas <jinx@martigny.ai.mit.edu>
   6 ;; Adapted-by: Dave Love <d.love@dl.ac.uk>
   7 ;; Keywords: languages, lisp
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; The major mode for editing Scheme-type Lisp code, very similar to
  29 ;; the Lisp mode documented in the Emacs manual.  `dsssl-mode' is a
  30 ;; variant of scheme-mode for editing DSSSL specifications for SGML
  31 ;; documents.  [As of Apr 1997, some pointers for DSSSL may be found,
  32 ;; for instance, at <URL:http://www.sil.org/sgml/related.html#dsssl>.]
  33 ;; All these Lisp-ish modes vary basically in details of the language
  34 ;; syntax they highlight/indent/index, but dsssl-mode uses "^;;;" as
  35 ;; the page-delimiter since ^L isn't normally a legal SGML character.
  36 ;;
  37 ;; For interacting with a Scheme interpreter See also `run-scheme' in
  38 ;; the `cmuscheme' package and also the implementation-specific
  39 ;; `xscheme' package.
  40
  41 ;; Here's a recipe to generate a TAGS file for DSSSL, by the way:
  42 ;; etags --lang=scheme --regex='/[ \t]*(\(mode\|element\)[ \t
  43 ;; ]+\([^ \t(
  44 ;; ]+\)/\2/' --regex='/[ \t]*(element[ \t
  45 ;; ]*([^)]+[ \t
  46 ;; ]+\([^)]+\)[ \t
  47 ;; ]*)/\1/' --regex='/(declare[^ \t
  48 ;; ]*[ \t
  49 ;; ]+\([^ \t
  50 ;; ]+\)/\1/' "$@"
  51
  52 ;;; Code:
  53 \f
  54 (require 'lisp-mode)
  55
  56 (defvar scheme-mode-syntax-table nil)
  57 (if (not scheme-mode-syntax-table)
  58     (let ((i 0))
  59       (setq scheme-mode-syntax-table (make-syntax-table))
  60       (set-syntax-table scheme-mode-syntax-table)
  61
  62       ;; Default is atom-constituent.
  63       (while (< i 256)
  64         (modify-syntax-entry i "_   ")
  65         (setq i (1+ i)))
  66
  67       ;; Word components.
  68       (setq i ?0)
  69       (while (<= i ?9)
  70         (modify-syntax-entry i "w   ")
  71         (setq i (1+ i)))
  72       (setq i ?A)
  73       (while (<= i ?Z)
  74         (modify-syntax-entry i "w   ")
  75         (setq i (1+ i)))
  76       (setq i ?a)
  77       (while (<= i ?z)
  78         (modify-syntax-entry i "w   ")
  79         (setq i (1+ i)))
  80
  81       ;; Whitespace
  82       (modify-syntax-entry ?\t "    ")
  83       (modify-syntax-entry ?\n ">   ")
  84       (modify-syntax-entry ?\f "    ")
  85       (modify-syntax-entry ?\r "    ")
  86       (modify-syntax-entry ?  "    ")
  87
  88       ;; These characters are delimiters but otherwise undefined.
  89       ;; Brackets and braces balance for editing convenience.
  90       (modify-syntax-entry ?\[ "(]  ")
  91       (modify-syntax-entry ?\] ")[  ")
  92       (modify-syntax-entry ?{ "(}  ")
  93       (modify-syntax-entry ?} "){  ")
  94       (modify-syntax-entry ?\| "  23")
  95
  96       ;; Other atom delimiters
  97       (modify-syntax-entry ?\( "()  ")
  98       (modify-syntax-entry ?\) ")(  ")
  99       (modify-syntax-entry ?\; "<   ")
 100       (modify-syntax-entry ?\" "\"    ")
 101       (modify-syntax-entry ?' "  p")
 102       (modify-syntax-entry ?` "  p")
 103
 104       ;; Special characters
 105       (modify-syntax-entry ?, "_ p")
 106       (modify-syntax-entry ?@ "_ p")
 107       (modify-syntax-entry ?# "_ p14")
 108       (modify-syntax-entry ?\\ "\\   ")))
 109 \f
 110 (defvar scheme-mode-abbrev-table nil)
 111 (define-abbrev-table 'scheme-mode-abbrev-table ())
 112
 113 (defvar scheme-imenu-generic-expression
 114       '((nil
 115          "^(define\\(\\|-\\(generic\\(\\|-procedure\\)\\|method\\)\\)*\\s-+(?\\(\\sw+\\)" 4)
 116         ("Types"
 117          "^(define-class\\s-+(?\\(\\sw+\\)" 1)
 118         ("Macros"
 119          "^(\\(defmacro\\|define-macro\\|define-syntax\\)\\s-+(?\\(\\sw+\\)" 2))
 120   "Imenu generic expression for Scheme mode.  See `imenu-generic-expression'.")
 121
 122 (defun scheme-mode-variables ()
 123   (set-syntax-table scheme-mode-syntax-table)
 124   (setq local-abbrev-table scheme-mode-abbrev-table)
 125   (make-local-variable 'paragraph-start)
 126   (setq paragraph-start (concat "$\\|" page-delimiter))
 127   (make-local-variable 'paragraph-separate)
 128   (setq paragraph-separate paragraph-start)
 129   (make-local-variable 'paragraph-ignore-fill-prefix)
 130   (setq paragraph-ignore-fill-prefix t)
 131   (make-local-variable 'fill-paragraph-function)
 132   (setq fill-paragraph-function 'lisp-fill-paragraph)
 133   ;; Adaptive fill mode gets in the way of auto-fill,
 134   ;; and should make no difference for explicit fill
 135   ;; because lisp-fill-paragraph should do the job.
 136   (make-local-variable 'adaptive-fill-mode)
 137   (setq adaptive-fill-mode nil)
 138   (make-local-variable 'normal-auto-fill-function)
 139   (setq normal-auto-fill-function 'lisp-mode-auto-fill)
 140   (make-local-variable 'indent-line-function)
 141   (setq indent-line-function 'lisp-indent-line)
 142   (make-local-variable 'parse-sexp-ignore-comments)
 143   (setq parse-sexp-ignore-comments t)
 144   (make-local-variable 'outline-regexp)
 145   (setq outline-regexp ";;; \\|(....")
 146   (make-local-variable 'comment-start)
 147   (setq comment-start ";")
 148   (make-local-variable 'comment-start-skip)
 149   ;; Look within the line for a ; following an even number of backslashes
 150   ;; after either a non-backslash or the line beginning.
 151   (setq comment-start-skip "\\(\\(^\\|[^\\\\\n]\\)\\(\\\\\\\\\\)*\\);+[ \t]*")
 152   (make-local-variable 'comment-column)
 153   (setq comment-column 40)
 154   (make-local-variable 'comment-indent-function)
 155   (setq comment-indent-function 'lisp-comment-indent)
 156   (make-local-variable 'parse-sexp-ignore-comments)
 157   (setq parse-sexp-ignore-comments t)
 158   (make-local-variable 'lisp-indent-function)
 159   (set lisp-indent-function 'scheme-indent-function)
 160   (setq mode-line-process '("" scheme-mode-line-process))
 161   (make-local-variable 'imenu-case-fold-search)
 162   (setq imenu-case-fold-search t)
 163   (setq imenu-generic-expression scheme-imenu-generic-expression)
 164   (make-local-variable 'imenu-syntax-alist)
 165   (setq imenu-syntax-alist '(("+-*/.<>=?!$%_&~^:" . "w")))
 166   (make-local-variable 'font-lock-defaults)
 167   (setq font-lock-defaults
 168         '((scheme-font-lock-keywords
 169            scheme-font-lock-keywords-1 scheme-font-lock-keywords-2)
 170           nil t (("+-*/.<>=!?$%_&~^:" . "w")) beginning-of-defun
 171           (font-lock-mark-block-function . mark-defun))))
 172
 173 (defvar scheme-mode-line-process "")
 174
 175 (defvar scheme-mode-map nil
 176   "Keymap for Scheme mode.
 177 All commands in `shared-lisp-mode-map' are inherited by this map.")
 178
 179 (if scheme-mode-map
 180     ()
 181   (let ((map (make-sparse-keymap "Scheme")))
 182     (setq scheme-mode-map
 183           (nconc (make-sparse-keymap) shared-lisp-mode-map))
 184     (define-key scheme-mode-map [menu-bar] (make-sparse-keymap))
 185     (define-key scheme-mode-map [menu-bar scheme]
 186       (cons "Scheme" map))
 187     (define-key map [run-scheme] '("Run Inferior Scheme" . run-scheme))
 188     (define-key map [uncomment-region]
 189       '("Uncomment Out Region" . (lambda (beg end)
 190                                    (interactive "r")
 191                                    (comment-region beg end '(4)))))
 192     (define-key map [comment-region] '("Comment Out Region" . comment-region))
 193     (define-key map [indent-region] '("Indent Region" . indent-region))
 194     (define-key map [indent-line] '("Indent Line" . lisp-indent-line))
 195     (put 'comment-region 'menu-enable 'mark-active)
 196     (put 'uncomment-region 'menu-enable 'mark-active)
 197     (put 'indent-region 'menu-enable 'mark-active)))
 198
 199 ;; Used by cmuscheme
 200 (defun scheme-mode-commands (map)
 201   ;;(define-key map "\t" 'indent-for-tab-command) ; default
 202   (define-key map "\177" 'backward-delete-char-untabify)
 203   (define-key map "\e\C-q" 'indent-sexp))
 204 \f
 205 ;;;###autoload
 206 (defun scheme-mode ()
 207   "Major mode for editing Scheme code.
 208 Editing commands are similar to those of `lisp-mode'.
 209
 210 In addition, if an inferior Scheme process is running, some additional
 211 commands will be defined, for evaluating expressions and controlling
 212 the interpreter, and the state of the process will be displayed in the
 213 modeline of all Scheme buffers.  The names of commands that interact
 214 with the Scheme process start with \"xscheme-\".  For more information
 215 see the documentation for xscheme-interaction-mode.
 216
 217 Commands:
 218 Delete converts tabs to spaces as it moves back.
 219 Blank lines separate paragraphs.  Semicolons start comments.
 220 \\{scheme-mode-map}
 221 Entry to this mode calls the value of `scheme-mode-hook'
 222 if that value is non-nil."
 223   (interactive)
 224   (kill-all-local-variables)
 225   (scheme-mode-initialize)
 226   (scheme-mode-variables)
 227   (run-hooks 'scheme-mode-hook))
 228
 229 (defun scheme-mode-initialize ()
 230   (use-local-map scheme-mode-map)
 231   (setq major-mode 'scheme-mode)
 232   (setq mode-name "Scheme"))
 233
 234 (defgroup scheme nil
 235   "Editing Scheme code"
 236   :group 'lisp)
 237
 238 (defcustom scheme-mit-dialect t
 239   "If non-nil, scheme mode is specialized for MIT Scheme.
 240 Set this to nil if you normally use another dialect."
 241   :type 'boolean
 242   :group 'scheme)
 243
 244 (defcustom dsssl-sgml-declaration
 245   "<!DOCTYPE style-sheet PUBLIC \"-//James Clark//DTD DSSSL Style Sheet//EN\">
 246 "
 247   "*An SGML declaration for the DSSSL file.
 248 If it is defined as a string this will be inserted into an empty buffer
 249 which is in `dsssl-mode'.  It is typically James Clark's style-sheet
 250 doctype, as required for Jade."
 251   :type '(choice (string :tag "Specified string")
 252                  (const :tag "None" :value nil))
 253   :group 'scheme)
 254
 255 (defcustom scheme-mode-hook nil
 256   "Normal hook run when entering `scheme-mode'.
 257 See `run-hooks'."
 258   :type 'hook
 259   :group 'scheme)
 260
 261 (defcustom dsssl-mode-hook nil
 262   "Normal hook run when entering `dsssl-mode'.
 263 See `run-hooks'."
 264   :type 'hook
 265   :group 'scheme)
 266
 267 (defvar dsssl-imenu-generic-expression
 268   ;; Perhaps this should also look for the style-sheet DTD tags.  I'm
 269   ;; not sure it's the best way to organize it; perhaps one type
 270   ;; should be at the first level, though you don't see this anyhow if
 271   ;; it gets split up.
 272   '(("Defines"
 273      "^(define\\s-+(?\\(\\sw+\\)" 1)
 274     ("Modes"
 275      "^\\s-*(mode\\s-+\\(\\(\\sw\\|\\s-\\)+\\)" 1)
 276     ("Elements"
 277      ;; (element foo ...) or (element (foo bar ...) ...)
 278      ;; Fixme: Perhaps it should do `root'.
 279      "^\\s-*(element\\s-+(?\\(\\(\\sw\\|\\s-\\)+\\))?" 1)
 280     ("Declarations"
 281      "^(declare\\(-\\sw+\\)+\\>\\s-+\\(\\sw+\\)" 2))
 282   "Imenu generic expression for DSSSL mode.  See `imenu-generic-expression'.")
 283
 284 (defconst scheme-font-lock-keywords-1
 285   (eval-when-compile
 286     (list
 287      ;;
 288      ;; Declarations.  Hannes Haug <hannes.haug@student.uni-tuebingen.de> says
 289      ;; this works for SOS, STklos, SCOOPS, Meroon and Tiny CLOS.
 290      (list (concat "(\\(define\\*?\\("
 291                    ;; Function names.
 292                    "\\(\\|-public\\|-method\\|-generic\\(-procedure\\)?\\)\\|"
 293                    ;; Macro names, as variable names.  A bit dubious, this.
 294                    "\\(-syntax\\)\\|"
 295                    ;; Class names.
 296                    "-class"
 297                    ;; Guile modules.
 298                    "\\|-module"
 299                    "\\)\\)\\>"
 300                    ;; Any whitespace and declared object.
 301                    "[ \t]*(?"
 302                    "\\(\\sw+\\)?")
 303            '(1 font-lock-keyword-face)
 304            '(6 (cond ((match-beginning 3) font-lock-function-name-face)
 305                      ((match-beginning 5) font-lock-variable-name-face)
 306                      (t font-lock-type-face))
 307                nil t))
 308      ))
 309   "Subdued expressions to highlight in Scheme modes.")
 310
 311 (defconst scheme-font-lock-keywords-2
 312   (append scheme-font-lock-keywords-1
 313    (eval-when-compile
 314      (list
 315       ;;
 316       ;; Control structures.
 317       (cons
 318        (concat
 319         "(" (regexp-opt
 320              '("begin" "call-with-current-continuation" "call/cc"
 321                "call-with-input-file" "call-with-output-file" "case" "cond"
 322                "do" "else" "for-each" "if" "lambda"
 323                "let" "let*" "let-syntax" "letrec" "letrec-syntax"
 324                ;; Hannes Haug <hannes.haug@student.uni-tuebingen.de> wants:
 325                "and" "or" "delay"
 326                ;; Stefan Monnier <stefan.monnier@epfl.ch> says don't bother:
 327                ;;"quasiquote" "quote" "unquote" "unquote-splicing"
 328                "map" "syntax" "syntax-rules") t)
 329         "\\>") 1)
 330       ;;
 331       ;; David Fox <fox@graphics.cs.nyu.edu> for SOS/STklos class specifiers.
 332       '("\\<<\\sw+>\\>" . font-lock-type-face)
 333       ;;
 334       ;; Scheme `:' keywords as builtins.
 335       '("\\<:\\sw+\\>" . font-lock-builtin-face)
 336       )))
 337   "Gaudy expressions to highlight in Scheme modes.")
 338
 339 (defvar scheme-font-lock-keywords scheme-font-lock-keywords-1
 340   "Default expressions to highlight in Scheme modes.")
 341
 342 ;;;###autoload
 343 (defun dsssl-mode ()
 344   "Major mode for editing DSSSL code.
 345 Editing commands are similar to those of `lisp-mode'.
 346
 347 Commands:
 348 Delete converts tabs to spaces as it moves back.
 349 Blank lines separate paragraphs.  Semicolons start comments.
 350 \\{scheme-mode-map}
 351 Entering this mode runs the hooks `scheme-mode-hook' and then
 352 `dsssl-mode-hook' and inserts the value of `dsssl-sgml-declaration' if
 353 that variable's value is a string."
 354   (interactive)
 355   (kill-all-local-variables)
 356   (use-local-map scheme-mode-map)
 357   (scheme-mode-initialize)
 358   (make-local-variable 'page-delimiter)
 359   (setq page-delimiter "^;;;" ; ^L not valid SGML char
 360         major-mode 'dsssl-mode
 361         mode-name "DSSSL")
 362   ;; Insert a suitable SGML declaration into an empty buffer.
 363   (and (zerop (buffer-size))
 364        (stringp dsssl-sgml-declaration)
 365        (not buffer-read-only)
 366        (insert dsssl-sgml-declaration))
 367   (scheme-mode-variables)
 368   (setq font-lock-defaults '(dsssl-font-lock-keywords
 369                              nil t (("+-*/.<>=?$%_&~^:" . "w"))
 370                              beginning-of-defun
 371                              (font-lock-mark-block-function . mark-defun)))
 372   (setq imenu-case-fold-search nil)
 373   (setq imenu-generic-expression dsssl-imenu-generic-expression)
 374   (setq imenu-syntax-alist '(("+-*/.<>=?$%_&~^:" . "w")))
 375   (run-hooks 'scheme-mode-hook)
 376   (run-hooks 'dsssl-mode-hook))
 377
 378 ;; Extra syntax for DSSSL.  This isn't separated from Scheme, but
 379 ;; shouldn't cause much trouble in scheme-mode.
 380 (put 'element 'scheme-indent-function 1)
 381 (put 'mode 'scheme-indent-function 1)
 382 (put 'with-mode 'scheme-indent-function 1)
 383 (put 'make 'scheme-indent-function 1)
 384 (put 'style 'scheme-indent-function 1)
 385 (put 'root 'scheme-indent-function 1)
 386
 387 (defvar dsssl-font-lock-keywords
 388   (eval-when-compile
 389     (list
 390      ;; Similar to Scheme
 391      (list "(\\(define\\(-\\w+\\)?\\)\\>[       ]*\\\((?\\)\\(\\sw+\\)\\>"
 392            '(1 font-lock-keyword-face)
 393            '(4 font-lock-function-name-face))
 394      (cons
 395       (concat "(\\("
 396               ;; (make-regexp '("case" "cond" "else" "if" "lambda"
 397               ;; "let" "let*" "letrec" "and" "or" "map" "with-mode"))
 398               "and\\|c\\(ase\\|ond\\)\\|else\\|if\\|"
 399               "l\\(ambda\\|et\\(\\|*\\|rec\\)\\)\\|map\\|or\\|with-mode"
 400               "\\)\\>")
 401       1)
 402      ;; DSSSL syntax
 403      '("(\\(element\\|mode\\|declare-\\w+\\)\\>[        ]*\\(\\sw+\\)"
 404        (1 font-lock-keyword-face)
 405        (2 font-lock-type-face))
 406      '("(\\(element\\)\\>[      ]*(\\(\\S)+\\))"
 407        (1 font-lock-keyword-face)
 408        (2 font-lock-type-face))
 409      '("\\<\\sw+:\\>" . font-lock-constant-face) ; trailing `:' c.f. scheme
 410      ;; SGML markup (from sgml-mode) :
 411      '("<\\([!?][-a-z0-9]+\\)" 1 font-lock-keyword-face)
 412      '("<\\(/?[-a-z0-9]+\\)" 1 font-lock-function-name-face)))
 413   "Default expressions to highlight in DSSSL mode.")
 414
 415 \f
 416 (defvar calculate-lisp-indent-last-sexp)
 417
 418 ;; Copied from lisp-indent-function, but with gets of
 419 ;; scheme-indent-{function,hook}.
 420 (defun scheme-indent-function (indent-point state)
 421   (let ((normal-indent (current-column)))
 422     (goto-char (1+ (elt state 1)))
 423     (parse-partial-sexp (point) calculate-lisp-indent-last-sexp 0 t)
 424     (if (and (elt state 2)
 425              (not (looking-at "\\sw\\|\\s_")))
 426         ;; car of form doesn't seem to be a a symbol
 427         (progn
 428           (if (not (> (save-excursion (forward-line 1) (point))
 429                       calculate-lisp-indent-last-sexp))
 430               (progn (goto-char calculate-lisp-indent-last-sexp)
 431                      (beginning-of-line)
 432                      (parse-partial-sexp (point)
 433                                          calculate-lisp-indent-last-sexp 0 t)))
 434           ;; Indent under the list or under the first sexp on the same
 435           ;; line as calculate-lisp-indent-last-sexp.  Note that first
 436           ;; thing on that line has to be complete sexp since we are
 437           ;; inside the innermost containing sexp.
 438           (backward-prefix-chars)
 439           (current-column))
 440       (let ((function (buffer-substring (point)
 441                                         (progn (forward-sexp 1) (point))))
 442             method)
 443         (setq method (or (get (intern-soft function) 'scheme-indent-function)
 444                          (get (intern-soft function) 'scheme-indent-hook)))
 445         (cond ((or (eq method 'defun)
 446                    (and (null method)
 447                         (> (length function) 3)
 448                         (string-match "\\`def" function)))
 449                (lisp-indent-defform state indent-point))
 450               ((integerp method)
 451                (lisp-indent-specform method state
 452                                      indent-point normal-indent))
 453               (method
 454                 (funcall method state indent-point normal-indent)))))))
 455
 456 \f
 457 ;;; Let is different in Scheme
 458
 459 (defun would-be-symbol (string)
 460   (not (string-equal (substring string 0 1) "(")))
 461
 462 (defun next-sexp-as-string ()
 463   ;; Assumes that it is protected by a save-excursion
 464   (forward-sexp 1)
 465   (let ((the-end (point)))
 466     (backward-sexp 1)
 467     (buffer-substring (point) the-end)))
 468
 469 ;; This is correct but too slow.
 470 ;; The one below works almost always.
 471 ;;(defun scheme-let-indent (state indent-point)
 472 ;;  (if (would-be-symbol (next-sexp-as-string))
 473 ;;      (scheme-indent-specform 2 state indent-point)
 474 ;;      (scheme-indent-specform 1 state indent-point)))
 475
 476 (defun scheme-let-indent (state indent-point normal-indent)
 477   (skip-chars-forward " \t")
 478   (if (looking-at "[-a-zA-Z0-9+*/?!@$%^&_:~]")
 479       (lisp-indent-specform 2 state indent-point normal-indent)
 480     (lisp-indent-specform 1 state indent-point normal-indent)))
 481
 482 ;; (put 'begin 'scheme-indent-function 0), say, causes begin to be indented
 483 ;; like defun if the first form is placed on the next line, otherwise
 484 ;; it is indented like any other form (i.e. forms line up under first).
 485
 486 (put 'begin 'scheme-indent-function 0)
 487 (put 'case 'scheme-indent-function 1)
 488 (put 'delay 'scheme-indent-function 0)
 489 (put 'do 'scheme-indent-function 2)
 490 (put 'lambda 'scheme-indent-function 1)
 491 (put 'let 'scheme-indent-function 'scheme-let-indent)
 492 (put 'let* 'scheme-indent-function 1)
 493 (put 'letrec 'scheme-indent-function 1)
 494 (put 'sequence 'scheme-indent-function 0) ; SICP, not r4rs
 495 (put 'let-syntax 'scheme-indent-function 1)
 496 (put 'letrec-syntax 'scheme-indent-function 1)
 497 (put 'syntax-rules 'scheme-indent-function 1)
 498
 499
 500 (put 'call-with-input-file 'scheme-indent-function 1)
 501 (put 'with-input-from-file 'scheme-indent-function 1)
 502 (put 'with-input-from-port 'scheme-indent-function 1)
 503 (put 'call-with-output-file 'scheme-indent-function 1)
 504 (put 'with-output-to-file 'scheme-indent-function 1)
 505 (put 'with-output-to-port 'scheme-indent-function 1)
 506 (put 'call-with-values 'scheme-indent-function 1) ; r5rs?
 507 (put 'dynamic-wind 'scheme-indent-function 3) ; r5rs?
 508 \f
 509 ;;;; MIT Scheme specific indentation.
 510
 511 (if scheme-mit-dialect
 512     (progn
 513       (put 'fluid-let 'scheme-indent-function 1)
 514       (put 'in-package 'scheme-indent-function 1)
 515       (put 'local-declare 'scheme-indent-function 1)
 516       (put 'macro 'scheme-indent-function 1)
 517       (put 'make-environment 'scheme-indent-function 0)
 518       (put 'named-lambda 'scheme-indent-function 1)
 519       (put 'using-syntax 'scheme-indent-function 1)
 520
 521       (put 'with-input-from-string 'scheme-indent-function 1)
 522       (put 'with-output-to-string 'scheme-indent-function 0)
 523       (put 'with-values 'scheme-indent-function 1)
 524
 525       (put 'syntax-table-define 'scheme-indent-function 2)
 526       (put 'list-transform-positive 'scheme-indent-function 1)
 527       (put 'list-transform-negative 'scheme-indent-function 1)
 528       (put 'list-search-positive 'scheme-indent-function 1)
 529       (put 'list-search-negative 'scheme-indent-function 1)
 530
 531       (put 'access-components 'scheme-indent-function 1)
 532       (put 'assignment-components 'scheme-indent-function 1)
 533       (put 'combination-components 'scheme-indent-function 1)
 534       (put 'comment-components 'scheme-indent-function 1)
 535       (put 'conditional-components 'scheme-indent-function 1)
 536       (put 'disjunction-components 'scheme-indent-function 1)
 537       (put 'declaration-components 'scheme-indent-function 1)
 538       (put 'definition-components 'scheme-indent-function 1)
 539       (put 'delay-components 'scheme-indent-function 1)
 540       (put 'in-package-components 'scheme-indent-function 1)
 541       (put 'lambda-components 'scheme-indent-function 1)
 542       (put 'lambda-components* 'scheme-indent-function 1)
 543       (put 'lambda-components** 'scheme-indent-function 1)
 544       (put 'open-block-components 'scheme-indent-function 1)
 545       (put 'pathname-components 'scheme-indent-function 1)
 546       (put 'procedure-components 'scheme-indent-function 1)
 547       (put 'sequence-components 'scheme-indent-function 1)
 548       (put 'unassigned\?-components 'scheme-indent-function 1)
 549       (put 'unbound\?-components 'scheme-indent-function 1)
 550       (put 'variable-components 'scheme-indent-function 1)))
 551
 552 (provide 'scheme)
 553
 554 ;;; scheme.el ends here