code.delx.au - gnu-emacs/blob - lisp/vc/vc-svn.el

   1 ;;; vc-svn.el --- non-resident support for Subversion version-control  -*- lexical-binding:t -*-
   2
   3 ;; Copyright (C) 2003-2013 Free Software Foundation, Inc.
   4
   5 ;; Author:      FSF (see vc.el for full credits)
   6 ;; Maintainer:  Stefan Monnier <monnier@gnu.org>
   7 ;; Package: vc
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; Sync'd with Subversion's vc-svn.el as of revision 5801. but this version
  27 ;; has been extensively modified since to handle filesets.
  28
  29 ;;; Code:
  30
  31 (eval-when-compile
  32   (require 'vc))
  33
  34 ;; Clear up the cache to force vc-call to check again and discover
  35 ;; new functions when we reload this file.
  36 (put 'SVN 'vc-functions nil)
  37
  38 ;;;
  39 ;;; Customization options
  40 ;;;
  41
  42 (defgroup vc-svn nil
  43   "VC Subversion (svn) backend."
  44   :version "24.1"
  45   :group 'vc)
  46
  47 ;; FIXME there is also svnadmin.
  48 (defcustom vc-svn-program "svn"
  49   "Name of the SVN executable."
  50   :type 'string
  51   :group 'vc-svn)
  52
  53 ;; Might be nice if svn defaulted to non-interactive if stdin not tty.
  54 ;; http://svn.haxx.se/dev/archive-2008-05/0762.shtml
  55 ;; http://svn.haxx.se/dev/archive-2009-04/0094.shtml
  56 ;; Maybe newer ones do?
  57 (defcustom vc-svn-global-switches (unless (eq system-type 'darwin) ; bug#13513
  58                                     '("--non-interactive"))
  59   "Global switches to pass to any SVN command.
  60 The option \"--non-interactive\" is often needed to prevent SVN
  61 hanging while prompting for authorization."
  62   :type '(choice (const :tag "None" nil)
  63                  (string :tag "Argument String")
  64                  (repeat :tag "Argument List"
  65                          :value ("")
  66                          string))
  67   :version "24.4"
  68   :group 'vc-svn)
  69
  70 (defcustom vc-svn-register-switches nil
  71   "Switches for registering a file into SVN.
  72 A string or list of strings passed to the checkin program by
  73 \\[vc-register].  If nil, use the value of `vc-register-switches'.
  74 If t, use no switches."
  75   :type '(choice (const :tag "Unspecified" nil)
  76                  (const :tag "None" t)
  77                  (string :tag "Argument String")
  78                  (repeat :tag "Argument List" :value ("") string))
  79   :version "22.1"
  80   :group 'vc-svn)
  81
  82 (defcustom vc-svn-diff-switches
  83   t                        ;`svn' doesn't support common args like -c or -b.
  84   "String or list of strings specifying extra switches for svn diff under VC.
  85 If nil, use the value of `vc-diff-switches' (or `diff-switches'),
  86 together with \"-x --diff-cmd=\"`diff-command' (since 'svn diff'
  87 does not support the default \"-c\" value of `diff-switches').
  88 If you want to force an empty list of arguments, use t."
  89   :type '(choice (const :tag "Unspecified" nil)
  90                  (const :tag "None" t)
  91                  (string :tag "Argument String")
  92                  (repeat :tag "Argument List"
  93                          :value ("")
  94                          string))
  95   :version "22.1"
  96   :group 'vc-svn)
  97
  98 (defcustom vc-svn-header '("\$Id\$")
  99   "Header keywords to be inserted by `vc-insert-headers'."
 100   :version "24.1"     ; no longer consult the obsolete vc-header-alist
 101   :type '(repeat string)
 102   :group 'vc-svn)
 103
 104 ;; We want to autoload it for use by the autoloaded version of
 105 ;; vc-svn-registered, but we want the value to be compiled at startup, not
 106 ;; at dump time.
 107 ;; ;;;###autoload
 108 (defconst vc-svn-admin-directory
 109   (cond ((and (memq system-type '(cygwin windows-nt ms-dos))
 110               (getenv "SVN_ASP_DOT_NET_HACK"))
 111          "_svn")
 112         (t ".svn"))
 113   "The name of the \".svn\" subdirectory or its equivalent.")
 114
 115 ;;; Properties of the backend
 116
 117 (defun vc-svn-revision-granularity () 'repository)
 118 (defun vc-svn-checkout-model (_files) 'implicit)
 119
 120 ;;;
 121 ;;; State-querying functions
 122 ;;;
 123
 124 ;;; vc-svn-admin-directory is generally not defined when the
 125 ;;; autoloaded function is called.
 126
 127 ;;;###autoload (defun vc-svn-registered (f)
 128 ;;;###autoload   (let ((admin-dir (cond ((and (eq system-type 'windows-nt)
 129 ;;;###autoload                                (getenv "SVN_ASP_DOT_NET_HACK"))
 130 ;;;###autoload                           "_svn")
 131 ;;;###autoload                          (t ".svn"))))
 132 ;;;###autoload     (when (vc-find-root f admin-dir)
 133 ;;;###autoload       (load "vc-svn" nil t)
 134 ;;;###autoload       (vc-svn-registered f))))
 135
 136 (defun vc-svn-registered (file)
 137   "Check if FILE is SVN registered."
 138   (when (vc-svn-root file)
 139     (with-temp-buffer
 140       (cd (file-name-directory file))
 141       (let* (process-file-side-effects
 142              (status
 143              (condition-case nil
 144                  ;; Ignore all errors.
 145                  (vc-svn-command t t file "status" "-v")
 146                ;; Some problem happened.  E.g. We can't find an `svn'
 147                ;; executable.  We used to only catch `file-error' but when
 148                ;; the process is run on a remote host via Tramp, the error
 149                ;; is only reported via the exit status which is turned into
 150                ;; an `error' by vc-do-command.
 151                (error nil))))
 152         (when (eq 0 status)
 153           (let ((parsed (vc-svn-parse-status file)))
 154             (and parsed (not (memq parsed '(ignored unregistered))))))))))
 155
 156 (defun vc-svn-state (file &optional localp)
 157   "SVN-specific version of `vc-state'."
 158   (let (process-file-side-effects)
 159     (setq localp (or localp (vc-stay-local-p file 'SVN)))
 160     (with-temp-buffer
 161       (cd (file-name-directory file))
 162       (vc-svn-command t 0 file "status" (if localp "-v" "-u"))
 163       (vc-svn-parse-status file))))
 164
 165 ;; NB this does not handle svn properties, which can be changed
 166 ;; without changing the file timestamp.
 167 ;; Note that unlike vc-cvs-state-heuristic, this is not called from
 168 ;; vc-svn-state.  AFAICS, it is only called from vc-state-refresh via
 169 ;; vc-after-save (bug#7850).  Therefore the fact that it ignores
 170 ;; properties is irrelevant.  If you want to make vc-svn-state call
 171 ;; this, it should be extended to handle svn properties.
 172 (defun vc-svn-state-heuristic (file)
 173   "SVN-specific state heuristic."
 174   ;; If the file has not changed since checkout, consider it `up-to-date'.
 175   ;; Otherwise consider it `edited'.  Copied from vc-cvs-state-heuristic.
 176   (let ((checkout-time (vc-file-getprop file 'vc-checkout-time))
 177         (lastmod (nth 5 (file-attributes file))))
 178     (cond
 179      ((equal checkout-time lastmod) 'up-to-date)
 180      ((string= (vc-working-revision file) "0") 'added)
 181      ((null checkout-time) 'unregistered)
 182      (t 'edited))))
 183
 184 ;; FIXME it would be better not to have the "remote" argument,
 185 ;; but to distinguish the two output formats based on content.
 186 (defun vc-svn-after-dir-status (callback &optional remote)
 187   (let ((state-map '((?A . added)
 188                      (?C . conflict)
 189                      (?I . ignored)
 190                      (?M . edited)
 191                      (?D . removed)
 192                      (?R . removed)
 193                      (?? . unregistered)
 194                      ;; This is what vc-svn-parse-status does.
 195                      (?~ . edited)))
 196         (re (if remote "^\\(.\\)\\(.\\).....? \\([ *]\\) +\\(?:[-0-9]+\\)?   \\(.*\\)$"
 197               ;; Subexp 3 is a dummy in this case, so the numbers match.
 198               "^\\(.\\)\\(.\\)...\\(.\\) \\(.*\\)$"))
 199        result)
 200     (goto-char (point-min))
 201     (while (re-search-forward re nil t)
 202       (let ((state (cdr (assq (aref (match-string 1) 0) state-map)))
 203             (propstat (cdr (assq (aref (match-string 2) 0) state-map)))
 204             (filename (if (memq system-type '(windows-nt ms-dos))
 205                           (replace-regexp-in-string "\\\\" "/" (match-string 4))
 206                         (match-string 4))))
 207         (and (memq propstat '(conflict edited))
 208              (not (eq state 'conflict)) ; conflict always wins
 209              (setq state propstat))
 210         (and remote (string-equal (match-string 3) "*")
 211              ;; FIXME are there other possible combinations?
 212              (cond ((eq state 'edited) (setq state 'needs-merge))
 213                    ((not state) (setq state 'needs-update))))
 214         (when (and state (not (string= "." filename)))
 215          (setq result (cons (list filename state) result)))))
 216     (funcall callback result)))
 217
 218 ;; -dir-status called from vc-dir, which loads vc, which loads vc-dispatcher.
 219 (declare-function vc-exec-after "vc-dispatcher" (code))
 220
 221 (defun vc-svn-dir-status (dir callback)
 222   "Run 'svn status' for DIR and update BUFFER via CALLBACK.
 223 CALLBACK is called as (CALLBACK RESULT BUFFER), where
 224 RESULT is a list of conses (FILE . STATE) for directory DIR."
 225   ;; FIXME should this rather be all the files in dir?
 226   ;; FIXME: the vc-stay-local-p logic below is disabled, it ends up
 227   ;; calling synchronously (vc-svn-registered DIR) => calling svn status -v DIR
 228   ;; which is VERY SLOW for big trees and it makes emacs
 229   ;; completely unresponsive during that time.
 230   (let* ((local (and nil (vc-stay-local-p dir 'SVN)))
 231          (remote (or t (not local) (eq local 'only-file))))
 232     (vc-svn-command (current-buffer) 'async nil "status"
 233                     (if remote "-u"))
 234   (vc-run-delayed
 235    (vc-svn-after-dir-status callback remote))))
 236
 237 (defun vc-svn-dir-status-files (_dir files _default-state callback)
 238   (apply 'vc-svn-command (current-buffer) 'async nil "status" files)
 239   (vc-run-delayed
 240    (vc-svn-after-dir-status callback)))
 241
 242 (defun vc-svn-dir-extra-headers (_dir)
 243   "Generate extra status headers for a Subversion working copy."
 244   (let (process-file-side-effects)
 245     (vc-svn-command "*vc*" 0 nil "info"))
 246   (let ((repo
 247          (save-excursion
 248            (and (progn
 249                   (set-buffer "*vc*")
 250                   (goto-char (point-min))
 251                   (re-search-forward "Repository Root: *\\(.*\\)" nil t))
 252                 (match-string 1)))))
 253     (concat
 254      (cond (repo
 255             (concat
 256              (propertize "Repository : " 'face 'font-lock-type-face)
 257              (propertize repo 'face 'font-lock-variable-name-face)))
 258            (t "")))))
 259
 260 (defun vc-svn-working-revision (file)
 261   "SVN-specific version of `vc-working-revision'."
 262   ;; There is no need to consult RCS headers under SVN, because we
 263   ;; get the workfile version for free when we recognize that a file
 264   ;; is registered in SVN.
 265   (vc-svn-registered file)
 266   (vc-file-getprop file 'vc-working-revision))
 267
 268 ;; vc-svn-mode-line-string doesn't exist because the default implementation
 269 ;; works just fine.
 270
 271 (defun vc-svn-previous-revision (_file rev)
 272   (let ((newrev (1- (string-to-number rev))))
 273     (when (< 0 newrev)
 274       (number-to-string newrev))))
 275
 276 (defun vc-svn-next-revision (file rev)
 277   (let ((newrev (1+ (string-to-number rev))))
 278     ;; The "working revision" is an uneasy conceptual fit under Subversion;
 279     ;; we use it as the upper bound until a better idea comes along.  If the
 280     ;; workfile version W coincides with the tree's latest revision R, then
 281     ;; this check prevents a "no such revision: R+1" error.  Otherwise, it
 282     ;; inhibits showing of W+1 through R, which could be considered anywhere
 283     ;; from gracious to impolite.
 284     (unless (< (string-to-number (vc-file-getprop file 'vc-working-revision))
 285                newrev)
 286       (number-to-string newrev))))
 287
 288
 289 ;;;
 290 ;;; State-changing functions
 291 ;;;
 292
 293 (defun vc-svn-create-repo ()
 294   "Create a new SVN repository."
 295   (vc-do-command "*vc*" 0 "svnadmin" '("create" "SVN"))
 296   (vc-svn-command "*vc*" 0 "." "checkout"
 297                   (concat "file://" default-directory "SVN")))
 298
 299 (autoload 'vc-switches "vc")
 300
 301 (defun vc-svn-register (files &optional _rev _comment)
 302   "Register FILES into the SVN version-control system.
 303 The COMMENT argument is ignored  This does an add but not a commit.
 304 Passes either `vc-svn-register-switches' or `vc-register-switches'
 305 to the SVN command."
 306   (apply 'vc-svn-command nil 0 files "add" (vc-switches 'SVN 'register)))
 307
 308 (defun vc-svn-root (file)
 309   (vc-find-root file vc-svn-admin-directory))
 310
 311 (defalias 'vc-svn-responsible-p 'vc-svn-root)
 312
 313 (defalias 'vc-svn-could-register 'vc-svn-root
 314   "Return non-nil if FILE could be registered in SVN.
 315 This is only possible if SVN is responsible for FILE's directory.")
 316
 317 (defun vc-svn-checkin (files rev comment &optional _extra-args-ignored)
 318   "SVN-specific version of `vc-backend-checkin'."
 319   (if rev (error "Committing to a specific revision is unsupported in SVN"))
 320   (let ((status (apply
 321                  'vc-svn-command nil 1 files "ci"
 322                  (nconc (list "-m" comment) (vc-switches 'SVN 'checkin)))))
 323     (set-buffer "*vc*")
 324     (goto-char (point-min))
 325     (unless (equal status 0)
 326       ;; Check checkin problem.
 327       (cond
 328        ((search-forward "Transaction is out of date" nil t)
 329         (mapc (lambda (file) (vc-file-setprop file 'vc-state 'needs-merge))
 330               files)
 331         (error (substitute-command-keys
 332                 (concat "Up-to-date check failed: "
 333                         "type \\[vc-next-action] to merge in changes"))))
 334        (t
 335         (pop-to-buffer (current-buffer))
 336         (goto-char (point-min))
 337         (shrink-window-if-larger-than-buffer)
 338         (error "Check-in failed"))))
 339     ;; Update file properties
 340     ;; (vc-file-setprop
 341     ;;  file 'vc-working-revision
 342     ;;  (vc-parse-buffer "^\\(new\\|initial\\) revision: \\([0-9.]+\\)" 2))
 343     ))
 344
 345 (defun vc-svn-find-revision (file rev buffer)
 346   "SVN-specific retrieval of a specified version into a buffer."
 347   (let (process-file-side-effects)
 348     (apply 'vc-svn-command
 349            buffer 0 file
 350            "cat"
 351            (and rev (not (string= rev ""))
 352                 (concat "-r" rev))
 353            (vc-switches 'SVN 'checkout))))
 354
 355 (defun vc-svn-ignore (file &optional _directory _remove)
 356   "Ignore FILE under Subversion.
 357 FILE is a file wildcard, relative to the root directory of DIRECTORY."
 358   (vc-svn-command t 0 file "propedit" "svn:ignore"))
 359
 360 (defun vc-svn-ignore-completion-table (_file)
 361   "Return the list of ignored files."
 362   )
 363
 364 (defun vc-svn-checkout (file &optional editable rev)
 365   (message "Checking out %s..." file)
 366   (with-current-buffer (or (get-file-buffer file) (current-buffer))
 367     (vc-svn-update file editable rev (vc-switches 'SVN 'checkout)))
 368   (vc-mode-line file 'SVN)
 369   (message "Checking out %s...done" file))
 370
 371 (defun vc-svn-update (file _editable rev switches)
 372   (if (and (file-exists-p file) (not rev))
 373       ;; If no revision was specified, there's nothing to do.
 374       nil
 375     ;; Check out a particular version (or recreate the file).
 376     (vc-file-setprop file 'vc-working-revision nil)
 377     (apply 'vc-svn-command nil 0 file
 378            "update"
 379            (cond
 380             ((null rev) "-rBASE")
 381             ((or (eq rev t) (equal rev "")) nil)
 382             (t (concat "-r" rev)))
 383            switches)))
 384
 385 (defun vc-svn-delete-file (file)
 386   (vc-svn-command nil 0 file "remove"))
 387
 388 (defun vc-svn-rename-file (old new)
 389   (vc-svn-command nil 0 new "move" (file-relative-name old)))
 390
 391 (defun vc-svn-revert (file &optional contents-done)
 392   "Revert FILE to the version it was based on."
 393   (unless contents-done
 394     (vc-svn-command nil 0 file "revert")))
 395
 396 (defun vc-svn-merge (file first-version &optional second-version)
 397   "Merge changes into current working copy of FILE.
 398 The changes are between FIRST-VERSION and SECOND-VERSION."
 399   (vc-svn-command nil 0 file
 400                  "merge"
 401                  "-r" (if second-version
 402                         (concat first-version ":" second-version)
 403                       first-version))
 404   (vc-file-setprop file 'vc-state 'edited)
 405   (with-current-buffer (get-buffer "*vc*")
 406     (goto-char (point-min))
 407     (if (looking-at "C  ")
 408         1                               ; signal conflict
 409       0)))                              ; signal success
 410
 411 (defun vc-svn-merge-news (file)
 412   "Merge in any new changes made to FILE."
 413   (message "Merging changes into %s..." file)
 414   ;; (vc-file-setprop file 'vc-working-revision nil)
 415   (vc-file-setprop file 'vc-checkout-time 0)
 416   (vc-svn-command nil 0 file "update")
 417   ;; Analyze the merge result reported by SVN, and set
 418   ;; file properties accordingly.
 419   (with-current-buffer (get-buffer "*vc*")
 420     (goto-char (point-min))
 421     ;; get new working revision
 422     (if (re-search-forward
 423          "^\\(Updated to\\|At\\) revision \\([0-9]+\\)" nil t)
 424         (vc-file-setprop file 'vc-working-revision (match-string 2))
 425       (vc-file-setprop file 'vc-working-revision nil))
 426     ;; get file status
 427     (goto-char (point-min))
 428     (prog1
 429         (if (looking-at "At revision")
 430             0 ;; there were no news; indicate success
 431           (if (re-search-forward
 432                ;; Newer SVN clients have 3 columns of chars (one for the
 433                ;; file's contents, then second for its properties, and the
 434                ;; third for lock-grabbing info), before the 2 spaces.
 435                ;; We also used to match the filename in column 0 without any
 436                ;; meta-info before it, but I believe this can never happen.
 437                (concat "^\\(\\([ACGDU]\\)\\(.[B ]\\)?  \\)"
 438                        (regexp-quote (file-relative-name file)))
 439                nil t)
 440               (cond
 441                ;; Merge successful, we are in sync with repository now
 442                ((string= (match-string 2) "U")
 443                 (vc-file-setprop file 'vc-state 'up-to-date)
 444                 (vc-file-setprop file 'vc-checkout-time
 445                                  (nth 5 (file-attributes file)))
 446                 0);; indicate success to the caller
 447                ;; Merge successful, but our own changes are still in the file
 448                ((string= (match-string 2) "G")
 449                 (vc-file-setprop file 'vc-state 'edited)
 450                 0);; indicate success to the caller
 451                ;; Conflicts detected!
 452                (t
 453                 (vc-file-setprop file 'vc-state 'edited)
 454                 1);; signal the error to the caller
 455                )
 456             (pop-to-buffer "*vc*")
 457             (error "Couldn't analyze svn update result")))
 458       (message "Merging changes into %s...done" file))))
 459
 460 (defun vc-svn-modify-change-comment (_files rev comment)
 461   "Modify the change comments for a specified REV.
 462 You must have ssh access to the repository host, and the directory Emacs
 463 uses locally for temp files must also be writable by you on that host.
 464 This is only supported if the repository access method is either file://
 465 or svn+ssh://."
 466   (let (tempfile host remotefile directory fileurl-p)
 467     (with-temp-buffer
 468       (vc-svn-command (current-buffer) 0 nil "info")
 469       (goto-char (point-min))
 470       (unless (re-search-forward "Repository Root: \\(file://\\(/.*\\)\\)\\|\\(svn\\+ssh://\\([^/]+\\)\\(/.*\\)\\)" nil t)
 471         (error "Repository information is unavailable"))
 472       (if (match-string 1)
 473           (progn
 474             (setq fileurl-p t)
 475             (setq directory (match-string 2)))
 476         (setq host (match-string 4))
 477         (setq directory (match-string 5))
 478         (setq remotefile (concat host ":" tempfile))))
 479     (with-temp-file (setq tempfile (make-temp-file user-mail-address))
 480       (insert comment))
 481     (if fileurl-p
 482         ;; Repository Root is a local file.
 483         (progn
 484           (unless (vc-do-command
 485                    "*vc*" 0 "svnadmin" nil
 486                    "setlog" "--bypass-hooks" directory
 487                    "-r" rev (format "%s" tempfile))
 488             (error "Log edit failed"))
 489           (delete-file tempfile))
 490
 491       ;; Remote repository, using svn+ssh.
 492       (unless (vc-do-command "*vc*" 0 "scp" nil "-q" tempfile remotefile)
 493         (error "Copy of comment to %s failed" remotefile))
 494       (unless (vc-do-command
 495                "*vc*" 0 "ssh" nil "-q" host
 496                (format "svnadmin setlog --bypass-hooks %s -r %s %s; rm %s"
 497                        directory rev tempfile tempfile))
 498         (error "Log edit failed")))))
 499
 500 ;;;
 501 ;;; History functions
 502 ;;;
 503
 504 (defvar log-view-per-file-logs)
 505
 506 (define-derived-mode vc-svn-log-view-mode log-view-mode "SVN-Log-View"
 507   (require 'add-log)
 508   (set (make-local-variable 'log-view-per-file-logs) nil))
 509
 510 (autoload 'vc-setup-buffer "vc-dispatcher")
 511
 512 (defun vc-svn-print-log (files buffer &optional _shortlog start-revision limit)
 513   "Print commit log associated with FILES into specified BUFFER.
 514 SHORTLOG is ignored.
 515 If START-REVISION is non-nil, it is the newest revision to show.
 516 If LIMIT is non-nil, show no more than this many entries."
 517   (save-current-buffer
 518     (vc-setup-buffer buffer)
 519     (let ((inhibit-read-only t))
 520       (goto-char (point-min))
 521       (if files
 522           (dolist (file files)
 523                   (insert "Working file: " file "\n")
 524                   (apply
 525                    'vc-svn-command
 526                    buffer
 527                    'async
 528                    ;; (if (and (= (length files) 1) (vc-stay-local-p file 'SVN)) 'async 0)
 529                    (list file)
 530                    "log"
 531                    (append
 532                     (list
 533                      (if start-revision
 534                          (format "-r%s:1" start-revision)
 535                        ;; By default Subversion only shows the log up to the
 536                        ;; working revision, whereas we also want the log of the
 537                        ;; subsequent commits.  At least that's what the
 538                        ;; vc-cvs.el code does.
 539                        "-rHEAD:0"))
 540                     (when limit (list "--limit" (format "%s" limit))))))
 541         ;; Dump log for the entire directory.
 542         (apply 'vc-svn-command buffer 0 nil "log"
 543                (append
 544                 (list
 545                  (if start-revision (format "-r%s" start-revision) "-rHEAD:0"))
 546                 (when limit (list "--limit" (format "%s" limit)))))))))
 547
 548 (defun vc-svn-diff (files &optional oldvers newvers buffer)
 549   "Get a difference report using SVN between two revisions of fileset FILES."
 550   (and oldvers
 551        (not newvers)
 552        files
 553        (catch 'no
 554          (dolist (f files)
 555            (or (equal oldvers (vc-working-revision f))
 556                (throw 'no nil)))
 557          t)
 558        ;; Use nil rather than the current revision because svn handles
 559        ;; it better (i.e. locally).  Note that if _any_ of the files
 560        ;; has a different revision, we fetch the lot, which is
 561        ;; obviously sub-optimal.
 562        (setq oldvers nil))
 563   (let* ((switches
 564             (if vc-svn-diff-switches
 565                 (vc-switches 'SVN 'diff)
 566               (list (concat "--diff-cmd=" diff-command) "-x"
 567                     (mapconcat 'identity (vc-switches nil 'diff) " "))))
 568            (async (and (not vc-disable-async-diff)
 569                        (vc-stay-local-p files 'SVN)
 570                        (or oldvers newvers)))) ; Svn diffs those locally.
 571       (apply 'vc-svn-command buffer
 572              (if async 'async 0)
 573              files "diff"
 574              (append
 575               switches
 576               (when oldvers
 577                 (list "-r" (if newvers (concat oldvers ":" newvers)
 578                              oldvers)))))
 579       (if async 1                     ; async diff => pessimistic assumption
 580         ;; For some reason `svn diff' does not return a useful
 581         ;; status w.r.t whether the diff was empty or not.
 582         (buffer-size (get-buffer buffer)))))
 583
 584 ;;;
 585 ;;; Tag system
 586 ;;;
 587
 588 (defun vc-svn-create-tag (dir name branchp)
 589   "Assign to DIR's current revision a given NAME.
 590 If BRANCHP is non-nil, the name is created as a branch (and the current
 591 workspace is immediately moved to that new branch).
 592 NAME is assumed to be a URL."
 593   (vc-svn-command nil 0 dir "copy" name)
 594   (when branchp (vc-svn-retrieve-tag dir name nil)))
 595
 596 (defun vc-svn-retrieve-tag (dir name update)
 597   "Retrieve a tag at and below DIR.
 598 NAME is the name of the tag; if it is empty, do a `svn update'.
 599 If UPDATE is non-nil, then update (resynch) any affected buffers.
 600 NAME is assumed to be a URL."
 601   (vc-svn-command nil 0 dir "switch" name)
 602   ;; FIXME: parse the output and obey `update'.
 603   )
 604
 605 ;;;
 606 ;;; Miscellaneous
 607 ;;;
 608
 609 ;; Subversion makes backups for us, so don't bother.
 610 ;; (defun vc-svn-make-version-backups-p (file)
 611 ;;   "Return non-nil if version backups should be made for FILE."
 612 ;;  (vc-stay-local-p file 'SVN))
 613
 614 (defun vc-svn-check-headers ()
 615   "Check if the current file has any headers in it."
 616   (save-excursion
 617     (goto-char (point-min))
 618     (re-search-forward "\\$[A-Za-z\300-\326\330-\366\370-\377]+\
 619 \\(: [\t -#%-\176\240-\377]*\\)?\\$" nil t)))
 620
 621
 622 ;;;
 623 ;;; Internal functions
 624 ;;;
 625
 626 (defun vc-svn-command (buffer okstatus file-or-list &rest flags)
 627   "A wrapper around `vc-do-command' for use in vc-svn.el.
 628 The difference to vc-do-command is that this function always invokes `svn',
 629 and that it passes `vc-svn-global-switches' to it before FLAGS."
 630   (apply 'vc-do-command (or buffer "*vc*") okstatus vc-svn-program file-or-list
 631          (if (stringp vc-svn-global-switches)
 632              (cons vc-svn-global-switches flags)
 633            (append vc-svn-global-switches flags))))
 634
 635 (defun vc-svn-repository-hostname (dirname)
 636   (with-temp-buffer
 637     (let (process-file-side-effects)
 638       (vc-svn-command t t dirname "info" "--xml"))
 639     (goto-char (point-min))
 640     (when (re-search-forward "<url>\\(.*\\)</url>" nil t)
 641       ;; This is not a hostname but a URL.  This may actually be considered
 642       ;; as a feature since it allows vc-svn-stay-local to specify different
 643       ;; behavior for different modules on the same server.
 644       (match-string 1))))
 645
 646 (defun vc-svn-resolve-when-done ()
 647   "Call \"svn resolved\" if the conflict markers have been removed."
 648   (save-excursion
 649     (goto-char (point-min))
 650     (unless (re-search-forward "^<<<<<<< " nil t)
 651       (vc-svn-command nil 0 buffer-file-name "resolved")
 652       ;; Remove the hook so that it is not called multiple times.
 653       (remove-hook 'after-save-hook 'vc-svn-resolve-when-done t))))
 654
 655 ;; Inspired by vc-arch-find-file-hook.
 656 (defun vc-svn-find-file-hook ()
 657   (when (eq ?C (vc-file-getprop buffer-file-name 'vc-svn-status))
 658     ;; If the file is marked as "conflicted", then we should try and call
 659     ;; "svn resolved" when applicable.
 660     (if (save-excursion
 661           (goto-char (point-min))
 662           (re-search-forward "^<<<<<<< " nil t))
 663         ;; There are conflict markers.
 664         (progn
 665           (smerge-start-session)
 666           (add-hook 'after-save-hook 'vc-svn-resolve-when-done nil t))
 667       ;; There are no conflict markers.  This is problematic: maybe it means
 668       ;; the conflict has been resolved and we should immediately call "svn
 669       ;; resolved", or it means that the file's type does not allow Svn to
 670       ;; use conflict markers in which case we don't really know what to do.
 671       ;; So let's just punt for now.
 672       nil)
 673     (message "There are unresolved conflicts in this file")))
 674
 675 (defun vc-svn-parse-status (&optional filename)
 676   "Parse output of \"svn status\" command in the current buffer.
 677 Set file properties accordingly.  If FILENAME is non-nil, return its status."
 678   (let (multifile file status propstat)
 679     (goto-char (point-min))
 680     (while (re-search-forward
 681             ;; Ignore the files with status X.
 682             "^\\(?:\\?\\|[ ACDGIMR!~][ MC][ L][ +][ S]..\\([ *]\\) +\\([-0-9]+\\) +\\([0-9?]+\\) +\\([^ ]+\\)\\) +" nil t)
 683       ;; If the username contains spaces, the output format is ambiguous,
 684       ;; so don't trust the output's filename unless we have to.
 685       (setq file (or (unless multifile filename)
 686                      (expand-file-name
 687                       (buffer-substring (point) (line-end-position))))
 688             ;; If we are parsing the result of running status on a directory,
 689             ;; there could be multiple files in the output.
 690             ;; We assume that filename, if supplied, applies to the first
 691             ;; listed file (ie, the directory).  Bug#15322.
 692             multifile t
 693             status (char-after (line-beginning-position))
 694             ;; Status of the item's properties ([ MC]).
 695             propstat (char-after (1+ (line-beginning-position))))
 696       (if (eq status ??)
 697           (vc-file-setprop file 'vc-state 'unregistered)
 698         ;; Use the last-modified revision, so that searching in vc-print-log
 699         ;; output works.
 700         (vc-file-setprop file 'vc-working-revision (match-string 3))
 701         ;; Remember Svn's own status.
 702         (vc-file-setprop file 'vc-svn-status status)
 703         (vc-file-setprop
 704          file 'vc-state
 705          (cond
 706           ((and (eq status ?\ ) (eq propstat ?\ ))
 707            (if (eq (char-after (match-beginning 1)) ?*)
 708                'needs-update
 709              (vc-file-setprop file 'vc-checkout-time
 710                               (nth 5 (file-attributes file)))
 711              'up-to-date))
 712           ((eq status ?A)
 713            ;; If the file was actually copied, (match-string 2) is "-".
 714            (vc-file-setprop file 'vc-working-revision "0")
 715            (vc-file-setprop file 'vc-checkout-time 0)
 716            'added)
 717           ;; Conflict in contents or properties.
 718           ((or (eq status ?C) (eq propstat ?C))
 719            (vc-file-setprop file 'vc-state 'conflict))
 720           ;; Modified contents or properties.
 721           ((or (eq status ?M) (eq propstat ?M))
 722            (if (eq (char-after (match-beginning 1)) ?*)
 723                'needs-merge
 724              'edited))
 725           ((eq status ?I)
 726            (vc-file-setprop file 'vc-state 'ignored))
 727           ((memq status '(?D ?R))
 728            (vc-file-setprop file 'vc-state 'removed))
 729           (t 'edited)))))
 730     (when filename (vc-file-getprop filename 'vc-state))))
 731
 732 (defun vc-svn-valid-symbolic-tag-name-p (tag)
 733   "Return non-nil if TAG is a valid symbolic tag name."
 734   ;; According to the SVN manual, a valid symbolic tag must start with
 735   ;; an uppercase or lowercase letter and can contain uppercase and
 736   ;; lowercase letters, digits, `-', and `_'.
 737   (and (string-match "^[a-zA-Z]" tag)
 738        (not (string-match "[^a-z0-9A-Z-_]" tag))))
 739
 740 (defun vc-svn-valid-revision-number-p (tag)
 741   "Return non-nil if TAG is a valid revision number."
 742   (and (string-match "^[0-9]" tag)
 743        (not (string-match "[^0-9]" tag))))
 744
 745 ;; Support for `svn annotate'
 746
 747 (defun vc-svn-annotate-command (file buf &optional rev)
 748   (vc-svn-command buf 'async file "annotate" (if rev (concat "-r" rev))))
 749
 750 (defun vc-svn-annotate-time-of-rev (rev)
 751   ;; Arbitrarily assume 10 commits per day.
 752   (/ (string-to-number rev) 10.0))
 753
 754 (defvar vc-annotate-parent-rev)
 755
 756 (defun vc-svn-annotate-current-time ()
 757   (vc-svn-annotate-time-of-rev vc-annotate-parent-rev))
 758
 759 (defconst vc-svn-annotate-re "[ \t]*\\([0-9]+\\)[ \t]+[^\t ]+ ")
 760
 761 (defun vc-svn-annotate-time ()
 762   (when (looking-at vc-svn-annotate-re)
 763     (goto-char (match-end 0))
 764     (vc-svn-annotate-time-of-rev (match-string 1))))
 765
 766 (defun vc-svn-annotate-extract-revision-at-line ()
 767   (save-excursion
 768     (beginning-of-line)
 769     (if (looking-at vc-svn-annotate-re) (match-string 1))))
 770
 771 (defun vc-svn-revision-table (files)
 772   (let ((vc-svn-revisions '()))
 773     (with-current-buffer "*vc*"
 774       (vc-svn-command nil 0 files "log" "-q")
 775       (goto-char (point-min))
 776       (forward-line)
 777       (let ((start (point-min))
 778             (loglines (buffer-substring-no-properties (point-min)
 779                                                       (point-max))))
 780         (while (string-match "^r\\([0-9]+\\) " loglines)
 781           (push (match-string 1 loglines) vc-svn-revisions)
 782           (setq start (+ start (match-end 0)))
 783           (setq loglines (buffer-substring-no-properties start (point-max)))))
 784     vc-svn-revisions)))
 785
 786 (provide 'vc-svn)
 787
 788 ;;; vc-svn.el ends here