code.delx.au - gnu-emacs/blob - lisp/dired-x.el

   1 ;;; dired-x.el --- extra Dired functionality -*-byte-compile-dynamic: t;-*-
   2
   3 ;; Author: Sebastian Kremer <sk@thp.uni-koeln.de>
   4 ;;      Lawrence R. Dodd <dodd@roebling.poly.edu>
   5 ;; Maintainer: nobody (want to volunteer?)
   6 ;; Version: 2.37+
   7 ;; Date: 1994/08/18 19:27:42
   8 ;; Keywords: dired extensions files
   9
  10 ;; Copyright (C) 1993, 1994, 1997, 2001, 2002, 2003, 2004,
  11 ;;   2005 Free Software Foundation, Inc.
  12
  13 ;; This file is part of GNU Emacs.
  14
  15 ;; GNU Emacs is free software; you can redistribute it and/or modify
  16 ;; it under the terms of the GNU General Public License as published by
  17 ;; the Free Software Foundation; either version 2, or (at your option)
  18 ;; any later version.
  19
  20 ;; GNU Emacs is distributed in the hope that it will be useful,
  21 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  22 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  23 ;; GNU General Public License for more details.
  24
  25 ;; You should have received a copy of the GNU General Public License
  26 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  27 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  28 ;; Boston, MA 02110-1301, USA.
  29
  30 ;;; Commentary:
  31
  32 ;; This is Sebastian Kremer's excellent dired-x.el (Dired Extra), version
  33 ;; 1.191, hacked up for GNU Emacs.  Redundant or conflicting material has
  34 ;; been removed or renamed in order to work properly with dired of GNU
  35 ;; Emacs.  All suggestions or comments are most welcomed.
  36
  37 ;;
  38 ;; Please, PLEASE, *PLEASE* see the info pages.
  39 ;;
  40
  41 ;; BUGS: Type M-x dired-x-submit-report and a report will be generated.
  42
  43 ;; INSTALLATION: In your ~/.emacs,
  44 ;;
  45 ;; (add-hook 'dired-load-hook
  46 ;;           (function (lambda ()
  47 ;;                       (load "dired-x")
  48 ;;                       ;; Set global variables here.  For example:
  49 ;;                       ;; (setq dired-guess-shell-gnutar "gtar")
  50 ;;                       )))
  51 ;; (add-hook 'dired-mode-hook
  52 ;;           (function (lambda ()
  53 ;;                       ;; Set buffer-local variables here.  For example:
  54 ;;                       ;; (dired-omit-mode 1)
  55 ;;                       )))
  56 ;;
  57 ;; At load time dired-x.el will install itself, redefine some functions, and
  58 ;; bind some dired keys.  *Please* see the info pages for more details.
  59
  60 ;; *Please* see the info pages for more details.
  61
  62 ;; User defined variables:
  63 ;;
  64 ;;      dired-bind-vm
  65 ;;      dired-vm-read-only-folders
  66 ;;      dired-bind-jump
  67 ;;      dired-bind-info
  68 ;;      dired-bind-man
  69 ;;      dired-x-hands-off-my-keys
  70 ;;      dired-find-subdir
  71 ;;      dired-enable-local-variables
  72 ;;      dired-local-variables-file
  73 ;;      dired-guess-shell-gnutar
  74 ;;      dired-guess-shell-gzip-quiet
  75 ;;      dired-guess-shell-znew-switches
  76 ;;      dired-guess-shell-alist-user
  77 ;;      dired-clean-up-buffers-too
  78 ;;      dired-omit-mode
  79 ;;      dired-omit-files
  80 ;;      dired-omit-extensions
  81 ;;      dired-omit-size-limit
  82 ;;
  83 ;; To find out more about these variables, load this file, put your cursor at
  84 ;; the end of any of the variable names, and hit C-h v [RET].  *Please* see
  85 ;; the info pages for more details.
  86
  87 ;; When loaded this code redefines the following functions of GNU Emacs
  88 ;;
  89 ;;   Function                         Found in this file of GNU Emacs
  90 ;;   --------                         -------------------------------
  91 ;;   dired-clean-up-after-deletion    ../lisp/dired.el
  92 ;;   dired-find-buffer-nocreate       ../lisp/dired.el
  93 ;;   dired-initial-position           ../lisp/dired.el
  94 ;;
  95 ;;   dired-add-entry                  ../lisp/dired-aux.el
  96 ;;   dired-read-shell-command         ../lisp/dired-aux.el
  97
  98 \f
  99 ;;; Code:
 100
 101 ;; LOAD.
 102
 103 ;; This is a no-op if dired-x is being loaded via `dired-load-hook'.  It is
 104 ;; here in case the user has autoloaded dired-x via the dired-jump key binding
 105 ;; (instead of autoloading to dired as is suggested in the info-pages).
 106
 107 (require 'dired)
 108
 109 ;; We will redefine some functions and also need some macros so we need to
 110 ;; load dired stuff of GNU Emacs.
 111
 112 (require 'dired-aux)
 113
 114 (defvar vm-folder-directory)
 115
 116 ;;; User-defined variables.
 117
 118 (defgroup dired-x nil
 119   "Extended directory editing (dired-x)."
 120   :group 'dired)
 121
 122 (defgroup dired-keys nil
 123   "Dired keys customizations."
 124   :prefix "dired-"
 125   :group 'dired-x)
 126
 127 (defcustom dired-bind-vm nil
 128   "*Non-nil means \"V\" runs `dired-vm', otherwise \"V\" runs `dired-rmail'.
 129 Also, RMAIL files contain -*- rmail -*- at the top so \"f\",
 130 `dired-advertised-find-file', will run rmail."
 131   :type 'boolean
 132   :group 'dired-keys)
 133
 134 (defcustom dired-bind-jump t
 135   "*Non-nil means bind `dired-jump' to C-x C-j, otherwise do not."
 136   :type 'boolean
 137   :group 'dired-keys)
 138
 139 (defcustom dired-bind-man t
 140   "*Non-nil means bind `dired-man' to \"N\" in dired-mode, otherwise do not."
 141   :type 'boolean
 142   :group 'dired-keys)
 143
 144 (defcustom dired-bind-info t
 145   "*Non-nil means bind `dired-info' to \"I\" in dired-mode, otherwise do not."
 146   :type 'boolean
 147   :group 'dired-keys)
 148
 149 (defcustom dired-vm-read-only-folders nil
 150   "*If non-nil, \\[dired-vm] will visit all folders read-only.
 151 If neither nil nor t, e.g. the symbol `if-file-read-only', only
 152 files not writable by you are visited read-only.
 153
 154 Read-only folders only work in VM 5, not in VM 4."
 155   :type '(choice (const :tag "off" nil)
 156                  (const :tag "on" t)
 157                  (other :tag "non-writable only" if-file-read-only))
 158   :group 'dired-x)
 159
 160 (define-minor-mode dired-omit-mode
 161   "Toggle Dired-Omit mode.
 162 With numeric ARG, enable Dired-Omit mode if ARG is positive, disable
 163 otherwise.  Enabling and disabling is buffer-local.
 164 If enabled, \"uninteresting\" files are not listed.
 165 Uninteresting files are those whose filenames match regexp `dired-omit-files',
 166 plus those ending with extensions in `dired-omit-extensions'."
 167   :group 'dired-x
 168   (if dired-omit-mode
 169       ;; This will mention how many lines were omitted:
 170       (let ((dired-omit-size-limit nil)) (dired-omit-expunge))
 171     (revert-buffer)))
 172
 173 ;; For backward compatibility
 174 (defvaralias 'dired-omit-files-p 'dired-omit-mode)
 175 (make-obsolete-variable 'dired-omit-files-p 'dired-omit-mode)
 176
 177 (defcustom dired-omit-files "^\\.?#\\|^\\.$\\|^\\.\\.$"
 178   "*Filenames matching this regexp will not be displayed.
 179 This only has effect when `dired-omit-mode' is t.  See interactive function
 180 `dired-omit-mode' \(\\[dired-omit-mode]\) and variable
 181 `dired-omit-extensions'.  The default is to omit  `.', `..', auto-save
 182 files and lock files."
 183   :type 'regexp
 184   :group 'dired-x)
 185
 186 (defcustom dired-find-subdir nil           ; t is pretty near to DWIM...
 187   "*If non-nil, Dired always finds a directory in a buffer of its own.
 188 If nil, Dired finds the directory as a subdirectory in some other buffer
 189 if it is present as one.
 190
 191 If there are several dired buffers for a directory, the most recently
 192 used is chosen.
 193
 194 Dired avoids switching to the current buffer, so that if you have
 195 a normal and a wildcard buffer for the same directory, \\[dired] will
 196 toggle between those two."
 197   :type 'boolean
 198   :group 'dired-x)
 199
 200 (defcustom dired-omit-size-limit 30000
 201   "*Maximum size for the \"omitting\" feature.
 202 If nil, there is no maximum size."
 203   :type '(choice (const :tag "no maximum" nil) integer)
 204   :group 'dired-x)
 205
 206 (defcustom dired-enable-local-variables t
 207   "*Control use of local-variables lists in Dired.
 208 The value can be t, nil or something else.
 209 A value of t means local-variables lists are obeyed;
 210 nil means they are ignored; anything else means query.
 211
 212 This temporarily overrides the value of `enable-local-variables' when listing
 213 a directory.  See also `dired-local-variables-file'."
 214   :type 'boolean
 215   :group 'dired-x)
 216
 217 (defcustom dired-guess-shell-gnutar nil
 218   "*If non-nil, name of GNU tar executable.
 219 \(E.g., \"tar\" or \"gtar\").  The `z' switch will be used with it for
 220 compressed or gzip'ed tar files.  If you don't have GNU tar, set this
 221 to nil: a pipe using `zcat' or `gunzip -c' will be used."
 222   :type '(choice (const :tag "Not GNU tar" nil)
 223                  (string :tag "Command name"))
 224   :group 'dired-x)
 225
 226 (defcustom dired-guess-shell-gzip-quiet t
 227   "*Non-nil says pass -q to gzip overriding verbose GZIP environment."
 228   :type 'boolean
 229   :group 'dired-x)
 230
 231 (defcustom dired-guess-shell-znew-switches nil
 232   "*If non-nil, then string of switches passed to `znew', example: \"-K\"."
 233   :type '(choice (const :tag "None" nil)
 234                  (string :tag "Switches"))
 235   :group 'dired-x)
 236
 237 (defcustom dired-clean-up-buffers-too t
 238   "*Non-nil means offer to kill buffers visiting files and dirs deleted in Dired."
 239   :type 'boolean
 240   :group 'dired-x)
 241
 242 ;;; KEY BINDINGS.
 243
 244 (define-key dired-mode-map "\M-o" 'dired-omit-mode)
 245 (define-key dired-mode-map "*O" 'dired-mark-omitted)
 246 (define-key dired-mode-map "\M-(" 'dired-mark-sexp)
 247 (define-key dired-mode-map "*(" 'dired-mark-sexp)
 248 (define-key dired-mode-map "*." 'dired-mark-extension)
 249 (define-key dired-mode-map "\M-!" 'dired-smart-shell-command)
 250 (define-key dired-mode-map "w" 'dired-copy-filename-as-kill)
 251 (define-key dired-mode-map "\M-g" 'dired-goto-file)
 252 (define-key dired-mode-map "\M-G" 'dired-goto-subdir)
 253 (define-key dired-mode-map "F" 'dired-do-find-marked-files)
 254 (define-key dired-mode-map "Y"  'dired-do-relsymlink)
 255 (define-key dired-mode-map "%Y" 'dired-do-relsymlink-regexp)
 256 (define-key dired-mode-map "V" 'dired-do-run-mail)
 257
 258 (if dired-bind-man
 259     (define-key dired-mode-map "N" 'dired-man))
 260
 261 (if dired-bind-info
 262     (define-key dired-mode-map "I" 'dired-info))
 263
 264 ;;; GLOBAL BINDING.
 265 (if dired-bind-jump
 266     (progn
 267       (define-key global-map "\C-x\C-j" 'dired-jump)
 268       (define-key global-map "\C-x4\C-j" 'dired-jump-other-window)))
 269
 270 \f
 271 ;;; Install into appropriate hooks.
 272
 273 (add-hook 'dired-mode-hook 'dired-extra-startup)
 274 (add-hook 'dired-after-readin-hook 'dired-omit-expunge)
 275
 276 (defun dired-extra-startup ()
 277   "Automatically put on `dired-mode-hook' to get extra Dired features:
 278 \\<dired-mode-map>
 279   \\[dired-do-run-mail]\t-- run mail on folder (see `dired-bind-vm')
 280   \\[dired-info]\t-- run info on file
 281   \\[dired-man]\t-- run man on file
 282   \\[dired-do-find-marked-files]\t-- visit all marked files simultaneously
 283   \\[dired-omit-mode]\t-- toggle omitting of files
 284   \\[dired-mark-sexp]\t-- mark by Lisp expression
 285   \\[dired-copy-filename-as-kill]\t-- copy the file or subdir names into the kill ring;
 286   \t   you can feed it to other commands using \\[yank]
 287
 288 For more features, see variables
 289
 290   `dired-bind-vm'
 291   `dired-bind-jump'
 292   `dired-bind-info'
 293   `dired-bind-man'
 294   `dired-vm-read-only-folders'
 295   `dired-omit-mode'
 296   `dired-omit-files'
 297   `dired-omit-extensions'
 298   `dired-omit-size-limit'
 299   `dired-find-subdir'
 300   `dired-enable-local-variables'
 301   `dired-local-variables-file'
 302   `dired-guess-shell-gnutar'
 303   `dired-guess-shell-gzip-quiet'
 304   `dired-guess-shell-znew-switches'
 305   `dired-guess-shell-alist-user'
 306   `dired-clean-up-buffers-too'
 307
 308 See also functions
 309
 310   `dired-flag-extension'
 311   `dired-virtual'
 312   `dired-jump'
 313   `dired-man'
 314   `dired-vm'
 315   `dired-rmail'
 316   `dired-info'
 317   `dired-do-find-marked-files'"
 318   (interactive)
 319
 320   ;; These must be done in each new dired buffer.
 321   (dired-hack-local-variables)
 322   (dired-omit-startup))
 323
 324 \f
 325 ;;; BUFFER CLEANING.
 326
 327 ;; REDEFINE.
 328 (defun dired-clean-up-after-deletion (fn)
 329   "Clean up after a deleted file or directory FN.
 330 Remove expanded subdir of deleted dir, if any."
 331   (save-excursion (and (cdr dired-subdir-alist)
 332                        (dired-goto-subdir fn)
 333                        (dired-kill-subdir)))
 334
 335   ;; Offer to kill buffer of deleted file FN.
 336   (if dired-clean-up-buffers-too
 337       (progn
 338         (let ((buf (get-file-buffer fn)))
 339           (and buf
 340                (funcall (function y-or-n-p)
 341                         (format "Kill buffer of %s, too? "
 342                                 (file-name-nondirectory fn)))
 343                (save-excursion ; you never know where kill-buffer leaves you
 344                  (kill-buffer buf))))
 345         (let ((buf-list (dired-buffers-for-dir (expand-file-name fn)))
 346               (buf nil))
 347           (and buf-list
 348                (y-or-n-p (format "Kill dired buffer%s of %s, too? "
 349                                  (dired-plural-s (length buf-list))
 350                                  (file-name-nondirectory fn)))
 351                (while buf-list
 352                  (save-excursion (kill-buffer (car buf-list)))
 353                  (setq buf-list (cdr buf-list)))))))
 354   ;; Anything else?
 355   )
 356
 357 \f
 358 ;;; EXTENSION MARKING FUNCTIONS.
 359
 360 ;;; Mark files with some extension.
 361 (defun dired-mark-extension (extension &optional marker-char)
 362   "Mark all files with a certain EXTENSION for use in later commands.
 363 A `.' is *not* automatically prepended to the string entered."
 364   ;; EXTENSION may also be a list of extensions instead of a single one.
 365   ;; Optional MARKER-CHAR is marker to use.
 366   (interactive "sMarking extension: \nP")
 367   (or (listp extension)
 368       (setq extension (list extension)))
 369   (dired-mark-files-regexp
 370    (concat ".";; don't match names with nothing but an extension
 371            "\\("
 372            (mapconcat 'regexp-quote extension "\\|")
 373            "\\)$")
 374    marker-char))
 375
 376 (defun dired-flag-extension (extension)
 377   "In dired, flag all files with a certain EXTENSION for deletion.
 378 A `.' is *not* automatically prepended to the string entered."
 379   (interactive "sFlagging extension: ")
 380   (dired-mark-extension extension dired-del-marker))
 381
 382 ;;; Define some unpopular file extensions.  Used for cleaning and omitting.
 383
 384 (defvar dired-patch-unclean-extensions
 385   '(".rej" ".orig")
 386   "List of extensions of dispensable files created by the `patch' program.")
 387
 388 (defvar dired-tex-unclean-extensions
 389   '(".toc" ".log" ".aux");; these are already in completion-ignored-extensions
 390   "List of extensions of dispensable files created by TeX.")
 391
 392 (defvar dired-latex-unclean-extensions
 393   '(".idx" ".lof" ".lot" ".glo")
 394   "List of extensions of dispensable files created by LaTeX.")
 395
 396 (defvar dired-bibtex-unclean-extensions
 397   '(".blg" ".bbl")
 398   "List of extensions of dispensable files created by BibTeX.")
 399
 400 (defvar dired-texinfo-unclean-extensions
 401   '(".cp" ".cps" ".fn" ".fns" ".ky" ".kys" ".pg" ".pgs"
 402     ".tp" ".tps" ".vr" ".vrs")
 403   "List of extensions of dispensable files created by texinfo.")
 404
 405 (defun dired-clean-patch ()
 406   "Flag dispensable files created by patch for deletion.
 407 See variable `dired-patch-unclean-extensions'."
 408   (interactive)
 409   (dired-flag-extension dired-patch-unclean-extensions))
 410
 411 (defun dired-clean-tex ()
 412   "Flag dispensable files created by [La]TeX etc. for deletion.
 413 See variables `dired-tex-unclean-extensions',
 414 `dired-latex-unclean-extensions', `dired-bibtex-unclean-extensions' and
 415 `dired-texinfo-unclean-extensions'."
 416   (interactive)
 417   (dired-flag-extension (append dired-texinfo-unclean-extensions
 418                                 dired-latex-unclean-extensions
 419                                 dired-bibtex-unclean-extensions
 420                                 dired-tex-unclean-extensions)))
 421
 422 (defun dired-very-clean-tex ()
 423   "Flag dispensable files created by [La]TeX *and* \".dvi\" for deletion.
 424 See variables `dired-texinfo-unclean-extensions',
 425 `dired-latex-unclean-extensions', `dired-bibtex-unclean-extensions' and
 426 `dired-texinfo-unclean-extensions'."
 427   (interactive)
 428   (dired-flag-extension (append dired-texinfo-unclean-extensions
 429                                 dired-latex-unclean-extensions
 430                                 dired-bibtex-unclean-extensions
 431                                 dired-tex-unclean-extensions
 432                                 (list ".dvi"))))
 433 \f
 434 ;;; JUMP.
 435
 436 ;;;###autoload
 437 (defun dired-jump (&optional other-window)
 438   "Jump to dired buffer corresponding to current buffer.
 439 If in a file, dired the current directory and move to file's line.
 440 If in Dired already, pop up a level and goto old directory's line.
 441 In case the proper dired file line cannot be found, refresh the dired
 442 buffer and try again."
 443   (interactive "P")
 444   (let* ((file buffer-file-name)
 445          (dir (if file (file-name-directory file) default-directory)))
 446     (if (eq major-mode 'dired-mode)
 447         (progn
 448           (setq dir (dired-current-directory))
 449           (dired-up-directory other-window)
 450           (or (dired-goto-file dir)
 451               ;; refresh and try again
 452               (progn
 453                 (dired-insert-subdir (file-name-directory dir))
 454                 (dired-goto-file dir))))
 455       (if other-window
 456           (dired-other-window dir)
 457         (dired dir))
 458       (if file
 459           (or (dired-goto-file file)
 460               ;; refresh and try again
 461               (progn
 462                 (dired-insert-subdir (file-name-directory file))
 463                 (dired-goto-file file))
 464               ;; Toggle omitting, if it is on, and try again.
 465               (if dired-omit-mode
 466                   (progn
 467                     (dired-omit-mode)
 468                     (dired-goto-file file))))))))
 469
 470 (defun dired-jump-other-window ()
 471   "Like \\[dired-jump] (`dired-jump') but in other window."
 472   (interactive)
 473   (dired-jump t))
 474 \f
 475 ;;; OMITTING.
 476
 477 ;;; Enhanced omitting of lines from directory listings.
 478 ;;; Marked files are never omitted.
 479
 480 ;; should probably get rid of this and always use 'no-dir.
 481 ;; sk 28-Aug-1991 09:37
 482 (defvar dired-omit-localp 'no-dir
 483   "The LOCALP argument `dired-omit-expunge' passes to `dired-get-filename'.
 484 If it is `no-dir', omitting is much faster, but you can only match
 485 against the non-directory part of the file name.  Set it to nil if you
 486 need to match the entire file name.")
 487
 488 ;; \017=^O for Omit - other packages can chose other control characters.
 489 (defvar dired-omit-marker-char ?\017
 490   "Temporary marker used by dired-omit.
 491 Should never be used as marker by the user or other packages.")
 492
 493 (defun dired-omit-startup ()
 494   (or (assq 'dired-omit-mode minor-mode-alist)
 495       (setq minor-mode-alist
 496             (append '((dired-omit-mode
 497                        (:eval (if (eq major-mode 'dired-mode)
 498                                   " Omit" ""))))
 499                     minor-mode-alist))))
 500
 501 (defun dired-mark-omitted ()
 502   "Mark files matching `dired-omit-files' and `dired-omit-extensions'."
 503   (interactive)
 504   (let ((dired-omit-mode nil)) (revert-buffer)) ;; Show omitted files
 505   (dired-mark-unmarked-files (dired-omit-regexp) nil nil dired-omit-localp))
 506
 507 (defvar dired-omit-extensions
 508   (append completion-ignored-extensions
 509           dired-latex-unclean-extensions
 510           dired-bibtex-unclean-extensions
 511           dired-texinfo-unclean-extensions)
 512   "If non-nil, a list of extensions \(strings\) to omit from Dired listings.
 513 Defaults to elements of `completion-ignored-extensions',
 514 `dired-latex-unclean-extensions', `dired-bibtex-unclean-extensions', and
 515 `dired-texinfo-unclean-extensions'.
 516
 517 See interactive function `dired-omit-mode' \(\\[dired-omit-mode]\) and
 518 variables `dired-omit-mode' and `dired-omit-files'.")
 519
 520 (defun dired-omit-expunge (&optional regexp)
 521   "Erases all unmarked files matching REGEXP.
 522 Does nothing if global variable `dired-omit-mode' is nil, or if called
 523   non-interactively and buffer is bigger than `dired-omit-size-limit'.
 524 If REGEXP is nil or not specified, uses `dired-omit-files', and also omits
 525   filenames ending in `dired-omit-extensions'.
 526 If REGEXP is the empty string, this function is a no-op.
 527
 528 This functions works by temporarily binding `dired-marker-char' to
 529 `dired-omit-marker-char' and calling `dired-do-kill-lines'."
 530   (interactive "sOmit files (regexp): ")
 531   (if (and dired-omit-mode
 532            (or (interactive-p)
 533                (not dired-omit-size-limit)
 534                (< (buffer-size) dired-omit-size-limit)
 535                (progn
 536                  (message "Not omitting: directory larger than %d characters."
 537                           dired-omit-size-limit)
 538                  (setq dired-omit-mode nil)
 539                  nil)))
 540       (let ((omit-re (or regexp (dired-omit-regexp)))
 541             (old-modified-p (buffer-modified-p))
 542             count)
 543         (or (string= omit-re "")
 544             (let ((dired-marker-char dired-omit-marker-char))
 545               (message "Omitting...")
 546               (if (dired-mark-unmarked-files omit-re nil nil dired-omit-localp)
 547                   (progn
 548                     (setq count (dired-do-kill-lines nil "Omitted %d line%s."))
 549                     (force-mode-line-update))
 550                 (message "(Nothing to omit)"))))
 551         ;; Try to preserve modified state of buffer.  So `%*' doesn't appear
 552         ;; in mode-line of omitted buffers.
 553         (set-buffer-modified-p (and old-modified-p
 554                                     (save-excursion
 555                                       (goto-char (point-min))
 556                                       (re-search-forward dired-re-mark nil t))))
 557         count)))
 558
 559 (defun dired-omit-regexp ()
 560   (concat (if dired-omit-files (concat "\\(" dired-omit-files "\\)") "")
 561           (if (and dired-omit-files dired-omit-extensions) "\\|" "")
 562           (if dired-omit-extensions
 563               (concat ".";; a non-extension part should exist
 564                       "\\("
 565                       (mapconcat 'regexp-quote dired-omit-extensions "\\|")
 566                       "\\)$")
 567             "")))
 568
 569 ;; Returns t if any work was done, nil otherwise.
 570 (defun dired-mark-unmarked-files (regexp msg &optional unflag-p localp)
 571   "Mark unmarked files matching REGEXP, displaying MSG.
 572 REGEXP is matched against the entire file name.
 573 Does not re-mark files which already have a mark.
 574 With prefix argument, unflag all those files.
 575 Optional fourth argument LOCALP is as in `dired-get-filename'."
 576   (interactive "P")
 577   (let ((dired-marker-char (if unflag-p ?\s dired-marker-char)))
 578     (dired-mark-if
 579      (and
 580       ;; not already marked
 581       (looking-at " ")
 582       ;; uninteresting
 583       (let ((fn (dired-get-filename localp t)))
 584         (and fn (string-match regexp fn))))
 585      msg)))
 586
 587 ;;; REDEFINE.
 588 (defun dired-omit-new-add-entry (filename &optional marker-char relative)
 589   ;; This redefines dired-aux.el's dired-add-entry to avoid calling ls for
 590   ;; files that are going to be omitted anyway.
 591   (if dired-omit-mode
 592       ;; perhaps return t without calling ls
 593       (let ((omit-re (dired-omit-regexp)))
 594         (if (or (string= omit-re "")
 595                 (not
 596                  (string-match omit-re
 597                                (cond
 598                                 ((eq 'no-dir dired-omit-localp)
 599                                  filename)
 600                                 ((eq t dired-omit-localp)
 601                                  (dired-make-relative filename))
 602                                 (t
 603                                  (dired-make-absolute
 604                                   filename
 605                                   (file-name-directory filename)))))))
 606             ;; if it didn't match, go ahead and add the entry
 607             (dired-omit-old-add-entry filename marker-char relative)
 608           ;; dired-add-entry returns t for success, perhaps we should
 609           ;; return file-exists-p
 610           t))
 611     ;; omitting is not turned on at all
 612     (dired-omit-old-add-entry filename marker-char relative)))
 613
 614 ;;; REDEFINE.
 615 ;;; Redefine dired-aux.el's version of `dired-add-entry'
 616 ;;; Save old defun if not already done:
 617 (or (fboundp 'dired-omit-old-add-entry)
 618     (fset 'dired-omit-old-add-entry (symbol-function 'dired-add-entry)))
 619 ;; Redefine it.
 620 (fset 'dired-add-entry 'dired-omit-new-add-entry)
 621
 622 \f
 623 ;;; VIRTUAL DIRED MODE.
 624
 625 ;;; For browsing `ls -lR' listings in a dired-like fashion.
 626
 627 (defalias 'virtual-dired 'dired-virtual)
 628 (defun dired-virtual (dirname &optional switches)
 629   "Put this buffer into Virtual Dired mode.
 630
 631 In Virtual Dired mode, all commands that do not actually consult the
 632 filesystem will work.
 633
 634 This is useful if you want to peruse and move around in an ls -lR
 635 output file, for example one you got from an ftp server.  With
 636 ange-ftp, you can even dired a directory containing an ls-lR file,
 637 visit that file and turn on virtual dired mode.  But don't try to save
 638 this file, as dired-virtual indents the listing and thus changes the
 639 buffer.
 640
 641 If you have save a Dired buffer in a file you can use \\[dired-virtual] to
 642 resume it in a later session.
 643
 644 Type \\<dired-mode-map>\\[revert-buffer] \
 645 in the Virtual Dired buffer and answer `y' to convert
 646 the virtual to a real dired buffer again.  You don't have to do this, though:
 647 you can relist single subdirs using \\[dired-do-redisplay]."
 648
 649   ;; DIRNAME is the top level directory of the buffer.  It will become
 650   ;; its `default-directory'.  If nil, the old value of
 651   ;; default-directory is used.
 652
 653   ;; Optional SWITCHES are the ls switches to use.
 654
 655   ;; Shell wildcards will be used if there already is a `wildcard'
 656   ;; line in the buffer (thus it is a saved Dired buffer), but there
 657   ;; is no other way to get wildcards.  Insert a `wildcard' line by
 658   ;; hand if you want them.
 659
 660   (interactive
 661    (list (read-string "Virtual Dired directory: " (dired-virtual-guess-dir))))
 662   (goto-char (point-min))
 663   (or (looking-at "  ")
 664       ;; if not already indented, do it now:
 665       (indent-region (point-min) (point-max) 2))
 666   (or dirname (setq dirname default-directory))
 667   (setq dirname (expand-file-name (file-name-as-directory dirname)))
 668   (setq default-directory dirname)      ; contains no wildcards
 669   (let ((wildcard (save-excursion
 670                     (goto-char (point-min))
 671                     (forward-line 1)
 672                     (and (looking-at "^  wildcard ")
 673                          (buffer-substring (match-end 0)
 674                                            (progn (end-of-line) (point)))))))
 675   (if wildcard
 676         (setq dirname (expand-file-name wildcard default-directory))))
 677   ;; If raw ls listing (not a saved old dired buffer), give it a
 678   ;; decent subdir headerline:
 679   (goto-char (point-min))
 680   (or (looking-at dired-subdir-regexp)
 681       (dired-insert-headerline default-directory))
 682   (dired-mode dirname (or switches dired-listing-switches))
 683   (setq mode-name "Virtual Dired"
 684         revert-buffer-function 'dired-virtual-revert)
 685   (set (make-local-variable 'dired-subdir-alist) nil)
 686   (dired-build-subdir-alist)
 687   (goto-char (point-min))
 688   (dired-initial-position dirname))
 689
 690 (defun dired-virtual-guess-dir ()
 691   "Guess and return appropriate working directory of this buffer.
 692 The buffer is assumed to be in Dired or ls -lR format.  The guess is
 693 based upon buffer contents.  If nothing could be guessed, returns
 694 nil."
 695
 696   (let ((regexp "^\\(  \\)?\\([^ \n\r]*\\)\\(:\\)[\n\r]")
 697         (subexpr 2))
 698     (goto-char (point-min))
 699     (cond ((looking-at regexp)
 700            ;; If a saved dired buffer, look to which dir and
 701            ;; perhaps wildcard it belongs:
 702            (let ((dir (buffer-substring (match-beginning subexpr)
 703                                         (match-end subexpr))))
 704              (file-name-as-directory dir)))
 705           ;; Else no match for headerline found.  It's a raw ls listing.
 706           ;; In raw ls listings the directory does not have a headerline
 707           ;; try parent of first subdir, if any
 708           ((re-search-forward regexp nil t)
 709            (file-name-directory
 710             (directory-file-name
 711              (file-name-as-directory
 712               (buffer-substring (match-beginning subexpr)
 713                                 (match-end subexpr))))))
 714           (t                            ; if all else fails
 715            nil))))
 716
 717
 718 (defun dired-virtual-revert (&optional arg noconfirm)
 719   (if (not
 720        (y-or-n-p "Cannot revert a Virtual Dired buffer - switch to Real Dired mode? "))
 721       (error "Cannot revert a Virtual Dired buffer")
 722     (setq mode-name "Dired"
 723           revert-buffer-function 'dired-revert)
 724     (revert-buffer)))
 725
 726 ;; A zero-arg version of dired-virtual.
 727 ;; You need my modified version of set-auto-mode for the
 728 ;; `buffer-contents-mode-alist'.
 729 ;; Or you use infer-mode.el and infer-mode-alist, same syntax.
 730 (defun dired-virtual-mode ()
 731   "Put current buffer into Virtual Dired mode (see `dired-virtual').
 732 Useful on `buffer-contents-mode-alist' (which see) with the regexp
 733
 734     \"^  \\(/[^ /]+\\)/?+:$\"
 735
 736 to put saved dired buffers automatically into Virtual Dired mode.
 737
 738 Also useful for `auto-mode-alist' (which see) like this:
 739
 740   \(setq auto-mode-alist (cons '(\"[^/]\\.dired\\'\" . dired-virtual-mode)
 741                               auto-mode-alist)\)"
 742   (interactive)
 743   (dired-virtual (dired-virtual-guess-dir)))
 744
 745 \f
 746 ;;; SMART SHELL.
 747
 748 ;;; An Emacs buffer can have but one working directory, stored in the
 749 ;;; buffer-local variable `default-directory'.  A Dired buffer may have
 750 ;;; several subdirectories inserted, but still has but one working directory:
 751 ;;; that of the top level Dired directory in that buffer.  For some commands
 752 ;;; it is appropriate that they use the current Dired directory instead of
 753 ;;; `default-directory', e.g., `find-file' and `compile'.  This is a general
 754 ;;; mechanism is provided for special handling of the working directory in
 755 ;;; special major modes.
 756
 757 ;; It's easier to add to this alist than redefine function
 758 ;; default-directory while keeping the old information.
 759 (defconst default-directory-alist
 760   '((dired-mode . (if (fboundp 'dired-current-directory)
 761                       (dired-current-directory)
 762                     default-directory)))
 763   "Alist of major modes and their opinion on `default-directory'.
 764 This is given as a Lisp expression to evaluate.  A resulting value of
 765 nil is ignored in favor of `default-directory'.")
 766
 767 (defun dired-default-directory ()
 768   "Usage like variable `default-directory'.
 769 Knows about the special cases in variable `default-directory-alist'."
 770   (or (eval (cdr (assq major-mode default-directory-alist)))
 771       default-directory))
 772
 773 (defun dired-smart-shell-command (cmd &optional insert)
 774   "Like function `shell-command', but in the current Virtual Dired directory."
 775   (interactive (list (read-from-minibuffer "Shell command: "
 776                                            nil nil nil 'shell-command-history)
 777                      current-prefix-arg))
 778   (let ((default-directory (dired-default-directory)))
 779     (shell-command cmd insert)))
 780
 781 \f
 782 ;;; LOCAL VARIABLES FOR DIRED BUFFERS.
 783
 784 ;;; Brief Description:
 785 ;;;
 786 ;;; * `dired-extra-startup' is part of the `dired-mode-hook'.
 787 ;;;
 788 ;;; * `dired-extra-startup' calls `dired-hack-local-variables'
 789 ;;;
 790 ;;; * `dired-hack-local-variables' checks the value of
 791 ;;;   `dired-local-variables-file'
 792 ;;;
 793 ;;; * Check if `dired-local-variables-file' is a non-nil string and is a
 794 ;;;   filename found in the directory of the Dired Buffer being created.
 795 ;;;
 796 ;;; * If `dired-local-variables-file' satisfies the above, then temporarily
 797 ;;;   include it in the Dired Buffer at the bottom.
 798 ;;;
 799 ;;; * Set `enable-local-variables' temporarily to the user variable
 800 ;;;   `dired-enable-local-variables' and run `hack-local-variables' on the
 801 ;;;   Dired Buffer.
 802
 803 (defvar dired-local-variables-file (convert-standard-filename ".dired")
 804   "Filename, as string, containing local dired buffer variables to be hacked.
 805 If this file found in current directory, then it will be inserted into dired
 806 buffer and `hack-local-variables' will be run.  See Info node
 807 `(emacs)File Variables' for more information on local variables.
 808 See also `dired-enable-local-variables'.")
 809
 810 (defun dired-hack-local-variables ()
 811   "Evaluate local variables in `dired-local-variables-file' for dired buffer."
 812   (if (and dired-local-variables-file
 813            (stringp dired-local-variables-file)
 814            (file-exists-p dired-local-variables-file))
 815       (let ((opoint (point-max))
 816             buffer-read-only
 817             ;; In case user has `enable-local-variables' set to nil we
 818             ;; override it locally with dired's variable.
 819             (enable-local-variables dired-enable-local-variables))
 820         ;; Insert 'em.
 821         (save-excursion
 822           (goto-char opoint)
 823           (insert "\^L\n")
 824           (insert-file-contents dired-local-variables-file))
 825         ;; Hack 'em.
 826         (let ((buffer-file-name dired-local-variables-file))
 827           (hack-local-variables))
 828         ;; Make sure that the modeline shows the proper information.
 829         (dired-sort-set-modeline)
 830         ;; Delete this stuff: `eobp' is used to find last subdir by dired.el.
 831         (delete-region opoint (point-max)))))
 832
 833 (defun dired-omit-here-always ()
 834   "Create `dired-local-variables-file' for omitting and reverts directory.
 835 Sets `dired-omit-mode' to t in a local variables file that is readable by
 836 dired."
 837   (interactive)
 838   (if (file-exists-p dired-local-variables-file)
 839       (message "File `./%s' already exists." dired-local-variables-file)
 840
 841     ;; Create `dired-local-variables-file'.
 842     (save-excursion
 843       (set-buffer (get-buffer-create " *dot-dired*"))
 844       (erase-buffer)
 845       (insert "Local Variables:\ndired-omit-mode: t\nEnd:\n")
 846       (write-file dired-local-variables-file)
 847       (kill-buffer (current-buffer)))
 848
 849     ;; Run extra-hooks and revert directory.
 850     (dired-extra-startup)
 851     (dired-revert)))
 852
 853 \f
 854 ;;; GUESS SHELL COMMAND.
 855
 856 ;;; Brief Description:
 857 ;;;
 858 ;;; `dired-do-shell-command' is bound to `!' by dired.el.
 859 ;;;
 860 ;;; * Redefine `dired-do-shell-command' so it calls
 861 ;;;   `dired-guess-shell-command'.
 862 ;;;
 863 ;;; * `dired-guess-shell-command' calls `dired-guess-default' with list of
 864 ;;;    marked files.
 865 ;;;
 866 ;;; * Parse `dired-guess-shell-alist-user' and
 867 ;;;   `dired-guess-shell-alist-default' (in that order) for the first REGEXP
 868 ;;;   that matches the first file in the file list.
 869 ;;;
 870 ;;; * If the REGEXP matches all the entries of the file list then evaluate
 871 ;;;   COMMAND, which is either a string or a Lisp expression returning a
 872 ;;;   string.  COMMAND may be a list of commands.
 873 ;;;
 874 ;;; * Return this command to `dired-guess-shell-command' which prompts user
 875 ;;;   with it.  The list of commands is temporarily put into the history list.
 876 ;;;   If a command is used successfully then it is stored permanently in
 877 ;;;   `dired-shell-command-history'.
 878
 879 ;;; Guess what shell command to apply to a file.
 880 (defvar dired-shell-command-history nil
 881   "History list for commands that read dired-shell commands.")
 882
 883 ;;; Default list of shell commands.
 884
 885 ;;; NOTE: Use `gunzip -c' instead of `zcat' on `.gz' files.  Some do not
 886 ;;; install GNU zip's version of zcat.
 887
 888 (defvar dired-guess-shell-alist-default
 889   (list
 890    (list "\\.tar$"
 891          '(if dired-guess-shell-gnutar
 892               (concat dired-guess-shell-gnutar " xvf")
 893             "tar xvf")
 894          ;; Extract files into a separate subdirectory
 895          '(if dired-guess-shell-gnutar
 896               (concat "mkdir " (file-name-sans-extension file)
 897                       "; " dired-guess-shell-gnutar " -C "
 898                       (file-name-sans-extension file) " -xvf")
 899             (concat "mkdir " (file-name-sans-extension file)
 900                     "; tar -C " (file-name-sans-extension file) " -xvf")))
 901
 902    ;; REGEXPS for compressed archives must come before the .Z rule to
 903    ;; be recognized:
 904    (list "\\.tar\\.Z$"
 905          ;; Untar it.
 906          '(if dired-guess-shell-gnutar
 907               (concat dired-guess-shell-gnutar " zxvf")
 908             (concat "zcat * | tar xvf -"))
 909          ;; Optional conversion to gzip format.
 910          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
 911                   " " dired-guess-shell-znew-switches))
 912
 913    ;; gzip'ed archives
 914    (list "\\.t\\(ar\\.\\)?gz$"
 915          '(if dired-guess-shell-gnutar
 916               (concat dired-guess-shell-gnutar " zxvf")
 917             (concat "gunzip -qc * | tar xvf -"))
 918          ;; Extract files into a separate subdirectory
 919          '(if dired-guess-shell-gnutar
 920               (concat "mkdir " (file-name-sans-extension file)
 921                       "; " dired-guess-shell-gnutar " -C "
 922                       (file-name-sans-extension file) " -zxvf")
 923             (concat "mkdir " (file-name-sans-extension file)
 924                     "; gunzip -qc * | tar -C "
 925                     (file-name-sans-extension file) " -xvf -"))
 926          ;; Optional decompression.
 927          '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q" "")))
 928
 929    ;; bzip2'ed archives
 930    (list "\\.t\\(ar\\.bz2\\|bz\\)$"
 931          "bunzip2 -c * | tar xvf -"
 932          ;; Extract files into a separate subdirectory
 933          '(concat "mkdir " (file-name-sans-extension file)
 934                   "; bunzip2 -c * | tar -C "
 935                   (file-name-sans-extension file) " -xvf -")
 936          ;; Optional decompression.
 937          "bunzip2")
 938
 939    '("\\.shar\\.Z$" "zcat * | unshar")
 940    '("\\.shar\\.g?z$" "gunzip -qc * | unshar")
 941
 942    '("\\.e?ps$" "ghostview" "xloadimage" "lpr")
 943    (list "\\.e?ps\\.g?z$" "gunzip -qc * | ghostview -"
 944          ;; Optional decompression.
 945          '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q")))
 946    (list "\\.e?ps\\.Z$" "zcat * | ghostview -"
 947          ;; Optional conversion to gzip format.
 948          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
 949                   " " dired-guess-shell-znew-switches))
 950
 951    '("\\.patch$" "cat * | patch")
 952    (list "\\.patch\\.g?z$" "gunzip -qc * | patch"
 953          ;; Optional decompression.
 954          '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q")))
 955    (list "\\.patch\\.Z$" "zcat * | patch"
 956          ;; Optional conversion to gzip format.
 957          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
 958                   " " dired-guess-shell-znew-switches))
 959
 960    ;; The following four extensions are useful with dired-man ("N" key)
 961    (list "\\.[0-9]$" '(progn (require 'man)
 962                              (if (Man-support-local-filenames)
 963                                  "man -l"
 964                                "cat * | tbl | nroff -man -h")))
 965    (list "\\.[0-9]\\.g?z$" '(progn (require 'man)
 966                                    (if (Man-support-local-filenames)
 967                                        "man -l"
 968                                      "gunzip -qc * | tbl | nroff -man -h"))
 969          ;; Optional decompression.
 970          '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q")))
 971    (list "\\.[0-9]\\.Z$" '(progn (require 'man)
 972                                  (if (Man-support-local-filenames)
 973                                      "man -l"
 974                                    "zcat * | tbl | nroff -man -h"))
 975          ;; Optional conversion to gzip format.
 976          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
 977                   " " dired-guess-shell-znew-switches))
 978    '("\\.pod$" "perldoc" "pod2man * | nroff -man")
 979
 980    '("\\.dvi$" "xdvi" "dvips")          ; preview and printing
 981    '("\\.au$" "play")                   ; play Sun audiofiles
 982    '("\\.mpg$" "mpeg_play")
 983    '("\\.uu$" "uudecode")               ; for uudecoded files
 984    '("\\.hqx$" "mcvert")
 985    '("\\.sh$" "sh")                     ; execute shell scripts
 986    '("\\.xbm$" "bitmap")                ; view X11 bitmaps
 987    '("\\.gp$" "gnuplot")
 988    '("\\.p[bgpn]m$" "xloadimage")
 989    '("\\.gif$" "xloadimage")                    ; view gif pictures
 990    '("\\.tif$" "xloadimage")
 991    '("\\.png$" "display")               ; xloadimage 4.1 doesn't grok PNG
 992    '("\\.jpe?g$" "xloadimage")
 993    '("\\.fig$" "xfig")                  ; edit fig pictures
 994    '("\\.out$" "xgraph")                ; for plotting purposes.
 995    '("\\.tex$" "latex" "tex")
 996    '("\\.texi\\(nfo\\)?$" "makeinfo" "texi2dvi")
 997    '("\\.pdf$" "xpdf")              ; edit PDF files
 998
 999    ;; Some other popular archivers.
1000    (list "\\.zip$" "unzip"
1001          ;; Extract files into a separate subdirectory
1002          '(concat "unzip" (if dired-guess-shell-gzip-quiet " -q")
1003                   " -d " (file-name-sans-extension file)))
1004    '("\\.zoo$" "zoo x//")
1005    '("\\.lzh$" "lharc x")
1006    '("\\.arc$" "arc x")
1007    '("\\.shar$" "unshar")
1008
1009    ;; Compression.
1010    (list "\\.g?z$" '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q")))
1011    (list "\\.dz$" "dictunzip")
1012    (list "\\.bz2$" "bunzip2")
1013    (list "\\.Z$" "uncompress"
1014          ;; Optional conversion to gzip format.
1015          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
1016                   " " dired-guess-shell-znew-switches))
1017    )
1018
1019   "Default alist used for shell command guessing.
1020 See `dired-guess-shell-alist-user'.")
1021
1022 (defcustom dired-guess-shell-alist-user nil
1023   "User-defined alist of rules for suggested commands.
1024 These rules take precedence over the predefined rules in the variable
1025 `dired-guess-shell-alist-default' (to which they are prepended).
1026
1027 Each element of this list looks like
1028
1029     \(REGEXP COMMAND...\)
1030
1031 where each COMMAND can either be a string or a Lisp expression that evaluates
1032 to a string.  If several COMMANDs are given, the first one will be the default
1033 and the rest will be added temporarily to the history and can be retrieved
1034 with \\[previous-history-element] (M-p) .
1035
1036 You can set this variable in your ~/.emacs.  For example, to add rules for
1037 `.foo' and `.bar' files, write
1038
1039  \(setq dired-guess-shell-alist-user
1040        (list (list \"\\\\.foo\\\\'\" \"FOO-COMMAND\");; fixed rule
1041               ;; possibly more rules ...
1042               (list \"\\\\.bar\\\'\";; rule with condition test
1043                     '(if condition
1044                           \"BAR-COMMAND-1\"
1045                         \"BAR-COMMAND-2\")))\)"
1046   :group 'dired-x
1047   :type '(alist :key-type regexp :value-type (repeat sexp)))
1048
1049 (defcustom dired-guess-shell-case-fold-search t
1050   "If non-nil, `dired-guess-shell-alist-default' and
1051 `dired-guess-shell-alist-user' are matched case-insensitively."
1052   :group 'dired-x
1053   :type 'boolean)
1054
1055 (defun dired-guess-default (files)
1056   "Guess a shell commands for FILES.  Return command or list of commands.
1057 See `dired-guess-shell-alist-user'."
1058
1059   (let* ((case-fold-search dired-guess-shell-case-fold-search)
1060          ;; Prepend the user's alist to the default alist.
1061          (alist (append dired-guess-shell-alist-user
1062                         dired-guess-shell-alist-default))
1063          (file (car files))
1064          (flist (cdr files))
1065          elt regexp cmds)
1066
1067     ;; Find the first match in the alist for first file in FILES.
1068     (while alist
1069       (setq elt (car alist)
1070             regexp (car elt)
1071             alist (cdr alist))
1072       (if (string-match regexp file)
1073           (setq cmds (cdr elt)
1074                 alist nil)))
1075
1076     ;; If more than one file, see if all of FILES match regular expression.
1077     (while (and flist
1078                 (string-match regexp (car flist)))
1079       (setq flist (cdr flist)))
1080
1081     ;; If flist is still non-nil, then do not guess since this means that not
1082     ;; all the files in FILES were matched by the regexp.
1083     (setq cmds (and (not flist) cmds))
1084
1085     ;; Return commands or nil if flist is still non-nil.
1086     ;; Evaluate the commands in order that any logical testing will be done.
1087     (cond ((not (cdr cmds))
1088            (eval (car cmds))) ; single command
1089           (t
1090            (mapcar (function eval) cmds)))))
1091
1092 (defun dired-guess-shell-command (prompt files)
1093   "Ask user with PROMPT for a shell command, guessing a default from FILES."
1094
1095   (let ((default (dired-guess-default files))
1096         default-list old-history val (failed t))
1097
1098     (if (null default)
1099         ;; Nothing to guess
1100         (read-from-minibuffer prompt nil nil nil 'dired-shell-command-history)
1101
1102       ;; Save current history list
1103       (setq old-history dired-shell-command-history)
1104
1105       (if (listp default)
1106
1107           ;; More than one guess
1108           (setq default-list default
1109                 default (car default)
1110                 prompt (concat
1111                         prompt
1112                         (format "{%d guesses} " (length default-list))))
1113
1114         ;; Just one guess
1115         (setq default-list (list default)))
1116
1117       ;; Push all guesses onto history so that they can be retrieved with M-p
1118       ;; and put the first guess in the prompt but not in the initial value.
1119       (setq dired-shell-command-history
1120             (append default-list dired-shell-command-history)
1121             prompt (concat prompt (format "[%s] " default)))
1122
1123       ;; The unwind-protect returns VAL, and we too.
1124       (unwind-protect
1125           ;; BODYFORM
1126           (progn
1127             (setq val (read-from-minibuffer prompt nil nil nil
1128                                             'dired-shell-command-history)
1129                   failed nil)
1130             ;; If we got a return, then use default.
1131             (if (equal val "")
1132                 (setq val default))
1133             val)
1134
1135         ;; UNWINDFORMS
1136         ;; Undo pushing onto the history list so that an aborted
1137         ;; command doesn't get the default in the next command.
1138         (setq dired-shell-command-history old-history)
1139         (if (not failed)
1140             (or (equal val (car-safe dired-shell-command-history))
1141                 (setq dired-shell-command-history
1142                       (cons val dired-shell-command-history))))))))
1143
1144
1145 ;;; REDEFINE.
1146 ;;; Redefine dired-aux.el's version:
1147 (defun dired-read-shell-command (prompt arg files)
1148   "Read a dired shell command prompting with PROMPT (using read-string).
1149 ARG is the prefix arg and may be used to indicate in the prompt which
1150   files are affected.
1151 This is an extra function so that you can redefine it."
1152   (dired-mark-pop-up
1153    nil 'shell files
1154    'dired-guess-shell-command
1155    (format prompt (dired-mark-prompt arg files)) ; PROMPT
1156    files))                                       ; FILES
1157
1158 \f
1159 ;;; RELATIVE SYMBOLIC LINKS.
1160
1161 (defvar dired-keep-marker-relsymlink ?S
1162   "See variable `dired-keep-marker-move'.")
1163
1164 (defun dired-make-relative-symlink (file1 file2 &optional ok-if-already-exists)
1165   "Make a symbolic link (pointing to FILE1) in FILE2.
1166 The link is relative (if possible), for example
1167
1168     \"/vol/tex/bin/foo\" \"/vol/local/bin/foo\"
1169
1170 results in
1171
1172     \"../../tex/bin/foo\" \"/vol/local/bin/foo\""
1173   (interactive "FRelSymLink: \nFRelSymLink %s: \np")
1174   (let (name1 name2 len1 len2 (index 0) sub)
1175     (setq file1 (expand-file-name file1)
1176           file2 (expand-file-name file2)
1177           len1 (length file1)
1178           len2 (length file2))
1179     ;; Find common initial file name components:
1180     (let (next)
1181       (while (and (setq next (string-match "/" file1 index))
1182                   (setq next (1+ next))
1183                   (< next (min len1 len2))
1184                   ;; For the comparison, both substrings must end in
1185                   ;; `/', so NEXT is *one plus* the result of the
1186                   ;; string-match.
1187                   ;; E.g., consider the case of linking "/tmp/a/abc"
1188                   ;; to "/tmp/abc" erroneously giving "/tmp/a" instead
1189                   ;; of "/tmp/" as common initial component
1190                   (string-equal (substring file1 0 next)
1191                                 (substring file2 0 next)))
1192         (setq index next))
1193       (setq name2 file2
1194             sub (substring file1 0 index)
1195             name1 (substring file1 index)))
1196     (if (string-equal sub "/")
1197         ;; No common initial file name found
1198         (setq name1 file1)
1199       ;; Else they have a common parent directory
1200       (let ((tem (substring file2 index))
1201             (start 0)
1202             (count 0))
1203         ;; Count number of slashes we must compensate for ...
1204         (while (setq start (string-match "/" tem start))
1205           (setq count (1+ count)
1206                 start (1+ start)))
1207         ;; ... and prepend a "../" for each slash found:
1208         (while (> count 0)
1209           (setq count (1- count)
1210                 name1 (concat "../" name1)))))
1211     (make-symbolic-link
1212      (directory-file-name name1)        ; must not link to foo/
1213                                         ; (trailing slash!)
1214      name2 ok-if-already-exists)))
1215
1216 (defun dired-do-relsymlink (&optional arg)
1217    "Relative symlink all marked (or next ARG) files into a directory.
1218 Otherwise make a relative symbolic link to the current file.
1219 This creates relative symbolic links like
1220
1221     foo -> ../bar/foo
1222
1223 not absolute ones like
1224
1225     foo -> /ugly/file/name/that/may/change/any/day/bar/foo"
1226   (interactive "P")
1227   (dired-do-create-files 'relsymlink (function dired-make-relative-symlink)
1228                            "RelSymLink" arg dired-keep-marker-relsymlink))
1229
1230 (defun dired-do-relsymlink-regexp (regexp newname &optional arg whole-name)
1231   "RelSymlink all marked files containing REGEXP to NEWNAME.
1232 See functions `dired-do-rename-regexp' and `dired-do-relsymlink'
1233 for more info."
1234   (interactive (dired-mark-read-regexp "RelSymLink"))
1235   (dired-do-create-files-regexp
1236    (function dired-make-relative-symlink)
1237    "RelSymLink" arg regexp newname whole-name dired-keep-marker-relsymlink))
1238
1239 \f
1240 ;;; VISIT ALL MARKED FILES SIMULTANEOUSLY.
1241
1242 ;;; Brief Description:
1243 ;;;
1244 ;;; `dired-do-find-marked-files' is bound to `F' by dired-x.el.
1245 ;;;
1246 ;;; * Use `dired-get-marked-files' to collect the marked files in the current
1247 ;;;   Dired Buffer into a list of filenames `FILE-LIST'.
1248 ;;;
1249 ;;; * Pass FILE-LIST to `dired-simultaneous-find-file' all with
1250 ;;;   `dired-do-find-marked-files''s prefix argument NOSELECT.
1251 ;;;
1252 ;;; * `dired-simultaneous-find-file' runs through FILE-LIST decrementing the
1253 ;;;   list each time.
1254 ;;;
1255 ;;; * If NOSELECT is non-nil then just run `find-file-noselect'  on each
1256 ;;;   element of FILE-LIST.
1257 ;;;
1258 ;;; * If NOSELECT is nil then calculate the `size' of the window for each file
1259 ;;;   by dividing the `window-height' by length of FILE-LIST.  Thus, `size' is
1260 ;;;   cognizant of the window-configuration.
1261 ;;;
1262 ;;; * If `size' is too small abort, otherwise run `find-file' on each element
1263 ;;;   of FILE-LIST giving each a window of height `size'.
1264
1265 (defun dired-do-find-marked-files (&optional noselect)
1266   "Find all marked files displaying all of them simultaneously.
1267 With optional NOSELECT just find files but do not select them.
1268
1269 The current window is split across all files marked, as evenly as possible.
1270 Remaining lines go to bottom-most window.  The number of files that can be
1271 displayed this way is restricted by the height of the current window and
1272 `window-min-height'.
1273
1274 To keep dired buffer displayed, type \\[split-window-vertically] first.
1275 To display just marked files, type \\[delete-other-windows] first."
1276
1277   (interactive "P")
1278   (dired-simultaneous-find-file (dired-get-marked-files) noselect))
1279
1280 (defun dired-simultaneous-find-file (file-list noselect)
1281
1282   "Visit all files in FILE-LIST and display them simultaneously.
1283 The current window is split across all files in FILE-LIST, as evenly as
1284 possible.  Remaining lines go to the bottom-most window.  The number of
1285 files that can be displayed this way is restricted by the height of the
1286 current window and the variable `window-min-height'.  With non-nil
1287 NOSELECT the files are merely found but not selected."
1288
1289   ;; We don't make this function interactive because it is usually too clumsy
1290   ;; to specify FILE-LIST interactively unless via dired.
1291
1292   (let (size)
1293
1294     (if noselect
1295         ;; Do not select the buffer.
1296         (find-file-noselect (car file-list))
1297
1298       ;; We will have to select the buffer.  Calculate and check window size.
1299       (setq size (/ (window-height) (length file-list)))
1300       (or (<= window-min-height size)
1301           (error "Too many files to visit simultaneously.  Try C-u prefix"))
1302       (find-file (car file-list)))
1303
1304     ;; Decrement.
1305     (setq file-list (cdr file-list))
1306
1307     (while file-list
1308
1309       (if noselect
1310           ;; Do not select the buffer.
1311           (find-file-noselect (car file-list))
1312
1313         ;; Vertically split off a window of desired size.  Upper window will
1314         ;; have SIZE lines.  Select lower (larger) window.  We split it again.
1315         (select-window (split-window nil size))
1316         (find-file (car file-list)))
1317
1318       ;; Decrement.
1319       (setq file-list (cdr file-list)))))
1320
1321 \f
1322 ;;; MISCELLANEOUS COMMANDS.
1323
1324 ;;; Run man on files.
1325
1326 (defun dired-man ()
1327   "Run man on this file.  Display old buffer if buffer name matches filename.
1328 Uses `man.el' of \\[manual-entry] fame."
1329   (interactive)
1330   (require 'man)
1331   (let* ((file (dired-get-filename))
1332          (manual-program (replace-regexp-in-string "\\*" "%s"
1333                           (dired-guess-shell-command
1334                            "Man command: " (list file)))))
1335     (Man-getpage-in-background file)))
1336
1337 ;;; Run Info on files.
1338
1339 (defun dired-info ()
1340   "Run info on this file."
1341   (interactive)
1342   (info (dired-get-filename)))
1343
1344 ;;; Run mail on mail folders.
1345
1346 ;;; (and (not (fboundp 'vm-visit-folder))
1347 ;;;      (defun vm-visit-folder (file &optional arg)
1348 ;;;        nil))
1349
1350 (defun dired-vm (&optional read-only)
1351   "Run VM on this file.
1352 With prefix arg, visit folder read-only (this requires at least VM 5).
1353 See also variable `dired-vm-read-only-folders'."
1354   (interactive "P")
1355   (let ((dir (dired-current-directory))
1356         (fil (dired-get-filename)))
1357     ;; take care to supply 2nd arg only if requested - may still run VM 4!
1358     (cond (read-only (vm-visit-folder fil t))
1359           ((eq t dired-vm-read-only-folders) (vm-visit-folder fil t))
1360           ((null dired-vm-read-only-folders) (vm-visit-folder fil))
1361           (t (vm-visit-folder fil (not (file-writable-p fil)))))
1362     ;; so that pressing `v' inside VM does prompt within current directory:
1363     (set (make-local-variable 'vm-folder-directory) dir)))
1364
1365 (defun dired-rmail ()
1366   "Run RMAIL on this file."
1367   (interactive)
1368   (rmail (dired-get-filename)))
1369
1370 (defun dired-do-run-mail ()
1371   "If `dired-bind-vm' is t, then function `dired-vm', otherwise `dired-rmail'."
1372   (interactive)
1373   (if dired-bind-vm
1374       ;; Read mail folder using vm.
1375       (dired-vm)
1376     ;; Read mail folder using rmail.
1377     (dired-rmail)))
1378
1379 \f
1380 ;;; MISCELLANEOUS INTERNAL FUNCTIONS.
1381
1382 (or (fboundp 'dired-old-find-buffer-nocreate)
1383     (fset 'dired-old-find-buffer-nocreate
1384           (symbol-function 'dired-find-buffer-nocreate)))
1385
1386 ;;; REDEFINE.
1387 ;;; Redefines dired.el's version of `dired-find-buffer-nocreate'
1388 (defun dired-find-buffer-nocreate (dirname &optional mode)
1389   (if (and dired-find-subdir
1390            ;; don't try to find a wildcard as a subdirectory
1391            (string-equal dirname (file-name-directory dirname)))
1392       (let* ((cur-buf (current-buffer))
1393              (buffers (nreverse
1394                        (dired-buffers-for-dir (expand-file-name dirname))))
1395              (cur-buf-matches (and (memq cur-buf buffers)
1396                                    ;; wildcards must match, too:
1397                                    (equal dired-directory dirname))))
1398         ;; We don't want to switch to the same buffer---
1399         (setq buffers (delq cur-buf buffers));;need setq with delq
1400         (or (car (sort buffers (function dired-buffer-more-recently-used-p)))
1401             ;; ---unless it's the only possibility:
1402             (and cur-buf-matches cur-buf)))
1403     (dired-old-find-buffer-nocreate dirname mode)))
1404
1405 ;; This should be a builtin
1406 (defun dired-buffer-more-recently-used-p (buffer1 buffer2)
1407   "Return t if BUFFER1 is more recently used than BUFFER2."
1408   (if (equal buffer1 buffer2)
1409       nil
1410     (let ((more-recent nil)
1411           (list (buffer-list)))
1412       (while (and list
1413                   (not (setq more-recent (equal buffer1 (car list))))
1414                   (not (equal buffer2 (car list))))
1415         (setq list (cdr list)))
1416       more-recent)))
1417
1418 ;;; Same thing as `dired-buffers-for-dir' of dired.el? - lrd 11/23/93
1419 ;;; (defun dired-buffers-for-dir-exact (dir)
1420 ;;; ;; Return a list of buffers that dired DIR (a directory or wildcard)
1421 ;;; ;; at top level, or as subdirectory.
1422 ;;; ;; Top level matches must match the wildcard part too, if any.
1423 ;;; ;; The list is in reverse order of buffer creation, most recent last.
1424 ;;; ;; As a side effect, killed dired buffers for DIR are removed from
1425 ;;; ;; dired-buffers.
1426 ;;;   (let ((alist dired-buffers) result elt)
1427 ;;;     (while alist
1428 ;;;       (setq elt (car alist)
1429 ;;;             alist (cdr alist))
1430 ;;;       (let ((buf (cdr elt)))
1431 ;;;         (if (buffer-name buf)
1432 ;;;             ;; Top level must match exactly against dired-directory in
1433 ;;;             ;; case one of them is a wildcard.
1434 ;;;             (if (or (equal dir (save-excursion (set-buffer buf)
1435 ;;;                                                dired-directory))
1436 ;;;                     (assoc dir (save-excursion (set-buffer buf)
1437 ;;;                                                dired-subdir-alist)))
1438 ;;;                 (setq result (cons buf result)))
1439 ;;;           ;; else buffer is killed - clean up:
1440 ;;;           (setq dired-buffers (delq elt dired-buffers)))))
1441 ;;;     result))
1442
1443 ;;; REDEFINE.
1444 ;;; Redefines dired.el's version of `dired-initial-position'
1445 (defun dired-initial-position (dirname)
1446   "Where point should go in a new listing of DIRNAME.
1447 Point assumed at beginning of new subdir line.
1448 You may redefine this function as you wish, e.g. like in `dired-x.el'."
1449   (end-of-line)
1450   (if dired-find-subdir (dired-goto-subdir dirname)) ; new
1451   (if dired-trivial-filenames (dired-goto-next-nontrivial-file)))
1452
1453 \f
1454 ;; Does anyone use this? - lrd 6/29/93.
1455 ;; Apparently people do use it. - lrd 12/22/97.
1456 (defun dired-mark-sexp (predicate &optional unflag-p)
1457   "Mark files for which PREDICATE returns non-nil.
1458 With a prefix arg, unflag those files instead.
1459
1460 PREDICATE is a lisp expression that can refer to the following symbols:
1461
1462     inode  [integer] the inode of the file (only for ls -i output)
1463     s      [integer] the size of the file for ls -s output
1464                      (usually in blocks or, with -k, in KByte)
1465     mode   [string]  file permission bits, e.g. \"-rw-r--r--\"
1466     nlink  [integer] number of links to file
1467     uid    [string]  owner
1468     gid    [string]  group  (If the gid is not displayed by ls,
1469                      this will still be set (to the same as uid))
1470     size   [integer] file size in bytes
1471     time   [string]  the time that ls displays, e.g. \"Feb 12 14:17\"
1472     name   [string]  the name of the file
1473     sym    [string]  if file is a symbolic link, the linked-to name, else \"\"
1474
1475 For example, use
1476
1477         (equal 0 size)
1478
1479 to mark all zero length files."
1480   ;; Using sym="" instead of nil avoids the trap of
1481   ;; (string-match "foo" sym) into which a user would soon fall.
1482   ;; Give `equal' instead of `=' in the example, as this works on
1483   ;; integers and strings.
1484   (interactive "xMark if (lisp expr): \nP")
1485   (message "%s" predicate)
1486   (let ((dired-marker-char (if unflag-p ?\040 dired-marker-char))
1487         inode s mode nlink uid gid size time name sym)
1488     (dired-mark-if
1489      (save-excursion
1490        (and
1491         ;; Sets vars
1492         ;;                inode s mode nlink uid gid size time name sym
1493
1494         ;; according to current file line.  Returns t for success, nil if
1495         ;; there is no file line.  Upon success, all variables are set, either
1496         ;; to nil or the appropriate value, so they need not be initialized.
1497         ;; Moves point within the current line.
1498         (if (dired-move-to-filename)
1499             (let (pos
1500                   (mode-len 10) ; length of mode string
1501                   ;; like in dired.el, but with subexpressions \1=inode, \2=s:
1502                   (dired-re-inode-size "\\s *\\([0-9]*\\)\\s *\\([0-9]*\\) ?"))
1503               (beginning-of-line)
1504               (forward-char 2)
1505               (if (looking-at dired-re-inode-size)
1506                   (progn
1507                     (goto-char (match-end 0))
1508                     (setq inode (string-to-number (buffer-substring (match-beginning 1)
1509                                                                     (match-end 1)))
1510                           s (string-to-number (buffer-substring (match-beginning 2)
1511                                                                 (match-end 2)))))
1512                 (setq inode nil
1513                       s nil))
1514               (setq mode (buffer-substring (point) (+ mode-len (point))))
1515               (forward-char mode-len)
1516               (setq nlink (read (current-buffer)))
1517               ;; Karsten Wenger <kw@cis.uni-muenchen.de> fixed uid.
1518               (setq uid (buffer-substring (+ (point) 1)
1519                                           (progn (forward-word 1) (point))))
1520               (re-search-forward dired-move-to-filename-regexp)
1521               (goto-char (match-beginning 1))
1522               (forward-char -1)
1523               (setq size (string-to-number (buffer-substring (save-excursion
1524                                                                (backward-word 1)
1525                                                                (setq pos (point)))
1526                                                              (point))))
1527               (goto-char pos)
1528               (backward-word 1)
1529               ;; if no gid is displayed, gid will be set to uid
1530               ;; but user will then not reference it anyway in PREDICATE.
1531               (setq gid (buffer-substring (save-excursion
1532                                             (forward-word 1) (point))
1533                                           (point))
1534                     time (buffer-substring (match-beginning 1)
1535                                            (1- (dired-move-to-filename)))
1536                     name (buffer-substring (point)
1537                                            (or
1538                                             (dired-move-to-end-of-filename t)
1539                                             (point)))
1540                     sym  (progn
1541                            (if (looking-at " -> ")
1542                                (buffer-substring
1543                                 (progn (forward-char 4) (point))
1544                                 (progn (end-of-line) (point)))
1545                              "")))
1546               t)
1547           nil)
1548                       (eval predicate)))
1549      (format "'%s file" predicate))))
1550
1551 \f
1552 ;;; FIND FILE AT POINT.
1553
1554 (defvar dired-x-hands-off-my-keys t
1555   "*Non-nil means don't bind `dired-x-find-file' over `find-file' on keyboard.
1556 Similarly for `dired-x-find-file-other-window' over `find-file-other-window'.
1557 If you change this variable after `dired-x.el' is loaded then do
1558 \\[dired-x-bind-find-file].")
1559
1560 ;;; Bind `dired-x-find-file{-other-window}' over wherever
1561 ;;; `find-file{-other-window}' is bound?
1562 (defun dired-x-bind-find-file ()
1563   "Bind `dired-x-find-file' in place of `find-file' \(or reverse\).
1564 Similarly for `dired-x-find-file-other-window' and `find-file-other-window'.
1565 Binding direction based on `dired-x-hands-off-my-keys'.
1566 This function is part of `after-init-hook'."
1567   (interactive)
1568   (if (interactive-p)
1569       (setq dired-x-hands-off-my-keys
1570             (not (y-or-n-p "Bind dired-x-find-file over find-file? "))))
1571   (cond ((not dired-x-hands-off-my-keys)
1572          (substitute-key-definition 'find-file
1573                                     'dired-x-find-file
1574                                     (current-global-map))
1575          (substitute-key-definition 'find-file-other-window
1576                                     'dired-x-find-file-other-window
1577                                     (current-global-map)))
1578         (t
1579          (substitute-key-definition 'dired-x-find-file
1580                                     'find-file
1581                                     (current-global-map))
1582          (substitute-key-definition 'dired-x-find-file-other-window
1583                                     'find-file-other-window
1584                                     (current-global-map))))
1585   ;; Clear mini-buffer.
1586   (message nil))
1587
1588 ;;; Now call it so binding is correct and put on `after-init-hook' in case
1589 ;;; user changes binding.
1590 (dired-x-bind-find-file)
1591 (add-hook 'after-init-hook 'dired-x-bind-find-file)
1592
1593 (defun dired-x-find-file (filename)
1594   "Edit file FILENAME.
1595 May create a new window, or reuse an existing one.
1596 See the function `display-buffer'.
1597
1598 Identical to `find-file' except when called interactively, with a prefix arg
1599 \(e.g., \\[universal-argument]\), in which case it guesses filename near point.
1600 Useful for editing file mentioned in buffer you are viewing,
1601 or to test if that file exists.  Use minibuffer after snatching filename."
1602   (interactive (list (read-filename-at-point "Find file: ")))
1603   (find-file (expand-file-name filename)))
1604
1605 (defun dired-x-find-file-other-window (filename)
1606   "Edit file FILENAME, in another window.
1607 May create a new window, or reuse an existing one.
1608 See the function `display-buffer'.
1609
1610 Identical to `find-file-other-window' except when called interactively, with a
1611 prefix arg \(e.g., \\[universal-argument]\), in which case it guesses filename near point.
1612 Useful for editing file mentioned in buffer you are viewing,
1613 or to test if that file exists.  Use minibuffer after snatching filename."
1614   (interactive (list (read-filename-at-point "Find file: ")))
1615   (find-file-other-window (expand-file-name filename)))
1616
1617 ;;; Internal functions.
1618
1619 ;; Fixme: This should probably use `thing-at-point'.  -- fx
1620 (defun dired-filename-at-point ()
1621   "Get the filename closest to point, but do not change position.
1622 Has a preference for looking backward when not directly on a symbol.  Not
1623 perfect - point must be in middle of or end of filename."
1624
1625   (let ((filename-chars "-.[:alnum:]_/:$+@")
1626         start end filename prefix)
1627
1628     (save-excursion
1629       ;; First see if just past a filename.
1630       (if (not (eobp))
1631           (if (looking-at "[] \t\n[{}()]") ; whitespace or some parens
1632               (progn
1633                 (skip-chars-backward " \n\t\r({[]})")
1634                 (if (not (bobp))
1635                     (backward-char 1)))))
1636
1637       (if (string-match (concat "[" filename-chars "]")
1638                         (char-to-string (following-char)))
1639           (progn
1640             (if (re-search-backward (concat "[^" filename-chars "]") nil t)
1641                 (forward-char)
1642               (goto-char (point-min)))
1643             (setq start (point))
1644             (setq prefix
1645                   (and (string-match
1646                         "^\\w+@"
1647                         (buffer-substring start (line-beginning-position)))
1648                        "/"))
1649             (goto-char start)
1650             (if (string-match "[/~]" (char-to-string (preceding-char)))
1651                 (setq start (1- start)))
1652             (re-search-forward (concat "\\=[" filename-chars "]*") nil t))
1653
1654         (error "No file found around point!"))
1655
1656       ;; Return string.
1657       (expand-file-name (concat prefix (buffer-substring start (point)))))))
1658
1659 (defun read-filename-at-point (prompt)
1660   "Return filename prompting with PROMPT with completion.
1661 If `current-prefix-arg' is non-nil, uses name at point as guess."
1662   (if current-prefix-arg
1663       (let ((guess (dired-filename-at-point)))
1664         (read-file-name prompt
1665                         (file-name-directory guess)
1666                         guess
1667                         nil (file-name-nondirectory guess)))
1668     (read-file-name prompt default-directory)))
1669 \f
1670 ;;; BUG REPORTS
1671
1672 ;; Fixme: get rid of this later.
1673
1674 ;;; This section is provided for reports.  It uses Barry A. Warsaw's
1675 ;;; reporter.el which is bundled with GNU Emacs v19.
1676
1677 (defconst dired-x-help-address "bug-gnu-emacs@gnu.org"
1678   "Address(es) accepting submission of reports on dired-x.el.")
1679
1680 (defconst dired-x-variable-list
1681   (list
1682    'dired-bind-vm
1683    'dired-vm-read-only-folders
1684    'dired-bind-jump
1685    'dired-bind-info
1686    'dired-bind-man
1687    'dired-find-subdir
1688    'dired-enable-local-variables
1689    'dired-local-variables-file
1690    'dired-guess-shell-gnutar
1691    'dired-guess-shell-gzip-quiet
1692    'dired-guess-shell-znew-switches
1693    'dired-guess-shell-alist-user
1694    'dired-clean-up-buffers-too
1695    'dired-omit-mode
1696    'dired-omit-files
1697    'dired-omit-extensions
1698    )
1699   "List of variables to be appended to reports sent by `dired-x-submit-report'.")
1700
1701 (defun dired-x-submit-report ()
1702   "Submit via `reporter.el' a bug report on program.
1703 Send report on `dired-x-file' version `dired-x-version,' to
1704 `dired-x-maintainer' at address `dired-x-help-address' listing
1705 variables `dired-x-variable-list' in the message."
1706   (interactive)
1707
1708   (reporter-submit-bug-report
1709    dired-x-help-address                 ; address
1710    "dired-x"                            ; pkgname
1711    dired-x-variable-list                ; varlist
1712    nil nil                              ; pre-/post-hooks
1713    ""))
1714
1715 \f
1716 ;; As Barry Warsaw would say: "This might be useful..."
1717 (provide 'dired-x)
1718
1719 ;;; arch-tag: 71a43ba2-7a00-4793-a028-0613dd7765ae
1720 ;;; dired-x.el ends here