code.delx.au - gnu-emacs/blob - lisp/progmodes/inf-lisp.el

   1 ;;; inf-lisp.el --- an inferior-lisp mode
   2
   3 ;; Copyright (C) 1988, 1993, 1994 Free Software Foundation, Inc.
   4
   5 ;; Author: Olin Shivers <shivers@cs.cmu.edu>
   6 ;; Keywords: processes, lisp
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; Hacked from tea.el by Olin Shivers (shivers@cs.cmu.edu). 8/88
  28
  29 ;; This file defines a a lisp-in-a-buffer package (inferior-lisp
  30 ;; mode) built on top of comint mode.  This version is more
  31 ;; featureful, robust, and uniform than the Emacs 18 version.  The
  32 ;; key bindings are also more compatible with the bindings of Hemlock
  33 ;; and Zwei (the Lisp Machine emacs).
  34
  35 ;; Since this mode is built on top of the general command-interpreter-in-
  36 ;; a-buffer mode (comint mode), it shares a common base functionality,
  37 ;; and a common set of bindings, with all modes derived from comint mode.
  38 ;; This makes these modes easier to use.
  39
  40 ;; For documentation on the functionality provided by comint mode, and
  41 ;; the hooks available for customising it, see the file comint.el.
  42 ;; For further information on inferior-lisp mode, see the comments below.
  43
  44 ;; Needs fixin:
  45 ;; The load-file/compile-file default mechanism could be smarter -- it
  46 ;; doesn't know about the relationship between filename extensions and
  47 ;; whether the file is source or executable. If you compile foo.lisp
  48 ;; with compile-file, then the next load-file should use foo.bin for
  49 ;; the default, not foo.lisp. This is tricky to do right, particularly
  50 ;; because the extension for executable files varies so much (.o, .bin,
  51 ;; .lbin, .mo, .vo, .ao, ...).
  52 ;;
  53 ;; It would be nice if inferior-lisp (and inferior scheme, T, ...) modes
  54 ;; had a verbose minor mode wherein sending or compiling defuns, etc.
  55 ;; would be reflected in the transcript with suitable comments, e.g.
  56 ;; ";;; redefining fact". Several ways to do this. Which is right?
  57 ;;
  58 ;; When sending text from a source file to a subprocess, the process-mark can
  59 ;; move off the window, so you can lose sight of the process interactions.
  60 ;; Maybe I should ensure the process mark is in the window when I send
  61 ;; text to the process? Switch selectable?
  62
  63 ;;; Code:
  64
  65 (require 'comint)
  66 (require 'lisp-mode)
  67
  68 \f
  69 ;;;###autoload
  70 (defvar inferior-lisp-filter-regexp "\\`\\s *\\(:\\(\\w\\|\\s_\\)\\)?\\s *\\'"
  71   "*What not to save on inferior Lisp's input history.
  72 Input matching this regexp is not saved on the input history in Inferior Lisp
  73 mode.  Default is whitespace followed by 0 or 1 single-letter colon-keyword
  74 \(as in :a, :c, etc.)")
  75
  76 (defvar inferior-lisp-mode-map nil)
  77 (cond ((not inferior-lisp-mode-map)
  78        (setq inferior-lisp-mode-map
  79              (copy-keymap comint-mode-map))
  80        (setq inferior-lisp-mode-map
  81              (nconc inferior-lisp-mode-map shared-lisp-mode-map))
  82        (define-key inferior-lisp-mode-map "\C-x\C-e" 'lisp-eval-last-sexp)
  83        (define-key inferior-lisp-mode-map "\C-c\C-l" 'lisp-load-file)
  84        (define-key inferior-lisp-mode-map "\C-c\C-k" 'lisp-compile-file)
  85        (define-key inferior-lisp-mode-map "\C-c\C-a" 'lisp-show-arglist)
  86        (define-key inferior-lisp-mode-map "\C-c\C-d" 'lisp-describe-sym)
  87        (define-key inferior-lisp-mode-map "\C-c\C-f"
  88          'lisp-show-function-documentation)
  89        (define-key inferior-lisp-mode-map "\C-c\C-v"
  90          'lisp-show-variable-documentation)))
  91
  92 ;;; These commands augment Lisp mode, so you can process Lisp code in
  93 ;;; the source files.
  94 (define-key lisp-mode-map "\M-\C-x"  'lisp-eval-defun)     ; Gnu convention
  95 (define-key lisp-mode-map "\C-x\C-e" 'lisp-eval-last-sexp) ; Gnu convention
  96 (define-key lisp-mode-map "\C-c\C-e" 'lisp-eval-defun)
  97 (define-key lisp-mode-map "\C-c\C-r" 'lisp-eval-region)
  98 (define-key lisp-mode-map "\C-c\C-c" 'lisp-compile-defun)
  99 (define-key lisp-mode-map "\C-c\C-z" 'switch-to-lisp)
 100 (define-key lisp-mode-map "\C-c\C-l" 'lisp-load-file)
 101 (define-key lisp-mode-map "\C-c\C-k" 'lisp-compile-file)  ; "kompile" file
 102 (define-key lisp-mode-map "\C-c\C-a" 'lisp-show-arglist)
 103 (define-key lisp-mode-map "\C-c\C-d" 'lisp-describe-sym)
 104 (define-key lisp-mode-map "\C-c\C-f" 'lisp-show-function-documentation)
 105 (define-key lisp-mode-map "\C-c\C-v" 'lisp-show-variable-documentation)
 106
 107
 108 ;;; This function exists for backwards compatibility.
 109 ;;; Previous versions of this package bound commands to C-c <letter>
 110 ;;; bindings, which is not allowed by the gnumacs standard.
 111
 112 ;;;  "This function binds many inferior-lisp commands to C-c <letter> bindings,
 113 ;;;where they are more accessible. C-c <letter> bindings are reserved for the
 114 ;;;user, so these bindings are non-standard. If you want them, you should
 115 ;;;have this function called by the inferior-lisp-load-hook:
 116 ;;;    (setq inferior-lisp-load-hook '(inferior-lisp-install-letter-bindings))
 117 ;;;You can modify this function to install just the bindings you want."
 118 (defun inferior-lisp-install-letter-bindings ()
 119   (define-key lisp-mode-map "\C-ce" 'lisp-eval-defun-and-go)
 120   (define-key lisp-mode-map "\C-cr" 'lisp-eval-region-and-go)
 121   (define-key lisp-mode-map "\C-cc" 'lisp-compile-defun-and-go)
 122   (define-key lisp-mode-map "\C-cz" 'switch-to-lisp)
 123   (define-key lisp-mode-map "\C-cl" 'lisp-load-file)
 124   (define-key lisp-mode-map "\C-ck" 'lisp-compile-file)
 125   (define-key lisp-mode-map "\C-ca" 'lisp-show-arglist)
 126   (define-key lisp-mode-map "\C-cd" 'lisp-describe-sym)
 127   (define-key lisp-mode-map "\C-cf" 'lisp-show-function-documentation)
 128   (define-key lisp-mode-map "\C-cv" 'lisp-show-variable-documentation)
 129
 130   (define-key inferior-lisp-mode-map "\C-cl" 'lisp-load-file)
 131   (define-key inferior-lisp-mode-map "\C-ck" 'lisp-compile-file)
 132   (define-key inferior-lisp-mode-map "\C-ca" 'lisp-show-arglist)
 133   (define-key inferior-lisp-mode-map "\C-cd" 'lisp-describe-sym)
 134   (define-key inferior-lisp-mode-map "\C-cf" 'lisp-show-function-documentation)
 135   (define-key inferior-lisp-mode-map "\C-cv"
 136     'lisp-show-variable-documentation))
 137
 138
 139 ;;;###autoload
 140 (defvar inferior-lisp-program "lisp"
 141   "*Program name for invoking an inferior Lisp with for Inferior Lisp mode.")
 142
 143 ;;;###autoload
 144 (defvar inferior-lisp-load-command "(load \"%s\")\n"
 145   "*Format-string for building a Lisp expression to load a file.
 146 This format string should use `%s' to substitute a file name
 147 and should result in a Lisp expression that will command the inferior Lisp
 148 to load that file.  The default works acceptably on most Lisps.
 149 The string \"(progn (load \\\"%s\\\" :verbose nil :print t) (values))\\n\"
 150 produces cosmetically superior output for this application,
 151 but it works only in Common Lisp.")
 152
 153 ;;;###autoload
 154 (defvar inferior-lisp-prompt "^[^> \n]*>+:? *"
 155   "Regexp to recognise prompts in the Inferior Lisp mode.
 156 Defaults to \"^[^> \\n]*>+:? *\", which works pretty good for Lucid, kcl,
 157 and franz.  This variable is used to initialize `comint-prompt-regexp' in the
 158 Inferior Lisp buffer.
 159
 160 More precise choices:
 161 Lucid Common Lisp: \"^\\\\(>\\\\|\\\\(->\\\\)+\\\\) *\"
 162 franz: \"^\\\\(->\\\\|<[0-9]*>:\\\\) *\"
 163 kcl: \"^>+ *\"
 164
 165 This is a fine thing to set in your .emacs file.")
 166
 167 (defvar inferior-lisp-buffer nil "*The current inferior-lisp process buffer.
 168
 169 MULTIPLE PROCESS SUPPORT
 170 ===========================================================================
 171 To run multiple Lisp processes, you start the first up
 172 with \\[inferior-lisp].  It will be in a buffer named `*inferior-lisp*'.
 173 Rename this buffer with \\[rename-buffer].  You may now start up a new
 174 process with another \\[inferior-lisp].  It will be in a new buffer,
 175 named `*inferior-lisp*'.  You can switch between the different process
 176 buffers with \\[switch-to-buffer].
 177
 178 Commands that send text from source buffers to Lisp processes --
 179 like `lisp-eval-defun' or `lisp-show-arglist' -- have to choose a process
 180 to send to, when you have more than one Lisp process around.  This
 181 is determined by the global variable `inferior-lisp-buffer'.  Suppose you
 182 have three inferior Lisps running:
 183     Buffer              Process
 184     foo                 inferior-lisp
 185     bar                 inferior-lisp<2>
 186     *inferior-lisp*     inferior-lisp<3>
 187 If you do a \\[lisp-eval-defun] command on some Lisp source code,
 188 what process do you send it to?
 189
 190 - If you're in a process buffer (foo, bar, or *inferior-lisp*),
 191   you send it to that process.
 192 - If you're in some other buffer (e.g., a source file), you
 193   send it to the process attached to buffer `inferior-lisp-buffer'.
 194 This process selection is performed by function `inferior-lisp-proc'.
 195
 196 Whenever \\[inferior-lisp] fires up a new process, it resets
 197 `inferior-lisp-buffer' to be the new process's buffer.  If you only run
 198 one process, this does the right thing.  If you run multiple
 199 processes, you can change `inferior-lisp-buffer' to another process
 200 buffer with \\[set-variable].")
 201
 202 ;;;###autoload
 203 (defvar inferior-lisp-mode-hook '()
 204   "*Hook for customising Inferior Lisp mode.")
 205
 206 (put 'inferior-lisp-mode 'mode-class 'special)
 207
 208 (defun inferior-lisp-mode ()
 209   "Major mode for interacting with an inferior Lisp process.
 210 Runs a Lisp interpreter as a subprocess of Emacs, with Lisp I/O through an
 211 Emacs buffer.  Variable `inferior-lisp-program' controls which Lisp interpreter
 212 is run.  Variables `inferior-lisp-prompt', `inferior-lisp-filter-regexp' and
 213 `inferior-lisp-load-command' can customize this mode for different Lisp
 214 interpreters.
 215
 216 For information on running multiple processes in multiple buffers, see
 217 documentation for variable `inferior-lisp-buffer'.
 218
 219 \\{inferior-lisp-mode-map}
 220
 221 Customisation: Entry to this mode runs the hooks on `comint-mode-hook' and
 222 `inferior-lisp-mode-hook' (in that order).
 223
 224 You can send text to the inferior Lisp process from other buffers containing
 225 Lisp source.
 226     switch-to-lisp switches the current buffer to the Lisp process buffer.
 227     lisp-eval-defun sends the current defun to the Lisp process.
 228     lisp-compile-defun compiles the current defun.
 229     lisp-eval-region sends the current region to the Lisp process.
 230     lisp-compile-region compiles the current region.
 231
 232     Prefixing the lisp-eval/compile-defun/region commands with
 233     a \\[universal-argument] causes a switch to the Lisp process buffer after sending
 234     the text.
 235
 236 Commands:
 237 Return after the end of the process' output sends the text from the
 238     end of process to point.
 239 Return before the end of the process' output copies the sexp ending at point
 240     to the end of the process' output, and sends it.
 241 Delete converts tabs to spaces as it moves back.
 242 Tab indents for Lisp; with argument, shifts rest
 243     of expression rigidly with the current line.
 244 C-M-q does Tab on each line starting within following expression.
 245 Paragraphs are separated only by blank lines.  Semicolons start comments.
 246 If you accidentally suspend your process, use \\[comint-continue-subjob]
 247 to continue it."
 248   (interactive)
 249   (comint-mode)
 250   (setq comint-prompt-regexp inferior-lisp-prompt)
 251   (setq major-mode 'inferior-lisp-mode)
 252   (setq mode-name "Inferior Lisp")
 253   (setq mode-line-process '(":%s"))
 254   (lisp-mode-variables t)
 255   (use-local-map inferior-lisp-mode-map)    ;c-c c-k for "kompile" file
 256   (setq comint-get-old-input (function lisp-get-old-input))
 257   (setq comint-input-filter (function lisp-input-filter))
 258   (setq comint-input-sentinel 'ignore)
 259   (run-hooks 'inferior-lisp-mode-hook))
 260
 261 (defun lisp-get-old-input ()
 262   "Return a string containing the sexp ending at point."
 263   (save-excursion
 264     (let ((end (point)))
 265       (backward-sexp)
 266       (buffer-substring (point) end))))
 267
 268 (defun lisp-input-filter (str)
 269   "t if STR does not match `inferior-lisp-filter-regexp'."
 270   (not (string-match inferior-lisp-filter-regexp str)))
 271
 272 ;;;###autoload
 273 (defun inferior-lisp (cmd)
 274   "Run an inferior Lisp process, input and output via buffer `*inferior-lisp*'.
 275 If there is a process already running in `*inferior-lisp*', just switch
 276 to that buffer.
 277 With argument, allows you to edit the command line (default is value
 278 of `inferior-lisp-program').  Runs the hooks from
 279 `inferior-lisp-mode-hook' (after the `comint-mode-hook' is run).
 280 \(Type \\[describe-mode] in the process buffer for a list of commands.)"
 281   (interactive (list (if current-prefix-arg
 282                          (read-string "Run lisp: " inferior-lisp-program)
 283                        inferior-lisp-program)))
 284   (if (not (comint-check-proc "*inferior-lisp*"))
 285       (let ((cmdlist (inferior-lisp-args-to-list cmd)))
 286         (set-buffer (apply (function make-comint)
 287                            "inferior-lisp" (car cmdlist) nil (cdr cmdlist)))
 288         (inferior-lisp-mode)))
 289   (setq inferior-lisp-buffer "*inferior-lisp*")
 290   (pop-to-buffer "*inferior-lisp*"))
 291 ;;;###autoload (add-hook 'same-window-buffer-names "*inferior-lisp*")
 292
 293 ;;;###autoload
 294 (defalias 'run-lisp 'inferior-lisp)
 295
 296 ;;; Break a string up into a list of arguments.
 297 ;;; This will break if you have an argument with whitespace, as in
 298 ;;; string = "-ab +c -x 'you lose'".
 299 (defun inferior-lisp-args-to-list (string)
 300   (let ((where (string-match "[ \t]" string)))
 301     (cond ((null where) (list string))
 302           ((not (= where 0))
 303            (cons (substring string 0 where)
 304                  (inferior-lisp-args-to-list (substring string (+ 1 where)
 305                                                         (length string)))))
 306           (t (let ((pos (string-match "[^ \t]" string)))
 307                (if (null pos)
 308                    nil
 309                  (inferior-lisp-args-to-list (substring string pos
 310                                                         (length string)))))))))
 311
 312 (defun lisp-eval-region (start end &optional and-go)
 313   "Send the current region to the inferior Lisp process.
 314 Prefix argument means switch to the Lisp buffer afterwards."
 315   (interactive "r\nP")
 316   (comint-send-region (inferior-lisp-proc) start end)
 317   (comint-send-string (inferior-lisp-proc) "\n")
 318   (if and-go (switch-to-lisp t)))
 319
 320 (defun lisp-eval-defun (&optional and-go)
 321   "Send the current defun to the inferior Lisp process.
 322 Prefix argument means switch to the Lisp buffer afterwards."
 323   (interactive "P")
 324   (save-excursion
 325     (end-of-defun)
 326     (skip-chars-backward " \t\n\r\f") ;  Makes allegro happy
 327     (let ((end (point)))
 328       (beginning-of-defun)
 329       (lisp-eval-region (point) end)))
 330   (if and-go (switch-to-lisp t)))
 331
 332 (defun lisp-eval-last-sexp (&optional and-go)
 333   "Send the previous sexp to the inferior Lisp process.
 334 Prefix argument means switch to the Lisp buffer afterwards."
 335   (interactive "P")
 336   (lisp-eval-region (save-excursion (backward-sexp) (point)) (point) and-go))
 337
 338 ;;; Common Lisp COMPILE sux.
 339 (defun lisp-compile-region (start end &optional and-go)
 340   "Compile the current region in the inferior Lisp process.
 341 Prefix argument means switch to the Lisp buffer afterwards."
 342   (interactive "r\nP")
 343   (comint-send-string
 344    (inferior-lisp-proc)
 345    (format "(funcall (compile nil `(lambda () (progn 'compile %s))))\n"
 346            (buffer-substring start end)))
 347   (if and-go (switch-to-lisp t)))
 348
 349 (defun lisp-compile-defun (&optional and-go)
 350   "Compile the current defun in the inferior Lisp process.
 351 Prefix argument means switch to the Lisp buffer afterwards."
 352   (interactive "P")
 353   (save-excursion
 354     (end-of-defun)
 355     (skip-chars-backward " \t\n\r\f") ;  Makes allegro happy
 356     (let ((e (point)))
 357       (beginning-of-defun)
 358       (lisp-compile-region (point) e)))
 359   (if and-go (switch-to-lisp t)))
 360
 361 (defun switch-to-lisp (eob-p)
 362   "Switch to the inferior Lisp process buffer.
 363 With argument, positions cursor at end of buffer."
 364   (interactive "P")
 365   (if (get-buffer-process inferior-lisp-buffer)
 366       (let ((pop-up-frames
 367              ;; Be willing to use another frame
 368              ;; that already has the window in it.
 369              (or pop-up-frames
 370                  (get-buffer-window inferior-lisp-buffer t))))
 371         (pop-to-buffer inferior-lisp-buffer))
 372       (run-lisp inferior-lisp-program))
 373   (when eob-p
 374          (push-mark)
 375     (goto-char (point-max))))
 376
 377
 378 ;;; Now that lisp-compile/eval-defun/region takes an optional prefix arg,
 379 ;;; these commands are redundant. But they are kept around for the user
 380 ;;; to bind if he wishes, for backwards functionality, and because it's
 381 ;;; easier to type C-c e than C-u C-c C-e.
 382
 383 (defun lisp-eval-region-and-go (start end)
 384   "Send the current region to the inferior Lisp, and switch to its buffer."
 385   (interactive "r")
 386   (lisp-eval-region start end t))
 387
 388 (defun lisp-eval-defun-and-go ()
 389   "Send the current defun to the inferior Lisp, and switch to its buffer."
 390   (interactive)
 391   (lisp-eval-defun t))
 392
 393 (defun lisp-compile-region-and-go (start end)
 394   "Compile the current region in the inferior Lisp, and switch to its buffer."
 395   (interactive "r")
 396   (lisp-compile-region start end t))
 397
 398 (defun lisp-compile-defun-and-go ()
 399   "Compile the current defun in the inferior Lisp, and switch to its buffer."
 400   (interactive)
 401   (lisp-compile-defun t))
 402
 403 ;;; A version of the form in H. Shevis' soar-mode.el package. Less robust.
 404 ;;; (defun lisp-compile-sexp (start end)
 405 ;;;   "Compile the s-expression bounded by START and END in the inferior lisp.
 406 ;;; If the sexp isn't a DEFUN form, it is evaluated instead."
 407 ;;;   (cond ((looking-at "(defun\\s +")
 408 ;;;      (goto-char (match-end 0))
 409 ;;;      (let ((name-start (point)))
 410 ;;;        (forward-sexp 1)
 411 ;;;        (process-send-string "inferior-lisp"
 412 ;;;                             (format "(compile '%s #'(lambda "
 413 ;;;                                     (buffer-substring name-start
 414 ;;;                                                       (point)))))
 415 ;;;      (let ((body-start (point)))
 416 ;;;        (goto-char start) (forward-sexp 1) ; Can't use end-of-defun.
 417 ;;;        (process-send-region "inferior-lisp"
 418 ;;;                             (buffer-substring body-start (point))))
 419 ;;;      (process-send-string "inferior-lisp" ")\n"))
 420 ;;;     (t (lisp-eval-region start end)))))
 421 ;;;
 422 ;;; (defun lisp-compile-region (start end)
 423 ;;;   "Each s-expression in the current region is compiled (if a DEFUN)
 424 ;;; or evaluated (if not) in the inferior lisp."
 425 ;;;   (interactive "r")
 426 ;;;   (save-excursion
 427 ;;;     (goto-char start) (end-of-defun) (beginning-of-defun) ; error check
 428 ;;;     (if (< (point) start) (error "region begins in middle of defun"))
 429 ;;;     (goto-char start)
 430 ;;;     (let ((s start))
 431 ;;;       (end-of-defun)
 432 ;;;       (while (<= (point) end) ; Zip through
 433 ;;;     (lisp-compile-sexp s (point)) ; compiling up defun-sized chunks.
 434 ;;;     (setq s (point))
 435 ;;;     (end-of-defun))
 436 ;;;       (if (< s end) (lisp-compile-sexp s end)))))
 437 ;;;
 438 ;;; End of HS-style code
 439
 440
 441 (defvar lisp-prev-l/c-dir/file nil
 442   "Record last directory and file used in loading or compiling.
 443 This holds a cons cell of the form `(DIRECTORY . FILE)'
 444 describing the last `lisp-load-file' or `lisp-compile-file' command.")
 445
 446 (defvar lisp-source-modes '(lisp-mode)
 447   "*Used to determine if a buffer contains Lisp source code.
 448 If it's loaded into a buffer that is in one of these major modes, it's
 449 considered a Lisp source file by `lisp-load-file' and `lisp-compile-file'.
 450 Used by these commands to determine defaults.")
 451
 452 (defun lisp-load-file (file-name)
 453   "Load a Lisp file into the inferior Lisp process."
 454   (interactive (comint-get-source "Load Lisp file: " lisp-prev-l/c-dir/file
 455                                   lisp-source-modes nil)) ; NIL because LOAD
 456                                         ; doesn't need an exact name
 457   (comint-check-source file-name) ; Check to see if buffer needs saved.
 458   (setq lisp-prev-l/c-dir/file (cons (file-name-directory    file-name)
 459                                      (file-name-nondirectory file-name)))
 460   (comint-send-string (inferior-lisp-proc)
 461                       (format inferior-lisp-load-command file-name))
 462   (switch-to-lisp t))
 463
 464
 465 (defun lisp-compile-file (file-name)
 466   "Compile a Lisp file in the inferior Lisp process."
 467   (interactive (comint-get-source "Compile Lisp file: " lisp-prev-l/c-dir/file
 468                                   lisp-source-modes nil)) ; NIL = don't need
 469                                         ; suffix .lisp
 470   (comint-check-source file-name) ; Check to see if buffer needs saved.
 471   (setq lisp-prev-l/c-dir/file (cons (file-name-directory    file-name)
 472                                      (file-name-nondirectory file-name)))
 473   (comint-send-string (inferior-lisp-proc) (concat "(compile-file \""
 474                                                    file-name
 475                                                    "\"\)\n"))
 476   (switch-to-lisp t))
 477
 478
 479 \f
 480 ;;; Documentation functions: function doc, var doc, arglist, and
 481 ;;; describe symbol.
 482 ;;; ===========================================================================
 483
 484 ;;; Command strings
 485 ;;; ===============
 486
 487 (defvar lisp-function-doc-command
 488   "(let ((fn '%s))
 489      (format t \"Documentation for ~a:~&~a\"
 490              fn (documentation fn 'function))
 491      (values))\n"
 492   "Command to query inferior Lisp for a function's documentation.")
 493
 494 (defvar lisp-var-doc-command
 495   "(let ((v '%s))
 496      (format t \"Documentation for ~a:~&~a\"
 497              v (documentation v 'variable))
 498      (values))\n"
 499   "Command to query inferior Lisp for a variable's documentation.")
 500
 501 (defvar lisp-arglist-command
 502   "(let ((fn '%s))
 503      (format t \"Arglist for ~a: ~a\" fn (arglist fn))
 504      (values))\n"
 505   "Command to query inferior Lisp for a function's arglist.")
 506
 507 (defvar lisp-describe-sym-command
 508   "(describe '%s)\n"
 509   "Command to query inferior Lisp for a variable's documentation.")
 510
 511
 512 ;;; Ancillary functions
 513 ;;; ===================
 514
 515 ;;; Reads a string from the user.
 516 (defun lisp-symprompt (prompt default)
 517   (list (let* ((prompt (if default
 518                            (format "%s (default %s): " prompt default)
 519                          (concat prompt ": ")))
 520                (ans (read-string prompt)))
 521           (if (zerop (length ans)) default ans))))
 522
 523
 524 ;;; Adapted from function-called-at-point in help.el.
 525 (defun lisp-fn-called-at-pt ()
 526   "Returns the name of the function called in the current call.
 527 The value is nil if it can't find one."
 528   (condition-case nil
 529       (save-excursion
 530         (save-restriction
 531           (narrow-to-region (max (point-min) (- (point) 1000)) (point-max))
 532           (backward-up-list 1)
 533           (forward-char 1)
 534           (let ((obj (read (current-buffer))))
 535             (and (symbolp obj) obj))))
 536     (error nil)))
 537
 538
 539 ;;; Adapted from variable-at-point in help.el.
 540 (defun lisp-var-at-pt ()
 541   (condition-case ()
 542       (save-excursion
 543         (forward-sexp -1)
 544         (skip-chars-forward "'")
 545         (let ((obj (read (current-buffer))))
 546           (and (symbolp obj) obj)))
 547     (error nil)))
 548
 549
 550 ;;; Documentation functions: fn and var doc, arglist, and symbol describe.
 551 ;;; ======================================================================
 552
 553 (defun lisp-show-function-documentation (fn)
 554   "Send a command to the inferior Lisp to give documentation for function FN.
 555 See variable `lisp-function-doc-command'."
 556   (interactive (lisp-symprompt "Function doc" (lisp-fn-called-at-pt)))
 557   (comint-proc-query (inferior-lisp-proc)
 558                      (format lisp-function-doc-command fn)))
 559
 560 (defun lisp-show-variable-documentation (var)
 561   "Send a command to the inferior Lisp to give documentation for function FN.
 562 See variable `lisp-var-doc-command'."
 563   (interactive (lisp-symprompt "Variable doc" (lisp-var-at-pt)))
 564   (comint-proc-query (inferior-lisp-proc) (format lisp-var-doc-command var)))
 565
 566 (defun lisp-show-arglist (fn)
 567   "Send a query to the inferior Lisp for the arglist for function FN.
 568 See variable `lisp-arglist-command'."
 569   (interactive (lisp-symprompt "Arglist" (lisp-fn-called-at-pt)))
 570   (comint-proc-query (inferior-lisp-proc) (format lisp-arglist-command fn)))
 571
 572 (defun lisp-describe-sym (sym)
 573   "Send a command to the inferior Lisp to describe symbol SYM.
 574 See variable `lisp-describe-sym-command'."
 575   (interactive (lisp-symprompt "Describe" (lisp-var-at-pt)))
 576   (comint-proc-query (inferior-lisp-proc)
 577                      (format lisp-describe-sym-command sym)))
 578
 579 \f
 580 ;;  "Returns the current inferior Lisp process.
 581 ;; See variable `inferior-lisp-buffer'."
 582 (defun inferior-lisp-proc ()
 583   (let ((proc (get-buffer-process (if (eq major-mode 'inferior-lisp-mode)
 584                                       (current-buffer)
 585                                     inferior-lisp-buffer))))
 586     (or proc
 587         (error "No Lisp subprocess; see variable `inferior-lisp-buffer'"))))
 588
 589
 590 ;;; Do the user's customisation...
 591 ;;;===============================
 592 (defvar inferior-lisp-load-hook nil
 593   "This hook is run when the library `inf-lisp' is loaded.
 594 This is a good place to put keybindings.")
 595
 596 (run-hooks 'inferior-lisp-load-hook)
 597
 598 ;;; CHANGE LOG
 599 ;;; ===========================================================================
 600 ;;; 7/21/92 Jim Blandy
 601 ;;; - Changed all uses of the cmulisp name or prefix to inferior-lisp;
 602 ;;;   this is now the official inferior lisp package.  Use the global
 603 ;;;   ChangeLog from now on.
 604 ;;; 5/24/90 Olin
 605 ;;; - Split cmulisp and cmushell modes into separate files.
 606 ;;;   Not only is this a good idea, it's apparently the way it'll be rel 19.
 607 ;;; - Upgraded process sends to use comint-send-string instead of
 608 ;;;   process-send-string.
 609 ;;; - Explicit references to process "cmulisp" have been replaced with
 610 ;;;   (cmulisp-proc). This allows better handling of multiple process bufs.
 611 ;;; - Added process query and var/function/symbol documentation
 612 ;;;   commands. Based on code written by Douglas Roberts.
 613 ;;; - Added lisp-eval-last-sexp, bound to C-x C-e.
 614 ;;;
 615 ;;; 9/20/90 Olin
 616 ;;; Added a save-restriction to lisp-fn-called-at-pt. This bug and fix
 617 ;;; reported by Lennart Staflin.
 618 ;;;
 619 ;;; 3/12/90 Olin
 620 ;;; - lisp-load-file and lisp-compile-file no longer switch-to-lisp.
 621 ;;;   Tale suggested this.
 622 ;;; - Reversed this decision 7/15/91. You need the visual feedback.
 623 ;;;
 624 ;;; 7/25/91 Olin
 625 ;;; Changed all keybindings of the form C-c <letter>. These are
 626 ;;; supposed to be reserved for the user to bind. This affected
 627 ;;; mainly the compile/eval-defun/region[-and-go] commands.
 628 ;;; This was painful, but necessary to adhere to the gnumacs standard.
 629 ;;; For some backwards compatibility, see the
 630 ;;;     cmulisp-install-letter-bindings
 631 ;;; function.
 632 ;;;
 633 ;;; 8/2/91 Olin
 634 ;;; - The lisp-compile/eval-defun/region commands now take a prefix arg,
 635 ;;;   which means switch-to-lisp after sending the text to the Lisp process.
 636 ;;;   This obsoletes all the -and-go commands. The -and-go commands are
 637 ;;;   kept around for historical reasons, and because the user can bind
 638 ;;;   them to key sequences shorter than C-u C-c C-<letter>.
 639 ;;; - If M-x cmulisp is invoked with a prefix arg, it allows you to
 640 ;;;   edit the command line.
 641
 642 (provide 'inf-lisp)
 643
 644 ;;; inf-lisp.el ends here