code.delx.au - gnu-emacs/blob - lisp/ediff.el

   1 ;;; ediff.el --- a comprehensive visual interface to diff & patch
   2
   3 ;; Copyright (C) 1994, 1995 Free Software Foundation, Inc.
   4
   5 ;; Author: Michael Kifer <kifer@cs.sunysb.edu>
   6 ;; Created: February 2, 1994
   7 ;; Keywords: comparing, merging, patching, version control.
   8
   9 (defconst ediff-version "2.54" "The current version of Ediff")
  10 (defconst ediff-date "February 14, 1996" "Date of last update")
  11
  12 ;; This file is part of GNU Emacs.
  13
  14 ;; GNU Emacs is free software; you can redistribute it and/or modify
  15 ;; it under the terms of the GNU General Public License as published by
  16 ;; the Free Software Foundation; either version 2, or (at your option)
  17 ;; any later version.
  18
  19 ;; GNU Emacs is distributed in the hope that it will be useful,
  20 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ;; GNU General Public License for more details.
  23
  24 ;; You should have received a copy of the GNU General Public License
  25 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  26 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  27 ;; Boston, MA 02111-1307, USA.
  28
  29 ;;; Commentary:
  30
  31 ;; Never read that diff output again!
  32 ;; Apply patch selectively, like a pro!
  33 ;; Merge with ease!
  34
  35 ;; This package provides a convenient way of simultaneous browsing through
  36 ;; the differences between a pair (or a triple) of files or buffers.  The
  37 ;; files being compared, file-A, file-B, and file-C (if applicable) are
  38 ;; shown in separate windows (side by side, one above the another, or in
  39 ;; separate frames), and the differences are highlighted as you step
  40 ;; through them.  You can also copy difference regions from one buffer to
  41 ;; another (and recover old differences if you change your mind).
  42
  43 ;; Ediff also supports merging operations on files and buffers, including
  44 ;; merging using ancestor versions. Both comparison and merging operations can
  45 ;; be performed on directories, i.e., by pairwise comparison of files in those
  46 ;; directories.
  47
  48 ;; In addition, Ediff can apply a patch to a file and then let you step
  49 ;; though both files, the patched and the original one, simultaneously,
  50 ;; difference-by-difference.  You can even apply a patch right out of a
  51 ;; mail buffer, i.e., patches received by mail don't even have to be saved.
  52 ;; Since Ediff lets you copy differences between buffers, you can, in
  53 ;; effect, apply patches selectively (i.e., you can copy a difference
  54 ;; region from file_orig to file, thereby undoing any particular patch that
  55 ;; you don't like).
  56
  57 ;; Ediff is aware of version control, which lets the user compare
  58 ;; files with their older versions. Ediff can also work with remote and
  59 ;; compressed files. Details are given below.
  60
  61 ;; Finally, Ediff supports directory-level comparison and merging operations.
  62 ;; See the on-line manual for details.
  63
  64 ;; This package builds upon the ideas borrowed from emerge.el and several
  65 ;; Ediff's functions are adaptations from emerge.el. Much of the functionality
  66 ;; Ediff provides is also influenced by emerge.el.
  67
  68 ;; The present version of Ediff supersedes Emerge. It provides a superior user
  69 ;; interface and has numerous major features not found in Emerge. In
  70 ;; particular, it can do patching, and 2-way and 3-way file comparison,
  71 ;; merging, and directory operations.
  72
  73
  74
  75 ;;; Bugs:
  76
  77 ;;  1. The undo command doesn't restore deleted regions well. That is, if
  78 ;;  you delete all characters in a difference region and then invoke
  79 ;;  `undo', the reinstated text will most likely be inserted outside of
  80 ;;  what Ediff thinks is the current difference region. (This problem
  81 ;;  doesn't seem to exist with XEmacs.)
  82 ;;
  83 ;;  If at any point you feel that difference regions are no longer correct,
  84 ;;  you can hit '!' to recompute the differences.
  85
  86 ;;  2. On a monochrome display, the repertoire of faces with which to
  87 ;;  highlight fine differences is limited. By default, Ediff is using
  88 ;;  underlining. However, if the region is already underlined by some other
  89 ;;  overlays, there is no simple way to temporarily remove that residual
  90 ;;  underlining. This problem occurs when a buffer is highlighted with
  91 ;;  hilit19.el or font-lock.el packages. If this residual highlighting gets
  92 ;;  in the way, you can do the following. Both font-lock.el and hilit19.el
  93 ;;  provide commands for unhighlighting buffers. You can either place these
  94 ;;  commands in `ediff-prepare-buffer-hook' (which will unhighlight every
  95 ;;  buffer used by Ediff) or you can execute them interactively, at any time
  96 ;;  and on any buffer.
  97
  98
  99 ;;; Acknowledgements:
 100
 101 ;; Ediff was inspired by Dale R. Worley's <drw@math.mit.edu> emerge.el.
 102 ;; Ediff would not have been possible without the help and encouragement of
 103 ;; its many users. See Ediff on-line Info for the full list of those who
 104 ;; helped. Improved defaults in Ediff file-name reading commands.
 105
 106 ;;; Code:
 107
 108 (require 'ediff-init)
 109 (require 'ediff-mult)
 110
 111 (defvar ediff-use-last-dir nil
 112   "*If t, Ediff uses previous directory as default when reading file name.")
 113
 114 (defvar ediff-last-dir-A nil
 115   "Last directory used by an Ediff command for file-A.")
 116 (defvar ediff-last-dir-B nil
 117   "Last directory used by an Ediff command for file-B.")
 118 (defvar ediff-last-dir-C nil
 119   "Last directory used by an Ediff command for file-C.")
 120 (defvar ediff-last-dir-ancestor nil
 121   "Last directory used by an Ediff command for the ancestor file.")
 122 (defvar ediff-last-dir-patch nil
 123   "Last directory used by an Ediff command for file to patch.")
 124
 125 ;;; Patching
 126
 127 (defvar ediff-backup-extension
 128   (if (memq system-type '(vax-vms axp-vms emx ms-dos windows-nt windows-95))
 129       "_orig" ".orig")
 130   "Default backup extension for the patch program.")
 131
 132 ;;;###autoload
 133 (defun ediff-patch-file (source-filename &optional startup-hooks job-name)
 134   "Run Ediff by patching SOURCE-FILENAME."
 135   ;; This now returns the control buffer
 136   (interactive
 137    (list (ediff-read-file-name
 138           "File to patch"
 139           (if ediff-use-last-dir
 140               ediff-last-dir-patch
 141             default-directory)
 142           (ediff-get-default-file-name))))
 143
 144   (setq source-filename (expand-file-name source-filename))
 145   (ediff-get-patch-buffer
 146    (if (eq job-name 'ediff-patch-buffer)
 147        (ediff-eval-in-buffer (get-file-buffer source-filename)
 148          default-directory)
 149      (file-name-directory source-filename)))
 150
 151   (let* ((backup-extension
 152           ;; if the user specified a -b option, extract the backup
 153           ;; extension from there; else use ediff-backup-extension
 154           (substring ediff-patch-options
 155                      (if (string-match "-b[ \t]+" ediff-patch-options)
 156                          (match-end 0) 0)
 157                      (if (string-match "-b[ \t]+[^ \t]+" ediff-patch-options)
 158                          (match-end 0) 0)))
 159          (shell-file-name ediff-shell)
 160          ;; ediff-find-file may use a temp file to do the patch
 161          ;; so, we save source-filename and true-source-filename as a var
 162          ;; that initially is source-filename but may be changed to a temp
 163          ;; file for the purpose of patching.
 164          (true-source-filename source-filename)
 165          (target-filename source-filename)
 166          target-buf buf-to-patch file-name-magic-p ctl-buf backup-style)
 167
 168     ;; if the user didn't specify a backup extension, use
 169     ;; ediff-backup-extension
 170     (if (string= backup-extension "")
 171         (setq backup-extension ediff-backup-extension))
 172     (if (string-match "-V" ediff-patch-options)
 173         (error
 174          "Ediff doesn't take the -V option in `ediff-patch-options'--sorry"))
 175
 176     ;; Make a temp file, if source-filename has a magic file handler (or if
 177     ;; it is handled via auto-mode-alist and similar magic).
 178     ;; Check if there is a buffer visiting source-filename and if they are in
 179     ;; sync; arrange for the deletion of temp file.
 180     (ediff-find-file 'true-source-filename 'buf-to-patch
 181                      'ediff-last-dir-patch 'startup-hooks)
 182
 183     ;; Check if source file name has triggered black magic, such as file name
 184     ;; handlers or auto mode alist, and make a note of it.
 185     ;; true-source-filename should be either the original name or a
 186     ;; temporary file where we put the after-product of the file handler.
 187     (setq file-name-magic-p (not (equal (file-truename true-source-filename)
 188                                         (file-truename source-filename))))
 189
 190     ;; Checkout orig file, if necessary, so that the patched file could be
 191     ;; checked back in.
 192     (if (ediff-file-checked-in-p (buffer-file-name buf-to-patch))
 193         (ediff-toggle-read-only buf-to-patch))
 194
 195     (ediff-eval-in-buffer ediff-patch-diagnostics
 196       (message "Applying patch ... ")
 197       ;; fix environment for gnu patch, so it won't make numbered extensions
 198       (setq backup-style (getenv "VERSION_CONTROL"))
 199       (setenv "VERSION_CONTROL" nil)
 200       ;; always pass patch the -f option, so it won't ask any questions
 201       (shell-command-on-region
 202        (point-min) (point-max)
 203        (format "%s -f %s -b %s %s"
 204                ediff-patch-program ediff-patch-options
 205                backup-extension
 206                (expand-file-name true-source-filename))
 207        t)
 208       ;; restore environment for gnu patch
 209       (setenv "VERSION_CONTROL" backup-style))
 210     ;;(message "Applying patch ... done")(sit-for 0)
 211     (switch-to-buffer ediff-patch-diagnostics)
 212     (sit-for 0) ; synchronize - let the user see diagnostics
 213
 214     (or (file-exists-p (concat true-source-filename backup-extension))
 215         (error "Patch failed or didn't modify the original file"))
 216
 217     ;; If black magic is involved, apply patch to a temp copy of the
 218     ;; file. Otherwise, apply patch to the orig copy.  If patch is applied
 219     ;; to temp copy, we name the result old-name_patched for local files
 220     ;; and temp-copy_patched for remote files. The orig file name isn't
 221     ;; changed, and the temp copy of the original is later deleted.
 222     ;; Without magic, the original file is renamed (usually into
 223     ;; old-name_orig) and the result of patching will have the same name as
 224     ;; the original.
 225     (if (not file-name-magic-p)
 226         (ediff-eval-in-buffer buf-to-patch
 227           (set-visited-file-name (concat source-filename backup-extension))
 228           (set-buffer-modified-p nil))
 229
 230       ;; Black magic in effect.
 231       ;; If orig file was remote, put the patched file in the temp directory.
 232       ;; If orig file is local, put the patched file in the directory of
 233       ;; the orig file.
 234       (setq target-filename
 235             (concat
 236              (if (ediff-file-remote-p (file-truename source-filename))
 237                  true-source-filename
 238                source-filename)
 239              "_patched"))
 240
 241       (rename-file true-source-filename target-filename t)
 242
 243       ;; arrange that the temp copy of orig will be deleted
 244       (rename-file (concat true-source-filename backup-extension)
 245                    true-source-filename t))
 246
 247     ;; make orig buffer read-only
 248     (setq startup-hooks
 249           (cons 'ediff-set-read-only-in-buf-A startup-hooks))
 250
 251     ;; set up a buf for the patched file
 252     (setq target-buf (find-file-noselect target-filename))
 253
 254     (setq ctl-buf
 255           (ediff-buffers-internal
 256            buf-to-patch target-buf nil
 257            startup-hooks (or job-name 'ediff-patch-file)))
 258
 259     (bury-buffer ediff-patch-diagnostics)
 260     (message "Patch diagnostics are available in buffer %s"
 261              (buffer-name ediff-patch-diagnostics))
 262     ctl-buf))
 263
 264 ;; Used as a startup hook to set `_orig' patch file read-only.
 265 (defun ediff-set-read-only-in-buf-A ()
 266   (ediff-eval-in-buffer ediff-buffer-A
 267     (toggle-read-only 1)))
 268
 269 ;; Return a plausible default for ediff's first file:
 270 ;; In dired, return the file name under the point, unless it is a directory
 271 ;; If the buffer has a file name, return that file name.
 272 (defun ediff-get-default-file-name ()
 273   (cond ((eq major-mode 'dired-mode)
 274          (let ((f (dired-get-filename nil 'no-error)))
 275            (if (and (stringp f) (not (file-directory-p f)))
 276                f)))
 277         ((buffer-file-name (current-buffer))
 278          (file-name-nondirectory (buffer-file-name (current-buffer))))
 279         ))
 280
 281 ;;;###autoload
 282 (defalias 'epatch 'ediff-patch-file)
 283 ;;;###autoload
 284 (defalias 'epatch-buffer 'ediff-patch-buffer)
 285
 286 ;;; Compare files/buffers
 287
 288 ;;;###autoload
 289 (defun ediff-files (file-A file-B &optional startup-hooks)
 290   "Run Ediff on a pair of files, FILE-A and FILE-B."
 291   (interactive
 292    (let ((dir-A (if ediff-use-last-dir
 293                     ediff-last-dir-A
 294                   default-directory))
 295          dir-B f)
 296      (list (setq f (ediff-read-file-name
 297                     "File A to compare" dir-A
 298                     (ediff-get-default-file-name)))
 299            (ediff-read-file-name "File B to compare"
 300                                  (setq dir-B
 301                                        (if ediff-use-last-dir
 302                                            ediff-last-dir-B
 303                                          (file-name-directory f)))
 304                                  (progn
 305                                    (setq file-name-history
 306                                          (cons (ediff-abbreviate-file-name
 307                                                 (expand-file-name
 308                                                  (file-name-nondirectory f)
 309                                                  dir-B))
 310                                                file-name-history))
 311                                    f))
 312            )))
 313   (ediff-files-internal file-A
 314                         (if (file-directory-p file-B)
 315                             (expand-file-name
 316                              (file-name-nondirectory file-A) file-B)
 317                           file-B)
 318                         nil ; file-C
 319                         startup-hooks
 320                         'ediff-files))
 321
 322 ;;;###autoload
 323 (defun ediff-files3 (file-A file-B file-C &optional startup-hooks)
 324   "Run Ediff on three files, FILE-A, FILE-B, and FILE-C."
 325   (interactive
 326    (let ((dir-A (if ediff-use-last-dir
 327                     ediff-last-dir-A
 328                   default-directory))
 329          dir-B dir-C f ff)
 330      (list (setq f (ediff-read-file-name
 331                     "File A to compare" dir-A
 332                     (ediff-get-default-file-name)))
 333            (setq ff (ediff-read-file-name "File B to compare"
 334                                           (setq dir-B
 335                                                 (if ediff-use-last-dir
 336                                                     ediff-last-dir-B
 337                                                   (file-name-directory f)))
 338                                           (progn
 339                                             (setq file-name-history
 340                                                   (cons
 341                                                    (ediff-abbreviate-file-name
 342                                                     (expand-file-name
 343                                                      (file-name-nondirectory f)
 344                                                      dir-B))
 345                                                    file-name-history))
 346                                             f)))
 347            (ediff-read-file-name "File C to compare"
 348                                  (setq dir-C (if ediff-use-last-dir
 349                                                  ediff-last-dir-C
 350                                                (file-name-directory ff)))
 351                                  (progn
 352                                    (setq file-name-history
 353                                          (cons (ediff-abbreviate-file-name
 354                                                 (expand-file-name
 355                                                  (file-name-nondirectory ff)
 356                                                  dir-C))
 357                                                file-name-history))
 358                                    ff))
 359            )))
 360   (ediff-files-internal file-A
 361                         (if (file-directory-p file-B)
 362                             (expand-file-name
 363                              (file-name-nondirectory file-A) file-B)
 364                           file-B)
 365                         (if (file-directory-p file-C)
 366                             (expand-file-name
 367                              (file-name-nondirectory file-A) file-C)
 368                           file-C)
 369                         startup-hooks
 370                         'ediff-files3))
 371
 372 ;;;###autoload
 373 (defalias 'ediff3 'ediff-files3)
 374
 375
 376 ;; Visit FILE and arrange its buffer to Ediff's liking.
 377 ;; FILE is actually a variable symbol that must contain a true file name.
 378 ;; BUFFER-NAME is a variable symbol, which will get the buffer object into
 379 ;; which FILE is read.
 380 ;; LAST-DIR is the directory variable symbol where FILE's
 381 ;; directory name should be returned. HOOKS-VAR is a variable symbol that will
 382 ;; be assigned the hook to be executed after `ediff-startup' is finished.
 383 ;; `ediff-find-file' arranges that the temp files it might create will be
 384 ;; deleted.
 385 (defun ediff-find-file (file-var buffer-name &optional last-dir hooks-var)
 386   (let* ((file (symbol-value file-var))
 387          (file-magic (find-file-name-handler file 'find-file-noselect))
 388          (temp-file-name-prefix (file-name-nondirectory file)))
 389     (cond ((not (file-readable-p file))
 390            (error "File `%s' does not exist or is not readable" file))
 391           ((file-directory-p file)
 392            (error "File `%s' is a directory" file)))
 393
 394     ;; some of the commands, below, require full file name
 395     (setq file (expand-file-name file))
 396
 397     ;; Record the directory of the file
 398     (if last-dir
 399         (set last-dir (expand-file-name (file-name-directory file))))
 400
 401     ;; Setup the buffer
 402     (set buffer-name (find-file-noselect file))
 403
 404     (ediff-eval-in-buffer (symbol-value buffer-name)
 405       (widen) ; Make sure the entire file is seen
 406       (cond (file-magic  ;; file has handler, such as jka-compr-handler or
 407              ;; ange-ftp-hook-function--arrange for temp file
 408              (ediff-verify-file-buffer 'magic)
 409              (setq file
 410                    (ediff-make-temp-file
 411                     (current-buffer) temp-file-name-prefix))
 412              (set hooks-var (cons (` (lambda () (delete-file (, file))))
 413                                   (symbol-value hooks-var))))
 414             ;; file processed via auto-mode-alist, a la uncompress.el
 415             ((not (equal (file-truename file)
 416                          (file-truename (buffer-file-name))))
 417              (setq file
 418                    (ediff-make-temp-file
 419                     (current-buffer) temp-file-name-prefix))
 420              (set hooks-var (cons (` (lambda () (delete-file (, file))))
 421                                   (symbol-value hooks-var))))
 422             (t ;; plain file---just check that the file matches the buffer
 423              (ediff-verify-file-buffer))))
 424     (set file-var file)))
 425
 426 (defun ediff-files-internal (file-A file-B file-C startup-hooks job-name)
 427   (let (buf-A buf-B buf-C)
 428     (message "Reading file %s ... " file-A)
 429     ;;(sit-for 0)
 430     (ediff-find-file 'file-A 'buf-A 'ediff-last-dir-A 'startup-hooks)
 431     (message "Reading file %s ... " file-B)
 432     ;;(sit-for 0)
 433     (ediff-find-file 'file-B 'buf-B 'ediff-last-dir-B 'startup-hooks)
 434     (if (stringp file-C)
 435         (progn
 436           (message "Reading file %s ... " file-C)
 437           ;;(sit-for 0)
 438           (ediff-find-file
 439            'file-C 'buf-C
 440            (if (eq job-name 'ediff-merge-files-with-ancestor)
 441                'ediff-last-dir-ancestor 'ediff-last-dir-C)
 442            'startup-hooks)))
 443     (ediff-setup buf-A file-A
 444                  buf-B file-B
 445                  buf-C file-C
 446                  startup-hooks
 447                  (list (cons 'ediff-job-name job-name)))))
 448
 449
 450 ;;;###autoload
 451 (defalias 'ediff 'ediff-files)
 452
 453
 454 ;;;###autoload
 455 (defun ediff-buffers (buffer-A buffer-B &optional startup-hooks job-name)
 456   "Run Ediff on a pair of buffers, BUFFER-A and BUFFER-B."
 457   (interactive
 458    (let (bf)
 459      (list (setq bf (read-buffer "Buffer A to compare: "
 460                                  (ediff-other-buffer "") t))
 461            (read-buffer "Buffer B to compare: "
 462                         (progn
 463                           ;; realign buffers so that two visible bufs will be
 464                           ;; at the top
 465                           (save-window-excursion (other-window 1))
 466                           (ediff-other-buffer bf))
 467                         t))))
 468
 469   (or job-name (setq job-name 'ediff-buffers))
 470   (ediff-buffers-internal buffer-A buffer-B nil startup-hooks job-name))
 471
 472 ;;;###autoload
 473 (defun ediff-buffers3 (buffer-A buffer-B buffer-C
 474                                  &optional startup-hooks job-name)
 475   "Run Ediff on three buffers, BUFFER-A, BUFFER-B, and BUFFER-C."
 476   (interactive
 477    (let (bf bff)
 478      (list (setq bf (read-buffer "Buffer A to compare: "
 479                                  (ediff-other-buffer "") t))
 480            (setq bff (read-buffer "Buffer B to compare: "
 481                                   (progn
 482                                     ;; realign buffers so that two visible
 483                                     ;; bufs will be at the top
 484                                     (save-window-excursion (other-window 1))
 485                                     (ediff-other-buffer bf))
 486                                   t))
 487            (read-buffer "Buffer C to compare: "
 488                                   (progn
 489                                     ;; realign buffers so that three visible
 490                                     ;; bufs will be at the top
 491                                     (save-window-excursion (other-window 1))
 492                                     (ediff-other-buffer (list bf bff)))
 493                                   t)
 494            )))
 495
 496   (or job-name (setq job-name 'ediff-buffers3))
 497   (ediff-buffers-internal buffer-A buffer-B buffer-C startup-hooks job-name))
 498
 499
 500
 501 (defun ediff-buffers-internal (buf-A buf-B buf-C startup-hooks job-name)
 502   (let* ((buf-A-file-name (buffer-file-name (get-buffer buf-A)))
 503          (buf-B-file-name (buffer-file-name (get-buffer buf-B)))
 504          (buf-C-is-alive (ediff-buffer-live-p buf-C))
 505          (buf-C-file-name (if buf-C-is-alive
 506                               (buffer-file-name (get-buffer buf-B))))
 507          file-A file-B file-C)
 508     (if (not (ediff-buffer-live-p buf-A))
 509         (error "Buffer %S doesn't exist" buf-A))
 510     (if (not (ediff-buffer-live-p buf-B))
 511         (error "Buffer %S doesn't exist" buf-B))
 512     (let ((ediff-job-name job-name))
 513       (if (and ediff-3way-comparison-job
 514                (not buf-C-is-alive))
 515           (error "Buffer %S doesn't exist" buf-C)))
 516     (if (stringp buf-A-file-name)
 517         (setq buf-A-file-name (file-name-nondirectory buf-A-file-name)))
 518     (if (stringp buf-B-file-name)
 519         (setq buf-B-file-name (file-name-nondirectory buf-B-file-name)))
 520     (if (stringp buf-C-file-name)
 521         (setq buf-C-file-name (file-name-nondirectory buf-C-file-name)))
 522
 523     (setq file-A (ediff-make-temp-file buf-A buf-A-file-name)
 524           file-B (ediff-make-temp-file buf-B buf-B-file-name))
 525     (if buf-C-is-alive
 526         (setq file-C (ediff-make-temp-file buf-C buf-C-file-name)))
 527
 528     (ediff-setup (get-buffer buf-A) file-A
 529                  (get-buffer buf-B) file-B
 530                  (if buf-C-is-alive (get-buffer buf-C))
 531                  file-C
 532                  (cons (` (lambda ()
 533                             (delete-file (, file-A))
 534                             (delete-file (, file-B))
 535                             (if (stringp (, file-C)) (delete-file (, file-C)))
 536                             ))
 537                        startup-hooks)
 538                  (list (cons 'ediff-job-name job-name))
 539                  )))
 540
 541
 542 ;;; Directory and file group operations
 543
 544 ;; Get appropriate default name for directory:
 545 ;; If ediff-use-last-dir, use ediff-last-dir-A.
 546 ;; In dired mode, use the directory that is under the point (if any);
 547 ;; otherwise, use default-directory
 548 (defun ediff-get-default-directory-name ()
 549   (cond (ediff-use-last-dir ediff-last-dir-A)
 550         ((eq major-mode 'dired-mode)
 551          (let ((f (dired-get-filename nil 'noerror)))
 552            (if (and (stringp f) (file-directory-p f))
 553                f
 554              default-directory)))
 555         (t default-directory)))
 556
 557
 558 ;;;###autoload
 559 (defun ediff-directories (dir1 dir2 regexp)
 560   "Run Ediff on a pair of directories, DIR1 and DIR2, comparing files that have
 561 the same name in both. The third argument, REGEXP, is a regular expression that
 562 further filters the file names."
 563   (interactive
 564    (let ((dir-A (ediff-get-default-directory-name))
 565          f)
 566      (list (setq f (ediff-read-file-name "Directory A to compare" dir-A nil))
 567            (ediff-read-file-name "Directory B to compare"
 568                                  (if ediff-use-last-dir
 569                                      ediff-last-dir-B
 570                                    (ediff-strip-last-dir f))
 571                                  nil)
 572            (read-string "Filter through regular expression: "
 573                         nil ediff-filtering-regexp-history)
 574            )))
 575   (ediff-directories-internal
 576    dir1 dir2 nil regexp 'ediff-files 'ediff-directories
 577    ))
 578
 579 ;;;###autoload
 580 (defalias 'edirs 'ediff-directories)
 581
 582
 583 ;;;###autoload
 584 (defun ediff-directory-revisions (dir1 regexp)
 585   "Run Ediff on a directory, DIR1, comparing its files with their revisions.
 586 The second argument, REGEXP, is a regular expression that filters the file
 587 names. Only the files that are under revision control are taken into account."
 588   (interactive
 589    (let ((dir-A (ediff-get-default-directory-name)))
 590      (list (ediff-read-file-name
 591             "Directory to compare with revision" dir-A nil)
 592            (read-string "Filter through regular expression: "
 593                         nil ediff-filtering-regexp-history)
 594            )))
 595   (ediff-directory-revisions-internal
 596    dir1 regexp 'ediff-revision 'ediff-directory-revisions
 597    ))
 598
 599 ;;;###autoload
 600 (defalias 'edir-revisions 'ediff-directory-revisions)
 601
 602
 603 ;;;###autoload
 604 (defun ediff-directories3 (dir1 dir2 dir3 regexp)
 605   "Run Ediff on three directories, DIR1, DIR2, and DIR3, comparing files that
 606 have the same name in all three. The last argument, REGEXP, is a regular
 607 expression that further filters the file names."
 608   (interactive
 609    (let ((dir-A (ediff-get-default-directory-name))
 610          f)
 611      (list (setq f (ediff-read-file-name "Directory A to compare" dir-A nil))
 612            (setq f (ediff-read-file-name "Directory B to compare"
 613                                          (if ediff-use-last-dir
 614                                              ediff-last-dir-B
 615                                            (ediff-strip-last-dir f))
 616                                          nil))
 617            (ediff-read-file-name "Directory C to compare"
 618                                  (if ediff-use-last-dir
 619                                      ediff-last-dir-C
 620                                    (ediff-strip-last-dir f))
 621                                  nil)
 622            (read-string "Filter through regular expression: "
 623                         nil ediff-filtering-regexp-history)
 624            )))
 625   (ediff-directories-internal
 626    dir1 dir2 dir3 regexp 'ediff-files3 'ediff-directories3
 627    ))
 628
 629 ;;;###autoload
 630 (defalias 'edirs3 'ediff-directories3)
 631
 632 ;;;###autoload
 633 (defun ediff-merge-directories (dir1 dir2 regexp)
 634   "Run Ediff on a pair of directories, DIR1 and DIR2, merging files that have
 635 the same name in both. The third argument, REGEXP, is a regular expression that
 636 further filters the file names."
 637   (interactive
 638    (let ((dir-A (ediff-get-default-directory-name))
 639          f)
 640      (list (setq f (ediff-read-file-name "Directory A to merge" dir-A nil))
 641            (ediff-read-file-name "Directory B to merge"
 642                                  (if ediff-use-last-dir
 643                                      ediff-last-dir-B
 644                                    (ediff-strip-last-dir f))
 645                                  nil)
 646            (read-string "Filter through regular expression: "
 647                         nil ediff-filtering-regexp-history)
 648            )))
 649   (ediff-directories-internal
 650    dir1 dir2 nil regexp 'ediff-merge-files 'ediff-merge-directories
 651    ))
 652
 653 ;;;###autoload
 654 (defalias 'edirs-merge 'ediff-merge-directories)
 655
 656 ;;;###autoload
 657 (defun ediff-merge-directories-with-ancestor (dir1 dir2 dir3 regexp)
 658   "Run Ediff on a pair of directories, DIR1 and DIR2, merging files that have
 659 the same name in both. The third argument, REGEXP, is a regular expression that
 660 further filters the file names."
 661   (interactive
 662    (let ((dir-A (ediff-get-default-directory-name))
 663          f)
 664      (list (setq f (ediff-read-file-name "Directory A to merge" dir-A nil))
 665            (setq f (ediff-read-file-name "Directory B to merge"
 666                                  (if ediff-use-last-dir
 667                                      ediff-last-dir-B
 668                                    (ediff-strip-last-dir f))
 669                                  nil))
 670            (ediff-read-file-name "Ancestor directory: "
 671                                  (if ediff-use-last-dir
 672                                      ediff-last-dir-C
 673                                    (ediff-strip-last-dir f))
 674                                  nil)
 675            (read-string "Filter through regular expression: "
 676                         nil ediff-filtering-regexp-history)
 677            )))
 678   (ediff-directories-internal
 679    dir1 dir2 dir3 regexp
 680    'ediff-merge-files-with-ancestor 'ediff-merge-directories-with-ancestor
 681    ))
 682
 683 ;;;###autoload
 684 (defun ediff-merge-directory-revisions (dir1 regexp)
 685   "Run Ediff on a directory, DIR1, merging its files with their revisions.
 686 The second argument, REGEXP, is a regular expression that filters the file
 687 names. Only the files that are under revision control are taken into account."
 688   (interactive
 689    (let ((dir-A (ediff-get-default-directory-name)))
 690      (list (ediff-read-file-name
 691             "Directory to merge with revisions" dir-A nil)
 692            (read-string "Filter through regular expression: "
 693                         nil ediff-filtering-regexp-history)
 694            )))
 695   (ediff-directory-revisions-internal
 696    dir1 regexp 'ediff-merge-revisions 'ediff-merge-directory-revisions
 697    ))
 698
 699 ;;;###autoload
 700 (defalias 'edir-merge-revisions 'ediff-merge-directory-revisions)
 701
 702 ;;;###autoload
 703 (defun ediff-merge-directory-revisions-with-ancestor (dir1 regexp)
 704   "Run Ediff on a directory, DIR1, merging its files with their revisions and ancestors.
 705 The second argument, REGEXP, is a regular expression that filters the file
 706 names. Only the files that are under revision control are taken into account."
 707   (interactive
 708    (let ((dir-A (ediff-get-default-directory-name)))
 709      (list (ediff-read-file-name
 710             "Directory to merge with revisions and ancestors" dir-A nil)
 711            (read-string "Filter through regular expression: "
 712                         nil ediff-filtering-regexp-history)
 713            )))
 714   (ediff-directory-revisions-internal
 715    dir1 regexp 'ediff-merge-revisions-with-ancestor
 716    'ediff-merge-directory-revisions-with-ancestor
 717    ))
 718
 719 ;;;###autoload
 720 (defalias
 721   'edir-merge-revisions-with-ancestor
 722   'ediff-merge-directory-revisions-with-ancestor)
 723
 724 ;;;###autoload
 725 (defalias 'edirs-merge-with-ancestor 'ediff-merge-directories-with-ancestor)
 726
 727 ;; Run ediff-action (ediff-files, ediff-merge, ediff-merge-with-ancestors)
 728 ;; on a pair of directories (three directories, in case of ancestor).
 729 ;; The third argument, REGEXP, is a regular expression that further filters the
 730 ;; file names.
 731 ;; JOBNAME is the symbol indicating the meta-job to be performed.
 732 (defun ediff-directories-internal (dir1 dir2 dir3 regexp
 733                                         action jobname
 734                                         &optional startup-hooks)
 735   ;; ediff-read-file-name is set to attach a previously entered file name if
 736   ;; the currently entered file is a directory. This code takes care of that.
 737   (setq dir1 (if (file-directory-p dir1) dir1 (file-name-directory dir1))
 738         dir2 (if (file-directory-p dir2) dir2 (file-name-directory dir2)))
 739
 740   (if (stringp dir3)
 741       (setq dir3 (if (file-directory-p dir3) dir3 (file-name-directory dir3))))
 742
 743   (cond ((string= dir1 dir2)
 744          (error "Directories A and B are the same: %s" dir1))
 745         ((and (eq jobname 'ediff-directories3)
 746               (string= dir1 dir3))
 747          (error "Directories A and C are the same: %s" dir1))
 748         ((and (eq jobname 'ediff-directories3)
 749               (string= dir2 dir3))
 750          (error "Directories B and C are the same: %s" dir1)))
 751
 752   (let (diffs ; var where ediff-intersect-directories returns the diff list
 753         file-list meta-buf)
 754     (setq file-list (ediff-intersect-directories
 755                      jobname 'diffs regexp dir1 dir2 dir3))
 756     (setq startup-hooks
 757           ;; this sets various vars in the meta buffer inside
 758           ;; ediff-prepare-meta-buffer
 759           (cons (` (lambda ()
 760                      ;; tell what to do if the user clicks on a session record
 761                      (setq ediff-session-action-function (quote (, action)))
 762                      ;; set ediff-dir-difference-list
 763                      (setq ediff-dir-difference-list (quote (, diffs)))))
 764                 startup-hooks))
 765     (setq meta-buf (ediff-prepare-meta-buffer
 766                     'ediff-dir-action
 767                     file-list
 768                     "*Ediff Session Group Panel"
 769                     'ediff-redraw-directory-group-buffer
 770                     jobname
 771                     startup-hooks))
 772     (ediff-show-meta-buffer meta-buf)
 773     ))
 774
 775 (defun ediff-directory-revisions-internal (dir1 regexp action jobname
 776                                                 &optional startup-hooks)
 777   (setq dir1 (if (file-directory-p dir1) dir1 (file-name-directory dir1)))
 778   (let (file-list meta-buf)
 779     (setq file-list
 780           (ediff-get-directory-files-under-revision jobname regexp dir1))
 781     (setq startup-hooks
 782           ;; this sets various vars in the meta buffer inside
 783           ;; ediff-prepare-meta-buffer
 784           (cons (` (lambda ()
 785                      ;; tell what to do if the user clicks on a session record
 786                      (setq ediff-session-action-function (quote (, action)))
 787                      ))
 788                 startup-hooks))
 789     (setq meta-buf (ediff-prepare-meta-buffer
 790                     'ediff-dir-action
 791                     file-list
 792                     "*Ediff Session Group Panel"
 793                     'ediff-redraw-directory-group-buffer
 794                     jobname
 795                     startup-hooks))
 796     (ediff-show-meta-buffer meta-buf)
 797     ))
 798
 799
 800 ;;; Compare regions and windows
 801
 802 ;;;###autoload
 803 (defun ediff-windows-wordwise (dumb-mode &optional wind-A wind-B startup-hooks)
 804   "Compare WIND-A and WIND-B, which are selected by clicking, wordwise.
 805 With prefix argument, DUMB-MODE, or on a non-windowing display, works as
 806 follows:
 807 If WIND-A is nil, use selected window.
 808 If WIND-B is nil, use window next to WIND-A."
 809   (interactive "P")
 810   (ediff-windows dumb-mode wind-A wind-B
 811                  startup-hooks 'ediff-windows-wordwise 'word-mode))
 812
 813 ;;;###autoload
 814 (defun ediff-windows-linewise (dumb-mode &optional wind-A wind-B startup-hooks)
 815   "Compare WIND-A and WIND-B, which are selected by clicking, linewise.
 816 With prefix argument, DUMB-MODE, or on a non-windowing display, works as
 817 follows:
 818 If WIND-A is nil, use selected window.
 819 If WIND-B is nil, use window next to WIND-A."
 820   (interactive "P")
 821   (ediff-windows dumb-mode wind-A wind-B
 822                  startup-hooks 'ediff-windows-linewise nil))
 823
 824 ;; Compare WIND-A and WIND-B, which are selected by clicking.
 825 ;; With prefix argument, DUMB-MODE, or on a non-windowing display,
 826 ;; works as follows:
 827 ;; If WIND-A is nil, use selected window.
 828 ;; If WIND-B is nil, use window next to WIND-A.
 829 (defun ediff-windows (dumb-mode wind-A wind-B startup-hooks job-name word-mode)
 830   (if (or dumb-mode (not (ediff-window-display-p)))
 831       (setq wind-A (ediff-get-next-window wind-A nil)
 832             wind-B (ediff-get-next-window wind-B wind-A))
 833     (setq wind-A (ediff-get-window-by-clicking wind-A nil 1)
 834           wind-B (ediff-get-window-by-clicking wind-B wind-A 2)))
 835
 836   (let ((buffer-A (window-buffer wind-A))
 837         (buffer-B (window-buffer wind-B))
 838         beg-A end-A beg-B end-B)
 839
 840     (save-excursion
 841       (save-window-excursion
 842         (sit-for 0) ; sync before using window-start/end -- a precaution
 843         (select-window wind-A)
 844         (setq beg-A (window-start)
 845               end-A (window-end))
 846         (select-window wind-B)
 847         (setq beg-B (window-start)
 848               end-B (window-end))))
 849     (ediff-regions-internal
 850      buffer-A beg-A end-A buffer-B beg-B end-B
 851      startup-hooks job-name word-mode)))
 852
 853 ;;;###autoload
 854 (defun ediff-regions-wordwise (buffer-A buffer-B &optional startup-hooks)
 855   "Run Ediff on a pair of regions in two different buffers.
 856 Regions \(i.e., point and mark\) are assumed to be set in advance.
 857 This function is effective only for relatively small regions, up to 200
 858 lines. For large regions, use `ediff-regions-linewise'."
 859   (interactive
 860    (let (bf)
 861      (list (setq bf (read-buffer "Region's A buffer: "
 862                                  (ediff-other-buffer "") t))
 863            (read-buffer "Region's B buffer: "
 864                         (progn
 865                           ;; realign buffers so that two visible bufs will be
 866                           ;; at the top
 867                           (save-window-excursion (other-window 1))
 868                           (ediff-other-buffer bf))
 869                         t))))
 870   (if (not (ediff-buffer-live-p buffer-A))
 871       (error "Buffer %S doesn't exist" buffer-A))
 872   (if (not (ediff-buffer-live-p buffer-B))
 873       (error "Buffer %S doesn't exist" buffer-B))
 874
 875
 876   (let (reg-A-beg reg-A-end reg-B-beg reg-B-end)
 877     (save-excursion
 878       (set-buffer buffer-A)
 879       (setq reg-A-beg (region-beginning)
 880             reg-A-end (region-end))
 881       (set-buffer buffer-B)
 882       (setq reg-B-beg (region-beginning)
 883             reg-B-end (region-end)))
 884
 885     (ediff-regions-internal
 886      (get-buffer buffer-A) reg-A-beg reg-A-end
 887      (get-buffer buffer-B) reg-B-beg reg-B-end
 888      startup-hooks 'ediff-regions-wordwise 'word-mode)))
 889
 890 ;;;###autoload
 891 (defun ediff-regions-linewise (buffer-A buffer-B &optional startup-hooks)
 892   "Run Ediff on a pair of regions in two different buffers.
 893 Regions \(i.e., point and mark\) are assumed to be set in advance.
 894 Each region is enlarged to contain full lines.
 895 This function is effective for large regions, over 100-200
 896 lines. For small regions, use `ediff-regions-wordwise'."
 897   (interactive
 898    (let (bf)
 899      (list (setq bf (read-buffer "Region A's buffer: "
 900                                  (ediff-other-buffer "") t))
 901            (read-buffer "Region B's buffer: "
 902                         (progn
 903                           ;; realign buffers so that two visible bufs will be
 904                           ;; at the top
 905                           (save-window-excursion (other-window 1))
 906                           (ediff-other-buffer bf))
 907                         t))))
 908   (if (not (ediff-buffer-live-p buffer-A))
 909       (error "Buffer %S doesn't exist" buffer-A))
 910   (if (not (ediff-buffer-live-p buffer-B))
 911       (error "Buffer %S doesn't exist" buffer-B))
 912
 913   (let (reg-A-beg reg-A-end reg-B-beg reg-B-end)
 914     (save-excursion
 915       (set-buffer buffer-A)
 916       (setq reg-A-beg (region-beginning)
 917             reg-A-end (region-end))
 918       ;; enlarge the region to hold full lines
 919       (goto-char reg-A-beg)
 920       (beginning-of-line)
 921       (setq reg-A-beg (point))
 922       (goto-char reg-A-end)
 923       (end-of-line)
 924       (or (eobp) (forward-char)) ; include the newline char
 925       (setq reg-A-end (point))
 926
 927       (set-buffer buffer-B)
 928       (setq reg-B-beg (region-beginning)
 929             reg-B-end (region-end))
 930       ;; enlarge the region to hold full lines
 931       (goto-char reg-A-beg)
 932       (goto-char reg-B-beg)
 933       (beginning-of-line)
 934       (setq reg-B-beg (point))
 935       (goto-char reg-B-end)
 936       (end-of-line)
 937       (or (eobp) (forward-char)) ; include the newline char
 938       (setq reg-B-end (point))
 939       ) ; save excursion
 940
 941     (ediff-regions-internal
 942      (get-buffer buffer-A) reg-A-beg reg-A-end
 943      (get-buffer buffer-B) reg-B-beg reg-B-end
 944      startup-hooks 'ediff-regions-linewise nil))) ; no word mode
 945
 946 ;; compare region beg-A to end-A of buffer-A
 947 ;; to regions beg-B -- end-B in buffer-B.
 948 (defun ediff-regions-internal (buffer-A beg-A end-A buffer-B beg-B end-B
 949                                         startup-hooks job-name word-mode)
 950   (let ((tmp-buffer (get-buffer-create ediff-tmp-buffer))
 951         overl-A overl-B
 952         file-A file-B)
 953
 954     ;; in case beg/end-A/B aren't markers--make them into markers
 955     (ediff-eval-in-buffer buffer-A
 956       (setq beg-A (move-marker (make-marker) beg-A)
 957             end-A (move-marker (make-marker) end-A)))
 958     (ediff-eval-in-buffer buffer-B
 959       (setq beg-B (move-marker (make-marker) beg-B)
 960             end-B (move-marker (make-marker) end-B)))
 961
 962     (if (and (eq buffer-A buffer-B)
 963              (or (and (< beg-A end-B) (<= beg-B beg-A))   ; b-B b-A e-B
 964                  (and (< beg-B end-A) (<= end-A end-B)))) ; b-B e-A e-B
 965         (progn
 966           (with-output-to-temp-buffer ediff-msg-buffer
 967             (princ "
 968 You have requested to compare overlapping regions of the same buffer.
 969
 970 In this case, Ediff's highlighting may be confusing---in the same window,
 971 you may see highlighted regions that belong to different regions.
 972
 973 Continue anyway? (y/n) "))
 974
 975           (if (y-or-n-p "Continue anyway? ")
 976               ()
 977             (error "%S aborted" job-name))))
 978
 979     ;; make file-A
 980     (if word-mode
 981         (ediff-wordify beg-A end-A buffer-A tmp-buffer)
 982       (ediff-copy-to-buffer beg-A end-A buffer-A tmp-buffer))
 983     (setq file-A (ediff-make-temp-file tmp-buffer "regA"))
 984
 985     ;; make file-B
 986     (if word-mode
 987         (ediff-wordify beg-B end-B buffer-B tmp-buffer)
 988       (ediff-copy-to-buffer beg-B end-B buffer-B tmp-buffer))
 989     (setq file-B (ediff-make-temp-file tmp-buffer "regB"))
 990
 991     (setq overl-A (ediff-make-bullet-proof-overlay beg-A end-A buffer-A))
 992     (setq overl-B (ediff-make-bullet-proof-overlay beg-B end-B buffer-B))
 993     (ediff-setup buffer-A file-A
 994                  buffer-B file-B
 995                  nil nil            ; buffer & file C
 996                  (cons (` (lambda ()
 997                             (delete-file (, file-A))
 998                             (delete-file (, file-B))))
 999                        startup-hooks)
1000                  (list (cons 'ediff-word-mode  word-mode)
1001                        (cons 'ediff-narrow-bounds (list overl-A overl-B))
1002                        (cons 'ediff-job-name job-name))
1003                  )
1004     ))
1005
1006
1007 ;;; Merge files and buffers
1008
1009 ;;;###autoload
1010 (defalias 'ediff-merge 'ediff-merge-files)
1011
1012 (defsubst ediff-merge-on-startup ()
1013   (ediff-do-merge 0)
1014   (ediff-eval-in-buffer ediff-buffer-C
1015     (set-buffer-modified-p nil)))
1016
1017 ;;;###autoload
1018 (defun ediff-merge-files (file-A file-B &optional startup-hooks)
1019   "Merge two files without ancestor."
1020   (interactive
1021    (let ((dir-A (if ediff-use-last-dir
1022                     ediff-last-dir-A
1023                   default-directory))
1024          dir-B f)
1025      (list (setq f (ediff-read-file-name
1026                     "File A to merge" dir-A
1027                     (ediff-get-default-file-name)))
1028            (ediff-read-file-name "File B to merge"
1029                                  (setq dir-B
1030                                        (if ediff-use-last-dir
1031                                            ediff-last-dir-B
1032                                          (file-name-directory f)))
1033                                  (progn
1034                                    (setq file-name-history
1035                                          (cons (ediff-abbreviate-file-name
1036                                                 (expand-file-name
1037                                                  (file-name-nondirectory f)
1038                                                  dir-B))
1039                                                file-name-history))
1040                                    f))
1041            )))
1042   (setq startup-hooks (cons 'ediff-merge-on-startup startup-hooks))
1043   (ediff-files-internal file-A
1044                         (if (file-directory-p file-B)
1045                             (expand-file-name
1046                              (file-name-nondirectory file-A) file-B)
1047                           file-B)
1048                           nil ; file-C
1049                           startup-hooks
1050                           'ediff-merge-files))
1051
1052 ;;;###autoload
1053 (defun ediff-merge-files-with-ancestor (file-A file-B file-ancestor
1054                                                &optional startup-hooks)
1055   "Merge two files with ancestor."
1056   (interactive
1057    (let ((dir-A (if ediff-use-last-dir
1058                     ediff-last-dir-A
1059                   default-directory))
1060          dir-B dir-ancestor f ff)
1061      (list (setq f (ediff-read-file-name
1062                     "File A to merge" dir-A
1063                     (ediff-get-default-file-name)))
1064            (setq ff (ediff-read-file-name "File B to merge"
1065                                           (setq dir-B
1066                                                 (if ediff-use-last-dir
1067                                                     ediff-last-dir-B
1068                                                   (file-name-directory f)))
1069                                           (progn
1070                                             (setq file-name-history
1071                                                   (cons
1072                                                    (ediff-abbreviate-file-name
1073                                                     (expand-file-name
1074                                                      (file-name-nondirectory f)
1075                                                      dir-B))
1076                                                    file-name-history))
1077                                             f)))
1078            (ediff-read-file-name "Ancestor file"
1079                                  (setq dir-ancestor
1080                                        (if ediff-use-last-dir
1081                                            ediff-last-dir-ancestor
1082                                          (file-name-directory ff)))
1083                                  (progn
1084                                    (setq file-name-history
1085                                          (cons (ediff-abbreviate-file-name
1086                                                 (expand-file-name
1087                                                  (file-name-nondirectory ff)
1088                                                  dir-ancestor))
1089                                                file-name-history))
1090                                    ff))
1091            )))
1092   (setq startup-hooks (cons 'ediff-merge-on-startup startup-hooks))
1093   (ediff-files-internal file-A
1094                         (if (file-directory-p file-B)
1095                             (expand-file-name
1096                              (file-name-nondirectory file-A) file-B)
1097                           file-B)
1098                           file-ancestor
1099                           startup-hooks
1100                           'ediff-merge-files-with-ancestor))
1101
1102 ;;;###autoload
1103 (defalias 'ediff-merge-with-ancestor 'ediff-merge-files-with-ancestor)
1104
1105 ;;;###autoload
1106 (defun ediff-merge-buffers (buffer-A buffer-B &optional startup-hooks job-name)
1107   "Merge buffers without ancestor."
1108   (interactive
1109    (let (bf)
1110      (list (setq bf (read-buffer "Buffer A to merge: "
1111                                  (ediff-other-buffer "") t))
1112            (read-buffer "Buffer B to merge: "
1113                         (progn
1114                           ;; realign buffers so that two visible bufs will be
1115                           ;; at the top
1116                           (save-window-excursion (other-window 1))
1117                           (ediff-other-buffer bf))
1118                         t))))
1119
1120   (setq startup-hooks (cons 'ediff-merge-on-startup startup-hooks))
1121   (or job-name (setq job-name 'ediff-merge-buffers))
1122   (ediff-buffers-internal
1123    buffer-A buffer-B nil startup-hooks job-name))
1124
1125 ;;;###autoload
1126 (defun ediff-merge-buffers-with-ancestor (buffer-A
1127                                           buffer-B buffer-ancestor
1128                                           &optional startup-hooks job-name)
1129   "Merge buffers with ancestor."
1130   (interactive
1131    (let (bf bff)
1132      (list (setq bf (read-buffer "Buffer A to merge: "
1133                                  (ediff-other-buffer "") t))
1134            (setq bff (read-buffer "Buffer B to merge: "
1135                                   (progn
1136                                     ;; realign buffers so that two visible
1137                                     ;; bufs will be at the top
1138                                     (save-window-excursion (other-window 1))
1139                                     (ediff-other-buffer bf))
1140                                   t))
1141            (read-buffer "Ancestor buffer: "
1142                                   (progn
1143                                     ;; realign buffers so that three visible
1144                                     ;; bufs will be at the top
1145                                     (save-window-excursion (other-window 1))
1146                                     (ediff-other-buffer (list bf bff)))
1147                                   t)
1148            )))
1149
1150   (setq startup-hooks (cons 'ediff-merge-on-startup startup-hooks))
1151   (or job-name (setq job-name 'ediff-merge-buffers-with-ancestor))
1152   (ediff-buffers-internal
1153    buffer-A buffer-B buffer-ancestor startup-hooks job-name))
1154
1155
1156 ;;;###autoload
1157 (defun ediff-merge-revisions (&optional file startup-hooks)
1158   "Run Ediff by merging two revisions of a file.
1159 The file is the optional FILE argument or the file visited by the current
1160 buffer."
1161   (interactive)
1162   (if (stringp file) (find-file file))
1163   (let (rev1 rev2)
1164     (setq rev1
1165           (read-string
1166            (format
1167             "Version 1 to merge (default: %s's latest version): "
1168             (if (stringp file)
1169                 (file-name-nondirectory file) "current buffer")))
1170           rev2
1171           (read-string
1172            (format
1173             "Version 2 to merge (default: %s): "
1174             (if (stringp file)
1175                 (file-name-nondirectory file) "current buffer"))))
1176     (ediff-load-version-control)
1177     ;; ancestor-revision=nil
1178     (funcall
1179      (intern (format "%S-ediff-merge-internal" ediff-version-control-package))
1180      rev1 rev2 nil startup-hooks)))
1181
1182
1183 ;;;###autoload
1184 (defun ediff-merge-revisions-with-ancestor (&optional file startup-hooks)
1185   "Run Ediff by merging two revisions of a file with a common ancestor.
1186 The file is the the optional FILE argument or the file visited by the current
1187 buffer."
1188   (interactive)
1189   (if (stringp file) (find-file file))
1190   (let (rev1 rev2 ancestor-rev)
1191     (setq rev1
1192           (read-string
1193            (format
1194             "Version 1 to merge (default: %s's latest version): "
1195             (if (stringp file)
1196                 (file-name-nondirectory file) "current buffer")))
1197           rev2
1198           (read-string
1199            (format
1200             "Version 2 to merge (default: %s): "
1201             (if (stringp file)
1202                 (file-name-nondirectory file) "current buffer")))
1203           ancestor-rev
1204           (read-string
1205            (format
1206             "Ancestor version (default: %s): "
1207             (if (stringp file)
1208                 (file-name-nondirectory file) "current buffer"))))
1209     (ediff-load-version-control)
1210     (funcall
1211      (intern (format "%S-ediff-merge-internal" ediff-version-control-package))
1212      rev1 rev2 ancestor-rev startup-hooks)))
1213
1214 ;;;###autoload
1215 (defun run-ediff-from-cvs-buffer (pos)
1216   "Run Ediff-merge on appropriate revisions of the selected file.
1217 First run after `M-x cvs-update'. Then place the cursor on a lide describing a
1218 file and then run `run-ediff-from-cvs-buffer'."
1219   (interactive "d")
1220   (ediff-load-version-control)
1221   (let ((tin (tin-locate cvs-cookie-handle pos)))
1222     (if tin
1223         (cvs-run-ediff-on-file-descriptor tin)
1224       (error "There is no file to merge"))))
1225
1226
1227 ;;; Apply patch
1228
1229 ;;;###autoload
1230 (defun ediff-patch-buffer (buffer-name &optional startup-hooks)
1231   "Run Ediff by patching BUFFER-NAME."
1232   (interactive "bBuffer to patch: ")
1233
1234   (let* ((buf-to-patch (get-buffer buffer-name))
1235          (file-name-ok (if buf-to-patch (buffer-file-name  buf-to-patch)))
1236          (buf-mod-status (buffer-modified-p buf-to-patch))
1237          default-dir file-name ctl-buf)
1238     (if file-name-ok
1239         (setq file-name file-name-ok)
1240       (ediff-eval-in-buffer buffer-name
1241         (setq default-dir default-directory)
1242         (setq file-name (ediff-make-temp-file buffer-name))
1243         (set-visited-file-name file-name)
1244         (setq buffer-auto-save-file-name nil) ; don't create auto-save file
1245         (rename-buffer buffer-name) ; don't confuse the user with new buf name
1246         (set-buffer-modified-p nil)
1247         (set-visited-file-modtime) ; sync buffer and temp file
1248         (setq default-directory default-dir)
1249         ))
1250
1251     (setq ctl-buf
1252           (ediff-patch-file file-name startup-hooks 'ediff-patch-buffer))
1253
1254     (if file-name-ok
1255         ()
1256       (ediff-eval-in-buffer ctl-buf
1257         (delete-file (buffer-file-name ediff-buffer-A))
1258         (delete-file (buffer-file-name ediff-buffer-B))
1259         (ediff-eval-in-buffer ediff-buffer-A
1260           (if default-dir (setq default-directory default-dir))
1261           (set-visited-file-name nil)
1262           (rename-buffer buffer-name)
1263           (set-buffer-modified-p buf-mod-status))
1264         (ediff-eval-in-buffer ediff-buffer-B
1265           (setq buffer-auto-save-file-name nil) ; don't create auto-save file
1266           (if default-dir (setq default-directory default-dir))
1267           (set-visited-file-name nil)
1268           (rename-buffer (ediff-unique-buffer-name
1269                           (concat buffer-name "_patched") ""))
1270           (set-buffer-modified-p t))))
1271     ))
1272
1273
1274 (defun ediff-get-patch-buffer (dir)
1275   "Obtain patch buffer.  If patch is already in a buffer---use it.
1276 Else, read patch file into a new buffer."
1277   (if (y-or-n-p "Is the patch file already in a buffer? ")
1278       (setq ediff-patch-buf
1279             (get-buffer (read-buffer "Patch buffer name: " nil t))) ;must match
1280     (setq ediff-patch-buf
1281           (find-file-noselect (read-file-name "Patch file name: " dir))))
1282
1283   (setq ediff-patch-diagnostics
1284         (get-buffer-create "*ediff patch diagnostics*"))
1285   (ediff-eval-in-buffer ediff-patch-diagnostics
1286     (insert-buffer ediff-patch-buf)))
1287
1288
1289
1290
1291 \f
1292 ;;; Versions Control functions
1293
1294 ;;;###autoload
1295 (defun ediff-revision (&optional file startup-hooks)
1296   "Run Ediff by comparing versions of a file.
1297 The file is an optional FILE argument or the file visited by the current
1298 buffer. Use `vc.el' or `rcs.el' depending on `ediff-version-control-package'."
1299   ;; if buffer is non-nil, use that buffer instead of the current buffer
1300   (interactive "P")
1301   (if (stringp file) (find-file file))
1302   (let (rev1 rev2)
1303     (setq rev1
1304           (read-string
1305            (format "Version 1 to compare (default: %s's latest version): "
1306                    (if (stringp file)
1307                        (file-name-nondirectory file) "current buffer")))
1308           rev2
1309           (read-string
1310            (format "Version 2 to compare (default: %s): "
1311                    (if (stringp file)
1312                        (file-name-nondirectory file) "current buffer"))))
1313     (ediff-load-version-control)
1314     (funcall
1315      (intern (format "%S-ediff-internal" ediff-version-control-package))
1316      rev1 rev2 startup-hooks)
1317     ))
1318
1319
1320 ;; Test if version control package is loaded and load if not
1321 ;; Is SILENT is non-nil, don't report error if package is not found.
1322 (defun ediff-load-version-control (&optional silent)
1323   (require 'ediff-vers)
1324   (or (featurep ediff-version-control-package)
1325       (if (locate-library (symbol-name ediff-version-control-package))
1326           (progn
1327             (message "") ; kill the message from `locate-library'
1328             (require ediff-version-control-package))
1329         (or silent
1330             (error "Version control package %S.el not found. Use vc.el instead"
1331                    ediff-version-control-package)))))
1332
1333
1334 ;;;###autoload
1335 (defun ediff-version ()
1336   "Return string describing the version of Ediff.
1337 When called interactively, displays the version."
1338   (interactive)
1339   (if (interactive-p)
1340       (message (ediff-version))
1341     (format "Ediff %s of %s" ediff-version ediff-date)))
1342
1343
1344 ;;;###autoload
1345 (defun ediff-documentation ()
1346   "Jump to Ediff's Info file."
1347   (interactive)
1348   (let ((ctl-window ediff-control-window)
1349         (ctl-buf ediff-control-buffer))
1350
1351     (ediff-skip-unsuitable-frames)
1352     (condition-case nil
1353         (progn
1354           (pop-to-buffer (get-buffer-create "*info*"))
1355           (info (if ediff-xemacs-p "ediff.info" "ediff"))
1356           (message "Type `i' to search for a specific topic"))
1357       (error (beep 1)
1358              (with-output-to-temp-buffer " *ediff-info*"
1359                (princ (format "
1360 The Info file for Ediff does not seem to be installed.
1361
1362 This file is part of the distribution of %sEmacs.
1363 Please contact your system administrator. "
1364                               (if ediff-xemacs-p "X" ""))))
1365              (if (window-live-p ctl-window)
1366                  (progn
1367                    (select-window ctl-window)
1368                    (set-window-buffer ctl-window ctl-buf)))))))
1369
1370
1371
1372
1373 ;;; Local Variables:
1374 ;;; eval: (put 'ediff-defvar-local 'lisp-indent-hook 'defun)
1375 ;;; eval: (put 'ediff-eval-in-buffer 'lisp-indent-hook 1)
1376 ;;; End:
1377
1378 (provide 'ediff)
1379 (require 'ediff-util)
1380
1381 ;;; ediff.el ends here