code.delx.au - gnu-emacs/blob - lisp/calendar/lunar.el

   1 ;;; lunar.el --- calendar functions for phases of the moon.
   2
   3 ;; Copyright (C) 1992, 1993, 1995 Free Software Foundation, Inc.
   4
   5 ;; Author: Edward M. Reingold <reingold@cs.uiuc.edu>
   6 ;; Keywords: calendar
   7 ;; Human-Keywords: moon, lunar phases, calendar, diary
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  23 ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; This collection of functions implements lunar phases for calendar.el and
  28 ;; diary.el.
  29
  30 ;; Based on ``Astronomical Formulae for Calculators,'' 3rd ed., by Jean Meeus,
  31 ;; Willmann-Bell, Inc., 1985 and ``Astronomical Algorithms'' by Jean Meeus,
  32 ;; Willmann-Bell, Inc., 1991.
  33 ;;
  34 ;; WARNING: The calculations will be accurate only to within a few minutes.
  35
  36 ;; The author would be delighted to have an astronomically more sophisticated
  37 ;; person rewrite the code for the lunar calculations in this file!
  38
  39 ;; Comments, corrections, and improvements should be sent to
  40 ;;  Edward M. Reingold               Department of Computer Science
  41 ;;  (217) 333-6733                   University of Illinois at Urbana-Champaign
  42 ;;  reingold@cs.uiuc.edu             1304 West Springfield Avenue
  43 ;;                                   Urbana, Illinois 61801
  44
  45 ;;; Code:
  46
  47 (if (fboundp 'atan)
  48     (require 'lisp-float-type)
  49   (error "Lunar calculations impossible since floating point is unavailable."))
  50
  51 (require 'solar)
  52
  53 (defun lunar-phase-list (month year)
  54   "List of lunar phases for three months starting with Gregorian MONTH, YEAR."
  55   (let ((end-month month)
  56         (end-year year)
  57         (start-month month)
  58         (start-year year))
  59     (increment-calendar-month end-month end-year 3)
  60     (increment-calendar-month start-month start-year -1)
  61     (let* ((end-date (list (list end-month 1 end-year)))
  62            (start-date (list (list start-month
  63                                    (calendar-last-day-of-month
  64                                     start-month start-year)
  65                                    start-year)))
  66            (index (* 4
  67                      (truncate
  68                       (* 12.3685
  69                          (+ year
  70                             ( / (calendar-day-number (list month 1 year))
  71                                 366.0)
  72                             -1900)))))
  73            (new-moon (lunar-phase index))
  74            (list))
  75       (while (calendar-date-compare new-moon end-date)
  76         (if (calendar-date-compare start-date new-moon)
  77             (setq list (append list (list new-moon))))
  78         (setq index (1+ index))
  79         (setq new-moon (lunar-phase index)))
  80       list)))
  81
  82 (defun lunar-phase (index)
  83   "Local date and time of lunar phase INDEX.
  84 Integer below INDEX/4 gives the lunation number, counting from Jan 1, 1900;
  85 remainder mod 4 gives the phase: 0 new moon, 1 first quarter, 2 full moon,
  86 3 last quarter."
  87   (let* ((phase (mod index 4))
  88          (index (/ index 4.0))
  89          (time (/ index 1236.85))
  90          (date (+ (calendar-absolute-from-gregorian '(1 0.5 1900))
  91                   0.75933
  92                   (* 29.53058868 index)
  93                   (* 0.0001178 time time)
  94                   (* -0.000000155 time time time)
  95                   (* 0.00033
  96                      (solar-sin-degrees (+ 166.56
  97                                            (* 132.87 time)
  98                                            (* -0.009173 time time))))))
  99          (sun-anomaly (mod
 100                        (+ 359.2242
 101                           (* 29.105356 index)
 102                           (* -0.0000333 time time)
 103                           (* -0.00000347 time time time))
 104                        360.0))
 105          (moon-anomaly (mod
 106                         (+ 306.0253
 107                            (* 385.81691806 index)
 108                            (* 0.0107306 time time)
 109                            (* 0.00001236 time time time))
 110                         360.0))
 111          (moon-lat (mod
 112                     (+ 21.2964
 113                        (* 390.67050646 index)
 114                        (* -0.0016528 time time)
 115                        (* -0.00000239 time time time))
 116                     360.0))
 117          (adjustment
 118           (if (memq phase '(0 2))
 119               (+ (* (- 0.1734 (* 0.000393 time))
 120                     (solar-sin-degrees sun-anomaly))
 121                  (* 0.0021 (solar-sin-degrees (* 2 sun-anomaly)))
 122                  (* -0.4068 (solar-sin-degrees moon-anomaly))
 123                  (* 0.0161 (solar-sin-degrees (* 2 moon-anomaly)))
 124                  (* -0.0004 (solar-sin-degrees (* 3 moon-anomaly)))
 125                  (* 0.0104 (solar-sin-degrees (* 2 moon-lat)))
 126                  (* -0.0051 (solar-sin-degrees (+ sun-anomaly moon-anomaly)))
 127                  (* -0.0074 (solar-sin-degrees (- sun-anomaly moon-anomaly)))
 128                  (* 0.0004 (solar-sin-degrees (+ (* 2 moon-lat) sun-anomaly)))
 129                  (* -0.0004 (solar-sin-degrees (- (* 2 moon-lat) sun-anomaly)))
 130                  (* -0.0006 (solar-sin-degrees
 131                              (+ (* 2 moon-lat) moon-anomaly)))
 132                  (* 0.0010 (solar-sin-degrees (- (* 2 moon-lat) moon-anomaly)))
 133                  (* 0.0005 (solar-sin-degrees
 134                             (+ (* 2 moon-anomaly) sun-anomaly))))
 135             (+ (* (- 0.1721 (* 0.0004 time))
 136                   (solar-sin-degrees sun-anomaly))
 137                (* 0.0021 (solar-sin-degrees (* 2 sun-anomaly)))
 138                (* -0.6280 (solar-sin-degrees moon-anomaly))
 139                (* 0.0089 (solar-sin-degrees (* 2 moon-anomaly)))
 140                (* -0.0004 (solar-sin-degrees (* 3 moon-anomaly)))
 141                (* 0.0079 (solar-sin-degrees (* 2 moon-lat)))
 142                (* -0.0119 (solar-sin-degrees (+ sun-anomaly moon-anomaly)))
 143                (* -0.0047 (solar-sin-degrees (- sun-anomaly moon-anomaly)))
 144                (* 0.0003 (solar-sin-degrees (+ (* 2 moon-lat) sun-anomaly)))
 145                (* -0.0004 (solar-sin-degrees (- (* 2 moon-lat) sun-anomaly)))
 146                (* -0.0006 (solar-sin-degrees (+ (* 2 moon-lat) moon-anomaly)))
 147                (* 0.0021 (solar-sin-degrees (- (* 2 moon-lat) moon-anomaly)))
 148                (* 0.0003 (solar-sin-degrees
 149                           (+ (* 2 moon-anomaly) sun-anomaly)))
 150                (* 0.0004 (solar-sin-degrees
 151                           (- sun-anomaly (* 2 moon-anomaly))))
 152                (* -0.0003 (solar-sin-degrees
 153                           (+ (* 2 sun-anomaly) moon-anomaly))))))
 154          (adj (+ 0.0028
 155                  (* -0.0004 (solar-cosine-degrees
 156                              sun-anomaly))
 157                  (* 0.0003 (solar-cosine-degrees
 158                             moon-anomaly))))
 159          (adjustment (cond ((= phase 1) (+ adjustment adj))
 160                            ((= phase 2) (- adjustment adj))
 161                            (t adjustment)))
 162          (date (+ date adjustment))
 163          (date (+ date (/ (- calendar-time-zone
 164                              (solar-ephemeris-correction
 165                               (extract-calendar-year
 166                                (calendar-gregorian-from-absolute
 167                                 (truncate date)))))
 168                           60.0 24.0)))
 169          (time (* 24 (- date (truncate date))))
 170          (date (calendar-gregorian-from-absolute (truncate date)))
 171          (adj (dst-adjust-time date time)))
 172     (list (car adj) (apply 'solar-time-string (cdr adj)) phase)))
 173
 174 (defun lunar-phase-name (phase)
 175   "Name of lunar PHASE.
 176 0 = new moon, 1 = first quarter, 2 = full moon, 3 = last quarter."
 177   (cond ((= 0 phase) "New Moon")
 178         ((= 1 phase) "First Quarter Moon")
 179         ((= 2 phase) "Full Moon")
 180         ((= 3 phase) "Last Quarter Moon")))
 181
 182 (defun calendar-phases-of-moon ()
 183   "Create a buffer with the lunar phases for the current calendar window."
 184   (interactive)
 185   (message "Computing phases of the moon...")
 186   (let ((m1 displayed-month)
 187         (y1 displayed-year)
 188         (m2 displayed-month)
 189         (y2 displayed-year))
 190     (increment-calendar-month m1 y1 -1)
 191     (increment-calendar-month m2 y2 1)
 192     (set-buffer (get-buffer-create lunar-phases-buffer))
 193     (setq buffer-read-only nil)
 194     (calendar-set-mode-line
 195      (if (= y1 y2)
 196          (format "Phases of the Moon from %s to %s, %d%%-"
 197                  (calendar-month-name m1) (calendar-month-name m2) y2)
 198        (format "Phases of the Moon from %s, %d to %s, %d%%-"
 199                (calendar-month-name m1) y1 (calendar-month-name m2) y2)))
 200     (erase-buffer)
 201     (insert
 202      (mapconcat
 203       '(lambda (x)
 204          (let ((date (car x))
 205                (time (car (cdr x)))
 206                (phase (car (cdr (cdr x)))))
 207            (concat (calendar-date-string date)
 208                    ": "
 209                    (lunar-phase-name phase)
 210                    " "
 211                    time)))
 212       (lunar-phase-list m1 y1) "\n"))
 213     (goto-char (point-min))
 214     (set-buffer-modified-p nil)
 215     (setq buffer-read-only t)
 216     (display-buffer lunar-phases-buffer)
 217     (message "Computing phases of the moon...done")))
 218
 219 ;;;###autoload
 220 (defun phases-of-moon (&optional arg)
 221   "Display the quarters of the moon for last month, this month, and next month.
 222 If called with an optional prefix argument, prompts for month and year.
 223
 224 This function is suitable for execution in a .emacs file."
 225   (interactive "P")
 226   (save-excursion
 227     (let* ((date (if arg
 228                      (calendar-read-date t)
 229                    (calendar-current-date)))
 230            (displayed-month (extract-calendar-month date))
 231            (displayed-year (extract-calendar-year date)))
 232       (calendar-phases-of-moon))))
 233
 234 (defun diary-phases-of-moon ()
 235   "Moon phases diary entry."
 236   (let* ((index (* 4
 237                    (truncate
 238                     (* 12.3685
 239                        (+ (extract-calendar-year date)
 240                           ( / (calendar-day-number date)
 241                               366.0)
 242                           -1900)))))
 243          (phase (lunar-phase index)))
 244     (while (calendar-date-compare phase (list date))
 245       (setq index (1+ index))
 246       (setq phase (lunar-phase index)))
 247     (if (calendar-date-equal (car phase) date)
 248         (concat (lunar-phase-name (car (cdr (cdr phase)))) " "
 249                 (car (cdr phase))))))
 250
 251
 252 ;;  For the Chinese calendar the calculations for the new moon need to be more
 253 ;;  accurate than those above, so we use more terms in the approximation.
 254
 255 (defun lunar-new-moon-time (k)
 256   "Astronomical (Julian) day number of K th new moon."
 257   (let* ((T (/ k 1236.85))
 258          (T2 (* T T))
 259          (T3 (* T T T))
 260          (T4 (* T2 T2))
 261          (JDE (+ 2451550.09765
 262                  (* 29.530588853 k)
 263                  (* 0.0001337 T2)
 264                  (* -0.000000150 T3)
 265                  (* 0.00000000073 T4)))
 266          (E (- 1 (* 0.002516 T) (* 0.0000074 T2)))
 267          (sun-anomaly (+ 2.5534
 268                          (* 29.10535669 k)
 269                          (* -0.0000218 T2)
 270                          (* -0.00000011 T3)))
 271          (moon-anomaly (+ 201.5643
 272                           (* 385.81693528 k)
 273                           (* 0.0107438 T2)
 274                           (* 0.00001239 T3)
 275                           (* -0.000000058 T4)))
 276          (moon-argument (+ 160.7108
 277                            (* 390.67050274 k)
 278                            (* -0.0016341 T2)
 279                            (* -0.00000227 T3)
 280                            (* 0.000000011 T4)))
 281          (omega (+ 124.7746
 282                    (* -1.56375580 k)
 283                    (* 0.0020691 T2)
 284                    (* 0.00000215 T3)))
 285          (A1  (+ 299.77 (*  0.107408 k) (* -0.009173 T2)))
 286          (A2  (+ 251.88 (*  0.016321 k)))
 287          (A3  (+ 251.83 (* 26.641886 k)))
 288          (A4  (+ 349.42 (* 36.412478 k)))
 289          (A5  (+  84.66 (* 18.206239 k)))
 290          (A6  (+ 141.74 (* 53.303771 k)))
 291          (A7  (+ 207.14 (*  2.453732 k)))
 292          (A8  (+ 154.84 (*  7.306860 k)))
 293          (A9  (+  34.52 (* 27.261239 k)))
 294          (A10 (+ 207.19 (*  0.121824 k)))
 295          (A11 (+ 291.34 (*  1.844379 k)))
 296          (A12 (+ 161.72 (* 24.198154 k)))
 297          (A13 (+ 239.56 (* 25.513099 k)))
 298          (A14 (+ 331.55 (*  3.592518 k)))
 299          (correction
 300             (+ (* -0.40720   (solar-sin-degrees moon-anomaly))
 301                (*  0.17241 E (solar-sin-degrees sun-anomaly))
 302                (*  0.01608   (solar-sin-degrees (* 2 moon-anomaly)))
 303                (*  0.01039   (solar-sin-degrees (* 2 moon-argument)))
 304                (*  0.00739 E (solar-sin-degrees (- moon-anomaly sun-anomaly)))
 305                (* -0.00514 E (solar-sin-degrees (+ moon-anomaly sun-anomaly)))
 306                (*  0.00208 E E (solar-sin-degrees (* 2 sun-anomaly)))
 307                (* -0.00111   (solar-sin-degrees
 308                                (- moon-anomaly (* 2 moon-argument))))
 309                (* -0.00057   (solar-sin-degrees
 310                                (+ moon-anomaly (* 2 moon-argument))))
 311                (*  0.00056 E (solar-sin-degrees
 312                                (+ (* 2 moon-anomaly) sun-anomaly)))
 313                (* -0.00042   (solar-sin-degrees (* 3 moon-anomaly)))
 314                (*  0.00042 E (solar-sin-degrees
 315                                (+ sun-anomaly (* 2 moon-argument))))
 316                (*  0.00038 E (solar-sin-degrees
 317                                (- sun-anomaly (* 2 moon-argument))))
 318                (* -0.00024 E (solar-sin-degrees
 319                                (- (* 2 moon-anomaly) sun-anomaly)))
 320                (* -0.00017   (solar-sin-degrees omega))
 321                (* -0.00007   (solar-sin-degrees
 322                                (+ moon-anomaly (* 2 sun-anomaly))))
 323                (*  0.00004   (solar-sin-degrees
 324                                (- (* 2 moon-anomaly) (* 2 moon-argument))))
 325                (*  0.00004   (solar-sin-degrees (* 3 sun-anomaly)))
 326                (*  0.00003   (solar-sin-degrees (+ moon-anomaly sun-anomaly
 327                                                    (* -2 moon-argument))))
 328                (*  0.00003   (solar-sin-degrees
 329                                (+ (* 2 moon-anomaly) (* 2 moon-argument))))
 330                (* -0.00003   (solar-sin-degrees (+ moon-anomaly sun-anomaly
 331                                                    (* 2 moon-argument))))
 332                (*  0.00003   (solar-sin-degrees (- moon-anomaly sun-anomaly
 333                                                    (* -2 moon-argument))))
 334                (* -0.00002   (solar-sin-degrees (- moon-anomaly sun-anomaly
 335                                                    (* 2 moon-argument))))
 336                (* -0.00002   (solar-sin-degrees
 337                                (+ (* 3 moon-anomaly) sun-anomaly)))
 338                (*  0.00002   (solar-sin-degrees (* 4 moon-anomaly)))))
 339          (additional
 340             (+ (* 0.000325 (solar-sin-degrees A1))
 341                (* 0.000165 (solar-sin-degrees A2))
 342                (* 0.000164 (solar-sin-degrees A3))
 343                (* 0.000126 (solar-sin-degrees A4))
 344                (* 0.000110 (solar-sin-degrees A5))
 345                (* 0.000062 (solar-sin-degrees A6))
 346                (* 0.000060 (solar-sin-degrees A7))
 347                (* 0.000056 (solar-sin-degrees A8))
 348                (* 0.000047 (solar-sin-degrees A9))
 349                (* 0.000042 (solar-sin-degrees A10))
 350                (* 0.000040 (solar-sin-degrees A11))
 351                (* 0.000037 (solar-sin-degrees A12))
 352                (* 0.000035 (solar-sin-degrees A13))
 353                (* 0.000023 (solar-sin-degrees A14))))
 354          (newJDE (+ JDE correction additional)))
 355     (+ newJDE
 356        (- (solar-ephemeris-correction
 357            (extract-calendar-year
 358             (calendar-gregorian-from-absolute
 359              (floor (calendar-absolute-from-astro newJDE))))))
 360        (/ calendar-time-zone 60.0 24.0))))
 361
 362 (defun lunar-new-moon-on-or-after (d)
 363   "Astronomical (Julian) day number of first new moon on or after astronomical
 364 (Julian) day number d.  The fractional part is the time of day.
 365
 366 The date and time are local time, including any daylight savings rules,
 367 as governed by the values of calendar-daylight-savings-starts,
 368 calendar-daylight-savings-starts-time, calendar-daylight-savings-ends,
 369 calendar-daylight-savings-ends-time, calendar-daylight-time-offset, and
 370 calendar-time-zone."
 371   (let* ((date (calendar-gregorian-from-absolute
 372                 (floor (calendar-absolute-from-astro d))))
 373          (year (+ (extract-calendar-year date)
 374                   (/ (calendar-day-number date) 365.25)))
 375          (k (floor (* (- year 2000.0) 12.3685)))
 376          (date (lunar-new-moon-time k)))
 377     (while (< date d)
 378       (setq k (1+ k))
 379       (setq date (lunar-new-moon-time k)))
 380     (let* ((a-date (calendar-absolute-from-astro date))
 381            (time (* 24 (- a-date (truncate a-date))))
 382            (date (calendar-gregorian-from-absolute (truncate a-date)))
 383            (adj (dst-adjust-time date time)))
 384       (calendar-astro-from-absolute
 385        (+ (calendar-absolute-from-gregorian (car adj))
 386           (/ (car (cdr adj)) 24.0))))))
 387
 388 (provide 'lunar)
 389
 390 ;;; lunar.el ends here