code.delx.au - gnu-emacs/blob - lisp/faces.el

   1 ;;; faces.el --- Lisp faces
   2
   3 ;; Copyright (C) 1992, 1993, 1994, 1995, 1996, 1998, 1999, 2000
   4 ;;   Free Software Foundation, Inc.
   5
   6 ;; This file is part of GNU Emacs.
   7
   8 ;; GNU Emacs is free software; you can redistribute it and/or modify
   9 ;; it under the terms of the GNU General Public License as published by
  10 ;; the Free Software Foundation; either version 2, or (at your option)
  11 ;; any later version.
  12
  13 ;; GNU Emacs is distributed in the hope that it will be useful,
  14 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 ;; GNU General Public License for more details.
  17
  18 ;; You should have received a copy of the GNU General Public License
  19 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  20 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  21 ;; Boston, MA 02111-1307, USA.
  22
  23 ;;; Commentary:
  24
  25 ;;; Code:
  26
  27 (eval-when-compile
  28   (require 'cl)
  29   ;; Warning suppression -- can't require x-win in batch:
  30   (autoload 'xw-defined-colors "x-win"))
  31
  32 (require 'cus-face)
  33
  34 \f
  35 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  36 ;;; Font selection.
  37 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  38
  39 (defgroup font-selection nil
  40   "Influencing face font selection."
  41   :group 'faces)
  42
  43
  44 (defcustom face-font-selection-order
  45   '(:width :height :weight :slant)
  46   "*A list specifying how face font selection chooses fonts.
  47 Each of the four symbols `:width', `:height', `:weight', and `:slant'
  48 must appear once in the list, and the list must not contain any other
  49 elements.  Font selection tries to find a best matching font for
  50 those face attributes first that appear first in the list.  For
  51 example, if `:slant' appears before `:height', font selection first
  52 tries to find a font with a suitable slant, even if this results in
  53 a font height that isn't optimal."
  54   :tag "Font selection order."
  55   :type '(list symbol symbol symbol symbol)
  56   :group 'font-selection
  57   :set #'(lambda (symbol value)
  58            (set-default symbol value)
  59            (internal-set-font-selection-order value)))
  60
  61 ;; This is defined originally in {w32,x}faces.c.
  62 (defcustom face-font-family-alternatives
  63   '(("courier" "fixed")
  64     ("helv" "helvetica" "arial" "fixed"))
  65   "*Alist of alternative font family names.
  66 Each element has the the form (FAMILY ALTERNATIVE1 ALTERNATIVE2 ...).
  67 If fonts of family FAMILY can't be loaded, try ALTERNATIVE1, then
  68 ALTERNATIVE2 etc."
  69   :tag "Alternative font families to try."
  70   :type '(repeat (repeat string))
  71   :group 'font-selection
  72   :set #'(lambda (symbol value)
  73            (set-default symbol value)
  74            (internal-set-alternative-font-family-alist value)))
  75
  76
  77 \f
  78 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  79 ;;; Creation, copying.
  80 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  81
  82
  83 (defun face-list ()
  84   "Return a list of all defined face names."
  85   (mapcar #'car face-new-frame-defaults))
  86
  87
  88 ;;; ### If not frame-local initialize by what X resources?
  89
  90 (defun make-face (face &optional no-init-from-resources)
  91   "Define a new face with name FACE, a symbol.
  92 NO-INIT-FROM-RESOURCES non-nil means don't initialize frame-local
  93 variants of FACE from X resources.  (X resources recognized are found
  94 in the global variable `face-x-resources'.)  If FACE is already known
  95 as a face, leave it unmodified.  Value is FACE."
  96   (interactive "SMake face: ")
  97   (unless (facep face)
  98     ;; Make frame-local faces (this also makes the global one).
  99     (dolist (frame (frame-list))
 100       (internal-make-lisp-face face frame))
 101     ;; Add the face to the face menu.
 102     (when (fboundp 'facemenu-add-new-face)
 103       (facemenu-add-new-face face))
 104     ;; Define frame-local faces for all frames from X resources.
 105     (unless no-init-from-resources
 106       (make-face-x-resource-internal face)))
 107   face)
 108
 109
 110 (defun make-empty-face (face)
 111   "Define a new, empty face with name FACE.
 112 If the face already exists, it is left unmodified.  Value is FACE."
 113   (interactive "SMake empty face: ")
 114   (make-face face 'no-init-from-resources))
 115
 116
 117 (defun copy-face (old-face new-face &optional frame new-frame)
 118   "Define a face just like OLD-FACE, with name NEW-FACE.
 119
 120 If NEW-FACE already exists as a face, it is modified to be like
 121 OLD-FACE.  If it doesn't already exist, it is created.
 122
 123 If the optional argument FRAME is given as a frame,  NEW-FACE is
 124 changed on FRAME only.
 125 If FRAME is t, the frame-independent default specification for OLD-FACE
 126 is copied to NEW-FACE.
 127 If FRAME is nil, copying is done for the frame-independent defaults
 128 and for each existing frame.
 129
 130 If the optional fourth argument NEW-FRAME is given,
 131 copy the information from face OLD-FACE on frame FRAME
 132 to NEW-FACE on frame NEW-FRAME."
 133   (let ((inhibit-quit t))
 134     (if (null frame)
 135         (progn
 136           (dolist (frame (frame-list))
 137             (copy-face old-face new-face frame))
 138           (copy-face old-face new-face t))
 139       (internal-copy-lisp-face old-face new-face frame new-frame))
 140     new-face))
 141
 142
 143 \f
 144 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 145 ;;; Obsolete functions
 146 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 147
 148 ;; The functions in this section are defined because Lisp packages use
 149 ;; them, despite the prefix `internal-' suggesting that they are
 150 ;; private to the face implementation.
 151
 152 (defun internal-find-face (name &optional frame)
 153   "Retrieve the face named NAME.
 154 Return nil if there is no such face.
 155 If the optional argument FRAME is given, this gets the face NAME for
 156 that frame; otherwise, it uses the selected frame.
 157 If FRAME is the symbol t, then the global, non-frame face is returned.
 158 If NAME is already a face, it is simply returned.
 159
 160 This function is defined for compatibility with Emacs 20.2.  It
 161 should not be used anymore."
 162   (facep name))
 163 (make-obsolete 'internal-find-face 'facep "21.1")
 164
 165
 166 (defun internal-get-face (name &optional frame)
 167   "Retrieve the face named NAME; error if there is none.
 168 If the optional argument FRAME is given, this gets the face NAME for
 169 that frame; otherwise, it uses the selected frame.
 170 If FRAME is the symbol t, then the global, non-frame face is returned.
 171 If NAME is already a face, it is simply returned.
 172
 173 This function is defined for compatibility with Emacs 20.2.  It
 174 should not be used anymore."
 175   (or (internal-find-face name frame)
 176       (check-face name)))
 177 (make-obsolete 'internal-get-face "See `facep' and `check-face'." "21.1")
 178
 179 \f
 180 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 181 ;;; Predicates, type checks.
 182 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 183
 184 (defun facep (face)
 185   "Return non-nil if FACE is a face name."
 186   (internal-lisp-face-p face))
 187
 188
 189 (defun check-face (face)
 190   "Signal an error if FACE doesn't name a face.
 191 Value is FACE."
 192   (unless (facep face)
 193     (error "Not a face: %s" face))
 194   face)
 195
 196
 197 ;; The ID returned is not to be confused with the internally used IDs
 198 ;; of realized faces.  The ID assigned to Lisp faces is used to
 199 ;; support faces in display table entries.
 200
 201 (defun face-id (face &optional frame)
 202   "Return the interNal ID of face with name FACE.
 203 If optional argument FRAME is nil or omitted, use the selected frame."
 204   (check-face face)
 205   (get face 'face))
 206
 207
 208 (defun face-equal (face1 face2 &optional frame)
 209   "Non-nil if faces FACE1 and FACE2 are equal.
 210 Faces are considered equal if all their attributes are equal.
 211 If the optional argument FRAME is given, report on face FACE in that frame.
 212 If FRAME is t, report on the defaults for face FACE (for new frames).
 213 If FRAME is omitted or nil, use the selected frame."
 214   (internal-lisp-face-equal-p face1 face2 frame))
 215
 216
 217 (defun face-differs-from-default-p (face &optional frame)
 218   "Non-nil if FACE displays differently from the default face.
 219 If the optional argument FRAME is given, report on face FACE in that frame.
 220 If FRAME is t, report on the defaults for face FACE (for new frames).
 221 If FRAME is omitted or nil, use the selected frame.
 222 A face is considered to be ``the same'' as the default face if it is
 223 actually specified in the same way (equal attributes) or if it is
 224 fully-unspecified, and thus inherits the attributes of any face it
 225 is displayed on top of."
 226   (cond ((eq frame t) (setq frame nil))
 227         ((null frame) (setq frame (selected-frame))))
 228   (let* ((v1 (internal-lisp-face-p face frame))
 229          (n (if v1 (length v1) 0))
 230          (v2 (internal-lisp-face-p 'default frame))
 231          (i 1))
 232     (unless v1
 233       (error "Not a face: %S" face))
 234     (while (and (< i n)
 235                 (or (eq 'unspecified (aref v1 i))
 236                     (equal (aref v1 i) (aref v2 i))))
 237       (setq i (1+ i)))
 238     (< i n)))
 239
 240
 241 (defun face-nontrivial-p (face &optional frame)
 242   "True if face FACE has some non-nil attribute.
 243 If the optional argument FRAME is given, report on face FACE in that frame.
 244 If FRAME is t, report on the defaults for face FACE (for new frames).
 245 If FRAME is omitted or nil, use the selected frame."
 246   (not (internal-lisp-face-empty-p face frame)))
 247
 248
 249 \f
 250 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 251 ;;; Setting face attributes from X resources.
 252 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 253
 254 (defcustom face-x-resources
 255   '((:family (".attributeFamily" . "Face.AttributeFamily"))
 256     (:width (".attributeWidth" . "Face.AttributeWidth"))
 257     (:height (".attributeHeight" . "Face.AttributeHeight"))
 258     (:weight (".attributeWeight" . "Face.AttributeWeight"))
 259     (:slant (".attributeSlant" . "Face.AttributeSlant"))
 260     (:foreground (".attributeForeground" . "Face.AttributeForeground"))
 261     (:background (".attributeBackground" . "Face.AttributeBackground"))
 262     (:overline (".attributeOverline" . "Face.AttributeOverline"))
 263     (:strike-through (".attributeStrikeThrough" . "Face.AttributeStrikeThrough"))
 264     (:box (".attributeBox" . "Face.AttributeBox"))
 265     (:underline (".attributeUnderline" . "Face.AttributeUnderline"))
 266     (:inverse-video (".attributeInverse" . "Face.AttributeInverse"))
 267     (:stipple
 268      (".attributeStipple" . "Face.AttributeStipple")
 269      (".attributeBackgroundPixmap" . "Face.AttributeBackgroundPixmap"))
 270     (:bold (".attributeBold" . "Face.AttributeBold"))
 271     (:italic (".attributeItalic" . "Face.AttributeItalic"))
 272     (:font (".attributeFont" . "Face.AttributeFont"))
 273     (:inherit (".attributeInherit" . "Face.AttributeInherit")))
 274   "*List of X resources and classes for face attributes.
 275 Each element has the form (ATTRIBUTE ENTRY1 ENTRY2...) where ATTRIBUTE is
 276 the name of a face attribute, and each ENTRY is a cons of the form
 277 (RESOURCE . CLASS) with RESOURCE being the resource and CLASS being the
 278 X resource class for the attribute."
 279   :type '(repeat (cons symbol (repeat (cons string string))))
 280   :group 'faces)
 281
 282
 283 (defun set-face-attribute-from-resource (face attribute resource class frame)
 284   "Set FACE's ATTRIBUTE from X resource RESOURCE, class CLASS on FRAME.
 285 Value is the attribute value specified by the resource, or nil
 286 if not present.  This function displays a message if the resource
 287 specifies an invalid attribute."
 288   (let* ((face-name (face-name face))
 289          (value (internal-face-x-get-resource (concat face-name resource)
 290                                               class frame)))
 291     (when value
 292       (condition-case ()
 293           (internal-set-lisp-face-attribute-from-resource
 294            face attribute (downcase value) frame)
 295         (error
 296          (message "Face %s, frame %s: invalid attribute %s %s from X resource"
 297                   face-name frame attribute value))))
 298     value))
 299
 300
 301 (defun set-face-attributes-from-resources (face frame)
 302   "Set attributes of FACE from X resources for FRAME."
 303   (when (memq (framep frame) '(x w32))
 304     (dolist (definition face-x-resources)
 305       (let ((attribute (car definition)))
 306         (dolist (entry (cdr definition))
 307           (set-face-attribute-from-resource face attribute (car entry)
 308                                             (cdr entry) frame))))))
 309
 310
 311 (defun make-face-x-resource-internal (face &optional frame)
 312   "Fill frame-local FACE on FRAME from X resources.
 313 FRAME nil or not specified means do it for all frames."
 314   (if (null frame)
 315       (dolist (frame (frame-list))
 316         (set-face-attributes-from-resources face frame))
 317     (set-face-attributes-from-resources face frame)))
 318
 319
 320 \f
 321 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 322 ;;; Retrieving face attributes.
 323 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 324
 325 (defun face-name (face)
 326   "Return the name of face FACE."
 327   (symbol-name (check-face face)))
 328
 329
 330 (defun face-attribute (face attribute &optional frame)
 331   "Return the value of FACE's ATTRIBUTE on FRAME.
 332 If the optional argument FRAME is given, report on face FACE in that frame.
 333 If FRAME is t, report on the defaults for face FACE (for new frames).
 334 If FRAME is omitted or nil, use the selected frame."
 335   (internal-get-lisp-face-attribute face attribute frame))
 336
 337
 338 (defun face-foreground (face &optional frame)
 339   "Return the foreground color name of FACE, or nil if unspecified.
 340 If the optional argument FRAME is given, report on face FACE in that frame.
 341 If FRAME is t, report on the defaults for face FACE (for new frames).
 342 If FRAME is omitted or nil, use the selected frame."
 343   (internal-get-lisp-face-attribute face :foreground frame))
 344
 345
 346 (defun face-background (face &optional frame)
 347   "Return the background color name of FACE, or nil if unspecified.
 348 If the optional argument FRAME is given, report on face FACE in that frame.
 349 If FRAME is t, report on the defaults for face FACE (for new frames).
 350 If FRAME is omitted or nil, use the selected frame."
 351   (internal-get-lisp-face-attribute face :background frame))
 352
 353
 354 (defun face-stipple (face &optional frame)
 355  "Return the stipple pixmap name of FACE, or nil if unspecified.
 356 If the optional argument FRAME is given, report on face FACE in that frame.
 357 If FRAME is t, report on the defaults for face FACE (for new frames).
 358 If FRAME is omitted or nil, use the selected frame."
 359   (internal-get-lisp-face-attribute face :stipple frame))
 360
 361
 362 (defalias 'face-background-pixmap 'face-stipple)
 363
 364
 365 (defun face-underline-p (face &optional frame)
 366  "Return non-nil if FACE is underlined.
 367 If the optional argument FRAME is given, report on face FACE in that frame.
 368 If FRAME is t, report on the defaults for face FACE (for new frames).
 369 If FRAME is omitted or nil, use the selected frame."
 370  (eq (face-attribute face :underline frame) t))
 371
 372
 373 (defun face-inverse-video-p (face &optional frame)
 374  "Return non-nil if FACE is in inverse video on FRAME.
 375 If the optional argument FRAME is given, report on face FACE in that frame.
 376 If FRAME is t, report on the defaults for face FACE (for new frames).
 377 If FRAME is omitted or nil, use the selected frame."
 378  (eq (face-attribute face :inverse-video frame) t))
 379
 380
 381 (defun face-bold-p (face &optional frame)
 382   "Return non-nil if the font of FACE is bold on FRAME.
 383 If the optional argument FRAME is given, report on face FACE in that frame.
 384 If FRAME is t, report on the defaults for face FACE (for new frames).
 385 If FRAME is omitted or nil, use the selected frame.
 386 Use `face-attribute' for finer control."
 387   (let ((bold (face-attribute face :weight frame)))
 388     (memq bold '(semi-bold bold extra-bold ultra-bold))))
 389
 390
 391 (defun face-italic-p (face &optional frame)
 392   "Return non-nil if the font of FACE is italic on FRAME.
 393 If the optional argument FRAME is given, report on face FACE in that frame.
 394 If FRAME is t, report on the defaults for face FACE (for new frames).
 395 If FRAME is omitted or nil, use the selected frame.
 396 Use `face-attribute' for finer control."
 397   (let ((italic (face-attribute face :slant frame)))
 398     (memq italic '(italic oblique))))
 399
 400
 401
 402
 403 \f
 404 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 405 ;;; Face documentation.
 406 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 407
 408 (defun face-documentation (face)
 409   "Get the documentation string for FACE."
 410   (get face 'face-documentation))
 411
 412
 413 (defun set-face-documentation (face string)
 414   "Set the documentation string for FACE to STRING."
 415   ;; Perhaps the text should go in DOC.
 416   (put face 'face-documentation (purecopy string)))
 417
 418
 419 (defalias 'face-doc-string 'face-documentation)
 420 (defalias 'set-face-doc-string 'set-face-documentation)
 421
 422
 423 \f
 424 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 425 ;; Setting face attributes.
 426 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 427
 428
 429 (defun set-face-attribute (face frame &rest args)
 430   "Set attributes of FACE on FRAME from ARGS.
 431
 432 FRAME nil means change attributes on all frames.  FRAME t means change
 433 the default for new frames (this is done automatically each time an
 434 attribute is changed on all frames).
 435
 436 ARGS must come in pairs ATTRIBUTE VALUE.  ATTRIBUTE must be a valid
 437 face attribute name.  All attributes can be set to `unspecified';
 438 this fact is not further mentioned below.
 439
 440 The following attributes are recognized:
 441
 442 `:family'
 443
 444 VALUE must be a string specifying the font family, e.g. ``courier'',
 445 or a fontset alias name.  If a font family is specified, wild-cards `*'
 446 and `?' are allowed.
 447
 448 `:width'
 449
 450 VALUE specifies the relative proportionate width of the font to use.
 451 It must be one of the symbols `ultra-condensed', `extra-condensed',
 452 `condensed', `semi-condensed', `normal', `semi-expanded', `expanded',
 453 `extra-expanded', or `ultra-expanded'.
 454
 455 `:height'
 456
 457 VALUE must be either an integer specifying the height of the font to use
 458 in 1/10 pt, a floating point number specifying the amount by which to
 459 scale any underlying face, or a function, which is called with the old
 460 height (from the underlying face), and should return the new height.
 461
 462 `:weight'
 463
 464 VALUE specifies the weight of the font to use.  It must be one of the
 465 symbols `ultra-bold', `extra-bold', `bold', `semi-bold', `normal',
 466 `semi-light', `light', `extra-light', `ultra-light'.
 467
 468 `:slant'
 469
 470 VALUE specifies the slant of the font to use.  It must be one of the
 471 symbols `italic', `oblique', `normal', `reverse-italic', or
 472 `reverse-oblique'.
 473
 474 `:foreground', `:background'
 475
 476 VALUE must be a color name, a string.
 477
 478 `:underline'
 479
 480 VALUE specifies whether characters in FACE should be underlined.  If
 481 VALUE is t, underline with foreground color of the face.  If VALUE is
 482 a string, underline with that color.  If VALUE is nil, explicitly
 483 don't underline.
 484
 485 `:overline'
 486
 487 VALUE specifies whether characters in FACE should be overlined.  If
 488 VALUE is t, overline with foreground color of the face.  If VALUE is a
 489 string, overline with that color.  If VALUE is nil, explicitly don't
 490 overline.
 491
 492 `:strike-through'
 493
 494 VALUE specifies whether characters in FACE should be drawn with a line
 495 striking through them.  If VALUE is t, use the foreground color of the
 496 face.  If VALUE is a string, strike-through with that color.  If VALUE
 497 is nil, explicitly don't strike through.
 498
 499 `:box'
 500
 501 VALUE specifies whether characters in FACE should have a box drawn
 502 around them.  If VALUE is nil, explicitly don't draw boxes.  If
 503 VALUE is t, draw a box with lines of width 1 in the foreground color
 504 of the face.  If VALUE is a string, the string must be a color name,
 505 and the box is drawn in that color with a line width of 1.  Otherwise,
 506 VALUE must be a property list of the form `(:line-width WIDTH
 507 :color COLOR :style STYLE)'.  If a keyword/value pair is missing from
 508 the property list, a default value will be used for the value, as
 509 specified below.  WIDTH specifies the width of the lines to draw; it
 510 defaults to 1.  COLOR is the name of the color to draw in, default is
 511 the foreground color of the face for simple boxes, and the background
 512 color of the face for 3D boxes.  STYLE specifies whether a 3D box
 513 should be draw.  If STYLE is `released-button', draw a box looking
 514 like a released 3D button.  If STYLE is `pressed-button' draw a box
 515 that appears like a pressed button.  If STYLE is nil, the default if
 516 the property list doesn't contain a style specification, draw a 2D
 517 box.
 518
 519 `:inverse-video'
 520
 521 VALUE specifies whether characters in FACE should be displayed in
 522 inverse video.  VALUE must be one of t or nil.
 523
 524 `:stipple'
 525
 526 If VALUE is a string, it must be the name of a file of pixmap data.
 527 The directories listed in the `x-bitmap-file-path' variable are
 528 searched.  Alternatively, VALUE may be a list of the form (WIDTH
 529 HEIGHT DATA) where WIDTH and HEIGHT are the size in pixels, and DATA
 530 is a string containing the raw bits of the bitmap.  VALUE nil means
 531 explicitly don't use a stipple pattern.
 532
 533 For convenience, attributes `:family', `:width', `:height', `:weight',
 534 and `:slant' may also be set in one step from an X font name:
 535
 536 `:font'
 537
 538 Set font-related face attributes from VALUE.  VALUE must be a valid
 539 XLFD font name.  If it is a font name pattern, the first matching font
 540 will be used.
 541
 542 For compatibility with Emacs 20, keywords `:bold' and `:italic' can
 543 be used to specify that a bold or italic font should be used.  VALUE
 544 must be t or nil in that case.  A value of `unspecified' is not allowed.
 545
 546 `:inherit'
 547
 548 VALUE is the name of a face from which to inherit attributes, or a list
 549 of face names.  Attributes from inherited faces are merged into the face
 550 like an underlying face would be, with higher priority than underlying faces."
 551   (let ((where (if (null frame) 0 frame)))
 552     (setq args (purecopy args))
 553     (while args
 554       (internal-set-lisp-face-attribute face (car args)
 555                                         (purecopy (cadr args))
 556                                         where)
 557       (setq args (cdr (cdr args))))))
 558
 559
 560 (defun make-face-bold (face &optional frame noerror)
 561   "Make the font of FACE be bold, if possible.
 562 FRAME nil or not specified means change face on all frames.
 563 Argument NOERROR is ignored and retained for compatibility.
 564 Use `set-face-attribute' for finer control of the font weight."
 565   (interactive (list (read-face-name "Make which face bold ")))
 566   (set-face-attribute face frame :weight 'bold))
 567
 568
 569 (defun make-face-unbold (face &optional frame noerror)
 570   "Make the font of FACE be non-bold, if possible.
 571 FRAME nil or not specified means change face on all frames.
 572 Argument NOERROR is ignored and retained for compatibility."
 573   (interactive (list (read-face-name "Make which face non-bold ")))
 574   (set-face-attribute face frame :weight 'normal))
 575
 576
 577 (defun make-face-italic (face &optional frame noerror)
 578   "Make the font of FACE be italic, if possible.
 579 FRAME nil or not specified means change face on all frames.
 580 Argument NOERROR is ignored and retained for compatibility.
 581 Use `set-face-attribute' for finer control of the font slant."
 582   (interactive (list (read-face-name "Make which face italic ")))
 583   (set-face-attribute face frame :slant 'italic))
 584
 585
 586 (defun make-face-unitalic (face &optional frame noerror)
 587   "Make the font of FACE be non-italic, if possible.
 588 FRAME nil or not specified means change face on all frames.
 589 Argument NOERROR is ignored and retained for compatibility."
 590   (interactive (list (read-face-name "Make which face non-italic ")))
 591   (set-face-attribute face frame :slant 'normal))
 592
 593
 594 (defun make-face-bold-italic (face &optional frame noerror)
 595   "Make the font of FACE be bold and italic, if possible.
 596 FRAME nil or not specified means change face on all frames.
 597 Argument NOERROR is ignored and retained for compatibility.
 598 Use `set-face-attribute' for finer control of font weight and slant."
 599   (interactive (list (read-face-name "Make which face bold-italic: ")))
 600   (set-face-attribute face frame :weight 'bold :slant 'italic))
 601
 602
 603 (defun set-face-font (face font &optional frame)
 604   "Change font-related attributes of FACE to those of FONT (a string).
 605 FRAME nil or not specified means change face on all frames.
 606 This sets the attributes `:family', `:width', `:height', `:weight',
 607 and `:slant'.  When called interactively, prompt for the face and font."
 608   (interactive (read-face-and-attribute :font))
 609   (set-face-attribute face frame :font font))
 610
 611
 612 ;; Implementation note: Emulating gray background colors with a
 613 ;; stipple pattern is now part of the face realization process, and is
 614 ;; done in C depending on the frame on which the face is realized.
 615
 616 (defun set-face-background (face color &optional frame)
 617   "Change the background color of face FACE to COLOR (a string).
 618 FRAME nil or not specified means change face on all frames.
 619 When called interactively, prompt for the face and color."
 620   (interactive (read-face-and-attribute :background))
 621   (set-face-attribute face frame :background color))
 622
 623
 624 (defun set-face-foreground (face color &optional frame)
 625   "Change the foreground color of face FACE to COLOR (a string).
 626 FRAME nil or not specified means change face on all frames.
 627 When called interactively, prompt for the face and color."
 628   (interactive (read-face-and-attribute :foreground))
 629   (set-face-attribute face frame :foreground color))
 630
 631
 632 (defun set-face-stipple (face stipple &optional frame)
 633   "Change the stipple pixmap of face FACE to STIPPLE.
 634 FRAME nil or not specified means change face on all frames.
 635 STIPPLE should be a string, the name of a file of pixmap data.
 636 The directories listed in the `x-bitmap-file-path' variable are searched.
 637
 638 Alternatively, STIPPLE may be a list of the form (WIDTH HEIGHT DATA)
 639 where WIDTH and HEIGHT are the size in pixels,
 640 and DATA is a string, containing the raw bits of the bitmap."
 641   (interactive (read-face-and-attribute :stipple))
 642   (set-face-attribute face frame :stipple stipple))
 643
 644
 645 (defun set-face-underline (face underline &optional frame)
 646   "Specify whether face FACE is underlined.
 647 UNDERLINE nil means FACE explicitly doesn't underline.
 648 UNDERLINE non-nil means FACE explicitly does underlining
 649 with the same of the foreground color.
 650 If UNDERLINE is a string, underline with the color named UNDERLINE.
 651 FRAME nil or not specified means change face on all frames.
 652 Use `set-face-attribute' to ``unspecify'' underlining."
 653   (interactive
 654    (let ((list (read-face-and-attribute :underline)))
 655      (list (car list) (eq (car (cdr list)) t))))
 656   (set-face-attribute face frame :underline underline))
 657
 658
 659 (defun set-face-underline-p (face underline-p &optional frame)
 660   "Specify whether face FACE is underlined.
 661 UNDERLINE-P nil means FACE explicitly doesn't underline.
 662 UNDERLINE-P non-nil means FACE explicitly does underlining.
 663 FRAME nil or not specified means change face on all frames.
 664 Use `set-face-attribute' to ``unspecify'' underlining."
 665   (interactive
 666    (let ((list (read-face-and-attribute :underline)))
 667      (list (car list) (eq (car (cdr list)) t))))
 668   (set-face-attribute face frame :underline underline-p))
 669
 670
 671 (defun set-face-inverse-video-p (face inverse-video-p &optional frame)
 672   "Specify whether face FACE is in inverse video.
 673 INVERSE-VIDEO-P non-nil means FACE displays explicitly in inverse video.
 674 INVERSE-VIDEO-P nil means FACE explicitly is not in inverse video.
 675 FRAME nil or not specified means change face on all frames.
 676 Use `set-face-attribute' to ``unspecify'' the inverse video attribute."
 677   (interactive
 678    (let ((list (read-face-and-attribute :inverse-video)))
 679      (list (car list) (eq (car (cdr list)) t))))
 680   (set-face-attribute face frame :inverse-video inverse-video-p))
 681
 682
 683 (defun set-face-bold-p (face bold-p &optional frame)
 684   "Specify whether face FACE is bold.
 685 BOLD-P non-nil means FACE should explicitly display bold.
 686 BOLD-P nil means FACE should explicitly display non-bold.
 687 FRAME nil or not specified means change face on all frames.
 688 Use `set-face-attribute' or `modify-face' for finer control."
 689   (if (null bold-p)
 690       (make-face-unbold face frame)
 691     (make-face-bold face frame)))
 692
 693
 694 (defun set-face-italic-p (face italic-p &optional frame)
 695   "Specify whether face FACE is italic.
 696 ITALIC-P non-nil means FACE should explicitly display italic.
 697 ITALIC-P nil means FACE should explicitly display non-italic.
 698 FRAME nil or not specified means change face on all frames.
 699 Use `set-face-attribute' or `modify-face' for finer control."
 700   (if (null italic-p)
 701       (make-face-unitalic face frame)
 702     (make-face-italic face frame)))
 703
 704
 705 (defalias 'set-face-background-pixmap 'set-face-stipple)
 706
 707
 708 (defun invert-face (face &optional frame)
 709   "Swap the foreground and background colors of FACE.
 710 FRAME nil or not specified means change face on all frames.
 711 If FACE specifies neither foreground nor background color,
 712 set its foreground and background to the background and foreground
 713 of the default face.  Value is FACE."
 714   (interactive (list (read-face-name "Invert face ")))
 715   (let ((fg (face-attribute face :foreground frame))
 716         (bg (face-attribute face :background frame)))
 717     (if (or fg bg)
 718         (set-face-attribute face frame :foreground bg :background fg)
 719       (set-face-attribute face frame
 720                           :foreground
 721                           (face-attribute 'default :background frame)
 722                           :background
 723                           (face-attribute 'default :foreground frame))))
 724   face)
 725
 726 \f
 727 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 728 ;;; Interactively modifying faces.
 729 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 730
 731 (defun read-face-name (prompt)
 732   "Read and return a face symbol, prompting with PROMPT.
 733 Value is a symbol naming a known face."
 734   (let ((face-list (mapcar #'(lambda (x) (cons (symbol-name x) x))
 735                            (face-list)))
 736         (def (thing-at-point 'symbol))
 737         face)
 738     (cond ((assoc def face-list)
 739            (setq prompt (concat prompt " (default " def "): ")))
 740           (t (setq def nil)
 741              (setq prompt (concat prompt ": "))))
 742     (while (equal "" (setq face (completing-read
 743                                  prompt face-list nil t nil nil def))))
 744     (intern face)))
 745
 746
 747 (defun face-valid-attribute-values (attribute &optional frame)
 748   "Return valid values for face attribute ATTRIBUTE.
 749 The optional argument FRAME is used to determine available fonts
 750 and colors.  If it is nil or not specified, the selected frame is
 751 used.  Value is an alist of (NAME . VALUE) if ATTRIBUTE expects a value
 752 out of a set of discrete values.  Value is `integerp' if ATTRIBUTE expects
 753 an integer value."
 754   (let (valid)
 755     (setq valid
 756           (case attribute
 757             (:family
 758              (if window-system
 759                  (mapcar #'(lambda (x) (cons (car x) (car x)))
 760                          (x-font-family-list))
 761                ;; Only one font on TTYs.
 762                (list (cons "default" "default"))))
 763             ((:width :weight :slant :inverse-video)
 764              (mapcar #'(lambda (x) (cons (symbol-name x) x))
 765                      (internal-lisp-face-attribute-values attribute)))
 766             ((:underline :overline :strike-through :box)
 767              (if window-system
 768                  (nconc (mapcar #'(lambda (x) (cons (symbol-name x) x))
 769                                 (internal-lisp-face-attribute-values attribute))
 770                         (mapcar #'(lambda (c) (cons c c))
 771                                 (x-defined-colors frame)))
 772                (mapcar #'(lambda (x) (cons (symbol-name x) x))
 773                        (internal-lisp-face-attribute-values attribute))))
 774             ((:foreground :background)
 775              (mapcar #'(lambda (c) (cons c c))
 776                      (defined-colors frame)))
 777             ((:height)
 778              'integerp)
 779             (:stipple
 780              (and (memq window-system '(x w32))
 781                   (mapcar #'list
 782                           (apply #'nconc (mapcar #'directory-files
 783                                                  x-bitmap-file-path)))))
 784             (:inherit
 785              (cons '("none" . nil)
 786                    (mapcar #'(lambda (c) (cons (symbol-name c) c))
 787                            (face-list))))
 788             (t
 789              (error "Internal error"))))
 790     (if (and (listp valid) (not (memq attribute '(:inherit))))
 791         (nconc (list (cons "unspecified" 'unspecified)) valid)
 792       valid)))
 793
 794
 795
 796 (defvar face-attribute-name-alist
 797   '((:family . "font family")
 798     (:width . "character set width")
 799     (:height . "height in 1/10 pt")
 800     (:weight . "weight")
 801     (:slant . "slant")
 802     (:underline . "underline")
 803     (:overline . "overline")
 804     (:strike-through . "strike-through")
 805     (:box . "box")
 806     (:inverse-video . "inverse-video display")
 807     (:foreground . "foreground color")
 808     (:background . "background color")
 809     (:stipple . "background stipple")
 810     (:inherit . "inheritance"))
 811   "An alist of descriptive names for face attributes.
 812 Each element has the form (ATTRIBUTE-NAME . DESCRIPTION) where
 813 ATTRIBUTE-NAME is a face attribute name (a keyword symbol), and
 814 DESCRIPTION is a descriptive name for ATTRIBUTE-NAME.")
 815
 816
 817 (defun face-descriptive-attribute-name (attribute)
 818   "Return a descriptive name for ATTRIBUTE."
 819   (cdr (assq attribute face-attribute-name-alist)))
 820
 821
 822 (defun face-read-string (face default name &optional completion-alist)
 823   "Interactively read a face attribute string value.
 824 FACE is the face whose attribute is read.  If non-nil, DEFAULT is the
 825 default string to return if no new value is entered.  NAME is a
 826 descriptive name of the attribute for prompting.  COMPLETION-ALIST is an
 827 alist of valid values, if non-nil.
 828
 829 Entering nothing accepts the default string DEFAULT.
 830 Value is the new attribute value."
 831   ;; Capitalize NAME (we don't use `capitalize' because that capitalizes
 832   ;; each word in a string separately).
 833   (setq name (concat (upcase (substring name 0 1)) (substring name 1)))
 834   (let* ((completion-ignore-case t)
 835          (value (completing-read
 836                  (if default
 837                      (format "%s for face `%s' (default %s): "
 838                              name face default)
 839                    (format "%s for face `%s': " name face))
 840                  completion-alist)))
 841     (if (equal value "") default value)))
 842
 843
 844 (defun face-read-integer (face default name)
 845   "Interactively read an integer face attribute value.
 846 FACE is the face whose attribute is read.  DEFAULT is the default
 847 value to return if no new value is entered.  NAME is a descriptive
 848 name of the attribute for prompting.  Value is the new attribute value."
 849   (let ((new-value
 850          (face-read-string face
 851                            (format "%s" default)
 852                            name
 853                            (list (cons "unspecified" 'unspecified)))))
 854     (cond ((equal new-value "unspecified")
 855            'unspecified)
 856           ((member new-value '("unspecified-fg" "unspecified-bg"))
 857            new-value)
 858           (t
 859            (string-to-int new-value)))))
 860
 861
 862 (defun read-face-attribute (face attribute &optional frame)
 863   "Interactively read a new value for FACE's ATTRIBUTE.
 864 Optional argument FRAME nil or unspecified means read an attribute value
 865 of a global face.  Value is the new attribute value."
 866   (let* ((old-value (face-attribute face attribute frame))
 867          (attribute-name (face-descriptive-attribute-name attribute))
 868          (valid (face-valid-attribute-values attribute frame))
 869          new-value)
 870     ;; Represent complex attribute values as strings by printing them
 871     ;; out.  Stipple can be a vector; (WIDTH HEIGHT DATA).  Box can be
 872     ;; a list `(:width WIDTH :color COLOR)' or `(:width WIDTH :shadow
 873     ;; SHADOW)'.
 874     (when (and (or (eq attribute :stipple)
 875                    (eq attribute :box))
 876                (or (consp old-value)
 877                    (vectorp old-value)))
 878       (setq old-value (prin1-to-string old-value)))
 879     (cond ((listp valid)
 880            (let ((default
 881                    (or (car (rassoc old-value valid))
 882                        (format "%s" old-value))))
 883              (setq new-value
 884                    (face-read-string face default attribute-name valid))
 885              (if (equal new-value default)
 886                  ;; Nothing changed, so don't bother with all the stuff
 887                  ;; below.  In particular, this avoids a non-tty color
 888                  ;; from being canonicalized for a tty when the user
 889                  ;; just uses the default.
 890                  (setq new-value old-value)
 891                ;; Terminal frames can support colors that don't appear
 892                ;; explicitly in VALID, using color approximation code
 893                ;; in tty-colors.el.
 894                (if (and (memq attribute '(:foreground :background))
 895                         (not (memq window-system '(x w32 mac)))
 896                         (not (member new-value
 897                                      '("unspecified"
 898                                        "unspecified-fg" "unspecified-bg"))))
 899                    (setq new-value (car (tty-color-desc new-value frame))))
 900                (setq new-value (cdr (assoc new-value valid))))))
 901           ((eq valid 'integerp)
 902            (setq new-value (face-read-integer face old-value attribute-name)))
 903           (t (error "Internal error")))
 904     ;; Convert stipple and box value text we read back to a list or
 905     ;; vector if it looks like one.  This makes the assumption that a
 906     ;; pixmap file name won't start with an open-paren.
 907     (when (and (or (eq attribute :stipple)
 908                    (eq attribute :box))
 909                (stringp new-value)
 910                (string-match "^[[(]" new-value))
 911       (setq new-value (read new-value)))
 912     new-value))
 913
 914
 915 (defun read-face-font (face &optional frame)
 916   "Read the name of a font for FACE on FRAME.
 917 If optional argument FRAME Is nil or omitted, use the selected frame."
 918   (let ((completion-ignore-case t))
 919     (completing-read (format "Set font attributes of face `%s' from font: " face)
 920                      (mapcar 'list (x-list-fonts "*" nil frame)))))
 921
 922
 923 (defun read-all-face-attributes (face &optional frame)
 924   "Interactively read all attributes for FACE.
 925 If optional argument FRAME Is nil or omitted, use the selected frame.
 926 Value is a property list of attribute names and new values."
 927   (let (result)
 928     (dolist (attribute face-attribute-name-alist result)
 929       (setq result (cons (car attribute)
 930                          (cons (read-face-attribute face (car attribute) frame)
 931                                result))))))
 932
 933
 934 (defun modify-face (&optional frame)
 935   "Modify attributes of faces interactively.
 936 If optional argument FRAME is nil or omitted, modify the face used
 937 for newly created frame, i.e. the global face."
 938   (interactive)
 939   (let ((face (read-face-name "Modify face")))
 940     (apply #'set-face-attribute face frame
 941            (read-all-face-attributes face frame))))
 942
 943
 944 (defun read-face-and-attribute (attribute &optional frame)
 945   "Read face name and face attribute value.
 946 ATTRIBUTE is the attribute whose new value is read.
 947 FRAME nil or unspecified means read attribute value of global face.
 948 Value is a list (FACE NEW-VALUE) where FACE is the face read
 949 (a symbol), and NEW-VALUE is value read."
 950   (cond ((eq attribute :font)
 951          (let* ((prompt "Set font-related attributes of face")
 952                 (face (read-face-name prompt))
 953                 (font (read-face-font face frame)))
 954            (list face font)))
 955         (t
 956          (let* ((attribute-name (face-descriptive-attribute-name attribute))
 957                 (prompt (format "Set %s of face" attribute-name))
 958                 (face (read-face-name prompt))
 959                 (new-value (read-face-attribute face attribute frame)))
 960            (list face new-value)))))
 961
 962
 963 \f
 964 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 965 ;;; Listing faces.
 966 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 967
 968 (defvar list-faces-sample-text
 969   "abcdefghijklmnopqrstuvwxyz ABCDEFGHIJKLMNOPQRSTUVWXYZ"
 970   "*Text string to display as the sample text for `list-faces-display'.")
 971
 972
 973 ;; The name list-faces would be more consistent, but let's avoid a
 974 ;; conflict with Lucid, which uses that name differently.
 975
 976 (defun list-faces-display ()
 977   "List all faces, using the same sample text in each.
 978 The sample text is a string that comes from the variable
 979 `list-faces-sample-text'."
 980   (interactive)
 981   (let ((faces (sort (face-list) #'string-lessp))
 982         (face nil)
 983         (frame (selected-frame))
 984         disp-frame window face-name)
 985     (with-output-to-temp-buffer "*Faces*"
 986       (save-excursion
 987         (set-buffer standard-output)
 988         (setq truncate-lines t)
 989         (insert
 990          (substitute-command-keys
 991           (concat
 992            "Use "
 993            (if (display-mouse-p) "\\[help-follow-mouse] or ")
 994            "\\[help-follow] on a face name to customize it\n"
 995            "or on its sample text for a decription of the face.\n\n")))
 996         (setq help-xref-stack nil)
 997         (while faces
 998           (setq face (car faces))
 999           (setq faces (cdr faces))
1000           (setq face-name (symbol-name face))
1001           (insert (format "%25s " face-name))
1002           ;; Hyperlink to a customization buffer for the face.  Using
1003           ;; the help xref mechanism may not be the best way.
1004           (save-excursion
1005             (save-match-data
1006               (search-backward face-name)
1007               (help-xref-button 0 (lambda (f)
1008                                     (if help-xref-stack
1009                                         (pop help-xref-stack))
1010                                     (customize-face f))
1011                                 face-name
1012                                 "mouse-2: customize this face")))
1013           (let ((beg (point)))
1014             (insert list-faces-sample-text)
1015             ;; Hyperlink to a help buffer for the face.
1016             (save-excursion
1017               (save-match-data
1018                 (search-backward list-faces-sample-text)
1019                 (help-xref-button 0 #'describe-face face
1020                                   "mouse-2: describe this face")))
1021             (insert "\n")
1022             (put-text-property beg (1- (point)) 'face face)
1023             ;; If the sample text has multiple lines, line up all of them.
1024             (goto-char beg)
1025             (forward-line 1)
1026             (while (not (eobp))
1027               (insert "                          ")
1028               (forward-line 1))))
1029         (goto-char (point-min)))
1030       (print-help-return-message))
1031     ;; If the *Faces* buffer appears in a different frame,
1032     ;; copy all the face definitions from FRAME,
1033     ;; so that the display will reflect the frame that was selected.
1034     (setq window (get-buffer-window (get-buffer "*Faces*") t))
1035     (setq disp-frame (if window (window-frame window)
1036                        (car (frame-list))))
1037     (or (eq frame disp-frame)
1038         (let ((faces (face-list)))
1039           (while faces
1040             (copy-face (car faces) (car faces) frame disp-frame)
1041             (setq faces (cdr faces)))))))
1042
1043
1044 (defun describe-face (face &optional frame)
1045   "Display the properties of face FACE on FRAME.
1046 If the optional argument FRAME is given, report on face FACE in that frame.
1047 If FRAME is t, report on the defaults for face FACE (for new frames).
1048 If FRAME is omitted or nil, use the selected frame."
1049   (interactive (list (read-face-name "Describe face")))
1050   (let* ((attrs '((:family . "Family")
1051                   (:width . "Width")
1052                   (:height . "Height")
1053                   (:weight . "Weight")
1054                   (:slant . "Slant")
1055                   (:foreground . "Foreground")
1056                   (:background . "Background")
1057                   (:underline . "Underline")
1058                   (:overline . "Overline")
1059                   (:strike-through . "Strike-through")
1060                   (:box . "Box")
1061                   (:inverse-video . "Inverse")
1062                   (:stipple . "Stipple")
1063                   (:font . "Font or fontset")
1064                   (:inherit . "Inherit")))
1065         (max-width (apply #'max (mapcar #'(lambda (x) (length (cdr x)))
1066                                         attrs))))
1067     (with-output-to-temp-buffer "*Help*"
1068       (save-excursion
1069         (set-buffer standard-output)
1070         (dolist (a attrs)
1071           (let ((attr (face-attribute face (car a) frame)))
1072             (insert (make-string (- max-width (length (cdr a))) ?\ )
1073                     (cdr a) ": " (format "%s" attr) "\n")))
1074         (insert "\nDocumentation:\n\n"
1075                 (or (face-documentation face)
1076                     "not documented as a face."))
1077         (let ((customize-label "customize"))
1078           (terpri)
1079           (terpri)
1080           (princ (concat "You can " customize-label " this face."))
1081           (with-current-buffer "*Help*"
1082             (save-excursion
1083               (re-search-backward
1084                (concat "\\(" customize-label "\\)") nil t)
1085               (help-xref-button 1 #'customize-face face
1086                                 "mouse-2, RET: customize face")))))
1087       (print-help-return-message)
1088       (with-current-buffer "*Help*"
1089         (help-setup-xref (list #'describe-face face) (interactive-p))
1090         (buffer-string)))))
1091 \f
1092 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1093 ;;; Face specifications (defface).
1094 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1095
1096 ;; Parameter FRAME Is kept for call compatibility to with previous
1097 ;; face implementation.
1098
1099 (defun face-attr-construct (face &optional frame)
1100   "Return a defface-style attribute list for FACE on FRAME.
1101 Value is a property list of pairs ATTRIBUTE VALUE for all specified
1102 face attributes of FACE where ATTRIBUTE is the attribute name and
1103 VALUE is the specified value of that attribute."
1104   (let (result)
1105     (dolist (entry face-attribute-name-alist result)
1106       (let* ((attribute (car entry))
1107              (value (face-attribute face attribute)))
1108         (unless (eq value 'unspecified)
1109           (setq result (nconc (list attribute value) result)))))))
1110
1111
1112 (defun face-spec-set-match-display (display frame)
1113   "Non-nil if DISPLAY matches FRAME.
1114 DISPLAY is part of a spec such as can be used in `defface'.
1115 If FRAME is nil, the current FRAME is used."
1116   (let* ((conjuncts display)
1117          conjunct req options
1118          ;; t means we have succeeded against all the conjuncts in
1119          ;; DISPLAY that have been tested so far.
1120          (match t))
1121     (if (eq conjuncts t)
1122         (setq conjuncts nil))
1123     (while (and conjuncts match)
1124       (setq conjunct (car conjuncts)
1125             conjuncts (cdr conjuncts)
1126             req (car conjunct)
1127             options (cdr conjunct)
1128             match (cond ((eq req 'type)
1129                          (or (memq window-system options)
1130                              (and (null window-system)
1131                                   (memq 'tty options))
1132                              (and (memq 'motif options)
1133                                   (featurep 'motif))
1134                              (and (memq 'lucid options)
1135                                   (featurep 'x-toolkit)
1136                                   (not (featurep 'motif)))
1137                              (and (memq 'x-toolkit options)
1138                                   (featurep 'x-toolkit))))
1139                         ((eq req 'class)
1140                          (memq (frame-parameter frame 'display-type) options))
1141                         ((eq req 'background)
1142                          (memq (frame-parameter frame 'background-mode)
1143                                options))
1144                         (t (error "Unknown req `%S' with options `%S'"
1145                                   req options)))))
1146     match))
1147
1148
1149 (defun face-spec-choose (spec &optional frame)
1150   "Choose the proper attributes for FRAME, out of SPEC."
1151   (unless frame
1152     (setq frame (selected-frame)))
1153   (let ((tail spec)
1154         result)
1155     (while tail
1156       (let* ((entry (car tail))
1157              (display (nth 0 entry))
1158              (attrs (nth 1 entry)))
1159         (setq tail (cdr tail))
1160         (when (face-spec-set-match-display display frame)
1161           (setq result attrs tail nil))))
1162     result))
1163
1164
1165 (defun face-spec-reset-face (face &optional frame)
1166   "Reset all attributes of FACE on FRAME to unspecified."
1167   (let ((attrs face-attribute-name-alist))
1168     (while attrs
1169       (let ((attr-and-name (car attrs)))
1170         (set-face-attribute face frame (car attr-and-name) 'unspecified))
1171       (setq attrs (cdr attrs)))))
1172
1173
1174 (defun face-spec-set (face spec &optional frame)
1175   "Set FACE's attributes according to the first matching entry in SPEC.
1176 FRAME is the frame whose frame-local face is set.  FRAME nil means
1177 do it on all frames.  See `defface' for information about SPEC."
1178   (let ((attrs (face-spec-choose spec frame)))
1179     (when attrs
1180       (face-spec-reset-face face frame))
1181     (while attrs
1182       (let ((attribute (car attrs))
1183             (value (car (cdr attrs))))
1184         ;; Support some old-style attribute names and values.
1185         (case attribute
1186           (:bold (setq attribute :weight value (if value 'bold 'normal)))
1187           (:italic (setq attribute :slant value (if value 'italic 'normal)))
1188           (t (unless (assq attribute face-x-resources)
1189                (setq attribute nil))))
1190         (when attribute
1191           (set-face-attribute face frame attribute value)))
1192       (setq attrs (cdr (cdr attrs))))))
1193
1194
1195 (defun face-attr-match-p (face attrs &optional frame)
1196   "Return t if attributes of FACE match values in plist ATTRS.
1197 Optional parameter FRAME is the frame whose definition of FACE
1198 is used.  If nil or omitted, use the selected frame."
1199   (unless frame
1200     (setq frame (selected-frame)))
1201   (let ((list face-attribute-name-alist)
1202         (match t))
1203     (while (and match (not (null list)))
1204       (let* ((attr (car (car list)))
1205              (specified-value
1206               (if (plist-member attrs attr)
1207                   (plist-get attrs attr)
1208                 'unspecified))
1209              (value-now (face-attribute face attr frame)))
1210         (setq match (equal specified-value value-now))
1211         (setq list (cdr list))))
1212     match))
1213
1214 (defun face-spec-match-p (face spec &optional frame)
1215   "Return t if FACE, on FRAME, matches what SPEC says it should look like."
1216   (face-attr-match-p face (face-spec-choose spec frame) frame))
1217
1218
1219 \f
1220 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1221 ;;; Frame-type independent color support.
1222 ;;; We keep the old x-* names as aliases for back-compatibility.
1223 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1224
1225 (defun defined-colors (&optional frame)
1226   "Return a list of colors supported for a particular frame.
1227 The argument FRAME specifies which frame to try.
1228 The value may be different for frames on different display types.
1229 If FRAME doesn't support colors, the value is nil."
1230   (if (memq (framep (or frame (selected-frame))) '(x w32))
1231       (xw-defined-colors frame)
1232     (mapcar 'car (tty-color-alist frame))))
1233 (defalias 'x-defined-colors 'defined-colors)
1234
1235 (defun color-defined-p (color &optional frame)
1236   "Return non-nil if color COLOR is supported on frame FRAME.
1237 If FRAME is omitted or nil, use the selected frame.
1238 If COLOR is the symbol `unspecified' or one of the strings
1239 \"unspecified-fg\" or \"unspecified-bg\", the value is nil."
1240   (if (memq color '(unspecified "unspecified-bg" "unspecified-fg"))
1241       nil
1242     (if (memq (framep (or frame (selected-frame))) '(x w32))
1243         (xw-color-defined-p color frame)
1244       (numberp (tty-color-translate color frame)))))
1245 (defalias 'x-color-defined-p 'color-defined-p)
1246
1247 (defun color-values (color &optional frame)
1248   "Return a description of the color named COLOR on frame FRAME.
1249 The value is a list of integer RGB values--\(RED GREEN BLUE\).
1250 These values appear to range from 0 65535; white is \(65535 65535 65535\).
1251 If FRAME is omitted or nil, use the selected frame.
1252 If FRAME cannot display COLOR, the value is nil.
1253 If COLOR is the symbol `unspecified' or one of the strings
1254 \"unspecified-fg\" or \"unspecified-bg\", the value is nil."
1255   (if (memq color '(unspecified "unspecified-fg" "unspecified-bg"))
1256       nil
1257     (if (memq (framep (or frame (selected-frame))) '(x w32))
1258         (xw-color-values color frame)
1259       (tty-color-values color frame))))
1260 (defalias 'x-color-values 'color-values)
1261
1262 (defun display-color-p (&optional display)
1263   "Return t if DISPLAY supports color.
1264 The optional argument DISPLAY specifies which display to ask about.
1265 DISPLAY should be either a frame or a display name (a string).
1266 If omitted or nil, that stands for the selected frame's display."
1267   (if (memq (framep-on-display display) '(x w32))
1268       (xw-display-color-p display)
1269     (tty-display-color-p display)))
1270 (defalias 'x-display-color-p 'display-color-p)
1271
1272 (defun display-grayscale-p (&optional display)
1273   "Return non-nil if frames on DISPLAY can display shades of gray."
1274   (let ((frame-type (framep-on-display display)))
1275     (cond
1276      ((memq frame-type '(x w32 mac))
1277       (x-display-grayscale-p display))
1278      (t
1279       (> (tty-color-gray-shades display) 2)))))
1280
1281 \f
1282 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1283 ;;; Background mode.
1284 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1285
1286 (defcustom frame-background-mode nil
1287   "*The brightness of the background.
1288 Set this to the symbol `dark' if your background color is dark, `light' if
1289 your background is light, or nil (default) if you want Emacs to
1290 examine the brightness for you.  Don't set this variable with `setq';
1291 this won't have the expected effect."
1292   :group 'faces
1293   :set #'(lambda (var value)
1294            (set-default var value)
1295            (mapc 'frame-set-background-mode (frame-list)))
1296   :initialize 'custom-initialize-changed
1297   :type '(choice (choice-item dark)
1298                  (choice-item light)
1299                  (choice-item :tag "default" nil)))
1300
1301
1302 (defun frame-set-background-mode (frame)
1303   "Set up the `background-mode' and `display-type' frame parameters for FRAME."
1304   (let* ((bg-resource
1305           (and window-system
1306                (x-get-resource ".backgroundMode" "BackgroundMode")))
1307          (bg-mode (cond (frame-background-mode)
1308                         ((null window-system)
1309                          ;; No way to determine this automatically (?).
1310                          'dark)
1311                         (bg-resource
1312                          (intern (downcase bg-resource)))
1313                         ((< (apply '+ (x-color-values
1314                                        (frame-parameter frame 'background-color)
1315                                        frame))
1316                             ;; Just looking at the screen, colors whose
1317                             ;; values add up to .6 of the white total
1318                             ;; still look dark to me.
1319                             (* (apply '+ (x-color-values "white" frame)) .6))
1320                          'dark)
1321                         (t 'light)))
1322          (display-type (cond ((null window-system)
1323                               (if (tty-display-color-p frame) 'color 'mono))
1324                              ((x-display-color-p frame)
1325                               'color)
1326                              ((x-display-grayscale-p frame)
1327                               'grayscale)
1328                              (t 'mono))))
1329     (modify-frame-parameters frame
1330                              (list (cons 'background-mode bg-mode)
1331                                    (cons 'display-type display-type))))
1332
1333   ;; For all named faces, choose face specs matching the new frame
1334   ;; parameters.
1335   (let ((face-list (face-list)))
1336     (while face-list
1337       (let* ((face (car face-list))
1338              (spec (get face 'face-defface-spec)))
1339         (when spec
1340           (face-spec-set face spec frame))
1341       (setq face-list (cdr face-list))))))
1342
1343
1344
1345 \f
1346 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1347 ;;; Frame creation.
1348 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1349
1350 (defun x-handle-named-frame-geometry (parameters)
1351   "Add geometry parameters for a named frame to parameter list PARAMETERS.
1352 Value is the new parameter list."
1353   (let* ((name (or (cdr (assq 'name parameters))
1354                    (cdr (assq 'name default-frame-alist))))
1355          (x-resource-name name)
1356          (res-geometry (if name (x-get-resource "geometry" "Geometry"))))
1357     (when res-geometry
1358       (let ((parsed (x-parse-geometry res-geometry)))
1359         ;; If the resource specifies a position, call the position
1360         ;; and size "user-specified".
1361         (when (or (assq 'top parsed)
1362                   (assq 'left parsed))
1363           (setq parsed (append '((user-position . t) (user-size . t)) parsed)))
1364         ;; Put the geometry parameters at the end.  Copy
1365         ;; default-frame-alist so that they go after it.
1366         (setq parameters (append parameters default-frame-alist parsed))))
1367     parameters))
1368
1369
1370 (defun x-handle-reverse-video (frame parameters)
1371   "Handle the reverse-video frame parameter and X resource.
1372 `x-create-frame' does not handle this one."
1373   (when (cdr (or (assq 'reverse parameters)
1374                  (assq 'reverse default-frame-alist)
1375                  (let ((resource (x-get-resource "reverseVideo"
1376                                                  "ReverseVideo")))
1377                    (if resource
1378                        (cons nil (member (downcase resource)
1379                                          '("on" "true")))))))
1380       (let* ((params (frame-parameters frame))
1381              (bg (cdr (assq 'foreground-color params)))
1382              (fg (cdr (assq 'background-color params))))
1383         (modify-frame-parameters frame
1384                                  (list (cons 'foreground-color fg)
1385                                        (cons 'background-color bg)))
1386         (if (equal bg (cdr (assq 'border-color params)))
1387             (modify-frame-parameters frame
1388                                      (list (cons 'border-color fg))))
1389         (if (equal bg (cdr (assq 'mouse-color params)))
1390             (modify-frame-parameters frame
1391                                      (list (cons 'mouse-color fg))))
1392         (if (equal bg (cdr (assq 'cursor-color params)))
1393             (modify-frame-parameters frame
1394                                      (list (cons 'cursor-color fg)))))))
1395
1396
1397 (defun x-create-frame-with-faces (&optional parameters)
1398   "Create a frame from optional frame parameters PARAMETERS.
1399 Parameters not specified by PARAMETERS are taken from
1400 `default-frame-alist'.  If PARAMETERS specify a frame name,
1401 handle X geometry resources for that name.  If either PARAMETERS
1402 or `default-frame-alist' contains a `reverse' parameter, or
1403 the X resource ``reverseVideo'' is present, handle that.
1404 Value is the new frame created."
1405   (setq parameters (x-handle-named-frame-geometry parameters))
1406   (let ((visibility-spec (assq 'visibility parameters))
1407         (frame-list (frame-list))
1408         (frame (x-create-frame (cons '(visibility . nil) parameters)))
1409         success)
1410     (unwind-protect
1411         (progn
1412           (x-handle-reverse-video frame parameters)
1413           (frame-set-background-mode frame)
1414           (face-set-after-frame-default frame)
1415           (if (or (null frame-list) (null visibility-spec))
1416               (make-frame-visible frame)
1417             (modify-frame-parameters frame (list visibility-spec)))
1418           (setq success t))
1419       (unless success
1420         (delete-frame frame)))
1421     frame))
1422
1423
1424 (defun face-set-after-frame-default (frame)
1425   "Set frame-local faces of FRAME from face specs and resources.
1426 Initialize colors of certain faces from frame parameters."
1427   (dolist (face (face-list))
1428     (let ((spec (or (get face 'saved-face)
1429                     (get face 'face-defface-spec))))
1430       (when spec
1431         (face-spec-set face spec frame))
1432       (internal-merge-in-global-face face frame)
1433       (when (memq window-system '(x w32))
1434         (make-face-x-resource-internal face frame))))
1435
1436   ;; Initialize attributes from frame parameters.
1437   (let ((params '((foreground-color default :foreground)
1438                   (background-color default :background)
1439                   (border-color border :background)
1440                   (cursor-color cursor :background)
1441                   (scroll-bar-foreground scroll-bar :foreground)
1442                   (scroll-bar-background scroll-bar :background)
1443                   (mouse-color mouse :background))))
1444     (while params
1445       (let ((param-name (nth 0 (car params)))
1446             (face (nth 1 (car params)))
1447             (attr (nth 2 (car params)))
1448             value)
1449         (when (setq value (frame-parameter frame param-name))
1450           (set-face-attribute face frame attr value)))
1451       (setq params (cdr params)))))
1452
1453
1454 (defun tty-create-frame-with-faces (&optional parameters)
1455   "Create a frame from optional frame parameters PARAMETERS.
1456 Parameters not specified by PARAMETERS are taken from
1457 `default-frame-alist'.  If either PARAMETERS or `default-frame-alist'
1458 contains a `reverse' parameter, handle that.  Value is the new frame
1459 created."
1460   (let ((frame (make-terminal-frame parameters))
1461         success)
1462     (unwind-protect
1463         (progn
1464           (frame-set-background-mode frame)
1465           (face-set-after-frame-default frame)
1466           (setq success t))
1467       (unless success
1468         (delete-frame frame)))
1469     frame))
1470
1471
1472 ;; Called from C function init_display to initialize faces of the
1473 ;; dumped terminal frame on startup.
1474
1475 (defun tty-set-up-initial-frame-faces ()
1476   (let ((frame (selected-frame)))
1477     (frame-set-background-mode frame)
1478     (face-set-after-frame-default frame)))
1479
1480
1481
1482 \f
1483 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1484 ;;; Compatiblity with 20.2
1485 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1486
1487 ;; Update a frame's faces when we change its default font.
1488
1489 (defalias 'frame-update-faces 'ignore)
1490 (make-obsolete 'frame-update-faces "No longer necessary" "21.1")
1491
1492 ;; Update the colors of FACE, after FRAME's own colors have been
1493 ;; changed.
1494
1495 (defalias 'frame-update-face-colors 'frame-set-background-mode)
1496 (make-obsolete 'frame-update-face-colors 'frame-set-background-mode "21.1")
1497
1498 \f
1499 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1500 ;;; Standard faces.
1501 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1502
1503 (defgroup basic-faces nil
1504   "The standard faces of Emacs."
1505   :group 'faces)
1506
1507
1508 (defface default
1509   '((t nil))
1510   "Basic default face."
1511   :group 'basic-faces)
1512
1513
1514 (defface mode-line
1515   '((((type x) (class color))
1516      (:box (:line-width 2 :style released-button)
1517            :background "grey75" :foreground "black"))
1518     (((type w32) (class color))
1519      (:box (:line-width 2 :style released-button)
1520            :background "grey75" :foreground "black"))
1521     (t
1522      (:inverse-video t)))
1523   "Basic mode line face."
1524   :version "21.1"
1525   :group 'modeline
1526   :group 'basic-faces)
1527
1528 ;; Make `modeline' an alias for `mode-line', for compatibility.
1529 (put 'modeline 'face-alias 'mode-line)
1530
1531 (defface header-line
1532   '((((type tty))
1533      (:inverse-video t))
1534     (((class color) (background light))
1535      (:box (:line-width 1 :style released-button)
1536            :background "grey90"
1537            :inherit mode-line))
1538     (((class color) (background dark))
1539      (:box (:line-width 1 :style released-button)
1540            :background "grey20"
1541            :inherit mode-line))
1542     (((class mono))
1543      (:box (:line-width 1 :style released-button)
1544            :background "grey"
1545            :inherit mode-line))
1546     (t
1547      (:inverse-video t)))
1548   "Basic header-line face."
1549   :version "21.1"
1550   :group 'basic-faces)
1551
1552
1553 (defface tool-bar
1554   '((((type x) (class color))
1555      (:box (:line-width 1 :style released-button)
1556            :background "grey75" :foreground "black"))
1557     (((type x) (class mono))
1558      (:box (:line-width 1 :style released-button)
1559            :background "grey" :foreground "black"))
1560     (((type w32) (class color))
1561      (:box (:line-width 1 :style released-button)
1562            :background "grey75" :foreground "black"))
1563     (t
1564      ()))
1565   "Basic tool-bar face."
1566   :version "21.1"
1567   :group 'basic-faces)
1568
1569
1570 (defface region
1571   '((((type tty) (class color))
1572      (:background "blue" :foreground "white"))
1573     (((type tty) (class mono))
1574      (:inverse-video t))
1575     (((class color) (background dark))
1576      (:background "blue"))
1577     (((class color) (background light))
1578      (:background "light goldenrod yellow"))
1579     (t (:background "gray")))
1580   "Basic face for highlighting the region."
1581   :version "21.1"
1582   :group 'basic-faces)
1583
1584
1585 (defface fringe
1586   '((((class color) (background light))
1587        (:background "grey95"))
1588       (((class color) (background dark))
1589        (:background "grey10"))
1590       (t
1591        (:background "gray")))
1592   "Basic face for the fringes to the left and right of windows under X."
1593   :version "21.1"
1594   :group 'frames
1595   :group 'basic-faces)
1596
1597
1598 (defface scroll-bar '()
1599   "Basic face for the scroll bar colors under X."
1600   :version "21.1"
1601   :group 'frames
1602   :group 'basic-faces)
1603
1604
1605 (defface menu
1606   '((((type x-toolkit)) ())
1607     (t (:inverse-video t)))
1608   "Basic menu face."
1609   :version "21.1"
1610   :group 'menu
1611   :group 'basic-faces)
1612
1613
1614 (defface border '()
1615   "Basic face for the frame border under X."
1616   :version "21.1"
1617   :group 'frames
1618   :group 'basic-faces)
1619
1620
1621 (defface cursor '()
1622   "Basic face for the cursor color under X."
1623   :version "21.1"
1624   :group 'cursor
1625   :group 'basic-faces)
1626
1627
1628 (defface mouse '()
1629   "Basic face for the mouse color under X."
1630   :version "21.1"
1631   :group 'mouse
1632   :group 'basic-faces)
1633
1634
1635 (defface bold '((t (:weight bold)))
1636   "Basic bold face."
1637   :group 'basic-faces)
1638
1639
1640 (defface italic '((t (:slant italic)))
1641   "Basic italic font."
1642   :group 'basic-faces)
1643
1644
1645 (defface bold-italic '((t (:weight bold :slant italic)))
1646   "Basic bold-italic face."
1647   :group 'basic-faces)
1648
1649
1650 (defface underline '((t (:underline t)))
1651   "Basic underlined face."
1652   :group 'basic-faces)
1653
1654
1655 (defface highlight
1656   '((((type tty) (class color))
1657      (:background "green"))
1658     (((class color) (background light))
1659      (:background "darkseagreen2"))
1660     (((class color) (background dark))
1661      (:background "darkolivegreen"))
1662     (t (:inverse-video t)))
1663   "Basic face for highlighting."
1664   :group 'basic-faces)
1665
1666
1667 (defface secondary-selection
1668   '((((type tty) (class color))
1669      (:background "cyan"))
1670     (((class color) (background light))
1671      (:background "yellow"))
1672     (((class color) (background dark))
1673      (:background "yellow"))
1674     (t (:inverse-video t)))
1675   "Basic face for displaying the secondary selection."
1676   :group 'basic-faces)
1677
1678
1679 (defface fixed-pitch '((t (:family "courier")))
1680   "The basic fixed-pitch face."
1681   :group 'basic-faces)
1682
1683
1684 (defface variable-pitch '((t (:family "helv")))
1685   "The basic variable-pitch face."
1686   :group 'basic-faces)
1687
1688
1689 (defface trailing-whitespace
1690   '((((class color) (background light))
1691      (:background "red"))
1692     (((class color) (background dark))
1693      (:background "red"))
1694     (t (:inverse-video t)))
1695   "Basic face for highlighting trailing whitespace."
1696   :version "21.1"
1697   :group 'font-lock                     ; like `show-trailing-whitespace'
1698   :group 'basic-faces)
1699
1700
1701 \f
1702 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1703 ;;; Manipulating font names.
1704 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1705
1706 ;; This is here for compatibilty with Emacs 20.2.  For example,
1707 ;; international/fontset.el uses x-resolve-font-name.  The following
1708 ;; functions are not used in the face implementation itself.
1709
1710 (defvar x-font-regexp nil)
1711 (defvar x-font-regexp-head nil)
1712 (defvar x-font-regexp-weight nil)
1713 (defvar x-font-regexp-slant nil)
1714
1715 (defconst x-font-regexp-weight-subnum 1)
1716 (defconst x-font-regexp-slant-subnum 2)
1717 (defconst x-font-regexp-swidth-subnum 3)
1718 (defconst x-font-regexp-adstyle-subnum 4)
1719
1720 ;;; Regexps matching font names in "Host Portable Character Representation."
1721 ;;;
1722 (let ((-                "[-?]")
1723       (foundry          "[^-]+")
1724       (family           "[^-]+")
1725       (weight           "\\(bold\\|demibold\\|medium\\)")               ; 1
1726 ;     (weight\?         "\\(\\*\\|bold\\|demibold\\|medium\\|\\)")      ; 1
1727       (weight\?         "\\([^-]*\\)")                                  ; 1
1728       (slant            "\\([ior]\\)")                                  ; 2
1729 ;     (slant\?          "\\([ior?*]?\\)")                               ; 2
1730       (slant\?          "\\([^-]?\\)")                                  ; 2
1731 ;     (swidth           "\\(\\*\\|normal\\|semicondensed\\|\\)")        ; 3
1732       (swidth           "\\([^-]*\\)")                                  ; 3
1733 ;     (adstyle          "\\(\\*\\|sans\\|\\)")                          ; 4
1734       (adstyle          "\\([^-]*\\)")                                  ; 4
1735       (pixelsize        "[0-9]+")
1736       (pointsize        "[0-9][0-9]+")
1737       (resx             "[0-9][0-9]+")
1738       (resy             "[0-9][0-9]+")
1739       (spacing          "[cmp?*]")
1740       (avgwidth         "[0-9]+")
1741       (registry         "[^-]+")
1742       (encoding         "[^-]+")
1743       )
1744   (setq x-font-regexp
1745         (concat "\\`\\*?[-?*]"
1746                 foundry - family - weight\? - slant\? - swidth - adstyle -
1747                 pixelsize - pointsize - resx - resy - spacing - avgwidth -
1748                 registry - encoding "\\*?\\'"
1749                 ))
1750   (setq x-font-regexp-head
1751         (concat "\\`[-?*]" foundry - family - weight\? - slant\?
1752                 "\\([-*?]\\|\\'\\)"))
1753   (setq x-font-regexp-slant (concat - slant -))
1754   (setq x-font-regexp-weight (concat - weight -))
1755   nil)
1756
1757
1758 (defun x-resolve-font-name (pattern &optional face frame)
1759   "Return a font name matching PATTERN.
1760 All wildcards in PATTERN are instantiated.
1761 If PATTERN is nil, return the name of the frame's base font, which never
1762 contains wildcards.
1763 Given optional arguments FACE and FRAME, return a font which is
1764 also the same size as FACE on FRAME, or fail."
1765   (or (symbolp face)
1766       (setq face (face-name face)))
1767   (and (eq frame t)
1768        (setq frame nil))
1769   (if pattern
1770       ;; Note that x-list-fonts has code to handle a face with nil as its font.
1771       (let ((fonts (x-list-fonts pattern face frame 1)))
1772         (or fonts
1773             (if face
1774                 (if (string-match "\\*" pattern)
1775                     (if (null (face-font face))
1776                         (error "No matching fonts are the same height as the frame default font")
1777                       (error "No matching fonts are the same height as face `%s'" face))
1778                   (if (null (face-font face))
1779                       (error "Height of font `%s' doesn't match the frame default font"
1780                              pattern)
1781                     (error "Height of font `%s' doesn't match face `%s'"
1782                            pattern face)))
1783               (error "No fonts match `%s'" pattern)))
1784         (car fonts))
1785     (cdr (assq 'font (frame-parameters (selected-frame))))))
1786
1787
1788 (defun x-frob-font-weight (font which)
1789   (let ((case-fold-search t))
1790     (cond ((string-match x-font-regexp font)
1791            (concat (substring font 0
1792                               (match-beginning x-font-regexp-weight-subnum))
1793                    which
1794                    (substring font (match-end x-font-regexp-weight-subnum)
1795                               (match-beginning x-font-regexp-adstyle-subnum))
1796                    ;; Replace the ADD_STYLE_NAME field with *
1797                    ;; because the info in it may not be the same
1798                    ;; for related fonts.
1799                    "*"
1800                    (substring font (match-end x-font-regexp-adstyle-subnum))))
1801           ((string-match x-font-regexp-head font)
1802            (concat (substring font 0 (match-beginning 1)) which
1803                    (substring font (match-end 1))))
1804           ((string-match x-font-regexp-weight font)
1805            (concat (substring font 0 (match-beginning 1)) which
1806                    (substring font (match-end 1)))))))
1807 (make-obsolete 'x-frob-font-weight 'make-face-... "21.1")
1808
1809 (defun x-frob-font-slant (font which)
1810   (let ((case-fold-search t))
1811     (cond ((string-match x-font-regexp font)
1812            (concat (substring font 0
1813                               (match-beginning x-font-regexp-slant-subnum))
1814                    which
1815                    (substring font (match-end x-font-regexp-slant-subnum)
1816                               (match-beginning x-font-regexp-adstyle-subnum))
1817                    ;; Replace the ADD_STYLE_NAME field with *
1818                    ;; because the info in it may not be the same
1819                    ;; for related fonts.
1820                    "*"
1821                    (substring font (match-end x-font-regexp-adstyle-subnum))))
1822           ((string-match x-font-regexp-head font)
1823            (concat (substring font 0 (match-beginning 2)) which
1824                    (substring font (match-end 2))))
1825           ((string-match x-font-regexp-slant font)
1826            (concat (substring font 0 (match-beginning 1)) which
1827                    (substring font (match-end 1)))))))
1828 (make-obsolete 'x-frob-font-slant 'make-face-... "21.1")
1829
1830 (defun x-make-font-bold (font)
1831   "Given an X font specification, make a bold version of it.
1832 If that can't be done, return nil."
1833   (x-frob-font-weight font "bold"))
1834 (make-obsolete 'x-make-font-bold 'make-face-bold "21.1")
1835
1836 (defun x-make-font-demibold (font)
1837   "Given an X font specification, make a demibold version of it.
1838 If that can't be done, return nil."
1839   (x-frob-font-weight font "demibold"))
1840 (make-obsolete 'x-make-font-demibold 'make-face-bold "21.1")
1841
1842 (defun x-make-font-unbold (font)
1843   "Given an X font specification, make a non-bold version of it.
1844 If that can't be done, return nil."
1845   (x-frob-font-weight font "medium"))
1846 (make-obsolete 'x-make-font-unbold 'make-face-unbold "21.1")
1847
1848 (defun x-make-font-italic (font)
1849   "Given an X font specification, make an italic version of it.
1850 If that can't be done, return nil."
1851   (x-frob-font-slant font "i"))
1852 (make-obsolete 'x-make-font-italic 'make-face-italic "21.1")
1853
1854 (defun x-make-font-oblique (font) ; you say tomayto...
1855   "Given an X font specification, make an oblique version of it.
1856 If that can't be done, return nil."
1857   (x-frob-font-slant font "o"))
1858 (make-obsolete 'x-make-font-oblique 'make-face-italic "21.1")
1859
1860 (defun x-make-font-unitalic (font)
1861   "Given an X font specification, make a non-italic version of it.
1862 If that can't be done, return nil."
1863   (x-frob-font-slant font "r"))
1864 (make-obsolete 'x-make-font-unitalic 'make-face-unitalic "21.1")
1865
1866 (defun x-make-font-bold-italic (font)
1867   "Given an X font specification, make a bold and italic version of it.
1868 If that can't be done, return nil."
1869   (and (setq font (x-make-font-bold font))
1870        (x-make-font-italic font)))
1871 (make-obsolete 'x-make-font-bold-italic 'make-face-bold-italic "21.1")
1872
1873 (provide 'faces)
1874
1875 ;;; faces.el ends here