code.delx.au - gnu-emacs/blob - lisp/gnus/gnus-srvr.el

   1 ;;; gnus-srvr.el --- virtual server support for Gnus
   2 ;; Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003,
   3 ;; 2004, 2005
   4 ;;        Free Software Foundation, Inc.
   5
   6 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   7 ;; Keywords: news
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;; Code:
  29
  30 (eval-when-compile (require 'cl))
  31
  32 (require 'gnus)
  33 (require 'gnus-spec)
  34 (require 'gnus-group)
  35 (require 'gnus-int)
  36 (require 'gnus-range)
  37
  38 (defcustom gnus-server-mode-hook nil
  39   "Hook run in `gnus-server-mode' buffers."
  40   :group 'gnus-server
  41   :type 'hook)
  42
  43 (defcustom gnus-server-exit-hook nil
  44   "Hook run when exiting the server buffer."
  45   :group 'gnus-server
  46   :type 'hook)
  47
  48 (defcustom gnus-server-line-format "     {%(%h:%w%)} %s%a\n"
  49   "Format of server lines.
  50 It works along the same lines as a normal formatting string,
  51 with some simple extensions.
  52
  53 The following specs are understood:
  54
  55 %h backend
  56 %n name
  57 %w address
  58 %s status
  59 %a agent covered
  60
  61 General format specifiers can also be used.
  62 See Info node `(gnus)Formatting Variables'."
  63   :link '(custom-manual "(gnus)Formatting Variables")
  64   :group 'gnus-server-visual
  65   :type 'string)
  66
  67 (defcustom gnus-server-mode-line-format "Gnus: %%b"
  68   "The format specification for the server mode line."
  69   :group 'gnus-server-visual
  70   :type 'string)
  71
  72 (defcustom gnus-server-browse-in-group-buffer nil
  73   "Whether server browsing should take place in the group buffer.
  74 If nil, a faster, but more primitive, buffer is used instead."
  75   :version "22.1"
  76   :group 'gnus-server-visual
  77   :type 'boolean)
  78
  79 ;;; Internal variables.
  80
  81 (defvar gnus-inserted-opened-servers nil)
  82
  83 (defvar gnus-server-line-format-alist
  84   `((?h gnus-tmp-how ?s)
  85     (?n gnus-tmp-name ?s)
  86     (?w gnus-tmp-where ?s)
  87     (?s gnus-tmp-status ?s)
  88     (?a gnus-tmp-agent ?s)))
  89
  90 (defvar gnus-server-mode-line-format-alist
  91   `((?S gnus-tmp-news-server ?s)
  92     (?M gnus-tmp-news-method ?s)
  93     (?u gnus-tmp-user-defined ?s)))
  94
  95 (defvar gnus-server-line-format-spec nil)
  96 (defvar gnus-server-mode-line-format-spec nil)
  97 (defvar gnus-server-killed-servers nil)
  98
  99 (defvar gnus-server-mode-map)
 100
 101 (defvar gnus-server-menu-hook nil
 102   "*Hook run after the creation of the server mode menu.")
 103
 104 (defun gnus-server-make-menu-bar ()
 105   (gnus-turn-off-edit-menu 'server)
 106   (unless (boundp 'gnus-server-server-menu)
 107     (easy-menu-define
 108      gnus-server-server-menu gnus-server-mode-map ""
 109      '("Server"
 110        ["Add..." gnus-server-add-server t]
 111        ["Browse" gnus-server-read-server t]
 112        ["Scan" gnus-server-scan-server t]
 113        ["List" gnus-server-list-servers t]
 114        ["Kill" gnus-server-kill-server t]
 115        ["Yank" gnus-server-yank-server t]
 116        ["Copy" gnus-server-copy-server t]
 117        ["Edit" gnus-server-edit-server t]
 118        ["Regenerate" gnus-server-regenerate-server t]
 119        ["Exit" gnus-server-exit t]))
 120
 121     (easy-menu-define
 122      gnus-server-connections-menu gnus-server-mode-map ""
 123      '("Connections"
 124        ["Open" gnus-server-open-server t]
 125        ["Close" gnus-server-close-server t]
 126        ["Offline" gnus-server-offline-server t]
 127        ["Deny" gnus-server-deny-server t]
 128        "---"
 129        ["Open All" gnus-server-open-all-servers t]
 130        ["Close All" gnus-server-close-all-servers t]
 131        ["Reset All" gnus-server-remove-denials t]))
 132
 133     (gnus-run-hooks 'gnus-server-menu-hook)))
 134
 135 (defvar gnus-server-mode-map nil)
 136 (put 'gnus-server-mode 'mode-class 'special)
 137
 138 (unless gnus-server-mode-map
 139   (setq gnus-server-mode-map (make-sparse-keymap))
 140   (suppress-keymap gnus-server-mode-map)
 141
 142   (gnus-define-keys gnus-server-mode-map
 143     " " gnus-server-read-server-in-server-buffer
 144     "\r" gnus-server-read-server
 145     gnus-mouse-2 gnus-server-pick-server
 146     "q" gnus-server-exit
 147     "l" gnus-server-list-servers
 148     "k" gnus-server-kill-server
 149     "y" gnus-server-yank-server
 150     "c" gnus-server-copy-server
 151     "a" gnus-server-add-server
 152     "e" gnus-server-edit-server
 153     "s" gnus-server-scan-server
 154
 155     "O" gnus-server-open-server
 156     "\M-o" gnus-server-open-all-servers
 157     "C" gnus-server-close-server
 158     "\M-c" gnus-server-close-all-servers
 159     "D" gnus-server-deny-server
 160     "L" gnus-server-offline-server
 161     "R" gnus-server-remove-denials
 162
 163     "n" next-line
 164     "p" previous-line
 165
 166     "g" gnus-server-regenerate-server
 167
 168     "\C-c\C-i" gnus-info-find-node
 169     "\C-c\C-b" gnus-bug))
 170
 171 (defface gnus-server-agent-face
 172   '((((class color) (background light)) (:foreground "PaleTurquoise" :bold t))
 173     (((class color) (background dark)) (:foreground "PaleTurquoise" :bold t))
 174     (t (:bold t)))
 175   "Face used for displaying AGENTIZED servers"
 176   :group 'gnus-server-visual)
 177
 178 (defface gnus-server-opened-face
 179   '((((class color) (background light)) (:foreground "Green3" :bold t))
 180     (((class color) (background dark)) (:foreground "Green1" :bold t))
 181     (t (:bold t)))
 182   "Face used for displaying OPENED servers"
 183   :group 'gnus-server-visual)
 184
 185 (defface gnus-server-closed-face
 186   '((((class color) (background light)) (:foreground "Steel Blue" :italic t))
 187     (((class color) (background dark))
 188      (:foreground "Light Steel Blue" :italic t))
 189     (t (:italic t)))
 190   "Face used for displaying CLOSED servers"
 191   :group 'gnus-server-visual)
 192
 193 (defface gnus-server-denied-face
 194   '((((class color) (background light)) (:foreground "Red" :bold t))
 195     (((class color) (background dark)) (:foreground "Pink" :bold t))
 196     (t (:inverse-video t :bold t)))
 197   "Face used for displaying DENIED servers"
 198   :group 'gnus-server-visual)
 199
 200 (defface gnus-server-offline-face
 201   '((((class color) (background light)) (:foreground "Orange" :bold t))
 202     (((class color) (background dark)) (:foreground "Yellow" :bold t))
 203     (t (:inverse-video t :bold t)))
 204   "Face used for displaying OFFLINE servers"
 205   :group 'gnus-server-visual)
 206
 207 (defcustom gnus-server-agent-face 'gnus-server-agent-face
 208   "Face name to use on AGENTIZED servers."
 209   :version "22.1"
 210   :group 'gnus-server-visual
 211   :type 'face)
 212
 213 (defcustom gnus-server-opened-face 'gnus-server-opened-face
 214   "Face name to use on OPENED servers."
 215   :version "22.1"
 216   :group 'gnus-server-visual
 217   :type 'face)
 218
 219 (defcustom gnus-server-closed-face 'gnus-server-closed-face
 220   "Face name to use on CLOSED servers."
 221   :version "22.1"
 222   :group 'gnus-server-visual
 223   :type 'face)
 224
 225 (defcustom gnus-server-denied-face 'gnus-server-denied-face
 226   "Face name to use on DENIED servers."
 227   :version "22.1"
 228   :group 'gnus-server-visual
 229   :type 'face)
 230
 231 (defcustom gnus-server-offline-face 'gnus-server-offline-face
 232   "Face name to use on OFFLINE servers."
 233   :version "22.1"
 234   :group 'gnus-server-visual
 235   :type 'face)
 236
 237 (defvar gnus-server-font-lock-keywords
 238   (list
 239    '("(\\(agent\\))" 1 gnus-server-agent-face)
 240    '("(\\(opened\\))" 1 gnus-server-opened-face)
 241    '("(\\(closed\\))" 1 gnus-server-closed-face)
 242    '("(\\(offline\\))" 1 gnus-server-offline-face)
 243    '("(\\(denied\\))" 1 gnus-server-denied-face)))
 244
 245 (defun gnus-server-mode ()
 246   "Major mode for listing and editing servers.
 247
 248 All normal editing commands are switched off.
 249 \\<gnus-server-mode-map>
 250 For more in-depth information on this mode, read the manual
 251 \(`\\[gnus-info-find-node]').
 252
 253 The following commands are available:
 254
 255 \\{gnus-server-mode-map}"
 256   (interactive)
 257   (when (gnus-visual-p 'server-menu 'menu)
 258     (gnus-server-make-menu-bar))
 259   (kill-all-local-variables)
 260   (gnus-simplify-mode-line)
 261   (setq major-mode 'gnus-server-mode)
 262   (setq mode-name "Server")
 263   (gnus-set-default-directory)
 264   (setq mode-line-process nil)
 265   (use-local-map gnus-server-mode-map)
 266   (buffer-disable-undo)
 267   (setq truncate-lines t)
 268   (setq buffer-read-only t)
 269   (if (featurep 'xemacs)
 270       (put 'gnus-server-mode 'font-lock-defaults '(gnus-server-font-lock-keywords t))
 271     (set (make-local-variable 'font-lock-defaults)
 272          '(gnus-server-font-lock-keywords t)))
 273   (gnus-run-mode-hooks 'gnus-server-mode-hook))
 274
 275 (defun gnus-server-insert-server-line (gnus-tmp-name method)
 276   (let* ((gnus-tmp-how (car method))
 277          (gnus-tmp-where (nth 1 method))
 278          (elem (assoc method gnus-opened-servers))
 279          (gnus-tmp-status
 280           (cond
 281            ((eq (nth 1 elem) 'denied) "(denied)")
 282            ((eq (nth 1 elem) 'offline) "(offline)")
 283            (t
 284             (condition-case nil
 285                 (if (or (gnus-server-opened method)
 286                         (eq (nth 1 elem) 'ok))
 287                     "(opened)"
 288                   "(closed)")
 289               ((error) "(error)")))))
 290          (gnus-tmp-agent (if (and gnus-agent
 291                                   (gnus-agent-method-p method))
 292                              " (agent)"
 293                            "")))
 294     (beginning-of-line)
 295     (gnus-add-text-properties
 296      (point)
 297      (prog1 (1+ (point))
 298        ;; Insert the text.
 299        (eval gnus-server-line-format-spec))
 300      (list 'gnus-server (intern gnus-tmp-name)
 301            'gnus-named-server (intern (gnus-method-to-server method))))))
 302
 303 (defun gnus-enter-server-buffer ()
 304   "Set up the server buffer."
 305   (gnus-server-setup-buffer)
 306   (gnus-configure-windows 'server)
 307   (gnus-server-prepare))
 308
 309 (defun gnus-server-setup-buffer ()
 310   "Initialize the server buffer."
 311   (unless (get-buffer gnus-server-buffer)
 312     (save-excursion
 313       (set-buffer (gnus-get-buffer-create gnus-server-buffer))
 314       (gnus-server-mode)
 315       (when gnus-carpal
 316         (gnus-carpal-setup-buffer 'server)))))
 317
 318 (defun gnus-server-prepare ()
 319   (gnus-set-format 'server-mode)
 320   (gnus-set-format 'server t)
 321   (let ((alist gnus-server-alist)
 322         (buffer-read-only nil)
 323         (opened gnus-opened-servers)
 324         done server op-ser)
 325     (erase-buffer)
 326     (setq gnus-inserted-opened-servers nil)
 327     ;; First we do the real list of servers.
 328     (while alist
 329       (unless (member (cdar alist) done)
 330         (push (cdar alist) done)
 331         (setq server (pop alist))
 332         (when (and server (car server) (cdr server))
 333           (gnus-server-insert-server-line (car server) (cdr server))))
 334       (when (member (cdar alist) done)
 335         (pop alist)))
 336     ;; Then we insert the list of servers that have been opened in
 337     ;; this session.
 338     (while opened
 339       (when (and (not (member (caar opened) done))
 340                  ;; Just ignore ephemeral servers.
 341                  (not (member (caar opened) gnus-ephemeral-servers)))
 342         (push (caar opened) done)
 343         (gnus-server-insert-server-line
 344          (setq op-ser (format "%s:%s" (caaar opened) (nth 1 (caar opened))))
 345          (caar opened))
 346         (push (list op-ser (caar opened)) gnus-inserted-opened-servers))
 347       (setq opened (cdr opened))))
 348   (goto-char (point-min))
 349   (gnus-server-position-point))
 350
 351 (defun gnus-server-server-name ()
 352   (let ((server (get-text-property (gnus-point-at-bol) 'gnus-server)))
 353     (and server (symbol-name server))))
 354
 355 (defun gnus-server-named-server ()
 356   "Returns a server name that matches one of the names returned by
 357 gnus-method-to-server."
 358   (let ((server (get-text-property (gnus-point-at-bol) 'gnus-named-server)))
 359     (and server (symbol-name server))))
 360
 361 (defalias 'gnus-server-position-point 'gnus-goto-colon)
 362
 363 (defconst gnus-server-edit-buffer "*Gnus edit server*")
 364
 365 (defun gnus-server-update-server (server)
 366   (save-excursion
 367     (set-buffer gnus-server-buffer)
 368     (let* ((buffer-read-only nil)
 369            (entry (assoc server gnus-server-alist))
 370            (oentry (assoc (gnus-server-to-method server)
 371                           gnus-opened-servers)))
 372       (when entry
 373         (gnus-dribble-enter
 374          (concat "(gnus-server-set-info \"" server "\" '"
 375                  (gnus-prin1-to-string (cdr entry)) ")\n")))
 376       (when (or entry oentry)
 377         ;; Buffer may be narrowed.
 378         (save-restriction
 379           (widen)
 380           (when (gnus-server-goto-server server)
 381             (gnus-delete-line))
 382           (if entry
 383               (gnus-server-insert-server-line (car entry) (cdr entry))
 384             (gnus-server-insert-server-line
 385              (format "%s:%s" (caar oentry) (nth 1 (car oentry)))
 386              (car oentry)))
 387           (gnus-server-position-point))))))
 388
 389 (defun gnus-server-set-info (server info)
 390   ;; Enter a select method into the virtual server alist.
 391   (when (and server info)
 392     (gnus-dribble-enter
 393      (concat "(gnus-server-set-info \"" server "\" '"
 394              (gnus-prin1-to-string info) ")"))
 395     (let* ((server (nth 1 info))
 396            (entry (assoc server gnus-server-alist))
 397            (cached (assoc server gnus-server-method-cache)))
 398       (if cached
 399           (setq gnus-server-method-cache
 400                 (delq cached gnus-server-method-cache)))
 401       (if entry (setcdr entry info)
 402         (setq gnus-server-alist
 403               (nconc gnus-server-alist (list (cons server info))))))))
 404
 405 ;;; Interactive server functions.
 406
 407 (defun gnus-server-kill-server (server)
 408   "Kill the server on the current line."
 409   (interactive (list (gnus-server-server-name)))
 410   (unless (gnus-server-goto-server server)
 411     (if server (error "No such server: %s" server)
 412       (error "No server on the current line")))
 413   (unless (assoc server gnus-server-alist)
 414     (error "Read-only server %s" server))
 415   (gnus-dribble-touch)
 416   (let ((buffer-read-only nil))
 417     (gnus-delete-line))
 418   (push (assoc server gnus-server-alist) gnus-server-killed-servers)
 419   (setq gnus-server-alist (delq (car gnus-server-killed-servers)
 420                                 gnus-server-alist))
 421   (let ((groups (gnus-groups-from-server server)))
 422     (when (and groups
 423                (gnus-yes-or-no-p
 424                 (format "Kill all %s groups from this server? "
 425                         (length groups))))
 426       (dolist (group groups)
 427         (setq gnus-newsrc-alist
 428               (delq (assoc group gnus-newsrc-alist)
 429                     gnus-newsrc-alist))
 430         (when gnus-group-change-level-function
 431           (funcall gnus-group-change-level-function
 432                    group gnus-level-killed 3)))))
 433   (gnus-server-position-point))
 434
 435 (defun gnus-server-yank-server ()
 436   "Yank the previously killed server."
 437   (interactive)
 438   (unless gnus-server-killed-servers
 439     (error "No killed servers to be yanked"))
 440   (let ((alist gnus-server-alist)
 441         (server (gnus-server-server-name))
 442         (killed (car gnus-server-killed-servers)))
 443     (if (not server)
 444         (setq gnus-server-alist (nconc gnus-server-alist (list killed)))
 445       (if (string= server (caar gnus-server-alist))
 446           (push killed gnus-server-alist)
 447         (while (and (cdr alist)
 448                     (not (string= server (caadr alist))))
 449           (setq alist (cdr alist)))
 450         (if alist
 451             (setcdr alist (cons killed (cdr alist)))
 452           (setq gnus-server-alist (list killed)))))
 453     (gnus-server-update-server (car killed))
 454     (setq gnus-server-killed-servers (cdr gnus-server-killed-servers))
 455     (gnus-server-position-point)))
 456
 457 (defun gnus-server-exit ()
 458   "Return to the group buffer."
 459   (interactive)
 460   (gnus-run-hooks 'gnus-server-exit-hook)
 461   (gnus-kill-buffer (current-buffer))
 462   (gnus-configure-windows 'group t))
 463
 464 (defun gnus-server-list-servers ()
 465   "List all available servers."
 466   (interactive)
 467   (let ((cur (gnus-server-server-name)))
 468     (gnus-server-prepare)
 469     (if cur (gnus-server-goto-server cur)
 470       (goto-char (point-max))
 471       (forward-line -1))
 472     (gnus-server-position-point)))
 473
 474 (defun gnus-server-set-status (method status)
 475   "Make METHOD have STATUS."
 476   (let ((entry (assoc method gnus-opened-servers)))
 477     (if entry
 478         (setcar (cdr entry) status)
 479       (push (list method status) gnus-opened-servers))))
 480
 481 (defun gnus-opened-servers-remove (method)
 482   "Remove METHOD from the list of opened servers."
 483   (setq gnus-opened-servers (delq (assoc method gnus-opened-servers)
 484                                   gnus-opened-servers)))
 485
 486 (defun gnus-server-open-server (server)
 487   "Force an open of SERVER."
 488   (interactive (list (gnus-server-server-name)))
 489   (let ((method (gnus-server-to-method server)))
 490     (unless method
 491       (error "No such server: %s" server))
 492     (gnus-server-set-status method 'ok)
 493     (prog1
 494         (or (gnus-open-server method)
 495             (progn (message "Couldn't open %s" server) nil))
 496       (gnus-server-update-server server)
 497       (gnus-server-position-point))))
 498
 499 (defun gnus-server-open-all-servers ()
 500   "Open all servers."
 501   (interactive)
 502   (let ((servers gnus-inserted-opened-servers))
 503     (while servers
 504       (gnus-server-open-server (car (pop servers))))))
 505
 506 (defun gnus-server-close-server (server)
 507   "Close SERVER."
 508   (interactive (list (gnus-server-server-name)))
 509   (let ((method (gnus-server-to-method server)))
 510     (unless method
 511       (error "No such server: %s" server))
 512     (gnus-server-set-status method 'closed)
 513     (prog1
 514         (gnus-close-server method)
 515       (gnus-server-update-server server)
 516       (gnus-server-position-point))))
 517
 518 (defun gnus-server-offline-server (server)
 519   "Set SERVER to offline."
 520   (interactive (list (gnus-server-server-name)))
 521   (let ((method (gnus-server-to-method server)))
 522     (unless method
 523       (error "No such server: %s" server))
 524     (prog1
 525         (gnus-close-server method)
 526       (gnus-server-set-status method 'offline)
 527       (gnus-server-update-server server)
 528       (gnus-server-position-point))))
 529
 530 (defun gnus-server-close-all-servers ()
 531   "Close all servers."
 532   (interactive)
 533   (dolist (server gnus-inserted-opened-servers)
 534     (gnus-server-close-server (car server))))
 535
 536 (defun gnus-server-deny-server (server)
 537   "Make sure SERVER will never be attempted opened."
 538   (interactive (list (gnus-server-server-name)))
 539   (let ((method (gnus-server-to-method server)))
 540     (unless method
 541       (error "No such server: %s" server))
 542     (gnus-server-set-status method 'denied))
 543   (gnus-server-update-server server)
 544   (gnus-server-position-point)
 545   t)
 546
 547 (defun gnus-server-remove-denials ()
 548   "Make all denied servers into closed servers."
 549   (interactive)
 550   (dolist (server gnus-opened-servers)
 551     (when (eq (nth 1 server) 'denied)
 552       (setcar (nthcdr 1 server) 'closed)))
 553   (gnus-server-list-servers))
 554
 555 (defun gnus-server-copy-server (from to)
 556   (interactive
 557    (list
 558     (or (gnus-server-server-name)
 559         (error "No server on the current line"))
 560     (read-string "Copy to: ")))
 561   (unless from
 562     (error "No server on current line"))
 563   (unless (and to (not (string= to "")))
 564     (error "No name to copy to"))
 565   (when (assoc to gnus-server-alist)
 566     (error "%s already exists" to))
 567   (unless (gnus-server-to-method from)
 568     (error "%s: no such server" from))
 569   (let ((to-entry (cons from (gnus-copy-sequence
 570                               (gnus-server-to-method from)))))
 571     (setcar to-entry to)
 572     (setcar (nthcdr 2 to-entry) to)
 573     (push to-entry gnus-server-killed-servers)
 574     (gnus-server-yank-server)))
 575
 576 (defun gnus-server-add-server (how where)
 577   (interactive
 578    (list (intern (completing-read "Server method: "
 579                                   gnus-valid-select-methods nil t))
 580          (read-string "Server name: ")))
 581   (when (assq where gnus-server-alist)
 582     (error "Server with that name already defined"))
 583   (push (list where how where) gnus-server-killed-servers)
 584   (gnus-server-yank-server))
 585
 586 (defun gnus-server-goto-server (server)
 587   "Jump to a server line."
 588   (interactive
 589    (list (completing-read "Goto server: " gnus-server-alist nil t)))
 590   (let ((to (text-property-any (point-min) (point-max)
 591                                'gnus-server (intern server))))
 592     (when to
 593       (goto-char to)
 594       (gnus-server-position-point))))
 595
 596 (defun gnus-server-edit-server (server)
 597   "Edit the server on the current line."
 598   (interactive (list (gnus-server-server-name)))
 599   (unless server
 600     (error "No server on current line"))
 601   (unless (assoc server gnus-server-alist)
 602     (error "This server can't be edited"))
 603   (let ((info (cdr (assoc server gnus-server-alist))))
 604     (gnus-close-server info)
 605     (gnus-edit-form
 606      info "Editing the server."
 607      `(lambda (form)
 608         (gnus-server-set-info ,server form)
 609         (gnus-server-list-servers)
 610         (gnus-server-position-point)))))
 611
 612 (defun gnus-server-scan-server (server)
 613   "Request a scan from the current server."
 614   (interactive (list (gnus-server-server-name)))
 615   (let ((method (gnus-server-to-method server)))
 616     (if (not (gnus-get-function method 'request-scan))
 617         (error "Server %s can't scan" (car method))
 618       (gnus-message 3 "Scanning %s..." server)
 619       (gnus-request-scan nil method)
 620       (gnus-message 3 "Scanning %s...done" server))))
 621
 622 (defun gnus-server-read-server-in-server-buffer (server)
 623   "Browse a server in server buffer."
 624   (interactive (list (gnus-server-server-name)))
 625   (let (gnus-server-browse-in-group-buffer)
 626     (gnus-server-read-server server)))
 627
 628 (defun gnus-server-read-server (server)
 629   "Browse a server."
 630   (interactive (list (gnus-server-server-name)))
 631   (let ((buf (current-buffer)))
 632     (prog1
 633         (gnus-browse-foreign-server server buf)
 634       (save-excursion
 635         (set-buffer buf)
 636         (gnus-server-update-server (gnus-server-server-name))
 637         (gnus-server-position-point)))))
 638
 639 (defun gnus-server-pick-server (e)
 640   (interactive "e")
 641   (mouse-set-point e)
 642   (gnus-server-read-server (gnus-server-server-name)))
 643
 644 \f
 645 ;;;
 646 ;;; Browse Server Mode
 647 ;;;
 648
 649 (defvar gnus-browse-menu-hook nil
 650   "*Hook run after the creation of the browse mode menu.")
 651
 652 (defvar gnus-browse-mode-hook nil)
 653 (defvar gnus-browse-mode-map nil)
 654 (put 'gnus-browse-mode 'mode-class 'special)
 655
 656 (unless gnus-browse-mode-map
 657   (setq gnus-browse-mode-map (make-keymap))
 658   (suppress-keymap gnus-browse-mode-map)
 659
 660   (gnus-define-keys
 661       gnus-browse-mode-map
 662     " " gnus-browse-read-group
 663     "=" gnus-browse-select-group
 664     "n" gnus-browse-next-group
 665     "p" gnus-browse-prev-group
 666     "\177" gnus-browse-prev-group
 667     [delete] gnus-browse-prev-group
 668     "N" gnus-browse-next-group
 669     "P" gnus-browse-prev-group
 670     "\M-n" gnus-browse-next-group
 671     "\M-p" gnus-browse-prev-group
 672     "\r" gnus-browse-select-group
 673     "u" gnus-browse-unsubscribe-current-group
 674     "l" gnus-browse-exit
 675     "L" gnus-browse-exit
 676     "q" gnus-browse-exit
 677     "Q" gnus-browse-exit
 678     "d" gnus-browse-describe-group
 679     "\C-c\C-c" gnus-browse-exit
 680     "?" gnus-browse-describe-briefly
 681
 682     "\C-c\C-i" gnus-info-find-node
 683     "\C-c\C-b" gnus-bug))
 684
 685 (defun gnus-browse-make-menu-bar ()
 686   (gnus-turn-off-edit-menu 'browse)
 687   (unless (boundp 'gnus-browse-menu)
 688     (easy-menu-define
 689      gnus-browse-menu gnus-browse-mode-map ""
 690      '("Browse"
 691        ["Subscribe" gnus-browse-unsubscribe-current-group t]
 692        ["Read" gnus-browse-read-group t]
 693        ["Select" gnus-browse-select-group t]
 694        ["Describe" gnus-browse-describe-group t]
 695        ["Next" gnus-browse-next-group t]
 696        ["Prev" gnus-browse-prev-group t]
 697        ["Exit" gnus-browse-exit t]))
 698     (gnus-run-hooks 'gnus-browse-menu-hook)))
 699
 700 (defvar gnus-browse-current-method nil)
 701 (defvar gnus-browse-return-buffer nil)
 702
 703 (defvar gnus-browse-buffer "*Gnus Browse Server*")
 704
 705 (defun gnus-browse-foreign-server (server &optional return-buffer)
 706   "Browse the server SERVER."
 707   (setq gnus-browse-current-method (gnus-server-to-method server))
 708   (setq gnus-browse-return-buffer return-buffer)
 709   (let* ((method gnus-browse-current-method)
 710          (orig-select-method gnus-select-method)
 711          (gnus-select-method method)
 712          groups group)
 713     (gnus-message 5 "Connecting to %s..." (nth 1 method))
 714     (cond
 715      ((not (gnus-check-server method))
 716       (gnus-message
 717        1 "Unable to contact server %s: %s" (nth 1 method)
 718        (gnus-status-message method))
 719       nil)
 720      ((not
 721        (prog2
 722            (gnus-message 6 "Reading active file...")
 723            (gnus-request-list method)
 724          (gnus-message 6 "Reading active file...done")))
 725       (gnus-message
 726        1 "Couldn't request list: %s" (gnus-status-message method))
 727       nil)
 728      (t
 729       (with-current-buffer nntp-server-buffer
 730         (let ((cur (current-buffer)))
 731           (goto-char (point-min))
 732           (unless (string= gnus-ignored-newsgroups "")
 733             (delete-matching-lines gnus-ignored-newsgroups))
 734           ;; We treat NNTP as a special case to avoid problems with
 735           ;; garbage group names like `"foo' that appear in some badly
 736           ;; managed active files. -jh.
 737           (if (eq (car method) 'nntp)
 738               (while (not (eobp))
 739                 (ignore-errors
 740                   (push (cons
 741                          (buffer-substring
 742                           (point)
 743                           (progn
 744                             (skip-chars-forward "^ \t")
 745                             (point)))
 746                          (let ((last (read cur)))
 747                            (cons (read cur) last)))
 748                         groups))
 749                 (forward-line))
 750             (while (not (eobp))
 751               (ignore-errors
 752                 (push (cons
 753                        (if (eq (char-after) ?\")
 754                            (read cur)
 755                          (let ((p (point)) (name ""))
 756                            (skip-chars-forward "^ \t\\\\")
 757                            (setq name (buffer-substring p (point)))
 758                            (while (eq (char-after) ?\\)
 759                              (setq p (1+ (point)))
 760                              (forward-char 2)
 761                              (skip-chars-forward "^ \t\\\\")
 762                              (setq name (concat name (buffer-substring
 763                                                       p (point)))))
 764                            name))
 765                        (let ((last (read cur)))
 766                          (cons (read cur) last)))
 767                       groups))
 768               (forward-line)))))
 769       (setq groups (sort groups
 770                          (lambda (l1 l2)
 771                            (string< (car l1) (car l2)))))
 772       (if gnus-server-browse-in-group-buffer
 773           (let* ((gnus-select-method orig-select-method)
 774                  (gnus-group-listed-groups
 775                   (mapcar (lambda (group)
 776                             (let ((name
 777                                    (gnus-group-prefixed-name
 778                                     (car group) method)))
 779                               (gnus-set-active name (cdr group))
 780                               name))
 781                           groups)))
 782             (gnus-configure-windows 'group)
 783             (funcall gnus-group-prepare-function
 784                      gnus-level-killed 'ignore 1 'ignore))
 785         (gnus-get-buffer-create gnus-browse-buffer)
 786         (when gnus-carpal
 787           (gnus-carpal-setup-buffer 'browse))
 788         (gnus-configure-windows 'browse)
 789         (buffer-disable-undo)
 790         (let ((buffer-read-only nil))
 791           (erase-buffer))
 792         (gnus-browse-mode)
 793         (setq mode-line-buffer-identification
 794               (list
 795                (format
 796                 "Gnus: %%b {%s:%s}" (car method) (cadr method))))
 797         (let ((buffer-read-only nil)
 798               name
 799               (prefix (let ((gnus-select-method orig-select-method))
 800                         (gnus-group-prefixed-name "" method))))
 801           (while (setq group (pop groups))
 802             (gnus-add-text-properties
 803              (point)
 804              (prog1 (1+ (point))
 805                (insert
 806                 (format "%c%7d: %s\n"
 807                         (let ((level (gnus-group-level
 808                                       (concat prefix (setq name (car group))))))
 809                               (cond
 810                                ((<= level gnus-level-subscribed) ? )
 811                                ((<= level gnus-level-unsubscribed) ?U)
 812                                ((= level gnus-level-zombie) ?Z)
 813                                (t ?K)))
 814                         (max 0 (- (1+ (cddr group)) (cadr group)))
 815                         (mm-decode-coding-string
 816                          name
 817                          (inline (gnus-group-name-charset method name))))))
 818              (list 'gnus-group name))))
 819         (switch-to-buffer (current-buffer)))
 820       (goto-char (point-min))
 821       (gnus-group-position-point)
 822       (gnus-message 5 "Connecting to %s...done" (nth 1 method))
 823       t))))
 824
 825 (defun gnus-browse-mode ()
 826   "Major mode for browsing a foreign server.
 827
 828 All normal editing commands are switched off.
 829
 830 \\<gnus-browse-mode-map>
 831 The only things you can do in this buffer is
 832
 833 1) `\\[gnus-browse-unsubscribe-current-group]' to subscribe to a group.
 834 The group will be inserted into the group buffer upon exit from this
 835 buffer.
 836
 837 2) `\\[gnus-browse-read-group]' to read a group ephemerally.
 838
 839 3) `\\[gnus-browse-exit]' to return to the group buffer."
 840   (interactive)
 841   (kill-all-local-variables)
 842   (when (gnus-visual-p 'browse-menu 'menu)
 843     (gnus-browse-make-menu-bar))
 844   (gnus-simplify-mode-line)
 845   (setq major-mode 'gnus-browse-mode)
 846   (setq mode-name "Browse Server")
 847   (setq mode-line-process nil)
 848   (use-local-map gnus-browse-mode-map)
 849   (buffer-disable-undo)
 850   (setq truncate-lines t)
 851   (gnus-set-default-directory)
 852   (setq buffer-read-only t)
 853   (gnus-run-mode-hooks 'gnus-browse-mode-hook))
 854
 855 (defun gnus-browse-read-group (&optional no-article number)
 856   "Enter the group at the current line.
 857 If NUMBER, fetch this number of articles."
 858   (interactive "P")
 859   (let ((group (gnus-browse-group-name)))
 860     (if (or (not (gnus-get-info group))
 861             (gnus-ephemeral-group-p group))
 862         (unless (gnus-group-read-ephemeral-group
 863                  group gnus-browse-current-method nil
 864                  (cons (current-buffer) 'browse)
 865                  nil nil nil number)
 866           (error "Couldn't enter %s" group))
 867       (unless (gnus-group-read-group nil no-article group)
 868         (error "Couldn't enter %s" group)))))
 869
 870 (defun gnus-browse-select-group (&optional number)
 871   "Select the current group.
 872 If NUMBER, fetch this number of articles."
 873   (interactive "P")
 874   (gnus-browse-read-group 'no number))
 875
 876 (defun gnus-browse-next-group (n)
 877   "Go to the next group."
 878   (interactive "p")
 879   (prog1
 880       (forward-line n)
 881     (gnus-group-position-point)))
 882
 883 (defun gnus-browse-prev-group (n)
 884   "Go to the next group."
 885   (interactive "p")
 886   (gnus-browse-next-group (- n)))
 887
 888 (defun gnus-browse-unsubscribe-current-group (arg)
 889   "(Un)subscribe to the next ARG groups."
 890   (interactive "p")
 891   (when (eobp)
 892     (error "No group at current line"))
 893   (let ((ward (if (< arg 0) -1 1))
 894         (arg (abs arg)))
 895     (while (and (> arg 0)
 896                 (not (eobp))
 897                 (gnus-browse-unsubscribe-group)
 898                 (zerop (gnus-browse-next-group ward)))
 899       (decf arg))
 900     (gnus-group-position-point)
 901     (when (/= 0 arg)
 902       (gnus-message 7 "No more newsgroups"))
 903     arg))
 904
 905 (defun gnus-browse-group-name ()
 906   (save-excursion
 907     (beginning-of-line)
 908     (let ((name (get-text-property (point) 'gnus-group)))
 909       (when (re-search-forward ": \\(.*\\)$" (gnus-point-at-eol) t)
 910         (concat (gnus-method-to-server-name gnus-browse-current-method) ":"
 911                 (or name
 912                     (match-string-no-properties 1)))))))
 913
 914 (defun gnus-browse-describe-group (group)
 915   "Describe the current group."
 916   (interactive (list (gnus-browse-group-name)))
 917   (gnus-group-describe-group nil group))
 918
 919 (defun gnus-browse-unsubscribe-group ()
 920   "Toggle subscription of the current group in the browse buffer."
 921   (let ((sub nil)
 922         (buffer-read-only nil)
 923         group)
 924     (save-excursion
 925       (beginning-of-line)
 926       ;; If this group it killed, then we want to subscribe it.
 927       (unless (eq (char-after) ? )
 928         (setq sub t))
 929       (setq group (gnus-browse-group-name))
 930       (when (gnus-server-equal gnus-browse-current-method "native")
 931         (setq group (gnus-group-real-name group)))
 932       (if sub
 933           (progn
 934             ;; Make sure the group has been properly removed before we
 935             ;; subscribe to it.
 936             (gnus-kill-ephemeral-group group)
 937             (gnus-group-change-level
 938              (list t group gnus-level-default-subscribed
 939                    nil nil (if (gnus-server-equal
 940                                 gnus-browse-current-method "native")
 941                                nil
 942                              (gnus-method-simplify
 943                               gnus-browse-current-method)))
 944              gnus-level-default-subscribed (gnus-group-level group)
 945              (and (car (nth 1 gnus-newsrc-alist))
 946                   (gnus-gethash (car (nth 1 gnus-newsrc-alist))
 947                                 gnus-newsrc-hashtb))
 948              t)
 949             (delete-char 1)
 950             (insert ? ))
 951         (gnus-group-change-level
 952          group gnus-level-unsubscribed gnus-level-default-subscribed)
 953         (delete-char 1)
 954         (insert ?U)))
 955     t))
 956
 957 (defun gnus-browse-exit ()
 958   "Quit browsing and return to the group buffer."
 959   (interactive)
 960   (when (eq major-mode 'gnus-browse-mode)
 961     (gnus-kill-buffer (current-buffer)))
 962   ;; Insert the newly subscribed groups in the group buffer.
 963   (save-excursion
 964     (set-buffer gnus-group-buffer)
 965     (gnus-group-list-groups nil))
 966   (if gnus-browse-return-buffer
 967       (gnus-configure-windows 'server 'force)
 968     (gnus-configure-windows 'group 'force)))
 969
 970 (defun gnus-browse-describe-briefly ()
 971   "Give a one line description of the group mode commands."
 972   (interactive)
 973   (gnus-message 6
 974                 (substitute-command-keys "\\<gnus-browse-mode-map>\\[gnus-group-next-group]:Forward  \\[gnus-group-prev-group]:Backward  \\[gnus-browse-exit]:Exit  \\[gnus-info-find-node]:Run Info  \\[gnus-browse-describe-briefly]:This help")))
 975
 976 (defun gnus-server-regenerate-server ()
 977   "Issue a command to the server to regenerate all its data structures."
 978   (interactive)
 979   (let ((server (gnus-server-server-name)))
 980     (unless server
 981       (error "No server on the current line"))
 982     (condition-case ()
 983         (gnus-get-function (gnus-server-to-method server)
 984                            'request-regenerate)
 985       (error
 986         (error "This backend doesn't support regeneration")))
 987     (gnus-message 5 "Requesting regeneration of %s..." server)
 988     (unless (gnus-open-server server)
 989       (error "Couldn't open server"))
 990     (if (gnus-request-regenerate server)
 991         (gnus-message 5 "Requesting regeneration of %s...done" server)
 992       (gnus-message 5 "Couldn't regenerate %s" server))))
 993
 994 (provide 'gnus-srvr)
 995
 996 ;;; arch-tag: c0117f64-27ca-475d-9406-8da6854c7a25
 997 ;;; gnus-srvr.el ends here