code.delx.au - gnu-emacs/blob - lisp/complete.el

   1 ;;; complete.el --- partial completion mechanism plus other goodies
   2
   3 ;; Copyright (C) 1990, 1991, 1992, 1993, 1999, 2000, 2002, 2003, 2004,
   4 ;;   2005 Free Software Foundation, Inc.
   5
   6 ;; Author: Dave Gillespie <daveg@synaptics.com>
   7 ;; Keywords: abbrev convenience
   8 ;; Special thanks to Hallvard Furuseth for his many ideas and contributions.
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  25 ;; Boston, MA 02110-1301, USA.
  26
  27 ;;; Commentary:
  28
  29 ;; Extended completion for the Emacs minibuffer.
  30 ;;
  31 ;; The basic idea is that the command name or other completable text is
  32 ;; divided into words and each word is completed separately, so that
  33 ;; "M-x p-b" expands to "M-x print-buffer".  If the entry is ambiguous
  34 ;; each word is completed as much as possible and then the cursor is
  35 ;; left at the first position where typing another letter will resolve
  36 ;; the ambiguity.
  37 ;;
  38 ;; Word separators for this purpose are hyphen, space, and period.
  39 ;; These would most likely occur in command names, Info menu items,
  40 ;; and file names, respectively.  But all word separators are treated
  41 ;; alike at all times.
  42 ;;
  43 ;; This completion package replaces the old-style completer's key
  44 ;; bindings for TAB, SPC, RET, and `?'.  The old completer is still
  45 ;; available on the Meta versions of those keys.  If you set
  46 ;; PC-meta-flag to nil, the old completion keys will be left alone
  47 ;; and the partial completer will use the Meta versions of the keys.
  48
  49
  50 ;; Usage:  M-x partial-completion-mode.  During completable minibuffer entry,
  51 ;;
  52 ;;     TAB    means to do a partial completion;
  53 ;;     SPC    means to do a partial complete-word;
  54 ;;     RET    means to do a partial complete-and-exit;
  55 ;;     ?      means to do a partial completion-help.
  56 ;;
  57 ;; If you set PC-meta-flag to nil, then TAB, SPC, RET, and ? perform
  58 ;; original Emacs completions, and M-TAB etc. do partial completion.
  59 ;; To do this, put the command,
  60 ;;
  61 ;;       (setq PC-meta-flag nil)
  62 ;;
  63 ;; in your .emacs file.  To load partial completion automatically, put
  64 ;;
  65 ;;       (partial-completion-mode t)
  66 ;;
  67 ;; in your .emacs file, too.  Things will be faster if you byte-compile
  68 ;; this file when you install it.
  69 ;;
  70 ;; As an extra feature, in cases where RET would not normally
  71 ;; complete (such as `C-x b'), the M-RET key will always do a partial
  72 ;; complete-and-exit.  Thus `C-x b f.c RET' will select or create a
  73 ;; buffer called "f.c", but `C-x b f.c M-RET' will select the existing
  74 ;; buffer whose name matches that pattern (perhaps "filing.c").
  75 ;; (PC-meta-flag does not affect this behavior; M-RET used to be
  76 ;; undefined in this situation.)
  77 ;;
  78 ;; The regular M-TAB (lisp-complete-symbol) command also supports
  79 ;; partial completion in this package.
  80
  81 ;; In addition, this package includes a feature for accessing include
  82 ;; files.  For example, `C-x C-f <sys/time.h> RET' reads the file
  83 ;; /usr/include/sys/time.h.  The variable PC-include-file-path is a
  84 ;; list of directories in which to search for include files.  Completion
  85 ;; is supported in include file names.
  86
  87
  88 ;;; Code:
  89
  90 (defgroup partial-completion nil
  91   "Partial Completion of items."
  92   :prefix "pc-"
  93   :group 'minibuffer
  94   :group 'convenience)
  95
  96 (defcustom PC-first-char 'find-file
  97   "*Control how the first character of a string is to be interpreted.
  98 If nil, the first character of a string is not taken literally if it is a word
  99 delimiter, so that \".e\" matches \"*.e*\".
 100 If t, the first character of a string is always taken literally even if it is a
 101 word delimiter, so that \".e\" matches \".e*\".
 102 If non-nil and non-t, the first character is taken literally only for file name
 103 completion."
 104   :type '(choice (const :tag "delimiter" nil)
 105                  (const :tag "literal" t)
 106                  (other :tag "find-file" find-file))
 107   :group 'partial-completion)
 108
 109 (defcustom PC-meta-flag t
 110   "*If non-nil, TAB means PC completion and M-TAB means normal completion.
 111 Otherwise, TAB means normal completion and M-TAB means Partial Completion."
 112   :type 'boolean
 113   :group 'partial-completion)
 114
 115 (defcustom PC-word-delimiters "-_. "
 116   "*A string of characters treated as word delimiters for completion.
 117 Some arcane rules:
 118 If `]' is in this string, it must come first.
 119 If `^' is in this string, it must not come first.
 120 If `-' is in this string, it must come first or right after `]'.
 121 In other words, if S is this string, then `[S]' must be a valid Emacs regular
 122 expression (not containing character ranges like `a-z')."
 123   :type 'string
 124   :group 'partial-completion)
 125
 126 (defcustom PC-include-file-path '("/usr/include" "/usr/local/include")
 127   "*A list of directories in which to look for include files.
 128 If nil, means use the colon-separated path in the variable $INCPATH instead."
 129   :type '(repeat directory)
 130   :group 'partial-completion)
 131
 132 (defcustom PC-disable-includes nil
 133   "*If non-nil, include-file support in \\[find-file] is disabled."
 134   :type 'boolean
 135   :group 'partial-completion)
 136
 137 (defvar PC-default-bindings t
 138   "If non-nil, default partial completion key bindings are suppressed.")
 139
 140 (defvar PC-env-vars-alist nil
 141   "A list of the environment variable names and values.")
 142
 143 \f
 144 (defvar PC-old-read-file-name-internal nil)
 145
 146 (defun PC-bindings (bind)
 147   (let ((completion-map minibuffer-local-completion-map)
 148         (must-match-map minibuffer-local-must-match-map))
 149     (cond ((not bind)
 150            ;; These bindings are the default bindings.  It would be better to
 151            ;; restore the previous bindings.
 152            (define-key completion-map "\t"      'minibuffer-complete)
 153            (define-key completion-map " "       'minibuffer-complete-word)
 154            (define-key completion-map "?"       'minibuffer-completion-help)
 155
 156            (define-key must-match-map "\t"      'minibuffer-complete)
 157            (define-key must-match-map " "       'minibuffer-complete-word)
 158            (define-key must-match-map "\r"      'minibuffer-complete-and-exit)
 159            (define-key must-match-map "\n"      'minibuffer-complete-and-exit)
 160            (define-key must-match-map "?"       'minibuffer-completion-help)
 161
 162            (define-key global-map "\e\t"        'complete-symbol))
 163           (PC-default-bindings
 164            (define-key completion-map "\t"      'PC-complete)
 165            (define-key completion-map " "       'PC-complete-word)
 166            (define-key completion-map "?"       'PC-completion-help)
 167
 168            (define-key completion-map "\e\t"    'PC-complete)
 169            (define-key completion-map "\e "     'PC-complete-word)
 170            (define-key completion-map "\e\r"    'PC-force-complete-and-exit)
 171            (define-key completion-map "\e\n"    'PC-force-complete-and-exit)
 172            (define-key completion-map "\e?"     'PC-completion-help)
 173
 174            (define-key must-match-map "\t"      'PC-complete)
 175            (define-key must-match-map " "       'PC-complete-word)
 176            (define-key must-match-map "\r"      'PC-complete-and-exit)
 177            (define-key must-match-map "\n"      'PC-complete-and-exit)
 178            (define-key must-match-map "?"       'PC-completion-help)
 179
 180            (define-key must-match-map "\e\t"    'PC-complete)
 181            (define-key must-match-map "\e "     'PC-complete-word)
 182            (define-key must-match-map "\e\r"    'PC-complete-and-exit)
 183            (define-key must-match-map "\e\n"    'PC-complete-and-exit)
 184            (define-key must-match-map "\e?"     'PC-completion-help)
 185
 186            (define-key global-map "\e\t"        'PC-lisp-complete-symbol)))))
 187
 188 ;;;###autoload
 189 (define-minor-mode partial-completion-mode
 190   "Toggle Partial Completion mode.
 191 With prefix ARG, turn Partial Completion mode on if ARG is positive.
 192
 193 When Partial Completion mode is enabled, TAB (or M-TAB if `PC-meta-flag' is
 194 nil) is enhanced so that if some string is divided into words and each word is
 195 delimited by a character in `PC-word-delimiters', partial words are completed
 196 as much as possible and `*' characters are treated likewise in file names.
 197
 198 For example, M-x p-c-m expands to M-x partial-completion-mode since no other
 199 command begins with that sequence of characters, and
 200 \\[find-file] f_b.c TAB might complete to foo_bar.c if that file existed and no
 201 other file in that directory begin with that sequence of characters.
 202
 203 Unless `PC-disable-includes' is non-nil, the `<...>' sequence is interpreted
 204 specially in \\[find-file].  For example,
 205 \\[find-file] <sys/time.h> RET finds the file `/usr/include/sys/time.h'.
 206 See also the variable `PC-include-file-path'.
 207
 208 Partial Completion mode extends the meaning of `completion-auto-help' (which
 209 see) so that if it is neither nil nor t, Emacs will show the  *Completions*
 210 buffer only on the second attempt to complete.  I.e. if TAB finds nothing
 211 to complete, the first TAB will just say \"Next char not unique\" without
 212 bringing up the *Completions* buffer, and the second TAB will then bring up
 213 the *Completions* buffer."
 214   :global t :group 'partial-completion
 215   ;; Deal with key bindings...
 216   (PC-bindings partial-completion-mode)
 217   ;; Deal with include file feature...
 218   (cond ((not partial-completion-mode)
 219          (remove-hook 'find-file-not-found-functions 'PC-look-for-include-file))
 220         ((not PC-disable-includes)
 221          (add-hook 'find-file-not-found-functions 'PC-look-for-include-file)))
 222   ;; ... with some underhand redefining.
 223   (cond ((and (not partial-completion-mode)
 224               (functionp PC-old-read-file-name-internal))
 225          (fset 'read-file-name-internal PC-old-read-file-name-internal))
 226         ((and (not PC-disable-includes) (not PC-old-read-file-name-internal))
 227          (setq PC-old-read-file-name-internal
 228                (symbol-function 'read-file-name-internal))
 229          (fset 'read-file-name-internal
 230                'PC-read-include-file-name-internal)))
 231     (when (and partial-completion-mode (null PC-env-vars-alist))
 232       (setq PC-env-vars-alist
 233             (mapcar (lambda (string)
 234                       (let ((d (string-match "=" string)))
 235                         (cons (concat "$" (substring string 0 d))
 236                               (and d (substring string (1+ d))))))
 237                     process-environment))))
 238
 239 \f
 240 (defun PC-complete ()
 241   "Like minibuffer-complete, but allows \"b--di\"-style abbreviations.
 242 For example, \"M-x b--di\" would match `byte-recompile-directory', or any
 243 name which consists of three or more words, the first beginning with \"b\"
 244 and the third beginning with \"di\".
 245
 246 The pattern \"b--d\" is ambiguous for `byte-recompile-directory' and
 247 `beginning-of-defun', so this would produce a list of completions
 248 just like when normal Emacs completions are ambiguous.
 249
 250 Word-delimiters for the purposes of Partial Completion are \"-\", \"_\",
 251 \".\", and SPC."
 252   (interactive)
 253   (if (PC-was-meta-key)
 254       (minibuffer-complete)
 255     ;; If the previous command was not this one,
 256     ;; never scroll, always retry completion.
 257     (or (eq last-command this-command)
 258         (setq minibuffer-scroll-window nil))
 259     (let ((window minibuffer-scroll-window))
 260       ;; If there's a fresh completion window with a live buffer,
 261       ;; and this command is repeated, scroll that window.
 262       (if (and window (window-buffer window)
 263                (buffer-name (window-buffer window)))
 264           (with-current-buffer (window-buffer window)
 265             (if (pos-visible-in-window-p (point-max) window)
 266                 (set-window-start window (point-min) nil)
 267               (scroll-other-window)))
 268         (PC-do-completion nil)))))
 269
 270
 271 (defun PC-complete-word ()
 272   "Like `minibuffer-complete-word', but allows \"b--di\"-style abbreviations.
 273 See `PC-complete' for details.
 274 This can be bound to other keys, like `-' and `.', if you wish."
 275   (interactive)
 276   (if (eq (PC-was-meta-key) PC-meta-flag)
 277       (if (eq last-command-char ? )
 278           (minibuffer-complete-word)
 279         (self-insert-command 1))
 280     (self-insert-command 1)
 281     (if (eobp)
 282         (PC-do-completion 'word))))
 283
 284
 285 (defun PC-complete-space ()
 286   "Like `minibuffer-complete-word', but allows \"b--di\"-style abbreviations.
 287 See `PC-complete' for details.
 288 This is suitable for binding to other keys which should act just like SPC."
 289   (interactive)
 290   (if (eq (PC-was-meta-key) PC-meta-flag)
 291       (minibuffer-complete-word)
 292     (insert " ")
 293     (if (eobp)
 294         (PC-do-completion 'word))))
 295
 296
 297 (defun PC-complete-and-exit ()
 298   "Like `minibuffer-complete-and-exit', but allows \"b--di\"-style abbreviations.
 299 See `PC-complete' for details."
 300   (interactive)
 301   (if (eq (PC-was-meta-key) PC-meta-flag)
 302       (minibuffer-complete-and-exit)
 303     (PC-do-complete-and-exit)))
 304
 305 (defun PC-force-complete-and-exit ()
 306   "Like `minibuffer-complete-and-exit', but allows \"b--di\"-style abbreviations.
 307 See `PC-complete' for details."
 308   (interactive)
 309   (let ((minibuffer-completion-confirm nil))
 310     (PC-do-complete-and-exit)))
 311
 312 (defun PC-do-complete-and-exit ()
 313   (if (= (point-max) (minibuffer-prompt-end))  ; Duplicate the "bug" that Info-menu relies on...
 314       (exit-minibuffer)
 315     (let ((flag (PC-do-completion 'exit)))
 316       (and flag
 317            (if (or (eq flag 'complete)
 318                    (not minibuffer-completion-confirm))
 319                (exit-minibuffer)
 320              (PC-temp-minibuffer-message " [Confirm]"))))))
 321
 322
 323 (defun PC-completion-help ()
 324   "Like `minibuffer-completion-help', but allows \"b--di\"-style abbreviations.
 325 See `PC-complete' for details."
 326   (interactive)
 327   (if (eq (PC-was-meta-key) PC-meta-flag)
 328       (minibuffer-completion-help)
 329     (PC-do-completion 'help)))
 330
 331 (defun PC-was-meta-key ()
 332   (or (/= (length (this-command-keys)) 1)
 333       (let ((key (aref (this-command-keys) 0)))
 334         (if (integerp key)
 335             (>= key 128)
 336           (not (null (memq 'meta (event-modifiers key))))))))
 337
 338
 339 (defvar PC-ignored-extensions 'empty-cache)
 340 (defvar PC-delims 'empty-cache)
 341 (defvar PC-ignored-regexp nil)
 342 (defvar PC-word-failed-flag nil)
 343 (defvar PC-delim-regex nil)
 344 (defvar PC-ndelims-regex nil)
 345 (defvar PC-delims-list nil)
 346
 347 (defvar PC-completion-as-file-name-predicate
 348   (lambda () minibuffer-completing-file-name)
 349   "A function testing whether a minibuffer completion now will work filename-style.
 350 The function takes no arguments, and typically looks at the value
 351 of `minibuffer-completion-table' and the minibuffer contents.")
 352
 353 (defun PC-do-completion (&optional mode beg end)
 354   (or beg (setq beg (minibuffer-prompt-end)))
 355   (or end (setq end (point-max)))
 356   (let* ((table minibuffer-completion-table)
 357          (pred minibuffer-completion-predicate)
 358          (filename (funcall PC-completion-as-file-name-predicate))
 359          (dirname nil)
 360          (dirlength 0)
 361          (str (buffer-substring beg end))
 362          (incname (and filename (string-match "<\\([^\"<>]*\\)>?$" str)))
 363          (ambig nil)
 364          basestr
 365          env-on
 366          regex
 367          p offset
 368          (poss nil)
 369          helpposs
 370          (case-fold-search completion-ignore-case))
 371
 372     ;; Check if buffer contents can already be considered complete
 373     (if (and (eq mode 'exit)
 374              (test-completion str table pred))
 375         'complete
 376
 377       ;; Do substitutions in directory names
 378       (and filename
 379            (setq basestr (or (file-name-directory str) ""))
 380            (setq dirlength (length basestr))
 381            ;; Do substitutions in directory names
 382            (setq p (substitute-in-file-name basestr))
 383            (not (string-equal basestr p))
 384            (setq str (concat p (file-name-nondirectory str)))
 385            (progn
 386              (delete-region beg end)
 387              (insert str)
 388              (setq end (+ beg (length str)))))
 389
 390       ;; Prepare various delimiter strings
 391       (or (equal PC-word-delimiters PC-delims)
 392           (setq PC-delims PC-word-delimiters
 393                 PC-delim-regex (concat "[" PC-delims "]")
 394                 PC-ndelims-regex (concat "[^" PC-delims "]*")
 395                 PC-delims-list (append PC-delims nil)))
 396
 397       ;; Add wildcards if necessary
 398       (and filename
 399            (let ((dir (file-name-directory str))
 400                  (file (file-name-nondirectory str))
 401                  ;; The base dir for file-completion is passed in `predicate'.
 402                  (default-directory (expand-file-name pred)))
 403              (while (and (stringp dir) (not (file-directory-p dir)))
 404                (setq dir (directory-file-name dir))
 405                (setq file (concat (replace-regexp-in-string
 406                                    PC-delim-regex "*\\&"
 407                                    (file-name-nondirectory dir))
 408                                   "*/" file))
 409                (setq dir (file-name-directory dir)))
 410              (setq str (concat dir file))))
 411
 412       ;; Look for wildcard expansions in directory name
 413       (and filename
 414            (string-match "\\*.*/" str)
 415            (let ((pat str)
 416                  ;; The base dir for file-completion is passed in `predicate'.
 417                  (default-directory (expand-file-name pred))
 418                  files)
 419              (setq p (1+ (string-match "/[^/]*\\'" pat)))
 420              (while (setq p (string-match PC-delim-regex pat p))
 421                (setq pat (concat (substring pat 0 p)
 422                                  "*"
 423                                  (substring pat p))
 424                      p (+ p 2)))
 425              (setq files (PC-expand-many-files (concat pat "*")))
 426              (if files
 427                  (let ((dir (file-name-directory (car files)))
 428                        (p files))
 429                    (while (and (setq p (cdr p))
 430                                (equal dir (file-name-directory (car p)))))
 431                    (if p
 432                        (setq filename nil table nil pred nil
 433                              ambig t)
 434                      (delete-region beg end)
 435                      (setq str (concat dir (file-name-nondirectory str)))
 436                      (insert str)
 437                      (setq end (+ beg (length str)))))
 438                (setq filename nil table nil pred nil))))
 439
 440       ;; Strip directory name if appropriate
 441       (if filename
 442           (if incname
 443               (setq basestr (substring str incname)
 444                     dirname (substring str 0 incname))
 445             (setq basestr (file-name-nondirectory str)
 446                   dirname (file-name-directory str))
 447             ;; Make sure str is consistent with its directory and basename
 448             ;; parts.  This is important on DOZe'NT systems when str only
 449             ;; includes a drive letter, like in "d:".
 450             (setq str (concat dirname basestr)))
 451         (setq basestr str))
 452
 453       ;; Convert search pattern to a standard regular expression
 454       (setq regex (regexp-quote basestr)
 455             offset (if (and (> (length regex) 0)
 456                             (not (eq (aref basestr 0) ?\*))
 457                             (or (eq PC-first-char t)
 458                                 (and PC-first-char filename))) 1 0)
 459             p offset)
 460       (while (setq p (string-match PC-delim-regex regex p))
 461         (if (eq (aref regex p) ? )
 462             (setq regex (concat (substring regex 0 p)
 463                                 PC-ndelims-regex
 464                                 PC-delim-regex
 465                                 (substring regex (1+ p)))
 466                   p (+ p (length PC-ndelims-regex) (length PC-delim-regex)))
 467           (let ((bump (if (memq (aref regex p)
 468                                 '(?$ ?^ ?\. ?* ?+ ?? ?[ ?] ?\\))
 469                           -1 0)))
 470             (setq regex (concat (substring regex 0 (+ p bump))
 471                                 PC-ndelims-regex
 472                                 (substring regex (+ p bump)))
 473                   p (+ p (length PC-ndelims-regex) 1)))))
 474       (setq p 0)
 475       (if filename
 476           (while (setq p (string-match "\\\\\\*" regex p))
 477             (setq regex (concat (substring regex 0 p)
 478                                 "[^/]*"
 479                                 (substring regex (+ p 2))))))
 480       ;;(setq the-regex regex)
 481       (setq regex (concat "\\`" regex))
 482
 483       (and (> (length basestr) 0)
 484            (= (aref basestr 0) ?$)
 485            (setq env-on t
 486                  table PC-env-vars-alist
 487                  pred nil))
 488
 489       ;; Find an initial list of possible completions
 490       (if (not (setq p (string-match (concat PC-delim-regex
 491                                              (if filename "\\|\\*" ""))
 492                                      str
 493                                      (+ (length dirname) offset))))
 494
 495           ;; Minibuffer contains no hyphens -- simple case!
 496           (setq poss (all-completions (if env-on
 497                                           basestr str)
 498                                       table
 499                                       pred))
 500
 501         ;; Use all-completions to do an initial cull.  This is a big win,
 502         ;; since all-completions is written in C!
 503         (let ((compl (all-completions (if env-on
 504                                           (file-name-nondirectory (substring str 0 p))
 505                                         (substring str 0 p))
 506                                         table
 507                                         pred)))
 508           (setq p compl)
 509           (while p
 510             (and (string-match regex (car p))
 511                  (progn
 512                    (set-text-properties 0 (length (car p)) '() (car p))
 513                    (setq poss (cons (car p) poss))))
 514             (setq p (cdr p)))))
 515
 516       ;; Now we have a list of possible completions
 517       (cond
 518
 519        ;; No valid completions found
 520        ((null poss)
 521         (if (and (eq mode 'word)
 522                  (not PC-word-failed-flag))
 523             (let ((PC-word-failed-flag t))
 524               (delete-backward-char 1)
 525               (PC-do-completion 'word))
 526           (beep)
 527           (PC-temp-minibuffer-message (if ambig
 528                                           " [Ambiguous dir name]"
 529                                         (if (eq mode 'help)
 530                                             " [No completions]"
 531                                           " [No match]")))
 532           nil))
 533
 534        ;; More than one valid completion found
 535        ((or (cdr (setq helpposs poss))
 536             (memq mode '(help word)))
 537
 538         ;; Handle completion-ignored-extensions
 539         (and filename
 540              (not (eq mode 'help))
 541              (let ((p2 poss))
 542
 543                ;; Build a regular expression representing the extensions list
 544                (or (equal completion-ignored-extensions PC-ignored-extensions)
 545                    (setq PC-ignored-regexp
 546                          (concat "\\("
 547                                  (mapconcat
 548                                   'regexp-quote
 549                                   (setq PC-ignored-extensions
 550                                         completion-ignored-extensions)
 551                                   "\\|")
 552                                  "\\)\\'")))
 553
 554                ;; Check if there are any without an ignored extension.
 555                ;; Also ignore `.' and `..'.
 556                (setq p nil)
 557                (while p2
 558                  (or (string-match PC-ignored-regexp (car p2))
 559                      (string-match "\\(\\`\\|/\\)[.][.]?/?\\'" (car p2))
 560                      (setq p (cons (car p2) p)))
 561                  (setq p2 (cdr p2)))
 562
 563                ;; If there are "good" names, use them
 564                (and p (setq poss p))))
 565
 566         ;; Is the actual string one of the possible completions?
 567         (setq p (and (not (eq mode 'help)) poss))
 568         (while (and p
 569                     (not (string-equal (car p) basestr)))
 570           (setq p (cdr p)))
 571         (and p (null mode)
 572              (PC-temp-minibuffer-message " [Complete, but not unique]"))
 573         (if (and p
 574                  (not (and (null mode)
 575                            (eq this-command last-command))))
 576             t
 577
 578           ;; If ambiguous, try for a partial completion
 579           (let ((improved nil)
 580                 prefix
 581                 (pt nil)
 582                 (skip "\\`"))
 583
 584             ;; Check if next few letters are the same in all cases
 585             (if (and (not (eq mode 'help))
 586                      (setq prefix (try-completion "" (mapcar 'list poss))))
 587                 (let ((first t) i)
 588                   (if (eq mode 'word)
 589                       (setq prefix (PC-chop-word prefix basestr)))
 590                   (goto-char (+ beg (length dirname)))
 591                   (while (and (progn
 592                                 (setq i 0)
 593                                 (while (< i (length prefix))
 594                                   (if (and (< (point) end)
 595                                            (eq (aref prefix i)
 596                                                (following-char)))
 597                                       (forward-char 1)
 598                                     (if (and (< (point) end)
 599                                              (or (and (looking-at " ")
 600                                                       (memq (aref prefix i)
 601                                                             PC-delims-list))
 602                                                  (eq (downcase (aref prefix i))
 603                                                      (downcase
 604                                                       (following-char)))))
 605                                         (progn
 606                                           (delete-char 1)
 607                                           (setq end (1- end)))
 608                                       (and filename (looking-at "\\*")
 609                                            (progn
 610                                              (delete-char 1)
 611                                              (setq end (1- end))))
 612                                       (setq improved t))
 613                                     (insert (substring prefix i (1+ i)))
 614                                     (setq end (1+ end)))
 615                                   (setq i (1+ i)))
 616                                 (or pt (equal (point) beg)
 617                                     (setq pt (point)))
 618                                 (looking-at PC-delim-regex))
 619                               (setq skip (concat skip
 620                                                  (regexp-quote prefix)
 621                                                  PC-ndelims-regex)
 622                                     prefix (try-completion
 623                                             ""
 624                                             (mapcar
 625                                              (function
 626                                               (lambda (x)
 627                                                 (list
 628                                                  (and (string-match skip x)
 629                                                       (substring
 630                                                        x
 631                                                        (match-end 0))))))
 632                                              poss)))
 633                               (or (> i 0) (> (length prefix) 0))
 634                               (or (not (eq mode 'word))
 635                                   (and first (> (length prefix) 0)
 636                                        (setq first nil
 637                                              prefix (substring prefix 0 1))))))
 638                   (goto-char (if (eq mode 'word) end
 639                                (or pt beg)))))
 640
 641             (if (and (eq mode 'word)
 642                      (not PC-word-failed-flag))
 643
 644                 (if improved
 645
 646                     ;; We changed it... would it be complete without the space?
 647                     (if (test-completion (buffer-substring 1 (1- end))
 648                                           table pred)
 649                         (delete-region (1- end) end)))
 650
 651               (if improved
 652
 653                   ;; We changed it... enough to be complete?
 654                   (and (eq mode 'exit)
 655                        (test-completion (field-string) table pred))
 656
 657                 ;; If totally ambiguous, display a list of completions
 658                 (if (or (eq completion-auto-help t)
 659                         (and completion-auto-help
 660                              (eq last-command this-command))
 661                         (eq mode 'help))
 662                     (with-output-to-temp-buffer "*Completions*"
 663                       (display-completion-list (sort helpposs 'string-lessp))
 664                       (with-current-buffer standard-output
 665                         ;; Record which part of the buffer we are completing
 666                         ;; so that choosing a completion from the list
 667                         ;; knows how much old text to replace.
 668                         (setq completion-base-size dirlength)))
 669                   (PC-temp-minibuffer-message " [Next char not unique]"))
 670                 nil)))))
 671
 672        ;; Only one possible completion
 673        (t
 674         (if (and (equal basestr (car poss))
 675                  (not (and env-on filename)))
 676             (if (null mode)
 677                 (PC-temp-minibuffer-message " [Sole completion]"))
 678           (delete-region beg end)
 679           (insert (format "%s"
 680                           (if filename
 681                               (substitute-in-file-name (concat dirname (car poss)))
 682                             (car poss)))))
 683         t)))))
 684
 685 (defun PC-chop-word (new old)
 686   (let ((i -1)
 687         (j -1))
 688     (while (and (setq i (string-match PC-delim-regex old (1+ i)))
 689                 (setq j (string-match PC-delim-regex new (1+ j)))))
 690     (if (and j
 691              (or (not PC-word-failed-flag)
 692                  (setq j (string-match PC-delim-regex new (1+ j)))))
 693         (substring new 0 (1+ j))
 694       new)))
 695
 696 (defvar PC-not-minibuffer nil)
 697
 698 (defun PC-temp-minibuffer-message (message)
 699   "A Lisp version of `temp_minibuffer_message' from minibuf.c."
 700   (cond (PC-not-minibuffer
 701          (message message)
 702          (sit-for 2)
 703          (message ""))
 704         ((fboundp 'temp-minibuffer-message)
 705          (temp-minibuffer-message message))
 706         (t
 707          (let ((point-max (point-max)))
 708            (save-excursion
 709              (goto-char point-max)
 710              (insert message))
 711            (let ((inhibit-quit t))
 712              (sit-for 2)
 713              (delete-region point-max (point-max))
 714              (when quit-flag
 715                (setq quit-flag nil
 716                      unread-command-events '(7))))))))
 717
 718
 719 (defun PC-lisp-complete-symbol ()
 720   "Perform completion on Lisp symbol preceding point.
 721 That symbol is compared against the symbols that exist
 722 and any additional characters determined by what is there
 723 are inserted.
 724 If the symbol starts just after an open-parenthesis,
 725 only symbols with function definitions are considered.
 726 Otherwise, all symbols with function definitions, values
 727 or properties are considered."
 728   (interactive)
 729   (let* ((end (point))
 730          (beg (save-excursion
 731                 (with-syntax-table lisp-mode-syntax-table
 732                   (backward-sexp 1)
 733                   (while (= (char-syntax (following-char)) ?\')
 734                     (forward-char 1))
 735                   (point))))
 736          (minibuffer-completion-table obarray)
 737          (minibuffer-completion-predicate
 738           (if (eq (char-after (1- beg)) ?\()
 739               'fboundp
 740             (function (lambda (sym)
 741                         (or (boundp sym) (fboundp sym)
 742                             (symbol-plist sym))))))
 743          (PC-not-minibuffer t))
 744     (PC-do-completion nil beg end)))
 745
 746 (defun PC-complete-as-file-name ()
 747    "Perform completion on file names preceding point.
 748  Environment vars are converted to their values."
 749    (interactive)
 750    (let* ((end (point))
 751           (beg (if (re-search-backward "[^\\][ \t\n\"\`\'][^ \t\n\"\`\']"
 752                                        (point-min) t)
 753                    (+ (point) 2)
 754                    (point-min)))
 755           (minibuffer-completion-table 'read-file-name-internal)
 756           (minibuffer-completion-predicate "")
 757           (PC-not-minibuffer t))
 758      (goto-char end)
 759      (PC-do-completion nil beg end)))
 760
 761 ;; Use the shell to do globbing.
 762 ;; This could now use file-expand-wildcards instead.
 763
 764 (defun PC-expand-many-files (name)
 765   (with-current-buffer (generate-new-buffer " *Glob Output*")
 766     (erase-buffer)
 767     (shell-command (concat "echo " name) t)
 768     (goto-char (point-min))
 769     (if (looking-at ".*No match")
 770         nil
 771       (insert "(\"")
 772       (while (search-forward " " nil t)
 773         (delete-backward-char 1)
 774         (insert "\" \""))
 775       (goto-char (point-max))
 776       (delete-backward-char 1)
 777       (insert "\")")
 778       (goto-char (point-min))
 779       (let ((files (read (current-buffer))) (p nil))
 780         (kill-buffer (current-buffer))
 781         (or (equal completion-ignored-extensions PC-ignored-extensions)
 782             (setq PC-ignored-regexp
 783                   (concat "\\("
 784                           (mapconcat
 785                            'regexp-quote
 786                            (setq PC-ignored-extensions
 787                                  completion-ignored-extensions)
 788                            "\\|")
 789                           "\\)\\'")))
 790         (setq p nil)
 791         (while files
 792           (or (string-match PC-ignored-regexp (car files))
 793               (setq p (cons (car files) p)))
 794           (setq files (cdr files)))
 795         p))))
 796
 797 ;; Facilities for loading C header files.  This is independent from the
 798 ;; main completion code.  See also the variable `PC-include-file-path'
 799 ;; at top of this file.
 800
 801 (defun PC-look-for-include-file ()
 802   (if (string-match "[\"<]\\([^\"<>]*\\)[\">]?$" (buffer-file-name))
 803       (let ((name (substring (buffer-file-name)
 804                              (match-beginning 1) (match-end 1)))
 805             (punc (aref (buffer-file-name) (match-beginning 0)))
 806             (path nil)
 807             new-buf)
 808         (kill-buffer (current-buffer))
 809         (if (equal name "")
 810             (with-current-buffer (car (buffer-list))
 811               (save-excursion
 812                 (beginning-of-line)
 813                 (if (looking-at
 814                      "[ \t]*#[ \t]*include[ \t]+[<\"]\\(.+\\)[>\"][ \t]*[\n/]")
 815                     (setq name (buffer-substring (match-beginning 1)
 816                                                  (match-end 1))
 817                           punc (char-after (1- (match-beginning 1))))
 818                   ;; Suggested by Frank Siebenlist:
 819                   (if (or (looking-at
 820                            "[ \t]*([ \t]*load[ \t]+\"\\([^\"]+\\)\"")
 821                           (looking-at
 822                            "[ \t]*([ \t]*load-library[ \t]+\"\\([^\"]+\\)\"")
 823                           (looking-at
 824                            "[ \t]*([ \t]*require[ \t]+'\\([^\t )]+\\)[\t )]"))
 825                       (progn
 826                         (setq name (buffer-substring (match-beginning 1)
 827                                                      (match-end 1))
 828                               punc ?\<
 829                               path load-path)
 830                         (if (string-match "\\.elc$" name)
 831                             (setq name (substring name 0 -1))
 832                           (or (string-match "\\.el$" name)
 833                               (setq name (concat name ".el")))))
 834                     (error "Not on an #include line"))))))
 835         (or (string-match "\\.[[:alnum:]]+$" name)
 836             (setq name (concat name ".h")))
 837         (if (eq punc ?\<)
 838             (let ((path (or path (PC-include-file-path))))
 839               (while (and path
 840                           (not (file-exists-p
 841                                 (concat (file-name-as-directory (car path))
 842                                         name))))
 843                 (setq path (cdr path)))
 844               (if path
 845                   (setq name (concat (file-name-as-directory (car path)) name))
 846                 (error "No such include file: <%s>" name)))
 847           (let ((dir (with-current-buffer (car (buffer-list))
 848                        default-directory)))
 849             (if (file-exists-p (concat dir name))
 850                 (setq name (concat dir name))
 851               (error "No such include file: `%s'" name))))
 852         (setq new-buf (get-file-buffer name))
 853         (if new-buf
 854             ;; no need to verify last-modified time for this!
 855             (set-buffer new-buf)
 856           (set-buffer (create-file-buffer name))
 857           (erase-buffer)
 858           (insert-file-contents name t))
 859         ;; Returning non-nil with the new buffer current
 860         ;; is sufficient to tell find-file to use it.
 861         t)
 862     nil))
 863
 864 (defun PC-include-file-path ()
 865   (or PC-include-file-path
 866       (let ((env (getenv "INCPATH"))
 867             (path nil)
 868             pos)
 869         (or env (error "No include file path specified"))
 870         (while (setq pos (string-match ":[^:]+$" env))
 871           (setq path (cons (substring env (1+ pos)) path)
 872                 env (substring env 0 pos)))
 873         path)))
 874
 875 ;; This is adapted from lib-complete.el, by Mike Williams.
 876 (defun PC-include-file-all-completions (file search-path &optional full)
 877   "Return all completions for FILE in any directory on SEARCH-PATH.
 878 If optional third argument FULL is non-nil, returned pathnames should be
 879 absolute rather than relative to some directory on the SEARCH-PATH."
 880   (setq search-path
 881         (mapcar (lambda (dir)
 882                   (if dir (file-name-as-directory dir) default-directory))
 883                 search-path))
 884   (if (file-name-absolute-p file)
 885       ;; It's an absolute file name, so don't need search-path
 886       (progn
 887         (setq file (expand-file-name file))
 888         (file-name-all-completions
 889          (file-name-nondirectory file) (file-name-directory file)))
 890     (let ((subdir (file-name-directory file))
 891           (ndfile (file-name-nondirectory file))
 892           file-lists)
 893       ;; Append subdirectory part to each element of search-path
 894       (if subdir
 895           (setq search-path
 896                 (mapcar (lambda (dir) (concat dir subdir))
 897                         search-path)
 898                 file ))
 899       ;; Make list of completions in each directory on search-path
 900       (while search-path
 901         (let* ((dir (car search-path))
 902                (subdir (if full dir subdir)))
 903           (if (file-directory-p dir)
 904               (progn
 905                 (setq file-lists
 906                       (cons
 907                        (mapcar (lambda (file) (concat subdir file))
 908                                (file-name-all-completions ndfile
 909                                                           (car search-path)))
 910                        file-lists))))
 911           (setq search-path (cdr search-path))))
 912       ;; Compress out duplicates while building complete list (slloooow!)
 913       (let ((sorted (sort (apply 'nconc file-lists)
 914                           (lambda (x y) (not (string-lessp x y)))))
 915             compressed)
 916         (while sorted
 917           (if (equal (car sorted) (car compressed)) nil
 918             (setq compressed (cons (car sorted) compressed)))
 919           (setq sorted (cdr sorted)))
 920         compressed))))
 921
 922 (defun PC-read-include-file-name-internal (string dir action)
 923   (if (string-match "<\\([^\"<>]*\\)>?$" string)
 924       (let* ((name (substring string (match-beginning 1) (match-end 1)))
 925              (str2 (substring string (match-beginning 0)))
 926              (completion-table
 927               (mapcar (function (lambda (x) (list (format "<%s>" x))))
 928                       (PC-include-file-all-completions
 929                        name (PC-include-file-path)))))
 930         (cond
 931          ((not completion-table) nil)
 932          ((eq action nil) (try-completion str2 completion-table nil))
 933          ((eq action t) (all-completions str2 completion-table nil))
 934          ((eq action 'lambda) (test-completion str2 completion-table nil))))
 935     (funcall PC-old-read-file-name-internal string dir action)))
 936 \f
 937
 938 (provide 'complete)
 939
 940 ;; arch-tag: fc7e2768-ff44-4e22-b579-4d825b968458
 941 ;;; complete.el ends here