code.delx.au - gnu-emacs/blob - lisp/frame.el

   1 ;;; frame.el --- multi-frame management independent of window systems.
   2
   3 ;;;; Copyright (C) 1993, 1994 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6 ;; Keywords: internal
   7
   8 ;;; This file is part of GNU Emacs.
   9 ;;;
  10 ;;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;;; it under the terms of the GNU General Public License as published by
  12 ;;; the Free Software Foundation; either version 2, or (at your option)
  13 ;;; any later version.
  14 ;;;
  15 ;;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;;; GNU General Public License for more details.
  19 ;;;
  20 ;;; You should have received a copy of the GNU General Public License
  21 ;;; along with GNU Emacs; see the file COPYING.  If not, write to
  22 ;;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  23
  24 ;;; Code:
  25
  26 (defvar frame-creation-function nil
  27   "Window-system dependent function to call to create a new frame.
  28 The window system startup file should set this to its frame creation
  29 function, which should take an alist of parameters as its argument.")
  30
  31 ;;; The initial value given here for this must ask for a minibuffer.
  32 ;;; There must always exist a frame with a minibuffer, and after we
  33 ;;; delete the terminal frame, this will be the only frame.
  34 (defvar initial-frame-alist '((minibuffer . t))
  35   "Alist of frame parameters for creating the initial X window frame.
  36 You can set this in your `.emacs' file; for example,
  37  (setq initial-frame-alist '((top . 1) (left . 1) (width . 80) (height . 55)))
  38 Parameters specified here supersede the values given in `default-frame-alist'.
  39
  40 If the value calls for a frame without a minibuffer, and you have not created
  41 a minibuffer frame on your own, one is created according to
  42 `minibuffer-frame-alist'.
  43
  44 You can specify geometry-related options for just the initial frame
  45 by setting this variable in your `.emacs' file; however, they won't
  46 take effect until Emacs reads `.emacs', which happens after first creating
  47 the frame.  If you want the frame to have the proper geometry as soon
  48 as it appears, you need to use this three-step process:
  49 * Specify X resources to give the geometry you want.
  50 * Set `default-frame-alist' to override these options so that they
  51   don't affect subsequent frames.
  52 * Set `initial-frame-alist' in a way that matches the X resources,
  53   to override what you put in `default-frame-alist'.")
  54
  55 (defvar minibuffer-frame-alist '((width . 80) (height . 2))
  56   "Alist of frame parameters for initially creating a minibuffer frame.
  57 You can set this in your `.emacs' file; for example,
  58  (setq minibuffer-frame-alist
  59    '((top . 1) (left . 1) (width . 80) (height . 2)))
  60 Parameters specified here supersede the values given in
  61 `default-frame-alist'.")
  62
  63 (defvar pop-up-frame-alist nil
  64   "Alist of frame parameters used when creating pop-up frames.
  65 Pop-up frames are used for completions, help, and the like.
  66 This variable can be set in your init file, like this:
  67   (setq pop-up-frame-alist '((width . 80) (height . 20)))
  68 These supersede the values given in `default-frame-alist'.")
  69
  70 (setq pop-up-frame-function
  71       (function (lambda ()
  72                   (make-frame pop-up-frame-alist))))
  73
  74 (defvar special-display-frame-alist
  75   '((height . 14) (width . 80) (unsplittable . t))
  76   "*Alist of frame parameters used when creating special frames.
  77 Special frames are used for buffers whose names are in
  78 `special-display-buffer-names' and for buffers whose names match
  79 one of the regular expressions in `special-display-regexps'.
  80 This variable can be set in your init file, like this:
  81   (setq special-display-frame-alist '((width . 80) (height . 20)))
  82 These supersede the values given in `default-frame-alist'.")
  83
  84 ;; Display BUFFER in its own frame, reusing an existing window if any.
  85 ;; Return the window chosen.
  86 ;; Currently we do not insist on selecting the window within its frame.
  87 ;; If ARGS is an alist, use it as a list of frame parameter specs.
  88 ;; If ARGS is a list whose car is a symbol,
  89 ;; use (car ARGS) as a function to do the work.
  90 ;; Pass it BUFFER as first arg, and (cdr ARGS) gives the rest of the args.
  91 (defun special-display-popup-frame (buffer &optional args)
  92   (if (and args (symbolp (car args)))
  93       (apply (car args) buffer (cdr args))
  94     (let ((window (get-buffer-window buffer t)))
  95       (if window
  96           ;; If we have a window already, make it visible.
  97           (let ((frame (window-frame window)))
  98             (make-frame-visible frame)
  99             (raise-frame frame)
 100             window)
 101         ;; If no window yet, make one in a new frame.
 102         (let ((frame (make-frame (append args special-display-frame-alist))))
 103           (set-window-buffer (frame-selected-window frame) buffer)
 104           (set-window-dedicated-p (frame-selected-window frame) t)
 105           (frame-selected-window frame))))))
 106
 107 ;; Handle delete-frame events from the X server.
 108 (defun handle-delete-frame (event)
 109   (interactive "e")
 110   (let ((frame (posn-window (event-start event)))
 111         (i 0)
 112         (tail (frame-list)))
 113     (while tail
 114       (and (frame-visible-p (car tail))
 115            (not (eq (car tail) frame))
 116           (setq i (1+ i)))
 117       (setq tail (cdr tail)))
 118     (if (> i 0)
 119         (delete-frame frame t)
 120       (kill-emacs))))
 121 \f
 122 ;;;; Arrangement of frames at startup
 123
 124 ;;; 1) Load the window system startup file from the lisp library and read the
 125 ;;; high-priority arguments (-q and the like).  The window system startup
 126 ;;; file should create any frames specified in the window system defaults.
 127 ;;;
 128 ;;; 2) If no frames have been opened, we open an initial text frame.
 129 ;;;
 130 ;;; 3) Once the init file is done, we apply any newly set parameters
 131 ;;; in initial-frame-alist to the frame.
 132
 133 ;; These are now called explicitly at the proper times,
 134 ;; since that is easier to understand.
 135 ;; Actually using hooks within Emacs is bad for future maintenance. --rms.
 136 ;; (add-hook 'before-init-hook 'frame-initialize)
 137 ;; (add-hook 'window-setup-hook 'frame-notice-user-settings)
 138
 139 ;;; If we create the initial frame, this is it.
 140 (defvar frame-initial-frame nil)
 141
 142 ;; Record the parameters used in frame-initialize to make the initial frame.
 143 (defvar frame-initial-frame-alist)
 144
 145 (defvar frame-initial-geometry-arguments nil)
 146
 147 ;;; startup.el calls this function before loading the user's init
 148 ;;; file - if there is no frame with a minibuffer open now, create
 149 ;;; one to display messages while loading the init file.
 150 (defun frame-initialize ()
 151
 152   ;; Are we actually running under a window system at all?
 153   (if (and window-system (not noninteractive))
 154       (progn
 155         ;; Turn on special-display processing only if there's a window system.
 156         (setq special-display-function 'special-display-popup-frame)
 157
 158         ;; If there is no frame with a minibuffer besides the terminal
 159         ;; frame, then we need to create the opening frame.  Make sure
 160         ;; it has a minibuffer, but let initial-frame-alist omit the
 161         ;; minibuffer spec.
 162         (or (delq terminal-frame (minibuffer-frame-list))
 163             (progn
 164               (setq frame-initial-frame-alist
 165                     (append initial-frame-alist default-frame-alist))
 166               ;; Record these with their default values
 167               ;; if they don't have any values explicitly.
 168               (or (assq 'vertical-scroll-bars frame-initial-frame-alist)
 169                   (setq frame-initial-frame-alist
 170                         (cons '(vertical-scroll-bars . t)
 171                               frame-initial-frame-alist)))
 172               (or (assq 'horizontal-scroll-bars frame-initial-frame-alist)
 173                   (setq frame-initial-frame-alist
 174                         (cons '(horizontal-scroll-bars . t)
 175                               frame-initial-frame-alist)))
 176               (setq default-minibuffer-frame
 177                     (setq frame-initial-frame
 178                           (make-frame initial-frame-alist)))
 179               ;; Delete any specifications for window geometry parameters
 180               ;; so that we won't reapply them in frame-notice-user-settings.
 181               ;; It would be wrong to reapply them then,
 182               ;; because that would override explicit user resizing.
 183               (setq initial-frame-alist
 184                     (frame-remove-geometry-params initial-frame-alist))))
 185         ;; At this point, we know that we have a frame open, so we
 186         ;; can delete the terminal frame.
 187         (delete-frame terminal-frame)
 188         (setq terminal-frame nil))
 189
 190     ;; No, we're not running a window system.  Use make-terminal-frame if
 191     ;; we support that feature, otherwise arrange to cause errors.
 192     (setq frame-creation-function
 193           (if (fboundp 'make-terminal-frame)
 194               'make-terminal-frame
 195             (function
 196              (lambda (parameters)
 197                (error
 198                 "Can't create multiple frames without a window system")))))))
 199
 200 ;;; startup.el calls this function after loading the user's init
 201 ;;; file.  Now default-frame-alist and initial-frame-alist contain
 202 ;;; information to which we must react; do what needs to be done.
 203 (defun frame-notice-user-settings ()
 204
 205   ;; Make menu-bar-mode and default-frame-alist consistent.
 206   (if (boundp 'menu-bar-mode)
 207       (let ((default (assq 'menu-bar-lines default-frame-alist)))
 208         (if default
 209             (setq menu-bar-mode (not (eq (cdr default) 0)))
 210           (setq default-frame-alist
 211                 (cons (cons 'menu-bar-lines (if menu-bar-mode 1 0))
 212                       default-frame-alist)))))
 213
 214   ;; Creating and deleting frames may shift the selected frame around,
 215   ;; and thus the current buffer.  Protect against that.  We don't
 216   ;; want to use save-excursion here, because that may also try to set
 217   ;; the buffer of the selected window, which fails when the selected
 218   ;; window is the minibuffer.
 219   (let ((old-buffer (current-buffer)))
 220
 221     ;; If the initial frame is still around, apply initial-frame-alist
 222     ;; and default-frame-alist to it.
 223     (if (frame-live-p frame-initial-frame)
 224
 225         ;; The initial frame we create above always has a minibuffer.
 226         ;; If the user wants to remove it, or make it a minibuffer-only
 227         ;; frame, then we'll have to delete the current frame and make a
 228         ;; new one; you can't remove or add a root window to/from an
 229         ;; existing frame.
 230         ;;
 231         ;; NOTE: default-frame-alist was nil when we created the
 232         ;; existing frame.  We need to explicitly include
 233         ;; default-frame-alist in the parameters of the screen we
 234         ;; create here, so that its new value, gleaned from the user's
 235         ;; .emacs file, will be applied to the existing screen.
 236         (if (not (eq (cdr (or (assq 'minibuffer initial-frame-alist)
 237                               (assq 'minibuffer default-frame-alist)
 238                               '(minibuffer . t)))
 239                      t))
 240             ;; Create the new frame.
 241             (let (parms new)
 242               ;; If the frame isn't visible yet, wait till it is.
 243               ;; If the user has to position the window,
 244               ;; Emacs doesn't know its real position until
 245               ;; the frame is seen to be visible.
 246               (while (not (cdr (assq 'visibility
 247                                      (frame-parameters frame-initial-frame))))
 248                 (sleep-for 1))
 249               (setq parms (append initial-frame-alist
 250                                   default-frame-alist
 251                                   (frame-parameters frame-initial-frame)
 252                                   nil))
 253               ;; Get rid of `reverse', because that was handled
 254               ;; when we first made the frame.
 255               (setq parms (cons '(reverse) (delq (assq 'reverse parms) parms)))
 256               (if (assq 'height frame-initial-geometry-arguments)
 257                   (setq parms (frame-delete-all 'height parms)))
 258               (if (assq 'width frame-initial-geometry-arguments)
 259                   (setq parms (frame-delete-all 'width parms)))
 260               (if (assq 'left frame-initial-geometry-arguments)
 261                   (setq parms (frame-delete-all 'left parms)))
 262               (if (assq 'top frame-initial-geometry-arguments)
 263                   (setq parms (frame-delete-all 'top parms)))
 264               (setq new
 265                     (make-frame
 266                      ;; Use the geometry args that created the existing
 267                      ;; frame, rather than the parms we get for it.
 268                      (append frame-initial-geometry-arguments
 269                              '((user-size . t) (user-position . t))
 270                              parms)))
 271               ;; The initial frame, which we are about to delete, may be
 272               ;; the only frame with a minibuffer.  If it is, create a
 273               ;; new one.
 274               (or (delq frame-initial-frame (minibuffer-frame-list))
 275                   (make-frame (append minibuffer-frame-alist
 276                                      '((minibuffer . only)))))
 277
 278               ;; If the initial frame is serving as a surrogate
 279               ;; minibuffer frame for any frames, we need to wean them
 280               ;; onto a new frame.  The default-minibuffer-frame
 281               ;; variable must be handled similarly.
 282               (let ((users-of-initial
 283                      (filtered-frame-list
 284                       (function (lambda (frame)
 285                                   (and (not (eq frame frame-initial-frame))
 286                                        (eq (window-frame
 287                                             (minibuffer-window frame))
 288                                            frame-initial-frame)))))))
 289                 (if (or users-of-initial
 290                         (eq default-minibuffer-frame frame-initial-frame))
 291
 292                     ;; Choose an appropriate frame.  Prefer frames which
 293                     ;; are only minibuffers.
 294                     (let* ((new-surrogate
 295                             (car
 296                              (or (filtered-frame-list
 297                                   (function
 298                                    (lambda (frame)
 299                                      (eq (cdr (assq 'minibuffer
 300                                                     (frame-parameters frame)))
 301                                          'only))))
 302                                  (minibuffer-frame-list))))
 303                            (new-minibuffer (minibuffer-window new-surrogate)))
 304
 305                       (if (eq default-minibuffer-frame frame-initial-frame)
 306                           (setq default-minibuffer-frame new-surrogate))
 307
 308                       ;; Wean the frames using frame-initial-frame as
 309                       ;; their minibuffer frame.
 310                       (mapcar
 311                        (function
 312                         (lambda (frame)
 313                           (modify-frame-parameters
 314                            frame (list (cons 'minibuffer new-minibuffer)))))
 315                        users-of-initial))))
 316
 317               ;; Redirect events enqueued at this frame to the new frame.
 318               ;; Is this a good idea?
 319               (redirect-frame-focus frame-initial-frame new)
 320
 321               ;; Finally, get rid of the old frame.
 322               (delete-frame frame-initial-frame t))
 323
 324           ;; Otherwise, we don't need all that rigamarole; just apply
 325           ;; the new parameters.
 326           (let (newparms allparms tail)
 327             (setq allparms (append initial-frame-alist
 328                                    default-frame-alist))
 329             (if (assq 'height frame-initial-geometry-arguments)
 330                 (setq allparms (frame-delete-all 'height allparms)))
 331             (if (assq 'width frame-initial-geometry-arguments)
 332                 (setq allparms (frame-delete-all 'width allparms)))
 333             (if (assq 'left frame-initial-geometry-arguments)
 334                 (setq allparms (frame-delete-all 'left allparms)))
 335             (if (assq 'top frame-initial-geometry-arguments)
 336                 (setq allparms (frame-delete-all 'top allparms)))
 337             (setq tail allparms)
 338             ;; Find just the parms that have changed since we first
 339             ;; made this frame.  Those are the ones actually set by
 340             ;; the init file.  For those parms whose values we already knew
 341             ;; (such as those spec'd by command line options)
 342             ;; it is undesirable to specify the parm again
 343             ;; once the user has seen the frame and been able to alter it
 344             ;; manually.
 345             (while tail
 346               (let (newval oldval)
 347                 (setq oldval (cdr (assq (car (car tail))
 348                                         frame-initial-frame-alist)))
 349                 (setq newval (cdr (assq (car (car tail)) allparms)))
 350                 (or (eq oldval newval)
 351                     (setq newparms
 352                           (cons (cons (car (car tail)) newval) newparms))))
 353               (setq tail (cdr tail)))
 354             (setq newparms (nreverse newparms))
 355             (modify-frame-parameters frame-initial-frame
 356                                      newparms)
 357             (if (assq 'font newparms)
 358                 (frame-update-faces frame-initial-frame)))))
 359
 360     ;; Restore the original buffer.
 361     (set-buffer old-buffer)
 362
 363     ;; Make sure the initial frame can be GC'd if it is ever deleted.
 364     ;; Make sure frame-notice-user-settings does nothing if called twice.
 365     (setq frame-initial-frame nil)))
 366
 367 ;; Delete from ALIST all elements whose car is KEY.
 368 ;; Return the modified alist.
 369 (defun frame-delete-all (key alist)
 370   (setq alist (copy-sequence alist))
 371   (let ((tail alist))
 372     (while tail
 373       (if (eq (car (car tail)) key)
 374           (setq alist (delq (car tail) alist)))
 375       (setq tail (cdr tail)))
 376     alist))
 377 \f
 378 ;;;; Creation of additional frames, and other frame miscellanea
 379
 380 ;;; Return some frame other than the current frame, creating one if
 381 ;;; necessary.  Note that the minibuffer frame, if separate, is not
 382 ;;; considered (see next-frame).
 383 (defun get-other-frame ()
 384   (let ((s (if (equal (next-frame (selected-frame)) (selected-frame))
 385                (make-frame)
 386              (next-frame (selected-frame)))))
 387     s))
 388
 389 (defun next-multiframe-window ()
 390   "Select the next window, regardless of which frame it is on."
 391   (interactive)
 392   (select-window (next-window (selected-window)
 393                               (> (minibuffer-depth) 0)
 394                               t)))
 395
 396 (defun previous-multiframe-window ()
 397   "Select the previous window, regardless of which frame it is on."
 398   (interactive)
 399   (select-window (previous-window (selected-window)
 400                                   (> (minibuffer-depth) 0)
 401                                   t)))
 402
 403 (defun make-frame-on-display (display &optional parameters)
 404   "Make a frame on display DISPLAY.
 405 The optional second argument PARAMETERS specifies additional frame parameters."
 406   (interactive "sMake frame on display: ")
 407   (make-frame (cons (cons 'display display) parameters)))
 408
 409 ;; Alias, kept temporarily.
 410 (defalias 'new-frame 'make-frame)
 411 (defun make-frame (&optional parameters)
 412   "Create a new frame, displaying the current buffer.
 413
 414 Optional argument PARAMETERS is an alist of parameters for the new
 415 frame.  Specifically, PARAMETERS is a list of pairs, each having
 416 the form (NAME . VALUE).
 417
 418 Here are some of the parameters allowed (not a complete list):
 419
 420 \(name . STRING)        - The frame should be named STRING.
 421
 422 \(height . NUMBER) - The frame should be NUMBER text lines high.  If
 423         this parameter is present, the width parameter must also be
 424         given.
 425
 426 \(width . NUMBER) - The frame should be NUMBER characters in width.
 427         If this parameter is present, the height parameter must also
 428         be given.
 429
 430 \(minibuffer . t) - the frame should have a minibuffer
 431 \(minibuffer . nil) - the frame should have no minibuffer
 432 \(minibuffer . only) - the frame should contain only a minibuffer
 433 \(minibuffer . WINDOW) - the frame should use WINDOW as its minibuffer window."
 434   (interactive)
 435   (let ((nframe))
 436     (run-hooks 'before-make-frame-hook)
 437     (setq nframe (funcall frame-creation-function parameters))
 438     (run-hooks 'after-make-frame-hook)
 439     nframe))
 440
 441 (defun filtered-frame-list (predicate)
 442   "Return a list of all live frames which satisfy PREDICATE."
 443   (let ((frames (frame-list))
 444         good-frames)
 445     (while (consp frames)
 446       (if (funcall predicate (car frames))
 447           (setq good-frames (cons (car frames) good-frames)))
 448       (setq frames (cdr frames)))
 449     good-frames))
 450
 451 (defun minibuffer-frame-list ()
 452   "Return a list of all frames with their own minibuffers."
 453   (filtered-frame-list
 454    (function (lambda (frame)
 455                (eq frame (window-frame (minibuffer-window frame)))))))
 456
 457 (defun frame-remove-geometry-params (param-list)
 458   "Return the parameter list PARAM-LIST, but with geometry specs removed.
 459 This deletes all bindings in PARAM-LIST for `top', `left', `width',
 460 `height', `user-size' and `user-position' parameters.
 461 Emacs uses this to avoid overriding explicit moves and resizings from
 462 the user during startup."
 463   (setq param-list (cons nil param-list))
 464   (let ((tail param-list))
 465     (while (consp (cdr tail))
 466       (if (and (consp (car (cdr tail)))
 467                (memq (car (car (cdr tail)))
 468                      '(height width top left user-position user-size)))
 469           (progn
 470             (setq frame-initial-geometry-arguments
 471                   (cons (car (cdr tail)) frame-initial-geometry-arguments))
 472             (setcdr tail (cdr (cdr tail))))
 473         (setq tail (cdr tail)))))
 474   (setq frame-initial-geometry-arguments
 475         (nreverse frame-initial-geometry-arguments))
 476   (cdr param-list))
 477
 478
 479 (defun other-frame (arg)
 480   "Select the ARG'th different visible frame, and raise it.
 481 All frames are arranged in a cyclic order.
 482 This command selects the frame ARG steps away in that order.
 483 A negative ARG moves in the opposite order."
 484   (interactive "p")
 485   (let ((frame (selected-frame)))
 486     (while (> arg 0)
 487       (setq frame (next-frame frame))
 488       (while (not (eq (frame-visible-p frame) t))
 489         (setq frame (next-frame frame)))
 490       (setq arg (1- arg)))
 491     (while (< arg 0)
 492       (setq frame (previous-frame frame))
 493       (while (not (eq (frame-visible-p frame) t))
 494         (setq frame (previous-frame frame)))
 495       (setq arg (1+ arg)))
 496     (raise-frame frame)
 497     (select-frame frame)
 498     (set-mouse-position (selected-frame) (1- (frame-width)) 0)
 499     (if (fboundp 'unfocus-frame)
 500         (unfocus-frame))))
 501 \f
 502 ;;;; Frame configurations
 503
 504 (defun current-frame-configuration ()
 505   "Return a list describing the positions and states of all frames.
 506 Its car is `frame-configuration'.
 507 Each element of the cdr is a list of the form (FRAME ALIST WINDOW-CONFIG),
 508 where
 509   FRAME is a frame object,
 510   ALIST is an association list specifying some of FRAME's parameters, and
 511   WINDOW-CONFIG is a window configuration object for FRAME."
 512   (cons 'frame-configuration
 513         (mapcar (function
 514                  (lambda (frame)
 515                    (list frame
 516                          (frame-parameters frame)
 517                          (current-window-configuration frame))))
 518                 (frame-list))))
 519
 520 (defun set-frame-configuration (configuration &optional nodelete)
 521   "Restore the frames to the state described by CONFIGURATION.
 522 Each frame listed in CONFIGURATION has its position, size, window
 523 configuration, and other parameters set as specified in CONFIGURATION.
 524 Ordinarily, this function deletes all existing frames not
 525 listed in CONFIGURATION.  But if optional second argument NODELETE
 526 is given and non-nil, the unwanted frames are iconified instead."
 527   (or (frame-configuration-p configuration)
 528       (signal 'wrong-type-argument
 529               (list 'frame-configuration-p configuration)))
 530   (let ((config-alist (cdr configuration))
 531         frames-to-delete)
 532     (mapcar (function
 533              (lambda (frame)
 534                (let ((parameters (assq frame config-alist)))
 535                  (if parameters
 536                      (progn
 537                        (modify-frame-parameters
 538                         frame
 539                         ;; Since we can't set a frame's minibuffer status,
 540                         ;; we might as well omit the parameter altogether.
 541                         (let* ((parms (nth 1 parameters))
 542                                (mini (assq 'minibuffer parms)))
 543                           (if mini (setq parms (delq mini parms)))
 544                           parms))
 545                        (set-window-configuration (nth 2 parameters)))
 546                    (setq frames-to-delete (cons frame frames-to-delete))))))
 547             (frame-list))
 548     (if nodelete
 549         ;; Note: making frames invisible here was tried
 550         ;; but led to some strange behavior--each time the frame
 551         ;; was made visible again, the window manager asked afresh
 552         ;; for where to put it.
 553         (mapcar 'iconify-frame frames-to-delete)
 554       (mapcar 'delete-frame frames-to-delete))))
 555
 556 (defun frame-configuration-p (object)
 557   "Return non-nil if OBJECT seems to be a frame configuration.
 558 Any list whose car is `frame-configuration' is assumed to be a frame
 559 configuration."
 560   (and (consp object)
 561        (eq (car object) 'frame-configuration)))
 562
 563 \f
 564 ;;;; Convenience functions for accessing and interactively changing
 565 ;;;; frame parameters.
 566
 567 (defun frame-height (&optional frame)
 568   "Return number of lines available for display on FRAME.
 569 If FRAME is omitted, describe the currently selected frame."
 570   (cdr (assq 'height (frame-parameters frame))))
 571
 572 (defun frame-width (&optional frame)
 573   "Return number of columns available for display on FRAME.
 574 If FRAME is omitted, describe the currently selected frame."
 575   (cdr (assq 'width (frame-parameters frame))))
 576
 577 (defun set-default-font (font-name)
 578   "Set the font of the selected frame to FONT.
 579 When called interactively, prompt for the name of the font to use."
 580   (interactive "sFont name: ")
 581   (modify-frame-parameters (selected-frame)
 582                            (list (cons 'font font-name)))
 583   ;; Update faces that want a bold or italic version of the default font.
 584   (frame-update-faces (selected-frame)))
 585
 586 (defun set-background-color (color-name)
 587   "Set the background color of the selected frame to COLOR.
 588 When called interactively, prompt for the name of the color to use."
 589   (interactive "sColor: ")
 590   (modify-frame-parameters (selected-frame)
 591                            (list (cons 'background-color color-name)))
 592   (frame-update-face-colors (selected-frame)))
 593
 594 (defun set-foreground-color (color-name)
 595   "Set the foreground color of the selected frame to COLOR.
 596 When called interactively, prompt for the name of the color to use."
 597   (interactive "sColor: ")
 598   (modify-frame-parameters (selected-frame)
 599                            (list (cons 'foreground-color color-name)))
 600   (frame-update-face-colors (selected-frame)))
 601
 602 (defun set-cursor-color (color-name)
 603   "Set the text cursor color of the selected frame to COLOR.
 604 When called interactively, prompt for the name of the color to use."
 605   (interactive "sColor: ")
 606   (modify-frame-parameters (selected-frame)
 607                            (list (cons 'cursor-color color-name))))
 608
 609 (defun set-mouse-color (color-name)
 610   "Set the color of the mouse pointer of the selected frame to COLOR.
 611 When called interactively, prompt for the name of the color to use."
 612   (interactive "sColor: ")
 613   (modify-frame-parameters (selected-frame)
 614                            (list (cons 'mouse-color color-name))))
 615
 616 (defun set-border-color (color-name)
 617   "Set the color of the border of the selected frame to COLOR.
 618 When called interactively, prompt for the name of the color to use."
 619   (interactive "sColor: ")
 620   (modify-frame-parameters (selected-frame)
 621                            (list (cons 'border-color color-name))))
 622
 623 (defun auto-raise-mode (arg)
 624   "Toggle whether or not the selected frame should auto-raise.
 625 With arg, turn auto-raise mode on if and only if arg is positive.
 626 Note that this controls Emacs's own auto-raise feature.
 627 Some window managers allow you to enable auto-raise for certain windows.
 628 You can use that for Emacs windows if you wish, but if you do,
 629 that is beyond the control of Emacs and this command has no effect on it."
 630   (interactive "P")
 631   (if (null arg)
 632       (setq arg
 633             (if (cdr (assq 'auto-raise (frame-parameters (selected-frame))))
 634                 -1 1)))
 635   (modify-frame-parameters (selected-frame)
 636                            (list (cons 'auto-raise (> arg 0)))))
 637
 638 (defun auto-lower-mode (arg)
 639   "Toggle whether or not the selected frame should auto-lower.
 640 With arg, turn auto-lower mode on if and only if arg is positive.
 641 Note that this controls Emacs's own auto-lower feature.
 642 Some window managers allow you to enable auto-lower for certain windows.
 643 You can use that for Emacs windows if you wish, but if you do,
 644 that is beyond the control of Emacs and this command has no effect on it."
 645   (interactive "P")
 646   (if (null arg)
 647       (setq arg
 648             (if (cdr (assq 'auto-lower (frame-parameters (selected-frame))))
 649                 -1 1)))
 650   (modify-frame-parameters (selected-frame)
 651                            (list (cons 'auto-lower (> arg 0)))))
 652
 653 (defun toggle-scroll-bar (arg)
 654   "Toggle whether or not the selected frame has vertical scroll bars.
 655 With arg, turn vertical scroll bars on if and only if arg is positive."
 656   (interactive "P")
 657   (if (null arg)
 658       (setq arg
 659             (if (cdr (assq 'vertical-scroll-bars
 660                            (frame-parameters (selected-frame))))
 661                 -1 1)))
 662   (modify-frame-parameters (selected-frame)
 663                            (list (cons 'vertical-scroll-bars (> arg 0)))))
 664
 665 (defun toggle-horizontal-scroll-bar (arg)
 666   "Toggle whether or not the selected frame has horizontal scroll bars.
 667 With arg, turn horizontal scroll bars on if and only if arg is positive.
 668 Horizontal scroll bars aren't implemented yet."
 669   (interactive "P")
 670   (error "Horizontal scroll bars aren't implemented yet"))
 671
 672 \f
 673 ;;;; Aliases for backward compatibility with Emacs 18.
 674 (defalias 'screen-height 'frame-height)
 675 (defalias 'screen-width 'frame-width)
 676
 677 (defun set-screen-width (cols &optional pretend)
 678   "Obsolete function to change the size of the screen to COLS columns.\n\
 679 Optional second arg non-nil means that redisplay should use COLS columns\n\
 680 but that the idea of the actual width of the frame should not be changed.\n\
 681 This function is provided only for compatibility with Emacs 18; new code\n\
 682 should use `set-frame-width instead'."
 683   (set-frame-width (selected-frame) cols pretend))
 684
 685 (defun set-screen-height (lines &optional pretend)
 686   "Obsolete function to change the height of the screen to LINES lines.\n\
 687 Optional second arg non-nil means that redisplay should use LINES lines\n\
 688 but that the idea of the actual height of the screen should not be changed.\n\
 689 This function is provided only for compatibility with Emacs 18; new code\n\
 690 should use `set-frame-width' instead."
 691   (set-frame-height (selected-frame) lines pretend))
 692
 693 (make-obsolete 'screen-height 'frame-height)
 694 (make-obsolete 'screen-width  'frame-width)
 695 (make-obsolete 'set-screen-width 'set-frame-width)
 696 (make-obsolete 'set-screen-height 'set-frame-height)
 697
 698 \f
 699 ;;;; Key bindings
 700 (defvar ctl-x-5-map (make-sparse-keymap)
 701   "Keymap for frame commands.")
 702 (defalias 'ctl-x-5-prefix ctl-x-5-map)
 703 (define-key ctl-x-map "5" 'ctl-x-5-prefix)
 704
 705 (define-key ctl-x-5-map "2" 'make-frame)
 706 (define-key ctl-x-5-map "0" 'delete-frame)
 707 (define-key ctl-x-5-map "o" 'other-frame)
 708
 709 (provide 'frame)
 710
 711 ;;; frame.el ends here