code.delx.au - gnu-emacs/blob - lisp/faces.el

   1 ;;; faces.el --- Lisp faces
   2
   3 ;; Copyright (C) 1992, 1993, 1994, 1995, 1996, 1998, 1999, 2000, 2001
   4 ;;   Free Software Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;;; Code:
  28
  29 (eval-when-compile
  30   (require 'cl)
  31   ;; Warning suppression -- can't require x-win in batch:
  32   (autoload 'xw-defined-colors "x-win"))
  33
  34 (require 'cus-face)
  35
  36 \f
  37 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  38 ;;; Font selection.
  39 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  40
  41 (defgroup font-selection nil
  42   "Influencing face font selection."
  43   :group 'faces)
  44
  45
  46 (defcustom face-font-selection-order
  47   '(:width :height :weight :slant)
  48   "*A list specifying how face font selection chooses fonts.
  49 Each of the four symbols `:width', `:height', `:weight', and `:slant'
  50 must appear once in the list, and the list must not contain any other
  51 elements.  Font selection tries to find a best matching font for
  52 those face attributes first that appear first in the list.  For
  53 example, if `:slant' appears before `:height', font selection first
  54 tries to find a font with a suitable slant, even if this results in
  55 a font height that isn't optimal."
  56   :tag "Font selection order."
  57   :type '(list symbol symbol symbol symbol)
  58   :group 'font-selection
  59   :set #'(lambda (symbol value)
  60            (set-default symbol value)
  61            (internal-set-font-selection-order value)))
  62
  63
  64 ;; This is defined originally in xfaces.c.
  65 (defcustom face-font-family-alternatives
  66   '(("courier" "fixed")
  67     ("helv" "helvetica" "arial" "fixed"))
  68   "*Alist of alternative font family names.
  69 Each element has the the form (FAMILY ALTERNATIVE1 ALTERNATIVE2 ...).
  70 If fonts of family FAMILY can't be loaded, try ALTERNATIVE1, then
  71 ALTERNATIVE2 etc."
  72   :tag "Alternative font families to try."
  73   :type '(repeat (repeat string))
  74   :group 'font-selection
  75   :set #'(lambda (symbol value)
  76            (set-default symbol value)
  77            (internal-set-alternative-font-family-alist value)))
  78
  79
  80 ;; This is defined originally in xfaces.c.
  81 (defcustom face-font-registry-alternatives
  82   (if (eq system-type 'windows-nt)
  83       '(("gb2312.1980" "gb2312")
  84         ("jisx0208.1990" "jisx0208.1983" "jisx0208.1978")
  85         ("ksc5601.1989" "ksx1001.1992" "ksc5601.1987")
  86         ("muletibetan-2" "muletibetan-0"))
  87     '(("gb2312.1980" "gb2312.80&gb8565.88" "gbk*")
  88       ("jisx0208.1990" "jisx0208.1983" "jisx0208.1978")
  89       ("ksc5601.1989" "ksx1001.1992" "ksc5601.1987")
  90       ("muletibetan-2" "muletibetan-0")))
  91   "*Alist of alternative font registry names.
  92 Each element has the the form (REGISTRY ALTERNATIVE1 ALTERNATIVE2 ...).
  93 If fonts of registry REGISTRY can be loaded, font selection
  94 tries to find a best matching font among all fonts of registry
  95 REGISTRY, ALTERNATIVE1, ALTERNATIVE2, and etc."
  96   :tag "Alternative font registries to try."
  97   :type '(repeat (repeat string))
  98   :version "21.1"
  99   :group 'font-selection
 100   :set #'(lambda (symbol value)
 101            (set-default symbol value)
 102            (internal-set-alternative-font-registry-alist value)))
 103
 104
 105 \f
 106 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 107 ;;; Creation, copying.
 108 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 109
 110
 111 (defun face-list ()
 112   "Return a list of all defined face names."
 113   (mapcar #'car face-new-frame-defaults))
 114
 115
 116 ;;; ### If not frame-local initialize by what X resources?
 117
 118 (defun make-face (face &optional no-init-from-resources)
 119   "Define a new face with name FACE, a symbol.
 120 NO-INIT-FROM-RESOURCES non-nil means don't initialize frame-local
 121 variants of FACE from X resources.  (X resources recognized are found
 122 in the global variable `face-x-resources'.)  If FACE is already known
 123 as a face, leave it unmodified.  Value is FACE."
 124   (interactive "SMake face: ")
 125   (unless (facep face)
 126     ;; Make frame-local faces (this also makes the global one).
 127     (dolist (frame (frame-list))
 128       (internal-make-lisp-face face frame))
 129     ;; Add the face to the face menu.
 130     (when (fboundp 'facemenu-add-new-face)
 131       (facemenu-add-new-face face))
 132     ;; Define frame-local faces for all frames from X resources.
 133     (unless no-init-from-resources
 134       (make-face-x-resource-internal face)))
 135   face)
 136
 137
 138 (defun make-empty-face (face)
 139   "Define a new, empty face with name FACE.
 140 If the face already exists, it is left unmodified.  Value is FACE."
 141   (interactive "SMake empty face: ")
 142   (make-face face 'no-init-from-resources))
 143
 144
 145 (defun copy-face (old-face new-face &optional frame new-frame)
 146   "Define a face just like OLD-FACE, with name NEW-FACE.
 147
 148 If NEW-FACE already exists as a face, it is modified to be like
 149 OLD-FACE.  If it doesn't already exist, it is created.
 150
 151 If the optional argument FRAME is given as a frame,  NEW-FACE is
 152 changed on FRAME only.
 153 If FRAME is t, the frame-independent default specification for OLD-FACE
 154 is copied to NEW-FACE.
 155 If FRAME is nil, copying is done for the frame-independent defaults
 156 and for each existing frame.
 157
 158 If the optional fourth argument NEW-FRAME is given,
 159 copy the information from face OLD-FACE on frame FRAME
 160 to NEW-FACE on frame NEW-FRAME."
 161   (let ((inhibit-quit t))
 162     (if (null frame)
 163         (progn
 164           (dolist (frame (frame-list))
 165             (copy-face old-face new-face frame))
 166           (copy-face old-face new-face t))
 167       (internal-copy-lisp-face old-face new-face frame new-frame))
 168     new-face))
 169
 170
 171 \f
 172 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 173 ;;; Obsolete functions
 174 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 175
 176 ;; The functions in this section are defined because Lisp packages use
 177 ;; them, despite the prefix `internal-' suggesting that they are
 178 ;; private to the face implementation.
 179
 180 (defun internal-find-face (name &optional frame)
 181   "Retrieve the face named NAME.
 182 Return nil if there is no such face.
 183 If the optional argument FRAME is given, this gets the face NAME for
 184 that frame; otherwise, it uses the selected frame.
 185 If FRAME is the symbol t, then the global, non-frame face is returned.
 186 If NAME is already a face, it is simply returned.
 187
 188 This function is defined for compatibility with Emacs 20.2.  It
 189 should not be used anymore."
 190   (facep name))
 191 (make-obsolete 'internal-find-face 'facep "21.1")
 192
 193
 194 (defun internal-get-face (name &optional frame)
 195   "Retrieve the face named NAME; error if there is none.
 196 If the optional argument FRAME is given, this gets the face NAME for
 197 that frame; otherwise, it uses the selected frame.
 198 If FRAME is the symbol t, then the global, non-frame face is returned.
 199 If NAME is already a face, it is simply returned.
 200
 201 This function is defined for compatibility with Emacs 20.2.  It
 202 should not be used anymore."
 203   (or (internal-find-face name frame)
 204       (check-face name)))
 205 (make-obsolete 'internal-get-face "See `facep' and `check-face'." "21.1")
 206
 207 \f
 208 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 209 ;;; Predicates, type checks.
 210 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 211
 212 (defun facep (face)
 213   "Return non-nil if FACE is a face name."
 214   (internal-lisp-face-p face))
 215
 216
 217 (defun check-face (face)
 218   "Signal an error if FACE doesn't name a face.
 219 Value is FACE."
 220   (unless (facep face)
 221     (error "Not a face: %s" face))
 222   face)
 223
 224
 225 ;; The ID returned is not to be confused with the internally used IDs
 226 ;; of realized faces.  The ID assigned to Lisp faces is used to
 227 ;; support faces in display table entries.
 228
 229 (defun face-id (face &optional frame)
 230   "Return the interNal ID of face with name FACE.
 231 If optional argument FRAME is nil or omitted, use the selected frame."
 232   (check-face face)
 233   (get face 'face))
 234
 235
 236 (defun face-equal (face1 face2 &optional frame)
 237   "Non-nil if faces FACE1 and FACE2 are equal.
 238 Faces are considered equal if all their attributes are equal.
 239 If the optional argument FRAME is given, report on face FACE in that frame.
 240 If FRAME is t, report on the defaults for face FACE (for new frames).
 241 If FRAME is omitted or nil, use the selected frame."
 242   (internal-lisp-face-equal-p face1 face2 frame))
 243
 244
 245 (defun face-differs-from-default-p (face &optional frame)
 246   "Non-nil if FACE displays differently from the default face.
 247 If the optional argument FRAME is given, report on face FACE in that frame.
 248 If FRAME is t, report on the defaults for face FACE (for new frames).
 249 If FRAME is omitted or nil, use the selected frame.
 250 A face is considered to be ``the same'' as the default face if it is
 251 actually specified in the same way (equal attributes) or if it is
 252 fully-unspecified, and thus inherits the attributes of any face it
 253 is displayed on top of."
 254   (cond ((eq frame t) (setq frame nil))
 255         ((null frame) (setq frame (selected-frame))))
 256   (let* ((v1 (internal-lisp-face-p face frame))
 257          (n (if v1 (length v1) 0))
 258          (v2 (internal-lisp-face-p 'default frame))
 259          (i 1))
 260     (unless v1
 261       (error "Not a face: %S" face))
 262     (while (and (< i n)
 263                 (or (eq 'unspecified (aref v1 i))
 264                     (equal (aref v1 i) (aref v2 i))))
 265       (setq i (1+ i)))
 266     (< i n)))
 267
 268
 269 (defun face-nontrivial-p (face &optional frame)
 270   "True if face FACE has some non-nil attribute.
 271 If the optional argument FRAME is given, report on face FACE in that frame.
 272 If FRAME is t, report on the defaults for face FACE (for new frames).
 273 If FRAME is omitted or nil, use the selected frame."
 274   (not (internal-lisp-face-empty-p face frame)))
 275
 276
 277 \f
 278 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 279 ;;; Setting face attributes from X resources.
 280 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 281
 282 (defcustom face-x-resources
 283   '((:family (".attributeFamily" . "Face.AttributeFamily"))
 284     (:width (".attributeWidth" . "Face.AttributeWidth"))
 285     (:height (".attributeHeight" . "Face.AttributeHeight"))
 286     (:weight (".attributeWeight" . "Face.AttributeWeight"))
 287     (:slant (".attributeSlant" . "Face.AttributeSlant"))
 288     (:foreground (".attributeForeground" . "Face.AttributeForeground"))
 289     (:background (".attributeBackground" . "Face.AttributeBackground"))
 290     (:overline (".attributeOverline" . "Face.AttributeOverline"))
 291     (:strike-through (".attributeStrikeThrough" . "Face.AttributeStrikeThrough"))
 292     (:box (".attributeBox" . "Face.AttributeBox"))
 293     (:underline (".attributeUnderline" . "Face.AttributeUnderline"))
 294     (:inverse-video (".attributeInverse" . "Face.AttributeInverse"))
 295     (:stipple
 296      (".attributeStipple" . "Face.AttributeStipple")
 297      (".attributeBackgroundPixmap" . "Face.AttributeBackgroundPixmap"))
 298     (:bold (".attributeBold" . "Face.AttributeBold"))
 299     (:italic (".attributeItalic" . "Face.AttributeItalic"))
 300     (:font (".attributeFont" . "Face.AttributeFont"))
 301     (:inherit (".attributeInherit" . "Face.AttributeInherit")))
 302   "*List of X resources and classes for face attributes.
 303 Each element has the form (ATTRIBUTE ENTRY1 ENTRY2...) where ATTRIBUTE is
 304 the name of a face attribute, and each ENTRY is a cons of the form
 305 (RESOURCE . CLASS) with RESOURCE being the resource and CLASS being the
 306 X resource class for the attribute."
 307   :type '(repeat (cons symbol (repeat (cons string string))))
 308   :group 'faces)
 309
 310
 311 (defun set-face-attribute-from-resource (face attribute resource class frame)
 312   "Set FACE's ATTRIBUTE from X resource RESOURCE, class CLASS on FRAME.
 313 Value is the attribute value specified by the resource, or nil
 314 if not present.  This function displays a message if the resource
 315 specifies an invalid attribute."
 316   (let* ((face-name (face-name face))
 317          (value (internal-face-x-get-resource (concat face-name resource)
 318                                               class frame)))
 319     (when value
 320       (condition-case ()
 321           (internal-set-lisp-face-attribute-from-resource
 322            face attribute (downcase value) frame)
 323         (error
 324          (message "Face %s, frame %s: invalid attribute %s %s from X resource"
 325                   face-name frame attribute value))))
 326     value))
 327
 328
 329 (defun set-face-attributes-from-resources (face frame)
 330   "Set attributes of FACE from X resources for FRAME."
 331   (when (memq (framep frame) '(x w32 mac))
 332     (dolist (definition face-x-resources)
 333       (let ((attribute (car definition)))
 334         (dolist (entry (cdr definition))
 335           (set-face-attribute-from-resource face attribute (car entry)
 336                                             (cdr entry) frame))))))
 337
 338
 339 (defun make-face-x-resource-internal (face &optional frame)
 340   "Fill frame-local FACE on FRAME from X resources.
 341 FRAME nil or not specified means do it for all frames."
 342   (if (null frame)
 343       (dolist (frame (frame-list))
 344         (set-face-attributes-from-resources face frame))
 345     (set-face-attributes-from-resources face frame)))
 346
 347
 348 \f
 349 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 350 ;;; Retrieving face attributes.
 351 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 352
 353 (defun face-name (face)
 354   "Return the name of face FACE."
 355   (symbol-name (check-face face)))
 356
 357
 358 (defun face-attribute (face attribute &optional frame)
 359   "Return the value of FACE's ATTRIBUTE on FRAME.
 360 If the optional argument FRAME is given, report on face FACE in that frame.
 361 If FRAME is t, report on the defaults for face FACE (for new frames).
 362 If FRAME is omitted or nil, use the selected frame."
 363   (internal-get-lisp-face-attribute face attribute frame))
 364
 365
 366 (defun face-foreground (face &optional frame)
 367   "Return the foreground color name of FACE, or nil if unspecified.
 368 If the optional argument FRAME is given, report on face FACE in that frame.
 369 If FRAME is t, report on the defaults for face FACE (for new frames).
 370 If FRAME is omitted or nil, use the selected frame."
 371   (let ((value (internal-get-lisp-face-attribute face :foreground frame)))
 372     (if (eq value 'unspecified)
 373         nil
 374       value)))
 375
 376
 377 (defun face-background (face &optional frame)
 378   "Return the background color name of FACE, or nil if unspecified.
 379 If the optional argument FRAME is given, report on face FACE in that frame.
 380 If FRAME is t, report on the defaults for face FACE (for new frames).
 381 If FRAME is omitted or nil, use the selected frame."
 382   (let ((value (internal-get-lisp-face-attribute face :background frame)))
 383     (if (eq value 'unspecified)
 384         nil
 385       value)))
 386
 387
 388 (defun face-stipple (face &optional frame)
 389  "Return the stipple pixmap name of FACE, or nil if unspecified.
 390 If the optional argument FRAME is given, report on face FACE in that frame.
 391 If FRAME is t, report on the defaults for face FACE (for new frames).
 392 If FRAME is omitted or nil, use the selected frame."
 393   (let ((value (internal-get-lisp-face-attribute face :stipple frame)))
 394     (if (eq value 'unspecified)
 395         nil
 396       value)))
 397
 398
 399 (defalias 'face-background-pixmap 'face-stipple)
 400
 401
 402 (defun face-underline-p (face &optional frame)
 403  "Return non-nil if FACE is underlined.
 404 If the optional argument FRAME is given, report on face FACE in that frame.
 405 If FRAME is t, report on the defaults for face FACE (for new frames).
 406 If FRAME is omitted or nil, use the selected frame."
 407  (eq (face-attribute face :underline frame) t))
 408
 409
 410 (defun face-inverse-video-p (face &optional frame)
 411  "Return non-nil if FACE is in inverse video on FRAME.
 412 If the optional argument FRAME is given, report on face FACE in that frame.
 413 If FRAME is t, report on the defaults for face FACE (for new frames).
 414 If FRAME is omitted or nil, use the selected frame."
 415  (eq (face-attribute face :inverse-video frame) t))
 416
 417
 418 (defun face-bold-p (face &optional frame)
 419   "Return non-nil if the font of FACE is bold on FRAME.
 420 If the optional argument FRAME is given, report on face FACE in that frame.
 421 If FRAME is t, report on the defaults for face FACE (for new frames).
 422 If FRAME is omitted or nil, use the selected frame.
 423 Use `face-attribute' for finer control."
 424   (let ((bold (face-attribute face :weight frame)))
 425     (memq bold '(semi-bold bold extra-bold ultra-bold))))
 426
 427
 428 (defun face-italic-p (face &optional frame)
 429   "Return non-nil if the font of FACE is italic on FRAME.
 430 If the optional argument FRAME is given, report on face FACE in that frame.
 431 If FRAME is t, report on the defaults for face FACE (for new frames).
 432 If FRAME is omitted or nil, use the selected frame.
 433 Use `face-attribute' for finer control."
 434   (let ((italic (face-attribute face :slant frame)))
 435     (memq italic '(italic oblique))))
 436
 437
 438 \f
 439 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 440 ;;; Face documentation.
 441 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 442
 443 (defun face-documentation (face)
 444   "Get the documentation string for FACE."
 445   (get face 'face-documentation))
 446
 447
 448 (defun set-face-documentation (face string)
 449   "Set the documentation string for FACE to STRING."
 450   ;; Perhaps the text should go in DOC.
 451   (put face 'face-documentation (purecopy string)))
 452
 453
 454 (defalias 'face-doc-string 'face-documentation)
 455 (defalias 'set-face-doc-string 'set-face-documentation)
 456
 457
 458 \f
 459 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 460 ;; Setting face attributes.
 461 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 462
 463
 464 (defun set-face-attribute (face frame &rest args)
 465   "Set attributes of FACE on FRAME from ARGS.
 466
 467 FRAME nil means change attributes on all frames.  FRAME t means change
 468 the default for new frames (this is done automatically each time an
 469 attribute is changed on all frames).
 470
 471 ARGS must come in pairs ATTRIBUTE VALUE.  ATTRIBUTE must be a valid
 472 face attribute name.  All attributes can be set to `unspecified';
 473 this fact is not further mentioned below.
 474
 475 The following attributes are recognized:
 476
 477 `:family'
 478
 479 VALUE must be a string specifying the font family, e.g. ``courier'',
 480 or a fontset alias name.  If a font family is specified, wild-cards `*'
 481 and `?' are allowed.
 482
 483 `:width'
 484
 485 VALUE specifies the relative proportionate width of the font to use.
 486 It must be one of the symbols `ultra-condensed', `extra-condensed',
 487 `condensed', `semi-condensed', `normal', `semi-expanded', `expanded',
 488 `extra-expanded', or `ultra-expanded'.
 489
 490 `:height'
 491
 492 VALUE must be either an integer specifying the height of the font to use
 493 in 1/10 pt, a floating point number specifying the amount by which to
 494 scale any underlying face, or a function, which is called with the old
 495 height (from the underlying face), and should return the new height.
 496
 497 `:weight'
 498
 499 VALUE specifies the weight of the font to use.  It must be one of the
 500 symbols `ultra-bold', `extra-bold', `bold', `semi-bold', `normal',
 501 `semi-light', `light', `extra-light', `ultra-light'.
 502
 503 `:slant'
 504
 505 VALUE specifies the slant of the font to use.  It must be one of the
 506 symbols `italic', `oblique', `normal', `reverse-italic', or
 507 `reverse-oblique'.
 508
 509 `:foreground', `:background'
 510
 511 VALUE must be a color name, a string.
 512
 513 `:underline'
 514
 515 VALUE specifies whether characters in FACE should be underlined.  If
 516 VALUE is t, underline with foreground color of the face.  If VALUE is
 517 a string, underline with that color.  If VALUE is nil, explicitly
 518 don't underline.
 519
 520 `:overline'
 521
 522 VALUE specifies whether characters in FACE should be overlined.  If
 523 VALUE is t, overline with foreground color of the face.  If VALUE is a
 524 string, overline with that color.  If VALUE is nil, explicitly don't
 525 overline.
 526
 527 `:strike-through'
 528
 529 VALUE specifies whether characters in FACE should be drawn with a line
 530 striking through them.  If VALUE is t, use the foreground color of the
 531 face.  If VALUE is a string, strike-through with that color.  If VALUE
 532 is nil, explicitly don't strike through.
 533
 534 `:box'
 535
 536 VALUE specifies whether characters in FACE should have a box drawn
 537 around them.  If VALUE is nil, explicitly don't draw boxes.  If
 538 VALUE is t, draw a box with lines of width 1 in the foreground color
 539 of the face.  If VALUE is a string, the string must be a color name,
 540 and the box is drawn in that color with a line width of 1.  Otherwise,
 541 VALUE must be a property list of the form `(:line-width WIDTH
 542 :color COLOR :style STYLE)'.  If a keyword/value pair is missing from
 543 the property list, a default value will be used for the value, as
 544 specified below.  WIDTH specifies the width of the lines to draw; it
 545 defaults to 1.  If WIDTH is negative, the absolute value is the width
 546 of the lines, and draw top/bottom lines inside the characters area,
 547 not around it.  COLOR is the name of the color to draw in, default is
 548 the foreground color of the face for simple boxes, and the background
 549 color of the face for 3D boxes.  STYLE specifies whether a 3D box
 550 should be draw.  If STYLE is `released-button', draw a box looking
 551 like a released 3D button.  If STYLE is `pressed-button' draw a box
 552 that appears like a pressed button.  If STYLE is nil, the default if
 553 the property list doesn't contain a style specification, draw a 2D
 554 box.
 555
 556 `:inverse-video'
 557
 558 VALUE specifies whether characters in FACE should be displayed in
 559 inverse video.  VALUE must be one of t or nil.
 560
 561 `:stipple'
 562
 563 If VALUE is a string, it must be the name of a file of pixmap data.
 564 The directories listed in the `x-bitmap-file-path' variable are
 565 searched.  Alternatively, VALUE may be a list of the form (WIDTH
 566 HEIGHT DATA) where WIDTH and HEIGHT are the size in pixels, and DATA
 567 is a string containing the raw bits of the bitmap.  VALUE nil means
 568 explicitly don't use a stipple pattern.
 569
 570 For convenience, attributes `:family', `:width', `:height', `:weight',
 571 and `:slant' may also be set in one step from an X font name:
 572
 573 `:font'
 574
 575 Set font-related face attributes from VALUE.  VALUE must be a valid
 576 XLFD font name.  If it is a font name pattern, the first matching font
 577 will be used.
 578
 579 For compatibility with Emacs 20, keywords `:bold' and `:italic' can
 580 be used to specify that a bold or italic font should be used.  VALUE
 581 must be t or nil in that case.  A value of `unspecified' is not allowed.
 582
 583 `:inherit'
 584
 585 VALUE is the name of a face from which to inherit attributes, or a list
 586 of face names.  Attributes from inherited faces are merged into the face
 587 like an underlying face would be, with higher priority than underlying faces."
 588   (let ((where (if (null frame) 0 frame)))
 589     (setq args (purecopy args))
 590     (while args
 591       (internal-set-lisp-face-attribute face (car args)
 592                                         (purecopy (cadr args))
 593                                         where)
 594       (setq args (cdr (cdr args))))))
 595
 596
 597 (defun make-face-bold (face &optional frame noerror)
 598   "Make the font of FACE be bold, if possible.
 599 FRAME nil or not specified means change face on all frames.
 600 Argument NOERROR is ignored and retained for compatibility.
 601 Use `set-face-attribute' for finer control of the font weight."
 602   (interactive (list (read-face-name "Make which face bold ")))
 603   (set-face-attribute face frame :weight 'bold))
 604
 605
 606 (defun make-face-unbold (face &optional frame noerror)
 607   "Make the font of FACE be non-bold, if possible.
 608 FRAME nil or not specified means change face on all frames.
 609 Argument NOERROR is ignored and retained for compatibility."
 610   (interactive (list (read-face-name "Make which face non-bold ")))
 611   (set-face-attribute face frame :weight 'normal))
 612
 613
 614 (defun make-face-italic (face &optional frame noerror)
 615   "Make the font of FACE be italic, if possible.
 616 FRAME nil or not specified means change face on all frames.
 617 Argument NOERROR is ignored and retained for compatibility.
 618 Use `set-face-attribute' for finer control of the font slant."
 619   (interactive (list (read-face-name "Make which face italic ")))
 620   (set-face-attribute face frame :slant 'italic))
 621
 622
 623 (defun make-face-unitalic (face &optional frame noerror)
 624   "Make the font of FACE be non-italic, if possible.
 625 FRAME nil or not specified means change face on all frames.
 626 Argument NOERROR is ignored and retained for compatibility."
 627   (interactive (list (read-face-name "Make which face non-italic ")))
 628   (set-face-attribute face frame :slant 'normal))
 629
 630
 631 (defun make-face-bold-italic (face &optional frame noerror)
 632   "Make the font of FACE be bold and italic, if possible.
 633 FRAME nil or not specified means change face on all frames.
 634 Argument NOERROR is ignored and retained for compatibility.
 635 Use `set-face-attribute' for finer control of font weight and slant."
 636   (interactive (list (read-face-name "Make which face bold-italic: ")))
 637   (set-face-attribute face frame :weight 'bold :slant 'italic))
 638
 639
 640 (defun set-face-font (face font &optional frame)
 641   "Change font-related attributes of FACE to those of FONT (a string).
 642 FRAME nil or not specified means change face on all frames.
 643 This sets the attributes `:family', `:width', `:height', `:weight',
 644 and `:slant'.  When called interactively, prompt for the face and font."
 645   (interactive (read-face-and-attribute :font))
 646   (set-face-attribute face frame :font font))
 647
 648
 649 ;; Implementation note: Emulating gray background colors with a
 650 ;; stipple pattern is now part of the face realization process, and is
 651 ;; done in C depending on the frame on which the face is realized.
 652
 653 (defun set-face-background (face color &optional frame)
 654   "Change the background color of face FACE to COLOR (a string).
 655 FRAME nil or not specified means change face on all frames.
 656 When called interactively, prompt for the face and color."
 657   (interactive (read-face-and-attribute :background))
 658   (set-face-attribute face frame :background (or color 'unspecified)))
 659
 660
 661 (defun set-face-foreground (face color &optional frame)
 662   "Change the foreground color of face FACE to COLOR (a string).
 663 FRAME nil or not specified means change face on all frames.
 664 When called interactively, prompt for the face and color."
 665   (interactive (read-face-and-attribute :foreground))
 666   (set-face-attribute face frame :foreground (or color 'unspecified)))
 667
 668
 669 (defun set-face-stipple (face stipple &optional frame)
 670   "Change the stipple pixmap of face FACE to STIPPLE.
 671 FRAME nil or not specified means change face on all frames.
 672 STIPPLE should be a string, the name of a file of pixmap data.
 673 The directories listed in the `x-bitmap-file-path' variable are searched.
 674
 675 Alternatively, STIPPLE may be a list of the form (WIDTH HEIGHT DATA)
 676 where WIDTH and HEIGHT are the size in pixels,
 677 and DATA is a string, containing the raw bits of the bitmap."
 678   (interactive (read-face-and-attribute :stipple))
 679   (set-face-attribute face frame :stipple (or stipple 'unspecified)))
 680
 681
 682 (defun set-face-underline (face underline &optional frame)
 683   "Specify whether face FACE is underlined.
 684 UNDERLINE nil means FACE explicitly doesn't underline.
 685 UNDERLINE non-nil means FACE explicitly does underlining
 686 with the same of the foreground color.
 687 If UNDERLINE is a string, underline with the color named UNDERLINE.
 688 FRAME nil or not specified means change face on all frames.
 689 Use `set-face-attribute' to ``unspecify'' underlining."
 690   (interactive
 691    (let ((list (read-face-and-attribute :underline)))
 692      (list (car list) (eq (car (cdr list)) t))))
 693   (set-face-attribute face frame :underline underline))
 694
 695
 696 (defun set-face-underline-p (face underline-p &optional frame)
 697   "Specify whether face FACE is underlined.
 698 UNDERLINE-P nil means FACE explicitly doesn't underline.
 699 UNDERLINE-P non-nil means FACE explicitly does underlining.
 700 FRAME nil or not specified means change face on all frames.
 701 Use `set-face-attribute' to ``unspecify'' underlining."
 702   (interactive
 703    (let ((list (read-face-and-attribute :underline)))
 704      (list (car list) (eq (car (cdr list)) t))))
 705   (set-face-attribute face frame :underline underline-p))
 706
 707
 708 (defun set-face-inverse-video-p (face inverse-video-p &optional frame)
 709   "Specify whether face FACE is in inverse video.
 710 INVERSE-VIDEO-P non-nil means FACE displays explicitly in inverse video.
 711 INVERSE-VIDEO-P nil means FACE explicitly is not in inverse video.
 712 FRAME nil or not specified means change face on all frames.
 713 Use `set-face-attribute' to ``unspecify'' the inverse video attribute."
 714   (interactive
 715    (let ((list (read-face-and-attribute :inverse-video)))
 716      (list (car list) (eq (car (cdr list)) t))))
 717   (set-face-attribute face frame :inverse-video inverse-video-p))
 718
 719
 720 (defun set-face-bold-p (face bold-p &optional frame)
 721   "Specify whether face FACE is bold.
 722 BOLD-P non-nil means FACE should explicitly display bold.
 723 BOLD-P nil means FACE should explicitly display non-bold.
 724 FRAME nil or not specified means change face on all frames.
 725 Use `set-face-attribute' or `modify-face' for finer control."
 726   (if (null bold-p)
 727       (make-face-unbold face frame)
 728     (make-face-bold face frame)))
 729
 730
 731 (defun set-face-italic-p (face italic-p &optional frame)
 732   "Specify whether face FACE is italic.
 733 ITALIC-P non-nil means FACE should explicitly display italic.
 734 ITALIC-P nil means FACE should explicitly display non-italic.
 735 FRAME nil or not specified means change face on all frames.
 736 Use `set-face-attribute' or `modify-face' for finer control."
 737   (if (null italic-p)
 738       (make-face-unitalic face frame)
 739     (make-face-italic face frame)))
 740
 741
 742 (defalias 'set-face-background-pixmap 'set-face-stipple)
 743
 744
 745 (defun invert-face (face &optional frame)
 746   "Swap the foreground and background colors of FACE.
 747 FRAME nil or not specified means change face on all frames.
 748 If FACE specifies neither foreground nor background color,
 749 set its foreground and background to the background and foreground
 750 of the default face.  Value is FACE."
 751   (interactive (list (read-face-name "Invert face ")))
 752   (let ((fg (face-attribute face :foreground frame))
 753         (bg (face-attribute face :background frame)))
 754     (if (or fg bg)
 755         (set-face-attribute face frame :foreground bg :background fg)
 756       (set-face-attribute face frame
 757                           :foreground
 758                           (face-attribute 'default :background frame)
 759                           :background
 760                           (face-attribute 'default :foreground frame))))
 761   face)
 762
 763 \f
 764 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 765 ;;; Interactively modifying faces.
 766 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 767
 768 (defun read-face-name (prompt)
 769   "Read and return a face symbol, prompting with PROMPT.
 770 Value is a symbol naming a known face."
 771   (let ((face-list (mapcar #'(lambda (x) (cons (symbol-name x) x))
 772                            (face-list)))
 773         (def (thing-at-point 'symbol))
 774         face)
 775     (cond ((assoc def face-list)
 776            (setq prompt (concat prompt " (default " def "): ")))
 777           (t (setq def nil)
 778              (setq prompt (concat prompt ": "))))
 779     (while (equal "" (setq face (completing-read
 780                                  prompt face-list nil t nil nil def))))
 781     (intern face)))
 782
 783
 784 (defun face-valid-attribute-values (attribute &optional frame)
 785   "Return valid values for face attribute ATTRIBUTE.
 786 The optional argument FRAME is used to determine available fonts
 787 and colors.  If it is nil or not specified, the selected frame is
 788 used.  Value is an alist of (NAME . VALUE) if ATTRIBUTE expects a value
 789 out of a set of discrete values.  Value is `integerp' if ATTRIBUTE expects
 790 an integer value."
 791   (let ((valid
 792          (case attribute
 793            (:family
 794             (if window-system
 795                 (mapcar #'(lambda (x) (cons (car x) (car x)))
 796                         (x-font-family-list))
 797               ;; Only one font on TTYs.
 798               (list (cons "default" "default"))))
 799            ((:width :weight :slant :inverse-video)
 800             (mapcar #'(lambda (x) (cons (symbol-name x) x))
 801                     (internal-lisp-face-attribute-values attribute)))
 802            ((:underline :overline :strike-through :box)
 803             (if window-system
 804                 (nconc (mapcar #'(lambda (x) (cons (symbol-name x) x))
 805                                (internal-lisp-face-attribute-values attribute))
 806                        (mapcar #'(lambda (c) (cons c c))
 807                                (x-defined-colors frame)))
 808               (mapcar #'(lambda (x) (cons (symbol-name x) x))
 809                       (internal-lisp-face-attribute-values attribute))))
 810            ((:foreground :background)
 811             (mapcar #'(lambda (c) (cons c c))
 812                     (defined-colors frame)))
 813            ((:height)
 814             'integerp)
 815            (:stipple
 816             (and (memq window-system '(x w32 mac))
 817                  (mapcar #'list
 818                          (apply #'nconc
 819                                 (mapcar (lambda (dir)
 820                                           (and (file-readable-p dir)
 821                                                (file-directory-p dir)
 822                                                (directory-files dir)))
 823                                         x-bitmap-file-path)))))
 824            (:inherit
 825             (cons '("none" . nil)
 826                   (mapcar #'(lambda (c) (cons (symbol-name c) c))
 827                           (face-list))))
 828            (t
 829             (error "Internal error")))))
 830     (if (and (listp valid) (not (memq attribute '(:inherit))))
 831         (nconc (list (cons "unspecified" 'unspecified)) valid)
 832       valid)))
 833
 834
 835 (defvar face-attribute-name-alist
 836   '((:family . "font family")
 837     (:width . "character set width")
 838     (:height . "height in 1/10 pt")
 839     (:weight . "weight")
 840     (:slant . "slant")
 841     (:underline . "underline")
 842     (:overline . "overline")
 843     (:strike-through . "strike-through")
 844     (:box . "box")
 845     (:inverse-video . "inverse-video display")
 846     (:foreground . "foreground color")
 847     (:background . "background color")
 848     (:stipple . "background stipple")
 849     (:inherit . "inheritance"))
 850   "An alist of descriptive names for face attributes.
 851 Each element has the form (ATTRIBUTE-NAME . DESCRIPTION) where
 852 ATTRIBUTE-NAME is a face attribute name (a keyword symbol), and
 853 DESCRIPTION is a descriptive name for ATTRIBUTE-NAME.")
 854
 855
 856 (defun face-descriptive-attribute-name (attribute)
 857   "Return a descriptive name for ATTRIBUTE."
 858   (cdr (assq attribute face-attribute-name-alist)))
 859
 860
 861 (defun face-read-string (face default name &optional completion-alist)
 862   "Interactively read a face attribute string value.
 863 FACE is the face whose attribute is read.  If non-nil, DEFAULT is the
 864 default string to return if no new value is entered.  NAME is a
 865 descriptive name of the attribute for prompting.  COMPLETION-ALIST is an
 866 alist of valid values, if non-nil.
 867
 868 Entering nothing accepts the default string DEFAULT.
 869 Value is the new attribute value."
 870   ;; Capitalize NAME (we don't use `capitalize' because that capitalizes
 871   ;; each word in a string separately).
 872   (setq name (concat (upcase (substring name 0 1)) (substring name 1)))
 873   (let* ((completion-ignore-case t)
 874          (value (completing-read
 875                  (if default
 876                      (format "%s for face `%s' (default %s): "
 877                              name face default)
 878                    (format "%s for face `%s': " name face))
 879                  completion-alist)))
 880     (if (equal value "") default value)))
 881
 882
 883 (defun face-read-integer (face default name)
 884   "Interactively read an integer face attribute value.
 885 FACE is the face whose attribute is read.  DEFAULT is the default
 886 value to return if no new value is entered.  NAME is a descriptive
 887 name of the attribute for prompting.  Value is the new attribute value."
 888   (let ((new-value
 889          (face-read-string face
 890                            (format "%s" default)
 891                            name
 892                            (list (cons "unspecified" 'unspecified)))))
 893     (cond ((equal new-value "unspecified")
 894            'unspecified)
 895           ((member new-value '("unspecified-fg" "unspecified-bg"))
 896            new-value)
 897           (t
 898            (string-to-int new-value)))))
 899
 900
 901 (defun read-face-attribute (face attribute &optional frame)
 902   "Interactively read a new value for FACE's ATTRIBUTE.
 903 Optional argument FRAME nil or unspecified means read an attribute value
 904 of a global face.  Value is the new attribute value."
 905   (let* ((old-value (face-attribute face attribute frame))
 906          (attribute-name (face-descriptive-attribute-name attribute))
 907          (valid (face-valid-attribute-values attribute frame))
 908          new-value)
 909     ;; Represent complex attribute values as strings by printing them
 910     ;; out.  Stipple can be a vector; (WIDTH HEIGHT DATA).  Box can be
 911     ;; a list `(:width WIDTH :color COLOR)' or `(:width WIDTH :shadow
 912     ;; SHADOW)'.
 913     (when (and (or (eq attribute :stipple)
 914                    (eq attribute :box))
 915                (or (consp old-value)
 916                    (vectorp old-value)))
 917       (setq old-value (prin1-to-string old-value)))
 918     (cond ((listp valid)
 919            (let ((default
 920                    (or (car (rassoc old-value valid))
 921                        (format "%s" old-value))))
 922              (setq new-value
 923                    (face-read-string face default attribute-name valid))
 924              (if (equal new-value default)
 925                  ;; Nothing changed, so don't bother with all the stuff
 926                  ;; below.  In particular, this avoids a non-tty color
 927                  ;; from being canonicalized for a tty when the user
 928                  ;; just uses the default.
 929                  (setq new-value old-value)
 930                ;; Terminal frames can support colors that don't appear
 931                ;; explicitly in VALID, using color approximation code
 932                ;; in tty-colors.el.
 933                (when (and (memq attribute '(:foreground :background))
 934                           (not (memq window-system '(x w32 mac)))
 935                           (not (member new-value
 936                                        '("unspecified"
 937                                          "unspecified-fg" "unspecified-bg"))))
 938                  (setq new-value (car (tty-color-desc new-value frame))))
 939                (when (assoc new-value valid)
 940                  (setq new-value (cdr (assoc new-value valid)))))))
 941           ((eq valid 'integerp)
 942            (setq new-value (face-read-integer face old-value attribute-name)))
 943           (t (error "Internal error")))
 944     ;; Convert stipple and box value text we read back to a list or
 945     ;; vector if it looks like one.  This makes the assumption that a
 946     ;; pixmap file name won't start with an open-paren.
 947     (when (and (or (eq attribute :stipple)
 948                    (eq attribute :box))
 949                (stringp new-value)
 950                (string-match "^[[(]" new-value))
 951       (setq new-value (read new-value)))
 952     new-value))
 953
 954
 955 (defun read-face-font (face &optional frame)
 956   "Read the name of a font for FACE on FRAME.
 957 If optional argument FRAME Is nil or omitted, use the selected frame."
 958   (let ((completion-ignore-case t))
 959     (completing-read (format "Set font attributes of face `%s' from font: " face)
 960                      (mapcar 'list (x-list-fonts "*" nil frame)))))
 961
 962
 963 (defun read-all-face-attributes (face &optional frame)
 964   "Interactively read all attributes for FACE.
 965 If optional argument FRAME Is nil or omitted, use the selected frame.
 966 Value is a property list of attribute names and new values."
 967   (let (result)
 968     (dolist (attribute face-attribute-name-alist result)
 969       (setq result (cons (car attribute)
 970                          (cons (read-face-attribute face (car attribute) frame)
 971                                result))))))
 972
 973 (defun modify-face (&optional face foreground background stipple
 974                               bold-p italic-p underline-p inverse-p frame)
 975   "Modify attributes of faces interactively.
 976 If optional argument FRAME is nil or omitted, modify the face used
 977 for newly created frame, i.e. the global face.
 978 For non-interactive use, `set-face-attribute' is preferred.
 979 When called from elisp, if FACE is nil, all arguments but FRAME are ignored
 980 and the face and its settings are obtained by querying the user."
 981   (interactive)
 982   (if face
 983       (set-face-attribute face frame
 984                           :foreground (or foreground 'unspecified)
 985                           :background (or background 'unspecified)
 986                           :stipple stipple
 987                           :bold bold-p
 988                           :italic italic-p
 989                           :underline underline-p
 990                           :inverse-video inverse-p)
 991     (setq face (read-face-name "Modify face"))
 992     (apply #'set-face-attribute face frame
 993            (read-all-face-attributes face frame))))
 994
 995 (defun read-face-and-attribute (attribute &optional frame)
 996   "Read face name and face attribute value.
 997 ATTRIBUTE is the attribute whose new value is read.
 998 FRAME nil or unspecified means read attribute value of global face.
 999 Value is a list (FACE NEW-VALUE) where FACE is the face read
1000 \(a symbol), and NEW-VALUE is value read."
1001   (cond ((eq attribute :font)
1002          (let* ((prompt "Set font-related attributes of face")
1003                 (face (read-face-name prompt))
1004                 (font (read-face-font face frame)))
1005            (list face font)))
1006         (t
1007          (let* ((attribute-name (face-descriptive-attribute-name attribute))
1008                 (prompt (format "Set %s of face" attribute-name))
1009                 (face (read-face-name prompt))
1010                 (new-value (read-face-attribute face attribute frame)))
1011            (list face new-value)))))
1012
1013
1014 \f
1015 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1016 ;;; Listing faces.
1017 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1018
1019 (defvar list-faces-sample-text
1020   "abcdefghijklmnopqrstuvwxyz ABCDEFGHIJKLMNOPQRSTUVWXYZ"
1021   "*Text string to display as the sample text for `list-faces-display'.")
1022
1023
1024 ;; The name list-faces would be more consistent, but let's avoid a
1025 ;; conflict with Lucid, which uses that name differently.
1026
1027 (defun list-faces-display ()
1028   "List all faces, using the same sample text in each.
1029 The sample text is a string that comes from the variable
1030 `list-faces-sample-text'."
1031   (interactive)
1032   (let ((faces (sort (face-list) #'string-lessp))
1033         (face nil)
1034         (frame (selected-frame))
1035         disp-frame window face-name)
1036     (with-output-to-temp-buffer "*Faces*"
1037       (save-excursion
1038         (set-buffer standard-output)
1039         (setq truncate-lines t)
1040         (insert
1041          (substitute-command-keys
1042           (concat
1043            "Use "
1044            (if (display-mouse-p) "\\[help-follow-mouse] or ")
1045            "\\[help-follow] on a face name to customize it\n"
1046            "or on its sample text for a decription of the face.\n\n")))
1047         (setq help-xref-stack nil)
1048         (while faces
1049           (setq face (car faces))
1050           (setq faces (cdr faces))
1051           (setq face-name (symbol-name face))
1052           (insert (format "%25s " face-name))
1053           ;; Hyperlink to a customization buffer for the face.  Using
1054           ;; the help xref mechanism may not be the best way.
1055           (save-excursion
1056             (save-match-data
1057               (search-backward face-name)
1058               (help-xref-button 0 'help-customize-face face-name)))
1059           (let ((beg (point)))
1060             (insert list-faces-sample-text)
1061             ;; Hyperlink to a help buffer for the face.
1062             (save-excursion
1063               (save-match-data
1064                 (search-backward list-faces-sample-text)
1065                 (help-xref-button 0 'help-face face)))
1066             (insert "\n")
1067             (put-text-property beg (1- (point)) 'face face)
1068             ;; If the sample text has multiple lines, line up all of them.
1069             (goto-char beg)
1070             (forward-line 1)
1071             (while (not (eobp))
1072               (insert "                          ")
1073               (forward-line 1))))
1074         (goto-char (point-min)))
1075       (print-help-return-message))
1076     ;; If the *Faces* buffer appears in a different frame,
1077     ;; copy all the face definitions from FRAME,
1078     ;; so that the display will reflect the frame that was selected.
1079     (setq window (get-buffer-window (get-buffer "*Faces*") t))
1080     (setq disp-frame (if window (window-frame window)
1081                        (car (frame-list))))
1082     (or (eq frame disp-frame)
1083         (let ((faces (face-list)))
1084           (while faces
1085             (copy-face (car faces) (car faces) frame disp-frame)
1086             (setq faces (cdr faces)))))))
1087
1088
1089 (defun describe-face (face &optional frame)
1090   "Display the properties of face FACE on FRAME.
1091 If the optional argument FRAME is given, report on face FACE in that frame.
1092 If FRAME is t, report on the defaults for face FACE (for new frames).
1093 If FRAME is omitted or nil, use the selected frame."
1094   (interactive (list (read-face-name "Describe face")))
1095   (let* ((attrs '((:family . "Family")
1096                   (:width . "Width")
1097                   (:height . "Height")
1098                   (:weight . "Weight")
1099                   (:slant . "Slant")
1100                   (:foreground . "Foreground")
1101                   (:background . "Background")
1102                   (:underline . "Underline")
1103                   (:overline . "Overline")
1104                   (:strike-through . "Strike-through")
1105                   (:box . "Box")
1106                   (:inverse-video . "Inverse")
1107                   (:stipple . "Stipple")
1108                   (:font . "Font or fontset")
1109                   (:inherit . "Inherit")))
1110         (max-width (apply #'max (mapcar #'(lambda (x) (length (cdr x)))
1111                                         attrs))))
1112     (require 'help-mode)
1113     (with-output-to-temp-buffer (help-buffer)
1114       (save-excursion
1115         (set-buffer standard-output)
1116         (dolist (a attrs)
1117           (let ((attr (face-attribute face (car a) frame)))
1118             (insert (make-string (- max-width (length (cdr a))) ?\ )
1119                     (cdr a) ": " (format "%s" attr) "\n")))
1120         (insert "\nDocumentation:\n\n"
1121                 (or (face-documentation face)
1122                     "not documented as a face."))
1123         (let ((customize-label "customize"))
1124           (terpri)
1125           (terpri)
1126           (princ (concat "You can " customize-label " this face."))
1127           (with-current-buffer standard-output
1128             (save-excursion
1129               (re-search-backward
1130                (concat "\\(" customize-label "\\)") nil t)
1131               (help-xref-button 1 'help-customize-face face)))))
1132       (print-help-return-message)
1133       (help-setup-xref (list #'describe-face face) (interactive-p)))))
1134
1135 \f
1136 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1137 ;;; Face specifications (defface).
1138 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1139
1140 ;; Parameter FRAME Is kept for call compatibility to with previous
1141 ;; face implementation.
1142
1143 (defun face-attr-construct (face &optional frame)
1144   "Return a defface-style attribute list for FACE on FRAME.
1145 Value is a property list of pairs ATTRIBUTE VALUE for all specified
1146 face attributes of FACE where ATTRIBUTE is the attribute name and
1147 VALUE is the specified value of that attribute."
1148   (let (result)
1149     (dolist (entry face-attribute-name-alist result)
1150       (let* ((attribute (car entry))
1151              (value (face-attribute face attribute)))
1152         (unless (eq value 'unspecified)
1153           (setq result (nconc (list attribute value) result)))))))
1154
1155
1156 (defun face-spec-set-match-display (display frame)
1157   "Non-nil if DISPLAY matches FRAME.
1158 DISPLAY is part of a spec such as can be used in `defface'.
1159 If FRAME is nil, the current FRAME is used."
1160   (let* ((conjuncts display)
1161          conjunct req options
1162          ;; t means we have succeeded against all the conjuncts in
1163          ;; DISPLAY that have been tested so far.
1164          (match t))
1165     (if (eq conjuncts t)
1166         (setq conjuncts nil))
1167     (while (and conjuncts match)
1168       (setq conjunct (car conjuncts)
1169             conjuncts (cdr conjuncts)
1170             req (car conjunct)
1171             options (cdr conjunct)
1172             match (cond ((eq req 'type)
1173                          (or (memq window-system options)
1174                              ;; FIXME: This should be revisited to use
1175                              ;; display-graphic-p, provided that the
1176                              ;; color selection depends on the number
1177                              ;; of supported colors, and all defface's
1178                              ;; are changed to look at number of colors
1179                              ;; instead of (type graphic) etc.
1180                              (and (null window-system)
1181                                   (memq 'tty options))
1182                              (and (memq 'motif options)
1183                                   (featurep 'motif))
1184                              (and (memq 'lucid options)
1185                                   (featurep 'x-toolkit)
1186                                   (not (featurep 'motif)))
1187                              (and (memq 'x-toolkit options)
1188                                   (featurep 'x-toolkit))))
1189                         ((eq req 'class)
1190                          (memq (frame-parameter frame 'display-type) options))
1191                         ((eq req 'background)
1192                          (memq (frame-parameter frame 'background-mode)
1193                                options))
1194                         (t (error "Unknown req `%S' with options `%S'"
1195                                   req options)))))
1196     match))
1197
1198
1199 (defun face-spec-choose (spec &optional frame)
1200   "Choose the proper attributes for FRAME, out of SPEC.
1201 If SPEC is nil, return nil."
1202   (unless frame
1203     (setq frame (selected-frame)))
1204   (let ((tail spec)
1205         result)
1206     (while tail
1207       (let* ((entry (pop tail))
1208              (display (car entry))
1209              (attrs (cdr entry)))
1210         (when (face-spec-set-match-display display frame)
1211           (setq result (if (listp (car attrs))
1212                            ;; Old-style entry, the attribute list is the
1213                            ;; first element.
1214                            (car attrs)
1215                          attrs)
1216                 tail nil))))
1217     result))
1218
1219
1220 (defun face-spec-reset-face (face &optional frame)
1221   "Reset all attributes of FACE on FRAME to unspecified."
1222   (let ((attrs face-attribute-name-alist))
1223     (while attrs
1224       (let ((attr-and-name (car attrs)))
1225         (set-face-attribute face frame (car attr-and-name) 'unspecified))
1226       (setq attrs (cdr attrs)))))
1227
1228
1229 (defun face-spec-set (face spec &optional frame)
1230   "Set FACE's attributes according to the first matching entry in SPEC.
1231 FRAME is the frame whose frame-local face is set.  FRAME nil means
1232 do it on all frames.  See `defface' for information about SPEC.
1233 If SPEC is nil, do nothing."
1234   (let ((attrs (face-spec-choose spec frame)))
1235     (when attrs
1236       (face-spec-reset-face face frame))
1237     (while attrs
1238       (let ((attribute (car attrs))
1239             (value (car (cdr attrs))))
1240         ;; Support some old-style attribute names and values.
1241         (case attribute
1242           (:bold (setq attribute :weight value (if value 'bold 'normal)))
1243           (:italic (setq attribute :slant value (if value 'italic 'normal)))
1244           ((:foreground :background)
1245            ;; Compatibility with 20.x.  Some bogus face specs seem to
1246            ;; exist containing things like `:foreground nil'.
1247            (if (null value) (setq value 'unspecified)))
1248           (t (unless (assq attribute face-x-resources)
1249                (setq attribute nil))))
1250         (when attribute
1251           (set-face-attribute face frame attribute value)))
1252       (setq attrs (cdr (cdr attrs))))))
1253
1254
1255 (defun face-attr-match-p (face attrs &optional frame)
1256   "Return t if attributes of FACE match values in plist ATTRS.
1257 Optional parameter FRAME is the frame whose definition of FACE
1258 is used.  If nil or omitted, use the selected frame."
1259   (unless frame
1260     (setq frame (selected-frame)))
1261   (let ((list face-attribute-name-alist)
1262         (match t))
1263     (while (and match (not (null list)))
1264       (let* ((attr (car (car list)))
1265              (specified-value
1266               (if (plist-member attrs attr)
1267                   (plist-get attrs attr)
1268                 'unspecified))
1269              (value-now (face-attribute face attr frame)))
1270         (setq match (equal specified-value value-now))
1271         (setq list (cdr list))))
1272     match))
1273
1274 (defun face-spec-match-p (face spec &optional frame)
1275   "Return t if FACE, on FRAME, matches what SPEC says it should look like."
1276   (face-attr-match-p face (face-spec-choose spec frame) frame))
1277
1278 (defsubst face-default-spec (face)
1279   "Return the default face-spec for FACE, ignoring any user customization.
1280 If there is no default for FACE, return nil."
1281   (get face 'face-defface-spec))
1282
1283 (defsubst face-user-default-spec (face)
1284   "Return the user's customized face-spec for FACE, or the default if none.
1285 If there is neither a user setting nor a default for FACE, return nil."
1286   (or (get face 'saved-face)
1287       (face-default-spec face)))
1288
1289 \f
1290 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1291 ;;; Frame-type independent color support.
1292 ;;; We keep the old x-* names as aliases for back-compatibility.
1293 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1294
1295 (defun defined-colors (&optional frame)
1296   "Return a list of colors supported for a particular frame.
1297 The argument FRAME specifies which frame to try.
1298 The value may be different for frames on different display types.
1299 If FRAME doesn't support colors, the value is nil."
1300   (if (memq (framep (or frame (selected-frame))) '(x w32 mac))
1301       (xw-defined-colors frame)
1302     (mapcar 'car (tty-color-alist frame))))
1303 (defalias 'x-defined-colors 'defined-colors)
1304
1305 (defun color-defined-p (color &optional frame)
1306   "Return non-nil if color COLOR is supported on frame FRAME.
1307 If FRAME is omitted or nil, use the selected frame.
1308 If COLOR is the symbol `unspecified' or one of the strings
1309 \"unspecified-fg\" or \"unspecified-bg\", the value is nil."
1310   (if (member color '(unspecified "unspecified-bg" "unspecified-fg"))
1311       nil
1312     (if (member (framep (or frame (selected-frame))) '(x w32 mac))
1313         (xw-color-defined-p color frame)
1314       (numberp (tty-color-translate color frame)))))
1315 (defalias 'x-color-defined-p 'color-defined-p)
1316
1317 (defun color-values (color &optional frame)
1318   "Return a description of the color named COLOR on frame FRAME.
1319 The value is a list of integer RGB values--\(RED GREEN BLUE\).
1320 These values appear to range from 0 65535; white is \(65535 65535 65535\).
1321 If FRAME is omitted or nil, use the selected frame.
1322 If FRAME cannot display COLOR, the value is nil.
1323 If COLOR is the symbol `unspecified' or one of the strings
1324 \"unspecified-fg\" or \"unspecified-bg\", the value is nil."
1325   (if (member color '(unspecified "unspecified-fg" "unspecified-bg"))
1326       nil
1327     (if (memq (framep (or frame (selected-frame))) '(x w32 mac))
1328         (xw-color-values color frame)
1329       (tty-color-values color frame))))
1330 (defalias 'x-color-values 'color-values)
1331
1332 (defun display-color-p (&optional display)
1333   "Return t if DISPLAY supports color.
1334 The optional argument DISPLAY specifies which display to ask about.
1335 DISPLAY should be either a frame or a display name (a string).
1336 If omitted or nil, that stands for the selected frame's display."
1337   (if (memq (framep-on-display display) '(x w32 mac))
1338       (xw-display-color-p display)
1339     (tty-display-color-p display)))
1340 (defalias 'x-display-color-p 'display-color-p)
1341
1342 (defun display-grayscale-p (&optional display)
1343   "Return non-nil if frames on DISPLAY can display shades of gray."
1344   (let ((frame-type (framep-on-display display)))
1345     (cond
1346      ((memq frame-type '(x w32 mac))
1347       (x-display-grayscale-p display))
1348      (t
1349       (> (tty-color-gray-shades display) 2)))))
1350
1351 \f
1352 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1353 ;;; Background mode.
1354 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1355
1356 (defcustom frame-background-mode nil
1357   "*The brightness of the background.
1358 Set this to the symbol `dark' if your background color is dark, `light' if
1359 your background is light, or nil (default) if you want Emacs to
1360 examine the brightness for you.  Don't set this variable with `setq';
1361 this won't have the expected effect."
1362   :group 'faces
1363   :set #'(lambda (var value)
1364            (set-default var value)
1365            (mapc 'frame-set-background-mode (frame-list)))
1366   :initialize 'custom-initialize-changed
1367   :type '(choice (choice-item dark)
1368                  (choice-item light)
1369                  (choice-item :tag "default" nil)))
1370
1371
1372 (defun frame-set-background-mode (frame)
1373   "Set up display-dependent faces on FRAME.
1374 Display-dependent faces are those which have different definitions
1375 according to the `background-mode' and `display-type' frame parameters."
1376   (let* ((bg-resource
1377           (and window-system
1378                (x-get-resource ".backgroundMode" "BackgroundMode")))
1379          (bg-color (frame-parameter frame 'background-color))
1380          (bg-mode
1381           (cond (frame-background-mode)
1382                 (bg-resource
1383                  (intern (downcase bg-resource)))
1384                 ((and (null window-system) (null bg-color))
1385                  ;; No way to determine this automatically (?).
1386                  'dark)
1387                 ;; Unspecified frame background color can only happen
1388                 ;; on tty's.
1389                 ((member bg-color '(unspecified "unspecified-bg"))
1390                  'dark)
1391                 ((equal bg-color "unspecified-fg") ; inverted colors
1392                  'light)
1393                 ((>= (apply '+ (x-color-values bg-color frame))
1394                     ;; Just looking at the screen, colors whose
1395                     ;; values add up to .6 of the white total
1396                     ;; still look dark to me.
1397                     (* (apply '+ (x-color-values "white" frame)) .6))
1398                  'light)
1399                 (t 'dark)))
1400          (display-type
1401           (cond ((null window-system)
1402                  (if (tty-display-color-p frame) 'color 'mono))
1403                 ((x-display-color-p frame)
1404                  'color)
1405                 ((x-display-grayscale-p frame)
1406                  'grayscale)
1407                 (t 'mono)))
1408          (old-bg-mode
1409           (frame-parameter frame 'background-mode))
1410          (old-display-type
1411           (frame-parameter frame 'display-type)))
1412
1413     (unless (and (eq bg-mode old-bg-mode) (eq display-type old-display-type))
1414       (let ((locally-modified-faces nil))
1415         ;; Before modifying the frame parameters, we collect a list of
1416         ;; faces that don't match what their face-spec says they should
1417         ;; look like; we then avoid changing these faces below.  A
1418         ;; negative list is used on the assumption that most faces will
1419         ;; be unmodified, so we can avoid consing in the common case.
1420         (dolist (face (face-list))
1421           (when (not (face-spec-match-p face
1422                                         (face-user-default-spec face)
1423                                         (selected-frame)))
1424             (push face locally-modified-faces)))
1425         ;; Now change to the new frame parameters
1426         (modify-frame-parameters frame
1427                                  (list (cons 'background-mode bg-mode)
1428                                        (cons 'display-type display-type)))
1429         ;; For all named faces, choose face specs matching the new frame
1430         ;; parameters, unless they have been locally modified.
1431         (dolist (face (face-list))
1432           (unless (memq face locally-modified-faces)
1433             (face-spec-set face (face-user-default-spec face) frame)))))))
1434
1435 \f
1436 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1437 ;;; Frame creation.
1438 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1439
1440 (defun x-handle-named-frame-geometry (parameters)
1441   "Add geometry parameters for a named frame to parameter list PARAMETERS.
1442 Value is the new parameter list."
1443   (let* ((name (or (cdr (assq 'name parameters))
1444                    (cdr (assq 'name default-frame-alist))))
1445          (x-resource-name name)
1446          (res-geometry (if name (x-get-resource "geometry" "Geometry"))))
1447     (when res-geometry
1448       (let ((parsed (x-parse-geometry res-geometry)))
1449         ;; If the resource specifies a position, call the position
1450         ;; and size "user-specified".
1451         (when (or (assq 'top parsed)
1452                   (assq 'left parsed))
1453           (setq parsed (append '((user-position . t) (user-size . t)) parsed)))
1454         ;; Put the geometry parameters at the end.  Copy
1455         ;; default-frame-alist so that they go after it.
1456         (setq parameters (append parameters default-frame-alist parsed))))
1457     parameters))
1458
1459
1460 (defun x-handle-reverse-video (frame parameters)
1461   "Handle the reverse-video frame parameter and X resource.
1462 `x-create-frame' does not handle this one."
1463   (when (cdr (or (assq 'reverse parameters)
1464                  (assq 'reverse default-frame-alist)
1465                  (let ((resource (x-get-resource "reverseVideo"
1466                                                  "ReverseVideo")))
1467                    (if resource
1468                        (cons nil (member (downcase resource)
1469                                          '("on" "true")))))))
1470       (let* ((params (frame-parameters frame))
1471              (bg (cdr (assq 'foreground-color params)))
1472              (fg (cdr (assq 'background-color params))))
1473         (modify-frame-parameters frame
1474                                  (list (cons 'foreground-color fg)
1475                                        (cons 'background-color bg)))
1476         (if (equal bg (cdr (assq 'border-color params)))
1477             (modify-frame-parameters frame
1478                                      (list (cons 'border-color fg))))
1479         (if (equal bg (cdr (assq 'mouse-color params)))
1480             (modify-frame-parameters frame
1481                                      (list (cons 'mouse-color fg))))
1482         (if (equal bg (cdr (assq 'cursor-color params)))
1483             (modify-frame-parameters frame
1484                                      (list (cons 'cursor-color fg)))))))
1485
1486
1487 (defun x-create-frame-with-faces (&optional parameters)
1488   "Create a frame from optional frame parameters PARAMETERS.
1489 Parameters not specified by PARAMETERS are taken from
1490 `default-frame-alist'.  If PARAMETERS specify a frame name,
1491 handle X geometry resources for that name.  If either PARAMETERS
1492 or `default-frame-alist' contains a `reverse' parameter, or
1493 the X resource ``reverseVideo'' is present, handle that.
1494 Value is the new frame created."
1495   (setq parameters (x-handle-named-frame-geometry parameters))
1496   (let ((visibility-spec (assq 'visibility parameters))
1497         (frame-list (frame-list))
1498         (frame (x-create-frame (cons '(visibility . nil) parameters)))
1499         success)
1500     (unwind-protect
1501         (progn
1502           (x-handle-reverse-video frame parameters)
1503           (frame-set-background-mode frame)
1504           (face-set-after-frame-default frame)
1505           (if (or (null frame-list) (null visibility-spec))
1506               (make-frame-visible frame)
1507             (modify-frame-parameters frame (list visibility-spec)))
1508           (setq success t))
1509       (unless success
1510         (delete-frame frame)))
1511     frame))
1512
1513
1514 (defun face-set-after-frame-default (frame)
1515   "Set frame-local faces of FRAME from face specs and resources.
1516 Initialize colors of certain faces from frame parameters."
1517   (dolist (face (face-list))
1518     (face-spec-set face (face-user-default-spec face) frame)
1519     (internal-merge-in-global-face face frame)
1520     (when (and (memq window-system '(x w32 mac))
1521                (or (not (boundp 'inhibit-default-face-x-resources))
1522                    (not (eq face 'default))))
1523       (make-face-x-resource-internal face frame)))
1524
1525   ;; Initialize attributes from frame parameters.
1526   (let ((params '((foreground-color default :foreground)
1527                   (background-color default :background)
1528                   (border-color border :background)
1529                   (cursor-color cursor :background)
1530                   (scroll-bar-foreground scroll-bar :foreground)
1531                   (scroll-bar-background scroll-bar :background)
1532                   (mouse-color mouse :background))))
1533     (dolist (param params)
1534       (let ((frame-param (frame-parameter frame (nth 0 param)))
1535             (face (nth 1 param))
1536             (attr (nth 2 param)))
1537         (when (and frame-param
1538                    ;; Don't override face attributes explicitly
1539                    ;; specified for new frames.
1540                    (eq (face-attribute face attr t) 'unspecified))
1541           (set-face-attribute face frame attr frame-param))))))
1542
1543
1544 (defun tty-handle-reverse-video (frame parameters)
1545   "Handle the reverse-video frame parameter for terminal frames."
1546   (when (cdr (or (assq 'reverse parameters)
1547                  (assq 'reverse default-frame-alist)))
1548     (let* ((params (frame-parameters frame))
1549            (bg (cdr (assq 'foreground-color params)))
1550            (fg (cdr (assq 'background-color params))))
1551       (modify-frame-parameters frame
1552                                (list (cons 'foreground-color fg)
1553                                      (cons 'background-color bg)))
1554       (if (equal bg (cdr (assq 'mouse-color params)))
1555           (modify-frame-parameters frame
1556                                    (list (cons 'mouse-color fg))))
1557       (if (equal bg (cdr (assq 'cursor-color params)))
1558           (modify-frame-parameters frame
1559                                    (list (cons 'cursor-color fg)))))))
1560
1561
1562 (defun tty-create-frame-with-faces (&optional parameters)
1563   "Create a frame from optional frame parameters PARAMETERS.
1564 Parameters not specified by PARAMETERS are taken from
1565 `default-frame-alist'.  If either PARAMETERS or `default-frame-alist'
1566 contains a `reverse' parameter, handle that.  Value is the new frame
1567 created."
1568   (let ((frame (make-terminal-frame parameters))
1569         success)
1570     (unwind-protect
1571         (progn
1572           (tty-handle-reverse-video frame (frame-parameters frame))
1573           (frame-set-background-mode frame)
1574           (face-set-after-frame-default frame)
1575           (setq success t))
1576       (unless success
1577         (delete-frame frame)))
1578     frame))
1579
1580
1581 ;; Called from C function init_display to initialize faces of the
1582 ;; dumped terminal frame on startup.
1583
1584 (defun tty-set-up-initial-frame-faces ()
1585   (let ((frame (selected-frame)))
1586     (frame-set-background-mode frame)
1587     (face-set-after-frame-default frame)))
1588
1589
1590
1591 \f
1592 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1593 ;;; Compatiblity with 20.2
1594 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1595
1596 ;; Update a frame's faces when we change its default font.
1597
1598 (defalias 'frame-update-faces 'ignore)
1599 (make-obsolete 'frame-update-faces "No longer necessary" "21.1")
1600
1601 ;; Update the colors of FACE, after FRAME's own colors have been
1602 ;; changed.
1603
1604 (defalias 'frame-update-face-colors 'frame-set-background-mode)
1605 (make-obsolete 'frame-update-face-colors 'frame-set-background-mode "21.1")
1606
1607 \f
1608 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1609 ;;; Standard faces.
1610 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1611
1612 (defgroup basic-faces nil
1613   "The standard faces of Emacs."
1614   :group 'faces)
1615
1616
1617 (defface default
1618   '((t nil))
1619   "Basic default face."
1620   :group 'basic-faces)
1621
1622
1623 (defface mode-line
1624   '((((type x w32 mac) (class color))
1625      (:box (:line-width -1 :style released-button)
1626            :background "grey75" :foreground "black"))
1627     (t
1628      (:inverse-video t)))
1629   "Basic mode line face."
1630   :version "21.1"
1631   :group 'modeline
1632   :group 'basic-faces)
1633
1634 ;; Make `modeline' an alias for `mode-line', for compatibility.
1635 (put 'modeline 'face-alias 'mode-line)
1636
1637 (defface header-line
1638   '((((type tty))
1639      ;; This used to be `:inverse-video t', but that doesn't look very
1640      ;; good when combined with inverse-video mode-lines and multiple
1641      ;; windows.  Underlining looks better, and is more consistent with
1642      ;; the window-system face variants, which deemphasize the
1643      ;; header-line in relation to the mode-line face.  If a terminal
1644      ;; can't underline, then the header-line will end up without any
1645      ;; highlighting; this may be too confusing in general, although it
1646      ;; happens to look good with the only current use of header-lines,
1647      ;; the info browser. XXX
1648      :underline t)
1649     (((class color grayscale) (background light))
1650      :inherit mode-line
1651      :background "grey90" :foreground "grey20"
1652      :box nil)
1653     (((class color grayscale) (background dark))
1654      :inherit mode-line
1655      :background "grey20" :foreground "grey90"
1656      :box nil)
1657     (((class mono) (background light))
1658      :inherit mode-line
1659      :background "white" :foreground "black"
1660      :inverse-video nil
1661      :box nil
1662      :underline t)
1663     (((class mono) (background dark))
1664      :inherit mode-line
1665      :background "black" :foreground "white"
1666      :inverse-video nil
1667      :box nil
1668      :underline t)
1669     (t
1670      :inverse-video t))
1671   "Basic header-line face."
1672   :version "21.1"
1673   :group 'basic-faces)
1674
1675
1676 (defface tool-bar
1677   '((((type x w32 mac) (class color))
1678      (:box (:line-width 1 :style released-button)
1679            :background "grey75" :foreground "black"))
1680     (((type x) (class mono))
1681      (:box (:line-width 1 :style released-button)
1682            :background "grey" :foreground "black"))
1683     (t
1684      ()))
1685   "Basic tool-bar face."
1686   :version "21.1"
1687   :group 'basic-faces)
1688
1689
1690 (defface region
1691   '((((type tty) (class color))
1692      (:background "blue" :foreground "white"))
1693     (((type tty) (class mono))
1694      (:inverse-video t))
1695     (((class color) (background dark))
1696      (:background "blue3"))
1697     (((class color) (background light))
1698      (:background "lightgoldenrod2"))
1699     (t (:background "gray")))
1700   "Basic face for highlighting the region."
1701   :version "21.1"
1702   :group 'basic-faces)
1703
1704
1705 (defface fringe
1706   '((((class color) (background light))
1707        (:background "grey95"))
1708       (((class color) (background dark))
1709        (:background "grey10"))
1710       (t
1711        (:background "gray")))
1712   "Basic face for the fringes to the left and right of windows under X."
1713   :version "21.1"
1714   :group 'frames
1715   :group 'basic-faces)
1716
1717
1718 (defface scroll-bar '()
1719   "Basic face for the scroll bar colors under X."
1720   :version "21.1"
1721   :group 'frames
1722   :group 'basic-faces)
1723
1724
1725 (defface menu
1726   '((((type tty))
1727      :inverse-video t)
1728     (((type x-toolkit))
1729      )
1730     (t
1731      :inverse-video t))
1732   "Basic face for the font and colors of the menu bar and popup menus."
1733   :version "21.1"
1734   :group 'menu
1735   :group 'basic-faces)
1736
1737
1738 (defface border '()
1739   "Basic face for the frame border under X."
1740   :version "21.1"
1741   :group 'frames
1742   :group 'basic-faces)
1743
1744
1745 (defface cursor '()
1746   "Basic face for the cursor color under X."
1747   :version "21.1"
1748   :group 'cursor
1749   :group 'basic-faces)
1750
1751
1752 (defface mouse '()
1753   "Basic face for the mouse color under X."
1754   :version "21.1"
1755   :group 'mouse
1756   :group 'basic-faces)
1757
1758
1759 (defface bold '((t (:weight bold)))
1760   "Basic bold face."
1761   :group 'basic-faces)
1762
1763
1764 (defface italic '((t (:slant italic)))
1765   "Basic italic font."
1766   :group 'basic-faces)
1767
1768
1769 (defface bold-italic '((t (:weight bold :slant italic)))
1770   "Basic bold-italic face."
1771   :group 'basic-faces)
1772
1773
1774 (defface underline '((t (:underline t)))
1775   "Basic underlined face."
1776   :group 'basic-faces)
1777
1778
1779 (defface highlight
1780   '((((type tty) (class color))
1781      (:background "green"))
1782     (((class color) (background light))
1783      (:background "darkseagreen2"))
1784     (((class color) (background dark))
1785      (:background "darkolivegreen"))
1786     (t (:inverse-video t)))
1787   "Basic face for highlighting."
1788   :group 'basic-faces)
1789
1790
1791 (defface secondary-selection
1792   '((((type tty) (class color))
1793      (:background "cyan" :foreground "black"))
1794     (((class color) (background light))
1795      (:background "yellow"))
1796     (((class color) (background dark))
1797      (:background "SkyBlue4"))
1798     (t (:inverse-video t)))
1799   "Basic face for displaying the secondary selection."
1800   :group 'basic-faces)
1801
1802
1803 (defface fixed-pitch '((t (:family "courier")))
1804   "The basic fixed-pitch face."
1805   :group 'basic-faces)
1806
1807
1808 (defface variable-pitch '((t (:family "helv")))
1809   "The basic variable-pitch face."
1810   :group 'basic-faces)
1811
1812
1813 (defface trailing-whitespace
1814   '((((class color) (background light))
1815      (:background "red"))
1816     (((class color) (background dark))
1817      (:background "red"))
1818     (t (:inverse-video t)))
1819   "Basic face for highlighting trailing whitespace."
1820   :version "21.1"
1821   :group 'font-lock                     ; like `show-trailing-whitespace'
1822   :group 'basic-faces)
1823
1824
1825 \f
1826 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1827 ;;; Manipulating font names.
1828 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1829
1830 ;; This is here for compatibilty with Emacs 20.2.  For example,
1831 ;; international/fontset.el uses x-resolve-font-name.  The following
1832 ;; functions are not used in the face implementation itself.
1833
1834 (defvar x-font-regexp nil)
1835 (defvar x-font-regexp-head nil)
1836 (defvar x-font-regexp-weight nil)
1837 (defvar x-font-regexp-slant nil)
1838
1839 (defconst x-font-regexp-weight-subnum 1)
1840 (defconst x-font-regexp-slant-subnum 2)
1841 (defconst x-font-regexp-swidth-subnum 3)
1842 (defconst x-font-regexp-adstyle-subnum 4)
1843
1844 ;;; Regexps matching font names in "Host Portable Character Representation."
1845 ;;;
1846 (let ((-                "[-?]")
1847       (foundry          "[^-]+")
1848       (family           "[^-]+")
1849       (weight           "\\(bold\\|demibold\\|medium\\)")               ; 1
1850 ;     (weight\?         "\\(\\*\\|bold\\|demibold\\|medium\\|\\)")      ; 1
1851       (weight\?         "\\([^-]*\\)")                                  ; 1
1852       (slant            "\\([ior]\\)")                                  ; 2
1853 ;     (slant\?          "\\([ior?*]?\\)")                               ; 2
1854       (slant\?          "\\([^-]?\\)")                                  ; 2
1855 ;     (swidth           "\\(\\*\\|normal\\|semicondensed\\|\\)")        ; 3
1856       (swidth           "\\([^-]*\\)")                                  ; 3
1857 ;     (adstyle          "\\(\\*\\|sans\\|\\)")                          ; 4
1858       (adstyle          "\\([^-]*\\)")                                  ; 4
1859       (pixelsize        "[0-9]+")
1860       (pointsize        "[0-9][0-9]+")
1861       (resx             "[0-9][0-9]+")
1862       (resy             "[0-9][0-9]+")
1863       (spacing          "[cmp?*]")
1864       (avgwidth         "[0-9]+")
1865       (registry         "[^-]+")
1866       (encoding         "[^-]+")
1867       )
1868   (setq x-font-regexp
1869         (concat "\\`\\*?[-?*]"
1870                 foundry - family - weight\? - slant\? - swidth - adstyle -
1871                 pixelsize - pointsize - resx - resy - spacing - avgwidth -
1872                 registry - encoding "\\*?\\'"
1873                 ))
1874   (setq x-font-regexp-head
1875         (concat "\\`[-?*]" foundry - family - weight\? - slant\?
1876                 "\\([-*?]\\|\\'\\)"))
1877   (setq x-font-regexp-slant (concat - slant -))
1878   (setq x-font-regexp-weight (concat - weight -))
1879   nil)
1880
1881
1882 (defun x-resolve-font-name (pattern &optional face frame)
1883   "Return a font name matching PATTERN.
1884 All wildcards in PATTERN are instantiated.
1885 If PATTERN is nil, return the name of the frame's base font, which never
1886 contains wildcards.
1887 Given optional arguments FACE and FRAME, return a font which is
1888 also the same size as FACE on FRAME, or fail."
1889   (or (symbolp face)
1890       (setq face (face-name face)))
1891   (and (eq frame t)
1892        (setq frame nil))
1893   (if pattern
1894       ;; Note that x-list-fonts has code to handle a face with nil as its font.
1895       (let ((fonts (x-list-fonts pattern face frame 1)))
1896         (or fonts
1897             (if face
1898                 (if (string-match "\\*" pattern)
1899                     (if (null (face-font face))
1900                         (error "No matching fonts are the same height as the frame default font")
1901                       (error "No matching fonts are the same height as face `%s'" face))
1902                   (if (null (face-font face))
1903                       (error "Height of font `%s' doesn't match the frame default font"
1904                              pattern)
1905                     (error "Height of font `%s' doesn't match face `%s'"
1906                            pattern face)))
1907               (error "No fonts match `%s'" pattern)))
1908         (car fonts))
1909     (cdr (assq 'font (frame-parameters (selected-frame))))))
1910
1911
1912 (defun x-frob-font-weight (font which)
1913   (let ((case-fold-search t))
1914     (cond ((string-match x-font-regexp font)
1915            (concat (substring font 0
1916                               (match-beginning x-font-regexp-weight-subnum))
1917                    which
1918                    (substring font (match-end x-font-regexp-weight-subnum)
1919                               (match-beginning x-font-regexp-adstyle-subnum))
1920                    ;; Replace the ADD_STYLE_NAME field with *
1921                    ;; because the info in it may not be the same
1922                    ;; for related fonts.
1923                    "*"
1924                    (substring font (match-end x-font-regexp-adstyle-subnum))))
1925           ((string-match x-font-regexp-head font)
1926            (concat (substring font 0 (match-beginning 1)) which
1927                    (substring font (match-end 1))))
1928           ((string-match x-font-regexp-weight font)
1929            (concat (substring font 0 (match-beginning 1)) which
1930                    (substring font (match-end 1)))))))
1931 (make-obsolete 'x-frob-font-weight 'make-face-... "21.1")
1932
1933 (defun x-frob-font-slant (font which)
1934   (let ((case-fold-search t))
1935     (cond ((string-match x-font-regexp font)
1936            (concat (substring font 0
1937                               (match-beginning x-font-regexp-slant-subnum))
1938                    which
1939                    (substring font (match-end x-font-regexp-slant-subnum)
1940                               (match-beginning x-font-regexp-adstyle-subnum))
1941                    ;; Replace the ADD_STYLE_NAME field with *
1942                    ;; because the info in it may not be the same
1943                    ;; for related fonts.
1944                    "*"
1945                    (substring font (match-end x-font-regexp-adstyle-subnum))))
1946           ((string-match x-font-regexp-head font)
1947            (concat (substring font 0 (match-beginning 2)) which
1948                    (substring font (match-end 2))))
1949           ((string-match x-font-regexp-slant font)
1950            (concat (substring font 0 (match-beginning 1)) which
1951                    (substring font (match-end 1)))))))
1952 (make-obsolete 'x-frob-font-slant 'make-face-... "21.1")
1953
1954 (defun x-make-font-bold (font)
1955   "Given an X font specification, make a bold version of it.
1956 If that can't be done, return nil."
1957   (x-frob-font-weight font "bold"))
1958 (make-obsolete 'x-make-font-bold 'make-face-bold "21.1")
1959
1960 (defun x-make-font-demibold (font)
1961   "Given an X font specification, make a demibold version of it.
1962 If that can't be done, return nil."
1963   (x-frob-font-weight font "demibold"))
1964 (make-obsolete 'x-make-font-demibold 'make-face-bold "21.1")
1965
1966 (defun x-make-font-unbold (font)
1967   "Given an X font specification, make a non-bold version of it.
1968 If that can't be done, return nil."
1969   (x-frob-font-weight font "medium"))
1970 (make-obsolete 'x-make-font-unbold 'make-face-unbold "21.1")
1971
1972 (defun x-make-font-italic (font)
1973   "Given an X font specification, make an italic version of it.
1974 If that can't be done, return nil."
1975   (x-frob-font-slant font "i"))
1976 (make-obsolete 'x-make-font-italic 'make-face-italic "21.1")
1977
1978 (defun x-make-font-oblique (font) ; you say tomayto...
1979   "Given an X font specification, make an oblique version of it.
1980 If that can't be done, return nil."
1981   (x-frob-font-slant font "o"))
1982 (make-obsolete 'x-make-font-oblique 'make-face-italic "21.1")
1983
1984 (defun x-make-font-unitalic (font)
1985   "Given an X font specification, make a non-italic version of it.
1986 If that can't be done, return nil."
1987   (x-frob-font-slant font "r"))
1988 (make-obsolete 'x-make-font-unitalic 'make-face-unitalic "21.1")
1989
1990 (defun x-make-font-bold-italic (font)
1991   "Given an X font specification, make a bold and italic version of it.
1992 If that can't be done, return nil."
1993   (and (setq font (x-make-font-bold font))
1994        (x-make-font-italic font)))
1995 (make-obsolete 'x-make-font-bold-italic 'make-face-bold-italic "21.1")
1996
1997 (provide 'faces)
1998
1999 ;;; faces.el ends here