code.delx.au - gnu-emacs/blob - lisp/progmodes/cc-menus.el

   1 ;;; cc-menus.el --- imenu support for CC Mode
   2
   3 ;; Copyright (C) 1985, 1987, 1992, 1993, 1994, 1995, 1996, 1997, 1998,
   4 ;;   1999, 2000, 2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009
   5 ;;   Free Software Foundation, Inc.
   6
   7 ;; Authors:    1998- Martin Stjernholm
   8 ;;             1992-1999 Barry A. Warsaw
   9 ;;             1987 Dave Detlefs
  10 ;;             1987 Stewart Clamen
  11 ;;             1985 Richard M. Stallman
  12 ;; Maintainer: bug-cc-mode@gnu.org
  13 ;; Created:    22-Apr-1997 (split from cc-mode.el)
  14 ;; Version:    See cc-mode.el
  15 ;; Keywords:   c languages oop
  16
  17 ;; This file is part of GNU Emacs.
  18
  19 ;; GNU Emacs is free software: you can redistribute it and/or modify
  20 ;; it under the terms of the GNU General Public License as published by
  21 ;; the Free Software Foundation, either version 3 of the License, or
  22 ;; (at your option) any later version.
  23
  24 ;; GNU Emacs is distributed in the hope that it will be useful,
  25 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  26 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  27 ;; GNU General Public License for more details.
  28
  29 ;; You should have received a copy of the GNU General Public License
  30 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  31
  32 ;;; Commentary:
  33
  34 ;;; Code:
  35
  36 (eval-when-compile
  37   (let ((load-path
  38          (if (and (boundp 'byte-compile-dest-file)
  39                   (stringp byte-compile-dest-file))
  40              (cons (file-name-directory byte-compile-dest-file) load-path)
  41            load-path)))
  42     (load "cc-bytecomp" nil t)))
  43
  44 (cc-require 'cc-defs)
  45
  46 ;; The things referenced in imenu, which we don't require.
  47 (cc-bytecomp-defvar imenu-case-fold-search)
  48 (cc-bytecomp-defvar imenu-generic-expression)
  49 (cc-bytecomp-defvar imenu-create-index-function)
  50
  51 \f
  52 ;; imenu integration
  53 (defvar cc-imenu-c-prototype-macro-regexp nil
  54   "RE matching macro names used to conditionally specify function prototypes.
  55
  56 For example:
  57
  58     #ifdef __STDC__
  59       #define _P(x) x
  60     #else
  61       #define _P(x) /*nothing*/
  62     #endif
  63
  64     int main _P( (int argc, char *argv[]) )
  65
  66 A sample value might look like: `\\(_P\\|_PROTO\\)'.")
  67
  68 (defvar cc-imenu-c++-generic-expression
  69   `(
  70     ;; Try to match ::operator definitions first. Otherwise `X::operator new ()'
  71     ;; will be incorrectly recognised as function `new ()' because the regexps
  72     ;; work by backtracking from the end of the definition.
  73     (nil
  74      ,(concat
  75        "^\\<.*"
  76        "[^" c-alnum "_:<>~]"                  ; match any non-identifier char
  77                                               ; (note: this can be `\n')
  78        "\\("
  79           "\\([" c-alnum "_:<>~]*::\\)?"      ; match an operator
  80           "operator\\>[ \t]*"
  81           "\\(()\\|[^(]*\\)"                  ; special case for `()' operator
  82        "\\)"
  83
  84        "[ \t]*([^)]*)[ \t]*[^ \t;]"           ; followed by ws, arg list,
  85                                               ; require something other than
  86                                               ; a `;' after the (...) to
  87                                               ; avoid prototypes.  Can't
  88                                               ; catch cases with () inside
  89                                               ; the parentheses surrounding
  90                                               ; the parameters.  e.g.:
  91                                               ; `int foo(int a=bar()) {...}'
  92        ) 1)
  93     ;; Special case to match a line like `main() {}'
  94     ;; e.g. no return type, not even on the previous line.
  95     (nil
  96      ,(concat
  97        "^"
  98        "\\([" c-alpha "_][" c-alnum "_:<>~]*\\)" ; match function name
  99        "[ \t]*("                              ; see above, BUT
 100        "[ \t]*\\([^ \t(*][^)]*\\)?)"          ; the arg list must not start
 101        "[ \t]*[^ \t;(]"                       ; with an asterisk or parentheses
 102        ) 1)
 103     ;; General function name regexp
 104     (nil
 105      ,(concat
 106        "^\\<"                                 ; line MUST start with word char
 107        ;; \n added to prevent overflow in regexp matcher.
 108        ;; http://lists.gnu.org/archive/html/emacs-pretest-bug/2007-02/msg00021.html
 109        "[^()\n]*"                             ; no parentheses before
 110        "[^" c-alnum "_:<>~]"                  ; match any non-identifier char
 111        "\\([" c-alpha "_][" c-alnum "_:<>~]*\\)" ; match function name
 112        "\\([ \t\n]\\|\\\\\n\\)*("             ; see above, BUT the arg list
 113        "\\([ \t\n]\\|\\\\\n\\)*\\([^ \t\n(*][^)]*\\)?)" ; must not start
 114        "\\([ \t\n]\\|\\\\\n\\)*[^ \t\n;(]"    ; with an asterisk or parentheses
 115        ) 1)
 116     ;; Special case for definitions using phony prototype macros like:
 117     ;; `int main _PROTO( (int argc,char *argv[]) )'.
 118     ;; This case is only included if cc-imenu-c-prototype-macro-regexp is set.
 119     ;; Only supported in c-code, so no `:<>~' chars in function name!
 120     ,@(if cc-imenu-c-prototype-macro-regexp
 121             `((nil
 122                  ,(concat
 123                    "^\\<.*"                   ; line MUST start with word char
 124                    "[^" c-alnum "_]"          ; match any non-identifier char
 125                    "\\([" c-alpha "_][" c-alnum "_]*\\)" ; match function name
 126                    "[ \t]*"                   ; whitespace before macro name
 127                    cc-imenu-c-prototype-macro-regexp
 128                    "[ \t]*("                  ; ws followed by first paren.
 129                    "[ \t]*([^)]*)[ \t]*)[ \t]*[^ \t;]" ; see above
 130                    ) 1)))
 131     ;; Class definitions
 132     ("Class"
 133      ,(concat
 134          "^"                                  ; beginning of line is required
 135          "\\(template[ \t]*<[^>]+>[ \t]*\\)?" ; there may be a `template <...>'
 136          "\\(class\\|struct\\)[ \t]+"
 137          "\\("                                ; the string we want to get
 138          "[" c-alnum "_]+"                    ; class name
 139          "\\(<[^>]+>\\)?"                     ; possibly explicitly specialized
 140          "\\)"
 141          "\\([ \t\n]\\|\\\\\n\\)*[:{]"
 142          ) 3))
 143   "Imenu generic expression for C++ mode.  See `imenu-generic-expression'.")
 144
 145 (defvar cc-imenu-c-generic-expression
 146   cc-imenu-c++-generic-expression
 147   "Imenu generic expression for C mode.  See `imenu-generic-expression'.")
 148
 149 (defvar cc-imenu-java-generic-expression
 150   `((nil
 151      ,(concat
 152        "[" c-alpha "_][\]\[." c-alnum "_<> ]+[ \t\n\r]+" ; type spec
 153        "\\([" c-alpha "_][" c-alnum "_]+\\)" ; method name
 154        "[ \t\n\r]*"
 155        ;; An argument list htat is either empty or contains any number
 156        ;; of arguments.  An argument is any number of annotations
 157        ;; followed by a type spec followed by a word.  A word is an
 158        ;; identifier.  A type spec is an identifier, possibly followed
 159        ;; by < typespec > possibly followed by [].
 160        (concat "("
 161                "\\("
 162                   "[ \t\n\r]*"
 163                   "\\("
 164                      "@"
 165                      "[" c-alpha "_]"
 166                      "[" c-alnum "._]""*"
 167                      "[ \t\n\r]+"
 168                   "\\)*"
 169                   "\\("
 170                      "[" c-alpha "_]"
 171                      "[\]\[" c-alnum "_.]*"
 172                      "\\("
 173                         "<"
 174                         "[ \t\n\r]*"
 175                         "[\]\[.," c-alnum "_<> \t\n\r]*"
 176                         ">"
 177                      "\\)?"
 178                      "\\(\\[\\]\\)?"
 179                      "[ \t\n\r]+"
 180                   "\\)"
 181                  "[" c-alpha "_]"
 182                  "[" c-alnum "_]*"
 183                  "[ \t\n\r,]*"
 184                "\\)*"
 185               ")"
 186            "[ \t\n\r]*"
 187        "{"
 188        )) 1))
 189   "Imenu generic expression for Java mode.  See
 190 `imenu-generic-expression'.")
 191
 192 ;;                        *Warning for cc-mode developers*
 193 ;;
 194 ;; `cc-imenu-objc-generic-expression' elements depend on
 195 ;; `cc-imenu-c++-generic-expression'. So if you change this
 196 ;; expression, you need to change following variables,
 197 ;; `cc-imenu-objc-generic-expression-*-index',
 198 ;; too. `cc-imenu-objc-function' uses these *-index variables, in
 199 ;; order to know where the each regexp *group \\(foobar\\)* elements
 200 ;; are started.
 201 ;;
 202 ;; *-index variables are initialized during `cc-imenu-objc-generic-expression'
 203 ;; being initialized.
 204 ;;
 205
 206 ;; Internal variables
 207 (defvar cc-imenu-objc-generic-expression-noreturn-index nil)
 208 (defvar cc-imenu-objc-generic-expression-general-func-index nil)
 209 (defvar cc-imenu-objc-generic-expression-proto-index nil)
 210 (defvar cc-imenu-objc-generic-expression-objc-base-index nil)
 211
 212 (defvar cc-imenu-objc-generic-expression
 213   (concat
 214    ;;
 215    ;; For C
 216    ;;
 217    ;; > Special case to match a line like `main() {}'
 218    ;; > e.g. no return type, not even on the previous line.
 219    ;; Pick a token by (match-string 1)
 220    (car (cdr (nth 1 cc-imenu-c++-generic-expression))) ; -> index += 2
 221    (prog2 (setq cc-imenu-objc-generic-expression-noreturn-index 1) "")
 222    "\\|"
 223    ;; > General function name regexp
 224    ;; Pick a token by  (match-string 3)
 225    (car (cdr (nth 2 cc-imenu-c++-generic-expression))) ; -> index += 5
 226    (prog2 (setq cc-imenu-objc-generic-expression-general-func-index 3) "")
 227    ;; > Special case for definitions using phony prototype macros like:
 228    ;; > `int main _PROTO( (int argc,char *argv[]) )'.
 229    ;; Pick a token by  (match-string 8)
 230    (if cc-imenu-c-prototype-macro-regexp
 231        (concat
 232         "\\|"
 233         (car (cdr (nth 3 cc-imenu-c++-generic-expression))) ; -> index += 1
 234         (prog2 (setq cc-imenu-objc-generic-expression-objc-base-index 9) "")
 235         )
 236      (prog2 (setq cc-imenu-objc-generic-expression-objc-base-index 8) "")
 237      "")                                ; -> index += 0
 238    (prog2 (setq cc-imenu-objc-generic-expression-proto-index 8) "")
 239    ;;
 240    ;; For Objective-C
 241    ;; Pick a token by (match-string 8 or 9)
 242    ;;
 243    "\\|\\("
 244    "^[-+][:" c-alnum "()*_<>\n\t ]*[;{]"        ; Methods
 245    "\\|"
 246    "^@interface[\t ]+[" c-alnum "_]+[\t ]*:"
 247    "\\|"
 248    "^@interface[\t ]+[" c-alnum "_]+[\t ]*([" c-alnum "_]+)"
 249    "\\|"
 250    ;; For NSObject, NSProxy and Object... They don't have super class.
 251    "^@interface[\t ]+[" c-alnum "_]+[\t ]*.*$"
 252    "\\|"
 253    "^@implementation[\t ]+[" c-alnum "_]+[\t ]*([" c-alnum "_]+)"
 254    "\\|"
 255    "^@implementation[\t ]+[" c-alnum "_]+"
 256    "\\|"
 257    "^@protocol[\t ]+[" c-alnum "_]+" "\\)")
 258   "Imenu generic expression for ObjC mode.  See `imenu-generic-expression'.")
 259
 260
 261 ;; Imenu support for objective-c uses functions.
 262 (defsubst cc-imenu-objc-method-to-selector (method)
 263   "Return the objc selector style string of METHOD.
 264 Example:
 265 - perform: (SEL)aSelector withObject: object1 withObject: object2; /* METHOD */
 266 =>
 267 -perform:withObject:withObject:withObject: /* selector */"
 268   (let ((return "")                     ; String to be returned
 269         (p 0)                           ; Current scanning position in METHOD
 270         (pmax (length method))          ;
 271         char                            ; Current scanning target
 272         (betweenparen 0)                ; CHAR is in parentheses.
 273         argreq                          ; An argument is required.
 274         inargvar)                       ; position of CHAR is in an argument variable.
 275     (while (< p pmax)
 276       (setq char (aref method p)
 277             p (1+ p))
 278       (cond
 279        ;; Is CHAR part of a objc token?
 280        ((and (not inargvar)     ; Ignore if CHAR is part of an argument variable.
 281              (eq 0 betweenparen) ; Ignore if CHAR is in parentheses.
 282              (or (and (<= ?a char) (<= char ?z))
 283                  (and (<= ?A char) (<= char ?Z))
 284                  (and (<= ?0 char) (<= char ?9))
 285                  (= ?_ char)))
 286         (if argreq
 287             (setq inargvar t
 288                   argreq nil)
 289           (setq return (concat return (char-to-string char)))))
 290        ;; Or a white space?
 291        ((and inargvar (or (eq ?\  char) (eq ?\n char))
 292              (setq inargvar nil)))
 293        ;; Or a method separator?
 294        ;; If a method separator, the next token will be an argument variable.
 295        ((eq ?: char)
 296         (setq argreq t
 297               return (concat return (char-to-string char))))
 298        ;; Or an open parentheses?
 299        ((eq ?\( char)
 300         (setq betweenparen (1+ betweenparen)))
 301        ;; Or a close parentheses?
 302        ((eq ?\) char)
 303         (setq betweenparen (1- betweenparen)))))
 304     return))
 305
 306 (defun cc-imenu-objc-remove-white-space  (str)
 307   "Remove all spaces and tabs from STR."
 308   (let ((return "")
 309         (p 0)
 310         (max (length str))
 311         char)
 312     (while (< p max)
 313       (setq char (aref str p))
 314       (setq p (1+ p))
 315       (if (or (= char ?\ ) (= char ?\t))
 316           ()
 317         (setq return (concat return (char-to-string char)))))
 318     return))
 319
 320 (defun cc-imenu-objc-function ()
 321   "Imenu support for Objective C mode."
 322   (let (methodlist
 323         clist
 324         ;;
 325         ;; OBJC, Cnoreturn, Cgeneralfunc, Cproto are constants.
 326         ;;
 327         ;;                  *Warning for developers*
 328         ;; These constants depend on `cc-imenu-c++-generic-expression'.
 329         ;;
 330         (OBJC cc-imenu-objc-generic-expression-objc-base-index)
 331         ;; Special case to match a line like `main() {}'
 332         (Cnoreturn cc-imenu-objc-generic-expression-noreturn-index)
 333         ;; General function name regexp
 334         (Cgeneralfunc cc-imenu-objc-generic-expression-general-func-index)
 335         ;; Special case for definitions using phony prototype macros like:
 336         (Cproto cc-imenu-objc-generic-expression-proto-index)
 337         langnum
 338         ;;
 339         (classcount 0)
 340         toplist
 341         str
 342         str2
 343         (intflen (length "@interface"))
 344         (implen  (length "@implementation"))
 345         (prtlen  (length "@protocol"))
 346         (func
 347          ;;
 348          ;; Does this emacs have buffer-substring-no-properties?
 349          ;;
 350          (if (fboundp 'buffer-substring-no-properties)
 351              'buffer-substring-no-properties
 352            'buffer-substring)))
 353     (goto-char (point-max))
 354     ;;
 355     (while (re-search-backward cc-imenu-objc-generic-expression nil t)
 356       (setq langnum (if (match-beginning OBJC)
 357                         OBJC
 358                       (cond
 359                        ((match-beginning Cproto) Cproto)
 360                        ((match-beginning Cgeneralfunc) Cgeneralfunc)
 361                        ((match-beginning Cnoreturn) Cnoreturn))))
 362       (setq str (funcall func (match-beginning langnum) (match-end langnum)))
 363       ;;
 364       (cond
 365        ;;
 366        ;; C
 367        ;;
 368        ((not (eq langnum OBJC))
 369         (setq clist (cons (cons str (match-beginning langnum)) clist)))
 370        ;;
 371        ;; ObjC
 372        ;;
 373        ;; An instance Method
 374        ((eq (aref str 0) ?-)
 375         (setq str (concat "-" (cc-imenu-objc-method-to-selector str)))
 376         (setq methodlist (cons (cons str
 377                               (match-beginning langnum))
 378                         methodlist)))
 379        ;; A factory Method
 380        ((eq (aref str 0) ?+)
 381         (setq str (concat "+" (cc-imenu-objc-method-to-selector str)))
 382         (setq methodlist (cons (cons str
 383                               (match-beginning langnum))
 384                         methodlist)))
 385        ;; Interface or implementation or protocol
 386        ((eq (aref str 0) ?@)
 387         (setq classcount (1+ classcount))
 388         (cond
 389          ((and (> (length str) implen)
 390                (string= (substring  str 0 implen) "@implementation"))
 391           (setq str (substring str implen)
 392                 str2 "@implementation"))
 393          ((string= (substring  str 0 intflen) "@interface")
 394           (setq str (substring str intflen)
 395                 str2 "@interface"))
 396          ((string= (substring  str 0 prtlen) "@protocol")
 397           (setq str (substring str prtlen)
 398                 str2 "@protocol")))
 399         (setq str (cc-imenu-objc-remove-white-space str))
 400         (setq methodlist (cons (cons str2
 401                               (match-beginning langnum))
 402                                methodlist))
 403         (setq toplist (cons nil (cons (cons str
 404                                           methodlist) toplist))
 405               methodlist nil))))
 406     ;;
 407     (if (eq (car toplist) nil)
 408         (setq toplist (cdr toplist)))
 409
 410     ;; In this buffer, there is only one or zero @{interface|implementation|protocol}.
 411     (if (< classcount 2)
 412         (let ((classname (car (car toplist)))
 413               (p (cdr (car (cdr (car toplist)))))
 414               last)
 415           (setq toplist (cons (cons classname p) (cdr (cdr (car toplist)))))
 416           ;; Add C lang token
 417           (if clist
 418               (progn
 419                 (setq last toplist)
 420                 (while (cdr last)
 421                   (setq last (cdr last)))
 422                 (setcdr last clist))))
 423       ;; Add C lang tokens as a sub menu
 424       (if clist
 425           (setq toplist (cons (cons "C" clist) toplist))))
 426     ;;
 427     toplist
 428     ))
 429
 430 ;(defvar cc-imenu-pike-generic-expression
 431 ;  ())
 432 ; FIXME: Please contribute one!
 433
 434 (defun cc-imenu-init (mode-generic-expression
 435                       &optional mode-create-index-function)
 436   (setq imenu-generic-expression mode-generic-expression
 437         imenu-case-fold-search nil)
 438   (when mode-create-index-function
 439     (setq imenu-create-index-function mode-create-index-function)))
 440
 441 \f
 442 (cc-provide 'cc-menus)
 443
 444 ;; arch-tag: f6b60933-91f0-4145-ab44-70ca6d1b919b
 445 ;;; cc-menus.el ends here