code.delx.au - gnu-emacs/blob - lisp/fast-lock.el

   1 ;;; fast-lock.el --- Automagic text properties caching for fast Font Lock mode.
   2
   3 ;; Copyright (C) 1994, 1995, 1996 Free Software Foundation, Inc.
   4
   5 ;; Author: Simon Marshall <simon@gnu.ai.mit.edu>
   6 ;; Keywords: faces files
   7 ;; Version: 3.09
   8
   9 ;;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; Purpose:
  29 ;;
  30 ;; To make visiting a file in `font-lock-mode' faster by restoring its face
  31 ;; text properties from automatically saved associated Font Lock cache files.
  32 ;;
  33 ;; See caveats and feedback below.
  34 ;; See also the lazy-lock package.  (But don't use the two at the same time!)
  35
  36 ;; Installation:
  37 ;;
  38 ;; Put in your ~/.emacs:
  39 ;;
  40 ;; (add-hook 'font-lock-mode-hook 'turn-on-fast-lock)
  41 ;;
  42 ;; Start up a new Emacs and use font-lock as usual (except that you can use the
  43 ;; so-called "gaudier" fontification regexps on big files without frustration).
  44 ;;
  45 ;; When you visit a file (which has `font-lock-mode' enabled) that has a
  46 ;; corresponding Font Lock cache file associated with it, the Font Lock cache
  47 ;; will be loaded from that file instead of being generated by Font Lock code.
  48
  49 ;; Caveats:
  50 ;;
  51 ;; A cache will be saved when visiting a compressed file using crypt++, but not
  52 ;; be read.  This is a "feature"/"consequence"/"bug" of crypt++.
  53 ;;
  54 ;; Version control packages are likely to stamp all over file modification
  55 ;; times.  Therefore the act of checking out may invalidate a cache.
  56
  57 ;; Feedback:
  58 ;;
  59 ;; Feedback is welcome.
  60 ;; To submit a bug report (or make comments) please use the mechanism provided:
  61 ;;
  62 ;; M-x fast-lock-submit-bug-report RET
  63 \f
  64 ;; History:
  65 ;;
  66 ;; 0.02--1.00:
  67 ;; - Changed name from turbo-prop to fast-lock.  Automagic for font-lock only
  68 ;; - Made `fast-lock-mode' a minor mode, like G. Dinesh Dutt's fss-mode
  69 ;; 1.00--1.01:
  70 ;; - Turn on `fast-lock-mode' only if `buffer-file-name' or `interactive-p'
  71 ;; - Made `fast-lock-file-name' use `buffer-name' if `buffer-file-name' is nil
  72 ;; - Moved save-all conditions to `fast-lock-save-cache'
  73 ;; - Added `fast-lock-save-text-properties' to `kill-buffer-hook'
  74 ;; 1.01--2.00: complete rewrite---not worth the space to document
  75 ;; - Changed structure of text properties cache and threw out file mod checks
  76 ;; 2.00--2.01:
  77 ;; - Made `condition-case' forms understand `quit'.
  78 ;; - Made `fast-lock' require `font-lock'
  79 ;; - Made `fast-lock-cache-name' chase links (from Ben Liblit)
  80 ;; 2.01--3.00:
  81 ;; - Changed structure of cache to include `font-lock-keywords' (from rms)
  82 ;; - Changed `fast-lock-cache-mechanisms' to `fast-lock-cache-directories'
  83 ;; - Removed `fast-lock-read-others'
  84 ;; - Made `fast-lock-read-cache' ignore cache owner
  85 ;; - Made `fast-lock-save-cache-external' create cache directory
  86 ;; - Made `fast-lock-save-cache-external' save `font-lock-keywords'
  87 ;; - Made `fast-lock-cache-data' check `font-lock-keywords'
  88 ;; 3.00--3.01: incorporated port of 2.00 to Lucid, made by Barry Warsaw
  89 ;; - Package now provides itself
  90 ;; - Lucid: Use `font-lock-any-extents-p' for `font-lock-any-properties-p'
  91 ;; - Lucid: Use `list-faces' for `face-list'
  92 ;; - Lucid: Added `set-text-properties'
  93 ;; - Lucid: Made `turn-on-fast-lock' pass 1 not t to `fast-lock-mode'
  94 ;; - Removed test for `fast-lock-mode' from `fast-lock-read-cache'
  95 ;; - Lucid: Added Lucid-specific `fast-lock-get-face-properties'
  96 ;; 3.01--3.02: now works with Lucid Emacs, thanks to Barry Warsaw
  97 ;; - Made `fast-lock-cache-name' map ":" to ";" for OS/2 (from Serganova Vera)
  98 ;; - Made `fast-lock-cache-name' use abbreviated file name (from Barry Warsaw)
  99 ;; - Lucid: Separated handlers for `error' and `quit' for `condition-case'
 100 ;; 3.02--3.03:
 101 ;; - Changed `fast-lock-save-cache-external' to `fast-lock-save-cache-data'
 102 ;; - Lucid: Added Lucid-specific `fast-lock-set-face-properties'
 103 ;; 3.03--3.04:
 104 ;; - Corrected `subrp' test of Lucid code
 105 ;; - Replaced `font-lock-any-properties-p' with `text-property-not-all'
 106 ;; - Lucid: Made `fast-lock-set-face-properties' put `text-prop' on extents
 107 ;; - Made `fast-lock-cache-directories' a regexp alist (from Colin Rafferty)
 108 ;; - Made `fast-lock-cache-directory' to return a usable cache file directory
 109 ;; 3.04--3.05:
 110 ;; - Lucid: Fix for XEmacs 19.11 `text-property-not-all'
 111 ;; - Replaced `subrp' test of Lucid code with `emacs-version' `string-match'
 112 ;; - Made `byte-compile-warnings' omit `unresolved' on compilation
 113 ;; - Made `fast-lock-save-cache-data' use a buffer (from Rick Sladkey)
 114 ;; - Reverted to old `fast-lock-get-face-properties' (from Rick Sladkey)
 115 ;; 3.05--3.06: incorporated hack of 3.03, made by Jonathan Stigelman (Stig)
 116 ;; - Reverted to 3.04 version of `fast-lock-get-face-properties'
 117 ;; - XEmacs: Removed `list-faces' `defalias'
 118 ;; - Made `fast-lock-mode' and `turn-on-fast-lock' succeed `autoload' cookies
 119 ;; - Added `fast-lock-submit-bug-report'
 120 ;; - Renamed `fast-lock-save-size' to `fast-lock-minimum-size'
 121 ;; - Made `fast-lock-save-cache' output a message if no save ever attempted
 122 ;; - Made `fast-lock-save-cache-data' output a message if save attempted
 123 ;; - Made `fast-lock-cache-data' output a message if load attempted
 124 ;; - Made `fast-lock-save-cache-data' do `condition-case' not `unwind-protect'
 125 ;; - Made `fast-lock-save-cache' and `fast-lock-read-cache' return nothing
 126 ;; - Made `fast-lock-save-cache' check `buffer-modified-p' (Stig)
 127 ;; - Added `fast-lock-save-events'
 128 ;; - Added `fast-lock-after-save-hook' to `after-save-hook' (Stig)
 129 ;; - Added `fast-lock-kill-buffer-hook' to `kill-buffer-hook'
 130 ;; - Changed `fast-lock-save-caches' to `fast-lock-kill-emacs-hook'
 131 ;; - Added `fast-lock-kill-emacs-hook' to `kill-emacs-hook'
 132 ;; - Made `fast-lock-save-cache' check `verify-visited-file-modtime' (Stig)
 133 ;; - Made `visited-file-modtime' be the basis of the timestamp (Stig)
 134 ;; - Made `fast-lock-save-cache-1' and `fast-lock-cache-data' use/reformat it
 135 ;; - Added `fast-lock-cache-filename' to keep track of the cache file name
 136 ;; - Added `fast-lock-after-fontify-buffer'
 137 ;; - Added `fast-lock-save-faces' list of faces to save (idea from Stig/Tibor)
 138 ;; - Made `fast-lock-get-face-properties' functions use it
 139 ;; - XEmacs: Made `fast-lock-set-face-properties' do extents the Font Lock way
 140 ;; - XEmacs: Removed fix for `text-property-not-all' (19.11 support dropped)
 141 ;; - Made `fast-lock-mode' ensure `font-lock-mode' is on
 142 ;; - Made `fast-lock-save-cache' do `cdr-safe' not `cdr' (from Dave Foster)
 143 ;; - Made `fast-lock-save-cache' do `set-buffer' first (from Dave Foster)
 144 ;; - Made `fast-lock-save-cache' loop until saved or quit (from Georg Nikodym)
 145 ;; - Made `fast-lock-cache-data' check `buffer-modified-p'
 146 ;; - Made `fast-lock-cache-data' do `font-lock-compile-keywords' if necessary
 147 ;; - XEmacs: Made `font-lock-compile-keywords' `defalias'
 148 ;; 3.06--3.07:
 149 ;; - XEmacs: Add `fast-lock-after-fontify-buffer' to the Font Lock hook
 150 ;; - Made `fast-lock-cache-name' explain the use of `directory-abbrev-alist'
 151 ;; - Made `fast-lock-mode' use `buffer-file-truename' not `buffer-file-name'
 152 ;; 3.07--3.08:
 153 ;; - Made `fast-lock-read-cache' set `fast-lock-cache-filename'
 154 ;; 3.08--3.09:
 155 ;; - Made `fast-lock-save-cache' cope if `fast-lock-minimum-size' is a list
 156 ;; - Made `fast-lock-mode' respect the value of `font-lock-inhibit-thing-lock'
 157 ;; - Added `fast-lock-after-unfontify-buffer'
 158 \f
 159 (require 'font-lock)
 160
 161 (eval-when-compile
 162   ;; Shut Emacs' byte-compiler up (cf. stop me getting mail from users).
 163   (setq byte-compile-warnings '(free-vars callargs redefine)))
 164
 165 (defun fast-lock-submit-bug-report ()
 166   "Submit via mail a bug report on fast-lock.el."
 167   (interactive)
 168   (let ((reporter-prompt-for-summary-p t))
 169     (reporter-submit-bug-report "simon@gnu.ai.mit.edu" "fast-lock 3.09"
 170      '(fast-lock-cache-directories fast-lock-minimum-size
 171        fast-lock-save-others fast-lock-save-events fast-lock-save-faces)
 172      nil nil
 173      (concat "Hi Si.,
 174
 175 I want to report a bug.  I've read the `Bugs' section of `Info' on Emacs, so I
 176 know how to make a clear and unambiguous report.  To reproduce the bug:
 177
 178 Start a fresh Emacs via `" invocation-name " -no-init-file -no-site-file'.
 179 In the `*scratch*' buffer, evaluate:"))))
 180
 181 ;;;###autoload
 182 (defvar fast-lock-mode nil)             ; for modeline
 183 (defvar fast-lock-cache-timestamp nil)  ; for saving/reading
 184 (defvar fast-lock-cache-filename nil)   ; for deleting
 185 \f
 186 ;; User Variables:
 187
 188 (defvar fast-lock-cache-directories '("." "~/.emacs-flc")
 189 ; - `internal', keep each file's Font Lock cache file in the same file.
 190 ; - `external', keep each file's Font Lock cache file in the same directory.
 191   "Directories in which Font Lock cache files are saved and read.
 192 Each item should be either DIR or a cons pair of the form (REGEXP . DIR) where
 193 DIR is a directory name (relative or absolute) and REGEXP is a regexp.
 194
 195 An attempt will be made to save or read Font Lock cache files using these items
 196 until one succeeds (i.e., until a readable or writable one is found).  If an
 197 item contains REGEXP, DIR is used only if the buffer file name matches REGEXP.
 198 For example:
 199
 200  (let ((home (expand-file-name (abbreviate-file-name (file-truename \"~/\")))))
 201    (list (cons (concat \"^\" (regexp-quote home)) \".\") \"~/.emacs-flc\"))
 202     =>
 203  ((\"^/your/true/home/directory/\" . \".\") \"~/.emacs-flc\")
 204
 205 would cause a file's current directory to be used if the file is under your
 206 home directory hierarchy, or otherwise the absolute directory `~/.emacs-flc'.")
 207
 208 (defvar fast-lock-minimum-size (* 25 1024)
 209   "If non-nil, the minimum size for buffers.
 210 Only buffers more than this can have associated Font Lock cache files saved.
 211 If nil, means cache files are never created.
 212 If a list, each element should be a cons pair of the form (MAJOR-MODE . SIZE),
 213 where MAJOR-MODE is a symbol or t (meaning the default).  For example:
 214  ((c++-mode . 25600) (c-mode . 25600) (rmail-mode . 1048576))
 215 means that the minimum size is 25K for buffers in `c++-mode' or `c-mode', one
 216 megabyte for buffers in `rmail-mode', and size is irrelevant otherwise.")
 217
 218 (defvar fast-lock-save-events '(kill-buffer kill-emacs)
 219   "A list of events under which caches will be saved.
 220 Valid events are `save-buffer', `kill-buffer' and `kill-emacs'.
 221 If concurrent editing sessions use the same associated cache file for a file's
 222 buffer, then you should add `save-buffer' to this list.")
 223
 224 (defvar fast-lock-save-others t
 225   "If non-nil, save Font Lock cache files irrespective of file owner.
 226 If nil, means only buffer files known to be owned by you can have associated
 227 Font Lock cache files saved.  Ownership may be unknown for networked files.")
 228
 229 (defvar fast-lock-save-faces
 230   ;; Since XEmacs uses extents for everything, we have to pick the right ones.
 231   ;; In XEmacs 19.13 we can't identify which text properties are Font Lock's.
 232   (if (save-match-data (string-match "XEmacs" (emacs-version)))
 233       '(font-lock-string-face font-lock-doc-string-face font-lock-type-face
 234         font-lock-function-name-face font-lock-comment-face
 235         font-lock-keyword-face font-lock-reference-face
 236         font-lock-preprocessor-face)
 237     ;; For Emacs 19.30 I don't think this is generally necessary.
 238     nil)
 239   "A list of faces that will be saved in a Font Lock cache file.
 240 If nil, means information for all faces will be saved.")
 241 \f
 242 ;; User Functions:
 243
 244 ;;;###autoload
 245 (defun fast-lock-mode (&optional arg)
 246   "Toggle Fast Lock mode.
 247 With arg, turn Fast Lock mode on if and only if arg is positive and the buffer
 248 is associated with a file.  Enable it automatically in your `~/.emacs' by:
 249
 250  (add-hook 'font-lock-mode-hook 'turn-on-fast-lock)
 251
 252 If Fast Lock mode is enabled, and the current buffer does not contain any text
 253 properties, any associated Font Lock cache is used if its timestamp matches the
 254 buffer's file, and its `font-lock-keywords' match those that you are using.
 255
 256 Font Lock caches may be saved:
 257  - When you save the file's buffer.
 258  - When you kill an unmodified file's buffer.
 259  - When you exit Emacs, for all unmodified or saved buffers.
 260 Depending on the value of `fast-lock-save-events'.
 261 See also the commands `fast-lock-read-cache' and `fast-lock-save-cache'.
 262
 263 Use \\[font-lock-fontify-buffer] to fontify the buffer if the cache is bad.
 264
 265 Various methods of control are provided for the Font Lock cache.  In general,
 266 see variable `fast-lock-cache-directories' and function `fast-lock-cache-name'.
 267 For saving, see variables `fast-lock-minimum-size', `fast-lock-save-events',
 268 `fast-lock-save-others' and `fast-lock-save-faces'.
 269
 270 Use \\[fast-lock-submit-bug-report] to send bug reports or feedback."
 271   (interactive "P")
 272   ;; Only turn on if we are visiting a file.  We could use `buffer-file-name',
 273   ;; but many packages temporarily wrap that to nil when doing their own thing.
 274   (set (make-local-variable 'fast-lock-mode)
 275        (and buffer-file-truename
 276             (not (memq 'fast-lock-mode font-lock-inhibit-thing-lock))
 277             (if arg (> (prefix-numeric-value arg) 0) (not fast-lock-mode))))
 278   (if (and fast-lock-mode (not font-lock-mode))
 279       ;; Turned on `fast-lock-mode' rather than using `font-lock-mode-hook'.
 280       (progn
 281         (add-hook 'font-lock-mode-hook 'turn-on-fast-lock)
 282         (font-lock-mode t))
 283     ;; Let's get down to business.
 284     (set (make-local-variable 'fast-lock-cache-timestamp) nil)
 285     (set (make-local-variable 'fast-lock-cache-filename) nil)
 286     (if (and fast-lock-mode (not font-lock-fontified))
 287         (fast-lock-read-cache))))
 288
 289 (defun fast-lock-read-cache ()
 290   "Read the Font Lock cache for the current buffer.
 291
 292 The following criteria must be met for a Font Lock cache file to be read:
 293  - Fast Lock mode must be turned on in the buffer.
 294  - The buffer must not be modified.
 295  - The buffer's `font-lock-keywords' must match the cache's.
 296  - The buffer file's timestamp must match the cache's.
 297  - Criteria imposed by `fast-lock-cache-directories'.
 298
 299 See `fast-lock-mode'."
 300   (interactive)
 301   (let ((directories fast-lock-cache-directories)
 302         (modified (buffer-modified-p)) (inhibit-read-only t)
 303         (fontified font-lock-fontified))
 304     (set (make-local-variable 'font-lock-fontified) nil)
 305     ;; Keep trying directories until fontification is turned off.
 306     (while (and directories (not font-lock-fontified))
 307       (let ((directory (fast-lock-cache-directory (car directories) nil)))
 308         (if (not directory)
 309             nil
 310           (setq fast-lock-cache-filename (fast-lock-cache-name directory))
 311           (condition-case nil
 312               (if (file-readable-p fast-lock-cache-filename)
 313                   (load fast-lock-cache-filename t t t))
 314             (error nil) (quit nil)))
 315         (setq directories (cdr directories))))
 316     ;; Unset `fast-lock-cache-filename', and restore `font-lock-fontified', if
 317     ;; we don't use a cache.  (Note that `fast-lock-cache-data' sets the value
 318     ;; of `fast-lock-cache-timestamp'.)
 319     (set-buffer-modified-p modified)
 320     (if (not font-lock-fontified)
 321         (setq fast-lock-cache-filename nil font-lock-fontified fontified))))
 322
 323 (defun fast-lock-save-cache (&optional buffer)
 324   "Save the Font Lock cache of BUFFER or the current buffer.
 325
 326 The following criteria must be met for a Font Lock cache file to be saved:
 327  - Fast Lock mode must be turned on in the buffer.
 328  - The event must be one of `fast-lock-save-events'.
 329  - The buffer must be at least `fast-lock-minimum-size' bytes long.
 330  - The buffer file must be owned by you, or `fast-lock-save-others' must be t.
 331  - The buffer must contain at least one `face' text property.
 332  - The buffer must not be modified.
 333  - The buffer file's timestamp must be the same as the file's on disk.
 334  - The on disk file's timestamp must be different than the buffer's cache.
 335  - Criteria imposed by `fast-lock-cache-directories'.
 336
 337 See `fast-lock-mode'."
 338   (interactive)
 339   (save-excursion
 340     (and buffer (set-buffer buffer))
 341     (let ((min-size (if (not (consp fast-lock-minimum-size))
 342                         fast-lock-minimum-size
 343                       (cdr (or (assq major-mode fast-lock-minimum-size)
 344                                (assq t fast-lock-minimum-size)))))
 345           (file-timestamp (visited-file-modtime)) (saved nil))
 346       (if (and fast-lock-mode
 347                ;;
 348                ;; "Only save if the buffer matches the file, the file has
 349                ;; changed, and it was changed by the current emacs session."
 350                ;;
 351                ;; Only save if the buffer is not modified,
 352                ;; (i.e., so we don't save for something not on disk)
 353                (not (buffer-modified-p))
 354                ;; and the file's timestamp is the same as the buffer's,
 355                ;; (i.e., someone else hasn't written the file in the meantime)
 356                (verify-visited-file-modtime (current-buffer))
 357                ;; and the file's timestamp is different from the cache's.
 358                ;; (i.e., a save has occurred since the cache was read)
 359                (not (equal fast-lock-cache-timestamp file-timestamp))
 360                ;;
 361                ;; Only save if user's restrictions are satisfied.
 362                (and min-size (>= (buffer-size) min-size))
 363                (or fast-lock-save-others
 364                    (eq (user-uid) (nth 2 (file-attributes buffer-file-name))))
 365                ;;
 366                ;; Only save if there are `face' properties to save.
 367                (text-property-not-all (point-min) (point-max) 'face nil))
 368           ;; Try each directory until we manage to save or the user quits.
 369           (let ((directories fast-lock-cache-directories))
 370             (while (and directories (memq saved '(nil error)))
 371               (let* ((dir (fast-lock-cache-directory (car directories) t))
 372                      (file (and dir (fast-lock-cache-name dir))))
 373                 (if (and file (file-writable-p file))
 374                     (setq saved (fast-lock-save-cache-1 file file-timestamp)))
 375                 (setq directories (cdr directories)))))))))
 376
 377 ;;;###autoload
 378 (defun turn-on-fast-lock ()
 379   "Unconditionally turn on Fast Lock mode."
 380   (fast-lock-mode t))
 381 \f
 382 ;;; API Functions:
 383
 384 (defun fast-lock-after-fontify-buffer ()
 385   ;; Delete the Font Lock cache file used to restore fontification, if any.
 386   (if fast-lock-cache-filename
 387       (if (file-writable-p fast-lock-cache-filename)
 388           (delete-file fast-lock-cache-filename)
 389         (message "File %s font lock cache cannot be deleted" (buffer-name))))
 390   ;; Flag so that a cache will be saved later even if the file is never saved.
 391   (setq fast-lock-cache-timestamp nil))
 392
 393 (defalias 'fast-lock-after-unfontify-buffer
 394   'ignore)
 395 \f
 396 ;; Miscellaneous Functions:
 397
 398 (defun fast-lock-after-save-hook ()
 399   ;; Do `fast-lock-save-cache' if `save-buffer' is on `fast-lock-save-events'.
 400   (if (memq 'save-buffer fast-lock-save-events)
 401       (fast-lock-save-cache)))
 402
 403 (defun fast-lock-kill-buffer-hook ()
 404   ;; Do `fast-lock-save-cache' if `kill-buffer' is on `fast-lock-save-events'.
 405   (if (memq 'kill-buffer fast-lock-save-events)
 406       (fast-lock-save-cache)))
 407
 408 (defun fast-lock-kill-emacs-hook ()
 409   ;; Do `fast-lock-save-cache's if `kill-emacs' is on `fast-lock-save-events'.
 410   (if (memq 'kill-emacs fast-lock-save-events)
 411       (mapcar 'fast-lock-save-cache (buffer-list))))
 412
 413 (defun fast-lock-cache-directory (directory create)
 414   "Return usable directory based on DIRECTORY.
 415 Returns nil if the directory does not exist, or, if CREATE non-nil, cannot be
 416 created.  DIRECTORY may be a string or a cons pair of the form (REGEXP . DIR).
 417 See `fast-lock-cache-directories'."
 418   (let ((dir
 419          (cond ((not buffer-file-name)
 420                 ;; Should never be nil, but `crypt++' screws it up.
 421                 nil)
 422                ((stringp directory)
 423                 ;; Just a directory.
 424                 directory)
 425                (t
 426                 ;; A directory iff the file name matches the regexp.
 427                 (let ((bufile (expand-file-name buffer-file-truename))
 428                       (case-fold-search nil))
 429                   (if (save-match-data (string-match (car directory) bufile))
 430                       (cdr directory)))))))
 431     (cond ((not dir)
 432            nil)
 433           ((file-accessible-directory-p dir)
 434            dir)
 435           (create
 436            (condition-case nil
 437                (progn (make-directory dir t) dir)
 438              (error nil))))))
 439
 440 ;; If you are wondering why we only hash if the directory is not ".", rather
 441 ;; than if `file-name-absolute-p', it is because if we just appended ".flc" for
 442 ;; relative cache directories (that are not ".") then it is possible that more
 443 ;; than one file would have the same cache name in that directory, if the luser
 444 ;; made a link from one relative cache directory to another.  (Phew!)
 445 (defun fast-lock-cache-name (directory)
 446   "Return full cache path name using caching DIRECTORY.
 447 If DIRECTORY is `.', the path is the buffer file name appended with `.flc'.
 448 Otherwise, the path name is constructed from DIRECTORY and the buffer's true
 449 abbreviated file name, with all `/' characters in the name replaced with `#'
 450 characters, and appended with `.flc'.
 451
 452 If the same file has different cache path names when edited on different
 453 machines, e.g., on one machine the cache file name has the prefix `#home',
 454 perhaps due to automount, try putting in your `~/.emacs' something like:
 455
 456  (setq directory-abbrev-alist (cons '(\"^/home/\" . \"/\") directory-abbrev-alist))
 457
 458 Emacs automagically removes the common `/tmp_mnt' automount prefix by default.
 459
 460 See `fast-lock-cache-directory'."
 461   (if (string-equal directory ".")
 462       (concat buffer-file-name ".flc")
 463     (let* ((bufile (expand-file-name buffer-file-truename))
 464            (chars-alist
 465             (if (eq system-type 'emx)
 466                 '((?/ . (?#)) (?# . (?# ?#)) (?: . (?\;)) (?\; . (?\; ?\;)))
 467               '((?/ . (?#)) (?# . (?# ?#)))))
 468            (mapchars
 469             (function (lambda (c) (or (cdr (assq c chars-alist)) (list c))))))
 470       (concat
 471        (file-name-as-directory (expand-file-name directory))
 472        (mapconcat 'char-to-string (apply 'append (mapcar mapchars bufile)) "")
 473        ".flc"))))
 474 \f
 475 ;; Font Lock Cache Processing Functions:
 476
 477 (defun fast-lock-save-cache-1 (file timestamp)
 478   ;; Save the FILE with the TIMESTAMP as:
 479   ;; (fast-lock-cache-data Version=2 TIMESTAMP font-lock-keywords PROPERTIES).
 480   ;; Returns non-nil if a save was attempted to a writable cache file.
 481   (let ((tpbuf (generate-new-buffer " *fast-lock*"))
 482         (buname (buffer-name)) (saved t))
 483     (message "Saving %s font lock cache..." buname)
 484     (condition-case nil
 485         (save-excursion
 486           (print (list 'fast-lock-cache-data 2
 487                        (list 'quote timestamp)
 488                        (list 'quote font-lock-keywords)
 489                        (list 'quote (fast-lock-get-face-properties)))
 490                  tpbuf)
 491           (set-buffer tpbuf)
 492           (write-region (point-min) (point-max) file nil 'quietly)
 493           (setq fast-lock-cache-timestamp timestamp
 494                 fast-lock-cache-filename file))
 495       (error (setq saved 'error)) (quit (setq saved 'quit)))
 496     (kill-buffer tpbuf)
 497     (message "Saving %s font lock cache... %s." buname
 498              (cond ((eq saved 'error) "failed")
 499                    ((eq saved 'quit) "aborted")
 500                    (t "done")))
 501     ;; We return non-nil regardless of whether a failure occurred.
 502     saved))
 503
 504 (defun fast-lock-cache-data (version timestamp keywords properties
 505                              &rest ignored)
 506   ;; Change from (HIGH LOW) for back compatibility.  Remove for version 3!
 507   (if (consp (cdr-safe timestamp)) (setcdr timestamp (nth 1 timestamp)))
 508   ;; Compile KEYWORDS and `font-lock-keywords' in case one is and one isn't.
 509   (let ((current font-lock-keywords))
 510     (setq keywords (font-lock-compile-keywords keywords)
 511           font-lock-keywords (font-lock-compile-keywords current)))
 512   ;; Use the Font Lock cache PROPERTIES if we're using cache VERSION format 2,
 513   ;; the current buffer's file timestamp matches the TIMESTAMP, and the current
 514   ;; buffer's font-lock-keywords are the same as KEYWORDS.
 515   (let ((buf-timestamp (visited-file-modtime))
 516         (buname (buffer-name)) (loaded t))
 517     (if (or (/= version 2)
 518             (buffer-modified-p)
 519             (not (equal timestamp buf-timestamp))
 520             (not (equal keywords font-lock-keywords)))
 521         (setq loaded nil)
 522       (message "Loading %s font lock cache..." buname)
 523       (condition-case nil
 524           (fast-lock-set-face-properties properties)
 525         (error (setq loaded 'error)) (quit (setq loaded 'quit)))
 526       (message "Loading %s font lock cache... %s." buname
 527                (cond ((eq loaded 'error) "failed")
 528                      ((eq loaded 'quit) "aborted")
 529                      (t "done"))))
 530     (setq font-lock-fontified (eq loaded t)
 531           fast-lock-cache-timestamp (and (eq loaded t) timestamp))))
 532 \f
 533 ;; Text Properties Processing Functions:
 534
 535 ;; This is faster, but fails if adjacent characters have different `face' text
 536 ;; properties.  Maybe that's why I dropped it in the first place?
 537 ;(defun fast-lock-get-face-properties ()
 538 ;  "Return a list of all `face' text properties in the current buffer.
 539 ;Each element of the list is of the form (VALUE START1 END1 START2 END2 ...)
 540 ;where VALUE is a `face' property value and STARTx and ENDx are positions."
 541 ;  (save-restriction
 542 ;    (widen)
 543 ;    (let ((start (text-property-not-all (point-min) (point-max) 'face nil))
 544 ;         (limit (point-max)) end properties value cell)
 545 ;      (while start
 546 ;       (setq end (next-single-property-change start 'face nil limit)
 547 ;             value (get-text-property start 'face))
 548 ;       ;; Make, or add to existing, list of regions with same `face'.
 549 ;       (if (setq cell (assq value properties))
 550 ;           (setcdr cell (cons start (cons end (cdr cell))))
 551 ;         (setq properties (cons (list value start end) properties)))
 552 ;       (setq start (next-single-property-change end 'face)))
 553 ;      properties)))
 554
 555 (defun fast-lock-get-face-properties ()
 556   "Return a list of all `face' text properties in the current buffer.
 557 Each element of the list is of the form (VALUE START1 END1 START2 END2 ...)
 558 where VALUE is a `face' property value and STARTx and ENDx are positions.
 559 Only those `face' VALUEs in `fast-lock-save-faces' are returned."
 560   (save-restriction
 561     (widen)
 562     (let ((faces (or fast-lock-save-faces (face-list))) (limit (point-max))
 563           properties regions face start end)
 564       (while faces
 565         (setq face (car faces) faces (cdr faces) regions () end (point-min))
 566         ;; Make a list of start/end regions with `face' property face.
 567         (while (setq start (text-property-any end limit 'face face))
 568           (setq end (or (text-property-not-all start limit 'face face) limit)
 569                 regions (cons start (cons end regions))))
 570         ;; Add `face' face's regions, if any, to properties.
 571         (if regions (setq properties (cons (cons face regions) properties))))
 572       properties)))
 573
 574 (defun fast-lock-set-face-properties (properties)
 575   "Set all `face' text properties to PROPERTIES in the current buffer.
 576 Any existing `face' text properties are removed first.  Leaves buffer modified.
 577 See `fast-lock-get-face-properties' for the format of PROPERTIES."
 578   (save-restriction
 579     (widen)
 580     (font-lock-unfontify-region (point-min) (point-max))
 581     (while properties
 582       (let ((plist (list 'face (car (car properties))))
 583             (regions (cdr (car properties))))
 584         ;; Set the `face' property for each start/end region.
 585         (while regions
 586           (set-text-properties (nth 0 regions) (nth 1 regions) plist)
 587           (setq regions (nthcdr 2 regions)))
 588         (setq properties (cdr properties))))))
 589 \f
 590 ;; Functions for XEmacs:
 591
 592 (if (save-match-data (string-match "XEmacs" (emacs-version)))
 593     ;; It would be better to use XEmacs 19.12's `map-extents' over extents with
 594     ;; `font-lock' property, but `face' properties are on different extents.
 595     (defun fast-lock-get-face-properties ()
 596       "Return a list of all `face' text properties in the current buffer.
 597 Each element of the list is of the form (VALUE START1 END1 START2 END2 ...)
 598 where VALUE is a `face' property value and STARTx and ENDx are positions.
 599 Only those `face' VALUEs in `fast-lock-save-faces' are returned."
 600       (save-restriction
 601         (widen)
 602         (let ((properties ()) cell)
 603           (map-extents
 604            (function
 605             (lambda (extent ignore)
 606               (let ((value (extent-face extent)))
 607                 ;; We're only interested if it's one of `fast-lock-save-faces'.
 608                 (if (and value (or (null fast-lock-save-faces)
 609                                    (memq value fast-lock-save-faces)))
 610                     (let ((start (extent-start-position extent))
 611                           (end (extent-end-position extent)))
 612                       ;; Make or add to existing list of regions with the same
 613                       ;; `face' property value.
 614                       (if (setq cell (assq value properties))
 615                           (setcdr cell (cons start (cons end (cdr cell))))
 616                         (setq properties (cons (list value start end)
 617                                                properties)))))
 618                 ;; Return nil to keep `map-extents' going.
 619                 nil))))
 620           properties))))
 621
 622 (if (save-match-data (string-match "XEmacs" (emacs-version)))
 623     ;; Make extents just like XEmacs's font-lock.el does.
 624     (defun fast-lock-set-face-properties (properties)
 625       "Set all `face' text properties to PROPERTIES in the current buffer.
 626 Any existing `face' text properties are removed first.
 627 See `fast-lock-get-face-properties' for the format of PROPERTIES."
 628       (save-restriction
 629         (widen)
 630         (font-lock-unfontify-region (point-min) (point-max))
 631         (while properties
 632           (let ((face (car (car properties)))
 633                 (regions (cdr (car properties))))
 634             ;; Set the `face' property, etc., for each start/end region.
 635             (while regions
 636               (font-lock-set-face (nth 0 regions) (nth 1 regions) face)
 637               (setq regions (nthcdr 2 regions)))
 638             (setq properties (cdr properties)))))))
 639
 640 (if (save-match-data (string-match "XEmacs" (emacs-version)))
 641     ;; XEmacs 19.12 font-lock.el's `font-lock-fontify-buffer' runs a hook.
 642     (add-hook 'font-lock-after-fontify-buffer-hook
 643               'fast-lock-after-fontify-buffer))
 644
 645 (or (boundp 'font-lock-inhibit-thing-lock)
 646     (defvar font-lock-inhibit-thing-lock nil
 647       "List of Font Lock mode related modes that should not be turned on."))
 648
 649 (or (fboundp 'font-lock-compile-keywords)
 650     (defalias 'font-lock-compile-keywords 'identity))
 651 \f
 652 ;; Install ourselves:
 653
 654 ;; We don't install ourselves on `font-lock-mode-hook' as packages with similar
 655 ;; functionality exist, and fast-lock.el should be dumpable without forcing
 656 ;; people to use caches or making it difficult for people to use alternatives.
 657 (add-hook 'after-save-hook 'fast-lock-after-save-hook)
 658 (add-hook 'kill-buffer-hook 'fast-lock-kill-buffer-hook)
 659 (add-hook 'kill-emacs-hook 'fast-lock-kill-emacs-hook)
 660
 661 (or (assq 'fast-lock-mode minor-mode-alist)
 662     (setq minor-mode-alist (append minor-mode-alist '((fast-lock-mode nil)))))
 663
 664 ;; Provide ourselves:
 665
 666 (provide 'fast-lock)
 667
 668 ;;; fast-lock.el ends here