code.delx.au - gnu-emacs/blob - lisp/calendar/appt.el

   1 ;;; appt.el --- appointment notification functions
   2
   3 ;; Copyright (C) 1989, 1990, 1994, 1998, 2004 Free Software Foundation, Inc.
   4
   5 ;; Author: Neil Mager <neilm@juliet.ll.mit.edu>
   6 ;; Maintainer: FSF
   7 ;; Keywords: calendar
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;
  29 ;; appt.el - visible and/or audible notification of
  30 ;;           appointments from diary file.
  31 ;;
  32 ;;;
  33 ;;; Thanks to  Edward M. Reingold for much help and many suggestions,
  34 ;;; And to many others for bug fixes and suggestions.
  35 ;;;
  36 ;;;
  37 ;;; This functions in this file will alert the user of a
  38 ;;; pending appointment based on his/her diary file.  This package
  39 ;;; is documented in the Emacs manual.
  40 ;;;
  41 ;;; To activate this package, simply use (appt-activate 1).
  42 ;;; A `diary-file' with appointments of the format described in the
  43 ;;; documentation of the function `appt-check' is required.
  44 ;;; Relevant customizable variables are also listed in the
  45 ;;; documentation of that function.
  46 ;;;
  47 ;;; Today's appointment list is initialized from the diary when this
  48 ;;; package is activated. Additionally, the appointments list is
  49 ;;; recreated automatically at 12:01am for those who do not logout
  50 ;;; every day or are programming late. It is also updated when the
  51 ;;; `diary-file' is saved. Calling `appt-check' with an argument forces
  52 ;;; a re-initialization at any time.
  53 ;;;
  54 ;;; In order to add or delete items from today's list, without
  55 ;;; changing the diary file, use `appt-add' and `appt-delete'.
  56 ;;;
  57
  58 ;;; Brief internal description - Skip this if you are not interested!
  59 ;;;
  60 ;;; The function `appt-make-list' creates the appointments list which
  61 ;;; `appt-check' reads.
  62 ;;;
  63 ;;; You can change the way the appointment window is created/deleted by
  64 ;;; setting the variables
  65 ;;;
  66 ;;;          appt-disp-window-function
  67 ;;; and
  68 ;;;          appt-delete-window-function
  69 ;;;
  70 ;;; For instance, these variables could be set to functions that display
  71 ;;; appointments in pop-up frames, which are lowered or iconified after
  72 ;;; `appt-display-interval' minutes.
  73 ;;;
  74
  75 ;;; Code:
  76
  77 ;; Make sure calendar is loaded when we compile this.
  78 (require 'calendar)
  79
  80
  81 ;;;###autoload
  82 (defcustom appt-issue-message t
  83   "*Non-nil means check for appointments in the diary buffer.
  84 To be detected, the diary entry must have the format described in the
  85 documentation of the function `appt-check'."
  86   :type 'boolean
  87   :group 'appt)
  88
  89 (make-obsolete-variable 'appt-issue-message
  90                         "use the function `appt-activate', and the \
  91 variable `appt-display-format' instead." "22.1")
  92
  93 ;;;###autoload
  94 (defcustom appt-message-warning-time 12
  95   "*Time in minutes before an appointment that the warning begins."
  96   :type 'integer
  97   :group 'appt)
  98
  99 ;;;###autoload
 100 (defcustom appt-audible t
 101   "*Non-nil means beep to indicate appointment."
 102   :type 'boolean
 103   :group 'appt)
 104
 105 ;;;###autoload
 106 (defcustom appt-visible t
 107   "*Non-nil means display appointment message in echo area.
 108 This variable is only relevant if `appt-msg-window' is nil."
 109   :type 'boolean
 110   :group 'appt)
 111
 112 (make-obsolete-variable 'appt-visible 'appt-display-format "22.1")
 113
 114 ;;;###autoload
 115 (defcustom appt-msg-window t
 116   "*Non-nil means display appointment message in another window.
 117 If non-nil, this variable overrides `appt-visible'."
 118   :type 'boolean
 119   :group 'appt)
 120
 121 (make-obsolete-variable 'appt-msg-window 'appt-display-format "22.1")
 122
 123 ;; TODO - add popup.
 124 (defcustom appt-display-format 'ignore
 125   "How appointment reminders should be displayed.
 126 The options are:
 127    window - use a separate window
 128    echo   - use the echo area
 129    nil    - no visible reminder.
 130 See also `appt-audible' and `appt-display-mode-line'.
 131
 132 The default value is 'ignore, which means to fall back on the value
 133 of the (obsolete) variables `appt-msg-window' and `appt-visible'."
 134   :type '(choice
 135           (const :tag "Separate window" window)
 136           (const :tag "Echo-area" echo)
 137           (const :tag "No visible display" nil))
 138   :group 'appt
 139   :version "22.1")
 140
 141 ;;;###autoload
 142 (defcustom appt-display-mode-line t
 143   "*Non-nil means display minutes to appointment and time on the mode line.
 144 This is in addition to any other display of appointment messages."
 145   :type 'boolean
 146   :group 'appt)
 147
 148 ;;;###autoload
 149 (defcustom appt-display-duration 10
 150   "*The number of seconds an appointment message is displayed.
 151 Only relevant if reminders are to be displayed in their own window."
 152   :type 'integer
 153   :group 'appt)
 154
 155 ;;;###autoload
 156 (defcustom appt-display-diary t
 157   "*Non-nil displays the diary when the appointment list is first initialized.
 158 This will occur at midnight when the appointment list is updated."
 159   :type 'boolean
 160   :group 'appt)
 161
 162 (defcustom appt-display-interval 3
 163   "*Number of minutes to wait between checking the appointment list."
 164   :type 'integer
 165   :group 'appt)
 166
 167 (defcustom appt-disp-window-function 'appt-disp-window
 168   "Function called to display appointment window.
 169 Only relevant if reminders are being displayed in a window."
 170   :type '(choice (const appt-disp-window)
 171                  function)
 172   :group 'appt)
 173
 174 (defcustom appt-delete-window-function 'appt-delete-window
 175   "Function called to remove appointment window and buffer.
 176 Only relevant if reminders are being displayed in a window."
 177   :type '(choice (const appt-delete-window)
 178                  function)
 179   :group 'appt)
 180
 181
 182 ;;; Internal variables below this point.
 183
 184 (defvar appt-buffer-name " *appt-buf*"
 185   "Name of the appointments buffer.")
 186
 187 (defvar appt-time-msg-list nil
 188   "The list of appointments for today.
 189 Use `appt-add' and `appt-delete' to add and delete appointments.
 190 The original list is generated from today's `diary-entries-list', and
 191 can be regenerated using the function `appt-check'.
 192 Each element of the generated list has the form (MINUTES) STRING; where
 193 MINUTES is the time in minutes of the appointment after midnight, and
 194 STRING is the description of the appointment.")
 195
 196 (defconst appt-max-time 1439
 197   "11:59pm in minutes - number of minutes in a day minus 1.")
 198
 199 (defvar appt-mode-string nil
 200   "String being displayed in the mode line saying you have an appointment.
 201 The actual string includes the amount of time till the appointment.
 202 Only used if `appt-display-mode-line' is non-nil.")
 203
 204 (defvar appt-prev-comp-time nil
 205   "Time of day (mins since midnight) at which we last checked appointments.
 206 A nil value forces the diary file to be (re-)checked for appointments.")
 207
 208 (defvar appt-now-displayed nil
 209   "Non-nil when we have started notifying about a appointment that is near.")
 210
 211 (defvar appt-display-count nil
 212   "Internal variable used to count number of consecutive reminders.")
 213
 214 (defvar appt-timer nil
 215   "Timer used for diary appointment notifications (`appt-check').
 216 If this is non-nil, appointment checking is active.")
 217
 218
 219 ;;; Functions.
 220
 221 (defun appt-display-message (string mins)
 222   "Display a reminder about an appointment.
 223 The string STRING describes the appointment, due in integer MINS minutes.
 224 The format of the visible reminder is controlled by `appt-display-format'.
 225 The variable `appt-audible' controls the audible reminder."
 226   ;; let binding for backwards compatability. Remove when obsolete
 227   ;; vars appt-msg-window and appt-visible are dropped.
 228   (let ((appt-display-format
 229          (if (eq appt-display-format 'ignore)
 230              (cond (appt-msg-window 'window)
 231                    (appt-visible 'echo))
 232            appt-display-format)))
 233     (cond ((eq appt-display-format 'window)
 234            (funcall appt-disp-window-function
 235                     (number-to-string mins)
 236                     (format-time-string "%a %b %e " (current-time))
 237                     string)
 238            (run-at-time (format "%d sec" appt-display-duration)
 239                         nil
 240                         appt-delete-window-function))
 241           ((eq appt-display-format 'echo)
 242            (message "%s" string)))
 243     (if appt-audible (beep 1))))
 244
 245
 246 (defun appt-check (&optional force)
 247   "Check for an appointment and update any reminder display.
 248 If optional argument FORCE is non-nil, reparse the diary file for
 249 appointments.  Otherwise the diary file is only parsed once per day,
 250 and when saved.
 251
 252 Note: the time must be the first thing in the line in the diary
 253 for a warning to be issued.  The format of the time can be either
 254 24 hour or am/pm.  For example:
 255
 256               02/23/89
 257                 18:00 Dinner
 258
 259               Thursday
 260                 11:45am Lunch meeting.
 261
 262 Appointments are checked every `appt-display-interval' minutes.
 263 The following variables control appointment notification:
 264
 265 `appt-display-format'
 266         Controls the format in which reminders are displayed.
 267
 268 `appt-audible'
 269         Variable used to determine if reminder is audible.
 270         Default is t.
 271
 272 `appt-message-warning-time'
 273         Variable used to determine when appointment message
 274         should first be displayed.
 275
 276 `appt-display-mode-line'
 277         If non-nil, a generic message giving the time remaining
 278         is shown in the mode-line when an appointment is due.
 279
 280 `appt-display-interval'
 281         Interval in minutes at which to check for pending appointments.
 282
 283 `appt-display-diary'
 284         Display the diary buffer when the appointment list is
 285         initialized for the first time in a day.
 286
 287 The following variables are only relevant if reminders are being
 288 displayed in a window:
 289
 290 `appt-display-duration'
 291         The number of seconds an appointment message is displayed.
 292
 293 `appt-disp-window-function'
 294         Function called to display appointment window.
 295
 296 `appt-delete-window-function'
 297         Function called to remove appointment window and buffer."
 298
 299   (let* ((min-to-app -1)
 300          (prev-appt-mode-string appt-mode-string)
 301          (prev-appt-display-count (or appt-display-count 0))
 302          ;; Non-nil means do a full check for pending appointments
 303          ;; and display in whatever ways the user has selected.
 304          ;; When no appointment is being displayed,
 305          ;; we always do a full check.
 306          (full-check
 307           (or (not appt-now-displayed)
 308               ;; This is true every appt-display-interval minutes.
 309               (zerop (mod prev-appt-display-count appt-display-interval))))
 310          ;; Non-nil means only update the interval displayed in the mode line.
 311          (mode-line-only
 312           (and (not full-check) appt-now-displayed)))
 313
 314     (when (or full-check mode-line-only)
 315       (save-excursion
 316
 317         ;; Get the current time and convert it to minutes
 318         ;; from midnight. ie. 12:01am = 1, midnight = 0.
 319
 320         (let* ((now (decode-time))
 321                (cur-hour (nth 2 now))
 322                (cur-min (nth 1 now))
 323                (cur-comp-time (+ (* cur-hour 60) cur-min)))
 324
 325           ;; At the first check in any given day, update our
 326           ;; appointments to today's list.
 327
 328           (if (or force                 ; eg initialize, diary save
 329                   (null appt-prev-comp-time)             ; first check
 330                   (< cur-comp-time appt-prev-comp-time)) ; new day
 331               (condition-case nil
 332                   (if appt-display-diary
 333                       (let ((diary-hook
 334                              (if (assoc 'appt-make-list diary-hook)
 335                                  diary-hook
 336                                (cons 'appt-make-list diary-hook))))
 337                         (diary))
 338                     (let ((diary-display-hook 'appt-make-list)
 339                           (d-buff (find-buffer-visiting
 340                                    (substitute-in-file-name diary-file)))
 341                           selective)
 342                       (if d-buff        ; diary buffer exists
 343                           (with-current-buffer d-buff
 344                             (setq selective selective-display)))
 345                       (diary)
 346                       ;; If the diary buffer existed before this command,
 347                       ;; restore its display state. Otherwise, kill it.
 348                       (if d-buff
 349                           ;; Displays the diary buffer.
 350                           (or selective (show-all-diary-entries))
 351                         (and
 352                          (setq d-buff (find-buffer-visiting
 353                                        (substitute-in-file-name diary-file)))
 354                          (kill-buffer d-buff)))))
 355                 (error nil)))
 356
 357           (setq appt-prev-comp-time cur-comp-time
 358                 appt-mode-string nil
 359                 appt-display-count nil)
 360
 361           ;; If there are entries in the list, and the
 362           ;; user wants a message issued,
 363           ;; get the first time off of the list
 364           ;; and calculate the number of minutes until the appointment.
 365
 366           (if (and appt-issue-message appt-time-msg-list)
 367               (let ((appt-comp-time (car (car (car appt-time-msg-list)))))
 368                 (setq min-to-app (- appt-comp-time cur-comp-time))
 369
 370                 (while (and appt-time-msg-list
 371                             (< appt-comp-time cur-comp-time))
 372                   (setq appt-time-msg-list (cdr appt-time-msg-list))
 373                   (if appt-time-msg-list
 374                       (setq appt-comp-time
 375                             (car (car (car appt-time-msg-list))))))
 376
 377                 ;; If we have an appointment between midnight and
 378                 ;; 'appt-message-warning-time' minutes after midnight,
 379                 ;; we must begin to issue a message before midnight.
 380                 ;; Midnight is considered 0 minutes and 11:59pm is
 381                 ;; 1439 minutes. Therefore we must recalculate the minutes
 382                 ;; to appointment variable. It is equal to the number of
 383                 ;; minutes before midnight plus the number of
 384                 ;; minutes after midnight our appointment is.
 385
 386                 (if (and (< appt-comp-time appt-message-warning-time)
 387                          (> (+ cur-comp-time appt-message-warning-time)
 388                             appt-max-time))
 389                     (setq min-to-app (+ (- (1+ appt-max-time) cur-comp-time))
 390                           appt-comp-time))
 391
 392                 ;; issue warning if the appointment time is
 393                 ;; within appt-message-warning time
 394
 395                 (when (and (<= min-to-app appt-message-warning-time)
 396                            (>= min-to-app 0))
 397                   (setq appt-now-displayed t
 398                         appt-display-count (1+ prev-appt-display-count))
 399                   (unless mode-line-only
 400                     (appt-display-message (cadr (car appt-time-msg-list))
 401                                           min-to-app))
 402                   (when appt-display-mode-line
 403                     (setq appt-mode-string
 404                           (format " App't in %s min." min-to-app)))
 405
 406                   ;; When an appointment is reached,
 407                   ;; delete it from the list.
 408                   ;; Reset the count to 0 in case we display another
 409                   ;; appointment on the next cycle.
 410                   (if (zerop min-to-app)
 411                       (setq appt-time-msg-list (cdr appt-time-msg-list)
 412                             appt-display-count nil)))))
 413
 414           ;; If we have changed the mode line string,
 415           ;; redisplay all mode lines.
 416           (and appt-display-mode-line
 417                (not (equal appt-mode-string
 418                            prev-appt-mode-string))
 419                (progn
 420                  (force-mode-line-update t)
 421                  ;; If the string now has a notification,
 422                  ;; redisplay right now.
 423                  (if appt-mode-string
 424                      (sit-for 0)))))))))
 425
 426
 427 (defun appt-disp-window (min-to-app new-time appt-msg)
 428   "Display appointment message APPT-MSG in a separate buffer.
 429 The appointment is due in MIN-TO-APP (a string) minutes.
 430 NEW-TIME is a string giving the date."
 431   (require 'electric)
 432
 433   ;; Make sure we're not in the minibuffer
 434   ;; before splitting the window.
 435
 436   (if (equal (selected-window) (minibuffer-window))
 437       (if (other-window 1)
 438           (select-window (other-window 1))
 439         (if (display-multi-frame-p)
 440             (select-frame (other-frame 1)))))
 441
 442   (let ((this-window (selected-window))
 443         (appt-disp-buf (set-buffer (get-buffer-create appt-buffer-name))))
 444
 445     (if (cdr (assq 'unsplittable (frame-parameters)))
 446         ;; In an unsplittable frame, use something somewhere else.
 447         (display-buffer appt-disp-buf)
 448       (unless (or (special-display-p (buffer-name appt-disp-buf))
 449                   (same-window-p (buffer-name appt-disp-buf)))
 450         ;; By default, split the bottom window and use the lower part.
 451         (appt-select-lowest-window)
 452         (select-window (split-window)))
 453       (switch-to-buffer appt-disp-buf))
 454     (calendar-set-mode-line
 455      (format " Appointment in %s minutes. %s " min-to-app new-time))
 456     (erase-buffer)
 457     (insert appt-msg)
 458     (shrink-window-if-larger-than-buffer (get-buffer-window appt-disp-buf t))
 459     (set-buffer-modified-p nil)
 460     (raise-frame (selected-frame))
 461     (select-window this-window)))
 462
 463 (defun appt-delete-window ()
 464   "Function called to undisplay appointment messages.
 465 Usually just deletes the appointment buffer."
 466   (let ((window (get-buffer-window appt-buffer-name t)))
 467     (and window
 468          (or (eq window (frame-root-window (window-frame window)))
 469              (delete-window window))))
 470   (kill-buffer appt-buffer-name)
 471   (if appt-audible
 472       (beep 1)))
 473
 474 (defun appt-select-lowest-window ()
 475 "Select the lowest window on the frame."
 476   (let ((lowest-window (selected-window))
 477         (bottom-edge (nth 3 (window-edges))))
 478     (walk-windows (lambda (w)
 479                     (let ((next-bottom-edge (nth 3 (window-edges w))))
 480                       (when (< bottom-edge next-bottom-edge)
 481                         (setq bottom-edge next-bottom-edge
 482                               lowest-window w)))))
 483     (select-window lowest-window)))
 484
 485 ;;;###autoload
 486 (defun appt-add (new-appt-time new-appt-msg)
 487   "Add an appointment for the day at NEW-APPT-TIME and issue message NEW-APPT-MSG.
 488 The time should be in either 24 hour format or am/pm format."
 489
 490   (interactive "sTime (hh:mm[am/pm]): \nsMessage: ")
 491   (unless (string-match "[0-9]?[0-9][:.][0-9][0-9]\\(am\\|pm\\)?"
 492                     new-appt-time)
 493     (error "Unacceptable time-string"))
 494   (let* ((appt-time-string (concat new-appt-time " " new-appt-msg))
 495          (appt-time (list (appt-convert-time new-appt-time)))
 496          (time-msg (cons appt-time (list appt-time-string))))
 497     (setq appt-time-msg-list (nconc appt-time-msg-list (list time-msg)))
 498     (setq appt-time-msg-list (appt-sort-list appt-time-msg-list))))
 499
 500 ;;;###autoload
 501 (defun appt-delete ()
 502   "Delete an appointment from the list of appointments."
 503   (interactive)
 504   (let ((tmp-msg-list appt-time-msg-list))
 505     (while tmp-msg-list
 506       (let* ((element (car tmp-msg-list))
 507              (prompt-string (concat "Delete "
 508                                     ;; We want to quote any doublequotes
 509                                     ;; in the string, as well as put
 510                                     ;; doublequotes around it.
 511                                     (prin1-to-string
 512                                      (substring-no-properties
 513                                       (car (cdr element)) 0))
 514                                     " from list? "))
 515              (test-input (y-or-n-p prompt-string)))
 516         (setq tmp-msg-list (cdr tmp-msg-list))
 517         (if test-input
 518             (setq appt-time-msg-list (delq element appt-time-msg-list)))))
 519     (appt-check)
 520     (message "")))
 521
 522
 523 (eval-when-compile (defvar number)
 524                    (defvar original-date)
 525                    (defvar diary-entries-list))
 526 ;;;###autoload
 527 (defun appt-make-list ()
 528   "Create the appointments list from today's diary buffer.
 529 The time must be at the beginning of a line for it to be
 530 put in the appointments list (see examples in documentation of
 531 the function `appt-check').  We assume that the variables DATE and
 532 NUMBER hold the arguments that `list-diary-entries' received.
 533 They specify the range of dates that the diary is being processed for."
 534
 535   ;; We have something to do if the range of dates that the diary is
 536   ;; considering includes the current date.
 537   (if (and (not (calendar-date-compare
 538                  (list (calendar-current-date))
 539                  (list original-date)))
 540            (calendar-date-compare
 541             (list (calendar-current-date))
 542             (list (calendar-gregorian-from-absolute
 543                    (+ (calendar-absolute-from-gregorian original-date)
 544                       number)))))
 545       (save-excursion
 546         ;; Clear the appointments list, then fill it in from the diary.
 547         (setq appt-time-msg-list nil)
 548         (if diary-entries-list
 549
 550             ;; Cycle through the entry-list (diary-entries-list)
 551             ;; looking for entries beginning with a time. If
 552             ;; the entry begins with a time, add it to the
 553             ;; appt-time-msg-list. Then sort the list.
 554
 555             (let ((entry-list diary-entries-list)
 556                   (new-time-string ""))
 557               ;; Skip diary entries for dates before today.
 558               (while (and entry-list
 559                           (calendar-date-compare
 560                            (car entry-list) (list (calendar-current-date))))
 561                 (setq entry-list (cdr entry-list)))
 562               ;; Parse the entries for today.
 563               (while (and entry-list
 564                           (calendar-date-equal
 565                            (calendar-current-date) (car (car entry-list))))
 566                 (let ((time-string (cadr (car entry-list))))
 567                   (while (string-match
 568                           "\\([0-9]?[0-9][:.][0-9][0-9]\\(am\\|pm\\)?\\).*"
 569                           time-string)
 570                     (let* ((beg (match-beginning 0))
 571                            ;; Get just the time for this appointment.
 572                            (only-time (match-string 1 time-string))
 573                            ;; Find the end of this appointment
 574                            ;; (the start of the next).
 575                            (end (string-match
 576                                  "^[ \t]*[0-9]?[0-9][:.][0-9][0-9]\\(am\\|pm\\)?"
 577                                  time-string
 578                                  (match-end 0)))
 579                            ;; Get the whole string for this appointment.
 580                            (appt-time-string
 581                             (substring time-string beg (if end (1- end)))))
 582
 583                       ;; Add this appointment to appt-time-msg-list.
 584                       (let* ((appt-time (list (appt-convert-time only-time)))
 585                              (time-msg (list appt-time appt-time-string)))
 586                         (setq appt-time-msg-list
 587                               (nconc appt-time-msg-list (list time-msg))))
 588
 589                       ;; Discard this appointment from the string.
 590                       (setq time-string
 591                             (if end (substring time-string end) "")))))
 592                 (setq entry-list (cdr entry-list)))))
 593         (setq appt-time-msg-list (appt-sort-list appt-time-msg-list))
 594
 595         ;; Get the current time and convert it to minutes
 596         ;; from midnight. ie. 12:01am = 1, midnight = 0,
 597         ;; so that the elements in the list
 598         ;; that are earlier than the present time can
 599         ;; be removed.
 600
 601         (let* ((now (decode-time))
 602                (cur-hour (nth 2 now))
 603                (cur-min (nth 1 now))
 604                (cur-comp-time (+ (* cur-hour 60) cur-min))
 605                (appt-comp-time (car (caar appt-time-msg-list))))
 606
 607           (while (and appt-time-msg-list (< appt-comp-time cur-comp-time))
 608             (setq appt-time-msg-list (cdr appt-time-msg-list))
 609             (if appt-time-msg-list
 610                 (setq appt-comp-time (car (caar appt-time-msg-list)))))))))
 611
 612
 613 (defun appt-sort-list (appt-list)
 614   "Sort an appointment list, putting earlier items at the front.
 615 APPT-LIST is a list of the same format as `appt-time-msg-list'."
 616 (sort appt-list (lambda (e1 e2) (< (caar e1) (caar e2)))))
 617
 618
 619 (defun appt-convert-time (time2conv)
 620   "Convert hour:min[am/pm] format to minutes from midnight.
 621 A period (.) can be used instead of a colon (:) to separate the
 622 hour and minute parts."
 623   (let ((conv-time 0)
 624         (hr 0)
 625         (min 0))
 626
 627     (string-match "[:.]\\([0-9][0-9]\\)" time2conv)
 628     (setq min (string-to-int
 629                (match-string 1 time2conv)))
 630
 631     (string-match "[0-9]?[0-9][:.]" time2conv)
 632     (setq hr (string-to-int
 633               (match-string 0 time2conv)))
 634
 635     ;; convert the time appointment time into 24 hour time
 636
 637     (cond ((and (string-match "pm" time2conv) (< hr 12))
 638            (setq hr (+ 12 hr)))
 639           ((and (string-match "am" time2conv) (= hr 12))
 640            (setq hr 0)))
 641
 642     ;; convert the actual time
 643     ;; into minutes for comparison
 644     ;; against the actual time.
 645
 646     (setq conv-time (+ (* hr 60) min))
 647     conv-time))
 648
 649
 650 (defun appt-update-list ()
 651   "If the current buffer is visiting the diary, update appointments.
 652 This function is intended for use with `write-file-functions'."
 653   (and (string-equal buffer-file-name (expand-file-name diary-file))
 654        appt-timer
 655        (let ((appt-display-diary nil))
 656          (appt-check t)))
 657   nil)
 658
 659
 660 ;;;###autoload
 661 (defun appt-activate (&optional arg)
 662 "Toggle checking of appointments.
 663 With optional numeric argument ARG, turn appointment checking on if
 664 ARG is positive, otherwise off."
 665   (interactive "P")
 666   (let ((appt-active appt-timer))
 667     (setq appt-active (if arg (> (prefix-numeric-value arg) 0)
 668                         (not appt-active)))
 669     (remove-hook 'write-file-functions 'appt-update-list)
 670     (or global-mode-string (setq global-mode-string '("")))
 671     (delq 'appt-mode-string global-mode-string)
 672     (when appt-timer
 673       (cancel-timer appt-timer)
 674       (setq appt-timer nil))
 675     (when appt-active
 676       (add-hook 'write-file-functions 'appt-update-list)
 677       (setq appt-timer (run-at-time t 60 'appt-check)
 678             global-mode-string
 679             (append global-mode-string '(appt-mode-string)))
 680       (appt-check t))))
 681
 682
 683 ;; This is needed for backwards compatibility. Feh.
 684 (appt-activate 1)
 685
 686
 687 (provide 'appt)
 688
 689 ;;; arch-tag: bf5791c4-8921-499e-a26f-772b1788d347
 690 ;;; appt.el ends here