code.delx.au - gnu-emacs/blob - lisp/net/eww.el

   1 ;;; eww.el --- Emacs Web Wowser
   2
   3 ;; Copyright (C) 2013-2014 Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;; Keywords: html
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;;; Code:
  26
  27 (eval-when-compile (require 'cl))
  28 (require 'format-spec)
  29 (require 'shr)
  30 (require 'url)
  31 (require 'url-queue)
  32 (require 'url-util)                     ; for url-get-url-at-point
  33 (require 'mm-url)
  34 (eval-when-compile (require 'subr-x)) ;; for string-trim
  35
  36 (defgroup eww nil
  37   "Emacs Web Wowser"
  38   :version "25.1"
  39   :link '(custom-manual "(eww) Top")
  40   :group 'web
  41   :prefix "eww-")
  42
  43 (defcustom eww-header-line-format "%t: %u"
  44   "Header line format.
  45 - %t is replaced by the title.
  46 - %u is replaced by the URL."
  47   :version "24.4"
  48   :group 'eww
  49   :type 'string)
  50
  51 (defcustom eww-search-prefix "https://duckduckgo.com/html/?q="
  52   "Prefix URL to search engine"
  53   :version "24.4"
  54   :group 'eww
  55   :type 'string)
  56
  57 (defcustom eww-download-directory "~/Downloads/"
  58   "Directory where files will downloaded."
  59   :version "24.4"
  60   :group 'eww
  61   :type 'string)
  62
  63 (defcustom eww-suggest-uris
  64   '(eww-links-at-point
  65     url-get-url-at-point
  66     eww-current-url)
  67   "List of functions called to form the list of default URIs for `eww'.
  68 Each of the elements is a function returning either a string or a list
  69 of strings.  The results will be joined into a single list with
  70 duplicate entries (if any) removed."
  71   :version "25.1"
  72   :group 'eww
  73   :type 'hook
  74   :options '(eww-links-at-point
  75              url-get-url-at-point
  76              eww-current-url))
  77
  78 (defcustom eww-bookmarks-directory user-emacs-directory
  79   "Directory where bookmark files will be stored."
  80   :version "25.1"
  81   :group 'eww
  82   :type 'string)
  83
  84 (defcustom eww-desktop-remove-duplicates t
  85   "Whether to remove duplicates from the history when saving desktop data.
  86 If non-nil, repetitive EWW history entries (comprising of the URI, the
  87 title, and the point position) will not be saved as part of the Emacs
  88 desktop.  Otherwise, such entries will be retained."
  89   :version "25.1"
  90   :group 'eww
  91   :type 'boolean)
  92
  93 (defcustom eww-restore-desktop nil
  94   "How to restore EWW buffers on `desktop-restore'.
  95 If t or 'auto, the buffers will be reloaded automatically.
  96 If nil, buffers will require manual reload, and will contain the text
  97 specified in `eww-restore-reload-prompt' instead of the actual Web
  98 page contents."
  99   :version "25.1"
 100   :group 'eww
 101   :type '(choice (const :tag "Restore all automatically" t)
 102                  (const :tag "Require manual reload" nil)))
 103
 104 (defcustom eww-restore-reload-prompt
 105   "\n\n *** Use \\[eww-reload] to reload this buffer. ***\n"
 106   "The string to put in the buffers not reloaded on `desktop-restore'.
 107 This prompt will be used if `eww-restore-desktop' is nil.
 108
 109 The string will be passed through `substitute-command-keys'."
 110   :version "25.1"
 111   :group 'eww
 112   :type 'string)
 113
 114 (defcustom eww-history-limit 50
 115   "Maximum number of entries to retain in the history."
 116   :version "25.1"
 117   :group 'eww
 118   :type '(choice (const :tag "Unlimited" nil)
 119                  integer))
 120
 121 (defcustom eww-use-external-browser-for-content-type
 122   "\\`\\(video/\\|audio/\\|application/ogg\\)"
 123   "Always use external browser for specified content-type."
 124   :version "24.4"
 125   :group 'eww
 126   :type '(choice (const :tag "Never" nil)
 127                  regexp))
 128
 129 (defcustom eww-after-render-hook nil
 130   "A hook called after eww has finished rendering the buffer."
 131   :version "25.1"
 132   :group 'eww
 133   :type 'hook)
 134
 135 (defcustom eww-form-checkbox-selected-symbol "[X]"
 136   "Symbol used to represent a selected checkbox.
 137 See also `eww-form-checkbox-symbol'."
 138   :version "24.4"
 139   :group 'eww
 140   :type '(choice (const "[X]")
 141                  (const "☒")            ; Unicode BALLOT BOX WITH X
 142                  (const "☑")            ; Unicode BALLOT BOX WITH CHECK
 143                  string))
 144
 145 (defcustom eww-form-checkbox-symbol "[ ]"
 146   "Symbol used to represent a checkbox.
 147 See also `eww-form-checkbox-selected-symbol'."
 148   :version "24.4"
 149   :group 'eww
 150   :type '(choice (const "[ ]")
 151                  (const "☐")            ; Unicode BALLOT BOX
 152                  string))
 153
 154 (defface eww-form-submit
 155   '((((type x w32 ns) (class color))    ; Like default mode line
 156      :box (:line-width 2 :style released-button)
 157      :background "#808080" :foreground "black"))
 158   "Face for eww buffer buttons."
 159   :version "24.4"
 160   :group 'eww)
 161
 162 (defface eww-form-file
 163   '((((type x w32 ns) (class color))    ; Like default mode line
 164      :box (:line-width 2 :style released-button)
 165      :background "#808080" :foreground "black"))
 166   "Face for eww buffer buttons."
 167   :version "25.1"
 168   :group 'eww)
 169
 170 (defface eww-form-checkbox
 171   '((((type x w32 ns) (class color))    ; Like default mode line
 172      :box (:line-width 2 :style released-button)
 173      :background "lightgrey" :foreground "black"))
 174   "Face for eww buffer buttons."
 175   :version "24.4"
 176   :group 'eww)
 177
 178 (defface eww-form-select
 179   '((((type x w32 ns) (class color))    ; Like default mode line
 180      :box (:line-width 2 :style released-button)
 181      :background "lightgrey" :foreground "black"))
 182   "Face for eww buffer buttons."
 183   :version "24.4"
 184   :group 'eww)
 185
 186 (defface eww-form-text
 187   '((t (:background "#505050"
 188                     :foreground "white"
 189                     :box (:line-width 1))))
 190   "Face for eww text inputs."
 191   :version "24.4"
 192   :group 'eww)
 193
 194 (defface eww-form-textarea
 195   '((t (:background "#C0C0C0"
 196                     :foreground "black"
 197                     :box (:line-width 1))))
 198   "Face for eww textarea inputs."
 199   :version "24.4"
 200   :group 'eww)
 201
 202 (defface eww-invalid-certificate
 203   '((default :weight bold)
 204     (((class color)) :foreground "red"))
 205   "Face for web pages with invalid certificates."
 206   :version "25.1"
 207   :group 'eww)
 208
 209 (defface eww-valid-certificate
 210   '((default :weight bold)
 211     (((class color)) :foreground "ForestGreen"))
 212   "Face for web pages with valid certificates."
 213   :version "25.1"
 214   :group 'eww)
 215
 216 (defvar eww-data nil)
 217 (defvar eww-history nil)
 218 (defvar eww-history-position 0)
 219
 220 (defvar eww-local-regex "localhost"
 221   "When this regex is found in the URL, it's not a keyword but an address.")
 222
 223 (defvar eww-link-keymap
 224   (let ((map (copy-keymap shr-map)))
 225     (define-key map "\r" 'eww-follow-link)
 226     map))
 227
 228 (defun eww-suggested-uris nil
 229   "Return the list of URIs to suggest at the `eww' prompt.
 230 This list can be customized via `eww-suggest-uris'."
 231   (let ((obseen (make-vector 42 0))
 232         (uris nil))
 233     (dolist (fun eww-suggest-uris)
 234       (let ((ret (funcall fun)))
 235         (dolist (uri (if (stringp ret) (list ret) ret))
 236           (when (and uri (not (intern-soft uri obseen)))
 237             (intern uri obseen)
 238             (push   uri uris)))))
 239     (nreverse uris)))
 240
 241 ;;;###autoload
 242 (defun eww (url)
 243   "Fetch URL and render the page.
 244 If the input doesn't look like an URL or a domain name, the
 245 word(s) will be searched for via `eww-search-prefix'."
 246   (interactive
 247    (let* ((uris (eww-suggested-uris))
 248           (prompt (concat "Enter URL or keywords"
 249                           (if uris (format " (default %s)" (car uris)) "")
 250                           ": ")))
 251      (list (read-string prompt nil nil uris))))
 252   (setq url (string-trim url))
 253   (cond ((string-match-p "\\`file:/" url))
 254         ;; Don't mangle file: URLs at all.
 255         ((string-match-p "\\`ftp://" url)
 256          (user-error "FTP is not supported."))
 257         (t
 258          (if (and (= (length (split-string url)) 1)
 259                   (or (and (not (string-match-p "\\`[\"\'].*[\"\']\\'" url))
 260                            (> (length (split-string url "[.:]")) 1))
 261                       (string-match eww-local-regex url)))
 262              (progn
 263                (unless (string-match-p "\\`[a-zA-Z][-a-zA-Z0-9+.]*://" url)
 264                  (setq url (concat "http://" url)))
 265                ;; some site don't redirect final /
 266                (when (string= (url-filename (url-generic-parse-url url)) "")
 267                  (setq url (concat url "/"))))
 268            (setq url (concat eww-search-prefix
 269                              (replace-regexp-in-string " " "+" url))))))
 270   (if (eq major-mode 'eww-mode)
 271       (when (or (plist-get eww-data :url)
 272                 (plist-get eww-data :dom))
 273         (eww-save-history))
 274     (eww-setup-buffer)
 275     (plist-put eww-data :url url)
 276     (eww-update-header-line-format)
 277     (let ((inhibit-read-only t))
 278       (insert (format "Loading %s..." url))
 279       (goto-char (point-min))))
 280   (url-retrieve url 'eww-render
 281                 (list url nil (current-buffer))))
 282
 283 ;;;###autoload (defalias 'browse-web 'eww)
 284
 285 ;;;###autoload
 286 (defun eww-open-file (file)
 287   "Render a file using EWW."
 288   (interactive "fFile: ")
 289   (eww (concat "file://"
 290                (and (memq system-type '(windows-nt ms-dos))
 291                     "/")
 292                (expand-file-name file))))
 293
 294 ;;;###autoload
 295 (defun eww-search-words (&optional beg end)
 296   "Search the web for the text between the point and marker.
 297 See the `eww-search-prefix' variable for the search engine used."
 298   (interactive "r")
 299   (eww (buffer-substring beg end)))
 300
 301 (defun eww-render (status url &optional point buffer encode)
 302   (let ((redirect (plist-get status :redirect)))
 303     (when redirect
 304       (setq url redirect)))
 305   (let* ((headers (eww-parse-headers))
 306          (content-type
 307           (mail-header-parse-content-type
 308            (or (cdr (assoc "content-type" headers))
 309                "text/plain")))
 310          (charset (intern
 311                    (downcase
 312                     (or (cdr (assq 'charset (cdr content-type)))
 313                         (eww-detect-charset (equal (car content-type)
 314                                                    "text/html"))
 315                         "utf-8"))))
 316          (data-buffer (current-buffer)))
 317     ;; Save the https peer status.
 318     (with-current-buffer buffer
 319       (plist-put eww-data :peer (plist-get status :peer)))
 320     (unwind-protect
 321         (progn
 322           (cond
 323            ((and eww-use-external-browser-for-content-type
 324                  (string-match-p eww-use-external-browser-for-content-type
 325                                  (car content-type)))
 326             (eww-browse-with-external-browser url))
 327            ((equal (car content-type) "text/html")
 328             (eww-display-html charset url nil point buffer encode))
 329            ((equal (car content-type) "application/pdf")
 330             (eww-display-pdf))
 331            ((string-match-p "\\`image/" (car content-type))
 332             (eww-display-image buffer))
 333            (t
 334             (eww-display-raw buffer encode)))
 335           (with-current-buffer buffer
 336             (plist-put eww-data :url url)
 337             (eww-update-header-line-format)
 338             (setq eww-history-position 0)
 339             (run-hooks 'eww-after-render-hook)))
 340       (kill-buffer data-buffer))))
 341
 342 (defun eww-parse-headers ()
 343   (let ((headers nil))
 344     (goto-char (point-min))
 345     (while (and (not (eobp))
 346                 (not (eolp)))
 347       (when (looking-at "\\([^:]+\\): *\\(.*\\)")
 348         (push (cons (downcase (match-string 1))
 349                     (match-string 2))
 350               headers))
 351       (forward-line 1))
 352     (unless (eobp)
 353       (forward-line 1))
 354     headers))
 355
 356 (defun eww-detect-charset (html-p)
 357   (let ((case-fold-search t)
 358         (pt (point)))
 359     (or (and html-p
 360              (re-search-forward
 361               "<meta[\t\n\r ]+[^>]*charset=\"?\\([^\t\n\r \"/>]+\\)[\\\"'.*]" nil t)
 362              (goto-char pt)
 363              (match-string 1))
 364         (and (looking-at
 365               "[\t\n\r ]*<\\?xml[\t\n\r ]+[^>]*encoding=\"\\([^\"]+\\)")
 366              (match-string 1)))))
 367
 368 (declare-function libxml-parse-html-region "xml.c"
 369                   (start end &optional base-url))
 370
 371 (defun eww-display-html (charset url &optional document point buffer encode)
 372   (unless (fboundp 'libxml-parse-html-region)
 373     (error "This function requires Emacs to be compiled with libxml2"))
 374   (unless (buffer-live-p buffer)
 375     (error "Buffer %s doesn't exist" buffer))
 376   ;; There should be a better way to abort loading images
 377   ;; asynchronously.
 378   (setq url-queue nil)
 379   (let ((document
 380          (or document
 381              (list
 382               'base (list (cons 'href url))
 383               (progn
 384                 (when (or (and encode
 385                                (not (eq charset encode)))
 386                           (not (eq charset 'utf-8)))
 387                   (condition-case nil
 388                       (decode-coding-region (point) (point-max)
 389                                             (or encode charset))
 390                     (coding-system-error nil)))
 391                 (libxml-parse-html-region (point) (point-max))))))
 392         (source (and (null document)
 393                      (buffer-substring (point) (point-max)))))
 394     (with-current-buffer buffer
 395       (plist-put eww-data :source source)
 396       (plist-put eww-data :dom document)
 397       (let ((inhibit-read-only t)
 398             (inhibit-modification-hooks t)
 399             (shr-target-id (url-target (url-generic-parse-url url)))
 400             (shr-external-rendering-functions
 401              '((title . eww-tag-title)
 402                (form . eww-tag-form)
 403                (input . eww-tag-input)
 404                (textarea . eww-tag-textarea)
 405                (body . eww-tag-body)
 406                (select . eww-tag-select)
 407                (link . eww-tag-link)
 408                (a . eww-tag-a))))
 409         (erase-buffer)
 410         (shr-insert-document document)
 411         (cond
 412          (point
 413           (goto-char point))
 414          (shr-target-id
 415           (goto-char (point-min))
 416           (let ((point (next-single-property-change
 417                         (point-min) 'shr-target-id)))
 418             (when point
 419               (goto-char point))))
 420          (t
 421           (goto-char (point-min))
 422           ;; Don't leave point inside forms, because the normal eww
 423           ;; commands aren't available there.
 424           (while (and (not (eobp))
 425                       (get-text-property (point) 'eww-form))
 426             (forward-line 1)))))
 427       (eww-size-text-inputs))))
 428
 429 (defun eww-handle-link (dom)
 430   (let* ((rel (dom-attr dom 'rel))
 431          (href (dom-attr dom 'href))
 432          (where (assoc
 433                  ;; The text associated with :rel is case-insensitive.
 434                  (if rel (downcase rel))
 435                  '(("next" . :next)
 436                    ;; Texinfo uses "previous", but HTML specifies
 437                    ;; "prev", so recognize both.
 438                    ("previous" . :previous)
 439                    ("prev" . :previous)
 440                    ;; HTML specifies "start" but also "contents",
 441                    ;; and Gtk seems to use "home".  Recognize
 442                    ;; them all; but store them in different
 443                    ;; variables so that we can readily choose the
 444                    ;; "best" one.
 445                    ("start" . :start)
 446                    ("home" . :home)
 447                    ("contents" . :contents)
 448                    ("up" . :up)))))
 449     (and href
 450          where
 451          (plist-put eww-data (cdr where) href))))
 452
 453 (defun eww-tag-link (dom)
 454   (eww-handle-link dom)
 455   (shr-generic dom))
 456
 457 (defun eww-tag-a (dom)
 458   (eww-handle-link dom)
 459   (let ((start (point)))
 460     (shr-tag-a dom)
 461     (put-text-property start (point) 'keymap eww-link-keymap)))
 462
 463 (defun eww-update-header-line-format ()
 464   (setq header-line-format
 465         (and eww-header-line-format
 466              (let ((title (plist-get eww-data :title))
 467                    (peer (plist-get eww-data :peer)))
 468                (when (zerop (length title))
 469                  (setq title "[untitled]"))
 470                ;; This connection has is https.
 471                (when peer
 472                  (setq title
 473                        (propertize title 'face
 474                                    (if (plist-get peer :warnings)
 475                                        'eww-invalid-certificate
 476                                      'eww-valid-certificate))))
 477                (replace-regexp-in-string
 478                 "%" "%%"
 479                 (format-spec
 480                  eww-header-line-format
 481                  `((?u . ,(or (plist-get eww-data :url) ""))
 482                    (?t . ,title))))))))
 483
 484 (defun eww-tag-title (dom)
 485   (plist-put eww-data :title
 486              (replace-regexp-in-string
 487               "^ \\| $" ""
 488               (replace-regexp-in-string "[ \t\r\n]+" " " (dom-text dom))))
 489   (eww-update-header-line-format))
 490
 491 (defun eww-tag-body (dom)
 492   (let* ((start (point))
 493          (fgcolor (or (dom-attr dom 'fgcolor) (dom-attr dom 'text)))
 494          (bgcolor (dom-attr dom 'bgcolor))
 495          (shr-stylesheet (list (cons 'color fgcolor)
 496                                (cons 'background-color bgcolor))))
 497     (shr-generic dom)
 498     (shr-colorize-region start (point) fgcolor bgcolor)))
 499
 500 (defun eww-display-raw (buffer &optional encode)
 501   (let ((data (buffer-substring (point) (point-max))))
 502     (unless (buffer-live-p buffer)
 503       (error "Buffer %s doesn't exist" buffer))
 504     (with-current-buffer buffer
 505       (let ((inhibit-read-only t))
 506         (erase-buffer)
 507         (insert data)
 508         (unless (eq encode 'utf-8)
 509           (encode-coding-region (point-min) (1+ (length data)) 'utf-8)
 510           (condition-case nil
 511               (decode-coding-region (point-min) (1+ (length data)) encode)
 512             (coding-system-error nil))))
 513       (goto-char (point-min)))))
 514
 515 (defun eww-display-image (buffer)
 516   (let ((data (shr-parse-image-data)))
 517     (unless (buffer-live-p buffer)
 518       (error "Buffer %s doesn't exist" buffer))
 519     (with-current-buffer buffer
 520       (let ((inhibit-read-only t))
 521         (erase-buffer)
 522         (shr-put-image data nil))
 523       (goto-char (point-min)))))
 524
 525 (declare-function mailcap-view-mime "mailcap" (type))
 526 (defun eww-display-pdf ()
 527   (let ((data (buffer-substring (point) (point-max))))
 528     (switch-to-buffer (get-buffer-create "*eww pdf*"))
 529     (let ((coding-system-for-write 'raw-text)
 530           (inhibit-read-only t))
 531       (erase-buffer)
 532       (insert data)
 533       (mailcap-view-mime "application/pdf")))
 534   (goto-char (point-min)))
 535
 536 (defun eww-setup-buffer ()
 537   (switch-to-buffer (get-buffer-create "*eww*"))
 538   (let ((inhibit-read-only t))
 539     (remove-overlays)
 540     (erase-buffer))
 541   (unless (eq major-mode 'eww-mode)
 542     (eww-mode)))
 543
 544 (defun eww-current-url nil
 545   "Return URI of the Web page the current EWW buffer is visiting."
 546   (plist-get eww-data :url))
 547
 548 (defun eww-links-at-point (&optional pt)
 549   "Return list of URIs, if any, linked at point."
 550   (remq nil
 551         (list (get-text-property (point) 'shr-url)
 552               (get-text-property (point) 'image-url))))
 553
 554 (defun eww-view-source ()
 555   "View the HTML source code of the current page."
 556   (interactive)
 557   (let ((buf (get-buffer-create "*eww-source*"))
 558         (source (plist-get eww-data :source)))
 559     (with-current-buffer buf
 560       (let ((inhibit-read-only t))
 561         (delete-region (point-min) (point-max))
 562         (insert (or source "no source"))
 563         (goto-char (point-min))
 564         (when (fboundp 'html-mode)
 565           (html-mode))))
 566     (view-buffer buf)))
 567
 568 (defun eww-readable ()
 569   "View the main \"readable\" parts of the current web page.
 570 This command uses heuristics to find the parts of the web page that
 571 contains the main textual portion, leaving out navigation menus and
 572 the like."
 573   (interactive)
 574   (let* ((old-data eww-data)
 575          (dom (with-temp-buffer
 576                 (insert (plist-get old-data :source))
 577                 (condition-case nil
 578                     (decode-coding-region (point-min) (point-max) 'utf-8)
 579                   (coding-system-error nil))
 580                 (libxml-parse-html-region (point-min) (point-max)))))
 581     (eww-score-readability dom)
 582     (eww-save-history)
 583     (eww-display-html nil nil
 584                       (eww-highest-readability dom)
 585                       nil (current-buffer))
 586     (dolist (elem '(:source :url :title :next :previous :up))
 587       (plist-put eww-data elem (plist-get old-data elem)))
 588     (eww-update-header-line-format)))
 589
 590 (defun eww-score-readability (node)
 591   (let ((score -1))
 592     (cond
 593      ((memq (dom-tag node) '(script head comment))
 594       (setq score -2))
 595      ((eq (dom-tag node) 'meta)
 596       (setq score -1))
 597      ((eq (dom-tag node) 'img)
 598       (setq score 2))
 599      ((eq (dom-tag node) 'a)
 600       (setq score (- (length (split-string (dom-text node))))))
 601      (t
 602       (dolist (elem (dom-children node))
 603         (if (stringp elem)
 604             (setq score (+ score (length (split-string elem))))
 605           (setq score (+ score
 606                          (or (cdr (assoc :eww-readability-score (cdr elem)))
 607                              (eww-score-readability elem))))))))
 608     ;; Cache the score of the node to avoid recomputing all the time.
 609     (dom-set-attribute node :eww-readability-score score)
 610     score))
 611
 612 (defun eww-highest-readability (node)
 613   (let ((result node)
 614         highest)
 615     (dolist (elem (dom-non-text-children node))
 616       (when (> (or (dom-attr
 617                     (setq highest (eww-highest-readability elem))
 618                     :eww-readability-score)
 619                    most-negative-fixnum)
 620                (or (dom-attr result :eww-readability-score)
 621                    most-negative-fixnum))
 622         (setq result highest)))
 623     result))
 624
 625 (defvar eww-mode-map
 626   (let ((map (make-sparse-keymap)))
 627     (suppress-keymap map)
 628     (define-key map "q" 'quit-window)
 629     (define-key map "g" 'eww-reload)
 630     (define-key map "G" 'eww)
 631     (define-key map [?\t] 'shr-next-link)
 632     (define-key map [?\M-\t] 'shr-previous-link)
 633     (define-key map [backtab] 'shr-previous-link)
 634     (define-key map [delete] 'scroll-down-command)
 635     (define-key map [?\S-\ ] 'scroll-down-command)
 636     (define-key map "\177" 'scroll-down-command)
 637     (define-key map " " 'scroll-up-command)
 638     (define-key map "l" 'eww-back-url)
 639     (define-key map "r" 'eww-forward-url)
 640     (define-key map "n" 'eww-next-url)
 641     (define-key map "p" 'eww-previous-url)
 642     (define-key map "u" 'eww-up-url)
 643     (define-key map "t" 'eww-top-url)
 644     (define-key map "&" 'eww-browse-with-external-browser)
 645     (define-key map "d" 'eww-download)
 646     (define-key map "w" 'eww-copy-page-url)
 647     (define-key map "C" 'url-cookie-list)
 648     (define-key map "v" 'eww-view-source)
 649     (define-key map "R" 'eww-readable)
 650     (define-key map "H" 'eww-list-histories)
 651     (define-key map "E" 'eww-set-character-encoding)
 652     (define-key map "S" 'eww-list-buffers)
 653
 654     (define-key map "b" 'eww-add-bookmark)
 655     (define-key map "B" 'eww-list-bookmarks)
 656     (define-key map [(meta n)] 'eww-next-bookmark)
 657     (define-key map [(meta p)] 'eww-previous-bookmark)
 658
 659     (easy-menu-define nil map ""
 660       '("Eww"
 661         ["Exit" quit-window t]
 662         ["Close browser" quit-window t]
 663         ["Reload" eww-reload t]
 664         ["Back to previous page" eww-back-url
 665          :active (not (zerop (length eww-history)))]
 666         ["Forward to next page" eww-forward-url
 667          :active (not (zerop eww-history-position))]
 668         ["Browse with external browser" eww-browse-with-external-browser t]
 669         ["Download" eww-download t]
 670         ["View page source" eww-view-source]
 671         ["Copy page URL" eww-copy-page-url t]
 672         ["List histories" eww-list-histories t]
 673         ["List buffers" eww-list-buffers t]
 674         ["Add bookmark" eww-add-bookmark t]
 675         ["List bookmarks" eww-list-bookmarks t]
 676         ["List cookies" url-cookie-list t]
 677        ["Character Encoding" eww-set-character-encoding]))
 678     map))
 679
 680 (defvar eww-tool-bar-map
 681   (let ((map (make-sparse-keymap)))
 682     (dolist (tool-bar-item
 683              '((quit-window . "close")
 684                (eww-reload . "refresh")
 685                (eww-back-url . "left-arrow")
 686                (eww-forward-url . "right-arrow")
 687                (eww-view-source . "show")
 688                (eww-copy-page-url . "copy")
 689                (eww-add-bookmark . "bookmark_add"))) ;; ...
 690       (tool-bar-local-item-from-menu
 691        (car tool-bar-item) (cdr tool-bar-item) map eww-mode-map))
 692     map)
 693   "Tool bar for `eww-mode'.")
 694
 695 (define-derived-mode eww-mode nil "eww"
 696   "Mode for browsing the web.
 697
 698 \\{eww-mode-map}"
 699   (setq-local eww-data (list :title ""))
 700   (setq-local browse-url-browser-function 'eww-browse-url)
 701   (setq-local after-change-functions 'eww-process-text-input)
 702   (setq-local eww-history nil)
 703   (setq-local eww-history-position 0)
 704   (when (boundp 'tool-bar-map)
 705    (setq-local tool-bar-map eww-tool-bar-map))
 706   ;; desktop support
 707   (setq-local desktop-save-buffer 'eww-desktop-misc-data)
 708   (setq truncate-lines t)
 709   (buffer-disable-undo)
 710   (setq buffer-read-only t))
 711
 712 ;;;###autoload
 713 (defun eww-browse-url (url &optional new-window)
 714   (cond (new-window
 715          (switch-to-buffer (generate-new-buffer "*eww*"))
 716          (eww-mode)))
 717   (eww url))
 718
 719 (defun eww-back-url ()
 720   "Go to the previously displayed page."
 721   (interactive)
 722   (when (>= eww-history-position (length eww-history))
 723     (user-error "No previous page"))
 724   (eww-save-history)
 725   (setq eww-history-position (+ eww-history-position 2))
 726   (eww-restore-history (elt eww-history (1- eww-history-position))))
 727
 728 (defun eww-forward-url ()
 729   "Go to the next displayed page."
 730   (interactive)
 731   (when (zerop eww-history-position)
 732     (user-error "No next page"))
 733   (eww-save-history)
 734   (eww-restore-history (elt eww-history (1- eww-history-position))))
 735
 736 (defun eww-restore-history (elem)
 737   (let ((inhibit-read-only t)
 738         (inhibit-modification-hooks t)
 739         (text (plist-get elem :text)))
 740     (setq eww-data elem)
 741     (if (null text)
 742         (eww-reload)                    ; FIXME: restore :point?
 743       (erase-buffer)
 744       (insert text)
 745       (goto-char (plist-get elem :point))
 746       (eww-update-header-line-format))))
 747
 748 (defun eww-next-url ()
 749   "Go to the page marked `next'.
 750 A page is marked `next' if rel=\"next\" appears in a <link>
 751 or <a> tag."
 752   (interactive)
 753   (if (plist-get eww-data :next)
 754       (eww-browse-url (shr-expand-url (plist-get eww-data :next)
 755                                       (plist-get eww-data :url)))
 756     (user-error "No `next' on this page")))
 757
 758 (defun eww-previous-url ()
 759   "Go to the page marked `previous'.
 760 A page is marked `previous' if rel=\"previous\" appears in a <link>
 761 or <a> tag."
 762   (interactive)
 763   (if (plist-get eww-data :previous)
 764       (eww-browse-url (shr-expand-url (plist-get eww-data :previous)
 765                                       (plist-get eww-data :url)))
 766     (user-error "No `previous' on this page")))
 767
 768 (defun eww-up-url ()
 769   "Go to the page marked `up'.
 770 A page is marked `up' if rel=\"up\" appears in a <link>
 771 or <a> tag."
 772   (interactive)
 773   (if (plist-get eww-data :up)
 774       (eww-browse-url (shr-expand-url (plist-get eww-data :up)
 775                                       (plist-get eww-data :url)))
 776     (user-error "No `up' on this page")))
 777
 778 (defun eww-top-url ()
 779   "Go to the page marked `top'.
 780 A page is marked `top' if rel=\"start\", rel=\"home\", or rel=\"contents\"
 781 appears in a <link> or <a> tag."
 782   (interactive)
 783   (let ((best-url (or (plist-get eww-data :start)
 784                       (plist-get eww-data :contents)
 785                       (plist-get eww-data :home))))
 786     (if best-url
 787         (eww-browse-url (shr-expand-url best-url (plist-get eww-data :url)))
 788       (user-error "No `top' for this page"))))
 789
 790 (defun eww-reload (&optional local encode)
 791   "Reload the current page.
 792 If LOCAL (the command prefix), don't reload the page from the
 793 network, but just re-display the HTML already fetched."
 794   (interactive "P")
 795   (let ((url (plist-get eww-data :url)))
 796     (if local
 797         (if (null (plist-get eww-data :dom))
 798             (error "No current HTML data")
 799           (eww-display-html 'utf-8 url (plist-get eww-data :dom)
 800                             (point) (current-buffer)))
 801       (url-retrieve url 'eww-render
 802                     (list url (point) (current-buffer) encode)))))
 803
 804 ;; Form support.
 805
 806 (defvar eww-form nil)
 807
 808 (defvar eww-submit-map
 809   (let ((map (make-sparse-keymap)))
 810     (define-key map "\r" 'eww-submit)
 811     (define-key map [(control c) (control c)] 'eww-submit)
 812     map))
 813
 814 (defvar eww-submit-file
 815   (let ((map (make-sparse-keymap)))
 816     (define-key map "\r" 'eww-select-file)
 817     (define-key map [(control c) (control c)] 'eww-submit)
 818     map))
 819
 820 (defvar eww-checkbox-map
 821   (let ((map (make-sparse-keymap)))
 822     (define-key map " " 'eww-toggle-checkbox)
 823     (define-key map "\r" 'eww-toggle-checkbox)
 824     (define-key map [(control c) (control c)] 'eww-submit)
 825     map))
 826
 827 (defvar eww-text-map
 828   (let ((map (make-keymap)))
 829     (set-keymap-parent map text-mode-map)
 830     (define-key map "\r" 'eww-submit)
 831     (define-key map [(control a)] 'eww-beginning-of-text)
 832     (define-key map [(control c) (control c)] 'eww-submit)
 833     (define-key map [(control e)] 'eww-end-of-text)
 834     (define-key map [?\t] 'shr-next-link)
 835     (define-key map [?\M-\t] 'shr-previous-link)
 836     map))
 837
 838 (defvar eww-textarea-map
 839   (let ((map (make-keymap)))
 840     (set-keymap-parent map text-mode-map)
 841     (define-key map "\r" 'forward-line)
 842     (define-key map [(control c) (control c)] 'eww-submit)
 843     (define-key map [?\t] 'shr-next-link)
 844     (define-key map [?\M-\t] 'shr-previous-link)
 845     map))
 846
 847 (defvar eww-select-map
 848   (let ((map (make-sparse-keymap)))
 849     (define-key map "\r" 'eww-change-select)
 850     (define-key map [(control c) (control c)] 'eww-submit)
 851     map))
 852
 853 (defun eww-beginning-of-text ()
 854   "Move to the start of the input field."
 855   (interactive)
 856   (goto-char (eww-beginning-of-field)))
 857
 858 (defun eww-end-of-text ()
 859   "Move to the end of the text in the input field."
 860   (interactive)
 861   (goto-char (eww-end-of-field))
 862   (let ((start (eww-beginning-of-field)))
 863     (while (and (equal (following-char) ? )
 864                 (> (point) start))
 865       (forward-char -1))
 866     (when (> (point) start)
 867       (forward-char 1))))
 868
 869 (defun eww-beginning-of-field ()
 870   (cond
 871    ((bobp)
 872     (point))
 873    ((not (eq (get-text-property (point) 'eww-form)
 874              (get-text-property (1- (point)) 'eww-form)))
 875     (point))
 876    (t
 877     (previous-single-property-change
 878      (point) 'eww-form nil (point-min)))))
 879
 880 (defun eww-end-of-field ()
 881   (1- (next-single-property-change
 882        (point) 'eww-form nil (point-max))))
 883
 884 (defun eww-tag-form (dom)
 885   (let ((eww-form (list (cons :method (dom-attr dom 'method))
 886                         (cons :action (dom-attr dom 'action))))
 887         (start (point)))
 888     (shr-ensure-paragraph)
 889     (shr-generic dom)
 890     (unless (bolp)
 891       (insert "\n"))
 892     (insert "\n")
 893     (when (> (point) start)
 894       (put-text-property start (1+ start)
 895                          'eww-form eww-form))))
 896
 897 (defun eww-form-submit (dom)
 898   (let ((start (point))
 899         (value (dom-attr dom 'value)))
 900     (setq value
 901           (if (zerop (length value))
 902               "Submit"
 903             value))
 904     (insert value)
 905     (add-face-text-property start (point) 'eww-form-submit)
 906     (put-text-property start (point) 'eww-form
 907                        (list :eww-form eww-form
 908                              :value value
 909                              :type "submit"
 910                              :name (dom-attr dom 'name)))
 911     (put-text-property start (point) 'keymap eww-submit-map)
 912     (insert " ")))
 913
 914 (defun eww-form-checkbox (dom)
 915   (let ((start (point)))
 916     (if (dom-attr dom 'checked)
 917         (insert eww-form-checkbox-selected-symbol)
 918       (insert eww-form-checkbox-symbol))
 919     (add-face-text-property start (point) 'eww-form-checkbox)
 920     (put-text-property start (point) 'eww-form
 921                        (list :eww-form eww-form
 922                              :value (dom-attr dom 'value)
 923                              :type (downcase (dom-attr dom 'type))
 924                              :checked (dom-attr dom 'checked)
 925                              :name (dom-attr dom 'name)))
 926     (put-text-property start (point) 'keymap eww-checkbox-map)
 927     (insert " ")))
 928
 929 (defun eww-form-file (dom)
 930   (let ((start (point))
 931         (value (dom-attr dom 'value)))
 932     (setq value
 933           (if (zerop (length value))
 934               " No file selected"
 935             value))
 936     (insert "Browse")
 937     (add-face-text-property start (point) 'eww-form-file)
 938     (insert value)
 939     (put-text-property start (point) 'eww-form
 940                        (list :eww-form eww-form
 941                              :value (dom-attr dom 'value)
 942                              :type (downcase (dom-attr dom 'type))
 943                              :name (dom-attr dom 'name)))
 944     (put-text-property start (point) 'keymap eww-submit-file)
 945     (insert " ")))
 946
 947 (defun eww-select-file ()
 948   "Change the value of the upload file menu under point."
 949   (interactive)
 950   (let*  ((input (get-text-property (point) 'eww-form)))
 951     (let ((filename
 952            (let ((insert-default-directory t))
 953              (read-file-name "filename:  "))))
 954       (eww-update-field filename (length "Browse"))
 955               (plist-put input :filename filename))))
 956
 957 (defun eww-form-text (dom)
 958   (let ((start (point))
 959         (type (downcase (or (dom-attr dom 'type) "text")))
 960         (value (or (dom-attr dom 'value) ""))
 961         (width (string-to-number (or (dom-attr dom 'size) "40")))
 962         (readonly-property (if (or (dom-attr dom 'disabled)
 963                                    (dom-attr dom 'readonly))
 964                                'read-only
 965                              'inhibit-read-only)))
 966     (insert value)
 967     (when (< (length value) width)
 968       (insert (make-string (- width (length value)) ? )))
 969     (put-text-property start (point) 'face 'eww-form-text)
 970     (put-text-property start (point) 'inhibit-read-only t)
 971     (put-text-property start (point) 'local-map eww-text-map)
 972     (put-text-property start (point) readonly-property t)
 973     (put-text-property start (point) 'eww-form
 974                        (list :eww-form eww-form
 975                              :value value
 976                              :type type
 977                              :name (dom-attr dom 'name)))
 978     (insert " ")))
 979
 980 (defconst eww-text-input-types '("text" "password" "textarea"
 981                                  "color" "date" "datetime" "datetime-local"
 982                                  "email" "month" "number" "search" "tel"
 983                                  "time" "url" "week")
 984   "List of input types which represent a text input.
 985 See URL `https://developer.mozilla.org/en-US/docs/Web/HTML/Element/Input'.")
 986
 987 (defun eww-process-text-input (beg end replace-length)
 988   (when-let (pos (and (< (1+ end) (point-max))
 989                       (> (1- end) (point-min))
 990                       (cond
 991                        ((get-text-property (1+ end) 'eww-form)
 992                         (1+ end))
 993                        ((get-text-property (1- end) 'eww-form)
 994                         (1- end)))))
 995     (let* ((form (get-text-property pos 'eww-form))
 996            (properties (text-properties-at pos))
 997            (inhibit-read-only t)
 998            (length (- end beg replace-length))
 999            (type (plist-get form :type)))
1000       (when (and form
1001                  (member type eww-text-input-types))
1002         (cond
1003          ((> length 0)
1004           ;; Delete some space at the end.
1005           (save-excursion
1006             (goto-char
1007              (if (equal type "textarea")
1008                  (1- (line-end-position))
1009                (eww-end-of-field)))
1010             (while (and (> length 0)
1011                         (eql (following-char) ? ))
1012               (delete-region (1- (point)) (point))
1013               (cl-decf length))))
1014          ((< length 0)
1015           ;; Add padding.
1016           (save-excursion
1017             (goto-char (1- end))
1018             (goto-char
1019              (if (equal type "textarea")
1020                  (1- (line-end-position))
1021                (1+ (eww-end-of-field))))
1022             (let ((start (point)))
1023               (insert (make-string (abs length) ? ))
1024               (set-text-properties start (point) properties))
1025             (goto-char (1- end)))))
1026         (set-text-properties (plist-get form :start) (plist-get form :end)
1027                              properties)
1028         (let ((value (buffer-substring-no-properties
1029                       (eww-beginning-of-field)
1030                       (eww-end-of-field))))
1031           (when (string-match " +\\'" value)
1032             (setq value (substring value 0 (match-beginning 0))))
1033           (plist-put form :value value)
1034           (when (equal type "password")
1035             ;; Display passwords as asterisks.
1036             (let ((start (eww-beginning-of-field)))
1037               (put-text-property start (+ start (length value))
1038                                  'display (make-string (length value) ?*)))))))))
1039
1040 (defun eww-tag-textarea (dom)
1041   (let ((start (point))
1042         (value (or (dom-attr dom 'value) ""))
1043         (lines (string-to-number (or (dom-attr dom 'rows) "10")))
1044         (width (string-to-number (or (dom-attr dom 'cols) "10")))
1045         end)
1046     (shr-ensure-newline)
1047     (insert value)
1048     (shr-ensure-newline)
1049     (when (< (count-lines start (point)) lines)
1050       (dotimes (i (- lines (count-lines start (point))))
1051         (insert "\n")))
1052     (setq end (point-marker))
1053     (goto-char start)
1054     (while (< (point) end)
1055       (end-of-line)
1056       (let ((pad (- width (- (point) (line-beginning-position)))))
1057         (when (> pad 0)
1058           (insert (make-string pad ? ))))
1059       (add-face-text-property (line-beginning-position)
1060                               (point) 'eww-form-textarea)
1061       (put-text-property (line-beginning-position) (point) 'inhibit-read-only t)
1062       (put-text-property (line-beginning-position) (point)
1063                          'local-map eww-textarea-map)
1064       (forward-line 1))
1065     (put-text-property start (point) 'eww-form
1066                        (list :eww-form eww-form
1067                              :value value
1068                              :type "textarea"
1069                              :name (dom-attr dom 'name)))))
1070
1071 (defun eww-tag-input (dom)
1072   (let ((type (downcase (or (dom-attr dom 'type) "text")))
1073         (start (point)))
1074     (cond
1075      ((or (equal type "checkbox")
1076           (equal type "radio"))
1077       (eww-form-checkbox dom))
1078      ((equal type "file")
1079       (eww-form-file dom))
1080      ((equal type "submit")
1081       (eww-form-submit dom))
1082      ((equal type "hidden")
1083       (let ((form eww-form)
1084             (name (dom-attr dom 'name)))
1085         ;; Don't add <input type=hidden> elements repeatedly.
1086         (while (and form
1087                     (or (not (consp (car form)))
1088                         (not (eq (caar form) 'hidden))
1089                         (not (equal (plist-get (cdr (car form)) :name)
1090                                     name))))
1091           (setq form (cdr form)))
1092         (unless form
1093           (nconc eww-form (list
1094                            (list 'hidden
1095                                  :name name
1096                                  :value (dom-attr dom 'value)))))))
1097      (t
1098       (eww-form-text dom)))
1099     (unless (= start (point))
1100       (put-text-property start (1+ start) 'help-echo "Input field"))))
1101
1102 (defun eww-tag-select (dom)
1103   (shr-ensure-paragraph)
1104   (let ((menu (list :name (dom-attr dom 'name)
1105                     :eww-form eww-form))
1106         (options nil)
1107         (start (point))
1108         (max 0)
1109         opelem)
1110     (if (eq (dom-tag dom) 'optgroup)
1111         (dolist (groupelem (dom-children dom))
1112           (unless (dom-attr groupelem 'disabled)
1113             (setq opelem (append opelem (list groupelem)))))
1114       (setq opelem (list dom)))
1115     (dolist (elem opelem)
1116       (when (eq (dom-tag elem) 'option)
1117         (when (dom-attr elem 'selected)
1118           (nconc menu (list :value (dom-attr elem 'value))))
1119         (let ((display (dom-text elem)))
1120           (setq max (max max (length display)))
1121           (push (list 'item
1122                       :value (dom-attr elem 'value)
1123                       :display display)
1124                 options))))
1125     (when options
1126       (setq options (nreverse options))
1127       ;; If we have no selected values, default to the first value.
1128       (unless (plist-get menu :value)
1129         (nconc menu (list :value (nth 2 (car options)))))
1130       (nconc menu options)
1131       (let ((selected (eww-select-display menu)))
1132         (insert selected
1133                 (make-string (- max (length selected)) ? )))
1134       (put-text-property start (point) 'eww-form menu)
1135       (add-face-text-property start (point) 'eww-form-select)
1136       (put-text-property start (point) 'keymap eww-select-map)
1137       (unless (= start (point))
1138        (put-text-property start (1+ start) 'help-echo "select field"))
1139       (shr-ensure-paragraph))))
1140
1141 (defun eww-select-display (select)
1142   (let ((value (plist-get select :value))
1143         display)
1144     (dolist (elem select)
1145       (when (and (consp elem)
1146                  (eq (car elem) 'item)
1147                  (equal value (plist-get (cdr elem) :value)))
1148         (setq display (plist-get (cdr elem) :display))))
1149     display))
1150
1151 (defun eww-change-select ()
1152   "Change the value of the select drop-down menu under point."
1153   (interactive)
1154   (let* ((input (get-text-property (point) 'eww-form))
1155          (completion-ignore-case t)
1156          (options
1157           (delq nil
1158                 (mapcar (lambda (elem)
1159                           (and (consp elem)
1160                                (eq (car elem) 'item)
1161                                (cons (plist-get (cdr elem) :display)
1162                                      (plist-get (cdr elem) :value))))
1163                         input)))
1164          (display
1165           (completing-read "Change value: " options nil 'require-match))
1166          (inhibit-read-only t))
1167     (plist-put input :value (cdr (assoc-string display options t)))
1168     (goto-char
1169      (eww-update-field display))))
1170
1171 (defun eww-update-field (string &optional offset)
1172   (if (not offset) (setq offset 0))
1173   (let ((properties (text-properties-at (point)))
1174         (start (+ (eww-beginning-of-field) offset))
1175         (current-end (1+ (eww-end-of-field)))
1176         (new-end (1+ (+ (eww-beginning-of-field) (length string)))))
1177     (delete-region start current-end)
1178     (forward-char offset)
1179     (insert string
1180             (make-string (- (- (+ new-end offset) start) (length string)) ? ))
1181     (if (= 0 offset) (set-text-properties start new-end properties))
1182     start))
1183
1184 (defun eww-toggle-checkbox ()
1185   "Toggle the value of the checkbox under point."
1186   (interactive)
1187   (let* ((input (get-text-property (point) 'eww-form))
1188          (type (plist-get input :type)))
1189     (if (equal type "checkbox")
1190         (goto-char
1191          (1+
1192           (if (plist-get input :checked)
1193               (progn
1194                 (plist-put input :checked nil)
1195                 (eww-update-field eww-form-checkbox-symbol))
1196             (plist-put input :checked t)
1197             (eww-update-field eww-form-checkbox-selected-symbol))))
1198       ;; Radio button.  Switch all other buttons off.
1199       (let ((name (plist-get input :name)))
1200         (save-excursion
1201           (dolist (elem (eww-inputs (plist-get input :eww-form)))
1202             (when (equal (plist-get (cdr elem) :name) name)
1203               (goto-char (car elem))
1204               (if (not (eq (cdr elem) input))
1205                   (progn
1206                     (plist-put input :checked nil)
1207                     (eww-update-field eww-form-checkbox-symbol))
1208                 (plist-put input :checked t)
1209                 (eww-update-field eww-form-checkbox-selected-symbol)))))
1210         (forward-char 1)))))
1211
1212 (defun eww-inputs (form)
1213   (let ((start (point-min))
1214         (inputs nil))
1215     (while (and start
1216                 (< start (point-max)))
1217       (when (or (get-text-property start 'eww-form)
1218                 (setq start (next-single-property-change start 'eww-form)))
1219         (when (eq (plist-get (get-text-property start 'eww-form) :eww-form)
1220                   form)
1221           (push (cons start (get-text-property start 'eww-form))
1222                 inputs))
1223         (setq start (next-single-property-change start 'eww-form))))
1224     (nreverse inputs)))
1225
1226 (defun eww-size-text-inputs ()
1227   (let ((start (point-min)))
1228     (while (and start
1229                 (< start (point-max)))
1230       (when (or (get-text-property start 'eww-form)
1231                 (setq start (next-single-property-change start 'eww-form)))
1232         (let ((props (get-text-property start 'eww-form)))
1233           (plist-put props :start start)
1234           (setq start (next-single-property-change
1235                        start 'eww-form nil (point-max)))
1236           (plist-put props :end start))))))
1237
1238 (defun eww-input-value (input)
1239   (let ((type (plist-get input :type))
1240         (value (plist-get input :value)))
1241     (cond
1242      ((equal type "textarea")
1243       (with-temp-buffer
1244         (insert value)
1245         (goto-char (point-min))
1246         (while (re-search-forward "^ +\n\\| +$" nil t)
1247           (replace-match "" t t))
1248         (buffer-string)))
1249      (t
1250       (if (string-match " +\\'" value)
1251           (substring value 0 (match-beginning 0))
1252         value)))))
1253
1254 (defun eww-submit ()
1255   "Submit the current form."
1256   (interactive)
1257   (let* ((this-input (get-text-property (point) 'eww-form))
1258          (form (plist-get this-input :eww-form))
1259          values next-submit)
1260     (dolist (elem (sort (eww-inputs form)
1261                         (lambda (o1 o2)
1262                           (< (car o1) (car o2)))))
1263       (let* ((input (cdr elem))
1264              (input-start (car elem))
1265              (name (plist-get input :name)))
1266         (when name
1267           (cond
1268            ((member (plist-get input :type) '("checkbox" "radio"))
1269             (when (plist-get input :checked)
1270               (push (cons name (plist-get input :value))
1271                     values)))
1272            ((equal (plist-get input :type) "file")
1273             (push (cons "file"
1274                         (list (cons "filedata"
1275                                     (with-temp-buffer
1276                                       (insert-file-contents
1277                                        (plist-get input :filename))
1278                                       (buffer-string)))
1279                               (cons "name" (plist-get input :name))
1280                               (cons "filename" (plist-get input :filename))))
1281                   values))
1282            ((equal (plist-get input :type) "submit")
1283             ;; We want the values from buttons if we hit a button if
1284             ;; we hit enter on it, or if it's the first button after
1285             ;; the field we did hit return on.
1286             (when (or (eq input this-input)
1287                       (and (not (eq input this-input))
1288                            (null next-submit)
1289                            (> input-start (point))))
1290               (setq next-submit t)
1291               (push (cons name (plist-get input :value))
1292                     values)))
1293            (t
1294             (push (cons name (eww-input-value input))
1295                   values))))))
1296     (dolist (elem form)
1297       (when (and (consp elem)
1298                  (eq (car elem) 'hidden))
1299         (push (cons (plist-get (cdr elem) :name)
1300                     (or (plist-get (cdr elem) :value) ""))
1301               values)))
1302     (if (and (stringp (cdr (assq :method form)))
1303              (equal (downcase (cdr (assq :method form))) "post"))
1304         (let ((mtype))
1305           (dolist (x values mtype)
1306             (if (equal (car x) "file")
1307                 (progn
1308                   (setq mtype "multipart/form-data"))))
1309           (cond ((equal mtype "multipart/form-data")
1310                  (let ((boundary (mml-compute-boundary '())))
1311                    (let ((url-request-method "POST")
1312                          (url-request-extra-headers
1313                           (list (cons "Content-Type"
1314                                       (concat "multipart/form-data; boundary="
1315                                               boundary))))
1316                          (url-request-data
1317                           (mm-url-encode-multipart-form-data values boundary)))
1318                      (eww-browse-url (shr-expand-url
1319                                       (cdr (assq :action form))
1320                                       (plist-get eww-data :url))))))
1321                 (t
1322                  (let ((url-request-method "POST")
1323                        (url-request-extra-headers
1324                         '(("Content-Type" .
1325                            "application/x-www-form-urlencoded")))
1326                        (url-request-data
1327                         (mm-url-encode-www-form-urlencoded values)))
1328                    (eww-browse-url (shr-expand-url
1329                                     (cdr (assq :action form))
1330                                     (plist-get eww-data :url)))))))
1331       (eww-browse-url
1332        (concat
1333         (if (cdr (assq :action form))
1334             (shr-expand-url (cdr (assq :action form)) (plist-get eww-data :url))
1335           (plist-get eww-data :url))
1336         "?"
1337         (mm-url-encode-www-form-urlencoded values))))))
1338
1339 (defun eww-browse-with-external-browser (&optional url)
1340   "Browse the current URL with an external browser.
1341 The browser to used is specified by the `shr-external-browser' variable."
1342   (interactive)
1343   (funcall shr-external-browser (or url (plist-get eww-data :url))))
1344
1345 (defun eww-follow-link (&optional external mouse-event)
1346   "Browse the URL under point.
1347 If EXTERNAL is single prefix, browse the URL using `shr-external-browser'.
1348 If EXTERNAL is double prefix, browse in new buffer."
1349   (interactive (list current-prefix-arg last-nonmenu-event))
1350   (mouse-set-point mouse-event)
1351   (let ((url (get-text-property (point) 'shr-url)))
1352     (cond
1353      ((not url)
1354       (message "No link under point"))
1355      ((string-match "^mailto:" url)
1356       (browse-url-mail url))
1357      ((and (consp external) (<= (car external) 4))
1358       (funcall shr-external-browser url))
1359      ;; This is a #target url in the same page as the current one.
1360      ((and (url-target (url-generic-parse-url url))
1361            (eww-same-page-p url (plist-get eww-data :url)))
1362       (let ((dom (plist-get eww-data :dom)))
1363         (eww-save-history)
1364         (eww-display-html 'utf-8 url dom nil (current-buffer))))
1365      (t
1366       (eww-browse-url url external)))))
1367
1368 (defun eww-same-page-p (url1 url2)
1369   "Return non-nil if both URLs represent the same page.
1370 Differences in #targets are ignored."
1371   (let ((obj1 (url-generic-parse-url url1))
1372         (obj2 (url-generic-parse-url url2)))
1373     (setf (url-target obj1) nil)
1374     (setf (url-target obj2) nil)
1375     (equal (url-recreate-url obj1) (url-recreate-url obj2))))
1376
1377 (defun eww-copy-page-url ()
1378   "Copy the URL of the current page into the kill ring."
1379   (interactive)
1380   (message "%s" (plist-get eww-data :url))
1381   (kill-new (plist-get eww-data :url)))
1382
1383 (defun eww-download ()
1384   "Download URL under point to `eww-download-directory'."
1385   (interactive)
1386   (let ((url (get-text-property (point) 'shr-url)))
1387     (if (not url)
1388         (message "No URL under point")
1389       (url-retrieve url 'eww-download-callback (list url)))))
1390
1391 (defun eww-download-callback (status url)
1392   (unless (plist-get status :error)
1393     (let* ((obj (url-generic-parse-url url))
1394            (path (car (url-path-and-query obj)))
1395            (file (eww-make-unique-file-name (file-name-nondirectory path)
1396                                             eww-download-directory)))
1397       (goto-char (point-min))
1398       (re-search-forward "\r?\n\r?\n")
1399       (write-region (point) (point-max) file)
1400       (message "Saved %s" file))))
1401
1402 (defun eww-make-unique-file-name (file directory)
1403     (cond
1404      ((zerop (length file))
1405       (setq file "!"))
1406      ((string-match "\\`[.]" file)
1407       (setq file (concat "!" file))))
1408     (let ((count 1))
1409       (while (file-exists-p (expand-file-name file directory))
1410         (setq file
1411               (if (string-match "\\`\\(.*\\)\\([.][^.]+\\)" file)
1412                   (format "%s(%d)%s" (match-string 1 file)
1413                           count (match-string 2 file))
1414                 (format "%s(%d)" file count)))
1415         (setq count (1+ count)))
1416       (expand-file-name file directory)))
1417
1418 (defun eww-set-character-encoding (charset)
1419   "Set character encoding."
1420   (interactive "zUse character set (default utf-8): ")
1421   (if (null charset)
1422       (eww-reload nil 'utf-8)
1423     (eww-reload nil charset)))
1424
1425 ;;; Bookmarks code
1426
1427 (defvar eww-bookmarks nil)
1428
1429 (defun eww-add-bookmark ()
1430   "Add the current page to the bookmarks."
1431   (interactive)
1432   (eww-read-bookmarks)
1433   (dolist (bookmark eww-bookmarks)
1434     (when (equal (plist-get eww-data :url) (plist-get bookmark :url))
1435       (user-error "Already bookmarked")))
1436   (if (y-or-n-p "bookmark this page? ")
1437       (progn
1438         (let ((title (replace-regexp-in-string "[\n\t\r]" " "
1439                                                (plist-get eww-data :title))))
1440           (setq title (replace-regexp-in-string "\\` +\\| +\\'" "" title))
1441           (push (list :url (plist-get eww-data :url)
1442                       :title title
1443                       :time (current-time-string))
1444                 eww-bookmarks))
1445         (eww-write-bookmarks)
1446         (message "Bookmarked %s (%s)" (plist-get eww-data :url)
1447                  (plist-get eww-data :title)))))
1448
1449 (defun eww-write-bookmarks ()
1450   (with-temp-file (expand-file-name "eww-bookmarks" eww-bookmarks-directory)
1451     (insert ";; Auto-generated file; don't edit\n")
1452     (pp eww-bookmarks (current-buffer))))
1453
1454 (defun eww-read-bookmarks ()
1455   (let ((file (expand-file-name "eww-bookmarks" eww-bookmarks-directory)))
1456     (setq eww-bookmarks
1457           (unless (zerop (or (nth 7 (file-attributes file)) 0))
1458             (with-temp-buffer
1459               (insert-file-contents file)
1460               (read (current-buffer)))))))
1461
1462 ;;;###autoload
1463 (defun eww-list-bookmarks ()
1464   "Display the bookmarks."
1465   (interactive)
1466   (eww-bookmark-prepare)
1467   (pop-to-buffer "*eww bookmarks*"))
1468
1469 (defun eww-bookmark-prepare ()
1470   (eww-read-bookmarks)
1471   (unless eww-bookmarks
1472     (user-error "No bookmarks are defined"))
1473   (set-buffer (get-buffer-create "*eww bookmarks*"))
1474   (eww-bookmark-mode)
1475   (let* ((width (/ (window-width) 2))
1476          (format (format "%%-%ds %%s" width))
1477          (inhibit-read-only t)
1478          start title)
1479     (erase-buffer)
1480     (setq header-line-format (concat " " (format format "Title" "URL")))
1481     (dolist (bookmark eww-bookmarks)
1482       (setq start (point)
1483             title (plist-get bookmark :title))
1484       (when (> (length title) width)
1485         (setq title (substring title 0 width)))
1486       (insert (format format title (plist-get bookmark :url)) "\n")
1487       (put-text-property start (1+ start) 'eww-bookmark bookmark))
1488     (goto-char (point-min))))
1489
1490 (defvar eww-bookmark-kill-ring nil)
1491
1492 (defun eww-bookmark-kill ()
1493   "Kill the current bookmark."
1494   (interactive)
1495   (let* ((start (line-beginning-position))
1496          (bookmark (get-text-property start 'eww-bookmark))
1497          (inhibit-read-only t))
1498     (unless bookmark
1499       (user-error "No bookmark on the current line"))
1500     (forward-line 1)
1501     (push (buffer-substring start (point)) eww-bookmark-kill-ring)
1502     (delete-region start (point))
1503     (setq eww-bookmarks (delq bookmark eww-bookmarks))
1504     (eww-write-bookmarks)))
1505
1506 (defun eww-bookmark-yank ()
1507   "Yank a previously killed bookmark to the current line."
1508   (interactive)
1509   (unless eww-bookmark-kill-ring
1510     (user-error "No previously killed bookmark"))
1511   (beginning-of-line)
1512   (let ((inhibit-read-only t)
1513         (start (point))
1514         bookmark)
1515     (insert (pop eww-bookmark-kill-ring))
1516     (setq bookmark (get-text-property start 'eww-bookmark))
1517     (if (= start (point-min))
1518         (push bookmark eww-bookmarks)
1519       (let ((line (count-lines start (point))))
1520         (setcdr (nthcdr (1- line) eww-bookmarks)
1521                 (cons bookmark (nthcdr line eww-bookmarks)))))
1522     (eww-write-bookmarks)))
1523
1524 (defun eww-bookmark-browse ()
1525   "Browse the bookmark under point in eww."
1526   (interactive)
1527   (let ((bookmark (get-text-property (line-beginning-position) 'eww-bookmark)))
1528     (unless bookmark
1529       (user-error "No bookmark on the current line"))
1530     (quit-window)
1531     (eww-browse-url (plist-get bookmark :url))))
1532
1533 (defun eww-next-bookmark ()
1534   "Go to the next bookmark in the list."
1535   (interactive)
1536   (let ((first nil)
1537         bookmark)
1538     (unless (get-buffer "*eww bookmarks*")
1539       (setq first t)
1540       (eww-bookmark-prepare))
1541     (with-current-buffer (get-buffer "*eww bookmarks*")
1542       (when (and (not first)
1543                  (not (eobp)))
1544         (forward-line 1))
1545       (setq bookmark (get-text-property (line-beginning-position)
1546                                         'eww-bookmark))
1547       (unless bookmark
1548         (user-error "No next bookmark")))
1549     (eww-browse-url (plist-get bookmark :url))))
1550
1551 (defun eww-previous-bookmark ()
1552   "Go to the previous bookmark in the list."
1553   (interactive)
1554   (let ((first nil)
1555         bookmark)
1556     (unless (get-buffer "*eww bookmarks*")
1557       (setq first t)
1558       (eww-bookmark-prepare))
1559     (with-current-buffer (get-buffer "*eww bookmarks*")
1560       (if first
1561           (goto-char (point-max))
1562         (beginning-of-line))
1563       ;; On the final line.
1564       (when (eolp)
1565         (forward-line -1))
1566       (if (bobp)
1567           (user-error "No previous bookmark")
1568         (forward-line -1))
1569       (setq bookmark (get-text-property (line-beginning-position)
1570                                         'eww-bookmark)))
1571     (eww-browse-url (plist-get bookmark :url))))
1572
1573 (defvar eww-bookmark-mode-map
1574   (let ((map (make-sparse-keymap)))
1575     (suppress-keymap map)
1576     (define-key map "q" 'quit-window)
1577     (define-key map [(control k)] 'eww-bookmark-kill)
1578     (define-key map [(control y)] 'eww-bookmark-yank)
1579     (define-key map "\r" 'eww-bookmark-browse)
1580
1581     (easy-menu-define nil map
1582       "Menu for `eww-bookmark-mode-map'."
1583       '("Eww Bookmark"
1584         ["Exit" quit-window t]
1585         ["Browse" eww-bookmark-browse
1586          :active (get-text-property (line-beginning-position) 'eww-bookmark)]
1587         ["Kill" eww-bookmark-kill
1588          :active (get-text-property (line-beginning-position) 'eww-bookmark)]
1589         ["Yank" eww-bookmark-yank
1590          :active eww-bookmark-kill-ring]))
1591     map))
1592
1593 (define-derived-mode eww-bookmark-mode nil "eww bookmarks"
1594   "Mode for listing bookmarks.
1595
1596 \\{eww-bookmark-mode-map}"
1597   (buffer-disable-undo)
1598   (setq buffer-read-only t
1599         truncate-lines t))
1600
1601 ;;; History code
1602
1603 (defun eww-save-history ()
1604   (plist-put eww-data :point (point))
1605   (plist-put eww-data :text (buffer-string))
1606   (push eww-data eww-history)
1607   (setq eww-data (list :title ""))
1608   ;; Don't let the history grow infinitely.  We store quite a lot of
1609   ;; data per page.
1610   (when-let (tail (and eww-history-limit
1611                        (nthcdr eww-history-limit eww-history)))
1612     (setcdr tail nil)))
1613
1614 (defvar eww-current-buffer)
1615
1616 (defun eww-list-histories ()
1617   "List the eww-histories."
1618   (interactive)
1619   (when (null eww-history)
1620     (error "No eww-histories are defined"))
1621   (let ((eww-history-trans eww-history)
1622         (buffer (current-buffer)))
1623     (set-buffer (get-buffer-create "*eww history*"))
1624     (eww-history-mode)
1625     (setq-local eww-current-buffer buffer)
1626     (let ((inhibit-read-only t)
1627           (domain-length 0)
1628           (title-length 0)
1629           url title format start)
1630       (erase-buffer)
1631       (dolist (history eww-history-trans)
1632         (setq start (point))
1633         (setq domain-length (max domain-length (length (plist-get history :url))))
1634         (setq title-length (max title-length (length (plist-get history :title)))))
1635       (setq format (format "%%-%ds %%-%ds" title-length domain-length)
1636             header-line-format
1637             (concat " " (format format "Title" "URL")))
1638       (dolist (history eww-history-trans)
1639         (setq start (point))
1640         (setq url (plist-get history :url))
1641         (setq title (plist-get history :title))
1642         (insert (format format title url))
1643         (insert "\n")
1644         (put-text-property start (1+ start) 'eww-history history))
1645       (goto-char (point-min)))
1646     (pop-to-buffer "*eww history*")))
1647
1648 (defun eww-history-browse ()
1649   "Browse the history under point in eww."
1650   (interactive)
1651   (let ((history (get-text-property (line-beginning-position) 'eww-history)))
1652     (unless history
1653       (error "No history on the current line"))
1654     (let ((buffer eww-current-buffer))
1655       (quit-window)
1656       (when buffer
1657         (switch-to-buffer buffer)))
1658     (eww-restore-history history)))
1659
1660 (defvar eww-history-mode-map
1661   (let ((map (make-sparse-keymap)))
1662     (suppress-keymap map)
1663     (define-key map "q" 'quit-window)
1664     (define-key map "\r" 'eww-history-browse)
1665 ;;    (define-key map "n" 'next-error-no-select)
1666 ;;    (define-key map "p" 'previous-error-no-select)
1667
1668     (easy-menu-define nil map
1669       "Menu for `eww-history-mode-map'."
1670       '("Eww History"
1671         ["Exit" quit-window t]
1672         ["Browse" eww-history-browse
1673          :active (get-text-property (line-beginning-position) 'eww-history)]))
1674     map))
1675
1676 (define-derived-mode eww-history-mode nil "eww history"
1677   "Mode for listing eww-histories.
1678
1679 \\{eww-history-mode-map}"
1680   (buffer-disable-undo)
1681   (setq buffer-read-only t
1682         truncate-lines t))
1683
1684 ;;; eww buffers list
1685
1686 (defun eww-list-buffers ()
1687   "Enlist eww buffers."
1688   (interactive)
1689   (let (buffers-info
1690         (current (current-buffer)))
1691     (dolist (buffer (buffer-list))
1692       (with-current-buffer buffer
1693         (when (derived-mode-p 'eww-mode)
1694           (push (vector buffer (plist-get eww-data :title)
1695                         (plist-get eww-data :url))
1696                 buffers-info))))
1697     (unless buffers-info
1698       (error "No eww buffers"))
1699     (setq buffers-info (nreverse buffers-info)) ;more recent on top
1700     (set-buffer (get-buffer-create "*eww buffers*"))
1701     (eww-buffers-mode)
1702     (let ((inhibit-read-only t)
1703           (domain-length 0)
1704           (title-length 0)
1705           url title format start)
1706       (erase-buffer)
1707       (dolist (buffer-info buffers-info)
1708         (setq title-length (max title-length
1709                                 (length (elt buffer-info 1)))
1710               domain-length (max domain-length
1711                                  (length (elt buffer-info 2)))))
1712       (setq format (format "%%-%ds %%-%ds" title-length domain-length)
1713             header-line-format
1714             (concat " " (format format "Title" "URL")))
1715       (let ((line 0)
1716             (current-buffer-line 1))
1717         (dolist (buffer-info buffers-info)
1718           (setq start (point)
1719                 title (elt buffer-info 1)
1720                 url (elt buffer-info 2)
1721                 line (1+ line))
1722           (insert (format format title url))
1723           (insert "\n")
1724           (let ((buffer (elt buffer-info 0)))
1725             (put-text-property start (1+ start) 'eww-buffer
1726                                buffer)
1727             (when (eq current buffer)
1728               (setq current-buffer-line line))))
1729         (goto-char (point-min))
1730         (forward-line (1- current-buffer-line)))))
1731   (pop-to-buffer "*eww buffers*"))
1732
1733 (defun eww-buffer-select ()
1734   "Switch to eww buffer."
1735   (interactive)
1736   (let ((buffer (get-text-property (line-beginning-position)
1737                                    'eww-buffer)))
1738     (unless buffer
1739       (error "No buffer on current line"))
1740     (quit-window)
1741     (switch-to-buffer buffer)))
1742
1743 (defun eww-buffer-show ()
1744   "Display buffer under point in eww buffer list."
1745   (let ((buffer (get-text-property (line-beginning-position)
1746                                    'eww-buffer)))
1747     (unless buffer
1748       (error "No buffer on current line"))
1749     (other-window -1)
1750     (switch-to-buffer buffer)
1751     (other-window 1)))
1752
1753 (defun eww-buffer-show-next ()
1754   "Move to next eww buffer in the list and display it."
1755   (interactive)
1756   (forward-line)
1757   (when (eobp)
1758     (goto-char (point-min)))
1759   (eww-buffer-show))
1760
1761 (defun eww-buffer-show-previous ()
1762   "Move to previous eww buffer in the list and display it."
1763   (interactive)
1764   (beginning-of-line)
1765   (when (bobp)
1766     (goto-char (point-max)))
1767   (forward-line -1)
1768   (eww-buffer-show))
1769
1770 (defun eww-buffer-kill ()
1771   "Kill buffer from eww list."
1772   (interactive)
1773   (let* ((start (line-beginning-position))
1774          (buffer (get-text-property start 'eww-buffer))
1775          (inhibit-read-only t))
1776     (unless buffer
1777       (user-error "No buffer on the current line"))
1778     (kill-buffer buffer)
1779     (forward-line 1)
1780     (delete-region start (point)))
1781   (when (eobp)
1782     (forward-line -1))
1783   (eww-buffer-show))
1784
1785 (defvar eww-buffers-mode-map
1786   (let ((map (make-sparse-keymap)))
1787     (suppress-keymap map)
1788     (define-key map "q" 'quit-window)
1789     (define-key map [(control k)] 'eww-buffer-kill)
1790     (define-key map "\r" 'eww-buffer-select)
1791     (define-key map "n" 'eww-buffer-show-next)
1792     (define-key map "p" 'eww-buffer-show-previous)
1793
1794     (easy-menu-define nil map
1795       "Menu for `eww-buffers-mode-map'."
1796       '("Eww Buffers"
1797         ["Exit" quit-window t]
1798         ["Select" eww-buffer-select
1799          :active (get-text-property (line-beginning-position) 'eww-buffer)]
1800         ["Kill" eww-buffer-kill
1801          :active (get-text-property (line-beginning-position) 'eww-buffer)]))
1802     map))
1803
1804 (define-derived-mode eww-buffers-mode nil "eww buffers"
1805   "Mode for listing buffers.
1806
1807 \\{eww-buffers-mode-map}"
1808   (buffer-disable-undo)
1809   (setq buffer-read-only t
1810         truncate-lines t))
1811
1812 ;;; Desktop support
1813
1814 (defvar eww-desktop-data-save
1815   '(:url :title :point)
1816   "List of `eww-data' properties to preserve in the desktop file.
1817 Also used when saving `eww-history'.")
1818
1819 (defun eww-desktop-data-1 (alist)
1820   (let ((acc  nil)
1821         (tail alist))
1822     (while tail
1823       (let ((k (car  tail))
1824             (v (cadr tail)))
1825         (when (memq k eww-desktop-data-save)
1826           (setq acc (cons k (cons v acc)))))
1827       (setq tail  (cddr tail)))
1828     acc))
1829
1830 (defun eww-desktop-history-duplicate (a b)
1831   (let ((tail a) (r t))
1832     (while tail
1833       (if (or (memq (car tail) '(:point)) ; ignore :point
1834               (equal (cadr tail)
1835                      (plist-get b (car tail))))
1836           (setq tail (cddr tail))
1837         (setq tail nil
1838               r    nil)))
1839     ;; .
1840     r))
1841
1842 (defun eww-desktop-misc-data (directory)
1843   "Return a property list with data used to restore eww buffers.
1844 This list will contain, as :history, the list, whose first element is
1845 the value of `eww-data', and the tail is `eww-history'.
1846
1847 If `eww-desktop-remove-duplicates' is non-nil, duplicate
1848 entries (if any) will be removed from the list.
1849
1850 Only the properties listed in `eww-desktop-data-save' are included.
1851 Generally, the list should not include the (usually overly large)
1852 :dom, :source and :text properties."
1853   (let ((history  (mapcar 'eww-desktop-data-1
1854                           (cons eww-data eww-history))))
1855     (list :history  (if eww-desktop-remove-duplicates
1856                         (cl-remove-duplicates
1857                          history :test 'eww-desktop-history-duplicate)
1858                       history))))
1859
1860 (defun eww-restore-desktop (file-name buffer-name misc-data)
1861   "Restore an eww buffer from its desktop file record.
1862 If `eww-restore-desktop' is t or 'auto, this function will also
1863 initiate the retrieval of the respective URI in the background.
1864 Otherwise, the restored buffer will contain a prompt to do so by using
1865 \\[eww-reload]."
1866   (with-current-buffer (get-buffer-create buffer-name)
1867     (eww-mode)
1868     ;; NB: eww-history, eww-data are buffer-local per (eww-mode)
1869     (setq eww-history       (cdr (plist-get misc-data :history))
1870           eww-data      (or (car (plist-get misc-data :history))
1871                             ;; backwards compatibility
1872                             (list :url (plist-get misc-data :uri))))
1873     (unless file-name
1874       (when (plist-get eww-data :url)
1875         (case eww-restore-desktop
1876           ((t auto) (eww (plist-get eww-data :url)))
1877           ((zerop (buffer-size))
1878            (insert (substitute-command-keys
1879                     eww-restore-reload-prompt))))))
1880     ;; .
1881     (current-buffer)))
1882
1883 (add-to-list 'desktop-locals-to-save
1884              'eww-history-position)
1885 (add-to-list 'desktop-buffer-mode-handlers
1886              '(eww-mode . eww-restore-desktop))
1887
1888 (provide 'eww)
1889
1890 ;;; eww.el ends here