code.delx.au - gnu-emacs/blob - lisp/ediff.el

   1 ;;; ediff.el --- a comprehensive visual interface to diff & patch
   2
   3 ;; Copyright (C) 1994, 95, 96, 97, 98, 99, 2000, 01, 02 Free Software Foundation, Inc.
   4
   5 ;; Author: Michael Kifer <kifer@cs.stonybrook.edu>
   6 ;; Created: February 2, 1994
   7 ;; Keywords: comparing, merging, patching, tools, unix
   8
   9 (defconst ediff-version "2.77" "The current version of Ediff")
  10 (defconst ediff-date "March 5, 2002" "Date of last update")
  11
  12
  13 ;; This file is part of GNU Emacs.
  14
  15 ;; GNU Emacs is free software; you can redistribute it and/or modify
  16 ;; it under the terms of the GNU General Public License as published by
  17 ;; the Free Software Foundation; either version 2, or (at your option)
  18 ;; any later version.
  19
  20 ;; GNU Emacs is distributed in the hope that it will be useful,
  21 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  22 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  23 ;; GNU General Public License for more details.
  24
  25 ;; You should have received a copy of the GNU General Public License
  26 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  27 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  28 ;; Boston, MA 02111-1307, USA.
  29
  30 ;;; Commentary:
  31
  32 ;; Never read that diff output again!
  33 ;; Apply patch interactively!
  34 ;; Merge with ease!
  35
  36 ;; This package provides a convenient way of simultaneous browsing through
  37 ;; the differences between a pair (or a triple) of files or buffers.  The
  38 ;; files being compared, file-A, file-B, and file-C (if applicable) are
  39 ;; shown in separate windows (side by side, one above the another, or in
  40 ;; separate frames), and the differences are highlighted as you step
  41 ;; through them.  You can also copy difference regions from one buffer to
  42 ;; another (and recover old differences if you change your mind).
  43
  44 ;; Ediff also supports merging operations on files and buffers, including
  45 ;; merging using ancestor versions.  Both comparison and merging operations can
  46 ;; be performed on directories, i.e., by pairwise comparison of files in those
  47 ;; directories.
  48
  49 ;; In addition, Ediff can apply a patch to a file and then let you step
  50 ;; though both files, the patched and the original one, simultaneously,
  51 ;; difference-by-difference.  You can even apply a patch right out of a
  52 ;; mail buffer, i.e., patches received by mail don't even have to be saved.
  53 ;; Since Ediff lets you copy differences between buffers, you can, in
  54 ;; effect, apply patches selectively (i.e., you can copy a difference
  55 ;; region from file_orig to file, thereby undoing any particular patch that
  56 ;; you don't like).
  57
  58 ;; Ediff is aware of version control, which lets the user compare
  59 ;; files with their older versions.  Ediff can also work with remote and
  60 ;; compressed files.  Details are given below.
  61
  62 ;; Finally, Ediff supports directory-level comparison, merging and patching.
  63 ;; See the on-line manual for details.
  64
  65 ;; This package builds upon the ideas borrowed from emerge.el and several
  66 ;; Ediff's functions are adaptations from emerge.el.  Much of the functionality
  67 ;; Ediff provides is also influenced by emerge.el.
  68
  69 ;; The present version of Ediff supersedes Emerge.  It provides a superior user
  70 ;; interface and has numerous major features not found in Emerge.  In
  71 ;; particular, it can do patching, and 2-way and 3-way file comparison,
  72 ;; merging, and directory operations.
  73
  74
  75
  76 ;;; Bugs:
  77
  78 ;;  1. The undo command doesn't restore deleted regions well.  That is, if
  79 ;;  you delete all characters in a difference region and then invoke
  80 ;;  `undo', the reinstated text will most likely be inserted outside of
  81 ;;  what Ediff thinks is the current difference region. (This problem
  82 ;;  doesn't seem to exist with XEmacs.)
  83 ;;
  84 ;;  If at any point you feel that difference regions are no longer correct,
  85 ;;  you can hit '!' to recompute the differences.
  86
  87 ;;  2. On a monochrome display, the repertoire of faces with which to
  88 ;;  highlight fine differences is limited.  By default, Ediff is using
  89 ;;  underlining.  However, if the region is already underlined by some other
  90 ;;  overlays, there is no simple way to temporarily remove that residual
  91 ;;  underlining.  This problem occurs when a buffer is highlighted with
  92 ;;  hilit19.el or font-lock.el packages.  If this residual highlighting gets
  93 ;;  in the way, you can do the following.  Both font-lock.el and hilit19.el
  94 ;;  provide commands for unhighlighting buffers.  You can either place these
  95 ;;  commands in `ediff-prepare-buffer-hook' (which will unhighlight every
  96 ;;  buffer used by Ediff) or you can execute them interactively, at any time
  97 ;;  and on any buffer.
  98
  99
 100 ;;; Acknowledgements:
 101
 102 ;; Ediff was inspired by Dale R. Worley's <drw@math.mit.edu> emerge.el.
 103 ;; Ediff would not have been possible without the help and encouragement of
 104 ;; its many users.  See Ediff on-line Info for the full list of those who
 105 ;; helped.  Improved defaults in Ediff file-name reading commands.
 106
 107 ;;; Code:
 108
 109 (provide 'ediff)
 110
 111 ;; Compiler pacifier
 112 (defvar cvs-cookie-handle)
 113 (defvar ediff-last-dir-patch)
 114 (defvar ediff-patch-default-directory)
 115
 116 (and noninteractive
 117      (eval-when-compile
 118          (load-library "dired")
 119          (load-library "info")
 120          (load "pcl-cvs" 'noerror)))
 121 (eval-when-compile
 122   (let ((load-path (cons (expand-file-name ".") load-path)))
 123     (or (featurep 'ediff-init)
 124         (load "ediff-init.el" nil nil 'nosuffix))
 125     (or (featurep 'ediff-mult)
 126         (load "ediff-mult.el" nil nil 'nosuffix))
 127     (or (featurep 'ediff-ptch)
 128         (load "ediff-ptch.el" nil nil 'nosuffix))
 129     (or (featurep 'ediff-vers)
 130         (load "ediff-vers.el" nil nil 'nosuffix))
 131     ))
 132 ;; end pacifier
 133
 134 (require 'ediff-init)
 135 (require 'ediff-mult)  ; required because of the registry stuff
 136
 137 (defgroup ediff nil
 138   "A comprehensive visual interface to diff & patch"
 139   :tag "Ediff"
 140   :group 'tools)
 141
 142
 143 (defcustom ediff-use-last-dir nil
 144   "*If t, Ediff will use previous directory as default when reading file name."
 145   :type 'boolean
 146   :group 'ediff)
 147
 148 ;; Last directory used by an Ediff command for file-A.
 149 (defvar ediff-last-dir-A nil)
 150 ;; Last directory used by an Ediff command for file-B.
 151 (defvar ediff-last-dir-B nil)
 152 ;; Last directory used by an Ediff command for file-C.
 153 (defvar ediff-last-dir-C nil)
 154 ;; Last directory used by an Ediff command for the ancestor file.
 155 (defvar ediff-last-dir-ancestor nil)
 156 ;; Last directory used by an Ediff command as the output directory for merge.
 157 (defvar ediff-last-merge-autostore-dir nil)
 158
 159
 160 ;; Used as a startup hook to set `_orig' patch file read-only.
 161 (defun ediff-set-read-only-in-buf-A ()
 162   (ediff-with-current-buffer ediff-buffer-A
 163     (toggle-read-only 1)))
 164
 165 ;; Return a plausible default for ediff's first file:
 166 ;; In dired, return the file number FILENO (or 0) in the list
 167 ;; (all-selected-files, filename under the cursor), where directories are
 168 ;; ignored. Otherwise, return DEFAULT file name, if non-nil. Else,
 169 ;; if the buffer is visiting a file, return that file name.
 170 (defun ediff-get-default-file-name (&optional default fileno)
 171   (cond ((eq major-mode 'dired-mode)
 172          (let ((current (dired-get-filename nil 'no-error))
 173                (marked (condition-case nil
 174                            (dired-get-marked-files 'no-dir)
 175                          (error nil)))
 176                aux-list choices result)
 177            (or (integerp fileno) (setq fileno 0))
 178            (if (stringp default)
 179                (setq aux-list (cons default aux-list)))
 180            (if (and (stringp current) (not (file-directory-p current)))
 181                (setq aux-list (cons current aux-list)))
 182            (setq choices (nconc  marked aux-list))
 183            (setq result (elt choices fileno))
 184            (or result
 185                default)))
 186         ((stringp default) default)
 187         ((buffer-file-name (current-buffer))
 188          (file-name-nondirectory (buffer-file-name (current-buffer))))
 189         ))
 190
 191 ;;; Compare files/buffers
 192
 193 ;;;###autoload
 194 (defun ediff-files (file-A file-B &optional startup-hooks)
 195   "Run Ediff on a pair of files, FILE-A and FILE-B."
 196   (interactive
 197    (let ((dir-A (if ediff-use-last-dir
 198                     ediff-last-dir-A
 199                   default-directory))
 200          dir-B f)
 201      (list (setq f (ediff-read-file-name
 202                     "File A to compare"
 203                     dir-A
 204                     (ediff-get-default-file-name)
 205                     'no-dirs))
 206            (ediff-read-file-name "File B to compare"
 207                                  (setq dir-B
 208                                        (if ediff-use-last-dir
 209                                            ediff-last-dir-B
 210                                          (file-name-directory f)))
 211                                  (progn
 212                                    (setq file-name-history
 213                                          (cons (ediff-abbreviate-file-name
 214                                                 (expand-file-name
 215                                                  (file-name-nondirectory f)
 216                                                  dir-B))
 217                                                file-name-history))
 218                                    (ediff-get-default-file-name f 1)))
 219            )))
 220   (ediff-files-internal file-A
 221                         (if (file-directory-p file-B)
 222                             (expand-file-name
 223                              (file-name-nondirectory file-A) file-B)
 224                           file-B)
 225                         nil ; file-C
 226                         startup-hooks
 227                         'ediff-files))
 228
 229 ;;;###autoload
 230 (defun ediff-files3 (file-A file-B file-C &optional startup-hooks)
 231   "Run Ediff on three files, FILE-A, FILE-B, and FILE-C."
 232   (interactive
 233    (let ((dir-A (if ediff-use-last-dir
 234                     ediff-last-dir-A
 235                   default-directory))
 236          dir-B dir-C f ff)
 237      (list (setq f (ediff-read-file-name
 238                     "File A to compare"
 239                     dir-A
 240                     (ediff-get-default-file-name)
 241                     'no-dirs))
 242            (setq ff (ediff-read-file-name "File B to compare"
 243                                           (setq dir-B
 244                                                 (if ediff-use-last-dir
 245                                                     ediff-last-dir-B
 246                                                   (file-name-directory f)))
 247                                           (progn
 248                                             (setq file-name-history
 249                                                   (cons
 250                                                    (ediff-abbreviate-file-name
 251                                                     (expand-file-name
 252                                                      (file-name-nondirectory f)
 253                                                      dir-B))
 254                                                    file-name-history))
 255                                             (ediff-get-default-file-name f 1))))
 256            (ediff-read-file-name "File C to compare"
 257                                  (setq dir-C (if ediff-use-last-dir
 258                                                  ediff-last-dir-C
 259                                                (file-name-directory ff)))
 260                                  (progn
 261                                    (setq file-name-history
 262                                          (cons (ediff-abbreviate-file-name
 263                                                 (expand-file-name
 264                                                  (file-name-nondirectory ff)
 265                                                  dir-C))
 266                                                file-name-history))
 267                                    (ediff-get-default-file-name ff 2)))
 268            )))
 269   (ediff-files-internal file-A
 270                         (if (file-directory-p file-B)
 271                             (expand-file-name
 272                              (file-name-nondirectory file-A) file-B)
 273                           file-B)
 274                         (if (file-directory-p file-C)
 275                             (expand-file-name
 276                              (file-name-nondirectory file-A) file-C)
 277                           file-C)
 278                         startup-hooks
 279                         'ediff-files3))
 280
 281 ;;;###autoload
 282 (defalias 'ediff3 'ediff-files3)
 283
 284
 285 ;; Visit FILE and arrange its buffer to Ediff's liking.
 286 ;; FILE is actually a variable symbol that must contain a true file name.
 287 ;; BUFFER-NAME is a variable symbol, which will get the buffer object into
 288 ;; which FILE is read.
 289 ;; LAST-DIR is the directory variable symbol where FILE's
 290 ;; directory name should be returned.  HOOKS-VAR is a variable symbol that will
 291 ;; be assigned the hook to be executed after `ediff-startup' is finished.
 292 ;; `ediff-find-file' arranges that the temp files it might create will be
 293 ;; deleted.
 294 (defun ediff-find-file (file-var buffer-name &optional last-dir hooks-var)
 295   (let* ((file (symbol-value file-var))
 296          (file-magic (ediff-filename-magic-p file))
 297          (temp-file-name-prefix (file-name-nondirectory file)))
 298     (cond ((not (file-readable-p file))
 299            (error "File `%s' does not exist or is not readable" file))
 300           ((file-directory-p file)
 301            (error "File `%s' is a directory" file)))
 302
 303     ;; some of the commands, below, require full file name
 304     (setq file (expand-file-name file))
 305
 306     ;; Record the directory of the file
 307     (if last-dir
 308         (set last-dir (expand-file-name (file-name-directory file))))
 309
 310     ;; Setup the buffer
 311     (set buffer-name (find-file-noselect file))
 312
 313     (ediff-with-current-buffer (symbol-value buffer-name)
 314       (widen) ; Make sure the entire file is seen
 315       (cond (file-magic  ;   file has a handler, such as jka-compr-handler or
 316                          ;;; ange-ftp-hook-function--arrange for temp file
 317              (ediff-verify-file-buffer 'magic)
 318              (setq file
 319                    (ediff-make-temp-file
 320                     (current-buffer) temp-file-name-prefix))
 321              (set hooks-var (cons `(lambda () (delete-file ,file))
 322                                   (symbol-value hooks-var))))
 323             ;; file processed via auto-mode-alist, a la uncompress.el
 324             ((not (equal (file-truename file)
 325                          (file-truename (buffer-file-name))))
 326              (setq file
 327                    (ediff-make-temp-file
 328                     (current-buffer) temp-file-name-prefix))
 329              (set hooks-var (cons `(lambda () (delete-file ,file))
 330                                   (symbol-value hooks-var))))
 331             (t ;; plain file---just check that the file matches the buffer
 332              (ediff-verify-file-buffer))))
 333     (set file-var file)))
 334
 335 ;; MERGE-BUFFER-FILE is the file to be associated with the merge buffer
 336 (defun ediff-files-internal (file-A file-B file-C startup-hooks job-name
 337                                     &optional merge-buffer-file)
 338   (let (buf-A buf-B buf-C)
 339     (if (string= file-A file-B)
 340         (error "Files A and B are the same"))
 341     (if (stringp file-C)
 342         (or (and (string= file-A file-C) (error "Files A and C are the same"))
 343             (and (string= file-B file-C) (error "Files B and C are the same"))))
 344     (message "Reading file %s ... " file-A)
 345     ;;(sit-for 0)
 346     (ediff-find-file 'file-A 'buf-A 'ediff-last-dir-A 'startup-hooks)
 347     (message "Reading file %s ... " file-B)
 348     ;;(sit-for 0)
 349     (ediff-find-file 'file-B 'buf-B 'ediff-last-dir-B 'startup-hooks)
 350     (if (stringp file-C)
 351         (progn
 352           (message "Reading file %s ... " file-C)
 353           ;;(sit-for 0)
 354           (ediff-find-file
 355            'file-C 'buf-C
 356            (if (eq job-name 'ediff-merge-files-with-ancestor)
 357                'ediff-last-dir-ancestor 'ediff-last-dir-C)
 358            'startup-hooks)))
 359     (ediff-setup buf-A file-A
 360                  buf-B file-B
 361                  buf-C file-C
 362                  startup-hooks
 363                  (list (cons 'ediff-job-name job-name))
 364                  merge-buffer-file)))
 365
 366
 367 ;;;###autoload
 368 (defalias 'ediff 'ediff-files)
 369
 370
 371 ;;;###autoload
 372 (defun ediff-buffers (buffer-A buffer-B &optional startup-hooks job-name)
 373   "Run Ediff on a pair of buffers, BUFFER-A and BUFFER-B."
 374   (interactive
 375    (let (bf)
 376      (list (setq bf (read-buffer "Buffer A to compare: "
 377                                  (ediff-other-buffer "") t))
 378            (read-buffer "Buffer B to compare: "
 379                         (progn
 380                           ;; realign buffers so that two visible bufs will be
 381                           ;; at the top
 382                           (save-window-excursion (other-window 1))
 383                           (ediff-other-buffer bf))
 384                         t))))
 385   (or job-name (setq job-name 'ediff-buffers))
 386   (ediff-buffers-internal buffer-A buffer-B nil startup-hooks job-name))
 387
 388 ;;;###autoload
 389 (defalias 'ebuffers 'ediff-buffers)
 390
 391
 392 ;;;###autoload
 393 (defun ediff-buffers3 (buffer-A buffer-B buffer-C
 394                                  &optional startup-hooks job-name)
 395   "Run Ediff on three buffers, BUFFER-A, BUFFER-B, and BUFFER-C."
 396   (interactive
 397    (let (bf bff)
 398      (list (setq bf (read-buffer "Buffer A to compare: "
 399                                  (ediff-other-buffer "") t))
 400            (setq bff (read-buffer "Buffer B to compare: "
 401                                   (progn
 402                                     ;; realign buffers so that two visible
 403                                     ;; bufs will be at the top
 404                                     (save-window-excursion (other-window 1))
 405                                     (ediff-other-buffer bf))
 406                                   t))
 407            (read-buffer "Buffer C to compare: "
 408                                   (progn
 409                                     ;; realign buffers so that three visible
 410                                     ;; bufs will be at the top
 411                                     (save-window-excursion (other-window 1))
 412                                     (ediff-other-buffer (list bf bff)))
 413                                   t)
 414            )))
 415   (or job-name (setq job-name 'ediff-buffers3))
 416   (ediff-buffers-internal buffer-A buffer-B buffer-C startup-hooks job-name))
 417
 418 ;;;###autoload
 419 (defalias 'ebuffers3 'ediff-buffers3)
 420
 421
 422
 423 ;; MERGE-BUFFER-FILE is the file to be associated with the merge buffer
 424 (defun ediff-buffers-internal (buf-A buf-B buf-C startup-hooks job-name
 425                                      &optional merge-buffer-file)
 426   (let* ((buf-A-file-name (buffer-file-name (get-buffer buf-A)))
 427          (buf-B-file-name (buffer-file-name (get-buffer buf-B)))
 428          (buf-C-is-alive (ediff-buffer-live-p buf-C))
 429          (buf-C-file-name (if buf-C-is-alive
 430                               (buffer-file-name (get-buffer buf-B))))
 431          file-A file-B file-C)
 432     (if (not (ediff-buffer-live-p buf-A))
 433         (error "Buffer %S doesn't exist" buf-A))
 434     (if (not (ediff-buffer-live-p buf-B))
 435         (error "Buffer %S doesn't exist" buf-B))
 436     (let ((ediff-job-name job-name))
 437       (if (and ediff-3way-comparison-job
 438                (not buf-C-is-alive))
 439           (error "Buffer %S doesn't exist" buf-C)))
 440     (if (stringp buf-A-file-name)
 441         (setq buf-A-file-name (file-name-nondirectory buf-A-file-name)))
 442     (if (stringp buf-B-file-name)
 443         (setq buf-B-file-name (file-name-nondirectory buf-B-file-name)))
 444     (if (stringp buf-C-file-name)
 445         (setq buf-C-file-name (file-name-nondirectory buf-C-file-name)))
 446
 447     (setq file-A (ediff-make-temp-file buf-A buf-A-file-name)
 448           file-B (ediff-make-temp-file buf-B buf-B-file-name))
 449     (if buf-C-is-alive
 450         (setq file-C (ediff-make-temp-file buf-C buf-C-file-name)))
 451
 452     (ediff-setup (get-buffer buf-A) file-A
 453                  (get-buffer buf-B) file-B
 454                  (if buf-C-is-alive (get-buffer buf-C))
 455                  file-C
 456                  (cons `(lambda ()
 457                           (delete-file ,file-A)
 458                           (delete-file ,file-B)
 459                           (if (stringp ,file-C) (delete-file ,file-C)))
 460                        startup-hooks)
 461                  (list (cons 'ediff-job-name job-name))
 462                  merge-buffer-file)))
 463
 464
 465 ;;; Directory and file group operations
 466
 467 ;; Get appropriate default name for directory:
 468 ;; If ediff-use-last-dir, use ediff-last-dir-A.
 469 ;; In dired mode, use the directory that is under the point (if any);
 470 ;; otherwise, use default-directory
 471 (defun ediff-get-default-directory-name ()
 472   (cond (ediff-use-last-dir ediff-last-dir-A)
 473         ((eq major-mode 'dired-mode)
 474          (let ((f (dired-get-filename nil 'noerror)))
 475            (if (and (stringp f) (file-directory-p f))
 476                f
 477              default-directory)))
 478         (t default-directory)))
 479
 480
 481 ;;;###autoload
 482 (defun ediff-directories (dir1 dir2 regexp)
 483   "Run Ediff on a pair of directories, DIR1 and DIR2, comparing files that have
 484 the same name in both.  The third argument, REGEXP, is a regular expression
 485 that can be used to filter out certain file names."
 486   (interactive
 487    (let ((dir-A (ediff-get-default-directory-name))
 488          f)
 489      (list (setq f (ediff-read-file-name "Directory A to compare:" dir-A nil))
 490            (ediff-read-file-name "Directory B to compare:"
 491                                  (if ediff-use-last-dir
 492                                      ediff-last-dir-B
 493                                    (ediff-strip-last-dir f))
 494                                  nil)
 495            (read-string "Filter through regular expression: "
 496                         nil 'ediff-filtering-regexp-history)
 497            )))
 498   (ediff-directories-internal
 499    dir1 dir2 nil regexp 'ediff-files 'ediff-directories
 500    ))
 501
 502 ;;;###autoload
 503 (defalias 'edirs 'ediff-directories)
 504
 505
 506 ;;;###autoload
 507 (defun ediff-directory-revisions (dir1 regexp)
 508   "Run Ediff on a directory, DIR1, comparing its files with their revisions.
 509 The second argument, REGEXP, is a regular expression that filters the file
 510 names.  Only the files that are under revision control are taken into account."
 511   (interactive
 512    (let ((dir-A (ediff-get-default-directory-name)))
 513      (list (ediff-read-file-name
 514             "Directory to compare with revision:" dir-A nil)
 515            (read-string "Filter through regular expression: "
 516                         nil 'ediff-filtering-regexp-history)
 517            )))
 518   (ediff-directory-revisions-internal
 519    dir1 regexp 'ediff-revision 'ediff-directory-revisions
 520    ))
 521
 522 ;;;###autoload
 523 (defalias 'edir-revisions 'ediff-directory-revisions)
 524
 525
 526 ;;;###autoload
 527 (defun ediff-directories3 (dir1 dir2 dir3 regexp)
 528   "Run Ediff on three directories, DIR1, DIR2, and DIR3, comparing files that
 529 have the same name in all three.  The last argument, REGEXP, is a regular
 530 expression that can be used to filter out certain file names."
 531   (interactive
 532    (let ((dir-A (ediff-get-default-directory-name))
 533          f)
 534      (list (setq f (ediff-read-file-name "Directory A to compare:" dir-A nil))
 535            (setq f (ediff-read-file-name "Directory B to compare:"
 536                                          (if ediff-use-last-dir
 537                                              ediff-last-dir-B
 538                                            (ediff-strip-last-dir f))
 539                                          nil))
 540            (ediff-read-file-name "Directory C to compare:"
 541                                  (if ediff-use-last-dir
 542                                      ediff-last-dir-C
 543                                    (ediff-strip-last-dir f))
 544                                  nil)
 545            (read-string "Filter through regular expression: "
 546                         nil 'ediff-filtering-regexp-history)
 547            )))
 548   (ediff-directories-internal
 549    dir1 dir2 dir3 regexp 'ediff-files3 'ediff-directories3
 550    ))
 551
 552 ;;;###autoload
 553 (defalias 'edirs3 'ediff-directories3)
 554
 555 ;;;###autoload
 556 (defun ediff-merge-directories (dir1 dir2 regexp &optional merge-autostore-dir)
 557   "Run Ediff on a pair of directories, DIR1 and DIR2, merging files that have
 558 the same name in both.  The third argument, REGEXP, is a regular expression
 559 that can be used to filter out certain file names."
 560   (interactive
 561    (let ((dir-A (ediff-get-default-directory-name))
 562          f)
 563      (list (setq f (ediff-read-file-name "Directory A to merge:" dir-A nil))
 564            (ediff-read-file-name "Directory B to merge:"
 565                                  (if ediff-use-last-dir
 566                                      ediff-last-dir-B
 567                                    (ediff-strip-last-dir f))
 568                                  nil)
 569            (read-string "Filter through regular expression: "
 570                         nil 'ediff-filtering-regexp-history)
 571            )))
 572   (ediff-directories-internal
 573    dir1 dir2 nil regexp 'ediff-merge-files 'ediff-merge-directories
 574    nil merge-autostore-dir
 575    ))
 576
 577 ;;;###autoload
 578 (defalias 'edirs-merge 'ediff-merge-directories)
 579
 580 ;;;###autoload
 581 (defun ediff-merge-directories-with-ancestor (dir1 dir2 ancestor-dir regexp
 582                                                    &optional
 583                                                    merge-autostore-dir)
 584   "Merge files in directories DIR1 and DIR2 using files in ANCESTOR-DIR as ancestors.
 585 Ediff merges files that have identical names in DIR1, DIR2.  If a pair of files
 586 in DIR1 and DIR2 doesn't have an ancestor in ANCESTOR-DIR, Ediff will merge
 587 without ancestor.  The fourth argument, REGEXP, is a regular expression that
 588 can be used to filter out certain file names."
 589   (interactive
 590    (let ((dir-A (ediff-get-default-directory-name))
 591          f)
 592      (list (setq f (ediff-read-file-name "Directory A to merge:" dir-A nil))
 593            (setq f (ediff-read-file-name "Directory B to merge:"
 594                                  (if ediff-use-last-dir
 595                                      ediff-last-dir-B
 596                                    (ediff-strip-last-dir f))
 597                                  nil))
 598            (ediff-read-file-name "Ancestor directory:"
 599                                  (if ediff-use-last-dir
 600                                      ediff-last-dir-C
 601                                    (ediff-strip-last-dir f))
 602                                  nil)
 603            (read-string "Filter through regular expression: "
 604                         nil 'ediff-filtering-regexp-history)
 605            )))
 606   (ediff-directories-internal
 607    dir1 dir2 ancestor-dir regexp
 608    'ediff-merge-files-with-ancestor 'ediff-merge-directories-with-ancestor
 609    nil merge-autostore-dir
 610    ))
 611
 612 ;;;###autoload
 613 (defun ediff-merge-directory-revisions (dir1 regexp
 614                                              &optional merge-autostore-dir)
 615   "Run Ediff on a directory, DIR1, merging its files with their revisions.
 616 The second argument, REGEXP, is a regular expression that filters the file
 617 names.  Only the files that are under revision control are taken into account."
 618   (interactive
 619    (let ((dir-A (ediff-get-default-directory-name)))
 620      (list (ediff-read-file-name
 621             "Directory to merge with revisions:" dir-A nil)
 622            (read-string "Filter through regular expression: "
 623                         nil 'ediff-filtering-regexp-history)
 624            )))
 625   (ediff-directory-revisions-internal
 626    dir1 regexp 'ediff-merge-revisions 'ediff-merge-directory-revisions
 627    nil merge-autostore-dir
 628    ))
 629
 630 ;;;###autoload
 631 (defalias 'edir-merge-revisions 'ediff-merge-directory-revisions)
 632
 633 ;;;###autoload
 634 (defun ediff-merge-directory-revisions-with-ancestor (dir1 regexp
 635                                                            &optional
 636                                                            merge-autostore-dir)
 637   "Run Ediff on a directory, DIR1, merging its files with their revisions and ancestors.
 638 The second argument, REGEXP, is a regular expression that filters the file
 639 names.  Only the files that are under revision control are taken into account."
 640   (interactive
 641    (let ((dir-A (ediff-get-default-directory-name)))
 642      (list (ediff-read-file-name
 643             "Directory to merge with revisions and ancestors:" dir-A nil)
 644            (read-string "Filter through regular expression: "
 645                         nil 'ediff-filtering-regexp-history)
 646            )))
 647   (ediff-directory-revisions-internal
 648    dir1 regexp 'ediff-merge-revisions-with-ancestor
 649    'ediff-merge-directory-revisions-with-ancestor
 650    nil merge-autostore-dir
 651    ))
 652
 653 ;;;###autoload
 654 (defalias
 655   'edir-merge-revisions-with-ancestor
 656   'ediff-merge-directory-revisions-with-ancestor)
 657
 658 ;;;###autoload
 659 (defalias 'edirs-merge-with-ancestor 'ediff-merge-directories-with-ancestor)
 660
 661 ;; Run ediff-action (ediff-files, ediff-merge, ediff-merge-with-ancestors)
 662 ;; on a pair of directories (three directories, in case of ancestor).
 663 ;; The third argument, REGEXP, is a regular expression that can be used to
 664 ;; filter out certain file names.
 665 ;; JOBNAME is the symbol indicating the meta-job to be performed.
 666 ;; MERGE-AUTOSTORE-DIR is the directory in which to store merged files.
 667 (defun ediff-directories-internal (dir1 dir2 dir3 regexp action jobname
 668                                         &optional startup-hooks
 669                                         merge-autostore-dir)
 670   ;; ediff-read-file-name is set to attach a previously entered file name if
 671   ;; the currently entered file is a directory.  This code takes care of that.
 672   (setq dir1 (if (file-directory-p dir1) dir1 (file-name-directory dir1))
 673         dir2 (if (file-directory-p dir2) dir2 (file-name-directory dir2)))
 674
 675   (if (stringp dir3)
 676       (setq dir3 (if (file-directory-p dir3) dir3 (file-name-directory dir3))))
 677
 678   (cond ((string= dir1 dir2)
 679          (error "Directories A and B are the same: %s" dir1))
 680         ((and (eq jobname 'ediff-directories3)
 681               (string= dir1 dir3))
 682          (error "Directories A and C are the same: %s" dir1))
 683         ((and (eq jobname 'ediff-directories3)
 684               (string= dir2 dir3))
 685          (error "Directories B and C are the same: %s" dir1)))
 686
 687   (if merge-autostore-dir
 688       (or (stringp merge-autostore-dir)
 689           (error "%s: Directory for storing merged files must be a string"
 690                  jobname)))
 691   (let (;; dir-diff-struct is of the form (common-list diff-list)
 692         ;; It is a structure where ediff-intersect-directories returns
 693         ;; commonalities and differences among directories
 694         dir-diff-struct
 695         meta-buf)
 696     (if (and ediff-autostore-merges
 697              (ediff-merge-metajob jobname)
 698              (not merge-autostore-dir))
 699         (setq merge-autostore-dir
 700               (read-file-name "Save merged files in directory: "
 701                               (if ediff-use-last-dir
 702                                         ediff-last-merge-autostore-dir
 703                                       (ediff-strip-last-dir dir1))
 704                               nil
 705                               'must-match)))
 706     ;; verify we are not merging into an orig directory
 707     (if merge-autostore-dir
 708         (cond ((and (stringp dir1) (string= merge-autostore-dir dir1))
 709                (or (y-or-n-p
 710                     "Directory for saving merged files = Directory A.  Sure? ")
 711                    (error "Directory merge aborted")))
 712               ((and (stringp dir2) (string= merge-autostore-dir dir2))
 713                (or (y-or-n-p
 714                     "Directory for saving merged files = Directory B.  Sure? ")
 715                    (error "Directory merge aborted")))
 716               ((and (stringp dir3) (string= merge-autostore-dir dir3))
 717                (or (y-or-n-p
 718                     "Directory for saving merged files = Ancestor Directory.  Sure? ")
 719                    (error "Directory merge aborted")))))
 720
 721     (setq dir-diff-struct (ediff-intersect-directories
 722                            jobname
 723                            regexp dir1 dir2 dir3 merge-autostore-dir))
 724     (setq startup-hooks
 725           ;; this sets various vars in the meta buffer inside
 726           ;; ediff-prepare-meta-buffer
 727           (cons `(lambda ()
 728                    ;; tell what to do if the user clicks on a session record
 729                    (setq ediff-session-action-function (quote ,action))
 730                    ;; set ediff-dir-difference-list
 731                    (setq ediff-dir-difference-list
 732                          (cdr (quote ,dir-diff-struct))))
 733                 startup-hooks))
 734     (setq meta-buf (ediff-prepare-meta-buffer
 735                     'ediff-filegroup-action
 736                     (car dir-diff-struct)
 737                     "*Ediff Session Group Panel"
 738                     'ediff-redraw-directory-group-buffer
 739                     jobname
 740                     startup-hooks))
 741     (ediff-show-meta-buffer meta-buf)
 742     ))
 743
 744 ;; MERGE-AUTOSTORE-DIR can be given to tell ediff where to store the merged
 745 ;; files
 746 (defun ediff-directory-revisions-internal (dir1 regexp action jobname
 747                                                 &optional startup-hooks
 748                                                 merge-autostore-dir)
 749   (setq dir1 (if (file-directory-p dir1) dir1 (file-name-directory dir1)))
 750
 751   (if merge-autostore-dir
 752       (or (stringp merge-autostore-dir)
 753           (error "%S: Directory for storing merged files must be a string"
 754                  jobname)))
 755   (let (file-list meta-buf)
 756     (if (and ediff-autostore-merges
 757              (ediff-merge-metajob jobname)
 758              (not merge-autostore-dir))
 759         (setq merge-autostore-dir
 760               (read-file-name "Save merged files in directory: "
 761                               (if ediff-use-last-dir
 762                                   ediff-last-merge-autostore-dir
 763                                 (ediff-strip-last-dir dir1))
 764                               nil
 765                               'must-match)))
 766     ;; verify merge-autostore-dir != dir1
 767     (if (and merge-autostore-dir
 768              (stringp dir1)
 769              (string= merge-autostore-dir dir1))
 770         (or (y-or-n-p
 771              "Directory for saving merged file = directory A.  Sure? ")
 772             (error "Merge of directory revisions aborted")))
 773
 774     (setq file-list
 775           (ediff-get-directory-files-under-revision
 776            jobname regexp dir1 merge-autostore-dir))
 777     (setq startup-hooks
 778           ;; this sets various vars in the meta buffer inside
 779           ;; ediff-prepare-meta-buffer
 780           (cons `(lambda ()
 781                    ;; tell what to do if the user clicks on a session record
 782                    (setq ediff-session-action-function (quote ,action)))
 783                 startup-hooks))
 784     (setq meta-buf (ediff-prepare-meta-buffer
 785                     'ediff-filegroup-action
 786                     file-list
 787                     "*Ediff Session Group Panel"
 788                     'ediff-redraw-directory-group-buffer
 789                     jobname
 790                     startup-hooks))
 791     (ediff-show-meta-buffer meta-buf)
 792     ))
 793
 794
 795 ;;; Compare regions and windows
 796
 797 ;;;###autoload
 798 (defun ediff-windows-wordwise (dumb-mode &optional wind-A wind-B startup-hooks)
 799   "Compare WIND-A and WIND-B, which are selected by clicking, wordwise.
 800 With prefix argument, DUMB-MODE, or on a non-windowing display, works as
 801 follows:
 802 If WIND-A is nil, use selected window.
 803 If WIND-B is nil, use window next to WIND-A."
 804   (interactive "P")
 805   (ediff-windows dumb-mode wind-A wind-B
 806                  startup-hooks 'ediff-windows-wordwise 'word-mode))
 807
 808 ;;;###autoload
 809 (defun ediff-windows-linewise (dumb-mode &optional wind-A wind-B startup-hooks)
 810   "Compare WIND-A and WIND-B, which are selected by clicking, linewise.
 811 With prefix argument, DUMB-MODE, or on a non-windowing display, works as
 812 follows:
 813 If WIND-A is nil, use selected window.
 814 If WIND-B is nil, use window next to WIND-A."
 815   (interactive "P")
 816   (ediff-windows dumb-mode wind-A wind-B
 817                  startup-hooks 'ediff-windows-linewise nil))
 818
 819 ;; Compare WIND-A and WIND-B, which are selected by clicking.
 820 ;; With prefix argument, DUMB-MODE, or on a non-windowing display,
 821 ;; works as follows:
 822 ;; If WIND-A is nil, use selected window.
 823 ;; If WIND-B is nil, use window next to WIND-A.
 824 (defun ediff-windows (dumb-mode wind-A wind-B startup-hooks job-name word-mode)
 825   (if (or dumb-mode (not (ediff-window-display-p)))
 826       (setq wind-A (ediff-get-next-window wind-A nil)
 827             wind-B (ediff-get-next-window wind-B wind-A))
 828     (setq wind-A (ediff-get-window-by-clicking wind-A nil 1)
 829           wind-B (ediff-get-window-by-clicking wind-B wind-A 2)))
 830
 831   (let ((buffer-A (window-buffer wind-A))
 832         (buffer-B (window-buffer wind-B))
 833         beg-A end-A beg-B end-B)
 834
 835     (save-excursion
 836       (save-window-excursion
 837         (sit-for 0) ; sync before using window-start/end -- a precaution
 838         (select-window wind-A)
 839         (setq beg-A (window-start)
 840               end-A (window-end))
 841         (select-window wind-B)
 842         (setq beg-B (window-start)
 843               end-B (window-end))))
 844     (setq buffer-A
 845           (ediff-clone-buffer-for-window-comparison
 846            buffer-A wind-A "-Window.A-")
 847           buffer-B
 848           (ediff-clone-buffer-for-window-comparison
 849            buffer-B wind-B "-Window.B-"))
 850     (ediff-regions-internal
 851      buffer-A beg-A end-A buffer-B beg-B end-B
 852      startup-hooks job-name word-mode nil)))
 853
 854
 855 ;;;###autoload
 856 (defun ediff-regions-wordwise (buffer-A buffer-B &optional startup-hooks)
 857   "Run Ediff on a pair of regions in specified buffers.
 858 Regions \(i.e., point and mark\) are assumed to be set in advance except
 859 for the second region in the case both regions are from the same buffer.
 860 In such a case the user is asked to interactively establish the second
 861 region.
 862 This function is effective only for relatively small regions, up to 200
 863 lines.  For large regions, use `ediff-regions-linewise'."
 864   (interactive
 865    (let (bf)
 866      (list (setq bf (read-buffer "Region's A buffer: "
 867                                  (ediff-other-buffer "") t))
 868            (read-buffer "Region's B buffer: "
 869                         (progn
 870                           ;; realign buffers so that two visible bufs will be
 871                           ;; at the top
 872                           (save-window-excursion (other-window 1))
 873                           (ediff-other-buffer bf))
 874                         t))))
 875   (if (not (ediff-buffer-live-p buffer-A))
 876       (error "Buffer %S doesn't exist" buffer-A))
 877   (if (not (ediff-buffer-live-p buffer-B))
 878       (error "Buffer %S doesn't exist" buffer-B))
 879
 880
 881   (let ((buffer-A
 882          (ediff-clone-buffer-for-region-comparison buffer-A "-Region.A-"))
 883         (buffer-B
 884          (ediff-clone-buffer-for-region-comparison buffer-B "-Region.B-"))
 885         reg-A-beg reg-A-end reg-B-beg reg-B-end)
 886     (save-excursion
 887       (set-buffer buffer-A)
 888       (setq reg-A-beg (region-beginning)
 889             reg-A-end (region-end))
 890       (set-buffer buffer-B)
 891       (setq reg-B-beg (region-beginning)
 892             reg-B-end (region-end)))
 893
 894     (ediff-regions-internal
 895      (get-buffer buffer-A) reg-A-beg reg-A-end
 896      (get-buffer buffer-B) reg-B-beg reg-B-end
 897      startup-hooks 'ediff-regions-wordwise 'word-mode nil)))
 898
 899 ;;;###autoload
 900 (defun ediff-regions-linewise (buffer-A buffer-B &optional startup-hooks)
 901   "Run Ediff on a pair of regions in specified buffers.
 902 Regions \(i.e., point and mark\) are assumed to be set in advance except
 903 for the second region in the case both regions are from the same buffer.
 904 In such a case the user is asked to interactively establish the second
 905 region.
 906 Each region is enlarged to contain full lines.
 907 This function is effective for large regions, over 100-200
 908 lines.  For small regions, use `ediff-regions-wordwise'."
 909   (interactive
 910    (let (bf)
 911      (list (setq bf (read-buffer "Region A's buffer: "
 912                                  (ediff-other-buffer "") t))
 913            (read-buffer "Region B's buffer: "
 914                         (progn
 915                           ;; realign buffers so that two visible bufs will be
 916                           ;; at the top
 917                           (save-window-excursion (other-window 1))
 918                           (ediff-other-buffer bf))
 919                         t))))
 920   (if (not (ediff-buffer-live-p buffer-A))
 921       (error "Buffer %S doesn't exist" buffer-A))
 922   (if (not (ediff-buffer-live-p buffer-B))
 923       (error "Buffer %S doesn't exist" buffer-B))
 924
 925   (let ((buffer-A
 926          (ediff-clone-buffer-for-region-comparison buffer-A "-Region.A-"))
 927         (buffer-B
 928          (ediff-clone-buffer-for-region-comparison buffer-B "-Region.B-"))
 929         reg-A-beg reg-A-end reg-B-beg reg-B-end)
 930     (save-excursion
 931       (set-buffer buffer-A)
 932       (setq reg-A-beg (region-beginning)
 933             reg-A-end (region-end))
 934       ;; enlarge the region to hold full lines
 935       (goto-char reg-A-beg)
 936       (beginning-of-line)
 937       (setq reg-A-beg (point))
 938       (goto-char reg-A-end)
 939       (end-of-line)
 940       (or (eobp) (forward-char)) ; include the newline char
 941       (setq reg-A-end (point))
 942
 943       (set-buffer buffer-B)
 944       (setq reg-B-beg (region-beginning)
 945             reg-B-end (region-end))
 946       ;; enlarge the region to hold full lines
 947       (goto-char reg-B-beg)
 948       (beginning-of-line)
 949       (setq reg-B-beg (point))
 950       (goto-char reg-B-end)
 951       (end-of-line)
 952       (or (eobp) (forward-char)) ; include the newline char
 953       (setq reg-B-end (point))
 954       ) ; save excursion
 955
 956     (ediff-regions-internal
 957      (get-buffer buffer-A) reg-A-beg reg-A-end
 958      (get-buffer buffer-B) reg-B-beg reg-B-end
 959      startup-hooks 'ediff-regions-linewise nil nil))) ; no word mode
 960
 961 ;; compare region beg-A to end-A of buffer-A
 962 ;; to regions beg-B -- end-B in buffer-B.
 963 (defun ediff-regions-internal (buffer-A beg-A end-A buffer-B beg-B end-B
 964                                         startup-hooks job-name word-mode
 965                                         setup-parameters)
 966   (let ((tmp-buffer (get-buffer-create ediff-tmp-buffer))
 967         overl-A overl-B
 968         file-A file-B)
 969
 970     ;; in case beg/end-A/B aren't markers--make them into markers
 971     (ediff-with-current-buffer buffer-A
 972       (setq beg-A (move-marker (make-marker) beg-A)
 973             end-A (move-marker (make-marker) end-A)))
 974     (ediff-with-current-buffer buffer-B
 975       (setq beg-B (move-marker (make-marker) beg-B)
 976             end-B (move-marker (make-marker) end-B)))
 977
 978     ;; make file-A
 979     (if word-mode
 980         (ediff-wordify beg-A end-A buffer-A tmp-buffer)
 981       (ediff-copy-to-buffer beg-A end-A buffer-A tmp-buffer))
 982     (setq file-A (ediff-make-temp-file tmp-buffer "regA"))
 983
 984     ;; make file-B
 985     (if word-mode
 986         (ediff-wordify beg-B end-B buffer-B tmp-buffer)
 987       (ediff-copy-to-buffer beg-B end-B buffer-B tmp-buffer))
 988     (setq file-B (ediff-make-temp-file tmp-buffer "regB"))
 989
 990     (setq overl-A (ediff-make-bullet-proof-overlay beg-A end-A buffer-A))
 991     (setq overl-B (ediff-make-bullet-proof-overlay beg-B end-B buffer-B))
 992     (ediff-setup buffer-A file-A
 993                  buffer-B file-B
 994                  nil nil            ; buffer & file C
 995                  (cons `(lambda ()
 996                             (delete-file ,file-A)
 997                             (delete-file ,file-B))
 998                        startup-hooks)
 999                  (append
1000                   (list (cons 'ediff-word-mode  word-mode)
1001                         (cons 'ediff-narrow-bounds (list overl-A overl-B))
1002                         (cons 'ediff-job-name job-name))
1003                   setup-parameters))
1004     ))
1005
1006
1007 ;;; Merge files and buffers
1008
1009 ;;;###autoload
1010 (defalias 'ediff-merge 'ediff-merge-files)
1011
1012 (defsubst ediff-merge-on-startup ()
1013   (ediff-do-merge 0)
1014   (ediff-with-current-buffer ediff-buffer-C
1015     (set-buffer-modified-p nil)))
1016
1017 ;;;###autoload
1018 (defun ediff-merge-files (file-A file-B
1019                                  ;; MERGE-BUFFER-FILE is the file to be
1020                                  ;; associated with the merge buffer
1021                                  &optional startup-hooks merge-buffer-file)
1022   "Merge two files without ancestor."
1023   (interactive
1024    (let ((dir-A (if ediff-use-last-dir
1025                     ediff-last-dir-A
1026                   default-directory))
1027          dir-B f)
1028      (list (setq f (ediff-read-file-name
1029                     "File A to merge"
1030                     dir-A
1031                     (ediff-get-default-file-name)
1032                     'no-dirs))
1033            (ediff-read-file-name "File B to merge"
1034                                  (setq dir-B
1035                                        (if ediff-use-last-dir
1036                                            ediff-last-dir-B
1037                                          (file-name-directory f)))
1038                                  (progn
1039                                    (setq file-name-history
1040                                          (cons (ediff-abbreviate-file-name
1041                                                 (expand-file-name
1042                                                  (file-name-nondirectory f)
1043                                                  dir-B))
1044                                                file-name-history))
1045                                    (ediff-get-default-file-name f 1)))
1046            )))
1047   (setq startup-hooks (cons 'ediff-merge-on-startup startup-hooks))
1048   (ediff-files-internal file-A
1049                         (if (file-directory-p file-B)
1050                             (expand-file-name
1051                              (file-name-nondirectory file-A) file-B)
1052                           file-B)
1053                           nil ; file-C
1054                           startup-hooks
1055                           'ediff-merge-files
1056                           merge-buffer-file))
1057
1058 ;;;###autoload
1059 (defun ediff-merge-files-with-ancestor (file-A file-B file-ancestor
1060                                                &optional
1061                                                startup-hooks
1062                                                ;; MERGE-BUFFER-FILE is the file
1063                                                ;; to be associated with the
1064                                                ;; merge buffer
1065                                                merge-buffer-file)
1066   "Merge two files with ancestor."
1067   (interactive
1068    (let ((dir-A (if ediff-use-last-dir
1069                     ediff-last-dir-A
1070                   default-directory))
1071          dir-B dir-ancestor f ff)
1072      (list (setq f (ediff-read-file-name
1073                     "File A to merge"
1074                     dir-A
1075                     (ediff-get-default-file-name)
1076                     'no-dirs))
1077            (setq ff (ediff-read-file-name "File B to merge"
1078                                           (setq dir-B
1079                                                 (if ediff-use-last-dir
1080                                                     ediff-last-dir-B
1081                                                   (file-name-directory f)))
1082                                           (progn
1083                                             (setq file-name-history
1084                                                   (cons
1085                                                    (ediff-abbreviate-file-name
1086                                                     (expand-file-name
1087                                                      (file-name-nondirectory f)
1088                                                      dir-B))
1089                                                    file-name-history))
1090                                             (ediff-get-default-file-name f 1))))
1091            (ediff-read-file-name "Ancestor file"
1092                                  (setq dir-ancestor
1093                                        (if ediff-use-last-dir
1094                                            ediff-last-dir-ancestor
1095                                          (file-name-directory ff)))
1096                                  (progn
1097                                    (setq file-name-history
1098                                          (cons (ediff-abbreviate-file-name
1099                                                 (expand-file-name
1100                                                  (file-name-nondirectory ff)
1101                                                  dir-ancestor))
1102                                                file-name-history))
1103                                    (ediff-get-default-file-name ff 2)))
1104            )))
1105   (setq startup-hooks (cons 'ediff-merge-on-startup startup-hooks))
1106   (ediff-files-internal file-A
1107                         (if (file-directory-p file-B)
1108                             (expand-file-name
1109                              (file-name-nondirectory file-A) file-B)
1110                           file-B)
1111                           file-ancestor
1112                           startup-hooks
1113                           'ediff-merge-files-with-ancestor
1114                           merge-buffer-file))
1115
1116 ;;;###autoload
1117 (defalias 'ediff-merge-with-ancestor 'ediff-merge-files-with-ancestor)
1118
1119 ;;;###autoload
1120 (defun ediff-merge-buffers (buffer-A buffer-B
1121                                      &optional
1122                                      ;; MERGE-BUFFER-FILE is the file to be
1123                                      ;; associated with the merge buffer
1124                                      startup-hooks job-name merge-buffer-file)
1125   "Merge buffers without ancestor."
1126   (interactive
1127    (let (bf)
1128      (list (setq bf (read-buffer "Buffer A to merge: "
1129                                  (ediff-other-buffer "") t))
1130            (read-buffer "Buffer B to merge: "
1131                         (progn
1132                           ;; realign buffers so that two visible bufs will be
1133                           ;; at the top
1134                           (save-window-excursion (other-window 1))
1135                           (ediff-other-buffer bf))
1136                         t))))
1137
1138   (setq startup-hooks (cons 'ediff-merge-on-startup startup-hooks))
1139   (or job-name (setq job-name 'ediff-merge-buffers))
1140   (ediff-buffers-internal
1141    buffer-A buffer-B nil startup-hooks job-name merge-buffer-file))
1142
1143 ;;;###autoload
1144 (defun ediff-merge-buffers-with-ancestor (buffer-A buffer-B buffer-ancestor
1145                                                    &optional
1146                                                    startup-hooks
1147                                                    job-name
1148                                                    ;; MERGE-BUFFER-FILE is the
1149                                                    ;; file to be associated
1150                                                    ;; with the merge buffer
1151                                                    merge-buffer-file)
1152   "Merge buffers with ancestor."
1153   (interactive
1154    (let (bf bff)
1155      (list (setq bf (read-buffer "Buffer A to merge: "
1156                                  (ediff-other-buffer "") t))
1157            (setq bff (read-buffer "Buffer B to merge: "
1158                                   (progn
1159                                     ;; realign buffers so that two visible
1160                                     ;; bufs will be at the top
1161                                     (save-window-excursion (other-window 1))
1162                                     (ediff-other-buffer bf))
1163                                   t))
1164            (read-buffer "Ancestor buffer: "
1165                                   (progn
1166                                     ;; realign buffers so that three visible
1167                                     ;; bufs will be at the top
1168                                     (save-window-excursion (other-window 1))
1169                                     (ediff-other-buffer (list bf bff)))
1170                                   t)
1171            )))
1172
1173   (setq startup-hooks (cons 'ediff-merge-on-startup startup-hooks))
1174   (or job-name (setq job-name 'ediff-merge-buffers-with-ancestor))
1175   (ediff-buffers-internal
1176    buffer-A buffer-B buffer-ancestor startup-hooks job-name merge-buffer-file))
1177
1178
1179 ;;;###autoload
1180 (defun ediff-merge-revisions (&optional file startup-hooks merge-buffer-file)
1181   ;; MERGE-BUFFER-FILE is the file to be associated with the merge buffer
1182   "Run Ediff by merging two revisions of a file.
1183 The file is the optional FILE argument or the file visited by the current
1184 buffer."
1185   (interactive)
1186   (if (stringp file) (find-file file))
1187   (let (rev1 rev2)
1188     (setq rev1
1189           (read-string
1190            (format
1191             "Version 1 to merge (default: %s's working version): "
1192             (if (stringp file)
1193                 (file-name-nondirectory file) "current buffer")))
1194           rev2
1195           (read-string
1196            (format
1197             "Version 2 to merge (default: %s): "
1198             (if (stringp file)
1199                 (file-name-nondirectory file) "current buffer"))))
1200     (ediff-load-version-control)
1201     ;; ancestor-revision=nil
1202     (funcall
1203      (intern (format "ediff-%S-merge-internal" ediff-version-control-package))
1204      rev1 rev2 nil startup-hooks merge-buffer-file)))
1205
1206
1207 ;;;###autoload
1208 (defun ediff-merge-revisions-with-ancestor (&optional
1209                                             file startup-hooks
1210                                             ;; MERGE-BUFFER-FILE is the file to
1211                                             ;; be associated with the merge
1212                                             ;; buffer
1213                                             merge-buffer-file)
1214   "Run Ediff by merging two revisions of a file with a common ancestor.
1215 The file is the optional FILE argument or the file visited by the current
1216 buffer."
1217   (interactive)
1218   (if (stringp file) (find-file file))
1219   (let (rev1 rev2 ancestor-rev)
1220     (setq rev1
1221           (read-string
1222            (format
1223             "Version 1 to merge (default: %s's working version): "
1224             (if (stringp file)
1225                 (file-name-nondirectory file) "current buffer")))
1226           rev2
1227           (read-string
1228            (format
1229             "Version 2 to merge (default: %s): "
1230             (if (stringp file)
1231                 (file-name-nondirectory file) "current buffer")))
1232           ancestor-rev
1233           (read-string
1234            (format
1235             "Ancestor version (default: %s's base revision): "
1236             (if (stringp file)
1237                 (file-name-nondirectory file) "current buffer"))))
1238     (ediff-load-version-control)
1239     (funcall
1240      (intern (format "ediff-%S-merge-internal" ediff-version-control-package))
1241      rev1 rev2 ancestor-rev startup-hooks merge-buffer-file)))
1242
1243 ;; MK: Check. This function doesn't seem to be used any more by pcvs or pcl-cvs
1244 ;;;###autoload
1245 (defun run-ediff-from-cvs-buffer (pos)
1246   "Run Ediff-merge on appropriate revisions of the selected file.
1247 First run after `M-x cvs-update'.  Then place the cursor on a line describing a
1248 file and then run `run-ediff-from-cvs-buffer'."
1249   (interactive "d")
1250   (ediff-load-version-control)
1251   (let ((tin (tin-locate cvs-cookie-handle pos)))
1252     (if tin
1253         (cvs-run-ediff-on-file-descriptor tin)
1254       (error "There is no file to merge"))))
1255
1256
1257 ;;; Apply patch
1258
1259 ;;;###autoload
1260 (defun ediff-patch-file (&optional arg patch-buf)
1261   "Run Ediff by patching SOURCE-FILENAME.
1262 If optional PATCH-BUF is given, use the patch in that buffer
1263 and don't ask the user.
1264 If prefix argument, then: if even argument, assume that the patch is in a
1265 buffer. If odd -- assume it is in a file."
1266   (interactive "P")
1267   (let (source-dir source-file)
1268     (require 'ediff-ptch)
1269     (setq patch-buf
1270           (ediff-get-patch-buffer
1271            (if arg (prefix-numeric-value arg)) patch-buf))
1272     (setq source-dir (cond (ediff-use-last-dir ediff-last-dir-patch)
1273                            ((and (not ediff-patch-default-directory)
1274                                  (buffer-file-name patch-buf))
1275                             (file-name-directory
1276                              (expand-file-name
1277                               (buffer-file-name patch-buf))))
1278                            (t default-directory)))
1279     (setq source-file
1280           (read-file-name
1281            "File to patch (directory, if multifile patch): "
1282            ;; use an explicit initial file
1283            source-dir nil nil (ediff-get-default-file-name)))
1284     (ediff-dispatch-file-patching-job patch-buf source-file)))
1285
1286 ;;;###autoload
1287 (defun ediff-patch-buffer (&optional arg patch-buf)
1288   "Run Ediff by patching BUFFER-NAME.
1289 Without prefix argument: asks if the patch is in some buffer and prompts for
1290 the buffer or a file, depending on the answer.
1291 With prefix arg=1: assumes the patch is in a file and prompts for the file.
1292 With prefix arg=2: assumes the patch is in a buffer and prompts for the buffer."
1293   (interactive "P")
1294   (require 'ediff-ptch)
1295   (setq patch-buf
1296         (ediff-get-patch-buffer
1297          (if arg (prefix-numeric-value arg)) patch-buf))
1298   (ediff-patch-buffer-internal
1299    patch-buf
1300    (read-buffer
1301     "Which buffer to patch? "
1302     (current-buffer))))
1303
1304
1305 ;;;###autoload
1306 (defalias 'epatch 'ediff-patch-file)
1307 ;;;###autoload
1308 (defalias 'epatch-buffer 'ediff-patch-buffer)
1309
1310
1311
1312 \f
1313 ;;; Versions Control functions
1314
1315 ;;;###autoload
1316 (defun ediff-revision (&optional file startup-hooks)
1317   "Run Ediff by comparing versions of a file.
1318 The file is an optional FILE argument or the file entered at the prompt.
1319 Default: the file visited by the current buffer.
1320 Uses `vc.el' or `rcs.el' depending on `ediff-version-control-package'."
1321   ;; if buffer is non-nil, use that buffer instead of the current buffer
1322   (interactive "P")
1323   (if (not (stringp file))
1324     (setq file
1325           (ediff-read-file-name "Compare revisions for file"
1326                                 (if ediff-use-last-dir
1327                                     ediff-last-dir-A
1328                                   default-directory)
1329                                 (ediff-get-default-file-name)
1330                                 'no-dirs)))
1331   (find-file file)
1332   (if (and (buffer-modified-p)
1333            (y-or-n-p (message "Buffer %s is modified. Save buffer? "
1334                               (buffer-name))))
1335       (save-buffer (current-buffer)))
1336   (let (rev1 rev2)
1337     (setq rev1
1338           (read-string
1339            (format "Version 1 to compare (default: %s's working version): "
1340                    (file-name-nondirectory file)))
1341           rev2
1342           (read-string
1343            (format "Version 2 to compare (default: %s): "
1344                    (file-name-nondirectory file))))
1345     (ediff-load-version-control)
1346     (funcall
1347      (intern (format "ediff-%S-internal" ediff-version-control-package))
1348      rev1 rev2 startup-hooks)
1349     ))
1350
1351
1352 ;;;###autoload
1353 (defalias 'erevision 'ediff-revision)
1354
1355
1356 ;; Test if version control package is loaded and load if not
1357 ;; Is SILENT is non-nil, don't report error if package is not found.
1358 (defun ediff-load-version-control (&optional silent)
1359   (require 'ediff-vers)
1360   (or (featurep ediff-version-control-package)
1361       (if (locate-library (symbol-name ediff-version-control-package))
1362           (progn
1363             (message "") ; kill the message from `locate-library'
1364             (require ediff-version-control-package))
1365         (or silent
1366             (error "Version control package %S.el not found.  Use vc.el instead"
1367                    ediff-version-control-package)))))
1368
1369
1370 ;;;###autoload
1371 (defun ediff-version ()
1372   "Return string describing the version of Ediff.
1373 When called interactively, displays the version."
1374   (interactive)
1375   (if (interactive-p)
1376       (message (ediff-version))
1377     (format "Ediff %s of %s" ediff-version ediff-date)))
1378
1379
1380 ;;;###autoload
1381 (defun ediff-documentation (&optional node)
1382   "Display Ediff's manual.
1383 With optional NODE, goes to that node."
1384   (interactive)
1385   (let ((ctl-window ediff-control-window)
1386         (ctl-buf ediff-control-buffer))
1387
1388     (ediff-skip-unsuitable-frames)
1389     (condition-case nil
1390         (progn
1391           (pop-to-buffer (get-buffer-create "*info*"))
1392           (info (if ediff-xemacs-p "ediff.info" "ediff"))
1393           (if node
1394               (Info-goto-node node)
1395             (message "Type `i' to search for a specific topic"))
1396           (raise-frame (selected-frame)))
1397       (error (beep 1)
1398              (with-output-to-temp-buffer ediff-msg-buffer
1399                (ediff-with-current-buffer standard-output
1400                  (fundamental-mode))
1401                (princ ediff-BAD-INFO))
1402              (if (window-live-p ctl-window)
1403                  (progn
1404                    (select-window ctl-window)
1405                    (set-window-buffer ctl-window ctl-buf)))))))
1406
1407
1408
1409
1410 ;;; Local Variables:
1411 ;;; eval: (put 'ediff-defvar-local 'lisp-indent-hook 'defun)
1412 ;;; eval: (put 'ediff-with-current-buffer 'lisp-indent-hook 1)
1413 ;;; eval: (put 'ediff-with-current-buffer 'edebug-form-spec '(form body))
1414 ;;; End:
1415
1416 (require 'ediff-util)
1417
1418 (run-hooks 'ediff-load-hook)
1419
1420 ;;; ediff.el ends here