code.delx.au - gnu-emacs/blob - lisp/startup.el

   1 ;;; startup.el --- process Emacs shell arguments
   2
   3 ;; Copyright (C) 1985, 1986, 1992, 1994 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6 ;; Keywords: internal
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  22 ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  23
  24 ;;; Commentary:
  25
  26 ; These are processed only at the beginning of the argument list.
  27 ; -batch                execute noninteractively (messages go to stdout,
  28 ;                        variable noninteractive set to t)
  29 ;                        This option must be the first in the arglist.
  30 ;                        Processed by `main' in emacs.c -- never seen by lisp
  31 ; -t file               Specify to use file rather than stdin/stdout
  32 ;                        as the terminal.
  33 ;                        This option must be the first in the arglist.
  34 ;                        Processed by `main' in emacs.c -- never seen by lisp
  35 ; -nw                   Inhibit the use of any window-system-specific display
  36 ;                        code; use the current virtual terminal.
  37 ;                        This option must be the first in the arglist.
  38 ;                        Processed by `main' in emacs.c -- never seen by lisp
  39 ; -q                    load no init file
  40 ; -no-init-file         same
  41 ; -u user               load user's init file
  42 ; -user user            same
  43 ; -debug-init           Don't catch errors in init file; let debugger run.
  44 ; -no-site-file         Don't load site-run-file.
  45
  46 ; These are processed in the order encountered.
  47 ; -f function           execute function
  48 ; -funcall function     same
  49 ; -l file               load file
  50 ; -load file            same
  51 ; -insert file          insert file into buffer
  52 ; file                  visit file
  53 ; -kill                 kill (exit) emacs
  54
  55 ;;; Code:
  56
  57 (setq top-level '(normal-top-level))
  58
  59 (defvar command-line-processed nil "t once command line has been processed")
  60
  61 (defconst inhibit-startup-message nil
  62   "*Non-nil inhibits the initial startup message.
  63 This is for use in your personal init file, once you are familiar
  64 with the contents of the startup message.")
  65
  66 (defconst inhibit-startup-echo-area-message nil
  67   "*Non-nil inhibits the initial startup echo area message.
  68 Inhibition takes effect only if your `.emacs' file contains
  69 a line of this form:
  70  (setq inhibit-startup-echo-area-message \"YOUR-USER-NAME\")
  71 If your `.emacs' file is byte-compiled, use the following form instead:
  72  (eval '(setq inhibit-startup-echo-area-message \"YOUR-USER-NAME\"))
  73 Thus, someone else using a copy of your `.emacs' file will see
  74 the startup message unless he personally acts to inhibit it.")
  75
  76 (defconst inhibit-default-init nil
  77   "*Non-nil inhibits loading the `default' library.")
  78
  79 (defconst command-switch-alist nil
  80   "Alist of command-line switches.
  81 Elements look like (SWITCH-STRING . HANDLER-FUNCTION).
  82 HANDLER-FUNCTION receives switch name as sole arg;
  83 remaining command-line args are in the variable `command-line-args-left'.")
  84
  85 (defvar command-line-args-left nil
  86   "List of command-line args not yet processed.")
  87
  88 (defvar command-line-functions nil    ;; lrs 7/31/89
  89   "List of functions to process unrecognized command-line arguments.
  90 Each function should access the dynamically bound variables
  91 `argi' (the current argument) and `command-line-args-left' (the remaining
  92 arguments).  The function should return non-nil only if it recognizes and
  93 processes `argi'.  If it does so, it may consume successive arguments by
  94 altering `command-line-args-left' to remove them.")
  95
  96 (defvar command-line-default-directory nil
  97   "Default directory to use for command line arguments.
  98 This is normally copied from `default-directory' when Emacs starts.")
  99
 100 (defvar before-init-hook nil
 101   "Functions to call after handling urgent options but before init files.
 102 The frame system uses this to open frames to display messages while
 103 Emacs loads the user's initialization file.")
 104
 105 (defvar after-init-hook nil
 106   "Functions to call after loading the init file (`~/.emacs').
 107 The call is not protected by a condition-case, so you can set `debug-on-error'
 108 in `.emacs', and put all the actual code on `after-init-hook'.")
 109
 110 (defvar term-setup-hook nil
 111   "Functions to be called after loading terminal-specific Lisp code.
 112 See `run-hooks'.  This variable exists for users to set,
 113 so as to override the definitions made by the terminal-specific file.
 114 Emacs never sets this variable itself.")
 115
 116 (defvar keyboard-type nil
 117   "The brand of keyboard you are using.
 118 This variable is used to define
 119 the proper function and keypad keys for use under X.  It is used in a
 120 fashion analogous to the environment value TERM.")
 121
 122 (defvar window-setup-hook nil
 123   "Normal hook run to initialize window system display.
 124 Emacs runs this hook after processing the command line arguments and loading
 125 the user's init file.")
 126
 127 (defconst initial-major-mode 'lisp-interaction-mode
 128   "Major mode command symbol to use for the initial *scratch* buffer.")
 129
 130 (defvar init-file-user nil
 131   "Identity of user whose `.emacs' file is or was read.
 132 The value is nil if no init file is being used; otherwise, it may be either
 133 the null string, meaning that the init file was taken from the user that
 134 originally logged in, or it may be a string containing a user's name.
 135
 136 In either of the latter cases, `(concat \"~\" init-file-user \"/\")'
 137 evaluates to the name of the directory where the `.emacs' file was
 138 looked for.")
 139
 140 (defvar site-run-file "site-start"
 141   "File containing site-wide run-time initializations.
 142 This file is loaded at run-time before `~/.emacs'.  It contains inits
 143 that need to be in place for the entire site, but which, due to their
 144 higher incidence of change, don't make sense to load into emacs'
 145 dumped image.  Thus, the run-time load order is: 1. file described in
 146 this variable, if non-nil; 2. `~/.emacs'; 3. `default.el'.")
 147
 148 (defconst iso-8859-1-locale-regexp "8859[-_]?1"
 149   "Regexp that specifies when to enable the ISO 8859-1 character set.
 150 We do that if this regexp matches the locale name
 151 specified by the LC_ALL, LC_CTYPE and LANG environment variables.")
 152
 153 (defvar mail-host-address nil
 154   "*Name of this machine, for purposes of naming users.")
 155
 156 (defvar user-mail-address nil
 157   "*Full mailing address of this user.")
 158
 159 (defvar init-file-debug nil)
 160
 161 (defvar init-file-had-error nil)
 162
 163 (defun normal-top-level ()
 164   (if command-line-processed
 165       (message "Back to top level.")
 166     (setq command-line-processed t)
 167     (if (not (eq system-type 'vax-vms))
 168         (progn
 169           ;; If the PWD environment variable isn't accurate, delete it.
 170           (let ((pwd (getenv "PWD")))
 171             (and (stringp pwd)
 172                  ;; Use FOO/., so that if FOO is a symlink, file-attributes
 173                  ;; describes the directory linked to, not FOO itself.
 174                  (or (equal (file-attributes
 175                              (concat (file-name-as-directory pwd) "."))
 176                             (file-attributes
 177                              (concat (file-name-as-directory default-directory)
 178                                      ".")))
 179                      (setq process-environment
 180                            (delete (concat "PWD=" pwd)
 181                                    process-environment)))))))
 182     (setq default-directory (abbreviate-file-name default-directory))
 183     (setq user-mail-address (concat (user-login-name) "@"
 184                                     (or mail-host-address
 185                                         (system-name))))
 186     (let ((menubar-bindings-done nil))
 187       (unwind-protect
 188           (command-line)
 189         ;; Do this again, in case .emacs defined more abbreviations.
 190         (setq default-directory (abbreviate-file-name default-directory))
 191         (run-hooks 'emacs-startup-hook)
 192         (and term-setup-hook
 193              (run-hooks 'term-setup-hook))
 194         ;; Modify the initial frame based on what .emacs puts into
 195         ;; ...-frame-alist.
 196         (if (fboundp 'frame-notice-user-settings)
 197             (frame-notice-user-settings))
 198         ;; Now we know the user's default font, so add it to the menu.
 199         (if (fboundp 'font-menu-add-default)
 200             (font-menu-add-default))
 201         (and window-setup-hook
 202              (run-hooks 'window-setup-hook))
 203         (or menubar-bindings-done
 204             (precompute-menubar-bindings))))))
 205
 206 ;; Precompute the keyboard equivalents in the menu bar items.
 207 (defun precompute-menubar-bindings ()
 208   (if (eq window-system 'x)
 209       (let ((submap (lookup-key global-map [menu-bar])))
 210         (while submap
 211           (and (consp (car submap))
 212                (symbolp (car (car submap)))
 213                (stringp (car-safe (cdr (car submap))))
 214                (keymapp (cdr (cdr (car submap))))
 215                (x-popup-menu nil (cdr (cdr (car submap)))))
 216           (setq submap (cdr submap))))))
 217
 218 (defun command-line ()
 219   (setq command-line-default-directory default-directory)
 220
 221   ;; See if we should import version-control from the environment variable.
 222   (let ((vc (getenv "VERSION_CONTROL")))
 223     (cond ((eq vc nil))                 ;don't do anything if not set
 224           ((or (string= vc "t")
 225                (string= vc "numbered"))
 226            (setq version-control t))
 227           ((or (string= vc "nil")
 228                (string= vc "existing"))
 229            (setq version-control nil))
 230           ((or (string= vc "never")
 231                (string= vc "simple"))
 232            (setq version-control 'never))))
 233
 234   (if (let ((ctype
 235              ;; Use the first of these three envvars that has a nonempty value.
 236              (or (let ((string (getenv "LC_ALL")))
 237                    (and (not (equal string "")) string))
 238                  (let ((string (getenv "LC_CTYPE")))
 239                    (and (not (equal string "")) string))
 240                  (let ((string (getenv "LANG")))
 241                    (and (not (equal string "")) string)))))
 242         (and ctype
 243              (string-match iso-8859-1-locale-regexp ctype)))
 244       (progn
 245         (standard-display-european t)
 246         (require 'iso-syntax)))
 247
 248   ;;! This has been commented out; I currently find the behavior when
 249   ;;! split-window-keep-point is nil disturbing, but if I can get used
 250   ;;! to it, then it would be better to eliminate the option.
 251   ;;! ;; Choose a good default value for split-window-keep-point.
 252   ;;! (setq split-window-keep-point (> baud-rate 2400))
 253
 254   ;; Read window system's init file if using a window system.
 255   (condition-case error
 256       (if (and window-system (not noninteractive))
 257           (load (concat term-file-prefix
 258                         (symbol-name window-system)
 259                         "-win")
 260                 ;; Every window system should have a startup file;
 261                 ;; barf if we can't find it.
 262                 nil t))
 263     ;; If we can't read it, print the error message and exit.
 264     (error
 265      (princ
 266       (if (eq (car error) 'error)
 267           (apply 'concat (cdr error))
 268         (if (memq 'file-error (get (car error) 'error-conditions))
 269             (format "%s: %s"
 270                      (nth 1 error)
 271                      (mapconcat '(lambda (obj) (prin1-to-string obj t))
 272                                 (cdr (cdr error)) ", "))
 273           (format "%s: %s"
 274                    (get (car error) 'error-message)
 275                    (mapconcat '(lambda (obj) (prin1-to-string obj t))
 276                               (cdr error) ", "))))
 277       'external-debugging-output)
 278      (setq window-system nil)
 279      (kill-emacs)))
 280
 281   (let ((done nil)
 282         (args (cdr command-line-args)))
 283
 284     ;; Figure out which user's init file to load,
 285     ;; either from the environment or from the options.
 286     (setq init-file-user (if noninteractive nil (user-login-name)))
 287     ;; If user has not done su, use current $HOME to find .emacs.
 288     (and init-file-user (string= init-file-user (user-real-login-name))
 289          (setq init-file-user ""))
 290
 291     ;; Process the command-line args, and delete the arguments
 292     ;; processed.  This is consistent with the way main in emacs.c
 293     ;; does things.
 294     (while (and (not done) args)
 295       (let ((longopts '(("--no-init-file") ("--no-site-file") ("--user")
 296                         ("--debug-init")))
 297             (argi (car args))
 298             (argval nil))
 299         (if (string-match "=" argi)
 300             (setq argval (substring argi (match-end 0))
 301                   argi (substring argi 0 (match-beginning 0))))
 302         (let ((completion (try-completion argi longopts)))
 303           (if (eq completion t)
 304               (setq argi (substring argi 1))
 305             (if (stringp completion)
 306                 (let ((elt (assoc completion longopts)))
 307                   (or elt
 308                       (error "Option `%s' is ambiguous" argi))
 309                   (setq argi (substring (car elt) 1))))))
 310         (cond
 311          ((or (string-equal argi "-q")
 312               (string-equal argi "-no-init-file"))
 313           (setq init-file-user nil
 314                 args (cdr args)))
 315          ((or (string-equal argi "-u")
 316               (string-equal argi "-user"))
 317           (or argval
 318               (setq argval (car args)
 319                     args (cdr args)))
 320           (setq init-file-user argval
 321                 argval nil
 322                 args (cdr args)))
 323          ((string-equal argi "-no-site-file")
 324           (setq site-run-file nil
 325                 args (cdr args)))
 326          ((string-equal argi "-debug-init")
 327           (setq init-file-debug t
 328                 args (cdr args)))
 329          (t (setq done t)))
 330         ;; Was argval set but not used?
 331         (and argval
 332              (error "Option `%s' doesn't allow an argument" argi))))
 333
 334     ;; Re-attach the program name to the front of the arg list.
 335     (setcdr command-line-args args))
 336
 337   ;; Under X Windows, this creates the X frame and deletes the terminal frame.
 338   (if (fboundp 'face-initialize)
 339       (face-initialize))
 340   (if (fboundp 'frame-initialize)
 341       (frame-initialize))
 342   ;; If frame was created with a menu bar, set menu-bar-mode on.
 343   (if (and (eq window-system 'x)
 344            (> (cdr (assq 'menu-bar-lines (frame-parameters))) 0))
 345       (menu-bar-mode t))
 346
 347   (run-hooks 'before-init-hook)
 348
 349   ;; Run the site-start library if it exists.  The point of this file is
 350   ;; that it is run before .emacs.  There is no point in doing this after
 351   ;; .emacs; that is useless.
 352   (if site-run-file
 353       (load site-run-file t t))
 354
 355   ;; Sites should not disable this.  Only individuals should disable
 356   ;; the startup message.
 357   (setq inhibit-startup-message nil)
 358
 359   ;; Load that user's init file, or the default one, or none.
 360   (let (debug-on-error-from-init-file
 361         debug-on-error-should-be-set
 362         (debug-on-error-initial
 363          (if (eq init-file-debug t) 'startup init-file-debug)))
 364     (let ((debug-on-error debug-on-error-initial)
 365           ;; This function actually reads the init files.
 366           (inner
 367            (function
 368             (lambda ()
 369               (if init-file-user
 370                   (progn
 371                     (setq user-init-file
 372                           (cond
 373                            ((eq system-type 'ms-dos)
 374                             (concat "~" init-file-user "/_emacs"))
 375                            ((eq system-type 'vax-vms)
 376                             "sys$login:.emacs")
 377                            (t
 378                             (concat "~" init-file-user "/.emacs"))))
 379                     (load user-init-file t t t)
 380                     (or inhibit-default-init
 381                         (let ((inhibit-startup-message nil))
 382                           ;; Users are supposed to be told their rights.
 383                           ;; (Plus how to get help and how to undo.)
 384                           ;; Don't you dare turn this off for anyone
 385                           ;; except yourself.
 386                           (load "default" t t)))))))))
 387       (if init-file-debug
 388           ;; Do this without a condition-case if the user wants to debug.
 389           (funcall inner)
 390         (condition-case error
 391             (progn
 392               (funcall inner)
 393               (setq init-file-had-error nil))
 394           (error (message "Error in init file: %s%s%s"
 395                           (get (car error) 'error-message)
 396                           (if (cdr error) ": " "")
 397                           (mapconcat 'prin1-to-string (cdr error) ", "))
 398                  (setq init-file-had-error t))))
 399       ;; If we can tell that the init file altered debug-on-error,
 400       ;; arrange to preserve the value that it set up.
 401       (or (eq debug-on-error debug-on-error-initial)
 402           (setq debug-on-error-should-be-set t
 403                 debug-on-error-from-init-file debug-on-error)))
 404     (if debug-on-error-should-be-set
 405         (setq debug-on-error debug-on-error-from-init-file)))
 406
 407   (run-hooks 'after-init-hook)
 408
 409   ;; If *scratch* exists and init file didn't change its mode, initialize it.
 410   (if (get-buffer "*scratch*")
 411       (save-excursion
 412         (set-buffer "*scratch*")
 413         (if (eq major-mode 'fundamental-mode)
 414             (funcall initial-major-mode))))
 415   ;; Load library for our terminal type.
 416   ;; User init file can set term-file-prefix to nil to prevent this.
 417   (and term-file-prefix (not noninteractive) (not window-system)
 418        (let ((term (getenv "TERM"))
 419              hyphend)
 420          (while (and term
 421                      (not (load (concat term-file-prefix term) t t)))
 422            ;; Strip off last hyphen and what follows, then try again
 423            (if (setq hyphend (string-match "[-_][^-_]+$" term))
 424                (setq term (substring term 0 hyphend))
 425              (setq term nil)))))
 426
 427   ;; Process the remaining args.
 428   (command-line-1 (cdr command-line-args))
 429
 430   ;; If -batch, terminate after processing the command options.
 431   (if noninteractive (kill-emacs t)))
 432
 433 (defun command-line-1 (command-line-args-left)
 434   (or noninteractive (input-pending-p) init-file-had-error
 435       (and inhibit-startup-echo-area-message
 436            (let ((buffer (get-buffer-create " *temp*")))
 437              (prog1
 438                  (condition-case nil
 439                      (save-excursion
 440                        (set-buffer buffer)
 441                        (insert-file-contents user-init-file)
 442                        (re-search-forward
 443                         (concat
 444                          "([ \t\n]*setq[ \t\n]+"
 445                          "inhibit-startup-echo-area-message[ \t\n]+"
 446                          (regexp-quote
 447                           (prin1-to-string
 448                            (if (string= init-file-user "")
 449                                (user-login-name)
 450                              init-file-user)))
 451                          "[ \t\n]*)")
 452                         nil t))
 453                    (error nil))
 454                (kill-buffer buffer))))
 455       (message (if (eq (key-binding "\C-h\C-p") 'describe-project)
 456                    "For information about the GNU Project and its goals, type C-h C-p."
 457                  (substitute-command-keys
 458                   "For information about the GNU Project and its goals, type \\[describe-project]."))))
 459   (if (null command-line-args-left)
 460       (cond ((and (not inhibit-startup-message) (not noninteractive)
 461                   ;; Don't clobber a non-scratch buffer if init file
 462                   ;; has selected it.
 463                   (string= (buffer-name) "*scratch*")
 464                   (not (input-pending-p)))
 465              ;; If there are no switches to process, we might as well
 466              ;; run this hook now, and there may be some need to do it
 467              ;; before doing any output.
 468              (and term-setup-hook
 469                   (run-hooks 'term-setup-hook))
 470              ;; Don't let the hook be run twice.
 471              (setq term-setup-hook nil)
 472
 473              ;; It's important to notice the user settings before we
 474              ;; display the startup message; otherwise, the settings
 475              ;; won't take effect until the user gives the first
 476              ;; keystroke, and that's distracting.
 477              (if (fboundp 'frame-notice-user-settings)
 478                  (frame-notice-user-settings))
 479
 480              (and window-setup-hook
 481                   (run-hooks 'window-setup-hook))
 482              (setq window-setup-hook nil)
 483              ;; Do this now to avoid an annoying delay if the user
 484              ;; clicks the menu bar during the sit-for.
 485              (precompute-menubar-bindings)
 486              (setq menubar-bindings-done t)
 487              (unwind-protect
 488                  (progn
 489                    (insert (emacs-version)
 490                            "
 491 Copyright (C) 1994 Free Software Foundation, Inc.\n\n")
 492                    ;; If keys have their default meanings,
 493                    ;; use precomputed string to save lots of time.
 494                    (if (and (eq (key-binding "\C-h") 'help-command)
 495                             (eq (key-binding "\C-xu") 'advertised-undo)
 496                             (eq (key-binding "\C-x\C-c") 'save-buffers-kill-emacs)
 497                             (eq (key-binding "\C-h\C-c") 'describe-copying)
 498                             (eq (key-binding "\C-h\C-d") 'describe-distribution)
 499                             (eq (key-binding "\C-h\C-w") 'describe-no-warranty)
 500                             (eq (key-binding "\C-ht") 'help-with-tutorial))
 501                        (insert
 502        "Type C-h for help; C-x u to undo changes.  (`C-' means use CTRL key.)
 503 To kill the Emacs job, type C-x C-c.
 504 Type C-h t for a tutorial on using Emacs.
 505 Type C-h i to enter Info, which you can use to read GNU documentation.
 506
 507 GNU Emacs comes with ABSOLUTELY NO WARRANTY; type C-h C-w for full details.
 508 You may give out copies of Emacs; type C-h C-c to see the conditions.
 509 Type C-h C-d for information on getting the latest version.")
 510                      (insert (substitute-command-keys
 511        "Type \\[help-command] for help; \\[advertised-undo] to undo changes.  (`C-' means use CTRL key.)
 512 To kill the Emacs job, type \\[save-buffers-kill-emacs].
 513 Type \\[help-with-tutorial] for a tutorial on using Emacs.
 514 Type \\[info] to enter Info, which you can use to read GNU documentation.
 515
 516 GNU Emacs comes with ABSOLUTELY NO WARRANTY; type \\[describe-no-warranty] for full details.
 517 You may give out copies of Emacs; type \\[describe-copying] to see the conditions.
 518 Type \\[describe-distribution] for information on getting the latest version.")))
 519                    (set-buffer-modified-p nil)
 520                    (sit-for 120))
 521                (save-excursion
 522                  ;; In case the Emacs server has already selected
 523                  ;; another buffer, erase the one our message is in.
 524                  (set-buffer (get-buffer "*scratch*"))
 525                  (erase-buffer)
 526                  (set-buffer-modified-p nil)))))
 527     (let ((dir command-line-default-directory)
 528           (file-count 0)
 529           first-file-buffer
 530           (line 0))
 531       (while command-line-args-left
 532         (let ((argi (car command-line-args-left))
 533               tem)
 534           (setq command-line-args-left (cdr command-line-args-left))
 535           (cond ((setq tem (assoc argi command-switch-alist))
 536                  (funcall (cdr tem) argi))
 537                 ((or (string-equal argi "-f")  ;what the manual claims
 538                      (string-equal argi "-funcall")
 539                      (string-equal argi "-e")) ; what the source used to say
 540                  (setq tem (intern (car command-line-args-left)))
 541                  (setq command-line-args-left (cdr command-line-args-left))
 542                  (funcall tem))
 543                 ((or (string-equal argi "-l")
 544                      (string-equal argi "-load"))
 545                  (let ((file (car command-line-args-left)))
 546                    ;; Take file from default dir if it exists there;
 547                    ;; otherwise let `load' search for it.
 548                    (if (file-exists-p (expand-file-name file))
 549                        (setq file (expand-file-name file)))
 550                    (load file nil t))
 551                  (setq command-line-args-left (cdr command-line-args-left)))
 552                 ((string-equal argi "-insert")
 553                  (or (stringp (car command-line-args-left))
 554                      (error "filename omitted from `-insert' option"))
 555                  (insert-file-contents (car command-line-args-left))
 556                  (setq command-line-args-left (cdr command-line-args-left)))
 557                 ((string-equal argi "-kill")
 558                  (kill-emacs t))
 559                 ((string-match "^\\+[0-9]+\\'" argi)
 560                  (setq line (string-to-int argi)))
 561                 (t
 562                  ;; We have almost exhausted our options. See if the
 563                  ;; user has made any other command-line options available
 564                  (let ((hooks command-line-functions);; lrs 7/31/89
 565                        (did-hook nil))
 566                    (while (and hooks
 567                                (not (setq did-hook (funcall (car hooks)))))
 568                      (setq hooks (cdr hooks)))
 569                    (if (not did-hook)
 570                        ;; Ok, presume that the argument is a file name
 571                        (progn
 572                          (setq file-count (1+ file-count))
 573                          (cond ((= file-count 1)
 574                                 (setq first-file-buffer
 575                                       (find-file (expand-file-name argi dir))))
 576                                (t
 577                                 (find-file-other-window (expand-file-name argi dir))))
 578                          (or (zerop line)
 579                              (goto-line line))
 580                          (setq line 0))))))))
 581       ;; If 3 or more files visited, and not all visible,
 582       ;; show user what they all are.
 583       (if (> file-count 2)
 584           (or (get-buffer-window first-file-buffer)
 585               (progn (other-window 1)
 586                      (buffer-menu)))))))
 587
 588 ;;; startup.el ends here