code.delx.au - gnu-emacs/blob - configure.in

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl If you changed any AC_DEFINES, also run autoheader.
   6 dnl
   7 dnl  Copyright (C) 1994, 1995, 1996, 1999, 2000, 2001, 2002, 2003, 2004,
   8 dnl    2005, 2006, 2007, 2008, 2009, 2010
   9 dnl    Free Software Foundation, Inc.
  10 dnl
  11 dnl  This file is part of GNU Emacs.
  12 dnl
  13 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  14 dnl  it under the terms of the GNU General Public License as published by
  15 dnl  the Free Software Foundation, either version 3 of the License, or
  16 dnl  (at your option) any later version.
  17 dnl
  18 dnl  GNU Emacs is distributed in the hope that it will be useful,
  19 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 dnl  GNU General Public License for more details.
  22 dnl
  23 dnl  You should have received a copy of the GNU General Public License
  24 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  25
  26 AC_PREREQ(2.65)
  27 AC_INIT(emacs, 24.0.50)
  28 AC_CONFIG_HEADER(src/config.h:src/config.in)
  29 AC_CONFIG_SRCDIR(src/lisp.h)
  30
  31 dnl Support for --program-prefix, --program-suffix and
  32 dnl --program-transform-name options
  33 AC_ARG_PROGRAM
  34
  35 dnl It is important that variables on the RHS not be expanded here,
  36 dnl hence the single quotes.  This is per the GNU coding standards, see
  37 dnl (autoconf) Installation Directory Variables
  38 dnl See also epaths.h below.
  39 lispdir='${datadir}/emacs/${version}/lisp'
  40 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  41 '${datadir}/emacs/site-lisp'
  42 lisppath='${locallisppath}:${lispdir}:${datadir}/emacs/${version}/leim'
  43 etcdir='${datadir}/emacs/${version}/etc'
  44 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  45 docdir='${datadir}/emacs/${version}/etc'
  46 gamedir='${localstatedir}/games/emacs'
  47
  48 gameuser=games
  49
  50 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  51 dnl Create a new --with option that defaults to being disabled.
  52 dnl NAME is the base name of the option.  The shell variable with_NAME
  53 dnl   will be set to either the user's value (if the option is
  54 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  55 dnl   option is not specified).  Note that the shell variable name is
  56 dnl   constructed as autoconf does, by replacing non-alphanumeric
  57 dnl   characters with "_".
  58 dnl HELP-STRING is the help text for the option.
  59 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  60   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  61     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  62 ])dnl
  63
  64 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  65 dnl Create a new --with option that defaults to being enabled.  NAME
  66 dnl   is the base name of the option.  The shell variable with_NAME
  67 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  68 dnl   'yes' (if the option is not specified).  Note that the shell
  69 dnl   variable name is constructed as autoconf does, by replacing
  70 dnl   non-alphanumeric characters with "_".
  71 dnl HELP-STRING is the help text for the option.
  72 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  73   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  74    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=yes])dnl
  75 ])dnl
  76
  77 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
  78 if test "$with_pop" = yes; then
  79    AC_DEFINE(MAIL_USE_POP)
  80 fi
  81 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  82
  83 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
  84 if test "$with_kerberos" != no; then
  85    AC_DEFINE(KERBEROS)
  86 fi
  87 AH_TEMPLATE(KERBEROS,
  88             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  89
  90 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
  91 if test "${with_kerberos5}" != no; then
  92   if test "${with_kerberos}" = no; then
  93     with_kerberos=yes
  94     AC_DEFINE(KERBEROS)
  95   fi
  96   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
  97 fi
  98
  99 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
 100 dnl FIXME hesiod support may not be present, so it seems like an error
 101 dnl to define, or at least use, this unconditionally.
 102 if test "$with_hesiod" != no; then
 103   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
 104 fi
 105
 106 OPTION_DEFAULT_OFF([mmdf],[support MMDF mailboxes])
 107 if test "$with_mmdf" != no; then
 108    AC_DEFINE(MAIL_USE_MMDF, 1, [Define to support MMDF mailboxes in movemail.])
 109 fi
 110
 111 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 112 if test "$with_mail_unlink" != no; then
 113    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 114 fi
 115
 116 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 117     [string giving default POP mail host])],
 118     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 119
 120 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
 121
 122 OPTION_DEFAULT_ON([sync-input],[process async input synchronously])
 123 if test "$with_sync_input" = yes; then
 124    AC_DEFINE(SYNC_INPUT, 1, [Process async input synchronously.])
 125 fi
 126
 127 dnl FIXME currently it is not the last.
 128 dnl This should be the last --with option, because --with-x is
 129 dnl added later on when we find the path of X, and it's best to
 130 dnl keep them together visually.
 131 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 132  [use an X toolkit (KIT one of: yes or gtk, gtk3, lucid or athena, motif, no)])],
 133 [         case "${withval}" in
 134             y | ye | yes )      val=gtk ;;
 135             n | no )            val=no  ;;
 136             l | lu | luc | luci | lucid )       val=lucid ;;
 137             a | at | ath | athe | athen | athena )      val=athena ;;
 138             m | mo | mot | moti | motif )       val=motif ;;
 139             g | gt | gtk  )     val=gtk ;;
 140             gtk3  )     val=gtk3 ;;
 141             * )
 142 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 143 this option's value should be `yes', `no', `lucid', `athena', `motif', `gtk' or
 144 `gtk3'.  `yes' and `gtk' are synonyms. `athena' and `lucid' are synonyms.])
 145             ;;
 146           esac
 147           with_x_toolkit=$val
 148 ])
 149
 150 dnl _ON results in a '--without' option in the --help output, so
 151 dnl the help text should refer to "don't compile", etc.
 152 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 153 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 154 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 155 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 156 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 157 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 158
 159 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 160 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 161 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 162
 163 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 164 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 165 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 166 OPTION_DEFAULT_OFF([ns],[use nextstep (Cocoa or GNUstep) windowing system])
 167
 168 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 169 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 170 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 171 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 172
 173 ## For the times when you want to build Emacs but don't have
 174 ## a suitable makeinfo, and can live without the manuals.
 175 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 176 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 177
 178 ## This is an option because I do not know if all info/man support
 179 ## compressed files, nor how to test if they do so.
 180 OPTION_DEFAULT_ON([compress-info],[don't compress the installed Info pages])
 181 if test $with_compress_info = yes; then
 182    GZIP_INFO=yes
 183 else
 184    GZIP_INFO=
 185 fi
 186 AC_SUBST(GZIP_INFO)
 187
 188 AC_ARG_WITH([pkg-config-prog],dnl
 189 [AS_HELP_STRING([--with-pkg-config-prog=PATH],
 190                   [path to pkg-config for finding GTK and librsvg])])
 191 if test "X${with_pkg_config_prog}" != X; then
 192    if test "${with_pkg_config_prog}" != yes; then
 193       PKG_CONFIG="${with_pkg_config_prog}"
 194    fi
 195 fi
 196
 197 CRT_DIR=
 198 AC_ARG_WITH([crt-dir],dnl
 199 [AS_HELP_STRING([--with-crt-dir=DIR],[directory containing crtn.o etc.
 200 The default is /usr/lib, or /usr/lib64 on some platforms.])])
 201 CRT_DIR="${with_crt_dir}"
 202
 203 AC_ARG_WITH([gnustep-conf],dnl
 204 [AS_HELP_STRING([--with-gnustep-conf=PATH],[path to GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
 205 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 206   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 207 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 208      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 209
 210 AC_ARG_ENABLE(ns-self-contained,
 211 [AS_HELP_STRING([--disable-ns-self-contained],
 212                 [disable self contained build under NeXTstep])],
 213    EN_NS_SELF_CONTAINED=$enableval,
 214    EN_NS_SELF_CONTAINED=yes)
 215
 216 AC_ARG_ENABLE(asserts,
 217 [AS_HELP_STRING([--enable-asserts], [compile code with asserts enabled])],
 218       USE_XASSERTS=$enableval,
 219       USE_XASSERTS=no)
 220
 221 AC_ARG_ENABLE(maintainer-mode,
 222 [AS_HELP_STRING([--enable-maintainer-mode],
 223                 [enable make rules and dependencies not useful (and sometimes
 224                  confusing) to the casual installer])],
 225       USE_MAINTAINER_MODE=$enableval,
 226       USE_MAINTAINER_MODE=no)
 227 if test $USE_MAINTAINER_MODE = yes; then
 228   MAINT=
 229 else
 230   MAINT=#
 231 fi
 232 AC_SUBST(MAINT)
 233
 234 AC_ARG_ENABLE(locallisppath,
 235 [AS_HELP_STRING([--enable-locallisppath=PATH],
 236                 [directories Emacs should search for lisp files specific
 237                  to this site])],
 238 if test "${enableval}" = "no"; then
 239   locallisppath=
 240 elif test "${enableval}" != "yes"; then
 241   locallisppath=${enableval}
 242 fi)
 243
 244 AC_ARG_ENABLE(checking,
 245 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 246                 [enable expensive run-time checks.  With LIST,
 247                  enable only specific categories of checks.
 248                  Categories are: all,yes,no.
 249                  Flags are: stringbytes, stringoverrun, stringfreelist,
 250                  xmallocoverrun, conslist])],
 251 [ac_checking_flags="${enableval}"],[])
 252 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 253 for check in $ac_checking_flags
 254 do
 255         case $check in
 256         # these set all the flags to specific states
 257         yes)            ac_enable_checking=1 ;;
 258         no)             ac_enable_checking= ;
 259                         ac_gc_check_stringbytes= ;
 260                         ac_gc_check_string_overrun= ;
 261                         ac_gc_check_string_free_list= ;
 262                         ac_xmalloc_overrun= ;
 263                         ac_gc_check_cons_list= ;;
 264         all)            ac_enable_checking=1 ;
 265                         ac_gc_check_stringbytes=1 ;
 266                         ac_gc_check_string_overrun=1 ;
 267                         ac_gc_check_string_free_list=1 ;
 268                         ac_xmalloc_overrun=1 ;
 269                         ac_gc_check_cons_list=1 ;;
 270         # these enable particular checks
 271         stringbytes)    ac_gc_check_stringbytes=1 ;;
 272         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 273         stringfreelist) ac_gc_check_string_free_list=1 ;;
 274         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 275         conslist)       ac_gc_check_cons_list=1 ;;
 276         *)      AC_MSG_ERROR(unknown check category $check) ;;
 277         esac
 278 done
 279 IFS="$ac_save_IFS"
 280
 281 if test x$ac_enable_checking != x ; then
 282   AC_DEFINE(ENABLE_CHECKING, 1,
 283 [Enable expensive run-time checking of data types?])
 284 fi
 285 if test x$ac_gc_check_stringbytes != x ; then
 286   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 287 [Define this temporarily to hunt a bug.  If defined, the size of
 288    strings is redundantly recorded in sdata structures so that it can
 289    be compared to the sizes recorded in Lisp strings.])
 290 fi
 291 if test x$ac_gc_check_stringoverrun != x ; then
 292   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 293 [Define this to check for short string overrun.])
 294 fi
 295 if test x$ac_gc_check_string_free_list != x ; then
 296   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 297 [Define this to check the string free list.])
 298 fi
 299 if test x$ac_xmalloc_overrun != x ; then
 300   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 301 [Define this to check for malloc buffer overrun.])
 302 fi
 303 if test x$ac_gc_check_cons_list != x ; then
 304   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 305 [Define this to check for errors in cons list.])
 306 fi
 307
 308 AC_ARG_ENABLE(use-lisp-union-type,
 309 [AS_HELP_STRING([--enable-use-lisp-union-type],
 310                 [use a union for the Lisp_Object data type.
 311                 This is only useful for development for catching certain types of bugs.])],
 312 if test "${enableval}" != "no"; then
 313    AC_DEFINE(USE_LISP_UNION_TYPE, 1,
 314    [Define this to use a lisp union for the Lisp_Object data type.])
 315 fi)
 316
 317
 318 AC_ARG_ENABLE(profiling,
 319 [AS_HELP_STRING([--enable-profiling],
 320                 [build emacs with profiling support.
 321                  This might not work on all platforms])],
 322 [ac_enable_profiling="${enableval}"],[])
 323 if test x$ac_enable_profiling != x ; then
 324    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 325    PROFILING_LDFLAGS="-pg"
 326 else
 327    PROFILING_CFLAGS=
 328    PROFILING_LDFLAGS=
 329 fi
 330
 331 AC_ARG_ENABLE(autodepend,
 332 [AS_HELP_STRING([--enable-autodepend],
 333                 [automatically generate dependencies to .h-files.
 334                  Requires GNU Make and Gcc. Enabled if GNU Make and Gcc is
 335                  found])],
 336 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 337
 338 #### Make srcdir absolute, if it isn't already.  It's important to
 339 #### avoid running the path through pwd unnecessarily, since pwd can
 340 #### give you automounter prefixes, which can go away.  We do all this
 341 #### so Emacs can find its files when run uninstalled.
 342 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 343 unset CDPATH
 344 case "${srcdir}" in
 345   /* ) ;;
 346   . )
 347     ## We may be able to use the $PWD environment variable to make this
 348     ## absolute.  But sometimes PWD is inaccurate.
 349     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 350     ## but that tested only for a well-formed and valid PWD,
 351     ## it did not object when PWD was well-formed and valid but just wrong.
 352     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 353     then
 354       srcdir="$PWD"
 355     else
 356       srcdir="`(cd ${srcdir}; pwd)`"
 357     fi
 358   ;;
 359   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 360 esac
 361
 362 #### Check if the source directory already has a configured system in it.
 363 if test `pwd` != `(cd ${srcdir} && pwd)` \
 364    && test -f "${srcdir}/src/config.h" ; then
 365   AC_MSG_WARN([[The directory tree `${srcdir}' is being used
 366    as a build directory right now; it has been configured in its own
 367    right.  To configure in another directory as well, you MUST
 368    use GNU make.  If you do not have GNU make, then you must
 369    now do `make distclean' in ${srcdir},
 370    and then run $0 again.]])
 371 fi
 372
 373 #### Given the configuration name, set machfile and opsysfile to the
 374 #### names of the m/*.h and s/*.h files we should use.
 375
 376 ### Canonicalize the configuration name.
 377
 378 AC_CANONICAL_HOST
 379 canonical=$host
 380 configuration=${host_alias-${build_alias-$host}}
 381
 382 dnl This used to use changequote, but, apart from `changequote is evil'
 383 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 384 dnl the great gob of text.  Thus it's not processed for possible expansion.
 385 dnl Just make sure the brackets remain balanced.
 386 dnl
 387 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 388 dnl indicated by comments.
 389 dnl quotation begins
 390 [
 391
 392 ### If you add support for a new configuration, add code to this
 393 ### switch statement to recognize your configuration name and select
 394 ### the appropriate operating system and machine description files.
 395
 396 ### You would hope that you could choose an m/*.h file pretty much
 397 ### based on the machine portion of the configuration name, and an s/*.h
 398 ### file based on the operating system portion.  However, it turns out
 399 ### that each m/*.h file is pretty manufacturer-specific - for
 400 ### example mips.h is MIPS
 401 ### So we basically have to have a special case for each
 402 ### configuration name.
 403 ###
 404 ### As far as handling version numbers on operating systems is
 405 ### concerned, make sure things will fail in a fixable way.  If
 406 ### /etc/MACHINES doesn't say anything about version numbers, be
 407 ### prepared to handle anything reasonably.  If version numbers
 408 ### matter, be sure /etc/MACHINES says something about it.
 409
 410 machine='' opsys='' unported=no
 411 case "${canonical}" in
 412
 413   ## FreeBSD ports
 414   *-*-freebsd* )
 415     opsys=freebsd
 416     case "${canonical}" in
 417       alpha*)           machine=alpha ;;
 418       amd64-*|x86_64-*) machine=amdx86-64 ;;
 419       arm*)             machine=arm ;;
 420       ia64-*)           machine=ia64 ;;
 421       i[3456]86-*)      machine=intel386 ;;
 422       powerpc-*)        machine=macppc ;;
 423       sparc-*)          machine=sparc ;;
 424       sparc64-*)        machine=sparc ;;
 425     esac
 426   ;;
 427
 428   ## FreeBSD kernel + glibc based userland
 429   *-*-kfreebsd*gnu* )
 430     opsys=gnu-kfreebsd
 431     case "${canonical}" in
 432       alpha*)           machine=alpha ;;
 433       amd64-*|x86_64-*) machine=amdx86-64 ;;
 434       ia64-*)           machine=ia64 ;;
 435       i[3456]86-*)      machine=intel386 ;;
 436       powerpc-*)        machine=macppc ;;
 437       sparc-*)          machine=sparc ;;
 438       sparc64-*)        machine=sparc ;;
 439     esac
 440   ;;
 441
 442   ## NetBSD ports
 443   *-*-netbsd* )
 444     opsys=netbsd
 445     case "${canonical}" in
 446       alpha*)      machine=alpha ;;
 447       x86_64-*)    machine=amdx86-64 ;;
 448       arm-*)       machine=arm ;;
 449       hppa-*)      machine=hp800 ;;
 450       i[3456]86-*) machine=intel386 ;;
 451       m68k-*)      machine=m68k ;;
 452       powerpc-*)   machine=macppc ;;
 453       mips-*)      machine=mips ;;
 454       mipse[bl]-*) machine=mips ;;
 455       sparc*-)     machine=sparc ;;
 456       vax-*)       machine=vax ;;
 457     esac
 458   ;;
 459
 460   ## OpenBSD ports
 461   *-*-openbsd* )
 462     opsys=openbsd
 463     case "${canonical}" in
 464       alpha*)    machine=alpha ;;
 465       x86_64-*)  machine=amdx86-64 ;;
 466       arm-*)     machine=arm ;;
 467       hppa-*)    machine=hp800 ;;
 468       i386-*)    machine=intel386 ;;
 469       powerpc-*) machine=macppc ;;
 470       sparc*)    machine=sparc ;;
 471       vax-*)     machine=vax ;;
 472     esac
 473   ;;
 474
 475   alpha*-*-linux-gnu* )
 476     machine=alpha opsys=gnu-linux
 477   ;;
 478
 479   arm*-*-linux-gnu* )
 480     machine=arm opsys=gnu-linux
 481   ;;
 482
 483   ## Apple Darwin / Mac OS X
 484   *-apple-darwin* )
 485     case "${canonical}" in
 486       i[3456]86-* )  machine=intel386 ;;
 487       powerpc-* )    machine=macppc ;;
 488       x86_64-* )     machine=amdx86-64 ;;
 489       * )            unported=yes ;;
 490     esac
 491     opsys=darwin
 492     # Define CPP as follows to make autoconf work correctly.
 493     CPP="${CC-cc} -E -no-cpp-precomp"
 494     # Use fink packages if available.
 495     if test -d /sw/include && test -d /sw/lib; then
 496       GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 497       CPP="${CPP} ${GCC_TEST_OPTIONS}"
 498       NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 499     fi
 500   ;;
 501
 502   ## HP 9000 series 700 and 800, running HP/UX
 503   hppa*-hp-hpux10.2* )
 504     machine=hp800 opsys=hpux10-20
 505   ;;
 506   hppa*-hp-hpux1[1-9]* )
 507     machine=hp800 opsys=hpux11
 508     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 509   ;;
 510
 511   hppa*-*-linux-gnu* )
 512     machine=hp800 opsys=gnu-linux
 513   ;;
 514
 515   ## IBM machines
 516   s390-*-linux-gnu* )
 517     machine=ibms390 opsys=gnu-linux
 518   ;;
 519   s390x-*-linux-gnu* )
 520     machine=ibms390x opsys=gnu-linux
 521   ;;
 522   rs6000-ibm-aix4.[23]* )
 523     machine=ibmrs6000 opsys=aix4-2
 524   ;;
 525   powerpc-ibm-aix4.[23]*  )
 526     machine=ibmrs6000 opsys=aix4-2
 527   ;;
 528   rs6000-ibm-aix[56]* )
 529     machine=ibmrs6000 opsys=aix4-2
 530   ;;
 531   powerpc-ibm-aix[56]*  )
 532     machine=ibmrs6000 opsys=aix4-2
 533   ;;
 534
 535   ## Macintosh PowerPC
 536   powerpc*-*-linux-gnu* )
 537     machine=macppc opsys=gnu-linux
 538   ;;
 539
 540   ## Silicon Graphics machines
 541   ## Iris 4D
 542   mips-sgi-irix6.5 )
 543     machine=iris4d opsys=irix6-5
 544     # Without defining _LANGUAGE_C, things get masked out in the headers
 545     # so that, for instance, grepping for `free' in stdlib.h fails and
 546     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 547     NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
 548     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 549   ;;
 550
 551   ## Suns
 552   sparc-*-linux-gnu* | sparc64-*-linux-gnu* )
 553     machine=sparc opsys=gnu-linux
 554   ;;
 555
 556   *-sun-solaris* \
 557     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 558     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 559     case "${canonical}" in
 560       i[3456]86-*-* )     machine=intel386 ;;
 561       amd64-*-*|x86_64-*-*)     machine=amdx86-64 ;;
 562       sparc* )          machine=sparc ;;
 563       * )               unported=yes ;;
 564     esac
 565     case "${canonical}" in
 566       *-sunos5.6* | *-solaris2.6* )
 567                 opsys=sol2-6
 568                 NON_GNU_CPP=/usr/ccs/lib/cpp
 569                 RANLIB="ar -ts"
 570                 ;;
 571       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 572                 opsys=sol2-6
 573                 emacs_check_sunpro_c=yes
 574                 NON_GNU_CPP=/usr/ccs/lib/cpp
 575                 ;;
 576       *-sunos5* | *-solaris* )
 577                 opsys=sol2-10
 578                 emacs_check_sunpro_c=yes
 579                 NON_GNU_CPP=/usr/ccs/lib/cpp
 580                 ;;
 581     esac
 582     ## Watch out for a compiler that we know will not work.
 583     case "${canonical}" in
 584      *-solaris* | *-sunos5* )
 585                 if [ "x$CC" = x/usr/ucb/cc ]; then
 586                   ## /usr/ucb/cc doesn't work;
 587                   ## we should find some other compiler that does work.
 588                   unset CC
 589                 fi
 590                 ;;
 591       *) ;;
 592     esac
 593   ;;
 594
 595   ## IA-64
 596   ia64*-*-linux* )
 597     machine=ia64 opsys=gnu-linux
 598   ;;
 599
 600   ## Intel 386 machines where we don't care about the manufacturer.
 601   i[3456]86-*-* )
 602     machine=intel386
 603     case "${canonical}" in
 604       *-cygwin )                opsys=cygwin ;;
 605       *-darwin* )               opsys=darwin
 606                                 CPP="${CC-cc} -E -no-cpp-precomp"
 607                                 ;;
 608       *-linux-gnu* )            opsys=gnu-linux ;;
 609       *-sysv4.2uw* )            opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 610       *-sysv5uw* )              opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 611       *-sysv5OpenUNIX* )        opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 612       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 613     esac
 614   ;;
 615
 616   ## m68k Linux-based GNU system
 617   m68k-*-linux-gnu* )
 618     machine=m68k opsys=gnu-linux
 619   ;;
 620
 621   ## Mips Linux-based GNU system
 622   mips-*-linux-gnu* | mipsel-*-linux-gnu* \
 623     | mips64-*-linux-gnu* | mips64el-*-linux-gnu* )
 624     machine=mips opsys=gnu-linux
 625   ;;
 626
 627   ## AMD x86-64 Linux-based GNU system
 628   x86_64-*-linux-gnu* )
 629     machine=amdx86-64 opsys=gnu-linux
 630   ;;
 631
 632   ## Tensilica Xtensa Linux-based GNU system
 633   xtensa*-*-linux-gnu* )
 634     machine=xtensa opsys=gnu-linux
 635     ;;
 636
 637   ## SuperH Linux-based GNU system
 638   sh[34]*-*-linux-gnu* )
 639     machine=sh3 opsys=gnu-linux
 640   ;;
 641
 642   * )
 643     unported=yes
 644   ;;
 645 esac
 646
 647 ### If the code above didn't choose an operating system, just choose
 648 ### an operating system based on the configuration name.  You really
 649 ### only want to use this when you have no idea what the right
 650 ### operating system is; if you know what operating systems a machine
 651 ### runs, it's cleaner to make it explicit in the case statement
 652 ### above.
 653 if test x"${opsys}" = x; then
 654   case "${canonical}" in
 655     *-gnu* )                            opsys=gnu ;;
 656     * )
 657       unported=yes
 658     ;;
 659   esac
 660 fi
 661
 662 ]
 663 dnl quotation ends
 664
 665 if test $unported = yes; then
 666   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 667 Check `etc/MACHINES' for recognized configuration names.])
 668 fi
 669
 670 machfile="m/${machine}.h"
 671 opsysfile="s/${opsys}.h"
 672
 673
 674 #### Choose a compiler.
 675 test -n "$CC" && cc_specified=yes
 676
 677 # Save the value of CFLAGS that the user specified.
 678 SPECIFIED_CFLAGS="$CFLAGS"
 679
 680 dnl Sets GCC=yes if using gcc.
 681 AC_PROG_CC
 682
 683 # On Suns, sometimes $CPP names a directory.
 684 if test -n "$CPP" && test -d "$CPP"; then
 685   CPP=
 686 fi
 687
 688 ## If not using gcc, and on Solaris, and no CPP specified, see if
 689 ## using a Sun compiler, which needs -Xs to prevent whitespace.
 690 if test x"$GCC" != xyes && test x"$emacs_check_sunpro_c" = xyes && \
 691  test x"$CPP" = x; then
 692   AC_MSG_CHECKING([whether we are using a Sun C compiler])
 693   AC_CACHE_VAL(emacs_cv_sunpro_c,
 694   [AC_TRY_LINK([],
 695 [#ifndef __SUNPRO_C
 696 fail;
 697 #endif
 698 ], emacs_cv_sunpro_c=yes, emacs_cv_sunpro_c=no)])
 699   AC_MSG_RESULT($emacs_cv_sunpro_c)
 700
 701   if test x"$emacs_cv_sunpro_c" = xyes; then
 702     NON_GNU_CPP="$CC -E -Xs"
 703   fi
 704 fi
 705
 706 #### Some systems specify a CPP to use unless we are using GCC.
 707 #### Now that we know whether we are using GCC, we can decide whether
 708 #### to use that one.
 709 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
 710 then
 711   CPP="$NON_GNU_CPP"
 712 fi
 713
 714 #### Some systems specify a CC to use unless we are using GCC.
 715 #### Now that we know whether we are using GCC, we can decide whether
 716 #### to use that one.
 717 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
 718   test x$cc_specified != xyes
 719 then
 720   CC="$NON_GNU_CC"
 721 fi
 722
 723 if test x$GCC = xyes; then
 724   C_OPTIMIZE_SWITCH=-O2
 725   test "x$GCC_TEST_OPTIONS" != x && CC="$CC $GCC_TEST_OPTIONS"
 726 else
 727   C_OPTIMIZE_SWITCH=-O
 728   test "x$NON_GCC_TEST_OPTIONS" != x && CC="$CC $NON_GCC_TEST_OPTIONS"
 729 fi
 730
 731 dnl checks for Unix variants
 732 AC_USE_SYSTEM_EXTENSIONS
 733
 734 ### Use -Wno-pointer-sign if the compiler supports it
 735 AC_MSG_CHECKING([whether gcc understands -Wno-pointer-sign])
 736 SAVE_CFLAGS="$CFLAGS"
 737 CFLAGS="$CFLAGS -Wno-pointer-sign"
 738 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 739 if test $has_option = yes; then
 740    C_WARNINGS_SWITCH="-Wno-pointer-sign $C_WARNINGS_SWITCH"
 741 fi
 742 AC_MSG_RESULT($has_option)
 743 CFLAGS="$SAVE_CFLAGS"
 744 unset has_option
 745 unset SAVE_CFLAGS
 746
 747 ### Use -Wdeclaration-after-statement if the compiler supports it
 748 AC_MSG_CHECKING([whether gcc understands -Wdeclaration-after-statement])
 749 SAVE_CFLAGS="$CFLAGS"
 750 CFLAGS="$CFLAGS -Wdeclaration-after-statement"
 751 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 752 if test $has_option = yes; then
 753    C_WARNINGS_SWITCH="-Wdeclaration-after-statement $C_WARNINGS_SWITCH"
 754 fi
 755 AC_MSG_RESULT($has_option)
 756 CFLAGS="$SAVE_CFLAGS"
 757 unset has_option
 758 unset SAVE_CFLAGS
 759
 760 #### Some other nice autoconf tests.
 761
 762 dnl checks for programs
 763 AC_PROG_CPP
 764 AC_PROG_INSTALL
 765 if test "x$RANLIB" = x; then
 766   AC_PROG_RANLIB
 767 fi
 768
 769 ## Although we're running on an amd64 kernel, we're actually compiling for
 770 ## the x86 architecture.  The user should probably have provided an
 771 ## explicit --build to `configure', but if everything else than the kernel
 772 ## is running in i386 mode, we can help them out.
 773 if test "$machine" = "amdx86-64"; then
 774   AC_CHECK_DECL([i386])
 775   if test "$ac_cv_have_decl_i386" = "yes"; then
 776     canonical=`echo "$canonical" | sed -e 's/^amd64/i386/' -e 's/^x86_64/i386/'`
 777     machine=intel386
 778     machfile="m/${machine}.h"
 779   fi
 780 fi
 781
 782 AC_PATH_PROG(INSTALL_INFO, install-info)
 783 AC_PATH_PROG(INSTALL_INFO, install-info,, /usr/sbin)
 784 AC_PATH_PROG(INSTALL_INFO, install-info,:, /sbin)
 785 dnl Don't use GZIP, which is used by gzip for additional parameters.
 786 AC_PATH_PROG(GZIP_PROG, gzip)
 787
 788
 789 ## Need makeinfo >= 4.6 (?) to build the manuals.
 790 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 791 dnl By this stage, configure has already checked for egrep and set EGREP,
 792 dnl or exited with an error if no egrep was found.
 793 if test "$MAKEINFO" != "no" && \
 794   test x"`$MAKEINFO --version 2> /dev/null | $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[6-9]]|4\.[[1-5]][[0-9]]+)'`" = x; then
 795    MAKEINFO=no
 796 fi
 797
 798 ## Makeinfo is unusual.  For a released Emacs, the manuals are
 799 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
 800 ## therefore in the category of "special tools" not normally required, which
 801 ## configure does not have to check for (eg autoconf itself).
 802 ## In a Bazaar checkout on the other hand, the manuals are not included.
 803 ## So makeinfo is a requirement to build from Bazaar, and configure
 804 ## should test for it as it does for any other build requirement.
 805 ## We use the presence of $srcdir/info/emacs to distinguish a release,
 806 ## with pre-built manuals, from a Bazaar checkout.
 807 if test "$MAKEINFO" = "no"; then
 808   if test "x${with_makeinfo}" = "xno"; then
 809     MAKEINFO=off
 810   elif test ! -e $srcdir/info/emacs; then
 811     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.6, and your
 812 source tree does not seem to have pre-built manuals in the `info' directory.
 813 Either install a suitable version of makeinfo, or re-run configure
 814 with the `--without-makeinfo' option to build without the manuals.] )
 815   fi
 816 fi
 817
 818 dnl Add our options to ac_link now, after it is set up.
 819
 820 if test x$GCC = xyes && test "x$GCC_LINK_TEST_OPTIONS" != x
 821 then
 822   ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 823 fi
 824
 825 if test x$GCC = x && test "x$NON_GCC_LINK_TEST_OPTIONS" != x
 826 then
 827   ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 828 fi
 829
 830 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 831 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 832 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 833 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 834 dnl if not built to support GNU ld.
 835
 836 late_LDFLAGS=$LDFLAGS
 837 if test "$GCC" = yes; then
 838   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 839 else
 840   LDFLAGS="$LDFLAGS -znocombreloc"
 841 fi
 842
 843 AC_MSG_CHECKING([for -znocombreloc])
 844 AC_LINK_IFELSE([main(){return 0;}],
 845   [AC_MSG_RESULT(yes)],
 846   LDFLAGS=$late_LDFLAGS
 847   [AC_MSG_RESULT(no)])
 848
 849 LDFLAGS="${LDFLAGS} ${PROFILING_LDFLAGS}"
 850
 851
 852 # The value of CPP is a quoted variable reference, so we need to do this
 853 # to get its actual value...
 854 CPP=`eval "echo $CPP"`
 855
 856
 857 ### First figure out CFLAGS (which we use for running the compiler here)
 858 ### and REAL_CFLAGS (which we use for real compilation).
 859 ### The two are the same except when using GCC where we might use
 860 ### extra warning and profiling flags.
 861
 862 ### If the CFLAGS env var is specified, we use that value
 863 ### instead of the default.
 864
 865 dnl Note AC_PROG_CC sets CFLAGS to -g -O2 for gcc anyway.
 866 if test "x$SPECIFIED_CFLAGS" = x; then
 867   CFLAGS="-g $C_OPTIMIZE_SWITCH"
 868   if test x$GCC = xyes; then
 869     REAL_CFLAGS="$CFLAGS $C_WARNINGS_SWITCH $PROFILING_CFLAGS"
 870   else
 871     REAL_CFLAGS="$CFLAGS"
 872   fi
 873 else
 874   REAL_CFLAGS="$CFLAGS"
 875 fi
 876
 877
 878 dnl Not used by any currently supported platform.
 879 dnl The function dump-emacs will not be defined and temacs will do
 880 dnl (load "loadup") automatically unless told otherwise.
 881 CANNOT_DUMP=no
 882 case "$opsys" in
 883   your-opsys-here)
 884    CANNOT_DUMP=yes
 885    AC_DEFINE(CANNOT_DUMP, 1, [Define if Emacs cannot be dumped on your system.])
 886   ;;
 887 esac
 888 AC_SUBST(CANNOT_DUMP)
 889
 890
 891 UNEXEC_OBJ=unexelf.o
 892 case "$opsys" in
 893   aix4-2)
 894    UNEXEC_OBJ=unexaix.o
 895    ;;
 896   cygwin)
 897    UNEXEC_OBJ=unexcw.o
 898    ;;
 899   darwin)
 900    UNEXEC_OBJ=unexmacosx.o
 901    ;;
 902   hpux10-20 | hpux11)
 903    UNEXEC_OBJ=unexhp9k800.o
 904    ;;
 905   sol2-10)
 906    # Use the Solaris dldump() function, called from unexsol.c, to dump
 907    # emacs, instead of the generic ELF dump code found in unexelf.c.
 908    # The resulting binary has a complete symbol table, and is better
 909    # for debugging and other observability tools (debuggers, pstack, etc).
 910    #
 911    # If you encounter a problem using dldump(), please consider sending
 912    # a message to the OpenSolaris tools-linking mailing list:
 913    #      http://mail.opensolaris.org/mailman/listinfo/tools-linking
 914    #
 915    # It is likely that dldump() works with older Solaris too, but this has
 916    # not been tested, so for now this change is for Solaris 10 or newer.
 917    UNEXEC_OBJ=unexsol.o
 918    ;;
 919 esac
 920
 921 LD_SWITCH_SYSTEM=
 922 case "$opsys" in
 923   freebsd)
 924    ## Let `ld' find image libs and similar things in /usr/local/lib.
 925    ## The system compiler, GCC, has apparently been modified to not
 926    ## look there, contrary to what a stock GCC would do.
 927    LD_SWITCH_SYSTEM=-L/usr/local/lib
 928    ;;
 929
 930   gnu-linux)
 931    ## cpp test was "ifdef __mips__", but presumably this is equivalent...
 932    test "$machine" = "mips" && LD_SWITCH_SYSTEM="-G 0"
 933    ;;
 934
 935   netbsd)
 936    LD_SWITCH_SYSTEM="-Wl,-rpath,/usr/pkg/lib -L/usr/pkg/lib -Wl,-rpath,/usr/local/lib -L/usr/local/lib"
 937    ;;
 938
 939   openbsd)
 940    ## Han Boetes <han@mijncomputer.nl> says this is necessary,
 941    ## otherwise Emacs dumps core on elf systems.
 942    LD_SWITCH_SYSTEM="-Z"
 943    ;;
 944 esac
 945 AC_SUBST(LD_SWITCH_SYSTEM)
 946
 947 ac_link="$ac_link $LD_SWITCH_SYSTEM"
 948
 949 ## This setting of LD_SWITCH_SYSTEM references LD_SWITCH_X_SITE_AUX,
 950 ## which has not been defined yet.  When this was handled with cpp,
 951 ## it was expanded to null when configure sourced the s/*.h file.
 952 ## Thus LD_SWITCH_SYSTEM had different values in configure and the Makefiles.
 953 ## FIXME it would be cleaner to put this in LD_SWITCH_SYSTEM_TEMACS
 954 ## (or somesuch), but because it is supposed to go at the _front_
 955 ## of LD_SWITCH_SYSTEM, we cannot do that in exactly the same way.
 956 ## Compare with the gnu-linux case below, which added to the end
 957 ## of LD_SWITCH_SYSTEM, and so can instead go at the front of
 958 ## LD_SWITCH_SYSTEM_TEMACS.
 959 case "$opsys" in
 960   netbsd|openbsd)
 961    ## _AUX_RPATH is like _AUX, but uses -rpath instead of -R.
 962    LD_SWITCH_SYSTEM="\$(LD_SWITCH_X_SITE_AUX_RPATH) $LD_SWITCH_SYSTEM" ;;
 963 esac
 964
 965
 966 C_SWITCH_MACHINE=
 967 if test "$machine" = "alpha"; then
 968   AC_CHECK_DECL([__ELF__])
 969   if test "$ac_cv_have_decl___ELF__" = "yes"; then
 970     ## With ELF, make sure that all common symbols get allocated to in the
 971     ## data section.  Otherwise, the dump of temacs may miss variables in
 972     ## the shared library that have been initialized.  For example, with
 973     ## GNU libc, __malloc_initialized would normally be resolved to the
 974     ## shared library's .bss section, which is fatal.
 975     if test "x$GCC" = "xyes"; then
 976       C_SWITCH_MACHINE="-fno-common"
 977     else
 978       AC_MSG_ERROR([What gives?  Fix me if DEC Unix supports ELF now.])
 979     fi
 980   else
 981     UNEXEC_OBJ=unexalpha.o
 982   fi
 983 fi
 984 AC_SUBST(C_SWITCH_MACHINE)
 985
 986 AC_SUBST(UNEXEC_OBJ)
 987
 988 C_SWITCH_SYSTEM=
 989 ## Some programs in src produce warnings saying certain subprograms
 990 ## are too complex and need a MAXMEM value greater than 2000 for
 991 ## additional optimization.  --nils@exp-math.uni-essen.de
 992 test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \
 993   C_SWITCH_SYSTEM="-ma -qmaxmem=4000"
 994 ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems.
 995 ## It is redundant in glibc2, since we define _GNU_SOURCE.
 996 AC_SUBST(C_SWITCH_SYSTEM)
 997
 998
 999 LIBS_SYSTEM=
1000 case "$opsys" in
1001   ## IBM's X11R5 uses -lIM and -liconv in AIX 3.2.2.
1002   aix4-2) LIBS_SYSTEM="-lrts -lIM -liconv" ;;
1003
1004   freebsd) LIBS_SYSTEM="-lutil" ;;
1005
1006   hpux*) LIBS_SYSTEM="-l:libdld.sl" ;;
1007
1008   sol2*) LIBS_SYSTEM="-lsocket -lnsl -lkstat" ;;
1009
1010   ## Motif needs -lgen.
1011   unixware) LIBS_SYSTEM="-lsocket -lnsl -lelf -lgen" ;;
1012 esac
1013 AC_SUBST(LIBS_SYSTEM)
1014
1015
1016 ### Make sure subsequent tests use flags consistent with the build flags.
1017
1018 if test x"${OVERRIDE_CPPFLAGS}" != x; then
1019   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
1020 else
1021   CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS"
1022 fi
1023
1024 dnl For AC_FUNC_GETLOADAVG, at least:
1025 AC_CONFIG_LIBOBJ_DIR(src)
1026
1027 dnl Do this early because it can frob feature test macros for Unix-98 &c.
1028 AC_SYS_LARGEFILE
1029
1030
1031 ## If user specified a crt-dir, use that unconditionally.
1032 if test "X$CRT_DIR" = "X"; then
1033
1034   case "$canonical" in
1035     x86_64-*-linux-gnu* | s390x-*-linux-gnu*)
1036     ## On x86-64 and s390x GNU/Linux distributions, the standard library
1037     ## can be in a variety of places.  We only try /usr/lib64 and /usr/lib.
1038     ## For anything else (eg /usr/lib32), it is up the user to specify
1039     ## the location (bug#5655).
1040     ## Test for crtn.o, not just the directory, because sometimes the
1041     ## directory exists but does not have the relevant files (bug#1287).
1042     ## FIXME better to test for binary compatibility somehow.
1043     test -e /usr/lib64/crtn.o && CRT_DIR=/usr/lib64
1044     ;;
1045
1046     powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*) CRT_DIR=/usr/lib64 ;;
1047   esac
1048
1049   case "$opsys" in
1050     hpux10-20) CRT_DIR=/lib ;;
1051   esac
1052
1053   ## Default is /usr/lib.
1054   test "X$CRT_DIR" = "X" && CRT_DIR=/usr/lib
1055
1056 else
1057
1058   ## Some platforms don't use any of these files, so it is not
1059   ## appropriate to put this test outside the if block.
1060   test -e $CRT_DIR/crtn.o || test -e $CRT_DIR/crt0.o || \
1061     AC_MSG_ERROR([crt*.o not found in specified location.])
1062
1063 fi
1064
1065 AC_SUBST(CRT_DIR)
1066
1067 LIB_MATH=-lm
1068 LIB_STANDARD=
1069 START_FILES=
1070
1071 case $opsys in
1072   cygwin )
1073     LIB_MATH=
1074     START_FILES='ecrt0.o'
1075     ;;
1076   darwin )
1077     ## Adding -lm confuses the dynamic linker, so omit it.
1078     LIB_MATH=
1079     START_FILES='pre-crt0.o'
1080     ;;
1081   freebsd )
1082     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1083     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1084     ;;
1085   gnu-linux | gnu-kfreebsd )
1086     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtn.o'
1087     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o'
1088     ;;
1089   hpux10-20 | hpux11 )
1090     LIB_STANDARD=-lc
1091     START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o'
1092     ;;
1093   netbsd | openbsd )
1094     if test -f $CRT_DIR/crti.o; then
1095         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1096         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1097     else
1098         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o'
1099         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crtbegin.o'
1100     fi
1101     ;;
1102 esac
1103
1104 AC_SUBST(LIB_MATH)
1105 AC_SUBST(START_FILES)
1106
1107 dnl This function definition taken from Gnome 2.0
1108 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1109 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1110 dnl also defines GSTUFF_PKG_ERRORS on error
1111 AC_DEFUN([PKG_CHECK_MODULES], [
1112   succeeded=no
1113
1114   AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1115
1116   if test "$PKG_CONFIG" = "no" ; then
1117      ifelse([$4], , [AC_MSG_ERROR([
1118       *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
1119   else
1120      PKG_CONFIG_MIN_VERSION=0.9.0
1121      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1122         AC_MSG_CHECKING(for $2)
1123
1124         if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD; then
1125             AC_MSG_RESULT(yes)
1126             succeeded=yes
1127
1128             AC_MSG_CHECKING($1_CFLAGS)
1129             $1_CFLAGS=`$PKG_CONFIG --cflags "$2"|sed -e 's,///*,/,g'`
1130             AC_MSG_RESULT($$1_CFLAGS)
1131
1132             AC_MSG_CHECKING($1_LIBS)
1133             $1_LIBS=`$PKG_CONFIG --libs "$2"|sed -e 's,///*,/,g'`
1134             AC_MSG_RESULT($$1_LIBS)
1135         else
1136             AC_MSG_RESULT(no)
1137             $1_CFLAGS=""
1138             $1_LIBS=""
1139             ## If we have a custom action on failure, don't print errors, but
1140             ## do set a variable so people can do so.
1141             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1142             ifelse([$4], ,echo $$1_PKG_ERRORS,)
1143         fi
1144
1145         AC_SUBST($1_CFLAGS)
1146         AC_SUBST($1_LIBS)
1147      else
1148         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1149         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1150      fi
1151   fi
1152
1153   if test $succeeded = yes; then
1154      ifelse([$3], , :, [$3])
1155   else
1156      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1157   fi
1158 ])
1159
1160
1161 if test "${with_sound}" != "no"; then
1162   # Sound support for GNU/Linux and the free BSDs.
1163   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h,
1164     have_sound_header=yes)
1165   # Emulation library used on NetBSD.
1166   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1167   AC_SUBST(LIBSOUND)
1168
1169   ALSA_REQUIRED=1.0.0
1170   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1171   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1172   if test $HAVE_ALSA = yes; then
1173     SAVE_CFLAGS="$CFLAGS"
1174     SAVE_LDFLAGS="$LDFLAGS"
1175     CFLAGS="$ALSA_CFLAGS $CFLAGS"
1176     LDFLAGS="$ALSA_LIBS $LDFLAGS"
1177     AC_TRY_COMPILE([#include <asoundlib.h>], [snd_lib_error_set_handler (0);],
1178                     emacs_alsa_normal=yes,
1179                     emacs_alsa_normal=no)
1180     if test "$emacs_alsa_normal" != yes; then
1181       AC_TRY_COMPILE([#include <alsa/asoundlib.h>],
1182                      [snd_lib_error_set_handler (0);],
1183                      emacs_alsa_subdir=yes,
1184                      emacs_alsa_subdir=no)
1185       if test "$emacs_alsa_subdir" != yes; then
1186         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1187       fi
1188       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1189     fi
1190
1191     CFLAGS="$SAVE_CFLAGS"
1192     LDFLAGS="$SAVE_LDFLAGS"
1193     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1194     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1195     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1196   fi
1197
1198   dnl Define HAVE_SOUND if we have sound support.  We know it works and
1199   dnl compiles only on the specified platforms.  For others, it
1200   dnl probably doesn't make sense to try.
1201   if test x$have_sound_header = xyes || test $HAVE_ALSA = yes; then
1202      case "$opsys" in
1203        dnl defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
1204        gnu-linux|freebsd|netbsd)
1205          AC_DEFINE(HAVE_SOUND, 1, [Define to 1 if you have sound support.])
1206          ;;
1207      esac
1208   fi
1209
1210   AC_SUBST(CFLAGS_SOUND)
1211 fi
1212
1213 dnl checks for header files
1214 AC_CHECK_HEADERS(sys/select.h sys/timeb.h sys/time.h unistd.h utime.h \
1215   linux/version.h sys/systeminfo.h termios.h limits.h string.h stdlib.h \
1216   stdio_ext.h fcntl.h strings.h coff.h pty.h sys/mman.h \
1217   sys/param.h sys/vlimit.h sys/resource.h locale.h sys/_mbstate_t.h \
1218   sys/utsname.h pwd.h utmp.h)
1219
1220 AC_MSG_CHECKING(if personality LINUX32 can be set)
1221 AC_TRY_COMPILE([#include <sys/personality.h>], [personality (PER_LINUX32)],
1222                emacs_cv_personality_linux32=yes,
1223                emacs_cv_personality_linux32=no)
1224 AC_MSG_RESULT($emacs_cv_personality_linux32)
1225
1226 if test $emacs_cv_personality_linux32 = yes; then
1227   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1228             [Define to 1 if personality LINUX32 can be set.])
1229 fi
1230
1231 dnl On Solaris 8 there's a compilation warning for term.h because
1232 dnl it doesn't define `bool'.
1233 AC_CHECK_HEADERS(term.h, , , -)
1234 AC_HEADER_STDC
1235 AC_HEADER_TIME
1236 AC_CHECK_DECLS([sys_siglist])
1237 if test $ac_cv_have_decl_sys_siglist != yes; then
1238   # For Tru64, at least:
1239   AC_CHECK_DECLS([__sys_siglist])
1240   if test $ac_cv_have_decl___sys_siglist = yes; then
1241     AC_DEFINE(sys_siglist, __sys_siglist,
1242               [Define to any substitute for sys_siglist.])
1243   fi
1244 fi
1245 AC_HEADER_SYS_WAIT
1246
1247 dnl Some systems have utime.h but don't declare the struct anyplace.
1248 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1249 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1250 #include <sys/time.h>
1251 #include <time.h>
1252 #else
1253 #ifdef HAVE_SYS_TIME_H
1254 #include <sys/time.h>
1255 #else
1256 #include <time.h>
1257 #endif
1258 #endif
1259 #ifdef HAVE_UTIME_H
1260 #include <utime.h>
1261 #endif], [static struct utimbuf x; x.actime = x.modtime;],
1262   emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1263 if test $emacs_cv_struct_utimbuf = yes; then
1264   AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if `struct utimbuf' is declared by <utime.h>.])
1265 fi
1266
1267 dnl checks for typedefs
1268 AC_TYPE_SIGNAL
1269
1270 dnl Check for speed_t typedef.
1271 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1272   [AC_TRY_COMPILE([#include <termios.h>], [speed_t x = 1;],
1273     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1274 if test $emacs_cv_speed_t = yes; then
1275   AC_DEFINE(HAVE_SPEED_T, 1,
1276            [Define to 1 if `speed_t' is declared by <termios.h>.])
1277 fi
1278
1279 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1280 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1281 #include <sys/time.h>
1282 #include <time.h>
1283 #else
1284 #ifdef HAVE_SYS_TIME_H
1285 #include <sys/time.h>
1286 #else
1287 #include <time.h>
1288 #endif
1289 #endif], [static struct timeval x; x.tv_sec = x.tv_usec;],
1290   emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1291 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1292 if test $emacs_cv_struct_timeval = yes; then
1293   AC_DEFINE(HAVE_TIMEVAL, 1, [Define to 1 if `struct timeval' is declared by <sys/time.h>.])
1294 fi
1295
1296 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1297 AC_TRY_COMPILE([#include <math.h>],
1298 [static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;],
1299   emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1300 HAVE_EXCEPTION=$emacs_cv_struct_exception
1301 if test $emacs_cv_struct_exception != yes; then
1302   AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1303 fi
1304
1305 AC_CHECK_HEADERS(sys/socket.h)
1306 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1307 #if HAVE_SYS_SOCKET_H
1308 #include <sys/socket.h>
1309 #endif])
1310
1311 dnl checks for structure members
1312 AC_STRUCT_TM
1313 AC_STRUCT_TIMEZONE
1314 AC_CHECK_MEMBER(struct tm.tm_gmtoff,
1315                 [AC_DEFINE(HAVE_TM_GMTOFF, 1,
1316                            [Define to 1 if `tm_gmtoff' is member of `struct tm'.])],,
1317                 [#include <time.h>])
1318 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1319                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1320                   struct ifreq.ifr_addr], , ,
1321                  [AC_INCLUDES_DEFAULT
1322 #if HAVE_SYS_SOCKET_H
1323 #include <sys/socket.h>
1324 #endif
1325 #if HAVE_NET_IF_H
1326 #include <net/if.h>
1327 #endif])
1328
1329 dnl checks for compiler characteristics
1330
1331 dnl Testing __STDC__ to determine prototype support isn't good enough.
1332 dnl DEC C, for instance, doesn't define it with default options, and
1333 dnl is used on 64-bit systems (OSF Alphas).  Similarly for volatile
1334 dnl and void *.
1335 AC_C_PROTOTYPES
1336 AC_C_VOLATILE
1337 AC_C_CONST
1338 dnl This isn't useful because we can't turn on use of `inline' unless
1339 dnl the compiler groks `extern inline'.
1340 dnl AC_C_INLINE
1341 AC_CACHE_CHECK([for void * support], emacs_cv_void_star,
1342   [AC_TRY_COMPILE(, [void * foo;],
1343                    emacs_cv_void_star=yes, emacs_cv_void_star=no)])
1344 if test $emacs_cv_void_star = yes; then
1345   AC_DEFINE(POINTER_TYPE, void)
1346 else
1347   AC_DEFINE(POINTER_TYPE, char)
1348 fi
1349 AH_TEMPLATE(POINTER_TYPE,
1350             [Define as `void' if your compiler accepts `void *'; otherwise
1351              define as `char'.])dnl
1352
1353
1354
1355 dnl This could be used for targets which can have both byte sexes.
1356 dnl We could presumably replace the hardwired WORDS_BIG_ENDIAN generally.
1357 dnl AC_C_BIGENDIAN
1358
1359 dnl check for Make feature
1360 AC_PROG_MAKE_SET
1361
1362 DEPFLAGS=
1363 MKDEPDIR=":"
1364 deps_frag=deps.mk
1365 dnl check for GNU Make if we have GCC and autodepend is on.
1366 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1367    AC_MSG_CHECKING([whether we are using GNU Make])
1368    HAVE_GNU_MAKE=no
1369    testval=`make --version 2>/dev/null | grep 'GNU Make'`
1370    if test "x$testval" != x; then
1371       HAVE_GNU_MAKE=yes
1372    else
1373       ac_enable_autodepend=no
1374    fi
1375    AC_MSG_RESULT([$HAVE_GNU_MAKE])
1376    if test $HAVE_GNU_MAKE = yes; then
1377       AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1378       SAVE_CFLAGS="$CFLAGS"
1379       CFLAGS="$CFLAGS -MMD -MF deps.d"
1380       AC_TRY_COMPILE([], [], , ac_enable_autodepend=no)
1381       CFLAGS="$SAVE_CFLAGS"
1382       test -f deps.d || ac_enable_autodepend=no
1383       rm -rf deps.d
1384       AC_MSG_RESULT([$ac_enable_autodepend])
1385    fi
1386    if test $ac_enable_autodepend = yes; then
1387       DEPFLAGS='-MMD -MF ${DEPDIR}/$*.d'
1388       ## In parallel builds, another make might create depdir between
1389       ## the first test and mkdir, so stick another test on the end.
1390       ## Or use mkinstalldirs?  mkdir -p is not portable.
1391       MKDEPDIR='test -d ${DEPDIR} || mkdir ${DEPDIR} || test -d ${DEPDIR}'
1392       deps_frag=autodeps.mk
1393    fi
1394 fi
1395 deps_frag=$srcdir/src/$deps_frag
1396 AC_SUBST(MKDEPDIR)
1397 AC_SUBST(DEPFLAGS)
1398 AC_SUBST_FILE(deps_frag)
1399
1400
1401 dnl checks for operating system services
1402 AC_SYS_LONG_FILE_NAMES
1403
1404 #### Choose a window system.
1405
1406 AC_PATH_X
1407 if test "$no_x" = yes; then
1408   window_system=none
1409 else
1410   window_system=x11
1411 fi
1412
1413 ## Workaround for bug in autoconf <= 2.62.
1414 ## http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01551.html
1415 ## No need to do anything special for these standard directories.
1416 if test -n "${x_libraries}" && test x"${x_libraries}" != xNONE; then
1417
1418    x_libraries=`echo :${x_libraries}: | sed -e 's|:/usr/lib64:|:|g' -e 's|:/lib64:|:|g' -e 's|^:||' -e 's|:$||'`
1419
1420 fi
1421
1422 LD_SWITCH_X_SITE_AUX=
1423 LD_SWITCH_X_SITE_AUX_RPATH=
1424 if test "${x_libraries}" != NONE; then
1425   if test -n "${x_libraries}"; then
1426     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1427     LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
1428     LD_SWITCH_X_SITE_AUX_RPATH=`echo ${LD_SWITCH_X_SITE_AUX} | sed -e 's/-R/-Wl,-rpath,/'`
1429   fi
1430   x_default_search_path=""
1431   x_search_path=${x_libraries}
1432   if test -z "${x_search_path}"; then
1433     x_search_path=/usr/lib
1434   fi
1435   for x_library in `echo ${x_search_path}: | \
1436                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1437     x_search_path="\
1438 ${x_library}/X11/%L/%T/%N%C%S:\
1439 ${x_library}/X11/%l/%T/%N%C%S:\
1440 ${x_library}/X11/%T/%N%C%S:\
1441 ${x_library}/X11/%L/%T/%N%S:\
1442 ${x_library}/X11/%l/%T/%N%S:\
1443 ${x_library}/X11/%T/%N%S"
1444     if test x"${x_default_search_path}" = x; then
1445       x_default_search_path=${x_search_path}
1446     else
1447       x_default_search_path="${x_search_path}:${x_default_search_path}"
1448     fi
1449   done
1450 fi
1451 AC_SUBST(LD_SWITCH_X_SITE_AUX)
1452 AC_SUBST(LD_SWITCH_X_SITE_AUX_RPATH)
1453
1454 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1455   C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"`
1456 fi
1457
1458 if test x"${x_includes}" = x; then
1459   bitmapdir=/usr/include/X11/bitmaps
1460 else
1461   # accumulate include directories that have X11 bitmap subdirectories
1462   bmd_acc="dummyval"
1463   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1464     if test -d "${bmd}/X11/bitmaps"; then
1465       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1466     fi
1467     if test -d "${bmd}/bitmaps"; then
1468       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1469     fi
1470   done
1471   if test ${bmd_acc} != "dummyval"; then
1472     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1473   fi
1474 fi
1475
1476 HAVE_NS=no
1477 NS_IMPL_COCOA=no
1478 NS_IMPL_GNUSTEP=no
1479 tmp_CPPFLAGS="$CPPFLAGS"
1480 tmp_CFLAGS="$CFLAGS"
1481 CPPFLAGS="$CPPFLAGS -x objective-c"
1482 CFLAGS="$CFLAGS -x objective-c"
1483 TEMACS_LDFLAGS2="\${LDFLAGS}"
1484 dnl I don't think it's especially important, but src/Makefile.in
1485 dnl (now the only user of ns_appdir) used to go to the trouble of adding a
1486 dnl trailing "/" to it, so now we do it here.
1487 if test "${with_ns}" != no; then
1488   if test "${opsys}" = darwin; then
1489      NS_IMPL_COCOA=yes
1490      ns_appdir=`pwd`/nextstep/Emacs.app/
1491      ns_appbindir=${ns_appdir}Contents/MacOS/
1492      ns_appresdir=${ns_appdir}Contents/Resources
1493      ns_appsrc=${srcdir}/nextstep/Cocoa/Emacs.base
1494   elif test -f $GNUSTEP_CONFIG_FILE; then
1495      NS_IMPL_GNUSTEP=yes
1496      ns_appdir=`pwd`/nextstep/Emacs.app/
1497      ns_appbindir=${ns_appdir}
1498      ns_appresdir=${ns_appdir}Resources
1499      ns_appsrc=${srcdir}/nextstep/GNUstep/Emacs.base
1500      dnl FIXME sourcing this several times in subshells seems inefficient.
1501      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1502      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1503      dnl I seemed to need these as well with GNUstep-startup 0.25.
1504      GNUSTEP_LOCAL_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_HEADERS)"
1505      GNUSTEP_LOCAL_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_LIBRARIES)"
1506      test "x${GNUSTEP_LOCAL_HEADERS}" != "x" && \
1507        GNUSTEP_LOCAL_HEADERS="-I${GNUSTEP_LOCAL_HEADERS}"
1508      test "x${GNUSTEP_LOCAL_LIBRARIES}" != "x" && \
1509        GNUSTEP_LOCAL_LIBRARIES="-L${GNUSTEP_LOCAL_LIBRARIES}"
1510      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1511      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1512      REAL_CFLAGS="$REAL_CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1513      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES}"
1514      LIB_STANDARD=
1515      START_FILES=
1516      TEMACS_LDFLAGS2=
1517   fi
1518   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1519                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1520   files are missing or cannot be compiled.])])
1521   NS_HAVE_NSINTEGER=yes
1522   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1523                                      [NSInteger i;])],
1524                     ns_have_nsinteger=yes,
1525                     ns_have_nsinteger=no)
1526   if test $ns_have_nsinteger = no; then
1527     NS_HAVE_NSINTEGER=no
1528   fi
1529 fi
1530 AC_SUBST(TEMACS_LDFLAGS2)
1531
1532 ns_frag=/dev/null
1533 NS_OBJ=
1534 NS_SUPPORT=
1535 if test "${HAVE_NS}" = yes; then
1536   window_system=nextstep
1537   with_xft=no
1538   # set up packaging dirs
1539   exec_prefix=${ns_appbindir}
1540   libexecdir=${ns_appbindir}/libexec
1541   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1542      prefix=${ns_appresdir}
1543   fi
1544   ns_frag=$srcdir/src/ns.mk
1545   NS_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o nsfont.o fontset.o fringe.o image.o"
1546   NS_SUPPORT="\${lispsource}emacs-lisp/easymenu.elc \${lispsource}term/ns-win.elc"
1547 fi
1548 CFLAGS="$tmp_CFLAGS"
1549 CPPFLAGS="$tmp_CPPFLAGS"
1550 AC_SUBST(NS_OBJ)
1551 AC_SUBST(NS_SUPPORT)
1552 AC_SUBST(LIB_STANDARD)
1553 AC_SUBST_FILE(ns_frag)
1554
1555 case "${window_system}" in
1556   x11 )
1557     HAVE_X_WINDOWS=yes
1558     HAVE_X11=yes
1559     case "${with_x_toolkit}" in
1560       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1561       motif ) USE_X_TOOLKIT=MOTIF ;;
1562       gtk ) with_gtk=yes
1563 dnl Dont set this for GTK.  A lot of tests below assumes Xt when
1564 dnl USE_X_TOOLKIT is set.
1565             USE_X_TOOLKIT=none ;;
1566       gtk3 ) with_gtk3=yes
1567              USE_X_TOOLKIT=none ;;
1568       no ) USE_X_TOOLKIT=none ;;
1569 dnl If user did not say whether to use a toolkit, make this decision later:
1570 dnl use the toolkit if we have gtk, or X11R5 or newer.
1571       * ) USE_X_TOOLKIT=maybe ;;
1572     esac
1573   ;;
1574   nextstep | none )
1575     HAVE_X_WINDOWS=no
1576     HAVE_X11=no
1577     USE_X_TOOLKIT=none
1578   ;;
1579 esac
1580
1581 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1582    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1583    if test "$HAVE_XSERVER" = true ||
1584       test -n "$DISPLAY" ||
1585       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1586         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1587 were found.  You should install the relevant development files for X
1588 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1589 sure you have development files for image handling, i.e.
1590 tiff, gif, jpeg, png and xpm.
1591 If you are sure you want Emacs compiled without X window support, pass
1592   --without-x
1593 to configure.])
1594    fi
1595 fi
1596
1597 ### If we're using X11, we should use the X menu package.
1598 HAVE_MENUS=no
1599 case ${HAVE_X11} in
1600   yes ) HAVE_MENUS=yes ;;
1601 esac
1602
1603 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1604 # Assume not, until told otherwise.
1605 GNU_MALLOC=yes
1606 doug_lea_malloc=yes
1607 AC_CHECK_FUNC(malloc_get_state, ,doug_lea_malloc=no)
1608 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
1609 AC_CACHE_CHECK(whether __after_morecore_hook exists,
1610                emacs_cv_var___after_morecore_hook,
1611 [AC_TRY_LINK([extern void (* __after_morecore_hook)();],[__after_morecore_hook = 0],
1612   emacs_cv_var___after_morecore_hook=yes,
1613   emacs_cv_var___after_morecore_hook=no)])
1614 if test $emacs_cv_var___after_morecore_hook = no; then
1615   doug_lea_malloc=no
1616 fi
1617
1618
1619 dnl See comments in aix4-2.h about maybe using system malloc there.
1620 system_malloc=no
1621 case "$opsys" in
1622   ## darwin ld insists on the use of malloc routines in the System framework.
1623   darwin|sol2-10) system_malloc=yes ;;
1624 esac
1625
1626 if test "${system_malloc}" = "yes"; then
1627   AC_DEFINE(SYSTEM_MALLOC, 1, [Define to use system malloc.])
1628   GNU_MALLOC=no
1629   GNU_MALLOC_reason="
1630     (The GNU allocators don't work with this system configuration.)"
1631   GMALLOC_OBJ=
1632   VMLIMIT_OBJ=
1633 else
1634   test "$doug_lea_malloc" != "yes" && GMALLOC_OBJ=gmalloc.o
1635   VMLIMIT_OBJ=vm-limit.o
1636 fi
1637 AC_SUBST(GMALLOC_OBJ)
1638 AC_SUBST(VMLIMIT_OBJ)
1639
1640 if test "$doug_lea_malloc" = "yes" ; then
1641   if test "$GNU_MALLOC" = yes ; then
1642     GNU_MALLOC_reason="
1643       (Using Doug Lea's new malloc from the GNU C Library.)"
1644   fi
1645   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1646             [Define to 1 if you are using the GNU C Library.])
1647
1648   ## Use mmap directly for allocating larger buffers.
1649   ## FIXME this comes from src/s/{gnu,gnu-linux}.h:
1650   ## #ifdef DOUG_LEA_MALLOC; #undef REL_ALLOC; #endif
1651   ## Does the AC_FUNC_MMAP test below make this check unecessary?
1652   case "$opsys" in
1653     gnu*) REL_ALLOC=no ;;
1654   esac
1655 fi
1656
1657 if test x"${REL_ALLOC}" = x; then
1658   REL_ALLOC=${GNU_MALLOC}
1659 fi
1660
1661 use_mmap_for_buffers=no
1662 case "$opsys" in
1663   freebsd|irix6-5) use_mmap_for_buffers=yes ;;
1664 esac
1665
1666 AC_FUNC_MMAP
1667 if test $use_mmap_for_buffers = yes; then
1668   AC_DEFINE(USE_MMAP_FOR_BUFFERS, 1, [Define to use mmap to allocate buffer text.])
1669   REL_ALLOC=no
1670 fi
1671
1672 LIBS="$LIBS_SYSTEM $LIBS"
1673
1674 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1675 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1676 AC_CHECK_LIB(dnet, dnet_ntoa)
1677 dnl This causes -lresolv to get used in subsequent tests,
1678 dnl which causes failures on some systems such as HPUX 9.
1679 dnl AC_CHECK_LIB(resolv, gethostbyname)
1680
1681 dnl FIXME replace main with a function we actually want from this library.
1682 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1683
1684 AC_CHECK_LIB(pthreads, cma_open)
1685
1686 ## Note: when using cpp in s/aix4.2.h, this definition depended on
1687 ## HAVE_LIBPTHREADS.  That was not defined earlier in configure when
1688 ## the system file was sourced.  Hence the value of LIBS_SYSTEM
1689 ## added to LIBS in configure would never contain the pthreads part,
1690 ## but the value used in Makefiles might.  FIXME?
1691 ##
1692 ## -lpthreads seems to be necessary for Xlib in X11R6, and should
1693 ## be harmless on older versions of X where it happens to exist.
1694 test "$opsys" = "aix4-2" && \
1695   test $ac_cv_lib_pthreads_cma_open = yes && \
1696   LIBS_SYSTEM="$LIBS_SYSTEM -lpthreads"
1697
1698 dnl Check for need for bigtoc support on IBM AIX
1699
1700 case ${host_os} in
1701 aix*)
1702   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1703     case $GCC in
1704     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1705     *) gdb_cv_bigtoc=-bbigtoc ;;
1706     esac
1707
1708     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1709     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1710   ])
1711   ;;
1712 esac
1713
1714 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1715 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1716 # REAL_CPPFLAGS later on.
1717
1718 REAL_CPPFLAGS="$CPPFLAGS"
1719
1720 if test "${HAVE_X11}" = "yes"; then
1721   DEFS="$C_SWITCH_X_SITE $DEFS"
1722   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1723   LIBS="-lX11 $LIBS"
1724   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1725   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1726
1727   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1728   # This is handled by LD_SWITCH_X_SITE_AUX during the real build,
1729   # but it's more convenient here to set LD_RUN_PATH
1730   # since this also works on hosts that don't understand LD_SWITCH_X_SITE_AUX.
1731   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1732     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1733     export LD_RUN_PATH
1734   fi
1735
1736   if test "${opsys}" = "gnu-linux"; then
1737     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1738     AC_TRY_LINK([],
1739      [XOpenDisplay ("foo");],
1740      [xlinux_first_failure=no],
1741      [xlinux_first_failure=yes])
1742     if test "${xlinux_first_failure}" = "yes"; then
1743       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1744       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1745       OLD_CPPFLAGS="$CPPFLAGS"
1746       OLD_LIBS="$LIBS"
1747       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1748       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1749       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1750       LIBS="$LIBS -b i486-linuxaout"
1751       AC_TRY_LINK([],
1752        [XOpenDisplay ("foo");],
1753        [xlinux_second_failure=no],
1754        [xlinux_second_failure=yes])
1755       if test "${xlinux_second_failure}" = "yes"; then
1756         # If we get the same failure with -b, there is no use adding -b.
1757         # So take it out.  This plays safe.
1758         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1759         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1760         CPPFLAGS="$OLD_CPPFLAGS"
1761         LIBS="$OLD_LIBS"
1762         AC_MSG_RESULT(no)
1763       else
1764         AC_MSG_RESULT(yes)
1765       fi
1766     else
1767       AC_MSG_RESULT(no)
1768     fi
1769   fi
1770
1771   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1772   # header files included from there.
1773   AC_MSG_CHECKING(for Xkb)
1774   AC_TRY_LINK([#include <X11/Xlib.h>
1775 #include <X11/XKBlib.h>],
1776         [XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);],
1777         emacs_xkb=yes, emacs_xkb=no)
1778   AC_MSG_RESULT($emacs_xkb)
1779   if test $emacs_xkb = yes; then
1780     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1781   fi
1782
1783   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1784 XScreenNumberOfScreen XSetWMProtocols)
1785 fi
1786
1787 if test "${window_system}" = "x11"; then
1788   AC_MSG_CHECKING(X11 version 6)
1789   AC_CACHE_VAL(emacs_cv_x11_version_6,
1790   [AC_TRY_LINK([#include <X11/Xlib.h>],
1791 [#if XlibSpecificationRelease < 6
1792 fail;
1793 #endif
1794 ], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1795   if test $emacs_cv_x11_version_6 = yes; then
1796     AC_MSG_RESULT(6 or newer)
1797     AC_DEFINE(HAVE_X11R6, 1,
1798               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1799     AC_DEFINE(HAVE_X_I18N, 1, [Define if you have usable i18n support.])
1800     ## inoue@ainet.or.jp says Solaris has a bug related to X11R6-style
1801     ## XIM support.
1802     case "$opsys" in
1803       sol2-*) : ;;
1804       *) AC_DEFINE(HAVE_X11R6_XIM, 1,
1805            [Define if you have usable X11R6-style XIM support.])
1806          ;;
1807     esac
1808   else
1809     AC_MSG_RESULT(before 6)
1810   fi
1811 fi
1812
1813
1814 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1815 HAVE_RSVG=no
1816 if test "${HAVE_X11}" = "yes" || test "${NS_IMPL_GNUSTEP}" = "yes"; then
1817   if test "${with_rsvg}" != "no"; then
1818     RSVG_REQUIRED=2.11.0
1819     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1820
1821     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, :, :)
1822     AC_SUBST(RSVG_CFLAGS)
1823     AC_SUBST(RSVG_LIBS)
1824
1825     if test ".${RSVG_CFLAGS}" != "."; then
1826       HAVE_RSVG=yes
1827       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1828       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1829       LIBS="$RSVG_LIBS $LIBS"
1830     fi
1831   fi
1832 fi
1833
1834
1835 HAVE_GTK=no
1836 if test "${with_gtk3}" = "yes"; then
1837   GLIB_REQUIRED=2.6
1838   GTK_REQUIRED=2.90
1839   GTK_MODULES="gtk+-3.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1840
1841   dnl Checks for libraries.
1842   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1843   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1844      AC_MSG_ERROR($GTK_PKG_ERRORS)
1845   fi
1846 fi
1847
1848 if test "$pkg_check_gtk" != "yes"; then
1849   HAVE_GTK=no
1850 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
1851   GLIB_REQUIRED=2.6
1852   GTK_REQUIRED=2.6
1853   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1854
1855   dnl Checks for libraries.
1856   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1857   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1858      AC_MSG_ERROR($GTK_PKG_ERRORS)
1859   fi
1860 fi
1861 fi
1862
1863 GTK_OBJ=
1864 if test x"$pkg_check_gtk" = xyes; then
1865
1866   AC_SUBST(GTK_CFLAGS)
1867   AC_SUBST(GTK_LIBS)
1868   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1869   CFLAGS="$CFLAGS $GTK_CFLAGS"
1870   LIBS="$GTK_LIBS $LIBS"
1871   dnl Try to compile a simple GTK program.
1872   GTK_COMPILES=no
1873   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
1874   if test "${GTK_COMPILES}" != "yes"; then
1875     if test "$USE_X_TOOLKIT" != "maybe"; then
1876       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
1877     fi
1878   else
1879     HAVE_GTK=yes
1880     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
1881     GTK_OBJ=gtkutil.o
1882     USE_X_TOOLKIT=none
1883     if $PKG_CONFIG --atleast-version=2.10 gtk+-2.0; then
1884       :
1885     else
1886       AC_MSG_WARN([[Your version of Gtk+ will have problems with
1887        closing open displays.  This is no problem if you just use
1888        one display, but if you use more than one and close one of them
1889        Emacs may crash.]])
1890       sleep 3
1891     fi
1892   fi
1893
1894 fi
1895 AC_SUBST(GTK_OBJ)
1896
1897
1898 if test "${HAVE_GTK}" = "yes"; then
1899
1900   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
1901   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
1902   if test "$with_toolkit_scroll_bars" != no; then
1903     with_toolkit_scroll_bars=yes
1904   fi
1905
1906   dnl  Check if we have the old file selection dialog declared and
1907   dnl  in the link library.  In 2.x it may be in the library,
1908   dnl  but not declared if deprecated featured has been selected out.
1909   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
1910   HAVE_GTK_FILE_SELECTION=no
1911   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
1912                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
1913 #include <gtk/gtk.h>])
1914   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
1915     AC_CHECK_FUNCS(gtk_file_selection_new)
1916   fi
1917
1918   dnl Check if pthreads are available.  Emacs only needs this when using
1919   dnl gtk_file_chooser under Gnome.
1920     HAVE_GTK_AND_PTHREAD=no
1921     AC_CHECK_HEADERS(pthread.h)
1922     if test "$ac_cv_header_pthread_h"; then
1923       AC_CHECK_LIB(pthread, pthread_self, HAVE_GTK_AND_PTHREAD=yes)
1924     fi
1925     if test "$HAVE_GTK_AND_PTHREAD" = yes; then
1926       case "${canonical}" in
1927         *-hpux*) ;;
1928         *) GTK_LIBS="$GTK_LIBS -lpthread" ;;
1929       esac
1930       AC_DEFINE(HAVE_GTK_AND_PTHREAD, 1,
1931                [Define to 1 if you have GTK and pthread (-lpthread).])
1932     fi
1933
1934   dnl Check for functions introduced in 2.14 and later.
1935   AC_CHECK_FUNCS(gtk_widget_get_window gtk_widget_set_has_window \
1936                  gtk_dialog_get_action_area gtk_widget_get_sensitive \
1937                  gtk_widget_get_mapped gtk_adjustment_get_page_size \
1938                  gtk_orientable_set_orientation)
1939
1940 fi
1941
1942 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
1943 dnl other platforms.  Support for higher D-Bus versions than 1.0 is
1944 dnl also not configured.
1945 HAVE_DBUS=no
1946 DBUS_OBJ=
1947 if test "${with_dbus}" = "yes"; then
1948    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
1949    if test "$HAVE_DBUS" = yes; then
1950      LIBS="$LIBS $DBUS_LIBS"
1951      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
1952      AC_CHECK_FUNCS([dbus_watch_get_unix_fd])
1953      DBUS_OBJ=dbusbind.o
1954    fi
1955 fi
1956 AC_SUBST(DBUS_OBJ)
1957
1958 dnl GConf has been tested under GNU/Linux only.
1959 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
1960 HAVE_GCONF=no
1961 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
1962    PKG_CHECK_MODULES(GCONF, gconf-2.0 >= 2.13, HAVE_GCONF=yes, HAVE_GCONF=no)
1963    if test "$HAVE_GCONF" = yes; then
1964       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
1965    fi
1966 fi
1967
1968 dnl SELinux is available for GNU/Linux only.
1969 HAVE_LIBSELINUX=no
1970 LIBSELINUX_LIBS=
1971 if test "${with_selinux}" = "yes"; then
1972    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
1973    if test "$HAVE_LIBSELINUX" = yes; then
1974       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
1975       LIBSELINUX_LIBS=-lselinux
1976    fi
1977 fi
1978 AC_SUBST(LIBSELINUX_LIBS)
1979
1980 dnl Do not put whitespace before the #include statements below.
1981 dnl Older compilers (eg sunos4 cc) choke on it.
1982 HAVE_XAW3D=no
1983 LUCID_LIBW=
1984 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
1985   if test "$with_xaw3d" != no; then
1986     AC_MSG_CHECKING(for xaw3d)
1987     AC_CACHE_VAL(emacs_cv_xaw3d,
1988     [AC_TRY_LINK([
1989 #include <X11/Intrinsic.h>
1990 #include <X11/Xaw3d/Simple.h>],
1991       [],
1992       emacs_cv_xaw3d=yes,
1993       emacs_cv_xaw3d=no)])
1994   else
1995     emacs_cv_xaw3d=no
1996   fi
1997   if test $emacs_cv_xaw3d = yes; then
1998     AC_MSG_RESULT([yes; using Lucid toolkit])
1999     USE_X_TOOLKIT=LUCID
2000     HAVE_XAW3D=yes
2001     LUCID_LIBW=-lXaw3d
2002     AC_DEFINE(HAVE_XAW3D, 1,
2003               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
2004   else
2005     AC_MSG_RESULT(no)
2006     AC_MSG_CHECKING(for libXaw)
2007     AC_CACHE_VAL(emacs_cv_xaw,
2008     [AC_TRY_LINK([
2009 #include <X11/Intrinsic.h>
2010 #include <X11/Xaw/Simple.h>],
2011       [],
2012       emacs_cv_xaw=yes,
2013       emacs_cv_xaw=no)])
2014     if test $emacs_cv_xaw = yes; then
2015       AC_MSG_RESULT([yes; using Lucid toolkit])
2016       USE_X_TOOLKIT=LUCID
2017       LUCID_LIBW=-lXaw
2018     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
2019       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
2020     else
2021       AC_MSG_RESULT([no; do not use toolkit by default])
2022       USE_X_TOOLKIT=none
2023     fi
2024   fi
2025 fi
2026
2027 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
2028
2029 LIBXTR6=
2030 if test "${USE_X_TOOLKIT}" != "none"; then
2031   AC_MSG_CHECKING(X11 toolkit version)
2032   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2033   [AC_TRY_LINK([#include <X11/Intrinsic.h>],
2034 [#if XtSpecificationRelease < 6
2035 fail;
2036 #endif
2037 ], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2038   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2039   if test $emacs_cv_x11_toolkit_version_6 = yes; then
2040     AC_MSG_RESULT(6 or newer)
2041     AC_DEFINE(HAVE_X11XTR6, 1,
2042               [Define to 1 if you have the X11R6 or newer version of Xt.])
2043     LIBXTR6="-lSM -lICE"
2044     case "$opsys" in
2045       ## Use libw.a along with X11R6 Xt.
2046       unixware) LIBXTR6="$LIBXTR6 -lw" ;;
2047     esac
2048   else
2049     AC_MSG_RESULT(before 6)
2050   fi
2051
2052 dnl If using toolkit, check whether libXmu.a exists.
2053 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2054   OLDLIBS="$LIBS"
2055   if test x$HAVE_X11XTR6 = xyes; then
2056     LIBS="-lXt -lSM -lICE $LIBS"
2057   else
2058     LIBS="-lXt $LIBS"
2059   fi
2060   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
2061   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
2062 fi
2063 AC_SUBST(LIBXTR6)
2064
2065 dnl FIXME the logic here seems weird, but this is what cpp was doing.
2066 dnl Why not just test for libxmu in the normal way?
2067 LIBXMU=-lXmu
2068 case "$machine" in
2069   ## These machines don't supply Xmu.
2070   hpux* | aix4-2 )
2071     test "X$ac_cv_lib_Xmu_XmuConvertStandardSelection" != "Xyes" && LIBXMU=
2072     ;;
2073 esac
2074 AC_SUBST(LIBXMU)
2075
2076 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
2077 if test "${HAVE_X11}" = "yes"; then
2078   if test "${USE_X_TOOLKIT}" != "none"; then
2079     AC_CHECK_LIB(Xext, XShapeQueryExtension)
2080   fi
2081 fi
2082
2083 LIBXP=
2084 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2085   AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
2086   [AC_TRY_COMPILE([#include <Xm/Xm.h>],
2087     [#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2088 int x = 5;
2089 #else
2090 Motif version prior to 2.1.
2091 #endif],
2092     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2093   if test $emacs_cv_motif_version_2_1 = yes; then
2094     AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
2095   else
2096     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2097     # We put this in CFLAGS temporarily to precede other -I options
2098     # that might be in CFLAGS temporarily.
2099     # We put this in CPPFLAGS where it precedes the other -I options.
2100     OLD_CPPFLAGS=$CPPFLAGS
2101     OLD_CFLAGS=$CFLAGS
2102     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2103     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2104     [AC_TRY_COMPILE([#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>],
2105       [int x = 5;],
2106       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2107     if test $emacs_cv_lesstif = yes; then
2108       # Make sure this -I option remains in CPPFLAGS after it is set
2109       # back to REAL_CPPFLAGS.
2110       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
2111       # have those other -I options anyway.  Ultimately, having this
2112       # directory ultimately in CPPFLAGS will be enough.
2113       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
2114       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
2115     else
2116       CFLAGS=$OLD_CFLAGS
2117       CPPFLAGS=$OLD_CPPFLAGS
2118     fi
2119   fi
2120 fi
2121
2122 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2123 dnl using Motif or Xaw3d is available, and unless
2124 dnl --with-toolkit-scroll-bars=no was specified.
2125
2126 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2127             [Define to 1 if we should use toolkit scroll bars.])dnl
2128 USE_TOOLKIT_SCROLL_BARS=no
2129 if test "${with_toolkit_scroll_bars}" != "no"; then
2130   if test "${USE_X_TOOLKIT}" != "none"; then
2131     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2132       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2133       HAVE_XAW3D=no
2134       USE_TOOLKIT_SCROLL_BARS=yes
2135     elif test "${HAVE_XAW3D}" = "yes"; then
2136       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2137       USE_TOOLKIT_SCROLL_BARS=yes
2138     fi
2139   elif test "${HAVE_GTK}" = "yes"; then
2140     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2141     USE_TOOLKIT_SCROLL_BARS=yes
2142   elif test "${HAVE_NS}" = "yes"; then
2143     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2144     USE_TOOLKIT_SCROLL_BARS=yes
2145   fi
2146 fi
2147
2148 dnl See if XIM is available.
2149 AC_TRY_COMPILE([
2150           #include <X11/Xlib.h>
2151           #include <X11/Xresource.h>],
2152          [XIMProc  callback;],
2153          [HAVE_XIM=yes
2154          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
2155          HAVE_XIM=no)
2156
2157 dnl `--with-xim' now controls only the initial value of use_xim at run time.
2158
2159 if test "${with_xim}" != "no"; then
2160   AC_DEFINE(USE_XIM, 1,
2161             [Define to 1 if we should use XIM, if it is available.])
2162 fi
2163
2164
2165 if test "${HAVE_XIM}" != "no"; then
2166   late_CFLAGS=$CFLAGS
2167   if test "$GCC" = yes; then
2168     CFLAGS="$CFLAGS --pedantic-errors"
2169   fi
2170   AC_TRY_COMPILE([
2171 #include <X11/Xlib.h>
2172 #include <X11/Xresource.h>],
2173 [Display *display;
2174 XrmDatabase db;
2175 char *res_name;
2176 char *res_class;
2177 XIMProc  callback;
2178 XPointer *client_data;
2179 #ifndef __GNUC__
2180 /* If we're not using GCC, it's probably not XFree86, and this is
2181    probably right, but we can't use something like --pedantic-errors.  */
2182 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
2183                                            char*, XIMProc, XPointer*);
2184 #endif
2185 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
2186    client_data);],
2187     [emacs_cv_arg6_star=yes])
2188   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
2189          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
2190 either XPointer or XPointer*.])dnl
2191   if test "$emacs_cv_arg6_star" = yes; then
2192     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
2193   else
2194     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
2195   fi
2196   CFLAGS=$late_CFLAGS
2197 fi
2198
2199 ### Start of font-backend (under any platform) section.
2200 # (nothing here yet -- this is a placeholder)
2201 ### End of font-backend (under any platform) section.
2202
2203 ### Start of font-backend (under X11) section.
2204 if test "${HAVE_X11}" = "yes"; then
2205    PKG_CHECK_MODULES(FONTCONFIG, fontconfig >= 2.2.0, HAVE_FC=yes, HAVE_FC=no)
2206
2207    ## Use -lXft if available, unless `--with-xft=no'.
2208    HAVE_XFT=maybe
2209     if test "${HAVE_FC}" = "no" || test "x${with_x}" = "xno"; then
2210       with_xft="no";
2211     fi
2212     if test "x${with_xft}" != "xno"; then
2213
2214       PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
2215       ## Because xftfont.c uses XRenderQueryExtension, we also
2216       ## need to link to -lXrender.
2217       HAVE_XRENDER=no
2218       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
2219       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
2220         OLD_CPPFLAGS="$CPPFLAGS"
2221         OLD_CFLAGS="$CFLAGS"
2222         OLD_LIBS="$LIBS"
2223         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
2224         CFLAGS="$CFLAGS $XFT_CFLAGS"
2225         XFT_LIBS="-lXrender $XFT_LIBS"
2226         LIBS="$XFT_LIBS $LIBS"
2227         AC_CHECK_HEADER(X11/Xft/Xft.h,
2228           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS))
2229
2230         if test "${HAVE_XFT}" = "yes"; then
2231           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
2232             AC_SUBST(XFT_LIBS)
2233           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
2234         else
2235           CPPFLAGS="$OLD_CPPFLAGS"
2236           CFLAGS="$OLD_CFLAGS"
2237           LIBS="$OLD_LIBS"
2238         fi                        # "${HAVE_XFT}" = "yes"
2239       fi                          # "$HAVE_XFT" != no
2240     fi                            # "x${with_xft}" != "xno"
2241
2242     dnl For the "Does Emacs use" message at the end.
2243     if test "$HAVE_XFT" != "yes"; then
2244        HAVE_XFT=no
2245     fi
2246
2247
2248     HAVE_FREETYPE=no
2249     ## We used to allow building with FreeType and without Xft.
2250     ## However, the ftx font backend driver is not in good shape.
2251     if test "${HAVE_XFT}" = "yes"; then
2252       dnl As we use Xft, we anyway use freetype.
2253       dnl There's no need for additional CFLAGS and LIBS.
2254       HAVE_FREETYPE=yes
2255       FONTCONFIG_CFLAGS=
2256       FONTCONFIG_LIBS=
2257     fi
2258
2259     HAVE_LIBOTF=no
2260     if test "${HAVE_FREETYPE}" = "yes"; then
2261       AC_DEFINE(HAVE_FREETYPE, 1,
2262                 [Define to 1 if using the freetype and fontconfig libraries.])
2263       if test "${with_libotf}" != "no"; then
2264         PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
2265                           HAVE_LIBOTF=no)
2266         if test "$HAVE_LIBOTF" = "yes"; then
2267           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
2268           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
2269                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
2270                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
2271           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
2272             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
2273                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
2274           fi
2275         fi
2276       fi
2277     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
2278     dnl Does the new font backend require it, or can it work without it?
2279     fi
2280
2281     HAVE_M17N_FLT=no
2282     if test "${HAVE_LIBOTF}" = yes; then
2283       if test "${with_m17n_flt}" != "no"; then
2284         PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
2285         if test "$HAVE_M17N_FLT" = "yes"; then
2286           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
2287         fi
2288       fi
2289     fi
2290 else
2291     HAVE_XFT=no
2292     HAVE_FREETYPE=no
2293     HAVE_LIBOTF=no
2294     HAVE_M17N_FLT=no
2295 fi
2296
2297 ### End of font-backend (under X11) section.
2298
2299 AC_SUBST(FREETYPE_CFLAGS)
2300 AC_SUBST(FREETYPE_LIBS)
2301 AC_SUBST(FONTCONFIG_CFLAGS)
2302 AC_SUBST(FONTCONFIG_LIBS)
2303 AC_SUBST(LIBOTF_CFLAGS)
2304 AC_SUBST(LIBOTF_LIBS)
2305 AC_SUBST(M17N_FLT_CFLAGS)
2306 AC_SUBST(M17N_FLT_LIBS)
2307
2308 ### Use -lXpm if available, unless `--with-xpm=no'.
2309 HAVE_XPM=no
2310 LIBXPM=
2311 if test "${HAVE_X11}" = "yes"; then
2312   if test "${with_xpm}" != "no"; then
2313     AC_CHECK_HEADER(X11/xpm.h,
2314       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2315     if test "${HAVE_XPM}" = "yes"; then
2316       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2317       AC_EGREP_CPP(no_return_alloc_pixels,
2318       [#include "X11/xpm.h"
2319 #ifndef XpmReturnAllocPixels
2320 no_return_alloc_pixels
2321 #endif
2322       ], HAVE_XPM=no, HAVE_XPM=yes)
2323
2324       if test "${HAVE_XPM}" = "yes"; then
2325         AC_MSG_RESULT(yes)
2326       else
2327         AC_MSG_RESULT(no)
2328       fi
2329     fi
2330   fi
2331
2332   if test "${HAVE_XPM}" = "yes"; then
2333     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm libary (-lXpm).])
2334     LIBXPM=-lXpm
2335   fi
2336 fi
2337 AC_SUBST(LIBXPM)
2338
2339 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2340 HAVE_JPEG=no
2341 LIBJPEG=
2342 if test "${HAVE_X11}" = "yes"; then
2343   if test "${with_jpeg}" != "no"; then
2344     dnl Checking for jpeglib.h can lose because of a redefinition of
2345     dnl  HAVE_STDLIB_H.
2346     AC_CHECK_HEADER(jerror.h,
2347       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
2348   fi
2349
2350   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2351   if test "${HAVE_JPEG}" = "yes"; then
2352     AC_DEFINE(HAVE_JPEG)
2353     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2354         [#include <jpeglib.h>
2355          version=JPEG_LIB_VERSION
2356 ],
2357         [AC_DEFINE(HAVE_JPEG)],
2358         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2359         HAVE_JPEG=no])
2360   fi
2361   if test "${HAVE_JPEG}" = "yes"; then
2362     LIBJPEG=-ljpeg
2363   fi
2364 fi
2365 AC_SUBST(LIBJPEG)
2366
2367 ### Use -lpng if available, unless `--with-png=no'.
2368 HAVE_PNG=no
2369 LIBPNG=
2370 if test "${HAVE_X11}" = "yes"; then
2371   if test "${with_png}" != "no"; then
2372     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
2373     # in /usr/include/libpng.
2374     AC_CHECK_HEADERS(png.h libpng/png.h)
2375     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2376       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2377     fi
2378   fi
2379
2380   if test "${HAVE_PNG}" = "yes"; then
2381     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2382     LIBPNG="-lpng -lz -lm"
2383   fi
2384 fi
2385 AC_SUBST(LIBPNG)
2386
2387 ### Use -ltiff if available, unless `--with-tiff=no'.
2388 HAVE_TIFF=no
2389 LIBTIFF=
2390 if test "${HAVE_X11}" = "yes"; then
2391   if test "${with_tiff}" != "no"; then
2392     AC_CHECK_HEADER(tiffio.h,
2393       [tifflibs="-lz -lm"
2394       # At least one tiff package requires the jpeg library.
2395       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2396       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
2397   fi
2398
2399   if test "${HAVE_TIFF}" = "yes"; then
2400     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2401     dnl FIXME -lz -lm, as per libpng?
2402     LIBTIFF=-ltiff
2403   fi
2404 fi
2405 AC_SUBST(LIBTIFF)
2406
2407 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2408 HAVE_GIF=no
2409 LIBGIF=
2410 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no"; then
2411   AC_CHECK_HEADER(gif_lib.h,
2412 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2413 # Earlier versions can crash Emacs.
2414     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])
2415
2416   if test "$HAVE_GIF" = yes; then
2417     LIBGIF=-lgif
2418   elif test "$HAVE_GIF" = maybe; then
2419 # If gif_lib.h but no libgif, try libungif.
2420     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
2421     test "$HAVE_GIF" = yes && LIBGIF=-lungif
2422   fi
2423
2424   if test "${HAVE_GIF}" = "yes"; then
2425     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
2426   fi
2427 fi
2428 AC_SUBST(LIBGIF)
2429
2430 dnl Check for required libraries.
2431 if test "${HAVE_X11}" = "yes"; then
2432   MISSING=""
2433   WITH_NO=""
2434   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2435     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2436   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2437     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2438   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2439     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2440   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2441     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2442   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2443     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2444
2445   if test "X${MISSING}" != X; then
2446     AC_MSG_ERROR([The following required libraries were not found:
2447     $MISSING
2448 Maybe some development libraries/packages are missing?
2449 If you don't want to link with them give
2450     $WITH_NO
2451 as options to configure])
2452   fi
2453 fi
2454
2455 ### Use -lgpm if available, unless `--with-gpm=no'.
2456 HAVE_GPM=no
2457 LIBGPM=
2458 MOUSE_SUPPORT=
2459 if test "${with_gpm}" != "no"; then
2460   AC_CHECK_HEADER(gpm.h,
2461     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2462
2463   if test "${HAVE_GPM}" = "yes"; then
2464     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2465     LIBGPM=-lgpm
2466     ## May be reset below.
2467     MOUSE_SUPPORT="\$(GPM_MOUSE_SUPPORT)"
2468   fi
2469 fi
2470 AC_SUBST(LIBGPM)
2471
2472 dnl Check for malloc/malloc.h on darwin
2473 AC_CHECK_HEADER(malloc/malloc.h, [AC_DEFINE(HAVE_MALLOC_MALLOC_H, 1, [Define to 1 if you have the <malloc/malloc.h> header file.])])
2474
2475 C_SWITCH_X_SYSTEM=
2476 ### Use NeXTstep API to implement GUI.
2477 if test "${HAVE_NS}" = "yes"; then
2478   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
2479   if test "${NS_IMPL_COCOA}" = "yes"; then
2480     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
2481     GNU_OBJC_CFLAGS=
2482   fi
2483   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
2484     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
2485     # See also .m.o rule in Makefile.in */
2486     # FIXME: are all these flags really needed?  Document here why.  */
2487     C_SWITCH_X_SYSTEM="-D_REENTRANT -fPIC -fno-strict-aliasing"
2488     GNU_OBJC_CFLAGS="-fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
2489   fi
2490   if test "${NS_HAVE_NSINTEGER}" = "yes"; then
2491     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
2492   fi
2493   # We also have mouse menus.
2494   HAVE_MENUS=yes
2495   OTHER_FILES=ns-app
2496 fi
2497
2498
2499 ### Use session management (-lSM -lICE) if available
2500 HAVE_X_SM=no
2501 LIBXSM=
2502 if test "${HAVE_X11}" = "yes"; then
2503   AC_CHECK_HEADER(X11/SM/SMlib.h,
2504     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2505
2506   if test "${HAVE_X_SM}" = "yes"; then
2507     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2508     LIBXSM="-lSM -lICE"
2509     case "$LIBS" in
2510       *-lSM*) ;;
2511       *)      LIBS="$LIBXSM $LIBS" ;;
2512     esac
2513   fi
2514 fi
2515 AC_SUBST(LIBXSM)
2516
2517 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2518 AC_CACHE_CHECK(whether netdb declares h_errno,
2519                emacs_cv_netdb_declares_h_errno,
2520 [AC_TRY_LINK([#include <netdb.h>],
2521   [return h_errno;],
2522   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2523 if test $emacs_cv_netdb_declares_h_errno = yes; then
2524   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2525 fi
2526
2527 AC_FUNC_ALLOCA
2528
2529 dnl src/alloca.c has been removed.  Could also check if $ALLOCA is set?
2530 dnl FIXME is there an autoconf test that does the right thing, without
2531 dnl needing to call A_M_E afterwards?
2532 if test x"$ac_cv_func_alloca_works" != xyes; then
2533    AC_MSG_ERROR( [a system implementation of alloca is required] )
2534 fi
2535
2536 # fmod, logb, and frexp are found in -lm on most systems.
2537 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2538 AC_CHECK_LIB(m, sqrt)
2539
2540 # Check for mail-locking functions in a "mail" library.  Probably this should
2541 # have the same check as for liblockfile below.
2542 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
2543 if test $have_mail = yes; then
2544   LIBS_MAIL=-lmail
2545   LIBS="$LIBS_MAIL $LIBS"
2546   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the `mail' library (-lmail).])
2547 else
2548   LIBS_MAIL=
2549 fi
2550 dnl Debian, at least:
2551 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
2552 if test $have_lockfile = yes; then
2553    LIBS_MAIL=-llockfile
2554    LIBS="$LIBS_MAIL $LIBS"
2555    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the `lockfile' library (-llockfile).])
2556 else
2557 # If we have the shared liblockfile, assume we must use it for mail
2558 # locking (e.g. Debian).  If we couldn't link against liblockfile
2559 # (no liblockfile.a installed), ensure that we don't need to.
2560   dnl This works for files generally, not just executables.
2561   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2562   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2563                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2564   if test $ac_cv_prog_liblockfile = yes; then
2565     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2566 This probably means that movemail could lose mail.
2567 There may be a `development' package to install containing liblockfile.])
2568   fi
2569 fi
2570 AC_CHECK_FUNCS(touchlock)
2571 AC_CHECK_HEADERS(maillock.h)
2572 AC_SUBST(LIBS_MAIL)
2573
2574 ## Define MAIL_USE_FLOCK (or LOCKF) if the mailer uses flock (or lockf) to
2575 ## interlock access to the mail spool.  The alternative is a lock file named
2576 ## /usr/spool/mail/$USER.lock.
2577 mail_lock=no
2578 case "$opsys" in
2579   aix4-2) mail_lock="lockf" ;;
2580
2581   gnu|freebsd|netbsd|openbsd|darwin|irix6-5) mail_lock="flock" ;;
2582
2583   ## On GNU/Linux systems, both methods are used by various mail programs.
2584   ## I assume most people are using newer mailers that have heard of flock.
2585   ## Change this if you need to.
2586   ## Debian contains a patch which says: ``On Debian/GNU/Linux systems,
2587   ## configure gets the right answers, and that means *NOT* using flock.
2588   ## Using flock is guaranteed to be the wrong thing. See Debian Policy
2589   ## for details.'' and then uses `#ifdef DEBIAN'.  Unfortunately the
2590   ## Debian maintainer hasn't provided a clean fix for Emacs.
2591   ## movemail.c will use `maillock' when MAILDIR, HAVE_LIBMAIL and
2592   ## HAVE_MAILLOCK_H are defined, so the following appears to be the
2593   ## correct logic.  -- fx
2594   ## We must check for HAVE_LIBLOCKFILE too, as movemail does.
2595   ## liblockfile is a Free Software replacement for libmail, used on
2596   ## Debian systems and elsewhere. -rfr.
2597   gnu-*)
2598     mail_lock="flock"
2599     if test $have_mail = yes || test $have_lockfile = yes; then
2600       test $ac_cv_header_maillock_h = yes && mail_lock=no
2601     fi
2602     ;;
2603 esac
2604
2605 BLESSMAIL_TARGET=
2606 case "$mail_lock" in
2607   flock) AC_DEFINE(MAIL_USE_FLOCK, 1, [Define if the mailer uses flock to interlock the mail spool.]) ;;
2608
2609   lockf) AC_DEFINE(MAIL_USE_LOCKF, 1, [Define if the mailer uses lockf to interlock the mail spool.]) ;;
2610
2611   *) BLESSMAIL_TARGET="need-blessmail" ;;
2612 esac
2613 AC_SUBST(BLESSMAIL_TARGET)
2614
2615
2616 AC_CHECK_FUNCS(gethostname getdomainname dup2 \
2617 rename closedir mkdir rmdir sysinfo getrusage get_current_dir_name \
2618 random lrand48 bcopy bcmp logb frexp fmod rint cbrt ftime setsid \
2619 strerror fpathconf select mktime euidaccess getpagesize tzset setlocale \
2620 utimes getrlimit setrlimit setpgid getcwd getwd shutdown getaddrinfo \
2621 __fpending mblen mbrlen mbsinit strsignal setitimer ualarm index rindex \
2622 sendto recvfrom getsockopt setsockopt getsockname getpeername \
2623 gai_strerror mkstemp getline getdelim mremap memmove fsync sync bzero \
2624 memset memcmp difftime memcpy mempcpy mblen mbrlen posix_memalign \
2625 cfmakeraw cfsetspeed isnan copysign)
2626
2627 AC_CHECK_HEADERS(sys/un.h)
2628
2629 AC_FUNC_MKTIME
2630 if test "$ac_cv_func_working_mktime" = no; then
2631   AC_DEFINE(BROKEN_MKTIME, 1, [Define to 1 if the mktime function is broken.])
2632 fi
2633
2634 AC_FUNC_GETLOADAVG
2635
2636 AC_FUNC_FSEEKO
2637
2638 # Configure getopt.
2639 m4_include([m4/getopt.m4])
2640 gl_GETOPT_IFELSE([
2641   gl_GETOPT_SUBSTITUTE_HEADER
2642   gl_PREREQ_GETOPT
2643   GETOPTOBJS='getopt.o getopt1.o'
2644 ])
2645 AC_SUBST(GETOPTOBJS)
2646
2647 AC_FUNC_GETPGRP
2648
2649 AC_FUNC_STRFTIME
2650
2651 # UNIX98 PTYs.
2652 AC_CHECK_FUNCS(grantpt)
2653
2654 # PTY-related GNU extensions.
2655 AC_CHECK_FUNCS(getpt)
2656
2657 # Check this now, so that we will NOT find the above functions in ncurses.
2658 # That is because we have not set up to link ncurses in lib-src.
2659 # It's better to believe a function is not available
2660 # than to expect to find it in ncurses.
2661 # Also we need tputs and friends to be able to build at all.
2662 have_tputs_et_al=true
2663 AC_SEARCH_LIBS(tputs, [ncurses terminfo termcap], , have_tputs_et_al=false)
2664 if test "$have_tputs_et_al" != true; then
2665   AC_MSG_ERROR([I couldn't find termcap functions (tputs and friends).
2666 Maybe some development libraries/packages are missing?  Try installing
2667 libncurses-dev(el), libterminfo-dev(el) or similar.])
2668 fi
2669 # Must define this when any termcap library is found.
2670 AC_DEFINE(HAVE_LIBNCURSES, 1,
2671           [Define to 1 if you have the `ncurses' library (-lncurses).])
2672 ## FIXME This was the cpp logic, but I am not sure it is right.
2673 ## The above test has not necessarily found libncurses.
2674 HAVE_LIBNCURSES=yes
2675
2676 ## Use terminfo instead of termcap?
2677 ## Note only system files NOT using terminfo are:
2678 ## freebsd < 40000, ms-w32, msdos, netbsd < 599002500, and
2679 ## darwin|gnu without ncurses.
2680 TERMINFO=no
2681 LIBS_TERMCAP=
2682 case "$opsys" in
2683   ## cygwin: Fewer environment variables to go wrong, more terminal types.
2684   ## hpux10-20: Use the system provided termcap(3) library.
2685   ## openbsd: David Mazieres <dm@reeducation-labor.lcs.mit.edu> says this
2686   ##  is necessary.  Otherwise Emacs dumps core when run -nw.
2687   aix4-2|cygwin|hpux*|irix6-5|openbsd|sol2*|unixware) TERMINFO=yes ;;
2688
2689   ## darwin: Prevents crashes when running Emacs in Terminal.app under 10.2.
2690   ##  The ncurses library has been moved out of the System framework in
2691   ##  Mac OS X 10.2.  So if configure detects it, set the command-line
2692   ##  option to use it.
2693   darwin|gnu*)
2694     ## (HAVE_LIBNCURSES was not always true, but is since 2010-03-18.)
2695     if test "x$HAVE_LIBNCURSES" = "xyes"; then
2696       TERMINFO=yes
2697       LIBS_TERMCAP="-lncurses"
2698     fi
2699     ;;
2700
2701   freebsd)
2702     AC_MSG_CHECKING([whether FreeBSD is new enough to use terminfo])
2703     AC_CACHE_VAL(emacs_cv_freebsd_terminfo,
2704     [AC_TRY_LINK([#include <osreldate.h>],
2705 [#if __FreeBSD_version < 400000
2706 fail;
2707 #endif
2708 ], emacs_cv_freebsd_terminfo=yes, emacs_cv_freebsd_terminfo=no)])
2709
2710     AC_MSG_RESULT($emacs_cv_freebsd_terminfo)
2711
2712     if test $emacs_cv_freebsd_terminfo = yes; then
2713       TERMINFO=yes
2714       LIBS_TERMCAP="-lncurses"
2715     else
2716       LIBS_TERMCAP="-ltermcap"
2717     fi
2718     ;;
2719
2720   netbsd)
2721     if test $ac_cv_search_tputs = -lterminfo; then
2722       TERMINFO=yes
2723       LIBS_TERMCAP="-lterminfo"
2724     else
2725       LIBS_TERMCAP="-ltermcap"
2726     fi
2727     ;;
2728
2729 esac
2730
2731 case "$opsys" in
2732   ## hpux: Make sure we get select from libc rather than from libcurses
2733   ##  because libcurses on HPUX 10.10 has a broken version of select.
2734   ##  We used to use -lc -lcurses, but this may be cleaner.
2735   hpux*) LIBS_TERMCAP="-ltermcap" ;;
2736
2737   openbsd) LIBS_TERMCAP="-lncurses" ;;
2738
2739   ## Must use system termcap, if we use any termcap.  It does special things.
2740   sol2*) test "$TERMINFO" != yes && LIBS_TERMCAP="-ltermcap" ;;
2741 esac
2742
2743 TERMCAP_OBJ=tparam.o
2744 if test $TERMINFO = yes; then
2745   AC_DEFINE(TERMINFO, 1, [Define to 1 if you use terminfo instead of termcap.])
2746
2747   ## Default used to be -ltermcap.  Add a case above if need something else.
2748   test "x$LIBS_TERMCAP" = "x" && LIBS_TERMCAP="-lcurses"
2749
2750   TERMCAP_OBJ=terminfo.o
2751 fi
2752 AC_SUBST(LIBS_TERMCAP)
2753 AC_SUBST(TERMCAP_OBJ)
2754
2755
2756 # Do we have res_init, for detecting changes in /etc/resolv.conf?
2757 resolv=no
2758 AC_TRY_LINK([#include <netinet/in.h>
2759 #include <arpa/nameser.h>
2760 #include <resolv.h>],
2761     [return res_init();],
2762     have_res_init=yes, have_res_init=no)
2763 if test "$have_res_init" = no; then
2764   OLIBS="$LIBS"
2765   LIBS="$LIBS -lresolv"
2766   AC_MSG_CHECKING(for res_init with -lresolv)
2767   AC_TRY_LINK([#include <netinet/in.h>
2768 #include <arpa/nameser.h>
2769 #include <resolv.h>],
2770     [return res_init();],
2771     have_res_init=yes, have_res_init=no)
2772   AC_MSG_RESULT($have_res_init)
2773   if test "$have_res_init" = yes ; then
2774     resolv=yes
2775   fi
2776   LIBS="$OLIBS"
2777 fi
2778
2779 if test "$have_res_init" = yes; then
2780   AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
2781 fi
2782
2783 # Do we need the Hesiod library to provide the support routines?
2784 LIBHESIOD=
2785 if test "$with_hesiod" != no ; then
2786   # Don't set $LIBS here -- see comments above.  FIXME which comments?
2787   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2788      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2789                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2790   if test "$resolv" = yes ; then
2791     RESOLVLIB=-lresolv
2792   else
2793     RESOLVLIB=
2794   fi
2795   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2796         hesiod=yes, :, $RESOLVLIB)])
2797
2798   if test x"$hesiod" = xyes; then
2799     AC_DEFINE(HAVE_LIBHESIOD, 1,
2800               [Define to 1 if you have the hesiod library (-lhesiod).])
2801     LIBHESIOD=-lhesiod
2802   fi
2803 fi
2804 AC_SUBST(LIBHESIOD)
2805
2806 # Do we need libresolv (due to res_init or Hesiod)?
2807 if test "$resolv" = yes ; then
2808   AC_DEFINE(HAVE_LIBRESOLV, 1,
2809             [Define to 1 if you have the resolv library (-lresolv).])
2810   LIBRESOLV=-lresolv
2811 else
2812   LIBRESOLV=
2813 fi
2814 AC_SUBST(LIBRESOLV)
2815
2816 # These tell us which Kerberos-related libraries to use.
2817 COM_ERRLIB=
2818 CRYPTOLIB=
2819 KRB5LIB=
2820 DESLIB=
2821 KRB4LIB=
2822
2823 if test "${with_kerberos}" != no; then
2824   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
2825   if test $have_com_err = yes; then
2826     COM_ERRLIB=-lcom_err
2827     LIBS="$COM_ERRLIB $LIBS"
2828     AC_DEFINE(HAVE_LIBCOM_ERR, 1, [Define to 1 if you have the `com_err' library (-lcom_err).])
2829   fi
2830   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
2831   if test $have_crypto = yes; then
2832     CRYPTOLIB=-lcrypto
2833     LIBS="$CRYPTOLIB $LIBS"
2834     AC_DEFINE(HAVE_LIBCRYPTO, 1, [Define to 1 if you have the `crypto' library (-lcrypto).])
2835   fi
2836   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
2837   if test $have_k5crypto = yes; then
2838     CRYPTOLIB=-lk5crypto
2839     LIBS="$CRYPTOLIB $LIBS"
2840     AC_DEFINE(HAVE_LIBK5CRYPTO, 1, [Define to 1 if you have the `k5crypto' library (-lk5crypto).])
2841   fi
2842   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
2843   if test $have_krb5=yes; then
2844     KRB5LIB=-lkrb5
2845     LIBS="$KRB5LIB $LIBS"
2846     AC_DEFINE(HAVE_LIBKRB5, 1, [Define to 1 if you have the `krb5' library (-lkrb5).])
2847   fi
2848   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
2849   if test "${with_kerberos5}" = no; then
2850     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
2851     if test $have_des425 = yes; then
2852       DESLIB=-ldes425
2853       LIBS="$DESLIB $LIBS"
2854       AC_DEFINE(HAVE_LIBDES425, 1, [Define to 1 if you have the `des425' library (-ldes425).])
2855     else
2856       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
2857       if test $have_des = yes; then
2858         DESLIB=-ldes
2859         LIBS="$DESLIB $LIBS"
2860         AC_DEFINE(HAVE_LIBDES, 1, [Define to 1 if you have the `des' library (-ldes).])
2861       fi
2862     fi
2863     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
2864     if test $have_krb4 = yes; then
2865       KRB4LIB=-lkrb4
2866       LIBS="$KRB4LIB $LIBS"
2867       AC_DEFINE(HAVE_LIBKRB4, 1, [Define to 1 if you have the `krb4' library (-lkrb4).])
2868     else
2869       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
2870       if test $have_krb = yes; then
2871         KRB4LIB=-lkrb
2872         LIBS="$KRB4LIB $LIBS"
2873         AC_DEFINE(HAVE_LIBKRB, 1, [Define to 1 if you have the `krb' library (-lkrb).])
2874       fi
2875     fi
2876   fi
2877
2878   if test "${with_kerberos5}" != no; then
2879     AC_CHECK_HEADERS(krb5.h,
2880       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
2881                         [#include <krb5.h>])])
2882   else
2883     AC_CHECK_HEADERS(des.h,,
2884                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
2885                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
2886     AC_CHECK_HEADERS(krb.h,,
2887                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
2888                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
2889   fi
2890   AC_CHECK_HEADERS(com_err.h)
2891 fi
2892
2893 AC_SUBST(COM_ERRLIB)
2894 AC_SUBST(CRYPTOLIB)
2895 AC_SUBST(KRB5LIB)
2896 AC_SUBST(DESLIB)
2897 AC_SUBST(KRB4LIB)
2898
2899 # Solaris requires -lintl if you want strerror (which calls dgettext)
2900 # to return localized messages.
2901 AC_CHECK_LIB(intl, dgettext)
2902
2903 AC_MSG_CHECKING(whether localtime caches TZ)
2904 AC_CACHE_VAL(emacs_cv_localtime_cache,
2905 [if test x$ac_cv_func_tzset = xyes; then
2906 AC_TRY_RUN([#include <time.h>
2907 extern char **environ;
2908 unset_TZ ()
2909 {
2910   char **from, **to;
2911   for (to = from = environ; (*to = *from); from++)
2912     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
2913       to++;
2914 }
2915 char TZ_GMT0[] = "TZ=GMT0";
2916 char TZ_PST8[] = "TZ=PST8";
2917 main()
2918 {
2919   time_t now = time ((time_t *) 0);
2920   int hour_GMT0, hour_unset;
2921   if (putenv (TZ_GMT0) != 0)
2922     exit (1);
2923   hour_GMT0 = localtime (&now)->tm_hour;
2924   unset_TZ ();
2925   hour_unset = localtime (&now)->tm_hour;
2926   if (putenv (TZ_PST8) != 0)
2927     exit (1);
2928   if (localtime (&now)->tm_hour == hour_GMT0)
2929     exit (1);
2930   unset_TZ ();
2931   if (localtime (&now)->tm_hour != hour_unset)
2932     exit (1);
2933   exit (0);
2934 }], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
2935 [# If we have tzset, assume the worst when cross-compiling.
2936 emacs_cv_localtime_cache=yes])
2937 else
2938         # If we lack tzset, report that localtime does not cache TZ,
2939         # since we can't invalidate the cache if we don't have tzset.
2940         emacs_cv_localtime_cache=no
2941 fi])dnl
2942 AC_MSG_RESULT($emacs_cv_localtime_cache)
2943 if test $emacs_cv_localtime_cache = yes; then
2944   AC_DEFINE(LOCALTIME_CACHE, 1,
2945             [Define to 1 if localtime caches TZ.])
2946 fi
2947
2948 if test "x$HAVE_TIMEVAL" = xyes; then
2949   AC_CHECK_FUNCS(gettimeofday)
2950   if test $ac_cv_func_gettimeofday = yes; then
2951     AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
2952                    emacs_cv_gettimeofday_two_arguments,
2953     [AC_TRY_COMPILE([
2954 #ifdef TIME_WITH_SYS_TIME
2955 #include <sys/time.h>
2956 #include <time.h>
2957 #else
2958 #ifdef HAVE_SYS_TIME_H
2959 #include <sys/time.h>
2960 #else
2961 #include <time.h>
2962 #endif
2963 #endif],
2964       [struct timeval time;
2965        gettimeofday (&time, 0);],
2966       emacs_cv_gettimeofday_two_arguments=yes,
2967       emacs_cv_gettimeofday_two_arguments=no)])
2968     if test $emacs_cv_gettimeofday_two_arguments = no; then
2969       AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT, 1,
2970                 [Define to 1 if gettimeofday accepts only one argument.])
2971     fi
2972   fi
2973 fi
2974
2975 ok_so_far=yes
2976 AC_CHECK_FUNC(socket, , ok_so_far=no)
2977 if test $ok_so_far = yes; then
2978   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
2979 fi
2980 if test $ok_so_far = yes; then
2981   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
2982 fi
2983 if test $ok_so_far = yes; then
2984 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
2985   AC_DEFINE(HAVE_INET_SOCKETS, 1,
2986             [Define to 1 if you have inet sockets.])
2987 fi
2988
2989 AC_CHECK_HEADERS(sys/ioctl.h)
2990
2991 if test -f /usr/lpp/X11/bin/smt.exp; then
2992   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
2993             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
2994 fi
2995
2996 AC_MSG_CHECKING(whether system supports dynamic ptys)
2997 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
2998   AC_MSG_RESULT(yes)
2999   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
3000 else
3001   AC_MSG_RESULT(no)
3002 fi
3003
3004 AC_FUNC_FORK
3005
3006 dnl Adapted from Haible's version.
3007 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
3008   [AC_TRY_LINK([#include <langinfo.h>],
3009     [char* cs = nl_langinfo(CODESET);],
3010     emacs_cv_langinfo_codeset=yes,
3011     emacs_cv_langinfo_codeset=no)
3012   ])
3013 if test $emacs_cv_langinfo_codeset = yes; then
3014   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
3015     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
3016 fi
3017
3018 AC_CHECK_TYPES(size_t)
3019
3020 AC_TYPE_MBSTATE_T
3021
3022 dnl Restrict could probably be used effectively other than in regex.c.
3023 AC_CACHE_CHECK([for C restrict keyword], emacs_cv_c_restrict,
3024   [AC_TRY_COMPILE([void fred (int *restrict x);], [],
3025                   emacs_cv_c_restrict=yes,
3026                   [AC_TRY_COMPILE([void fred (int *__restrict x);], [],
3027                                   emacs_cv_c_restrict=__restrict,
3028                                   emacs_cv_c_restrict=no)])])
3029 case "$emacs_cv_c_restrict" in
3030   yes) emacs_restrict=restrict;;
3031   no) emacs_restrict="";;
3032   *) emacs_restrict="$emacs_cv_c_restrict";;
3033 esac
3034 if test "$emacs_restrict" != __restrict; then
3035   AC_DEFINE_UNQUOTED(__restrict, $emacs_restrict,
3036     [Define to compiler's equivalent of C99 restrict keyword.
3037      Don't define if equivalent is `__restrict'.])
3038 fi
3039
3040 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
3041   [AC_TRY_COMPILE([void fred (int x[__restrict]);], [],
3042                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
3043 if test "$emacs_cv_c_restrict_arr" = yes; then
3044   AC_DEFINE(__restrict_arr, __restrict,
3045     [Define to compiler's equivalent of C99 restrict keyword in array
3046      declarations.  Define as empty for no equivalent.])
3047 fi
3048
3049 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
3050 dnl how the tty code is related to POSIX and/or other versions of termios.
3051 dnl The following looks like a useful start.
3052 dnl
3053 dnl AC_SYS_POSIX_TERMIOS
3054 dnl if test $ac_cv_sys_posix_termios = yes; then
3055 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
3056 dnl                                and macros for terminal control.])
3057 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
3058 dnl fi
3059
3060 dnl Fixme: Use AC_FUNC_MEMCMP since memcmp is used.  (Needs libobj replacement.)
3061
3062 # Set up the CFLAGS for real compilation, so we can substitute it.
3063 CFLAGS="$REAL_CFLAGS"
3064 CPPFLAGS="$REAL_CPPFLAGS"
3065
3066 ## Hack to detect a buggy GCC version.
3067 if test "x$GCC" = xyes \
3068    && test x"`$CC --version 2> /dev/null | grep 'gcc.* 4.5.0'`" != x \
3069    && test x"`echo $CFLAGS | grep '\-O@<:@23@:>@'`" != x \
3070    && test x"`echo $CFLAGS | grep '\-fno-optimize-sibling-calls'`" = x; then
3071    AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS'.])
3072 fi
3073
3074 #### Find out which version of Emacs this is.
3075 [version=`grep 'const char emacs_version' ${srcdir}/src/emacs.c \
3076          | sed -e 's/^[^"]*"\([^"]*\)".*$/\1/'`]
3077 if test x"${version}" = x; then
3078   AC_MSG_ERROR([can't find current emacs version in `${srcdir}/src/emacs.c'.])
3079 fi
3080 if test x"${version}" != x"$PACKAGE_VERSION"; then
3081   AC_MSG_WARN([version mismatch between `${srcdir}/configure.in' and `${srcdir}/src/emacs.c'.])
3082 fi
3083
3084 ### Specify what sort of things we'll be editing into Makefile and config.h.
3085 ### Use configuration here uncanonicalized to avoid exceeding size limits.
3086 AC_SUBST(version)
3087 AC_SUBST(configuration)
3088 ## Unused?
3089 AC_SUBST(canonical)
3090 AC_SUBST(srcdir)
3091 AC_SUBST(prefix)
3092 AC_SUBST(exec_prefix)
3093 AC_SUBST(bindir)
3094 AC_SUBST(datadir)
3095 AC_SUBST(sharedstatedir)
3096 AC_SUBST(libexecdir)
3097 AC_SUBST(mandir)
3098 AC_SUBST(infodir)
3099 AC_SUBST(lispdir)
3100 AC_SUBST(locallisppath)
3101 AC_SUBST(lisppath)
3102 AC_SUBST(x_default_search_path)
3103 AC_SUBST(etcdir)
3104 AC_SUBST(archlibdir)
3105 AC_SUBST(docdir)
3106 AC_SUBST(bitmapdir)
3107 AC_SUBST(gamedir)
3108 AC_SUBST(gameuser)
3109 ## FIXME? Nothing uses @LD_SWITCH_X_SITE@.
3110 ## src/Makefile.in did add LD_SWITCH_X_SITE (as a cpp define) to the
3111 ## end of LIBX_BASE, but nothing ever set it.
3112 AC_SUBST(LD_SWITCH_X_SITE)
3113 AC_SUBST(C_SWITCH_X_SITE)
3114 AC_SUBST(C_SWITCH_X_SYSTEM)
3115 AC_SUBST(CFLAGS)
3116 ## Used in lwlib/Makefile.in.
3117 AC_SUBST(X_TOOLKIT_TYPE)
3118 AC_SUBST(machfile)
3119 AC_SUBST(opsysfile)
3120 AC_SUBST(GETLOADAVG_LIBS)
3121 AC_SUBST(ns_appdir)
3122 AC_SUBST(ns_appbindir)
3123 AC_SUBST(ns_appresdir)
3124 AC_SUBST(ns_appsrc)
3125 AC_SUBST(GNU_OBJC_CFLAGS)
3126 AC_SUBST(OTHER_FILES)
3127
3128 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
3129                    [Define to the canonical Emacs configuration name.])
3130 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
3131                    [Define to the options passed to configure.])
3132 AC_DEFINE_UNQUOTED(config_machfile,  "${machfile}",
3133                    [Define to the used machine dependent file.])
3134 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
3135                    [Define to the used os dependent file.])
3136
3137 XMENU_OBJ=
3138 XOBJ=
3139 FONT_OBJ=
3140 if test "${HAVE_X_WINDOWS}" = "yes" ; then
3141   AC_DEFINE(HAVE_X_WINDOWS, 1,
3142             [Define to 1 if you want to use the X window system.])
3143   XMENU_OBJ=xmenu.o
3144   XOBJ="xterm.o xfns.o xselect.o xrdb.o fontset.o xsmfns.o fringe.o image.o xsettings.o xgselect.o"
3145   FONT_OBJ=xfont.o
3146   if test "$HAVE_XFT" = "yes"; then
3147     FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o"
3148   elif test "$HAVE_FREETYPE" = "yes"; then
3149     FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o"
3150   fi
3151   AC_SUBST(FONT_OBJ)
3152 fi
3153 AC_SUBST(XMENU_OBJ)
3154 AC_SUBST(XOBJ)
3155 AC_SUBST(FONT_OBJ)
3156
3157 WIDGET_OBJ=
3158 MOTIF_LIBW=
3159 if test "${USE_X_TOOLKIT}" != "none" ; then
3160   WIDGET_OBJ=widget.o
3161   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
3162   if test "${USE_X_TOOLKIT}" = "LUCID"; then
3163     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
3164   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
3165     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
3166     MOTIF_LIBW=-lXm
3167     case "$opsys" in
3168       gnu-linux)
3169         ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed.
3170         MOTIF_LIBW="$MOTIF_LIBW -lXpm"
3171         ;;
3172
3173       unixware)
3174         ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov>
3175         ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2.
3176         MOTIF_LIBW="MOTIF_LIBW -lXimp"
3177         ;;
3178
3179       aix4-2)
3180         ## olson@mcs.anl.gov says -li18n is needed by -lXm.
3181         MOTIF_LIBW="$MOTIF_LIBW -li18n"
3182         ;;
3183     esac
3184     MOTIF_LIBW="$MOTIF_LIBW $LIBXP"
3185   fi
3186 fi
3187 AC_SUBST(WIDGET_OBJ)
3188
3189 TOOLKIT_LIBW=
3190 case "$USE_X_TOOLKIT" in
3191   MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;;
3192   LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;;
3193   none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS" ;;
3194 esac
3195 AC_SUBST(TOOLKIT_LIBW)
3196
3197 if test "$USE_X_TOOLKIT" = "none"; then
3198   LIBXT_OTHER="\$(LIBXSM)"
3199   OLDXMENU_TARGET="really-oldXMenu"
3200 else
3201   LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext"
3202   OLDXMENU_TARGET="really-lwlib"
3203 fi
3204 AC_SUBST(LIBXT_OTHER)
3205
3206 ## The X Menu stuff is present in the X10 distribution, but missing
3207 ## from X11.  If we have X10, just use the installed library;
3208 ## otherwise, use our own copy.
3209 if test "${HAVE_X11}" = "yes" ; then
3210   AC_DEFINE(HAVE_X11, 1,
3211             [Define to 1 if you want to use version 11 of X windows.
3212              Otherwise, Emacs expects to use version 10.])
3213
3214   if test "$USE_X_TOOLKIT" = "none"; then
3215     OLDXMENU="\${oldXMenudir}libXMenu11.a"
3216   else
3217     OLDXMENU="\${lwlibdir}liblw.a"
3218   fi
3219   LIBXMENU="\$(OLDXMENU)"
3220   LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)"
3221   OLDXMENU_DEPS="\${OLDXMENU} ../src/\${OLDXMENU}"
3222 else
3223   ## For a syntactically valid Makefile; not actually used for anything.
3224   ## See comments in src/Makefile.in.
3225   OLDXMENU=nothing
3226   ## FIXME This case (!HAVE_X11 && HAVE_X_WINDOWS) is no longer possible(?).
3227   if test "${HAVE_X_WINDOWS}" = "yes"; then
3228     LIBXMENU="-lXMenu"
3229   else
3230     LIBXMENU=
3231   fi
3232   LIBX_OTHER=
3233   OLDXMENU_DEPS=
3234 fi
3235
3236 if test "$HAVE_GTK" = "yes" || test "$HAVE_MENUS" != "yes"; then
3237   OLDXMENU_TARGET=
3238   OLDXMENU=nothing
3239   LIBXMENU=
3240   OLDXMENU_DEPS=
3241 fi
3242
3243 AC_SUBST(OLDXMENU_TARGET)
3244 AC_SUBST(OLDXMENU)
3245 AC_SUBST(LIBXMENU)
3246 AC_SUBST(LIBX_OTHER)
3247 AC_SUBST(OLDXMENU_DEPS)
3248
3249 if test "${HAVE_MENUS}" = "yes" ; then
3250   AC_DEFINE(HAVE_MENUS, 1,
3251             [Define to 1 if you have mouse menus.
3252              (This is automatic if you use X, but the option to specify it remains.)
3253              It is also defined with other window systems that support xmenu.c.])
3254 fi
3255
3256 if test "${GNU_MALLOC}" = "yes" ; then
3257   AC_DEFINE(GNU_MALLOC, 1,
3258             [Define to 1 if you want to use the GNU memory allocator.])
3259 fi
3260
3261 RALLOC_OBJ=
3262 if test "${REL_ALLOC}" = "yes" ; then
3263   AC_DEFINE(REL_ALLOC, 1,
3264             [Define REL_ALLOC if you want to use the relocating allocator for
3265              buffer space.])
3266
3267   test "$system_malloc" != "yes" && RALLOC_OBJ=ralloc.o
3268 fi
3269 AC_SUBST(RALLOC_OBJ)
3270
3271 if test "$opsys" = "cygwin"; then
3272   CYGWIN_OBJ="sheap.o"
3273   ## Cygwin differs because of its unexec().
3274   PRE_ALLOC_OBJ=
3275   POST_ALLOC_OBJ=lastfile.o
3276 else
3277   CYGWIN_OBJ=
3278   PRE_ALLOC_OBJ=lastfile.o
3279   POST_ALLOC_OBJ=
3280 fi
3281 AC_SUBST(CYGWIN_OBJ)
3282 AC_SUBST(PRE_ALLOC_OBJ)
3283 AC_SUBST(POST_ALLOC_OBJ)
3284
3285
3286 case "$opsys" in
3287   aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;;
3288
3289   darwin)
3290    ## The -headerpad option tells ld (see man page) to leave room at the
3291    ## end of the header for adding load commands.  Needed for dumping.
3292    ## 0x690 is the total size of 30 segment load commands (at 56
3293    ## each); under Cocoa 31 commands are required.
3294    if test "$HAVE_NS" = "yes"; then
3295      libs_nsgui="-framework AppKit"
3296      headerpad_extra=6C8
3297    else
3298      libs_nsgui=
3299      headerpad_extra=690
3300    fi
3301    LD_SWITCH_SYSTEM_TEMACS="-prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra"
3302
3303    ## This is here because src/Makefile.in did some extra fiddling around
3304    ## with LD_SWITCH_SYSTEM.  The cpp logic was:
3305    ##   #ifndef LD_SWITCH_SYSTEM
3306    ##   #if !defined (__GNUC__) && ((defined (BSD_SYSTEM) && !defined (COFF)))
3307    ## Since all the *bsds define LD_SWITCH_SYSTEM, this simplifies to:
3308    ## not using gcc, darwin system not on an alpha (ie darwin, since
3309    ## darwin + alpha does not occur).
3310    ## Because this was done in src/Makefile.in, the resulting part of
3311    ## LD_SWITCH_SYSTEM was not used in configure (ie, in ac_link).
3312    ## It therefore seems cleaner to put this in LD_SWITCH_SYSTEM_TEMACS,
3313    ## rather than LD_SWITCH_SYSTEM.
3314    test "x$LD_SWITCH_SYSTEM" = "x" && test "x$GCC" != "xyes" && \
3315      LD_SWITCH_SYSTEM_TEMACS="-X $LD_SWITCH_SYSTEM_TEMACS"
3316    ;;
3317
3318   ## LD_SWITCH_X_SITE_AUX is a -R option saying where to find X at run-time.
3319   ## When handled by cpp, this was in LD_SWITCH_SYSTEM.  However, at
3320   ## the point where configure sourced the s/*.h file, LD_SWITCH_X_SITE_AUX
3321   ## had not yet been defined and was expanded to null.  Hence LD_SWITCH_SYSTEM
3322   ## had different values in configure (in ac_link) and src/Makefile.in.
3323   ## It seems clearer therefore to put this piece in LD_SWITCH_SYSTEM_TEMACS.
3324   gnu-linux) LD_SWITCH_SYSTEM_TEMACS="\$(LD_SWITCH_X_SITE_AUX)" ;;
3325
3326   *) LD_SWITCH_SYSTEM_TEMACS= ;;
3327 esac
3328
3329 if test "$NS_IMPL_GNUSTEP" = "yes"; then
3330   LD_SWITCH_SYSTEM_TEMACS="${LD_SWITCH_SYSTEM_TEMACS} -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES} -lgnustep-gui -lgnustep-base -lobjc -lpthread"
3331 fi
3332
3333 AC_SUBST(LD_SWITCH_SYSTEM_TEMACS)
3334
3335
3336 LINKER=
3337 ORDINARY_LINK=
3338 case "$opsys" in
3339   ## gnu: GNU needs its own crt0.
3340   aix4-2|darwin|gnu|usg5-4|irix6-5|sol2*|unixware) ORDINARY_LINK=yes ;;
3341
3342   cygwin) LINKER="\$(CC)" ;;
3343
3344   ## On post 1.3 releases of NetBSD, gcc -nostdlib also clears the
3345   ## library search parth, i.e. it won't search /usr/lib for libc and
3346   ## friends.  Using -nostartfiles instead avoids this problem, and
3347   ## will also work on earlier NetBSD releases.
3348   netbsd|openbsd) LINKER="\$(CC) -nostartfiles" ;;
3349
3350   ## macpcc: NAKAJI Hiroyuki <nakaji@tutrp.tut.ac.jp> says
3351   ##   MkLinux/LinuxPPC needs this.
3352   ## ibms390x only supports opsys = gnu-linux so it can be added here.
3353   gnu-*)
3354     case "$machine" in
3355       macppc|ibms390x) LINKER="\$(CC) -nostdlib" ;;
3356     esac
3357     ;;
3358 esac
3359
3360
3361 PRE_EDIT_LDFLAGS=
3362 POST_EDIT_LDFLAGS=
3363 if test "x$ORDINARY_LINK" = "xyes"; then
3364
3365   LINKER="\$(CC)"
3366   AC_DEFINE(ORDINARY_LINK, 1, [Define if the C compiler is the linker.])
3367
3368 ## The system files defining neither ORDINARY_LINK nor LINKER are:
3369 ## (bsd-common), freebsd, gnu-* not on macppc|ibms390x, hpux*.
3370 elif test "x$GCC" = "xyes" && test "x$LINKER" = "x"; then
3371
3372   ## Versions of GCC >= 2.0 put their library, libgcc.a, in obscure
3373   ## places that are difficult to figure out at make time.  Fortunately,
3374   ## these same versions allow you to pass arbitrary flags on to the
3375   ## linker, so there is no reason not to use it as a linker.
3376   ##
3377   ## Well, it is not quite perfect.  The "-nostdlib" keeps GCC from
3378   ## searching for libraries in its internal directories, so we have to
3379   ## ask GCC explicitly where to find libgcc.a (LIB_GCC below).
3380   LINKER="\$(CC) -nostdlib"
3381   ## GCC passes any argument prefixed with -Xlinker directly to the linker.
3382   ## See prefix-args.c for an explanation of why we do not do this with the
3383   ## shell''s ``for'' construct.  Note that sane people do not have '.' in
3384   ## their paths, so we must use ./prefix-args.
3385   ## TODO either make prefix-args check ORDINARY_LINK internally,
3386   ## or remove it altogether (bug#6184), removing the need for this hack.
3387   PRE_EDIT_LDFLAGS='`./prefix-args -Xlinker'
3388   POST_EDIT_LDFLAGS='`'
3389 fi
3390 AC_SUBST(PRE_EDIT_LDFLAGS)
3391 AC_SUBST(POST_EDIT_LDFLAGS)
3392
3393 test "x$LINKER" = "x" && LINKER=ld
3394 ## FIXME? What setting of EDIT_LDFLAGS should this have?
3395 test "$NS_IMPL_GNUSTEP" = "yes" && LINKER="\$(CC) -rdynamic"
3396
3397 AC_SUBST(LINKER)
3398
3399
3400 ## FIXME? The logic here is not precisely the same as that above.
3401 ## There is no check here for a pre-defined LINKER.
3402 ## Should we only be setting LIB_GCC if LD ~ -nostdlib?
3403 LIB_GCC=
3404 if test "x$GCC" = "xyes" && test "x$ORDINARY_LINK" != "xyes"; then
3405
3406   case "$opsys" in
3407     ## cygwin: don't link against static libgcc.
3408     cygwin|freebsd|netbsd|openbsd) LIB_GCC= ;;
3409
3410     gnu-*)
3411       ## armin76@gentoo.org reported that the lgcc_s flag is necessary to
3412       ## build on ARM EABI under GNU/Linux.  (Bug#5518)
3413       ## Note that m/arm.h never bothered to undefine LIB_GCC first.
3414       if test "$machine" = "arm"; then
3415         LIB_GCC="-lgcc_s"
3416       else
3417         ## FIXME? s/gnu-linux.h used to define LIB_GCC as below, then
3418         ## immediately undefine it again and redefine it to empty.
3419         ## Was the C_SWITCH_X_SITE part really necessary?
3420 ##      LIB_GCC=`$CC $C_SWITCH_X_SITE -print-libgcc-file-name`
3421         LIB_GCC=
3422       fi
3423       ;;
3424
3425     ## Ask GCC where to find libgcc.a.
3426     *) LIB_GCC=`$CC -print-libgcc-file-name 2> /dev/null` ;;
3427   esac
3428 fi                              dnl if $GCC
3429 AC_SUBST(LIB_GCC)
3430
3431
3432 TOOLTIP_SUPPORT=
3433 WINDOW_SUPPORT=
3434 ## If we're using X11/GNUstep, define some consequences.
3435 if test "$HAVE_X_WINDOWS" = "yes" || test "$HAVE_NS" = "yes"; then
3436   AC_DEFINE(HAVE_WINDOW_SYSTEM, 1, [Define if you have a window system.])
3437   AC_DEFINE(HAVE_MOUSE, 1, [Define if you have mouse support.])
3438   MOUSE_SUPPORT="\$(REAL_MOUSE_SUPPORT)"
3439   TOOLTIP_SUPPORT="\${lispsource}mouse.elc"
3440
3441   WINDOW_SUPPORT="\$(BASE_WINDOW_SUPPORT)"
3442   test "$HAVE_X_WINDOWS" = "yes" && \
3443     WINDOW_SUPPORT="$WINDOW_SUPPORT \$(X_WINDOW_SUPPORT)"
3444
3445 fi
3446 AC_SUBST(MOUSE_SUPPORT)
3447 AC_SUBST(TOOLTIP_SUPPORT)
3448 AC_SUBST(WINDOW_SUPPORT)
3449
3450
3451 AH_TOP([/* GNU Emacs site configuration template file.
3452    Copyright (C) 1988, 1993, 1994, 1999, 2000, 2001, 2002, 2004, 2005,
3453      2006, 2007, 2008, 2009, 2010  Free Software Foundation, Inc.
3454
3455 This file is part of GNU Emacs.
3456
3457 GNU Emacs is free software: you can redistribute it and/or modify
3458 it under the terms of the GNU General Public License as published by
3459 the Free Software Foundation, either version 3 of the License, or
3460 (at your option) any later version.
3461
3462 GNU Emacs is distributed in the hope that it will be useful,
3463 but WITHOUT ANY WARRANTY; without even the implied warranty of
3464 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
3465 GNU General Public License for more details.
3466
3467 You should have received a copy of the GNU General Public License
3468 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
3469
3470
3471 /* No code in Emacs #includes config.h twice, but some bits of code
3472    intended to work with other packages as well (like gmalloc.c)
3473    think they can include it as many times as they like.  */
3474 #ifndef EMACS_CONFIG_H
3475 #define EMACS_CONFIG_H
3476 ])dnl
3477
3478 AH_BOTTOM([
3479 /* Define AMPERSAND_FULL_NAME if you use the convention
3480    that & in the full name stands for the login id.  */
3481 /* Turned on June 1996 supposing nobody will mind it.  */
3482 #define AMPERSAND_FULL_NAME
3483
3484 /* If using GNU, then support inline function declarations.  */
3485 /* Don't try to switch on inline handling as detected by AC_C_INLINE
3486    generally, because even if non-gcc compilers accept `inline', they
3487    may reject `extern inline'.  */
3488 #if defined (__GNUC__) && defined (OPTIMIZE)
3489 #define INLINE __inline__
3490 #else
3491 #define INLINE
3492 #endif
3493
3494 /* `subprocesses' should be defined if you want to
3495    have code for asynchronous subprocesses
3496    (as used in M-x compile and M-x shell).
3497    Only MSDOS does not support this (it overrides
3498    this in its config_opsysfile below).  */
3499
3500 #define subprocesses
3501
3502 /* Include the os and machine dependent files.  */
3503 #include config_opsysfile
3504 #include config_machfile
3505
3506 /* Set up some defines, C and LD flags for NeXTstep interface on GNUstep.
3507   (There is probably a better place to do this, but right now the Cocoa
3508    side does this in s/darwin.h and we cannot
3509    parallel this exactly since GNUstep is multi-OS.  */
3510 #ifdef HAVE_NS
3511 # ifdef NS_IMPL_GNUSTEP
3512 /* GNUstep needs a bit more pure memory.  Of the existing knobs,
3513 SYSTEM_PURESIZE_EXTRA seems like the least likely to cause problems.  */
3514 #  define SYSTEM_PURESIZE_EXTRA 30000
3515 # endif /* NS_IMPL_GNUSTEP */
3516 #endif /* HAVE_NS */
3517
3518 /* SIGTYPE is the macro we actually use.  */
3519 #ifndef SIGTYPE
3520 #define SIGTYPE RETSIGTYPE
3521 #endif
3522
3523 #ifdef emacs /* Don't do this for lib-src.  */
3524 /* Tell regex.c to use a type compatible with Emacs.  */
3525 #define RE_TRANSLATE_TYPE Lisp_Object
3526 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
3527 #ifdef make_number
3528 /* If make_number is a macro, use it.  */
3529 #define RE_TRANSLATE_P(TBL) (!EQ (TBL, make_number (0)))
3530 #else
3531 /* If make_number is a function, avoid it.  */
3532 #define RE_TRANSLATE_P(TBL) (!(INTEGERP (TBL) && XINT (TBL) == 0))
3533 #endif
3534 #endif
3535
3536 /* Avoid link-time collision with system mktime if we will use our own.  */
3537 #if ! HAVE_MKTIME || BROKEN_MKTIME
3538 #define mktime emacs_mktime
3539 #endif
3540
3541 #define my_strftime nstrftime   /* for strftime.c */
3542
3543 /* Some of the files of Emacs which are intended for use with other
3544    programs assume that if you have a config.h file, you must declare
3545    the type of getenv.  */
3546 extern char *getenv ();
3547
3548 /* These default definitions are good for almost all machines.
3549    The exceptions override them in m/MACHINE.h.  */
3550
3551 #ifndef BITS_PER_CHAR
3552 #define BITS_PER_CHAR 8
3553 #endif
3554
3555 #ifndef BITS_PER_SHORT
3556 #define BITS_PER_SHORT 16
3557 #endif
3558
3559 /* Note that lisp.h uses this in a preprocessor conditional, so it
3560    would not work to use sizeof.  That being so, we do all of them
3561    without sizeof, for uniformity's sake.  */
3562 #ifndef BITS_PER_INT
3563 #define BITS_PER_INT 32
3564 #endif
3565
3566 #ifndef BITS_PER_LONG
3567 #ifdef _LP64
3568 #define BITS_PER_LONG 64
3569 #else
3570 #define BITS_PER_LONG 32
3571 #endif
3572 #endif
3573
3574 /* Define if the compiler supports function prototypes.  It may do so but
3575    not define __STDC__ (e.g. DEC C by default) or may define it as zero.  */
3576 #undef PROTOTYPES
3577
3578 #ifdef HAVE_STRING_H
3579 #include <string.h>
3580 #endif
3581
3582 #ifdef HAVE_STRINGS_H
3583 #include <strings.h>  /* May be needed for bcopy & al.  */
3584 #endif
3585
3586 #ifdef HAVE_STDLIB_H
3587 #include <stdlib.h>
3588 #endif
3589
3590 #ifdef HAVE_ALLOCA_H
3591 # include <alloca.h>
3592 #elif defined __GNUC__
3593 # define alloca __builtin_alloca
3594 #elif defined _AIX
3595 # define alloca __alloca
3596 #else
3597 # include <stddef.h>
3598 # ifdef  __cplusplus
3599 extern "C"
3600 # endif
3601 void *alloca (size_t);
3602 #endif
3603
3604 #ifndef HAVE_SIZE_T
3605 typedef unsigned size_t;
3606 #endif
3607
3608 #if defined __GNUC__ && (__GNUC__ > 2 \
3609                          || (__GNUC__ == 2 && __GNUC_MINOR__ >= 5))
3610 #define NO_RETURN       __attribute__ ((__noreturn__))
3611 #else
3612 #define NO_RETURN       /* nothing */
3613 #endif
3614
3615 /* These won't be used automatically yet.  We also need to know, at least,
3616    that the stack is continuous.  */
3617 #ifdef __GNUC__
3618 #  ifndef GC_SETJMP_WORKS
3619   /* GC_SETJMP_WORKS is nearly always appropriate for GCC.  */
3620 #    define GC_SETJMP_WORKS 1
3621 #  endif
3622 #  ifndef GC_LISP_OBJECT_ALIGNMENT
3623 #    define GC_LISP_OBJECT_ALIGNMENT (__alignof__ (Lisp_Object))
3624 #  endif
3625 #endif
3626
3627 #ifndef HAVE_BCOPY
3628 #define bcopy(a,b,s) memcpy (b,a,s)
3629 #endif
3630 #ifndef HAVE_BZERO
3631 #define bzero(a,s) memset (a,0,s)
3632 #endif
3633 #ifndef HAVE_BCMP
3634 #define BCMP memcmp
3635 #endif
3636
3637 #endif /* EMACS_CONFIG_H */
3638
3639 /*
3640 Local Variables:
3641 mode: c
3642 End:
3643 */
3644 ])dnl
3645
3646 #### Report on what we decided to do.
3647 #### Report GTK as a toolkit, even if it doesn't use Xt.
3648 #### It makes printing result more understandable as using GTK sets
3649 #### toolkit_scroll_bars to yes by default.
3650 if test "${HAVE_GTK}" = "yes"; then
3651   USE_X_TOOLKIT=GTK
3652 fi
3653
3654 echo "
3655 Configured for \`${canonical}'.
3656
3657   Where should the build process find the source code?    ${srcdir}
3658   What operating system and machine description files should Emacs use?
3659         \`${opsysfile}' and \`${machfile}'
3660   What compiler should emacs be built with?               ${CC} ${CFLAGS}
3661   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
3662   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
3663   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
3664   What window system should Emacs use?                    ${window_system}
3665   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
3666
3667 if test -n "${x_includes}"; then
3668 echo "  Where do we find X Windows header files?                ${x_includes}"
3669 else
3670 echo "  Where do we find X Windows header files?                Standard dirs"
3671 fi
3672 if test -n "${x_libraries}"; then
3673 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
3674 else
3675 echo "  Where do we find X Windows libraries?                   Standard dirs"
3676 fi
3677
3678 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
3679 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
3680 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
3681 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
3682 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF"
3683 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
3684 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
3685 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
3686 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
3687 echo "  Does Emacs use -lgconf?                                 ${HAVE_GCONF}"
3688 echo "  Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}"
3689
3690 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
3691 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
3692 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
3693 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
3694
3695 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
3696 echo
3697
3698 if test $USE_XASSERTS = yes; then
3699    echo "  Compiling with asserts turned on."
3700    CPPFLAGS="$CPPFLAGS -DXASSERTS=1"
3701 fi
3702
3703 echo
3704
3705 if test "$HAVE_NS" = "yes"; then
3706    echo
3707    echo "You must run \"make install\" in order to test the built application.
3708 The installed application will go to nextstep/Emacs.app and can be
3709 run or moved from there."
3710    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
3711       echo "The application will be fully self-contained."
3712     else
3713       echo "The lisp resources for the application will be installed under ${prefix}.
3714 You may need to run \"make install\" with sudo.  The application will fail
3715 to run if these resources are not installed."
3716    fi
3717    echo
3718 fi
3719
3720 if test "$HAVE_DBUS" = yes && test "${opsys}" != "gnu-linux"; then
3721   echo "D-Bus integration has been tested for GNU/Linux only."
3722   echo
3723 fi
3724
3725
3726 # Remove any trailing slashes in these variables.
3727 [test "${prefix}" != NONE &&
3728   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
3729 test "${exec_prefix}" != NONE &&
3730   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
3731
3732 dnl You might wonder (I did) why epaths.h is generated by running make,
3733 dnl rather than just letting configure generate it from epaths.in.
3734 dnl One reason is that the various paths are not fully expanded (see above);
3735 dnl eg gamedir=${prefix}/var/games/emacs.
3736 dnl Secondly, the GNU Coding standards require that one should be able
3737 dnl to run `make prefix=/some/where/else' and override the values set
3738 dnl by configure.  This also explains the `move-if-change' test and
3739 dnl the use of force in the `epaths-force' rule in Makefile.in.
3740 AC_OUTPUT(Makefile lib-src/Makefile oldXMenu/Makefile \
3741         doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
3742         doc/lispref/Makefile src/Makefile \
3743         lwlib/Makefile lisp/Makefile leim/Makefile, [
3744
3745 ### Make the necessary directories, if they don't exist.
3746 for dir in etc lisp ; do
3747   test -d ${dir} || mkdir ${dir}
3748 done
3749
3750 echo creating src/epaths.h
3751 ${MAKE-make} epaths-force
3752
3753 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
3754   echo creating src/.gdbinit
3755   echo source $srcdir/src/.gdbinit > src/.gdbinit
3756 fi
3757
3758 ], [GCC="$GCC" NON_GNU_CPP="$NON_GNU_CPP" CPP="$CPP" CPPFLAGS="$CPPFLAGS"])
3759
3760 m4_if(dnl       Do not change this comment
3761    arch-tag: 156a4dd5-bddc-4d18-96ac-f37742cf6a5e
3762 )dnl