code.delx.au - gnu-emacs/blob - lisp/mail/rmailedit.el

   1 ;;; rmailedit.el --- "RMAIL edit mode"  Edit the current message.
   2
   3 ;; Copyright (C) 1985, 1994 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6 ;; Keywords: mail
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Code:
  26
  27 (require 'rmail)
  28
  29 (defvar rmail-edit-map nil)
  30 (if rmail-edit-map
  31     nil
  32   ;; Make a keymap that inherits text-mode-map.
  33   (setq rmail-edit-map (nconc (make-sparse-keymap) text-mode-map))
  34   (define-key rmail-edit-map "\C-c\C-c" 'rmail-cease-edit)
  35   (define-key rmail-edit-map "\C-c\C-]" 'rmail-abort-edit))
  36
  37 ;; Rmail Edit mode is suitable only for specially formatted data.
  38 (put 'rmail-edit-mode 'mode-class 'special)
  39
  40 (defun rmail-edit-mode ()
  41   "Major mode for editing the contents of an RMAIL message.
  42 The editing commands are the same as in Text mode, together with two commands
  43 to return to regular RMAIL:
  44   *  rmail-abort-edit cancels the changes
  45      you have made and returns to RMAIL
  46   *  rmail-cease-edit makes them permanent.
  47 \\{rmail-edit-map}"
  48   (use-local-map rmail-edit-map)
  49   (setq major-mode 'rmail-edit-mode)
  50   (setq mode-name "RMAIL Edit")
  51   (if (boundp 'mode-line-modified)
  52       (setq mode-line-modified (default-value 'mode-line-modified))
  53     (setq mode-line-format (default-value 'mode-line-format)))
  54   (if (rmail-summary-exists)
  55       (save-excursion
  56         (set-buffer rmail-summary-buffer)
  57         (rmail-summary-disable)))
  58   (run-hooks 'text-mode-hook 'rmail-edit-mode-hook))
  59
  60 ;;;###autoload
  61 (defun rmail-edit-current-message ()
  62   "Edit the contents of this message."
  63   (interactive)
  64   (rmail-edit-mode)
  65   (make-local-variable 'rmail-old-text)
  66   (setq rmail-old-text (buffer-substring (point-min) (point-max)))
  67   (setq buffer-read-only nil)
  68   (force-mode-line-update)
  69   (if (and (eq (key-binding "\C-c\C-c") 'rmail-cease-edit)
  70            (eq (key-binding "\C-c\C-]") 'rmail-abort-edit))
  71       (message "Editing: Type C-c C-c to return to Rmail, C-c C-] to abort")
  72     (message "%s" (substitute-command-keys
  73                "Editing: Type \\[rmail-cease-edit] to return to Rmail, \\[rmail-abort-edit] to abort"))))
  74
  75 (defun rmail-cease-edit ()
  76   "Finish editing message; switch back to Rmail proper."
  77   (interactive)
  78   (if (rmail-summary-exists)
  79       (save-excursion
  80         (set-buffer rmail-summary-buffer)
  81         (rmail-summary-enable)))
  82   ;; Make sure buffer ends with a newline.
  83   (save-excursion
  84     (goto-char (point-max))
  85     (if (/= (preceding-char) ?\n)
  86         (insert "\n"))
  87     ;; Adjust the marker that points to the end of this message.
  88     (set-marker (aref rmail-message-vector (1+ rmail-current-message))
  89                 (point)))
  90   (let ((old rmail-old-text))
  91     (force-mode-line-update)
  92     (rmail-mode-1)
  93     (if (and (= (length old) (- (point-max) (point-min)))
  94              (string= old (buffer-substring (point-min) (point-max))))
  95         ()
  96       (setq old nil)
  97       (rmail-set-attribute "edited" t)
  98       (if (boundp 'rmail-summary-vector)
  99           (progn
 100             (aset rmail-summary-vector (1- rmail-current-message) nil)
 101             (save-excursion
 102               (rmail-widen-to-current-msgbeg
 103                 (function (lambda ()
 104                             (forward-line 2)
 105                             (if (looking-at "Summary-line: ")
 106                                 (let ((buffer-read-only nil))
 107                                   (delete-region (point)
 108                                                  (progn (forward-line 1)
 109                                                         (point))))))))
 110               (rmail-show-message))))))
 111   (setq buffer-read-only t))
 112
 113 (defun rmail-abort-edit ()
 114   "Abort edit of current message; restore original contents."
 115   (interactive)
 116   (delete-region (point-min) (point-max))
 117   (insert rmail-old-text)
 118   (rmail-cease-edit)
 119   (rmail-highlight-headers))
 120
 121 ;;; rmailedit.el ends here