code.delx.au - gnu-emacs/blob - lisp/loadhist.el

   1 ;;; loadhist.el --- lisp functions for working with feature groups
   2
   3 ;; Copyright (C) 1995, 1998, 2000, 2001, 2002, 2003, 2004,
   4 ;;   2005, 2006, 2007 Free Software Foundation, Inc.
   5
   6 ;; Author: Eric S. Raymond <esr@snark.thyrsus.com>
   7 ;; Maintainer: FSF
   8 ;; Keywords: internal
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 3, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  25 ;; Boston, MA 02110-1301, USA.
  26
  27 ;;; Commentary:
  28
  29 ;; These functions exploit the load-history system variable.
  30 ;; Entry points include `unload-feature', `symbol-file', and
  31 ;; `feature-file', documented in the Emacs Lisp manual.
  32
  33 ;;; Code:
  34
  35 (eval-when-compile (require 'cl))
  36
  37 (defun feature-symbols (feature)
  38   "Return the file and list of definitions associated with FEATURE.
  39 The value is actually the element of `load-history'
  40 for the file that did (provide FEATURE)."
  41    (catch 'foundit
  42      (mapc (lambda (x)
  43              (if (member (cons 'provide feature) (cdr x))
  44                  (throw 'foundit x)))
  45            load-history)
  46      nil))
  47
  48 (defun feature-file (feature)
  49   "Return the file name from which a given FEATURE was loaded.
  50 Actually, return the load argument, if any; this is sometimes the name of a
  51 Lisp file without an extension.  If the feature came from an `eval-buffer' on
  52 a buffer with no associated file, or an `eval-region', return nil."
  53   (if (not (featurep feature))
  54       (error "%S is not a currently loaded feature" feature)
  55     (car (feature-symbols feature))))
  56
  57 (defun file-loadhist-lookup (file)
  58   "Return the `load-history' element for FILE.
  59 FILE can be a file name, or a library name.
  60 A library name is equivalent to the file name that `load-library' would load."
  61   ;; First look for FILE as given.
  62   (let ((symbols (assoc file load-history)))
  63     ;; Try converting a library name to an absolute file name.
  64     (and (null symbols)
  65          (let ((absname
  66                 (locate-file file load-path (get-load-suffixes))))
  67            (and absname (not (equal absname file))
  68                 (setq symbols (cdr (assoc absname load-history))))))
  69     symbols))
  70
  71 (defun file-provides (file)
  72   "Return the list of features provided by FILE as it was loaded.
  73 FILE can be a file name, or a library name.
  74 A library name is equivalent to the file name that `load-library' would load."
  75   (let ((symbols (file-loadhist-lookup file))
  76         provides)
  77     (mapc (lambda (x)
  78             (if (and (consp x) (eq (car x) 'provide))
  79                 (setq provides (cons (cdr x) provides))))
  80           symbols)
  81     provides))
  82
  83 (defun file-requires (file)
  84   "Return the list of features required by FILE as it was loaded.
  85 FILE can be a file name, or a library name.
  86 A library name is equivalent to the file name that `load-library' would load."
  87   (let ((symbols (file-loadhist-lookup file))
  88         requires)
  89     (mapc (lambda (x)
  90             (if (and (consp x) (eq (car x) 'require))
  91                 (setq requires (cons (cdr x) requires))))
  92           symbols)
  93     requires))
  94
  95 (defsubst file-set-intersect (p q)
  96   "Return the set intersection of two lists."
  97   (let ((ret nil))
  98     (dolist (x p ret)
  99       (if (memq x q) (setq ret (cons x ret))))
 100     ret))
 101
 102 (defun file-dependents (file)
 103   "Return the list of loaded libraries that depend on FILE.
 104 This can include FILE itself.
 105 FILE can be a file name, or a library name.
 106 A library name is equivalent to the file name that `load-library' would load."
 107   (let ((provides (file-provides file))
 108         (dependents nil))
 109     (dolist (x load-history dependents)
 110       (if (file-set-intersect provides (file-requires (car x)))
 111           (setq dependents (cons (car x) dependents))))
 112     dependents))
 113
 114 (defun read-feature (prompt &optional loaded-p)
 115   "Read feature name from the minibuffer, prompting with string PROMPT.
 116 If optional second arg LOADED-P is non-nil, the feature must be loaded
 117 from a file."
 118   (intern
 119    (completing-read prompt
 120                     (cons nil features)
 121                     (and loaded-p
 122                          #'(lambda (f)
 123                              (and f     ; ignore nil
 124                                   (feature-file f))))
 125                     loaded-p)))
 126
 127 (defvaralias 'loadhist-hook-functions 'unload-feature-special-hooks)
 128 (defvar unload-feature-special-hooks
 129   '(after-change-functions after-insert-file-functions
 130     after-make-frame-functions auto-fill-function before-change-functions
 131     blink-paren-function buffer-access-fontify-functions command-line-functions
 132     comment-indent-function compilation-finish-functions
 133     disabled-command-function find-file-not-found-functions
 134     font-lock-beginning-of-syntax-function font-lock-fontify-buffer-function
 135     font-lock-fontify-region-function font-lock-mark-block-function
 136     font-lock-syntactic-face-function font-lock-unfontify-buffer-function
 137     font-lock-unfontify-region-function kill-buffer-query-functions
 138     kill-emacs-query-functions lisp-indent-function mouse-position-function
 139     redisplay-end-trigger-functions temp-buffer-show-function
 140     window-scroll-functions window-size-change-functions
 141     write-contents-functions write-file-functions
 142     write-region-annotate-functions)
 143   "A list of special hooks from Info node `(elisp)Standard Hooks'.
 144
 145 These are symbols with hook-type values whose names don't end in
 146 `-hook' or `-hooks', from which `unload-feature' tries to remove
 147 pertinent symbols.")
 148
 149 (defvar unload-hook-features-list nil
 150   "List of features of the package being unloaded.
 151
 152 This is meant to be used by FEATURE-unload-hook hooks, see the
 153 documentation of `unload-feature' for details.")
 154
 155 ;;;###autoload
 156 (defun unload-feature (feature &optional force)
 157   "Unload the library that provided FEATURE, restoring all its autoloads.
 158 If the feature is required by any other loaded code, and prefix arg FORCE
 159 is nil, raise an error.
 160
 161 This function tries to undo any modifications that the package has
 162 made to hook values in Emacs.  Normally it does this using heuristics.
 163 The packages may define a hook `FEATURE-unload-hook'; if that exists,
 164 it is called instead of the normal heuristics.
 165
 166 Such a hook should undo all the relevant global state changes that may
 167 have been made by loading the package or executing functions in it.
 168 It has access to the package's feature list (before anything is unbound)
 169 in the variable `unload-hook-features-list' and could remove features
 170 from it in the event that the package has done something strange,
 171 such as redefining an Emacs function."
 172   (interactive
 173    (list
 174     (read-feature "Unload feature: " t)
 175     current-prefix-arg))
 176   (unless (featurep feature)
 177     (error "%s is not a currently loaded feature" (symbol-name feature)))
 178   (unless force
 179     (let* ((file (feature-file feature))
 180            (dependents (delete file (copy-sequence (file-dependents file)))))
 181       (when dependents
 182         (error "Loaded libraries %s depend on %s"
 183                (prin1-to-string dependents) file))))
 184   (let* ((unload-hook-features-list (feature-symbols feature))
 185          (file (pop unload-hook-features-list))
 186          ;; If non-nil, this is a symbol for which we should
 187          ;; restore a previous autoload if possible.
 188          restore-autoload
 189          (unload-hook (intern-soft (concat (symbol-name feature)
 190                                            "-unload-hook"))))
 191     ;; Try to avoid losing badly when hooks installed in critical
 192     ;; places go away.  (Some packages install things on
 193     ;; `kill-buffer-hook', `activate-menubar-hook' and the like.)
 194     ;; First off, provide a clean way for package FOO to arrange
 195     ;; this by adding hooks on the variable `FOO-unload-hook'.
 196     (if unload-hook
 197         (run-hooks unload-hook)
 198       ;; Otherwise, do our best.  Look through the obarray for symbols
 199       ;; which seem to be hook variables or special hook functions and
 200       ;; remove anything from them which matches the feature-symbols
 201       ;; about to get zapped.  Obviously this won't get anonymous
 202       ;; functions which the package might just have installed, and
 203       ;; there might be other important state, but this tactic
 204       ;; normally works.
 205       (mapatoms
 206        (lambda (x)
 207          (when (and (boundp x)
 208                     (or (and (consp (symbol-value x)) ; Random hooks.
 209                              (string-match "-hooks?\\'" (symbol-name x)))
 210                         (memq x unload-feature-special-hooks))) ; Known abnormal hooks etc.
 211            (dolist (y unload-hook-features-list)
 212              (when (and (eq (car-safe y) 'defun)
 213                         (not (get (cdr y) 'autoload)))
 214                (remove-hook x (cdr y)))))))
 215       ;; Remove any feature-symbols from auto-mode-alist as well.
 216       (dolist (y unload-hook-features-list)
 217         (when (and (eq (car-safe y) 'defun)
 218                    (not (get (cdr y) 'autoload)))
 219           (setq auto-mode-alist
 220                 (rassq-delete-all (cdr y) auto-mode-alist)))))
 221     (when (fboundp 'elp-restore-function) ; remove ELP stuff first
 222       (dolist (elt unload-hook-features-list)
 223         (when (symbolp elt)
 224           (elp-restore-function elt))))
 225
 226     (dolist (x unload-hook-features-list)
 227       (if (consp x)
 228           (case (car x)
 229            ;; Remove any feature names that this file provided.
 230            (provide
 231             (setq features (delq (cdr x) features)))
 232            ((defun autoload)
 233             (let ((fun (cdr x)))
 234               (when (fboundp fun)
 235                 (when (fboundp 'ad-unadvise)
 236                   (ad-unadvise fun))
 237                 (let ((aload (get fun 'autoload)))
 238                   (if (and aload (eq fun restore-autoload))
 239                       (fset fun (cons 'autoload aload))
 240                     (fmakunbound fun))))))
 241            ;; (t . SYMBOL) comes before (defun . SYMBOL)
 242            ;; and says we should restore SYMBOL's autoload
 243            ;; when we undefine it.
 244            ((t) (setq restore-autoload (cdr x)))
 245            ((require defface) nil)
 246            (t (message "Unexpected element %s in load-history" x)))
 247         ;; Kill local values as much as possible.
 248         (dolist (buf (buffer-list))
 249           (with-current-buffer buf
 250             (if (and (boundp x) (timerp (symbol-value x)))
 251                 (cancel-timer (symbol-value x)))
 252             (kill-local-variable x)))
 253         (if (and (boundp x) (timerp (symbol-value x)))
 254             (cancel-timer (symbol-value x)))
 255         ;; Get rid of the default binding if we can.
 256         (unless (local-variable-if-set-p x)
 257           (makunbound x))))
 258     ;; Delete the load-history element for this file.
 259     (setq load-history (delq (assoc file load-history) load-history)))
 260   ;; Don't return load-history, it is not useful.
 261   nil)
 262
 263 (provide 'loadhist)
 264
 265 ;; arch-tag: 70bb846a-c413-4f01-bf88-78dba4ac0798
 266 ;;; loadhist.el ends here