code.delx.au - gnu-emacs/blob - lisp/progmodes/elisp-mode.el

   1 ;;; elisp-mode.el --- Emacs Lisp mode  -*- lexical-binding:t -*-
   2
   3 ;; Copyright (C) 1985-1986, 1999-2015 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: emacs-devel@gnu.org
   6 ;; Keywords: lisp, languages
   7 ;; Package: emacs
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; The major mode for editing Emacs Lisp code.
  27 ;; This mode is documented in the Emacs manual.
  28
  29 ;;; Code:
  30
  31 (require 'cl-generic)
  32 (require 'lisp-mode)
  33 (eval-when-compile (require 'cl-lib))
  34
  35 (define-abbrev-table 'emacs-lisp-mode-abbrev-table ()
  36   "Abbrev table for Emacs Lisp mode.
  37 It has `lisp-mode-abbrev-table' as its parent."
  38   :parents (list lisp-mode-abbrev-table))
  39
  40 (defvar emacs-lisp-mode-syntax-table
  41   (let ((table (make-syntax-table lisp--mode-syntax-table)))
  42     (modify-syntax-entry ?\[ "(]  " table)
  43     (modify-syntax-entry ?\] ")[  " table)
  44     table)
  45   "Syntax table used in `emacs-lisp-mode'.")
  46
  47 (defvar emacs-lisp-mode-map
  48   (let ((map (make-sparse-keymap "Emacs-Lisp"))
  49         (menu-map (make-sparse-keymap "Emacs-Lisp"))
  50         (lint-map (make-sparse-keymap))
  51         (prof-map (make-sparse-keymap))
  52         (tracing-map (make-sparse-keymap)))
  53     (set-keymap-parent map lisp-mode-shared-map)
  54     (define-key map "\e\t" 'completion-at-point)
  55     (define-key map "\e\C-x" 'eval-defun)
  56     (define-key map "\e\C-q" 'indent-pp-sexp)
  57     (bindings--define-key map [menu-bar emacs-lisp]
  58       (cons "Emacs-Lisp" menu-map))
  59     (bindings--define-key menu-map [eldoc]
  60       '(menu-item "Auto-Display Documentation Strings" eldoc-mode
  61                   :button (:toggle . (bound-and-true-p eldoc-mode))
  62                   :help "Display the documentation string for the item under cursor"))
  63     (bindings--define-key menu-map [checkdoc]
  64       '(menu-item "Check Documentation Strings" checkdoc
  65                   :help "Check documentation strings for style requirements"))
  66     (bindings--define-key menu-map [re-builder]
  67       '(menu-item "Construct Regexp" re-builder
  68                   :help "Construct a regexp interactively"))
  69     (bindings--define-key menu-map [tracing] (cons "Tracing" tracing-map))
  70     (bindings--define-key tracing-map [tr-a]
  71       '(menu-item "Untrace All" untrace-all
  72                   :help "Untrace all currently traced functions"))
  73     (bindings--define-key tracing-map [tr-uf]
  74       '(menu-item "Untrace Function..." untrace-function
  75                   :help "Untrace function, and possibly activate all remaining advice"))
  76     (bindings--define-key tracing-map [tr-sep] menu-bar-separator)
  77     (bindings--define-key tracing-map [tr-q]
  78       '(menu-item "Trace Function Quietly..." trace-function-background
  79                   :help "Trace the function with trace output going quietly to a buffer"))
  80     (bindings--define-key tracing-map [tr-f]
  81       '(menu-item "Trace Function..." trace-function
  82                   :help "Trace the function given as an argument"))
  83     (bindings--define-key menu-map [profiling] (cons "Profiling" prof-map))
  84     (bindings--define-key prof-map [prof-restall]
  85       '(menu-item "Remove Instrumentation for All Functions" elp-restore-all
  86                   :help "Restore the original definitions of all functions being profiled"))
  87     (bindings--define-key prof-map [prof-restfunc]
  88       '(menu-item "Remove Instrumentation for Function..." elp-restore-function
  89                   :help "Restore an instrumented function to its original definition"))
  90
  91     (bindings--define-key prof-map [sep-rem] menu-bar-separator)
  92     (bindings--define-key prof-map [prof-resall]
  93       '(menu-item "Reset Counters for All Functions" elp-reset-all
  94                   :help "Reset the profiling information for all functions being profiled"))
  95     (bindings--define-key prof-map [prof-resfunc]
  96       '(menu-item "Reset Counters for Function..." elp-reset-function
  97                   :help "Reset the profiling information for a function"))
  98     (bindings--define-key prof-map [prof-res]
  99       '(menu-item "Show Profiling Results" elp-results
 100                   :help "Display current profiling results"))
 101     (bindings--define-key prof-map [prof-pack]
 102       '(menu-item "Instrument Package..." elp-instrument-package
 103                   :help "Instrument for profiling all function that start with a prefix"))
 104     (bindings--define-key prof-map [prof-func]
 105       '(menu-item "Instrument Function..." elp-instrument-function
 106                   :help "Instrument a function for profiling"))
 107     ;; Maybe this should be in a separate submenu from the ELP stuff?
 108     (bindings--define-key prof-map [sep-natprof] menu-bar-separator)
 109     (bindings--define-key prof-map [prof-natprof-stop]
 110       '(menu-item "Stop Native Profiler" profiler-stop
 111                   :help "Stop recording profiling information"
 112                   :enable (and (featurep 'profiler)
 113                                (profiler-running-p))))
 114     (bindings--define-key prof-map [prof-natprof-report]
 115       '(menu-item "Show Profiler Report" profiler-report
 116                   :help "Show the current profiler report"
 117                   :enable (and (featurep 'profiler)
 118                                (profiler-running-p))))
 119     (bindings--define-key prof-map [prof-natprof-start]
 120       '(menu-item "Start Native Profiler..." profiler-start
 121                   :help "Start recording profiling information"))
 122
 123     (bindings--define-key menu-map [lint] (cons "Linting" lint-map))
 124     (bindings--define-key lint-map [lint-di]
 125       '(menu-item "Lint Directory..." elint-directory
 126                   :help "Lint a directory"))
 127     (bindings--define-key lint-map [lint-f]
 128       '(menu-item "Lint File..." elint-file
 129                   :help "Lint a file"))
 130     (bindings--define-key lint-map [lint-b]
 131       '(menu-item "Lint Buffer" elint-current-buffer
 132                   :help "Lint the current buffer"))
 133     (bindings--define-key lint-map [lint-d]
 134       '(menu-item "Lint Defun" elint-defun
 135                   :help "Lint the function at point"))
 136     (bindings--define-key menu-map [edebug-defun]
 137       '(menu-item "Instrument Function for Debugging" edebug-defun
 138                   :help "Evaluate the top level form point is in, stepping through with Edebug"
 139                   :keys "C-u C-M-x"))
 140     (bindings--define-key menu-map [separator-byte] menu-bar-separator)
 141     (bindings--define-key menu-map [disas]
 142       '(menu-item "Disassemble Byte Compiled Object..." disassemble
 143                   :help "Print disassembled code for OBJECT in a buffer"))
 144     (bindings--define-key menu-map [byte-recompile]
 145       '(menu-item "Byte-recompile Directory..." byte-recompile-directory
 146                   :help "Recompile every `.el' file in DIRECTORY that needs recompilation"))
 147     (bindings--define-key menu-map [emacs-byte-compile-and-load]
 148       '(menu-item "Byte-compile and Load" emacs-lisp-byte-compile-and-load
 149                   :help "Byte-compile the current file (if it has changed), then load compiled code"))
 150     (bindings--define-key menu-map [byte-compile]
 151       '(menu-item "Byte-compile This File" emacs-lisp-byte-compile
 152                   :help "Byte compile the file containing the current buffer"))
 153     (bindings--define-key menu-map [separator-eval] menu-bar-separator)
 154     (bindings--define-key menu-map [ielm]
 155       '(menu-item "Interactive Expression Evaluation" ielm
 156                   :help "Interactively evaluate Emacs Lisp expressions"))
 157     (bindings--define-key menu-map [eval-buffer]
 158       '(menu-item "Evaluate Buffer" eval-buffer
 159                   :help "Execute the current buffer as Lisp code"))
 160     (bindings--define-key menu-map [eval-region]
 161       '(menu-item "Evaluate Region" eval-region
 162                   :help "Execute the region as Lisp code"
 163                   :enable mark-active))
 164     (bindings--define-key menu-map [eval-sexp]
 165       '(menu-item "Evaluate Last S-expression" eval-last-sexp
 166                   :help "Evaluate sexp before point; print value in echo area"))
 167     (bindings--define-key menu-map [separator-format] menu-bar-separator)
 168     (bindings--define-key menu-map [comment-region]
 169       '(menu-item "Comment Out Region" comment-region
 170                   :help "Comment or uncomment each line in the region"
 171                   :enable mark-active))
 172     (bindings--define-key menu-map [indent-region]
 173       '(menu-item "Indent Region" indent-region
 174                   :help "Indent each nonblank line in the region"
 175                   :enable mark-active))
 176     (bindings--define-key menu-map [indent-line]
 177       '(menu-item "Indent Line" lisp-indent-line))
 178     map)
 179   "Keymap for Emacs Lisp mode.
 180 All commands in `lisp-mode-shared-map' are inherited by this map.")
 181
 182 (defun emacs-lisp-byte-compile ()
 183   "Byte compile the file containing the current buffer."
 184   (interactive)
 185   (if buffer-file-name
 186       (byte-compile-file buffer-file-name)
 187     (error "The buffer must be saved in a file first")))
 188
 189 (defun emacs-lisp-byte-compile-and-load ()
 190   "Byte-compile the current file (if it has changed), then load compiled code."
 191   (interactive)
 192   (or buffer-file-name
 193       (error "The buffer must be saved in a file first"))
 194   (require 'bytecomp)
 195   ;; Recompile if file or buffer has changed since last compilation.
 196   (if (and (buffer-modified-p)
 197            (y-or-n-p (format "Save buffer %s first? " (buffer-name))))
 198       (save-buffer))
 199   (byte-recompile-file buffer-file-name nil 0 t))
 200
 201 (defun emacs-lisp-macroexpand ()
 202   "Macroexpand the form after point.
 203 Comments in the form will be lost."
 204   (interactive)
 205   (let* ((start (point))
 206          (exp (read (current-buffer)))
 207          ;; Compute it before, since it may signal errors.
 208          (new (macroexpand-1 exp)))
 209     (if (equal exp new)
 210         (message "Not a macro call, nothing to expand")
 211       (delete-region start (point))
 212       (pp new (current-buffer))
 213       (if (bolp) (delete-char -1))
 214       (indent-region start (point)))))
 215
 216 (defcustom emacs-lisp-mode-hook nil
 217   "Hook run when entering Emacs Lisp mode."
 218   :options '(eldoc-mode imenu-add-menubar-index checkdoc-minor-mode)
 219   :type 'hook
 220   :group 'lisp)
 221
 222 ;;;###autoload
 223 (define-derived-mode emacs-lisp-mode prog-mode "Emacs-Lisp"
 224   "Major mode for editing Lisp code to run in Emacs.
 225 Commands:
 226 Delete converts tabs to spaces as it moves back.
 227 Blank lines separate paragraphs.  Semicolons start comments.
 228
 229 \\{emacs-lisp-mode-map}"
 230   :group 'lisp
 231   (defvar xref-backend-functions)
 232   (defvar project-library-roots-function)
 233   (lisp-mode-variables nil nil 'elisp)
 234   (add-hook 'after-load-functions #'elisp--font-lock-flush-elisp-buffers)
 235   (setq-local electric-pair-text-pairs
 236               (append '((?\` . ?\') (?‘ . ?’)) electric-pair-text-pairs))
 237   (setq-local electric-quote-string t)
 238   (setq imenu-case-fold-search nil)
 239   (add-function :before-until (local 'eldoc-documentation-function)
 240                 #'elisp-eldoc-documentation-function)
 241   (add-hook 'xref-backend-functions #'elisp--xref-backend nil t)
 242   (setq-local project-library-roots-function #'elisp-library-roots)
 243   (add-hook 'completion-at-point-functions
 244             #'elisp-completion-at-point nil 'local))
 245
 246 ;; Font-locking support.
 247
 248 (defun elisp--font-lock-flush-elisp-buffers (&optional file)
 249   ;; FIXME: Aren't we only ever called from after-load-functions?
 250   ;; Don't flush during load unless called from after-load-functions.
 251   ;; In that case, FILE is non-nil.  It's somehow strange that
 252   ;; load-in-progress is t when an after-load-function is called since
 253   ;; that should run *after* the load...
 254   (when (or (not load-in-progress) file)
 255     ;; FIXME: If the loaded file did not define any macros, there shouldn't
 256     ;; be any need to font-lock-flush all the Elisp buffers.
 257     (dolist (buf (buffer-list))
 258       (with-current-buffer buf
 259         (when (derived-mode-p 'emacs-lisp-mode)
 260           ;; So as to take into account new macros that may have been defined
 261           ;; by the just-loaded file.
 262           (font-lock-flush))))))
 263
 264 ;;; Completion at point for Elisp
 265
 266 (defun elisp--local-variables-1 (vars sexp)
 267   "Return the vars locally bound around the witness, or nil if not found."
 268   (let (res)
 269     (while
 270         (unless
 271             (setq res
 272                   (pcase sexp
 273                     (`(,(or `let `let*) ,bindings)
 274                      (let ((vars vars))
 275                        (when (eq 'let* (car sexp))
 276                          (dolist (binding (cdr (reverse bindings)))
 277                            (push (or (car-safe binding) binding) vars)))
 278                        (elisp--local-variables-1
 279                         vars (car (cdr-safe (car (last bindings)))))))
 280                     (`(,(or `let `let*) ,bindings . ,body)
 281                      (let ((vars vars))
 282                        (dolist (binding bindings)
 283                          (push (or (car-safe binding) binding) vars))
 284                        (elisp--local-variables-1 vars (car (last body)))))
 285                     (`(lambda ,_args)
 286                      ;; FIXME: Look for the witness inside `args'.
 287                      (setq sexp nil))
 288                     (`(lambda ,args . ,body)
 289                      (elisp--local-variables-1
 290                       (append (remq '&optional (remq '&rest args)) vars)
 291                       (car (last body))))
 292                     (`(condition-case ,_ ,e) (elisp--local-variables-1 vars e))
 293                     (`(condition-case ,v ,_ . ,catches)
 294                      (elisp--local-variables-1
 295                       (cons v vars) (cdr (car (last catches)))))
 296                     (`(quote . ,_)
 297                      ;; FIXME: Look for the witness inside sexp.
 298                      (setq sexp nil))
 299                     ;; FIXME: Handle `cond'.
 300                     (`(,_ . ,_)
 301                      (elisp--local-variables-1 vars (car (last sexp))))
 302                     (`elisp--witness--lisp (or vars '(nil)))
 303                     (_ nil)))
 304           ;; We didn't find the witness in the last element so we try to
 305           ;; backtrack to the last-but-one.
 306           (setq sexp (ignore-errors (butlast sexp)))))
 307     res))
 308
 309 (defun elisp--local-variables ()
 310   "Return a list of locally let-bound variables at point."
 311   (save-excursion
 312     (skip-syntax-backward "w_")
 313     (let* ((ppss (syntax-ppss))
 314            (txt (buffer-substring-no-properties (or (car (nth 9 ppss)) (point))
 315                                                 (or (nth 8 ppss) (point))))
 316            (closer ()))
 317       (dolist (p (nth 9 ppss))
 318         (push (cdr (syntax-after p)) closer))
 319       (setq closer (apply #'string closer))
 320       (let* ((sexp (condition-case nil
 321                        (car (read-from-string
 322                              (concat txt "elisp--witness--lisp" closer)))
 323                      ((invalid-read-syntax end-of-file) nil)))
 324              (macroexpand-advice (lambda (expander form &rest args)
 325                                    (condition-case nil
 326                                        (apply expander form args)
 327                                      (error form))))
 328              (sexp
 329               (unwind-protect
 330                   (progn
 331                     (advice-add 'macroexpand :around macroexpand-advice)
 332                     (macroexpand-all sexp))
 333                 (advice-remove 'macroexpand macroexpand-advice)))
 334              (vars (elisp--local-variables-1 nil sexp)))
 335         (delq nil
 336               (mapcar (lambda (var)
 337                         (and (symbolp var)
 338                              (not (string-match (symbol-name var) "\\`[&_]"))
 339                              ;; Eliminate uninterned vars.
 340                              (intern-soft var)
 341                              var))
 342                       vars))))))
 343
 344 (defvar elisp--local-variables-completion-table
 345   ;; Use `defvar' rather than `defconst' since defconst would purecopy this
 346   ;; value, which would doubly fail: it would fail because purecopy can't
 347   ;; handle the recursive bytecode object, and it would fail because it would
 348   ;; move `lastpos' and `lastvars' to pure space where they'd be immutable!
 349   (let ((lastpos nil) (lastvars nil))
 350     (letrec ((hookfun (lambda ()
 351                         (setq lastpos nil)
 352                         (remove-hook 'post-command-hook hookfun))))
 353       (completion-table-dynamic
 354        (lambda (_string)
 355          (save-excursion
 356            (skip-syntax-backward "_w")
 357            (let ((newpos (cons (point) (current-buffer))))
 358              (unless (equal lastpos newpos)
 359                (add-hook 'post-command-hook hookfun)
 360                (setq lastpos newpos)
 361                (setq lastvars
 362                      (mapcar #'symbol-name (elisp--local-variables))))))
 363          lastvars)))))
 364
 365 (defun elisp--expect-function-p (pos)
 366   "Return non-nil if the symbol at point is expected to be a function."
 367   (or
 368    (and (eq (char-before pos) ?')
 369         (eq (char-before (1- pos)) ?#))
 370    (save-excursion
 371      (let ((parent (nth 1 (syntax-ppss pos))))
 372        (when parent
 373          (goto-char parent)
 374          (and
 375           (looking-at (concat "(\\(cl-\\)?"
 376                               (regexp-opt '("declare-function"
 377                                             "function" "defadvice"
 378                                             "callf" "callf2"
 379                                             "defsetf"))
 380                               "[ \t\r\n]+"))
 381           (eq (match-end 0) pos)))))))
 382
 383 (defun elisp--form-quoted-p (pos)
 384   "Return non-nil if the form at POS is not evaluated.
 385 It can be quoted, or be inside a quoted form."
 386   ;; FIXME: Do some macro expansion maybe.
 387   (save-excursion
 388     (let ((state (syntax-ppss pos)))
 389       (or (nth 8 state)   ; Code inside strings usually isn't evaluated.
 390           ;; FIXME: The 9th element is undocumented.
 391           (let ((nesting (cons (point) (reverse (nth 9 state))))
 392                 res)
 393             (while (and nesting (not res))
 394               (goto-char (pop nesting))
 395               (cond
 396                ((or (eq (char-after) ?\[)
 397                     (progn
 398                       (skip-chars-backward " ")
 399                       (memq (char-before) '(?' ?` ?‘))))
 400                 (setq res t))
 401                ((eq (char-before) ?,)
 402                 (setq nesting nil))))
 403             res)))))
 404
 405 ;; FIXME: Support for Company brings in features which straddle eldoc.
 406 ;; We should consolidate this, so that major modes can provide all that
 407 ;; data all at once:
 408 ;; - a function to extract "the reference at point" (may be more complex
 409 ;;     than a mere string, to distinguish various namespaces).
 410 ;; - a function to jump to such a reference.
 411 ;; - a function to show the signature/interface of such a reference.
 412 ;; - a function to build a help-buffer about that reference.
 413 ;; FIXME: Those functions should also be used by the normal completion code in
 414 ;; the *Completions* buffer.
 415
 416 (defun elisp--company-doc-buffer (str)
 417   (let ((symbol (intern-soft str)))
 418     ;; FIXME: we really don't want to "display-buffer and then undo it".
 419     (save-window-excursion
 420       ;; Make sure we don't display it in another frame, otherwise
 421       ;; save-window-excursion won't be able to undo it.
 422       (let ((display-buffer-overriding-action
 423              '(nil . ((inhibit-switch-frame . t)))))
 424         (ignore-errors
 425           (cond
 426            ((fboundp symbol) (describe-function symbol))
 427            ((boundp symbol) (describe-variable symbol))
 428            ((featurep symbol) (describe-package symbol))
 429            ((facep symbol) (describe-face symbol))
 430            (t (signal 'user-error nil)))
 431           (help-buffer))))))
 432
 433 (defun elisp--company-doc-string (str)
 434   (let* ((symbol (intern-soft str))
 435          (doc (if (fboundp symbol)
 436                   (documentation symbol t)
 437                 (documentation-property symbol 'variable-documentation t))))
 438     (and (stringp doc)
 439          (string-match ".*$" doc)
 440          (match-string 0 doc))))
 441
 442 ;; can't (require 'find-func) in a preloaded file
 443 (declare-function find-library-name "find-func" (library))
 444 (declare-function find-function-library "find-func" (function &optional l-o v))
 445
 446 (defun elisp--company-location (str)
 447   (let ((sym (intern-soft str)))
 448     (cond
 449      ((fboundp sym) (find-definition-noselect sym nil))
 450      ((boundp sym) (find-definition-noselect sym 'defvar))
 451      ((featurep sym)
 452       (require 'find-func)
 453       (cons (find-file-noselect (find-library-name
 454                                  (symbol-name sym)))
 455             0))
 456      ((facep sym) (find-definition-noselect sym 'defface)))))
 457
 458 (defun elisp-completion-at-point ()
 459   "Function used for `completion-at-point-functions' in `emacs-lisp-mode'."
 460   (with-syntax-table emacs-lisp-mode-syntax-table
 461     (let* ((pos (point))
 462            (beg (condition-case nil
 463                     (save-excursion
 464                       (backward-sexp 1)
 465                       (skip-chars-forward "`',‘#")
 466                       (point))
 467                   (scan-error pos)))
 468            (end
 469             (unless (or (eq beg (point-max))
 470                         (member (char-syntax (char-after beg))
 471                                 '(?\s ?\" ?\( ?\))))
 472               (condition-case nil
 473                   (save-excursion
 474                     (goto-char beg)
 475                     (forward-sexp 1)
 476                     (skip-chars-backward "'’")
 477                     (when (>= (point) pos)
 478                       (point)))
 479                 (scan-error pos))))
 480            ;; t if in function position.
 481            (funpos (eq (char-before beg) ?\())
 482            (quoted (elisp--form-quoted-p beg)))
 483       (when (and end (or (not (nth 8 (syntax-ppss)))
 484                          (memq (char-before beg) '(?` ?‘))))
 485         (let ((table-etc
 486                (if (or (not funpos) quoted)
 487                    ;; FIXME: We could look at the first element of the list and
 488                    ;; use it to provide a more specific completion table in some
 489                    ;; cases.  E.g. filter out keywords that are not understood by
 490                    ;; the macro/function being called.
 491                    (cond
 492                     ((elisp--expect-function-p beg)
 493                      (list nil obarray
 494                            :predicate #'fboundp
 495                            :company-doc-buffer #'elisp--company-doc-buffer
 496                            :company-docsig #'elisp--company-doc-string
 497                            :company-location #'elisp--company-location))
 498                     (quoted
 499                      (list nil obarray
 500                            ;; Don't include all symbols (bug#16646).
 501                            :predicate (lambda (sym)
 502                                         (or (boundp sym)
 503                                             (fboundp sym)
 504                                             (featurep sym)
 505                                             (symbol-plist sym)))
 506                            :annotation-function
 507                            (lambda (str) (if (fboundp (intern-soft str)) " <f>"))
 508                            :company-doc-buffer #'elisp--company-doc-buffer
 509                            :company-docsig #'elisp--company-doc-string
 510                            :company-location #'elisp--company-location))
 511                     (t
 512                      (list nil (completion-table-merge
 513                                 elisp--local-variables-completion-table
 514                                 (apply-partially #'completion-table-with-predicate
 515                                                  obarray
 516                                                  #'boundp
 517                                                  'strict))
 518                            :company-doc-buffer #'elisp--company-doc-buffer
 519                            :company-docsig #'elisp--company-doc-string
 520                            :company-location #'elisp--company-location)))
 521                  ;; Looks like a funcall position.  Let's double check.
 522                  (save-excursion
 523                    (goto-char (1- beg))
 524                    (let ((parent
 525                           (condition-case nil
 526                               (progn (up-list -1) (forward-char 1)
 527                                      (let ((c (char-after)))
 528                                        (if (eq c ?\() ?\(
 529                                          (if (memq (char-syntax c) '(?w ?_))
 530                                              (read (current-buffer))))))
 531                             (error nil))))
 532                      (pcase parent
 533                        ;; FIXME: Rather than hardcode special cases here,
 534                        ;; we should use something like a symbol-property.
 535                        (`declare
 536                         (list t (mapcar (lambda (x) (symbol-name (car x)))
 537                                         (delete-dups
 538                                          ;; FIXME: We should include some
 539                                          ;; docstring with each entry.
 540                                          (append
 541                                           macro-declarations-alist
 542                                           defun-declarations-alist)))))
 543                        ((and (or `condition-case `condition-case-unless-debug)
 544                              (guard (save-excursion
 545                                       (ignore-errors
 546                                         (forward-sexp 2)
 547                                         (< (point) beg)))))
 548                         (list t obarray
 549                               :predicate (lambda (sym) (get sym 'error-conditions))))
 550                        ((and (or ?\( `let `let*)
 551                              (guard (save-excursion
 552                                       (goto-char (1- beg))
 553                                       (when (eq parent ?\()
 554                                         (up-list -1))
 555                                       (forward-symbol -1)
 556                                       (looking-at "\\_<let\\*?\\_>"))))
 557                         (list t obarray
 558                               :predicate #'boundp
 559                               :company-doc-buffer #'elisp--company-doc-buffer
 560                               :company-docsig #'elisp--company-doc-string
 561                               :company-location #'elisp--company-location))
 562                        (_ (list nil obarray
 563                                 :predicate #'fboundp
 564                                 :company-doc-buffer #'elisp--company-doc-buffer
 565                                 :company-docsig #'elisp--company-doc-string
 566                                 :company-location #'elisp--company-location
 567                                 ))))))))
 568           (nconc (list beg end)
 569                  (if (null (car table-etc))
 570                      (cdr table-etc)
 571                    (cons
 572                     (if (memq (char-syntax (or (char-after end) ?\s))
 573                               '(?\s ?>))
 574                         (cadr table-etc)
 575                       (apply-partially 'completion-table-with-terminator
 576                                        " " (cadr table-etc)))
 577                     (cddr table-etc)))))))))
 578
 579 (define-obsolete-function-alias
 580   'lisp-completion-at-point 'elisp-completion-at-point "25.1")
 581
 582 ;;; Xref backend
 583
 584 (declare-function xref-make-bogus-location "xref" (message))
 585 (declare-function xref-make "xref" (summary location))
 586 (declare-function xref-collect-references "xref" (symbol dir))
 587
 588 (defun elisp--xref-backend () 'elisp)
 589
 590 ;; WORKAROUND: This is nominally a constant, but the text properties
 591 ;; are not preserved thru dump if use defconst.  See bug#21237.
 592 (defvar elisp--xref-format
 593   (let ((str "(%s %s)"))
 594     (put-text-property 1 3 'face 'font-lock-keyword-face str)
 595     (put-text-property 4 6 'face 'font-lock-function-name-face str)
 596     str))
 597
 598 ;; WORKAROUND: This is nominally a constant, but the text properties
 599 ;; are not preserved thru dump if use defconst.  See bug#21237.
 600 (defvar elisp--xref-format-extra
 601   (let ((str "(%s %s %s)"))
 602     (put-text-property 1 3 'face 'font-lock-keyword-face str)
 603     (put-text-property 4 6 'face 'font-lock-function-name-face str)
 604     str))
 605
 606 (defvar find-feature-regexp);; in find-func.el
 607
 608 (defun elisp--xref-make-xref (type symbol file &optional summary)
 609   "Return an xref for TYPE SYMBOL in FILE.
 610 TYPE must be a type in `find-function-regexp-alist' (use nil for
 611 'defun).  If SUMMARY is non-nil, use it for the summary;
 612 otherwise build the summary from TYPE and SYMBOL."
 613   (xref-make (or summary
 614                  (format elisp--xref-format (or type 'defun) symbol))
 615              (xref-make-elisp-location symbol type file)))
 616
 617 (defvar elisp-xref-find-def-functions nil
 618   "List of functions to be run from `elisp--xref-find-definitions' to add additional xrefs.
 619 Called with one arg; the symbol whose definition is desired.
 620 Each function should return a list of xrefs, or nil; the first
 621 non-nil result supercedes the xrefs produced by
 622 `elisp--xref-find-definitions'.")
 623
 624 (cl-defmethod xref-backend-definitions ((_backend (eql elisp)) identifier)
 625   (require 'find-func)
 626   ;; FIXME: use information in source near point to filter results:
 627   ;; (dvc-log-edit ...) - exclude 'feature
 628   ;; (require 'dvc-log-edit) - only 'feature
 629   ;; Semantic may provide additional information
 630   ;;
 631   (let ((sym (intern-soft identifier)))
 632     (when sym
 633       (elisp--xref-find-definitions sym))))
 634
 635 (defun elisp--xref-find-definitions (symbol)
 636   ;; The file name is not known when `symbol' is defined via interactive eval.
 637   (let (xrefs)
 638
 639     (let ((temp elisp-xref-find-def-functions))
 640       (while (and (null xrefs)
 641                   temp)
 642         (setq xrefs (append xrefs (funcall (pop temp) symbol)))))
 643
 644     (unless xrefs
 645       ;; alphabetical by result type symbol
 646
 647       ;; FIXME: advised function; list of advice functions
 648       ;; FIXME: aliased variable
 649
 650       ;; Coding system symbols do not appear in ‘load-history’,
 651       ;; so we can’t get a location for them.
 652
 653       (when (and (symbolp symbol)
 654                  (symbol-function symbol)
 655                  (symbolp (symbol-function symbol)))
 656         ;; aliased function
 657         (let* ((alias-symbol symbol)
 658                (alias-file (symbol-file alias-symbol))
 659                (real-symbol  (symbol-function symbol))
 660                (real-file (find-lisp-object-file-name real-symbol 'defun)))
 661
 662           (when real-file
 663             (push (elisp--xref-make-xref nil real-symbol real-file) xrefs))
 664
 665           (when alias-file
 666             (push (elisp--xref-make-xref 'defalias alias-symbol alias-file) xrefs))))
 667
 668       (when (facep symbol)
 669         (let ((file (find-lisp-object-file-name symbol 'defface)))
 670           (when file
 671             (push (elisp--xref-make-xref 'defface symbol file) xrefs))))
 672
 673       (when (fboundp symbol)
 674         (let ((file (find-lisp-object-file-name symbol (symbol-function symbol)))
 675               generic doc)
 676           (when file
 677             (cond
 678              ((eq file 'C-source)
 679               ;; First call to find-lisp-object-file-name for an object
 680               ;; defined in C; the doc strings from the C source have
 681               ;; not been loaded yet.  Second call will return "src/*.c"
 682               ;; in file; handled by 't' case below.
 683               (push (elisp--xref-make-xref nil symbol (help-C-file-name (symbol-function symbol) 'subr)) xrefs))
 684
 685              ((and (setq doc (documentation symbol t))
 686                    ;; This doc string is defined in cl-macs.el cl-defstruct
 687                    (string-match "Constructor for objects of type `\\(.*\\)'" doc))
 688               ;; `symbol' is a name for the default constructor created by
 689               ;; cl-defstruct, so return the location of the cl-defstruct.
 690               (let* ((type-name (match-string 1 doc))
 691                      (type-symbol (intern type-name))
 692                      (file (find-lisp-object-file-name type-symbol 'define-type))
 693                      (summary (format elisp--xref-format-extra
 694                                       'cl-defstruct
 695                                       (concat "(" type-name)
 696                                       (concat "(:constructor " (symbol-name symbol) "))"))))
 697                 (push (elisp--xref-make-xref 'define-type type-symbol file summary) xrefs)
 698                 ))
 699
 700              ((setq generic (cl--generic symbol))
 701               ;; FIXME: move this to elisp-xref-find-def-functions, in cl-generic.el
 702
 703               ;; A generic function. If there is a default method, it
 704               ;; will appear in the method table, with no
 705               ;; specializers.
 706               ;;
 707               ;; If the default method is declared by the cl-defgeneric
 708               ;; declaration, it will have the same location as the
 709               ;; cl-defgeneric, so we want to exclude it from the
 710               ;; result. In this case, it will have a null doc
 711               ;; string. User declarations of default methods may also
 712               ;; have null doc strings, but we hope that is
 713               ;; rare. Perhaps this heuristic will discourage that.
 714               (dolist (method (cl--generic-method-table generic))
 715                 (let* ((info (cl--generic-method-info method));; qual-string combined-args doconly
 716                        (specializers (cl--generic-method-specializers method))
 717                        (non-default nil)
 718                        (met-name (cons symbol specializers))
 719                        (file (find-lisp-object-file-name met-name 'cl-defmethod)))
 720                   (dolist (item specializers)
 721                     ;; default method has all 't' in specializers
 722                     (setq non-default (or non-default (not (equal t item)))))
 723
 724                   (when (and file
 725                              (or non-default
 726                                  (nth 2 info))) ;; assuming only co-located default has null doc string
 727                     (if specializers
 728                         (let ((summary (format elisp--xref-format-extra 'cl-defmethod symbol (nth 1 info))))
 729                           (push (elisp--xref-make-xref 'cl-defmethod met-name file summary) xrefs))
 730
 731                       (let ((summary (format elisp--xref-format-extra 'cl-defmethod symbol "()")))
 732                         (push (elisp--xref-make-xref 'cl-defmethod met-name file summary) xrefs))))
 733                   ))
 734
 735               (if (and (setq doc (documentation symbol t))
 736                        ;; This doc string is created somewhere in
 737                        ;; cl--generic-make-function for an implicit
 738                        ;; defgeneric.
 739                        (string-match "\n\n(fn ARG &rest ARGS)" doc))
 740                   ;; This symbol is an implicitly defined defgeneric, so
 741                   ;; don't return it.
 742                   nil
 743                 (push (elisp--xref-make-xref 'cl-defgeneric symbol file) xrefs))
 744               )
 745
 746              (t
 747               (push (elisp--xref-make-xref nil symbol file) xrefs))
 748              ))))
 749
 750       (when (boundp symbol)
 751         ;; A variable
 752         (let ((file (find-lisp-object-file-name symbol 'defvar)))
 753           (when file
 754             (cond
 755              ((eq file 'C-source)
 756               ;; The doc strings from the C source have not been loaded
 757               ;; yet; help-C-file-name does that.  Second call will
 758               ;; return "src/*.c" in file; handled below.
 759               (push (elisp--xref-make-xref 'defvar symbol (help-C-file-name symbol 'var)) xrefs))
 760
 761              ((string= "src/" (substring file 0 4))
 762               ;; The variable is defined in a C source file; don't check
 763               ;; for define-minor-mode.
 764               (push (elisp--xref-make-xref 'defvar symbol file) xrefs))
 765
 766              ((memq symbol minor-mode-list)
 767               ;; The symbol is a minor mode. These should be defined by
 768               ;; "define-minor-mode", which means the variable and the
 769               ;; function are declared in the same place. So we return only
 770               ;; the function, arbitrarily.
 771               ;;
 772               ;; There is an exception, when the variable is defined in C
 773               ;; code, as for abbrev-mode.
 774               ;;
 775               ;; IMPROVEME: If the user is searching for the identifier at
 776               ;; point, we can determine whether it is a variable or
 777               ;; function by looking at the source code near point.
 778               ;;
 779               ;; IMPROVEME: The user may actually be asking "do any
 780               ;; variables by this name exist"; we need a way to specify
 781               ;; that.
 782               nil)
 783
 784              (t
 785               (push (elisp--xref-make-xref 'defvar symbol file) xrefs))
 786
 787              ))))
 788
 789       (when (featurep symbol)
 790         (let ((file (ignore-errors
 791                       (find-library-name (symbol-name symbol)))))
 792           (when file
 793             (push (elisp--xref-make-xref 'feature symbol file) xrefs))))
 794       );; 'unless xrefs'
 795
 796     xrefs))
 797
 798 (declare-function project-library-roots "project")
 799
 800 (cl-defmethod xref-backend-apropos ((_backend (eql elisp)) regexp)
 801   (apply #'nconc
 802          (let (lst)
 803            (dolist (sym (apropos-internal regexp))
 804             (push (elisp--xref-find-definitions sym) lst))
 805            (nreverse lst))))
 806
 807 (defvar elisp--xref-identifier-completion-table
 808   (apply-partially #'completion-table-with-predicate
 809                    obarray
 810                    (lambda (sym)
 811                      (or (boundp sym)
 812                          (fboundp sym)
 813                          (featurep sym)
 814                          (facep sym)))
 815                    'strict))
 816
 817 (cl-defmethod xref-backend-identifier-completion-table ((_backend (eql elisp)))
 818   elisp--xref-identifier-completion-table)
 819
 820 (cl-defstruct (xref-elisp-location
 821                (:constructor xref-make-elisp-location (symbol type file)))
 822   "Location of an Emacs Lisp symbol definition."
 823   symbol type file)
 824
 825 (cl-defmethod xref-location-marker ((l xref-elisp-location))
 826   (pcase-let (((cl-struct xref-elisp-location symbol type file) l))
 827     (let ((buffer-point (find-function-search-for-symbol symbol type file)))
 828       (with-current-buffer (car buffer-point)
 829         (goto-char (or (cdr buffer-point) (point-min)))
 830         (point-marker)))))
 831
 832 (cl-defmethod xref-location-group ((l xref-elisp-location))
 833   (xref-elisp-location-file l))
 834
 835 (defun elisp-library-roots ()
 836   (defvar package-user-dir)
 837   (cons package-user-dir load-path))
 838
 839 ;;; Elisp Interaction mode
 840
 841 (defvar lisp-interaction-mode-map
 842   (let ((map (make-sparse-keymap))
 843         (menu-map (make-sparse-keymap "Lisp-Interaction")))
 844     (set-keymap-parent map lisp-mode-shared-map)
 845     (define-key map "\e\C-x" 'eval-defun)
 846     (define-key map "\e\C-q" 'indent-pp-sexp)
 847     (define-key map "\e\t" 'completion-at-point)
 848     (define-key map "\n" 'eval-print-last-sexp)
 849     (bindings--define-key map [menu-bar lisp-interaction]
 850       (cons "Lisp-Interaction" menu-map))
 851     (bindings--define-key menu-map [eval-defun]
 852       '(menu-item "Evaluate Defun" eval-defun
 853                   :help "Evaluate the top-level form containing point, or after point"))
 854     (bindings--define-key menu-map [eval-print-last-sexp]
 855       '(menu-item "Evaluate and Print" eval-print-last-sexp
 856                   :help "Evaluate sexp before point; print value into current buffer"))
 857     (bindings--define-key menu-map [edebug-defun-lisp-interaction]
 858       '(menu-item "Instrument Function for Debugging" edebug-defun
 859                   :help "Evaluate the top level form point is in, stepping through with Edebug"
 860                   :keys "C-u C-M-x"))
 861     (bindings--define-key menu-map [indent-pp-sexp]
 862       '(menu-item "Indent or Pretty-Print" indent-pp-sexp
 863                   :help "Indent each line of the list starting just after point, or prettyprint it"))
 864     (bindings--define-key menu-map [complete-symbol]
 865       '(menu-item "Complete Lisp Symbol" completion-at-point
 866                   :help "Perform completion on Lisp symbol preceding point"))
 867     map)
 868   "Keymap for Lisp Interaction mode.
 869 All commands in `lisp-mode-shared-map' are inherited by this map.")
 870
 871 (define-derived-mode lisp-interaction-mode emacs-lisp-mode "Lisp Interaction"
 872   "Major mode for typing and evaluating Lisp forms.
 873 Like Lisp mode except that \\[eval-print-last-sexp] evals the Lisp expression
 874 before point, and prints its value into the buffer, advancing point.
 875 Note that printing is controlled by `eval-expression-print-length'
 876 and `eval-expression-print-level'.
 877
 878 Commands:
 879 Delete converts tabs to spaces as it moves back.
 880 Paragraphs are separated only by blank lines.
 881 Semicolons start comments.
 882
 883 \\{lisp-interaction-mode-map}"
 884   :abbrev-table nil)
 885
 886 ;;; Emacs Lisp Byte-Code mode
 887
 888 (eval-and-compile
 889   (defconst emacs-list-byte-code-comment-re
 890     (concat "\\(#\\)@\\([0-9]+\\) "
 891             ;; Make sure it's a docstring and not a lazy-loaded byte-code.
 892             "\\(?:[^(]\\|([^\"]\\)")))
 893
 894 (defun elisp--byte-code-comment (end &optional _point)
 895   "Try to syntactically mark the #@NNN ....^_ docstrings in byte-code files."
 896   (let ((ppss (syntax-ppss)))
 897     (when (and (nth 4 ppss)
 898                (eq (char-after (nth 8 ppss)) ?#))
 899       (let* ((n (save-excursion
 900                   (goto-char (nth 8 ppss))
 901                   (when (looking-at emacs-list-byte-code-comment-re)
 902                     (string-to-number (match-string 2)))))
 903              ;; `maxdiff' tries to make sure the loop below terminates.
 904              (maxdiff n))
 905         (when n
 906           (let* ((bchar (match-end 2))
 907                  (b (position-bytes bchar)))
 908             (goto-char (+ b n))
 909             (while (let ((diff (- (position-bytes (point)) b n)))
 910                      (unless (zerop diff)
 911                        (when (> diff maxdiff) (setq diff maxdiff))
 912                        (forward-char (- diff))
 913                        (setq maxdiff (if (> diff 0) diff
 914                                        (max (1- maxdiff) 1)))
 915                        t))))
 916           (if (<= (point) end)
 917               (put-text-property (1- (point)) (point)
 918                                  'syntax-table
 919                                  (string-to-syntax "> b"))
 920             (goto-char end)))))))
 921
 922 (defun elisp-byte-code-syntax-propertize (start end)
 923   (goto-char start)
 924   (elisp--byte-code-comment end (point))
 925   (funcall
 926    (syntax-propertize-rules
 927     (emacs-list-byte-code-comment-re
 928      (1 (prog1 "< b" (elisp--byte-code-comment end (point))))))
 929    start end))
 930
 931 ;;;###autoload
 932 (add-to-list 'auto-mode-alist '("\\.elc\\'" . elisp-byte-code-mode))
 933 ;;;###autoload
 934 (define-derived-mode elisp-byte-code-mode emacs-lisp-mode
 935   "Elisp-Byte-Code"
 936   "Major mode for *.elc files."
 937   ;; TODO: Add way to disassemble byte-code under point.
 938   (setq-local open-paren-in-column-0-is-defun-start nil)
 939   (setq-local syntax-propertize-function
 940               #'elisp-byte-code-syntax-propertize))
 941
 942
 943 ;;; Globally accessible functionality
 944
 945 (defun eval-print-last-sexp (&optional eval-last-sexp-arg-internal)
 946   "Evaluate sexp before point; print value into current buffer.
 947
 948 Normally, this function truncates long output according to the value
 949 of the variables `eval-expression-print-length' and
 950 `eval-expression-print-level'.  With a prefix argument of zero,
 951 however, there is no such truncation.  Such a prefix argument
 952 also causes integers to be printed in several additional formats
 953 \(octal, hexadecimal, and character).
 954
 955 If `eval-expression-debug-on-error' is non-nil, which is the default,
 956 this command arranges for all errors to enter the debugger."
 957   (interactive "P")
 958   (let ((standard-output (current-buffer)))
 959     (terpri)
 960     (eval-last-sexp (or eval-last-sexp-arg-internal t))
 961     (terpri)))
 962
 963
 964 (defun last-sexp-setup-props (beg end value alt1 alt2)
 965   "Set up text properties for the output of `elisp--eval-last-sexp'.
 966 BEG and END are the start and end of the output in current-buffer.
 967 VALUE is the Lisp value printed, ALT1 and ALT2 are strings for the
 968 alternative printed representations that can be displayed."
 969   (let ((map (make-sparse-keymap)))
 970     (define-key map "\C-m" 'elisp-last-sexp-toggle-display)
 971     (define-key map [down-mouse-2] 'mouse-set-point)
 972     (define-key map [mouse-2] 'elisp-last-sexp-toggle-display)
 973     (add-text-properties
 974      beg end
 975      `(printed-value (,value ,alt1 ,alt2)
 976                      mouse-face highlight
 977                      keymap ,map
 978                      help-echo "RET, mouse-2: toggle abbreviated display"
 979                      rear-nonsticky (mouse-face keymap help-echo
 980                                                 printed-value)))))
 981
 982
 983 (defun elisp-last-sexp-toggle-display (&optional _arg)
 984   "Toggle between abbreviated and unabbreviated printed representations."
 985   (interactive "P")
 986   (save-restriction
 987     (widen)
 988     (let ((value (get-text-property (point) 'printed-value)))
 989       (when value
 990         (let ((beg (or (previous-single-property-change (min (point-max) (1+ (point)))
 991                                                         'printed-value)
 992                        (point)))
 993               (end (or (next-single-char-property-change (point) 'printed-value) (point)))
 994               (standard-output (current-buffer))
 995               (point (point)))
 996           (delete-region beg end)
 997           (insert (nth 1 value))
 998           (or (= beg point)
 999               (setq point (1- (point))))
1000           (last-sexp-setup-props beg (point)
1001                                  (nth 0 value)
1002                                  (nth 2 value)
1003                                  (nth 1 value))
1004           (goto-char (min (point-max) point)))))))
1005
1006 (defun prin1-char (char)                ;FIXME: Move it, e.g. to simple.el.
1007   "Return a string representing CHAR as a character rather than as an integer.
1008 If CHAR is not a character, return nil."
1009   (and (integerp char)
1010        (eventp char)
1011        (let ((c (event-basic-type char))
1012              (mods (event-modifiers char))
1013              string)
1014          ;; Prevent ?A from turning into ?\S-a.
1015          (if (and (memq 'shift mods)
1016                   (zerop (logand char ?\S-\^@))
1017                   (not (let ((case-fold-search nil))
1018                          (char-equal c (upcase c)))))
1019              (setq c (upcase c) mods nil))
1020          ;; What string are we considering using?
1021          (condition-case nil
1022              (setq string
1023                    (concat
1024                     "?"
1025                     (mapconcat
1026                      (lambda (modif)
1027                        (cond ((eq modif 'super) "\\s-")
1028                              (t (string ?\\ (upcase (aref (symbol-name modif) 0)) ?-))))
1029                      mods "")
1030                     (cond
1031                      ((memq c '(?\; ?\( ?\) ?\{ ?\} ?\[ ?\] ?\" ?\' ?\\)) (string ?\\ c))
1032                      ((eq c 127) "\\C-?")
1033                      (t
1034                       (string c)))))
1035            (error nil))
1036          ;; Verify the string reads a CHAR, not to some other character.
1037          ;; If it doesn't, return nil instead.
1038          (and string
1039               (= (car (read-from-string string)) char)
1040               string))))
1041
1042 (defun elisp--preceding-sexp ()
1043   "Return sexp before the point."
1044   (let ((opoint (point))
1045         (left-quote ?‘)
1046         expr)
1047     (save-excursion
1048       (with-syntax-table emacs-lisp-mode-syntax-table
1049         ;; If this sexp appears to be enclosed in `...' or ‘...’
1050         ;; then ignore the surrounding quotes.
1051         (cond ((eq (preceding-char) ?’)
1052                (progn (forward-char -1) (setq opoint (point))))
1053               ((or (eq (following-char) ?\')
1054                    (eq (preceding-char) ?\'))
1055                (setq left-quote ?\`)))
1056         (forward-sexp -1)
1057         ;; If we were after `?\e' (or similar case),
1058         ;; use the whole thing, not just the `e'.
1059         (when (eq (preceding-char) ?\\)
1060           (forward-char -1)
1061           (when (eq (preceding-char) ??)
1062             (forward-char -1)))
1063
1064         ;; Skip over hash table read syntax.
1065         (and (> (point) (1+ (point-min)))
1066              (looking-back "#s" (- (point) 2))
1067              (forward-char -2))
1068
1069         ;; Skip over `#N='s.
1070         (when (eq (preceding-char) ?=)
1071           (let (labeled-p)
1072             (save-excursion
1073               (skip-chars-backward "0-9#=")
1074               (setq labeled-p (looking-at "\\(#[0-9]+=\\)+")))
1075             (when labeled-p
1076               (forward-sexp -1))))
1077
1078         (save-restriction
1079           (if (eq (following-char) left-quote)
1080               ;; vladimir@cs.ualberta.ca 30-Jul-1997: Skip ` in `variable' so
1081               ;; that the value is returned, not the name.
1082               (forward-char))
1083           (when (looking-at ",@?") (goto-char (match-end 0)))
1084           (narrow-to-region (point-min) opoint)
1085           (setq expr (read (current-buffer)))
1086           ;; If it's an (interactive ...) form, it's more useful to show how an
1087           ;; interactive call would use it.
1088           ;; FIXME: Is it really the right place for this?
1089           (when (eq (car-safe expr) 'interactive)
1090                (setq expr
1091                   `(call-interactively
1092                     (lambda (&rest args) ,expr args))))
1093           expr)))))
1094 (define-obsolete-function-alias 'preceding-sexp 'elisp--preceding-sexp "25.1")
1095
1096 (defun elisp--eval-last-sexp (eval-last-sexp-arg-internal)
1097   "Evaluate sexp before point; print value in the echo area.
1098 If EVAL-LAST-SEXP-ARG-INTERNAL is non-nil, print output into
1099 current buffer.  If EVAL-LAST-SEXP-ARG-INTERNAL is `0', print
1100 output with no limit on the length and level of lists, and
1101 include additional formats for integers \(octal, hexadecimal, and
1102 character)."
1103   (let ((standard-output (if eval-last-sexp-arg-internal (current-buffer) t)))
1104     ;; Setup the lexical environment if lexical-binding is enabled.
1105     (elisp--eval-last-sexp-print-value
1106      (eval (eval-sexp-add-defvars (elisp--preceding-sexp)) lexical-binding)
1107      eval-last-sexp-arg-internal)))
1108
1109 (defun elisp--eval-last-sexp-print-value (value &optional eval-last-sexp-arg-internal)
1110   (let ((unabbreviated (let ((print-length nil) (print-level nil))
1111                          (prin1-to-string value)))
1112         (print-length (and (not (zerop (prefix-numeric-value
1113                                         eval-last-sexp-arg-internal)))
1114                            eval-expression-print-length))
1115         (print-level (and (not (zerop (prefix-numeric-value
1116                                        eval-last-sexp-arg-internal)))
1117                           eval-expression-print-level))
1118         (beg (point))
1119         end)
1120     (prog1
1121         (prin1 value)
1122       (let ((str (eval-expression-print-format value)))
1123         (if str (princ str)))
1124       (setq end (point))
1125       (when (and (bufferp standard-output)
1126                  (or (not (null print-length))
1127                      (not (null print-level)))
1128                  (not (string= unabbreviated
1129                                (buffer-substring-no-properties beg end))))
1130         (last-sexp-setup-props beg end value
1131                                unabbreviated
1132                                (buffer-substring-no-properties beg end))
1133         ))))
1134
1135
1136 (defvar elisp--eval-last-sexp-fake-value (make-symbol "t"))
1137
1138 (defun eval-sexp-add-defvars (exp &optional pos)
1139   "Prepend EXP with all the `defvar's that precede it in the buffer.
1140 POS specifies the starting position where EXP was found and defaults to point."
1141   (setq exp (macroexpand-all exp))      ;Eager macro-expansion.
1142   (if (not lexical-binding)
1143       exp
1144     (save-excursion
1145       (unless pos (setq pos (point)))
1146       (let ((vars ()))
1147         (goto-char (point-min))
1148         (while (re-search-forward
1149                 "(def\\(?:var\\|const\\|custom\\)[ \t\n]+\\([^; '()\n\t]+\\)"
1150                 pos t)
1151           (let ((var (intern (match-string 1))))
1152             (and (not (special-variable-p var))
1153                  (save-excursion
1154                    (zerop (car (syntax-ppss (match-beginning 0)))))
1155               (push var vars))))
1156         `(progn ,@(mapcar (lambda (v) `(defvar ,v)) vars) ,exp)))))
1157
1158 (defun eval-last-sexp (eval-last-sexp-arg-internal)
1159   "Evaluate sexp before point; print value in the echo area.
1160 Interactively, with prefix argument, print output into current buffer.
1161
1162 Normally, this function truncates long output according to the value
1163 of the variables `eval-expression-print-length' and
1164 `eval-expression-print-level'.  With a prefix argument of zero,
1165 however, there is no such truncation.  Such a prefix argument
1166 also causes integers to be printed in several additional formats
1167 \(octal, hexadecimal, and character).
1168
1169 If `eval-expression-debug-on-error' is non-nil, which is the default,
1170 this command arranges for all errors to enter the debugger."
1171   (interactive "P")
1172   (if (null eval-expression-debug-on-error)
1173       (elisp--eval-last-sexp eval-last-sexp-arg-internal)
1174     (let ((value
1175            (let ((debug-on-error elisp--eval-last-sexp-fake-value))
1176              (cons (elisp--eval-last-sexp eval-last-sexp-arg-internal)
1177                    debug-on-error))))
1178       (unless (eq (cdr value) elisp--eval-last-sexp-fake-value)
1179         (setq debug-on-error (cdr value)))
1180       (car value))))
1181
1182 (defun elisp--eval-defun-1 (form)
1183   "Treat some expressions specially.
1184 Reset the `defvar' and `defcustom' variables to the initial value.
1185 \(For `defcustom', use the :set function if there is one.)
1186 Reinitialize the face according to the `defface' specification."
1187   ;; The code in edebug-defun should be consistent with this, but not
1188   ;; the same, since this gets a macroexpanded form.
1189   (cond ((not (listp form))
1190          form)
1191         ((and (eq (car form) 'defvar)
1192               (cdr-safe (cdr-safe form))
1193               (boundp (cadr form)))
1194          ;; Force variable to be re-set.
1195          `(progn (defvar ,(nth 1 form) nil ,@(nthcdr 3 form))
1196                  (setq-default ,(nth 1 form) ,(nth 2 form))))
1197         ;; `defcustom' is now macroexpanded to
1198         ;; `custom-declare-variable' with a quoted value arg.
1199         ((and (eq (car form) 'custom-declare-variable)
1200               (default-boundp (eval (nth 1 form) lexical-binding)))
1201          ;; Force variable to be bound, using :set function if specified.
1202          (let ((setfunc (memq :set form)))
1203            (when setfunc
1204              (setq setfunc (car-safe (cdr-safe setfunc)))
1205              (or (functionp setfunc) (setq setfunc nil)))
1206            (funcall (or setfunc 'set-default)
1207                     (eval (nth 1 form) lexical-binding)
1208                     ;; The second arg is an expression that evaluates to
1209                     ;; an expression.  The second evaluation is the one
1210                     ;; normally performed not by normal execution but by
1211                     ;; custom-initialize-set (for example), which does not
1212                     ;; use lexical-binding.
1213                     (eval (eval (nth 2 form) lexical-binding))))
1214          form)
1215         ;; `defface' is macroexpanded to `custom-declare-face'.
1216         ((eq (car form) 'custom-declare-face)
1217          ;; Reset the face.
1218          (let ((face-symbol (eval (nth 1 form) lexical-binding)))
1219            (setq face-new-frame-defaults
1220                  (assq-delete-all face-symbol face-new-frame-defaults))
1221            (put face-symbol 'face-defface-spec nil)
1222            (put face-symbol 'face-override-spec nil))
1223          form)
1224         ((eq (car form) 'progn)
1225          (cons 'progn (mapcar #'elisp--eval-defun-1 (cdr form))))
1226         (t form)))
1227
1228 (defun elisp--eval-defun ()
1229   "Evaluate defun that point is in or before.
1230 The value is displayed in the echo area.
1231 If the current defun is actually a call to `defvar',
1232 then reset the variable using the initial value expression
1233 even if the variable already has some other value.
1234 \(Normally `defvar' does not change the variable's value
1235 if it already has a value.)
1236
1237 Return the result of evaluation."
1238   ;; FIXME: the print-length/level bindings should only be applied while
1239   ;; printing, not while evaluating.
1240   (let ((debug-on-error eval-expression-debug-on-error)
1241         (print-length eval-expression-print-length)
1242         (print-level eval-expression-print-level))
1243     (save-excursion
1244       ;; Arrange for eval-region to "read" the (possibly) altered form.
1245       ;; eval-region handles recording which file defines a function or
1246       ;; variable.
1247       (let ((standard-output t)
1248             beg end form)
1249         ;; Read the form from the buffer, and record where it ends.
1250         (save-excursion
1251           (end-of-defun)
1252           (beginning-of-defun)
1253           (setq beg (point))
1254           (setq form (read (current-buffer)))
1255           (setq end (point)))
1256         ;; Alter the form if necessary.
1257         (let ((form (eval-sexp-add-defvars
1258                      (elisp--eval-defun-1 (macroexpand form)))))
1259           (eval-region beg end standard-output
1260                        (lambda (_ignore)
1261                          ;; Skipping to the end of the specified region
1262                          ;; will make eval-region return.
1263                          (goto-char end)
1264                          form))))))
1265   (let ((str (eval-expression-print-format (car values))))
1266     (if str (princ str)))
1267   ;; The result of evaluation has been put onto VALUES.  So return it.
1268   (car values))
1269
1270 (defun eval-defun (edebug-it)
1271   "Evaluate the top-level form containing point, or after point.
1272
1273 If the current defun is actually a call to `defvar' or `defcustom',
1274 evaluating it this way resets the variable using its initial value
1275 expression (using the defcustom's :set function if there is one), even
1276 if the variable already has some other value.  \(Normally `defvar' and
1277 `defcustom' do not alter the value if there already is one.)  In an
1278 analogous way, evaluating a `defface' overrides any customizations of
1279 the face, so that it becomes defined exactly as the `defface' expression
1280 says.
1281
1282 If `eval-expression-debug-on-error' is non-nil, which is the default,
1283 this command arranges for all errors to enter the debugger.
1284
1285 With a prefix argument, instrument the code for Edebug.
1286
1287 If acting on a `defun' for FUNCTION, and the function was
1288 instrumented, `Edebug: FUNCTION' is printed in the echo area.  If not
1289 instrumented, just FUNCTION is printed.
1290
1291 If not acting on a `defun', the result of evaluation is displayed in
1292 the echo area.  This display is controlled by the variables
1293 `eval-expression-print-length' and `eval-expression-print-level',
1294 which see."
1295   (interactive "P")
1296   (cond (edebug-it
1297          (require 'edebug)
1298          (eval-defun (not edebug-all-defs)))
1299         (t
1300          (if (null eval-expression-debug-on-error)
1301              (elisp--eval-defun)
1302            (let (new-value value)
1303              (let ((debug-on-error elisp--eval-last-sexp-fake-value))
1304                (setq value (elisp--eval-defun))
1305                (setq new-value debug-on-error))
1306              (unless (eq elisp--eval-last-sexp-fake-value new-value)
1307                (setq debug-on-error new-value))
1308              value)))))
1309
1310 ;;; ElDoc Support
1311
1312 (defvar elisp--eldoc-last-data (make-vector 3 nil)
1313   "Bookkeeping; elements are as follows:
1314   0 - contains the last symbol read from the buffer.
1315   1 - contains the string last displayed in the echo area for variables,
1316       or argument string for functions.
1317   2 - `function' if function args, `variable' if variable documentation.")
1318
1319 (defun elisp-eldoc-documentation-function ()
1320   "`eldoc-documentation-function' (which see) for Emacs Lisp."
1321   (let ((current-symbol (elisp--current-symbol))
1322         (current-fnsym  (elisp--fnsym-in-current-sexp)))
1323     (cond ((null current-fnsym)
1324            nil)
1325           ((eq current-symbol (car current-fnsym))
1326            (or (apply #'elisp-get-fnsym-args-string current-fnsym)
1327                (elisp-get-var-docstring current-symbol)))
1328           (t
1329            (or (elisp-get-var-docstring current-symbol)
1330                (apply #'elisp-get-fnsym-args-string current-fnsym))))))
1331
1332 (defun elisp-get-fnsym-args-string (sym &optional index prefix)
1333   "Return a string containing the parameter list of the function SYM.
1334 If SYM is a subr and no arglist is obtainable from the docstring
1335 or elsewhere, return a 1-line docstring."
1336   (let ((argstring
1337          (cond
1338           ((not (and sym (symbolp sym) (fboundp sym))) nil)
1339           ((and (eq sym (aref elisp--eldoc-last-data 0))
1340                 (eq 'function (aref elisp--eldoc-last-data 2)))
1341            (aref elisp--eldoc-last-data 1))
1342           (t
1343            (let* ((advertised (gethash (indirect-function sym)
1344                                        advertised-signature-table t))
1345                   doc
1346                   (args
1347                    (cond
1348                     ((listp advertised) advertised)
1349                     ((setq doc (help-split-fundoc
1350                                 (condition-case nil (documentation sym t)
1351                                   (invalid-function nil))
1352                                 sym))
1353                      (car doc))
1354                     (t (help-function-arglist sym)))))
1355              ;; Stringify, and store before highlighting, downcasing, etc.
1356              (elisp--last-data-store sym (elisp-function-argstring args)
1357                                     'function))))))
1358     ;; Highlight, truncate.
1359     (if argstring
1360         (elisp--highlight-function-argument
1361          sym argstring index
1362          (or prefix
1363              (concat (propertize (symbol-name sym) 'face
1364                                  (if (functionp sym)
1365                                      'font-lock-function-name-face
1366                                    'font-lock-keyword-face))
1367                      ": "))))))
1368
1369 (defun elisp--highlight-function-argument (sym args index prefix)
1370   "Highlight argument INDEX in ARGS list for function SYM.
1371 In the absence of INDEX, just call `eldoc-docstring-format-sym-doc'."
1372   ;; FIXME: This should probably work on the list representation of `args'
1373   ;; rather than its string representation.
1374   ;; FIXME: This function is much too long, we need to split it up!
1375   (let ((start          nil)
1376         (end            0)
1377         (argument-face  'eldoc-highlight-function-argument)
1378         (args-lst (mapcar (lambda (x)
1379                             (replace-regexp-in-string
1380                              "\\`[(]\\|[)]\\'" "" x))
1381                           (split-string args))))
1382     ;; Find the current argument in the argument string.  We need to
1383     ;; handle `&rest' and informal `...' properly.
1384     ;;
1385     ;; FIXME: What to do with optional arguments, like in
1386     ;;        (defun NAME ARGLIST [DOCSTRING] BODY...) case?
1387     ;;        The problem is there is no robust way to determine if
1388     ;;        the current argument is indeed a docstring.
1389
1390     ;; When `&key' is used finding position based on `index'
1391     ;; would be wrong, so find the arg at point and determine
1392     ;; position in ARGS based on this current arg.
1393     (when (string-match "&key" args)
1394       (let* (case-fold-search
1395              key-have-value
1396              (sym-name (symbol-name sym))
1397              (cur-w (current-word))
1398              (args-lst-ak (cdr (member "&key" args-lst)))
1399              (limit (save-excursion
1400                       (when (re-search-backward sym-name nil t)
1401                         (match-end 0))))
1402              (cur-a (if (and cur-w (string-match ":\\([^ ()]*\\)" cur-w))
1403                         (substring cur-w 1)
1404                       (save-excursion
1405                         (let (split)
1406                           (when (re-search-backward ":\\([^()\n]*\\)" limit t)
1407                             (setq split (split-string (match-string 1) " " t))
1408                             (prog1 (car split)
1409                               (when (cdr split)
1410                                 (setq key-have-value t))))))))
1411              ;; If `cur-a' is not one of `args-lst-ak'
1412              ;; assume user is entering an unknown key
1413              ;; referenced in last position in signature.
1414              (other-key-arg (and (stringp cur-a)
1415                                  args-lst-ak
1416                                  (not (member (upcase cur-a) args-lst-ak))
1417                                  (upcase (car (last args-lst-ak))))))
1418         (unless (string= cur-w sym-name)
1419           ;; The last keyword have already a value
1420           ;; i.e :foo a b and cursor is at b.
1421           ;; If signature have also `&rest'
1422           ;; (assume it is after the `&key' section)
1423           ;; go to the arg after `&rest'.
1424           (if (and key-have-value
1425                    (save-excursion
1426                      (not (re-search-forward ":.*" (point-at-eol) t)))
1427                    (string-match "&rest \\([^ ()]*\\)" args))
1428               (setq index nil ; Skip next block based on positional args.
1429                     start (match-beginning 1)
1430                     end   (match-end 1))
1431             ;; If `cur-a' is nil probably cursor is on a positional arg
1432             ;; before `&key', in this case, exit this block and determine
1433             ;; position with `index'.
1434             (when (and cur-a     ; A keyword arg (dot removed) or nil.
1435                        (or (string-match
1436                             (concat "\\_<" (upcase cur-a) "\\_>") args)
1437                            (string-match
1438                             (concat "\\_<" other-key-arg "\\_>") args)))
1439               (setq index nil ; Skip next block based on positional args.
1440                     start (match-beginning 0)
1441                     end   (match-end 0)))))))
1442     ;; Handle now positional arguments.
1443     (while (and index (>= index 1))
1444       (if (string-match "[^ ()]+" args end)
1445           (progn
1446             (setq start (match-beginning 0)
1447                   end   (match-end 0))
1448             (let ((argument (match-string 0 args)))
1449               (cond ((string= argument "&rest")
1450                      ;; All the rest arguments are the same.
1451                      (setq index 1))
1452                     ((string= argument "&optional"))         ; Skip.
1453                     ((string= argument "&allow-other-keys")) ; Skip.
1454                     ;; Back to index 0 in ARG1 ARG2 ARG2 ARG3 etc...
1455                     ;; like in `setq'.
1456                     ((or (and (string-match-p "\\.\\.\\.\\'" argument)
1457                               (string= argument (car (last args-lst))))
1458                          (and (string-match-p "\\.\\.\\.\\'"
1459                                               (substring args 1 (1- (length args))))
1460                               (= (length (remove "..." args-lst)) 2)
1461                               (> index 1) (eq (logand index 1) 1)))
1462                      (setq index 0))
1463                     (t
1464                      (setq index (1- index))))))
1465         (setq end           (length args)
1466               start         (1- end)
1467               argument-face 'font-lock-warning-face
1468               index         0)))
1469     (let ((doc args))
1470       (when start
1471         (setq doc (copy-sequence args))
1472         (add-text-properties start end (list 'face argument-face) doc))
1473       (setq doc (eldoc-docstring-format-sym-doc prefix doc))
1474       doc)))
1475
1476 ;; Return a string containing a brief (one-line) documentation string for
1477 ;; the variable.
1478 (defun elisp-get-var-docstring (sym)
1479   (cond ((not sym) nil)
1480         ((and (eq sym (aref elisp--eldoc-last-data 0))
1481               (eq 'variable (aref elisp--eldoc-last-data 2)))
1482          (aref elisp--eldoc-last-data 1))
1483         (t
1484          (let ((doc (documentation-property sym 'variable-documentation t)))
1485            (when doc
1486              (let ((doc (eldoc-docstring-format-sym-doc
1487                          sym (elisp--docstring-first-line doc)
1488                          'font-lock-variable-name-face)))
1489                (elisp--last-data-store sym doc 'variable)))))))
1490
1491 (defun elisp--last-data-store (symbol doc type)
1492   (aset elisp--eldoc-last-data 0 symbol)
1493   (aset elisp--eldoc-last-data 1 doc)
1494   (aset elisp--eldoc-last-data 2 type)
1495   doc)
1496
1497 ;; Note that any leading `*' in the docstring (which indicates the variable
1498 ;; is a user option) is removed.
1499 (defun elisp--docstring-first-line (doc)
1500   (and (stringp doc)
1501        (substitute-command-keys
1502         (save-match-data
1503           ;; Don't use "^" in the regexp below since it may match
1504           ;; anywhere in the doc-string.
1505           (let ((start (if (string-match "\\`\\*" doc) (match-end 0) 0)))
1506             (cond ((string-match "\n" doc)
1507                    (substring doc start (match-beginning 0)))
1508                   ((zerop start) doc)
1509                   (t (substring doc start))))))))
1510 \f
1511 ;; Return a list of current function name and argument index.
1512 (defun elisp--fnsym-in-current-sexp ()
1513   (save-excursion
1514     (let ((argument-index (1- (elisp--beginning-of-sexp))))
1515       ;; If we are at the beginning of function name, this will be -1.
1516       (when (< argument-index 0)
1517         (setq argument-index 0))
1518       ;; Don't do anything if current word is inside a string.
1519       (if (= (or (char-after (1- (point))) 0) ?\")
1520           nil
1521         (list (elisp--current-symbol) argument-index)))))
1522
1523 ;; Move to the beginning of current sexp.  Return the number of nested
1524 ;; sexp the point was over or after.
1525 (defun elisp--beginning-of-sexp ()
1526   (let ((parse-sexp-ignore-comments t)
1527         (num-skipped-sexps 0))
1528     (condition-case _
1529         (progn
1530           ;; First account for the case the point is directly over a
1531           ;; beginning of a nested sexp.
1532           (condition-case _
1533               (let ((p (point)))
1534                 (forward-sexp -1)
1535                 (forward-sexp 1)
1536                 (when (< (point) p)
1537                   (setq num-skipped-sexps 1)))
1538             (error))
1539           (while
1540               (let ((p (point)))
1541                 (forward-sexp -1)
1542                 (when (< (point) p)
1543                   (setq num-skipped-sexps (1+ num-skipped-sexps))))))
1544       (error))
1545     num-skipped-sexps))
1546
1547 ;; returns nil unless current word is an interned symbol.
1548 (defun elisp--current-symbol ()
1549   (let ((c (char-after (point))))
1550     (and c
1551          (memq (char-syntax c) '(?w ?_))
1552          (intern-soft (current-word)))))
1553
1554 (defun elisp-function-argstring (arglist)
1555   "Return ARGLIST as a string enclosed by ().
1556 ARGLIST is either a string, or a list of strings or symbols."
1557   (let ((str (cond ((stringp arglist) arglist)
1558                    ((not (listp arglist)) nil)
1559                    (t (help--make-usage-docstring 'toto arglist)))))
1560     (if (and str (string-match "\\`([^ )]+ ?" str))
1561         (replace-match "(" t t str)
1562       str)))
1563
1564 (provide 'elisp-mode)
1565 ;;; elisp-mode.el ends here