code.delx.au - gnu-emacs/blob - lisp/play/gamegrid.el

   1 ;;; gamegrid.el --- library for implementing grid-based games on Emacs
   2
   3 ;; Copyright (C) 1997, 1998, 2005 Free Software Foundation, Inc.
   4
   5 ;; Author: Glynn Clements <glynn@sensei.co.uk>
   6 ;; Version: 1.02
   7 ;; Created: 1997-08-13
   8 ;; Keywords: games
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  25 ;; Boston, MA 02110-1301, USA.
  26
  27 ;;; Commentary:
  28
  29 ;;; Code:
  30
  31 (eval-when-compile
  32   (require 'cl))
  33
  34 ;; ;;;;;;;;;;;;; buffer-local variables ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  35
  36 (defvar gamegrid-use-glyphs t
  37   "Non-nil means use glyphs when available.")
  38
  39 (defvar gamegrid-use-color t
  40   "Non-nil means use color when available.")
  41
  42 (defvar gamegrid-font "-*-courier-medium-r-*-*-*-140-100-75-*-*-iso8859-*"
  43   "Name of the font used in X mode.")
  44
  45 (defvar gamegrid-face nil
  46   "Indicates the face to use as a default.")
  47 (make-variable-buffer-local 'gamegrid-face)
  48
  49 (defvar gamegrid-display-options nil)
  50
  51 (defvar gamegrid-buffer-width 0)
  52 (defvar gamegrid-buffer-height 0)
  53 (defvar gamegrid-blank 0)
  54
  55 (defvar gamegrid-timer nil)
  56
  57 (defvar gamegrid-display-mode nil)
  58
  59 (defvar gamegrid-display-table)
  60
  61 (defvar gamegrid-face-table nil)
  62
  63 (defvar gamegrid-buffer-start 1)
  64
  65 (defvar gamegrid-score-file-length 50
  66   "Number of high scores to keep")
  67
  68 (defvar gamegrid-user-score-file-directory "~/.emacs.d/games"
  69   "A directory for game scores which can't be shared.
  70 If Emacs was built without support for shared game scores, then this
  71 directory will be used.")
  72
  73 (make-variable-buffer-local 'gamegrid-use-glyphs)
  74 (make-variable-buffer-local 'gamegrid-use-color)
  75 (make-variable-buffer-local 'gamegrid-font)
  76 (make-variable-buffer-local 'gamegrid-display-options)
  77 (make-variable-buffer-local 'gamegrid-buffer-width)
  78 (make-variable-buffer-local 'gamegrid-buffer-height)
  79 (make-variable-buffer-local 'gamegrid-blank)
  80 (make-variable-buffer-local 'gamegrid-timer)
  81 (make-variable-buffer-local 'gamegrid-display-mode)
  82 (make-variable-buffer-local 'gamegrid-display-table)
  83 (make-variable-buffer-local 'gamegrid-face-table)
  84 (make-variable-buffer-local 'gamegrid-buffer-start)
  85 (make-variable-buffer-local 'gamegrid-score-file-length)
  86
  87 ;; ;;;;;;;;;;;;; global variables ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  88
  89 (defvar gamegrid-grid-x-face nil)
  90 (defvar gamegrid-mono-x-face nil)
  91 (defvar gamegrid-mono-tty-face nil)
  92
  93 ;; ;;;;;;;;;;;;; constants ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  94
  95 (defconst gamegrid-glyph-height 16)
  96
  97 (defconst gamegrid-xpm "\
  98 /* XPM */
  99 static char *noname[] = {
 100 /* width height ncolors chars_per_pixel */
 101 \"16 16 3 1\",
 102 /* colors */
 103 \"+ s col1\",
 104 \". s col2\",
 105 \"- s col3\",
 106 /* pixels */
 107 \"---------------+\",
 108 \"--------------++\",
 109 \"--............++\",
 110 \"--............++\",
 111 \"--............++\",
 112 \"--............++\",
 113 \"--............++\",
 114 \"--............++\",
 115 \"--............++\",
 116 \"--............++\",
 117 \"--............++\",
 118 \"--............++\",
 119 \"--............++\",
 120 \"--............++\",
 121 \"-+++++++++++++++\",
 122 \"++++++++++++++++\"
 123 };
 124 "
 125   "XPM format image used for each square")
 126
 127 (defvar gamegrid-xbm "\
 128 /* gamegrid XBM */
 129 #define gamegrid_width 16
 130 #define gamegrid_height 16
 131 static unsigned char gamegrid_bits[] = {
 132    0xff, 0xff, 0xff, 0x7f, 0xff, 0x3f, 0xaf, 0x0a, 0x57, 0x15, 0xaf, 0x0a,
 133    0x57, 0x15, 0xaf, 0x0a, 0x57, 0x15, 0xaf, 0x0a, 0x57, 0x15, 0xaf, 0x0a,
 134    0x57, 0x15, 0x07, 0x00, 0x03, 0x00, 0x01, 0x00 };"
 135   "XBM format image used for each square.")
 136
 137 ;; ;;;;;;;;;;;;;;;; miscellaneous functions ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 138
 139 (defsubst gamegrid-characterp (arg)
 140   (if (fboundp 'characterp)
 141       (characterp arg)
 142     (integerp arg)))
 143
 144 (defsubst gamegrid-event-x (event)
 145   (if (fboundp 'event-x)
 146       (event-x event)
 147     (car (posn-col-row (event-end event)))))
 148
 149 (defsubst gamegrid-event-y (event)
 150   (if (fboundp 'event-y)
 151       (event-y event)
 152     (cdr (posn-col-row (event-end event)))))
 153
 154 ;; ;;;;;;;;;;;;; display functions ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 155
 156 (defun gamegrid-color (color shade)
 157   (let* ((v (floor (* shade 255)))
 158          (r (* v (aref color 0)))
 159          (g (* v (aref color 1)))
 160          (b (* v (aref color 2))))
 161     (format "#%02x%02x%02x" r g b)))
 162
 163 (defun gamegrid-set-font (face)
 164   (if gamegrid-font
 165       (condition-case nil
 166           (set-face-font face gamegrid-font)
 167         (error nil))))
 168
 169 (defun gamegrid-setup-face (face color)
 170   (set-face-foreground face color)
 171   (set-face-background face color)
 172   (gamegrid-set-font face)
 173   (condition-case nil
 174       (set-face-background-pixmap face [nothing]);; XEmacs
 175     (error nil))
 176   (condition-case nil
 177       (set-face-background-pixmap face nil);; Emacs
 178     (error nil)))
 179
 180 (defun gamegrid-make-mono-tty-face ()
 181   (let ((face (make-face 'gamegrid-mono-tty-face)))
 182     (set-face-inverse-video-p face t)
 183     face))
 184
 185 (defun gamegrid-make-color-tty-face (color)
 186   (let* ((color-str (if (symbolp color) (symbol-value color) color))
 187          (name (intern (format "gamegrid-color-tty-face-%s" color-str)))
 188          (face (make-face name)))
 189     (gamegrid-setup-face face color-str)
 190     face))
 191
 192 (defun gamegrid-make-grid-x-face ()
 193   (let ((face (make-face 'gamegrid-x-border-face)))
 194     (gamegrid-set-font face)
 195     face))
 196
 197 (defun gamegrid-make-mono-x-face ()
 198   (let ((face (make-face 'gamegrid-mono-x-face))
 199         (color (face-foreground 'default)))
 200     (if (null color)
 201         (setq color
 202               (cdr-safe (assq 'foreground-color (frame-parameters)))))
 203     (gamegrid-setup-face face color)
 204     face))
 205
 206 (defun gamegrid-make-color-x-face (color)
 207   (let* ((hex (gamegrid-color color 1.0))
 208          (name (intern (format "gamegrid-color-x-face-%s" hex)))
 209          (face (make-face name)))
 210     (gamegrid-setup-face face hex)
 211     face))
 212
 213 (defun gamegrid-make-face (data-spec-list color-spec-list)
 214   (let ((data (gamegrid-match-spec-list data-spec-list))
 215         (color (gamegrid-match-spec-list color-spec-list)))
 216     (case data
 217       ('color-x
 218        (gamegrid-make-color-x-face color))
 219       ('grid-x
 220        (unless gamegrid-grid-x-face
 221          (setq gamegrid-grid-x-face (gamegrid-make-grid-x-face)))
 222        gamegrid-grid-x-face)
 223       ('mono-x
 224        (unless gamegrid-mono-x-face
 225          (setq gamegrid-mono-x-face (gamegrid-make-mono-x-face)))
 226        gamegrid-mono-x-face)
 227       ('color-tty
 228        (gamegrid-make-color-tty-face color))
 229       ('mono-tty
 230        (unless gamegrid-mono-tty-face
 231          (setq gamegrid-mono-tty-face (gamegrid-make-mono-tty-face)))
 232        gamegrid-mono-tty-face))))
 233
 234 (defun gamegrid-colorize-glyph (color)
 235   (find-image `((:type xpm :data ,gamegrid-xpm
 236                        :ascent center
 237                        :color-symbols
 238                        (("col1" . ,(gamegrid-color color 0.6))
 239                         ("col2" . ,(gamegrid-color color 0.8))
 240                         ("col3" . ,(gamegrid-color color 1.0))))
 241                 (:type xbm :data ,gamegrid-xbm
 242                        :ascent center
 243                        :foreground ,(gamegrid-color color 1.0)
 244                        :background ,(gamegrid-color color 0.5)))))
 245
 246 (defun gamegrid-match-spec (spec)
 247   (let ((locale (car spec))
 248         (value (cadr spec)))
 249     (and (or (eq locale t)
 250              (and (listp locale)
 251                   (memq gamegrid-display-mode locale))
 252              (and (symbolp locale)
 253                   (eq gamegrid-display-mode locale)))
 254          value)))
 255
 256 (defun gamegrid-match-spec-list (spec-list)
 257   (and spec-list
 258        (or (gamegrid-match-spec (car spec-list))
 259            (gamegrid-match-spec-list (cdr spec-list)))))
 260
 261 (defun gamegrid-make-glyph (data-spec-list color-spec-list)
 262   (let ((data (gamegrid-match-spec-list data-spec-list))
 263         (color (gamegrid-match-spec-list color-spec-list)))
 264     (cond ((gamegrid-characterp data)
 265            (vector data))
 266           ((eq data 'colorize)
 267            (gamegrid-colorize-glyph color))
 268           ((listp data)
 269            (find-image data)) ;untested!
 270           ((vectorp data)
 271            (gamegrid-make-image-from-vector data)))))
 272
 273 (defun gamegrid-make-image-from-vector (vect)
 274   "Convert an XEmacs style \"glyph\" to an image-spec."
 275   (let ((l (list 'image :type)))
 276     (dotimes (n (length vect))
 277       (setf l (nconc l (list (aref vect n)))))
 278     (nconc l (list :ascent 'center))))
 279
 280 (defun gamegrid-display-type ()
 281   (cond ((and gamegrid-use-glyphs
 282               (display-images-p))
 283          'glyph)
 284         ((and gamegrid-use-color
 285               (display-graphic-p)
 286               (display-color-p))
 287          'color-x)
 288         ((display-graphic-p)
 289          'mono-x)
 290         ((and gamegrid-use-color
 291               (display-color-p))
 292          'color-tty)
 293         ((display-multi-font-p) ;???
 294          'mono-tty)
 295         (t
 296            'emacs-tty)))
 297
 298 (defun gamegrid-set-display-table ()
 299   (if (featurep 'xemacs)
 300       (add-spec-to-specifier current-display-table
 301                              gamegrid-display-table
 302                              (current-buffer)
 303                              nil
 304                              'remove-locale)
 305     (setq buffer-display-table gamegrid-display-table)))
 306
 307 (defun gamegrid-setup-default-font ()
 308   (setq gamegrid-face
 309         (copy-face 'default
 310                    (intern (concat "gamegrid-face-" (buffer-name)))))
 311   (when (eq gamegrid-display-mode 'glyph)
 312     (let ((max-height nil))
 313       (loop for c from 0 to 255 do
 314             (let ((glyph (aref gamegrid-display-table c)))
 315               (when (and (listp glyph) (eq (car  glyph) 'image))
 316                 (let ((height (cdr (image-size glyph))))
 317                   (if (or (null max-height)
 318                           (< max-height height))
 319                       (setq max-height height))))))
 320       (when (and max-height (< max-height 1))
 321         (set-face-attribute gamegrid-face nil :height max-height)))))
 322
 323 (defun gamegrid-initialize-display ()
 324   (setq gamegrid-display-mode (gamegrid-display-type))
 325   (setq gamegrid-display-table (make-display-table))
 326   (setq gamegrid-face-table (make-vector 256 nil))
 327   (loop for c from 0 to 255 do
 328     (let* ((spec (aref gamegrid-display-options c))
 329            (glyph (gamegrid-make-glyph (car spec) (caddr spec)))
 330            (face (gamegrid-make-face (cadr spec) (caddr spec))))
 331       (aset gamegrid-face-table c face)
 332       (aset gamegrid-display-table c glyph)))
 333   (gamegrid-setup-default-font)
 334   (gamegrid-set-display-table)
 335   (setq cursor-type nil))
 336
 337
 338 (defun gamegrid-set-face (c)
 339   (if (eq gamegrid-display-mode 'glyph)
 340       (add-text-properties (1- (point)) (point)
 341                            (list 'display (list (aref gamegrid-display-table c))))
 342     (put-text-property (1- (point))
 343                        (point)
 344                        'face
 345                        (aref gamegrid-face-table c))))
 346
 347 (defun gamegrid-cell-offset (x y)
 348   (+ gamegrid-buffer-start
 349      (* (1+ gamegrid-buffer-width) y)
 350      x))
 351
 352 ;; ;;;;;;;;;;;;;;;; grid functions ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 353
 354 (defun gamegrid-get-cell (x y)
 355   (char-after (gamegrid-cell-offset x y)))
 356
 357 (defun gamegrid-set-cell (x y c)
 358   (save-excursion
 359     (let ((buffer-read-only nil))
 360       (goto-char (gamegrid-cell-offset x y))
 361       (delete-char 1)
 362       (insert-char c 1)
 363       (gamegrid-set-face c))))
 364
 365 (defun gamegrid-init-buffer (width height blank)
 366   (setq gamegrid-buffer-width width
 367         gamegrid-buffer-height height)
 368   (let ((line (concat
 369                (make-string width blank)
 370                "\n"))
 371         (buffer-read-only nil))
 372     (erase-buffer)
 373     (setq gamegrid-buffer-start (point))
 374     (dotimes (i height)
 375       (insert line))
 376     ;; Adjust the height of the default face to the height of the
 377     ;; images. Unlike XEmacs, Emacs doesn't allow to make the default
 378     ;; face buffer-local; so we do this with an overlay.
 379     (when (eq gamegrid-display-mode 'glyph)
 380       (overlay-put (make-overlay (point-min) (point-max))
 381                    'face gamegrid-face))
 382     (goto-char (point-min))))
 383
 384 (defun gamegrid-init (options)
 385   (setq buffer-read-only t
 386         truncate-lines t
 387         gamegrid-display-options options)
 388   (buffer-disable-undo (current-buffer))
 389   (gamegrid-initialize-display))
 390
 391 ;; ;;;;;;;;;;;;;;;; timer functions ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 392
 393 (defun gamegrid-start-timer (period func)
 394   (setq gamegrid-timer
 395         (if (featurep 'itimer)
 396             (start-itimer "Gamegrid"
 397                           func
 398                           period
 399                           period
 400                           nil
 401                           t
 402                           (current-buffer))
 403           (run-with-timer period
 404                           period
 405                           func
 406                           (current-buffer)))))
 407
 408 (defun gamegrid-set-timer (delay)
 409   (if gamegrid-timer
 410       (if (fboundp 'set-itimer-restart)
 411           (set-itimer-restart gamegrid-timer delay)
 412         (timer-set-time gamegrid-timer
 413                         (list (aref gamegrid-timer 1)
 414                               (aref gamegrid-timer 2)
 415                               (aref gamegrid-timer 3))
 416                         delay))))
 417
 418 (defun gamegrid-kill-timer ()
 419   (if gamegrid-timer
 420       (if (featurep 'itimer)
 421           (delete-itimer gamegrid-timer)
 422         (timer-set-time gamegrid-timer '(0 0 0) nil)))
 423   (setq gamegrid-timer nil))
 424
 425 ;; ;;;;;;;;;;;;;;; high score functions ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 426
 427 (defun gamegrid-add-score (file score)
 428   "Add the current score to the high score file.
 429
 430 On POSIX systems there may be a shared game directory for all users in
 431 which the scorefiles are kept. On such systems Emacs doesn't create
 432 the score file FILE in this directory, if it doesn't already exist. In
 433 this case Emacs searches for FILE in the directory specified by
 434 `gamegrid-user-score-file-directory' and creates it there, if
 435 necessary.
 436
 437 To add the score file for a game to the system wide shared game
 438 directory, create the file with the shell command \"touch\" in this
 439 directory and make sure that it is owned by the correct user and
 440 group. You probably need special user privileges to do this.
 441
 442 On non-POSIX systems Emacs searches for FILE in the directory
 443 specified by the variable `temporary-file-directory'. If necessary,
 444 FILE is created there."
 445   (case system-type
 446     ((ms-dos windows-nt)
 447      (gamegrid-add-score-insecure file score))
 448     (t
 449      (gamegrid-add-score-with-update-game-score file score))))
 450
 451
 452 ;; On POSIX systems there are four cases to distinguish:
 453
 454 ;;     1. FILE is an absolute filename.  Then it should be a file in
 455 ;;        temporary file directory.  This is the way,
 456 ;;        `gamegrid-add-score' was supposed to be used in the past and
 457 ;;        is covered here for backward-compatibility.
 458 ;;
 459 ;;     2. The helper program "update-game-score" is setuid and the
 460 ;;        file FILE does already exist in a system wide shared game
 461 ;;        directory.  This should be the normal case on POSIX systems,
 462 ;;        if the game was installed system wide.  Use
 463 ;;        "update-game-score" to add the score to the file in the
 464 ;;        shared game directory.
 465 ;;
 466 ;;     3. "update-game-score" is setuid, but the file FILE does *not*
 467 ;;        exist in the system wide shared game directory.  Use
 468 ;;        `gamegrid-add-score-insecure' to create--if necessary--and
 469 ;;        update FILE.  This is for the case that a user has installed
 470 ;;        a game on her own.
 471 ;;
 472 ;;     4. "update-game-score" is not setuid.  Use it to create/update
 473 ;;        FILE in the user's home directory.  There is presumably no
 474 ;;        shared game directory.
 475
 476 (defvar gamegrid-shared-game-dir)
 477
 478 (defun gamegrid-add-score-with-update-game-score (file score)
 479   (let* ((result nil) ;; What is this good for? -- os
 480          (gamegrid-shared-game-dir
 481           (not (zerop (logand (file-modes
 482                                (expand-file-name "update-game-score"
 483                                                  exec-directory))
 484                               #o4000)))))
 485     (cond ((file-name-absolute-p file)
 486            (gamegrid-add-score-insecure file score))
 487           ((and gamegrid-shared-game-dir
 488                 (file-exists-p (expand-file-name file shared-game-score-directory)))
 489            ;; Use the setuid "update-game-score" program to update a
 490            ;; system-wide score file.
 491            (gamegrid-add-score-with-update-game-score-1 file
 492             (expand-file-name file shared-game-score-directory) score))
 493           ;; Else: Add the score to a score file in the user's home
 494           ;; directory.
 495           (gamegrid-shared-game-dir
 496            ;; If `gamegrid-shared-game-dir' is non-nil, then
 497            ;; "update-gamescore" program is setuid, so don't use it.
 498            (unless (file-exists-p
 499                     (directory-file-name gamegrid-user-score-file-directory))
 500              (make-directory gamegrid-user-score-file-directory t))
 501            (gamegrid-add-score-insecure file score
 502                                         gamegrid-user-score-file-directory))
 503           (t (let ((f (expand-file-name
 504                        gamegrid-user-score-file-directory)))
 505                (when (file-writable-p f)
 506                  (unless (eq (car-safe (file-attributes f))
 507                              t)
 508                    (make-directory f))
 509                  (setq f (expand-file-name file f))
 510                  (unless (file-exists-p f)
 511                    (write-region "" nil f nil 'silent nil 'excl)))
 512                (gamegrid-add-score-with-update-game-score-1 file f score))))))
 513
 514 (defun gamegrid-add-score-with-update-game-score-1 (file target score)
 515   (let ((default-directory "/")
 516         (errbuf (generate-new-buffer " *update-game-score loss*")))
 517     (apply
 518      'call-process
 519      (append
 520       (list
 521        (expand-file-name "update-game-score" exec-directory)
 522        nil errbuf nil
 523        "-m" (int-to-string gamegrid-score-file-length)
 524        "-d" (if gamegrid-shared-game-dir
 525                 (expand-file-name shared-game-score-directory)
 526               (file-name-directory target))
 527        file
 528        (int-to-string score)
 529        (concat
 530         (user-full-name)
 531         " <"
 532         (cond ((fboundp 'user-mail-address)
 533                (user-mail-address))
 534               ((boundp 'user-mail-address)
 535                user-mail-address)
 536               (t ""))
 537         ">  "
 538         (current-time-string)))))
 539     (if (buffer-modified-p errbuf)
 540         (progn
 541           (display-buffer errbuf)
 542           (error "Failed to update game score file"))
 543       (kill-buffer errbuf))
 544     (save-excursion
 545       (let ((buf (find-buffer-visiting target)))
 546         (if buf
 547             (progn
 548               (with-current-buffer buf
 549                 (revert-buffer nil t nil))
 550               (display-buffer buf))
 551           (find-file-read-only-other-window target))))))
 552
 553 (defun gamegrid-add-score-insecure (file score &optional directory)
 554   (save-excursion
 555     (setq file (expand-file-name file (or directory
 556                                           temporary-file-directory)))
 557     (find-file-other-window file)
 558     (setq buffer-read-only nil)
 559     (goto-char (point-max))
 560     (insert (format "%05d\t%s\t%s <%s>\n"
 561                     score
 562                     (current-time-string)
 563                     (user-full-name)
 564                     (cond ((fboundp 'user-mail-address)
 565                            (user-mail-address))
 566                           ((boundp 'user-mail-address)
 567                            user-mail-address)
 568                           (t ""))))
 569     (sort-fields 1 (point-min) (point-max))
 570     (reverse-region (point-min) (point-max))
 571     (goto-line (1+ gamegrid-score-file-length))
 572     (delete-region (point) (point-max))
 573     (setq buffer-read-only t)
 574     (save-buffer)))
 575
 576
 577 ;; ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 578
 579 (provide 'gamegrid)
 580
 581 ;;; arch-tag: a96c2ff4-1c12-427e-bd3d-faeaf174cd46
 582 ;;; gamegrid.el ends here