code.delx.au - gnu-emacs/blob - lisp/textmodes/outline.el

   1 ;;; outline.el --- outline mode commands for Emacs
   2
   3 ;; Copyright (C) 1986, 1993, 1994, 1995, 1997 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6 ;; Keywords: outlines
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; This package is a major mode for editing outline-format documents.
  28 ;; An outline can be `abstracted' to show headers at any given level,
  29 ;; with all stuff below hidden.  See the Emacs manual for details.
  30
  31 ;;; Code:
  32
  33 (defgroup outlines nil
  34   "Support for hierarchical outlining"
  35   :prefix "outline-"
  36   :group 'editing)
  37
  38 (defcustom outline-regexp nil
  39   "*Regular expression to match the beginning of a heading.
  40 Any line whose beginning matches this regexp is considered to start a heading.
  41 The recommended way to set this is with a Local Variables: list
  42 in the file it applies to.  See also `outline-heading-end-regexp'."
  43   :type '(choice regexp (const nil))
  44   :group 'outlines)
  45
  46 ;; Can't initialize this in the defvar above -- some major modes have
  47 ;; already assigned a local value to it.
  48 (or (default-value 'outline-regexp)
  49     (setq-default outline-regexp "[*\^L]+"))
  50
  51 (defcustom outline-heading-end-regexp "\n"
  52   "*Regular expression to match the end of a heading line.
  53 You can assume that point is at the beginning of a heading when this
  54 regexp is searched for.  The heading ends at the end of the match.
  55 The recommended way to set this is with a `Local Variables:' list
  56 in the file it applies to."
  57   :type 'regexp
  58   :group 'outlines)
  59
  60 (defvar outline-mode-prefix-map nil)
  61
  62 (if outline-mode-prefix-map
  63     nil
  64   (setq outline-mode-prefix-map (make-sparse-keymap))
  65   (define-key outline-mode-prefix-map "@" 'outline-mark-subtree)
  66   (define-key outline-mode-prefix-map "\C-n" 'outline-next-visible-heading)
  67   (define-key outline-mode-prefix-map "\C-p" 'outline-previous-visible-heading)
  68   (define-key outline-mode-prefix-map "\C-i" 'show-children)
  69   (define-key outline-mode-prefix-map "\C-s" 'show-subtree)
  70   (define-key outline-mode-prefix-map "\C-d" 'hide-subtree)
  71   (define-key outline-mode-prefix-map "\C-u" 'outline-up-heading)
  72   (define-key outline-mode-prefix-map "\C-f" 'outline-forward-same-level)
  73   (define-key outline-mode-prefix-map "\C-b" 'outline-backward-same-level)
  74   (define-key outline-mode-prefix-map "\C-t" 'hide-body)
  75   (define-key outline-mode-prefix-map "\C-a" 'show-all)
  76   (define-key outline-mode-prefix-map "\C-c" 'hide-entry)
  77   (define-key outline-mode-prefix-map "\C-e" 'show-entry)
  78   (define-key outline-mode-prefix-map "\C-l" 'hide-leaves)
  79   (define-key outline-mode-prefix-map "\C-k" 'show-branches)
  80   (define-key outline-mode-prefix-map "\C-q" 'hide-sublevels)
  81   (define-key outline-mode-prefix-map "\C-o" 'hide-other))
  82
  83 (defvar outline-mode-menu-bar-map nil)
  84 (if outline-mode-menu-bar-map
  85     nil
  86   (setq outline-mode-menu-bar-map (make-sparse-keymap))
  87
  88   (define-key outline-mode-menu-bar-map [hide]
  89     (cons "Hide" (make-sparse-keymap "Hide")))
  90
  91   (define-key outline-mode-menu-bar-map [hide hide-other]
  92     '("Hide Other" . hide-other))
  93   (define-key outline-mode-menu-bar-map [hide hide-sublevels]
  94     '("Hide Sublevels" . hide-sublevels))
  95   (define-key outline-mode-menu-bar-map [hide hide-subtree]
  96     '("Hide Subtree" . hide-subtree))
  97   (define-key outline-mode-menu-bar-map [hide hide-entry]
  98     '("Hide Entry" . hide-entry))
  99   (define-key outline-mode-menu-bar-map [hide hide-body]
 100     '("Hide Body" . hide-body))
 101   (define-key outline-mode-menu-bar-map [hide hide-leaves]
 102     '("Hide Leaves" . hide-leaves))
 103
 104   (define-key outline-mode-menu-bar-map [show]
 105     (cons "Show" (make-sparse-keymap "Show")))
 106
 107   (define-key outline-mode-menu-bar-map [show show-subtree]
 108     '("Show Subtree" . show-subtree))
 109   (define-key outline-mode-menu-bar-map [show show-children]
 110     '("Show Children" . show-children))
 111   (define-key outline-mode-menu-bar-map [show show-branches]
 112     '("Show Branches" . show-branches))
 113   (define-key outline-mode-menu-bar-map [show show-entry]
 114     '("Show Entry" . show-entry))
 115   (define-key outline-mode-menu-bar-map [show show-all]
 116     '("Show All" . show-all))
 117
 118   (define-key outline-mode-menu-bar-map [headings]
 119     (cons "Headings" (make-sparse-keymap "Headings")))
 120
 121   (define-key outline-mode-menu-bar-map [headings outline-backward-same-level]
 122     '("Previous Same Level" . outline-backward-same-level))
 123   (define-key outline-mode-menu-bar-map [headings outline-forward-same-level]
 124     '("Next Same Level" . outline-forward-same-level))
 125   (define-key outline-mode-menu-bar-map [headings outline-previous-visible-heading]
 126     '("Previous" . outline-previous-visible-heading))
 127   (define-key outline-mode-menu-bar-map [headings outline-next-visible-heading]
 128     '("Next" . outline-next-visible-heading))
 129   (define-key outline-mode-menu-bar-map [headings outline-up-heading]
 130     '("Up" . outline-up-heading)))
 131
 132 (defvar outline-mode-map nil "")
 133
 134 (if outline-mode-map
 135     nil
 136   (setq outline-mode-map (nconc (make-sparse-keymap) text-mode-map))
 137   (define-key outline-mode-map "\C-c" outline-mode-prefix-map)
 138   (define-key outline-mode-map [menu-bar] outline-mode-menu-bar-map))
 139
 140 (defcustom outline-minor-mode nil
 141   "Non-nil if using Outline mode as a minor mode of some other mode."
 142   :type 'boolean
 143   :group 'outlines)
 144 (make-variable-buffer-local 'outline-minor-mode)
 145 (or (assq 'outline-minor-mode minor-mode-alist)
 146     (setq minor-mode-alist (append minor-mode-alist
 147                                    (list '(outline-minor-mode " Outl")))))
 148
 149 (defvar outline-font-lock-keywords
 150   '(;;
 151     ;; Highlight headings according to the level.
 152     (eval . (list (concat "^" outline-regexp ".+")
 153                   0 '(or (cdr (assq (outline-font-lock-level)
 154                                     '((1 . font-lock-function-name-face)
 155                                       (2 . font-lock-variable-name-face)
 156                                       (3 . font-lock-keyword-face)
 157                                       (4 . font-lock-builtin-face)
 158                                       (5 . font-lock-comment-face)
 159                                       (6 . font-lock-constant-face)
 160                                       (7 . font-lock-type-face)
 161                                       (8 . font-lock-string-face))))
 162                          font-lock-warning-face)
 163                   nil t)))
 164   "Additional expressions to highlight in Outline mode.")
 165
 166 (defun outline-font-lock-level ()
 167   (let ((count 1))
 168     (save-excursion
 169       (outline-back-to-heading t)
 170       (condition-case nil
 171           (while (not (bobp))
 172             (outline-up-heading-all 1)
 173             (setq count (1+ count)))
 174         (error)))
 175     count))
 176
 177 (defvar outline-view-change-hook nil
 178   "Normal hook to be run after outline visibility changes.")
 179
 180 ;;;###autoload
 181 (defun outline-mode ()
 182   "Set major mode for editing outlines with selective display.
 183 Headings are lines which start with asterisks: one for major headings,
 184 two for subheadings, etc.  Lines not starting with asterisks are body lines.
 185
 186 Body text or subheadings under a heading can be made temporarily
 187 invisible, or visible again.  Invisible lines are attached to the end
 188 of the heading, so they move with it, if the line is killed and yanked
 189 back.  A heading with text hidden under it is marked with an ellipsis (...).
 190
 191 Commands:\\<outline-mode-map>
 192 \\[outline-next-visible-heading]   outline-next-visible-heading      move by visible headings
 193 \\[outline-previous-visible-heading]   outline-previous-visible-heading
 194 \\[outline-forward-same-level]   outline-forward-same-level        similar but skip subheadings
 195 \\[outline-backward-same-level]   outline-backward-same-level
 196 \\[outline-up-heading]   outline-up-heading                 move from subheading to heading
 197
 198 \\[hide-body]   make all text invisible (not headings).
 199 \\[show-all]    make everything in buffer visible.
 200
 201 The remaining commands are used when point is on a heading line.
 202 They apply to some of the body or subheadings of that heading.
 203 \\[hide-subtree]   hide-subtree make body and subheadings invisible.
 204 \\[show-subtree]   show-subtree make body and subheadings visible.
 205 \\[show-children]   show-children       make direct subheadings visible.
 206                  No effect on body, or subheadings 2 or more levels down.
 207                  With arg N, affects subheadings N levels down.
 208 \\[hide-entry]     make immediately following body invisible.
 209 \\[show-entry]     make it visible.
 210 \\[hide-leaves]    make body under heading and under its subheadings invisible.
 211                      The subheadings remain visible.
 212 \\[show-branches]  make all subheadings at all levels visible.
 213
 214 The variable `outline-regexp' can be changed to control what is a heading.
 215 A line is a heading if `outline-regexp' matches something at the
 216 beginning of the line.  The longer the match, the deeper the level.
 217
 218 Turning on outline mode calls the value of `text-mode-hook' and then of
 219 `outline-mode-hook', if they are non-nil."
 220   (interactive)
 221   (kill-all-local-variables)
 222   (use-local-map outline-mode-map)
 223   (setq mode-name "Outline")
 224   (setq major-mode 'outline-mode)
 225   (define-abbrev-table 'text-mode-abbrev-table ())
 226   (setq local-abbrev-table text-mode-abbrev-table)
 227   (set-syntax-table text-mode-syntax-table)
 228   (make-local-variable 'line-move-ignore-invisible)
 229   (setq line-move-ignore-invisible t)
 230   ;; Cause use of ellipses for invisible text.
 231   (add-to-invisibility-spec '(outline . t))
 232   (make-local-variable 'paragraph-start)
 233   (setq paragraph-start (concat paragraph-start "\\|\\("
 234                                 outline-regexp "\\)"))
 235   ;; Inhibit auto-filling of header lines.
 236   (make-local-variable 'auto-fill-inhibit-regexp)
 237   (setq auto-fill-inhibit-regexp outline-regexp)
 238   (make-local-variable 'paragraph-separate)
 239   (setq paragraph-separate (concat paragraph-separate "\\|\\("
 240                                    outline-regexp "\\)"))
 241   (make-local-variable 'font-lock-defaults)
 242   (setq font-lock-defaults '(outline-font-lock-keywords t))
 243   (make-local-variable 'change-major-mode-hook)
 244   (add-hook 'change-major-mode-hook 'show-all)
 245   (run-hooks 'text-mode-hook 'outline-mode-hook))
 246
 247 (defcustom outline-minor-mode-prefix "\C-c@"
 248   "*Prefix key to use for Outline commands in Outline minor mode.
 249 The value of this variable is checked as part of loading Outline mode.
 250 After that, changing the prefix key requires manipulating keymaps."
 251   :type 'string
 252   :group 'outlines)
 253
 254 (defvar outline-minor-mode-map nil)
 255 (if outline-minor-mode-map
 256     nil
 257   (setq outline-minor-mode-map (make-sparse-keymap))
 258   (define-key outline-minor-mode-map [menu-bar]
 259     outline-mode-menu-bar-map)
 260   (define-key outline-minor-mode-map outline-minor-mode-prefix
 261     outline-mode-prefix-map))
 262
 263 (or (assq 'outline-minor-mode minor-mode-map-alist)
 264     (setq minor-mode-map-alist
 265           (cons (cons 'outline-minor-mode outline-minor-mode-map)
 266                 minor-mode-map-alist)))
 267
 268 ;;;###autoload
 269 (defun outline-minor-mode (&optional arg)
 270   "Toggle Outline minor mode.
 271 With arg, turn Outline minor mode on if arg is positive, off otherwise.
 272 See the command `outline-mode' for more information on this mode."
 273   (interactive "P")
 274   (setq outline-minor-mode
 275         (if (null arg) (not outline-minor-mode)
 276           (> (prefix-numeric-value arg) 0)))
 277   (if outline-minor-mode
 278       (progn
 279         (make-local-hook 'change-major-mode-hook)
 280         ;; Turn off this mode if we change major modes.
 281         (add-hook 'change-major-mode-hook
 282                   '(lambda () (outline-minor-mode -1))
 283                   nil t)
 284         (make-local-variable 'line-move-ignore-invisible)
 285         (setq line-move-ignore-invisible t)
 286         ;; Cause use of ellipses for invisible text.
 287         (add-to-invisibility-spec '(outline . t))
 288         (run-hooks 'outline-minor-mode-hook))
 289     (setq line-move-ignore-invisible nil)
 290     ;; Cause use of ellipses for invisible text.
 291     (remove-from-invisibility-spec '(outline . t)))
 292   ;; When turning off outline mode, get rid of any outline hiding.
 293   (or outline-minor-mode
 294       (show-all))
 295   (force-mode-line-update))
 296 \f
 297 (defcustom outline-level 'outline-level
 298   "*Function of no args to compute a header's nesting level in an outline.
 299 It can assume point is at the beginning of a header line."
 300   :type 'function
 301   :group 'outlines)
 302
 303 ;; This used to count columns rather than characters, but that made ^L
 304 ;; appear to be at level 2 instead of 1.  Columns would be better for
 305 ;; tab handling, but the default regexp doesn't use tabs, and anyone
 306 ;; who changes the regexp can also redefine the outline-level variable
 307 ;; as appropriate.
 308 (defun outline-level ()
 309   "Return the depth to which a statement is nested in the outline.
 310 Point must be at the beginning of a header line.  This is actually
 311 the number of characters that `outline-regexp' matches."
 312   (save-excursion
 313     (looking-at outline-regexp)
 314     (- (match-end 0) (match-beginning 0))))
 315
 316 (defun outline-next-preface ()
 317   "Skip forward to just before the next heading line.
 318 If there's no following heading line, stop before the newline
 319 at the end of the buffer."
 320   (if (re-search-forward (concat "\n\\(" outline-regexp "\\)")
 321                          nil 'move)
 322       (goto-char (match-beginning 0)))
 323   (if (and (bolp) (not (bobp)))
 324       (forward-char -1)))
 325
 326 (defun outline-next-heading ()
 327   "Move to the next (possibly invisible) heading line."
 328   (interactive)
 329   (if (re-search-forward (concat "\n\\(" outline-regexp "\\)")
 330                          nil 'move)
 331       (goto-char (1+ (match-beginning 0)))))
 332
 333 (defun outline-previous-heading ()
 334   "Move to the previous (possibly invisible) heading line."
 335   (interactive)
 336   (re-search-backward (concat "^\\(" outline-regexp "\\)")
 337                       nil 'move))
 338
 339 (defsubst outline-visible ()
 340   "Non-nil if the character after point is visible."
 341   (not (get-char-property (point) 'invisible)))
 342
 343 (defun outline-back-to-heading (&optional invisible-ok)
 344   "Move to previous heading line, or beg of this line if it's a heading.
 345 Only visible heading lines are considered, unless INVISIBLE-OK is non-nil."
 346   (beginning-of-line)
 347   (or (outline-on-heading-p invisible-ok)
 348       (let (found)
 349         (save-excursion
 350           (while (not found)
 351             (or (re-search-backward (concat "^\\(" outline-regexp "\\)")
 352                                     nil t)
 353                 (error "before first heading"))
 354             (setq found (and (or invisible-ok (outline-visible)) (point)))))
 355         (goto-char found)
 356         found)))
 357
 358 (defun outline-on-heading-p (&optional invisible-ok)
 359   "Return t if point is on a (visible) heading line.
 360 If INVISIBLE-OK is non-nil, an invisible heading line is ok too."
 361   (save-excursion
 362     (beginning-of-line)
 363     (and (bolp) (or invisible-ok (outline-visible))
 364          (looking-at outline-regexp))))
 365
 366 (defun outline-end-of-heading ()
 367   (if (re-search-forward outline-heading-end-regexp nil 'move)
 368       (forward-char -1)))
 369
 370 (defun outline-next-visible-heading (arg)
 371   "Move to the next visible heading line.
 372 With argument, repeats or can move backward if negative.
 373 A heading line is one that starts with a `*' (or that
 374 `outline-regexp' matches)."
 375   (interactive "p")
 376   (if (< arg 0)
 377       (beginning-of-line)
 378     (end-of-line))
 379   (while (and (not (bobp)) (< arg 0))
 380     (while (and (not (bobp))
 381                 (re-search-backward (concat "^\\(" outline-regexp "\\)")
 382                                     nil 'move)
 383                 (not (outline-visible))))
 384     (setq arg (1+ arg)))
 385   (while (and (not (eobp)) (> arg 0))
 386     (while (and (not (eobp))
 387                 (re-search-forward (concat "^\\(" outline-regexp "\\)")
 388                                    nil 'move)
 389                 (not (outline-visible))))
 390     (setq arg (1- arg)))
 391   (beginning-of-line))
 392
 393 (defun outline-previous-visible-heading (arg)
 394   "Move to the previous heading line.
 395 With argument, repeats or can move forward if negative.
 396 A heading line is one that starts with a `*' (or that
 397 `outline-regexp' matches)."
 398   (interactive "p")
 399   (outline-next-visible-heading (- arg)))
 400
 401 (defun outline-mark-subtree ()
 402   "Mark the current subtree in an outlined document.
 403 This puts point at the start of the current subtree, and mark at the end."
 404   (interactive)
 405   (let ((beg))
 406     (if (outline-on-heading-p)
 407         ;; we are already looking at a heading
 408         (beginning-of-line)
 409       ;; else go back to previous heading
 410       (outline-previous-visible-heading 1))
 411     (setq beg (point))
 412     (outline-end-of-subtree)
 413     (push-mark (point))
 414     (goto-char beg)))
 415 \f
 416 (defun outline-flag-region (from to flag)
 417   "Hides or shows lines from FROM to TO, according to FLAG.
 418 If FLAG is nil then text is shown, while if FLAG is t the text is hidden."
 419   (let ((inhibit-read-only t))
 420     (save-excursion
 421       (goto-char from)
 422       (end-of-line)
 423       (outline-discard-overlays (point) to 'outline)
 424       (if flag
 425           (let ((o (make-overlay (point) to)))
 426             (overlay-put o 'invisible 'outline)
 427             (overlay-put o 'isearch-open-invisible
 428                          'outline-isearch-open-invisible)))))
 429   (run-hooks 'outline-view-change-hook))
 430
 431
 432 ;; Function to be set as an outline-isearch-open-invisible' property
 433 ;; to the overlay that makes the outline invisible (see
 434 ;; `outline-flag-region').
 435 (defun outline-isearch-open-invisible (overlay)
 436   (save-excursion
 437     (goto-char (overlay-start overlay))
 438     (show-entry)))
 439
 440
 441 ;; Exclude from the region BEG ... END all overlays
 442 ;; which have PROP as the value of the `invisible' property.
 443 ;; Exclude them by shrinking them to exclude BEG ... END,
 444 ;; or even by splitting them if necessary.
 445 ;; Overlays without such an `invisible' property are not touched.
 446 (defun outline-discard-overlays (beg end prop)
 447   (if (< end beg)
 448       (setq beg (prog1 end (setq end beg))))
 449   (save-excursion
 450     (let ((overlays (overlays-in beg end))
 451           o
 452           o1)
 453       (while overlays
 454         (setq o (car overlays))
 455         (if (eq (overlay-get o 'invisible) prop)
 456             ;; Either push this overlay outside beg...end
 457             ;; or split it to exclude beg...end
 458             ;; or delete it entirely (if it is contained in beg...end).
 459             (if (< (overlay-start o) beg)
 460                 (if (> (overlay-end o) end)
 461                     (progn
 462                       (setq o1 (outline-copy-overlay o))
 463                       (move-overlay o1 (overlay-start o1) beg)
 464                       (move-overlay o end (overlay-end o)))
 465                   (move-overlay o (overlay-start o) beg))
 466               (if (> (overlay-end o) end)
 467                   (move-overlay o end (overlay-end o))
 468                 (delete-overlay o))))
 469         (setq overlays (cdr overlays))))))
 470
 471 ;; Make a copy of overlay O, with the same beginning, end and properties.
 472 (defun outline-copy-overlay (o)
 473   (let ((o1 (make-overlay (overlay-start o) (overlay-end o)
 474                           (overlay-buffer o)))
 475         (props (overlay-properties o)))
 476     (while props
 477       (overlay-put o1 (car props) (nth 1 props))
 478       (setq props (cdr (cdr props))))
 479     o1))
 480 \f
 481 (defun hide-entry ()
 482   "Hide the body directly following this heading."
 483   (interactive)
 484   (outline-back-to-heading)
 485   (outline-end-of-heading)
 486   (save-excursion
 487    (outline-flag-region (point) (progn (outline-next-preface) (point)) t)))
 488
 489 (defun show-entry ()
 490   "Show the body directly following this heading.
 491 Show the heading too, if it is currently invisible."
 492   (interactive)
 493   (save-excursion
 494     (outline-back-to-heading t)
 495     (outline-flag-region (1- (point))
 496                          (progn (outline-next-preface) (point)) nil)))
 497
 498 (defun hide-body ()
 499   "Hide all of buffer except headings."
 500   (interactive)
 501   (hide-region-body (point-min) (point-max)))
 502
 503 (defun hide-region-body (start end)
 504   "Hide all body lines in the region, but not headings."
 505   ;; Nullify the hook to avoid repeated calls to `outline-flag-region'
 506   ;; wasting lots of time running `lazy-lock-fontify-after-outline'
 507   ;; and run the hook finally.
 508   (let (outline-view-change-hook)
 509     (save-excursion
 510       (save-restriction
 511         (narrow-to-region start end)
 512         (goto-char (point-min))
 513         (if (outline-on-heading-p)
 514             (outline-end-of-heading))
 515         (while (not (eobp))
 516           (outline-flag-region (point)
 517                                (progn (outline-next-preface) (point)) t)
 518           (if (not (eobp))
 519               (progn
 520                 (forward-char
 521                  (if (looking-at "\n\n")
 522                      2 1))
 523                 (outline-end-of-heading)))))))
 524   (run-hooks 'outline-view-change-hook))
 525
 526 (defun show-all ()
 527   "Show all of the text in the buffer."
 528   (interactive)
 529   (outline-flag-region (point-min) (point-max) nil))
 530
 531 (defun hide-subtree ()
 532   "Hide everything after this heading at deeper levels."
 533   (interactive)
 534   (outline-flag-subtree t))
 535
 536 (defun hide-leaves ()
 537   "Hide all body after this heading at deeper levels."
 538   (interactive)
 539   (outline-back-to-heading)
 540   (outline-end-of-heading)
 541   (hide-region-body (point) (progn (outline-end-of-subtree) (point))))
 542
 543 (defun show-subtree ()
 544   "Show everything after this heading at deeper levels."
 545   (interactive)
 546   (outline-flag-subtree nil))
 547
 548 (defun hide-sublevels (levels)
 549   "Hide everything but the top LEVELS levels of headers, in whole buffer."
 550   (interactive "p")
 551   (if (< levels 1)
 552       (error "Must keep at least one level of headers"))
 553   (setq levels (1- levels))
 554   (let (outline-view-change-hook)
 555     (save-excursion
 556       (goto-char (point-min))
 557       ;; Keep advancing to the next top-level heading.
 558       (while (or (and (bobp) (outline-on-heading-p))
 559                  (outline-next-heading))
 560         (let ((end (save-excursion (outline-end-of-subtree) (point))))
 561           ;; Hide everything under that.
 562           (outline-flag-region (point) end t)
 563           ;; Show the first LEVELS levels under that.
 564           (if (> levels 0)
 565               (show-children levels))
 566           ;; Move to the next, since we already found it.
 567           (goto-char end)))))
 568   (run-hooks 'outline-view-change-hook))
 569
 570 (defun hide-other ()
 571   "Hide everything except current body and parent and top-level headings."
 572   (interactive)
 573   (hide-sublevels 1)
 574   (let (outline-view-change-hook)
 575     (save-excursion
 576       (outline-back-to-heading t)
 577       (show-entry)
 578       (while (condition-case nil (progn (outline-up-heading 1) t)
 579                (error nil))
 580         (outline-flag-region (1- (point))
 581                              (save-excursion (forward-line 1) (point))
 582                              nil))))
 583   (run-hooks 'outline-view-change-hook))
 584
 585 (defun outline-flag-subtree (flag)
 586   (save-excursion
 587     (outline-back-to-heading)
 588     (outline-end-of-heading)
 589     (outline-flag-region (point)
 590                           (progn (outline-end-of-subtree) (point))
 591                           flag)))
 592
 593 (defun outline-end-of-subtree ()
 594   (outline-back-to-heading)
 595   (let ((opoint (point))
 596         (first t)
 597         (level (funcall outline-level)))
 598     (while (and (not (eobp))
 599                 (or first (> (funcall outline-level) level)))
 600       (setq first nil)
 601       (outline-next-heading))
 602     (if (bolp)
 603         (progn
 604           ;; Go to end of line before heading
 605           (forward-char -1)
 606           (if (bolp)
 607               ;; leave blank line before heading
 608               (forward-char -1))))))
 609 \f
 610 (defun show-branches ()
 611   "Show all subheadings of this heading, but not their bodies."
 612   (interactive)
 613   (show-children 1000))
 614
 615 (defun show-children (&optional level)
 616   "Show all direct subheadings of this heading.
 617 Prefix arg LEVEL is how many levels below the current level should be shown.
 618 Default is enough to cause the following heading to appear."
 619   (interactive "P")
 620   (setq level
 621         (if level (prefix-numeric-value level)
 622           (save-excursion
 623             (outline-back-to-heading)
 624             (let ((start-level (funcall outline-level)))
 625               (outline-next-heading)
 626               (if (eobp)
 627                   1
 628                 (max 1 (- (funcall outline-level) start-level)))))))
 629   (let (outline-view-change-hook)
 630     (save-excursion
 631       (save-restriction
 632         (outline-back-to-heading)
 633         (setq level (+ level (funcall outline-level)))
 634         (narrow-to-region (point)
 635                           (progn (outline-end-of-subtree)
 636                                  (if (eobp) (point-max) (1+ (point)))))
 637         (goto-char (point-min))
 638         (while (and (not (eobp))
 639                     (progn
 640                       (outline-next-heading)
 641                       (not (eobp))))
 642           (if (<= (funcall outline-level) level)
 643               (save-excursion
 644                 (outline-flag-region (save-excursion
 645                                        (forward-char -1)
 646                                        (if (bolp)
 647                                            (forward-char -1))
 648                                        (point))
 649                                      (progn (outline-end-of-heading) (point))
 650                                      nil)))))))
 651   (run-hooks 'outline-view-change-hook))
 652 \f
 653 (defun outline-up-heading-all (arg)
 654   "Move to the heading line of which the present line is a subheading.
 655 This function considers both visible and invisible heading lines.
 656 With argument, move up ARG levels."
 657   (outline-back-to-heading t)
 658   (if (eq (funcall outline-level) 1)
 659       (error "Already at top level of the outline"))
 660   (while (and (> (funcall outline-level) 1)
 661               (> arg 0)
 662               (not (bobp)))
 663     (let ((present-level (funcall outline-level)))
 664       (while (and (not (< (funcall outline-level) present-level))
 665                   (not (bobp)))
 666         (outline-previous-heading))
 667       (setq arg (- arg 1)))))
 668
 669 (defun outline-up-heading (arg)
 670   "Move to the visible heading line of which the present line is a subheading.
 671 With argument, move up ARG levels."
 672   (interactive "p")
 673   (outline-back-to-heading)
 674   (if (eq (funcall outline-level) 1)
 675       (error "Already at top level of the outline"))
 676   (while (and (> (funcall outline-level) 1)
 677               (> arg 0)
 678               (not (bobp)))
 679     (let ((present-level (funcall outline-level)))
 680       (while (and (not (< (funcall outline-level) present-level))
 681                   (not (bobp)))
 682         (outline-previous-visible-heading 1))
 683       (setq arg (- arg 1)))))
 684
 685 (defun outline-forward-same-level (arg)
 686   "Move forward to the ARG'th subheading at same level as this one.
 687 Stop at the first and last subheadings of a superior heading."
 688   (interactive "p")
 689   (outline-back-to-heading)
 690   (while (> arg 0)
 691     (let ((point-to-move-to (save-excursion
 692                               (outline-get-next-sibling))))
 693       (if point-to-move-to
 694           (progn
 695             (goto-char point-to-move-to)
 696             (setq arg (1- arg)))
 697         (progn
 698           (setq arg 0)
 699           (error "No following same-level heading"))))))
 700
 701 (defun outline-get-next-sibling ()
 702   "Move to next heading of the same level, and return point or nil if none."
 703   (let ((level (funcall outline-level)))
 704     (outline-next-visible-heading 1)
 705     (while (and (> (funcall outline-level) level)
 706                 (not (eobp)))
 707       (outline-next-visible-heading 1))
 708     (if (< (funcall outline-level) level)
 709         nil
 710       (point))))
 711
 712 (defun outline-backward-same-level (arg)
 713   "Move backward to the ARG'th subheading at same level as this one.
 714 Stop at the first and last subheadings of a superior heading."
 715   (interactive "p")
 716   (outline-back-to-heading)
 717   (while (> arg 0)
 718     (let ((point-to-move-to (save-excursion
 719                               (outline-get-last-sibling))))
 720       (if point-to-move-to
 721           (progn
 722             (goto-char point-to-move-to)
 723             (setq arg (1- arg)))
 724         (progn
 725           (setq arg 0)
 726           (error "No previous same-level heading"))))))
 727
 728 (defun outline-get-last-sibling ()
 729   "Move to previous heading of the same level, and return point or nil if none."
 730   (let ((level (funcall outline-level)))
 731     (outline-previous-visible-heading 1)
 732     (while (and (> (funcall outline-level) level)
 733                 (not (bobp)))
 734       (outline-previous-visible-heading 1))
 735     (if (< (funcall outline-level) level)
 736         nil
 737         (point))))
 738
 739 (provide 'outline)
 740 (provide 'noutline)
 741
 742 ;;; outline.el ends here