code.delx.au - gnu-emacs/blob - lisp/emacs-lisp/debug.el

   1 ;;; debug.el --- debuggers and related commands for Emacs
   2
   3 ;; Copyright (C) 1985, 1986, 1994 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6 ;; Keywords: lisp, tools, maint
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; This is a major mode documented in the Emacs manual.
  28
  29 ;;; Code:
  30
  31 (defgroup debugger nil
  32   "Debuggers and related commands for Emacs."
  33   :prefix "debugger-"
  34   :group 'debug)
  35
  36 (defcustom debugger-mode-hook nil
  37   "*Hooks run when `debugger-mode' is turned on."
  38   :type 'hook
  39   :group 'debugger
  40   :version "20.3")
  41
  42
  43 (defcustom debug-function-list nil
  44   "List of functions currently set for debug on entry."
  45   :type '(repeat function)
  46   :group 'debugger)
  47
  48 (defcustom debugger-step-after-exit nil
  49   "Non-nil means \"single-step\" after the debugger exits."
  50   :type 'boolean
  51   :group 'debugger)
  52
  53 (defvar debugger-value nil
  54   "This is the value for the debugger to return, when it returns.")
  55
  56 (defvar debugger-old-buffer nil
  57   "This is the buffer that was current when the debugger was entered.")
  58
  59 (defvar debugger-outer-match-data)
  60 (defvar debugger-outer-load-read-function)
  61 (defvar debugger-outer-overriding-local-map)
  62 (defvar debugger-outer-overriding-terminal-local-map)
  63 (defvar debugger-outer-track-mouse)
  64 (defvar debugger-outer-last-command)
  65 (defvar debugger-outer-this-command)
  66 (defvar debugger-outer-unread-command-char)
  67 (defvar debugger-outer-unread-command-events)
  68 (defvar debugger-outer-unread-post-input-method-events)
  69 (defvar debugger-outer-last-input-event)
  70 (defvar debugger-outer-last-command-event)
  71 (defvar debugger-outer-last-nonmenu-event)
  72 (defvar debugger-outer-last-event-frame)
  73 (defvar debugger-outer-standard-input)
  74 (defvar debugger-outer-standard-output)
  75 (defvar debugger-outer-cursor-in-echo-area)
  76
  77 ;;;###autoload
  78 (setq debugger 'debug)
  79 ;;;###autoload
  80 (defun debug (&rest debugger-args)
  81   "Enter debugger.  To return, type \\<debugger-mode-map>`\\[debugger-continue]'.
  82 Arguments are mainly for use when this is called from the internals
  83 of the evaluator.
  84
  85 You may call with no args, or you may pass nil as the first arg and
  86 any other args you like.  In that case, the list of args after the
  87 first will be printed into the backtrace buffer."
  88   (interactive)
  89   (message "Entering debugger...")
  90   (let (debugger-value
  91         (debug-on-error nil)
  92         (debug-on-quit nil)
  93         (debugger-buffer (let ((default-major-mode 'fundamental-mode))
  94                            (get-buffer-create "*Backtrace*")))
  95         (debugger-old-buffer (current-buffer))
  96         (debugger-step-after-exit nil)
  97         ;; Don't keep reading from an executing kbd macro!
  98         (executing-kbd-macro nil)
  99         ;; Save the outer values of these vars for the `e' command
 100         ;; before we replace the values.
 101         (debugger-outer-match-data (match-data))
 102         (debugger-outer-load-read-function load-read-function)
 103         (debugger-outer-overriding-local-map overriding-local-map)
 104         (debugger-outer-overriding-terminal-local-map
 105          overriding-terminal-local-map)
 106         (debugger-outer-track-mouse track-mouse)
 107         (debugger-outer-last-command last-command)
 108         (debugger-outer-this-command this-command)
 109         (debugger-outer-unread-command-char unread-command-char)
 110         (debugger-outer-unread-command-events unread-command-events)
 111         (debugger-outer-unread-post-input-method-events
 112          unread-post-input-method-events)
 113         (debugger-outer-last-input-event last-input-event)
 114         (debugger-outer-last-command-event last-command-event)
 115         (debugger-outer-last-nonmenu-event last-nonmenu-event)
 116         (debugger-outer-last-event-frame last-event-frame)
 117         (debugger-outer-standard-input standard-input)
 118         (debugger-outer-standard-output standard-output)
 119         (debugger-outer-cursor-in-echo-area cursor-in-echo-area))
 120     ;; Set this instead of binding it, so that `q'
 121     ;; will not restore it.
 122     (setq overriding-terminal-local-map nil)
 123     ;; Don't let these magic variables affect the debugger itself.
 124     (let ((last-command nil) this-command track-mouse
 125           (unread-command-char -1) unread-command-events
 126           unread-post-input-method-events
 127           last-input-event last-command-event last-nonmenu-event
 128           last-event-frame
 129           overriding-local-map
 130           load-read-function
 131           ;; If we are inside a minibuffer, allow nesting
 132           ;; so that we don't get an error from the `e' command.
 133           (enable-recursive-minibuffers
 134            (or enable-recursive-minibuffers (> (minibuffer-depth) 0)))
 135           (standard-input t) (standard-output t)
 136           (cursor-in-echo-area nil))
 137       (unwind-protect
 138           (save-excursion
 139             (save-window-excursion
 140               (pop-to-buffer debugger-buffer)
 141               (erase-buffer)
 142               (set-buffer-multibyte nil)
 143               (let ((standard-output (current-buffer))
 144                     (print-escape-newlines t)
 145                     (print-length 50))
 146                 (backtrace))
 147               (goto-char (point-min))
 148               (debugger-mode)
 149               (delete-region (point)
 150                              (progn
 151                                (search-forward "\n  debug(")
 152                                (forward-line 1)
 153                                (point)))
 154               (debugger-reenable)
 155               ;; lambda is for debug-on-call when a function call is next.
 156               ;; debug is for debug-on-entry function called.
 157               (cond ((memq (car debugger-args) '(lambda debug))
 158                      (insert "Entering:\n")
 159                      (if (eq (car debugger-args) 'debug)
 160                          (progn
 161                            ;; Skip the frames for backtrace-debug, byte-code,
 162                            ;; and debug.
 163                            (backtrace-debug 3 t)
 164                            (delete-char 1)
 165                            (insert ?*)
 166                            (beginning-of-line))))
 167                     ;; Exiting a function.
 168                     ((eq (car debugger-args) 'exit)
 169                      (insert "Return value: ")
 170                      (setq debugger-value (nth 1 debugger-args))
 171                      (prin1 debugger-value (current-buffer))
 172                      (insert ?\n)
 173                      (delete-char 1)
 174                      (insert ? )
 175                      (beginning-of-line))
 176                     ;; Debugger entered for an error.
 177                     ((eq (car debugger-args) 'error)
 178                      (insert "Signaling: ")
 179                      (prin1 (nth 1 debugger-args) (current-buffer))
 180                      (insert ?\n))
 181                     ;; debug-on-call, when the next thing is an eval.
 182                     ((eq (car debugger-args) t)
 183                      (insert "Beginning evaluation of function call form:\n"))
 184                     ;; User calls debug directly.
 185                     (t
 186                      (prin1 (if (eq (car debugger-args) 'nil)
 187                                 (cdr debugger-args) debugger-args)
 188                             (current-buffer))
 189                      (insert ?\n)))
 190               (message "")
 191               (let ((inhibit-trace t)
 192                     (standard-output nil)
 193                     (buffer-read-only t))
 194                 (message "")
 195                 ;; Make sure we unbind buffer-read-only in the right buffer.
 196                 (save-excursion
 197                   (recursive-edit)))))
 198         ;; Kill or at least neuter the backtrace buffer, so that users
 199         ;; don't try to execute debugger commands in an invalid context.
 200         (if (get-buffer-window debugger-buffer 'visible)
 201             ;; Still visible despite the save-window-excursion?  Maybe it
 202             ;; it's in a pop-up frame.  It would be annoying to delete and
 203             ;; recreate it every time the debugger stops, so instead we'll
 204             ;; erase it but leave it visible.
 205             (save-excursion
 206               (set-buffer debugger-buffer)
 207               (erase-buffer)
 208               (fundamental-mode))
 209           (kill-buffer debugger-buffer))
 210         (set-match-data debugger-outer-match-data)))
 211     ;; Put into effect the modified values of these variables
 212     ;; in case the user set them with the `e' command.
 213     (setq load-read-function debugger-outer-load-read-function)
 214     (setq overriding-local-map debugger-outer-overriding-local-map)
 215     (setq overriding-terminal-local-map
 216           debugger-outer-overriding-terminal-local-map)
 217     (setq track-mouse debugger-outer-track-mouse)
 218     (setq last-command debugger-outer-last-command)
 219     (setq this-command debugger-outer-this-command)
 220     (setq unread-command-char debugger-outer-unread-command-char)
 221     (setq unread-command-events debugger-outer-unread-command-events)
 222     (setq unread-post-input-method-events
 223           debugger-outer-unread-post-input-method-events)
 224     (setq last-input-event debugger-outer-last-input-event)
 225     (setq last-command-event debugger-outer-last-command-event)
 226     (setq last-nonmenu-event debugger-outer-last-nonmenu-event)
 227     (setq last-event-frame debugger-outer-last-event-frame)
 228     (setq standard-input debugger-outer-standard-input)
 229     (setq standard-output debugger-outer-standard-output)
 230     (setq cursor-in-echo-area debugger-outer-cursor-in-echo-area)
 231     (setq debug-on-next-call debugger-step-after-exit)
 232     debugger-value))
 233 \f
 234 (defun debugger-step-through ()
 235   "Proceed, stepping through subexpressions of this expression.
 236 Enter another debugger on next entry to eval, apply or funcall."
 237   (interactive)
 238   (setq debugger-step-after-exit t)
 239   (message "Proceeding, will debug on next eval or call.")
 240   (exit-recursive-edit))
 241
 242 (defun debugger-continue ()
 243   "Continue, evaluating this expression without stopping."
 244   (interactive)
 245   (message "Continuing.")
 246   (exit-recursive-edit))
 247
 248 (defun debugger-return-value (val)
 249   "Continue, specifying value to return.
 250 This is only useful when the value returned from the debugger
 251 will be used, such as in a debug on exit from a frame."
 252   (interactive "XReturn value (evaluated): ")
 253   (setq debugger-value val)
 254   (princ "Returning " t)
 255   (prin1 debugger-value)
 256   (exit-recursive-edit))
 257
 258 (defun debugger-jump ()
 259   "Continue to exit from this frame, with all debug-on-entry suspended."
 260   (interactive)
 261   ;; Compensate for the two extra stack frames for debugger-jump.
 262   (let ((debugger-frame-offset (+ debugger-frame-offset 2)))
 263     (debugger-frame))
 264   ;; Turn off all debug-on-entry functions
 265   ;; but leave them in the list.
 266   (let ((list debug-function-list))
 267     (while list
 268       (fset (car list)
 269             (debug-on-entry-1 (car list) (symbol-function (car list)) nil))
 270       (setq list (cdr list))))
 271   (message "Continuing through this frame")
 272   (exit-recursive-edit))
 273
 274 (defun debugger-reenable ()
 275   "Turn all debug-on-entry functions back on."
 276   (let ((list debug-function-list))
 277     (while list
 278       (or (consp (symbol-function (car list)))
 279           (debug-convert-byte-code (car list)))
 280       (fset (car list)
 281             (debug-on-entry-1 (car list) (symbol-function (car list)) t))
 282       (setq list (cdr list)))))
 283
 284 (defun debugger-frame-number ()
 285   "Return number of frames in backtrace before the one point points at."
 286   (save-excursion
 287     (beginning-of-line)
 288     (let ((opoint (point))
 289           (count 0))
 290       (goto-char (point-min))
 291       (if (or (equal (buffer-substring (point) (+ (point) 6))
 292                      "Signal")
 293               (equal (buffer-substring (point) (+ (point) 6))
 294                      "Return"))
 295           (progn
 296             (search-forward ":")
 297             (forward-sexp 1)))
 298       (forward-line 1)
 299       (while (progn
 300                (forward-char 2)
 301                (if (= (following-char) ?\()
 302                    (forward-sexp 1)
 303                  (forward-sexp 2))
 304                (forward-line 1)
 305                (<= (point) opoint))
 306         (setq count (1+ count)))
 307       count)))
 308
 309 ;; Chosen empirically to account for all the frames
 310 ;; that will exist when debugger-frame is called
 311 ;; within the first one that appears in the backtrace buffer.
 312 ;; Assumes debugger-frame is called from a key;
 313 ;; will be wrong if it is called with Meta-x.
 314 (defconst debugger-frame-offset 8 "")
 315
 316 (defun debugger-frame ()
 317   "Request entry to debugger when this frame exits.
 318 Applies to the frame whose line point is on in the backtrace."
 319   (interactive)
 320   (beginning-of-line)
 321   (let ((level (debugger-frame-number)))
 322     (backtrace-debug (+ level debugger-frame-offset) t))
 323   (if (= (following-char) ? )
 324       (let ((buffer-read-only nil))
 325         (delete-char 1)
 326         (insert ?*)))
 327   (beginning-of-line))
 328
 329 (defun debugger-frame-clear ()
 330   "Do not enter debugger when this frame exits.
 331 Applies to the frame whose line point is on in the backtrace."
 332   (interactive)
 333   (beginning-of-line)
 334   (let ((level (debugger-frame-number)))
 335     (backtrace-debug (+ level debugger-frame-offset) nil))
 336   (if (= (following-char) ?*)
 337       (let ((buffer-read-only nil))
 338         (delete-char 1)
 339         (insert ? )))
 340   (beginning-of-line))
 341
 342
 343
 344 (put 'debugger-env-macro 'lisp-indent-function 0)
 345 (defmacro debugger-env-macro (&rest body)
 346   "Run BODY in original environment."
 347   (`
 348    (save-excursion
 349      (if (null (buffer-name debugger-old-buffer))
 350          ;; old buffer deleted
 351          (setq debugger-old-buffer (current-buffer)))
 352      (set-buffer debugger-old-buffer)
 353      (let ((track-mouse debugger-outer-track-mouse)
 354            (last-command debugger-outer-last-command)
 355            (this-command debugger-outer-this-command)
 356            (unread-command-char debugger-outer-unread-command-char)
 357            (unread-command-events debugger-outer-unread-command-events)
 358            (unread-post-input-method-events
 359             debugger-outer-unread-post-input-method-events)
 360            (last-input-event debugger-outer-last-input-event)
 361            (last-command-event debugger-outer-last-command-event)
 362            (last-nonmenu-event debugger-outer-last-nonmenu-event)
 363            (last-event-frame debugger-outer-last-event-frame)
 364            (standard-input debugger-outer-standard-input)
 365            (standard-output debugger-outer-standard-output)
 366            (cursor-in-echo-area debugger-outer-cursor-in-echo-area)
 367            (overriding-local-map debugger-outer-overriding-local-map)
 368            (overriding-terminal-local-map
 369             debugger-outer-overriding-terminal-local-map)
 370            (load-read-function debugger-outer-load-read-function))
 371        (set-match-data debugger-outer-match-data)
 372        (prog1 (progn (,@ body))
 373          (setq debugger-outer-match-data (match-data))
 374          (setq debugger-outer-load-read-function load-read-function)
 375          (setq debugger-outer-overriding-terminal-local-map
 376                overriding-terminal-local-map)
 377          (setq debugger-outer-overriding-local-map overriding-local-map)
 378          (setq debugger-outer-track-mouse track-mouse)
 379          (setq debugger-outer-last-command last-command)
 380          (setq debugger-outer-this-command this-command)
 381          (setq debugger-outer-unread-command-char unread-command-char)
 382          (setq debugger-outer-unread-command-events unread-command-events)
 383          (setq debugger-outer-unread-post-input-method-events
 384                unread-post-input-method-events)
 385          (setq debugger-outer-last-input-event last-input-event)
 386          (setq debugger-outer-last-command-event last-command-event)
 387          (setq debugger-outer-last-nonmenu-event last-nonmenu-event)
 388          (setq debugger-outer-last-event-frame last-event-frame)
 389          (setq debugger-outer-standard-input standard-input)
 390          (setq debugger-outer-standard-output standard-output)
 391          (setq debugger-outer-cursor-in-echo-area cursor-in-echo-area)
 392          )))))
 393
 394 (defun debugger-eval-expression (exp)
 395   "Eval an expression, in an environment like that outside the debugger."
 396   (interactive
 397    (list (read-from-minibuffer "Eval: "
 398                                nil read-expression-map t
 399                                'read-expression-history)))
 400   (debugger-env-macro (eval-expression exp)))
 401 \f
 402 (defvar debugger-mode-map nil)
 403 (if debugger-mode-map
 404     nil
 405   (let ((loop ? ))
 406     (setq debugger-mode-map (make-keymap))
 407     (suppress-keymap debugger-mode-map)
 408     (define-key debugger-mode-map "-" 'negative-argument)
 409     (define-key debugger-mode-map "b" 'debugger-frame)
 410     (define-key debugger-mode-map "c" 'debugger-continue)
 411     (define-key debugger-mode-map "j" 'debugger-jump)
 412     (define-key debugger-mode-map "r" 'debugger-return-value)
 413     (define-key debugger-mode-map "u" 'debugger-frame-clear)
 414     (define-key debugger-mode-map "d" 'debugger-step-through)
 415     (define-key debugger-mode-map "l" 'debugger-list-functions)
 416     (define-key debugger-mode-map "h" 'describe-mode)
 417     (define-key debugger-mode-map "q" 'top-level)
 418     (define-key debugger-mode-map "e" 'debugger-eval-expression)
 419     (define-key debugger-mode-map " " 'next-line)
 420     (define-key debugger-mode-map "R" 'debugger-record-expression)
 421     ))
 422
 423
 424 (defcustom debugger-record-buffer "*Debugger-record*"
 425   "*Buffer name for expression values, for \\[debugger-record-expression]."
 426   :type 'string
 427   :group 'debugger
 428   :version "20.3")
 429
 430 (defun debugger-record-expression  (exp)
 431   "Display a variable's value and record it in `*Backtrace-record*' buffer."
 432   (interactive
 433    (list (read-from-minibuffer
 434           "Record Eval: "
 435           nil
 436           read-expression-map t
 437           'read-expression-history)))
 438   (let* ((buffer (get-buffer-create debugger-record-buffer))
 439          (standard-output buffer))
 440     (princ (format "Debugger Eval (%s): " exp))
 441     (princ (debugger-eval-expression exp))
 442     (terpri))
 443
 444   (with-current-buffer (get-buffer debugger-record-buffer)
 445     (save-excursion
 446       (forward-line -1)
 447       (message
 448        (buffer-substring (point) (progn (end-of-line) (point)))))))
 449
 450 (put 'debugger-mode 'mode-class 'special)
 451
 452 (defun debugger-mode ()
 453   "Mode for backtrace buffers, selected in debugger.
 454 \\<debugger-mode-map>
 455 A line starts with `*' if exiting that frame will call the debugger.
 456 Type \\[debugger-frame] or \\[debugger-frame-clear] to set or remove the `*'.
 457
 458 When in debugger due to frame being exited,
 459 use the \\[debugger-return-value] command to override the value
 460 being returned from that frame.
 461
 462 Use \\[debug-on-entry] and \\[cancel-debug-on-entry] to control
 463 which functions will enter the debugger when called.
 464
 465 Complete list of commands:
 466 \\{debugger-mode-map}"
 467   (kill-all-local-variables)
 468   (setq major-mode 'debugger-mode)
 469   (setq mode-name "Debugger")
 470   (setq truncate-lines t)
 471   (set-syntax-table emacs-lisp-mode-syntax-table)
 472   (use-local-map debugger-mode-map)
 473   (run-hooks 'debugger-mode-hook))
 474 \f
 475 ;;;###autoload
 476 (defun debug-on-entry (function)
 477   "Request FUNCTION to invoke debugger each time it is called.
 478 If you tell the debugger to continue, FUNCTION's execution proceeds.
 479 This works by modifying the definition of FUNCTION,
 480 which must be written in Lisp, not predefined.
 481 Use \\[cancel-debug-on-entry] to cancel the effect of this command.
 482 Redefining FUNCTION also cancels it."
 483   (interactive "aDebug on entry (to function): ")
 484   (debugger-reenable)
 485   ;; Handle a function that has been aliased to some other function.
 486   (if (symbolp (symbol-function function))
 487       (fset function `(lambda (&rest debug-on-entry-args)
 488                         (apply ',(symbol-function function)
 489                                debug-on-entry-args))))
 490   (if (subrp (symbol-function function))
 491       (error "Function %s is a primitive" function))
 492   (or (consp (symbol-function function))
 493       (debug-convert-byte-code function))
 494   (or (consp (symbol-function function))
 495       (error "Definition of %s is not a list" function))
 496   (fset function (debug-on-entry-1 function (symbol-function function) t))
 497   (or (memq function debug-function-list)
 498       (setq debug-function-list (cons function debug-function-list)))
 499   function)
 500
 501 ;;;###autoload
 502 (defun cancel-debug-on-entry (&optional function)
 503   "Undo effect of \\[debug-on-entry] on FUNCTION.
 504 If argument is nil or an empty string, cancel for all functions."
 505   (interactive
 506    (list (let ((name
 507                 (completing-read "Cancel debug on entry (to function): "
 508                                  ;; Make an "alist" of the functions
 509                                  ;; that now have debug on entry.
 510                                  (mapcar 'list
 511                                          (mapcar 'symbol-name
 512                                                  debug-function-list))
 513                                  nil t nil)))
 514            (if name (intern name)))))
 515   (debugger-reenable)
 516   (if (and function (not (string= function "")))
 517       (progn
 518         (fset function
 519               (debug-on-entry-1 function (symbol-function function) nil))
 520         (setq debug-function-list (delq function debug-function-list))
 521         function)
 522     (message "Cancelling debug-on-entry for all functions")
 523     (mapcar 'cancel-debug-on-entry debug-function-list)))
 524
 525 (defun debug-convert-byte-code (function)
 526   (let ((defn (symbol-function function)))
 527     (if (not (consp defn))
 528         ;; Assume a compiled code object.
 529         (let* ((contents (append defn nil))
 530                (body
 531                 (list (list 'byte-code (nth 1 contents)
 532                             (nth 2 contents) (nth 3 contents)))))
 533           (if (nthcdr 5 contents)
 534               (setq body (cons (list 'interactive (nth 5 contents)) body)))
 535           (if (nth 4 contents)
 536               ;; Use `documentation' here, to get the actual string,
 537               ;; in case the compiled function has a reference
 538               ;; to the .elc file.
 539               (setq body (cons (documentation function) body)))
 540           (fset function (cons 'lambda (cons (car contents) body)))))))
 541
 542 (defun debug-on-entry-1 (function defn flag)
 543   (if (subrp defn)
 544       (error "%s is a built-in function" function)
 545     (if (eq (car defn) 'macro)
 546         (debug-on-entry-1 function (cdr defn) flag)
 547       (or (eq (car defn) 'lambda)
 548           (error "%s not user-defined Lisp function" function))
 549       (let (tail prec)
 550         (if (stringp (car (nthcdr 2 defn)))
 551             (setq tail (nthcdr 3 defn)
 552                   prec (list (car defn) (car (cdr defn))
 553                              (car (cdr (cdr defn)))))
 554           (setq tail (nthcdr 2 defn)
 555                 prec (list (car defn) (car (cdr defn)))))
 556         (if (eq flag (equal (car tail) '(debug 'debug)))
 557             defn
 558           (if flag
 559               (nconc prec (cons '(debug 'debug) tail))
 560             (nconc prec (cdr tail))))))))
 561
 562 (defun debugger-list-functions ()
 563   "Display a list of all the functions now set to debug on entry."
 564   (interactive)
 565   (with-output-to-temp-buffer "*Help*"
 566     (if (null debug-function-list)
 567         (princ "No debug-on-entry functions now\n")
 568       (princ "Functions set to debug on entry:\n\n")
 569       (let ((list debug-function-list))
 570         (while list
 571           (prin1 (car list))
 572           (terpri)
 573           (setq list (cdr list))))
 574       (princ "Note: if you have redefined a function, then it may no longer\n")
 575       (princ "be set to debug on entry, even if it is in the list."))
 576     (save-excursion
 577       (set-buffer standard-output)
 578       (help-mode))))
 579
 580 (provide 'debug)
 581
 582 ;;; debug.el ends here