code.delx.au - gnu-emacs/blob - lisp/gnus/spam-report.el

   1 ;;; spam-report.el --- Reporting spam
   2
   3 ;; Copyright (C) 2002, 2003, 2004, 2005, 2006 Free Software Foundation, Inc.
   4
   5 ;; Author: Teodor Zlatanov <tzz@lifelogs.com>
   6 ;; Keywords: network
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  23 ;; Boston, MA 02110-1301, USA.
  24
  25 ;;; Commentary:
  26
  27 ;;; This module addresses a few aspects of spam reporting under Gnus.  Page
  28 ;;; breaks are used for grouping declarations and documentation relating to
  29 ;;; each particular aspect.
  30
  31 ;;; Code:
  32 (require 'gnus)
  33 (require 'gnus-sum)
  34
  35 (eval-and-compile
  36   (autoload 'mm-url-insert "mm-url"))
  37
  38 (defgroup spam-report nil
  39   "Spam reporting configuration."
  40   :group 'mail
  41   :group 'news)
  42
  43 (defcustom spam-report-gmane-regex nil
  44   "Regexp matching Gmane newsgroups, e.g. \"^nntp\\+.*:gmane\\.\"
  45 If you are using spam.el, consider setting gnus-spam-process-newsgroups
  46 or the gnus-group-spam-exit-processor-report-gmane group/topic parameter
  47 instead."
  48   :type '(radio (const nil)
  49                 (regexp :value "^nntp\+.*:gmane\."))
  50   :group 'spam-report)
  51
  52 (defcustom spam-report-gmane-use-article-number t
  53   "Whether the article number (faster!) or the header should be used."
  54   :type 'boolean
  55   :group 'spam-report)
  56
  57 (defcustom spam-report-url-ping-function
  58   'spam-report-url-ping-plain
  59   "Function to use for url ping spam reporting.
  60 The function must accept the arguments `host' and `report'."
  61   :type '(choice
  62           (const :tag "Connect directly"
  63                  spam-report-url-ping-plain)
  64           (const :tag "Use the external program specified in `mm-url-program'"
  65                  spam-report-url-ping-mm-url)
  66           (const :tag "Store request URLs in `spam-report-requests-file'"
  67                  spam-report-url-to-file)
  68           (function :tag "User defined function" nil))
  69   :group 'spam-report)
  70
  71 (defcustom spam-report-requests-file
  72   (nnheader-concat gnus-directory "spam/" "spam-report-requests.url")
  73   ;; Is there a convention for the extension of such a file?
  74   ;; Should we use `spam-directory'?
  75   "File where spam report request are stored."
  76   :type 'file
  77   :group 'spam-report)
  78
  79 (defvar spam-report-url-ping-temp-agent-function nil
  80   "Internal variable for `spam-report-agentize' and `spam-report-deagentize'.
  81 This variable will store the value of `spam-report-url-ping-function' from
  82 before `spam-report-agentize' was run, so that `spam-report-deagentize' can
  83 undo that change.")
  84
  85 (defun spam-report-gmane (&rest articles)
  86   "Report an article as spam through Gmane"
  87   (dolist (article articles)
  88     (when (and gnus-newsgroup-name
  89                (or (null spam-report-gmane-regex)
  90                    (string-match spam-report-gmane-regex gnus-newsgroup-name)))
  91       (gnus-message 6 "Reporting spam article %d to spam.gmane.org..." article)
  92       (if spam-report-gmane-use-article-number
  93           (spam-report-url-ping
  94            "spam.gmane.org"
  95            (format "/%s:%d"
  96                    (gnus-group-real-name gnus-newsgroup-name)
  97                    article))
  98         (with-current-buffer nntp-server-buffer
  99           (gnus-request-head article gnus-newsgroup-name)
 100           (let ((case-fold-search t)
 101                 field host report url)
 102             ;; First check for X-Report-Spam because it's more specific to
 103             ;; spam reporting than Archived-At.  OTOH, all new articles on
 104             ;; Gmane don't have X-Report-Spam anymore (unless Lars changes his
 105             ;; mind :-)).
 106             ;;
 107             ;; There might be more than one Archived-At header so we need to
 108             ;; find (and transform) the one related to Gmane.
 109             (setq field (or (gnus-fetch-field "X-Report-Spam")
 110                             (gnus-fetch-field "Archived-At")))
 111             (setq host (progn
 112                          (string-match
 113                           (concat "http://\\([a-z]+\\.gmane\\.org\\)"
 114                                   "\\(/[^:/]+[:/][0-9]+\\)")
 115                           field)
 116                          (match-string 1 field)))
 117             (setq report (match-string 2 field))
 118             (when (string-equal "permalink.gmane.org" host)
 119               (setq host "spam.gmane.org")
 120               (setq report (gnus-replace-in-string
 121                             report "/\\([0-9]+\\)$" ":\\1")))
 122             (setq url (format "http://%s%s" host report))
 123             (if (not (and host report url))
 124                 (gnus-message
 125                  3 "Could not find a spam report header in article %d..."
 126                  article)
 127               (gnus-message 7 "Reporting spam through URL %s..." url)
 128               (spam-report-url-ping host report))))))))
 129
 130 (defun spam-report-url-ping (host report)
 131   "Ping a host through HTTP, addressing a specific GET resource using
 132 the function specified by `spam-report-url-ping-function'."
 133   ;; Example:
 134   ;; host: "spam.gmane.org"
 135   ;; report: "/gmane.some.group:123456"
 136   (funcall spam-report-url-ping-function host report))
 137
 138 (defun spam-report-url-ping-plain (host report)
 139   "Ping a host through HTTP, addressing a specific GET resource."
 140   (let ((tcp-connection))
 141     (with-temp-buffer
 142       (or (setq tcp-connection
 143                 (open-network-stream
 144                  "URL ping"
 145                  (buffer-name)
 146                  host
 147                  80))
 148           (error "Could not open connection to %s" host))
 149       (set-marker (process-mark tcp-connection) (point-min))
 150       (process-send-string
 151        tcp-connection
 152        (format "GET %s HTTP/1.1\nUser-Agent: %s (spam-report.el)\nHost: %s\n\n"
 153                report (gnus-extended-version) host)))))
 154
 155 ;;;###autoload
 156 (defun spam-report-process-queue (&optional file keep)
 157   "Report all queued requests from `spam-report-requests-file'.
 158
 159 If FILE is given, use it instead of `spam-report-requests-file'.
 160 If KEEP is t, leave old requests in the file.  If KEEP is the
 161 symbol `ask', query before flushing the queue file."
 162   (interactive
 163    (list (read-file-name
 164           "File: "
 165           (file-name-directory spam-report-requests-file)
 166           spam-report-requests-file
 167           nil
 168           (file-name-nondirectory spam-report-requests-file))
 169          current-prefix-arg))
 170   (if (eq spam-report-url-ping-function 'spam-report-url-to-file)
 171       (error (concat "Cannot process requests when "
 172                      "`spam-report-url-ping-function' is "
 173                      "`spam-report-url-to-file'."))
 174     (gnus-message 7 "Processing requests using `%s'."
 175                   spam-report-url-ping-function))
 176   (or file (setq file spam-report-requests-file))
 177   (save-excursion
 178     (set-buffer (find-file-noselect file))
 179     (goto-char (point-min))
 180     (while (and (not (eobp))
 181                 (re-search-forward
 182                  "http://\\([^/]+\\)\\(/.*\\) *$" (gnus-point-at-eol) t))
 183       (funcall spam-report-url-ping-function (match-string 1) (match-string 2))
 184       (forward-line 1))
 185     (if (or (eq keep nil)
 186             (and (eq keep 'ask)
 187                  (y-or-n-p
 188                   (format
 189                    "Flush requests from `%s'? " (current-buffer)))))
 190         (progn
 191           (gnus-message 7 "Flushing request file `%s'"
 192                         spam-report-requests-file)
 193           (erase-buffer)
 194           (save-buffer)
 195           (kill-buffer (current-buffer)))
 196       (gnus-message 7 "Keeping requests in `%s'" spam-report-requests-file))))
 197
 198 ;;;###autoload
 199 (defun spam-report-url-ping-mm-url (host report)
 200   "Ping a host through HTTP, addressing a specific GET resource. Use
 201 the external program specified in `mm-url-program' to connect to
 202 server."
 203   (with-temp-buffer
 204     (let ((url (format "http://%s%s" host report)))
 205       (mm-url-insert url t))))
 206
 207 ;;;###autoload
 208 (defun spam-report-url-to-file (host report)
 209   "Collect spam report requests in `spam-report-requests-file'.
 210 Customize `spam-report-url-ping-function' to use this function."
 211   (let ((url (format "http://%s%s" host report))
 212         (file spam-report-requests-file))
 213     (gnus-make-directory (file-name-directory file))
 214     (gnus-message 9 "Writing URL `%s' to file `%s'" url file)
 215     (with-temp-buffer
 216       (insert url)
 217       (newline)
 218       (append-to-file (point-min) (point-max) file))))
 219
 220 ;;;###autoload
 221 (defun spam-report-agentize ()
 222   "Add spam-report support to the Agent.
 223 Spam reports will be queued with \\[spam-report-url-to-file] when
 224 the Agent is unplugged, and will be submitted in a batch when the
 225 Agent is plugged."
 226   (interactive)
 227   (add-hook 'gnus-agent-plugged-hook 'spam-report-plug-agent)
 228   (add-hook 'gnus-agent-unplugged-hook 'spam-report-unplug-agent))
 229
 230 ;;;###autoload
 231 (defun spam-report-deagentize ()
 232   "Remove spam-report support from the Agent.
 233 Spam reports will be queued with the method used when
 234 \\[spam-report-agentize] was run."
 235   (interactive)
 236   (remove-hook 'gnus-agent-plugged-hook 'spam-report-plug-agent)
 237   (remove-hook 'gnus-agent-unplugged-hook 'spam-report-unplug-agent))
 238
 239 (defun spam-report-plug-agent ()
 240   "Adjust spam report settings for plugged state.
 241 Process queued spam reports."
 242   ;; Process the queue, unless the user only wanted to report to a file
 243   ;; anyway.
 244   (unless (equal spam-report-url-ping-temp-agent-function
 245                  'spam-report-url-to-file)
 246     (spam-report-process-queue))
 247   ;; Set the reporting function, if we have memorized something otherwise,
 248   ;; stick with plain URL reporting.
 249   (setq spam-report-url-ping-function
 250         (or spam-report-url-ping-temp-agent-function
 251             'spam-report-url-ping-plain)))
 252
 253 (defun spam-report-unplug-agent ()
 254   "Restore spam report settings for unplugged state."
 255   ;; save the old value
 256   (setq spam-report-url-ping-temp-agent-function
 257         spam-report-url-ping-function)
 258   ;; store all reports to file
 259   (setq spam-report-url-ping-function
 260         'spam-report-url-to-file))
 261
 262 (provide 'spam-report)
 263
 264 ;;; arch-tag: f6683295-ec89-4ab5-8803-8cc842293022
 265 ;;; spam-report.el ends here.