code.delx.au - gnu-emacs/blob - lisp/arc-mode.el

   1 ;;; arc-mode.el --- simple editing of archives
   2
   3 ;; Copyright (C) 1995, 1997, 1998, 2002, 2003, 2004,
   4 ;;   2005, 2006 Free Software Foundation, Inc.
   5
   6 ;; Author: Morten Welinder <terra@gnu.org>
   7 ;; Keywords: archives msdog editing major-mode
   8 ;; Favourite-brand-of-beer: None, I hate beer.
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  25 ;; Boston, MA 02110-1301, USA.
  26
  27 ;;; Commentary:
  28
  29 ;; NAMING: "arc" is short for "archive" and does not refer specifically
  30 ;; to files whose name end in ".arc"
  31 ;;
  32 ;; This code does not decode any files internally, although it does
  33 ;; understand the directory level of the archives.  For this reason,
  34 ;; you should expect this code to need more fiddling than tar-mode.el
  35 ;; (although it at present has fewer bugs :-)  In particular, I have
  36 ;; not tested this under Ms-Dog myself.
  37 ;; -------------------------------------
  38 ;; INTERACTION: arc-mode.el should play together with
  39 ;;
  40 ;; * ange-ftp.el: Remote archives (i.e., ones that ange-ftp has brought
  41 ;;                to you) are handled by doing all updates on a local
  42 ;;                copy.  When you make changes to a remote file the
  43 ;;                changes will first take effect when the archive buffer
  44 ;;                is saved.  You will be warned about this.
  45 ;;
  46 ;; * dos-fns.el:  (Part of Emacs 19).  You get automatic ^M^J <--> ^J
  47 ;;                conversion.
  48 ;;
  49 ;; arc-mode.el does not work well with crypt++.el; for the archives as
  50 ;; such this could be fixed (but wouldn't be useful) by declaring such
  51 ;; archives to be "remote".  For the members this is a general Emacs
  52 ;; problem that 19.29's file formats may fix.
  53 ;; -------------------------------------
  54 ;; ARCHIVE TYPES: Currently only the archives below are handled, but the
  55 ;; structure for handling just about anything is in place.
  56 ;;
  57 ;;                        Arc     Lzh     Zip     Zoo
  58 ;;                        --------------------------------
  59 ;; View listing           Intern  Intern  Intern  Intern
  60 ;; Extract member         Y       Y       Y       Y
  61 ;; Save changed member    Y       Y       Y       Y
  62 ;; Add new member         N       N       N       N
  63 ;; Delete member          Y       Y       Y       Y
  64 ;; Rename member          Y       Y       N       N
  65 ;; Chmod                  -       Y       Y       -
  66 ;; Chown                  -       Y       -       -
  67 ;; Chgrp                  -       Y       -       -
  68 ;;
  69 ;; Special thanks to Bill Brodie <wbrodie@panix.com> for very useful tips
  70 ;; on the first released version of this package.
  71 ;;
  72 ;; This code is partly based on tar-mode.el from Emacs.
  73 ;; -------------------------------------
  74 ;; ARCHIVE STRUCTURES:
  75 ;; (This is mostly for myself.)
  76 ;;
  77 ;; ARC         A series of (header,file).  No interactions among members.
  78 ;;
  79 ;; LZH         A series of (header,file).  Headers are checksummed.  No
  80 ;;             interaction among members.
  81 ;;             Headers come in three flavours called level 0, 1 and 2 headers.
  82 ;;             Level 2 header is free of DOS specific restrictions and most
  83 ;;             prevalently used.  Also level 1 and 2 headers consist of base
  84 ;;             and extension headers.  For more details see
  85 ;;             http://homepage1.nifty.com/dangan/en/Content/Program/Java/jLHA/Notes/Notes.html
  86 ;;             http://www.osirusoft.com/joejared/lzhformat.html
  87 ;;
  88 ;; ZIP         A series of (lheader,fil) followed by a "central directory"
  89 ;;             which is a series of (cheader) followed by an end-of-
  90 ;;             central-dir record possibly followed by junk.  The e-o-c-d
  91 ;;             links to c-d.  cheaders link to lheaders which are basically
  92 ;;             cut-down versions of the cheaders.
  93 ;;
  94 ;; ZOO         An archive header followed by a series of (header,file).
  95 ;;             Each member header points to the next.  The archive is
  96 ;;             terminated by a bogus header with a zero next link.
  97 ;; -------------------------------------
  98 ;; HOOKS: `foo' means one of the supported archive types.
  99 ;;
 100 ;; archive-mode-hook
 101 ;; archive-foo-mode-hook
 102 ;; archive-extract-hooks
 103
 104 ;;; Code:
 105
 106 ;; -------------------------------------------------------------------------
 107 ;; Section: Configuration.
 108
 109 (defgroup archive nil
 110   "Simple editing of archives."
 111   :group 'data)
 112
 113 (defgroup archive-arc nil
 114   "ARC-specific options to archive."
 115   :group 'archive)
 116
 117 (defgroup archive-lzh nil
 118   "LZH-specific options to archive."
 119   :group 'archive)
 120
 121 (defgroup archive-zip nil
 122   "ZIP-specific options to archive."
 123   :group 'archive)
 124
 125 (defgroup archive-zoo nil
 126   "ZOO-specific options to archive."
 127   :group 'archive)
 128
 129 (defcustom archive-tmpdir
 130   ;; make-temp-name is safe here because we use this name
 131   ;; to create a directory.
 132   (make-temp-name
 133    (expand-file-name (if (eq system-type 'ms-dos) "ar" "archive.tmp")
 134                      temporary-file-directory))
 135   "Directory for temporary files made by `arc-mode.el'."
 136   :type 'directory
 137   :group 'archive)
 138
 139 (defcustom archive-remote-regexp "^/[^/:]*[^/:.]:"
 140   "*Regexp recognizing archive files names that are not local.
 141 A non-local file is one whose file name is not proper outside Emacs.
 142 A local copy of the archive will be used when updating."
 143   :type 'regexp
 144   :group 'archive)
 145
 146 (defcustom archive-extract-hooks nil
 147   "*Hooks to run when an archive member has been extracted."
 148   :type 'hook
 149   :group 'archive)
 150 ;; ------------------------------
 151 ;; Arc archive configuration
 152
 153 ;; We always go via a local file since there seems to be no reliable way
 154 ;; to extract to stdout without junk getting added.
 155 (defcustom archive-arc-extract
 156   '("arc" "x")
 157   "*Program and its options to run in order to extract an arc file member.
 158 Extraction should happen to the current directory.  Archive and member
 159 name will be added."
 160   :type '(list (string :tag "Program")
 161                 (repeat :tag "Options"
 162                         :inline t
 163                         (string :format "%v")))
 164   :group 'archive-arc)
 165
 166 (defcustom archive-arc-expunge
 167   '("arc" "d")
 168   "*Program and its options to run in order to delete arc file members.
 169 Archive and member names will be added."
 170   :type '(list (string :tag "Program")
 171                 (repeat :tag "Options"
 172                         :inline t
 173                         (string :format "%v")))
 174   :group 'archive-arc)
 175
 176 (defcustom archive-arc-write-file-member
 177   '("arc" "u")
 178   "*Program and its options to run in order to update an arc file member.
 179 Archive and member name will be added."
 180   :type '(list (string :tag "Program")
 181                 (repeat :tag "Options"
 182                         :inline t
 183                         (string :format "%v")))
 184   :group 'archive-arc)
 185 ;; ------------------------------
 186 ;; Lzh archive configuration
 187
 188 (defcustom archive-lzh-extract
 189   '("lha" "pq")
 190   "*Program and its options to run in order to extract an lzh file member.
 191 Extraction should happen to standard output.  Archive and member name will
 192 be added."
 193   :type '(list (string :tag "Program")
 194                 (repeat :tag "Options"
 195                         :inline t
 196                         (string :format "%v")))
 197   :group 'archive-lzh)
 198
 199 (defcustom archive-lzh-expunge
 200   '("lha" "d")
 201   "*Program and its options to run in order to delete lzh file members.
 202 Archive and member names will be added."
 203   :type '(list (string :tag "Program")
 204                 (repeat :tag "Options"
 205                         :inline t
 206                         (string :format "%v")))
 207   :group 'archive-lzh)
 208
 209 (defcustom archive-lzh-write-file-member
 210   '("lha" "a")
 211   "*Program and its options to run in order to update an lzh file member.
 212 Archive and member name will be added."
 213   :type '(list (string :tag "Program")
 214                 (repeat :tag "Options"
 215                         :inline t
 216                         (string :format "%v")))
 217   :group 'archive-lzh)
 218 ;; ------------------------------
 219 ;; Zip archive configuration
 220
 221 (defcustom archive-zip-extract
 222   (if (and (not (executable-find "unzip"))
 223            (executable-find "pkunzip"))
 224       '("pkunzip" "-e" "-o-")
 225     '("unzip" "-qq" "-c"))
 226   "*Program and its options to run in order to extract a zip file member.
 227 Extraction should happen to standard output.  Archive and member name will
 228 be added."
 229   :type '(list (string :tag "Program")
 230                 (repeat :tag "Options"
 231                         :inline t
 232                         (string :format "%v")))
 233   :group 'archive-zip)
 234
 235 ;; For several reasons the latter behaviour is not desirable in general.
 236 ;; (1) It uses more disk space.  (2) Error checking is worse or non-
 237 ;; existent.  (3) It tends to do funny things with other systems' file
 238 ;; names.
 239
 240 (defcustom archive-zip-expunge
 241   (if (and (not (executable-find "zip"))
 242            (executable-find "pkzip"))
 243       '("pkzip" "-d")
 244     '("zip" "-d" "-q"))
 245   "*Program and its options to run in order to delete zip file members.
 246 Archive and member names will be added."
 247   :type '(list (string :tag "Program")
 248                 (repeat :tag "Options"
 249                         :inline t
 250                         (string :format "%v")))
 251   :group 'archive-zip)
 252
 253 (defcustom archive-zip-update
 254   (if (and (not (executable-find "zip"))
 255            (executable-find "pkzip"))
 256       '("pkzip" "-u" "-P")
 257     '("zip" "-q"))
 258   "*Program and its options to run in order to update a zip file member.
 259 Options should ensure that specified directory will be put into the zip
 260 file.  Archive and member name will be added."
 261   :type '(list (string :tag "Program")
 262                 (repeat :tag "Options"
 263                         :inline t
 264                         (string :format "%v")))
 265   :group 'archive-zip)
 266
 267 (defcustom archive-zip-update-case
 268   (if (and (not (executable-find "zip"))
 269            (executable-find "pkzip"))
 270       '("pkzip" "-u" "-P")
 271     '("zip" "-q" "-k"))
 272   "*Program and its options to run in order to update a case fiddled zip member.
 273 Options should ensure that specified directory will be put into the zip file.
 274 Archive and member name will be added."
 275   :type '(list (string :tag "Program")
 276                 (repeat :tag "Options"
 277                         :inline t
 278                         (string :format "%v")))
 279   :group 'archive-zip)
 280
 281 (defcustom archive-zip-case-fiddle t
 282   "*If non-nil then zip file members may be down-cased.
 283 This case fiddling will only happen for members created by a system
 284 that uses caseless file names."
 285   :type 'boolean
 286   :group 'archive-zip)
 287 ;; ------------------------------
 288 ;; Zoo archive configuration
 289
 290 (defcustom archive-zoo-extract
 291   '("zoo" "xpq")
 292   "*Program and its options to run in order to extract a zoo file member.
 293 Extraction should happen to standard output.  Archive and member name will
 294 be added."
 295   :type '(list (string :tag "Program")
 296                 (repeat :tag "Options"
 297                         :inline t
 298                         (string :format "%v")))
 299   :group 'archive-zoo)
 300
 301 (defcustom archive-zoo-expunge
 302   '("zoo" "DqPP")
 303   "*Program and its options to run in order to delete zoo file members.
 304 Archive and member names will be added."
 305   :type '(list (string :tag "Program")
 306                 (repeat :tag "Options"
 307                         :inline t
 308                         (string :format "%v")))
 309   :group 'archive-zoo)
 310
 311 (defcustom archive-zoo-write-file-member
 312   '("zoo" "a")
 313   "*Program and its options to run in order to update a zoo file member.
 314 Archive and member name will be added."
 315   :type '(list (string :tag "Program")
 316                 (repeat :tag "Options"
 317                         :inline t
 318                         (string :format "%v")))
 319   :group 'archive-zoo)
 320 ;; -------------------------------------------------------------------------
 321 ;; Section: Variables
 322
 323 (defvar archive-subtype nil "Symbol describing archive type.")
 324 (defvar archive-file-list-start nil "Position of first contents line.")
 325 (defvar archive-file-list-end nil "Position just after last contents line.")
 326 (defvar archive-proper-file-start nil "Position of real archive's start.")
 327 (defvar archive-read-only nil "Non-nil if the archive is read-only on disk.")
 328 (defvar archive-local-name nil "Name of local copy of remote archive.")
 329 (defvar archive-mode-map
 330   (let ((map (make-keymap)))
 331     (suppress-keymap map)
 332     (define-key map " " 'archive-next-line)
 333     (define-key map "a" 'archive-alternate-display)
 334     ;;(define-key map "c" 'archive-copy)
 335     (define-key map "d" 'archive-flag-deleted)
 336     (define-key map "\C-d" 'archive-flag-deleted)
 337     (define-key map "e" 'archive-extract)
 338     (define-key map "f" 'archive-extract)
 339     (define-key map "\C-m" 'archive-extract)
 340     (define-key map "g" 'revert-buffer)
 341     (define-key map "h" 'describe-mode)
 342     (define-key map "m" 'archive-mark)
 343     (define-key map "n" 'archive-next-line)
 344     (define-key map "\C-n" 'archive-next-line)
 345     (define-key map [down] 'archive-next-line)
 346     (define-key map "o" 'archive-extract-other-window)
 347     (define-key map "p" 'archive-previous-line)
 348     (define-key map "q" 'quit-window)
 349     (define-key map "\C-p" 'archive-previous-line)
 350     (define-key map [up] 'archive-previous-line)
 351     (define-key map "r" 'archive-rename-entry)
 352     (define-key map "u" 'archive-unflag)
 353     (define-key map "\M-\C-?" 'archive-unmark-all-files)
 354     (define-key map "v" 'archive-view)
 355     (define-key map "x" 'archive-expunge)
 356     (define-key map "\177" 'archive-unflag-backwards)
 357     (define-key map "E" 'archive-extract-other-window)
 358     (define-key map "M" 'archive-chmod-entry)
 359     (define-key map "G" 'archive-chgrp-entry)
 360     (define-key map "O" 'archive-chown-entry)
 361
 362     (if (fboundp 'command-remapping)
 363         (progn
 364           (define-key map [remap advertised-undo] 'archive-undo)
 365           (define-key map [remap undo] 'archive-undo))
 366       (substitute-key-definition 'advertised-undo 'archive-undo map global-map)
 367       (substitute-key-definition 'undo 'archive-undo map global-map))
 368
 369     (define-key map
 370       (if (featurep 'xemacs) 'button2 [mouse-2]) 'archive-extract)
 371
 372     (if (featurep 'xemacs)
 373         ()                              ; out of luck
 374
 375       (define-key map [menu-bar immediate]
 376         (cons "Immediate" (make-sparse-keymap "Immediate")))
 377       (define-key map [menu-bar immediate alternate]
 378         '(menu-item "Alternate Display" archive-alternate-display
 379           :enable (boundp (archive-name "alternate-display"))
 380           :help "Toggle alternate file info display"))
 381       (define-key map [menu-bar immediate view]
 382         '(menu-item "View This File" archive-view
 383           :help "Display file at cursor in View Mode"))
 384       (define-key map [menu-bar immediate display]
 385         '(menu-item "Display in Other Window" archive-display-other-window
 386           :help "Display file at cursor in another window"))
 387       (define-key map [menu-bar immediate find-file-other-window]
 388         '(menu-item "Find in Other Window" archive-extract-other-window
 389           :help "Edit file at cursor in another window"))
 390       (define-key map [menu-bar immediate find-file]
 391         '(menu-item "Find This File" archive-extract
 392           :help "Extract file at cursor and edit it"))
 393
 394       (define-key map [menu-bar mark]
 395         (cons "Mark" (make-sparse-keymap "Mark")))
 396       (define-key map [menu-bar mark unmark-all]
 397         '(menu-item "Unmark All" archive-unmark-all-files
 398           :help "Unmark all marked files"))
 399       (define-key map [menu-bar mark deletion]
 400         '(menu-item "Flag" archive-flag-deleted
 401           :help "Flag file at cursor for deletion"))
 402       (define-key map [menu-bar mark unmark]
 403         '(menu-item "Unflag" archive-unflag
 404           :help "Unmark file at cursor"))
 405       (define-key map [menu-bar mark mark]
 406         '(menu-item "Mark" archive-mark
 407           :help "Mark file at cursor"))
 408
 409       (define-key map [menu-bar operate]
 410         (cons "Operate" (make-sparse-keymap "Operate")))
 411       (define-key map [menu-bar operate chown]
 412         '(menu-item "Change Owner..." archive-chown-entry
 413           :enable (fboundp (archive-name "chown-entry"))
 414           :help "Change owner of marked files"))
 415       (define-key map [menu-bar operate chgrp]
 416         '(menu-item "Change Group..." archive-chgrp-entry
 417           :enable (fboundp (archive-name "chgrp-entry"))
 418           :help "Change group ownership of marked files"))
 419       (define-key map [menu-bar operate chmod]
 420         '(menu-item "Change Mode..." archive-chmod-entry
 421           :enable (fboundp (archive-name "chmod-entry"))
 422           :help "Change mode (permissions) of marked files"))
 423       (define-key map [menu-bar operate rename]
 424         '(menu-item "Rename to..." archive-rename-entry
 425           :enable (fboundp (archive-name "rename-entry"))
 426           :help "Rename marked files"))
 427       ;;(define-key map [menu-bar operate copy]
 428       ;;  '(menu-item "Copy to..." archive-copy))
 429       (define-key map [menu-bar operate expunge]
 430         '(menu-item "Expunge Marked Files" archive-expunge
 431           :help "Delete all flagged files from archive"))
 432       map))
 433   "Local keymap for archive mode listings.")
 434 (defvar archive-file-name-indent nil "Column where file names start.")
 435
 436 (defvar archive-remote nil "Non-nil if the archive is outside file system.")
 437 (make-variable-buffer-local 'archive-remote)
 438 (put 'archive-remote 'permanent-local t)
 439
 440 (defvar archive-member-coding-system nil "Coding-system of archive member.")
 441 (make-variable-buffer-local 'archive-member-coding-system)
 442
 443 (defvar archive-alternate-display nil
 444   "Non-nil when alternate information is shown.")
 445 (make-variable-buffer-local 'archive-alternate-display)
 446 (put 'archive-alternate-display 'permanent-local t)
 447
 448 (defvar archive-superior-buffer nil "In archive members, points to archive.")
 449 (put 'archive-superior-buffer 'permanent-local t)
 450
 451 (defvar archive-subfile-mode nil "Non-nil in archive member buffers.")
 452 (make-variable-buffer-local 'archive-subfile-mode)
 453 (put 'archive-subfile-mode 'permanent-local t)
 454
 455 (defvar archive-files nil
 456   "Vector of file descriptors.
 457 Each descriptor is a vector of the form
 458  [EXT-FILE-NAME INT-FILE-NAME CASE-FIDDLED MODE ...]")
 459 (make-variable-buffer-local 'archive-files)
 460
 461 ;; -------------------------------------------------------------------------
 462 ;; Section: Support functions.
 463
 464 (defsubst archive-name (suffix)
 465   (intern (concat "archive-" (symbol-name archive-subtype) "-" suffix)))
 466
 467 (defun archive-l-e (str &optional len float)
 468   "Convert little endian string/vector STR to integer.
 469 Alternatively, STR may be a buffer position in the current buffer
 470 in which case a second argument, length LEN, should be supplied.
 471 FLOAT, if non-nil, means generate and return a float instead of an integer
 472 \(use this for numbers that can overflow the Emacs integer)."
 473   (if (stringp str)
 474       (setq len (length str))
 475     (setq str (buffer-substring str (+ str len))))
 476   (let ((result 0)
 477         (i 0))
 478     (while (< i len)
 479       (setq i (1+ i)
 480             result (+ (if float (* result 256.0) (ash result 8))
 481                       (aref str (- len i)))))
 482     result))
 483
 484 (defun archive-int-to-mode (mode)
 485   "Turn an integer like 0700 (i.e., 448) into a mode string like -rwx------."
 486   ;; FIXME: merge with tar-grind-file-mode.
 487   (string
 488     (if (zerop (logand  8192 mode))
 489         (if (zerop (logand 16384 mode)) ?- ?d)
 490       ?c) ; completeness
 491     (if (zerop (logand   256 mode)) ?- ?r)
 492     (if (zerop (logand   128 mode)) ?- ?w)
 493     (if (zerop (logand    64 mode))
 494         (if (zerop (logand  1024 mode)) ?- ?S)
 495       (if (zerop (logand  1024 mode)) ?x ?s))
 496     (if (zerop (logand    32 mode)) ?- ?r)
 497     (if (zerop (logand    16 mode)) ?- ?w)
 498     (if (zerop (logand     8 mode))
 499         (if (zerop (logand  2048 mode)) ?- ?S)
 500       (if (zerop (logand  2048 mode)) ?x ?s))
 501     (if (zerop (logand     4 mode)) ?- ?r)
 502     (if (zerop (logand     2 mode)) ?- ?w)
 503     (if (zerop (logand     1 mode)) ?- ?x)))
 504
 505 (defun archive-calc-mode (oldmode newmode &optional error)
 506   "From the integer OLDMODE and the string NEWMODE calculate a new file mode.
 507 NEWMODE may be an octal number including a leading zero in which case it
 508 will become the new mode.\n
 509 NEWMODE may also be a relative specification like \"og-rwx\" in which case
 510 OLDMODE will be modified accordingly just like chmod(2) would have done.\n
 511 If optional third argument ERROR is non-nil an error will be signaled if
 512 the mode is invalid.  If ERROR is nil then nil will be returned."
 513   (cond ((string-match "^0[0-7]*$" newmode)
 514          (let ((result 0)
 515                (len (length newmode))
 516                (i 1))
 517            (while (< i len)
 518              (setq result (+ (lsh result 3) (aref newmode i) (- ?0))
 519                    i (1+ i)))
 520            (logior (logand oldmode 65024) result)))
 521         ((string-match "^\\([agou]+\\)\\([---+=]\\)\\([rwxst]+\\)$" newmode)
 522          (let ((who 0)
 523                (result oldmode)
 524                (op (aref newmode (match-beginning 2)))
 525                (bits 0)
 526                (i (match-beginning 3)))
 527            (while (< i (match-end 3))
 528              (let ((rwx (aref newmode i)))
 529                (setq bits (logior bits (cond ((= rwx ?r)  292)
 530                                              ((= rwx ?w)  146)
 531                                              ((= rwx ?x)   73)
 532                                              ((= rwx ?s) 3072)
 533                                              ((= rwx ?t)  512)))
 534                      i (1+ i))))
 535            (while (< who (match-end 1))
 536              (let* ((whoc (aref newmode who))
 537                     (whomask (cond ((= whoc ?a) 4095)
 538                                    ((= whoc ?u) 1472)
 539                                    ((= whoc ?g) 2104)
 540                                    ((= whoc ?o)    7))))
 541                (if (= op ?=)
 542                    (setq result (logand result (lognot whomask))))
 543                (if (= op ?-)
 544                    (setq result (logand result (lognot (logand whomask bits))))
 545                  (setq result (logior result (logand whomask bits)))))
 546              (setq who (1+ who)))
 547            result))
 548         (t
 549          (if error
 550              (error "Invalid mode specification: %s" newmode)))))
 551
 552 (defun archive-dosdate (date)
 553   "Stringify dos packed DATE record."
 554   (let ((year (+ 1980 (logand (ash date -9) 127)))
 555         (month (logand (ash date -5) 15))
 556         (day (logand date 31)))
 557     (if (or (> month 12) (< month 1))
 558         ""
 559       (format "%2d-%s-%d"
 560               day
 561               (aref ["Jan" "Feb" "Mar" "Apr" "May" "Jun"
 562                      "Jul" "Aug" "Sep" "Oct" "Nov" "Dec"] (1- month))
 563               year))))
 564
 565 (defun archive-dostime (time)
 566   "Stringify dos packed TIME record."
 567   (let ((hour (logand (ash time -11) 31))
 568         (minute (logand (ash time -5) 63))
 569         (second (* 2 (logand time 31)))) ; 2 seconds resolution
 570     (format "%02d:%02d:%02d" hour minute second)))
 571
 572 (defun archive-unixdate (low high)
 573   "Stringify Unix (LOW HIGH) date."
 574   (let ((str (current-time-string (cons high low))))
 575     (format "%s-%s-%s"
 576             (substring str 8 10)
 577             (substring str 4 7)
 578             (substring str 20 24))))
 579
 580 (defun archive-unixtime (low high)
 581   "Stringify Unix (LOW HIGH) time."
 582   (let ((str (current-time-string (cons high low))))
 583     (substring str 11 19)))
 584
 585 (defun archive-get-lineno ()
 586   (if (>= (point) archive-file-list-start)
 587       (count-lines archive-file-list-start
 588                    (save-excursion (beginning-of-line) (point)))
 589     0))
 590
 591 (defun archive-get-descr (&optional noerror)
 592   "Return the descriptor vector for file at point.
 593 Does not signal an error if optional argument NOERROR is non-nil."
 594   (let ((no (archive-get-lineno)))
 595     (if (and (>= (point) archive-file-list-start)
 596              (< no (length archive-files)))
 597         (let ((item (aref archive-files no)))
 598           (if (vectorp item)
 599               item
 600             (if (not noerror)
 601                 (error "Entry is not a regular member of the archive"))))
 602       (if (not noerror)
 603           (error "Line does not describe a member of the archive")))))
 604 ;; -------------------------------------------------------------------------
 605 ;; Section: the mode definition
 606
 607 ;;;###autoload
 608 (defun archive-mode (&optional force)
 609   "Major mode for viewing an archive file in a dired-like way.
 610 You can move around using the usual cursor motion commands.
 611 Letters no longer insert themselves.
 612 Type `e' to pull a file out of the archive and into its own buffer;
 613 or click mouse-2 on the file's line in the archive mode buffer.
 614
 615 If you edit a sub-file of this archive (as with the `e' command) and
 616 save it, the contents of that buffer will be saved back into the
 617 archive.
 618
 619 \\{archive-mode-map}"
 620   ;; This is not interactive because you shouldn't be turning this
 621   ;; mode on and off.  You can corrupt things that way.
 622   (if (zerop (buffer-size))
 623       ;; At present we cannot create archives from scratch
 624       (funcall default-major-mode)
 625     (if (and (not force) archive-files) nil
 626       (let* ((type (archive-find-type))
 627              (typename (capitalize (symbol-name type))))
 628         (kill-all-local-variables)
 629         (make-local-variable 'archive-subtype)
 630         (setq archive-subtype type)
 631
 632         ;; Buffer contains treated image of file before the file contents
 633         (make-local-variable 'revert-buffer-function)
 634         (setq revert-buffer-function 'archive-mode-revert)
 635         (auto-save-mode 0)
 636
 637         ;; Remote archives are not written by a hook.
 638         (if archive-remote nil
 639           (add-hook 'write-contents-functions 'archive-write-file nil t))
 640
 641         (make-local-variable 'require-final-newline)
 642         (setq require-final-newline nil)
 643         (make-local-variable 'local-enable-local-variables)
 644         (setq local-enable-local-variables nil)
 645
 646         ;; Prevent loss of data when saving the file.
 647         (make-local-variable 'file-precious-flag)
 648         (setq file-precious-flag t)
 649
 650         (make-local-variable 'archive-read-only)
 651         ;; Archives which are inside other archives and whose
 652         ;; names are invalid for this OS, can't be written.
 653         (setq archive-read-only
 654               (or (not (file-writable-p (buffer-file-name)))
 655                   (and archive-subfile-mode
 656                        (string-match file-name-invalid-regexp
 657                                      (aref archive-subfile-mode 0)))))
 658
 659         ;; Should we use a local copy when accessing from outside Emacs?
 660         (make-local-variable 'archive-local-name)
 661
 662         ;; An archive can contain another archive whose name is invalid
 663         ;; on local filesystem.  Treat such archives as remote.
 664         (or archive-remote
 665             (setq archive-remote
 666                   (or (string-match archive-remote-regexp (buffer-file-name))
 667                       (string-match file-name-invalid-regexp
 668                                     (buffer-file-name)))))
 669
 670         (setq major-mode 'archive-mode)
 671         (setq mode-name (concat typename "-Archive"))
 672         ;; Run archive-foo-mode-hook and archive-mode-hook
 673         (run-mode-hooks (archive-name "mode-hook") 'archive-mode-hook)
 674         (use-local-map archive-mode-map))
 675
 676       (make-local-variable 'archive-proper-file-start)
 677       (make-local-variable 'archive-file-list-start)
 678       (make-local-variable 'archive-file-list-end)
 679       (make-local-variable 'archive-file-name-indent)
 680       (archive-summarize nil)
 681       (setq buffer-read-only t))))
 682
 683 ;; Archive mode is suitable only for specially formatted data.
 684 (put 'archive-mode 'mode-class 'special)
 685
 686 (let ((item1 '(archive-subfile-mode " Archive")))
 687   (or (member item1 minor-mode-alist)
 688       (setq minor-mode-alist (cons item1 minor-mode-alist))))
 689 ;; -------------------------------------------------------------------------
 690 (defun archive-find-type ()
 691   (widen)
 692   (goto-char (point-min))
 693   ;; The funny [] here make it unlikely that the .elc file will be treated
 694   ;; as an archive by other software.
 695   (let (case-fold-search)
 696     (cond ((looking-at "[P]K\003\004") 'zip)
 697           ((looking-at "..-l[hz][0-9ds]-") 'lzh)
 698           ((looking-at "....................[\334]\247\304\375") 'zoo)
 699           ((and (looking-at "\C-z")     ; signature too simple, IMHO
 700                 (string-match "\\.[aA][rR][cC]$"
 701                               (or buffer-file-name (buffer-name))))
 702            'arc)
 703           (t (error "Buffer format not recognized")))))
 704 ;; -------------------------------------------------------------------------
 705 (defun archive-summarize (&optional shut-up)
 706   "Parse the contents of the archive file in the current buffer.
 707 Place a dired-like listing on the front;
 708 then narrow to it, so that only that listing
 709 is visible (and the real data of the buffer is hidden).
 710 Optional argument SHUT-UP, if non-nil, means don't print messages
 711 when parsing the archive."
 712   (widen)
 713   (set-buffer-multibyte nil)
 714   (let ((inhibit-read-only t))
 715     (or shut-up
 716         (message "Parsing archive file..."))
 717     (buffer-disable-undo (current-buffer))
 718     (setq archive-files (funcall (archive-name "summarize")))
 719     (or shut-up
 720         (message "Parsing archive file...done."))
 721     (setq archive-proper-file-start (point-marker))
 722     (narrow-to-region (point-min) (point))
 723     (set-buffer-modified-p nil)
 724     (buffer-enable-undo))
 725   (goto-char archive-file-list-start)
 726   (archive-next-line 0))
 727
 728 (defun archive-resummarize ()
 729   "Recreate the contents listing of an archive."
 730   (let ((modified (buffer-modified-p))
 731         (no (archive-get-lineno))
 732         (inhibit-read-only t))
 733     (widen)
 734     (delete-region (point-min) archive-proper-file-start)
 735     (archive-summarize t)
 736     (restore-buffer-modified-p modified)
 737     (goto-char archive-file-list-start)
 738     (archive-next-line no)))
 739
 740 (defun archive-summarize-files (files)
 741   "Insert a description of a list of files annotated with proper mouse face."
 742   (setq archive-file-list-start (point-marker))
 743   (setq archive-file-name-indent (if files (aref (car files) 1) 0))
 744   ;; We don't want to do an insert for each element since that takes too
 745   ;; long when the archive -- which has to be moved in memory -- is large.
 746   (insert
 747    (apply
 748     (function concat)
 749     (mapcar
 750      (lambda (fil)
 751        ;; Using `concat' here copies the text also, so we can add
 752        ;; properties without problems.
 753        (let ((text (concat (aref fil 0) "\n")))
 754          (if (featurep 'xemacs)
 755              ()                         ; out of luck
 756            (add-text-properties
 757             (aref fil 1) (aref fil 2)
 758             '(mouse-face highlight
 759               help-echo "mouse-2: extract this file into a buffer")
 760             text))
 761          text))
 762      files)))
 763   (setq archive-file-list-end (point-marker)))
 764
 765 (defun archive-alternate-display ()
 766   "Toggle alternative display.
 767 To avoid very long lines archive mode does not show all information.
 768 This function changes the set of information shown for each files."
 769   (interactive)
 770   (setq archive-alternate-display (not archive-alternate-display))
 771   (archive-resummarize))
 772 ;; -------------------------------------------------------------------------
 773 ;; Section: Local archive copy handling
 774
 775 (defun archive-unique-fname (fname dir)
 776   "Make sure a file FNAME can be created uniquely in directory DIR.
 777
 778 If FNAME can be uniquely created in DIR, it is returned unaltered.
 779 If FNAME is something our underlying filesystem can't grok, or if another
 780 file by that name already exists in DIR, a unique new name is generated
 781 using `make-temp-file', and the generated name is returned."
 782   (let ((fullname (expand-file-name fname dir))
 783         (alien (string-match file-name-invalid-regexp fname)))
 784     (if (or alien (file-exists-p fullname))
 785         (make-temp-file
 786          (expand-file-name
 787           (if (if (fboundp 'msdos-long-file-names)
 788                   (not (msdos-long-file-names)))
 789               "am"
 790             "arc-mode.")
 791           dir))
 792       fullname)))
 793
 794 (defun archive-maybe-copy (archive)
 795   (let ((coding-system-for-write 'no-conversion))
 796     (if archive-remote
 797         (let ((start (point-max))
 798               ;; Sometimes ARCHIVE is invalid while its actual name, as
 799               ;; recorded in its parent archive, is not.  For example, an
 800               ;; archive bar.zip inside another archive foo.zip gets a name
 801               ;; "foo.zip:bar.zip", which is invalid on DOS/Windows.
 802               ;; So use the actual name if available.
 803               (archive-name
 804                (or (and archive-subfile-mode (aref archive-subfile-mode 0))
 805                    archive)))
 806           (setq archive-local-name
 807                 (archive-unique-fname archive-name archive-tmpdir))
 808           ;; Maked sure all the leading directories in
 809           ;; archive-local-name exist under archive-tmpdir, so that
 810           ;; the directory structure recorded in the archive is
 811           ;; reconstructed in the temporary directory.
 812           (make-directory (file-name-directory archive-local-name) t)
 813           (save-restriction
 814             (widen)
 815             (write-region start (point-max) archive-local-name nil 'nomessage))
 816           archive-local-name)
 817       (if (buffer-modified-p) (save-buffer))
 818       archive)))
 819
 820 (defun archive-maybe-update (unchanged)
 821   (if archive-remote
 822       (let ((name archive-local-name)
 823             (modified (buffer-modified-p))
 824             (coding-system-for-read 'no-conversion)
 825             (lno (archive-get-lineno))
 826             (inhibit-read-only t))
 827         (if unchanged nil
 828           (setq archive-files nil)
 829           (erase-buffer)
 830           (insert-file-contents name)
 831           (archive-mode t)
 832           (goto-char archive-file-list-start)
 833           (archive-next-line lno))
 834         (archive-delete-local name)
 835         (if (not unchanged)
 836             (message
 837              "Buffer `%s' must be saved for changes to take effect"
 838              (buffer-name (current-buffer))))
 839         (set-buffer-modified-p (or modified (not unchanged))))))
 840
 841 (defun archive-delete-local (name)
 842   "Delete file NAME and its parents up to and including `archive-tmpdir'."
 843   (let ((again t)
 844         (top (directory-file-name (file-name-as-directory archive-tmpdir))))
 845     (condition-case nil
 846         (delete-file name)
 847       (error nil))
 848     (while again
 849       (setq name (directory-file-name (file-name-directory name)))
 850       (condition-case nil
 851           (delete-directory name)
 852         (error nil))
 853       (if (string= name top) (setq again nil)))))
 854 ;; -------------------------------------------------------------------------
 855 ;; Section: Member extraction
 856
 857 (defun archive-file-name-handler (op &rest args)
 858   (or (eq op 'file-exists-p)
 859       (let ((file-name-handler-alist nil))
 860         (apply op args))))
 861
 862 (defun archive-set-buffer-as-visiting-file (filename)
 863   "Set the current buffer as if it were visiting FILENAME."
 864   (save-excursion
 865     (goto-char (point-min))
 866     (let ((buffer-undo-list t)
 867           (coding
 868            (or coding-system-for-read
 869                (and set-auto-coding-function
 870                     (save-excursion
 871                       (funcall set-auto-coding-function
 872                                filename (- (point-max) (point-min)))))
 873                ;; dos-w32.el defines find-operation-coding-system for
 874                ;; DOS/Windows systems which preserves the coding-system
 875                ;; of existing files.  We want it to act here as if the
 876                ;; extracted file existed.
 877                (let ((file-name-handler-alist
 878                       '(("" . archive-file-name-handler))))
 879                  (car (find-operation-coding-system 'insert-file-contents
 880                                                     filename t))))))
 881       (if (and (not coding-system-for-read)
 882                (not enable-multibyte-characters))
 883           (setq coding
 884                 (coding-system-change-text-conversion coding 'raw-text)))
 885       (if (and coding
 886                (not (eq coding 'no-conversion)))
 887           (decode-coding-region (point-min) (point-max) coding)
 888         (setq last-coding-system-used coding))
 889       (set-buffer-modified-p nil)
 890       (kill-local-variable 'buffer-file-coding-system)
 891       (after-insert-file-set-coding (- (point-max) (point-min))))))
 892
 893 (define-obsolete-function-alias 'archive-mouse-extract 'archive-extract "22.1")
 894
 895 (defun archive-extract (&optional other-window-p event)
 896   "In archive mode, extract this entry of the archive into its own buffer."
 897   (interactive (list nil last-input-event))
 898   (if event (posn-set-point (event-end event)))
 899   (let* ((view-p (eq other-window-p 'view))
 900          (descr (archive-get-descr))
 901          (ename (aref descr 0))
 902          (iname (aref descr 1))
 903          (archive-buffer (current-buffer))
 904          (arcdir default-directory)
 905          (archive (buffer-file-name))
 906          (arcname (file-name-nondirectory archive))
 907          (bufname (concat (file-name-nondirectory iname) " (" arcname ")"))
 908          (extractor (archive-name "extract"))
 909          ;; Members with file names which aren't valid for the
 910          ;; underlying filesystem, are treated as read-only.
 911          (read-only-p (or archive-read-only
 912                           view-p
 913                           (string-match file-name-invalid-regexp ename)))
 914          (arcfilename (expand-file-name (concat arcname ":" iname)))
 915          (buffer (get-buffer bufname))
 916          (just-created nil))
 917       (if (and buffer
 918                (string= (buffer-file-name buffer) arcfilename))
 919           nil
 920         (setq archive (archive-maybe-copy archive))
 921         (setq bufname (generate-new-buffer-name bufname))
 922         (setq buffer (get-buffer-create bufname))
 923         (setq just-created t)
 924         (with-current-buffer buffer
 925           (setq buffer-file-name arcfilename)
 926           (setq buffer-file-truename
 927                 (abbreviate-file-name buffer-file-name))
 928           ;; Set the default-directory to the dir of the superior buffer.
 929           (setq default-directory arcdir)
 930           (make-local-variable 'archive-superior-buffer)
 931           (setq archive-superior-buffer archive-buffer)
 932           (add-hook 'write-file-functions 'archive-write-file-member nil t)
 933           (setq archive-subfile-mode descr)
 934           (if (and
 935                (null
 936                 (let (;; We may have to encode file name arguement for
 937                       ;; external programs.
 938                       (coding-system-for-write
 939                        (and enable-multibyte-characters
 940                             file-name-coding-system))
 941                       ;; We read an archive member by no-conversion at
 942                       ;; first, then decode appropriately by calling
 943                       ;; archive-set-buffer-as-visiting-file later.
 944                       (coding-system-for-read 'no-conversion))
 945                   (condition-case err
 946                       (if (fboundp extractor)
 947                           (funcall extractor archive ename)
 948                         (archive-*-extract archive ename
 949                                            (symbol-value extractor)))
 950                     (error
 951                      (ding (message "%s" (error-message-string err)))
 952                      nil))))
 953                just-created)
 954               (progn
 955                 (set-buffer-modified-p nil)
 956                 (kill-buffer buffer))
 957             (archive-set-buffer-as-visiting-file ename)
 958             (goto-char (point-min))
 959             (rename-buffer bufname)
 960             (setq buffer-read-only read-only-p)
 961             (setq buffer-undo-list nil)
 962             (set-buffer-modified-p nil)
 963             (setq buffer-saved-size (buffer-size))
 964             (normal-mode)
 965             ;; Just in case an archive occurs inside another archive.
 966             (when (derived-mode-p 'archive-mode)
 967               (setq archive-remote t)
 968               (if read-only-p (setq archive-read-only t))
 969               ;; We will write out the archive ourselves if it is
 970               ;; part of another archive.
 971               (remove-hook 'write-contents-functions 'archive-write-file t))
 972             (run-hooks 'archive-extract-hooks)
 973             (if archive-read-only
 974                 (message "Note: altering this archive is not implemented."))))
 975         (archive-maybe-update t))
 976       (or (not (buffer-name buffer))
 977           (cond
 978            (view-p (view-buffer buffer (and just-created 'kill-buffer)))
 979            ((eq other-window-p 'display) (display-buffer buffer))
 980            (other-window-p (switch-to-buffer-other-window buffer))
 981            (t (switch-to-buffer buffer))))))
 982
 983 (defun archive-*-extract (archive name command)
 984   (let* ((default-directory (file-name-as-directory archive-tmpdir))
 985          (tmpfile (expand-file-name (file-name-nondirectory name)
 986                                     default-directory))
 987          exit-status success)
 988     (make-directory (directory-file-name default-directory) t)
 989     (setq exit-status
 990           (apply 'call-process
 991                  (car command)
 992                  nil
 993                  nil
 994                  nil
 995                  (append (cdr command) (list archive name))))
 996     (cond ((and (numberp exit-status) (= exit-status 0))
 997            (if (not (file-exists-p tmpfile))
 998                (ding (message "`%s': no such file or directory" tmpfile))
 999              (insert-file-contents tmpfile)
1000              (setq success t)))
1001           ((numberp exit-status)
1002            (ding
1003             (message "`%s' exited with status %d" (car command) exit-status)))
1004           ((stringp exit-status)
1005            (ding (message "`%s' aborted: %s" (car command) exit-status)))
1006           (t
1007            (ding (message "`%s' failed" (car command)))))
1008     (archive-delete-local tmpfile)
1009     success))
1010
1011 (defun archive-extract-by-stdout (archive name command)
1012   (apply 'call-process
1013          (car command)
1014          nil
1015          t
1016          nil
1017          (append (cdr command) (list archive name))))
1018
1019 (defun archive-extract-other-window ()
1020   "In archive mode, find this member in another window."
1021   (interactive)
1022   (archive-extract t))
1023
1024 (defun archive-display-other-window ()
1025   "In archive mode, display this member in another window."
1026   (interactive)
1027   (archive-extract 'display))
1028
1029 (defun archive-view ()
1030   "In archive mode, view the member on this line."
1031   (interactive)
1032   (archive-extract 'view))
1033
1034 (defun archive-add-new-member (arcbuf name)
1035   "Add current buffer to the archive in ARCBUF naming it NAME."
1036   (interactive
1037    (list (get-buffer
1038           (read-buffer "Buffer containing archive: "
1039                        ;; Find first archive buffer and suggest that
1040                        (let ((bufs (buffer-list)))
1041                          (while (and bufs
1042                                      (not (with-current-buffer (car bufs)
1043                                             (derived-mode-p 'archive-mode))))
1044                            (setq bufs (cdr bufs)))
1045                          (if bufs
1046                              (car bufs)
1047                            (error "There are no archive buffers")))
1048                        t))
1049          (read-string "File name in archive: "
1050                       (if buffer-file-name
1051                           (file-name-nondirectory buffer-file-name)
1052                         ""))))
1053   (with-current-buffer arcbuf
1054     (or (eq major-mode 'archive-mode)
1055         (error "Buffer is not an archive buffer"))
1056     (if archive-read-only
1057         (error "Archive is read-only")))
1058   (if (eq arcbuf (current-buffer))
1059       (error "An archive buffer cannot be added to itself"))
1060   (if (string= name "")
1061       (error "Archive members may not be given empty names"))
1062   (let ((func (with-current-buffer arcbuf
1063                 (archive-name "add-new-member")))
1064         (membuf (current-buffer)))
1065     (if (fboundp func)
1066         (with-current-buffer arcbuf
1067           (funcall func buffer-file-name membuf name))
1068       (error "Adding a new member is not supported for this archive type"))))
1069 ;; -------------------------------------------------------------------------
1070 ;; Section: IO stuff
1071
1072 (defun archive-write-file-member ()
1073   (save-excursion
1074     (save-restriction
1075       (message "Updating archive...")
1076       (widen)
1077       (let ((writer  (with-current-buffer archive-superior-buffer
1078                        (archive-name "write-file-member")))
1079             (archive (with-current-buffer archive-superior-buffer
1080                        (archive-maybe-copy (buffer-file-name)))))
1081         (if (fboundp writer)
1082             (funcall writer archive archive-subfile-mode)
1083           (archive-*-write-file-member archive
1084                                        archive-subfile-mode
1085                                        (symbol-value writer)))
1086         (set-buffer-modified-p nil)
1087         (message "Updating archive...done"))
1088       (set-buffer archive-superior-buffer)
1089       (if (not archive-remote) (revert-buffer) (archive-maybe-update nil))))
1090   ;; Restore the value of last-coding-system-used, so that basic-save-buffer
1091   ;; won't reset the coding-system of this archive member.
1092   (if (local-variable-p 'archive-member-coding-system)
1093       (setq last-coding-system-used archive-member-coding-system))
1094   t)
1095
1096 (defun archive-*-write-file-member (archive descr command)
1097   (let* ((ename (aref descr 0))
1098          (tmpfile (expand-file-name ename archive-tmpdir))
1099          (top (directory-file-name (file-name-as-directory archive-tmpdir)))
1100          (default-directory (file-name-as-directory top)))
1101     (unwind-protect
1102         (progn
1103           (make-directory (file-name-directory tmpfile) t)
1104           ;; If the member is itself an archive, write it without
1105           ;; the dired-like listing we created.
1106           (if (eq major-mode 'archive-mode)
1107               (archive-write-file tmpfile)
1108             (write-region (point-min) (point-max) tmpfile nil 'nomessage))
1109           ;; basic-save-buffer needs last-coding-system-used to have
1110           ;; the value used to write the file, so save it before any
1111           ;; further processing clobbers it (we restore it in
1112           ;; archive-write-file-member, above).
1113           (setq archive-member-coding-system last-coding-system-used)
1114           (if (aref descr 3)
1115               ;; Set the file modes, but make sure we can read it.
1116               (set-file-modes tmpfile (logior ?\400 (aref descr 3))))
1117           (if enable-multibyte-characters
1118               (setq ename
1119                     (encode-coding-string ename file-name-coding-system)))
1120           (let ((exitcode (apply 'call-process
1121                                  (car command)
1122                                  nil
1123                                  nil
1124                                  nil
1125                                  (append (cdr command) (list archive ename)))))
1126             (if (equal exitcode 0)
1127                 nil
1128               (error "Updating was unsuccessful (%S)" exitcode))))
1129       (archive-delete-local tmpfile))))
1130
1131 (defun archive-write-file (&optional file)
1132   (save-excursion
1133     (let ((coding-system-for-write 'no-conversion))
1134       (write-region archive-proper-file-start (point-max)
1135                     (or file buffer-file-name) nil t)
1136       (set-buffer-modified-p nil))
1137     t))
1138 ;; -------------------------------------------------------------------------
1139 ;; Section: Marking and unmarking.
1140
1141 (defun archive-flag-deleted (p &optional type)
1142   "In archive mode, mark this member to be deleted from the archive.
1143 With a prefix argument, mark that many files."
1144   (interactive "p")
1145   (or type (setq type ?D))
1146   (beginning-of-line)
1147   (let ((sign (if (>= p 0) +1 -1))
1148         (modified (buffer-modified-p))
1149         (inhibit-read-only t))
1150     (while (not (zerop p))
1151       (if (archive-get-descr t)
1152           (progn
1153             (delete-char 1)
1154             (insert type)))
1155       (forward-line sign)
1156       (setq p (- p sign)))
1157     (restore-buffer-modified-p modified))
1158   (archive-next-line 0))
1159
1160 (defun archive-unflag (p)
1161   "In archive mode, un-mark this member if it is marked to be deleted.
1162 With a prefix argument, un-mark that many files forward."
1163   (interactive "p")
1164   (archive-flag-deleted p ?\s))
1165
1166 (defun archive-unflag-backwards (p)
1167   "In archive mode, un-mark this member if it is marked to be deleted.
1168 With a prefix argument, un-mark that many members backward."
1169   (interactive "p")
1170   (archive-flag-deleted (- p) ?\s))
1171
1172 (defun archive-unmark-all-files ()
1173   "Remove all marks."
1174   (interactive)
1175   (let ((modified (buffer-modified-p))
1176         (inhibit-read-only t))
1177     (save-excursion
1178       (goto-char archive-file-list-start)
1179       (while (< (point) archive-file-list-end)
1180         (or (= (following-char) ?\s)
1181             (progn (delete-char 1) (insert ?\s)))
1182         (forward-line 1)))
1183     (restore-buffer-modified-p modified)))
1184
1185 (defun archive-mark (p)
1186   "In archive mode, mark this member for group operations.
1187 With a prefix argument, mark that many members.
1188 Use \\[archive-unmark-all-files] to remove all marks."
1189   (interactive "p")
1190   (archive-flag-deleted p ?*))
1191
1192 (defun archive-get-marked (mark &optional default)
1193   (let (files)
1194     (save-excursion
1195       (goto-char archive-file-list-start)
1196       (while (< (point) archive-file-list-end)
1197         (if (= (following-char) mark)
1198             (setq files (cons (archive-get-descr) files)))
1199         (forward-line 1)))
1200     (or (nreverse files)
1201         (and default
1202              (list (archive-get-descr))))))
1203 ;; -------------------------------------------------------------------------
1204 ;; Section: Operate
1205
1206 (defun archive-next-line (p)
1207   (interactive "p")
1208   (forward-line p)
1209   (or (eobp)
1210       (forward-char archive-file-name-indent)))
1211
1212 (defun archive-previous-line (p)
1213   (interactive "p")
1214   (archive-next-line (- p)))
1215
1216 (defun archive-chmod-entry (new-mode)
1217   "Change the protection bits associated with all marked or this member.
1218 The new protection bits can either be specified as an octal number or
1219 as a relative change like \"g+rw\" as for chmod(2)."
1220   (interactive "sNew mode (octal or relative): ")
1221   (if archive-read-only (error "Archive is read-only"))
1222   (let ((func (archive-name "chmod-entry")))
1223     (if (fboundp func)
1224         (progn
1225           (funcall func new-mode (archive-get-marked ?* t))
1226           (archive-resummarize))
1227       (error "Setting mode bits is not supported for this archive type"))))
1228
1229 (defun archive-chown-entry (new-uid)
1230   "Change the owner of all marked or this member."
1231   (interactive "nNew uid: ")
1232   (if archive-read-only (error "Archive is read-only"))
1233   (let ((func (archive-name "chown-entry")))
1234     (if (fboundp func)
1235         (progn
1236           (funcall func new-uid (archive-get-marked ?* t))
1237           (archive-resummarize))
1238       (error "Setting owner is not supported for this archive type"))))
1239
1240 (defun archive-chgrp-entry (new-gid)
1241   "Change the group of all marked or this member."
1242   (interactive "nNew gid: ")
1243   (if archive-read-only (error "Archive is read-only"))
1244   (let ((func (archive-name "chgrp-entry")))
1245     (if (fboundp func)
1246         (progn
1247           (funcall func new-gid (archive-get-marked ?* t))
1248           (archive-resummarize))
1249       (error "Setting group is not supported for this archive type"))))
1250
1251 (defun archive-expunge ()
1252   "Do the flagged deletions."
1253   (interactive)
1254   (let (files)
1255     (save-excursion
1256       (goto-char archive-file-list-start)
1257       (while (< (point) archive-file-list-end)
1258         (if (= (following-char) ?D)
1259             (setq files (cons (aref (archive-get-descr) 0) files)))
1260         (forward-line 1)))
1261     (setq files (nreverse files))
1262     (and files
1263          (or (not archive-read-only)
1264              (error "Archive is read-only"))
1265          (or (yes-or-no-p (format "Really delete %d member%s? "
1266                                   (length files)
1267                                   (if (null (cdr files)) "" "s")))
1268              (error "Operation aborted"))
1269          (let ((archive (archive-maybe-copy (buffer-file-name)))
1270                (expunger (archive-name "expunge")))
1271            (if (fboundp expunger)
1272                (funcall expunger archive files)
1273              (archive-*-expunge archive files (symbol-value expunger)))
1274            (archive-maybe-update nil)
1275            (if archive-remote
1276                (archive-resummarize)
1277              (revert-buffer))))))
1278
1279 (defun archive-*-expunge (archive files command)
1280   (apply 'call-process
1281          (car command)
1282          nil
1283          nil
1284          nil
1285          (append (cdr command) (cons archive files))))
1286
1287 (defun archive-rename-entry (newname)
1288   "Change the name associated with this entry in the archive file."
1289   (interactive "sNew name: ")
1290   (if archive-read-only (error "Archive is read-only"))
1291   (if (string= newname "")
1292       (error "Archive members may not be given empty names"))
1293   (let ((func (archive-name "rename-entry"))
1294         (descr (archive-get-descr)))
1295     (if (fboundp func)
1296         (progn
1297           (funcall func
1298                    (if enable-multibyte-characters
1299                        (encode-coding-string newname file-name-coding-system)
1300                      newname)
1301                    descr)
1302           (archive-resummarize))
1303       (error "Renaming is not supported for this archive type"))))
1304
1305 ;; Revert the buffer and recompute the dired-like listing.
1306 (defun archive-mode-revert (&optional no-auto-save no-confirm)
1307   (let ((no (archive-get-lineno)))
1308     (setq archive-files nil)
1309     (let ((revert-buffer-function nil)
1310           (coding-system-for-read 'no-conversion))
1311       (set-buffer-multibyte nil)
1312       (revert-buffer t t))
1313     (archive-mode)
1314     (goto-char archive-file-list-start)
1315     (archive-next-line no)))
1316
1317 (defun archive-undo ()
1318   "Undo in an archive buffer.
1319 This doesn't recover lost files, it just undoes changes in the buffer itself."
1320   (interactive)
1321   (let ((inhibit-read-only t))
1322     (undo)))
1323 ;; -------------------------------------------------------------------------
1324 ;; Section: Arc Archives
1325
1326 (defun archive-arc-summarize ()
1327   (let ((p 1)
1328         (totalsize 0)
1329         (maxlen 8)
1330         files
1331         visual)
1332     (while (and (< (+ p 29) (point-max))
1333                 (= (char-after p) ?\C-z)
1334                 (> (char-after (1+ p)) 0))
1335       (let* ((namefld (buffer-substring (+ p 2) (+ p 2 13)))
1336              (fnlen   (or (string-match "\0" namefld) 13))
1337              (efnname (substring namefld 0 fnlen))
1338              ;; Convert to float to avoid overflow for very large files.
1339              (csize   (archive-l-e (+ p 15) 4 'float))
1340              (moddate (archive-l-e (+ p 19) 2))
1341              (modtime (archive-l-e (+ p 21) 2))
1342              (ucsize  (archive-l-e (+ p 25) 4 'float))
1343              (fiddle  (string= efnname (upcase efnname)))
1344              (ifnname (if fiddle (downcase efnname) efnname))
1345              (text    (format "  %8.0f  %-11s  %-8s  %s"
1346                               ucsize
1347                               (archive-dosdate moddate)
1348                               (archive-dostime modtime)
1349                               ifnname)))
1350         (setq maxlen (max maxlen fnlen)
1351               totalsize (+ totalsize ucsize)
1352               visual (cons (vector text
1353                                    (- (length text) (length ifnname))
1354                                    (length text))
1355                            visual)
1356               files (cons (vector efnname ifnname fiddle nil (1- p))
1357                           files)
1358               p (+ p 29 csize))))
1359     (goto-char (point-min))
1360     (let ((dash (concat "- --------  -----------  --------  "
1361                         (make-string maxlen ?-)
1362                         "\n")))
1363       (insert "M   Length  Date         Time      File\n"
1364               dash)
1365       (archive-summarize-files (nreverse visual))
1366       (insert dash
1367               (format "  %8.0f                         %d file%s"
1368                       totalsize
1369                       (length files)
1370                       (if (= 1 (length files)) "" "s"))
1371               "\n"))
1372     (apply 'vector (nreverse files))))
1373
1374 (defun archive-arc-rename-entry (newname descr)
1375   (if (string-match "[:\\\\/]" newname)
1376       (error "File names in arc files must not contain a directory component"))
1377   (if (> (length newname) 12)
1378       (error "File names in arc files are limited to 12 characters"))
1379   (let ((name (concat newname (substring "\0\0\0\0\0\0\0\0\0\0\0\0\0"
1380                                          (length newname))))
1381         (inhibit-read-only t))
1382     (save-restriction
1383       (save-excursion
1384         (widen)
1385         (set-buffer-multibyte nil)
1386         (goto-char (+ archive-proper-file-start (aref descr 4) 2))
1387         (delete-char 13)
1388         (insert name)))))
1389 ;; -------------------------------------------------------------------------
1390 ;; Section: Lzh Archives
1391
1392 (defun archive-lzh-summarize ()
1393   (let ((p 1)
1394         (totalsize 0)
1395         (maxlen 8)
1396         files
1397         visual)
1398     (while (progn (goto-char p)         ;beginning of a base header.
1399                   (looking-at "\\(.\\|\n\\)\\(.\\|\n\\)-l[hz][0-9ds]-"))
1400       (let* ((hsize   (char-after p))   ;size of the base header (level 0 and 1)
1401              ;; Convert to float to avoid overflow for very large files.
1402              (csize   (archive-l-e (+ p 7) 4 'float)) ;size of a compressed file to follow (level 0 and 2),
1403                                         ;size of extended headers + the compressed file to follow (level 1).
1404              (ucsize  (archive-l-e (+ p 11) 4 'float))  ;size of an uncompressed file.
1405              (time1   (archive-l-e (+ p 15) 2)) ;date/time (MSDOS format in level 0, 1 headers
1406              (time2   (archive-l-e (+ p 17) 2)) ;and UNIX format in level 2 header.)
1407              (hdrlvl  (char-after (+ p 20))) ;header level
1408              thsize             ;total header size (base + extensions)
1409              fnlen efnname fiddle ifnname width p2
1410              neh        ;beginning of next extension header (level 1 and 2)
1411              mode modestr uid gid text dir prname
1412              gname uname modtime moddate)
1413         (if (= hdrlvl 3) (error "can't handle lzh level 3 header type"))
1414         (when (or (= hdrlvl 0) (= hdrlvl 1))
1415           (setq fnlen   (char-after (+ p 21))) ;filename length
1416           (setq efnname (let ((str (buffer-substring (+ p 22) (+ p 22 fnlen)))) ;filename from offset 22
1417                         (if file-name-coding-system
1418                             (decode-coding-string str file-name-coding-system)
1419                           (string-as-multibyte str))))
1420           (setq p2      (+ p 22 fnlen))) ;
1421         (if (= hdrlvl 1)
1422             (setq neh (+ p2 3))         ;specific to level 1 header
1423           (if (= hdrlvl 2)
1424               (setq neh (+ p 24))))     ;specific to level 2 header
1425         (if neh         ;if level 1 or 2 we expect extension headers to follow
1426             (let* ((ehsize (archive-l-e neh 2)) ;size of the extension header
1427                    (etype (char-after (+ neh 2)))) ;extension type
1428               (while (not (= ehsize 0))
1429                   (cond
1430                  ((= etype 1)   ;file name
1431                   (let ((i (+ neh 3)))
1432                     (while (< i (+ neh ehsize))
1433                       (setq efnname (concat efnname (char-to-string (char-after i))))
1434                       (setq i (1+ i)))))
1435                  ((= etype 2)   ;directory name
1436                   (let ((i (+ neh 3)))
1437                     (while (< i (+ neh ehsize))
1438                                     (setq dir (concat dir
1439                                                        (if (= (char-after i)
1440                                                               255)
1441                                                            "/"
1442                                                          (char-to-string
1443                                                           (char-after i)))))
1444                                     (setq i (1+ i)))))
1445                  ((= etype 80)          ;Unix file permission
1446                   (setq mode (archive-l-e (+ neh 3) 2)))
1447                  ((= etype 81)          ;UNIX file group/user ID
1448                   (progn (setq uid (archive-l-e (+ neh 3) 2))
1449                          (setq gid (archive-l-e (+ neh 5) 2))))
1450                  ((= etype 82)          ;UNIX file group name
1451                   (let ((i (+ neh 3)))
1452                     (while (< i (+ neh ehsize))
1453                       (setq gname (concat gname (char-to-string (char-after i))))
1454                       (setq i (1+ i)))))
1455                  ((= etype 83)          ;UNIX file user name
1456                   (let ((i (+ neh 3)))
1457                     (while (< i (+ neh ehsize))
1458                       (setq uname (concat uname (char-to-string (char-after i))))
1459                       (setq i (1+ i)))))
1460                    )
1461                 (setq neh (+ neh ehsize))
1462                 (setq ehsize (archive-l-e neh 2))
1463                 (setq etype (char-after (+ neh 2))))
1464               ;;get total header size for level 1 and 2 headers
1465               (setq thsize (- neh p))))
1466         (if (= hdrlvl 0)  ;total header size
1467             (setq thsize hsize))
1468         (setq fiddle  (if efnname (string= efnname (upcase efnname))))
1469         (setq ifnname (if fiddle (downcase efnname) efnname))
1470         (setq prname (if dir (concat dir ifnname) ifnname))
1471         (setq width (if prname (string-width prname) 0))
1472         (setq modestr (if mode (archive-int-to-mode mode) "??????????"))
1473         (setq moddate (if (= hdrlvl 2)
1474                           (archive-unixdate time1 time2) ;level 2 header in UNIX format
1475                         (archive-dosdate time2))) ;level 0 and 1 header in DOS format
1476         (setq modtime (if (= hdrlvl 2)
1477                           (archive-unixtime time1 time2)
1478                         (archive-dostime time1)))
1479         (setq text    (if archive-alternate-display
1480                           (format "  %8.0f  %5S  %5S  %s"
1481                                   ucsize
1482                                   (or uid "?")
1483                                   (or gid "?")
1484                                   ifnname)
1485                         (format "  %10s  %8.0f  %-11s  %-8s  %s"
1486                                 modestr
1487                                 ucsize
1488                                 moddate
1489                                 modtime
1490                                 prname)))
1491         (setq maxlen (max maxlen width)
1492               totalsize (+ totalsize ucsize)
1493               visual (cons (vector text
1494                                    (- (length text) (length prname))
1495                                    (length text))
1496                            visual)
1497               files (cons (vector prname ifnname fiddle mode (1- p))
1498                           files))
1499         (cond ((= hdrlvl 1)
1500                (setq p (+ p hsize 2 csize)))
1501               ((or (= hdrlvl 2) (= hdrlvl 0))
1502                (setq p (+ p thsize 2 csize))))
1503         ))
1504     (goto-char (point-min))
1505     (set-buffer-multibyte default-enable-multibyte-characters)
1506     (let ((dash (concat (if archive-alternate-display
1507                             "- --------  -----  -----  "
1508                           "- ----------  --------  -----------  --------  ")
1509                         (make-string maxlen ?-)
1510                         "\n"))
1511           (header (if archive-alternate-display
1512                        "M   Length    Uid    Gid  File\n"
1513                     "M   Filemode    Length  Date         Time      File\n"))
1514           (sumline (if archive-alternate-display
1515                        "  %8.0f                %d file%s"
1516                      "              %8.0f                         %d file%s")))
1517       (insert header dash)
1518       (archive-summarize-files (nreverse visual))
1519       (insert dash
1520               (format sumline
1521                       totalsize
1522                       (length files)
1523                       (if (= 1 (length files)) "" "s"))
1524               "\n"))
1525     (apply 'vector (nreverse files))))
1526
1527 (defconst archive-lzh-alternate-display t)
1528
1529 (defun archive-lzh-extract (archive name)
1530   (archive-extract-by-stdout archive name archive-lzh-extract))
1531
1532 (defun archive-lzh-resum (p count)
1533   (let ((sum 0))
1534     (while (> count 0)
1535       (setq count (1- count)
1536             sum (+ sum (char-after p))
1537             p (1+ p)))
1538     (logand sum 255)))
1539
1540 (defun archive-lzh-rename-entry (newname descr)
1541   (save-restriction
1542     (save-excursion
1543       (widen)
1544       (set-buffer-multibyte nil)
1545       (let* ((p        (+ archive-proper-file-start (aref descr 4)))
1546              (oldhsize (char-after p))
1547              (oldfnlen (char-after (+ p 21)))
1548              (newfnlen (length newname))
1549              (newhsize (+ oldhsize newfnlen (- oldfnlen)))
1550              (inhibit-read-only t))
1551         (if (> newhsize 255)
1552             (error "The file name is too long"))
1553         (goto-char (+ p 21))
1554         (delete-char (1+ oldfnlen))
1555         (insert newfnlen newname)
1556         (goto-char p)
1557         (delete-char 2)
1558         (insert newhsize (archive-lzh-resum p newhsize))))))
1559
1560 (defun archive-lzh-ogm (newval files errtxt ofs)
1561   (save-excursion
1562     (save-restriction
1563       (widen)
1564       (set-buffer-multibyte nil)
1565       (dolist (fil files)
1566         (let* ((p (+ archive-proper-file-start (aref fil 4)))
1567                (hsize   (char-after p))
1568                (fnlen   (char-after (+ p 21)))
1569                (p2      (+ p 22 fnlen))
1570                (creator (if (>= (- hsize fnlen) 24) (char-after (+ p2 2)) 0))
1571                (inhibit-read-only t))
1572           (if (= creator ?U)
1573               (progn
1574                 (or (numberp newval)
1575                     (setq newval (funcall newval (archive-l-e (+ p2 ofs) 2))))
1576                 (goto-char (+ p2 ofs))
1577                 (delete-char 2)
1578                 (insert (logand newval 255) (lsh newval -8))
1579                 (goto-char (1+ p))
1580                 (delete-char 1)
1581                 (insert (archive-lzh-resum (1+ p) hsize)))
1582             (message "Member %s does not have %s field"
1583                      (aref fil 1) errtxt)))))))
1584
1585 (defun archive-lzh-chown-entry (newuid files)
1586   (archive-lzh-ogm newuid files "an uid" 10))
1587
1588 (defun archive-lzh-chgrp-entry (newgid files)
1589   (archive-lzh-ogm newgid files "a gid" 12))
1590
1591 (defun archive-lzh-chmod-entry (newmode files)
1592   (archive-lzh-ogm
1593    ;; This should work even though newmode will be dynamically accessed.
1594    (lambda (old) (archive-calc-mode old newmode t))
1595    files "a unix-style mode" 8))
1596 ;; -------------------------------------------------------------------------
1597 ;; Section: Zip Archives
1598
1599 (defun archive-zip-summarize ()
1600   (goto-char (- (point-max) (- 22 18)))
1601   (search-backward-regexp "[P]K\005\006")
1602   (let ((p (+ (point-min) (archive-l-e (+ (point) 16) 4)))
1603         (maxlen 8)
1604         (totalsize 0)
1605         files
1606         visual)
1607     (while (string= "PK\001\002" (buffer-substring p (+ p 4)))
1608       (let* ((creator (char-after (+ p 5)))
1609              ;; (method  (archive-l-e (+ p 10) 2))
1610              (modtime (archive-l-e (+ p 12) 2))
1611              (moddate (archive-l-e (+ p 14) 2))
1612              ;; Convert to float to avoid overflow for very large files.
1613              (ucsize  (archive-l-e (+ p 24) 4 'float))
1614              (fnlen   (archive-l-e (+ p 28) 2))
1615              (exlen   (archive-l-e (+ p 30) 2))
1616              (fclen   (archive-l-e (+ p 32) 2))
1617              (lheader (archive-l-e (+ p 42) 4))
1618              (efnname (let ((str (buffer-substring (+ p 46) (+ p 46 fnlen))))
1619                         (if file-name-coding-system
1620                             (decode-coding-string str file-name-coding-system)
1621                           (string-as-multibyte str))))
1622              (isdir   (and (= ucsize 0)
1623                            (string= (file-name-nondirectory efnname) "")))
1624              (mode    (cond ((memq creator '(2 3)) ; Unix + VMS
1625                              (archive-l-e (+ p 40) 2))
1626                             ((memq creator '(0 5 6 7 10 11 15)) ; Dos etc.
1627                              (logior ?\444
1628                                      (if isdir (logior 16384 ?\111) 0)
1629                                      (if (zerop
1630                                           (logand 1 (char-after (+ p 38))))
1631                                          ?\222 0)))
1632                             (t nil)))
1633              (modestr (if mode (archive-int-to-mode mode) "??????????"))
1634              (fiddle  (and archive-zip-case-fiddle
1635                            (not (not (memq creator '(0 2 4 5 9))))
1636                            (string= (upcase efnname) efnname)))
1637              (ifnname (if fiddle (downcase efnname) efnname))
1638              (width (string-width ifnname))
1639              (text    (format "  %10s  %8.0f  %-11s  %-8s  %s"
1640                               modestr
1641                               ucsize
1642                               (archive-dosdate moddate)
1643                               (archive-dostime modtime)
1644                               ifnname)))
1645         (setq maxlen (max maxlen width)
1646               totalsize (+ totalsize ucsize)
1647               visual (cons (vector text
1648                                    (- (length text) (length ifnname))
1649                                    (length text))
1650                            visual)
1651               files (cons (if isdir
1652                               nil
1653                             (vector efnname ifnname fiddle mode
1654                                     (list (1- p) lheader)))
1655                           files)
1656               p (+ p 46 fnlen exlen fclen))))
1657     (goto-char (point-min))
1658     (let ((dash (concat "- ----------  --------  -----------  --------  "
1659                         (make-string maxlen ?-)
1660                         "\n")))
1661       (insert "M Filemode      Length  Date         Time      File\n"
1662               dash)
1663       (archive-summarize-files (nreverse visual))
1664       (insert dash
1665               (format "              %8.0f                         %d file%s"
1666                       totalsize
1667                       (length files)
1668                       (if (= 1 (length files)) "" "s"))
1669               "\n"))
1670     (apply 'vector (nreverse files))))
1671
1672 (defun archive-zip-extract (archive name)
1673   (if (equal (car archive-zip-extract) "pkzip")
1674       (archive-*-extract archive name archive-zip-extract)
1675     (archive-extract-by-stdout archive name archive-zip-extract)))
1676
1677 (defun archive-zip-write-file-member (archive descr)
1678   (archive-*-write-file-member
1679    archive
1680    descr
1681    (if (aref descr 2) archive-zip-update-case archive-zip-update)))
1682
1683 (defun archive-zip-chmod-entry (newmode files)
1684   (save-restriction
1685     (save-excursion
1686       (widen)
1687       (set-buffer-multibyte nil)
1688       (dolist (fil files)
1689         (let* ((p (+ archive-proper-file-start (car (aref fil 4))))
1690                (creator (char-after (+ p 5)))
1691                (oldmode (aref fil 3))
1692                (newval  (archive-calc-mode oldmode newmode t))
1693                (inhibit-read-only t))
1694           (cond ((memq creator '(2 3)) ; Unix + VMS
1695                  (goto-char (+ p 40))
1696                  (delete-char 2)
1697                  (insert (logand newval 255) (lsh newval -8)))
1698                 ((memq creator '(0 5 6 7 10 11 15)) ; Dos etc.
1699                  (goto-char (+ p 38))
1700                  (insert (logior (logand (char-after (point)) 254)
1701                                  (logand (logxor 1 (lsh newval -7)) 1)))
1702                  (delete-char 1))
1703                 (t (message "Don't know how to change mode for this member"))))
1704         ))))
1705 ;; -------------------------------------------------------------------------
1706 ;; Section: Zoo Archives
1707
1708 (defun archive-zoo-summarize ()
1709   (let ((p (1+ (archive-l-e 25 4)))
1710         (maxlen 8)
1711         (totalsize 0)
1712         files
1713         visual)
1714     (while (and (string= "\334\247\304\375" (buffer-substring p (+ p 4)))
1715                 (> (archive-l-e (+ p 6) 4) 0))
1716       (let* ((next    (1+ (archive-l-e (+ p 6) 4)))
1717              (moddate (archive-l-e (+ p 14) 2))
1718              (modtime (archive-l-e (+ p 16) 2))
1719              ;; Convert to float to avoid overflow for very large files.
1720              (ucsize  (archive-l-e (+ p 20) 4 'float))
1721              (namefld (buffer-substring (+ p 38) (+ p 38 13)))
1722              (dirtype (char-after (+ p 4)))
1723              (lfnlen  (if (= dirtype 2) (char-after (+ p 56)) 0))
1724              (ldirlen (if (= dirtype 2) (char-after (+ p 57)) 0))
1725              (fnlen   (or (string-match "\0" namefld) 13))
1726              (efnname (let ((str
1727                              (concat
1728                               (if (> ldirlen 0)
1729                                   (concat (buffer-substring
1730                                            (+ p 58 lfnlen)
1731                                            (+ p 58 lfnlen ldirlen -1))
1732                                           "/")
1733                                 "")
1734                               (if (> lfnlen 0)
1735                                   (buffer-substring (+ p 58)
1736                                                     (+ p 58 lfnlen -1))
1737                                 (substring namefld 0 fnlen)))))
1738                         (if file-name-coding-system
1739                             (decode-coding-string str file-name-coding-system)
1740                           (string-as-multibyte str))))
1741              (fiddle  (and (= lfnlen 0) (string= efnname (upcase efnname))))
1742              (ifnname (if fiddle (downcase efnname) efnname))
1743              (width (string-width ifnname))
1744              (text    (format "  %8.0f  %-11s  %-8s  %s"
1745                               ucsize
1746                               (archive-dosdate moddate)
1747                               (archive-dostime modtime)
1748                               ifnname)))
1749         (setq maxlen (max maxlen width)
1750               totalsize (+ totalsize ucsize)
1751               visual (cons (vector text
1752                                    (- (length text) (length ifnname))
1753                                    (length text))
1754                            visual)
1755               files (cons (vector efnname ifnname fiddle nil (1- p))
1756                           files)
1757               p next)))
1758     (goto-char (point-min))
1759     (let ((dash (concat "- --------  -----------  --------  "
1760                         (make-string maxlen ?-)
1761                         "\n")))
1762       (insert "M   Length  Date         Time      File\n"
1763               dash)
1764       (archive-summarize-files (nreverse visual))
1765       (insert dash
1766               (format "  %8.0f                         %d file%s"
1767                       totalsize
1768                       (length files)
1769                       (if (= 1 (length files)) "" "s"))
1770               "\n"))
1771     (apply 'vector (nreverse files))))
1772
1773 (defun archive-zoo-extract (archive name)
1774   (archive-extract-by-stdout archive name archive-zoo-extract))
1775 ;; -------------------------------------------------------------------------
1776 ;; This line was a mistake; it is kept now for compatibility.
1777 ;; rms  15 Oct 98
1778 (provide 'archive-mode)
1779
1780 (provide 'arc-mode)
1781
1782 ;; arch-tag: e5966a01-35ec-4f27-8095-a043a79b457b
1783 ;;; arc-mode.el ends here