code.delx.au - gnu-emacs/blob - lisp/progmodes/executable.el

   1 ;;; executable.el --- base functionality for executable interpreter scripts
   2
   3 ;; Copyright (C) 1994, 1995, 1996 by Free Software Foundation, Inc.
   4
   5 ;; Author: Daniel.Pfeiffer@Informatik.START.dbp.de
   6 ;;               fax (+49 69) 7588-2389
   7 ;; Keywords: languages, unix
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; executable.el is used by certain major modes to insert a suitable
  29 ;; #! line at the beginning of the file, if the file does not already
  30 ;; have one.
  31
  32 ;; Unless it has a magic number, a Unix file with executable mode is passed to
  33 ;; a new instance of the running shell (or to a Bourne shell if a csh is
  34 ;; running and the file starts with `:').  Only a shell can start such a file,
  35 ;; exec() cannot, which is why it is important to have a magic number in every
  36 ;; executable script.  Such a magic number is made up by the characters `#!'
  37 ;; the filename of an interpreter (in COFF, ELF or somesuch format) and one
  38 ;; optional argument.
  39
  40 ;; This library is for certain major modes like sh-, awk-, perl-, tcl- or
  41 ;; makefile-mode to insert or update a suitable #! line at the beginning of
  42 ;; the file, if the file does not already have one and the file is not a
  43 ;; default file of that interpreter (like .profile or makefile).  It also
  44 ;; makes the file executable if it wasn't, as soon as it's saved.
  45
  46 ;; It also allows debugging scripts, with an adaptation of compile, as far
  47 ;; as interpreters give out meaningful error messages.
  48
  49 ;; Modes that use this should nconc `executable-map' to the end of their own
  50 ;; keymap and `executable-font-lock-keywords' to the end of their own font
  51 ;; lock keywords.  Their mode-setting commands should call
  52 ;; `executable-set-magic'.
  53
  54 ;;; Code:
  55
  56 (defgroup executable nil
  57   "Base functionality for executable interpreter scripts"
  58   :group 'processes)
  59
  60 (defcustom executable-insert 'other
  61   "*Non-nil means offer to add a magic number to a file.
  62 This takes effect when you switch to certain major modes,
  63 including Shell-script mode (`sh-mode').
  64 When you type \\[executable-set-magic], it always offers to add or
  65 update the magic number."
  66   :type '(choice (const :tag "off" nil)
  67                  (const :tag "on" t)
  68                  symbol)
  69   :group 'executable)
  70
  71
  72 (defcustom executable-query 'function
  73   "*If non-nil, ask user before changing an existing magic number.
  74 When this is `function', only ask when called non-interactively."
  75   :type '(choice (const :tag "Don't Ask" nil)
  76                  (const :tag "Ask" t)
  77                  (const :tag "Ask when non-interactive" function))
  78   :group 'executable)
  79
  80
  81 (defcustom executable-magicless-file-regexp "/[Mm]akefile$\\|/\\.\\(z?profile\\|bash_profile\\|z?login\\|bash_login\\|z?logout\\|bash_logout\\|.+shrc\\|esrc\\|rcrc\\|[kz]shenv\\)$"
  82   "*On files with this kind of name no magic is inserted or changed."
  83   :type 'regexp
  84   :group 'executable)
  85
  86
  87 (defcustom executable-prefix "#! "
  88   "*Interpreter magic number prefix inserted when there was no magic number."
  89   :type 'string
  90   :group 'executable)
  91
  92
  93 (defcustom executable-chmod 73
  94   "*After saving, if the file is not executable, set this mode.
  95 This mode passed to `set-file-modes' is taken absolutely when negative, or
  96 relative to the files existing modes.  Do nothing if this is nil.
  97 Typical values are 73 (+x) or -493 (rwxr-xr-x)."
  98   :type 'integer
  99   :group 'executable)
 100
 101
 102 (defvar executable-command nil)
 103
 104 (defcustom executable-self-display "tail"
 105   "*Command you use with argument `+2' to make text files self-display.
 106 Note that the like of `more' doesn't work too well under Emacs  \\[shell]."
 107   :type 'string
 108   :group 'executable)
 109
 110
 111 (defvar executable-font-lock-keywords
 112   '(("\\`#!.*/\\([^ \t\n]+\\)" 1 font-lock-keyword-face t))
 113   "*Rules for highlighting executable scripts' magic number.
 114 This can be included in `font-lock-keywords' by modes that call `executable'.")
 115
 116
 117 (defvar executable-error-regexp-alist
 118   '(;; /bin/xyz: syntax error at line 14: `(' unexpected
 119     ;; /bin/xyz[5]: syntax error at line 8 : ``' unmatched
 120     ("^\\(.*[^[/]\\)\\(\\[[0-9]+\\]\\)?: .* error .* line \\([0-9]+\\)" 1 3)
 121     ;; /bin/xyz[27]: ehco:  not found
 122     ("^\\(.*[^/]\\)\\[\\([0-9]+\\)\\]: .*: " 1 2)
 123     ;; /bin/xyz: syntax error near unexpected token `)'
 124     ;; /bin/xyz: /bin/xyz: line 2: `)'
 125     ("^\\(.*[^/]\\): [^0-9\n]+\n\\1: \\1: line \\([0-9]+\\):" 1 2)
 126     ;; /usr/bin/awk: syntax error at line 5 of file /bin/xyz
 127     (" error .* line \\([0-9]+\\) of file \\(.+\\)$" 2 1)
 128     ;; /usr/bin/awk: calling undefined function toto
 129     ;;  input record number 3, file awktestdata
 130     ;;  source line 4 of file /bin/xyz
 131     ("^[^ ].+\n\\( .+\n\\)* line \\([0-9]+\\) of file \\(.+\\)$" 3 2)
 132     ;; makefile:1: *** target pattern contains no `%'.  Stop.
 133     ("^\\(.+\\):\\([0-9]+\\): " 1 2))
 134   "Alist of regexps used to match script errors.
 135 See `compilation-error-regexp-alist'.")
 136
 137 ;; The C function openp slightly modified would do the trick fine
 138 (defun executable-find (command)
 139   "Search for COMMAND in exec-path and return the absolute file name.
 140 Return nil if COMMAND is not found anywhere in `exec-path'."
 141   (let ((list exec-path)
 142         file)
 143     (while list
 144       (setq list (if (and (setq file (expand-file-name command (car list)))
 145                           (file-executable-p file)
 146                           (not (file-directory-p file)))
 147                      nil
 148                    (setq file nil)
 149                    (cdr list))))
 150     file))
 151
 152
 153 (defun executable-chmod ()
 154   "This gets called after saving a file to assure that it be executable.
 155 You can set the absolute or relative mode in variable `executable-chmod' for
 156 non-executable files."
 157   (and executable-chmod
 158        buffer-file-name
 159        (or (file-executable-p buffer-file-name)
 160            (set-file-modes buffer-file-name
 161                            (if (< executable-chmod 0)
 162                                (- executable-chmod)
 163                              (logior executable-chmod
 164                                      (file-modes buffer-file-name)))))))
 165
 166
 167 (defun executable-interpret (command)
 168   "Run script with user-specified args, and collect output in a buffer.
 169 While script runs asynchronously, you can use the \\[next-error] command
 170 to find the next error."
 171   (interactive (list (read-string "Run script: "
 172                                   (or executable-command
 173                                       buffer-file-name))))
 174   (require 'compile)
 175   (save-some-buffers (not compilation-ask-about-save))
 176   (make-local-variable 'executable-command)
 177   (compile-internal (setq executable-command command)
 178                     "No more errors." "Interpretation"
 179                     ;; Give it a simpler regexp to match.
 180                     nil executable-error-regexp-alist))
 181
 182
 183
 184 ;;;###autoload
 185 (defun executable-set-magic (interpreter &optional argument
 186                                          no-query-flag insert-flag)
 187   "Set this buffer's interpreter to INTERPRETER with optional ARGUMENT.
 188 The variables `executable-magicless-file-regexp', `executable-prefix',
 189 `executable-insert', `executable-query' and `executable-chmod' control
 190 when and how magic numbers are inserted or replaced and scripts made
 191 executable."
 192   (interactive
 193    (let* ((name (read-string "Name or file name of interpreter: "))
 194           (arg (read-string (format "Argument for %s: " name))))
 195      (list name arg (eq executable-query 'function) t)))
 196   (setq interpreter (if (file-name-absolute-p interpreter)
 197                         interpreter
 198                       (or (executable-find interpreter)
 199                           (error "Interpreter %s not recognized" interpreter)))
 200         argument (concat interpreter
 201                          (and argument (string< "" argument) " ")
 202                          argument))
 203   (or buffer-read-only
 204       (if buffer-file-name
 205           (string-match executable-magicless-file-regexp
 206                         buffer-file-name))
 207       (not (or insert-flag executable-insert))
 208       (> (point-min) 1)
 209       (save-excursion
 210         (let ((point (point-marker))
 211               (buffer-modified-p (buffer-modified-p)))
 212           (goto-char (point-min))
 213           (make-local-hook 'after-save-hook)
 214           (add-hook 'after-save-hook 'executable-chmod nil t)
 215           (if (looking-at "#![ \t]*\\(.*\\)$")
 216               (and (goto-char (match-beginning 1))
 217                    ;; If the line ends in a space,
 218                    ;; don't offer to change it.
 219                    (not (= (char-after (1- (match-end 1))) ?\ ))
 220                    (not (string= argument
 221                                  (buffer-substring (point) (match-end 1))))
 222                    (if (or (not executable-query) no-query-flag
 223                            (save-window-excursion
 224                              ;; Make buffer visible before question.
 225                              (switch-to-buffer (current-buffer))
 226                              (y-or-n-p (concat "Replace magic number by `"
 227                                                executable-prefix argument "'? "))))
 228                        (progn
 229                          (replace-match argument t t nil 1)
 230                          (message "Magic number changed to `%s'"
 231                                   (concat executable-prefix argument)))))
 232             (insert executable-prefix argument ?\n)
 233             (message "Magic number changed to `%s'"
 234                      (concat executable-prefix argument)))
 235 ;;;       (or insert-flag
 236 ;;;           (eq executable-insert t)
 237 ;;;           (set-buffer-modified-p buffer-modified-p))
 238           )))
 239   interpreter)
 240
 241
 242
 243 ;;;###autoload
 244 (defun executable-self-display ()
 245   "Turn a text file into a self-displaying Un*x command.
 246 The magic number of such a command displays all lines but itself."
 247   (interactive)
 248   (if (eq this-command 'executable-self-display)
 249       (setq this-command 'executable-set-magic))
 250   (executable-set-magic executable-self-display "+2"))
 251
 252
 253
 254 (provide 'executable)
 255
 256 ;; executable.el ends here