code.delx.au - gnu-emacs/blob - lisp/faces.el

   1 ;;; faces.el --- Lisp faces
   2
   3 ;; Copyright (C) 1992, 1993, 1994, 1995, 1996, 1998, 1999, 2000
   4 ;;   Free Software Foundation, Inc.
   5
   6 ;; This file is part of GNU Emacs.
   7
   8 ;; GNU Emacs is free software; you can redistribute it and/or modify
   9 ;; it under the terms of the GNU General Public License as published by
  10 ;; the Free Software Foundation; either version 2, or (at your option)
  11 ;; any later version.
  12
  13 ;; GNU Emacs is distributed in the hope that it will be useful,
  14 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 ;; GNU General Public License for more details.
  17
  18 ;; You should have received a copy of the GNU General Public License
  19 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  20 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  21 ;; Boston, MA 02111-1307, USA.
  22
  23 ;;; Commentary:
  24
  25 ;;; Code:
  26
  27 (eval-when-compile
  28   (require 'cl)
  29   ;; Warning suppression -- can't require x-win in batch:
  30   (autoload 'xw-defined-colors "x-win"))
  31
  32 (require 'cus-face)
  33
  34 \f
  35 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  36 ;;; Font selection.
  37 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  38
  39 (defgroup font-selection nil
  40   "Influencing face font selection."
  41   :group 'faces)
  42
  43
  44 (defcustom face-font-selection-order
  45   '(:width :height :weight :slant)
  46   "*A list specifying how face font selection chooses fonts.
  47 Each of the four symbols `:width', `:height', `:weight', and `:slant'
  48 must appear once in the list, and the list must not contain any other
  49 elements.  Font selection tries to find a best matching font for
  50 those face attributes first that appear first in the list.  For
  51 example, if `:slant' appears before `:height', font selection first
  52 tries to find a font with a suitable slant, even if this results in
  53 a font height that isn't optimal."
  54   :tag "Font selection order."
  55   :type '(list symbol symbol symbol symbol)
  56   :group 'font-selection
  57   :set #'(lambda (symbol value)
  58            (set-default symbol value)
  59            (internal-set-font-selection-order value)))
  60
  61
  62 ;; This is defined originally in xfaces.c.
  63 (defcustom face-font-family-alternatives
  64   '(("courier" "fixed")
  65     ("helv" "helvetica" "arial" "fixed"))
  66   "*Alist of alternative font family names.
  67 Each element has the the form (FAMILY ALTERNATIVE1 ALTERNATIVE2 ...).
  68 If fonts of family FAMILY can't be loaded, try ALTERNATIVE1, then
  69 ALTERNATIVE2 etc."
  70   :tag "Alternative font families to try."
  71   :type '(repeat (repeat string))
  72   :group 'font-selection
  73   :set #'(lambda (symbol value)
  74            (set-default symbol value)
  75            (internal-set-alternative-font-family-alist value)))
  76
  77
  78 ;; This is defined originally in xfaces.c.
  79 (defcustom face-font-registry-alternatives
  80   '(("muletibetan-2" "muletibetan-0"))
  81   "*Alist of alternative font registry names.
  82 Each element has the the form (REGISTRY ALTERNATIVE1 ALTERNATIVE2 ...).
  83 If fonts of registry REGISTRY can't be loaded, try ALTERNATIVE1, then
  84 ALTERNATIVE2 etc."
  85   :tag "Alternative font registries to try."
  86   :type '(repeat (repeat string))
  87   :version "21.1"
  88   :group 'font-selection
  89   :set #'(lambda (symbol value)
  90            (set-default symbol value)
  91            (internal-set-alternative-font-registry-alist value)))
  92
  93
  94 \f
  95 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  96 ;;; Creation, copying.
  97 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  98
  99
 100 (defun face-list ()
 101   "Return a list of all defined face names."
 102   (mapcar #'car face-new-frame-defaults))
 103
 104
 105 ;;; ### If not frame-local initialize by what X resources?
 106
 107 (defun make-face (face &optional no-init-from-resources)
 108   "Define a new face with name FACE, a symbol.
 109 NO-INIT-FROM-RESOURCES non-nil means don't initialize frame-local
 110 variants of FACE from X resources.  (X resources recognized are found
 111 in the global variable `face-x-resources'.)  If FACE is already known
 112 as a face, leave it unmodified.  Value is FACE."
 113   (interactive "SMake face: ")
 114   (unless (facep face)
 115     ;; Make frame-local faces (this also makes the global one).
 116     (dolist (frame (frame-list))
 117       (internal-make-lisp-face face frame))
 118     ;; Add the face to the face menu.
 119     (when (fboundp 'facemenu-add-new-face)
 120       (facemenu-add-new-face face))
 121     ;; Define frame-local faces for all frames from X resources.
 122     (unless no-init-from-resources
 123       (make-face-x-resource-internal face)))
 124   face)
 125
 126
 127 (defun make-empty-face (face)
 128   "Define a new, empty face with name FACE.
 129 If the face already exists, it is left unmodified.  Value is FACE."
 130   (interactive "SMake empty face: ")
 131   (make-face face 'no-init-from-resources))
 132
 133
 134 (defun copy-face (old-face new-face &optional frame new-frame)
 135   "Define a face just like OLD-FACE, with name NEW-FACE.
 136
 137 If NEW-FACE already exists as a face, it is modified to be like
 138 OLD-FACE.  If it doesn't already exist, it is created.
 139
 140 If the optional argument FRAME is given as a frame,  NEW-FACE is
 141 changed on FRAME only.
 142 If FRAME is t, the frame-independent default specification for OLD-FACE
 143 is copied to NEW-FACE.
 144 If FRAME is nil, copying is done for the frame-independent defaults
 145 and for each existing frame.
 146
 147 If the optional fourth argument NEW-FRAME is given,
 148 copy the information from face OLD-FACE on frame FRAME
 149 to NEW-FACE on frame NEW-FRAME."
 150   (let ((inhibit-quit t))
 151     (if (null frame)
 152         (progn
 153           (dolist (frame (frame-list))
 154             (copy-face old-face new-face frame))
 155           (copy-face old-face new-face t))
 156       (internal-copy-lisp-face old-face new-face frame new-frame))
 157     new-face))
 158
 159
 160 \f
 161 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 162 ;;; Obsolete functions
 163 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 164
 165 ;; The functions in this section are defined because Lisp packages use
 166 ;; them, despite the prefix `internal-' suggesting that they are
 167 ;; private to the face implementation.
 168
 169 (defun internal-find-face (name &optional frame)
 170   "Retrieve the face named NAME.
 171 Return nil if there is no such face.
 172 If the optional argument FRAME is given, this gets the face NAME for
 173 that frame; otherwise, it uses the selected frame.
 174 If FRAME is the symbol t, then the global, non-frame face is returned.
 175 If NAME is already a face, it is simply returned.
 176
 177 This function is defined for compatibility with Emacs 20.2.  It
 178 should not be used anymore."
 179   (facep name))
 180 (make-obsolete 'internal-find-face 'facep "21.1")
 181
 182
 183 (defun internal-get-face (name &optional frame)
 184   "Retrieve the face named NAME; error if there is none.
 185 If the optional argument FRAME is given, this gets the face NAME for
 186 that frame; otherwise, it uses the selected frame.
 187 If FRAME is the symbol t, then the global, non-frame face is returned.
 188 If NAME is already a face, it is simply returned.
 189
 190 This function is defined for compatibility with Emacs 20.2.  It
 191 should not be used anymore."
 192   (or (internal-find-face name frame)
 193       (check-face name)))
 194 (make-obsolete 'internal-get-face "See `facep' and `check-face'." "21.1")
 195
 196 \f
 197 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 198 ;;; Predicates, type checks.
 199 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 200
 201 (defun facep (face)
 202   "Return non-nil if FACE is a face name."
 203   (internal-lisp-face-p face))
 204
 205
 206 (defun check-face (face)
 207   "Signal an error if FACE doesn't name a face.
 208 Value is FACE."
 209   (unless (facep face)
 210     (error "Not a face: %s" face))
 211   face)
 212
 213
 214 ;; The ID returned is not to be confused with the internally used IDs
 215 ;; of realized faces.  The ID assigned to Lisp faces is used to
 216 ;; support faces in display table entries.
 217
 218 (defun face-id (face &optional frame)
 219   "Return the interNal ID of face with name FACE.
 220 If optional argument FRAME is nil or omitted, use the selected frame."
 221   (check-face face)
 222   (get face 'face))
 223
 224
 225 (defun face-equal (face1 face2 &optional frame)
 226   "Non-nil if faces FACE1 and FACE2 are equal.
 227 Faces are considered equal if all their attributes are equal.
 228 If the optional argument FRAME is given, report on face FACE in that frame.
 229 If FRAME is t, report on the defaults for face FACE (for new frames).
 230 If FRAME is omitted or nil, use the selected frame."
 231   (internal-lisp-face-equal-p face1 face2 frame))
 232
 233
 234 (defun face-differs-from-default-p (face &optional frame)
 235   "Non-nil if FACE displays differently from the default face.
 236 If the optional argument FRAME is given, report on face FACE in that frame.
 237 If FRAME is t, report on the defaults for face FACE (for new frames).
 238 If FRAME is omitted or nil, use the selected frame.
 239 A face is considered to be ``the same'' as the default face if it is
 240 actually specified in the same way (equal attributes) or if it is
 241 fully-unspecified, and thus inherits the attributes of any face it
 242 is displayed on top of."
 243   (cond ((eq frame t) (setq frame nil))
 244         ((null frame) (setq frame (selected-frame))))
 245   (let* ((v1 (internal-lisp-face-p face frame))
 246          (n (if v1 (length v1) 0))
 247          (v2 (internal-lisp-face-p 'default frame))
 248          (i 1))
 249     (unless v1
 250       (error "Not a face: %S" face))
 251     (while (and (< i n)
 252                 (or (eq 'unspecified (aref v1 i))
 253                     (equal (aref v1 i) (aref v2 i))))
 254       (setq i (1+ i)))
 255     (< i n)))
 256
 257
 258 (defun face-nontrivial-p (face &optional frame)
 259   "True if face FACE has some non-nil attribute.
 260 If the optional argument FRAME is given, report on face FACE in that frame.
 261 If FRAME is t, report on the defaults for face FACE (for new frames).
 262 If FRAME is omitted or nil, use the selected frame."
 263   (not (internal-lisp-face-empty-p face frame)))
 264
 265
 266 \f
 267 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 268 ;;; Setting face attributes from X resources.
 269 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 270
 271 (defcustom face-x-resources
 272   '((:family (".attributeFamily" . "Face.AttributeFamily"))
 273     (:width (".attributeWidth" . "Face.AttributeWidth"))
 274     (:height (".attributeHeight" . "Face.AttributeHeight"))
 275     (:weight (".attributeWeight" . "Face.AttributeWeight"))
 276     (:slant (".attributeSlant" . "Face.AttributeSlant"))
 277     (:foreground (".attributeForeground" . "Face.AttributeForeground"))
 278     (:background (".attributeBackground" . "Face.AttributeBackground"))
 279     (:overline (".attributeOverline" . "Face.AttributeOverline"))
 280     (:strike-through (".attributeStrikeThrough" . "Face.AttributeStrikeThrough"))
 281     (:box (".attributeBox" . "Face.AttributeBox"))
 282     (:underline (".attributeUnderline" . "Face.AttributeUnderline"))
 283     (:inverse-video (".attributeInverse" . "Face.AttributeInverse"))
 284     (:stipple
 285      (".attributeStipple" . "Face.AttributeStipple")
 286      (".attributeBackgroundPixmap" . "Face.AttributeBackgroundPixmap"))
 287     (:bold (".attributeBold" . "Face.AttributeBold"))
 288     (:italic (".attributeItalic" . "Face.AttributeItalic"))
 289     (:font (".attributeFont" . "Face.AttributeFont"))
 290     (:inherit (".attributeInherit" . "Face.AttributeInherit")))
 291   "*List of X resources and classes for face attributes.
 292 Each element has the form (ATTRIBUTE ENTRY1 ENTRY2...) where ATTRIBUTE is
 293 the name of a face attribute, and each ENTRY is a cons of the form
 294 (RESOURCE . CLASS) with RESOURCE being the resource and CLASS being the
 295 X resource class for the attribute."
 296   :type '(repeat (cons symbol (repeat (cons string string))))
 297   :group 'faces)
 298
 299
 300 (defun set-face-attribute-from-resource (face attribute resource class frame)
 301   "Set FACE's ATTRIBUTE from X resource RESOURCE, class CLASS on FRAME.
 302 Value is the attribute value specified by the resource, or nil
 303 if not present.  This function displays a message if the resource
 304 specifies an invalid attribute."
 305   (let* ((face-name (face-name face))
 306          (value (internal-face-x-get-resource (concat face-name resource)
 307                                               class frame)))
 308     (when value
 309       (condition-case ()
 310           (internal-set-lisp-face-attribute-from-resource
 311            face attribute (downcase value) frame)
 312         (error
 313          (message "Face %s, frame %s: invalid attribute %s %s from X resource"
 314                   face-name frame attribute value))))
 315     value))
 316
 317
 318 (defun set-face-attributes-from-resources (face frame)
 319   "Set attributes of FACE from X resources for FRAME."
 320   (when (memq (framep frame) '(x w32 mac))
 321     (dolist (definition face-x-resources)
 322       (let ((attribute (car definition)))
 323         (dolist (entry (cdr definition))
 324           (set-face-attribute-from-resource face attribute (car entry)
 325                                             (cdr entry) frame))))))
 326
 327
 328 (defun make-face-x-resource-internal (face &optional frame)
 329   "Fill frame-local FACE on FRAME from X resources.
 330 FRAME nil or not specified means do it for all frames."
 331   (if (null frame)
 332       (dolist (frame (frame-list))
 333         (set-face-attributes-from-resources face frame))
 334     (set-face-attributes-from-resources face frame)))
 335
 336
 337 \f
 338 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 339 ;;; Retrieving face attributes.
 340 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 341
 342 (defun face-name (face)
 343   "Return the name of face FACE."
 344   (symbol-name (check-face face)))
 345
 346
 347 (defun face-attribute (face attribute &optional frame)
 348   "Return the value of FACE's ATTRIBUTE on FRAME.
 349 If the optional argument FRAME is given, report on face FACE in that frame.
 350 If FRAME is t, report on the defaults for face FACE (for new frames).
 351 If FRAME is omitted or nil, use the selected frame."
 352   (internal-get-lisp-face-attribute face attribute frame))
 353
 354
 355 (defun face-foreground (face &optional frame)
 356   "Return the foreground color name of FACE, or nil if unspecified.
 357 If the optional argument FRAME is given, report on face FACE in that frame.
 358 If FRAME is t, report on the defaults for face FACE (for new frames).
 359 If FRAME is omitted or nil, use the selected frame."
 360   (internal-get-lisp-face-attribute face :foreground frame))
 361
 362
 363 (defun face-background (face &optional frame)
 364   "Return the background color name of FACE, or nil if unspecified.
 365 If the optional argument FRAME is given, report on face FACE in that frame.
 366 If FRAME is t, report on the defaults for face FACE (for new frames).
 367 If FRAME is omitted or nil, use the selected frame."
 368   (internal-get-lisp-face-attribute face :background frame))
 369
 370
 371 (defun face-stipple (face &optional frame)
 372  "Return the stipple pixmap name of FACE, or nil if unspecified.
 373 If the optional argument FRAME is given, report on face FACE in that frame.
 374 If FRAME is t, report on the defaults for face FACE (for new frames).
 375 If FRAME is omitted or nil, use the selected frame."
 376   (internal-get-lisp-face-attribute face :stipple frame))
 377
 378
 379 (defalias 'face-background-pixmap 'face-stipple)
 380
 381
 382 (defun face-underline-p (face &optional frame)
 383  "Return non-nil if FACE is underlined.
 384 If the optional argument FRAME is given, report on face FACE in that frame.
 385 If FRAME is t, report on the defaults for face FACE (for new frames).
 386 If FRAME is omitted or nil, use the selected frame."
 387  (eq (face-attribute face :underline frame) t))
 388
 389
 390 (defun face-inverse-video-p (face &optional frame)
 391  "Return non-nil if FACE is in inverse video on FRAME.
 392 If the optional argument FRAME is given, report on face FACE in that frame.
 393 If FRAME is t, report on the defaults for face FACE (for new frames).
 394 If FRAME is omitted or nil, use the selected frame."
 395  (eq (face-attribute face :inverse-video frame) t))
 396
 397
 398 (defun face-bold-p (face &optional frame)
 399   "Return non-nil if the font of FACE is bold on FRAME.
 400 If the optional argument FRAME is given, report on face FACE in that frame.
 401 If FRAME is t, report on the defaults for face FACE (for new frames).
 402 If FRAME is omitted or nil, use the selected frame.
 403 Use `face-attribute' for finer control."
 404   (let ((bold (face-attribute face :weight frame)))
 405     (memq bold '(semi-bold bold extra-bold ultra-bold))))
 406
 407
 408 (defun face-italic-p (face &optional frame)
 409   "Return non-nil if the font of FACE is italic on FRAME.
 410 If the optional argument FRAME is given, report on face FACE in that frame.
 411 If FRAME is t, report on the defaults for face FACE (for new frames).
 412 If FRAME is omitted or nil, use the selected frame.
 413 Use `face-attribute' for finer control."
 414   (let ((italic (face-attribute face :slant frame)))
 415     (memq italic '(italic oblique))))
 416
 417
 418 \f
 419 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 420 ;;; Face documentation.
 421 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 422
 423 (defun face-documentation (face)
 424   "Get the documentation string for FACE."
 425   (get face 'face-documentation))
 426
 427
 428 (defun set-face-documentation (face string)
 429   "Set the documentation string for FACE to STRING."
 430   ;; Perhaps the text should go in DOC.
 431   (put face 'face-documentation (purecopy string)))
 432
 433
 434 (defalias 'face-doc-string 'face-documentation)
 435 (defalias 'set-face-doc-string 'set-face-documentation)
 436
 437
 438 \f
 439 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 440 ;; Setting face attributes.
 441 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 442
 443
 444 (defun set-face-attribute (face frame &rest args)
 445   "Set attributes of FACE on FRAME from ARGS.
 446
 447 FRAME nil means change attributes on all frames.  FRAME t means change
 448 the default for new frames (this is done automatically each time an
 449 attribute is changed on all frames).
 450
 451 ARGS must come in pairs ATTRIBUTE VALUE.  ATTRIBUTE must be a valid
 452 face attribute name.  All attributes can be set to `unspecified';
 453 this fact is not further mentioned below.
 454
 455 The following attributes are recognized:
 456
 457 `:family'
 458
 459 VALUE must be a string specifying the font family, e.g. ``courier'',
 460 or a fontset alias name.  If a font family is specified, wild-cards `*'
 461 and `?' are allowed.
 462
 463 `:width'
 464
 465 VALUE specifies the relative proportionate width of the font to use.
 466 It must be one of the symbols `ultra-condensed', `extra-condensed',
 467 `condensed', `semi-condensed', `normal', `semi-expanded', `expanded',
 468 `extra-expanded', or `ultra-expanded'.
 469
 470 `:height'
 471
 472 VALUE must be either an integer specifying the height of the font to use
 473 in 1/10 pt, a floating point number specifying the amount by which to
 474 scale any underlying face, or a function, which is called with the old
 475 height (from the underlying face), and should return the new height.
 476
 477 `:weight'
 478
 479 VALUE specifies the weight of the font to use.  It must be one of the
 480 symbols `ultra-bold', `extra-bold', `bold', `semi-bold', `normal',
 481 `semi-light', `light', `extra-light', `ultra-light'.
 482
 483 `:slant'
 484
 485 VALUE specifies the slant of the font to use.  It must be one of the
 486 symbols `italic', `oblique', `normal', `reverse-italic', or
 487 `reverse-oblique'.
 488
 489 `:foreground', `:background'
 490
 491 VALUE must be a color name, a string.
 492
 493 `:underline'
 494
 495 VALUE specifies whether characters in FACE should be underlined.  If
 496 VALUE is t, underline with foreground color of the face.  If VALUE is
 497 a string, underline with that color.  If VALUE is nil, explicitly
 498 don't underline.
 499
 500 `:overline'
 501
 502 VALUE specifies whether characters in FACE should be overlined.  If
 503 VALUE is t, overline with foreground color of the face.  If VALUE is a
 504 string, overline with that color.  If VALUE is nil, explicitly don't
 505 overline.
 506
 507 `:strike-through'
 508
 509 VALUE specifies whether characters in FACE should be drawn with a line
 510 striking through them.  If VALUE is t, use the foreground color of the
 511 face.  If VALUE is a string, strike-through with that color.  If VALUE
 512 is nil, explicitly don't strike through.
 513
 514 `:box'
 515
 516 VALUE specifies whether characters in FACE should have a box drawn
 517 around them.  If VALUE is nil, explicitly don't draw boxes.  If
 518 VALUE is t, draw a box with lines of width 1 in the foreground color
 519 of the face.  If VALUE is a string, the string must be a color name,
 520 and the box is drawn in that color with a line width of 1.  Otherwise,
 521 VALUE must be a property list of the form `(:line-width WIDTH
 522 :color COLOR :style STYLE)'.  If a keyword/value pair is missing from
 523 the property list, a default value will be used for the value, as
 524 specified below.  WIDTH specifies the width of the lines to draw; it
 525 defaults to 1.  COLOR is the name of the color to draw in, default is
 526 the foreground color of the face for simple boxes, and the background
 527 color of the face for 3D boxes.  STYLE specifies whether a 3D box
 528 should be draw.  If STYLE is `released-button', draw a box looking
 529 like a released 3D button.  If STYLE is `pressed-button' draw a box
 530 that appears like a pressed button.  If STYLE is nil, the default if
 531 the property list doesn't contain a style specification, draw a 2D
 532 box.
 533
 534 `:inverse-video'
 535
 536 VALUE specifies whether characters in FACE should be displayed in
 537 inverse video.  VALUE must be one of t or nil.
 538
 539 `:stipple'
 540
 541 If VALUE is a string, it must be the name of a file of pixmap data.
 542 The directories listed in the `x-bitmap-file-path' variable are
 543 searched.  Alternatively, VALUE may be a list of the form (WIDTH
 544 HEIGHT DATA) where WIDTH and HEIGHT are the size in pixels, and DATA
 545 is a string containing the raw bits of the bitmap.  VALUE nil means
 546 explicitly don't use a stipple pattern.
 547
 548 For convenience, attributes `:family', `:width', `:height', `:weight',
 549 and `:slant' may also be set in one step from an X font name:
 550
 551 `:font'
 552
 553 Set font-related face attributes from VALUE.  VALUE must be a valid
 554 XLFD font name.  If it is a font name pattern, the first matching font
 555 will be used.
 556
 557 For compatibility with Emacs 20, keywords `:bold' and `:italic' can
 558 be used to specify that a bold or italic font should be used.  VALUE
 559 must be t or nil in that case.  A value of `unspecified' is not allowed.
 560
 561 `:inherit'
 562
 563 VALUE is the name of a face from which to inherit attributes, or a list
 564 of face names.  Attributes from inherited faces are merged into the face
 565 like an underlying face would be, with higher priority than underlying faces."
 566   (let ((where (if (null frame) 0 frame)))
 567     (setq args (purecopy args))
 568     (while args
 569       (internal-set-lisp-face-attribute face (car args)
 570                                         (purecopy (cadr args))
 571                                         where)
 572       (setq args (cdr (cdr args))))))
 573
 574
 575 (defun make-face-bold (face &optional frame noerror)
 576   "Make the font of FACE be bold, if possible.
 577 FRAME nil or not specified means change face on all frames.
 578 Argument NOERROR is ignored and retained for compatibility.
 579 Use `set-face-attribute' for finer control of the font weight."
 580   (interactive (list (read-face-name "Make which face bold ")))
 581   (set-face-attribute face frame :weight 'bold))
 582
 583
 584 (defun make-face-unbold (face &optional frame noerror)
 585   "Make the font of FACE be non-bold, if possible.
 586 FRAME nil or not specified means change face on all frames.
 587 Argument NOERROR is ignored and retained for compatibility."
 588   (interactive (list (read-face-name "Make which face non-bold ")))
 589   (set-face-attribute face frame :weight 'normal))
 590
 591
 592 (defun make-face-italic (face &optional frame noerror)
 593   "Make the font of FACE be italic, if possible.
 594 FRAME nil or not specified means change face on all frames.
 595 Argument NOERROR is ignored and retained for compatibility.
 596 Use `set-face-attribute' for finer control of the font slant."
 597   (interactive (list (read-face-name "Make which face italic ")))
 598   (set-face-attribute face frame :slant 'italic))
 599
 600
 601 (defun make-face-unitalic (face &optional frame noerror)
 602   "Make the font of FACE be non-italic, if possible.
 603 FRAME nil or not specified means change face on all frames.
 604 Argument NOERROR is ignored and retained for compatibility."
 605   (interactive (list (read-face-name "Make which face non-italic ")))
 606   (set-face-attribute face frame :slant 'normal))
 607
 608
 609 (defun make-face-bold-italic (face &optional frame noerror)
 610   "Make the font of FACE be bold and italic, if possible.
 611 FRAME nil or not specified means change face on all frames.
 612 Argument NOERROR is ignored and retained for compatibility.
 613 Use `set-face-attribute' for finer control of font weight and slant."
 614   (interactive (list (read-face-name "Make which face bold-italic: ")))
 615   (set-face-attribute face frame :weight 'bold :slant 'italic))
 616
 617
 618 (defun set-face-font (face font &optional frame)
 619   "Change font-related attributes of FACE to those of FONT (a string).
 620 FRAME nil or not specified means change face on all frames.
 621 This sets the attributes `:family', `:width', `:height', `:weight',
 622 and `:slant'.  When called interactively, prompt for the face and font."
 623   (interactive (read-face-and-attribute :font))
 624   (set-face-attribute face frame :font font))
 625
 626
 627 ;; Implementation note: Emulating gray background colors with a
 628 ;; stipple pattern is now part of the face realization process, and is
 629 ;; done in C depending on the frame on which the face is realized.
 630
 631 (defun set-face-background (face color &optional frame)
 632   "Change the background color of face FACE to COLOR (a string).
 633 FRAME nil or not specified means change face on all frames.
 634 When called interactively, prompt for the face and color."
 635   (interactive (read-face-and-attribute :background))
 636   (set-face-attribute face frame :background color))
 637
 638
 639 (defun set-face-foreground (face color &optional frame)
 640   "Change the foreground color of face FACE to COLOR (a string).
 641 FRAME nil or not specified means change face on all frames.
 642 When called interactively, prompt for the face and color."
 643   (interactive (read-face-and-attribute :foreground))
 644   (set-face-attribute face frame :foreground color))
 645
 646
 647 (defun set-face-stipple (face stipple &optional frame)
 648   "Change the stipple pixmap of face FACE to STIPPLE.
 649 FRAME nil or not specified means change face on all frames.
 650 STIPPLE should be a string, the name of a file of pixmap data.
 651 The directories listed in the `x-bitmap-file-path' variable are searched.
 652
 653 Alternatively, STIPPLE may be a list of the form (WIDTH HEIGHT DATA)
 654 where WIDTH and HEIGHT are the size in pixels,
 655 and DATA is a string, containing the raw bits of the bitmap."
 656   (interactive (read-face-and-attribute :stipple))
 657   (set-face-attribute face frame :stipple stipple))
 658
 659
 660 (defun set-face-underline (face underline &optional frame)
 661   "Specify whether face FACE is underlined.
 662 UNDERLINE nil means FACE explicitly doesn't underline.
 663 UNDERLINE non-nil means FACE explicitly does underlining
 664 with the same of the foreground color.
 665 If UNDERLINE is a string, underline with the color named UNDERLINE.
 666 FRAME nil or not specified means change face on all frames.
 667 Use `set-face-attribute' to ``unspecify'' underlining."
 668   (interactive
 669    (let ((list (read-face-and-attribute :underline)))
 670      (list (car list) (eq (car (cdr list)) t))))
 671   (set-face-attribute face frame :underline underline))
 672
 673
 674 (defun set-face-underline-p (face underline-p &optional frame)
 675   "Specify whether face FACE is underlined.
 676 UNDERLINE-P nil means FACE explicitly doesn't underline.
 677 UNDERLINE-P non-nil means FACE explicitly does underlining.
 678 FRAME nil or not specified means change face on all frames.
 679 Use `set-face-attribute' to ``unspecify'' underlining."
 680   (interactive
 681    (let ((list (read-face-and-attribute :underline)))
 682      (list (car list) (eq (car (cdr list)) t))))
 683   (set-face-attribute face frame :underline underline-p))
 684
 685
 686 (defun set-face-inverse-video-p (face inverse-video-p &optional frame)
 687   "Specify whether face FACE is in inverse video.
 688 INVERSE-VIDEO-P non-nil means FACE displays explicitly in inverse video.
 689 INVERSE-VIDEO-P nil means FACE explicitly is not in inverse video.
 690 FRAME nil or not specified means change face on all frames.
 691 Use `set-face-attribute' to ``unspecify'' the inverse video attribute."
 692   (interactive
 693    (let ((list (read-face-and-attribute :inverse-video)))
 694      (list (car list) (eq (car (cdr list)) t))))
 695   (set-face-attribute face frame :inverse-video inverse-video-p))
 696
 697
 698 (defun set-face-bold-p (face bold-p &optional frame)
 699   "Specify whether face FACE is bold.
 700 BOLD-P non-nil means FACE should explicitly display bold.
 701 BOLD-P nil means FACE should explicitly display non-bold.
 702 FRAME nil or not specified means change face on all frames.
 703 Use `set-face-attribute' or `modify-face' for finer control."
 704   (if (null bold-p)
 705       (make-face-unbold face frame)
 706     (make-face-bold face frame)))
 707
 708
 709 (defun set-face-italic-p (face italic-p &optional frame)
 710   "Specify whether face FACE is italic.
 711 ITALIC-P non-nil means FACE should explicitly display italic.
 712 ITALIC-P nil means FACE should explicitly display non-italic.
 713 FRAME nil or not specified means change face on all frames.
 714 Use `set-face-attribute' or `modify-face' for finer control."
 715   (if (null italic-p)
 716       (make-face-unitalic face frame)
 717     (make-face-italic face frame)))
 718
 719
 720 (defalias 'set-face-background-pixmap 'set-face-stipple)
 721
 722
 723 (defun invert-face (face &optional frame)
 724   "Swap the foreground and background colors of FACE.
 725 FRAME nil or not specified means change face on all frames.
 726 If FACE specifies neither foreground nor background color,
 727 set its foreground and background to the background and foreground
 728 of the default face.  Value is FACE."
 729   (interactive (list (read-face-name "Invert face ")))
 730   (let ((fg (face-attribute face :foreground frame))
 731         (bg (face-attribute face :background frame)))
 732     (if (or fg bg)
 733         (set-face-attribute face frame :foreground bg :background fg)
 734       (set-face-attribute face frame
 735                           :foreground
 736                           (face-attribute 'default :background frame)
 737                           :background
 738                           (face-attribute 'default :foreground frame))))
 739   face)
 740
 741 \f
 742 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 743 ;;; Interactively modifying faces.
 744 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 745
 746 (defun read-face-name (prompt)
 747   "Read and return a face symbol, prompting with PROMPT.
 748 Value is a symbol naming a known face."
 749   (let ((face-list (mapcar #'(lambda (x) (cons (symbol-name x) x))
 750                            (face-list)))
 751         (def (thing-at-point 'symbol))
 752         face)
 753     (cond ((assoc def face-list)
 754            (setq prompt (concat prompt " (default " def "): ")))
 755           (t (setq def nil)
 756              (setq prompt (concat prompt ": "))))
 757     (while (equal "" (setq face (completing-read
 758                                  prompt face-list nil t nil nil def))))
 759     (intern face)))
 760
 761
 762 (defun face-valid-attribute-values (attribute &optional frame)
 763   "Return valid values for face attribute ATTRIBUTE.
 764 The optional argument FRAME is used to determine available fonts
 765 and colors.  If it is nil or not specified, the selected frame is
 766 used.  Value is an alist of (NAME . VALUE) if ATTRIBUTE expects a value
 767 out of a set of discrete values.  Value is `integerp' if ATTRIBUTE expects
 768 an integer value."
 769   (let (valid)
 770     (setq valid
 771           (case attribute
 772             (:family
 773              (if window-system
 774                  (mapcar #'(lambda (x) (cons (car x) (car x)))
 775                          (x-font-family-list))
 776                ;; Only one font on TTYs.
 777                (list (cons "default" "default"))))
 778             ((:width :weight :slant :inverse-video)
 779              (mapcar #'(lambda (x) (cons (symbol-name x) x))
 780                      (internal-lisp-face-attribute-values attribute)))
 781             ((:underline :overline :strike-through :box)
 782              (if window-system
 783                  (nconc (mapcar #'(lambda (x) (cons (symbol-name x) x))
 784                                 (internal-lisp-face-attribute-values attribute))
 785                         (mapcar #'(lambda (c) (cons c c))
 786                                 (x-defined-colors frame)))
 787                (mapcar #'(lambda (x) (cons (symbol-name x) x))
 788                        (internal-lisp-face-attribute-values attribute))))
 789             ((:foreground :background)
 790              (mapcar #'(lambda (c) (cons c c))
 791                      (defined-colors frame)))
 792             ((:height)
 793              'integerp)
 794             (:stipple
 795              (and (memq window-system '(x w32 mac))
 796                   (mapcar #'list
 797                           (apply #'nconc
 798                                  (mapcar (lambda (dir)
 799                                            (and (file-readable-p dir)
 800                                                 (file-directory-p dir)
 801                                                 (directory-files dir)))
 802                                          x-bitmap-file-path)))))
 803             (:inherit
 804              (cons '("none" . nil)
 805                    (mapcar #'(lambda (c) (cons (symbol-name c) c))
 806                            (face-list))))
 807             (t
 808              (error "Internal error"))))
 809     (if (and (listp valid) (not (memq attribute '(:inherit))))
 810         (nconc (list (cons "unspecified" 'unspecified)) valid)
 811       valid)))
 812
 813
 814
 815 (defvar face-attribute-name-alist
 816   '((:family . "font family")
 817     (:width . "character set width")
 818     (:height . "height in 1/10 pt")
 819     (:weight . "weight")
 820     (:slant . "slant")
 821     (:underline . "underline")
 822     (:overline . "overline")
 823     (:strike-through . "strike-through")
 824     (:box . "box")
 825     (:inverse-video . "inverse-video display")
 826     (:foreground . "foreground color")
 827     (:background . "background color")
 828     (:stipple . "background stipple")
 829     (:inherit . "inheritance"))
 830   "An alist of descriptive names for face attributes.
 831 Each element has the form (ATTRIBUTE-NAME . DESCRIPTION) where
 832 ATTRIBUTE-NAME is a face attribute name (a keyword symbol), and
 833 DESCRIPTION is a descriptive name for ATTRIBUTE-NAME.")
 834
 835
 836 (defun face-descriptive-attribute-name (attribute)
 837   "Return a descriptive name for ATTRIBUTE."
 838   (cdr (assq attribute face-attribute-name-alist)))
 839
 840
 841 (defun face-read-string (face default name &optional completion-alist)
 842   "Interactively read a face attribute string value.
 843 FACE is the face whose attribute is read.  If non-nil, DEFAULT is the
 844 default string to return if no new value is entered.  NAME is a
 845 descriptive name of the attribute for prompting.  COMPLETION-ALIST is an
 846 alist of valid values, if non-nil.
 847
 848 Entering nothing accepts the default string DEFAULT.
 849 Value is the new attribute value."
 850   ;; Capitalize NAME (we don't use `capitalize' because that capitalizes
 851   ;; each word in a string separately).
 852   (setq name (concat (upcase (substring name 0 1)) (substring name 1)))
 853   (let* ((completion-ignore-case t)
 854          (value (completing-read
 855                  (if default
 856                      (format "%s for face `%s' (default %s): "
 857                              name face default)
 858                    (format "%s for face `%s': " name face))
 859                  completion-alist)))
 860     (if (equal value "") default value)))
 861
 862
 863 (defun face-read-integer (face default name)
 864   "Interactively read an integer face attribute value.
 865 FACE is the face whose attribute is read.  DEFAULT is the default
 866 value to return if no new value is entered.  NAME is a descriptive
 867 name of the attribute for prompting.  Value is the new attribute value."
 868   (let ((new-value
 869          (face-read-string face
 870                            (format "%s" default)
 871                            name
 872                            (list (cons "unspecified" 'unspecified)))))
 873     (cond ((equal new-value "unspecified")
 874            'unspecified)
 875           ((member new-value '("unspecified-fg" "unspecified-bg"))
 876            new-value)
 877           (t
 878            (string-to-int new-value)))))
 879
 880
 881 (defun read-face-attribute (face attribute &optional frame)
 882   "Interactively read a new value for FACE's ATTRIBUTE.
 883 Optional argument FRAME nil or unspecified means read an attribute value
 884 of a global face.  Value is the new attribute value."
 885   (let* ((old-value (face-attribute face attribute frame))
 886          (attribute-name (face-descriptive-attribute-name attribute))
 887          (valid (face-valid-attribute-values attribute frame))
 888          new-value)
 889     ;; Represent complex attribute values as strings by printing them
 890     ;; out.  Stipple can be a vector; (WIDTH HEIGHT DATA).  Box can be
 891     ;; a list `(:width WIDTH :color COLOR)' or `(:width WIDTH :shadow
 892     ;; SHADOW)'.
 893     (when (and (or (eq attribute :stipple)
 894                    (eq attribute :box))
 895                (or (consp old-value)
 896                    (vectorp old-value)))
 897       (setq old-value (prin1-to-string old-value)))
 898     (cond ((listp valid)
 899            (let ((default
 900                    (or (car (rassoc old-value valid))
 901                        (format "%s" old-value))))
 902              (setq new-value
 903                    (face-read-string face default attribute-name valid))
 904              (if (equal new-value default)
 905                  ;; Nothing changed, so don't bother with all the stuff
 906                  ;; below.  In particular, this avoids a non-tty color
 907                  ;; from being canonicalized for a tty when the user
 908                  ;; just uses the default.
 909                  (setq new-value old-value)
 910                ;; Terminal frames can support colors that don't appear
 911                ;; explicitly in VALID, using color approximation code
 912                ;; in tty-colors.el.
 913                (if (and (memq attribute '(:foreground :background))
 914                         (not (memq window-system '(x w32 mac)))
 915                         (not (member new-value
 916                                      '("unspecified"
 917                                        "unspecified-fg" "unspecified-bg"))))
 918                    (setq new-value (car (tty-color-desc new-value frame))))
 919                (setq new-value (cdr (assoc new-value valid))))))
 920           ((eq valid 'integerp)
 921            (setq new-value (face-read-integer face old-value attribute-name)))
 922           (t (error "Internal error")))
 923     ;; Convert stipple and box value text we read back to a list or
 924     ;; vector if it looks like one.  This makes the assumption that a
 925     ;; pixmap file name won't start with an open-paren.
 926     (when (and (or (eq attribute :stipple)
 927                    (eq attribute :box))
 928                (stringp new-value)
 929                (string-match "^[[(]" new-value))
 930       (setq new-value (read new-value)))
 931     new-value))
 932
 933
 934 (defun read-face-font (face &optional frame)
 935   "Read the name of a font for FACE on FRAME.
 936 If optional argument FRAME Is nil or omitted, use the selected frame."
 937   (let ((completion-ignore-case t))
 938     (completing-read (format "Set font attributes of face `%s' from font: " face)
 939                      (mapcar 'list (x-list-fonts "*" nil frame)))))
 940
 941
 942 (defun read-all-face-attributes (face &optional frame)
 943   "Interactively read all attributes for FACE.
 944 If optional argument FRAME Is nil or omitted, use the selected frame.
 945 Value is a property list of attribute names and new values."
 946   (let (result)
 947     (dolist (attribute face-attribute-name-alist result)
 948       (setq result (cons (car attribute)
 949                          (cons (read-face-attribute face (car attribute) frame)
 950                                result))))))
 951
 952
 953 (defun modify-face (&optional frame)
 954   "Modify attributes of faces interactively.
 955 If optional argument FRAME is nil or omitted, modify the face used
 956 for newly created frame, i.e. the global face."
 957   (interactive)
 958   (let ((face (read-face-name "Modify face")))
 959     (apply #'set-face-attribute face frame
 960            (read-all-face-attributes face frame))))
 961
 962
 963 (defun read-face-and-attribute (attribute &optional frame)
 964   "Read face name and face attribute value.
 965 ATTRIBUTE is the attribute whose new value is read.
 966 FRAME nil or unspecified means read attribute value of global face.
 967 Value is a list (FACE NEW-VALUE) where FACE is the face read
 968 (a symbol), and NEW-VALUE is value read."
 969   (cond ((eq attribute :font)
 970          (let* ((prompt "Set font-related attributes of face")
 971                 (face (read-face-name prompt))
 972                 (font (read-face-font face frame)))
 973            (list face font)))
 974         (t
 975          (let* ((attribute-name (face-descriptive-attribute-name attribute))
 976                 (prompt (format "Set %s of face" attribute-name))
 977                 (face (read-face-name prompt))
 978                 (new-value (read-face-attribute face attribute frame)))
 979            (list face new-value)))))
 980
 981
 982 \f
 983 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 984 ;;; Listing faces.
 985 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 986
 987 (defvar list-faces-sample-text
 988   "abcdefghijklmnopqrstuvwxyz ABCDEFGHIJKLMNOPQRSTUVWXYZ"
 989   "*Text string to display as the sample text for `list-faces-display'.")
 990
 991
 992 ;; The name list-faces would be more consistent, but let's avoid a
 993 ;; conflict with Lucid, which uses that name differently.
 994
 995 (defun list-faces-display ()
 996   "List all faces, using the same sample text in each.
 997 The sample text is a string that comes from the variable
 998 `list-faces-sample-text'."
 999   (interactive)
1000   (let ((faces (sort (face-list) #'string-lessp))
1001         (face nil)
1002         (frame (selected-frame))
1003         disp-frame window face-name)
1004     (with-output-to-temp-buffer "*Faces*"
1005       (save-excursion
1006         (set-buffer standard-output)
1007         (setq truncate-lines t)
1008         (insert
1009          (substitute-command-keys
1010           (concat
1011            "Use "
1012            (if (display-mouse-p) "\\[help-follow-mouse] or ")
1013            "\\[help-follow] on a face name to customize it\n"
1014            "or on its sample text for a decription of the face.\n\n")))
1015         (setq help-xref-stack nil)
1016         (while faces
1017           (setq face (car faces))
1018           (setq faces (cdr faces))
1019           (setq face-name (symbol-name face))
1020           (insert (format "%25s " face-name))
1021           ;; Hyperlink to a customization buffer for the face.  Using
1022           ;; the help xref mechanism may not be the best way.
1023           (save-excursion
1024             (save-match-data
1025               (search-backward face-name)
1026               (help-xref-button 0 (lambda (f)
1027                                     (if help-xref-stack
1028                                         (pop help-xref-stack))
1029                                     (customize-face f))
1030                                 face-name
1031                                 "mouse-2: customize this face")))
1032           (let ((beg (point)))
1033             (insert list-faces-sample-text)
1034             ;; Hyperlink to a help buffer for the face.
1035             (save-excursion
1036               (save-match-data
1037                 (search-backward list-faces-sample-text)
1038                 (help-xref-button 0 #'describe-face face
1039                                   "mouse-2: describe this face")))
1040             (insert "\n")
1041             (put-text-property beg (1- (point)) 'face face)
1042             ;; If the sample text has multiple lines, line up all of them.
1043             (goto-char beg)
1044             (forward-line 1)
1045             (while (not (eobp))
1046               (insert "                          ")
1047               (forward-line 1))))
1048         (goto-char (point-min)))
1049       (print-help-return-message))
1050     ;; If the *Faces* buffer appears in a different frame,
1051     ;; copy all the face definitions from FRAME,
1052     ;; so that the display will reflect the frame that was selected.
1053     (setq window (get-buffer-window (get-buffer "*Faces*") t))
1054     (setq disp-frame (if window (window-frame window)
1055                        (car (frame-list))))
1056     (or (eq frame disp-frame)
1057         (let ((faces (face-list)))
1058           (while faces
1059             (copy-face (car faces) (car faces) frame disp-frame)
1060             (setq faces (cdr faces)))))))
1061
1062
1063 (defun describe-face (face &optional frame)
1064   "Display the properties of face FACE on FRAME.
1065 If the optional argument FRAME is given, report on face FACE in that frame.
1066 If FRAME is t, report on the defaults for face FACE (for new frames).
1067 If FRAME is omitted or nil, use the selected frame."
1068   (interactive (list (read-face-name "Describe face")))
1069   (let* ((attrs '((:family . "Family")
1070                   (:width . "Width")
1071                   (:height . "Height")
1072                   (:weight . "Weight")
1073                   (:slant . "Slant")
1074                   (:foreground . "Foreground")
1075                   (:background . "Background")
1076                   (:underline . "Underline")
1077                   (:overline . "Overline")
1078                   (:strike-through . "Strike-through")
1079                   (:box . "Box")
1080                   (:inverse-video . "Inverse")
1081                   (:stipple . "Stipple")
1082                   (:font . "Font or fontset")
1083                   (:inherit . "Inherit")))
1084         (max-width (apply #'max (mapcar #'(lambda (x) (length (cdr x)))
1085                                         attrs))))
1086     (with-output-to-temp-buffer "*Help*"
1087       (save-excursion
1088         (set-buffer standard-output)
1089         (dolist (a attrs)
1090           (let ((attr (face-attribute face (car a) frame)))
1091             (insert (make-string (- max-width (length (cdr a))) ?\ )
1092                     (cdr a) ": " (format "%s" attr) "\n")))
1093         (insert "\nDocumentation:\n\n"
1094                 (or (face-documentation face)
1095                     "not documented as a face."))
1096         (let ((customize-label "customize"))
1097           (terpri)
1098           (terpri)
1099           (princ (concat "You can " customize-label " this face."))
1100           (with-current-buffer "*Help*"
1101             (save-excursion
1102               (re-search-backward
1103                (concat "\\(" customize-label "\\)") nil t)
1104               (help-xref-button 1 #'customize-face face
1105                                 "mouse-2, RET: customize face")))))
1106       (print-help-return-message)
1107       (with-current-buffer "*Help*"
1108         (help-setup-xref (list #'describe-face face) (interactive-p))
1109         (buffer-string)))))
1110 \f
1111 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1112 ;;; Face specifications (defface).
1113 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1114
1115 ;; Parameter FRAME Is kept for call compatibility to with previous
1116 ;; face implementation.
1117
1118 (defun face-attr-construct (face &optional frame)
1119   "Return a defface-style attribute list for FACE on FRAME.
1120 Value is a property list of pairs ATTRIBUTE VALUE for all specified
1121 face attributes of FACE where ATTRIBUTE is the attribute name and
1122 VALUE is the specified value of that attribute."
1123   (let (result)
1124     (dolist (entry face-attribute-name-alist result)
1125       (let* ((attribute (car entry))
1126              (value (face-attribute face attribute)))
1127         (unless (eq value 'unspecified)
1128           (setq result (nconc (list attribute value) result)))))))
1129
1130
1131 (defun face-spec-set-match-display (display frame)
1132   "Non-nil if DISPLAY matches FRAME.
1133 DISPLAY is part of a spec such as can be used in `defface'.
1134 If FRAME is nil, the current FRAME is used."
1135   (let* ((conjuncts display)
1136          conjunct req options
1137          ;; t means we have succeeded against all the conjuncts in
1138          ;; DISPLAY that have been tested so far.
1139          (match t))
1140     (if (eq conjuncts t)
1141         (setq conjuncts nil))
1142     (while (and conjuncts match)
1143       (setq conjunct (car conjuncts)
1144             conjuncts (cdr conjuncts)
1145             req (car conjunct)
1146             options (cdr conjunct)
1147             match (cond ((eq req 'type)
1148                          (or (memq window-system options)
1149                              ;; FIXME: This should be revisited to use
1150                              ;; display-graphic-p, provided that the
1151                              ;; color selection depends on the number
1152                              ;; of supported colors, and all defface's
1153                              ;; are changed to look at number of colors
1154                              ;; instead of (type graphic) etc.
1155                              (and (null window-system)
1156                                   (memq 'tty options))
1157                              (and (memq 'motif options)
1158                                   (featurep 'motif))
1159                              (and (memq 'lucid options)
1160                                   (featurep 'x-toolkit)
1161                                   (not (featurep 'motif)))
1162                              (and (memq 'x-toolkit options)
1163                                   (featurep 'x-toolkit))))
1164                         ((eq req 'class)
1165                          (memq (frame-parameter frame 'display-type) options))
1166                         ((eq req 'background)
1167                          (memq (frame-parameter frame 'background-mode)
1168                                options))
1169                         (t (error "Unknown req `%S' with options `%S'"
1170                                   req options)))))
1171     match))
1172
1173
1174 (defun face-spec-choose (spec &optional frame)
1175   "Choose the proper attributes for FRAME, out of SPEC.
1176 If SPEC is nil, return nil."
1177   (unless frame
1178     (setq frame (selected-frame)))
1179   (let ((tail spec)
1180         result)
1181     (while tail
1182       (let* ((entry (pop tail))
1183              (display (car entry))
1184              (attrs (cdr entry)))
1185         (when (face-spec-set-match-display display frame)
1186           (setq result (if (listp (car attrs))
1187                            ;; Old-style entry, the attribute list is the
1188                            ;; first element.
1189                            (car attrs)
1190                          attrs)
1191                 tail nil))))
1192     result))
1193
1194
1195 (defun face-spec-reset-face (face &optional frame)
1196   "Reset all attributes of FACE on FRAME to unspecified."
1197   (let ((attrs face-attribute-name-alist))
1198     (while attrs
1199       (let ((attr-and-name (car attrs)))
1200         (set-face-attribute face frame (car attr-and-name) 'unspecified))
1201       (setq attrs (cdr attrs)))))
1202
1203
1204 (defun face-spec-set (face spec &optional frame)
1205   "Set FACE's attributes according to the first matching entry in SPEC.
1206 FRAME is the frame whose frame-local face is set.  FRAME nil means
1207 do it on all frames.  See `defface' for information about SPEC.
1208 If SPEC is nil, do nothing."
1209   (let ((attrs (face-spec-choose spec frame)))
1210     (when attrs
1211       (face-spec-reset-face face frame))
1212     (while attrs
1213       (let ((attribute (car attrs))
1214             (value (car (cdr attrs))))
1215         ;; Support some old-style attribute names and values.
1216         (case attribute
1217           (:bold (setq attribute :weight value (if value 'bold 'normal)))
1218           (:italic (setq attribute :slant value (if value 'italic 'normal)))
1219           (t (unless (assq attribute face-x-resources)
1220                (setq attribute nil))))
1221         (when attribute
1222           (set-face-attribute face frame attribute value)))
1223       (setq attrs (cdr (cdr attrs))))))
1224
1225
1226 (defun face-attr-match-p (face attrs &optional frame)
1227   "Return t if attributes of FACE match values in plist ATTRS.
1228 Optional parameter FRAME is the frame whose definition of FACE
1229 is used.  If nil or omitted, use the selected frame."
1230   (unless frame
1231     (setq frame (selected-frame)))
1232   (let ((list face-attribute-name-alist)
1233         (match t))
1234     (while (and match (not (null list)))
1235       (let* ((attr (car (car list)))
1236              (specified-value
1237               (if (plist-member attrs attr)
1238                   (plist-get attrs attr)
1239                 'unspecified))
1240              (value-now (face-attribute face attr frame)))
1241         (setq match (equal specified-value value-now))
1242         (setq list (cdr list))))
1243     match))
1244
1245 (defun face-spec-match-p (face spec &optional frame)
1246   "Return t if FACE, on FRAME, matches what SPEC says it should look like."
1247   (face-attr-match-p face (face-spec-choose spec frame) frame))
1248
1249 (defsubst face-default-spec (face)
1250   "Return the default face-spec for FACE, ignoring any user customization.
1251 If there is no default for FACE, return nil."
1252   (get face 'face-defface-spec))
1253
1254 (defsubst face-user-default-spec (face)
1255   "Return the user's customized face-spec for FACE, or the default if none.
1256 If there is neither a user setting or a default for FACE, return nil."
1257   (or (get face 'saved-face)
1258       (face-default-spec face)))
1259
1260 \f
1261 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1262 ;;; Frame-type independent color support.
1263 ;;; We keep the old x-* names as aliases for back-compatibility.
1264 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1265
1266 (defun defined-colors (&optional frame)
1267   "Return a list of colors supported for a particular frame.
1268 The argument FRAME specifies which frame to try.
1269 The value may be different for frames on different display types.
1270 If FRAME doesn't support colors, the value is nil."
1271   (if (memq (framep (or frame (selected-frame))) '(x w32 mac))
1272       (xw-defined-colors frame)
1273     (mapcar 'car (tty-color-alist frame))))
1274 (defalias 'x-defined-colors 'defined-colors)
1275
1276 (defun color-defined-p (color &optional frame)
1277   "Return non-nil if color COLOR is supported on frame FRAME.
1278 If FRAME is omitted or nil, use the selected frame.
1279 If COLOR is the symbol `unspecified' or one of the strings
1280 \"unspecified-fg\" or \"unspecified-bg\", the value is nil."
1281   (if (member color '(unspecified "unspecified-bg" "unspecified-fg"))
1282       nil
1283     (if (member (framep (or frame (selected-frame))) '(x w32 mac))
1284         (xw-color-defined-p color frame)
1285       (numberp (tty-color-translate color frame)))))
1286 (defalias 'x-color-defined-p 'color-defined-p)
1287
1288 (defun color-values (color &optional frame)
1289   "Return a description of the color named COLOR on frame FRAME.
1290 The value is a list of integer RGB values--\(RED GREEN BLUE\).
1291 These values appear to range from 0 65535; white is \(65535 65535 65535\).
1292 If FRAME is omitted or nil, use the selected frame.
1293 If FRAME cannot display COLOR, the value is nil.
1294 If COLOR is the symbol `unspecified' or one of the strings
1295 \"unspecified-fg\" or \"unspecified-bg\", the value is nil."
1296   (if (member color '(unspecified "unspecified-fg" "unspecified-bg"))
1297       nil
1298     (if (memq (framep (or frame (selected-frame))) '(x w32 mac))
1299         (xw-color-values color frame)
1300       (tty-color-values color frame))))
1301 (defalias 'x-color-values 'color-values)
1302
1303 (defun display-color-p (&optional display)
1304   "Return t if DISPLAY supports color.
1305 The optional argument DISPLAY specifies which display to ask about.
1306 DISPLAY should be either a frame or a display name (a string).
1307 If omitted or nil, that stands for the selected frame's display."
1308   (if (memq (framep-on-display display) '(x w32 mac))
1309       (xw-display-color-p display)
1310     (tty-display-color-p display)))
1311 (defalias 'x-display-color-p 'display-color-p)
1312
1313 (defun display-grayscale-p (&optional display)
1314   "Return non-nil if frames on DISPLAY can display shades of gray."
1315   (let ((frame-type (framep-on-display display)))
1316     (cond
1317      ((memq frame-type '(x w32 mac))
1318       (x-display-grayscale-p display))
1319      (t
1320       (> (tty-color-gray-shades display) 2)))))
1321
1322 \f
1323 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1324 ;;; Background mode.
1325 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1326
1327 (defcustom frame-background-mode nil
1328   "*The brightness of the background.
1329 Set this to the symbol `dark' if your background color is dark, `light' if
1330 your background is light, or nil (default) if you want Emacs to
1331 examine the brightness for you.  Don't set this variable with `setq';
1332 this won't have the expected effect."
1333   :group 'faces
1334   :set #'(lambda (var value)
1335            (set-default var value)
1336            (mapc 'frame-set-background-mode (frame-list)))
1337   :initialize 'custom-initialize-changed
1338   :type '(choice (choice-item dark)
1339                  (choice-item light)
1340                  (choice-item :tag "default" nil)))
1341
1342
1343 (defun frame-set-background-mode (frame)
1344   "Set up display-dependent faces on FRAME.
1345 Display-dependent faces are those which have different definitions
1346 according to the `background-mode' and `display-type' frame parameters."
1347   (let* ((bg-resource
1348           (and window-system
1349                (x-get-resource ".backgroundMode" "BackgroundMode")))
1350          (bg-color (frame-parameter frame 'background-color))
1351          (bg-mode
1352           (cond (frame-background-mode)
1353                 (bg-resource
1354                  (intern (downcase bg-resource)))
1355                 ((and (null window-system) (null bg-color))
1356                  ;; No way to determine this automatically (?).
1357                  'dark)
1358                 ;; Unspecified frame background color can only happen
1359                 ;; on tty's.
1360                 ((member bg-color '(unspecified "unspecified-bg"))
1361                  'dark)
1362                 ((equal bg-color "unspecified-fg") ; inverted colors
1363                  'light)
1364                 ((>= (apply '+ (x-color-values bg-color frame))
1365                     ;; Just looking at the screen, colors whose
1366                     ;; values add up to .6 of the white total
1367                     ;; still look dark to me.
1368                     (* (apply '+ (x-color-values "white" frame)) .6))
1369                  'light)
1370                 (t 'dark)))
1371          (display-type
1372           (cond ((null window-system)
1373                  (if (tty-display-color-p frame) 'color 'mono))
1374                 ((x-display-color-p frame)
1375                  'color)
1376                 ((x-display-grayscale-p frame)
1377                  'grayscale)
1378                 (t 'mono)))
1379          (old-bg-mode
1380           (frame-parameter frame 'background-mode))
1381          (old-display-type
1382           (frame-parameter frame 'display-type)))
1383
1384     (unless (and (eq bg-mode old-bg-mode) (eq display-type old-display-type))
1385       (modify-frame-parameters frame
1386                                (list (cons 'background-mode bg-mode)
1387                                      (cons 'display-type display-type)))
1388       ;; For all named faces, choose face specs matching the new frame
1389       ;; parameters.
1390       (dolist (face (face-list))
1391         (face-spec-set face (face-user-default-spec face) frame)))))
1392
1393 \f
1394 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1395 ;;; Frame creation.
1396 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1397
1398 (defun x-handle-named-frame-geometry (parameters)
1399   "Add geometry parameters for a named frame to parameter list PARAMETERS.
1400 Value is the new parameter list."
1401   (let* ((name (or (cdr (assq 'name parameters))
1402                    (cdr (assq 'name default-frame-alist))))
1403          (x-resource-name name)
1404          (res-geometry (if name (x-get-resource "geometry" "Geometry"))))
1405     (when res-geometry
1406       (let ((parsed (x-parse-geometry res-geometry)))
1407         ;; If the resource specifies a position, call the position
1408         ;; and size "user-specified".
1409         (when (or (assq 'top parsed)
1410                   (assq 'left parsed))
1411           (setq parsed (append '((user-position . t) (user-size . t)) parsed)))
1412         ;; Put the geometry parameters at the end.  Copy
1413         ;; default-frame-alist so that they go after it.
1414         (setq parameters (append parameters default-frame-alist parsed))))
1415     parameters))
1416
1417
1418 (defun x-handle-reverse-video (frame parameters)
1419   "Handle the reverse-video frame parameter and X resource.
1420 `x-create-frame' does not handle this one."
1421   (when (cdr (or (assq 'reverse parameters)
1422                  (assq 'reverse default-frame-alist)
1423                  (let ((resource (x-get-resource "reverseVideo"
1424                                                  "ReverseVideo")))
1425                    (if resource
1426                        (cons nil (member (downcase resource)
1427                                          '("on" "true")))))))
1428       (let* ((params (frame-parameters frame))
1429              (bg (cdr (assq 'foreground-color params)))
1430              (fg (cdr (assq 'background-color params))))
1431         (modify-frame-parameters frame
1432                                  (list (cons 'foreground-color fg)
1433                                        (cons 'background-color bg)))
1434         (if (equal bg (cdr (assq 'border-color params)))
1435             (modify-frame-parameters frame
1436                                      (list (cons 'border-color fg))))
1437         (if (equal bg (cdr (assq 'mouse-color params)))
1438             (modify-frame-parameters frame
1439                                      (list (cons 'mouse-color fg))))
1440         (if (equal bg (cdr (assq 'cursor-color params)))
1441             (modify-frame-parameters frame
1442                                      (list (cons 'cursor-color fg)))))))
1443
1444
1445 (defun x-create-frame-with-faces (&optional parameters)
1446   "Create a frame from optional frame parameters PARAMETERS.
1447 Parameters not specified by PARAMETERS are taken from
1448 `default-frame-alist'.  If PARAMETERS specify a frame name,
1449 handle X geometry resources for that name.  If either PARAMETERS
1450 or `default-frame-alist' contains a `reverse' parameter, or
1451 the X resource ``reverseVideo'' is present, handle that.
1452 Value is the new frame created."
1453   (setq parameters (x-handle-named-frame-geometry parameters))
1454   (let ((visibility-spec (assq 'visibility parameters))
1455         (frame-list (frame-list))
1456         (frame (x-create-frame (cons '(visibility . nil) parameters)))
1457         success)
1458     (unwind-protect
1459         (progn
1460           (x-handle-reverse-video frame parameters)
1461           (frame-set-background-mode frame)
1462           (face-set-after-frame-default frame)
1463           (if (or (null frame-list) (null visibility-spec))
1464               (make-frame-visible frame)
1465             (modify-frame-parameters frame (list visibility-spec)))
1466           (setq success t))
1467       (unless success
1468         (delete-frame frame)))
1469     frame))
1470
1471
1472 (defun face-set-after-frame-default (frame)
1473   "Set frame-local faces of FRAME from face specs and resources.
1474 Initialize colors of certain faces from frame parameters."
1475   (dolist (face (face-list))
1476     (face-spec-set face (face-user-default-spec face) frame)
1477     (internal-merge-in-global-face face frame)
1478     (when (memq window-system '(x w32 mac))
1479       (make-face-x-resource-internal face frame)))
1480
1481   ;; Initialize attributes from frame parameters.
1482   (let ((params '((foreground-color default :foreground)
1483                   (background-color default :background)
1484                   (border-color border :background)
1485                   (cursor-color cursor :background)
1486                   (scroll-bar-foreground scroll-bar :foreground)
1487                   (scroll-bar-background scroll-bar :background)
1488                   (mouse-color mouse :background))))
1489     (while params
1490       (let ((param-name (nth 0 (car params)))
1491             (face (nth 1 (car params)))
1492             (attr (nth 2 (car params)))
1493             value)
1494         (when (setq value (frame-parameter frame param-name))
1495           (set-face-attribute face frame attr value)))
1496       (setq params (cdr params)))))
1497
1498 (defun tty-handle-reverse-video (frame parameters)
1499   "Handle the reverse-video frame parameter for terminal frames."
1500   (when (cdr (or (assq 'reverse parameters)
1501                  (assq 'reverse default-frame-alist)))
1502     (if (null window-system)
1503         (setq inverse-video t))
1504     (let* ((params (frame-parameters frame))
1505            (bg (cdr (assq 'foreground-color params)))
1506            (fg (cdr (assq 'background-color params))))
1507       (modify-frame-parameters frame
1508                                (list (cons 'foreground-color fg)
1509                                      (cons 'background-color bg)))
1510       (if (equal bg (cdr (assq 'mouse-color params)))
1511           (modify-frame-parameters frame
1512                                    (list (cons 'mouse-color fg))))
1513       (if (equal bg (cdr (assq 'cursor-color params)))
1514           (modify-frame-parameters frame
1515                                    (list (cons 'cursor-color fg)))))))
1516
1517
1518 (defun tty-create-frame-with-faces (&optional parameters)
1519   "Create a frame from optional frame parameters PARAMETERS.
1520 Parameters not specified by PARAMETERS are taken from
1521 `default-frame-alist'.  If either PARAMETERS or `default-frame-alist'
1522 contains a `reverse' parameter, handle that.  Value is the new frame
1523 created."
1524   (let ((frame (make-terminal-frame parameters))
1525         success)
1526     (unwind-protect
1527         (progn
1528           (tty-handle-reverse-video frame (frame-parameters frame))
1529           (frame-set-background-mode frame)
1530           (face-set-after-frame-default frame)
1531           (setq success t))
1532       (unless success
1533         (delete-frame frame)))
1534     frame))
1535
1536
1537 ;; Called from C function init_display to initialize faces of the
1538 ;; dumped terminal frame on startup.
1539
1540 (defun tty-set-up-initial-frame-faces ()
1541   (let ((frame (selected-frame)))
1542     (frame-set-background-mode frame)
1543     (face-set-after-frame-default frame)))
1544
1545
1546
1547 \f
1548 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1549 ;;; Compatiblity with 20.2
1550 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1551
1552 ;; Update a frame's faces when we change its default font.
1553
1554 (defalias 'frame-update-faces 'ignore)
1555 (make-obsolete 'frame-update-faces "No longer necessary" "21.1")
1556
1557 ;; Update the colors of FACE, after FRAME's own colors have been
1558 ;; changed.
1559
1560 (defalias 'frame-update-face-colors 'frame-set-background-mode)
1561 (make-obsolete 'frame-update-face-colors 'frame-set-background-mode "21.1")
1562
1563 \f
1564 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1565 ;;; Standard faces.
1566 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1567
1568 (defgroup basic-faces nil
1569   "The standard faces of Emacs."
1570   :group 'faces)
1571
1572
1573 (defface default
1574   '((t nil))
1575   "Basic default face."
1576   :group 'basic-faces)
1577
1578
1579 (defface mode-line
1580   '((((type x w32 mac) (class color))
1581      (:box (:line-width 2 :style released-button)
1582            :background "grey75" :foreground "black"))
1583     (t
1584      (:inverse-video t)))
1585   "Basic mode line face."
1586   :version "21.1"
1587   :group 'modeline
1588   :group 'basic-faces)
1589
1590 ;; Make `modeline' an alias for `mode-line', for compatibility.
1591 (put 'modeline 'face-alias 'mode-line)
1592
1593 (defface header-line
1594   '((((type tty))
1595      ;; This used to be `:inverse-video t', but that doesn't look very
1596      ;; good when combined with inverse-video mode-lines and multiple
1597      ;; windows.  Underlining looks better, and is more consistent with
1598      ;; the window-system face variants, which deemphasize the
1599      ;; header-line in relation to the mode-line face.  If a terminal
1600      ;; can't underline, then the header-line will end up without any
1601      ;; highlighting; this may be too confusing in general, although it
1602      ;; happens to look good with the only current use of header-lines,
1603      ;; the info browser. XXX
1604      :underline t)
1605     (((class color grayscale) (background light))
1606      :inherit mode-line
1607      :background "grey90" :foreground "grey20"
1608      :box nil)
1609     (((class color grayscale) (background dark))
1610      :inherit mode-line
1611      :background "grey20" :foreground "grey90"
1612      :box nil)
1613     (((class mono) (background light))
1614      :inherit mode-line
1615      :background "white" :foreground "black"
1616      :inverse-video nil
1617      :box nil
1618      :underline t)
1619     (((class mono) (background dark))
1620      :inherit mode-line
1621      :background "black" :foreground "white"
1622      :inverse-video nil
1623      :box nil
1624      :underline t)
1625     (t
1626      :inverse-video t))
1627   "Basic header-line face."
1628   :version "21.1"
1629   :group 'basic-faces)
1630
1631
1632 (defface tool-bar
1633   '((((type x w32 mac) (class color))
1634      (:box (:line-width 1 :style released-button)
1635            :background "grey75" :foreground "black"))
1636     (((type x) (class mono))
1637      (:box (:line-width 1 :style released-button)
1638            :background "grey" :foreground "black"))
1639     (t
1640      ()))
1641   "Basic tool-bar face."
1642   :version "21.1"
1643   :group 'basic-faces)
1644
1645
1646 (defface region
1647   '((((type tty) (class color))
1648      (:background "blue" :foreground "white"))
1649     (((type tty) (class mono))
1650      (:inverse-video t))
1651     (((class color) (background dark))
1652      (:background "blue3"))
1653     (((class color) (background light))
1654      (:background "light goldenrod yellow"))
1655     (t (:background "gray")))
1656   "Basic face for highlighting the region."
1657   :version "21.1"
1658   :group 'basic-faces)
1659
1660
1661 (defface fringe
1662   '((((class color) (background light))
1663        (:background "grey95"))
1664       (((class color) (background dark))
1665        (:background "grey10"))
1666       (t
1667        (:background "gray")))
1668   "Basic face for the fringes to the left and right of windows under X."
1669   :version "21.1"
1670   :group 'frames
1671   :group 'basic-faces)
1672
1673
1674 (defface scroll-bar '()
1675   "Basic face for the scroll bar colors under X."
1676   :version "21.1"
1677   :group 'frames
1678   :group 'basic-faces)
1679
1680
1681 (defface menu
1682   '((((type x-toolkit)) ())
1683     (t (:inverse-video t)))
1684   "Basic menu face."
1685   :version "21.1"
1686   :group 'menu
1687   :group 'basic-faces)
1688
1689
1690 (defface border '()
1691   "Basic face for the frame border under X."
1692   :version "21.1"
1693   :group 'frames
1694   :group 'basic-faces)
1695
1696
1697 (defface cursor '()
1698   "Basic face for the cursor color under X."
1699   :version "21.1"
1700   :group 'cursor
1701   :group 'basic-faces)
1702
1703
1704 (defface mouse '()
1705   "Basic face for the mouse color under X."
1706   :version "21.1"
1707   :group 'mouse
1708   :group 'basic-faces)
1709
1710
1711 (defface bold '((t (:weight bold)))
1712   "Basic bold face."
1713   :group 'basic-faces)
1714
1715
1716 (defface italic '((t (:slant italic)))
1717   "Basic italic font."
1718   :group 'basic-faces)
1719
1720
1721 (defface bold-italic '((t (:weight bold :slant italic)))
1722   "Basic bold-italic face."
1723   :group 'basic-faces)
1724
1725
1726 (defface underline '((t (:underline t)))
1727   "Basic underlined face."
1728   :group 'basic-faces)
1729
1730
1731 (defface highlight
1732   '((((type tty) (class color))
1733      (:background "green"))
1734     (((class color) (background light))
1735      (:background "darkseagreen2"))
1736     (((class color) (background dark))
1737      (:background "darkolivegreen"))
1738     (t (:inverse-video t)))
1739   "Basic face for highlighting."
1740   :group 'basic-faces)
1741
1742
1743 (defface secondary-selection
1744   '((((type tty) (class color))
1745      (:background "cyan" :foreground "black"))
1746     (((class color) (background light))
1747      (:background "yellow"))
1748     (((class color) (background dark))
1749      (:background "SkyBlue4"))
1750     (t (:inverse-video t)))
1751   "Basic face for displaying the secondary selection."
1752   :group 'basic-faces)
1753
1754
1755 (defface fixed-pitch '((t (:family "courier")))
1756   "The basic fixed-pitch face."
1757   :group 'basic-faces)
1758
1759
1760 (defface variable-pitch '((t (:family "helv")))
1761   "The basic variable-pitch face."
1762   :group 'basic-faces)
1763
1764
1765 (defface trailing-whitespace
1766   '((((class color) (background light))
1767      (:background "red"))
1768     (((class color) (background dark))
1769      (:background "red"))
1770     (t (:inverse-video t)))
1771   "Basic face for highlighting trailing whitespace."
1772   :version "21.1"
1773   :group 'font-lock                     ; like `show-trailing-whitespace'
1774   :group 'basic-faces)
1775
1776
1777 \f
1778 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1779 ;;; Manipulating font names.
1780 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1781
1782 ;; This is here for compatibilty with Emacs 20.2.  For example,
1783 ;; international/fontset.el uses x-resolve-font-name.  The following
1784 ;; functions are not used in the face implementation itself.
1785
1786 (defvar x-font-regexp nil)
1787 (defvar x-font-regexp-head nil)
1788 (defvar x-font-regexp-weight nil)
1789 (defvar x-font-regexp-slant nil)
1790
1791 (defconst x-font-regexp-weight-subnum 1)
1792 (defconst x-font-regexp-slant-subnum 2)
1793 (defconst x-font-regexp-swidth-subnum 3)
1794 (defconst x-font-regexp-adstyle-subnum 4)
1795
1796 ;;; Regexps matching font names in "Host Portable Character Representation."
1797 ;;;
1798 (let ((-                "[-?]")
1799       (foundry          "[^-]+")
1800       (family           "[^-]+")
1801       (weight           "\\(bold\\|demibold\\|medium\\)")               ; 1
1802 ;     (weight\?         "\\(\\*\\|bold\\|demibold\\|medium\\|\\)")      ; 1
1803       (weight\?         "\\([^-]*\\)")                                  ; 1
1804       (slant            "\\([ior]\\)")                                  ; 2
1805 ;     (slant\?          "\\([ior?*]?\\)")                               ; 2
1806       (slant\?          "\\([^-]?\\)")                                  ; 2
1807 ;     (swidth           "\\(\\*\\|normal\\|semicondensed\\|\\)")        ; 3
1808       (swidth           "\\([^-]*\\)")                                  ; 3
1809 ;     (adstyle          "\\(\\*\\|sans\\|\\)")                          ; 4
1810       (adstyle          "\\([^-]*\\)")                                  ; 4
1811       (pixelsize        "[0-9]+")
1812       (pointsize        "[0-9][0-9]+")
1813       (resx             "[0-9][0-9]+")
1814       (resy             "[0-9][0-9]+")
1815       (spacing          "[cmp?*]")
1816       (avgwidth         "[0-9]+")
1817       (registry         "[^-]+")
1818       (encoding         "[^-]+")
1819       )
1820   (setq x-font-regexp
1821         (concat "\\`\\*?[-?*]"
1822                 foundry - family - weight\? - slant\? - swidth - adstyle -
1823                 pixelsize - pointsize - resx - resy - spacing - avgwidth -
1824                 registry - encoding "\\*?\\'"
1825                 ))
1826   (setq x-font-regexp-head
1827         (concat "\\`[-?*]" foundry - family - weight\? - slant\?
1828                 "\\([-*?]\\|\\'\\)"))
1829   (setq x-font-regexp-slant (concat - slant -))
1830   (setq x-font-regexp-weight (concat - weight -))
1831   nil)
1832
1833
1834 (defun x-resolve-font-name (pattern &optional face frame)
1835   "Return a font name matching PATTERN.
1836 All wildcards in PATTERN are instantiated.
1837 If PATTERN is nil, return the name of the frame's base font, which never
1838 contains wildcards.
1839 Given optional arguments FACE and FRAME, return a font which is
1840 also the same size as FACE on FRAME, or fail."
1841   (or (symbolp face)
1842       (setq face (face-name face)))
1843   (and (eq frame t)
1844        (setq frame nil))
1845   (if pattern
1846       ;; Note that x-list-fonts has code to handle a face with nil as its font.
1847       (let ((fonts (x-list-fonts pattern face frame 1)))
1848         (or fonts
1849             (if face
1850                 (if (string-match "\\*" pattern)
1851                     (if (null (face-font face))
1852                         (error "No matching fonts are the same height as the frame default font")
1853                       (error "No matching fonts are the same height as face `%s'" face))
1854                   (if (null (face-font face))
1855                       (error "Height of font `%s' doesn't match the frame default font"
1856                              pattern)
1857                     (error "Height of font `%s' doesn't match face `%s'"
1858                            pattern face)))
1859               (error "No fonts match `%s'" pattern)))
1860         (car fonts))
1861     (cdr (assq 'font (frame-parameters (selected-frame))))))
1862
1863
1864 (defun x-frob-font-weight (font which)
1865   (let ((case-fold-search t))
1866     (cond ((string-match x-font-regexp font)
1867            (concat (substring font 0
1868                               (match-beginning x-font-regexp-weight-subnum))
1869                    which
1870                    (substring font (match-end x-font-regexp-weight-subnum)
1871                               (match-beginning x-font-regexp-adstyle-subnum))
1872                    ;; Replace the ADD_STYLE_NAME field with *
1873                    ;; because the info in it may not be the same
1874                    ;; for related fonts.
1875                    "*"
1876                    (substring font (match-end x-font-regexp-adstyle-subnum))))
1877           ((string-match x-font-regexp-head font)
1878            (concat (substring font 0 (match-beginning 1)) which
1879                    (substring font (match-end 1))))
1880           ((string-match x-font-regexp-weight font)
1881            (concat (substring font 0 (match-beginning 1)) which
1882                    (substring font (match-end 1)))))))
1883 (make-obsolete 'x-frob-font-weight 'make-face-... "21.1")
1884
1885 (defun x-frob-font-slant (font which)
1886   (let ((case-fold-search t))
1887     (cond ((string-match x-font-regexp font)
1888            (concat (substring font 0
1889                               (match-beginning x-font-regexp-slant-subnum))
1890                    which
1891                    (substring font (match-end x-font-regexp-slant-subnum)
1892                               (match-beginning x-font-regexp-adstyle-subnum))
1893                    ;; Replace the ADD_STYLE_NAME field with *
1894                    ;; because the info in it may not be the same
1895                    ;; for related fonts.
1896                    "*"
1897                    (substring font (match-end x-font-regexp-adstyle-subnum))))
1898           ((string-match x-font-regexp-head font)
1899            (concat (substring font 0 (match-beginning 2)) which
1900                    (substring font (match-end 2))))
1901           ((string-match x-font-regexp-slant font)
1902            (concat (substring font 0 (match-beginning 1)) which
1903                    (substring font (match-end 1)))))))
1904 (make-obsolete 'x-frob-font-slant 'make-face-... "21.1")
1905
1906 (defun x-make-font-bold (font)
1907   "Given an X font specification, make a bold version of it.
1908 If that can't be done, return nil."
1909   (x-frob-font-weight font "bold"))
1910 (make-obsolete 'x-make-font-bold 'make-face-bold "21.1")
1911
1912 (defun x-make-font-demibold (font)
1913   "Given an X font specification, make a demibold version of it.
1914 If that can't be done, return nil."
1915   (x-frob-font-weight font "demibold"))
1916 (make-obsolete 'x-make-font-demibold 'make-face-bold "21.1")
1917
1918 (defun x-make-font-unbold (font)
1919   "Given an X font specification, make a non-bold version of it.
1920 If that can't be done, return nil."
1921   (x-frob-font-weight font "medium"))
1922 (make-obsolete 'x-make-font-unbold 'make-face-unbold "21.1")
1923
1924 (defun x-make-font-italic (font)
1925   "Given an X font specification, make an italic version of it.
1926 If that can't be done, return nil."
1927   (x-frob-font-slant font "i"))
1928 (make-obsolete 'x-make-font-italic 'make-face-italic "21.1")
1929
1930 (defun x-make-font-oblique (font) ; you say tomayto...
1931   "Given an X font specification, make an oblique version of it.
1932 If that can't be done, return nil."
1933   (x-frob-font-slant font "o"))
1934 (make-obsolete 'x-make-font-oblique 'make-face-italic "21.1")
1935
1936 (defun x-make-font-unitalic (font)
1937   "Given an X font specification, make a non-italic version of it.
1938 If that can't be done, return nil."
1939   (x-frob-font-slant font "r"))
1940 (make-obsolete 'x-make-font-unitalic 'make-face-unitalic "21.1")
1941
1942 (defun x-make-font-bold-italic (font)
1943   "Given an X font specification, make a bold and italic version of it.
1944 If that can't be done, return nil."
1945   (and (setq font (x-make-font-bold font))
1946        (x-make-font-italic font)))
1947 (make-obsolete 'x-make-font-bold-italic 'make-face-bold-italic "21.1")
1948
1949 (provide 'faces)
1950
1951 ;;; faces.el ends here