code.delx.au - gnu-emacs/blob - lisp/gnus/mm-bodies.el

   1 ;;; mm-bodies.el --- Functions for decoding MIME things
   2
   3 ;; Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2004,
   4 ;;   2005, 2006, 2007 Free Software Foundation, Inc.
   5
   6 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   7 ;;      MORIOKA Tomohiko <morioka@jaist.ac.jp>
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 3, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  23 ;; Boston, MA 02110-1301, USA.
  24
  25 ;;; Commentary:
  26
  27 ;;; Code:
  28
  29 (require 'mm-util)
  30 (require 'rfc2047)
  31 (require 'mm-encode)
  32
  33 (defvar mm-uu-yenc-decode-function)
  34 (defvar mm-uu-decode-function)
  35 (defvar mm-uu-binhex-decode-function)
  36
  37 ;; 8bit treatment gets any char except: 0x32 - 0x7f, LF, TAB, BEL,
  38 ;; BS, vertical TAB, form feed, and ^_
  39 ;;
  40 ;; Note that CR is *not* included, as that would allow a non-paired CR
  41 ;; in the body contrary to RFC 2822:
  42 ;;
  43 ;;   - CR and LF MUST only occur together as CRLF; they MUST NOT
  44 ;;     appear independently in the body.
  45
  46 (defvar mm-7bit-chars "\x20-\x7f\n\t\x7\x8\xb\xc\x1f")
  47
  48 (defcustom mm-body-charset-encoding-alist
  49   '((iso-2022-jp . 7bit)
  50     (iso-2022-jp-2 . 7bit)
  51     ;; We MUST encode UTF-16 because it can contain \0's which is
  52     ;; known to break servers.
  53     ;; Note: UTF-16 variants are invalid for text parts [RFC 2781],
  54     ;; so this can't happen :-/.
  55     ;; PPS: Yes, it can happen if the user specifies UTF-16 in the MML
  56     ;; markup. - jh.
  57     (utf-16 . base64)
  58     (utf-16be . base64)
  59     (utf-16le . base64))
  60   "Alist of MIME charsets to encodings.
  61 Valid encodings are `7bit', `8bit', `quoted-printable' and `base64'."
  62   :type '(repeat (cons (symbol :tag "charset")
  63                        (choice :tag "encoding"
  64                                (const 7bit)
  65                                (const 8bit)
  66                                (const quoted-printable)
  67                                (const base64))))
  68   :group 'mime)
  69
  70 (defun mm-encode-body (&optional charset)
  71   "Encode a body.
  72 Should be called narrowed to the body that is to be encoded.
  73 If there is more than one non-ASCII MULE charset in the body, then the
  74 list of MULE charsets found is returned.
  75 If CHARSET is non-nil, it is used as the MIME charset to encode the body.
  76 If successful, the MIME charset is returned.
  77 If no encoding was done, nil is returned."
  78   (if (not (mm-multibyte-p))
  79       ;; In the non-Mule case, we search for non-ASCII chars and
  80       ;; return the value of `mail-parse-charset' if any are found.
  81       (or charset
  82           (save-excursion
  83             (goto-char (point-min))
  84             (if (re-search-forward "[^\x0-\x7f]" nil t)
  85                 (or mail-parse-charset
  86                     (message-options-get 'mm-encody-body-charset)
  87                     (message-options-set
  88                      'mm-encody-body-charset
  89                      (mm-read-coding-system "Charset used in the article: ")))
  90               ;; The logic in `mml-generate-mime-1' confirms that it's OK
  91               ;; to return nil here.
  92               nil)))
  93     (save-excursion
  94       (if charset
  95           (progn
  96             (mm-encode-coding-region (point-min) (point-max)
  97                                      (mm-charset-to-coding-system charset))
  98             charset)
  99         (goto-char (point-min))
 100         (let ((charsets (mm-find-mime-charset-region (point-min) (point-max)
 101                                                      mm-hack-charsets)))
 102           (cond
 103            ;; No encoding.
 104            ((null charsets)
 105             nil)
 106            ;; Too many charsets.
 107            ((> (length charsets) 1)
 108             charsets)
 109            ;; We encode.
 110            (t
 111             (prog1
 112                 (setq charset (car charsets))
 113               (mm-encode-coding-region (point-min) (point-max)
 114                                        (mm-charset-to-coding-system charset))))
 115            ))))))
 116
 117 (defun mm-long-lines-p (length)
 118   "Say whether any of the lines in the buffer is longer than LENGTH."
 119   (save-excursion
 120     (goto-char (point-min))
 121     (end-of-line)
 122     (while (and (not (eobp))
 123                 (not (> (current-column) length)))
 124       (forward-line 1)
 125       (end-of-line))
 126     (and (> (current-column) length)
 127          (current-column))))
 128
 129 (defvar message-posting-charset)
 130
 131 (defun mm-body-encoding (charset &optional encoding)
 132   "Do Content-Transfer-Encoding and return the encoding of the current buffer."
 133   (when (stringp encoding)
 134     (setq encoding (intern (downcase encoding))))
 135   (let ((bits (mm-body-7-or-8))
 136         (longp (mm-long-lines-p 1000)))
 137     (require 'message)
 138     (cond
 139      ((and (not longp)
 140            (not (and mm-use-ultra-safe-encoding
 141                      (or (save-excursion (re-search-forward " $" nil t))
 142                          (save-excursion (re-search-forward "^From " nil t)))))
 143            (eq bits '7bit))
 144       bits)
 145      ((and (not mm-use-ultra-safe-encoding)
 146            (not longp)
 147            (not (cdr (assq charset mm-body-charset-encoding-alist)))
 148            (or (eq t (cdr message-posting-charset))
 149                (memq charset (cdr message-posting-charset))
 150                (eq charset mail-parse-charset)))
 151       bits)
 152      (t
 153       (let ((encoding (or encoding
 154                           (cdr (assq charset mm-body-charset-encoding-alist))
 155                           (mm-qp-or-base64))))
 156         (when mm-use-ultra-safe-encoding
 157           (setq encoding (mm-safer-encoding encoding)))
 158         (mm-encode-content-transfer-encoding encoding "text/plain")
 159         encoding)))))
 160
 161 (defun mm-body-7-or-8 ()
 162   "Say whether the body is 7bit or 8bit."
 163   (if (save-excursion
 164         (goto-char (point-min))
 165         (skip-chars-forward mm-7bit-chars)
 166         (eobp))
 167       '7bit
 168     '8bit))
 169
 170 ;;;
 171 ;;; Functions for decoding
 172 ;;;
 173
 174 (defun mm-decode-content-transfer-encoding (encoding &optional type)
 175   "Decodes buffer encoded with ENCODING, returning success status.
 176 If TYPE is `text/plain' CRLF->LF translation may occur."
 177   (prog1
 178       (condition-case error
 179           (cond
 180            ((eq encoding 'quoted-printable)
 181             (quoted-printable-decode-region (point-min) (point-max))
 182             t)
 183            ((eq encoding 'base64)
 184             (base64-decode-region
 185              (point-min)
 186              ;; Some mailers insert whitespace
 187              ;; junk at the end which
 188              ;; base64-decode-region dislikes.
 189              ;; Also remove possible junk which could
 190              ;; have been added by mailing list software.
 191              (save-excursion
 192                (goto-char (point-min))
 193                (while (re-search-forward "^[\t ]*\r?\n" nil t)
 194                  (delete-region (match-beginning 0) (match-end 0)))
 195                (goto-char (point-max))
 196                (when (re-search-backward "^[A-Za-z0-9+/]+=*[\t ]*$" nil t)
 197                  (forward-line))
 198                (point))))
 199            ((memq encoding '(7bit 8bit binary))
 200             ;; Do nothing.
 201             t)
 202            ((null encoding)
 203             ;; Do nothing.
 204             t)
 205            ((memq encoding '(x-uuencode x-uue))
 206             (require 'mm-uu)
 207             (funcall mm-uu-decode-function (point-min) (point-max))
 208             t)
 209            ((eq encoding 'x-binhex)
 210             (require 'mm-uu)
 211             (funcall mm-uu-binhex-decode-function (point-min) (point-max))
 212             t)
 213            ((eq encoding 'x-yenc)
 214             (require 'mm-uu)
 215             (funcall mm-uu-yenc-decode-function (point-min) (point-max))
 216             )
 217            ((functionp encoding)
 218             (funcall encoding (point-min) (point-max))
 219             t)
 220            (t
 221             (message "Unknown encoding %s; defaulting to 8bit" encoding)))
 222         (error
 223          (message "Error while decoding: %s" error)
 224          nil))
 225     (when (and
 226            type
 227            (memq encoding '(base64 x-uuencode x-uue x-binhex x-yenc))
 228            (string-match "\\`text/" type))
 229       (goto-char (point-min))
 230       (while (search-forward "\r\n" nil t)
 231         (replace-match "\n" t t)))))
 232
 233 (defun mm-decode-body (charset &optional encoding type)
 234   "Decode the current article that has been encoded with ENCODING to CHARSET.
 235 ENCODING is a MIME content transfer encoding.
 236 CHARSET is the MIME charset with which to decode the data after transfer
 237 decoding.  If it is nil, default to `mail-parse-charset'."
 238   (when (stringp charset)
 239     (setq charset (intern (downcase charset))))
 240   (when (or (not charset)
 241             (eq 'gnus-all mail-parse-ignored-charsets)
 242             (memq 'gnus-all mail-parse-ignored-charsets)
 243             (memq charset mail-parse-ignored-charsets))
 244     (setq charset mail-parse-charset))
 245   (save-excursion
 246     (when encoding
 247       (mm-decode-content-transfer-encoding encoding type))
 248     (when (and (featurep 'mule) ;; Fixme: Wrong test for unibyte session.
 249                (not (eq charset 'gnus-decoded)))
 250       (let ((coding-system (mm-charset-to-coding-system
 251                             ;; Allow overwrite using
 252                             ;; `mm-charset-override-alist'.
 253                             charset nil t)))
 254         (if (and (not coding-system)
 255                  (listp mail-parse-ignored-charsets)
 256                  (memq 'gnus-unknown mail-parse-ignored-charsets))
 257             (setq coding-system
 258                   (mm-charset-to-coding-system mail-parse-charset)))
 259         (when (and charset coding-system
 260                    ;; buffer-file-coding-system
 261                    ;;Article buffer is nil coding system
 262                    ;;in XEmacs
 263                    (mm-multibyte-p)
 264                    (or (not (eq coding-system 'ascii))
 265                        (setq coding-system mail-parse-charset)))
 266           (mm-decode-coding-region (point-min) (point-max)
 267                                    coding-system))
 268         (setq buffer-file-coding-system
 269               (if (boundp 'last-coding-system-used)
 270                   (symbol-value 'last-coding-system-used)
 271                 coding-system))))))
 272
 273 (defun mm-decode-string (string charset)
 274   "Decode STRING with CHARSET."
 275   (when (stringp charset)
 276     (setq charset (intern (downcase charset))))
 277   (when (or (not charset)
 278             (eq 'gnus-all mail-parse-ignored-charsets)
 279             (memq 'gnus-all mail-parse-ignored-charsets)
 280             (memq charset mail-parse-ignored-charsets))
 281     (setq charset mail-parse-charset))
 282   (or
 283    (when (featurep 'mule)
 284      (let ((coding-system (mm-charset-to-coding-system
 285                            charset
 286                            ;; Allow overwrite using
 287                            ;; `mm-charset-override-alist'.
 288                            nil t)))
 289        (if (and (not coding-system)
 290                 (listp mail-parse-ignored-charsets)
 291                 (memq 'gnus-unknown mail-parse-ignored-charsets))
 292            (setq coding-system
 293                  (mm-charset-to-coding-system mail-parse-charset)))
 294        (when (and charset coding-system
 295                   (mm-multibyte-p)
 296                   (or (not (eq coding-system 'ascii))
 297                       (setq coding-system mail-parse-charset)))
 298          (mm-decode-coding-string string coding-system))))
 299    string))
 300
 301 (provide 'mm-bodies)
 302
 303 ;;; arch-tag: 41104bb6-4443-4ca9-8d5c-ff87ecf27d8d
 304 ;;; mm-bodies.el ends here