code.delx.au - gnu-emacs/blob - lisp/startup.el

   1 ;;; startup.el --- process Emacs shell arguments
   2
   3 ;; Copyright (C) 1985, 86, 92, 94, 95, 96, 97, 1998, 1999 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6 ;; Keywords: internal
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; This file parses the command line and gets Emacs running.  Options on
  28 ;; the command line are handled in precedence order.  The order is the
  29 ;; one in the list below; first described means first handled.  Options
  30 ;; within each category (delimited by a bar) are handled in the order
  31 ;; encountered on the command line.
  32
  33 ;; -------------------------
  34 ;; -version                  Print Emacs version to stderr, then exit
  35 ;; --version                 successfully right away.
  36 ;;                           This option is handled by emacs.c
  37 ;; -------------------------
  38 ;; -help                     Print a short usage description and exit
  39 ;; --help                    successfully right away.
  40 ;;                           This option is handled by emacs.c
  41 ;; -------------------------
  42 ;; -nl                       Do not use shared memory (for systems that
  43 ;; -no-shared-memory         support this) for the dumped Emacs data.
  44 ;;                           This option is handled by emacs.c
  45 ;;
  46 ;; -map                      For VMS.
  47 ;; --map-data                This option is handled by emacs.c
  48 ;; -------------------------
  49 ;; -t FILE                   Use FILE as the name of the terminal.
  50 ;; --terminal FILE           Using this implies "-nw" also.
  51 ;;                           This option is handled by emacs.c
  52 ;; -------------------------
  53 ;; -d DISPNAME               Use DISPNAME as the name of the X-windows
  54 ;; -display DISPNAME         display for the initial frame.
  55 ;; --display DISPNAME        This option is handled by emacs.c
  56 ;; -------------------------
  57 ;; -nw                       Do not use a windows system (but use the
  58 ;; --no-windows              terminal instead.)
  59 ;;                           This option is handled by emacs.c
  60 ;; -------------------------
  61 ;; -batch                    Execute noninteractively (messages go to stdout,
  62 ;; --batch                   variable noninteractive set to t)
  63 ;;                           This option is handled by emacs.c
  64 ;; -------------------------
  65 ;; -q                        Do not load user's init file and do not load
  66 ;; -no-init-file             "default.el".  Regardless of this switch,
  67 ;; --no-init-file            "site-start" is still loaded.
  68 ;; -------------------------
  69 ;; -no-site-file             Do not load "site-start.el".  (This is the ONLY
  70 ;; --no-site-file            way to prevent loading that file.)
  71 ;; -------------------------
  72 ;; -u USER                   Load USER's init file instead of the init
  73 ;; -user USER                file belonging to the user starting Emacs.
  74 ;; --user USER
  75 ;; -------------------------
  76 ;; -debug-init               Don't catch errors in init files; let the
  77 ;; --debug-init              debugger run.
  78 ;; -------------------------
  79 ;; -i ICONTYPE               Set type of icon using when Emacs is
  80 ;; -itype ICONTYPE           iconified under X-windows.
  81 ;; --icon-type ICONTYPE      This option is passed on to term/x-win.el
  82 ;;
  83 ;; -iconic                   Start Emacs iconified under X-windows.
  84 ;; --iconic                  This option is passed on to term/x-win.el
  85 ;; -------------------------
  86 ;; Various X-windows options for colors/fonts/geometry/title etc.
  87 ;; These options are passed on to term/x-win.el which see.  Certain
  88 ;; of these are also found in term/pc-win.el
  89 ;; -------------------------
  90 ;; FILE                      Visit FILE.
  91 ;;
  92 ;; -L DIRNAME                Add DIRNAME to load-path
  93 ;; -directory DIRNAME
  94 ;; --directory DIRNAME
  95 ;;
  96 ;; -l FILE                   Load and execute the Emacs lisp code
  97 ;; -load FILE                in FILE.
  98 ;; --load FILE
  99 ;;
 100 ;; -f FUNC                   Execute Emacs lisp function FUNC with
 101 ;; -funcall FUNC             no arguments.  The "-e" form is outdated
 102 ;; --funcall FUNC            and should not be used.  (It's a typo
 103 ;; -e FUNC                   promoted to a feature.)
 104 ;;
 105 ;; -eval FORM                Execute Emacs lisp form FORM.
 106 ;; --eval FORM
 107 ;;
 108 ;; -insert FILE              Insert the contents of FILE into buffer.
 109 ;; --insert FILE
 110 ;; -------------------------
 111 ;; -kill                     Kill (exit) Emacs right away.
 112 ;; --kill
 113 ;; -------------------------
 114
 115 ;;; Code:
 116
 117 (setq top-level '(normal-top-level))
 118
 119 (defvar command-line-processed nil
 120   "Non-nil once command line has been processed")
 121
 122 (defgroup initialization nil
 123   "Emacs start-up procedure"
 124   :group 'internal)
 125
 126 (defcustom inhibit-startup-message nil
 127   "*Non-nil inhibits the initial startup message.
 128 This is for use in your personal init file, once you are familiar
 129 with the contents of the startup message."
 130   :type 'boolean
 131   :group 'initialization)
 132
 133 (defcustom inhibit-startup-echo-area-message nil
 134   "*Non-nil inhibits the initial startup echo area message.
 135 Setting this variable takes effect
 136 only if you do it with the customization buffer
 137 or if your `.emacs' file contains a line of this form:
 138  (setq inhibit-startup-echo-area-message \"YOUR-USER-NAME\")
 139 If your `.emacs' file is byte-compiled, use the following form instead:
 140  (eval '(setq inhibit-startup-echo-area-message \"YOUR-USER-NAME\"))
 141 Thus, someone else using a copy of your `.emacs' file will see
 142 the startup message unless he personally acts to inhibit it."
 143   :type '(choice (const :tag "Don't inhibit")
 144                  (string :tag "Enter your user name, to inhibit"))
 145   :group 'initialization)
 146
 147 (defcustom inhibit-default-init nil
 148   "*Non-nil inhibits loading the `default' library."
 149   :type 'boolean
 150   :group 'initialization)
 151
 152 (defvar command-switch-alist nil
 153   "Alist of command-line switches.
 154 Elements look like (SWITCH-STRING . HANDLER-FUNCTION).
 155 HANDLER-FUNCTION receives switch name as sole arg;
 156 remaining command-line args are in the variable `command-line-args-left'.")
 157
 158 (defvar command-line-args-left nil
 159   "List of command-line args not yet processed.")
 160
 161 (defvar command-line-functions nil    ;; lrs 7/31/89
 162   "List of functions to process unrecognized command-line arguments.
 163 Each function should access the dynamically bound variables
 164 `argi' (the current argument) and `command-line-args-left' (the remaining
 165 arguments).  The function should return non-nil only if it recognizes and
 166 processes `argi'.  If it does so, it may consume successive arguments by
 167 altering `command-line-args-left' to remove them.")
 168
 169 (defvar command-line-default-directory nil
 170   "Default directory to use for command line arguments.
 171 This is normally copied from `default-directory' when Emacs starts.")
 172
 173 ;;; This is here, rather than in x-win.el, so that we can ignore these
 174 ;;; options when we are not using X.
 175 (defvar command-line-x-option-alist
 176   '(("-bw" 1 x-handle-numeric-switch border-width)
 177     ("-d" 1 x-handle-display)
 178     ("-display" 1 x-handle-display)
 179     ("-name" 1 x-handle-name-switch)
 180     ("-title" 1 x-handle-switch title)
 181     ("-T" 1 x-handle-switch title)
 182     ("-r" 0 x-handle-switch reverse t)
 183     ("-rv" 0 x-handle-switch reverse t)
 184     ("-reverse" 0 x-handle-switch reverse t)
 185     ("-reverse-video" 0 x-handle-switch reverse t)
 186     ("-fn" 1 x-handle-switch font)
 187     ("-font" 1 x-handle-switch font)
 188     ("-ib" 1 x-handle-numeric-switch internal-border-width)
 189     ("-g" 1 x-handle-geometry)
 190     ("-geometry" 1 x-handle-geometry)
 191     ("-fg" 1 x-handle-switch foreground-color)
 192     ("-foreground" 1 x-handle-switch foreground-color)
 193     ("-bg" 1 x-handle-switch background-color)
 194     ("-background" 1 x-handle-switch background-color)
 195     ("-ms" 1 x-handle-switch mouse-color)
 196     ("-itype" 0 x-handle-switch icon-type t)
 197     ("-i" 0 x-handle-switch icon-type t)
 198     ("-iconic" 0 x-handle-iconic)
 199     ("-xrm" 1 x-handle-xrm-switch)
 200     ("-cr" 1 x-handle-switch cursor-color)
 201     ("-vb" 0 x-handle-switch vertical-scroll-bars t)
 202     ("-hb" 0 x-handle-switch horizontal-scroll-bars t)
 203     ("-bd" 1 x-handle-switch)
 204     ("--border-width" 1 x-handle-numeric-switch border-width)
 205     ("--display" 1 x-handle-display)
 206     ("--name" 1 x-handle-name-switch)
 207     ("--title" 1 x-handle-switch title)
 208     ("--reverse-video" 0 x-handle-switch reverse t)
 209     ("--font" 1 x-handle-switch font)
 210     ("--internal-border" 1 x-handle-numeric-switch internal-border-width)
 211     ("--geometry" 1 x-handle-geometry)
 212     ("--foreground-color" 1 x-handle-switch foreground-color)
 213     ("--background-color" 1 x-handle-switch background-color)
 214     ("--mouse-color" 1 x-handle-switch mouse-color)
 215     ("--icon-type" 0 x-handle-switch icon-type t)
 216     ("--iconic" 0 x-handle-iconic)
 217     ("--xrm" 1 x-handle-xrm-switch)
 218     ("--cursor-color" 1 x-handle-switch cursor-color)
 219     ("--vertical-scroll-bars" 0 x-handle-switch vertical-scroll-bars t)
 220     ("--border-color" 1 x-handle-switch border-width))
 221   "Alist of X Windows options.
 222 Each element has the form
 223   (NAME NUMARGS HANDLER FRAME-PARAM VALUE)
 224 where NAME is the option name string, NUMARGS is the number of arguments
 225 that the option accepts, HANDLER is a function to call to handle the option.
 226 FRAME-PARAM (optional) is the frame parameter this option specifies,
 227 and VALUE is the value which is given to that frame parameter
 228 \(most options use the argument for this, so VALUE is not present).")
 229
 230 (defvar before-init-hook nil
 231   "Normal hook run after handling urgent options but before loading init files.")
 232
 233 (defvar after-init-hook nil
 234   "Normal hook run after loading the init files, `~/.emacs' and `default.el'.
 235 There is no `condition-case' around the running of these functions;
 236 therefore, if you set `debug-on-error' non-nil in `.emacs',
 237 an error in one of these functions will invoke the debugger.")
 238
 239 (defvar emacs-startup-hook nil
 240   "Normal hook run after loading init files and handling the command line.")
 241
 242 (defvar term-setup-hook nil
 243   "Normal hook run after loading terminal-specific Lisp code.
 244 It also follows `emacs-startup-hook'.  This hook exists for users to set,
 245 so as to override the definitions made by the terminal-specific file.
 246 Emacs never sets this variable itself.")
 247
 248 (defvar keyboard-type nil
 249   "The brand of keyboard you are using.
 250 This variable is used to define
 251 the proper function and keypad keys for use under X.  It is used in a
 252 fashion analogous to the environment variable TERM.")
 253
 254 (defvar window-setup-hook nil
 255   "Normal hook run to initialize window system display.
 256 Emacs runs this hook after processing the command line arguments and loading
 257 the user's init file.")
 258
 259 (defcustom initial-major-mode 'lisp-interaction-mode
 260   "Major mode command symbol to use for the initial *scratch* buffer."
 261   :type 'function
 262   :group 'initialization)
 263
 264 (defcustom init-file-user nil
 265   "Identity of user whose `.emacs' file is or was read.
 266 The value is nil if `-q' or `--no-init-file' was specified,
 267 meaning do not load any init file.
 268
 269 Otherwise, the value may be the null string, meaning use the init file
 270 for the user that originally logged in, or it may be a
 271 string containing a user's name meaning use that person's init file.
 272
 273 In either of the latter cases, `(concat \"~\" init-file-user \"/\")'
 274 evaluates to the name of the directory where the `.emacs' file was
 275 looked for.
 276
 277 Setting `init-file-user' does not prevent Emacs from loading
 278 `site-start.el'.  The only way to do that is to use `--no-site-file'."
 279   :type '(choice (const :tag "none" nil) string)
 280   :group 'initialization)
 281
 282 (defcustom site-run-file "site-start"
 283   "File containing site-wide run-time initializations.
 284 This file is loaded at run-time before `~/.emacs'.  It contains inits
 285 that need to be in place for the entire site, but which, due to their
 286 higher incidence of change, don't make sense to load into emacs'
 287 dumped image.  Thus, the run-time load order is: 1. file described in
 288 this variable, if non-nil; 2. `~/.emacs'; 3. `default.el'.
 289
 290 Don't use the `site-start.el' file for things some users may not like.
 291 Put them in `default.el' instead, so that users can more easily
 292 override them.  Users can prevent loading `default.el' with the `-q'
 293 option or by setting `inhibit-default-init' in their own init files,
 294 but inhibiting `site-start.el' requires `--no-site-file', which
 295 is less convenient."
 296   :type '(choice (const :tag "none" nil) string)
 297   :group 'initialization)
 298
 299 (defconst iso-8859-n-locale-regexp "8859[-_]?\\([1-49]\\)"
 300   "Regexp that specifies when to enable an ISO 8859-N character set.
 301 We do that if this regexp matches the locale name
 302 specified by the LC_ALL, LC_CTYPE and LANG environment variables.
 303 The paren group in the regexp should match the specific character
 304 set number, N.")
 305
 306 (defcustom mail-host-address nil
 307   "*Name of this machine, for purposes of naming users."
 308   :type '(choice (const nil) string)
 309   :group 'mail)
 310
 311 (defcustom user-mail-address nil
 312   "*Full mailing address of this user.
 313 This is initialized based on `mail-host-address',
 314 after your init file is read, in case it sets `mail-host-address'."
 315   :type 'string
 316   :group 'mail)
 317
 318 (defcustom auto-save-list-file-prefix
 319   (if (eq system-type 'ms-dos)
 320       "~/_s"  ; MS-DOS cannot have initial dot, and allows only 8.3 names
 321     "~/.saves-")
 322   "Prefix for generating `auto-save-list-file-name'.
 323 This is used after reading your `.emacs' file to initialize
 324 `auto-save-list-file-name', by appending Emacs's pid and the system name,
 325 if you have not already set `auto-save-list-file-name' yourself.
 326 Set this to nil if you want to prevent `auto-save-list-file-name'
 327 from being initialized."
 328   :type '(choice (const :tag "Don't record a session's auto save list" nil)
 329                  string)
 330   :group 'auto-save)
 331
 332 (defvar locale-translation-file-name
 333   (let ((files '("/usr/lib/X11/locale/locale.alias" ; e.g. X11R6.4
 334                  "/usr/X11R6/lib/X11/locale/locale.alias" ; e.g. RedHat 4.2
 335                  "/usr/openwin/lib/locale/locale.alias" ; e.g. Solaris 2.6
 336                  ;;
 337                  ;; The following name appears after the X-related names above,
 338                  ;; since the X-related names are what X actually uses.
 339                  "/usr/share/locale/locale.alias" ; GNU/Linux sans X
 340                  )))
 341     (while (and files (not (file-exists-p (car files))))
 342       (setq files (cdr files)))
 343     (car files))
 344   "*File name for the system's file of locale-name aliases, or nil if none.")
 345
 346 (defvar init-file-debug nil)
 347
 348 (defvar init-file-had-error nil)
 349
 350 (defvar normal-top-level-add-subdirs-inode-list nil)
 351
 352 (defun normal-top-level-add-subdirs-to-load-path ()
 353   "Add all subdirectories of current directory to `load-path'.
 354 More precisely, this uses only the subdirectories whose names
 355 start with letters or digits; it excludes any subdirectory named `RCS'
 356 or `CVS', and any subdirectory that contains a file named `.nosearch'."
 357   (let (dirs
 358         attrs
 359         (pending (list default-directory)))
 360     ;; This loop does a breadth-first tree walk on DIR's subtree,
 361     ;; putting each subdir into DIRS as its contents are examined.
 362     (while pending
 363       (setq dirs (cons (car pending) dirs))
 364       (setq pending (cdr pending))
 365       (setq attrs (nthcdr 10 (file-attributes (car dirs))))
 366       (let ((contents (directory-files (car dirs)))
 367             (default-directory (car dirs)))
 368         (unless (member attrs normal-top-level-add-subdirs-inode-list)
 369           (setq normal-top-level-add-subdirs-inode-list
 370                 (cons attrs normal-top-level-add-subdirs-inode-list))
 371           (while contents
 372             (unless (member (car contents) '("." ".." "RCS" "CVS"))
 373               (when (and (string-match "\\`[a-zA-Z0-9]" (car contents))
 374                          (file-directory-p (car contents)))
 375                 (let ((expanded (expand-file-name (car contents))))
 376                   (unless (file-exists-p (expand-file-name ".nosearch"
 377                                                            expanded))
 378                     (setq pending (nconc pending (list expanded)))))))
 379             (setq contents (cdr contents))))))
 380     (normal-top-level-add-to-load-path (cdr (nreverse dirs)))))
 381
 382 ;; This function is called from a subdirs.el file.
 383 ;; It assumes that default-directory is the directory
 384 ;; in which the subdirs.el file exists,
 385 ;; and it adds to load-path the subdirs of that directory
 386 ;; as specified in DIRS.  Normally the elements of DIRS are relative.
 387 (defun normal-top-level-add-to-load-path (dirs)
 388   (let ((tail load-path)
 389         (thisdir (directory-file-name default-directory)))
 390     (while (and tail
 391                 (not (equal thisdir (car tail)))
 392                 (not (and (memq system-type '(ms-dos windows-nt))
 393                           (equal (downcase thisdir) (downcase (car tail))))))
 394       (setq tail (cdr tail)))
 395     (setcdr tail (append (mapcar 'expand-file-name dirs) (cdr tail)))))
 396
 397 (defun normal-top-level ()
 398   (if command-line-processed
 399       (message "Back to top level.")
 400     (setq command-line-processed t)
 401     ;; Give *Messages* the same default-directory as *scratch*,
 402     ;; just to keep things predictable.
 403     (let ((dir default-directory))
 404       (save-excursion
 405         (set-buffer (get-buffer "*Messages*"))
 406         (setq default-directory dir)))
 407     ;; For root, preserve owner and group when editing files.
 408     (if (equal (user-uid) 0)
 409         (setq backup-by-copying-when-mismatch t))
 410     ;; Look in each dir in load-path for a subdirs.el file.
 411     ;; If we find one, load it, which will add the appropriate subdirs
 412     ;; of that dir into load-path,
 413     (let ((tail load-path)
 414           new)
 415       (while tail
 416         (setq new (cons (car tail) new))
 417         (let ((default-directory (car tail)))
 418           (load (expand-file-name "subdirs.el" (car tail)) t t t))
 419         (setq tail (cdr tail))))
 420     (if (not (eq system-type 'vax-vms))
 421         (progn
 422           ;; If the PWD environment variable isn't accurate, delete it.
 423           (let ((pwd (getenv "PWD")))
 424             (and (stringp pwd)
 425                  ;; Use FOO/., so that if FOO is a symlink, file-attributes
 426                  ;; describes the directory linked to, not FOO itself.
 427                  (or (equal (file-attributes
 428                              (concat (file-name-as-directory pwd) "."))
 429                             (file-attributes
 430                              (concat (file-name-as-directory default-directory)
 431                                      ".")))
 432                      (setq process-environment
 433                            (delete (concat "PWD=" pwd)
 434                                    process-environment)))))))
 435     (setq default-directory (abbreviate-file-name default-directory))
 436     (let ((menubar-bindings-done nil))
 437       (unwind-protect
 438           (command-line)
 439         ;; Do this again, in case .emacs defined more abbreviations.
 440         (setq default-directory (abbreviate-file-name default-directory))
 441         ;; Specify the file for recording all the auto save files of this session.
 442         ;; This is used by recover-session.
 443         (or auto-save-list-file-name
 444             (and auto-save-list-file-prefix
 445                  (setq auto-save-list-file-name
 446                        ;; Under MS-DOS our PID is almost always reused between
 447                        ;; Emacs invocations.  We need something more unique.
 448                        (if (eq system-type 'ms-dos)
 449                            (concat
 450                             (make-temp-name
 451                              (expand-file-name auto-save-list-file-prefix))
 452                             "~")
 453
 454                          (expand-file-name (format "%s%d-%s~"
 455                                                    auto-save-list-file-prefix
 456                                                    (emacs-pid)
 457                                                    (system-name)))))))
 458         (run-hooks 'emacs-startup-hook)
 459         (and term-setup-hook
 460              (run-hooks 'term-setup-hook))
 461         ;; Modify the initial frame based on what .emacs puts into
 462         ;; ...-frame-alist.
 463         (if (fboundp 'frame-notice-user-settings)
 464             (frame-notice-user-settings))
 465         ;; Now we know the user's default font, so add it to the menu.
 466         (if (fboundp 'font-menu-add-default)
 467             (font-menu-add-default))
 468         (and window-setup-hook
 469              (run-hooks 'window-setup-hook))
 470         (or menubar-bindings-done
 471             (if (memq window-system '(x w32))
 472                 (precompute-menubar-bindings)))))))
 473
 474 ;; Precompute the keyboard equivalents in the menu bar items.
 475 (defun precompute-menubar-bindings ()
 476   (let ((submap (lookup-key global-map [menu-bar])))
 477     (while submap
 478       (and (consp (car submap))
 479            (symbolp (car (car submap)))
 480            (stringp (car-safe (cdr (car submap))))
 481            (keymapp (cdr (cdr (car submap))))
 482            (progn
 483              (x-popup-menu nil (cdr (cdr (car submap))))
 484              (if purify-flag
 485                  (garbage-collect))))
 486       (setq submap (cdr submap))))
 487   (setq define-key-rebound-commands t))
 488
 489 (defun command-line ()
 490   (setq command-line-default-directory default-directory)
 491
 492   ;; Choose a reasonable location for temporary files.
 493   (setq temporary-file-directory
 494         (file-name-as-directory
 495          (cond ((memq system-type '(ms-dos windows-nt))
 496                 (or (getenv "TEMP") (getenv "TMPDIR") (getenv "TMP") "c:/temp"))
 497                ((memq system-type '(vax-vms axp-vms))
 498                 (or (getenv "TMPDIR") (getenv "TMP") (getenv "TEMP") "SYS$SCRATCH:"))
 499                (t
 500                 (or (getenv "TMPDIR") (getenv "TMP") (getenv "TEMP") "/tmp")))))
 501
 502   ;; See if we should import version-control from the environment variable.
 503   (let ((vc (getenv "VERSION_CONTROL")))
 504     (cond ((eq vc nil))                 ;don't do anything if not set
 505           ((or (string= vc "t")
 506                (string= vc "numbered"))
 507            (setq version-control t))
 508           ((or (string= vc "nil")
 509                (string= vc "existing"))
 510            (setq version-control nil))
 511           ((or (string= vc "never")
 512                (string= vc "simple"))
 513            (setq version-control 'never))))
 514
 515   (let ((ctype
 516          ;; Use the first of these three envvars that has a nonempty value.
 517          (or (let ((string (getenv "LC_ALL")))
 518                (and (not (equal string "")) string))
 519              (let ((string (getenv "LC_CTYPE")))
 520                (and (not (equal string "")) string))
 521              (let ((string (getenv "LANG")))
 522                (and (not (equal string "")) string)))))
 523     ;; Translate "swedish" into "sv_SE.ISO-8859-1", and so on,
 524     ;; using the translation file that GNU/Linux systems have.
 525     (and ctype
 526          locale-translation-file-name
 527          (not (string-match iso-8859-n-locale-regexp ctype))
 528          (with-temp-buffer
 529            (insert-file-contents locale-translation-file-name)
 530            (if (re-search-forward
 531                 (concat "^" (regexp-quote ctype) ":?[ \t]+") nil t)
 532                (setq ctype (buffer-substring (point)
 533                                              (progn (end-of-line) (point)))))))
 534     ;; Now see if the locale specifies an ISO 8859 character set.
 535     (when (and ctype
 536                (string-match iso-8859-n-locale-regexp ctype))
 537       (let (charset (which (match-string 1 ctype)))
 538         (if (equal "9" which)
 539             (setq which "5"))
 540         (setq charset (concat "latin-" which))
 541         (when (string-match "latin-[12345]" charset)
 542           ;; Set up for this character set.
 543           ;; This is now the right way to do it
 544           ;; for both unibyte and multibyte modes.
 545           (set-language-environment charset)
 546           (unless (or noninteractive (eq window-system 'x))
 547             ;; Send those codes literally to a non-X terminal.
 548             (when default-enable-multibyte-characters
 549               ;; If this is nil, we are using single-byte characters,
 550               ;; so the terminal coding system is irrelevant.
 551               (set-terminal-coding-system
 552                (intern (downcase charset)))))
 553           (standard-display-european-internal)))))
 554
 555   ;;! This has been commented out; I currently find the behavior when
 556   ;;! split-window-keep-point is nil disturbing, but if I can get used
 557   ;;! to it, then it would be better to eliminate the option.
 558   ;;! ;; Choose a good default value for split-window-keep-point.
 559   ;;! (setq split-window-keep-point (> baud-rate 2400))
 560
 561   ;; Set the default strings to display in mode line for
 562   ;; end-of-line formats that aren't native to this platform.
 563   (cond
 564    ((memq system-type '(ms-dos windows-nt emx))
 565     (setq eol-mnemonic-unix "(Unix)")
 566     (setq eol-mnemonic-mac  "(Mac)"))
 567    ;; Mac-specific settings should come here, once there's a
 568    ;; system-type symbol specific to MacOS.
 569    (t   ; this is for Unix/GNU/Linux systems
 570     (setq eol-mnemonic-dos  "(DOS)")
 571     (setq eol-mnemonic-mac  "(Mac)")))
 572
 573   ;; Read window system's init file if using a window system.
 574   (condition-case error
 575       (if (and window-system (not noninteractive))
 576           (load (concat term-file-prefix
 577                         (symbol-name window-system)
 578                         "-win")
 579                 ;; Every window system should have a startup file;
 580                 ;; barf if we can't find it.
 581                 nil t))
 582     ;; If we can't read it, print the error message and exit.
 583     (error
 584      (princ
 585       (if (eq (car error) 'error)
 586           (apply 'concat (cdr error))
 587         (if (memq 'file-error (get (car error) 'error-conditions))
 588             (format "%s: %s"
 589                      (nth 1 error)
 590                      (mapconcat '(lambda (obj) (prin1-to-string obj t))
 591                                 (cdr (cdr error)) ", "))
 592           (format "%s: %s"
 593                    (get (car error) 'error-message)
 594                    (mapconcat '(lambda (obj) (prin1-to-string obj t))
 595                               (cdr error) ", "))))
 596       'external-debugging-output)
 597      (setq window-system nil)
 598      (kill-emacs)))
 599
 600   (let ((done nil)
 601         (args (cdr command-line-args)))
 602
 603     ;; Figure out which user's init file to load,
 604     ;; either from the environment or from the options.
 605     (setq init-file-user (if noninteractive nil (user-login-name)))
 606     ;; If user has not done su, use current $HOME to find .emacs.
 607     (and init-file-user (string= init-file-user (user-real-login-name))
 608          (setq init-file-user ""))
 609
 610     ;; Process the command-line args, and delete the arguments
 611     ;; processed.  This is consistent with the way main in emacs.c
 612     ;; does things.
 613     (while (and (not done) args)
 614       (let ((longopts '(("--no-init-file") ("--no-site-file") ("--user")
 615                         ("--debug-init") ("--iconic") ("--icon-type")))
 616             (argi (car args))
 617             (argval nil))
 618         ;; Handle --OPTION=VALUE format.
 619         (if (and (string-match "\\`--" argi)
 620                  (string-match "=" argi))
 621             (setq argval (substring argi (match-end 0))
 622                   argi (substring argi 0 (match-beginning 0))))
 623         (or (equal argi "--")
 624             (let ((completion (try-completion argi longopts)))
 625               (if (eq completion t)
 626                   (setq argi (substring argi 1))
 627                 (if (stringp completion)
 628                     (let ((elt (assoc completion longopts)))
 629                       (or elt
 630                           (error "Option `%s' is ambiguous" argi))
 631                       (setq argi (substring (car elt) 1)))
 632                   (setq argval nil)))))
 633         (cond
 634          ((or (string-equal argi "-q")
 635               (string-equal argi "-no-init-file"))
 636           (setq init-file-user nil
 637                 args (cdr args)))
 638          ((or (string-equal argi "-u")
 639               (string-equal argi "-user"))
 640           (or argval
 641               (setq args (cdr args)
 642                     argval (car args)))
 643           (setq init-file-user argval
 644                 argval nil
 645                 args (cdr args)))
 646          ((string-equal argi "-no-site-file")
 647           (setq site-run-file nil
 648                 args (cdr args)))
 649          ((string-equal argi "-debug-init")
 650           (setq init-file-debug t
 651                 args (cdr args)))
 652          ((string-equal argi "-iconic")
 653           (setq initial-frame-alist
 654                 (cons '(visibility . icon) initial-frame-alist))
 655           (setq args (cdr args)))
 656          ((or (string-equal argi "-icon-type")
 657               (string-equal argi "-i")
 658               (string-equal argi "-itype"))
 659           (setq default-frame-alist
 660                 (cons '(icon-type . t) default-frame-alist))
 661           (setq args (cdr args)))
 662          (t (setq done t)))
 663         ;; Was argval set but not used?
 664         (and argval
 665              (error "Option `%s' doesn't allow an argument" argi))))
 666
 667     ;; Re-attach the program name to the front of the arg list.
 668     (and command-line-args (setcdr command-line-args args)))
 669
 670   ;; Under X Windows, this creates the X frame and deletes the terminal frame.
 671   (if (fboundp 'frame-initialize)
 672       (frame-initialize))
 673   ;; If frame was created with a menu bar, set menu-bar-mode on.
 674   (if (or (not (memq window-system '(x w32)))
 675           (> (cdr (assq 'menu-bar-lines (frame-parameters))) 0))
 676       (menu-bar-mode t))
 677
 678   (run-hooks 'before-init-hook)
 679
 680   ;; Run the site-start library if it exists.  The point of this file is
 681   ;; that it is run before .emacs.  There is no point in doing this after
 682   ;; .emacs; that is useless.
 683   (if site-run-file
 684       (load site-run-file t t))
 685
 686   ;; Register available input methods by loading LEIM list file.
 687   (load "leim-list.el" 'noerror 'nomessage 'nosuffix)
 688
 689   ;; Sites should not disable this.  Only individuals should disable
 690   ;; the startup message.
 691   (setq inhibit-startup-message nil)
 692
 693   ;; Load that user's init file, or the default one, or none.
 694   (let (debug-on-error-from-init-file
 695         debug-on-error-should-be-set
 696         (debug-on-error-initial
 697          (if (eq init-file-debug t) 'startup init-file-debug))
 698         (orig-enable-multibyte default-enable-multibyte-characters))
 699     (let ((debug-on-error debug-on-error-initial)
 700           ;; This function actually reads the init files.
 701           (inner
 702            (function
 703             (lambda ()
 704               (if init-file-user
 705                   (progn
 706                     (setq user-init-file
 707                           (cond
 708                            ((eq system-type 'ms-dos)
 709                             (concat "~" init-file-user "/_emacs"))
 710                            ((eq system-type 'windows-nt)
 711                             (if (directory-files "~" nil "^\.emacs\\(\.elc?\\)?$")
 712                                 "~/.emacs"
 713                               "~/_emacs"))
 714                            ((eq system-type 'vax-vms)
 715                             "sys$login:.emacs")
 716                            (t
 717                             (concat "~" init-file-user "/.emacs"))))
 718                     (load user-init-file t t)
 719                     (or inhibit-default-init
 720                         (let ((inhibit-startup-message nil))
 721                           ;; Users are supposed to be told their rights.
 722                           ;; (Plus how to get help and how to undo.)
 723                           ;; Don't you dare turn this off for anyone
 724                           ;; except yourself.
 725                           (load "default" t t)))))))))
 726       (if init-file-debug
 727           ;; Do this without a condition-case if the user wants to debug.
 728           (funcall inner)
 729         (condition-case error
 730             (progn
 731               (funcall inner)
 732               (setq init-file-had-error nil))
 733           (error (message "Error in init file: %s%s%s"
 734                           (get (car error) 'error-message)
 735                           (if (cdr error) ": " "")
 736                           (mapconcat 'prin1-to-string (cdr error) ", "))
 737                  (setq init-file-had-error t))))
 738       ;; If we can tell that the init file altered debug-on-error,
 739       ;; arrange to preserve the value that it set up.
 740       (or (eq debug-on-error debug-on-error-initial)
 741           (setq debug-on-error-should-be-set t
 742                 debug-on-error-from-init-file debug-on-error)))
 743     (if debug-on-error-should-be-set
 744         (setq debug-on-error debug-on-error-from-init-file))
 745     (unless (or default-enable-multibyte-characters
 746                 (eq orig-enable-multibyte default-enable-multibyte-characters))
 747       ;; Init file changed to unibyte.  Reset existing multibyte
 748       ;; buffers (probably *scratch*, *Messages*, *Minibuff-0*).
 749       ;; Arguably this should only be done if they're free of
 750       ;; multibyte characters.
 751       (mapcar (lambda (buffer)
 752                 (with-current-buffer buffer
 753                   (if enable-multibyte-characters
 754                       (set-buffer-multibyte nil))))
 755               (buffer-list))
 756       ;; Also re-set the language environment in case it was
 757       ;; originally done before unibyte was set and is sensitive to
 758       ;; unibyte (display table, terminal coding system &c).
 759       (set-language-environment current-language-environment)))
 760
 761   ;; Do this here in case the init file sets mail-host-address.
 762   (or user-mail-address
 763       (setq user-mail-address (concat (user-login-name) "@"
 764                                       (or mail-host-address
 765                                           (system-name)))))
 766
 767   (run-hooks 'after-init-hook)
 768
 769   ;; If *scratch* exists and init file didn't change its mode, initialize it.
 770   (if (get-buffer "*scratch*")
 771       (save-excursion
 772         (set-buffer "*scratch*")
 773         (if (eq major-mode 'fundamental-mode)
 774             (funcall initial-major-mode))))
 775   ;; Load library for our terminal type.
 776   ;; User init file can set term-file-prefix to nil to prevent this.
 777   (and term-file-prefix (not noninteractive) (not window-system)
 778        (let ((term (getenv "TERM"))
 779              hyphend)
 780          (while (and term
 781                      (not (load (concat term-file-prefix term) t t)))
 782            ;; Strip off last hyphen and what follows, then try again
 783            (if (setq hyphend (string-match "[-_][^-_]+$" term))
 784                (setq term (substring term 0 hyphend))
 785              (setq term nil)))))
 786
 787   ;; Process the remaining args.
 788   (command-line-1 (cdr command-line-args))
 789
 790   ;; If -batch, terminate after processing the command options.
 791   (if noninteractive (kill-emacs t)))
 792
 793 (defcustom initial-scratch-message "\
 794 This buffer is for notes you don't want to save, and for Lisp evaluation.
 795 If you want to create a file, visit that file with C-x C-f,
 796 then enter the text in that file's own buffer.
 797
 798 "
 799   "Initial message displayed in *scratch* buffer at startup.
 800 If this is nil, no message will be displayed."
 801   :type 'string)
 802
 803 (defun command-line-1 (command-line-args-left)
 804   (or noninteractive (input-pending-p) init-file-had-error
 805       (and inhibit-startup-echo-area-message
 806            user-init-file
 807            (or (and (get 'inhibit-startup-echo-area-message 'saved-value)
 808                     (equal inhibit-startup-echo-area-message
 809                            (if (string= init-file-user "")
 810                                (user-login-name)
 811                              init-file-user)))
 812                ;; Wasn't set with custom; see if .emacs has a setq.
 813                (let ((buffer (get-buffer-create " *temp*")))
 814                  (prog1
 815                      (condition-case nil
 816                          (save-excursion
 817                            (set-buffer buffer)
 818                            (insert-file-contents user-init-file)
 819                            (re-search-forward
 820                             (concat
 821                              "([ \t\n]*setq[ \t\n]+"
 822                              "inhibit-startup-echo-area-message[ \t\n]+"
 823                              (regexp-quote
 824                               (prin1-to-string
 825                                (if (string= init-file-user "")
 826                                    (user-login-name)
 827                                  init-file-user)))
 828                              "[ \t\n]*)")
 829                             nil t))
 830                        (error nil))
 831                    (kill-buffer buffer)))))
 832       (message (if (eq (key-binding "\C-h\C-p") 'describe-project)
 833                    "For information about the GNU Project and its goals, type C-h C-p."
 834                  (substitute-command-keys
 835                   "For information about the GNU Project and its goals, type \\[describe-project]."))))
 836   (if (null command-line-args-left)
 837       (cond ((and (not inhibit-startup-message) (not noninteractive)
 838                   ;; Don't clobber a non-scratch buffer if init file
 839                   ;; has selected it.
 840                   (string= (buffer-name) "*scratch*"))
 841              ;; If there are no switches to process, we might as well
 842              ;; run this hook now, and there may be some need to do it
 843              ;; before doing any output.
 844              (and term-setup-hook
 845                   (run-hooks 'term-setup-hook))
 846              ;; Don't let the hook be run twice.
 847              (setq term-setup-hook nil)
 848
 849              ;; It's important to notice the user settings before we
 850              ;; display the startup message; otherwise, the settings
 851              ;; won't take effect until the user gives the first
 852              ;; keystroke, and that's distracting.
 853              (if (fboundp 'frame-notice-user-settings)
 854                  (frame-notice-user-settings))
 855
 856              (and window-setup-hook
 857                   (run-hooks 'window-setup-hook))
 858              (setq window-setup-hook nil)
 859              ;; Do this now to avoid an annoying delay if the user
 860              ;; clicks the menu bar during the sit-for.
 861              (if (memq window-system '(x w32))
 862                  (precompute-menubar-bindings))
 863              (setq menubar-bindings-done t)
 864              (when (= (buffer-size) 0)
 865                (let ((buffer-undo-list t))
 866                  (unwind-protect
 867                      (when (not (input-pending-p))
 868                        (goto-char (point-max))
 869                        ;; The convention for this piece of code is that
 870                        ;; each piece of output starts with one or two newlines
 871                        ;; and does not end with any newlines.
 872                        (insert "Welcome to GNU Emacs")
 873                        (if (eq system-type 'gnu/linux)
 874                            (insert ", one component of a Linux-based GNU system."))
 875                        (insert "\n")
 876                        (if (assq 'display (frame-parameters))
 877                            (progn
 878                              (insert "\
 879 The menu bar and scroll bar are sufficient for basic editing with the mouse.
 880
 881 Useful Files menu items:
 882 Exit Emacs              (or type Control-x followed by Control-c)
 883 Recover Session         recover files you were editing before a crash
 884
 885 Important Help menu items:
 886 Emacs Tutorial          Learn-by-doing tutorial for using Emacs efficiently.
 887 \(Non)Warranty          GNU Emacs comes with ABSOLUTELY NO WARRANTY
 888 Copying Conditions      Conditions for redistributing and changing Emacs.
 889 Getting New Versions    How to obtain the latest version of Emacs.
 890 ")
 891                              (insert "\n\n" (emacs-version)
 892                                      "
 893 Copyright (C) 1999 Free Software Foundation, Inc."))
 894                          ;; If keys have their default meanings,
 895                          ;; use precomputed string to save lots of time.
 896                          (if (and (eq (key-binding "\C-h") 'help-command)
 897                                   (eq (key-binding "\C-xu") 'advertised-undo)
 898                                   (eq (key-binding "\C-x\C-c") 'save-buffers-kill-emacs)
 899                                   (eq (key-binding "\C-ht") 'help-with-tutorial)
 900                                   (eq (key-binding "\C-hi") 'info)
 901                                   (eq (key-binding "\C-h\C-n") 'view-emacs-news))
 902                              (insert "
 903 Get help           C-h  (Hold down CTRL and press h)
 904 Undo changes       C-x u       Exit Emacs               C-x C-c
 905 Get a tutorial     C-h t       Use Info to read docs    C-h i")
 906                            (insert (substitute-command-keys
 907                                     (format "\n
 908 Get help           %s
 909 Undo changes       \\[advertised-undo]
 910 Exit Emacs         \\[save-buffers-kill-emacs]
 911 Get a tutorial     \\[help-with-tutorial]
 912 Use Info to read docs   \\[info]"
 913                                             (let ((where (where-is-internal
 914                                                           'help-command nil t)))
 915                                               (if where
 916                                                   (key-description where)
 917                                                 "M-x help"))))))
 918                          ;; Say how to use the menu bar
 919                          ;; if that is not with the mouse.
 920                          (if (and (eq (key-binding "\M-`") 'tmm-menubar)
 921                                   (eq (key-binding [f10]) 'tmm-menubar))
 922                              (insert "
 923 Activate menubar   F10  or  ESC `  or   M-`")
 924                            (insert (substitute-command-keys "
 925 Activate menubar     \\[tmm-menubar]")))
 926
 927                        ;; Windows and MSDOS (currently) do not count as
 928                        ;; window systems, but do have mouse support.
 929                          (if window-system
 930                              (insert "
 931 Mode-specific menu   C-mouse-3 (third button, with CTRL)"))
 932                          ;; Many users seem to have problems with these.
 933                          (insert "
 934 \(`C-' means use the CTRL key.  `M-' means use the Meta (or Alt) key.
 935 If you have no Meta key, you may instead type ESC followed by the character.)")
 936                          (and auto-save-list-file-prefix
 937                               (directory-files
 938                                (file-name-directory auto-save-list-file-prefix)
 939                                nil
 940                                (concat "\\`"
 941                                        (regexp-quote (file-name-nondirectory
 942                                                       auto-save-list-file-prefix)))
 943                                t)
 944                               (insert "\n\nIf an Emacs session crashed recently, "
 945                                       "type M-x recover-session RET\nto recover"
 946                                       " the files you were editing."))
 947
 948                          (insert "\n\n" (emacs-version)
 949                                  "
 950 Copyright (C) 1999 Free Software Foundation, Inc.")
 951                          (if (and (eq (key-binding "\C-h\C-c") 'describe-copying)
 952                                   (eq (key-binding "\C-h\C-d") 'describe-distribution)
 953                                   (eq (key-binding "\C-h\C-w") 'describe-no-warranty))
 954                              (insert
 955                               "\n
 956 GNU Emacs comes with ABSOLUTELY NO WARRANTY; type C-h C-w for full details.
 957 You may give out copies of Emacs; type C-h C-c to see the conditions.
 958 Type C-h C-d for information on getting the latest version.")
 959                            (insert (substitute-command-keys
 960                                     "\n
 961 GNU Emacs comes with ABSOLUTELY NO WARRANTY; type \\[describe-no-warranty] for full details.
 962 You may give out copies of Emacs; type \\[describe-copying] to see the conditions.
 963 Type \\[describe-distribution] for information on getting the latest version."))))
 964                        (goto-char (point-min))
 965
 966                        (set-buffer-modified-p nil)
 967                        (sit-for 120))
 968                    (with-current-buffer (get-buffer "*scratch*")
 969                      (erase-buffer)
 970                      (and initial-scratch-message
 971                           (insert initial-scratch-message))
 972                      (set-buffer-modified-p nil)))))))
 973     ;; Delay 2 seconds after the init file error message
 974     ;; was displayed, so user can read it.
 975     (if init-file-had-error
 976         (sit-for 2))
 977     (let ((dir command-line-default-directory)
 978           (file-count 0)
 979           first-file-buffer
 980           tem
 981           just-files  ;; t if this follows the magic -- option.
 982           ;; This includes our standard options' long versions
 983           ;; and long versions of what's on command-switch-alist.
 984           (longopts
 985            (append '(("--funcall") ("--load") ("--insert") ("--kill")
 986                      ("--directory") ("--eval") ("--find-file") ("--visit"))
 987                    (mapcar '(lambda (elt)
 988                               (list (concat "-" (car elt))))
 989                            command-switch-alist)))
 990           (line 0))
 991
 992       ;; Add the long X options to longopts.
 993       (setq tem command-line-x-option-alist)
 994       (while tem
 995         (if (string-match "^--" (car (car tem)))
 996             (setq longopts (cons (list (car (car tem))) longopts)))
 997         (setq tem (cdr tem)))
 998
 999       ;; Loop, processing options.
1000       (while (and command-line-args-left)
1001         (let* ((argi (car command-line-args-left))
1002                (orig-argi argi)
1003                argval completion
1004                ;; List of directories specified in -L/--directory,
1005                ;; in reverse of the order specified.
1006                extra-load-path
1007                (initial-load-path load-path))
1008           (setq command-line-args-left (cdr command-line-args-left))
1009
1010           ;; Do preliminary decoding of the option.
1011           (if just-files
1012               ;; After --, don't look for options; treat all args as files.
1013               (setq argi "")
1014             ;; Convert long options to ordinary options
1015             ;; and separate out an attached option argument into argval.
1016             (if (string-match "^--[^=]*=" argi)
1017                 (setq argval (substring argi (match-end 0))
1018                       argi (substring argi 0 (1- (match-end 0)))))
1019             (if (equal argi "--")
1020                 (setq completion nil)
1021               (setq completion (try-completion argi longopts)))
1022             (if (eq completion t)
1023                 (setq argi (substring argi 1))
1024               (if (stringp completion)
1025                   (let ((elt (assoc completion longopts)))
1026                     (or elt
1027                         (error "Option `%s' is ambiguous" argi))
1028                     (setq argi (substring (car elt) 1)))
1029                 (setq argval nil argi orig-argi))))
1030
1031           ;; Execute the option.
1032           (cond ((setq tem (assoc argi command-switch-alist))
1033                  (if argval
1034                      (let ((command-line-args-left
1035                             (cons argval command-line-args-left)))
1036                        (funcall (cdr tem) argi))
1037                    (funcall (cdr tem) argi)))
1038                 ((or (string-equal argi "-f")  ;what the manual claims
1039                      (string-equal argi "-funcall")
1040                      (string-equal argi "-e")) ; what the source used to say
1041                  (if argval
1042                      (setq tem (intern argval))
1043                    (setq tem (intern (car command-line-args-left)))
1044                    (setq command-line-args-left (cdr command-line-args-left)))
1045                  (if (arrayp (symbol-function tem))
1046                      (command-execute tem)
1047                    (funcall tem)))
1048                 ((string-equal argi "-eval")
1049                  (if argval
1050                      (setq tem argval)
1051                    (setq tem (car command-line-args-left))
1052                    (setq command-line-args-left (cdr command-line-args-left)))
1053                  (eval (read tem)))
1054                 ;; Set the default directory as specified in -L.
1055                 ((or (string-equal argi "-L")
1056                      (string-equal argi "-directory"))
1057                  (if argval
1058                      (setq tem argval)
1059                    (setq tem (car command-line-args-left)
1060                          command-line-args-left (cdr command-line-args-left)))
1061                  (setq tem (command-line-normalize-file-name tem))
1062                  (setq extra-load-path
1063                        (cons (expand-file-name tem) extra-load-path))
1064                  (setq load-path (append (nreverse extra-load-path)
1065                                          initial-load-path)))
1066                 ((or (string-equal argi "-l")
1067                      (string-equal argi "-load"))
1068                  (if argval
1069                      (setq tem argval)
1070                    (setq tem (car command-line-args-left)
1071                          command-line-args-left (cdr command-line-args-left)))
1072                  (let ((file (command-line-normalize-file-name tem)))
1073                    ;; Take file from default dir if it exists there;
1074                    ;; otherwise let `load' search for it.
1075                    (if (file-exists-p (expand-file-name file))
1076                        (setq file (expand-file-name file)))
1077                    (load file nil t)))
1078                 ((string-equal argi "-insert")
1079                  (if argval
1080                      (setq tem argval)
1081                    (setq tem (car command-line-args-left)
1082                          command-line-args-left (cdr command-line-args-left)))
1083                  (or (stringp tem)
1084                      (error "File name omitted from `-insert' option"))
1085                  (insert-file-contents (command-line-normalize-file-name tem)))
1086                 ((string-equal argi "-kill")
1087                  (kill-emacs t))
1088                 ((string-match "^\\+[0-9]+\\'" argi)
1089                  (setq line (string-to-int argi)))
1090                 ((setq tem (assoc argi command-line-x-option-alist))
1091                  ;; Ignore X-windows options and their args if not using X.
1092                  (setq command-line-args-left
1093                        (nthcdr (nth 1 tem) command-line-args-left)))
1094                 ((or (string-equal argi "-find-file")
1095                      (string-equal argi "-visit"))
1096                  ;; An explicit option to specify visiting a file.
1097                  (setq file-count (1+ file-count))
1098                  (let ((file
1099                         (expand-file-name
1100                          (command-line-normalize-file-name orig-argi)
1101                          dir)))
1102                    (if (= file-count 1)
1103                        (setq first-file-buffer (find-file file))
1104                      (find-file-other-window file)))
1105                  (or (zerop line)
1106                      (goto-line line))
1107                  (setq line 0))
1108                 ((equal argi "--")
1109                  (setq just-files t))
1110                 (t
1111                  ;; We have almost exhausted our options. See if the
1112                  ;; user has made any other command-line options available
1113                  (let ((hooks command-line-functions);; lrs 7/31/89
1114                        (did-hook nil))
1115                    (while (and hooks
1116                                (not (setq did-hook (funcall (car hooks)))))
1117                      (setq hooks (cdr hooks)))
1118                    (if (not did-hook)
1119                        ;; Ok, presume that the argument is a file name
1120                        (progn
1121                          (if (string-match "\\`-" argi)
1122                              (error "Unknown option `%s'" argi))
1123                          (setq file-count (1+ file-count))
1124                          (let ((file
1125                                 (expand-file-name
1126                                  (command-line-normalize-file-name orig-argi)
1127                                  dir)))
1128                            (if (= file-count 1)
1129                                (setq first-file-buffer (find-file file))
1130                              (find-file-other-window file)))
1131                          (or (zerop line)
1132                              (goto-line line))
1133                          (setq line 0))))))))
1134       ;; If 3 or more files visited, and not all visible,
1135       ;; show user what they all are.
1136       (and (> file-count 2)
1137            (not noninteractive)
1138            (or (get-buffer-window first-file-buffer)
1139                (progn (other-window 1)
1140                       (buffer-menu)))))))
1141
1142 (defun command-line-normalize-file-name (file)
1143   "Collapse multiple slashes to one, to handle non-Emacs file names."
1144   (save-match-data
1145     ;; Use arg 1 so that we don't collapse // at the start of the file name.
1146     ;; That is significant on some systems.
1147     ;; However, /// at the beginning is supposed to mean just /, not //.
1148     (if (string-match "^///+" file)
1149         (setq file (replace-match "/" t t file)))
1150     (while (string-match "//+" file 1)
1151       (setq file (replace-match "/" t t file)))
1152     file))
1153
1154 ;;; startup.el ends here