code.delx.au - gnu-emacs/blob - lisp/emacs-lisp/derived.el

   1 ;;; derived.el --- allow inheritance of major modes
   2 ;; (formerly mode-clone.el)
   3
   4 ;; Copyright (C) 1993-1994, 1999, 2001-2016 Free Software Foundation,
   5 ;; Inc.
   6
   7 ;; Author: David Megginson (dmeggins@aix1.uottawa.ca)
   8 ;; Maintainer: emacs-devel@gnu.org
   9 ;; Keywords: extensions
  10 ;; Package: emacs
  11
  12 ;; This file is part of GNU Emacs.
  13
  14 ;; GNU Emacs is free software: you can redistribute it and/or modify
  15 ;; it under the terms of the GNU General Public License as published by
  16 ;; the Free Software Foundation, either version 3 of the License, or
  17 ;; (at your option) any later version.
  18
  19 ;; GNU Emacs is distributed in the hope that it will be useful,
  20 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ;; GNU General Public License for more details.
  23
  24 ;; You should have received a copy of the GNU General Public License
  25 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  26 \f
  27 ;;; Commentary:
  28
  29 ;; GNU Emacs is already, in a sense, object oriented -- each object
  30 ;; (buffer) belongs to a class (major mode), and that class defines
  31 ;; the relationship between messages (input events) and methods
  32 ;; (commands) by means of a keymap.
  33 ;;
  34 ;; The only thing missing is a good scheme of inheritance.  It is
  35 ;; possible to simulate a single level of inheritance with generous
  36 ;; use of hooks and a bit of work -- sgml-mode, for example, also runs
  37 ;; the hooks for text-mode, and keymaps can inherit from other keymaps
  38 ;; -- but generally, each major mode ends up reinventing the wheel.
  39 ;; Ideally, someone should redesign all of Emacs's major modes to
  40 ;; follow a more conventional object-oriented system: when defining a
  41 ;; new major mode, the user should need only to name the existing mode
  42 ;; it is most similar to, then list the (few) differences.
  43 ;;
  44 ;; In the mean time, this package offers most of the advantages of
  45 ;; full inheritance with the existing major modes.  The macro
  46 ;; `define-derived-mode' allows the user to make a variant of an existing
  47 ;; major mode, with its own keymap.  The new mode will inherit the key
  48 ;; bindings of its parent, and will, in fact, run its parent first
  49 ;; every time it is called.  For example, the commands
  50 ;;
  51 ;;  (define-derived-mode hypertext-mode text-mode "Hypertext"
  52 ;;    "Major mode for hypertext.\n\n\\{hypertext-mode-map}"
  53 ;;    (setq case-fold-search nil))
  54 ;;
  55 ;;  (define-key hypertext-mode-map [down-mouse-3] 'do-hyper-link)
  56 ;;
  57 ;; will create a function `hypertext-mode' with its own (sparse)
  58 ;; keymap `hypertext-mode-map.'  The command M-x hypertext-mode will
  59 ;; perform the following actions:
  60 ;;
  61 ;; - run the command (text-mode) to get its default setup
  62 ;; - replace the current keymap with 'hypertext-mode-map,' which will
  63 ;;   inherit from 'text-mode-map'.
  64 ;; - replace the current syntax table with
  65 ;;   'hypertext-mode-syntax-table', which will borrow its defaults
  66 ;;   from the current text-mode-syntax-table.
  67 ;; - replace the current abbrev table with
  68 ;;   'hypertext-mode-abbrev-table', which will borrow its defaults
  69 ;;   from the current text-mode-abbrev table
  70 ;; - change the mode line to read "Hypertext"
  71 ;; - assign the value 'hypertext-mode' to the 'major-mode' variable
  72 ;; - run the body of commands provided in the macro -- in this case,
  73 ;;   set the local variable `case-fold-search' to nil.
  74 ;;
  75 ;; The advantages of this system are threefold.  First, text mode is
  76 ;; untouched -- if you had added the new keystroke to `text-mode-map,'
  77 ;; possibly using hooks, you would have added it to all text buffers
  78 ;; -- here, it appears only in hypertext buffers, where it makes
  79 ;; sense.  Second, it is possible to build even further, and make
  80 ;; a derived mode from a derived mode.  The commands
  81 ;;
  82 ;;   (define-derived-mode html-mode hypertext-mode "HTML")
  83 ;;   [various key definitions]
  84 ;;
  85 ;; will add a new major mode for HTML with very little fuss.
  86 ;;
  87 ;; Note also the function `derived-mode-p' which can tell if the current
  88 ;; mode derives from another.  In a hypertext-mode, buffer, for example,
  89 ;; (derived-mode-p 'text-mode) would return non-nil.  This should always
  90 ;; be used in place of (eq major-mode 'text-mode).
  91 \f
  92 ;;; Code:
  93
  94 ;;; PRIVATE: defsubst must be defined before they are first used
  95
  96 (defsubst derived-mode-hook-name (mode)
  97   "Construct a mode-hook name based on a MODE name."
  98   (intern (concat (symbol-name mode) "-hook")))
  99
 100 (defsubst derived-mode-map-name (mode)
 101   "Construct a map name based on a MODE name."
 102   (intern (concat (symbol-name mode) "-map")))
 103
 104 (defsubst derived-mode-syntax-table-name (mode)
 105   "Construct a syntax-table name based on a MODE name."
 106   (intern (concat (symbol-name mode) "-syntax-table")))
 107
 108 (defsubst derived-mode-abbrev-table-name (mode)
 109   "Construct an abbrev-table name based on a MODE name."
 110   (intern (concat (symbol-name mode) "-abbrev-table")))
 111
 112 ;; PUBLIC: define a new major mode which inherits from an existing one.
 113
 114 ;;;###autoload
 115 (defmacro define-derived-mode (child parent name &optional docstring &rest body)
 116   "Create a new mode as a variant of an existing mode.
 117
 118 The arguments to this command are as follow:
 119
 120 CHILD:     the name of the command for the derived mode.
 121 PARENT:    the name of the command for the parent mode (e.g. `text-mode')
 122            or nil if there is no parent.
 123 NAME:      a string which will appear in the status line (e.g. \"Hypertext\")
 124 DOCSTRING: an optional documentation string--if you do not supply one,
 125            the function will attempt to invent something useful.
 126 BODY:      forms to execute just before running the
 127            hooks for the new mode.  Do not use `interactive' here.
 128
 129 BODY can start with a bunch of keyword arguments.  The following keyword
 130   arguments are currently understood:
 131 :group GROUP
 132         Declare the customization group that corresponds to this mode.
 133         The command `customize-mode' uses this.
 134 :syntax-table TABLE
 135         Use TABLE instead of the default (CHILD-syntax-table).
 136         A nil value means to simply use the same syntax-table as the parent.
 137 :abbrev-table TABLE
 138         Use TABLE instead of the default (CHILD-abbrev-table).
 139         A nil value means to simply use the same abbrev-table as the parent.
 140
 141 Here is how you could define LaTeX-Thesis mode as a variant of LaTeX mode:
 142
 143   (define-derived-mode LaTeX-thesis-mode LaTeX-mode \"LaTeX-Thesis\")
 144
 145 You could then make new key bindings for `LaTeX-thesis-mode-map'
 146 without changing regular LaTeX mode.  In this example, BODY is empty,
 147 and DOCSTRING is generated by default.
 148
 149 On a more complicated level, the following command uses `sgml-mode' as
 150 the parent, and then sets the variable `case-fold-search' to nil:
 151
 152   (define-derived-mode article-mode sgml-mode \"Article\"
 153     \"Major mode for editing technical articles.\"
 154     (setq case-fold-search nil))
 155
 156 Note that if the documentation string had been left out, it would have
 157 been generated automatically, with a reference to the keymap.
 158
 159 The new mode runs the hook constructed by the function
 160 `derived-mode-hook-name'.
 161
 162 See Info node `(elisp)Derived Modes' for more details."
 163   (declare (debug (&define name symbolp sexp [&optional stringp]
 164                            [&rest keywordp sexp] def-body))
 165            (doc-string 4)
 166            ;; Ask not what
 167            ;;(indent 3)
 168            ;; can do for you, ask what it can do to others. IOW, the
 169            ;; missing of indentation setting here is the indentation
 170            ;; setting and not an oversight.
 171            )
 172
 173   (when (and docstring (not (stringp docstring)))
 174     ;; Some trickiness, since what appears to be the docstring may really be
 175     ;; the first element of the body.
 176     (push docstring body)
 177     (setq docstring nil))
 178
 179   (when (eq parent 'fundamental-mode) (setq parent nil))
 180
 181   (let ((map (derived-mode-map-name child))
 182         (syntax (derived-mode-syntax-table-name child))
 183         (abbrev (derived-mode-abbrev-table-name child))
 184         (declare-abbrev t)
 185         (declare-syntax t)
 186         (hook (derived-mode-hook-name child))
 187         (group nil))
 188
 189     ;; Process the keyword args.
 190     (while (keywordp (car body))
 191       (pcase (pop body)
 192         (`:group (setq group (pop body)))
 193         (`:abbrev-table (setq abbrev (pop body)) (setq declare-abbrev nil))
 194         (`:syntax-table (setq syntax (pop body)) (setq declare-syntax nil))
 195         (_ (pop body))))
 196
 197     (setq docstring (derived-mode-make-docstring
 198                      parent child docstring syntax abbrev))
 199
 200     `(progn
 201        (defvar ,hook nil
 202          ,(format "Hook run after entering %s mode.
 203 No problems result if this variable is not bound.
 204 `add-hook' automatically binds it.  (This is true for all hook variables.)"
 205                   name))
 206        (unless (boundp ',map)
 207          (put ',map 'definition-name ',child))
 208        (with-no-warnings (defvar ,map (make-sparse-keymap)))
 209        (unless (get ',map 'variable-documentation)
 210          (put ',map 'variable-documentation
 211               (purecopy ,(format "Keymap for `%s'." child))))
 212        ,(if declare-syntax
 213             `(progn
 214                (unless (boundp ',syntax)
 215                  (put ',syntax 'definition-name ',child))
 216                (defvar ,syntax (make-syntax-table))
 217                (unless (get ',syntax 'variable-documentation)
 218                  (put ',syntax 'variable-documentation
 219                       (purecopy ,(format "Syntax table for `%s'." child))))))
 220        ,(if declare-abbrev
 221             `(progn
 222                (put ',abbrev 'definition-name ',child)
 223                (defvar ,abbrev
 224                  (progn (define-abbrev-table ',abbrev nil) ,abbrev))
 225                (unless (get ',abbrev 'variable-documentation)
 226                  (put ',abbrev 'variable-documentation
 227                       (purecopy ,(format "Abbrev table for `%s'." child))))))
 228        (put ',child 'derived-mode-parent ',parent)
 229        ,(if group `(put ',child 'custom-mode-group ,group))
 230
 231        (defun ,child ()
 232          ,docstring
 233          (interactive)
 234                                         ; Run the parent.
 235          (delay-mode-hooks
 236
 237           (,(or parent 'kill-all-local-variables))
 238                                         ; Identify the child mode.
 239           (setq major-mode (quote ,child))
 240           (setq mode-name ,name)
 241                                         ; Identify special modes.
 242           ,(when parent
 243              `(progn
 244                 (if (get (quote ,parent) 'mode-class)
 245                     (put (quote ,child) 'mode-class
 246                          (get (quote ,parent) 'mode-class)))
 247                                         ; Set up maps and tables.
 248                 (unless (keymap-parent ,map)
 249                   ;; It would probably be better to set the keymap's parent
 250                   ;; at the toplevel rather than inside the mode function,
 251                   ;; but this is not easy for at least the following reasons:
 252                   ;; - the parent (and its keymap) may not yet be loaded.
 253                   ;; - the parent's keymap name may be called something else
 254                   ;;   than <parent>-mode-map.
 255                   (set-keymap-parent ,map (current-local-map)))
 256                 ,(when declare-syntax
 257                    `(let ((parent (char-table-parent ,syntax)))
 258                       (unless (and parent
 259                                    (not (eq parent (standard-syntax-table))))
 260                         (set-char-table-parent ,syntax (syntax-table)))))
 261                 ,(when declare-abbrev
 262                    `(unless (or (abbrev-table-get ,abbrev :parents)
 263                                 ;; This can happen if the major mode defines
 264                                 ;; the abbrev-table to be its parent's.
 265                                 (eq ,abbrev local-abbrev-table))
 266                       (abbrev-table-put ,abbrev :parents
 267                                         (list local-abbrev-table))))))
 268           (use-local-map ,map)
 269           ,(when syntax `(set-syntax-table ,syntax))
 270           ,(when abbrev `(setq local-abbrev-table ,abbrev))
 271                                         ; Splice in the body (if any).
 272           ,@body
 273           )
 274          ;; Run the hooks, if any.
 275          (run-mode-hooks ',hook)))))
 276
 277 ;; PUBLIC: find the ultimate class of a derived mode.
 278
 279 (defun derived-mode-class (mode)
 280   "Find the class of a major MODE.
 281 A mode's class is the first ancestor which is NOT a derived mode.
 282 Use the `derived-mode-parent' property of the symbol to trace backwards.
 283 Since major-modes might all derive from `fundamental-mode', this function
 284 is not very useful."
 285   (declare (obsolete derived-mode-p "22.1"))
 286   (while (get mode 'derived-mode-parent)
 287     (setq mode (get mode 'derived-mode-parent)))
 288   mode)
 289
 290 \f
 291 ;;; PRIVATE
 292
 293 (defun derived-mode-make-docstring (parent child &optional
 294                                            docstring syntax abbrev)
 295   "Construct a docstring for a new mode if none is provided."
 296
 297   (let ((map (derived-mode-map-name child))
 298         (hook (derived-mode-hook-name child)))
 299
 300     (unless (stringp docstring)
 301       ;; Use a default docstring.
 302       (setq docstring
 303             (if (null parent)
 304                 ;; FIXME filling.
 305                 (format "Major-mode.\nUses keymap `%s'%s%s." map
 306                         (if abbrev (format "%s abbrev table `%s'"
 307                                            (if syntax "," " and") abbrev) "")
 308                         (if syntax (format " and syntax-table `%s'" syntax) ""))
 309               (format "Major mode derived from `%s' by `define-derived-mode'.
 310 It inherits all of the parent's attributes, but has its own keymap%s:
 311
 312   `%s'%s
 313
 314 which more-or-less shadow%s %s's corresponding table%s."
 315                       parent
 316                       (cond ((and abbrev syntax)
 317                              ",\nabbrev table and syntax table")
 318                             (abbrev "\nand abbrev table")
 319                             (syntax "\nand syntax table")
 320                             (t ""))
 321                       map
 322                       (cond ((and abbrev syntax)
 323                              (format ", `%s' and `%s'" abbrev syntax))
 324                             ((or abbrev syntax)
 325                              (format " and `%s'" (or abbrev syntax)))
 326                             (t ""))
 327                       (if (or abbrev syntax) "" "s")
 328                       parent
 329                       (if (or abbrev syntax) "s" "")))))
 330
 331     (unless (string-match (regexp-quote (symbol-name hook)) docstring)
 332       ;; Make sure the docstring mentions the mode's hook.
 333       (setq docstring
 334             (concat docstring
 335                     (if (null parent)
 336                         "\n\nThis mode "
 337                       (concat
 338                        "\n\nIn addition to any hooks its parent mode "
 339                        (if (string-match (format "[`‘]%s['’]"
 340                                                  (regexp-quote
 341                                                   (symbol-name parent)))
 342                                          docstring)
 343                            nil
 344                          (format "`%s' " parent))
 345                        "might have run,\nthis mode "))
 346                     (format "runs the hook `%s'" hook)
 347                     ", as the final step\nduring initialization.")))
 348
 349     (unless (string-match "\\\\[{[]" docstring)
 350       ;; And don't forget to put the mode's keymap.
 351       (setq docstring (concat docstring "\n\n\\{" (symbol-name map) "}")))
 352
 353     docstring))
 354
 355 \f
 356 ;;; OBSOLETE
 357 ;; The functions below are only provided for backward compatibility with
 358 ;; code byte-compiled with versions of derived.el prior to Emacs-21.
 359
 360 (defsubst derived-mode-setup-function-name (mode)
 361   "Construct a setup-function name based on a MODE name."
 362   (intern (concat (symbol-name mode) "-setup")))
 363
 364 \f
 365 ;; Utility functions for defining a derived mode.
 366
 367 ;;;###autoload
 368 (defun derived-mode-init-mode-variables (mode)
 369   "Initialize variables for a new MODE.
 370 Right now, if they don't already exist, set up a blank keymap, an
 371 empty syntax table, and an empty abbrev table -- these will be merged
 372 the first time the mode is used."
 373
 374   (if (boundp (derived-mode-map-name mode))
 375       t
 376     (eval `(defvar ,(derived-mode-map-name mode)
 377                (make-sparse-keymap)
 378                ,(format "Keymap for %s." mode)))
 379     (put (derived-mode-map-name mode) 'derived-mode-unmerged t))
 380
 381   (if (boundp (derived-mode-syntax-table-name mode))
 382       t
 383     (eval `(defvar ,(derived-mode-syntax-table-name mode)
 384              ;; Make a syntax table which doesn't specify anything
 385              ;; for any char.  Valid data will be merged in by
 386              ;; derived-mode-merge-syntax-tables.
 387              (make-char-table 'syntax-table nil)
 388              ,(format "Syntax table for %s." mode)))
 389     (put (derived-mode-syntax-table-name mode) 'derived-mode-unmerged t))
 390
 391   (if (boundp (derived-mode-abbrev-table-name mode))
 392       t
 393     (eval `(defvar ,(derived-mode-abbrev-table-name mode)
 394              (progn
 395                (define-abbrev-table (derived-mode-abbrev-table-name mode) nil)
 396                (make-abbrev-table))
 397              ,(format "Abbrev table for %s." mode)))))
 398 \f
 399 ;; Utility functions for running a derived mode.
 400
 401 (defun derived-mode-set-keymap (mode)
 402   "Set the keymap of the new MODE, maybe merging with the parent."
 403   (let* ((map-name (derived-mode-map-name mode))
 404          (new-map (eval map-name))
 405          (old-map (current-local-map)))
 406     (and old-map
 407          (get map-name 'derived-mode-unmerged)
 408          (derived-mode-merge-keymaps old-map new-map))
 409     (put map-name 'derived-mode-unmerged nil)
 410     (use-local-map new-map)))
 411
 412 (defun derived-mode-set-syntax-table (mode)
 413   "Set the syntax table of the new MODE, maybe merging with the parent."
 414   (let* ((table-name (derived-mode-syntax-table-name mode))
 415          (old-table (syntax-table))
 416          (new-table (eval table-name)))
 417     (if (get table-name 'derived-mode-unmerged)
 418         (derived-mode-merge-syntax-tables old-table new-table))
 419     (put table-name 'derived-mode-unmerged nil)
 420     (set-syntax-table new-table)))
 421
 422 (defun derived-mode-set-abbrev-table (mode)
 423   "Set the abbrev table for MODE if it exists.
 424 Always merge its parent into it, since the merge is non-destructive."
 425   (let* ((table-name (derived-mode-abbrev-table-name mode))
 426          (old-table local-abbrev-table)
 427          (new-table (eval table-name)))
 428     (derived-mode-merge-abbrev-tables old-table new-table)
 429     (setq local-abbrev-table new-table)))
 430
 431 (defun derived-mode-run-hooks (mode)
 432    "Run the mode hook for MODE."
 433    (let ((hooks-name (derived-mode-hook-name mode)))
 434      (if (boundp hooks-name)
 435          (run-hooks hooks-name))))
 436
 437 ;; Functions to merge maps and tables.
 438
 439 (defun derived-mode-merge-keymaps (old new)
 440   "Merge an OLD keymap into a NEW one.
 441 The old keymap is set to be the last cdr of the new one, so that there will
 442 be automatic inheritance."
 443   ;; ?? Can this just use `set-keymap-parent'?
 444   (let ((tail new))
 445     ;; Scan the NEW map for prefix keys.
 446     (while (consp tail)
 447       (and (consp (car tail))
 448            (let* ((key (vector (car (car tail))))
 449                   (subnew (lookup-key new key))
 450                   (subold (lookup-key old key)))
 451              ;; If KEY is a prefix key in both OLD and NEW, merge them.
 452              (and (keymapp subnew) (keymapp subold)
 453                   (derived-mode-merge-keymaps subold subnew))))
 454       (and (vectorp (car tail))
 455            ;; Search a vector of ASCII char bindings for prefix keys.
 456            (let ((i (1- (length (car tail)))))
 457              (while (>= i 0)
 458                (let* ((key (vector i))
 459                       (subnew (lookup-key new key))
 460                       (subold (lookup-key old key)))
 461                  ;; If KEY is a prefix key in both OLD and NEW, merge them.
 462                  (and (keymapp subnew) (keymapp subold)
 463                       (derived-mode-merge-keymaps subold subnew)))
 464                (setq i (1- i)))))
 465       (setq tail (cdr tail))))
 466   (setcdr (nthcdr (1- (length new)) new) old))
 467
 468 (defun derived-mode-merge-syntax-tables (old new)
 469   "Merge an OLD syntax table into a NEW one.
 470 Where the new table already has an entry, nothing is copied from the old one."
 471   (set-char-table-parent new old))
 472
 473 ;; Merge an old abbrev table into a new one.
 474 ;; This function requires internal knowledge of how abbrev tables work,
 475 ;; presuming that they are obarrays with the abbrev as the symbol, the expansion
 476 ;; as the value of the symbol, and the hook as the function definition.
 477 (defun derived-mode-merge-abbrev-tables (old new)
 478   (if old
 479       (mapatoms
 480        (lambda (symbol)
 481          (or (intern-soft (symbol-name symbol) new)
 482              (define-abbrev new (symbol-name symbol)
 483                (symbol-value symbol) (symbol-function symbol))))
 484        old)))
 485
 486 (provide 'derived)
 487
 488 ;;; derived.el ends here