code.delx.au - gnu-emacs/blob - lisp/emacs-lisp/easymenu.el

   1 ;;; easymenu.el --- support the easymenu interface for defining a menu
   2
   3 ;; Copyright (C) 1994, 1996, 1998, 1999, 2000, 2001, 2002, 2003,
   4 ;;   2004, 2005, 2006, 2007, 2008 Free Software Foundation, Inc.
   5
   6 ;; Keywords: emulations
   7 ;; Author: Richard Stallman <rms@gnu.org>
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 3, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 ;; Boston, MA 02110-1301, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; This is compatible with easymenu.el by Per Abrahamsen
  29 ;; but it is much simpler as it doesn't try to support other Emacs versions.
  30 ;; The code was mostly derived from lmenu.el.
  31
  32 ;;; Code:
  33
  34 (defcustom easy-menu-precalculate-equivalent-keybindings t
  35   "Determine when equivalent key bindings are computed for easy-menu menus.
  36 It can take some time to calculate the equivalent key bindings that are shown
  37 in a menu.  If the variable is on, then this calculation gives a (maybe
  38 noticeable) delay when a mode is first entered.  If the variable is off, then
  39 this delay will come when a menu is displayed the first time.  If you never use
  40 menus, turn this variable off, otherwise it is probably better to keep it on."
  41   :type 'boolean
  42   :group 'menu
  43   :version "20.3")
  44
  45 (defsubst easy-menu-intern (s)
  46   (if (stringp s) (intern s) s))
  47
  48 ;;;###autoload
  49 (put 'easy-menu-define 'lisp-indent-function 'defun)
  50 ;;;###autoload
  51 (defmacro easy-menu-define (symbol maps doc menu)
  52   "Define a menu bar submenu in maps MAPS, according to MENU.
  53
  54 If SYMBOL is non-nil, store the menu keymap in the value of SYMBOL,
  55 and define SYMBOL as a function to pop up the menu, with DOC as its doc string.
  56 If SYMBOL is nil, just store the menu keymap into MAPS.
  57
  58 The first element of MENU must be a string.  It is the menu bar item name.
  59 It may be followed by the following keyword argument pairs
  60
  61    :filter FUNCTION
  62
  63 FUNCTION is a function with one argument, the rest of menu items.
  64 It returns the remaining items of the displayed menu.
  65
  66    :visible INCLUDE
  67
  68 INCLUDE is an expression; this menu is only visible if this
  69 expression has a non-nil value.  `:included' is an alias for `:visible'.
  70
  71    :active ENABLE
  72
  73 ENABLE is an expression; the menu is enabled for selection
  74 whenever this expression's value is non-nil.
  75
  76 The rest of the elements in MENU, are menu items.
  77
  78 A menu item is usually a vector of three elements:  [NAME CALLBACK ENABLE]
  79
  80 NAME is a string--the menu item name.
  81
  82 CALLBACK is a command to run when the item is chosen,
  83 or a list to evaluate when the item is chosen.
  84
  85 ENABLE is an expression; the item is enabled for selection
  86 whenever this expression's value is non-nil.
  87
  88 Alternatively, a menu item may have the form:
  89
  90    [ NAME CALLBACK [ KEYWORD ARG ] ... ]
  91
  92 Where KEYWORD is one of the symbols defined below.
  93
  94    :keys KEYS
  95
  96 KEYS is a string; a complex keyboard equivalent to this menu item.
  97 This is normally not needed because keyboard equivalents are usually
  98 computed automatically.
  99 KEYS is expanded with `substitute-command-keys' before it is used.
 100
 101    :key-sequence KEYS
 102
 103 KEYS is nil, a string or a vector; nil or a keyboard equivalent to this
 104 menu item.
 105 This is a hint that will considerably speed up Emacs' first display of
 106 a menu.  Use `:key-sequence nil' when you know that this menu item has no
 107 keyboard equivalent.
 108
 109    :active ENABLE
 110
 111 ENABLE is an expression; the item is enabled for selection
 112 whenever this expression's value is non-nil.
 113
 114    :visible INCLUDE
 115
 116 INCLUDE is an expression; this item is only visible if this
 117 expression has a non-nil value.  `:included' is an alias for `:visible'.
 118
 119    :label FORM
 120
 121 FORM is an expression that will be dynamically evaluated and whose
 122 value will be used for the menu entry's text label (the default is NAME).
 123
 124    :suffix FORM
 125
 126 FORM is an expression that will be dynamically evaluated and whose
 127 value will be concatenated to the menu entry's label.
 128
 129    :style STYLE
 130
 131 STYLE is a symbol describing the type of menu item.  The following are
 132 defined:
 133
 134 toggle: A checkbox.
 135         Prepend the name with `(*) ' or `( ) ' depending on if selected or not.
 136 radio: A radio button.
 137        Prepend the name with `[X] ' or `[ ] ' depending on if selected or not.
 138 button: Surround the name with `[' and `]'.  Use this for an item in the
 139         menu bar itself.
 140 anything else means an ordinary menu item.
 141
 142    :selected SELECTED
 143
 144 SELECTED is an expression; the checkbox or radio button is selected
 145 whenever this expression's value is non-nil.
 146
 147    :help HELP
 148
 149 HELP is a string, the help to display for the menu item.
 150
 151 A menu item can be a string.  Then that string appears in the menu as
 152 unselectable text.  A string consisting solely of hyphens is displayed
 153 as a solid horizontal line.
 154
 155 A menu item can be a list with the same format as MENU.  This is a submenu."
 156   `(progn
 157      ,(if symbol `(defvar ,symbol nil ,doc))
 158      (easy-menu-do-define (quote ,symbol) ,maps ,doc ,menu)))
 159
 160 (defun easy-menu-binding (menu &optional item-name)
 161   "Return a binding suitable to pass to `define-key'.
 162 This is expected to be bound to a mouse event."
 163   ;; Under Emacs this is almost trivial, whereas under XEmacs this may
 164   ;; involve defining a function that calls popup-menu.
 165   (let ((props (if (symbolp menu)
 166                    (prog1 (get menu 'menu-prop)
 167                      (setq menu (symbol-function menu))))))
 168     (cons 'menu-item
 169           (cons (or item-name
 170                     (if (keymapp menu)
 171                         (keymap-prompt menu))
 172                     "")
 173                 (cons menu props)))))
 174
 175 ;;;###autoload
 176 (defun easy-menu-do-define (symbol maps doc menu)
 177   ;; We can't do anything that might differ between Emacs dialects in
 178   ;; `easy-menu-define' in order to make byte compiled files
 179   ;; compatible.  Therefore everything interesting is done in this
 180   ;; function.
 181   (let ((keymap (easy-menu-create-menu (car menu) (cdr menu))))
 182     (when symbol
 183       (set symbol keymap)
 184       (defalias symbol
 185         `(lambda (event) ,doc (interactive "@e")
 186            ;; FIXME: XEmacs uses popup-menu which calls the binding
 187            ;; while x-popup-menu only returns the selection.
 188            (x-popup-menu event
 189                          (or (and (symbolp ,symbol)
 190                                   (funcall
 191                                    (or (plist-get (get ,symbol 'menu-prop)
 192                                                   :filter)
 193                                        'identity)
 194                                    (symbol-function ,symbol)))
 195                              ,symbol)))))
 196     (dolist (map (if (keymapp maps) (list maps) maps))
 197       (define-key map
 198         (vector 'menu-bar (easy-menu-intern (car menu)))
 199         (easy-menu-binding keymap (car menu))))))
 200
 201 (defun easy-menu-filter-return (menu &optional name)
 202  "Convert MENU to the right thing to return from a menu filter.
 203 MENU is a menu as computed by `easy-menu-define' or `easy-menu-create-menu' or
 204 a symbol whose value is such a menu.
 205 In Emacs a menu filter must return a menu (a keymap), in XEmacs a filter must
 206 return a menu items list (without menu name and keywords).
 207 This function returns the right thing in the two cases.
 208 If NAME is provided, it is used for the keymap."
 209  (cond
 210   ((and (not (keymapp menu)) (consp menu))
 211    ;; If it's a cons but not a keymap, then it can't be right
 212    ;; unless it's an XEmacs menu.
 213    (setq menu (easy-menu-create-menu (or name "") menu)))
 214   ((vectorp menu)
 215    ;; It's just a menu entry.
 216    (setq menu (cdr (easy-menu-convert-item menu)))))
 217  menu)
 218
 219 (defvar easy-menu-avoid-duplicate-keys t
 220   "Dynamically scoped var to register already used keys in a menu.
 221 If it holds a list, this is expected to be a list of keys already seen in the
 222 menu we're processing.  Else it means we're not processing a menu.")
 223
 224 ;;;###autoload
 225 (defun easy-menu-create-menu (menu-name menu-items)
 226   "Create a menu called MENU-NAME with items described in MENU-ITEMS.
 227 MENU-NAME is a string, the name of the menu.  MENU-ITEMS is a list of items
 228 possibly preceded by keyword pairs as described in `easy-menu-define'."
 229   (let ((menu (make-sparse-keymap menu-name))
 230         (easy-menu-avoid-duplicate-keys nil)
 231         prop keyword arg label enable filter visible help)
 232     ;; Look for keywords.
 233     (while (and menu-items
 234                 (cdr menu-items)
 235                 (keywordp (setq keyword (car menu-items))))
 236       (setq arg (cadr menu-items))
 237       (setq menu-items (cddr menu-items))
 238       (cond
 239        ((eq keyword :filter)
 240         (setq filter `(lambda (menu)
 241                         (easy-menu-filter-return (,arg menu) ,menu-name))))
 242        ((eq keyword :active) (setq enable (or arg ''nil)))
 243        ((eq keyword :label) (setq label arg))
 244        ((eq keyword :help) (setq help arg))
 245        ((or (eq keyword :included) (eq keyword :visible))
 246         (setq visible (or arg ''nil)))))
 247     (if (equal visible ''nil)
 248         nil                             ; Invisible menu entry, return nil.
 249       (if (and visible (not (easy-menu-always-true-p visible)))
 250           (setq prop (cons :visible (cons visible prop))))
 251       (if (and enable (not (easy-menu-always-true-p enable)))
 252           (setq prop (cons :enable (cons enable prop))))
 253       (if filter (setq prop (cons :filter (cons filter prop))))
 254       (if help (setq prop (cons :help (cons help prop))))
 255       (if label (setq prop (cons nil (cons label prop))))
 256       (if filter
 257           ;; The filter expects the menu in its XEmacs form and the pre-filter
 258           ;; form will only be passed to the filter anyway, so we'd better
 259           ;; not convert it at all (it will be converted on the fly by
 260           ;; easy-menu-filter-return).
 261           (setq menu menu-items)
 262         (setq menu (append menu (mapcar 'easy-menu-convert-item menu-items))))
 263       (when prop
 264         (setq menu (easy-menu-make-symbol menu 'noexp))
 265         (put menu 'menu-prop prop))
 266       menu)))
 267
 268
 269 ;; Known button types.
 270 (defvar easy-menu-button-prefix
 271   '((radio . :radio) (toggle . :toggle)))
 272
 273 (defvar easy-menu-converted-items-table (make-hash-table :test 'equal))
 274
 275 (defun easy-menu-convert-item (item)
 276   "Memoize the value returned by `easy-menu-convert-item-1' called on ITEM.
 277 This makes key-shortcut-caching work a *lot* better when this
 278 conversion is done from within a filter.
 279 This also helps when the NAME of the entry is recreated each time:
 280 since the menu is built and traversed separately, the lookup
 281 would always fail because the key is `equal' but not `eq'."
 282   (or (gethash item easy-menu-converted-items-table)
 283       (puthash item (easy-menu-convert-item-1 item)
 284                easy-menu-converted-items-table)))
 285
 286 (defun easy-menu-convert-item-1 (item)
 287   "Parse an item description and convert it to a menu keymap element.
 288 ITEM defines an item as in `easy-menu-define'."
 289   (let (name command label prop remove)
 290     (cond
 291      ((stringp item)                    ; An item or separator.
 292       (setq label item))
 293      ((consp item)                      ; A sub-menu
 294       (setq label (setq name (car item)))
 295       (setq command (cdr item))
 296       (if (not (keymapp command))
 297           (setq command (easy-menu-create-menu name command)))
 298       (if (null command)
 299           ;; Invisible menu item. Don't insert into keymap.
 300           (setq remove t)
 301         (when (and (symbolp command) (setq prop (get command 'menu-prop)))
 302           (when (null (car prop))
 303             (setq label (cadr prop))
 304             (setq prop (cddr prop)))
 305           (setq command (symbol-function command)))))
 306      ((vectorp item)                    ; An item.
 307       (let* ((ilen (length item))
 308              (active (if (> ilen 2) (or (aref item 2) ''nil) t))
 309              (no-name (not (symbolp (setq command (aref item 1)))))
 310              cache cache-specified)
 311         (setq label (setq name (aref item 0)))
 312         (if no-name (setq command (easy-menu-make-symbol command)))
 313         (if (keywordp active)
 314             (let ((count 2)
 315                   keyword arg suffix visible style selected keys)
 316               (setq active nil)
 317               (while (> ilen count)
 318                 (setq keyword (aref item count))
 319                 (setq arg (aref item (1+ count)))
 320                 (setq count (+ 2 count))
 321                 (cond
 322                  ((or (eq keyword :included) (eq keyword :visible))
 323                   (setq visible (or arg ''nil)))
 324                  ((eq keyword :key-sequence)
 325                   (setq cache arg cache-specified t))
 326                  ((eq keyword :keys) (setq keys arg no-name nil))
 327                  ((eq keyword :label) (setq label arg))
 328                  ((eq keyword :active) (setq active (or arg ''nil)))
 329                  ((eq keyword :help) (setq prop (cons :help (cons arg prop))))
 330                  ((eq keyword :suffix) (setq suffix arg))
 331                  ((eq keyword :style) (setq style arg))
 332                  ((eq keyword :selected) (setq selected (or arg ''nil)))))
 333               (if suffix
 334                   (setq label
 335                         (if (stringp suffix)
 336                             (if (stringp label) (concat label " " suffix)
 337                               (list 'concat label (concat " " suffix)))
 338                           (if (stringp label)
 339                               (list 'concat (concat label " ") suffix)
 340                             (list 'concat label " " suffix)))))
 341               (cond
 342                ((eq style 'button)
 343                 (setq label (if (stringp label) (concat "[" label "]")
 344                               (list 'concat "[" label "]"))))
 345                ((and selected
 346                      (setq style (assq style easy-menu-button-prefix)))
 347                 (setq prop (cons :button
 348                                  (cons (cons (cdr style) selected) prop)))))
 349               (when (stringp keys)
 350                 (if (string-match "^[^\\]*\\(\\\\\\[\\([^]]+\\)]\\)[^\\]*$"
 351                                   keys)
 352                     (let ((prefix
 353                            (if (< (match-beginning 0) (match-beginning 1))
 354                                (substring keys 0 (match-beginning 1))))
 355                           (postfix
 356                            (if (< (match-end 1) (match-end 0))
 357                                (substring keys (match-end 1))))
 358                           (cmd (intern (match-string 2 keys))))
 359                       (setq keys (and (or prefix postfix)
 360                                       (cons prefix postfix)))
 361                       (setq keys
 362                             (and (or keys (not (eq command cmd)))
 363                                  (cons cmd keys))))
 364                   (setq cache-specified nil))
 365                 (if keys (setq prop (cons :keys (cons keys prop)))))
 366               (if (and visible (not (easy-menu-always-true-p visible)))
 367                   (if (equal visible ''nil)
 368                       ;; Invisible menu item. Don't insert into keymap.
 369                       (setq remove t)
 370                     (setq prop (cons :visible (cons visible prop)))))))
 371         (if (and active (not (easy-menu-always-true-p active)))
 372             (setq prop (cons :enable (cons active prop))))
 373         (if (and (or no-name cache-specified)
 374                  (or (null cache) (stringp cache) (vectorp cache)))
 375             (setq prop (cons :key-sequence (cons cache prop))))))
 376      (t (error "Invalid menu item in easymenu")))
 377     ;; `intern' the name so as to merge multiple entries with the same name.
 378     ;; It also makes it easier/possible to lookup/change menu bindings
 379     ;; via keymap functions.
 380     (let ((key (easy-menu-intern name)))
 381       (when (listp easy-menu-avoid-duplicate-keys)
 382         ;; Merging multiple entries with the same name is sometimes what we
 383         ;; want, but not when the entries are actually different (e.g. same
 384         ;; name but different :suffix as seen in cal-menu.el) and appear in
 385         ;; the same menu.  So we try to detect and resolve conflicts.
 386         (while (and (stringp name)
 387                     (memq key easy-menu-avoid-duplicate-keys))
 388           ;; We need to use some distinct object, ideally a symbol, ideally
 389           ;; related to the `name'.  Uninterned symbols do not work (they
 390           ;; are apparently turned into strings and re-interned later on).
 391           (setq key (intern (format "%s (%d)" (symbol-name key)
 392                                     (length easy-menu-avoid-duplicate-keys)))))
 393         (push key easy-menu-avoid-duplicate-keys))
 394
 395       (cons key
 396             (and (not remove)
 397                  (cons 'menu-item
 398                        (cons label
 399                              (and name
 400                                   (cons command prop)))))))))
 401
 402 (defun easy-menu-define-key (menu key item &optional before)
 403   "Add binding in MENU for KEY => ITEM.  Similar to `define-key-after'.
 404 If KEY is not nil then delete any duplications.
 405 If ITEM is nil, then delete the definition of KEY.
 406
 407 Optional argument BEFORE is nil or a key in MENU.  If BEFORE is not nil,
 408 put binding before the item in MENU named BEFORE; otherwise,
 409 if a binding for KEY is already present in MENU, just change it;
 410 otherwise put the new binding last in MENU.
 411 BEFORE can be either a string (menu item name) or a symbol
 412 \(the fake function key for the menu item).
 413 KEY does not have to be a symbol, and comparison is done with equal."
 414   (if (symbolp menu) (setq menu (indirect-function menu)))
 415   (let ((inserted (null item))          ; Fake already inserted.
 416         tail done)
 417     (while (not done)
 418       (cond
 419        ((or (setq done (or (null (cdr menu)) (keymapp (cdr menu))))
 420             (and before (easy-menu-name-match before (cadr menu))))
 421         ;; If key is nil, stop here, otherwise keep going past the
 422         ;; inserted element so we can delete any duplications that come
 423         ;; later.
 424         (if (null key) (setq done t))
 425         (unless inserted                ; Don't insert more than once.
 426           (setcdr menu (cons (cons key item) (cdr menu)))
 427           (setq inserted t)
 428           (setq menu (cdr menu)))
 429         (setq menu (cdr menu)))
 430        ((and key (equal (car-safe (cadr menu)) key))
 431         (if (or inserted                ; Already inserted or
 432                 (and before             ;  wanted elsewhere and
 433                      (setq tail (cddr menu)) ; not last item and not
 434                      (not (keymapp tail))
 435                      (not (easy-menu-name-match
 436                            before (car tail))))) ; in position
 437             (setcdr menu (cddr menu))   ; Remove item.
 438           (setcdr (cadr menu) item)     ; Change item.
 439           (setq inserted t)
 440           (setq menu (cdr menu))))
 441        (t (setq menu (cdr menu)))))))
 442
 443 (defun easy-menu-name-match (name item)
 444   "Return t if NAME is the name of menu item ITEM.
 445 NAME can be either a string, or a symbol.
 446 ITEM should be a keymap binding of the form (KEY . MENU-ITEM)."
 447   (if (consp item)
 448       (if (symbolp name)
 449           (eq (car-safe item) name)
 450         (if (stringp name)
 451             ;; Match against the text that is displayed to the user.
 452             (or (condition-case nil (member-ignore-case name item)
 453                   (error nil))          ;`item' might not be a proper list.
 454                 ;; Also check the string version of the symbol name,
 455                 ;; for backwards compatibility.
 456                 (eq (car-safe item) (intern name)))))))
 457
 458 (defun easy-menu-always-true-p (x)
 459   "Return true if form X never evaluates to nil."
 460   (if (consp x) (and (eq (car x) 'quote) (cadr x))
 461     (or (eq x t) (not (symbolp x)))))
 462
 463 (defvar easy-menu-item-count 0)
 464
 465 (defun easy-menu-make-symbol (callback &optional noexp)
 466   "Return a unique symbol with CALLBACK as function value.
 467 When non-nil, NOEXP indicates that CALLBACK cannot be an expression
 468 \(i.e. does not need to be turned into a function)."
 469   (let ((command
 470          (make-symbol (format "menu-function-%d" easy-menu-item-count))))
 471     (setq easy-menu-item-count (1+ easy-menu-item-count))
 472     (fset command
 473           (if (or (keymapp callback) (commandp callback)
 474                   ;; `functionp' is probably not needed.
 475                   (functionp callback) noexp)
 476               callback
 477             `(lambda () (interactive) ,callback)))
 478     command))
 479
 480 ;;;###autoload
 481 (defun easy-menu-change (path name items &optional before map)
 482   "Change menu found at PATH as item NAME to contain ITEMS.
 483 PATH is a list of strings for locating the menu that
 484 should contain a submenu named NAME.
 485 ITEMS is a list of menu items, as in `easy-menu-define'.
 486 These items entirely replace the previous items in that submenu.
 487
 488 If MAP is specified, it should normally be a keymap; nil stands for the local
 489 menu-bar keymap.  It can also be a symbol, which has earlier been used as the
 490 first argument in a call to `easy-menu-define', or the value of such a symbol.
 491
 492 If the menu located by PATH has no submenu named NAME, add one.
 493 If the optional argument BEFORE is present, add it just before
 494 the submenu named BEFORE, otherwise add it at the end of the menu.
 495
 496 To implement dynamic menus, either call this from
 497 `menu-bar-update-hook' or use a menu filter."
 498   (easy-menu-add-item map path (easy-menu-create-menu name items) before))
 499
 500 ;; XEmacs needs the following two functions to add and remove menus.
 501 ;; In Emacs this is done automatically when switching keymaps, so
 502 ;; here easy-menu-remove is a noop and easy-menu-add only precalculates
 503 ;; equivalent keybindings (if easy-menu-precalculate-equivalent-keybindings
 504 ;; is on).
 505 (defalias 'easy-menu-remove 'ignore
 506   "Remove MENU from the current menu bar.
 507 Contrary to XEmacs, this is a nop on Emacs since menus are automatically
 508 \(de)activated when the corresponding keymap is (de)activated.
 509
 510 \(fn MENU)")
 511
 512 (defun easy-menu-add (menu &optional map)
 513   "Add the menu to the menubar.
 514 On Emacs, menus are already automatically activated when the
 515 corresponding keymap is activated.  On XEmacs this is needed to
 516 actually add the menu to the current menubar.
 517
 518 This also precalculates equivalent key bindings when
 519 `easy-menu-precalculate-equivalent-keybindings' is on.
 520
 521 You should call this once the menu and keybindings are set up
 522 completely and menu filter functions can be expected to work."
 523   (when easy-menu-precalculate-equivalent-keybindings
 524     (if (and (symbolp menu) (not (keymapp menu)) (boundp menu))
 525         (setq menu (symbol-value menu)))
 526     (and (keymapp menu) (fboundp 'x-popup-menu)
 527          (x-popup-menu nil menu))
 528     ))
 529
 530 (defun add-submenu (menu-path submenu &optional before in-menu)
 531   "Add submenu SUBMENU in the menu at MENU-PATH.
 532 If BEFORE is non-nil, add before the item named BEFORE.
 533 If IN-MENU is non-nil, follow MENU-PATH in IN-MENU.
 534 This is a compatibility function; use `easy-menu-add-item'."
 535   (easy-menu-add-item (or in-menu (current-global-map))
 536                       (cons "menu-bar" menu-path)
 537                       submenu before))
 538
 539 (defun easy-menu-add-item (map path item &optional before)
 540   "To the submenu of MAP with path PATH, add ITEM.
 541
 542 If an item with the same name is already present in this submenu,
 543 then ITEM replaces it.  Otherwise, ITEM is added to this submenu.
 544 In the latter case, ITEM is normally added at the end of the submenu.
 545 However, if BEFORE is a string and there is an item in the submenu
 546 with that name, then ITEM is added before that item.
 547
 548 MAP should normally be a keymap; nil stands for the local menu-bar keymap.
 549 It can also be a symbol, which has earlier been used as the first
 550 argument in a call to `easy-menu-define', or the value of such a symbol.
 551
 552 PATH is a list of strings for locating the submenu where ITEM is to be
 553 added.  If PATH is nil, MAP itself is used.  Otherwise, the first
 554 element should be the name of a submenu directly under MAP.  This
 555 submenu is then traversed recursively with the remaining elements of PATH.
 556
 557 ITEM is either defined as in `easy-menu-define' or a non-nil value returned
 558 by `easy-menu-item-present-p' or `easy-menu-remove-item' or a menu defined
 559 earlier by `easy-menu-define' or `easy-menu-create-menu'."
 560   (setq map (easy-menu-get-map map path
 561                                (and (null map) (null path)
 562                                     (stringp (car-safe item))
 563                                     (car item))))
 564   (if (and (consp item) (consp (cdr item)) (eq (cadr item) 'menu-item))
 565       ;; This is a value returned by `easy-menu-item-present-p' or
 566       ;; `easy-menu-remove-item'.
 567       (easy-menu-define-key map (easy-menu-intern (car item))
 568                             (cdr item) before)
 569     (if (or (keymapp item)
 570             (and (symbolp item) (keymapp (symbol-value item))
 571                  (setq item (symbol-value item))))
 572         ;; Item is a keymap, find the prompt string and use as item name.
 573         (setq item (cons (keymap-prompt item) item)))
 574     (setq item (easy-menu-convert-item item))
 575     (easy-menu-define-key map (easy-menu-intern (car item)) (cdr item) before)))
 576
 577 (defun easy-menu-item-present-p (map path name)
 578   "In submenu of MAP with path PATH, return non-nil if item NAME is present.
 579 MAP and PATH are defined as in `easy-menu-add-item'.
 580 NAME should be a string, the name of the element to be looked for."
 581   (easy-menu-return-item (easy-menu-get-map map path) name))
 582
 583 (defun easy-menu-remove-item (map path name)
 584   "From submenu of MAP with path PATH remove item NAME.
 585 MAP and PATH are defined as in `easy-menu-add-item'.
 586 NAME should be a string, the name of the element to be removed."
 587   (setq map (easy-menu-get-map map path))
 588   (let ((ret (easy-menu-return-item map name)))
 589     (if ret (easy-menu-define-key map (easy-menu-intern name) nil))
 590     ret))
 591
 592 (defun easy-menu-return-item (menu name)
 593   "In menu MENU try to look for menu item with name NAME.
 594 If a menu item is found, return (NAME . item), otherwise return nil.
 595 If item is an old format item, a new format item is returned."
 596   ;; The call to `lookup-key' also calls the C function `get_keyelt' which
 597   ;; looks inside a menu-item to only return the actual command.  This is
 598   ;; not what we want here.  We should either add an arg to lookup-key to be
 599   ;; able to turn off this "feature", or else we could use map-keymap here.
 600   ;; In the mean time, I just use `assq' which is an OK approximation since
 601   ;; menus are rarely built from vectors or char-tables.
 602   (let ((item (or (cdr (assq name menu))
 603                   (lookup-key menu (vector (easy-menu-intern name)))))
 604         ret enable cache label)
 605     (cond
 606      ((stringp (car-safe item))
 607       ;; This is the old menu format. Convert it to new format.
 608       (setq label (car item))
 609       (when (stringp (car (setq item (cdr item)))) ; Got help string
 610         (setq ret (list :help (car item)))
 611         (setq item (cdr item)))
 612       (when (and (consp item) (consp (car item))
 613                  (or (null (caar item)) (numberp (caar item))))
 614         (setq cache (car item))         ; Got cache
 615         (setq item (cdr item)))
 616       (and (symbolp item) (setq enable (get item 'menu-enable)) ; Got enable
 617            (setq ret (cons :enable (cons enable ret))))
 618       (if cache (setq ret (cons cache ret)))
 619       (cons name (cons 'menu-enable (cons label (cons item ret)))))
 620      (item ; (or (symbolp item) (keymapp item) (eq (car-safe item) 'menu-item))
 621       (cons name item))                 ; Keymap or new menu format
 622      )))
 623
 624 (defun easy-menu-lookup-name (map name)
 625   "Lookup menu item NAME in keymap MAP.
 626 Like `lookup-key' except that NAME is not an array but just a single key
 627 and that NAME can be a string representing the menu item's name."
 628   (or (lookup-key map (vector (easy-menu-intern name)))
 629       (when (stringp name)
 630         ;; `lookup-key' failed and we have a menu item name: look at the
 631         ;; actual menu entries's names.
 632         (catch 'found
 633           (map-keymap (lambda (key item)
 634                         (if (condition-case nil (member name item)
 635                               (error nil))
 636                             ;; Found it!!  Look for it again with
 637                             ;; `lookup-key' so as to handle inheritance and
 638                             ;; to extract the actual command/keymap bound to
 639                             ;; `name' from the item (via get_keyelt).
 640                             (throw 'found (lookup-key map (vector key)))))
 641                       map)))))
 642
 643 (defun easy-menu-get-map (map path &optional to-modify)
 644   "Return a sparse keymap in which to add or remove an item.
 645 MAP and PATH are as defined in `easy-menu-add-item'.
 646
 647 TO-MODIFY, if non-nil, is the name of the item the caller
 648 wants to modify in the map that we return.
 649 In some cases we use that to select between the local and global maps."
 650   (setq map
 651         (catch 'found
 652           (if (and map (symbolp map) (not (keymapp map)))
 653               (setq map (symbol-value map)))
 654           (let ((maps (if map (if (keymapp map) (list map) map)
 655                         (current-active-maps))))
 656             ;; Look for PATH in each map.
 657             (unless map (push 'menu-bar path))
 658             (dolist (name path)
 659               (setq maps
 660                     (delq nil (mapcar (lambda (map)
 661                                         (setq map (easy-menu-lookup-name
 662                                                    map name))
 663                                         (and (keymapp map) map))
 664                                       maps))))
 665
 666             ;; Prefer a map that already contains the to-be-modified entry.
 667             (when to-modify
 668               (dolist (map maps)
 669                 (when (easy-menu-lookup-name map to-modify)
 670                   (throw 'found map))))
 671             ;; Use the first valid map.
 672             (when maps (throw 'found (car maps)))
 673
 674             ;; Otherwise, make one up.
 675             ;; Hardcoding current-local-map is lame, but it's difficult
 676             ;; to know what the caller intended for us to do ;-(
 677             (let* ((name (if path (format "%s" (car (reverse path)))))
 678                    (newmap (make-sparse-keymap name)))
 679               (define-key (or map (current-local-map))
 680                 (apply 'vector (mapcar 'easy-menu-intern path))
 681                 (if name (cons name newmap) newmap))
 682               newmap))))
 683   (or (keymapp map) (error "Malformed menu in easy-menu: (%s)" map))
 684   map)
 685
 686 (provide 'easymenu)
 687
 688 ;; arch-tag: 2a04020d-90d2-476d-a7c6-71e072007a4a
 689 ;;; easymenu.el ends here