]> code.delx.au - gnu-emacs/blob - lisp/uniquify.el
(uniquify-rationalize-file-buffer-names):
[gnu-emacs] / lisp / uniquify.el
1 ;;; uniquify.el --- unique buffer names dependent on file name
2
3 ;; Copyright (c) 1989, 1995, 1996, 1997, 2001 Free Software Foundation, Inc.
4
5 ;; Author: Dick King <king@reasoning.com>
6 ;; Maintainer: FSF
7 ;; Keywords: files
8 ;; Created: 15 May 86
9
10 ;; This file is part of GNU Emacs.
11
12 ;; GNU Emacs is free software; you can redistribute it and/or modify
13 ;; it under the terms of the GNU General Public License as published by
14 ;; the Free Software Foundation; either version 2, or (at your option)
15 ;; any later version.
16
17 ;; GNU Emacs is distributed in the hope that it will be useful,
18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
20 ;; GNU General Public License for more details.
21
22 ;; You should have received a copy of the GNU General Public License
23 ;; along with GNU Emacs; see the file COPYING. If not, write to the
24 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
25 ;; Boston, MA 02111-1307, USA.
26
27 ;;; Commentary:
28
29 ;; Emacs's standard method for making buffer names unique adds <2>, <3>,
30 ;; etc. to the end of (all but one of) the buffers. This file replaces
31 ;; that behavior, for buffers visiting files and dired buffers, with a
32 ;; uniquification that adds parts of the file name until the buffer names
33 ;; are unique. For instance, buffers visiting /u/mernst/tmp/Makefile and
34 ;; /usr/projects/zaphod/Makefile would be named Makefile|tmp and
35 ;; Makefile|zaphod, respectively (instead of Makefile and Makefile<2>).
36 ;; Other buffer name styles are also available.
37
38 ;; To use this file, do (require 'uniquify)
39 ;; and set uniquify-buffer-name-style to one of its non-nil alternative values.
40
41 ;; For other options, see "User-visible variables", below.
42
43 ;; A version of uniquify.el that works under Emacs 18, Emacs 19, XEmacs,
44 ;; and InfoDock is available from the maintainer.
45
46 ;;; Change Log:
47
48 ;; Originally by Dick King <king@reasoning.com> 15 May 86
49 ;; Converted for Emacs 18 by Stephen Gildea <gildea@stop.mail-abuse.org>
50 ;; Make uniquify-min-dir-content 0 truly non-invasive. gildea 23 May 89
51 ;; Some cleanup. uniquify-min-dir-content default 0. gildea 01 Jun 89
52 ;; Don't rename to "". Michael Ernst <mernst@theory.lcs.mit.edu> 15 Jun 94
53 ;; Add kill-buffer-hook. Kenneth Manheimer <ken.manheimer@nist.gov> 09 May 95
54 ;; Add advice for rename-buffer and create-file-buffer, handle dired buffers,
55 ;; kill-buffer-rationalize-buffer-names-p, documentation. mernst 24 May 95
56 ;; Remove free variables, fix typos. mernst 5 Jun 95
57 ;; Efficiently support Emacs 19.27 & earlier. ken.manheimer, mernst 10 Jun 95
58 ;; Rename user options to "uniquify-...", add uniquify-reverse-dir-content-p,
59 ;; add uniquify-ask-about-buffer-names-p. king, mernst 13 Jun 95
60 ;; Prefix functions by "uniquify-..."; rename mnemonic-buffer-names to
61 ;; uniquify-buffer-name-style; add 'forward and 'post-forward-angle-brackets
62 ;; styles; remove uniquify-reverse-dir-content-p; add
63 ;; uniquify-trailing-separator-p. mernst 4 Aug 95
64 ;; Don't call expand-file-name on nil. mernst 7 Jan 96
65 ;; Check whether list-buffers-directory is bound. mernst 11 Oct 96
66 ;; Ignore non-file non-dired buffers. Colin Rafferty <craffert@ml.com> 3 Mar 97
67 ;; Use last component, not "", for file name of directories. mernst 27 Jun 97
68 ;; Use directory-file-name; code cleanup. mernst 6 Sep 97
69 ;; Add uniquify-ignore-buffers-re.
70 ;; Andre Srinivasan <andre@visigenic.com> 9 Sep 97
71 ;; Add uniquify-list-buffers-directory-modes
72 ;; Stefan Monnier <monnier@cs.yale.edu> 17 Nov 2000
73 ;; Algorithm and data structure changed to reduce consing with lots of buffers
74 ;; Francesco Potortì <pot@gnu.org> (ideas by rms and monnier) 2001-07-18
75
76 ;; Valuable feedback was provided by
77 ;; Paul Smith <psmith@baynetworks.com>,
78 ;; Alastair Burt <burt@dfki.uni-kl.de>,
79 ;; Bob Weiner <weiner@footloose.sps.mot.com>,
80 ;; Albert L. Ting <alt@vlibs.com>,
81 ;; gyro@reasoning.com,
82 ;; Bryan O'Sullivan <bos@eng.sun.com>.
83
84
85 ;;; Code:
86
87 (eval-when-compile (require 'cl))
88
89 ;;; User-visible variables
90
91 (defgroup uniquify nil
92 "Unique buffer names dependent on file name"
93 :group 'applications)
94
95
96 (defcustom uniquify-buffer-name-style nil
97 "*If non-nil, buffer names are uniquified with parts of directory name.
98 The value determines the buffer name style and is one of `forward',
99 `reverse', `post-forward', or `post-forward-angle-brackets'.
100 For example, files `/foo/bar/mumble/name' and `/baz/quux/mumble/name'
101 would have the following buffer names in the various styles:
102 forward bar/mumble/name quux/mumble/name
103 reverse name\\mumble\\bar name\\mumble\\quux
104 post-forward name|bar/mumble name|quux/mumble
105 post-forward-angle-brackets name<bar/mumble> name<quux/mumble>
106 nil name name<2>"
107 :type '(radio (const forward)
108 (const reverse)
109 (const post-forward)
110 (const post-forward-angle-brackets)
111 (const :tag "standard Emacs behavior (nil)" nil))
112 :require 'uniquify)
113
114 (defcustom uniquify-after-kill-buffer-p nil
115 "*If non-nil, rerationalize buffer names after a buffer has been killed.
116 This can be dangerous if Emacs Lisp code is keeping track of buffers by their
117 names (rather than keeping pointers to the buffers themselves)."
118 :type 'boolean)
119
120 (defcustom uniquify-ask-about-buffer-names-p nil
121 "*If non-nil, permit user to choose names for buffers with same base file.
122 If the user chooses to name a buffer, uniquification is preempted and no
123 other buffer names are changed."
124 :type 'boolean)
125
126 ;; The default value matches certain Gnus buffers.
127 (defcustom uniquify-ignore-buffers-re "^\\*\\(un\\)?sent "
128 "*Regular expression matching buffer names that should not be uniquified.
129 For instance, set this to \"^draft-[0-9]+$\" to avoid having uniquify rename
130 draft buffers even if `uniquify-after-kill-buffer-p' is non-nil and the
131 visited file name isn't the same as that of the buffer."
132 :type '(choice (const :tag "Uniquify all buffers" nil) regexp))
133
134 (defcustom uniquify-min-dir-content 0
135 "*Minimum number of directory name components included in buffer name."
136 :type 'integer)
137
138 (defcustom uniquify-separator nil
139 "*String separator for buffer name components.
140 When `uniquify-buffer-name-style' is `post-forward', separates
141 base file name from directory part in buffer names (default \"|\").
142 When `uniquify-buffer-name-style' is `reverse', separates all
143 file name components (default \"\\\")."
144 :type '(choice (const nil) string))
145
146 (defcustom uniquify-trailing-separator-p nil
147 "*If non-nil, add a file name separator to dired buffer names.
148 If `uniquify-buffer-name-style' is `forward', add the separator at the end;
149 if it is `reverse', add the separator at the beginning; otherwise, this
150 variable is ignored."
151 :type 'boolean)
152
153 (defvar uniquify-list-buffers-directory-modes '(dired-mode cvs-mode)
154 "List of modes for which uniquify should obey `list-buffers-directory'.
155 That means that when `buffer-file-name' is set to nil, `list-buffers-directory'
156 contains the name of the directory which the buffer is visiting.")
157
158 ;;; Utilities
159
160 ;; uniquify-fix-list data structure
161 (defstruct (uniquify-item
162 (:constructor nil) (:copier nil)
163 (:constructor uniquify-make-item (base dirname buffer proposed)))
164 base dirname buffer proposed)
165
166 ;; Internal variables used free
167 (defvar uniquify-possibly-resolvable nil)
168
169 (defvar uniquify-managed nil
170 "Non-nil if the name of this buffer is managed by uniquify.
171 It actually holds the list of `uniquify-item's corresponding to the conflict.")
172 (make-variable-buffer-local 'uniquify-managed)
173 (put 'uniquify-managed 'permanent-local t)
174
175 ;;; Main entry point.
176
177 (defun uniquify-rationalize-file-buffer-names (newbuffile newbuf)
178 "Make file buffer names unique by adding segments from file name.
179 If `uniquify-min-dir-content' > 0, always pulls that many
180 file name elements.
181 Arguments NEWBUFFILE and NEWBUF cause only a subset of buffers to be renamed."
182 (interactive)
183 (if (null newbuffile)
184 (with-current-buffer newbuf (setq uniquify-managed nil))
185 (setq newbuffile (expand-file-name (directory-file-name newbuffile)))
186 (let ((fix-list nil)
187 (base (file-name-nondirectory newbuffile)))
188 (dolist (buffer (buffer-list))
189 (let ((bufname (buffer-name buffer))
190 bfn)
191 (when (and (not (and uniquify-ignore-buffers-re
192 (string-match uniquify-ignore-buffers-re
193 bufname)))
194 ;; Only try to rename buffers we actually manage.
195 (or (buffer-local-value 'uniquify-managed buffer)
196 (eq buffer newbuf))
197 (setq bfn (if (eq buffer newbuf) newbuffile
198 (uniquify-buffer-file-name buffer)))
199 (equal (file-name-nondirectory bfn) base))
200 (when (setq bfn (file-name-directory bfn)) ;Strip off the `base'.
201 (setq bfn (directory-file-name bfn))) ;Strip trailing slash.
202 (push (uniquify-make-item base bfn buffer
203 (uniquify-get-proposed-name base bfn))
204 fix-list))))
205 ;; selects buffers whose names may need changing, and others that
206 ;; may conflict, then bring conflicting names together
207 (uniquify-rationalize fix-list))))
208
209 ;; uniquify's version of buffer-file-name; result never contains trailing slash
210 (defun uniquify-buffer-file-name (buffer)
211 "Return name of file BUFFER is visiting, or nil if none.
212 Works on ordinary file-visiting buffers and buffers whose mode is mentioned
213 in `uniquify-list-buffers-directory-modes', otherwise returns nil."
214 (or (buffer-file-name buffer)
215 (with-current-buffer buffer
216 (and
217 (memq major-mode uniquify-list-buffers-directory-modes)
218 (if (boundp 'list-buffers-directory) ; XEmacs mightn't define this
219 (and list-buffers-directory
220 (directory-file-name list-buffers-directory))
221 ;; don't use default-directory if dired-directory is nil
222 (and dired-directory
223 (expand-file-name
224 (directory-file-name
225 (if (consp dired-directory)
226 (car dired-directory)
227 dired-directory)))))))))
228
229 (defun uniquify-rerationalize-w/o-cb (fix-list)
230 "Re-rationalize the buffers in FIX-LIST, but ignoring current-buffer."
231 (let ((new-fix-list nil))
232 (dolist (item fix-list)
233 (let ((buf (uniquify-item-buffer item)))
234 (unless (or (eq buf (current-buffer)) (not (buffer-live-p buf)))
235 ;; Reset the proposed names.
236 (setf (uniquify-item-proposed item)
237 (uniquify-get-proposed-name (uniquify-item-base item)
238 (uniquify-item-dirname item)))
239 (push item new-fix-list))))
240 (when new-fix-list
241 (uniquify-rationalize new-fix-list))))
242
243 (defun uniquify-rationalize (fix-list)
244 ;; Set up uniquify to re-rationalize after killing/renaming
245 ;; if there is a conflict.
246 (dolist (fix fix-list)
247 (with-current-buffer (uniquify-item-buffer fix)
248 (setq uniquify-managed fix-list)))
249 ;; If uniquify-min-dir-content is 0, this will end up just
250 ;; passing fix-list to uniquify-rationalize-conflicting-sublist.
251 (uniquify-rationalize-a-list fix-list))
252
253 (defun uniquify-item-greaterp (item1 item2)
254 (string-lessp (uniquify-item-proposed item2)
255 (uniquify-item-proposed item1)))
256
257 (defun uniquify-rationalize-a-list (fix-list &optional depth)
258 (unless depth (setq depth uniquify-min-dir-content))
259 (let (conflicting-sublist ; all elements have the same proposed name
260 (old-proposed "")
261 proposed)
262 ;; Divide fix-list into items with same proposed names and pass them
263 ;; to uniquify-rationalize-conflicting-sublist.
264 (dolist (item (sort fix-list 'uniquify-item-greaterp))
265 (setq proposed (uniquify-item-proposed item))
266 (unless (equal proposed old-proposed)
267 (uniquify-rationalize-conflicting-sublist conflicting-sublist
268 old-proposed depth)
269 (setq conflicting-sublist nil))
270 (push item conflicting-sublist)
271 (setq old-proposed proposed))
272 (uniquify-rationalize-conflicting-sublist conflicting-sublist
273 old-proposed depth)))
274
275 (defun uniquify-get-proposed-name (base dirname &optional depth)
276 (unless depth (setq depth uniquify-min-dir-content))
277 (assert (equal (directory-file-name dirname) dirname)) ;No trailing slash.
278
279 ;; Distinguish directories by adding extra separator.
280 (if (and uniquify-trailing-separator-p
281 (file-directory-p (expand-file-name base dirname))
282 (not (string-equal base "")))
283 (cond ((eq uniquify-buffer-name-style 'forward)
284 (setq base (file-name-as-directory base)))
285 ;; (setq base (concat base "/")))
286 ((eq uniquify-buffer-name-style 'reverse)
287 (setq base (concat (or uniquify-separator "\\") base)))))
288
289 (let ((extra-string nil)
290 (n depth))
291 (while (and (> n 0) dirname)
292 (let ((file (file-name-nondirectory dirname)))
293 (when (setq dirname (file-name-directory dirname))
294 (setq dirname (directory-file-name dirname)))
295 (setq n (1- n))
296 (push (if (zerop (length file)) ;nil or "".
297 (prog1 "" (setq dirname nil)) ;Could be `dirname' iso "".
298 file)
299 extra-string)))
300 (when (zerop n)
301 (if (and dirname extra-string
302 (equal dirname (file-name-directory dirname)))
303 ;; We're just before the root. Let's add the leading / already.
304 ;; With "/a/b"+"/c/d/b" this leads to "/a/b" and "d/b" but with
305 ;; "/a/b"+"/c/a/b" this leads to "/a/b" and "a/b".
306 (push "" extra-string))
307 (setq uniquify-possibly-resolvable t))
308
309 (cond
310 ((null extra-string) base)
311 ((string-equal base "") ;Happens for dired buffers on the root directory.
312 (mapconcat 'identity extra-string "/"))
313 ((eq uniquify-buffer-name-style 'reverse)
314 (mapconcat 'identity
315 (cons base (nreverse extra-string))
316 (or uniquify-separator "\\")))
317 ((eq uniquify-buffer-name-style 'forward)
318 (mapconcat 'identity (nconc extra-string (list base))
319 "/"))
320 ((eq uniquify-buffer-name-style 'post-forward)
321 (concat base (or uniquify-separator "|")
322 (mapconcat 'identity extra-string "/")))
323 ((eq uniquify-buffer-name-style 'post-forward-angle-brackets)
324 (concat base "<" (mapconcat 'identity extra-string "/")
325 ">"))
326 (t (error "Bad value for uniquify-buffer-name-style: %s"
327 uniquify-buffer-name-style)))))
328
329
330 ;; Deal with conflicting-sublist, all of whose elements have identical
331 ;; "base" components.
332 (defun uniquify-rationalize-conflicting-sublist (conf-list old-name depth)
333 (when conf-list
334 (if (or (cdr conf-list)
335 ;; Check that the proposed name doesn't conflict with some
336 ;; existing buffer.
337 (let ((buf (get-buffer old-name)))
338 (and buf (not (eq buf (uniquify-item-buffer (car conf-list)))))))
339 (when uniquify-possibly-resolvable
340 (setq uniquify-possibly-resolvable nil
341 depth (1+ depth))
342 (dolist (item conf-list)
343 (setf (uniquify-item-proposed item)
344 (uniquify-get-proposed-name
345 (uniquify-item-base item)
346 (uniquify-item-dirname item)
347 depth)))
348 (uniquify-rationalize-a-list conf-list depth))
349 (unless (string= old-name "")
350 (uniquify-rename-buffer (car conf-list) old-name)))))
351
352
353 (defun uniquify-rename-buffer (item newname)
354 (let ((buffer (uniquify-item-buffer item)))
355 (unless (equal newname (buffer-name buffer))
356 (with-current-buffer buffer
357 (let ((uniquify-buffer-name-style nil)) ;Avoid hooks on rename-buffer.
358 ;; Pass the `unique' arg, so the advice doesn't mark it as unmanaged.
359 (rename-buffer newname t))))))
360
361 ;;; Hooks from the rest of Emacs
362
363 ;; The logical place to put all this code is in generate-new-buffer-name.
364 ;; It's written in C, so we would add a generate-new-buffer-name-function
365 ;; which, if non-nil, would be called instead of the C. One problem with
366 ;; that is that generate-new-buffer-name takes a potential buffer name as
367 ;; its argument -- not other information, such as what file the buffer will
368 ;; visit.
369
370 ;; The below solution works because generate-new-buffer-name is called
371 ;; only by rename-buffer (which, as of 19.29, is never called from C) and
372 ;; generate-new-buffer, which is called only by Lisp functions
373 ;; create-file-buffer and rename-uniquely. Rename-uniquely generally
374 ;; isn't used for buffers visiting files, so it's sufficient to hook
375 ;; rename-buffer and create-file-buffer. (Setting find-file-hook isn't
376 ;; sufficient.)
377
378 (defadvice rename-buffer (after rename-buffer-uniquify activate)
379 "Uniquify buffer names with parts of directory name."
380 (uniquify-maybe-rerationalize-w/o-cb)
381 (if (null (ad-get-arg 1)) ; no UNIQUE argument.
382 ;; Mark this buffer so it won't be renamed by uniquify.
383 (setq uniquify-managed nil)
384 (when uniquify-buffer-name-style
385 ;; Rerationalize w.r.t the new name.
386 (uniquify-rationalize-file-buffer-names
387 (uniquify-buffer-file-name (current-buffer)) (current-buffer))
388 (setq ad-return-value (buffer-name (current-buffer))))))
389
390 (defadvice create-file-buffer (after create-file-buffer-uniquify activate)
391 "Uniquify buffer names with parts of directory name."
392 (if uniquify-buffer-name-style
393 (uniquify-rationalize-file-buffer-names (ad-get-arg 0) ad-return-value)))
394
395 ;; Buffer deletion
396 ;; Rerationalize after a buffer is killed, to reduce coinciding buffer names.
397 ;; This mechanism uses `kill-buffer-hook', which runs *before* deletion.
398 ;; That means that the kill-buffer-hook function cannot just delete the
399 ;; buffer -- it has to set something to do the rationalization *later*.
400 ;; It actually puts another function on `post-command-hook'. This other
401 ;; function runs the rationalization and then removes itself from the hook.
402 ;; Is there a better way to accomplish this?
403 ;; (This ought to set some global variables so the work is done only for
404 ;; buffers with names similar to the deleted buffer. -MDE)
405
406 (defun uniquify-maybe-rerationalize-w/o-cb ()
407 "Re-rationalize buffer names, ignoring current buffer.
408 For use on `kill-buffer-hook'."
409 (if (and (cdr uniquify-managed)
410 uniquify-buffer-name-style
411 uniquify-after-kill-buffer-p)
412 (uniquify-rerationalize-w/o-cb uniquify-managed)))
413
414 ;; Ideally we'd like to add it buffer-locally, but that doesn't work
415 ;; because kill-buffer-hook is not permanent-local :-(
416 (add-hook 'kill-buffer-hook 'uniquify-maybe-rerationalize-w/o-cb)
417
418 (provide 'uniquify)
419 ;;; uniquify.el ends here