code.delx.au - gnu-emacs/blob - lisp/dired-x.el

   1 ;;; dired-x.el --- extra Dired functionality -*-byte-compile-dynamic: t;-*-
   2
   3 ;; Author: Sebastian Kremer <sk@thp.uni-koeln.de>
   4 ;;      Lawrence R. Dodd <dodd@roebling.poly.edu>
   5 ;; Maintainer: nobody (want to volunteer?)
   6 ;; Version: 2.37+
   7 ;; Date: 1994/08/18 19:27:42
   8 ;; Keywords: dired extensions files
   9
  10 ;; Copyright (C) 1993, 1994, 1997, 2001, 2002, 2003, 2004,
  11 ;;   2005 Free Software Foundation, Inc.
  12
  13 ;; This file is part of GNU Emacs.
  14
  15 ;; GNU Emacs is free software; you can redistribute it and/or modify
  16 ;; it under the terms of the GNU General Public License as published by
  17 ;; the Free Software Foundation; either version 2, or (at your option)
  18 ;; any later version.
  19
  20 ;; GNU Emacs is distributed in the hope that it will be useful,
  21 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  22 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  23 ;; GNU General Public License for more details.
  24
  25 ;; You should have received a copy of the GNU General Public License
  26 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  27 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  28 ;; Boston, MA 02110-1301, USA.
  29
  30 ;;; Commentary:
  31
  32 ;; This is Sebastian Kremer's excellent dired-x.el (Dired Extra), version
  33 ;; 1.191, hacked up for GNU Emacs.  Redundant or conflicting material has
  34 ;; been removed or renamed in order to work properly with dired of GNU
  35 ;; Emacs.  All suggestions or comments are most welcomed.
  36
  37 ;;
  38 ;; Please, PLEASE, *PLEASE* see the info pages.
  39 ;;
  40
  41 ;; BUGS: Type M-x dired-x-submit-report and a report will be generated.
  42
  43 ;; INSTALLATION: In your ~/.emacs,
  44 ;;
  45 ;; (add-hook 'dired-load-hook
  46 ;;           (function (lambda ()
  47 ;;                       (load "dired-x")
  48 ;;                       ;; Set global variables here.  For example:
  49 ;;                       ;; (setq dired-guess-shell-gnutar "gtar")
  50 ;;                       )))
  51 ;; (add-hook 'dired-mode-hook
  52 ;;           (function (lambda ()
  53 ;;                       ;; Set buffer-local variables here.  For example:
  54 ;;                       ;; (dired-omit-mode 1)
  55 ;;                       )))
  56 ;;
  57 ;; At load time dired-x.el will install itself, redefine some functions, and
  58 ;; bind some dired keys.  *Please* see the info pages for more details.
  59
  60 ;; *Please* see the info pages for more details.
  61
  62 ;; User defined variables:
  63 ;;
  64 ;;      dired-bind-vm
  65 ;;      dired-vm-read-only-folders
  66 ;;      dired-bind-jump
  67 ;;      dired-bind-info
  68 ;;      dired-bind-man
  69 ;;      dired-x-hands-off-my-keys
  70 ;;      dired-find-subdir
  71 ;;      dired-enable-local-variables
  72 ;;      dired-local-variables-file
  73 ;;      dired-guess-shell-gnutar
  74 ;;      dired-guess-shell-gzip-quiet
  75 ;;      dired-guess-shell-znew-switches
  76 ;;      dired-guess-shell-alist-user
  77 ;;      dired-clean-up-buffers-too
  78 ;;      dired-omit-mode
  79 ;;      dired-omit-files
  80 ;;      dired-omit-extensions
  81 ;;      dired-omit-size-limit
  82 ;;
  83 ;; To find out more about these variables, load this file, put your cursor at
  84 ;; the end of any of the variable names, and hit C-h v [RET].  *Please* see
  85 ;; the info pages for more details.
  86
  87 ;; When loaded this code redefines the following functions of GNU Emacs
  88 ;;
  89 ;;   Function                         Found in this file of GNU Emacs
  90 ;;   --------                         -------------------------------
  91 ;;   dired-clean-up-after-deletion    ../lisp/dired.el
  92 ;;   dired-find-buffer-nocreate       ../lisp/dired.el
  93 ;;   dired-initial-position           ../lisp/dired.el
  94 ;;
  95 ;;   dired-add-entry                  ../lisp/dired-aux.el
  96 ;;   dired-read-shell-command         ../lisp/dired-aux.el
  97
  98 \f
  99 ;;; Code:
 100
 101 ;; LOAD.
 102
 103 ;; This is a no-op if dired-x is being loaded via `dired-load-hook'.  It is
 104 ;; here in case the user has autoloaded dired-x via the dired-jump key binding
 105 ;; (instead of autoloading to dired as is suggested in the info-pages).
 106
 107 (require 'dired)
 108
 109 ;; We will redefine some functions and also need some macros so we need to
 110 ;; load dired stuff of GNU Emacs.
 111
 112 (require 'dired-aux)
 113
 114 ;;; User-defined variables.
 115
 116 (defgroup dired-x nil
 117   "Extended directory editing (dired-x)."
 118   :group 'dired)
 119
 120 (defgroup dired-keys nil
 121   "Dired keys customizations."
 122   :prefix "dired-"
 123   :group 'dired-x)
 124
 125 (defcustom dired-bind-vm nil
 126   "*Non-nil means \"V\" runs `dired-vm', otherwise \"V\" runs `dired-rmail'.
 127 Also, RMAIL files contain -*- rmail -*- at the top so \"f\",
 128 `dired-advertised-find-file', will run rmail."
 129   :type 'boolean
 130   :group 'dired-keys)
 131
 132 (defcustom dired-bind-jump t
 133   "*Non-nil means bind `dired-jump' to C-x C-j, otherwise do not."
 134   :type 'boolean
 135   :group 'dired-keys)
 136
 137 (defcustom dired-bind-man t
 138   "*Non-nil means bind `dired-man' to \"N\" in dired-mode, otherwise do not."
 139   :type 'boolean
 140   :group 'dired-keys)
 141
 142 (defcustom dired-bind-info t
 143   "*Non-nil means bind `dired-info' to \"I\" in dired-mode, otherwise do not."
 144   :type 'boolean
 145   :group 'dired-keys)
 146
 147 (defcustom dired-vm-read-only-folders nil
 148   "*If non-nil, \\[dired-vm] will visit all folders read-only.
 149 If neither nil nor t, e.g. the symbol `if-file-read-only', only
 150 files not writable by you are visited read-only.
 151
 152 Read-only folders only work in VM 5, not in VM 4."
 153   :type '(choice (const :tag "off" nil)
 154                  (const :tag "on" t)
 155                  (other :tag "non-writable only" if-file-read-only))
 156   :group 'dired-x)
 157
 158 (define-minor-mode dired-omit-mode
 159   "Toggle Dired-Omit mode.
 160 With numeric ARG, enable Dired-Omit mode if ARG is positive, disable
 161 otherwise.  Enabling and disabling is buffer-local.
 162 If enabled, \"uninteresting\" files are not listed.
 163 Uninteresting files are those whose filenames match regexp `dired-omit-files',
 164 plus those ending with extensions in `dired-omit-extensions'."
 165   :group 'dired-x
 166   (if dired-omit-mode
 167       ;; This will mention how many lines were omitted:
 168       (let ((dired-omit-size-limit nil)) (dired-omit-expunge))
 169     (revert-buffer)))
 170
 171 ;; For backward compatibility
 172 (defvaralias 'dired-omit-files-p 'dired-omit-mode)
 173 (make-obsolete-variable 'dired-omit-files-p 'dired-omit-mode)
 174
 175 (defcustom dired-omit-files "^\\.?#\\|^\\.$\\|^\\.\\.$"
 176   "*Filenames matching this regexp will not be displayed.
 177 This only has effect when `dired-omit-mode' is t.  See interactive function
 178 `dired-omit-mode' \(\\[dired-omit-mode]\) and variable
 179 `dired-omit-extensions'.  The default is to omit  `.', `..', auto-save
 180 files and lock files."
 181   :type 'regexp
 182   :group 'dired-x)
 183
 184 (defcustom dired-find-subdir nil           ; t is pretty near to DWIM...
 185   "*If non-nil, Dired always finds a directory in a buffer of its own.
 186 If nil, Dired finds the directory as a subdirectory in some other buffer
 187 if it is present as one.
 188
 189 If there are several dired buffers for a directory, the most recently
 190 used is chosen.
 191
 192 Dired avoids switching to the current buffer, so that if you have
 193 a normal and a wildcard buffer for the same directory, \\[dired] will
 194 toggle between those two."
 195   :type 'boolean
 196   :group 'dired-x)
 197
 198 (defcustom dired-omit-size-limit 30000
 199   "*Maximum size for the \"omitting\" feature.
 200 If nil, there is no maximum size."
 201   :type '(choice (const :tag "no maximum" nil) integer)
 202   :group 'dired-x)
 203
 204 (defcustom dired-enable-local-variables t
 205   "*Control use of local-variables lists in Dired.
 206 The value can be t, nil or something else.
 207 A value of t means local-variables lists are obeyed;
 208 nil means they are ignored; anything else means query.
 209
 210 This temporarily overrides the value of `enable-local-variables' when listing
 211 a directory.  See also `dired-local-variables-file'."
 212   :type 'boolean
 213   :group 'dired-x)
 214
 215 (defcustom dired-guess-shell-gnutar nil
 216   "*If non-nil, name of GNU tar executable.
 217 \(E.g., \"tar\" or \"gtar\").  The `z' switch will be used with it for
 218 compressed or gzip'ed tar files.  If you don't have GNU tar, set this
 219 to nil: a pipe using `zcat' or `gunzip -c' will be used."
 220   :type '(choice (const :tag "Not GNU tar" nil)
 221                  (string :tag "Command name"))
 222   :group 'dired-x)
 223
 224 (defcustom dired-guess-shell-gzip-quiet t
 225   "*Non-nil says pass -q to gzip overriding verbose GZIP environment."
 226   :type 'boolean
 227   :group 'dired-x)
 228
 229 (defcustom dired-guess-shell-znew-switches nil
 230   "*If non-nil, then string of switches passed to `znew', example: \"-K\"."
 231   :type '(choice (const :tag "None" nil)
 232                  (string :tag "Switches"))
 233   :group 'dired-x)
 234
 235 (defcustom dired-clean-up-buffers-too t
 236   "*Non-nil means offer to kill buffers visiting files and dirs deleted in Dired."
 237   :type 'boolean
 238   :group 'dired-x)
 239
 240 ;;; KEY BINDINGS.
 241
 242 (define-key dired-mode-map "\M-o" 'dired-omit-mode)
 243 (define-key dired-mode-map "*O" 'dired-mark-omitted)
 244 (define-key dired-mode-map "\M-(" 'dired-mark-sexp)
 245 (define-key dired-mode-map "*(" 'dired-mark-sexp)
 246 (define-key dired-mode-map "*." 'dired-mark-extension)
 247 (define-key dired-mode-map "\M-!" 'dired-smart-shell-command)
 248 (define-key dired-mode-map "w" 'dired-copy-filename-as-kill)
 249 (define-key dired-mode-map "\M-g" 'dired-goto-file)
 250 (define-key dired-mode-map "\M-G" 'dired-goto-subdir)
 251 (define-key dired-mode-map "F" 'dired-do-find-marked-files)
 252 (define-key dired-mode-map "Y"  'dired-do-relsymlink)
 253 (define-key dired-mode-map "%Y" 'dired-do-relsymlink-regexp)
 254 (define-key dired-mode-map "V" 'dired-do-run-mail)
 255
 256 (if dired-bind-man
 257     (define-key dired-mode-map "N" 'dired-man))
 258
 259 (if dired-bind-info
 260     (define-key dired-mode-map "I" 'dired-info))
 261
 262 ;;; GLOBAL BINDING.
 263 (if dired-bind-jump
 264     (progn
 265       (define-key global-map "\C-x\C-j" 'dired-jump)
 266       (define-key global-map "\C-x4\C-j" 'dired-jump-other-window)))
 267
 268 \f
 269 ;;; Install into appropriate hooks.
 270
 271 (add-hook 'dired-mode-hook 'dired-extra-startup)
 272 (add-hook 'dired-after-readin-hook 'dired-omit-expunge)
 273
 274 (defun dired-extra-startup ()
 275   "Automatically put on `dired-mode-hook' to get extra Dired features:
 276 \\<dired-mode-map>
 277   \\[dired-do-run-mail]\t-- run mail on folder (see `dired-bind-vm')
 278   \\[dired-info]\t-- run info on file
 279   \\[dired-man]\t-- run man on file
 280   \\[dired-do-find-marked-files]\t-- visit all marked files simultaneously
 281   \\[dired-omit-mode]\t-- toggle omitting of files
 282   \\[dired-mark-sexp]\t-- mark by Lisp expression
 283   \\[dired-copy-filename-as-kill]\t-- copy the file or subdir names into the kill ring;
 284   \t   you can feed it to other commands using \\[yank]
 285
 286 For more features, see variables
 287
 288   `dired-bind-vm'
 289   `dired-bind-jump'
 290   `dired-bind-info'
 291   `dired-bind-man'
 292   `dired-vm-read-only-folders'
 293   `dired-omit-mode'
 294   `dired-omit-files'
 295   `dired-omit-extensions'
 296   `dired-omit-size-limit'
 297   `dired-find-subdir'
 298   `dired-enable-local-variables'
 299   `dired-local-variables-file'
 300   `dired-guess-shell-gnutar'
 301   `dired-guess-shell-gzip-quiet'
 302   `dired-guess-shell-znew-switches'
 303   `dired-guess-shell-alist-user'
 304   `dired-clean-up-buffers-too'
 305
 306 See also functions
 307
 308   `dired-flag-extension'
 309   `dired-virtual'
 310   `dired-jump'
 311   `dired-man'
 312   `dired-vm'
 313   `dired-rmail'
 314   `dired-info'
 315   `dired-do-find-marked-files'"
 316   (interactive)
 317
 318   ;; These must be done in each new dired buffer.
 319   (dired-hack-local-variables)
 320   (dired-omit-startup))
 321
 322 \f
 323 ;;; BUFFER CLEANING.
 324
 325 ;; REDEFINE.
 326 (defun dired-clean-up-after-deletion (fn)
 327   "Clean up after a deleted file or directory FN.
 328 Remove expanded subdir of deleted dir, if any."
 329   (save-excursion (and (cdr dired-subdir-alist)
 330                        (dired-goto-subdir fn)
 331                        (dired-kill-subdir)))
 332
 333   ;; Offer to kill buffer of deleted file FN.
 334   (if dired-clean-up-buffers-too
 335       (progn
 336         (let ((buf (get-file-buffer fn)))
 337           (and buf
 338                (funcall (function y-or-n-p)
 339                         (format "Kill buffer of %s, too? "
 340                                 (file-name-nondirectory fn)))
 341                (save-excursion ; you never know where kill-buffer leaves you
 342                  (kill-buffer buf))))
 343         (let ((buf-list (dired-buffers-for-dir (expand-file-name fn)))
 344               (buf nil))
 345           (and buf-list
 346                (y-or-n-p (format "Kill dired buffer%s of %s, too? "
 347                                  (dired-plural-s (length buf-list))
 348                                  (file-name-nondirectory fn)))
 349                (while buf-list
 350                  (save-excursion (kill-buffer (car buf-list)))
 351                  (setq buf-list (cdr buf-list)))))))
 352   ;; Anything else?
 353   )
 354
 355 \f
 356 ;;; EXTENSION MARKING FUNCTIONS.
 357
 358 ;;; Mark files with some extension.
 359 (defun dired-mark-extension (extension &optional marker-char)
 360   "Mark all files with a certain EXTENSION for use in later commands.
 361 A `.' is *not* automatically prepended to the string entered."
 362   ;; EXTENSION may also be a list of extensions instead of a single one.
 363   ;; Optional MARKER-CHAR is marker to use.
 364   (interactive "sMarking extension: \nP")
 365   (or (listp extension)
 366       (setq extension (list extension)))
 367   (dired-mark-files-regexp
 368    (concat ".";; don't match names with nothing but an extension
 369            "\\("
 370            (mapconcat 'regexp-quote extension "\\|")
 371            "\\)$")
 372    marker-char))
 373
 374 (defun dired-flag-extension (extension)
 375   "In dired, flag all files with a certain EXTENSION for deletion.
 376 A `.' is *not* automatically prepended to the string entered."
 377   (interactive "sFlagging extension: ")
 378   (dired-mark-extension extension dired-del-marker))
 379
 380 ;;; Define some unpopular file extensions.  Used for cleaning and omitting.
 381
 382 (defvar dired-patch-unclean-extensions
 383   '(".rej" ".orig")
 384   "List of extensions of dispensable files created by the `patch' program.")
 385
 386 (defvar dired-tex-unclean-extensions
 387   '(".toc" ".log" ".aux");; these are already in completion-ignored-extensions
 388   "List of extensions of dispensable files created by TeX.")
 389
 390 (defvar dired-latex-unclean-extensions
 391   '(".idx" ".lof" ".lot" ".glo")
 392   "List of extensions of dispensable files created by LaTeX.")
 393
 394 (defvar dired-bibtex-unclean-extensions
 395   '(".blg" ".bbl")
 396   "List of extensions of dispensable files created by BibTeX.")
 397
 398 (defvar dired-texinfo-unclean-extensions
 399   '(".cp" ".cps" ".fn" ".fns" ".ky" ".kys" ".pg" ".pgs"
 400     ".tp" ".tps" ".vr" ".vrs")
 401   "List of extensions of dispensable files created by texinfo.")
 402
 403 (defun dired-clean-patch ()
 404   "Flag dispensable files created by patch for deletion.
 405 See variable `dired-patch-unclean-extensions'."
 406   (interactive)
 407   (dired-flag-extension dired-patch-unclean-extensions))
 408
 409 (defun dired-clean-tex ()
 410   "Flag dispensable files created by [La]TeX etc. for deletion.
 411 See variables `dired-tex-unclean-extensions',
 412 `dired-latex-unclean-extensions', `dired-bibtex-unclean-extensions' and
 413 `dired-texinfo-unclean-extensions'."
 414   (interactive)
 415   (dired-flag-extension (append dired-texinfo-unclean-extensions
 416                                 dired-latex-unclean-extensions
 417                                 dired-bibtex-unclean-extensions
 418                                 dired-tex-unclean-extensions)))
 419
 420 (defun dired-very-clean-tex ()
 421   "Flag dispensable files created by [La]TeX *and* \".dvi\" for deletion.
 422 See variables `dired-texinfo-unclean-extensions',
 423 `dired-latex-unclean-extensions', `dired-bibtex-unclean-extensions' and
 424 `dired-texinfo-unclean-extensions'."
 425   (interactive)
 426   (dired-flag-extension (append dired-texinfo-unclean-extensions
 427                                 dired-latex-unclean-extensions
 428                                 dired-bibtex-unclean-extensions
 429                                 dired-tex-unclean-extensions
 430                                 (list ".dvi"))))
 431 \f
 432 ;;; JUMP.
 433
 434 ;;;###autoload
 435 (defun dired-jump (&optional other-window)
 436   "Jump to dired buffer corresponding to current buffer.
 437 If in a file, dired the current directory and move to file's line.
 438 If in Dired already, pop up a level and goto old directory's line.
 439 In case the proper dired file line cannot be found, refresh the dired
 440 buffer and try again."
 441   (interactive "P")
 442   (let* ((file buffer-file-name)
 443          (dir (if file (file-name-directory file) default-directory)))
 444     (if (eq major-mode 'dired-mode)
 445         (progn
 446           (setq dir (dired-current-directory))
 447           (dired-up-directory other-window)
 448           (or (dired-goto-file dir)
 449               ;; refresh and try again
 450               (progn
 451                 (dired-insert-subdir (file-name-directory dir))
 452                 (dired-goto-file dir))))
 453       (if other-window
 454           (dired-other-window dir)
 455         (dired dir))
 456       (if file
 457           (or (dired-goto-file file)
 458               ;; refresh and try again
 459               (progn
 460                 (dired-insert-subdir (file-name-directory file))
 461                 (dired-goto-file file))
 462               ;; Toggle omitting, if it is on, and try again.
 463               (if dired-omit-mode
 464                   (progn
 465                     (dired-omit-mode)
 466                     (dired-goto-file file))))))))
 467
 468 (defun dired-jump-other-window ()
 469   "Like \\[dired-jump] (`dired-jump') but in other window."
 470   (interactive)
 471   (dired-jump t))
 472 \f
 473 ;;; OMITTING.
 474
 475 ;;; Enhanced omitting of lines from directory listings.
 476 ;;; Marked files are never omitted.
 477
 478 ;; should probably get rid of this and always use 'no-dir.
 479 ;; sk 28-Aug-1991 09:37
 480 (defvar dired-omit-localp 'no-dir
 481   "The LOCALP argument `dired-omit-expunge' passes to `dired-get-filename'.
 482 If it is `no-dir', omitting is much faster, but you can only match
 483 against the non-directory part of the file name.  Set it to nil if you
 484 need to match the entire file name.")
 485
 486 ;; \017=^O for Omit - other packages can chose other control characters.
 487 (defvar dired-omit-marker-char ?\017
 488   "Temporary marker used by dired-omit.
 489 Should never be used as marker by the user or other packages.")
 490
 491 (defun dired-omit-startup ()
 492   (or (assq 'dired-omit-mode minor-mode-alist)
 493       (setq minor-mode-alist
 494             (append '((dired-omit-mode
 495                        (:eval (if (eq major-mode 'dired-mode)
 496                                   " Omit" ""))))
 497                     minor-mode-alist))))
 498
 499 (defun dired-mark-omitted ()
 500   "Mark files matching `dired-omit-files' and `dired-omit-extensions'."
 501   (interactive)
 502   (let ((dired-omit-mode nil)) (revert-buffer)) ;; Show omitted files
 503   (dired-mark-unmarked-files (dired-omit-regexp) nil nil dired-omit-localp))
 504
 505 (defvar dired-omit-extensions
 506   (append completion-ignored-extensions
 507           dired-latex-unclean-extensions
 508           dired-bibtex-unclean-extensions
 509           dired-texinfo-unclean-extensions)
 510   "If non-nil, a list of extensions \(strings\) to omit from Dired listings.
 511 Defaults to elements of `completion-ignored-extensions',
 512 `dired-latex-unclean-extensions', `dired-bibtex-unclean-extensions', and
 513 `dired-texinfo-unclean-extensions'.
 514
 515 See interactive function `dired-omit-mode' \(\\[dired-omit-mode]\) and
 516 variables `dired-omit-mode' and `dired-omit-files'.")
 517
 518 (defun dired-omit-expunge (&optional regexp)
 519   "Erases all unmarked files matching REGEXP.
 520 Does nothing if global variable `dired-omit-mode' is nil, or if called
 521   non-interactively and buffer is bigger than `dired-omit-size-limit'.
 522 If REGEXP is nil or not specified, uses `dired-omit-files', and also omits
 523   filenames ending in `dired-omit-extensions'.
 524 If REGEXP is the empty string, this function is a no-op.
 525
 526 This functions works by temporarily binding `dired-marker-char' to
 527 `dired-omit-marker-char' and calling `dired-do-kill-lines'."
 528   (interactive "sOmit files (regexp): ")
 529   (if (and dired-omit-mode
 530            (or (interactive-p)
 531                (not dired-omit-size-limit)
 532                (< (buffer-size) dired-omit-size-limit)
 533                (progn
 534                  (message "Not omitting: directory larger than %d characters."
 535                           dired-omit-size-limit)
 536                  (setq dired-omit-mode nil)
 537                  nil)))
 538       (let ((omit-re (or regexp (dired-omit-regexp)))
 539             (old-modified-p (buffer-modified-p))
 540             count)
 541         (or (string= omit-re "")
 542             (let ((dired-marker-char dired-omit-marker-char))
 543               (message "Omitting...")
 544               (if (dired-mark-unmarked-files omit-re nil nil dired-omit-localp)
 545                   (progn
 546                     (setq count (dired-do-kill-lines nil "Omitted %d line%s."))
 547                     (force-mode-line-update))
 548                 (message "(Nothing to omit)"))))
 549         ;; Try to preserve modified state of buffer.  So `%*' doesn't appear
 550         ;; in mode-line of omitted buffers.
 551         (set-buffer-modified-p (and old-modified-p
 552                                     (save-excursion
 553                                       (goto-char (point-min))
 554                                       (re-search-forward dired-re-mark nil t))))
 555         count)))
 556
 557 (defun dired-omit-regexp ()
 558   (concat (if dired-omit-files (concat "\\(" dired-omit-files "\\)") "")
 559           (if (and dired-omit-files dired-omit-extensions) "\\|" "")
 560           (if dired-omit-extensions
 561               (concat ".";; a non-extension part should exist
 562                       "\\("
 563                       (mapconcat 'regexp-quote dired-omit-extensions "\\|")
 564                       "\\)$")
 565             "")))
 566
 567 ;; Returns t if any work was done, nil otherwise.
 568 (defun dired-mark-unmarked-files (regexp msg &optional unflag-p localp)
 569   "Mark unmarked files matching REGEXP, displaying MSG.
 570 REGEXP is matched against the entire file name.
 571 Does not re-mark files which already have a mark.
 572 With prefix argument, unflag all those files.
 573 Optional fourth argument LOCALP is as in `dired-get-filename'."
 574   (interactive "P")
 575   (let ((dired-marker-char (if unflag-p ?\s dired-marker-char)))
 576     (dired-mark-if
 577      (and
 578       ;; not already marked
 579       (looking-at " ")
 580       ;; uninteresting
 581       (let ((fn (dired-get-filename localp t)))
 582         (and fn (string-match regexp fn))))
 583      msg)))
 584
 585 ;;; REDEFINE.
 586 (defun dired-omit-new-add-entry (filename &optional marker-char relative)
 587   ;; This redefines dired-aux.el's dired-add-entry to avoid calling ls for
 588   ;; files that are going to be omitted anyway.
 589   (if dired-omit-mode
 590       ;; perhaps return t without calling ls
 591       (let ((omit-re (dired-omit-regexp)))
 592         (if (or (string= omit-re "")
 593                 (not
 594                  (string-match omit-re
 595                                (cond
 596                                 ((eq 'no-dir dired-omit-localp)
 597                                  filename)
 598                                 ((eq t dired-omit-localp)
 599                                  (dired-make-relative filename))
 600                                 (t
 601                                  (dired-make-absolute
 602                                   filename
 603                                   (file-name-directory filename)))))))
 604             ;; if it didn't match, go ahead and add the entry
 605             (dired-omit-old-add-entry filename marker-char relative)
 606           ;; dired-add-entry returns t for success, perhaps we should
 607           ;; return file-exists-p
 608           t))
 609     ;; omitting is not turned on at all
 610     (dired-omit-old-add-entry filename marker-char relative)))
 611
 612 ;;; REDEFINE.
 613 ;;; Redefine dired-aux.el's version of `dired-add-entry'
 614 ;;; Save old defun if not already done:
 615 (or (fboundp 'dired-omit-old-add-entry)
 616     (fset 'dired-omit-old-add-entry (symbol-function 'dired-add-entry)))
 617 ;; Redefine it.
 618 (fset 'dired-add-entry 'dired-omit-new-add-entry)
 619
 620 \f
 621 ;;; VIRTUAL DIRED MODE.
 622
 623 ;;; For browsing `ls -lR' listings in a dired-like fashion.
 624
 625 (defalias 'virtual-dired 'dired-virtual)
 626 (defun dired-virtual (dirname &optional switches)
 627   "Put this buffer into Virtual Dired mode.
 628
 629 In Virtual Dired mode, all commands that do not actually consult the
 630 filesystem will work.
 631
 632 This is useful if you want to peruse and move around in an ls -lR
 633 output file, for example one you got from an ftp server.  With
 634 ange-ftp, you can even dired a directory containing an ls-lR file,
 635 visit that file and turn on virtual dired mode.  But don't try to save
 636 this file, as dired-virtual indents the listing and thus changes the
 637 buffer.
 638
 639 If you have save a Dired buffer in a file you can use \\[dired-virtual] to
 640 resume it in a later session.
 641
 642 Type \\<dired-mode-map>\\[revert-buffer] \
 643 in the Virtual Dired buffer and answer `y' to convert
 644 the virtual to a real dired buffer again.  You don't have to do this, though:
 645 you can relist single subdirs using \\[dired-do-redisplay]."
 646
 647   ;; DIRNAME is the top level directory of the buffer.  It will become
 648   ;; its `default-directory'.  If nil, the old value of
 649   ;; default-directory is used.
 650
 651   ;; Optional SWITCHES are the ls switches to use.
 652
 653   ;; Shell wildcards will be used if there already is a `wildcard'
 654   ;; line in the buffer (thus it is a saved Dired buffer), but there
 655   ;; is no other way to get wildcards.  Insert a `wildcard' line by
 656   ;; hand if you want them.
 657
 658   (interactive
 659    (list (read-string "Virtual Dired directory: " (dired-virtual-guess-dir))))
 660   (goto-char (point-min))
 661   (or (looking-at "  ")
 662       ;; if not already indented, do it now:
 663       (indent-region (point-min) (point-max) 2))
 664   (or dirname (setq dirname default-directory))
 665   (setq dirname (expand-file-name (file-name-as-directory dirname)))
 666   (setq default-directory dirname)      ; contains no wildcards
 667   (let ((wildcard (save-excursion
 668                     (goto-char (point-min))
 669                     (forward-line 1)
 670                     (and (looking-at "^  wildcard ")
 671                          (buffer-substring (match-end 0)
 672                                            (progn (end-of-line) (point)))))))
 673   (if wildcard
 674         (setq dirname (expand-file-name wildcard default-directory))))
 675   ;; If raw ls listing (not a saved old dired buffer), give it a
 676   ;; decent subdir headerline:
 677   (goto-char (point-min))
 678   (or (looking-at dired-subdir-regexp)
 679       (dired-insert-headerline default-directory))
 680   (dired-mode dirname (or switches dired-listing-switches))
 681   (setq mode-name "Virtual Dired"
 682         revert-buffer-function 'dired-virtual-revert)
 683   (set (make-local-variable 'dired-subdir-alist) nil)
 684   (dired-build-subdir-alist)
 685   (goto-char (point-min))
 686   (dired-initial-position dirname))
 687
 688 (defun dired-virtual-guess-dir ()
 689   "Guess and return appropriate working directory of this buffer.
 690 The buffer is assumed to be in Dired or ls -lR format.  The guess is
 691 based upon buffer contents.  If nothing could be guessed, returns
 692 nil."
 693
 694   (let ((regexp "^\\(  \\)?\\([^ \n\r]*\\)\\(:\\)[\n\r]")
 695         (subexpr 2))
 696     (goto-char (point-min))
 697     (cond ((looking-at regexp)
 698            ;; If a saved dired buffer, look to which dir and
 699            ;; perhaps wildcard it belongs:
 700            (let ((dir (buffer-substring (match-beginning subexpr)
 701                                         (match-end subexpr))))
 702              (file-name-as-directory dir)))
 703           ;; Else no match for headerline found.  It's a raw ls listing.
 704           ;; In raw ls listings the directory does not have a headerline
 705           ;; try parent of first subdir, if any
 706           ((re-search-forward regexp nil t)
 707            (file-name-directory
 708             (directory-file-name
 709              (file-name-as-directory
 710               (buffer-substring (match-beginning subexpr)
 711                                 (match-end subexpr))))))
 712           (t                            ; if all else fails
 713            nil))))
 714
 715
 716 (defun dired-virtual-revert (&optional arg noconfirm)
 717   (if (not
 718        (y-or-n-p "Cannot revert a Virtual Dired buffer - switch to Real Dired mode? "))
 719       (error "Cannot revert a Virtual Dired buffer")
 720     (setq mode-name "Dired"
 721           revert-buffer-function 'dired-revert)
 722     (revert-buffer)))
 723
 724 ;; A zero-arg version of dired-virtual.
 725 ;; You need my modified version of set-auto-mode for the
 726 ;; `buffer-contents-mode-alist'.
 727 ;; Or you use infer-mode.el and infer-mode-alist, same syntax.
 728 (defun dired-virtual-mode ()
 729   "Put current buffer into Virtual Dired mode (see `dired-virtual').
 730 Useful on `buffer-contents-mode-alist' (which see) with the regexp
 731
 732     \"^  \\(/[^ /]+\\)/?+:$\"
 733
 734 to put saved dired buffers automatically into Virtual Dired mode.
 735
 736 Also useful for `auto-mode-alist' (which see) like this:
 737
 738   \(setq auto-mode-alist (cons '(\"[^/]\\.dired\\'\" . dired-virtual-mode)
 739                               auto-mode-alist)\)"
 740   (interactive)
 741   (dired-virtual (dired-virtual-guess-dir)))
 742
 743 \f
 744 ;;; SMART SHELL.
 745
 746 ;;; An Emacs buffer can have but one working directory, stored in the
 747 ;;; buffer-local variable `default-directory'.  A Dired buffer may have
 748 ;;; several subdirectories inserted, but still has but one working directory:
 749 ;;; that of the top level Dired directory in that buffer.  For some commands
 750 ;;; it is appropriate that they use the current Dired directory instead of
 751 ;;; `default-directory', e.g., `find-file' and `compile'.  This is a general
 752 ;;; mechanism is provided for special handling of the working directory in
 753 ;;; special major modes.
 754
 755 ;; It's easier to add to this alist than redefine function
 756 ;; default-directory while keeping the old information.
 757 (defconst default-directory-alist
 758   '((dired-mode . (if (fboundp 'dired-current-directory)
 759                       (dired-current-directory)
 760                     default-directory)))
 761   "Alist of major modes and their opinion on `default-directory'.
 762 This is given as a Lisp expression to evaluate.  A resulting value of
 763 nil is ignored in favor of `default-directory'.")
 764
 765 (defun dired-default-directory ()
 766   "Usage like variable `default-directory'.
 767 Knows about the special cases in variable `default-directory-alist'."
 768   (or (eval (cdr (assq major-mode default-directory-alist)))
 769       default-directory))
 770
 771 (defun dired-smart-shell-command (cmd &optional insert)
 772   "Like function `shell-command', but in the current Virtual Dired directory."
 773   (interactive (list (read-from-minibuffer "Shell command: "
 774                                            nil nil nil 'shell-command-history)
 775                      current-prefix-arg))
 776   (let ((default-directory (dired-default-directory)))
 777     (shell-command cmd insert)))
 778
 779 \f
 780 ;;; LOCAL VARIABLES FOR DIRED BUFFERS.
 781
 782 ;;; Brief Description:
 783 ;;;
 784 ;;; * `dired-extra-startup' is part of the `dired-mode-hook'.
 785 ;;;
 786 ;;; * `dired-extra-startup' calls `dired-hack-local-variables'
 787 ;;;
 788 ;;; * `dired-hack-local-variables' checks the value of
 789 ;;;   `dired-local-variables-file'
 790 ;;;
 791 ;;; * Check if `dired-local-variables-file' is a non-nil string and is a
 792 ;;;   filename found in the directory of the Dired Buffer being created.
 793 ;;;
 794 ;;; * If `dired-local-variables-file' satisfies the above, then temporarily
 795 ;;;   include it in the Dired Buffer at the bottom.
 796 ;;;
 797 ;;; * Set `enable-local-variables' temporarily to the user variable
 798 ;;;   `dired-enable-local-variables' and run `hack-local-variables' on the
 799 ;;;   Dired Buffer.
 800
 801 (defvar dired-local-variables-file (convert-standard-filename ".dired")
 802   "Filename, as string, containing local dired buffer variables to be hacked.
 803 If this file found in current directory, then it will be inserted into dired
 804 buffer and `hack-local-variables' will be run.  See Info node
 805 `(emacs)File Variables' for more information on local variables.
 806 See also `dired-enable-local-variables'.")
 807
 808 (defun dired-hack-local-variables ()
 809   "Evaluate local variables in `dired-local-variables-file' for dired buffer."
 810   (if (and dired-local-variables-file
 811            (stringp dired-local-variables-file)
 812            (file-exists-p dired-local-variables-file))
 813       (let ((opoint (point-max))
 814             buffer-read-only
 815             ;; In case user has `enable-local-variables' set to nil we
 816             ;; override it locally with dired's variable.
 817             (enable-local-variables dired-enable-local-variables))
 818         ;; Insert 'em.
 819         (save-excursion
 820           (goto-char opoint)
 821           (insert "\^L\n")
 822           (insert-file-contents dired-local-variables-file))
 823         ;; Hack 'em.
 824         (let ((buffer-file-name dired-local-variables-file))
 825           (hack-local-variables))
 826         ;; Make sure that the modeline shows the proper information.
 827         (dired-sort-set-modeline)
 828         ;; Delete this stuff: `eobp' is used to find last subdir by dired.el.
 829         (delete-region opoint (point-max)))))
 830
 831 (defun dired-omit-here-always ()
 832   "Create `dired-local-variables-file' for omitting and reverts directory.
 833 Sets `dired-omit-mode' to t in a local variables file that is readable by
 834 dired."
 835   (interactive)
 836   (if (file-exists-p dired-local-variables-file)
 837       (message "File `./%s' already exists." dired-local-variables-file)
 838
 839     ;; Create `dired-local-variables-file'.
 840     (save-excursion
 841       (set-buffer (get-buffer-create " *dot-dired*"))
 842       (erase-buffer)
 843       (insert "Local Variables:\ndired-omit-mode: t\nEnd:\n")
 844       (write-file dired-local-variables-file)
 845       (kill-buffer (current-buffer)))
 846
 847     ;; Run extra-hooks and revert directory.
 848     (dired-extra-startup)
 849     (dired-revert)))
 850
 851 \f
 852 ;;; GUESS SHELL COMMAND.
 853
 854 ;;; Brief Description:
 855 ;;;
 856 ;;; `dired-do-shell-command' is bound to `!' by dired.el.
 857 ;;;
 858 ;;; * Redefine `dired-do-shell-command' so it calls
 859 ;;;   `dired-guess-shell-command'.
 860 ;;;
 861 ;;; * `dired-guess-shell-command' calls `dired-guess-default' with list of
 862 ;;;    marked files.
 863 ;;;
 864 ;;; * Parse `dired-guess-shell-alist-user' and
 865 ;;;   `dired-guess-shell-alist-default' (in that order) for the first REGEXP
 866 ;;;   that matches the first file in the file list.
 867 ;;;
 868 ;;; * If the REGEXP matches all the entries of the file list then evaluate
 869 ;;;   COMMAND, which is either a string or a Lisp expression returning a
 870 ;;;   string.  COMMAND may be a list of commands.
 871 ;;;
 872 ;;; * Return this command to `dired-guess-shell-command' which prompts user
 873 ;;;   with it.  The list of commands is temporarily put into the history list.
 874 ;;;   If a command is used successfully then it is stored permanently in
 875 ;;;   `dired-shell-command-history'.
 876
 877 ;;; Guess what shell command to apply to a file.
 878 (defvar dired-shell-command-history nil
 879   "History list for commands that read dired-shell commands.")
 880
 881 ;;; Default list of shell commands.
 882
 883 ;;; NOTE: Use `gunzip -c' instead of `zcat' on `.gz' files.  Some do not
 884 ;;; install GNU zip's version of zcat.
 885
 886 (defvar dired-guess-shell-alist-default
 887   (list
 888    (list "\\.tar$"
 889          '(if dired-guess-shell-gnutar
 890               (concat dired-guess-shell-gnutar " xvf")
 891             "tar xvf")
 892          ;; Extract files into a separate subdirectory
 893          '(if dired-guess-shell-gnutar
 894               (concat "mkdir " (file-name-sans-extension file)
 895                       "; " dired-guess-shell-gnutar " -C "
 896                       (file-name-sans-extension file) " -xvf")
 897             (concat "mkdir " (file-name-sans-extension file)
 898                     "; tar -C " (file-name-sans-extension file) " -xvf")))
 899
 900    ;; REGEXPS for compressed archives must come before the .Z rule to
 901    ;; be recognized:
 902    (list "\\.tar\\.Z$"
 903          ;; Untar it.
 904          '(if dired-guess-shell-gnutar
 905               (concat dired-guess-shell-gnutar " zxvf")
 906             (concat "zcat * | tar xvf -"))
 907          ;; Optional conversion to gzip format.
 908          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
 909                   " " dired-guess-shell-znew-switches))
 910
 911    ;; gzip'ed archives
 912    (list "\\.t\\(ar\\.\\)?gz$"
 913          '(if dired-guess-shell-gnutar
 914               (concat dired-guess-shell-gnutar " zxvf")
 915             (concat "gunzip -qc * | tar xvf -"))
 916          ;; Extract files into a separate subdirectory
 917          '(if dired-guess-shell-gnutar
 918               (concat "mkdir " (file-name-sans-extension file)
 919                       "; " dired-guess-shell-gnutar " -C "
 920                       (file-name-sans-extension file) " -zxvf")
 921             (concat "mkdir " (file-name-sans-extension file)
 922                     "; gunzip -qc * | tar -C "
 923                     (file-name-sans-extension file) " -xvf -"))
 924          ;; Optional decompression.
 925          '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q" "")))
 926
 927    ;; bzip2'ed archives
 928    (list "\\.t\\(ar\\.bz2\\|bz\\)$"
 929          "bunzip2 -c * | tar xvf -"
 930          ;; Extract files into a separate subdirectory
 931          '(concat "mkdir " (file-name-sans-extension file)
 932                   "; bunzip2 -c * | tar -C "
 933                   (file-name-sans-extension file) " -xvf -")
 934          ;; Optional decompression.
 935          "bunzip2")
 936
 937    '("\\.shar\\.Z$" "zcat * | unshar")
 938    '("\\.shar\\.g?z$" "gunzip -qc * | unshar")
 939
 940    '("\\.e?ps$" "ghostview" "xloadimage" "lpr")
 941    (list "\\.e?ps\\.g?z$" "gunzip -qc * | ghostview -"
 942          ;; Optional decompression.
 943          '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q")))
 944    (list "\\.e?ps\\.Z$" "zcat * | ghostview -"
 945          ;; Optional conversion to gzip format.
 946          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
 947                   " " dired-guess-shell-znew-switches))
 948
 949    '("\\.patch$" "cat * | patch")
 950    (list "\\.patch\\.g?z$" "gunzip -qc * | patch"
 951          ;; Optional decompression.
 952          '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q")))
 953    (list "\\.patch\\.Z$" "zcat * | patch"
 954          ;; Optional conversion to gzip format.
 955          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
 956                   " " dired-guess-shell-znew-switches))
 957
 958    ;; The following four extensions are useful with dired-man ("N" key)
 959    (list "\\.[0-9]$" '(progn (require 'man)
 960                              (if (Man-support-local-filenames)
 961                                  "man -l"
 962                                "cat * | tbl | nroff -man -h")))
 963    (list "\\.[0-9]\\.g?z$" '(progn (require 'man)
 964                                    (if (Man-support-local-filenames)
 965                                        "man -l"
 966                                      "gunzip -qc * | tbl | nroff -man -h"))
 967          ;; Optional decompression.
 968          '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q")))
 969    (list "\\.[0-9]\\.Z$" '(progn (require 'man)
 970                                  (if (Man-support-local-filenames)
 971                                      "man -l"
 972                                    "zcat * | tbl | nroff -man -h"))
 973          ;; Optional conversion to gzip format.
 974          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
 975                   " " dired-guess-shell-znew-switches))
 976    '("\\.pod$" "perldoc" "pod2man * | nroff -man")
 977
 978    '("\\.dvi$" "xdvi" "dvips")          ; preview and printing
 979    '("\\.au$" "play")                   ; play Sun audiofiles
 980    '("\\.mpg$" "mpeg_play")
 981    '("\\.uu$" "uudecode")               ; for uudecoded files
 982    '("\\.hqx$" "mcvert")
 983    '("\\.sh$" "sh")                     ; execute shell scripts
 984    '("\\.xbm$" "bitmap")                ; view X11 bitmaps
 985    '("\\.gp$" "gnuplot")
 986    '("\\.p[bgpn]m$" "xloadimage")
 987    '("\\.gif$" "xloadimage")                    ; view gif pictures
 988    '("\\.tif$" "xloadimage")
 989    '("\\.png$" "display")               ; xloadimage 4.1 doesn't grok PNG
 990    '("\\.jpe?g$" "xloadimage")
 991    '("\\.fig$" "xfig")                  ; edit fig pictures
 992    '("\\.out$" "xgraph")                ; for plotting purposes.
 993    '("\\.tex$" "latex" "tex")
 994    '("\\.texi\\(nfo\\)?$" "makeinfo" "texi2dvi")
 995    '("\\.pdf$" "xpdf")              ; edit PDF files
 996
 997    ;; Some other popular archivers.
 998    (list "\\.zip$" "unzip"
 999          ;; Extract files into a separate subdirectory
1000          '(concat "unzip" (if dired-guess-shell-gzip-quiet " -q")
1001                   " -d " (file-name-sans-extension file)))
1002    '("\\.zoo$" "zoo x//")
1003    '("\\.lzh$" "lharc x")
1004    '("\\.arc$" "arc x")
1005    '("\\.shar$" "unshar")
1006
1007    ;; Compression.
1008    (list "\\.g?z$" '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q")))
1009    (list "\\.dz$" "dictunzip")
1010    (list "\\.bz2$" "bunzip2")
1011    (list "\\.Z$" "uncompress"
1012          ;; Optional conversion to gzip format.
1013          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
1014                   " " dired-guess-shell-znew-switches))
1015    )
1016
1017   "Default alist used for shell command guessing.
1018 See `dired-guess-shell-alist-user'.")
1019
1020 (defcustom dired-guess-shell-alist-user nil
1021   "User-defined alist of rules for suggested commands.
1022 These rules take precedence over the predefined rules in the variable
1023 `dired-guess-shell-alist-default' (to which they are prepended).
1024
1025 Each element of this list looks like
1026
1027     \(REGEXP COMMAND...\)
1028
1029 where each COMMAND can either be a string or a Lisp expression that evaluates
1030 to a string.  If several COMMANDs are given, the first one will be the default
1031 and the rest will be added temporarily to the history and can be retrieved
1032 with \\[previous-history-element] (M-p) .
1033
1034 You can set this variable in your ~/.emacs.  For example, to add rules for
1035 `.foo' and `.bar' files, write
1036
1037  \(setq dired-guess-shell-alist-user
1038        (list (list \"\\\\.foo\\\\'\" \"FOO-COMMAND\");; fixed rule
1039               ;; possibly more rules ...
1040               (list \"\\\\.bar\\\'\";; rule with condition test
1041                     '(if condition
1042                           \"BAR-COMMAND-1\"
1043                         \"BAR-COMMAND-2\")))\)"
1044   :group 'dired-x
1045   :type '(alist :key-type regexp :value-type (repeat sexp)))
1046
1047 (defcustom dired-guess-shell-case-fold-search t
1048   "If non-nil, `dired-guess-shell-alist-default' and
1049 `dired-guess-shell-alist-user' are matched case-insensitively."
1050   :group 'dired-x
1051   :type 'boolean)
1052
1053 (defun dired-guess-default (files)
1054   "Guess a shell commands for FILES.  Return command or list of commands.
1055 See `dired-guess-shell-alist-user'."
1056
1057   (let* ((case-fold-search dired-guess-shell-case-fold-search)
1058          ;; Prepend the user's alist to the default alist.
1059          (alist (append dired-guess-shell-alist-user
1060                         dired-guess-shell-alist-default))
1061          (file (car files))
1062          (flist (cdr files))
1063          elt regexp cmds)
1064
1065     ;; Find the first match in the alist for first file in FILES.
1066     (while alist
1067       (setq elt (car alist)
1068             regexp (car elt)
1069             alist (cdr alist))
1070       (if (string-match regexp file)
1071           (setq cmds (cdr elt)
1072                 alist nil)))
1073
1074     ;; If more than one file, see if all of FILES match regular expression.
1075     (while (and flist
1076                 (string-match regexp (car flist)))
1077       (setq flist (cdr flist)))
1078
1079     ;; If flist is still non-nil, then do not guess since this means that not
1080     ;; all the files in FILES were matched by the regexp.
1081     (setq cmds (and (not flist) cmds))
1082
1083     ;; Return commands or nil if flist is still non-nil.
1084     ;; Evaluate the commands in order that any logical testing will be done.
1085     (cond ((not (cdr cmds))
1086            (eval (car cmds))) ; single command
1087           (t
1088            (mapcar (function eval) cmds)))))
1089
1090 (defun dired-guess-shell-command (prompt files)
1091   "Ask user with PROMPT for a shell command, guessing a default from FILES."
1092
1093   (let ((default (dired-guess-default files))
1094         default-list old-history val (failed t))
1095
1096     (if (null default)
1097         ;; Nothing to guess
1098         (read-from-minibuffer prompt nil nil nil 'dired-shell-command-history)
1099
1100       ;; Save current history list
1101       (setq old-history dired-shell-command-history)
1102
1103       (if (listp default)
1104
1105           ;; More than one guess
1106           (setq default-list default
1107                 default (car default)
1108                 prompt (concat
1109                         prompt
1110                         (format "{%d guesses} " (length default-list))))
1111
1112         ;; Just one guess
1113         (setq default-list (list default)))
1114
1115       ;; Push all guesses onto history so that they can be retrieved with M-p
1116       ;; and put the first guess in the prompt but not in the initial value.
1117       (setq dired-shell-command-history
1118             (append default-list dired-shell-command-history)
1119             prompt (concat prompt (format "[%s] " default)))
1120
1121       ;; The unwind-protect returns VAL, and we too.
1122       (unwind-protect
1123           ;; BODYFORM
1124           (progn
1125             (setq val (read-from-minibuffer prompt nil nil nil
1126                                             'dired-shell-command-history)
1127                   failed nil)
1128             ;; If we got a return, then use default.
1129             (if (equal val "")
1130                 (setq val default))
1131             val)
1132
1133         ;; UNWINDFORMS
1134         ;; Undo pushing onto the history list so that an aborted
1135         ;; command doesn't get the default in the next command.
1136         (setq dired-shell-command-history old-history)
1137         (if (not failed)
1138             (or (equal val (car-safe dired-shell-command-history))
1139                 (setq dired-shell-command-history
1140                       (cons val dired-shell-command-history))))))))
1141
1142
1143 ;;; REDEFINE.
1144 ;;; Redefine dired-aux.el's version:
1145 (defun dired-read-shell-command (prompt arg files)
1146   "Read a dired shell command prompting with PROMPT (using read-string).
1147 ARG is the prefix arg and may be used to indicate in the prompt which
1148   files are affected.
1149 This is an extra function so that you can redefine it."
1150   (dired-mark-pop-up
1151    nil 'shell files
1152    'dired-guess-shell-command
1153    (format prompt (dired-mark-prompt arg files)) ; PROMPT
1154    files))                                       ; FILES
1155
1156 \f
1157 ;;; RELATIVE SYMBOLIC LINKS.
1158
1159 (defvar dired-keep-marker-relsymlink ?S
1160   "See variable `dired-keep-marker-move'.")
1161
1162 (defun dired-make-relative-symlink (file1 file2 &optional ok-if-already-exists)
1163   "Make a symbolic link (pointing to FILE1) in FILE2.
1164 The link is relative (if possible), for example
1165
1166     \"/vol/tex/bin/foo\" \"/vol/local/bin/foo\"
1167
1168 results in
1169
1170     \"../../tex/bin/foo\" \"/vol/local/bin/foo\""
1171   (interactive "FRelSymLink: \nFRelSymLink %s: \np")
1172   (let (name1 name2 len1 len2 (index 0) sub)
1173     (setq file1 (expand-file-name file1)
1174           file2 (expand-file-name file2)
1175           len1 (length file1)
1176           len2 (length file2))
1177     ;; Find common initial file name components:
1178     (let (next)
1179       (while (and (setq next (string-match "/" file1 index))
1180                   (setq next (1+ next))
1181                   (< next (min len1 len2))
1182                   ;; For the comparison, both substrings must end in
1183                   ;; `/', so NEXT is *one plus* the result of the
1184                   ;; string-match.
1185                   ;; E.g., consider the case of linking "/tmp/a/abc"
1186                   ;; to "/tmp/abc" erroneously giving "/tmp/a" instead
1187                   ;; of "/tmp/" as common initial component
1188                   (string-equal (substring file1 0 next)
1189                                 (substring file2 0 next)))
1190         (setq index next))
1191       (setq name2 file2
1192             sub (substring file1 0 index)
1193             name1 (substring file1 index)))
1194     (if (string-equal sub "/")
1195         ;; No common initial file name found
1196         (setq name1 file1)
1197       ;; Else they have a common parent directory
1198       (let ((tem (substring file2 index))
1199             (start 0)
1200             (count 0))
1201         ;; Count number of slashes we must compensate for ...
1202         (while (setq start (string-match "/" tem start))
1203           (setq count (1+ count)
1204                 start (1+ start)))
1205         ;; ... and prepend a "../" for each slash found:
1206         (while (> count 0)
1207           (setq count (1- count)
1208                 name1 (concat "../" name1)))))
1209     (make-symbolic-link
1210      (directory-file-name name1)        ; must not link to foo/
1211                                         ; (trailing slash!)
1212      name2 ok-if-already-exists)))
1213
1214 (defun dired-do-relsymlink (&optional arg)
1215    "Relative symlink all marked (or next ARG) files into a directory.
1216 Otherwise make a relative symbolic link to the current file.
1217 This creates relative symbolic links like
1218
1219     foo -> ../bar/foo
1220
1221 not absolute ones like
1222
1223     foo -> /ugly/file/name/that/may/change/any/day/bar/foo"
1224   (interactive "P")
1225   (dired-do-create-files 'relsymlink (function dired-make-relative-symlink)
1226                            "RelSymLink" arg dired-keep-marker-relsymlink))
1227
1228 (defun dired-do-relsymlink-regexp (regexp newname &optional arg whole-name)
1229   "RelSymlink all marked files containing REGEXP to NEWNAME.
1230 See functions `dired-do-rename-regexp' and `dired-do-relsymlink'
1231 for more info."
1232   (interactive (dired-mark-read-regexp "RelSymLink"))
1233   (dired-do-create-files-regexp
1234    (function dired-make-relative-symlink)
1235    "RelSymLink" arg regexp newname whole-name dired-keep-marker-relsymlink))
1236
1237 \f
1238 ;;; VISIT ALL MARKED FILES SIMULTANEOUSLY.
1239
1240 ;;; Brief Description:
1241 ;;;
1242 ;;; `dired-do-find-marked-files' is bound to `F' by dired-x.el.
1243 ;;;
1244 ;;; * Use `dired-get-marked-files' to collect the marked files in the current
1245 ;;;   Dired Buffer into a list of filenames `FILE-LIST'.
1246 ;;;
1247 ;;; * Pass FILE-LIST to `dired-simultaneous-find-file' all with
1248 ;;;   `dired-do-find-marked-files''s prefix argument NOSELECT.
1249 ;;;
1250 ;;; * `dired-simultaneous-find-file' runs through FILE-LIST decrementing the
1251 ;;;   list each time.
1252 ;;;
1253 ;;; * If NOSELECT is non-nil then just run `find-file-noselect'  on each
1254 ;;;   element of FILE-LIST.
1255 ;;;
1256 ;;; * If NOSELECT is nil then calculate the `size' of the window for each file
1257 ;;;   by dividing the `window-height' by length of FILE-LIST.  Thus, `size' is
1258 ;;;   cognizant of the window-configuration.
1259 ;;;
1260 ;;; * If `size' is too small abort, otherwise run `find-file' on each element
1261 ;;;   of FILE-LIST giving each a window of height `size'.
1262
1263 (defun dired-do-find-marked-files (&optional noselect)
1264   "Find all marked files displaying all of them simultaneously.
1265 With optional NOSELECT just find files but do not select them.
1266
1267 The current window is split across all files marked, as evenly as possible.
1268 Remaining lines go to bottom-most window.  The number of files that can be
1269 displayed this way is restricted by the height of the current window and
1270 `window-min-height'.
1271
1272 To keep dired buffer displayed, type \\[split-window-vertically] first.
1273 To display just marked files, type \\[delete-other-windows] first."
1274
1275   (interactive "P")
1276   (dired-simultaneous-find-file (dired-get-marked-files) noselect))
1277
1278 (defun dired-simultaneous-find-file (file-list noselect)
1279
1280   "Visit all files in FILE-LIST and display them simultaneously.
1281 The current window is split across all files in FILE-LIST, as evenly as
1282 possible.  Remaining lines go to the bottom-most window.  The number of
1283 files that can be displayed this way is restricted by the height of the
1284 current window and the variable `window-min-height'.  With non-nil
1285 NOSELECT the files are merely found but not selected."
1286
1287   ;; We don't make this function interactive because it is usually too clumsy
1288   ;; to specify FILE-LIST interactively unless via dired.
1289
1290   (let (size)
1291
1292     (if noselect
1293         ;; Do not select the buffer.
1294         (find-file-noselect (car file-list))
1295
1296       ;; We will have to select the buffer.  Calculate and check window size.
1297       (setq size (/ (window-height) (length file-list)))
1298       (or (<= window-min-height size)
1299           (error "Too many files to visit simultaneously.  Try C-u prefix"))
1300       (find-file (car file-list)))
1301
1302     ;; Decrement.
1303     (setq file-list (cdr file-list))
1304
1305     (while file-list
1306
1307       (if noselect
1308           ;; Do not select the buffer.
1309           (find-file-noselect (car file-list))
1310
1311         ;; Vertically split off a window of desired size.  Upper window will
1312         ;; have SIZE lines.  Select lower (larger) window.  We split it again.
1313         (select-window (split-window nil size))
1314         (find-file (car file-list)))
1315
1316       ;; Decrement.
1317       (setq file-list (cdr file-list)))))
1318
1319 \f
1320 ;;; MISCELLANEOUS COMMANDS.
1321
1322 ;;; Run man on files.
1323
1324 (defun dired-man ()
1325   "Run man on this file.  Display old buffer if buffer name matches filename.
1326 Uses `man.el' of \\[manual-entry] fame."
1327   (interactive)
1328   (require 'man)
1329   (let* ((file (dired-get-filename))
1330          (manual-program (replace-regexp-in-string "\\*" "%s"
1331                           (dired-guess-shell-command
1332                            "Man command: " (list file)))))
1333     (Man-getpage-in-background file)))
1334
1335 ;;; Run Info on files.
1336
1337 (defun dired-info ()
1338   "Run info on this file."
1339   (interactive)
1340   (info (dired-get-filename)))
1341
1342 ;;; Run mail on mail folders.
1343
1344 ;;; (and (not (fboundp 'vm-visit-folder))
1345 ;;;      (defun vm-visit-folder (file &optional arg)
1346 ;;;        nil))
1347
1348 (defun dired-vm (&optional read-only)
1349   "Run VM on this file.
1350 With prefix arg, visit folder read-only (this requires at least VM 5).
1351 See also variable `dired-vm-read-only-folders'."
1352   (interactive "P")
1353   (let ((dir (dired-current-directory))
1354         (fil (dired-get-filename)))
1355     ;; take care to supply 2nd arg only if requested - may still run VM 4!
1356     (cond (read-only (vm-visit-folder fil t))
1357           ((eq t dired-vm-read-only-folders) (vm-visit-folder fil t))
1358           ((null dired-vm-read-only-folders) (vm-visit-folder fil))
1359           (t (vm-visit-folder fil (not (file-writable-p fil)))))
1360     ;; so that pressing `v' inside VM does prompt within current directory:
1361     (set (make-local-variable 'vm-folder-directory) dir)))
1362
1363 (defun dired-rmail ()
1364   "Run RMAIL on this file."
1365   (interactive)
1366   (rmail (dired-get-filename)))
1367
1368 (defun dired-do-run-mail ()
1369   "If `dired-bind-vm' is t, then function `dired-vm', otherwise `dired-rmail'."
1370   (interactive)
1371   (if dired-bind-vm
1372       ;; Read mail folder using vm.
1373       (dired-vm)
1374     ;; Read mail folder using rmail.
1375     (dired-rmail)))
1376
1377 \f
1378 ;;; MISCELLANEOUS INTERNAL FUNCTIONS.
1379
1380 (or (fboundp 'dired-old-find-buffer-nocreate)
1381     (fset 'dired-old-find-buffer-nocreate
1382           (symbol-function 'dired-find-buffer-nocreate)))
1383
1384 ;;; REDEFINE.
1385 ;;; Redefines dired.el's version of `dired-find-buffer-nocreate'
1386 (defun dired-find-buffer-nocreate (dirname &optional mode)
1387   (if (and dired-find-subdir
1388            ;; don't try to find a wildcard as a subdirectory
1389            (string-equal dirname (file-name-directory dirname)))
1390       (let* ((cur-buf (current-buffer))
1391              (buffers (nreverse
1392                        (dired-buffers-for-dir (expand-file-name dirname))))
1393              (cur-buf-matches (and (memq cur-buf buffers)
1394                                    ;; wildcards must match, too:
1395                                    (equal dired-directory dirname))))
1396         ;; We don't want to switch to the same buffer---
1397         (setq buffers (delq cur-buf buffers));;need setq with delq
1398         (or (car (sort buffers (function dired-buffer-more-recently-used-p)))
1399             ;; ---unless it's the only possibility:
1400             (and cur-buf-matches cur-buf)))
1401     (dired-old-find-buffer-nocreate dirname mode)))
1402
1403 ;; This should be a builtin
1404 (defun dired-buffer-more-recently-used-p (buffer1 buffer2)
1405   "Return t if BUFFER1 is more recently used than BUFFER2."
1406   (if (equal buffer1 buffer2)
1407       nil
1408     (let ((more-recent nil)
1409           (list (buffer-list)))
1410       (while (and list
1411                   (not (setq more-recent (equal buffer1 (car list))))
1412                   (not (equal buffer2 (car list))))
1413         (setq list (cdr list)))
1414       more-recent)))
1415
1416 ;;; Same thing as `dired-buffers-for-dir' of dired.el? - lrd 11/23/93
1417 ;;; (defun dired-buffers-for-dir-exact (dir)
1418 ;;; ;; Return a list of buffers that dired DIR (a directory or wildcard)
1419 ;;; ;; at top level, or as subdirectory.
1420 ;;; ;; Top level matches must match the wildcard part too, if any.
1421 ;;; ;; The list is in reverse order of buffer creation, most recent last.
1422 ;;; ;; As a side effect, killed dired buffers for DIR are removed from
1423 ;;; ;; dired-buffers.
1424 ;;;   (let ((alist dired-buffers) result elt)
1425 ;;;     (while alist
1426 ;;;       (setq elt (car alist)
1427 ;;;             alist (cdr alist))
1428 ;;;       (let ((buf (cdr elt)))
1429 ;;;         (if (buffer-name buf)
1430 ;;;             ;; Top level must match exactly against dired-directory in
1431 ;;;             ;; case one of them is a wildcard.
1432 ;;;             (if (or (equal dir (save-excursion (set-buffer buf)
1433 ;;;                                                dired-directory))
1434 ;;;                     (assoc dir (save-excursion (set-buffer buf)
1435 ;;;                                                dired-subdir-alist)))
1436 ;;;                 (setq result (cons buf result)))
1437 ;;;           ;; else buffer is killed - clean up:
1438 ;;;           (setq dired-buffers (delq elt dired-buffers)))))
1439 ;;;     result))
1440
1441 ;;; REDEFINE.
1442 ;;; Redefines dired.el's version of `dired-initial-position'
1443 (defun dired-initial-position (dirname)
1444   "Where point should go in a new listing of DIRNAME.
1445 Point assumed at beginning of new subdir line.
1446 You may redefine this function as you wish, e.g. like in `dired-x.el'."
1447   (end-of-line)
1448   (if dired-find-subdir (dired-goto-subdir dirname)) ; new
1449   (if dired-trivial-filenames (dired-goto-next-nontrivial-file)))
1450
1451 \f
1452 ;; Does anyone use this? - lrd 6/29/93.
1453 ;; Apparently people do use it. - lrd 12/22/97.
1454 (defun dired-mark-sexp (predicate &optional unflag-p)
1455   "Mark files for which PREDICATE returns non-nil.
1456 With a prefix arg, unflag those files instead.
1457
1458 PREDICATE is a lisp expression that can refer to the following symbols:
1459
1460     inode  [integer] the inode of the file (only for ls -i output)
1461     s      [integer] the size of the file for ls -s output
1462                      (usually in blocks or, with -k, in KByte)
1463     mode   [string]  file permission bits, e.g. \"-rw-r--r--\"
1464     nlink  [integer] number of links to file
1465     uid    [string]  owner
1466     gid    [string]  group  (If the gid is not displayed by ls,
1467                      this will still be set (to the same as uid))
1468     size   [integer] file size in bytes
1469     time   [string]  the time that ls displays, e.g. \"Feb 12 14:17\"
1470     name   [string]  the name of the file
1471     sym    [string]  if file is a symbolic link, the linked-to name, else \"\"
1472
1473 For example, use
1474
1475         (equal 0 size)
1476
1477 to mark all zero length files."
1478   ;; Using sym="" instead of nil avoids the trap of
1479   ;; (string-match "foo" sym) into which a user would soon fall.
1480   ;; Give `equal' instead of `=' in the example, as this works on
1481   ;; integers and strings.
1482   (interactive "xMark if (lisp expr): \nP")
1483   (message "%s" predicate)
1484   (let ((dired-marker-char (if unflag-p ?\040 dired-marker-char))
1485         inode s mode nlink uid gid size time name sym)
1486     (dired-mark-if
1487      (save-excursion
1488        (and
1489         ;; Sets vars
1490         ;;                inode s mode nlink uid gid size time name sym
1491
1492         ;; according to current file line.  Returns t for success, nil if
1493         ;; there is no file line.  Upon success, all variables are set, either
1494         ;; to nil or the appropriate value, so they need not be initialized.
1495         ;; Moves point within the current line.
1496         (if (dired-move-to-filename)
1497             (let (pos
1498                   (mode-len 10) ; length of mode string
1499                   ;; like in dired.el, but with subexpressions \1=inode, \2=s:
1500                   (dired-re-inode-size "\\s *\\([0-9]*\\)\\s *\\([0-9]*\\) ?"))
1501               (beginning-of-line)
1502               (forward-char 2)
1503               (if (looking-at dired-re-inode-size)
1504                   (progn
1505                     (goto-char (match-end 0))
1506                     (setq inode (string-to-number (buffer-substring (match-beginning 1)
1507                                                                     (match-end 1)))
1508                           s (string-to-number (buffer-substring (match-beginning 2)
1509                                                                 (match-end 2)))))
1510                 (setq inode nil
1511                       s nil))
1512               (setq mode (buffer-substring (point) (+ mode-len (point))))
1513               (forward-char mode-len)
1514               (setq nlink (read (current-buffer)))
1515               ;; Karsten Wenger <kw@cis.uni-muenchen.de> fixed uid.
1516               (setq uid (buffer-substring (+ (point) 1)
1517                                           (progn (forward-word 1) (point))))
1518               (re-search-forward dired-move-to-filename-regexp)
1519               (goto-char (match-beginning 1))
1520               (forward-char -1)
1521               (setq size (string-to-number (buffer-substring (save-excursion
1522                                                                (backward-word 1)
1523                                                                (setq pos (point)))
1524                                                              (point))))
1525               (goto-char pos)
1526               (backward-word 1)
1527               ;; if no gid is displayed, gid will be set to uid
1528               ;; but user will then not reference it anyway in PREDICATE.
1529               (setq gid (buffer-substring (save-excursion
1530                                             (forward-word 1) (point))
1531                                           (point))
1532                     time (buffer-substring (match-beginning 1)
1533                                            (1- (dired-move-to-filename)))
1534                     name (buffer-substring (point)
1535                                            (or
1536                                             (dired-move-to-end-of-filename t)
1537                                             (point)))
1538                     sym  (progn
1539                            (if (looking-at " -> ")
1540                                (buffer-substring
1541                                 (progn (forward-char 4) (point))
1542                                 (progn (end-of-line) (point)))
1543                              "")))
1544               t)
1545           nil)
1546                       (eval predicate)))
1547      (format "'%s file" predicate))))
1548
1549 \f
1550 ;;; FIND FILE AT POINT.
1551
1552 (defvar dired-x-hands-off-my-keys t
1553   "*Non-nil means don't bind `dired-x-find-file' over `find-file' on keyboard.
1554 Similarly for `dired-x-find-file-other-window' over `find-file-other-window'.
1555 If you change this variable after `dired-x.el' is loaded then do
1556 \\[dired-x-bind-find-file].")
1557
1558 ;;; Bind `dired-x-find-file{-other-window}' over wherever
1559 ;;; `find-file{-other-window}' is bound?
1560 (defun dired-x-bind-find-file ()
1561   "Bind `dired-x-find-file' in place of `find-file' \(or reverse\).
1562 Similarly for `dired-x-find-file-other-window' and `find-file-other-window'.
1563 Binding direction based on `dired-x-hands-off-my-keys'.
1564 This function is part of `after-init-hook'."
1565   (interactive)
1566   (if (interactive-p)
1567       (setq dired-x-hands-off-my-keys
1568             (not (y-or-n-p "Bind dired-x-find-file over find-file? "))))
1569   (cond ((not dired-x-hands-off-my-keys)
1570          (substitute-key-definition 'find-file
1571                                     'dired-x-find-file
1572                                     (current-global-map))
1573          (substitute-key-definition 'find-file-other-window
1574                                     'dired-x-find-file-other-window
1575                                     (current-global-map)))
1576         (t
1577          (substitute-key-definition 'dired-x-find-file
1578                                     'find-file
1579                                     (current-global-map))
1580          (substitute-key-definition 'dired-x-find-file-other-window
1581                                     'find-file-other-window
1582                                     (current-global-map))))
1583   ;; Clear mini-buffer.
1584   (message nil))
1585
1586 ;;; Now call it so binding is correct and put on `after-init-hook' in case
1587 ;;; user changes binding.
1588 (dired-x-bind-find-file)
1589 (add-hook 'after-init-hook 'dired-x-bind-find-file)
1590
1591 (defun dired-x-find-file (filename)
1592   "Edit file FILENAME.
1593 May create a new window, or reuse an existing one.
1594 See the function `display-buffer'.
1595
1596 Identical to `find-file' except when called interactively, with a prefix arg
1597 \(e.g., \\[universal-argument]\), in which case it guesses filename near point.
1598 Useful for editing file mentioned in buffer you are viewing,
1599 or to test if that file exists.  Use minibuffer after snatching filename."
1600   (interactive (list (read-filename-at-point "Find file: ")))
1601   (find-file (expand-file-name filename)))
1602
1603 (defun dired-x-find-file-other-window (filename)
1604   "Edit file FILENAME, in another window.
1605 May create a new window, or reuse an existing one.
1606 See the function `display-buffer'.
1607
1608 Identical to `find-file-other-window' except when called interactively, with a
1609 prefix arg \(e.g., \\[universal-argument]\), in which case it guesses filename near point.
1610 Useful for editing file mentioned in buffer you are viewing,
1611 or to test if that file exists.  Use minibuffer after snatching filename."
1612   (interactive (list (read-filename-at-point "Find file: ")))
1613   (find-file-other-window (expand-file-name filename)))
1614
1615 ;;; Internal functions.
1616
1617 ;; Fixme: This should probably use `thing-at-point'.  -- fx
1618 (defun dired-filename-at-point ()
1619   "Get the filename closest to point, but do not change position.
1620 Has a preference for looking backward when not directly on a symbol.  Not
1621 perfect - point must be in middle of or end of filename."
1622
1623   (let ((filename-chars "-.[:alnum:]_/:$+@")
1624         start end filename prefix)
1625
1626     (save-excursion
1627       ;; First see if just past a filename.
1628       (if (not (eobp))
1629           (if (looking-at "[] \t\n[{}()]") ; whitespace or some parens
1630               (progn
1631                 (skip-chars-backward " \n\t\r({[]})")
1632                 (if (not (bobp))
1633                     (backward-char 1)))))
1634
1635       (if (string-match (concat "[" filename-chars "]")
1636                         (char-to-string (following-char)))
1637           (progn
1638             (if (re-search-backward (concat "[^" filename-chars "]") nil t)
1639                 (forward-char)
1640               (goto-char (point-min)))
1641             (setq start (point))
1642             (setq prefix
1643                   (and (string-match
1644                         "^\\w+@"
1645                         (buffer-substring start (line-beginning-position)))
1646                        "/"))
1647             (goto-char start)
1648             (if (string-match "[/~]" (char-to-string (preceding-char)))
1649                 (setq start (1- start)))
1650             (re-search-forward (concat "\\=[" filename-chars "]*") nil t))
1651
1652         (error "No file found around point!"))
1653
1654       ;; Return string.
1655       (expand-file-name (concat prefix (buffer-substring start (point)))))))
1656
1657 (defun read-filename-at-point (prompt)
1658   "Return filename prompting with PROMPT with completion.
1659 If `current-prefix-arg' is non-nil, uses name at point as guess."
1660   (if current-prefix-arg
1661       (let ((guess (dired-filename-at-point)))
1662         (read-file-name prompt
1663                         (file-name-directory guess)
1664                         guess
1665                         nil (file-name-nondirectory guess)))
1666     (read-file-name prompt default-directory)))
1667 \f
1668 ;;; BUG REPORTS
1669
1670 ;; Fixme: get rid of this later.
1671
1672 ;;; This section is provided for reports.  It uses Barry A. Warsaw's
1673 ;;; reporter.el which is bundled with GNU Emacs v19.
1674
1675 (defconst dired-x-help-address "bug-gnu-emacs@gnu.org"
1676   "Address(es) accepting submission of reports on dired-x.el.")
1677
1678 (defconst dired-x-variable-list
1679   (list
1680    'dired-bind-vm
1681    'dired-vm-read-only-folders
1682    'dired-bind-jump
1683    'dired-bind-info
1684    'dired-bind-man
1685    'dired-find-subdir
1686    'dired-enable-local-variables
1687    'dired-local-variables-file
1688    'dired-guess-shell-gnutar
1689    'dired-guess-shell-gzip-quiet
1690    'dired-guess-shell-znew-switches
1691    'dired-guess-shell-alist-user
1692    'dired-clean-up-buffers-too
1693    'dired-omit-mode
1694    'dired-omit-files
1695    'dired-omit-extensions
1696    )
1697   "List of variables to be appended to reports sent by `dired-x-submit-report'.")
1698
1699 (defun dired-x-submit-report ()
1700   "Submit via `reporter.el' a bug report on program.
1701 Send report on `dired-x-file' version `dired-x-version,' to
1702 `dired-x-maintainer' at address `dired-x-help-address' listing
1703 variables `dired-x-variable-list' in the message."
1704   (interactive)
1705
1706   (reporter-submit-bug-report
1707    dired-x-help-address                 ; address
1708    "dired-x"                            ; pkgname
1709    dired-x-variable-list                ; varlist
1710    nil nil                              ; pre-/post-hooks
1711    ""))
1712
1713 \f
1714 ;; As Barry Warsaw would say: "This might be useful..."
1715 (provide 'dired-x)
1716
1717 ;;; arch-tag: 71a43ba2-7a00-4793-a028-0613dd7765ae
1718 ;;; dired-x.el ends here