code.delx.au - gnu-emacs/blob - lisp/gnus/gnus-srvr.el

   1 ;;; gnus-srvr.el --- virtual server support for Gnus
   2
   3 ;; Copyright (C) 1995-2016 Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;; Keywords: news
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;;; Code:
  26
  27 (eval-when-compile (require 'cl))
  28
  29 (require 'gnus)
  30 (require 'gnus-start)
  31 (require 'gnus-spec)
  32 (require 'gnus-group)
  33 (require 'gnus-int)
  34 (require 'gnus-range)
  35
  36 (autoload 'gnus-group-make-nnir-group "nnir")
  37
  38 (defcustom gnus-server-mode-hook nil
  39   "Hook run in `gnus-server-mode' buffers."
  40   :group 'gnus-server
  41   :type 'hook)
  42
  43 (defcustom gnus-server-exit-hook nil
  44   "Hook run when exiting the server buffer."
  45   :group 'gnus-server
  46   :type 'hook)
  47
  48 (defcustom gnus-server-line-format "     {%(%h:%w%)} %s%a%c\n"
  49   "Format of server lines.
  50 It works along the same lines as a normal formatting string,
  51 with some simple extensions.
  52
  53 The following specs are understood:
  54
  55 %h back end
  56 %n name
  57 %w address
  58 %s status
  59 %a agent covered
  60
  61 General format specifiers can also be used.
  62 See Info node `(gnus)Formatting Variables'."
  63   :link '(custom-manual "(gnus)Formatting Variables")
  64   :group 'gnus-server-visual
  65   :type 'string)
  66
  67 (defcustom gnus-server-mode-line-format "Gnus: %%b"
  68   "The format specification for the server mode line."
  69   :group 'gnus-server-visual
  70   :type 'string)
  71
  72 (defcustom gnus-server-browse-in-group-buffer nil
  73   "Whether server browsing should take place in the group buffer.
  74 If nil, a faster, but more primitive, buffer is used instead."
  75   :version "22.1"
  76   :group 'gnus-server-visual
  77   :type 'boolean)
  78
  79 ;;; Internal variables.
  80
  81 (defvar gnus-tmp-how)
  82 (defvar gnus-tmp-name)
  83 (defvar gnus-tmp-where)
  84 (defvar gnus-tmp-status)
  85 (defvar gnus-tmp-agent)
  86 (defvar gnus-tmp-cloud)
  87 (defvar gnus-tmp-news-server)
  88 (defvar gnus-tmp-news-method)
  89 (defvar gnus-tmp-user-defined)
  90
  91 (defvar gnus-inserted-opened-servers nil)
  92
  93 (defvar gnus-server-line-format-alist
  94   `((?h gnus-tmp-how ?s)
  95     (?n gnus-tmp-name ?s)
  96     (?w gnus-tmp-where ?s)
  97     (?s gnus-tmp-status ?s)
  98     (?a gnus-tmp-agent ?s)
  99     (?c gnus-tmp-cloud ?s)))
 100
 101 (defvar gnus-server-mode-line-format-alist
 102   `((?S gnus-tmp-news-server ?s)
 103     (?M gnus-tmp-news-method ?s)
 104     (?u gnus-tmp-user-defined ?s)))
 105
 106 (defvar gnus-server-line-format-spec nil)
 107 (defvar gnus-server-mode-line-format-spec nil)
 108 (defvar gnus-server-killed-servers nil)
 109
 110 (defvar gnus-server-mode-map)
 111
 112 (defcustom gnus-server-menu-hook nil
 113   "Hook run after the creation of the server mode menu."
 114   :type 'hook
 115   :group 'gnus-server)
 116
 117 (defun gnus-server-make-menu-bar ()
 118   (gnus-turn-off-edit-menu 'server)
 119   (unless (boundp 'gnus-server-server-menu)
 120     (easy-menu-define
 121      gnus-server-server-menu gnus-server-mode-map ""
 122      '("Server"
 123        ["Add..." gnus-server-add-server t]
 124        ["Browse" gnus-server-read-server t]
 125        ["Scan" gnus-server-scan-server t]
 126        ["List" gnus-server-list-servers t]
 127        ["Kill" gnus-server-kill-server t]
 128        ["Yank" gnus-server-yank-server t]
 129        ["Copy" gnus-server-copy-server t]
 130        ["Show" gnus-server-show-server t]
 131        ["Edit" gnus-server-edit-server t]
 132        ["Regenerate" gnus-server-regenerate-server t]
 133        ["Compact" gnus-server-compact-server t]
 134        ["Exit" gnus-server-exit t]))
 135
 136     (easy-menu-define
 137      gnus-server-connections-menu gnus-server-mode-map ""
 138      '("Connections"
 139        ["Open" gnus-server-open-server t]
 140        ["Close" gnus-server-close-server t]
 141        ["Offline" gnus-server-offline-server t]
 142        ["Deny" gnus-server-deny-server t]
 143        ["Toggle Cloud" gnus-server-toggle-cloud-server t]
 144        "---"
 145        ["Open All" gnus-server-open-all-servers t]
 146        ["Close All" gnus-server-close-all-servers t]
 147        ["Reset All" gnus-server-remove-denials t]))
 148
 149     (gnus-run-hooks 'gnus-server-menu-hook)))
 150
 151 (defvar gnus-server-mode-map nil)
 152 (put 'gnus-server-mode 'mode-class 'special)
 153
 154 (unless gnus-server-mode-map
 155   (setq gnus-server-mode-map (make-sparse-keymap))
 156   (suppress-keymap gnus-server-mode-map)
 157
 158   (gnus-define-keys gnus-server-mode-map
 159     " " gnus-server-read-server-in-server-buffer
 160     "\r" gnus-server-read-server
 161     [mouse-2] gnus-server-pick-server
 162     "q" gnus-server-exit
 163     "l" gnus-server-list-servers
 164     "k" gnus-server-kill-server
 165     "y" gnus-server-yank-server
 166     "c" gnus-server-copy-server
 167     "a" gnus-server-add-server
 168     "e" gnus-server-edit-server
 169     "S" gnus-server-show-server
 170     "s" gnus-server-scan-server
 171
 172     "O" gnus-server-open-server
 173     "\M-o" gnus-server-open-all-servers
 174     "C" gnus-server-close-server
 175     "\M-c" gnus-server-close-all-servers
 176     "D" gnus-server-deny-server
 177     "L" gnus-server-offline-server
 178     "R" gnus-server-remove-denials
 179
 180     "n" next-line
 181     "p" previous-line
 182
 183     "g" gnus-server-regenerate-server
 184
 185     "G" gnus-group-make-nnir-group
 186
 187     "z" gnus-server-compact-server
 188
 189     "i" gnus-server-toggle-cloud-server
 190
 191     "\C-c\C-i" gnus-info-find-node
 192     "\C-c\C-b" gnus-bug))
 193
 194 (defface gnus-server-agent
 195   '((((class color) (background light)) (:foreground "PaleTurquoise" :bold t))
 196     (((class color) (background dark)) (:foreground "PaleTurquoise" :bold t))
 197     (t (:bold t)))
 198   "Face used for displaying AGENTIZED servers"
 199   :group 'gnus-server-visual)
 200 ;; backward-compatibility alias
 201 (put 'gnus-server-agent-face 'face-alias 'gnus-server-agent)
 202 (put 'gnus-server-agent-face 'obsolete-face "22.1")
 203
 204 (defface gnus-server-cloud
 205   '((((class color) (background light)) (:foreground "ForestGreen" :bold t))
 206     (((class color) (background dark)) (:foreground "PaleGreen" :bold t))
 207     (t (:bold t)))
 208   "Face used for displaying AGENTIZED servers"
 209   :group 'gnus-server-visual)
 210
 211 (defface gnus-server-opened
 212   '((((class color) (background light)) (:foreground "Green3" :bold t))
 213     (((class color) (background dark)) (:foreground "Green1" :bold t))
 214     (t (:bold t)))
 215   "Face used for displaying OPENED servers"
 216   :group 'gnus-server-visual)
 217 ;; backward-compatibility alias
 218 (put 'gnus-server-opened-face 'face-alias 'gnus-server-opened)
 219 (put 'gnus-server-opened-face 'obsolete-face "22.1")
 220
 221 (defface gnus-server-closed
 222   '((((class color) (background light)) (:foreground "Steel Blue" :italic t))
 223     (((class color) (background dark))
 224      (:foreground "LightBlue" :italic t))
 225     (t (:italic t)))
 226   "Face used for displaying CLOSED servers"
 227   :group 'gnus-server-visual)
 228 ;; backward-compatibility alias
 229 (put 'gnus-server-closed-face 'face-alias 'gnus-server-closed)
 230 (put 'gnus-server-closed-face 'obsolete-face "22.1")
 231
 232 (defface gnus-server-denied
 233   '((((class color) (background light)) (:foreground "Red" :bold t))
 234     (((class color) (background dark)) (:foreground "Pink" :bold t))
 235     (t (:inverse-video t :bold t)))
 236   "Face used for displaying DENIED servers"
 237   :group 'gnus-server-visual)
 238 ;; backward-compatibility alias
 239 (put 'gnus-server-denied-face 'face-alias 'gnus-server-denied)
 240 (put 'gnus-server-denied-face 'obsolete-face "22.1")
 241
 242 (defface gnus-server-offline
 243   '((((class color) (background light)) (:foreground "Orange" :bold t))
 244     (((class color) (background dark)) (:foreground "Yellow" :bold t))
 245     (t (:inverse-video t :bold t)))
 246   "Face used for displaying OFFLINE servers"
 247   :group 'gnus-server-visual)
 248 ;; backward-compatibility alias
 249 (put 'gnus-server-offline-face 'face-alias 'gnus-server-offline)
 250 (put 'gnus-server-offline-face 'obsolete-face "22.1")
 251
 252 (defvar gnus-server-font-lock-keywords
 253   '(("(\\(agent\\))" 1 'gnus-server-agent)
 254     ("(\\(cloud\\))" 1 'gnus-server-cloud)
 255     ("(\\(opened\\))" 1 'gnus-server-opened)
 256     ("(\\(closed\\))" 1 'gnus-server-closed)
 257     ("(\\(offline\\))" 1 'gnus-server-offline)
 258     ("(\\(denied\\))" 1 'gnus-server-denied)))
 259
 260 (defun gnus-server-mode ()
 261   "Major mode for listing and editing servers.
 262
 263 All normal editing commands are switched off.
 264 \\<gnus-server-mode-map>
 265 For more in-depth information on this mode, read the manual
 266 \(`\\[gnus-info-find-node]').
 267
 268 The following commands are available:
 269
 270 \\{gnus-server-mode-map}"
 271   ;; FIXME: Use define-derived-mode.
 272   (interactive)
 273   (when (gnus-visual-p 'server-menu 'menu)
 274     (gnus-server-make-menu-bar))
 275   (kill-all-local-variables)
 276   (gnus-simplify-mode-line)
 277   (setq major-mode 'gnus-server-mode)
 278   (setq mode-name "Server")
 279   (gnus-set-default-directory)
 280   (setq mode-line-process nil)
 281   (use-local-map gnus-server-mode-map)
 282   (buffer-disable-undo)
 283   (setq truncate-lines t)
 284   (setq buffer-read-only t)
 285   (set (make-local-variable 'font-lock-defaults)
 286        '(gnus-server-font-lock-keywords t))
 287   (gnus-run-mode-hooks 'gnus-server-mode-hook))
 288
 289 (defun gnus-server-insert-server-line (name method)
 290   (let* ((gnus-tmp-name name)
 291          (gnus-tmp-how (car method))
 292          (gnus-tmp-where (nth 1 method))
 293          (elem (assoc method gnus-opened-servers))
 294          (gnus-tmp-status
 295           (cond
 296            ((eq (nth 1 elem) 'denied) "(denied)")
 297            ((eq (nth 1 elem) 'offline) "(offline)")
 298            (t
 299             (condition-case nil
 300                 (if (or (gnus-server-opened method)
 301                         (eq (nth 1 elem) 'ok))
 302                     "(opened)"
 303                   "(closed)")
 304               ((error) "(error)")))))
 305          (gnus-tmp-agent (if (and gnus-agent
 306                                   (gnus-agent-method-p method))
 307                              " (agent)"
 308                            ""))
 309          (gnus-tmp-cloud (if (gnus-cloud-server-p gnus-tmp-name)
 310                              " (cloud)"
 311                            "")))
 312     (beginning-of-line)
 313     (add-text-properties
 314      (point)
 315      (prog1 (1+ (point))
 316        ;; Insert the text.
 317        (eval gnus-server-line-format-spec))
 318      (list 'gnus-server (intern gnus-tmp-name)
 319            'gnus-named-server (intern (gnus-method-to-server method t))))))
 320
 321 (defun gnus-enter-server-buffer ()
 322   "Set up the server buffer."
 323   (gnus-server-setup-buffer)
 324   (gnus-configure-windows 'server)
 325   ;; Usually `gnus-configure-windows' will finish with the
 326   ;; `gnus-server-buffer' selected as the current buffer, but not always (I
 327   ;; bumped into it when starting from a dedicated *Group* frame, and
 328   ;; gnus-configure-windows opened *Server* into its own dedicated frame).
 329   (with-current-buffer (get-buffer gnus-server-buffer)
 330     (gnus-server-prepare)))
 331
 332 (defun gnus-server-setup-buffer ()
 333   "Initialize the server buffer."
 334   (unless (get-buffer gnus-server-buffer)
 335     (with-current-buffer (gnus-get-buffer-create gnus-server-buffer)
 336       (gnus-server-mode))))
 337
 338 (defun gnus-server-prepare ()
 339   (gnus-set-format 'server-mode)
 340   (gnus-set-format 'server t)
 341   (let ((alist gnus-server-alist)
 342         (buffer-read-only nil)
 343         done server op-ser)
 344     (erase-buffer)
 345     (setq gnus-inserted-opened-servers nil)
 346     ;; First we do the real list of servers.
 347     (while alist
 348       (unless (member (cdar alist) done)
 349         (push (cdar alist) done)
 350         (setq server (pop alist))
 351         (when (and server (car server) (cdr server))
 352           (gnus-server-insert-server-line (car server) (cdr server))))
 353       (when (member (cdar alist) done)
 354         (pop alist)))
 355     ;; Then we insert the list of servers that have been opened in
 356     ;; this session.
 357     (dolist (open gnus-opened-servers)
 358       (when (and (not (member (car open) done))
 359                  ;; Just ignore ephemeral servers.
 360                  (not (gnus-method-ephemeral-p (car open))))
 361         (push (car open) done)
 362         (gnus-server-insert-server-line
 363          (setq op-ser (format "%s:%s" (caar open) (nth 1 (car open))))
 364          (car open))
 365         (push (list op-ser (car open)) gnus-inserted-opened-servers))))
 366   (goto-char (point-min))
 367   (gnus-server-position-point))
 368
 369 (defun gnus-server-server-name ()
 370   (let ((server (get-text-property (point-at-bol) 'gnus-server)))
 371     (and server (symbol-name server))))
 372
 373 (defun gnus-server-named-server ()
 374   "Return a server name that matches one of the names returned by
 375 `gnus-method-to-server'."
 376   (let ((server (get-text-property (point-at-bol) 'gnus-named-server)))
 377     (and server (symbol-name server))))
 378
 379 (defalias 'gnus-server-position-point 'gnus-goto-colon)
 380
 381 (defconst gnus-server-edit-buffer "*Gnus edit server*")
 382
 383 (defun gnus-server-update-server (server)
 384   (with-current-buffer gnus-server-buffer
 385     (let* ((buffer-read-only nil)
 386            (entry (assoc server gnus-server-alist))
 387            (oentry (assoc (gnus-server-to-method server)
 388                           gnus-opened-servers)))
 389       (when entry
 390         (gnus-dribble-enter
 391          (concat "(gnus-server-set-info \"" server "\" '"
 392                  (gnus-prin1-to-string (cdr entry)) ")")
 393          (concat "^(gnus-server-set-info \"" (regexp-quote server) "\"")))
 394       (when (or entry oentry)
 395         ;; Buffer may be narrowed.
 396         (save-restriction
 397           (widen)
 398           (when (gnus-server-goto-server server)
 399             (gnus-delete-line))
 400           (if entry
 401               (gnus-server-insert-server-line (car entry) (cdr entry))
 402             (gnus-server-insert-server-line
 403              (format "%s:%s" (caar oentry) (nth 1 (car oentry)))
 404              (car oentry)))
 405           (gnus-server-position-point))))))
 406
 407 (defun gnus-server-set-info (server info)
 408   ;; Enter a select method into the virtual server alist.
 409   (when (and server info)
 410     (gnus-dribble-enter
 411      (concat "(gnus-server-set-info \"" server "\" '"
 412              (gnus-prin1-to-string info) ")")
 413      (concat "^(gnus-server-set-info \"" (regexp-quote server) "\""))
 414     (let* ((server (nth 1 info))
 415            (entry (assoc server gnus-server-alist))
 416            (cached (assoc server gnus-server-method-cache)))
 417       (if cached
 418           (setq gnus-server-method-cache
 419                 (delq cached gnus-server-method-cache)))
 420       (if entry
 421           (progn
 422             ;; Remove the server from `gnus-opened-servers' since
 423             ;; it has never been opened with the new `info' yet.
 424             (gnus-opened-servers-remove (cdr entry))
 425             ;; Don't make a new Lisp object.
 426             (setcar (cdr entry) (car info))
 427             (setcdr (cdr entry) (cdr info)))
 428         (setq gnus-server-alist
 429               (nconc gnus-server-alist (list (cons server info))))))))
 430
 431 ;;; Interactive server functions.
 432
 433 (defun gnus-server-kill-server (server)
 434   "Kill the server on the current line."
 435   (interactive (list (gnus-server-server-name)))
 436   (unless (gnus-server-goto-server server)
 437     (if server (error "No such server: %s" server)
 438       (error "No server on the current line")))
 439   (unless (assoc server gnus-server-alist)
 440     (error "Read-only server %s" server))
 441   (gnus-dribble-touch)
 442   (let ((buffer-read-only nil))
 443     (gnus-delete-line))
 444   (push (assoc server gnus-server-alist) gnus-server-killed-servers)
 445   (setq gnus-server-alist (delq (car gnus-server-killed-servers)
 446                                 gnus-server-alist))
 447   (let ((groups (gnus-groups-from-server server)))
 448     (when (and groups
 449                (gnus-yes-or-no-p
 450                 (format "Kill all %s groups from this server? "
 451                         (length groups))))
 452       (dolist (group groups)
 453         (setq gnus-newsrc-alist
 454               (delq (assoc group gnus-newsrc-alist)
 455                     gnus-newsrc-alist))
 456         (when gnus-group-change-level-function
 457           (funcall gnus-group-change-level-function
 458                    group gnus-level-killed 3)))))
 459   (gnus-server-position-point))
 460
 461 (defun gnus-server-yank-server ()
 462   "Yank the previously killed server."
 463   (interactive)
 464   (unless gnus-server-killed-servers
 465     (error "No killed servers to be yanked"))
 466   (let ((alist gnus-server-alist)
 467         (server (gnus-server-server-name))
 468         (killed (car gnus-server-killed-servers)))
 469     (if (not server)
 470         (setq gnus-server-alist (nconc gnus-server-alist (list killed)))
 471       (if (string= server (caar gnus-server-alist))
 472           (push killed gnus-server-alist)
 473         (while (and (cdr alist)
 474                     (not (string= server (caadr alist))))
 475           (setq alist (cdr alist)))
 476         (if alist
 477             (setcdr alist (cons killed (cdr alist)))
 478           (setq gnus-server-alist (list killed)))))
 479     (gnus-server-update-server (car killed))
 480     (setq gnus-server-killed-servers (cdr gnus-server-killed-servers))
 481     (gnus-server-position-point)))
 482
 483 (defun gnus-server-exit ()
 484   "Return to the group buffer."
 485   (interactive)
 486   (gnus-run-hooks 'gnus-server-exit-hook)
 487   (gnus-kill-buffer (current-buffer))
 488   (gnus-configure-windows 'group t))
 489
 490 (defun gnus-server-list-servers ()
 491   "List all available servers."
 492   (interactive)
 493   (let ((cur (gnus-server-server-name)))
 494     (gnus-server-prepare)
 495     (if cur (gnus-server-goto-server cur)
 496       (goto-char (point-max))
 497       (forward-line -1))
 498     (gnus-server-position-point)))
 499
 500 (defun gnus-server-set-status (method status)
 501   "Make METHOD have STATUS."
 502   (let ((entry (assoc method gnus-opened-servers)))
 503     (if entry
 504         (setcar (cdr entry) status)
 505       (push (list method status) gnus-opened-servers))))
 506
 507 (defun gnus-opened-servers-remove (method)
 508   "Remove METHOD from the list of opened servers."
 509   (setq gnus-opened-servers (delq (assoc method gnus-opened-servers)
 510                                   gnus-opened-servers)))
 511
 512 (defun gnus-server-open-server (server)
 513   "Force an open of SERVER."
 514   (interactive (list (gnus-server-server-name)))
 515   (let ((method (gnus-server-to-method server)))
 516     (unless method
 517       (error "No such server: %s" server))
 518     (gnus-server-set-status method 'ok)
 519     (prog1
 520         (gnus-open-server method)
 521       (gnus-server-update-server server)
 522       (gnus-server-position-point))))
 523
 524 (defun gnus-server-open-all-servers ()
 525   "Open all servers."
 526   (interactive)
 527   (dolist (server gnus-inserted-opened-servers)
 528     (gnus-server-open-server (car server))))
 529
 530 (defun gnus-server-close-server (server)
 531   "Close SERVER."
 532   (interactive (list (gnus-server-server-name)))
 533   (let ((method (gnus-server-to-method server)))
 534     (unless method
 535       (error "No such server: %s" server))
 536     (gnus-server-set-status method 'closed)
 537     (prog1
 538         (gnus-close-server method)
 539       (gnus-server-update-server server)
 540       (gnus-server-position-point))))
 541
 542 (defun gnus-server-offline-server (server)
 543   "Set SERVER to offline."
 544   (interactive (list (gnus-server-server-name)))
 545   (let ((method (gnus-server-to-method server)))
 546     (unless method
 547       (error "No such server: %s" server))
 548     (prog1
 549         (gnus-close-server method)
 550       (gnus-server-set-status method 'offline)
 551       (gnus-server-update-server server)
 552       (gnus-server-position-point))))
 553
 554 (defun gnus-server-close-all-servers ()
 555   "Close all servers."
 556   (interactive)
 557   (dolist (server gnus-inserted-opened-servers)
 558     (gnus-server-close-server (car server)))
 559   (dolist (server gnus-server-alist)
 560     (gnus-server-close-server (car server))))
 561
 562 (defun gnus-server-deny-server (server)
 563   "Make sure SERVER will never be attempted opened."
 564   (interactive (list (gnus-server-server-name)))
 565   (let ((method (gnus-server-to-method server)))
 566     (unless method
 567       (error "No such server: %s" server))
 568     (gnus-server-set-status method 'denied))
 569   (gnus-server-update-server server)
 570   (gnus-server-position-point)
 571   t)
 572
 573 (defun gnus-server-remove-denials ()
 574   "Make all denied servers into closed servers."
 575   (interactive)
 576   (dolist (server gnus-opened-servers)
 577     (when (eq (nth 1 server) 'denied)
 578       (setcar (nthcdr 1 server) 'closed)))
 579   (gnus-server-list-servers))
 580
 581 (defun gnus-server-copy-server (from to)
 582   "Copy a server definition to a new name."
 583   (interactive
 584    (list
 585     (or (gnus-server-server-name)
 586         (error "No server on the current line"))
 587     (read-string "Copy to: ")))
 588   (unless from
 589     (error "No server on current line"))
 590   (unless (and to (not (string= to "")))
 591     (error "No name to copy to"))
 592   (when (assoc to gnus-server-alist)
 593     (error "%s already exists" to))
 594   (unless (gnus-server-to-method from)
 595     (error "%s: no such server" from))
 596   (let ((to-entry (cons from (gnus-copy-sequence
 597                               (gnus-server-to-method from)))))
 598     (setcar to-entry to)
 599     (setcar (nthcdr 2 to-entry) to)
 600     (push to-entry gnus-server-killed-servers)
 601     (gnus-server-yank-server)))
 602
 603 (defun gnus-server-add-server (how where)
 604   (interactive
 605    (list (intern (gnus-completing-read "Server method"
 606                                        (mapcar 'car gnus-valid-select-methods)
 607                                        t))
 608          (read-string "Server name: ")))
 609   (when (assq where gnus-server-alist)
 610     (error "Server with that name already defined"))
 611   (push (list where how where) gnus-server-killed-servers)
 612   (gnus-server-yank-server))
 613
 614 (defun gnus-server-goto-server (server)
 615   "Jump to a server line."
 616   (interactive
 617    (list (gnus-completing-read "Goto server" (mapcar 'car gnus-server-alist) t)))
 618   (let ((to (text-property-any (point-min) (point-max)
 619                                'gnus-server (intern server))))
 620     (when to
 621       (goto-char to)
 622       (gnus-server-position-point))))
 623
 624 (defun gnus-server-edit-server (server)
 625   "Edit the server on the current line."
 626   (interactive (list (gnus-server-server-name)))
 627   (unless server
 628     (error "No server on current line"))
 629   (unless (assoc server gnus-server-alist)
 630     (error "This server can't be edited"))
 631   (let ((info (cdr (assoc server gnus-server-alist))))
 632     (gnus-close-server info)
 633     (gnus-edit-form
 634      info "Editing the server."
 635      `(lambda (form)
 636         (gnus-server-set-info ,server form)
 637         (gnus-server-list-servers)
 638         (gnus-server-position-point))
 639      'edit-server)))
 640
 641 (defun gnus-server-show-server (server)
 642   "Show the definition of the server on the current line."
 643   (interactive (list (gnus-server-server-name)))
 644   (unless server
 645     (error "No server on current line"))
 646   (let ((info (gnus-server-to-method server)))
 647     (gnus-edit-form
 648      info "Showing the server."
 649      `(lambda (form)
 650         (gnus-server-position-point))
 651      'edit-server)))
 652
 653 (defun gnus-server-scan-server (server)
 654   "Request a scan from the current server."
 655   (interactive (list (gnus-server-server-name)))
 656   (let ((method (gnus-server-to-method server)))
 657     (if (not (gnus-get-function method 'request-scan))
 658         (error "Server %s can't scan" (car method))
 659       (gnus-message 3 "Scanning %s..." server)
 660       (gnus-request-scan nil method)
 661       (gnus-message 3 "Scanning %s...done" server))))
 662
 663 (defun gnus-server-read-server-in-server-buffer (server)
 664   "Browse a server in server buffer."
 665   (interactive (list (gnus-server-server-name)))
 666   (let (gnus-server-browse-in-group-buffer)
 667     (gnus-server-read-server server)))
 668
 669 (defun gnus-server-read-server (server)
 670   "Browse a server."
 671   (interactive (list (gnus-server-server-name)))
 672   (let ((buf (current-buffer)))
 673     (prog1
 674         (gnus-browse-foreign-server server buf)
 675       (with-current-buffer buf
 676         (gnus-server-update-server (gnus-server-server-name))
 677         (gnus-server-position-point)))))
 678
 679 (defun gnus-server-pick-server (e)
 680   (interactive "e")
 681   (mouse-set-point e)
 682   (gnus-server-read-server (gnus-server-server-name)))
 683
 684 \f
 685 ;;;
 686 ;;; Browse Server Mode
 687 ;;;
 688
 689 (defcustom gnus-browse-menu-hook nil
 690   "Hook run after the creation of the browse mode menu."
 691   :group 'gnus-server
 692   :type 'hook)
 693
 694 (defcustom gnus-browse-subscribe-newsgroup-method
 695   'gnus-subscribe-alphabetically
 696   "Function(s) called when subscribing groups in the Browse Server Buffer
 697 A few pre-made functions are supplied: `gnus-subscribe-randomly'
 698 inserts new groups at the beginning of the list of groups;
 699 `gnus-subscribe-alphabetically' inserts new groups in strict
 700 alphabetic order; `gnus-subscribe-hierarchically' inserts new groups
 701 in hierarchical newsgroup order; `gnus-subscribe-interactively' asks
 702 for your decision; `gnus-subscribe-killed' kills all new groups;
 703 `gnus-subscribe-zombies' will make all new groups into zombies;
 704 `gnus-subscribe-topics' will enter groups into the topics that
 705 claim them."
 706   :version "24.1"
 707   :group 'gnus-server
 708   :type '(radio (function-item gnus-subscribe-randomly)
 709                 (function-item gnus-subscribe-alphabetically)
 710                 (function-item gnus-subscribe-hierarchically)
 711                 (function-item gnus-subscribe-interactively)
 712                 (function-item gnus-subscribe-killed)
 713                 (function-item gnus-subscribe-zombies)
 714                 (function-item gnus-subscribe-topics)
 715                 function
 716                 (repeat function)))
 717
 718 (defvar gnus-browse-mode-hook nil)
 719 (defvar gnus-browse-mode-map nil)
 720 (put 'gnus-browse-mode 'mode-class 'special)
 721
 722 (unless gnus-browse-mode-map
 723   (setq gnus-browse-mode-map (make-keymap))
 724   (suppress-keymap gnus-browse-mode-map)
 725
 726   (gnus-define-keys
 727       gnus-browse-mode-map
 728     " " gnus-browse-read-group
 729     "=" gnus-browse-select-group
 730     "n" gnus-browse-next-group
 731     "p" gnus-browse-prev-group
 732     "\177" gnus-browse-prev-group
 733     [delete] gnus-browse-prev-group
 734     "N" gnus-browse-next-group
 735     "P" gnus-browse-prev-group
 736     "\M-n" gnus-browse-next-group
 737     "\M-p" gnus-browse-prev-group
 738     "\r" gnus-browse-select-group
 739     "u" gnus-browse-unsubscribe-current-group
 740     "l" gnus-browse-exit
 741     "L" gnus-browse-exit
 742     "q" gnus-browse-exit
 743     "Q" gnus-browse-exit
 744     "d" gnus-browse-describe-group
 745     [delete] gnus-browse-delete-group
 746     "\C-c\C-c" gnus-browse-exit
 747     "?" gnus-browse-describe-briefly
 748
 749     "\C-c\C-i" gnus-info-find-node
 750     "\C-c\C-b" gnus-bug))
 751
 752 (defun gnus-browse-make-menu-bar ()
 753   (gnus-turn-off-edit-menu 'browse)
 754   (unless (boundp 'gnus-browse-menu)
 755     (easy-menu-define
 756      gnus-browse-menu gnus-browse-mode-map ""
 757      '("Browse"
 758        ["Subscribe" gnus-browse-unsubscribe-current-group t]
 759        ["Read" gnus-browse-read-group t]
 760        ["Select" gnus-browse-select-group t]
 761        ["Describe" gnus-browse-describe-group t]
 762        ["Next" gnus-browse-next-group t]
 763        ["Prev" gnus-browse-prev-group t]
 764        ["Exit" gnus-browse-exit t]))
 765     (gnus-run-hooks 'gnus-browse-menu-hook)))
 766
 767 (defvar gnus-browse-current-method nil)
 768 (defvar gnus-browse-return-buffer nil)
 769
 770 (defvar gnus-browse-buffer "*Gnus Browse Server*")
 771
 772 (defun gnus-browse-foreign-server (server &optional return-buffer)
 773   "Browse the server SERVER."
 774   (setq gnus-browse-current-method (gnus-server-to-method server))
 775   (setq gnus-browse-return-buffer return-buffer)
 776   (let* ((method gnus-browse-current-method)
 777          (orig-select-method gnus-select-method)
 778          (gnus-select-method method)
 779          groups group)
 780     (gnus-message 5 "Connecting to %s..." (nth 1 method))
 781     (cond
 782      ((not (gnus-check-server method))
 783       (gnus-message
 784        1 "Unable to contact server %s: %s" (nth 1 method)
 785        (gnus-status-message method))
 786       nil)
 787      ((not
 788        (prog2
 789            (gnus-message 6 "Reading active file...")
 790            (gnus-request-list method)
 791          (gnus-message 6 "Reading active file...done")))
 792       (gnus-message
 793        1 "Couldn't request list: %s" (gnus-status-message method))
 794       nil)
 795      (t
 796       (with-current-buffer nntp-server-buffer
 797         (let ((cur (current-buffer)))
 798           (goto-char (point-min))
 799          (unless (or (null gnus-ignored-newsgroups)
 800                      (string= gnus-ignored-newsgroups ""))
 801             (delete-matching-lines gnus-ignored-newsgroups))
 802           ;; We treat NNTP as a special case to avoid problems with
 803           ;; garbage group names like `"foo' that appear in some badly
 804           ;; managed active files. -jh.
 805           (if (eq (car method) 'nntp)
 806               (while (not (eobp))
 807                 (ignore-errors
 808                   (push (cons
 809                          (string-as-unibyte
 810                           (buffer-substring
 811                            (point)
 812                            (progn
 813                              (skip-chars-forward "^ \t")
 814                              (point))))
 815                          (let ((last (read cur)))
 816                            (cons (read cur) last)))
 817                         groups))
 818                 (forward-line))
 819             (while (not (eobp))
 820               (ignore-errors
 821                 (push (cons
 822                        (string-as-unibyte
 823                         (if (eq (char-after) ?\")
 824                             (read cur)
 825                           (let ((p (point)) (name ""))
 826                             (skip-chars-forward "^ \t\\\\")
 827                             (setq name (buffer-substring p (point)))
 828                             (while (eq (char-after) ?\\)
 829                               (setq p (1+ (point)))
 830                               (forward-char 2)
 831                               (skip-chars-forward "^ \t\\\\")
 832                               (setq name (concat name (buffer-substring
 833                                                        p (point)))))
 834                             name)))
 835                        (let ((last (read cur)))
 836                          (cons (read cur) last)))
 837                       groups))
 838               (forward-line)))))
 839       (setq groups (sort groups
 840                          (lambda (l1 l2)
 841                            (string< (car l1) (car l2)))))
 842       (if gnus-server-browse-in-group-buffer
 843           (let* ((gnus-select-method orig-select-method)
 844                  (gnus-group-listed-groups
 845                   (mapcar (lambda (group)
 846                             (let ((name
 847                                    (gnus-group-prefixed-name
 848                                     (car group) method)))
 849                               (gnus-set-active name (cdr group))
 850                               name))
 851                           groups)))
 852             (gnus-configure-windows 'group)
 853             (funcall gnus-group-prepare-function
 854                      gnus-level-killed 'ignore 1 'ignore))
 855         (gnus-get-buffer-create gnus-browse-buffer)
 856         (gnus-configure-windows 'browse)
 857         (buffer-disable-undo)
 858         (let ((buffer-read-only nil))
 859           (erase-buffer))
 860         (gnus-browse-mode)
 861         (setq mode-line-buffer-identification
 862               (list
 863                (format
 864                 "Gnus: %%b {%s:%s}" (car method) (cadr method))))
 865         (let ((buffer-read-only nil)
 866               name
 867               (prefix (let ((gnus-select-method orig-select-method))
 868                         (gnus-group-prefixed-name "" method))))
 869           (while (setq group (pop groups))
 870             (add-text-properties
 871              (point)
 872              (prog1 (1+ (point))
 873                (insert
 874                 (format "%c%7d: %s\n"
 875                         (let ((level
 876                                (if (string= prefix "")
 877                                    (gnus-group-level (setq name (car group)))
 878                                  (gnus-group-level
 879                                   (concat prefix (setq name (car group)))))))
 880                           (cond
 881                            ((<= level gnus-level-subscribed) ? )
 882                            ((<= level gnus-level-unsubscribed) ?U)
 883                            ((= level gnus-level-zombie) ?Z)
 884                            (t ?K)))
 885                         (max 0 (- (1+ (cddr group)) (cadr group)))
 886                         ;; Don't decode if name is ASCII
 887                         (if (eq (detect-coding-string name t) 'undecided)
 888                             name
 889                           (decode-coding-string
 890                            name
 891                            (inline (gnus-group-name-charset method name)))))))
 892              (list 'gnus-group name)
 893              )))
 894         (switch-to-buffer (current-buffer)))
 895       (goto-char (point-min))
 896       (gnus-group-position-point)
 897       (gnus-message 5 "Connecting to %s...done" (nth 1 method))
 898       t))))
 899
 900 (define-derived-mode gnus-browse-mode fundamental-mode "Browse Server"
 901   "Major mode for browsing a foreign server.
 902
 903 All normal editing commands are switched off.
 904
 905 \\<gnus-browse-mode-map>
 906 The only things you can do in this buffer is
 907
 908 1) `\\[gnus-browse-unsubscribe-current-group]' to subscribe to a group.
 909 The group will be inserted into the group buffer upon exit from this
 910 buffer.
 911
 912 2) `\\[gnus-browse-read-group]' to read a group ephemerally.
 913
 914 3) `\\[gnus-browse-exit]' to return to the group buffer."
 915   (when (gnus-visual-p 'browse-menu 'menu)
 916     (gnus-browse-make-menu-bar))
 917   (gnus-simplify-mode-line)
 918   (setq mode-line-process nil)
 919   (buffer-disable-undo)
 920   (setq truncate-lines t)
 921   (gnus-set-default-directory)
 922   (setq buffer-read-only t))
 923
 924 (defun gnus-browse-read-group (&optional no-article number)
 925   "Enter the group at the current line.
 926 If NUMBER, fetch this number of articles."
 927   (interactive "P")
 928   (let ((group (gnus-browse-group-name)))
 929     (if (or (not (gnus-get-info group))
 930             (gnus-ephemeral-group-p group))
 931         (unless (gnus-group-read-ephemeral-group
 932                  group gnus-browse-current-method nil
 933                  (cons (current-buffer) 'browse)
 934                  nil nil nil number)
 935           (error "Couldn't enter %s" group))
 936       (unless (gnus-group-read-group nil no-article group)
 937         (error "Couldn't enter %s" group)))))
 938
 939 (defun gnus-browse-select-group (&optional number)
 940   "Select the current group.
 941 If NUMBER, fetch this number of articles."
 942   (interactive "P")
 943   (gnus-browse-read-group 'no number))
 944
 945 (defun gnus-browse-next-group (n)
 946   "Go to the next group."
 947   (interactive "p")
 948   (prog1
 949       (forward-line n)
 950     (gnus-group-position-point)))
 951
 952 (defun gnus-browse-prev-group (n)
 953   "Go to the next group."
 954   (interactive "p")
 955   (gnus-browse-next-group (- n)))
 956
 957 (defun gnus-browse-unsubscribe-current-group (arg)
 958   "(Un)subscribe to the next ARG groups.
 959 The variable `gnus-browse-subscribe-newsgroup-method' determines
 960 how new groups will be entered into the group buffer."
 961   (interactive "p")
 962   (when (eobp)
 963     (error "No group at current line"))
 964   (let ((ward (if (< arg 0) -1 1))
 965         (arg (abs arg)))
 966     (while (and (> arg 0)
 967                 (not (eobp))
 968                 (gnus-browse-unsubscribe-group)
 969                 (zerop (gnus-browse-next-group ward)))
 970       (decf arg))
 971     (gnus-group-position-point)
 972     (when (/= 0 arg)
 973       (gnus-message 7 "No more newsgroups"))
 974     arg))
 975
 976 (defun gnus-browse-group-name ()
 977   (save-excursion
 978     (beginning-of-line)
 979     (let ((name (get-text-property (point) 'gnus-group)))
 980       (when (re-search-forward ": \\(.*\\)$" (point-at-eol) t)
 981         (concat (gnus-method-to-server-name gnus-browse-current-method) ":"
 982                 (or name
 983                     (match-string-no-properties 1)))))))
 984
 985 (defun gnus-browse-describe-group (group)
 986   "Describe the current group."
 987   (interactive (list (gnus-browse-group-name)))
 988   (gnus-group-describe-group nil group))
 989
 990 (defun gnus-browse-delete-group (group force)
 991   "Delete the current group.  Only meaningful with editable groups.
 992 If FORCE (the prefix) is non-nil, all the articles in the group will
 993 be deleted.  This is \"deleted\" as in \"removed forever from the face
 994 of the Earth\".  There is no undo.  The user will be prompted before
 995 doing the deletion."
 996   (interactive (list (gnus-browse-group-name)
 997                      current-prefix-arg))
 998   (gnus-group-delete-group group force))
 999
1000 (defun gnus-browse-unsubscribe-group ()
1001   "Toggle subscription of the current group in the browse buffer."
1002   (let ((sub nil)
1003         (buffer-read-only nil)
1004         group)
1005     (save-excursion
1006       (beginning-of-line)
1007       ;; If this group it killed, then we want to subscribe it.
1008       (unless (eq (char-after) ? )
1009         (setq sub t))
1010       (setq group (gnus-browse-group-name))
1011       (when (gnus-server-equal gnus-browse-current-method "native")
1012         (setq group (gnus-group-real-name group)))
1013       (if sub
1014           (progn
1015             ;; Make sure the group has been properly removed before we
1016             ;; subscribe to it.
1017             (if (gnus-ephemeral-group-p group)
1018                 (gnus-kill-ephemeral-group group))
1019             (let ((entry (gnus-group-entry group)))
1020               (if entry
1021                   ;; Just change the subscription level if it is an
1022                   ;; unsubscribed group.
1023                   (gnus-group-change-level entry
1024                                            gnus-level-default-subscribed)
1025                 ;; If it is a killed group or a zombie, feed it to the
1026                 ;; mechanism for new group subscription.
1027                 (gnus-call-subscribe-functions
1028                  gnus-browse-subscribe-newsgroup-method
1029                  group)
1030                 (gnus-request-update-group-status group 'subscribe)))
1031             (delete-char 1)
1032             (insert (let ((lvl (gnus-group-level group)))
1033                       (cond
1034                        ((< lvl gnus-level-unsubscribed) ? )
1035                        ((< lvl gnus-level-zombie) ?U)
1036                        ((< lvl gnus-level-killed) ?Z)
1037                        (t ?K)))))
1038         (gnus-group-change-level
1039          group gnus-level-unsubscribed gnus-level-default-subscribed)
1040         (delete-char 1)
1041         (insert ?U)))
1042     t))
1043
1044 (defun gnus-browse-exit ()
1045   "Quit browsing and return to the group buffer."
1046   (interactive)
1047   (when (derived-mode-p 'gnus-browse-mode)
1048     (gnus-kill-buffer (current-buffer)))
1049   ;; Insert the newly subscribed groups in the group buffer.
1050   (with-current-buffer gnus-group-buffer
1051     (gnus-group-list-groups nil))
1052   (if gnus-browse-return-buffer
1053       (gnus-configure-windows 'server 'force)
1054     (gnus-configure-windows 'group 'force)))
1055
1056 (defun gnus-browse-describe-briefly ()
1057   "Give a one line description of the group mode commands."
1058   (interactive)
1059   (gnus-message 6 "%s"
1060                 (substitute-command-keys "\\<gnus-browse-mode-map>\\[gnus-group-next-group]:Forward  \\[gnus-group-prev-group]:Backward  \\[gnus-browse-exit]:Exit  \\[gnus-info-find-node]:Run Info  \\[gnus-browse-describe-briefly]:This help")))
1061
1062 (defun gnus-server-regenerate-server ()
1063   "Issue a command to the server to regenerate all its data structures."
1064   (interactive)
1065   (let ((server (gnus-server-server-name)))
1066     (unless server
1067       (error "No server on the current line"))
1068     (condition-case ()
1069         (gnus-get-function (gnus-server-to-method server)
1070                            'request-regenerate)
1071       (error
1072         (error "This back end doesn't support regeneration")))
1073     (gnus-message 5 "Requesting regeneration of %s..." server)
1074     (unless (gnus-open-server server)
1075       (error "Couldn't open server"))
1076     (if (gnus-request-regenerate server)
1077         (gnus-message 5 "Requesting regeneration of %s...done" server)
1078       (gnus-message 5 "Couldn't regenerate %s" server))))
1079
1080
1081 ;;;
1082 ;;; Server compaction. -- dvl
1083 ;;;
1084
1085 ;; #### FIXME: this function currently fails to update the Group buffer's
1086 ;; #### appearance.
1087 (defun gnus-server-compact-server ()
1088   "Issue a command to the server to compact all its groups.
1089
1090 Note: currently only implemented in nnml."
1091   (interactive)
1092   (let ((server (gnus-server-server-name)))
1093     (unless server
1094       (error "No server on the current line"))
1095     (condition-case ()
1096         (gnus-get-function (gnus-server-to-method server)
1097                            'request-compact)
1098       (error
1099        (error "This back end doesn't support compaction")))
1100     (gnus-message 5 "\
1101 Requesting compaction of %s... (this may take a long time)"
1102                   server)
1103     (unless (gnus-open-server server)
1104       (error "Couldn't open server"))
1105     (if (not (gnus-request-compact server))
1106         (gnus-message 5 "Couldn't compact %s" server)
1107       (gnus-message 5 "Requesting compaction of %s...done" server)
1108       ;; Invalidate the original article buffer which might be out of date.
1109       ;; #### NOTE: Yes, this might be a bit rude, but since compaction
1110       ;; #### will not happen very often, I think this is acceptable.
1111       (let ((original (get-buffer gnus-original-article-buffer)))
1112         (and original (gnus-kill-buffer original))))))
1113
1114 (defun gnus-server-toggle-cloud-server ()
1115   "Make the server under point be replicated in the Emacs Cloud."
1116   (interactive)
1117   (let ((server (gnus-server-server-name)))
1118     (unless server
1119       (error "No server on the current line"))
1120
1121     (unless (gnus-method-option-p server 'cloud)
1122       (error "The server under point doesn't support cloudiness"))
1123
1124     (if (gnus-cloud-server-p server)
1125         (setq gnus-cloud-covered-servers
1126               (delete server gnus-cloud-covered-servers))
1127       (push server gnus-cloud-covered-servers))
1128
1129     (gnus-server-update-server server)
1130     (gnus-message 1 (if (gnus-cloud-server-p server)
1131                         "Replication of %s in the cloud will start"
1132                       "Replication of %s in the cloud will stop")
1133                   server)))
1134
1135 (provide 'gnus-srvr)
1136
1137 ;;; gnus-srvr.el ends here