code.delx.au - gnu-emacs/blob - lisp/cus-face.el

   1 ;;; cus-face.el --- customization support for faces
   2 ;;
   3 ;; Copyright (C) 1996, 1997, 1999, 2000, 2001, 2002 Free Software Foundation, Inc.
   4 ;;
   5 ;; Author: Per Abrahamsen <abraham@dina.kvl.dk>
   6 ;; Keywords: help, faces
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26 ;;
  27 ;; See `custom.el'.
  28
  29 ;;; Code:
  30
  31 (defalias 'custom-facep 'facep)
  32
  33 ;;; Declaring a face.
  34
  35 ;;;###autoload
  36 (defun custom-declare-face (face spec doc &rest args)
  37   "Like `defface', but FACE is evaluated as a normal argument."
  38   (unless (get face 'face-defface-spec)
  39     (when (fboundp 'facep)
  40       (unless (facep face)
  41         ;; If the user has already created the face, respect that.
  42         (let ((value (or (get face 'saved-face) spec))
  43               (have-window-system (memq initial-window-system '(x w32))))
  44           ;; Create global face.
  45           (make-empty-face face)
  46           ;; Create frame-local faces
  47           (dolist (frame (frame-list))
  48             (face-spec-set face value frame)
  49             (when (memq (window-system frame) '(x w32))
  50               (setq have-window-system t)))
  51           ;; When making a face after frames already exist
  52           (if have-window-system
  53               (make-face-x-resource-internal face)))))
  54     ;; Don't record SPEC until we see it causes no errors.
  55     (put face 'face-defface-spec spec)
  56     (when (and doc (null (face-documentation face)))
  57       (set-face-documentation face (purecopy doc)))
  58     (custom-handle-all-keywords face args 'custom-face)
  59     (run-hooks 'custom-define-hook))
  60   face)
  61
  62 ;;; Face attributes.
  63
  64 (defconst custom-face-attributes
  65   '((:family
  66      (string :tag "Font Family"
  67              :help-echo "Font family or fontset alias name."))
  68
  69     (:width
  70      (choice :tag "Width"
  71              :help-echo "Font width."
  72              :value normal              ; default
  73              (const :tag "compressed" condensed)
  74              (const :tag "condensed" condensed)
  75              (const :tag "demiexpanded" semi-expanded)
  76              (const :tag "expanded" expanded)
  77              (const :tag "extracondensed" extra-condensed)
  78              (const :tag "extraexpanded" extra-expanded)
  79              (const :tag "medium" normal)
  80              (const :tag "narrow" condensed)
  81              (const :tag "normal" normal)
  82              (const :tag "regular" normal)
  83              (const :tag "semicondensed" semi-condensed)
  84              (const :tag "semiexpanded" semi-expanded)
  85              (const :tag "ultracondensed" ultra-condensed)
  86              (const :tag "ultraexpanded" ultra-expanded)
  87              (const :tag "wide" extra-expanded)))
  88
  89     (:height
  90      (choice :tag "Height"
  91              :help-echo "Face's font height."
  92              :value 1.0                 ; default
  93              (integer :tag "Height in 1/10 pt")
  94              (number :tag "Scale" 1.0)))
  95
  96     (:weight
  97      (choice :tag "Weight"
  98              :help-echo "Font weight."
  99              :value normal              ; default
 100              (const :tag "black" ultra-bold)
 101              (const :tag "bold" bold)
 102              (const :tag "book" semi-light)
 103              (const :tag "demibold" semi-bold)
 104              (const :tag "extralight" extra-light)
 105              (const :tag "extrabold" extra-bold)
 106              (const :tag "heavy" extra-bold)
 107              (const :tag "light" light)
 108              (const :tag "medium" normal)
 109              (const :tag "normal" normal)
 110              (const :tag "regular" normal)
 111              (const :tag "semibold" semi-bold)
 112              (const :tag "semilight" semi-light)
 113              (const :tag "ultralight" ultra-light)
 114              (const :tag "ultrabold" ultra-bold)))
 115
 116     (:slant
 117      (choice :tag "Slant"
 118              :help-echo "Font slant."
 119              :value normal              ; default
 120              (const :tag "italic" italic)
 121              (const :tag "oblique" oblique)
 122              (const :tag "normal" normal)))
 123
 124     (:underline
 125      (choice :tag "Underline"
 126              :help-echo "Control text underlining."
 127              (const :tag "Off" nil)
 128              (const :tag "On" t)
 129              (color :tag "Colored")))
 130
 131     (:overline
 132      (choice :tag "Overline"
 133              :help-echo "Control text overlining."
 134              (const :tag "Off" nil)
 135              (const :tag "On" t)
 136              (color :tag "Colored")))
 137
 138     (:strike-through
 139      (choice :tag "Strike-through"
 140              :help-echo "Control text strike-through."
 141              (const :tag "Off" nil)
 142              (const :tag "On" t)
 143              (color :tag "Colored")))
 144
 145     (:box
 146      ;; Fixme: this can probably be done better.
 147      (choice :tag "Box around text"
 148              :help-echo "Control box around text."
 149              (const :tag "Off" nil)
 150              (list :tag "Box"
 151                    :value (:line-width 2 :color "grey75" :style released-button)
 152                    (const :format "" :value :line-width)
 153                    (integer :tag "Width")
 154                    (const :format "" :value :color)
 155                    (choice :tag "Color" (const :tag "*" nil) color)
 156                    (const :format "" :value :style)
 157                    (choice :tag "Style"
 158                            (const :tag "Raised" released-button)
 159                            (const :tag "Sunken" pressed-button)
 160                            (const :tag "None" nil))))
 161      ;; filter to make value suitable for customize
 162      (lambda (real-value)
 163        (and real-value
 164             (let ((lwidth
 165                    (or (and (consp real-value)
 166                             (plist-get real-value :line-width))
 167                        (and (integerp real-value) real-value)
 168                        1))
 169                   (color
 170                    (or (and (consp real-value) (plist-get real-value :color))
 171                        (and (stringp real-value) real-value)
 172                        nil))
 173                   (style
 174                    (and (consp real-value) (plist-get real-value :style))))
 175               (list :line-width lwidth :color color :style style))))
 176      ;; filter to make customized-value suitable for storing
 177      (lambda (cus-value)
 178        (and cus-value
 179             (let ((lwidth (plist-get cus-value :line-width))
 180                   (color (plist-get cus-value :color))
 181                   (style (plist-get cus-value :style)))
 182               (cond ((and (null color) (null style))
 183                      lwidth)
 184                     ((and (null lwidth) (null style))
 185                      ;; actually can't happen, because LWIDTH is always an int
 186                      color)
 187                     (t
 188                      ;; Keep as a plist, but remove null entries
 189                      (nconc (and lwidth `(:line-width ,lwidth))
 190                             (and color  `(:color ,color))
 191                             (and style  `(:style ,style)))))))))
 192
 193     (:inverse-video
 194      (choice :tag "Inverse-video"
 195              :help-echo "Control whether text should be in inverse-video."
 196              (const :tag "Off" nil)
 197              (const :tag "On" t)))
 198
 199     (:foreground
 200      (color :tag "Foreground"
 201             :help-echo "Set foreground color."))
 202
 203     (:background
 204      (color :tag "Background"
 205             :help-echo "Set background color."))
 206
 207     (:stipple
 208      (choice :tag "Stipple"
 209              :help-echo "Background bit-mask"
 210              (const :tag "None" nil)
 211              (file :tag "File"
 212                    :help-echo "Name of bitmap file."
 213                    :must-match t)))
 214
 215     (:inherit
 216      (repeat :tag "Inherit"
 217              :help-echo "List of faces to inherit attributes from."
 218              (face :Tag "Face" default))
 219      ;; filter to make value suitable for customize
 220      (lambda (real-value)
 221        (cond ((or (null real-value) (eq real-value 'unspecified))
 222               nil)
 223              ((symbolp real-value)
 224               (list real-value))
 225              (t
 226               real-value)))
 227      ;; filter to make customized-value suitable for storing
 228      (lambda (cus-value)
 229        (if (and (consp cus-value) (null (cdr cus-value)))
 230            (car cus-value)
 231          cus-value))))
 232
 233   "Alist of face attributes.
 234
 235 The elements are of the form (KEY TYPE PRE-FILTER POST-FILTER),
 236 where KEY is the name of the attribute, TYPE is a widget type for
 237 editing the attribute, PRE-FILTER is a function to make the attribute's
 238 value suitable for the customization widget, and POST-FILTER is a
 239 function to make the customized value suitable for storing.  PRE-FILTER
 240 and POST-FILTER are optional.
 241
 242 The PRE-FILTER should take a single argument, the attribute value as
 243 stored, and should return a value for customization (using the
 244 customization type TYPE).
 245
 246 The POST-FILTER should also take a single argument, the value after
 247 being customized, and should return a value suitable for setting the
 248 given face attribute.")
 249
 250 (defun custom-face-attributes-get (face frame)
 251   "For FACE on FRAME, return an alternating list describing its attributes.
 252 The list has the form (KEYWORD VALUE KEYWORD VALUE...).
 253 Each keyword should be listed in `custom-face-attributes'.
 254
 255 If FRAME is nil, use the global defaults for FACE."
 256   (let ((attrs custom-face-attributes)
 257         plist)
 258     (while attrs
 259       (let* ((attribute (car (car attrs)))
 260              (value (face-attribute face attribute frame)))
 261         (setq attrs (cdr attrs))
 262         (unless (or (eq value 'unspecified)
 263                     (and (null value) (memq attribute '(:inherit))))
 264           (setq plist (cons attribute (cons value plist))))))
 265     plist))
 266
 267 ;;; Initializing.
 268
 269 ;;;###autoload
 270 (defun custom-set-faces (&rest args)
 271   "Initialize faces according to user preferences.
 272 This associates the settings with the `user' theme.
 273 The arguments should be a list where each entry has the form:
 274
 275   (FACE SPEC [NOW [COMMENT]])
 276
 277 SPEC is stored as the saved value for FACE, as well as the value for the
 278 `user' theme.  The `user' theme is one of the default themes known to Emacs.
 279 See `custom-known-themes' for more information on the known themes.
 280 See `custom-theme-set-faces' for more information on the interplay
 281 between themes and faces.
 282 See `defface' for the format of SPEC.
 283
 284 If NOW is present and non-nil, FACE is created now, according to SPEC.
 285 COMMENT is a string comment about FACE."
 286   (apply 'custom-theme-set-faces 'user args))
 287
 288 (defun custom-theme-set-faces (theme &rest args)
 289   "Initialize faces for theme THEME.
 290 The arguments should be a list where each entry has the form:
 291
 292   (FACE SPEC [NOW [COMMENT]])
 293
 294 SPEC is stored as the saved value for FACE, as well as the value for the
 295 `user' theme.  The `user' theme is one of the default themes known to Emacs.
 296 See `custom-known-themes' for more information on the known themes.
 297 See `custom-theme-set-faces' for more information on the interplay
 298 between themes and faces.
 299 See `defface' for the format of SPEC.
 300
 301 If NOW is present and non-nil, FACE is created now, according to SPEC.
 302 COMMENT is a string comment about FACE.
 303
 304 Several properties of THEME and FACE are used in the process:
 305
 306 If THEME property `theme-immediate' is non-nil, this is equivalent of
 307 providing the NOW argument to all faces in the argument list: FACE is
 308 created now.  The only difference is FACE property `force-face': if NOW
 309 is non-nil, FACE property `force-face' is set to the symbol `rogue', else
 310 if THEME property `theme-immediate' is non-nil, FACE property `force-face'
 311 is set to the symbol `immediate'.
 312
 313 SPEC itself is saved in FACE property `saved-face' and it is stored in
 314 FACE's list property `theme-face' \(using `custom-push-theme')."
 315   (custom-check-theme theme)
 316   (let ((immediate (get theme 'theme-immediate)))
 317     (while args
 318       (let ((entry (car args)))
 319         (if (listp entry)
 320             (let ((face (nth 0 entry))
 321                   (spec (nth 1 entry))
 322                   (now (nth 2 entry))
 323                   (comment (nth 3 entry)))
 324               (put face 'saved-face spec)
 325               (put face 'saved-face-comment comment)
 326               (custom-push-theme 'theme-face face theme 'set spec)
 327               (when (or now immediate)
 328                 (put face 'force-face (if now 'rogue 'immediate)))
 329               (when (or now immediate (facep face))
 330                 (unless (facep face)
 331                   (make-empty-face face))
 332                 (put face 'face-comment comment)
 333                 (face-spec-set face spec))
 334             (setq args (cdr args)))
 335         ;; Old format, a plist of FACE SPEC pairs.
 336         (let ((face (nth 0 args))
 337               (spec (nth 1 args)))
 338           (put face 'saved-face spec)
 339           (custom-push-theme 'theme-face face theme 'set spec))
 340         (setq args (cdr (cdr args))))))))
 341
 342 ;;;###autoload
 343 (defun custom-theme-face-value (face theme)
 344   "Return spec of FACE in THEME if THEME modifies FACE.
 345 Value is nil otherwise.  The association between theme and spec for FACE
 346 is stored in FACE's property `theme-face'.  The appropriate face
 347 is retrieved using `custom-theme-value'."
 348   ;; Returns car because the value is stored inside a one element list
 349   (car-safe (custom-theme-value theme (get face 'theme-face))))
 350
 351 (defun custom-theme-reset-internal-face (face to-theme)
 352   "Reset FACE to the value defined by TO-THEME.
 353 If FACE is not defined in TO-THEME, reset FACE to the standard
 354 value.  See `custom-theme-face-value'.  The standard value is
 355 stored in SYMBOL's property `face-defface-spec' by `defface'."
 356   (let ((spec (custom-theme-face-value face to-theme))
 357         was-in-theme)
 358     (setq was-in-theme spec)
 359     (setq spec (or spec (get face 'face-defface-spec)))
 360     (when spec
 361       (put face 'save-face was-in-theme)
 362       (when (or (get face 'force-face) (facep face))
 363               (unless (facep face)
 364                 (make-empty-face face))
 365               (face-spec-set face spec)))
 366     spec))
 367
 368 ;;;###autoload
 369 (defun custom-theme-reset-faces (theme &rest args)
 370   "Reset the value of the face to values previously defined.
 371 Associate this setting with THEME.
 372
 373 ARGS is a list of lists of the form
 374
 375     (FACE TO-THEME)
 376
 377 This means reset FACE to its value in TO-THEME."
 378   (custom-check-theme theme)
 379   (mapcar '(lambda (arg)
 380              (apply 'custom-theme-reset-internal-face arg)
 381              (custom-push-theme 'theme-face (car arg) theme 'reset (cadr arg)))
 382           args))
 383
 384 ;;;###autoload
 385 (defun custom-reset-faces (&rest args)
 386   "Reset the value of the face to values previously saved.
 387 This is the setting assosiated the `user' theme.
 388
 389 ARGS is defined as for `custom-theme-reset-faces'"
 390   (apply 'custom-theme-reset-faces 'user args))
 391
 392 ;;; The End.
 393
 394 (provide 'cus-face)
 395
 396 ;;; arch-tag: 9a5c4b63-0d27-4c92-a5af-f2c7ed764c2b
 397 ;;; cus-face.el ends here