code.delx.au - gnu-emacs/blob - lisp/emacs-lisp/cl-lib.el

   1 ;;; cl-lib.el --- Common Lisp extensions for Emacs  -*- lexical-binding: t -*-
   2
   3 ;; Copyright (C) 1993, 2001-2014 Free Software Foundation, Inc.
   4
   5 ;; Author: Dave Gillespie <daveg@synaptics.com>
   6 ;; Version: 1.0
   7 ;; Keywords: extensions
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; These are extensions to Emacs Lisp that provide a degree of
  27 ;; Common Lisp compatibility, beyond what is already built-in
  28 ;; in Emacs Lisp.
  29 ;;
  30 ;; This package was written by Dave Gillespie; it is a complete
  31 ;; rewrite of Cesar Quiroz's original cl.el package of December 1986.
  32 ;;
  33 ;; Bug reports, comments, and suggestions are welcome!
  34
  35 ;; This file contains the portions of the Common Lisp extensions
  36 ;; package which should always be present.
  37
  38
  39 ;;; Change Log:
  40
  41 ;; Version 2.02 (30 Jul 93):
  42 ;;  * Added "cl-compat.el" file, extra compatibility with old package.
  43 ;;  * Added `lexical-let' and `lexical-let*'.
  44 ;;  * Added `define-modify-macro', `callf', and `callf2'.
  45 ;;  * Added `ignore-errors'.
  46 ;;  * Changed `(setf (nthcdr N PLACE) X)' to work when N is zero.
  47 ;;  * Merged `*gentemp-counter*' into `*gensym-counter*'.
  48 ;;  * Extended `subseq' to allow negative START and END like `substring'.
  49 ;;  * Added `in-ref', `across-ref', `elements of-ref' loop clauses.
  50 ;;  * Added `concat', `vconcat' loop clauses.
  51 ;;  * Cleaned up a number of compiler warnings.
  52
  53 ;; Version 2.01 (7 Jul 93):
  54 ;;  * Added support for FSF version of Emacs 19.
  55 ;;  * Added `add-hook' for Emacs 18 users.
  56 ;;  * Added `defsubst*' and `symbol-macrolet'.
  57 ;;  * Added `maplist', `mapc', `mapl', `mapcan', `mapcon'.
  58 ;;  * Added `map', `concatenate', `reduce', `merge'.
  59 ;;  * Added `revappend', `nreconc', `tailp', `tree-equal'.
  60 ;;  * Added `assert', `check-type', `typecase', `typep', and `deftype'.
  61 ;;  * Added destructuring and `&environment' support to `defmacro*'.
  62 ;;  * Added destructuring to `loop', and added the following clauses:
  63 ;;      `elements', `frames', `overlays', `intervals', `buffers', `key-seqs'.
  64 ;;  * Renamed `delete' to `delete*' and `remove' to `remove*'.
  65 ;;  * Completed support for all keywords in `remove*', `substitute', etc.
  66 ;;  * Added `most-positive-float' and company.
  67 ;;  * Fixed hash tables to work with latest Lucid Emacs.
  68 ;;  * `proclaim' forms are no longer compile-time-evaluating; use `declaim'.
  69 ;;  * Syntax for `warn' declarations has changed.
  70 ;;  * Improved implementation of `random*'.
  71 ;;  * Moved most sequence functions to a new file, cl-seq.el.
  72 ;;  * Moved `eval-when' into cl-macs.el.
  73 ;;  * Moved `pushnew' and `adjoin' to cl.el for most common cases.
  74 ;;  * Moved `provide' forms down to ends of files.
  75 ;;  * Changed expansion of `pop' to something that compiles to better code.
  76 ;;  * Changed so that no patch is required for Emacs 19 byte compiler.
  77 ;;  * Made more things dependent on `optimize' declarations.
  78 ;;  * Added a partial implementation of struct print functions.
  79 ;;  * Miscellaneous minor changes.
  80
  81 ;; Version 2.00:
  82 ;;  * First public release of this package.
  83
  84
  85 ;;; Code:
  86
  87 (require 'macroexp)
  88
  89 (defvar cl--optimize-speed 1)
  90 (defvar cl--optimize-safety 1)
  91
  92 ;;;###autoload
  93 (define-obsolete-variable-alias
  94   ;; This alias is needed for compatibility with .elc files that use defstruct
  95   ;; and were compiled with Emacs<24.3.
  96   'custom-print-functions 'cl-custom-print-functions "24.3")
  97
  98 ;;;###autoload
  99 (defvar cl-custom-print-functions nil
 100   "This is a list of functions that format user objects for printing.
 101 Each function is called in turn with three arguments: the object, the
 102 stream, and the print level (currently ignored).  If it is able to
 103 print the object it returns true; otherwise it returns nil and the
 104 printer proceeds to the next function on the list.
 105
 106 This variable is not used at present, but it is defined in hopes that
 107 a future Emacs interpreter will be able to use it.")
 108
 109 ;;; Generalized variables.
 110 ;; These macros are defined here so that they
 111 ;; can safely be used in init files.
 112
 113 (defmacro cl-incf (place &optional x)
 114   "Increment PLACE by X (1 by default).
 115 PLACE may be a symbol, or any generalized variable allowed by `setf'.
 116 The return value is the incremented value of PLACE."
 117   (declare (debug (place &optional form)))
 118   (if (symbolp place)
 119       (list 'setq place (if x (list '+ place x) (list '1+ place)))
 120     (list 'cl-callf '+ place (or x 1))))
 121
 122 (defmacro cl-decf (place &optional x)
 123   "Decrement PLACE by X (1 by default).
 124 PLACE may be a symbol, or any generalized variable allowed by `setf'.
 125 The return value is the decremented value of PLACE."
 126   (declare (debug cl-incf))
 127   (if (symbolp place)
 128       (list 'setq place (if x (list '- place x) (list '1- place)))
 129     (list 'cl-callf '- place (or x 1))))
 130
 131 (defmacro cl-pushnew (x place &rest keys)
 132   "(cl-pushnew X PLACE): insert X at the head of the list if not already there.
 133 Like (push X PLACE), except that the list is unmodified if X is `eql' to
 134 an element already on the list.
 135 \nKeywords supported:  :test :test-not :key
 136 \n(fn X PLACE [KEYWORD VALUE]...)"
 137   (declare (debug
 138             (form place &rest
 139                   &or [[&or ":test" ":test-not" ":key"] function-form]
 140                   [keywordp form])))
 141   (if (symbolp place)
 142       (if (null keys)
 143           (macroexp-let2 nil var x
 144             `(if (memql ,var ,place)
 145                  ;; This symbol may later on expand to actual code which then
 146                  ;; trigger warnings like "value unused" since cl-pushnew's
 147                  ;; return value is rarely used.  It should not matter that
 148                  ;; other warnings may be silenced, since `place' is used
 149                  ;; earlier and should have triggered them already.
 150                  (with-no-warnings ,place)
 151                (setq ,place (cons ,var ,place))))
 152         `(setq ,place (cl-adjoin ,x ,place ,@keys)))
 153     `(cl-callf2 cl-adjoin ,x ,place ,@keys)))
 154
 155 (defun cl--set-buffer-substring (start end val)
 156   (save-excursion (delete-region start end)
 157                   (goto-char start)
 158                   (insert val)
 159                   val))
 160
 161 (defun cl--set-substring (str start end val)
 162   (if end (if (< end 0) (cl-incf end (length str)))
 163     (setq end (length str)))
 164   (if (< start 0) (cl-incf start (length str)))
 165   (concat (and (> start 0) (substring str 0 start))
 166           val
 167           (and (< end (length str)) (substring str end))))
 168
 169
 170 ;;; Blocks and exits.
 171
 172 (defalias 'cl--block-wrapper 'identity)
 173 (defalias 'cl--block-throw 'throw)
 174
 175
 176 ;;; Multiple values.
 177 ;; True multiple values are not supported, or even
 178 ;; simulated.  Instead, cl-multiple-value-bind and friends simply expect
 179 ;; the target form to return the values as a list.
 180
 181 (defun cl--defalias (cl-f el-f &optional doc)
 182   (defalias cl-f el-f doc)
 183   (put cl-f 'byte-optimizer 'byte-compile-inline-expand))
 184
 185 (cl--defalias 'cl-values #'list
 186   "Return multiple values, Common Lisp style.
 187 The arguments of `cl-values' are the values
 188 that the containing function should return.
 189
 190 \(fn &rest VALUES)")
 191
 192 (cl--defalias 'cl-values-list #'identity
 193   "Return multiple values, Common Lisp style, taken from a list.
 194 LIST specifies the list of values
 195 that the containing function should return.
 196
 197 \(fn LIST)")
 198
 199 (defsubst cl-multiple-value-list (expression)
 200   "Return a list of the multiple values produced by EXPRESSION.
 201 This handles multiple values in Common Lisp style, but it does not
 202 work right when EXPRESSION calls an ordinary Emacs Lisp function
 203 that returns just one value."
 204   expression)
 205
 206 (defsubst cl-multiple-value-apply (function expression)
 207   "Evaluate EXPRESSION to get multiple values and apply FUNCTION to them.
 208 This handles multiple values in Common Lisp style, but it does not work
 209 right when EXPRESSION calls an ordinary Emacs Lisp function that returns just
 210 one value."
 211   (apply function expression))
 212
 213 (defalias 'cl-multiple-value-call 'apply
 214   "Apply FUNCTION to ARGUMENTS, taking multiple values into account.
 215 This implementation only handles the case where there is only one argument.")
 216
 217 (cl--defalias 'cl-nth-value #'nth
 218   "Evaluate EXPRESSION to get multiple values and return the Nth one.
 219 This handles multiple values in Common Lisp style, but it does not work
 220 right when EXPRESSION calls an ordinary Emacs Lisp function that returns just
 221 one value.
 222
 223 \(fn N EXPRESSION)")
 224
 225 ;;; Declarations.
 226
 227 (defvar cl--compiling-file nil)
 228 (defun cl--compiling-file ()
 229   (or cl--compiling-file
 230       (and (boundp 'byte-compile--outbuffer)
 231            (bufferp (symbol-value 'byte-compile--outbuffer))
 232            (equal (buffer-name (symbol-value 'byte-compile--outbuffer))
 233                   " *Compiler Output*"))))
 234
 235 (defvar cl--proclaims-deferred nil)
 236
 237 (defun cl-proclaim (spec)
 238   "Record a global declaration specified by SPEC."
 239   (if (fboundp 'cl--do-proclaim) (cl--do-proclaim spec t)
 240     (push spec cl--proclaims-deferred))
 241   nil)
 242
 243 (defmacro cl-declaim (&rest specs)
 244   "Like `cl-proclaim', but takes any number of unevaluated, unquoted arguments.
 245 Puts `(cl-eval-when (compile load eval) ...)' around the declarations
 246 so that they are registered at compile-time as well as run-time."
 247   (let ((body (mapcar (lambda (x) `(cl-proclaim ',x)) specs)))
 248     (if (cl--compiling-file) `(cl-eval-when (compile load eval) ,@body)
 249       `(progn ,@body))))           ; Avoid loading cl-macs.el for cl-eval-when.
 250
 251
 252 ;;; Symbols.
 253
 254 (defun cl--random-time ()
 255   (let* ((time (copy-sequence (current-time-string))) (i (length time)) (v 0))
 256     (while (>= (cl-decf i) 0) (setq v (+ (* v 3) (aref time i))))
 257     v))
 258
 259 (defvar cl--gensym-counter (* (logand (cl--random-time) 1023) 100))
 260
 261
 262 ;;; Numbers.
 263
 264 (define-obsolete-function-alias 'cl-floatp-safe 'floatp "24.4")
 265
 266 (defsubst cl-plusp (number)
 267   "Return t if NUMBER is positive."
 268   (> number 0))
 269
 270 (defsubst cl-minusp (number)
 271   "Return t if NUMBER is negative."
 272   (< number 0))
 273
 274 (defun cl-oddp (integer)
 275   "Return t if INTEGER is odd."
 276   (eq (logand integer 1) 1))
 277
 278 (defun cl-evenp (integer)
 279   "Return t if INTEGER is even."
 280   (eq (logand integer 1) 0))
 281
 282 (defvar cl--random-state
 283   (vector 'cl--random-state-tag -1 30 (cl--random-time)))
 284
 285 (defconst cl-most-positive-float nil
 286   "The largest value that a Lisp float can hold.
 287 If your system supports infinities, this is the largest finite value.
 288 For IEEE machines, this is approximately 1.79e+308.
 289 Call `cl-float-limits' to set this.")
 290
 291 (defconst cl-most-negative-float nil
 292   "The largest negative value that a Lisp float can hold.
 293 This is simply -`cl-most-positive-float'.
 294 Call `cl-float-limits' to set this.")
 295
 296 (defconst cl-least-positive-float nil
 297   "The smallest value greater than zero that a Lisp float can hold.
 298 For IEEE machines, it is about 4.94e-324 if denormals are supported,
 299 or 2.22e-308 if they are not.
 300 Call `cl-float-limits' to set this.")
 301
 302 (defconst cl-least-negative-float nil
 303   "The smallest value less than zero that a Lisp float can hold.
 304 This is simply -`cl-least-positive-float'.
 305 Call `cl-float-limits' to set this.")
 306
 307 (defconst cl-least-positive-normalized-float nil
 308   "The smallest normalized Lisp float greater than zero.
 309 This is the smallest value for which IEEE denormalization does not lose
 310 precision.  For IEEE machines, this value is about 2.22e-308.
 311 For machines that do not support the concept of denormalization
 312 and gradual underflow, this constant equals `cl-least-positive-float'.
 313 Call `cl-float-limits' to set this.")
 314
 315 (defconst cl-least-negative-normalized-float nil
 316   "The smallest normalized Lisp float less than zero.
 317 This is simply -`cl-least-positive-normalized-float'.
 318 Call `cl-float-limits' to set this.")
 319
 320 (defconst cl-float-epsilon nil
 321   "The smallest positive float that adds to 1.0 to give a distinct value.
 322 Adding a number less than this to 1.0 returns 1.0 due to roundoff.
 323 For IEEE machines, epsilon is about 2.22e-16.
 324 Call `cl-float-limits' to set this.")
 325
 326 (defconst cl-float-negative-epsilon nil
 327   "The smallest positive float that subtracts from 1.0 to give a distinct value.
 328 For IEEE machines, it is about 1.11e-16.
 329 Call `cl-float-limits' to set this.")
 330
 331
 332 ;;; Sequence functions.
 333
 334 (cl--defalias 'cl-copy-seq 'copy-sequence)
 335
 336 (declare-function cl--mapcar-many "cl-extra" (cl-func cl-seqs))
 337
 338 (defun cl-mapcar (cl-func cl-x &rest cl-rest)
 339   "Apply FUNCTION to each element of SEQ, and make a list of the results.
 340 If there are several SEQs, FUNCTION is called with that many arguments,
 341 and mapping stops as soon as the shortest list runs out.  With just one
 342 SEQ, this is like `mapcar'.  With several, it is like the Common Lisp
 343 `mapcar' function extended to arbitrary sequence types.
 344 \n(fn FUNCTION SEQ...)"
 345   (if cl-rest
 346       (if (or (cdr cl-rest) (nlistp cl-x) (nlistp (car cl-rest)))
 347           (cl--mapcar-many cl-func (cons cl-x cl-rest))
 348         (let ((cl-res nil) (cl-y (car cl-rest)))
 349           (while (and cl-x cl-y)
 350             (push (funcall cl-func (pop cl-x) (pop cl-y)) cl-res))
 351           (nreverse cl-res)))
 352     (mapcar cl-func cl-x)))
 353
 354 (cl--defalias 'cl-svref 'aref)
 355
 356 ;;; List functions.
 357
 358 (cl--defalias 'cl-first 'car)
 359 (cl--defalias 'cl-second 'cadr)
 360 (cl--defalias 'cl-rest 'cdr)
 361 (cl--defalias 'cl-endp 'null)
 362
 363 (cl--defalias 'cl-third 'cl-caddr "Return the third element of the list X.")
 364 (cl--defalias 'cl-fourth 'cl-cadddr "Return the fourth element of the list X.")
 365
 366 (defsubst cl-fifth (x)
 367   "Return the fifth element of the list X."
 368   (declare (gv-setter (lambda (store) `(setcar (nthcdr 4 ,x) ,store))))
 369   (nth 4 x))
 370
 371 (defsubst cl-sixth (x)
 372   "Return the sixth element of the list X."
 373   (declare (gv-setter (lambda (store) `(setcar (nthcdr 5 ,x) ,store))))
 374   (nth 5 x))
 375
 376 (defsubst cl-seventh (x)
 377   "Return the seventh element of the list X."
 378   (declare (gv-setter (lambda (store) `(setcar (nthcdr 6 ,x) ,store))))
 379   (nth 6 x))
 380
 381 (defsubst cl-eighth (x)
 382   "Return the eighth element of the list X."
 383   (declare (gv-setter (lambda (store) `(setcar (nthcdr 7 ,x) ,store))))
 384   (nth 7 x))
 385
 386 (defsubst cl-ninth (x)
 387   "Return the ninth element of the list X."
 388   (declare (gv-setter (lambda (store) `(setcar (nthcdr 8 ,x) ,store))))
 389   (nth 8 x))
 390
 391 (defsubst cl-tenth (x)
 392   "Return the tenth element of the list X."
 393   (declare (gv-setter (lambda (store) `(setcar (nthcdr 9 ,x) ,store))))
 394   (nth 9 x))
 395
 396 (defun cl-caaar (x)
 397   "Return the `car' of the `car' of the `car' of X."
 398   (declare (compiler-macro cl--compiler-macro-cXXr))
 399   (car (car (car x))))
 400
 401 (defun cl-caadr (x)
 402   "Return the `car' of the `car' of the `cdr' of X."
 403   (declare (compiler-macro cl--compiler-macro-cXXr))
 404   (car (car (cdr x))))
 405
 406 (defun cl-cadar (x)
 407   "Return the `car' of the `cdr' of the `car' of X."
 408   (declare (compiler-macro cl--compiler-macro-cXXr))
 409   (car (cdr (car x))))
 410
 411 (defun cl-caddr (x)
 412   "Return the `car' of the `cdr' of the `cdr' of X."
 413   (declare (compiler-macro cl--compiler-macro-cXXr))
 414   (car (cdr (cdr x))))
 415
 416 (defun cl-cdaar (x)
 417   "Return the `cdr' of the `car' of the `car' of X."
 418   (declare (compiler-macro cl--compiler-macro-cXXr))
 419   (cdr (car (car x))))
 420
 421 (defun cl-cdadr (x)
 422   "Return the `cdr' of the `car' of the `cdr' of X."
 423   (declare (compiler-macro cl--compiler-macro-cXXr))
 424   (cdr (car (cdr x))))
 425
 426 (defun cl-cddar (x)
 427   "Return the `cdr' of the `cdr' of the `car' of X."
 428   (declare (compiler-macro cl--compiler-macro-cXXr))
 429   (cdr (cdr (car x))))
 430
 431 (defun cl-cdddr (x)
 432   "Return the `cdr' of the `cdr' of the `cdr' of X."
 433   (declare (compiler-macro cl--compiler-macro-cXXr))
 434   (cdr (cdr (cdr x))))
 435
 436 (defun cl-caaaar (x)
 437   "Return the `car' of the `car' of the `car' of the `car' of X."
 438   (declare (compiler-macro cl--compiler-macro-cXXr))
 439   (car (car (car (car x)))))
 440
 441 (defun cl-caaadr (x)
 442   "Return the `car' of the `car' of the `car' of the `cdr' of X."
 443   (declare (compiler-macro cl--compiler-macro-cXXr))
 444   (car (car (car (cdr x)))))
 445
 446 (defun cl-caadar (x)
 447   "Return the `car' of the `car' of the `cdr' of the `car' of X."
 448   (declare (compiler-macro cl--compiler-macro-cXXr))
 449   (car (car (cdr (car x)))))
 450
 451 (defun cl-caaddr (x)
 452   "Return the `car' of the `car' of the `cdr' of the `cdr' of X."
 453   (declare (compiler-macro cl--compiler-macro-cXXr))
 454   (car (car (cdr (cdr x)))))
 455
 456 (defun cl-cadaar (x)
 457   "Return the `car' of the `cdr' of the `car' of the `car' of X."
 458   (declare (compiler-macro cl--compiler-macro-cXXr))
 459   (car (cdr (car (car x)))))
 460
 461 (defun cl-cadadr (x)
 462   "Return the `car' of the `cdr' of the `car' of the `cdr' of X."
 463   (declare (compiler-macro cl--compiler-macro-cXXr))
 464   (car (cdr (car (cdr x)))))
 465
 466 (defun cl-caddar (x)
 467   "Return the `car' of the `cdr' of the `cdr' of the `car' of X."
 468   (declare (compiler-macro cl--compiler-macro-cXXr))
 469   (car (cdr (cdr (car x)))))
 470
 471 (defun cl-cadddr (x)
 472   "Return the `car' of the `cdr' of the `cdr' of the `cdr' of X."
 473   (declare (compiler-macro cl--compiler-macro-cXXr))
 474   (car (cdr (cdr (cdr x)))))
 475
 476 (defun cl-cdaaar (x)
 477   "Return the `cdr' of the `car' of the `car' of the `car' of X."
 478   (declare (compiler-macro cl--compiler-macro-cXXr))
 479   (cdr (car (car (car x)))))
 480
 481 (defun cl-cdaadr (x)
 482   "Return the `cdr' of the `car' of the `car' of the `cdr' of X."
 483   (declare (compiler-macro cl--compiler-macro-cXXr))
 484   (cdr (car (car (cdr x)))))
 485
 486 (defun cl-cdadar (x)
 487   "Return the `cdr' of the `car' of the `cdr' of the `car' of X."
 488   (declare (compiler-macro cl--compiler-macro-cXXr))
 489   (cdr (car (cdr (car x)))))
 490
 491 (defun cl-cdaddr (x)
 492   "Return the `cdr' of the `car' of the `cdr' of the `cdr' of X."
 493   (declare (compiler-macro cl--compiler-macro-cXXr))
 494   (cdr (car (cdr (cdr x)))))
 495
 496 (defun cl-cddaar (x)
 497   "Return the `cdr' of the `cdr' of the `car' of the `car' of X."
 498   (declare (compiler-macro cl--compiler-macro-cXXr))
 499   (cdr (cdr (car (car x)))))
 500
 501 (defun cl-cddadr (x)
 502   "Return the `cdr' of the `cdr' of the `car' of the `cdr' of X."
 503   (declare (compiler-macro cl--compiler-macro-cXXr))
 504   (cdr (cdr (car (cdr x)))))
 505
 506 (defun cl-cdddar (x)
 507   "Return the `cdr' of the `cdr' of the `cdr' of the `car' of X."
 508   (declare (compiler-macro cl--compiler-macro-cXXr))
 509   (cdr (cdr (cdr (car x)))))
 510
 511 (defun cl-cddddr (x)
 512   "Return the `cdr' of the `cdr' of the `cdr' of the `cdr' of X."
 513   (declare (compiler-macro cl--compiler-macro-cXXr))
 514   (cdr (cdr (cdr (cdr x)))))
 515
 516 ;;(defun last* (x &optional n)
 517 ;;  "Returns the last link in the list LIST.
 518 ;;With optional argument N, returns Nth-to-last link (default 1)."
 519 ;;  (if n
 520 ;;      (let ((m 0) (p x))
 521 ;;      (while (consp p) (cl-incf m) (pop p))
 522 ;;      (if (<= n 0) p
 523 ;;        (if (< n m) (nthcdr (- m n) x) x)))
 524 ;;    (while (consp (cdr x)) (pop x))
 525 ;;    x))
 526
 527 (defun cl-list* (arg &rest rest)
 528   "Return a new list with specified ARGs as elements, consed to last ARG.
 529 Thus, `(cl-list* A B C D)' is equivalent to `(nconc (list A B C) D)', or to
 530 `(cons A (cons B (cons C D)))'.
 531 \n(fn ARG...)"
 532   (declare (compiler-macro cl--compiler-macro-list*))
 533   (cond ((not rest) arg)
 534         ((not (cdr rest)) (cons arg (car rest)))
 535         (t (let* ((n (length rest))
 536                   (copy (copy-sequence rest))
 537                   (last (nthcdr (- n 2) copy)))
 538              (setcdr last (car (cdr last)))
 539              (cons arg copy)))))
 540
 541 (defun cl-ldiff (list sublist)
 542   "Return a copy of LIST with the tail SUBLIST removed."
 543   (let ((res nil))
 544     (while (and (consp list) (not (eq list sublist)))
 545       (push (pop list) res))
 546     (nreverse res)))
 547
 548 (defun cl-copy-list (list)
 549   "Return a copy of LIST, which may be a dotted list.
 550 The elements of LIST are not copied, just the list structure itself."
 551   (if (consp list)
 552       (let ((res nil))
 553         (while (consp list) (push (pop list) res))
 554         (prog1 (nreverse res) (setcdr res list)))
 555     (car list)))
 556
 557 ;; Autoloaded, but we have not loaded cl-loaddefs yet.
 558 (declare-function cl-floor "cl-extra" (x &optional y))
 559 (declare-function cl-ceiling "cl-extra" (x &optional y))
 560 (declare-function cl-truncate "cl-extra" (x &optional y))
 561 (declare-function cl-round "cl-extra" (x &optional y))
 562 (declare-function cl-mod "cl-extra" (x y))
 563
 564 (defun cl-adjoin (cl-item cl-list &rest cl-keys)
 565   "Return ITEM consed onto the front of LIST only if it's not already there.
 566 Otherwise, return LIST unmodified.
 567 \nKeywords supported:  :test :test-not :key
 568 \n(fn ITEM LIST [KEYWORD VALUE]...)"
 569   (declare (compiler-macro cl--compiler-macro-adjoin))
 570   (cond ((or (equal cl-keys '(:test eq))
 571              (and (null cl-keys) (not (numberp cl-item))))
 572          (if (memq cl-item cl-list) cl-list (cons cl-item cl-list)))
 573         ((or (equal cl-keys '(:test equal)) (null cl-keys))
 574          (if (member cl-item cl-list) cl-list (cons cl-item cl-list)))
 575         (t (apply 'cl--adjoin cl-item cl-list cl-keys))))
 576
 577 (defun cl-subst (cl-new cl-old cl-tree &rest cl-keys)
 578   "Substitute NEW for OLD everywhere in TREE (non-destructively).
 579 Return a copy of TREE with all elements `eql' to OLD replaced by NEW.
 580 \nKeywords supported:  :test :test-not :key
 581 \n(fn NEW OLD TREE [KEYWORD VALUE]...)"
 582   (if (or cl-keys (and (numberp cl-old) (not (integerp cl-old))))
 583       (apply 'cl-sublis (list (cons cl-old cl-new)) cl-tree cl-keys)
 584     (cl--do-subst cl-new cl-old cl-tree)))
 585
 586 (defun cl--do-subst (cl-new cl-old cl-tree)
 587   (cond ((eq cl-tree cl-old) cl-new)
 588         ((consp cl-tree)
 589          (let ((a (cl--do-subst cl-new cl-old (car cl-tree)))
 590                (d (cl--do-subst cl-new cl-old (cdr cl-tree))))
 591            (if (and (eq a (car cl-tree)) (eq d (cdr cl-tree)))
 592                cl-tree (cons a d))))
 593         (t cl-tree)))
 594
 595 (defun cl-acons (key value alist)
 596   "Add KEY and VALUE to ALIST.
 597 Return a new list with (cons KEY VALUE) as car and ALIST as cdr."
 598   (cons (cons key value) alist))
 599
 600 (defun cl-pairlis (keys values &optional alist)
 601   "Make an alist from KEYS and VALUES.
 602 Return a new alist composed by associating KEYS to corresponding VALUES;
 603 the process stops as soon as KEYS or VALUES run out.
 604 If ALIST is non-nil, the new pairs are prepended to it."
 605   (nconc (cl-mapcar 'cons keys values) alist))
 606
 607
 608 ;;; Generalized variables.
 609
 610 ;; These used to be in cl-macs.el since all macros that use them (like setf)
 611 ;; were autoloaded from cl-macs.el.  But now that setf, push, and pop are in
 612 ;; core Elisp, they need to either be right here or be autoloaded via
 613 ;; cl-loaddefs.el, which is more trouble than it is worth.
 614
 615 ;; Some more Emacs-related place types.
 616 (gv-define-simple-setter buffer-file-name set-visited-file-name t)
 617 (gv-define-setter buffer-modified-p (flag &optional buf)
 618   `(with-current-buffer ,buf
 619      (set-buffer-modified-p ,flag)))
 620 (gv-define-simple-setter buffer-name rename-buffer t)
 621 (gv-define-setter buffer-string (store)
 622   `(insert (prog1 ,store (erase-buffer))))
 623 (gv-define-simple-setter buffer-substring cl--set-buffer-substring)
 624 (gv-define-simple-setter current-buffer set-buffer)
 625 (gv-define-simple-setter current-column move-to-column t)
 626 (gv-define-simple-setter current-global-map use-global-map t)
 627 (gv-define-setter current-input-mode (store)
 628   `(progn (apply #'set-input-mode ,store) ,store))
 629 (gv-define-simple-setter current-local-map use-local-map t)
 630 (gv-define-simple-setter current-window-configuration
 631                          set-window-configuration t)
 632 (gv-define-simple-setter default-file-modes set-default-file-modes t)
 633 (gv-define-simple-setter documentation-property put)
 634 (gv-define-setter face-background (x f &optional s)
 635   `(set-face-background ,f ,x ,s))
 636 (gv-define-setter face-background-pixmap (x f &optional s)
 637   `(set-face-background-pixmap ,f ,x ,s))
 638 (gv-define-setter face-font (x f &optional s) `(set-face-font ,f ,x ,s))
 639 (gv-define-setter face-foreground (x f &optional s)
 640   `(set-face-foreground ,f ,x ,s))
 641 (gv-define-setter face-underline-p (x f &optional s)
 642   `(set-face-underline ,f ,x ,s))
 643 (gv-define-simple-setter file-modes set-file-modes t)
 644 (gv-define-simple-setter frame-height set-screen-height t)
 645 (gv-define-simple-setter frame-parameters modify-frame-parameters t)
 646 (gv-define-simple-setter frame-visible-p cl--set-frame-visible-p)
 647 (gv-define-simple-setter frame-width set-screen-width t)
 648 (gv-define-simple-setter getenv setenv t)
 649 (gv-define-simple-setter get-register set-register)
 650 (gv-define-simple-setter global-key-binding global-set-key)
 651 (gv-define-simple-setter local-key-binding local-set-key)
 652 (gv-define-simple-setter mark set-mark t)
 653 (gv-define-simple-setter mark-marker set-mark t)
 654 (gv-define-simple-setter marker-position set-marker t)
 655 (gv-define-setter mouse-position (store scr)
 656   `(set-mouse-position ,scr (car ,store) (cadr ,store)
 657                        (cddr ,store)))
 658 (gv-define-simple-setter point goto-char)
 659 (gv-define-simple-setter point-marker goto-char t)
 660 (gv-define-setter point-max (store)
 661   `(progn (narrow-to-region (point-min) ,store) ,store))
 662 (gv-define-setter point-min (store)
 663   `(progn (narrow-to-region ,store (point-max)) ,store))
 664 (gv-define-setter read-mouse-position (store scr)
 665   `(set-mouse-position ,scr (car ,store) (cdr ,store)))
 666 (gv-define-simple-setter screen-height set-screen-height t)
 667 (gv-define-simple-setter screen-width set-screen-width t)
 668 (gv-define-simple-setter selected-window select-window)
 669 (gv-define-simple-setter selected-screen select-screen)
 670 (gv-define-simple-setter selected-frame select-frame)
 671 (gv-define-simple-setter standard-case-table set-standard-case-table)
 672 (gv-define-simple-setter syntax-table set-syntax-table)
 673 (gv-define-simple-setter visited-file-modtime set-visited-file-modtime t)
 674 (gv-define-setter window-height (store)
 675   `(progn (enlarge-window (- ,store (window-height))) ,store))
 676 (gv-define-setter window-width (store)
 677   `(progn (enlarge-window (- ,store (window-width)) t) ,store))
 678 (gv-define-simple-setter x-get-secondary-selection x-own-secondary-selection t)
 679 (gv-define-simple-setter x-get-selection x-own-selection t)
 680
 681 ;; More complex setf-methods.
 682
 683 ;; This is a hack that allows (setf (eq a 7) B) to mean either
 684 ;; (setq a 7) or (setq a nil) depending on whether B is nil or not.
 685 ;; This is useful when you have control over the PLACE but not over
 686 ;; the VALUE, as is the case in define-minor-mode's :variable.
 687 ;; It turned out that :variable needed more flexibility anyway, so
 688 ;; this doesn't seem too useful now.
 689 (gv-define-expander eq
 690   (lambda (do place val)
 691     (gv-letplace (getter setter) place
 692       (macroexp-let2 nil val val
 693         (funcall do `(eq ,getter ,val)
 694                  (lambda (v)
 695                    `(cond
 696                      (,v ,(funcall setter val))
 697                      ((eq ,getter ,val) ,(funcall setter `(not ,val))))))))))
 698
 699 (gv-define-expander substring
 700   (lambda (do place from &optional to)
 701     (gv-letplace (getter setter) place
 702       (macroexp-let2 nil start from
 703         (macroexp-let2 nil end to
 704           (funcall do `(substring ,getter ,start ,end)
 705                    (lambda (v)
 706                      (funcall setter `(cl--set-substring
 707                                        ,getter ,start ,end ,v)))))))))
 708
 709 ;;; Miscellaneous.
 710
 711 ;;;###autoload
 712 (progn
 713   ;; The `assert' macro from the cl package signals
 714   ;; `cl-assertion-failed' at runtime so always define it.
 715   (define-error 'cl-assertion-failed (purecopy "Assertion failed"))
 716   ;; Make sure functions defined with cl-defsubst can be inlined even in
 717   ;; packages which do not require CL.  We don't put an autoload cookie
 718   ;; directly on that function, since those cookies only go to cl-loaddefs.
 719   (autoload 'cl--defsubst-expand "cl-macs")
 720   ;; Autoload, so autoload.el and font-lock can use it even when CL
 721   ;; is not loaded.
 722   (put 'cl-defun    'doc-string-elt 3)
 723   (put 'cl-defmacro 'doc-string-elt 3)
 724   (put 'cl-defsubst 'doc-string-elt 3)
 725   (put 'cl-defstruct 'doc-string-elt 2))
 726
 727 (provide 'cl-lib)
 728 (or (load "cl-loaddefs" 'noerror 'quiet)
 729     ;; When bootstrapping, cl-loaddefs hasn't been built yet!
 730     (require 'cl-macs))
 731
 732 ;; Local variables:
 733 ;; byte-compile-dynamic: t
 734 ;; End:
 735
 736 ;;; cl-lib.el ends here