code.delx.au - gnu-emacs/blob - lisp/x-dnd.el

   1 ;;; x-dnd.el --- drag and drop support for X.
   2
   3 ;; Copyright (C) 2004, 2005 Free Software Foundation, Inc.
   4
   5 ;; Author: Jan Dj\e,Ad\e(Brv <jan.h.d@swipnet.se>
   6 ;; Maintainer: FSF
   7 ;; Keywords: window, drag, drop
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 ;; Boston, MA 02110-1301, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; This file provides the drop part only.  Currently supported protocols
  29 ;; are XDND, Motif and the old KDE 1.x protocol.
  30
  31 ;;; Code:
  32
  33 (require 'dnd)
  34
  35 ;;; Customizable variables
  36 (defcustom x-dnd-test-function 'x-dnd-default-test-function
  37   "The function drag and drop uses to determine if to accept or reject a drop.
  38 The function takes three arguments, WINDOW ACTION and TYPES.
  39 WINDOW is where the mouse is when the function is called.  WINDOW may be a
  40 frame if the mouse isn't over a real window (i.e. menu bar, tool bar or
  41 scroll bar).  ACTION is the suggested action from the drag and drop source,
  42 one of the symbols move, copy link or ask.  TYPES is a list of available types
  43 for the drop.
  44
  45 The function shall return nil to reject the drop or a cons with two values,
  46 the wanted action as car and the wanted type as cdr.  The wanted action
  47 can be copy, move, link, ask or private.
  48 The default value for this variable is `x-dnd-default-test-function'."
  49   :version "22.1"
  50   :type 'symbol
  51   :group 'x)
  52
  53
  54
  55 (defcustom x-dnd-types-alist
  56   '(
  57     ("text/uri-list" . x-dnd-handle-uri-list)
  58     ("text/x-moz-url" . x-dnd-handle-moz-url)
  59     ("_NETSCAPE_URL" . x-dnd-handle-uri-list)
  60     ("FILE_NAME" . x-dnd-handle-file-name)
  61     ("UTF8_STRING" . x-dnd-insert-utf8-text)
  62     ("text/plain;charset=UTF-8" . x-dnd-insert-utf8-text)
  63     ("text/plain;charset=utf-8" . x-dnd-insert-utf8-text)
  64     ("text/unicode" . x-dnd-insert-utf16-text)
  65     ("text/plain" . dnd-insert-text)
  66     ("COMPOUND_TEXT" . x-dnd-insert-ctext)
  67     ("STRING" . dnd-insert-text)
  68     ("TEXT"   . dnd-insert-text)
  69     )
  70   "Which function to call to handle a drop of that type.
  71 If the type for the drop is not present, or the function is nil,
  72 the drop is rejected.  The function takes three arguments, WINDOW, ACTION
  73 and DATA.  WINDOW is where the drop occured, ACTION is the action for
  74 this drop (copy, move, link, private or ask) as determined by a previous
  75 call to `x-dnd-test-function'.  DATA is the drop data.
  76 The function shall return the action used (copy, move, link or private) if drop
  77 is successful, nil if not."
  78   :version "22.1"
  79   :type 'alist
  80   :group 'x)
  81
  82 (defcustom x-dnd-known-types
  83   '("text/uri-list"
  84     "text/x-moz-url"
  85     "_NETSCAPE_URL"
  86     "FILE_NAME"
  87     "UTF8_STRING"
  88     "text/plain;charset=UTF-8"
  89     "text/plain;charset=utf-8"
  90     "text/unicode"
  91     "text/plain"
  92     "COMPOUND_TEXT"
  93     "STRING"
  94     "TEXT"
  95     )
  96   "The types accepted by default for dropped data.
  97 The types are chosen in the order they appear in the list."
  98   :version "22.1"
  99   :type '(repeat string)
 100   :group 'x
 101 )
 102
 103 ;; Internal variables
 104
 105 (defvar x-dnd-current-state nil
 106   "The current state for a drop.
 107 This is an alist with one entry for each display.  The value for each display
 108 is a vector that contains the state for drag and drop for that display.
 109 Elements in the vector are:
 110 Last buffer drag was in,
 111 last window drag was in,
 112 types available for drop,
 113 the action suggested by the source,
 114 the type we want for the drop,
 115 the action we want for the drop,
 116 any protocol specific data.")
 117
 118 (defvar x-dnd-empty-state [nil nil nil nil nil nil nil])
 119
 120
 121
 122 (defun x-dnd-init-frame (&optional frame)
 123   "Setup drag and drop for FRAME (i.e. create appropriate properties)."
 124   (x-dnd-init-xdnd-for-frame frame)
 125   (x-dnd-init-motif-for-frame frame))
 126
 127 (defun x-dnd-get-state-cons-for-frame (frame-or-window)
 128   "Return the entry in x-dnd-current-state for a frame or window."
 129   (let* ((frame (if (framep frame-or-window) frame-or-window
 130                   (window-frame frame-or-window)))
 131          (display (frame-parameter frame 'display)))
 132     (if (not (assoc display x-dnd-current-state))
 133         (push (cons display (copy-sequence x-dnd-empty-state))
 134               x-dnd-current-state))
 135     (assoc display x-dnd-current-state)))
 136
 137 (defun x-dnd-get-state-for-frame (frame-or-window)
 138   "Return the state in x-dnd-current-state for a frame or window."
 139   (cdr (x-dnd-get-state-cons-for-frame frame-or-window)))
 140
 141 (defun x-dnd-default-test-function (window action types)
 142   "The default test function for drag and drop.
 143 WINDOW is where the mouse is when this function is called.  It may be a frame
 144 if the mouse is over the menu bar, scroll bar or tool bar.
 145 ACTION is the suggested action from the source, and TYPES are the
 146 types the drop data can have.  This function only accepts drops with
 147 types in `x-dnd-known-types'.  It always returns the action private."
 148   (let ((type (x-dnd-choose-type types)))
 149     (when type (cons 'private type))))
 150
 151
 152 (defun x-dnd-current-type (frame-or-window)
 153   "Return the type we want the DND data to be in for the current drop.
 154 FRAME-OR-WINDOW is the frame or window that the mouse is over."
 155   (aref (x-dnd-get-state-for-frame frame-or-window) 4))
 156
 157 (defun x-dnd-forget-drop (frame-or-window)
 158   "Remove all state for the last drop.
 159 FRAME-OR-WINDOW is the frame or window that the mouse is over."
 160   (setcdr (x-dnd-get-state-cons-for-frame frame-or-window)
 161           (copy-sequence x-dnd-empty-state)))
 162
 163 (defun x-dnd-maybe-call-test-function (window action)
 164   "Call `x-dnd-test-function' if something has changed.
 165 WINDOW is the window the mouse is over.  ACTION is the suggested
 166 action from the source.  If nothing has changed, return the last
 167 action and type we got from `x-dnd-test-function'."
 168   (let ((buffer (when (and (windowp window) (window-live-p window))
 169                   (window-buffer window)))
 170         (current-state (x-dnd-get-state-for-frame window)))
 171     (when (or (not (equal buffer (aref current-state 0)))
 172               (not (equal window (aref current-state 1)))
 173               (not (equal action (aref current-state 3))))
 174       (save-excursion
 175         (when buffer (set-buffer buffer))
 176         (let* ((action-type (funcall x-dnd-test-function
 177                                      window
 178                                      action
 179                                      (aref current-state 2)))
 180                (handler (cdr (assoc (cdr action-type) x-dnd-types-alist))))
 181           ;; Ignore action-type if we have no handler.
 182           (setq current-state
 183                 (x-dnd-save-state window
 184                                   action
 185                                   (when handler action-type)))))))
 186   (let ((current-state (x-dnd-get-state-for-frame window)))
 187     (cons (aref current-state 5)
 188           (aref current-state 4))))
 189
 190 (defun x-dnd-save-state (window action action-type &optional types extra-data)
 191   "Save the state of the current drag and drop.
 192 WINDOW is the window the mouse is over.  ACTION is the action suggested
 193 by the source.  ACTION-TYPE is the result of calling `x-dnd-test-function'.
 194 If given, TYPES are the types for the drop data that the source supports.
 195 EXTRA-DATA is data needed for a specific protocol."
 196   (let ((current-state (x-dnd-get-state-for-frame window)))
 197     (aset current-state 5 (car action-type))
 198     (aset current-state 4 (cdr action-type))
 199     (aset current-state 3 action)
 200     (when types (aset current-state 2 types))
 201     (when extra-data (aset current-state 6 extra-data))
 202     (aset current-state 1 window)
 203     (aset current-state 0 (if (and (windowp window)
 204                                    (window-live-p window))
 205                               (window-buffer window) nil))
 206     (setcdr (x-dnd-get-state-cons-for-frame window) current-state)))
 207
 208
 209 (defun x-dnd-handle-moz-url (window action data)
 210   "Handle one item of type text/x-moz-url.
 211 WINDOW is the window where the drop happened.  ACTION is ignored.
 212 DATA is the moz-url, which is formatted as two strings separated by \r\n.
 213 The first string is the URL, the second string is the title of that URL.
 214 DATA is encoded in utf-16.  Decode the URL and call `x-dnd-handle-uri-list'."
 215   ;; Mozilla and applications based on it (Galeon for example) uses
 216   ;; text/unicode, but it is impossible to tell if it is le or be.  Use what
 217   ;; the machine Emacs runs on use.  This looses if dropping between machines
 218   ;; with different endian, but it is the best we can do.
 219   (let* ((coding (if (eq (byteorder) ?B) 'utf-16be 'utf-16le))
 220          (string (decode-coding-string data coding))
 221          (strings (split-string string "[\r\n]" t))
 222          ;; Can one drop more than one moz-url ??  Assume not.
 223          (url (car strings))
 224          (title (car (cdr strings))))
 225     (x-dnd-handle-uri-list window action url)))
 226
 227 (defun x-dnd-insert-utf8-text (window action text)
 228   "Decode the UTF-8 text and insert it at point.
 229 TEXT is the text as a string, WINDOW is the window where the drop happened."
 230   (dnd-insert-text window action (decode-coding-string text 'utf-8)))
 231
 232 (defun x-dnd-insert-utf16-text (window action text)
 233   "Decode the UTF-16 text and insert it at point.
 234 TEXT is the text as a string, WINDOW is the window where the drop happened."
 235   ;; See comment in x-dnd-handle-moz-url about coding.
 236   (let ((coding (if (eq (byteorder) ?B) 'utf-16be 'utf-16le)))
 237     (dnd-insert-text window action (decode-coding-string text coding))))
 238
 239 (defun x-dnd-insert-ctext (window action text)
 240   "Decode the compound text and insert it at point.
 241 TEXT is the text as a string, WINDOW is the window where the drop happened."
 242   (dnd-insert-text window action
 243                    (decode-coding-string text
 244                                          'compound-text-with-extensions)))
 245
 246 (defun x-dnd-handle-uri-list (window action string)
 247   "Split an uri-list into separate URIs and call `dnd-handle-one-url'.
 248 WINDOW is the window where the drop happened.
 249 STRING is the uri-list as a string.  The URIs are separated by \r\n."
 250   (let ((uri-list (split-string string "[\0\r\n]" t))
 251         retval)
 252     (dolist (bf uri-list)
 253       ;; If one URL is handeled, treat as if the whole drop succeeded.
 254       (let ((did-action (dnd-handle-one-url window action bf)))
 255         (when did-action (setq retval did-action))))
 256     retval))
 257
 258 (defun x-dnd-handle-file-name (window action string)
 259   "Prepend file:// to file names and call `dnd-handle-one-url'.
 260 WINDOW is the window where the drop happened.
 261 STRING is the file names as a string, separated by nulls."
 262   (let ((uri-list (split-string string "[\0\r\n]" t))
 263         retval)
 264     (dolist (bf uri-list)
 265       ;; If one URL is handeled, treat as if the whole drop succeeded.
 266       (let* ((file-uri (concat "file://" bf))
 267              (did-action (dnd-handle-one-url window action file-uri)))
 268         (when did-action (setq retval did-action))))
 269     retval))
 270
 271
 272 (defun x-dnd-choose-type (types &optional known-types)
 273   "Choose which type we want to receive for the drop.
 274 TYPES are the types the source of the drop offers, a vector of type names
 275 as strings or symbols.  Select among the types in `x-dnd-known-types' or
 276 KNOWN-TYPES if given,  and return that type name.
 277 If no suitable type is found, return nil."
 278   (let* ((known-list (or known-types x-dnd-known-types))
 279          (first-known-type (car known-list))
 280          (types-array types)
 281          (found (when first-known-type
 282                   (catch 'done
 283                     (dotimes (i (length types-array))
 284                       (let* ((type (aref types-array i))
 285                              (typename (if (symbolp type)
 286                                            (symbol-name type) type)))
 287                         (when (equal first-known-type typename)
 288                           (throw 'done first-known-type))))
 289                     nil))))
 290
 291     (if (and (not found) (cdr known-list))
 292         (x-dnd-choose-type types (cdr known-list))
 293       found)))
 294
 295 (defun x-dnd-drop-data (event frame window data type)
 296   "Drop one data item onto a frame.
 297 EVENT is the client message for the drop, FRAME is the frame the drop occurred
 298 on.  WINDOW is the window of FRAME where the drop happened.  DATA is the data
 299 received from the source, and type is the type for DATA, see
 300 `x-dnd-types-alist').
 301
 302 Returns the action used (move, copy, link, private) if drop was successful,
 303 nil if not."
 304   (let* ((type-info (assoc type x-dnd-types-alist))
 305          (handler (cdr type-info))
 306          (state (x-dnd-get-state-for-frame frame))
 307          (action (aref state 5))
 308          (w (posn-window (event-start event))))
 309     (when handler
 310       (if (and (windowp w) (window-live-p w))
 311           ;; If dropping in a window, open files in that window rather
 312           ;; than in a new widow.
 313           (let ((dnd-open-file-other-window nil))
 314             (goto-char (posn-point (event-start event)))
 315             (funcall handler window action data))
 316         (let ((dnd-open-file-other-window t))  ;; Dropping on non-window.
 317           (select-frame frame)
 318           (funcall handler window action data))))))
 319
 320 (defun x-dnd-handle-drag-n-drop-event (event)
 321   "Receive drag and drop events (X client messages).
 322 Currently XDND, Motif and old KDE 1.x protocols are recognized."
 323   (interactive "e")
 324   (let* ((client-message (car (cdr (cdr event))))
 325          (window (posn-window (event-start event)))
 326          (message-atom (aref client-message 0))
 327          (frame (aref client-message 1))
 328          (format (aref client-message 2))
 329          (data (aref client-message 3)))
 330
 331     (cond ((equal "DndProtocol" message-atom)   ; Old KDE 1.x.
 332            (x-dnd-handle-old-kde event frame window message-atom format data))
 333
 334           ((equal "_MOTIF_DRAG_AND_DROP_MESSAGE" message-atom)  ; Motif
 335            (x-dnd-handle-motif event frame window message-atom format data))
 336
 337           ((and (> (length message-atom) 4)     ; XDND protocol.
 338                 (equal "Xdnd" (substring message-atom 0 4)))
 339            (x-dnd-handle-xdnd event frame window message-atom format data)))))
 340
 341
 342 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 343 ;;;  Old KDE protocol.  Only dropping of files.
 344
 345 (defun x-dnd-handle-old-kde (event frame window message format data)
 346   "Open the files in a KDE 1.x drop."
 347   (let ((values (x-window-property "DndSelection" frame nil 0 t)))
 348     (x-dnd-handle-uri-list window 'private
 349                            (replace-regexp-in-string "\0$" "" values))))
 350 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 351
 352
 353
 354 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 355 ;;;  XDND protocol.
 356
 357 (defvar x-dnd-xdnd-to-action
 358   '(("XdndActionPrivate" . private)
 359     ("XdndActionCopy" . copy)
 360     ("XdndActionMove" . move)
 361     ("XdndActionLink" . link)
 362     ("XdndActionAsk" . ask))
 363   "Mapping from XDND action types to lisp symbols.")
 364
 365 (defun x-dnd-init-xdnd-for-frame (frame)
 366   "Set the XdndAware property for FRAME to indicate that we do XDND."
 367   (x-change-window-property "XdndAware"
 368                             '(5)        ;; The version of XDND we support.
 369                             frame "ATOM" 32 t))
 370
 371 (defun x-dnd-get-drop-width-height (frame w accept)
 372   "Return the widht/height to be sent in a XDndStatus message.
 373 FRAME is the frame and W is the window where the drop happened.
 374 If ACCEPT is nil return 0 (empty rectangle),
 375 otherwise if W is a window, return its widht/height,
 376 otherwise return the frame width/height."
 377   (if accept
 378       (if (windowp w)   ;; w is not a window if dropping on the menu bar,
 379                         ;; scroll bar or tool bar.
 380           (let ((edges (window-inside-pixel-edges w)))
 381             (cons
 382              (- (nth 2 edges) (nth 0 edges))    ;; right - left
 383              (- (nth 3 edges) (nth 1 edges))))  ;; bottom - top
 384         (cons (frame-pixel-width frame)
 385               (frame-pixel-height frame)))
 386     0))
 387
 388 (defun x-dnd-get-drop-x-y (frame w)
 389   "Return the x/y coordinates to be sent in a XDndStatus message.
 390 Coordinates are required to be absolute.
 391 FRAME is the frame and W is the window where the drop happened.
 392 If W is a window, return its absolute corrdinates,
 393 otherwise return the frame coordinates."
 394   (let* ((frame-left (frame-parameter frame 'left))
 395          ;; If the frame is outside the display, frame-left looks like
 396          ;; '(0 -16).  Extract the -16.
 397          (frame-real-left (if (consp frame-left) (car (cdr frame-left))
 398                             frame-left))
 399          (frame-top (frame-parameter frame 'top))
 400          (frame-real-top (if (consp frame-top) (car (cdr frame-top))
 401                            frame-top)))
 402     (if (windowp w)
 403         (let ((edges (window-inside-pixel-edges w)))
 404           (cons
 405            (+ frame-real-left (nth 0 edges))
 406            (+ frame-real-top (nth 1 edges))))
 407       (cons frame-real-left frame-real-top))))
 408
 409 (defun x-dnd-handle-xdnd (event frame window message format data)
 410   "Receive one XDND event (client message) and send the appropriate reply.
 411 EVENT is the client message.  FRAME is where the mouse is now.
 412 WINDOW is the window within FRAME where the mouse is now.
 413 FORMAT is 32 (not used).  MESSAGE is the data part of an XClientMessageEvent."
 414   (cond ((equal "XdndEnter" message)
 415          (let* ((flags (aref data 1))
 416                 (version (and (consp flags) (ash (car flags) -8)))
 417                 (more-than-3 (and (consp flags) (cdr flags)))
 418                 (dnd-source (aref data 0)))
 419            (if version  ;; If flags is bad, version will be nil.
 420                (x-dnd-save-state
 421                 window nil nil
 422                 (if (> more-than-3 0)
 423                     (x-window-property "XdndTypeList"
 424                                        frame "AnyPropertyType"
 425                                        dnd-source nil t)
 426                   (vector (x-get-atom-name (aref data 2))
 427                           (x-get-atom-name (aref data 3))
 428                           (x-get-atom-name (aref data 4))))))))
 429
 430         ((equal "XdndPosition" message)
 431          (let* ((x (car (aref data 2)))
 432                 (y (cdr (aref data 2)))
 433                 (action (x-get-atom-name (aref data 4)))
 434                 (dnd-source (aref data 0))
 435                 (dnd-time (aref data 3))
 436                 (action-type (x-dnd-maybe-call-test-function
 437                               window
 438                               (cdr (assoc action x-dnd-xdnd-to-action))))
 439                 (reply-action (car (rassoc (car action-type)
 440                                            x-dnd-xdnd-to-action)))
 441                 (accept ;; 1 = accept, 0 = reject
 442                  (if (and reply-action action-type) 1 0))
 443                 (list-to-send
 444                  (list (string-to-number
 445                         (frame-parameter frame 'outer-window-id))
 446                        accept ;; 1 = Accept, 0 = reject.
 447                        (x-dnd-get-drop-x-y frame window)
 448                        (x-dnd-get-drop-width-height
 449                         frame window (eq accept 1))
 450                        (or reply-action 0)
 451                        )))
 452            (x-send-client-message
 453             frame dnd-source frame "XdndStatus" 32 list-to-send)
 454            ))
 455
 456         ((equal "XdndLeave" message)
 457          (x-dnd-forget-drop window))
 458
 459         ((equal "XdndDrop" message)
 460          (if (windowp window) (select-window window))
 461          (let* ((dnd-source (aref data 0))
 462                 (value (and (x-dnd-current-type window)
 463                             (x-get-selection-internal
 464                              'XdndSelection
 465                              (intern (x-dnd-current-type window)))))
 466                 success action ret-action)
 467
 468            (setq action (if value
 469                             (condition-case info
 470                                 (x-dnd-drop-data event frame window value
 471                                                  (x-dnd-current-type window))
 472                               (error
 473                                (message "Error: %s" info)
 474                                nil))))
 475
 476            (setq success (if action 1 0))
 477            (setq ret-action
 478                  (if (eq success 1)
 479                      (or (car (rassoc action x-dnd-xdnd-to-action))
 480                          "XdndActionPrivate")
 481                    0))
 482
 483            (x-send-client-message
 484             frame dnd-source frame "XdndFinished" 32
 485             (list (string-to-number (frame-parameter frame 'outer-window-id))
 486                   success       ;; 1 = Success, 0 = Error
 487                   (if success "XdndActionPrivate" 0)
 488                   ))
 489            (x-dnd-forget-drop window)))
 490
 491         (t (error "Unknown XDND message %s %s" message data))))
 492
 493 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 494 ;;;  Motif protocol.
 495
 496 (defun x-dnd-init-motif-for-frame (frame)
 497   "Set _MOTIF_DRAG_RECEIVER_INFO  for FRAME to indicate that we do Motif DND."
 498   (x-change-window-property "_MOTIF_DRAG_RECEIVER_INFO"
 499                             (list
 500                              (byteorder)
 501                              0                  ; The Motif DND version.
 502                              5                  ; We want drag dynamic.
 503                              0 0 0 0 0 0 0
 504                              0 0 0 0 0 0)       ; Property must be 16 bytes.
 505                             frame "_MOTIF_DRAG_RECEIVER_INFO" 8 t))
 506
 507 (defun x-dnd-get-motif-value (data offset size byteorder)
 508   (cond ((eq size 2)
 509          (if (eq byteorder ?l)
 510              (+ (ash (aref data (1+ offset)) 8)
 511                 (aref data offset))
 512            (+ (ash (aref data offset) 8)
 513               (aref data (1+ offset)))))
 514
 515         ((eq size 4)
 516          (if (eq byteorder ?l)
 517              (cons (+ (ash (aref data (+ 3 offset)) 8)
 518                       (aref data (+ 2 offset)))
 519                    (+ (ash (aref data (1+ offset)) 8)
 520                       (aref data offset)))
 521            (cons (+ (ash (aref data offset) 8)
 522                     (aref data (1+ offset)))
 523                  (+ (ash (aref data (+ 2 offset)) 8)
 524                     (aref data (+ 3 offset))))))))
 525
 526 (defun x-dnd-motif-value-to-list (value size byteorder)
 527   (let ((bytes (cond ((eq size 2)
 528                       (list (logand (lsh value -8) ?\xff)
 529                             (logand value ?\xff)))
 530
 531                      ((eq size 4)
 532                       (if (consp value)
 533                           (list (logand (lsh (car value) -8) ?\xff)
 534                                 (logand (car value) ?\xff)
 535                                 (logand (lsh (cdr value) -8) ?\xff)
 536                                 (logand (cdr value) ?\xff))
 537                         (list (logand (lsh value -24) ?\xff)
 538                               (logand (lsh value -16) ?\xff)
 539                               (logand (lsh value -8) ?\xff)
 540                               (logand value ?\xff)))))))
 541     (if (eq byteorder ?l)
 542         (reverse bytes)
 543       bytes)))
 544
 545
 546 (defvar x-dnd-motif-message-types
 547   '((0 . XmTOP_LEVEL_ENTER)
 548     (1 . XmTOP_LEVEL_LEAVE)
 549     (2 . XmDRAG_MOTION)
 550     (3 . XmDROP_SITE_ENTER)
 551     (4 . XmDROP_SITE_LEAVE)
 552     (5 . XmDROP_START)
 553     (6 . XmDROP_FINISH)
 554     (7 . XmDRAG_DROP_FINISH)
 555     (8 . XmOPERATION_CHANGED))
 556   "Mapping from numbers to Motif DND message types.")
 557
 558 (defvar x-dnd-motif-to-action
 559   '((1 . move)
 560     (2 . copy)
 561     (3 . link)  ; Both 3 and 4 has been seen as link.
 562     (4 . link)
 563     (2 . private)) ; Motif does not have private, so use copy for private.
 564   "Mapping from number to operation for Motif DND.")
 565
 566 (defun x-dnd-handle-motif (event frame window message-atom format data)
 567   (let* ((message-type (cdr (assoc (aref data 0) x-dnd-motif-message-types)))
 568          (source-byteorder (aref data 1))
 569          (my-byteorder (byteorder))
 570          (source-flags (x-dnd-get-motif-value data 2 2 source-byteorder))
 571          (source-action (cdr (assoc (logand ?\xF source-flags)
 572                                     x-dnd-motif-to-action))))
 573
 574     (cond ((eq message-type 'XmTOP_LEVEL_ENTER)
 575            (let* ((dnd-source (x-dnd-get-motif-value
 576                                data 8 4 source-byteorder))
 577                   (selection-atom (x-dnd-get-motif-value
 578                                    data 12 4 source-byteorder))
 579                   (atom-name (x-get-atom-name selection-atom))
 580                   (types (when atom-name
 581                            (x-get-selection-internal (intern atom-name)
 582                                                      'TARGETS))))
 583              (x-dnd-forget-drop frame)
 584              (when types (x-dnd-save-state window nil nil
 585                                            types
 586                                            dnd-source))))
 587
 588           ;; Can not forget drop here, LEAVE comes before DROP_START and
 589           ;; we need the state in DROP_START.
 590           ((eq message-type 'XmTOP_LEVEL_LEAVE)
 591            nil)
 592
 593           ((eq message-type 'XmDRAG_MOTION)
 594            (let* ((state (x-dnd-get-state-for-frame frame))
 595                   (timestamp (x-dnd-motif-value-to-list
 596                               (x-dnd-get-motif-value data 4 4
 597                                                      source-byteorder)
 598                               4 my-byteorder))
 599                   (x (x-dnd-motif-value-to-list
 600                       (x-dnd-get-motif-value data 8 2 source-byteorder)
 601                       2 my-byteorder))
 602                   (y (x-dnd-motif-value-to-list
 603                       (x-dnd-get-motif-value data 10 2 source-byteorder)
 604                       2 my-byteorder))
 605                   (dnd-source (aref state 6))
 606                   (first-move (not (aref state 3)))
 607                   (action-type (x-dnd-maybe-call-test-function
 608                                 window
 609                                 source-action))
 610                   (reply-action (car (rassoc (car action-type)
 611                                              x-dnd-motif-to-action)))
 612                   (reply-flags
 613                    (x-dnd-motif-value-to-list
 614                     (if reply-action
 615                         (+ reply-action
 616                            ?\x30        ; 30:  valid drop site
 617                            ?\x700)      ; 700: can do copy, move or link
 618                       ?\x30)            ; 30:  drop site, but noop.
 619                     2 my-byteorder))
 620                   (reply (append
 621                           (list
 622                            (+ ?\x80     ; 0x80 indicates a reply.
 623                               (if first-move
 624                                   3     ; First time, reply is SITE_ENTER.
 625                                 2))     ; Not first time, reply is DRAG_MOTION.
 626                            my-byteorder)
 627                           reply-flags
 628                           timestamp
 629                           x
 630                           y)))
 631              (x-send-client-message frame
 632                                     dnd-source
 633                                     frame
 634                                     "_MOTIF_DRAG_AND_DROP_MESSAGE"
 635                                     8
 636                                     reply)))
 637
 638           ((eq message-type 'XmOPERATION_CHANGED)
 639            (let* ((state (x-dnd-get-state-for-frame frame))
 640                   (timestamp (x-dnd-motif-value-to-list
 641                               (x-dnd-get-motif-value data 4 4 source-byteorder)
 642                               4 my-byteorder))
 643                   (dnd-source (aref state 6))
 644                   (action-type (x-dnd-maybe-call-test-function
 645                                 window
 646                                 source-action))
 647                   (reply-action (car (rassoc (car action-type)
 648                                              x-dnd-motif-to-action)))
 649                   (reply-flags
 650                    (x-dnd-motif-value-to-list
 651                     (if reply-action
 652                         (+ reply-action
 653                            ?\x30        ; 30:  valid drop site
 654                            ?\x700)      ; 700: can do copy, move or link
 655                       ?\x30)            ; 30:  drop site, but noop
 656                     2 my-byteorder))
 657                   (reply (append
 658                           (list
 659                            (+ ?\x80     ; 0x80 indicates a reply.
 660                               8)        ; 8 is OPERATION_CHANGED
 661                            my-byteorder)
 662                           reply-flags
 663                           timestamp)))
 664              (x-send-client-message frame
 665                                     dnd-source
 666                                     frame
 667                                     "_MOTIF_DRAG_AND_DROP_MESSAGE"
 668                                     8
 669                                     reply)))
 670
 671           ((eq message-type 'XmDROP_START)
 672            (let* ((x (x-dnd-motif-value-to-list
 673                       (x-dnd-get-motif-value data 8 2 source-byteorder)
 674                       2 my-byteorder))
 675                   (y (x-dnd-motif-value-to-list
 676                       (x-dnd-get-motif-value data 10 2 source-byteorder)
 677                       2 my-byteorder))
 678                   (selection-atom (x-dnd-get-motif-value
 679                                    data 12 4 source-byteorder))
 680                   (atom-name (x-get-atom-name selection-atom))
 681                   (dnd-source (x-dnd-get-motif-value
 682                                data 16 4 source-byteorder))
 683                   (action-type (x-dnd-maybe-call-test-function
 684                                 window
 685                                 source-action))
 686                   (reply-action (car (rassoc (car action-type)
 687                                              x-dnd-motif-to-action)))
 688                   (reply-flags
 689                    (x-dnd-motif-value-to-list
 690                     (if reply-action
 691                         (+ reply-action
 692                            ?\x30        ; 30:  valid drop site
 693                            ?\x700)      ; 700: can do copy, move or link
 694                       (+ ?\x30          ; 30:  drop site, but noop.
 695                          ?\x200))       ; 200: drop cancel.
 696                     2 my-byteorder))
 697                   (reply (append
 698                           (list
 699                            (+ ?\x80     ; 0x80 indicates a reply.
 700                               5)        ; DROP_START.
 701                            my-byteorder)
 702                           reply-flags
 703                           x
 704                           y))
 705                   (timestamp (x-dnd-get-motif-value
 706                               data 4 4 source-byteorder))
 707                   action)
 708
 709              (x-send-client-message frame
 710                                     dnd-source
 711                                     frame
 712                                     "_MOTIF_DRAG_AND_DROP_MESSAGE"
 713                                     8
 714                                     reply)
 715              (setq action
 716                    (when (and reply-action atom-name)
 717                      (let* ((value (x-get-selection-internal
 718                                     (intern atom-name)
 719                                     (intern (x-dnd-current-type window)))))
 720                        (when value
 721                          (condition-case info
 722                              (x-dnd-drop-data event frame window value
 723                                               (x-dnd-current-type window))
 724                            (error
 725                             (message "Error: %s" info)
 726                             nil))))))
 727              (x-get-selection-internal
 728               (intern atom-name)
 729               (if action 'XmTRANSFER_SUCCESS 'XmTRANSFER_FAILURE)
 730               timestamp)
 731              (x-dnd-forget-drop frame)))
 732
 733           (t (error "Unknown Motif DND message %s %s" message-atom data)))))
 734
 735
 736 ;;;
 737
 738 (provide 'x-dnd)
 739
 740 ;;; arch-tag: b621fb7e-50da-4323-850b-5fc71ae64621
 741 ;;; x-dnd.el ends here