code.delx.au - gnu-emacs/blob - lisp/progmodes/meta-mode.el

   1 ;;; meta-mode.el --- major mode for editing Metafont or MetaPost sources
   2
   3 ;; Copyright (C) 1997, 2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008
   4 ;; Free Software Foundation, Inc.
   5
   6 ;; Author: Ulrik Vieth <vieth@thphy.uni-duesseldorf.de>
   7 ;; Version: 1.0
   8 ;; Keywords: Metafont, MetaPost, tex, languages
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; Description:
  28 ;;
  29 ;; This Emacs Lisp package provides a major mode for editing Metafont
  30 ;; or MetaPost sources.  It includes all the necessary code to set up
  31 ;; a major mode including an approriate syntax table, keymap, and a
  32 ;; mode-specific pull-down menu.  It also provides a sophisticated set
  33 ;; of font-lock patterns, a fancy indentation function adapted from
  34 ;; AUCTeX's latex.el, and some basic mode-specific editing functions
  35 ;; such as functions to move to the beginning or end of the enclosing
  36 ;; environment, or to mark, re-indent, or comment-out environments.
  37 ;; On the other hand, it doesn't yet provide any functionality for
  38 ;; running Metafont or MetaPost in a shell buffer form within Emacs,
  39 ;; but such functionality might be added later, either as part of this
  40 ;; package or as a separate Emacs Lisp package.
  41
  42 ;; Installation:
  43 ;;
  44 ;; An interface to running Metafont or MetaPost as a shell process
  45 ;; from within Emacs is currently under development as a separate
  46 ;; Emacs Lisp package (meta-buf.el).  In order to have that package
  47 ;; loaded automatically when first entering Metafont or MetaPost mode,
  48 ;; you might use the load-hook provided in this package by adding
  49 ;; these lines to your startup file:
  50 ;;
  51 ;;  (add-hook 'meta-mode-load-hook
  52 ;;            (lambda () (require 'meta-buf)))
  53 ;;
  54 ;; The add-on package loaded this way may in turn make use of the
  55 ;; mode-hooks provided in this package to activate additional features
  56 ;; when entering Metafont or MetaPost mode.
  57
  58 ;; Font Lock Support:
  59 ;;
  60 ;; If you are using global-font-lock-mode (introduced in Emacs 19.31),
  61 ;; fontification in Metafont and/or MetaPost mode will be activated
  62 ;; automatically.  To speed up fontification for the rather complex
  63 ;; patterns used in these modes, it may be a good idea to activate
  64 ;; lazy-lock as a font-lock-support-mode (introduced in Emacs 19.32)
  65 ;; by adding these lines to your startup file:
  66 ;;
  67 ;;  (global-font-lock-mode t)
  68 ;;  (setq font-lock-support-mode 'lazy-lock-mode)
  69 ;;
  70 ;; If you are using an older version of Emacs, which doesn't provide
  71 ;; global-font-lock-mode or font-lock-support-mode, you can also
  72 ;; activate fontification in Metafont and/or MetaPost mode by adding
  73 ;; the following lines to your startup file:
  74 ;;
  75 ;;  (add-hook 'meta-common-mode-hook 'turn-on-font-lock)
  76 ;;  (add-hook 'meta-common-mode-hook 'turn-on-lazy-lock)
  77
  78 ;; Customization:
  79 ;;
  80 ;; Following the usual Emacs Lisp coding conventions, the major modes
  81 ;; defined in this package provide several hook variables to allow for
  82 ;; local customization when entering the modes.  In particular, there
  83 ;; is a `meta-common-mode-hook' which applies to both modes as well as
  84 ;; `metafont-mode-hook' and `metapost-mode-hook' which apply to the
  85 ;; individual modes.  In addition, there are several variables and
  86 ;; regexps controlling e.g. the behavior of the indentation function,
  87 ;; which may be customized via `edit-options'.  Please refer to the
  88 ;; docstrings in the code below for details.
  89
  90 ;; Availability:
  91 ;;
  92 ;; This package is currently available via my "TeX Software" WWW page:
  93 ;;
  94 ;;  http://www.thphy.uni-duesseldorf.de/~vieth/subjects/tex/software.html
  95 ;;
  96 ;; As of this version 1.0, this package will be uploaded to CTAN
  97 ;; archives, where it shall find a permanent home, presumably in
  98 ;; tex-archive/support/emacs-modes.  It will also be submitted for
  99 ;; integration into the GNU Emacs distribution at that time.
 100 ;;
 101 ;; History:
 102 ;;
 103 ;; v 0.0 -- 1997/02/01  UV  Started writing meta-mode.el.
 104 ;; v 0.1 -- 1997/02/02  UV  Added preliminary set of font-lock patterns.
 105 ;; v 0.2 -- 1997/02/03  UV  Improved and debugged font-lock patterns.
 106 ;;                          Added indent-line-function for TAB.
 107 ;; v 0.3 -- 1997/02/17  UV  Improved font-lock patterns and syntax table.
 108 ;;                          Improved and debbuged indentation function.
 109 ;; v 0.4 -- 1997/02/18  UV  Added functions to indent regions for M-C-q,
 110 ;;                          also added a preliminary mode-specific menu.
 111 ;; v 0.5 -- 1997/02/19  UV  Added functions to skip to next or previous
 112 ;;                          defun and to re-indent or comment-out defuns.
 113 ;; v 0.6 -- 1997/02/20  UV  More debugging, testing and clean-up.
 114 ;; v 0.7 -- 1997/02/22  UV  Use easymenu to define mode-specific menu.
 115 ;; v 0.8 -- 1997/02/24  UV  Added completion function for M-TAB.
 116 ;; v 0.9 -- 1997/03/08  UV  Added fill-paragraph function for comments.
 117 ;;                          Also fixed a few remaining font-lock problems.
 118 ;;                          Added meta-mode-load-hook to load meta-buf.el.
 119 ;; v 1.0 -- 1997/04/07  UV  Cleanup for official public release.
 120 ;;
 121 ;; Historical Footnote:
 122 ;;
 123 ;; This package was begun on February 1, 1997, exactly 20 years after
 124 ;; the genesis of TeX took place according to Don Knuth's own account
 125 ;; (cf.  ``The Errors of TeX'', reprinted in ``Literate Programming'',
 126 ;; Chapter 10, p. 249).  What better date could there be to choose?
 127 ;;
 128
 129 \f
 130 ;;; Code:
 131
 132 (require 'easymenu)
 133
 134 (defgroup meta-font nil
 135   "Major mode for editing Metafont or MetaPost sources."
 136   :link '(custom-group-link :tag "Font Lock Faces group" font-lock-faces)
 137   :group 'languages)
 138
 139 ;;; Fontification.
 140
 141 (defvar meta-font-lock-keywords
 142       (let ((input-keywords
 143              "\\(input\\|generate\\)")
 144             (begin-keywords
 145              (concat "\\(begin\\(char\\|fig\\|graph\\|logochar\\)\\|"
 146                      "\\cmchar\\|dcchar\\|ecchar\\)"))
 147             (end-keywords
 148              "\\(end\\(char\\|fig\\|graph\\)\\)")
 149             (macro-keywords-1
 150              "\\(def\\|let\\|mode_def\\|vardef\\)")
 151             (macro-keywords-2
 152              "\\(primarydef\\|secondarydef\\|tertiarydef\\)")
 153 ;(make-regexp
 154 ; '("expr" "suffix" "text" "primary" "secondary" "tertiary") t)
 155             (args-keywords
 156              (concat "\\(expr\\|primary\\|s\\(econdary\\|uffix\\)\\|"
 157                      "te\\(rtiary\\|xt\\)\\)"))
 158 ;(make-regexp
 159 ; '("boolean" "color" "numeric" "pair" "path" "pen" "picture"
 160 ;   "string" "transform" "newinternal") t)
 161             (type-keywords
 162              (concat "\\(boolean\\|color\\|n\\(ewinternal\\|umeric\\)\\|"
 163                      "p\\(a\\(ir\\|th\\)\\|en\\|icture\\)\\|string\\|"
 164                      "transform\\)"))
 165 ;(make-regexp
 166 ; '("for" "forever" "forsuffixes" "endfor"
 167 ;   "step" "until" "upto" "downto" "thru" "within"
 168 ;   "iff" "if" "elseif" "else" "fi" "exitif" "exitunless"
 169 ;   "let" "def" "vardef" "enddef" "mode_def"
 170 ;   "true" "false" "known" "unknown" "and" "or" "not"
 171 ;   "save" "interim" "inner" "outer" "relax"
 172 ;   "begingroup" "endgroup" "expandafter" "scantokens"
 173 ;   "generate" "input" "endinput" "end" "bye"
 174 ;   "message" "errmessage" "errhelp" "special" "numspecial"
 175 ;   "readstring" "readfrom" "write") t)
 176             (syntactic-keywords
 177              (concat "\\(and\\|b\\(egingroup\\|ye\\)\\|"
 178                      "d\\(ef\\|ownto\\)\\|e\\(lse\\(\\|if\\)"
 179                      "\\|nd\\(\\|def\\|for\\|group\\|input\\)"
 180                      "\\|rr\\(help\\|message\\)"
 181                      "\\|x\\(it\\(if\\|unless\\)\\|pandafter\\)\\)\\|"
 182                      "f\\(alse\\|i\\|or\\(\\|ever\\|suffixes\\)\\)\\|"
 183                      "generate\\|i\\(ff?\\|n\\(ner\\|put\\|terim\\)\\)\\|"
 184                      "known\\|let\\|m\\(essage\\|ode_def\\)\\|"
 185                      "n\\(ot\\|umspecial\\)\\|o\\(r\\|uter\\)\\|"
 186                      "re\\(ad\\(from\\|string\\)\\|lax\\)\\|"
 187                      "s\\(ave\\|cantokens\\|pecial\\|tep\\)\\|"
 188                      "t\\(hru\\|rue\\)\\|"
 189                      "u\\(n\\(known\\|til\\)\\|pto\\)\\|"
 190                      "vardef\\|w\\(ithin\\|rite\\)\\)"))
 191             )
 192         (list
 193          ;; embedded TeX code in btex ... etex
 194          (cons (concat "\\(btex\\|verbatimtex\\)"
 195                        "[ \t\f]+\\(.*\\)[ \t\f]+"
 196                        "\\(etex\\)")
 197                '((1 font-lock-keyword-face)
 198                  (2 font-lock-string-face)
 199                  (3 font-lock-keyword-face)))
 200          ;; unary macro definitions: def, vardef, let
 201          (cons (concat "\\<" macro-keywords-1 "\\>"
 202                        "[ \t\f]+\\(\\sw+\\|\\s_+\\|\\s.+\\)")
 203                '((1 font-lock-keyword-face)
 204                  (2 font-lock-function-name-face)))
 205          ;; binary macro defintions: <leveldef> x operator y
 206          (cons (concat "\\<" macro-keywords-2 "\\>"
 207                        "[ \t\f]+\\(\\sw+\\)"
 208                        "[ \t\f]*\\(\\sw+\\|\\s.+\\)"
 209                        "[ \t\f]*\\(\\sw+\\)")
 210                '((1 font-lock-keyword-face)
 211                  (2 font-lock-variable-name-face nil t)
 212                  (3 font-lock-function-name-face nil t)
 213                  (4 font-lock-variable-name-face nil t)))
 214          ;; variable declarations: numeric, pair, color, ...
 215          (cons (concat "\\<" type-keywords "\\>"
 216                        "\\([ \t\f]+\\(\\sw+\\)\\)*")
 217                '((1 font-lock-type-face)
 218                  (font-lock-match-meta-declaration-item-and-skip-to-next
 219                   (goto-char (match-end 1)) nil
 220                   (1 font-lock-variable-name-face nil t))))
 221          ;; argument declarations: expr, suffix, text, ...
 222          (cons (concat "\\<" args-keywords "\\>"
 223                        "\\([ \t\f]+\\(\\sw+\\|\\s_+\\)\\)*")
 224                '((1 font-lock-type-face)
 225                  (font-lock-match-meta-declaration-item-and-skip-to-next
 226                   (goto-char (match-end 1)) nil
 227                   (1 font-lock-variable-name-face nil t))))
 228          ;; special case of arguments: expr x of y
 229          (cons (concat "\\(expr\\)[ \t\f]+\\(\\sw+\\)"
 230                        "[ \t\f]+\\(of\\)[ \t\f]+\\(\\sw+\\)")
 231                '((1 font-lock-type-face)
 232                  (2 font-lock-variable-name-face)
 233                  (3 font-lock-keyword-face nil t)
 234                  (4 font-lock-variable-name-face nil t)))
 235          ;; syntactic keywords
 236          (cons (concat "\\<" syntactic-keywords "\\>")
 237                'font-lock-keyword-face)
 238          ;; beginchar, beginfig
 239          (cons (concat "\\<" begin-keywords "\\>")
 240                'font-lock-keyword-face)
 241          ;; endchar, endfig
 242          (cons (concat "\\<" end-keywords "\\>")
 243                'font-lock-keyword-face)
 244          ;; input, generate
 245          (cons (concat "\\<" input-keywords "\\>"
 246                        "[ \t\f]+\\(\\sw+\\)")
 247                '((1 font-lock-keyword-face)
 248                  (2 font-lock-constant-face)))
 249          ;; embedded Metafont/MetaPost code in comments
 250          (cons "|\\([^|]+\\)|"
 251                '(1 font-lock-constant-face t))
 252      ))
 253   "Default expressions to highlight in Metafont or MetaPost mode.")
 254
 255
 256 (defun font-lock-match-meta-declaration-item-and-skip-to-next (limit)
 257   ;; Match and move over Metafont/MetaPost declaration item after point.
 258   ;;
 259   ;; The expected syntax of an item is either "word" or "symbol",
 260   ;; possibly ending with optional whitespace.  Everything following
 261   ;; the item (but belonging to it) is expected to by skipable by
 262   ;; `forward-sexp'.  The list of items is expected to be separated
 263   ;; by commas and terminated by semicolons or equals signs.
 264   ;;
 265   (if (looking-at "[ \t\f]*\\(\\sw+\\|\\s_+\\)")
 266       (save-match-data
 267         (condition-case nil
 268             (save-restriction
 269               ;; Restrict to end of line, currently guaranteed to be LIMIT.
 270               (narrow-to-region (point-min) limit)
 271               (goto-char (match-end 1))
 272               ;; Move over any item value, etc., to the next item.
 273               (while (not (looking-at "[ \t\f]*\\(\\(,\\)\\|;\\|=\\|$\\)"))
 274                 (goto-char (or (scan-sexps (point) 1) (point-max))))
 275               (goto-char (match-end 2)))
 276           (error t)))))
 277
 278
 279 \f
 280 ;;; Completion.
 281
 282 ;; The data used to prepare the following lists of primitives and
 283 ;; standard macros available in Metafont or MetaPost was extracted
 284 ;; from the original sources like this:
 285 ;;
 286 ;;   grep '^primitive' texk-7.0/web2c/{mf,mp}.web |\
 287 ;;   sed 's/primitive(\("[a-zA-Z]*"\).*/\1/' > {mf,mp}_prim.list
 288 ;;
 289 ;;   grep '\(let\|def\|vardef\|primarydef\|secondarydef\|tertiarydef\)'
 290 ;;     texmf/meta{font,post}/plain.{mf,mp} > {mf,mp}_plain.list
 291
 292 (defconst meta-common-primitives-list
 293   '("ASCII" "addto" "also" "and" "angle" "atleast" "batchmode"
 294     "begingroup" "boolean" "boundarychar" "char" "charcode" "chardp"
 295     "charexists" "charext" "charht" "charic" "charlist" "charwd"
 296     "contour" "controls" "cosd" "curl" "cycle" "day" "decimal" "def"
 297     "delimiters" "designsize" "directiontime" "doublepath" "dump" "else"
 298     "elseif" "end" "enddef" "endfor" "endgroup" "endinput" "errhelp"
 299     "errmessage" "errorstopmode" "everyjob" "exitif" "expandafter"
 300     "expr" "extensible" "false" "fi" "floor" "fontdimen" "fontmaking"
 301     "for" "forever" "forsuffixes" "headerbyte" "hex" "if" "inner"
 302     "input" "interim" "intersectiontimes" "jobname" "kern" "known"
 303     "length" "let" "ligtable" "makepath" "makepen" "message" "mexp"
 304     "mlog" "month" "newinternal" "nonstopmode" "normaldeviate" "not"
 305     "nullpen" "nullpicture" "numeric" "oct" "odd" "of" "or" "outer"
 306     "pair" "path" "pausing" "pen" "pencircle" "penoffset" "picture"
 307     "point" "postcontrol" "precontrol" "primary" "primarydef" "quote"
 308     "randomseed" "readstring" "reverse" "rotated" "save" "scaled"
 309     "scantokens" "scrollmode" "secondary" "secondarydef" "shifted"
 310     "shipout" "show" "showdependencies" "showstats" "showstopping"
 311     "showtoken" "showvariable" "sind" "skipto" "slanted" "special"
 312     "sqrt" "step" "str" "string" "subpath" "substring" "suffix"
 313     "tension" "tertiary" "tertiarydef" "text" "time" "to"
 314     "tracingcapsules" "tracingchoices" "tracingcommands"
 315     "tracingequations" "tracingmacros" "tracingonline" "tracingoutput"
 316     "tracingrestores" "tracingspecs" "tracingstats" "tracingtitles"
 317     "transform" "transformed" "true" "turningnumber" "uniformdeviate"
 318     "unknown" "until" "vardef" "warningcheck" "withpen" "xpart"
 319     "xscaled" "xxpart" "xypart" "year" "ypart" "yscaled" "yxpart"
 320     "yypart" "zscaled")
 321   "List of primitives common to Metafont and MetaPost.")
 322
 323 (defconst metafont-primitives-list
 324   '("at" "autorounding" "chardx" "chardy" "cull" "display"
 325     "dropping" "fillin" "from" "granularity" "hppp" "inwindow"
 326     "keeping" "numspecial" "openwindow" "proofing" "smoothing"
 327     "totalweight" "tracingedges" "tracingpens" "turningcheck" "vppp"
 328     "withweight" "xoffset" "yoffset")
 329   "List of primitives only defined in Metafont.")
 330
 331 (defconst metapost-primitives-list
 332   '("arclength" "arctime" "bluepart" "bounded" "btex" "clip"
 333     "clipped" "color" "dashed" "dashpart" "etex" "filled" "fontpart"
 334     "fontsize" "greenpart" "infont" "linecap" "linejoin" "llcorner"
 335     "lrcorner" "miterlimit" "mpxbreak" "pathpart" "penpart"
 336     "prologues" "readfrom" "redpart" "setbounds" "stroked" "textpart"
 337     "textual" "tracinglostchars" "truecorners" "ulcorner" "urcorner"
 338     "verbatimtex" "withcolor" "within" "write")
 339   "List of primitives only defined in MetaPost.")
 340
 341 (defconst meta-common-plain-macros-list
 342   '( "abs" "bot" "bye" "byte" "ceiling" "clear_pen_memory"
 343      "clearit" "clearpen" "clearxy" "counterclockwise" "cutdraw" "decr"
 344      "dir" "direction" "directionpoint" "div" "dotprod" "downto" "draw"
 345      "drawdot" "erase" "exitunless" "fill" "filldraw" "flex" "gobble"
 346      "hide" "incr" "interact" "interpath" "intersectionpoint" "inverse"
 347      "label" "labels" "lft" "loggingall" "magstep" "makelabel" "max"
 348      "min" "mod" "numtok" "penlabels" "penpos" "penstroke" "pickup"
 349      "range" "reflectedabout" "relax" "rotatedabout" "rotatedaround"
 350      "round" "rt" "savepen" "shipit" "softjoin" "solve" "stop"
 351      "superellipse" "takepower" "tensepath" "thru" "top" "tracingall"
 352      "tracingnone" "undraw" "undrawdot" "unfill" "unfilldraw"
 353      "unitvector" "upto" "whatever")
 354   "List of macros common to plain Metafont and MetaPost.")
 355
 356 (defconst metafont-plain-macros-list
 357   '("beginchar" "change_width" "culldraw" "cullit" "cutoff"
 358     "define_blacker_pixels" "define_corrected_pixels"
 359     "define_good_x_pixels" "define_good_y_pixels"
 360     "define_horizontal_corrected_pixels" "define_pixels"
 361     "define_whole_blacker_pixels" "define_whole_pixels"
 362     "define_whole_vertical_blacker_pixels"
 363     "define_whole_vertical_pixels" "endchar" "fix_units"
 364     "font_coding_scheme" "font_extra_space" "font_identifier"
 365     "font_normal_shrink" "font_normal_space" "font_normal_stretch"
 366     "font_quad" "font_size" "font_slant" "font_x_height" "gfcorners"
 367     "good.bot" "good.lft" "good.rt" "good.top" "good.x" "good.y"
 368     "grayfont" "hround" "imagerules" "italcorr" "labelfont"
 369     "lowres_fix" "makebox" "makegrid" "maketicks" "mode_lowres"
 370     "mode_proof" "mode_setup" "mode_smoke" "nodisplays" "notransforms"
 371     "openit" "penrazor" "pensquare" "proofoffset" "proofrule"
 372     "proofrulethickness" "screenchars" "screenrule" "screenstrokes"
 373     "showit" "slantfont" "smode" "titlefont" "vround")
 374   "List of macros only defined in plain Metafont.")
 375
 376 (defconst metapost-plain-macros-list
 377   '("arrowhead" "bbox" "beginfig" "buildcycle" "center" "cutafter"
 378     "cutbefore" "dashpattern" "dotlabel" "dotlabels" "drawarrow"
 379     "drawdblarrow" "drawoptions" "endfig" "image" "label" "off" "on"
 380     "thelabel")
 381   "List of macros only defined in plain MetaPost.")
 382
 383 (defconst metapost-graph-macros-list
 384   '("augment" "auto.x" "auto.y" "autogrid" "begingraph" "endgraph"
 385     "format" "frame" "gdata" "gdotlabel" "gdraw" "gdrawarrow"
 386     "gdrawdblarrow" "gfill" "glabel" "grid" "itick" "otick" "plot"
 387     "setcoords" "setrange")
 388   "List of macros only defined in MetaPost \"graph\" package.")
 389
 390 (defconst metapost-boxes-macros-list
 391   '("boxit" "boxjoin" "bpath" "circleit" "drawboxed" "drawboxes"
 392     "drawunboxed" "fixpos" "fixsize" "pic" "rboxit")
 393   "List of macros only defined in MetaPost \"boxes\" package.")
 394
 395
 396 (defvar metafont-symbol-list
 397   (append meta-common-primitives-list
 398           metafont-primitives-list
 399           meta-common-plain-macros-list
 400           metafont-plain-macros-list)
 401   "List of known symbols to complete in Metafont mode.")
 402
 403 (defvar metapost-symbol-list
 404   (append meta-common-primitives-list
 405           metapost-primitives-list
 406           meta-common-plain-macros-list
 407           metapost-plain-macros-list
 408           metapost-graph-macros-list
 409           metapost-boxes-macros-list)
 410   "List of known symbols to complete in MetaPost mode.")
 411
 412
 413 (defvar meta-symbol-list nil
 414   "List of known symbols to complete in Metafont or MetaPost mode.")
 415
 416 (defvar meta-symbol-changed nil
 417   "Flag indicating whether `meta-symbol-list' has been initialized.")
 418
 419 (defvar meta-complete-list nil
 420 ;  (list (list "\\<\\(\\sw+\\)" 1 'meta-symbol-list)
 421 ;        (list "" 'ispell-complete-word))
 422   "List of ways to perform completion in Metafont or MetaPost mode.
 423
 424 Each entry is a list with the following elements:
 425 1. Regexp matching the preceding text.
 426 2. A number indicating the subgroup in the regexp containing the text.
 427 3. A function returning an alist of possible completions.
 428 4. Text to append after a succesful completion (if any).
 429
 430 Or alternatively:
 431 1. Regexp matching the preceding text.
 432 2. Function to do the actual completion.")
 433
 434
 435 (defun meta-add-symbols (&rest entries)
 436   "Add entries to list of known symbols in Metafont or MetaPost mode."
 437   (if meta-symbol-changed
 438       (setq meta-symbol-list (cons entries meta-symbol-list))
 439     (setq meta-symbol-changed t)
 440     (setq meta-symbol-list (cons entries meta-symbol-list))))
 441
 442 (defun meta-symbol-list ()
 443   "Return value of list of known symbols in Metafont or MetaPost mode.
 444 If the list was changed, sort the list and remove duplicates first."
 445   (if (not meta-symbol-changed)
 446       ()
 447     (setq meta-symbol-changed nil)
 448     (message "Preparing completion list...")
 449     ;; sort list of symbols
 450     (setq meta-symbol-list
 451           (sort (mapcar 'meta-listify (apply 'append meta-symbol-list))
 452                 'meta-car-string-lessp))
 453     ;; remove duplicates
 454     (let ((entry meta-symbol-list))
 455       (while (and entry (cdr entry))
 456         (let ((this (car entry))
 457               (next (car (cdr entry))))
 458           (if (not (string-equal (car this) (car next)))
 459               (setq entry (cdr entry))
 460             (if (> (length next) (length this))
 461                 (setcdr this (cdr next)))
 462             (setcdr entry (cdr (cdr entry)))))))
 463     (message "Preparing completion list... done"))
 464   meta-symbol-list)
 465
 466 (defun meta-listify (a)
 467   ;; utility function used in `meta-add-symbols'
 468   (if (listp a) a (list a)))
 469
 470 (defun meta-car-string-lessp (a b)
 471   ;; utility function used in `meta-add-symbols'
 472   (string-lessp (car a) (car b)))
 473
 474
 475 (defun meta-complete-symbol ()
 476   "Perform completion on Metafont or MetaPost symbol preceding point."
 477   (interactive "*")
 478   (let ((list meta-complete-list)
 479         entry)
 480     (while list
 481       (setq entry (car list)
 482             list (cdr list))
 483       (if (meta-looking-at-backward (car entry) 200)
 484           (setq list nil)))
 485     (if (numberp (nth 1 entry))
 486         (let* ((sub (nth 1 entry))
 487                (close (nth 3 entry))
 488                (begin (match-beginning sub))
 489                (end (match-end sub))
 490                (pattern (meta-match-buffer 0))
 491                (symbol (buffer-substring begin end))
 492                (list (funcall (nth 2 entry)))
 493                (completion (try-completion symbol list)))
 494           (cond ((eq completion t)
 495                  (and close
 496                       (not (looking-at (regexp-quote close)))
 497                       (insert close)))
 498                 ((null completion)
 499                  (error "Can't find completion for \"%s\"" pattern))
 500                 ((not (string-equal symbol completion))
 501                  (delete-region begin end)
 502                  (insert completion)
 503                  (and close
 504                       (eq (try-completion completion list) t)
 505                       (not (looking-at (regexp-quote close)))
 506                       (insert close)))
 507                 (t
 508                  (message "Making completion list...")
 509                  (let ((list (all-completions symbol list nil)))
 510                    (with-output-to-temp-buffer "*Completions*"
 511                      (display-completion-list list symbol)))
 512                  (message "Making completion list... done"))))
 513       (funcall (nth 1 entry)))))
 514
 515
 516 (defun meta-looking-at-backward (regexp &optional limit)
 517   ;; utility function used in `meta-complete-symbol'
 518   (let ((pos (point)))
 519     (save-excursion
 520       (and (re-search-backward
 521             regexp (if limit (max (point-min) (- (point) limit))) t)
 522            (eq (match-end 0) pos)))))
 523
 524 (defun meta-match-buffer (n)
 525   ;; utility function used in `meta-complete-symbol'
 526   (if (match-beginning n)
 527       (let ((str (buffer-substring (match-beginning n) (match-end n))))
 528         (set-text-properties 0 (length str) nil str)
 529         (copy-sequence str))
 530     ""))
 531
 532
 533 \f
 534 ;;; Indentation.
 535
 536 (defcustom meta-indent-level 2
 537   "*Indentation of begin-end blocks in Metafont or MetaPost mode."
 538   :type 'integer
 539   :group 'meta-font)
 540
 541
 542 (defcustom meta-left-comment-regexp "%%+"
 543   "*Regexp matching comments that should be placed on the left margin."
 544   :type 'regexp
 545   :group 'meta-font)
 546
 547 (defcustom meta-right-comment-regexp nil
 548   "*Regexp matching comments that should be placed to the right margin."
 549   :type '(choice regexp
 550                  (const :tag "None" nil))
 551   :group 'meta-font)
 552
 553 (defcustom meta-ignore-comment-regexp "%[^%]"
 554   "*Regexp matching comments that whose indentation should not be touched."
 555   :type 'regexp
 556   :group 'meta-font)
 557
 558
 559 (defcustom meta-begin-environment-regexp
 560   (concat "\\(begin\\(char\\|fig\\|gr\\(aph\\|oup\\)\\|logochar\\)\\|"
 561           "def\\|for\\(\\|ever\\|suffixes\\)\\|if\\|mode_def\\|"
 562           "primarydef\\|secondarydef\\|tertiarydef\\|vardef\\)")
 563   "*Regexp matching the beginning of environments to be indented."
 564   :type 'regexp
 565   :group 'meta-font)
 566
 567 (defcustom meta-end-environment-regexp
 568   (concat "\\(end\\(char\\|def\\|f\\(ig\\|or\\)\\|gr\\(aph\\|oup\\)\\)"
 569           "\\|fi\\)")
 570   "*Regexp matching the end of environments to be indented."
 571   :type 'regexp
 572   :group 'meta-font)
 573
 574 (defcustom meta-within-environment-regexp
 575 ; (concat "\\(e\\(lse\\(\\|if\\)\\|xit\\(if\\|unless\\)\\)\\)")
 576   (concat "\\(else\\(\\|if\\)\\)")
 577   "*Regexp matching keywords within environments not to be indented."
 578   :type 'regexp
 579   :group 'meta-font)
 580
 581
 582 (defun meta-comment-indent ()
 583   "Return the indentation for a comment in Metafont or MetaPost mode."
 584   (if (and meta-left-comment-regexp
 585            (looking-at meta-left-comment-regexp))
 586       (current-column)
 587     (skip-chars-backward "\t\f ")
 588     (max (if (bolp) 0 (1+ (current-column)))
 589          comment-column)))
 590
 591 (defun meta-indent-line ()
 592   "Indent the line containing point as Metafont or MetaPost source."
 593   (interactive)
 594   (let ((indent (meta-indent-calculate)))
 595     (save-excursion
 596       (if (/= (current-indentation) indent)
 597           (let ((beg (progn (beginning-of-line) (point)))
 598                 (end (progn (back-to-indentation) (point))))
 599             (delete-region beg end)
 600             (indent-to indent))))
 601     (if (< (current-column) indent)
 602         (back-to-indentation))))
 603
 604 (defun meta-indent-calculate ()
 605   "Return the indentation of current line of Metafont or MetaPost source."
 606   ;; Indentation within strings is not considered as Meta* don't allow multi
 607   ;; line strings.
 608   (save-excursion
 609     (back-to-indentation)
 610     (cond
 611      ;; Comments to the left margin.
 612      ((and meta-left-comment-regexp
 613            (looking-at meta-left-comment-regexp))
 614       0)
 615      ;; Comments to the right margin.
 616      ((and meta-right-comment-regexp
 617            (looking-at meta-right-comment-regexp))
 618       comment-column)
 619      ;; Comments best left alone.
 620      ((and meta-ignore-comment-regexp
 621            (looking-at meta-ignore-comment-regexp))
 622       (current-indentation))
 623      ;; Beginning of buffer.
 624      ((eq (point-at-bol) (point-min))
 625       0)
 626      ;; Backindent at end of environments.
 627      ((meta-indent-looking-at-code
 628        (concat "\\<" meta-end-environment-regexp "\\>"))
 629       (- (meta-indent-current-indentation) meta-indent-level))
 630      ;; Backindent at keywords within environments.
 631      ((meta-indent-looking-at-code
 632        (concat "\\<" meta-within-environment-regexp "\\>"))
 633       (- (meta-indent-current-indentation) meta-indent-level))
 634      (t (meta-indent-current-indentation)))))
 635
 636 (defun meta-indent-in-string-p ()
 637   "Tell if the point is in a string."
 638   (or (nth 3 (syntax-ppss))
 639       (eq (get-text-property (point) 'face) font-lock-string-face)))
 640
 641 (defun meta-indent-looking-at-code (regexp)
 642   "Same as `looking-at' but checks that the point is not in a string."
 643   (unless (meta-indent-in-string-p)
 644     (looking-at regexp)))
 645
 646 (defun meta-indent-previous-line ()
 647   "Go to the previous line of code, skipping comments."
 648   (skip-chars-backward "\n\t\f ")
 649   (move-to-column (current-indentation))
 650   ;; Ignore comments.
 651   (while (and (looking-at comment-start) (not (bobp)))
 652     (skip-chars-backward "\n\t\f ")
 653     (when (not (bobp))
 654       (move-to-column (current-indentation)))))
 655
 656 (defun meta-indent-unfinished-line ()
 657   "Tell if the current line of code ends with an unfinished expression."
 658   (save-excursion
 659     (end-of-line)
 660     ;; Skip backward the comments.
 661     (let ((point-not-in-string (point)))
 662       (while (search-backward comment-start (point-at-bol) t)
 663         (unless (meta-indent-in-string-p)
 664           (setq point-not-in-string (point))))
 665       (goto-char point-not-in-string))
 666     ;; Search for the end of the previous expression.
 667     (if (search-backward ";" (point-at-bol) t)
 668         (progn (while (and (meta-indent-in-string-p)
 669                            (search-backward ";" (point-at-bol) t)))
 670                (if (= (char-after) ?\;)
 671                    (forward-char)
 672                  (beginning-of-line)))
 673       (beginning-of-line))
 674     ;; See if the last statement of the line is environment-related,
 675     ;; or exists at all.
 676     (if (meta-indent-looking-at-code
 677          (concat "[ \t\f]*\\($\\|" (regexp-quote comment-start)
 678                  "\\|\\<" meta-end-environment-regexp "\\>"
 679                  "\\|\\<" meta-begin-environment-regexp "\\>"
 680                  "\\|\\<" meta-within-environment-regexp "\\>\\)"))
 681         nil
 682       t)))
 683
 684 (defun meta-indent-current-indentation ()
 685   "Return the indentation wanted for the current line of code."
 686   (+ (meta-indent-current-nesting)
 687      (if (save-excursion
 688            (back-to-indentation)
 689            (and (not (looking-at (concat "\\<" meta-end-environment-regexp "\\>"
 690                                          "\\|\\<" meta-within-environment-regexp "\\>")))
 691                 (progn (meta-indent-previous-line)
 692                        (meta-indent-unfinished-line))))
 693          meta-indent-level
 694        0)))
 695
 696 (defun meta-indent-current-nesting ()
 697   "Return the indentation according to the nearest environment keyword."
 698   (save-excursion
 699     (save-restriction
 700       (widen)
 701       (back-to-indentation)
 702       (let ((to-add 0))
 703         ;; If we found some environment marker backward...
 704         (if (catch 'found
 705               (while (re-search-backward
 706                       (concat "(\\|)\\|\\<" meta-end-environment-regexp "\\>"
 707                               "\\|\\<" meta-begin-environment-regexp "\\>"
 708                               "\\|\\<" meta-within-environment-regexp "\\>")
 709                       nil t)
 710                 ;; If we aren't in a string or in a comment, we've found something.
 711                 (unless (or (meta-indent-in-string-p)
 712                             (nth 4 (syntax-ppss)))
 713                   (cond ((= (char-after) ?\()
 714                          (setq to-add (+ to-add meta-indent-level)))
 715                         ((= (char-after) ?\))
 716                          (setq to-add (- to-add meta-indent-level)))
 717                         (t (throw 'found t))))))
 718             (progn
 719               ;; ... then use it to compute the current indentation.
 720               (back-to-indentation)
 721               (+ to-add (current-indentation) (meta-indent-level-count)
 722                  ;; Compensate for backindent of end and within keywords.
 723                  (if (meta-indent-looking-at-code
 724                       (concat "\\<" meta-end-environment-regexp "\\>\\|"
 725                               "\\<" meta-within-environment-regexp "\\>"))
 726                      meta-indent-level
 727                    ;; Compensate for unfinished line.
 728                    (if (save-excursion
 729                          (meta-indent-previous-line)
 730                          (meta-indent-unfinished-line))
 731                        (- meta-indent-level)
 732                      0))))
 733           0)))))
 734
 735 (defun meta-indent-level-count ()
 736   "Count indentation change for begin-end commands in the current line."
 737   (save-excursion
 738     (save-restriction
 739       (let ((count 0))
 740         (narrow-to-region
 741          (point) (save-excursion
 742                    (re-search-forward "[^\\\\\"]%\\|\n\\|\\'" nil t)
 743                    (backward-char) (point)))
 744         (while (re-search-forward "\\<\\sw+\\>\\|(\\|)" nil t)
 745           (save-excursion
 746             (goto-char (match-beginning 0))
 747             (cond
 748              ;; Count number of begin-end keywords within line.
 749              ((meta-indent-looking-at-code
 750                (concat "\\<" meta-begin-environment-regexp "\\>"))
 751               (setq count (+ count meta-indent-level)))
 752              ((meta-indent-looking-at-code
 753                (concat "\\<" meta-end-environment-regexp "\\>"))
 754               (setq count (- count meta-indent-level))))))
 755         count))))
 756
 757
 758 \f
 759 ;;; Editing commands.
 760
 761 (defcustom meta-begin-defun-regexp
 762   (concat "\\(begin\\(char\\|fig\\|logochar\\)\\|def\\|mode_def\\|"
 763           "primarydef\\|secondarydef\\|tertiarydef\\|vardef\\)")
 764   "*Regexp matching beginning of defuns in Metafont or MetaPost mode."
 765   :type 'regexp
 766   :group 'meta-font)
 767
 768 (defcustom meta-end-defun-regexp
 769   (concat "\\(end\\(char\\|def\\|fig\\)\\)")
 770   "*Regexp matching the end of defuns in Metafont or MetaPost mode."
 771   :type 'regexp
 772   :group 'meta-font)
 773
 774
 775 (defun meta-beginning-of-defun (&optional arg)
 776   "Move backward to beginnning of a defun in Metafont or MetaPost code.
 777 With numeric argument, do it that many times.
 778 Negative arg -N means move forward to Nth following beginning of defun.
 779 Returns t unless search stops due to beginning or end of buffer."
 780   (interactive "p")
 781   (if (or (null arg) (= 0 arg)) (setq arg 1))
 782   (and arg (< arg 0) (not (eobp)) (forward-char 1))
 783   (and (re-search-backward
 784         (concat "\\<" meta-begin-defun-regexp "\\>") nil t arg)
 785        (progn (goto-char (match-beginning 0))
 786               (skip-chars-backward "%")
 787               (skip-chars-backward " \t\f") t)))
 788
 789 (defun meta-end-of-defun (&optional arg)
 790   "Move forward to end of a defun in Metafont or MetaPost code.
 791 With numeric argument, do it that many times.
 792 Negative argument -N means move back to Nth preceding end of defun.
 793 Returns t unless search stops due to beginning or end of buffer."
 794   (interactive "p")
 795   (if (or (null arg) (= 0 arg)) (setq arg 1))
 796   (and (< arg 0) (not (bobp)) (forward-line -1))
 797   (and (re-search-forward
 798         (concat "\\<" meta-end-defun-regexp "\\>") nil t arg)
 799        (progn (goto-char (match-end 0))
 800               (skip-chars-forward ";")
 801               (skip-chars-forward " \t\f")
 802               (if (looking-at "\n") (forward-line 1)) t)))
 803
 804
 805 (defun meta-comment-region (beg end &optional arg)
 806   "Comment out active region as Metafont or MetaPost source."
 807   (interactive "r")
 808   (comment-region beg end arg))
 809
 810 (defun meta-uncomment-region (beg end)
 811   "Uncomment active region as Metafont or MetaPost source."
 812   (interactive "r")
 813   (comment-region beg end -1))
 814
 815 (defun meta-comment-defun (&optional arg)
 816   "Comment out current environment as Metafont or MetaPost source.
 817 With prefix argument, uncomment the environment.
 818 The environment used is the one that contains point or follows point."
 819   (interactive "P")
 820   (save-excursion
 821     (let* ((end (if (meta-end-of-defun) (point) (point-max)))
 822            (beg (if (meta-beginning-of-defun) (point) (point-min))))
 823       (comment-region beg end arg))))
 824
 825 (defun meta-uncomment-defun ()
 826   "Uncomment current environment as Metafont or MetaPost source."
 827   (interactive)
 828   (meta-comment-defun -1))
 829
 830
 831 (defun meta-indent-region (beg end)
 832   "Indent the active region as Metafont or MetaPost source."
 833   (interactive "r")
 834   (indent-region beg end nil))
 835
 836 (defun meta-indent-buffer ()
 837   "Indent the whole buffer contents as Metafont or MetaPost source."
 838   (interactive)
 839   (save-excursion
 840     (indent-region (point-min) (point-max) nil)))
 841
 842 (defun meta-indent-defun ()
 843   "Indent the current environment as Metafont or MetaPost source.
 844 The environment indented is the one that contains point or follows point."
 845   (interactive)
 846   (save-excursion
 847     (let* ((end (if (meta-end-of-defun) (point) (point-max)))
 848            (beg (if (meta-beginning-of-defun) (point) (point-min))))
 849       (indent-region beg end nil))))
 850
 851
 852 (defun meta-mark-defun ()
 853   "Put mark at end of the environment, point at the beginning.
 854 The environment marked is the one that contains point or follows point."
 855   (interactive)
 856   (push-mark (point))
 857   (meta-end-of-defun)
 858   (push-mark (point) nil t)
 859   (meta-beginning-of-defun))
 860
 861
 862 \f
 863 ;;; Syntax table, keymap and menu.
 864
 865 (defvar meta-mode-abbrev-table nil
 866   "Abbrev table used in Metafont or MetaPost mode.")
 867 (define-abbrev-table 'meta-mode-abbrev-table ())
 868
 869 (defvar meta-mode-syntax-table
 870   (let ((st (make-syntax-table)))
 871     ;; underscores are word constituents
 872     (modify-syntax-entry ?_  "w"  st)
 873     ;; miscellaneous non-word symbols
 874     (modify-syntax-entry ?#  "_"  st)
 875     (modify-syntax-entry ?@  "_"  st)
 876     (modify-syntax-entry ?$  "_"  st)
 877     (modify-syntax-entry ??  "_"  st)
 878     (modify-syntax-entry ?!  "_"  st)
 879     ;; binary operators
 880     (modify-syntax-entry ?&  "."  st)
 881     (modify-syntax-entry ?+  "."  st)
 882     (modify-syntax-entry ?-  "."  st)
 883     (modify-syntax-entry ?/  "."  st)
 884     (modify-syntax-entry ?*  "."  st)
 885     (modify-syntax-entry ?.  "."  st)
 886     (modify-syntax-entry ?:  "."  st)
 887     (modify-syntax-entry ?=  "."  st)
 888     (modify-syntax-entry ?<  "."  st)
 889     (modify-syntax-entry ?>  "."  st)
 890     (modify-syntax-entry ?|  "."  st)
 891     ;; opening and closing delimiters
 892     (modify-syntax-entry ?\( "()" st)
 893     (modify-syntax-entry ?\) ")(" st)
 894     (modify-syntax-entry ?\[ "(]" st)
 895     (modify-syntax-entry ?\] ")[" st)
 896     (modify-syntax-entry ?\{ "(}" st)
 897     (modify-syntax-entry ?\} "){" st)
 898     ;; comment character
 899     (modify-syntax-entry ?%  "<"  st)
 900     (modify-syntax-entry ?\n ">"  st)
 901     ;; escape character, needed for embedded TeX code
 902     (modify-syntax-entry ?\\ "\\" st)
 903     st)
 904   "Syntax table used in Metafont or MetaPost mode.")
 905
 906 (defvar meta-mode-map
 907   (let ((map (make-sparse-keymap)))
 908     (define-key map "\C-m"      'reindent-then-newline-and-indent)
 909     ;; Comment Paragraphs:
 910     ;; (define-key map "\M-a"      'backward-sentence)
 911     ;; (define-key map "\M-e"      'forward-sentence)
 912     ;; (define-key map "\M-h"      'mark-paragraph)
 913     ;; (define-key map "\M-q"      'fill-paragraph)
 914     ;; Navigation:
 915     (define-key map "\M-\C-a"   'meta-beginning-of-defun)
 916     (define-key map "\M-\C-e"   'meta-end-of-defun)
 917     (define-key map "\M-\C-h"   'meta-mark-defun)
 918     ;; Indentation:
 919     (define-key map "\M-\C-q"   'meta-indent-defun)
 920     (define-key map "\C-c\C-qe" 'meta-indent-defun)
 921     (define-key map "\C-c\C-qr" 'meta-indent-region)
 922     (define-key map "\C-c\C-qb" 'meta-indent-buffer)
 923     ;; Commenting Out:
 924     (define-key map "\C-c%"     'meta-comment-defun)
 925     ;; (define-key map "\C-uC-c%"  'meta-uncomment-defun)
 926     (define-key map "\C-c;"     'meta-comment-region)
 927     (define-key map "\C-c:"     'meta-uncomment-region)
 928     ;; Symbol Completion:
 929     (define-key map "\M-\t"     'meta-complete-symbol)
 930     ;; Shell Commands:
 931     ;; (define-key map "\C-c\C-c"  'meta-command-file)
 932     ;; (define-key map "\C-c\C-k"  'meta-kill-job)
 933     ;; (define-key map "\C-c\C-l"  'meta-recenter-output)
 934     map)
 935   "Keymap used in Metafont or MetaPost mode.")
 936
 937
 938 (easy-menu-define
 939  meta-mode-menu meta-mode-map
 940  "Menu used in Metafont or MetaPost mode."
 941  (list "Meta"
 942        ["Forward Environment"           meta-beginning-of-defun t]
 943        ["Backward Environment"          meta-end-of-defun t]
 944        "--"
 945        ["Indent Line"                   meta-indent-line t]
 946        ["Indent Environment"            meta-indent-defun t]
 947        ["Indent Region"                 meta-indent-region
 948         :active (meta-mark-active)]
 949        ["Indent Buffer"                 meta-indent-buffer t]
 950        "--"
 951        ["Comment Out Environment"       meta-comment-defun t]
 952        ["Uncomment Environment"         meta-uncomment-defun t]
 953        ["Comment Out Region"            meta-comment-region
 954         :active (meta-mark-active)]
 955        ["Uncomment Region"              meta-uncomment-region
 956         :active (meta-mark-active)]
 957        "--"
 958        ["Complete Symbol"               meta-complete-symbol t]
 959 ;      "--"
 960 ;      ["Command on Buffer"             meta-command-file t]
 961 ;      ["Kill Job"                      meta-kill-job t]
 962 ;      ["Recenter Output Buffer"        meta-recenter-output-buffer t]
 963        ))
 964
 965 ;; Compatibility: XEmacs doesn't have the  `mark-active' variable.
 966 (defun meta-mark-active ()
 967   "Return whether the mark and region are currently active in this buffer."
 968   (if (boundp 'mark-active) mark-active (mark)))
 969
 970
 971 \f
 972 ;;; Hook variables.
 973
 974 (defcustom meta-mode-load-hook nil
 975   "*Hook evaluated when first loading Metafont or MetaPost mode."
 976   :type 'hook
 977   :group 'meta-font)
 978
 979 (defcustom meta-common-mode-hook nil
 980   "*Hook evaluated by both `metafont-mode' and `metapost-mode'."
 981   :type 'hook
 982   :group 'meta-font)
 983
 984 (defcustom metafont-mode-hook nil
 985   "*Hook evaluated by `metafont-mode' after `meta-common-mode-hook'."
 986   :type 'hook
 987   :group 'meta-font)
 988 (defcustom metapost-mode-hook nil
 989   "*Hook evaluated by `metapost-mode' after `meta-common-mode-hook'."
 990   :type 'hook
 991   :group 'meta-font)
 992
 993
 994 \f
 995 ;;; Initialization.
 996
 997 (defun meta-common-initialization ()
 998   "Common initialization for Metafont or MetaPost mode."
 999   (kill-all-local-variables)
1000
1001   (make-local-variable 'paragraph-start)
1002   (make-local-variable 'paragraph-separate)
1003   (setq paragraph-start
1004         (concat page-delimiter "\\|$"))
1005   (setq paragraph-separate
1006         (concat page-delimiter "\\|$"))
1007
1008   (make-local-variable 'paragraph-ignore-fill-prefix)
1009   (setq paragraph-ignore-fill-prefix t)
1010
1011   (make-local-variable 'comment-start-skip)
1012   (make-local-variable 'comment-start)
1013   (make-local-variable 'comment-end)
1014   (make-local-variable 'comment-multi-line)
1015   (setq comment-start-skip "%+[ \t\f]*")
1016   (setq comment-start "%")
1017   (setq comment-end "")
1018   (setq comment-multi-line nil)
1019
1020   ;; We use `back-to-indentation' but \f is no indentation sign.
1021   (modify-syntax-entry ?\f "_   ")
1022
1023   (make-local-variable 'parse-sexp-ignore-comments)
1024   (setq parse-sexp-ignore-comments t)
1025
1026   (make-local-variable 'comment-indent-function)
1027   (setq comment-indent-function 'meta-comment-indent)
1028   (make-local-variable 'indent-line-function)
1029   (setq indent-line-function 'meta-indent-line)
1030   ;; No need to define a mode-specific 'indent-region-function.
1031   ;; Simply use the generic 'indent-region and 'comment-region.
1032
1033   ;; Set defaults for font-lock mode.
1034   (make-local-variable 'font-lock-defaults)
1035   (setq font-lock-defaults
1036         '(meta-font-lock-keywords
1037           nil nil ((?_ . "w")) nil
1038           (font-lock-comment-start-regexp . "%")))
1039
1040   ;; Activate syntax table, keymap and menu.
1041   (setq local-abbrev-table meta-mode-abbrev-table)
1042   (set-syntax-table meta-mode-syntax-table)
1043   (use-local-map meta-mode-map)
1044   (easy-menu-add meta-mode-menu)
1045   )
1046
1047
1048 ;;;###autoload
1049 (defun metafont-mode ()
1050   "Major mode for editing Metafont sources.
1051 Special commands:
1052 \\{meta-mode-map}
1053
1054 Turning on Metafont mode calls the value of the variables
1055 `meta-common-mode-hook' and `metafont-mode-hook'."
1056   (interactive)
1057   (meta-common-initialization)
1058   (setq mode-name "Metafont")
1059   (setq major-mode 'metafont-mode)
1060
1061   ;; Set defaults for completion function.
1062   (make-local-variable 'meta-symbol-list)
1063   (make-local-variable 'meta-symbol-changed)
1064   (make-local-variable 'meta-complete-list)
1065   (setq meta-symbol-list nil)
1066   (setq meta-symbol-changed nil)
1067   (apply 'meta-add-symbols metafont-symbol-list)
1068   (setq meta-complete-list
1069         (list (list "\\<\\(\\sw+\\)" 1 'meta-symbol-list)
1070               (list "" 'ispell-complete-word)))
1071   (run-mode-hooks 'meta-common-mode-hook 'metafont-mode-hook))
1072
1073 ;;;###autoload
1074 (defun metapost-mode ()
1075   "Major mode for editing MetaPost sources.
1076 Special commands:
1077 \\{meta-mode-map}
1078
1079 Turning on MetaPost mode calls the value of the variable
1080 `meta-common-mode-hook' and `metafont-mode-hook'."
1081   (interactive)
1082   (meta-common-initialization)
1083   (setq mode-name "MetaPost")
1084   (setq major-mode 'metapost-mode)
1085
1086   ;; Set defaults for completion function.
1087   (make-local-variable 'meta-symbol-list)
1088   (make-local-variable 'meta-symbol-changed)
1089   (make-local-variable 'meta-complete-list)
1090   (setq meta-symbol-list nil)
1091   (setq meta-symbol-changed nil)
1092   (apply 'meta-add-symbols metapost-symbol-list)
1093   (setq meta-complete-list
1094         (list (list "\\<\\(\\sw+\\)" 1 'meta-symbol-list)
1095               (list "" 'ispell-complete-word)))
1096   (run-mode-hooks 'meta-common-mode-hook 'metapost-mode-hook))
1097
1098
1099 ;;; Just in case ...
1100
1101 (provide 'meta-mode)
1102 (run-hooks 'meta-mode-load-hook)
1103
1104 ;; arch-tag: ec2916b2-3a83-4cf7-962d-d8019370c006
1105 ;;; meta-mode.el ends here