code.delx.au - gnu-emacs/blob - configure.in

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl If you changed any AC_DEFINES, also run autoheader.
   6 dnl
   7 dnl  Copyright (C) 1994, 1995, 1996, 1999, 2000, 2001, 2002, 2003, 2004,
   8 dnl    2005, 2006, 2007, 2008, 2009, 2010, 2011
   9 dnl    Free Software Foundation, Inc.
  10 dnl
  11 dnl  This file is part of GNU Emacs.
  12 dnl
  13 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  14 dnl  it under the terms of the GNU General Public License as published by
  15 dnl  the Free Software Foundation, either version 3 of the License, or
  16 dnl  (at your option) any later version.
  17 dnl
  18 dnl  GNU Emacs is distributed in the hope that it will be useful,
  19 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 dnl  GNU General Public License for more details.
  22 dnl
  23 dnl  You should have received a copy of the GNU General Public License
  24 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  25
  26 AC_PREREQ(2.65)
  27 AC_INIT(emacs, 24.0.50)
  28 AC_CONFIG_HEADER(src/config.h:src/config.in)
  29 AC_CONFIG_SRCDIR(src/lisp.h)
  30 AM_INIT_AUTOMAKE
  31
  32 dnl Support for --program-prefix, --program-suffix and
  33 dnl --program-transform-name options
  34 AC_ARG_PROGRAM
  35
  36 dnl It is important that variables on the RHS not be expanded here,
  37 dnl hence the single quotes.  This is per the GNU coding standards, see
  38 dnl (autoconf) Installation Directory Variables
  39 dnl See also epaths.h below.
  40 lispdir='${datadir}/emacs/${version}/lisp'
  41 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  42 '${datadir}/emacs/site-lisp'
  43 lisppath='${locallisppath}:${lispdir}:${datadir}/emacs/${version}/leim'
  44 etcdir='${datadir}/emacs/${version}/etc'
  45 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  46 docdir='${datadir}/emacs/${version}/etc'
  47 gamedir='${localstatedir}/games/emacs'
  48
  49 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  50 dnl Create a new --with option that defaults to being disabled.
  51 dnl NAME is the base name of the option.  The shell variable with_NAME
  52 dnl   will be set to either the user's value (if the option is
  53 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  54 dnl   option is not specified).  Note that the shell variable name is
  55 dnl   constructed as autoconf does, by replacing non-alphanumeric
  56 dnl   characters with "_".
  57 dnl HELP-STRING is the help text for the option.
  58 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  59   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  60     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  61 ])dnl
  62
  63 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  64 dnl Create a new --with option that defaults to being enabled.  NAME
  65 dnl   is the base name of the option.  The shell variable with_NAME
  66 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  67 dnl   'yes' (if the option is not specified).  Note that the shell
  68 dnl   variable name is constructed as autoconf does, by replacing
  69 dnl   non-alphanumeric characters with "_".
  70 dnl HELP-STRING is the help text for the option.
  71 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  72   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  73    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=yes])dnl
  74 ])dnl
  75
  76 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
  77 if test "$with_pop" = yes; then
  78    AC_DEFINE(MAIL_USE_POP)
  79 fi
  80 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  81
  82 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
  83 if test "$with_kerberos" != no; then
  84    AC_DEFINE(KERBEROS)
  85 fi
  86 AH_TEMPLATE(KERBEROS,
  87             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  88
  89 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
  90 if test "${with_kerberos5}" != no; then
  91   if test "${with_kerberos}" = no; then
  92     with_kerberos=yes
  93     AC_DEFINE(KERBEROS)
  94   fi
  95   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
  96 fi
  97
  98 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
  99 dnl FIXME hesiod support may not be present, so it seems like an error
 100 dnl to define, or at least use, this unconditionally.
 101 if test "$with_hesiod" != no; then
 102   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
 103 fi
 104
 105 OPTION_DEFAULT_OFF([mmdf],[support MMDF mailboxes])
 106 if test "$with_mmdf" != no; then
 107    AC_DEFINE(MAIL_USE_MMDF, 1, [Define to support MMDF mailboxes in movemail.])
 108 fi
 109
 110 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 111 if test "$with_mail_unlink" != no; then
 112    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 113 fi
 114
 115 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 116     [string giving default POP mail host])],
 117     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 118
 119 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
 120
 121 OPTION_DEFAULT_ON([sync-input],[process async input synchronously])
 122 if test "$with_sync_input" = yes; then
 123    AC_DEFINE(SYNC_INPUT, 1, [Process async input synchronously.])
 124 fi
 125
 126 dnl FIXME currently it is not the last.
 127 dnl This should be the last --with option, because --with-x is
 128 dnl added later on when we find the path of X, and it's best to
 129 dnl keep them together visually.
 130 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 131  [use an X toolkit (KIT one of: yes or gtk, gtk3, lucid or athena, motif, no)])],
 132 [         case "${withval}" in
 133             y | ye | yes )      val=gtk ;;
 134             n | no )            val=no  ;;
 135             l | lu | luc | luci | lucid )       val=lucid ;;
 136             a | at | ath | athe | athen | athena )      val=athena ;;
 137             m | mo | mot | moti | motif )       val=motif ;;
 138             g | gt | gtk  )     val=gtk ;;
 139             gtk3  )     val=gtk3 ;;
 140             * )
 141 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 142 this option's value should be `yes', `no', `lucid', `athena', `motif', `gtk' or
 143 `gtk3'.  `yes' and `gtk' are synonyms. `athena' and `lucid' are synonyms.])
 144             ;;
 145           esac
 146           with_x_toolkit=$val
 147 ])
 148
 149 dnl _ON results in a '--without' option in the --help output, so
 150 dnl the help text should refer to "don't compile", etc.
 151 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 152 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 153 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 154 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 155 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 156 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 157 OPTION_DEFAULT_ON([xml2],[don't compile with XML parsing support])
 158 OPTION_DEFAULT_ON([imagemagick],[don't compile with ImageMagick image support])
 159
 160 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 161 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 162 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 163
 164 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 165 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 166 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 167 OPTION_DEFAULT_OFF([ns],[use nextstep (Cocoa or GNUstep) windowing system])
 168
 169 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 170 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 171 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 172 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 173 OPTION_DEFAULT_ON([gnutls],[don't use -lgnutls for SSL/TLS support])
 174
 175 ## For the times when you want to build Emacs but don't have
 176 ## a suitable makeinfo, and can live without the manuals.
 177 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 178 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 179
 180 ## This is an option because I do not know if all info/man support
 181 ## compressed files, nor how to test if they do so.
 182 OPTION_DEFAULT_ON([compress-info],[don't compress the installed Info pages])
 183 if test $with_compress_info = yes; then
 184    GZIP_INFO=yes
 185 else
 186    GZIP_INFO=
 187 fi
 188 AC_SUBST(GZIP_INFO)
 189
 190 AC_ARG_WITH([pkg-config-prog],dnl
 191 [AS_HELP_STRING([--with-pkg-config-prog=PATH],
 192                   [path to pkg-config for finding GTK and librsvg])])
 193 if test "X${with_pkg_config_prog}" != X; then
 194    if test "${with_pkg_config_prog}" != yes; then
 195       PKG_CONFIG="${with_pkg_config_prog}"
 196    fi
 197 fi
 198
 199 CRT_DIR=
 200 AC_ARG_WITH([crt-dir],dnl
 201 [AS_HELP_STRING([--with-crt-dir=DIR],[directory containing crtn.o etc.
 202 The default is /usr/lib, or /usr/lib64 on some platforms.])])
 203 CRT_DIR="${with_crt_dir}"
 204
 205 AC_ARG_WITH(gameuser,dnl
 206 [AS_HELP_STRING([--with-gameuser=USER],[user for shared game score files])])
 207 test "X${with_gameuser}" != X && test "${with_gameuser}" != yes \
 208   && gameuser="${with_gameuser}"
 209 test "X$gameuser" = X && gameuser=games
 210
 211 AC_ARG_WITH([gnustep-conf],dnl
 212 [AS_HELP_STRING([--with-gnustep-conf=PATH],[path to GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
 213 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 214   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 215 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 216      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 217
 218 AC_ARG_ENABLE(ns-self-contained,
 219 [AS_HELP_STRING([--disable-ns-self-contained],
 220                 [disable self contained build under NeXTstep])],
 221    EN_NS_SELF_CONTAINED=$enableval,
 222    EN_NS_SELF_CONTAINED=yes)
 223
 224 AC_ARG_ENABLE(asserts,
 225 [AS_HELP_STRING([--enable-asserts], [compile code with asserts enabled])],
 226       USE_XASSERTS=$enableval,
 227       USE_XASSERTS=no)
 228
 229 AC_ARG_ENABLE(maintainer-mode,
 230 [AS_HELP_STRING([--enable-maintainer-mode],
 231                 [enable make rules and dependencies not useful (and sometimes
 232                  confusing) to the casual installer])],
 233       USE_MAINTAINER_MODE=$enableval,
 234       USE_MAINTAINER_MODE=no)
 235 if test $USE_MAINTAINER_MODE = yes; then
 236   MAINT=
 237 else
 238   MAINT=#
 239 fi
 240 AC_SUBST(MAINT)
 241
 242 AC_ARG_ENABLE(locallisppath,
 243 [AS_HELP_STRING([--enable-locallisppath=PATH],
 244                 [directories Emacs should search for lisp files specific
 245                  to this site])],
 246 if test "${enableval}" = "no"; then
 247   locallisppath=
 248 elif test "${enableval}" != "yes"; then
 249   locallisppath=${enableval}
 250 fi)
 251
 252 AC_ARG_ENABLE(checking,
 253 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 254                 [enable expensive run-time checks.  With LIST,
 255                  enable only specific categories of checks.
 256                  Categories are: all,yes,no.
 257                  Flags are: stringbytes, stringoverrun, stringfreelist,
 258                  xmallocoverrun, conslist])],
 259 [ac_checking_flags="${enableval}"],[])
 260 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 261 for check in $ac_checking_flags
 262 do
 263         case $check in
 264         # these set all the flags to specific states
 265         yes)            ac_enable_checking=1 ;;
 266         no)             ac_enable_checking= ;
 267                         ac_gc_check_stringbytes= ;
 268                         ac_gc_check_string_overrun= ;
 269                         ac_gc_check_string_free_list= ;
 270                         ac_xmalloc_overrun= ;
 271                         ac_gc_check_cons_list= ;;
 272         all)            ac_enable_checking=1 ;
 273                         ac_gc_check_stringbytes=1 ;
 274                         ac_gc_check_string_overrun=1 ;
 275                         ac_gc_check_string_free_list=1 ;
 276                         ac_xmalloc_overrun=1 ;
 277                         ac_gc_check_cons_list=1 ;;
 278         # these enable particular checks
 279         stringbytes)    ac_gc_check_stringbytes=1 ;;
 280         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 281         stringfreelist) ac_gc_check_string_free_list=1 ;;
 282         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 283         conslist)       ac_gc_check_cons_list=1 ;;
 284         *)      AC_MSG_ERROR(unknown check category $check) ;;
 285         esac
 286 done
 287 IFS="$ac_save_IFS"
 288
 289 if test x$ac_enable_checking != x ; then
 290   AC_DEFINE(ENABLE_CHECKING, 1,
 291 [Enable expensive run-time checking of data types?])
 292 fi
 293 if test x$ac_gc_check_stringbytes != x ; then
 294   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 295 [Define this temporarily to hunt a bug.  If defined, the size of
 296    strings is redundantly recorded in sdata structures so that it can
 297    be compared to the sizes recorded in Lisp strings.])
 298 fi
 299 if test x$ac_gc_check_stringoverrun != x ; then
 300   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 301 [Define this to check for short string overrun.])
 302 fi
 303 if test x$ac_gc_check_string_free_list != x ; then
 304   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 305 [Define this to check the string free list.])
 306 fi
 307 if test x$ac_xmalloc_overrun != x ; then
 308   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 309 [Define this to check for malloc buffer overrun.])
 310 fi
 311 if test x$ac_gc_check_cons_list != x ; then
 312   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 313 [Define this to check for errors in cons list.])
 314 fi
 315
 316 AC_ARG_ENABLE(use-lisp-union-type,
 317 [AS_HELP_STRING([--enable-use-lisp-union-type],
 318                 [use a union for the Lisp_Object data type.
 319                 This is only useful for development for catching certain types of bugs.])],
 320 if test "${enableval}" != "no"; then
 321    AC_DEFINE(USE_LISP_UNION_TYPE, 1,
 322    [Define this to use a lisp union for the Lisp_Object data type.])
 323 fi)
 324
 325
 326 AC_ARG_ENABLE(profiling,
 327 [AS_HELP_STRING([--enable-profiling],
 328                 [build emacs with profiling support.
 329                  This might not work on all platforms])],
 330 [ac_enable_profiling="${enableval}"],[])
 331 if test x$ac_enable_profiling != x ; then
 332    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 333 else
 334    PROFILING_CFLAGS=
 335 fi
 336 AC_SUBST(PROFILING_CFLAGS)
 337
 338 AC_ARG_ENABLE(autodepend,
 339 [AS_HELP_STRING([--enable-autodepend],
 340                 [automatically generate dependencies to .h-files.
 341                  Requires GNU Make and Gcc. Enabled if GNU Make and Gcc is
 342                  found])],
 343 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 344
 345 #### Make srcdir absolute, if it isn't already.  It's important to
 346 #### avoid running the path through pwd unnecessarily, since pwd can
 347 #### give you automounter prefixes, which can go away.  We do all this
 348 #### so Emacs can find its files when run uninstalled.
 349 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 350 unset CDPATH
 351 case "${srcdir}" in
 352   /* ) ;;
 353   . )
 354     ## We may be able to use the $PWD environment variable to make this
 355     ## absolute.  But sometimes PWD is inaccurate.
 356     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 357     ## but that tested only for a well-formed and valid PWD,
 358     ## it did not object when PWD was well-formed and valid but just wrong.
 359     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 360     then
 361       srcdir="$PWD"
 362     else
 363       srcdir="`(cd ${srcdir}; pwd)`"
 364     fi
 365   ;;
 366   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 367 esac
 368
 369 #### Check if the source directory already has a configured system in it.
 370 if test `pwd` != `(cd ${srcdir} && pwd)` \
 371    && test -f "${srcdir}/src/config.h" ; then
 372   AC_MSG_WARN([[The directory tree `${srcdir}' is being used
 373    as a build directory right now; it has been configured in its own
 374    right.  To configure in another directory as well, you MUST
 375    use GNU make.  If you do not have GNU make, then you must
 376    now do `make distclean' in ${srcdir},
 377    and then run $0 again.]])
 378 fi
 379
 380 #### Given the configuration name, set machfile and opsysfile to the
 381 #### names of the m/*.h and s/*.h files we should use.
 382
 383 ### Canonicalize the configuration name.
 384
 385 AC_CANONICAL_HOST
 386 canonical=$host
 387 configuration=${host_alias-${build_alias-$host}}
 388
 389 dnl This used to use changequote, but, apart from `changequote is evil'
 390 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 391 dnl the great gob of text.  Thus it's not processed for possible expansion.
 392 dnl Just make sure the brackets remain balanced.
 393 dnl
 394 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 395 dnl indicated by comments.
 396 dnl quotation begins
 397 [
 398
 399 ### If you add support for a new configuration, add code to this
 400 ### switch statement to recognize your configuration name and select
 401 ### the appropriate operating system and machine description files.
 402
 403 ### You would hope that you could choose an m/*.h file pretty much
 404 ### based on the machine portion of the configuration name, and an s/*.h
 405 ### file based on the operating system portion.  However, it turns out
 406 ### that each m/*.h file is pretty manufacturer-specific - for
 407 ### example mips.h is MIPS
 408 ### So we basically have to have a special case for each
 409 ### configuration name.
 410 ###
 411 ### As far as handling version numbers on operating systems is
 412 ### concerned, make sure things will fail in a fixable way.  If
 413 ### /etc/MACHINES doesn't say anything about version numbers, be
 414 ### prepared to handle anything reasonably.  If version numbers
 415 ### matter, be sure /etc/MACHINES says something about it.
 416
 417 machine='' opsys='' unported=no
 418 case "${canonical}" in
 419
 420   ## GNU/Linux ports
 421   *-*-linux-gnu*)
 422     opsys=gnu-linux
 423     case ${canonical} in
 424       alpha*)   machine=alpha ;;
 425       s390-*)   machine=ibms390 ;;
 426       s390x-*)  machine=ibms390x ;;
 427       powerpc*) machine=macppc ;;
 428       sparc*)   machine=sparc ;;
 429       ia64*)    machine=ia64 ;;
 430       m68k*)    machine=m68k ;;
 431       x86_64*)  machine=amdx86-64 ;;
 432     esac
 433   ;;
 434
 435   ## FreeBSD ports
 436   *-*-freebsd* )
 437     opsys=freebsd
 438     case "${canonical}" in
 439       alpha*)           machine=alpha ;;
 440       amd64-*|x86_64-*) machine=amdx86-64 ;;
 441       ia64-*)           machine=ia64 ;;
 442       i[3456]86-*)      machine=intel386 ;;
 443       powerpc-*)        machine=macppc ;;
 444       sparc-*)          machine=sparc ;;
 445       sparc64-*)        machine=sparc ;;
 446     esac
 447   ;;
 448
 449   ## FreeBSD kernel + glibc based userland
 450   *-*-kfreebsd*gnu* )
 451     opsys=gnu-kfreebsd
 452     case "${canonical}" in
 453       alpha*)           machine=alpha ;;
 454       amd64-*|x86_64-*) machine=amdx86-64 ;;
 455       ia64-*)           machine=ia64 ;;
 456       i[3456]86-*)      machine=intel386 ;;
 457       powerpc-*)        machine=macppc ;;
 458       sparc-*)          machine=sparc ;;
 459       sparc64-*)        machine=sparc ;;
 460     esac
 461   ;;
 462
 463   ## NetBSD ports
 464   *-*-netbsd* )
 465     opsys=netbsd
 466     case "${canonical}" in
 467       alpha*)      machine=alpha ;;
 468       x86_64-*)    machine=amdx86-64 ;;
 469       i[3456]86-*) machine=intel386 ;;
 470       m68k-*)      machine=m68k ;;
 471       powerpc-*)   machine=macppc ;;
 472       sparc*-)     machine=sparc ;;
 473       vax-*)       machine=vax ;;
 474     esac
 475   ;;
 476
 477   ## OpenBSD ports
 478   *-*-openbsd* )
 479     opsys=openbsd
 480     case "${canonical}" in
 481       alpha*)    machine=alpha ;;
 482       x86_64-*)  machine=amdx86-64 ;;
 483       i386-*)    machine=intel386 ;;
 484       powerpc-*) machine=macppc ;;
 485       sparc*)    machine=sparc ;;
 486       vax-*)     machine=vax ;;
 487     esac
 488   ;;
 489
 490   ## Apple Darwin / Mac OS X
 491   *-apple-darwin* )
 492     case "${canonical}" in
 493       i[3456]86-* )  machine=intel386 ;;
 494       powerpc-* )    machine=macppc ;;
 495       x86_64-* )     machine=amdx86-64 ;;
 496       * )            unported=yes ;;
 497     esac
 498     opsys=darwin
 499     # Define CPP as follows to make autoconf work correctly.
 500     CPP="${CC-cc} -E -no-cpp-precomp"
 501     # Use fink packages if available.
 502     if test -d /sw/include && test -d /sw/lib; then
 503       GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 504       CPP="${CPP} ${GCC_TEST_OPTIONS}"
 505       NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 506     fi
 507   ;;
 508
 509   ## HP 9000 series 700 and 800, running HP/UX
 510   hppa*-hp-hpux10.2* )
 511     opsys=hpux10-20
 512   ;;
 513   hppa*-hp-hpux1[1-9]* )
 514     opsys=hpux11
 515     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 516   ;;
 517
 518   ## IBM machines
 519   rs6000-ibm-aix4.[23]* )
 520     machine=ibmrs6000 opsys=aix4-2
 521   ;;
 522   powerpc-ibm-aix4.[23]*  )
 523     machine=ibmrs6000 opsys=aix4-2
 524   ;;
 525   rs6000-ibm-aix[56]* )
 526     machine=ibmrs6000 opsys=aix4-2
 527   ;;
 528   powerpc-ibm-aix[56]*  )
 529     machine=ibmrs6000 opsys=aix4-2
 530   ;;
 531
 532   ## Silicon Graphics machines
 533   ## Iris 4D
 534   mips-sgi-irix6.5 )
 535     machine=iris4d opsys=irix6-5
 536     # Without defining _LANGUAGE_C, things get masked out in the headers
 537     # so that, for instance, grepping for `free' in stdlib.h fails and
 538     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 539     NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
 540     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 541   ;;
 542
 543   ## Suns
 544   *-sun-solaris* \
 545     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 546     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 547     case "${canonical}" in
 548       i[3456]86-*-* )     machine=intel386 ;;
 549       amd64-*-*|x86_64-*-*)     machine=amdx86-64 ;;
 550       sparc* )          machine=sparc ;;
 551       * )               unported=yes ;;
 552     esac
 553     case "${canonical}" in
 554       *-sunos5.6* | *-solaris2.6* )
 555                 opsys=sol2-6
 556                 NON_GNU_CPP=/usr/ccs/lib/cpp
 557                 RANLIB="ar -ts"
 558                 ;;
 559       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 560                 opsys=sol2-6
 561                 emacs_check_sunpro_c=yes
 562                 NON_GNU_CPP=/usr/ccs/lib/cpp
 563                 ;;
 564       *-sunos5* | *-solaris* )
 565                 opsys=sol2-10
 566                 emacs_check_sunpro_c=yes
 567                 NON_GNU_CPP=/usr/ccs/lib/cpp
 568                 ;;
 569     esac
 570     ## Watch out for a compiler that we know will not work.
 571     case "${canonical}" in
 572      *-solaris* | *-sunos5* )
 573                 if [ "x$CC" = x/usr/ucb/cc ]; then
 574                   ## /usr/ucb/cc doesn't work;
 575                   ## we should find some other compiler that does work.
 576                   unset CC
 577                 fi
 578                 ;;
 579       *) ;;
 580     esac
 581   ;;
 582
 583   ## Intel 386 machines where we don't care about the manufacturer.
 584   i[3456]86-*-* )
 585     machine=intel386
 586     case "${canonical}" in
 587       *-cygwin )                opsys=cygwin ;;
 588       *-darwin* )               opsys=darwin
 589                                 CPP="${CC-cc} -E -no-cpp-precomp"
 590                                 ;;
 591       *-sysv4.2uw* )            opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 592       *-sysv5uw* )              opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 593       *-sysv5OpenUNIX* )        opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 594       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 595     esac
 596   ;;
 597
 598   * )
 599     unported=yes
 600   ;;
 601 esac
 602
 603 ### If the code above didn't choose an operating system, just choose
 604 ### an operating system based on the configuration name.  You really
 605 ### only want to use this when you have no idea what the right
 606 ### operating system is; if you know what operating systems a machine
 607 ### runs, it's cleaner to make it explicit in the case statement
 608 ### above.
 609 if test x"${opsys}" = x; then
 610   case "${canonical}" in
 611     *-gnu* )                            opsys=gnu ;;
 612     * )
 613       unported=yes
 614     ;;
 615   esac
 616 fi
 617
 618 ]
 619 dnl quotation ends
 620
 621 if test $unported = yes; then
 622   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 623 Check `etc/MACHINES' for recognized configuration names.])
 624 fi
 625
 626 if test -n "$machine"; then
 627   machfile="m/${machine}.h"
 628 else
 629   machfile=
 630 fi
 631 opsysfile="s/${opsys}.h"
 632
 633
 634 #### Choose a compiler.
 635 test -n "$CC" && cc_specified=yes
 636
 637 # Save the value of CFLAGS that the user specified.
 638 SPECIFIED_CFLAGS="$CFLAGS"
 639
 640 dnl Sets GCC=yes if using gcc.
 641 AC_PROG_CC
 642 AM_PROG_CC_C_O
 643
 644 # Initialize gnulib right after verifying that the C compiler works.
 645 gl_EARLY
 646
 647 # On Suns, sometimes $CPP names a directory.
 648 if test -n "$CPP" && test -d "$CPP"; then
 649   CPP=
 650 fi
 651
 652 ## If not using gcc, and on Solaris, and no CPP specified, see if
 653 ## using a Sun compiler, which needs -Xs to prevent whitespace.
 654 if test x"$GCC" != xyes && test x"$emacs_check_sunpro_c" = xyes && \
 655  test x"$CPP" = x; then
 656   AC_MSG_CHECKING([whether we are using a Sun C compiler])
 657   AC_CACHE_VAL(emacs_cv_sunpro_c,
 658   [AC_TRY_LINK([],
 659 [#ifndef __SUNPRO_C
 660 fail;
 661 #endif
 662 ], emacs_cv_sunpro_c=yes, emacs_cv_sunpro_c=no)])
 663   AC_MSG_RESULT($emacs_cv_sunpro_c)
 664
 665   if test x"$emacs_cv_sunpro_c" = xyes; then
 666     NON_GNU_CPP="$CC -E -Xs"
 667   fi
 668 fi
 669
 670 #### Some systems specify a CPP to use unless we are using GCC.
 671 #### Now that we know whether we are using GCC, we can decide whether
 672 #### to use that one.
 673 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
 674 then
 675   CPP="$NON_GNU_CPP"
 676 fi
 677
 678 #### Some systems specify a CC to use unless we are using GCC.
 679 #### Now that we know whether we are using GCC, we can decide whether
 680 #### to use that one.
 681 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
 682   test x$cc_specified != xyes
 683 then
 684   CC="$NON_GNU_CC"
 685 fi
 686
 687 if test x$GCC = xyes; then
 688   test "x$GCC_TEST_OPTIONS" != x && CC="$CC $GCC_TEST_OPTIONS"
 689 else
 690   test "x$NON_GCC_TEST_OPTIONS" != x && CC="$CC $NON_GCC_TEST_OPTIONS"
 691 fi
 692
 693 ### Use -Wno-pointer-sign if the compiler supports it
 694 AC_MSG_CHECKING([whether gcc understands -Wno-pointer-sign])
 695 SAVE_CFLAGS="$CFLAGS"
 696 CFLAGS="$CFLAGS -Wno-pointer-sign"
 697 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 698 if test $has_option = yes; then
 699    C_WARNINGS_SWITCH="-Wno-pointer-sign $C_WARNINGS_SWITCH"
 700 fi
 701 AC_MSG_RESULT($has_option)
 702 CFLAGS="$SAVE_CFLAGS"
 703 unset has_option
 704 unset SAVE_CFLAGS
 705
 706 ### Use -Wdeclaration-after-statement if the compiler supports it
 707 AC_MSG_CHECKING([whether gcc understands -Wdeclaration-after-statement])
 708 SAVE_CFLAGS="$CFLAGS"
 709 CFLAGS="$CFLAGS -Wdeclaration-after-statement"
 710 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 711 if test $has_option = yes; then
 712    C_WARNINGS_SWITCH="-Wdeclaration-after-statement $C_WARNINGS_SWITCH"
 713 fi
 714 AC_MSG_RESULT($has_option)
 715 CFLAGS="$SAVE_CFLAGS"
 716 unset has_option
 717 unset SAVE_CFLAGS
 718
 719 ### Use -Wold-style-definition if the compiler supports it
 720 # This can be removed when conversion to standard C is finished.
 721 AC_MSG_CHECKING([whether gcc understands -Wold-style-definition])
 722 SAVE_CFLAGS="$CFLAGS"
 723 CFLAGS="$CFLAGS -Wold-style-definition"
 724 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 725 if test $has_option = yes; then
 726    C_WARNINGS_SWITCH="-Wold-style-definition $C_WARNINGS_SWITCH"
 727 fi
 728 AC_MSG_RESULT($has_option)
 729 CFLAGS="$SAVE_CFLAGS"
 730 unset has_option
 731 unset SAVE_CFLAGS
 732
 733 ### Use -Wimplicit-function-declaration if the compiler supports it
 734 AC_MSG_CHECKING([whether gcc understands -Wimplicit-function-declaration])
 735 SAVE_CFLAGS="$CFLAGS"
 736 CFLAGS="$CFLAGS -Wimplicit-function-declaration"
 737 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 738 if test $has_option = yes; then
 739    C_WARNINGS_SWITCH="-Wimplicit-function-declaration $C_WARNINGS_SWITCH"
 740 fi
 741 AC_MSG_RESULT($has_option)
 742 CFLAGS="$SAVE_CFLAGS"
 743 unset has_option
 744 unset SAVE_CFLAGS
 745
 746 AC_SUBST(C_WARNINGS_SWITCH)
 747
 748
 749 #### Some other nice autoconf tests.
 750
 751 dnl checks for programs
 752 AC_PROG_CPP
 753 AC_PROG_INSTALL
 754 if test "x$RANLIB" = x; then
 755   AC_PROG_RANLIB
 756 fi
 757
 758 ## Although we're running on an amd64 kernel, we're actually compiling for
 759 ## the x86 architecture.  The user should probably have provided an
 760 ## explicit --build to `configure', but if everything else than the kernel
 761 ## is running in i386 mode, we can help them out.
 762 if test "$machine" = "amdx86-64"; then
 763   AC_CHECK_DECL([i386])
 764   if test "$ac_cv_have_decl_i386" = "yes"; then
 765     canonical=`echo "$canonical" | sed -e 's/^amd64/i386/' -e 's/^x86_64/i386/'`
 766     machine=intel386
 767     machfile="m/${machine}.h"
 768   fi
 769 fi
 770
 771 AC_PATH_PROG(INSTALL_INFO, install-info)
 772 AC_PATH_PROG(INSTALL_INFO, install-info,, /usr/sbin)
 773 AC_PATH_PROG(INSTALL_INFO, install-info,:, /sbin)
 774 dnl Don't use GZIP, which is used by gzip for additional parameters.
 775 AC_PATH_PROG(GZIP_PROG, gzip)
 776
 777
 778 ## Need makeinfo >= 4.6 (?) to build the manuals.
 779 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 780 dnl By this stage, configure has already checked for egrep and set EGREP,
 781 dnl or exited with an error if no egrep was found.
 782 if test "$MAKEINFO" != "no" && \
 783   test x"`$MAKEINFO --version 2> /dev/null | $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[6-9]]|4\.[[1-5]][[0-9]]+)'`" = x; then
 784    MAKEINFO=no
 785 fi
 786
 787 ## Makeinfo is unusual.  For a released Emacs, the manuals are
 788 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
 789 ## therefore in the category of "special tools" not normally required, which
 790 ## configure does not have to check for (eg autoconf itself).
 791 ## In a Bazaar checkout on the other hand, the manuals are not included.
 792 ## So makeinfo is a requirement to build from Bazaar, and configure
 793 ## should test for it as it does for any other build requirement.
 794 ## We use the presence of $srcdir/info/emacs to distinguish a release,
 795 ## with pre-built manuals, from a Bazaar checkout.
 796 HAVE_MAKEINFO=yes
 797
 798 if test "$MAKEINFO" = "no"; then
 799   MAKEINFO=makeinfo
 800   if test "x${with_makeinfo}" = "xno"; then
 801     HAVE_MAKEINFO=no
 802   elif test ! -e $srcdir/info/emacs; then
 803     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.6, and your
 804 source tree does not seem to have pre-built manuals in the `info' directory.
 805 Either install a suitable version of makeinfo, or re-run configure
 806 with the `--without-makeinfo' option to build without the manuals.] )
 807   fi
 808 fi
 809 AC_SUBST(HAVE_MAKEINFO)
 810
 811 dnl Add our options to ac_link now, after it is set up.
 812
 813 if test x$GCC = xyes; then
 814   test "x$GCC_LINK_TEST_OPTIONS" != x && \
 815     ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 816 else
 817   test "x$NON_GCC_LINK_TEST_OPTIONS" != x && \
 818     ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 819 fi
 820
 821 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 822 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 823 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 824 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 825 dnl if not built to support GNU ld.
 826
 827 late_LDFLAGS=$LDFLAGS
 828 if test x$GCC = xyes; then
 829   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 830 else
 831   LDFLAGS="$LDFLAGS -znocombreloc"
 832 fi
 833
 834 AC_MSG_CHECKING([for -znocombreloc])
 835 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
 836   [AC_MSG_RESULT(yes)],
 837   LDFLAGS=$late_LDFLAGS
 838   [AC_MSG_RESULT(no)])
 839
 840
 841 # The value of CPP is a quoted variable reference, so we need to do this
 842 # to get its actual value...
 843 CPP=`eval "echo $CPP"`
 844
 845
 846 dnl Not used by any currently supported platform.
 847 dnl The function dump-emacs will not be defined and temacs will do
 848 dnl (load "loadup") automatically unless told otherwise.
 849 CANNOT_DUMP=no
 850 case "$opsys" in
 851   your-opsys-here)
 852    CANNOT_DUMP=yes
 853    AC_DEFINE(CANNOT_DUMP, 1, [Define if Emacs cannot be dumped on your system.])
 854   ;;
 855 esac
 856 AC_SUBST(CANNOT_DUMP)
 857
 858
 859 UNEXEC_OBJ=unexelf.o
 860 case "$opsys" in
 861   # MSDOS uses unexcoff.o
 862   # MSWindows uses unexw32.o
 863   aix4-2)
 864    UNEXEC_OBJ=unexaix.o
 865    ;;
 866   cygwin)
 867    UNEXEC_OBJ=unexcw.o
 868    ;;
 869   darwin)
 870    UNEXEC_OBJ=unexmacosx.o
 871    ;;
 872   hpux10-20 | hpux11)
 873    UNEXEC_OBJ=unexhp9k800.o
 874    ;;
 875   sol2-10)
 876    # Use the Solaris dldump() function, called from unexsol.c, to dump
 877    # emacs, instead of the generic ELF dump code found in unexelf.c.
 878    # The resulting binary has a complete symbol table, and is better
 879    # for debugging and other observability tools (debuggers, pstack, etc).
 880    #
 881    # If you encounter a problem using dldump(), please consider sending
 882    # a message to the OpenSolaris tools-linking mailing list:
 883    #      http://mail.opensolaris.org/mailman/listinfo/tools-linking
 884    #
 885    # It is likely that dldump() works with older Solaris too, but this has
 886    # not been tested, so for now this change is for Solaris 10 or newer.
 887    UNEXEC_OBJ=unexsol.o
 888    ;;
 889 esac
 890
 891 LD_SWITCH_SYSTEM=
 892 case "$opsys" in
 893   freebsd)
 894    ## Let `ld' find image libs and similar things in /usr/local/lib.
 895    ## The system compiler, GCC, has apparently been modified to not
 896    ## look there, contrary to what a stock GCC would do.
 897    LD_SWITCH_SYSTEM=-L/usr/local/lib
 898    ;;
 899
 900   gnu-linux)
 901    ## cpp test was "ifdef __mips__", but presumably this is equivalent...
 902    case $host_cpu in mips*) LD_SWITCH_SYSTEM="-G 0";; esac
 903    ;;
 904
 905   netbsd)
 906    LD_SWITCH_SYSTEM="-Wl,-rpath,/usr/pkg/lib -L/usr/pkg/lib -Wl,-rpath,/usr/local/lib -L/usr/local/lib"
 907    ;;
 908
 909   openbsd)
 910    ## Han Boetes <han@mijncomputer.nl> says this is necessary,
 911    ## otherwise Emacs dumps core on elf systems.
 912    LD_SWITCH_SYSTEM="-Z"
 913    ;;
 914 esac
 915 AC_SUBST(LD_SWITCH_SYSTEM)
 916
 917 ac_link="$ac_link $LD_SWITCH_SYSTEM"
 918
 919 ## This setting of LD_SWITCH_SYSTEM references LD_SWITCH_X_SITE_AUX,
 920 ## which has not been defined yet.  When this was handled with cpp,
 921 ## it was expanded to null when configure sourced the s/*.h file.
 922 ## Thus LD_SWITCH_SYSTEM had different values in configure and the Makefiles.
 923 ## FIXME it would be cleaner to put this in LD_SWITCH_SYSTEM_TEMACS
 924 ## (or somesuch), but because it is supposed to go at the _front_
 925 ## of LD_SWITCH_SYSTEM, we cannot do that in exactly the same way.
 926 ## Compare with the gnu-linux case below, which added to the end
 927 ## of LD_SWITCH_SYSTEM, and so can instead go at the front of
 928 ## LD_SWITCH_SYSTEM_TEMACS.
 929 case "$opsys" in
 930   netbsd|openbsd)
 931    ## _AUX_RPATH is like _AUX, but uses -rpath instead of -R.
 932    LD_SWITCH_SYSTEM="\$(LD_SWITCH_X_SITE_AUX_RPATH) $LD_SWITCH_SYSTEM" ;;
 933 esac
 934
 935
 936 C_SWITCH_MACHINE=
 937 if test "$machine" = "alpha"; then
 938   AC_CHECK_DECL([__ELF__])
 939   if test "$ac_cv_have_decl___ELF__" = "yes"; then
 940     ## With ELF, make sure that all common symbols get allocated to in the
 941     ## data section.  Otherwise, the dump of temacs may miss variables in
 942     ## the shared library that have been initialized.  For example, with
 943     ## GNU libc, __malloc_initialized would normally be resolved to the
 944     ## shared library's .bss section, which is fatal.
 945     if test "x$GCC" = "xyes"; then
 946       C_SWITCH_MACHINE="-fno-common"
 947     else
 948       AC_MSG_ERROR([What gives?  Fix me if DEC Unix supports ELF now.])
 949     fi
 950   else
 951     UNEXEC_OBJ=unexalpha.o
 952   fi
 953 fi
 954 AC_SUBST(C_SWITCH_MACHINE)
 955
 956 AC_SUBST(UNEXEC_OBJ)
 957
 958 C_SWITCH_SYSTEM=
 959 ## Some programs in src produce warnings saying certain subprograms
 960 ## are too complex and need a MAXMEM value greater than 2000 for
 961 ## additional optimization.  --nils@exp-math.uni-essen.de
 962 test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \
 963   C_SWITCH_SYSTEM="-ma -qmaxmem=4000"
 964 ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems.
 965 ## It is redundant in glibc2, since we define _GNU_SOURCE.
 966 AC_SUBST(C_SWITCH_SYSTEM)
 967
 968
 969 LIBS_SYSTEM=
 970 case "$opsys" in
 971   ## IBM's X11R5 uses -lIM and -liconv in AIX 3.2.2.
 972   aix4-2) LIBS_SYSTEM="-lrts -lIM -liconv" ;;
 973
 974   freebsd) LIBS_SYSTEM="-lutil" ;;
 975
 976   hpux*) LIBS_SYSTEM="-l:libdld.sl" ;;
 977
 978   sol2*) LIBS_SYSTEM="-lsocket -lnsl -lkstat" ;;
 979
 980   ## Motif needs -lgen.
 981   unixware) LIBS_SYSTEM="-lsocket -lnsl -lelf -lgen" ;;
 982 esac
 983 AC_SUBST(LIBS_SYSTEM)
 984
 985
 986 ### Make sure subsequent tests use flags consistent with the build flags.
 987
 988 if test x"${OVERRIDE_CPPFLAGS}" != x; then
 989   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
 990 else
 991   CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS"
 992 fi
 993
 994 dnl For AC_FUNC_GETLOADAVG, at least:
 995 AC_CONFIG_LIBOBJ_DIR(src)
 996
 997 dnl Do this early because it can frob feature test macros for Unix-98 &c.
 998 AC_SYS_LARGEFILE
 999
1000
1001 ## If user specified a crt-dir, use that unconditionally.
1002 if test "X$CRT_DIR" = "X"; then
1003
1004   case "$canonical" in
1005     x86_64-*-linux-gnu* | s390x-*-linux-gnu*)
1006     ## On x86-64 and s390x GNU/Linux distributions, the standard library
1007     ## can be in a variety of places.  We only try /usr/lib64 and /usr/lib.
1008     ## For anything else (eg /usr/lib32), it is up the user to specify
1009     ## the location (bug#5655).
1010     ## Test for crtn.o, not just the directory, because sometimes the
1011     ## directory exists but does not have the relevant files (bug#1287).
1012     ## FIXME better to test for binary compatibility somehow.
1013     test -e /usr/lib64/crtn.o && CRT_DIR=/usr/lib64
1014     ;;
1015
1016     powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*) CRT_DIR=/usr/lib64 ;;
1017   esac
1018
1019   case "$opsys" in
1020     hpux10-20) CRT_DIR=/lib ;;
1021   esac
1022
1023   ## Default is /usr/lib.
1024   test "X$CRT_DIR" = "X" && CRT_DIR=/usr/lib
1025
1026 else
1027
1028   ## Some platforms don't use any of these files, so it is not
1029   ## appropriate to put this test outside the if block.
1030   test -e $CRT_DIR/crtn.o || test -e $CRT_DIR/crt0.o || \
1031     AC_MSG_ERROR([crt*.o not found in specified location.])
1032
1033 fi
1034
1035 AC_SUBST(CRT_DIR)
1036
1037 LIB_MATH=-lm
1038 LIB_STANDARD=
1039 START_FILES=
1040
1041 case $opsys in
1042   cygwin )
1043     LIB_MATH=
1044     START_FILES='pre-crt0.o'
1045     ;;
1046   darwin )
1047     ## Adding -lm confuses the dynamic linker, so omit it.
1048     LIB_MATH=
1049     START_FILES='pre-crt0.o'
1050     ;;
1051   freebsd )
1052     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1053     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1054     ;;
1055   gnu-linux | gnu-kfreebsd )
1056     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtn.o'
1057     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o'
1058     ;;
1059   hpux10-20 | hpux11 )
1060     LIB_STANDARD=-lc
1061     START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o'
1062     ;;
1063   netbsd | openbsd )
1064     if test -f $CRT_DIR/crti.o; then
1065         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1066         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1067     else
1068         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o'
1069         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crtbegin.o'
1070     fi
1071     ;;
1072 esac
1073
1074 AC_SUBST(LIB_MATH)
1075 AC_SUBST(START_FILES)
1076
1077 dnl This function definition taken from Gnome 2.0
1078 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1079 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1080 dnl also defines GSTUFF_PKG_ERRORS on error
1081 AC_DEFUN([PKG_CHECK_MODULES], [
1082   succeeded=no
1083
1084   AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1085
1086   if test "$PKG_CONFIG" = "no" ; then
1087      ifelse([$4], , [AC_MSG_ERROR([
1088       *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
1089   else
1090      PKG_CONFIG_MIN_VERSION=0.9.0
1091      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1092         AC_MSG_CHECKING(for $2)
1093
1094         if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD; then
1095             AC_MSG_RESULT(yes)
1096             succeeded=yes
1097
1098             AC_MSG_CHECKING($1_CFLAGS)
1099             $1_CFLAGS=`$PKG_CONFIG --cflags "$2"|sed -e 's,///*,/,g'`
1100             AC_MSG_RESULT($$1_CFLAGS)
1101
1102             AC_MSG_CHECKING($1_LIBS)
1103             $1_LIBS=`$PKG_CONFIG --libs "$2"|sed -e 's,///*,/,g'`
1104             AC_MSG_RESULT($$1_LIBS)
1105         else
1106             AC_MSG_RESULT(no)
1107             $1_CFLAGS=""
1108             $1_LIBS=""
1109             ## If we have a custom action on failure, don't print errors, but
1110             ## do set a variable so people can do so.
1111             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1112             ifelse([$4], ,echo $$1_PKG_ERRORS,)
1113         fi
1114
1115         AC_SUBST($1_CFLAGS)
1116         AC_SUBST($1_LIBS)
1117      else
1118         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1119         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1120      fi
1121   fi
1122
1123   if test $succeeded = yes; then
1124      ifelse([$3], , :, [$3])
1125   else
1126      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1127   fi
1128 ])
1129
1130
1131 if test "${with_sound}" != "no"; then
1132   # Sound support for GNU/Linux and the free BSDs.
1133   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h,
1134     have_sound_header=yes)
1135   # Emulation library used on NetBSD.
1136   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1137   AC_SUBST(LIBSOUND)
1138
1139   ALSA_REQUIRED=1.0.0
1140   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1141   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1142   if test $HAVE_ALSA = yes; then
1143     SAVE_CFLAGS="$CFLAGS"
1144     SAVE_LDFLAGS="$LDFLAGS"
1145     CFLAGS="$ALSA_CFLAGS $CFLAGS"
1146     LDFLAGS="$ALSA_LIBS $LDFLAGS"
1147     AC_TRY_COMPILE([#include <asoundlib.h>], [snd_lib_error_set_handler (0);],
1148                     emacs_alsa_normal=yes,
1149                     emacs_alsa_normal=no)
1150     if test "$emacs_alsa_normal" != yes; then
1151       AC_TRY_COMPILE([#include <alsa/asoundlib.h>],
1152                      [snd_lib_error_set_handler (0);],
1153                      emacs_alsa_subdir=yes,
1154                      emacs_alsa_subdir=no)
1155       if test "$emacs_alsa_subdir" != yes; then
1156         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1157       fi
1158       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1159     fi
1160
1161     CFLAGS="$SAVE_CFLAGS"
1162     LDFLAGS="$SAVE_LDFLAGS"
1163     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1164     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1165     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1166   fi
1167
1168   dnl Define HAVE_SOUND if we have sound support.  We know it works and
1169   dnl compiles only on the specified platforms.  For others, it
1170   dnl probably doesn't make sense to try.
1171   if test x$have_sound_header = xyes || test $HAVE_ALSA = yes; then
1172      case "$opsys" in
1173        dnl defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
1174        gnu-linux|freebsd|netbsd)
1175          AC_DEFINE(HAVE_SOUND, 1, [Define to 1 if you have sound support.])
1176          ;;
1177      esac
1178   fi
1179
1180   AC_SUBST(CFLAGS_SOUND)
1181 fi
1182
1183 dnl checks for header files
1184 AC_CHECK_HEADERS(sys/select.h sys/time.h unistd.h utime.h \
1185   linux/version.h sys/systeminfo.h limits.h \
1186   stdio_ext.h fcntl.h coff.h pty.h sys/mman.h \
1187   sys/vlimit.h sys/resource.h locale.h sys/_mbstate_t.h \
1188   sys/utsname.h pwd.h utmp.h dirent.h util.h)
1189
1190 AC_MSG_CHECKING(if personality LINUX32 can be set)
1191 AC_TRY_COMPILE([#include <sys/personality.h>], [personality (PER_LINUX32)],
1192                emacs_cv_personality_linux32=yes,
1193                emacs_cv_personality_linux32=no)
1194 AC_MSG_RESULT($emacs_cv_personality_linux32)
1195
1196 if test $emacs_cv_personality_linux32 = yes; then
1197   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1198             [Define to 1 if personality LINUX32 can be set.])
1199 fi
1200
1201 dnl On Solaris 8 there's a compilation warning for term.h because
1202 dnl it doesn't define `bool'.
1203 AC_CHECK_HEADERS(term.h, , , -)
1204 AC_HEADER_STDC
1205 AC_HEADER_TIME
1206 AC_CHECK_DECLS([sys_siglist])
1207 if test $ac_cv_have_decl_sys_siglist != yes; then
1208   # For Tru64, at least:
1209   AC_CHECK_DECLS([__sys_siglist])
1210   if test $ac_cv_have_decl___sys_siglist = yes; then
1211     AC_DEFINE(sys_siglist, __sys_siglist,
1212               [Define to any substitute for sys_siglist.])
1213   fi
1214 fi
1215 AC_HEADER_SYS_WAIT
1216
1217 dnl Some systems have utime.h but don't declare the struct anyplace.
1218 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1219 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1220 #include <sys/time.h>
1221 #include <time.h>
1222 #else
1223 #ifdef HAVE_SYS_TIME_H
1224 #include <sys/time.h>
1225 #else
1226 #include <time.h>
1227 #endif
1228 #endif
1229 #ifdef HAVE_UTIME_H
1230 #include <utime.h>
1231 #endif], [static struct utimbuf x; x.actime = x.modtime;],
1232   emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1233 if test $emacs_cv_struct_utimbuf = yes; then
1234   AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if `struct utimbuf' is declared by <utime.h>.])
1235 fi
1236
1237 dnl checks for typedefs
1238 AC_TYPE_SIGNAL
1239
1240 dnl Check for speed_t typedef.
1241 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1242   [AC_TRY_COMPILE([#include <termios.h>], [speed_t x = 1;],
1243     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1244 if test $emacs_cv_speed_t = yes; then
1245   AC_DEFINE(HAVE_SPEED_T, 1,
1246            [Define to 1 if `speed_t' is declared by <termios.h>.])
1247 fi
1248
1249 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1250 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1251 #include <sys/time.h>
1252 #include <time.h>
1253 #else
1254 #ifdef HAVE_SYS_TIME_H
1255 #include <sys/time.h>
1256 #else
1257 #include <time.h>
1258 #endif
1259 #endif], [static struct timeval x; x.tv_sec = x.tv_usec;],
1260   emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1261 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1262 if test $emacs_cv_struct_timeval = yes; then
1263   AC_DEFINE(HAVE_TIMEVAL, 1, [Define to 1 if `struct timeval' is declared by <sys/time.h>.])
1264 fi
1265
1266 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1267 AC_TRY_COMPILE([#include <math.h>],
1268 [static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;],
1269   emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1270 HAVE_EXCEPTION=$emacs_cv_struct_exception
1271 if test $emacs_cv_struct_exception != yes; then
1272   AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1273 fi
1274
1275 AC_CHECK_HEADERS(sys/socket.h)
1276 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1277 #if HAVE_SYS_SOCKET_H
1278 #include <sys/socket.h>
1279 #endif])
1280
1281 dnl checks for structure members
1282 AC_STRUCT_TM
1283 AC_STRUCT_TIMEZONE
1284 AC_CHECK_MEMBER(struct tm.tm_gmtoff,
1285                 [AC_DEFINE(HAVE_TM_GMTOFF, 1,
1286                            [Define to 1 if `tm_gmtoff' is member of `struct tm'.])],,
1287                 [#include <time.h>])
1288 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1289                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1290                   struct ifreq.ifr_addr], , ,
1291                  [AC_INCLUDES_DEFAULT
1292 #if HAVE_SYS_SOCKET_H
1293 #include <sys/socket.h>
1294 #endif
1295 #if HAVE_NET_IF_H
1296 #include <net/if.h>
1297 #endif])
1298
1299 dnl checks for compiler characteristics
1300
1301 dnl Testing __STDC__ to determine prototype support isn't good enough.
1302 dnl DEC C, for instance, doesn't define it with default options, and
1303 dnl is used on 64-bit systems (OSF Alphas).  Similarly for volatile
1304 dnl and void *.
1305 AC_C_PROTOTYPES
1306 AC_C_VOLATILE
1307 AC_C_CONST
1308 dnl This isn't useful because we can't turn on use of `inline' unless
1309 dnl the compiler groks `extern inline'.
1310 dnl AC_C_INLINE
1311 AC_CACHE_CHECK([for void * support], emacs_cv_void_star,
1312   [AC_TRY_COMPILE(, [void * foo;],
1313                    emacs_cv_void_star=yes, emacs_cv_void_star=no)])
1314 if test $emacs_cv_void_star = yes; then
1315   AC_DEFINE(POINTER_TYPE, void)
1316 else
1317   AC_DEFINE(POINTER_TYPE, char)
1318 fi
1319 AH_TEMPLATE(POINTER_TYPE,
1320             [Define as `void' if your compiler accepts `void *'; otherwise
1321              define as `char'.])dnl
1322
1323 dnl Check for endianess
1324 AC_C_BIGENDIAN
1325
1326 AC_CACHE_CHECK([for  __attribute__ ((__aligned__ (expr)))],
1327   [emacs_cv_attribute_aligned],
1328   [AC_COMPILE_IFELSE(
1329      [AC_LANG_PROGRAM(
1330         [[char __attribute__ ((__aligned__ (1 << 3))) c;]],
1331         [[]])],
1332      [emacs_cv_attribute_aligned=yes],
1333      [emacs_cv_attribute_aligned=no])])
1334 if test $emacs_cv_attribute_aligned = yes; then
1335   AC_DEFINE([HAVE_ATTRIBUTE_ALIGNED], 1,
1336     [Define to 1 if GCC-style __attribute__ ((__aligned__ (expr))) works.])
1337 fi
1338
1339 dnl check for Make feature
1340 AC_PROG_MAKE_SET
1341
1342 DEPFLAGS=
1343 MKDEPDIR=":"
1344 deps_frag=deps.mk
1345 dnl check for GNU Make if we have GCC and autodepend is on.
1346 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1347    AC_MSG_CHECKING([whether we are using GNU Make])
1348    HAVE_GNU_MAKE=no
1349    testval=`make --version 2>/dev/null | grep 'GNU Make'`
1350    if test "x$testval" != x; then
1351       HAVE_GNU_MAKE=yes
1352    else
1353       ac_enable_autodepend=no
1354    fi
1355    AC_MSG_RESULT([$HAVE_GNU_MAKE])
1356    if test $HAVE_GNU_MAKE = yes; then
1357       AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1358       SAVE_CFLAGS="$CFLAGS"
1359       CFLAGS="$CFLAGS -MMD -MF deps.d"
1360       AC_TRY_COMPILE([], [], , ac_enable_autodepend=no)
1361       CFLAGS="$SAVE_CFLAGS"
1362       test -f deps.d || ac_enable_autodepend=no
1363       rm -rf deps.d
1364       AC_MSG_RESULT([$ac_enable_autodepend])
1365    fi
1366    if test $ac_enable_autodepend = yes; then
1367       DEPFLAGS='-MMD -MF ${DEPDIR}/$*.d'
1368       ## In parallel builds, another make might create depdir between
1369       ## the first test and mkdir, so stick another test on the end.
1370       ## Or use mkinstalldirs?  mkdir -p is not portable.
1371       MKDEPDIR='test -d ${DEPDIR} || mkdir ${DEPDIR} || test -d ${DEPDIR}'
1372       deps_frag=autodeps.mk
1373    fi
1374 fi
1375 deps_frag=$srcdir/src/$deps_frag
1376 AC_SUBST(MKDEPDIR)
1377 AC_SUBST(DEPFLAGS)
1378 AC_SUBST_FILE(deps_frag)
1379
1380
1381 dnl checks for operating system services
1382 AC_SYS_LONG_FILE_NAMES
1383
1384 #### Choose a window system.
1385
1386 AC_PATH_X
1387 if test "$no_x" = yes; then
1388   window_system=none
1389 else
1390   window_system=x11
1391 fi
1392
1393 ## Workaround for bug in autoconf <= 2.62.
1394 ## http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01551.html
1395 ## No need to do anything special for these standard directories.
1396 if test -n "${x_libraries}" && test x"${x_libraries}" != xNONE; then
1397
1398    x_libraries=`echo :${x_libraries}: | sed -e 's|:/usr/lib64:|:|g' -e 's|:/lib64:|:|g' -e 's|^:||' -e 's|:$||'`
1399
1400 fi
1401
1402 LD_SWITCH_X_SITE_AUX=
1403 LD_SWITCH_X_SITE_AUX_RPATH=
1404 if test "${x_libraries}" != NONE; then
1405   if test -n "${x_libraries}"; then
1406     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1407     LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
1408     LD_SWITCH_X_SITE_AUX_RPATH=`echo ${LD_SWITCH_X_SITE_AUX} | sed -e 's/-R/-Wl,-rpath,/'`
1409   fi
1410   x_default_search_path=""
1411   x_search_path=${x_libraries}
1412   if test -z "${x_search_path}"; then
1413     x_search_path=/usr/lib
1414   fi
1415   for x_library in `echo ${x_search_path}: | \
1416                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1417     x_search_path="\
1418 ${x_library}/X11/%L/%T/%N%C%S:\
1419 ${x_library}/X11/%l/%T/%N%C%S:\
1420 ${x_library}/X11/%T/%N%C%S:\
1421 ${x_library}/X11/%L/%T/%N%S:\
1422 ${x_library}/X11/%l/%T/%N%S:\
1423 ${x_library}/X11/%T/%N%S"
1424     if test x"${x_default_search_path}" = x; then
1425       x_default_search_path=${x_search_path}
1426     else
1427       x_default_search_path="${x_search_path}:${x_default_search_path}"
1428     fi
1429   done
1430 fi
1431 AC_SUBST(LD_SWITCH_X_SITE_AUX)
1432 AC_SUBST(LD_SWITCH_X_SITE_AUX_RPATH)
1433
1434 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1435   C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"`
1436 fi
1437
1438 if test x"${x_includes}" = x; then
1439   bitmapdir=/usr/include/X11/bitmaps
1440 else
1441   # accumulate include directories that have X11 bitmap subdirectories
1442   bmd_acc="dummyval"
1443   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1444     if test -d "${bmd}/X11/bitmaps"; then
1445       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1446     fi
1447     if test -d "${bmd}/bitmaps"; then
1448       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1449     fi
1450   done
1451   if test ${bmd_acc} != "dummyval"; then
1452     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1453   fi
1454 fi
1455
1456 HAVE_NS=no
1457 NS_IMPL_COCOA=no
1458 NS_IMPL_GNUSTEP=no
1459 tmp_CPPFLAGS="$CPPFLAGS"
1460 tmp_CFLAGS="$CFLAGS"
1461 CPPFLAGS="$CPPFLAGS -x objective-c"
1462 CFLAGS="$CFLAGS -x objective-c"
1463 TEMACS_LDFLAGS2="\${LDFLAGS}"
1464 dnl I don't think it's especially important, but src/Makefile.in
1465 dnl (now the only user of ns_appdir) used to go to the trouble of adding a
1466 dnl trailing "/" to it, so now we do it here.
1467 if test "${with_ns}" != no; then
1468   if test "${opsys}" = darwin; then
1469      NS_IMPL_COCOA=yes
1470      ns_appdir=`pwd`/nextstep/Emacs.app
1471      ns_appbindir=${ns_appdir}/Contents/MacOS/
1472      ns_appresdir=${ns_appdir}/Contents/Resources
1473      ns_appsrc=${srcdir}/nextstep/Cocoa/Emacs.base
1474   elif test -f $GNUSTEP_CONFIG_FILE; then
1475      NS_IMPL_GNUSTEP=yes
1476      ns_appdir=`pwd`/nextstep/Emacs.app
1477      ns_appbindir=${ns_appdir}/
1478      ns_appresdir=${ns_appdir}/Resources
1479      ns_appsrc=${srcdir}/nextstep/GNUstep/Emacs.base
1480      dnl FIXME sourcing this several times in subshells seems inefficient.
1481      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1482      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1483      dnl I seemed to need these as well with GNUstep-startup 0.25.
1484      GNUSTEP_LOCAL_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_HEADERS)"
1485      GNUSTEP_LOCAL_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_LIBRARIES)"
1486      test "x${GNUSTEP_LOCAL_HEADERS}" != "x" && \
1487        GNUSTEP_LOCAL_HEADERS="-I${GNUSTEP_LOCAL_HEADERS}"
1488      test "x${GNUSTEP_LOCAL_LIBRARIES}" != "x" && \
1489        GNUSTEP_LOCAL_LIBRARIES="-L${GNUSTEP_LOCAL_LIBRARIES}"
1490      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1491      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1492      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES}"
1493      LIB_STANDARD=
1494      START_FILES=
1495      TEMACS_LDFLAGS2=
1496   fi
1497   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1498                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1499   files are missing or cannot be compiled.])])
1500   NS_HAVE_NSINTEGER=yes
1501   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1502                                      [NSInteger i;])],
1503                     ns_have_nsinteger=yes,
1504                     ns_have_nsinteger=no)
1505   if test $ns_have_nsinteger = no; then
1506     NS_HAVE_NSINTEGER=no
1507   fi
1508 fi
1509 AC_SUBST(TEMACS_LDFLAGS2)
1510
1511 ns_frag=/dev/null
1512 NS_OBJ=
1513 NS_SUPPORT=
1514 if test "${HAVE_NS}" = yes; then
1515   window_system=nextstep
1516   with_xft=no
1517   # set up packaging dirs
1518   exec_prefix=${ns_appbindir}
1519   libexecdir=${ns_appbindir}/libexec
1520   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1521      prefix=${ns_appresdir}
1522   fi
1523   ns_frag=$srcdir/src/ns.mk
1524   NS_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o nsfont.o fontset.o fringe.o image.o"
1525   NS_SUPPORT="\${lispsource}/emacs-lisp/easymenu.elc \${lispsource}/term/ns-win.elc"
1526 fi
1527 CFLAGS="$tmp_CFLAGS"
1528 CPPFLAGS="$tmp_CPPFLAGS"
1529 AC_SUBST(NS_OBJ)
1530 AC_SUBST(NS_SUPPORT)
1531 AC_SUBST(LIB_STANDARD)
1532 AC_SUBST_FILE(ns_frag)
1533
1534 case "${window_system}" in
1535   x11 )
1536     HAVE_X_WINDOWS=yes
1537     HAVE_X11=yes
1538     case "${with_x_toolkit}" in
1539       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1540       motif ) USE_X_TOOLKIT=MOTIF ;;
1541       gtk ) with_gtk=yes
1542 dnl Dont set this for GTK.  A lot of tests below assumes Xt when
1543 dnl USE_X_TOOLKIT is set.
1544             USE_X_TOOLKIT=none ;;
1545       gtk3 ) with_gtk3=yes
1546              USE_X_TOOLKIT=none ;;
1547       no ) USE_X_TOOLKIT=none ;;
1548 dnl If user did not say whether to use a toolkit, make this decision later:
1549 dnl use the toolkit if we have gtk, or X11R5 or newer.
1550       * ) USE_X_TOOLKIT=maybe ;;
1551     esac
1552   ;;
1553   nextstep | none )
1554     HAVE_X_WINDOWS=no
1555     HAVE_X11=no
1556     USE_X_TOOLKIT=none
1557   ;;
1558 esac
1559
1560 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1561    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1562    if test "$HAVE_XSERVER" = true ||
1563       test -n "$DISPLAY" ||
1564       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1565         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1566 were found.  You should install the relevant development files for X
1567 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1568 sure you have development files for image handling, i.e.
1569 tiff, gif, jpeg, png and xpm.
1570 If you are sure you want Emacs compiled without X window support, pass
1571   --without-x
1572 to configure.])
1573    fi
1574 fi
1575
1576 ### If we're using X11, we should use the X menu package.
1577 HAVE_MENUS=no
1578 case ${HAVE_X11} in
1579   yes ) HAVE_MENUS=yes ;;
1580 esac
1581
1582 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1583 # Assume not, until told otherwise.
1584 GNU_MALLOC=yes
1585 doug_lea_malloc=yes
1586 AC_CHECK_FUNC(malloc_get_state, ,doug_lea_malloc=no)
1587 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
1588 AC_CACHE_CHECK(whether __after_morecore_hook exists,
1589                emacs_cv_var___after_morecore_hook,
1590 [AC_TRY_LINK([extern void (* __after_morecore_hook)();],[__after_morecore_hook = 0],
1591   emacs_cv_var___after_morecore_hook=yes,
1592   emacs_cv_var___after_morecore_hook=no)])
1593 if test $emacs_cv_var___after_morecore_hook = no; then
1594   doug_lea_malloc=no
1595 fi
1596
1597
1598 dnl See comments in aix4-2.h about maybe using system malloc there.
1599 system_malloc=no
1600 case "$opsys" in
1601   ## darwin ld insists on the use of malloc routines in the System framework.
1602   darwin|sol2-10) system_malloc=yes ;;
1603 esac
1604
1605 if test "${system_malloc}" = "yes"; then
1606   AC_DEFINE(SYSTEM_MALLOC, 1, [Define to use system malloc.])
1607   GNU_MALLOC=no
1608   GNU_MALLOC_reason="
1609     (The GNU allocators don't work with this system configuration.)"
1610   GMALLOC_OBJ=
1611   VMLIMIT_OBJ=
1612 else
1613   test "$doug_lea_malloc" != "yes" && GMALLOC_OBJ=gmalloc.o
1614   VMLIMIT_OBJ=vm-limit.o
1615 fi
1616 AC_SUBST(GMALLOC_OBJ)
1617 AC_SUBST(VMLIMIT_OBJ)
1618
1619 if test "$doug_lea_malloc" = "yes" ; then
1620   if test "$GNU_MALLOC" = yes ; then
1621     GNU_MALLOC_reason="
1622       (Using Doug Lea's new malloc from the GNU C Library.)"
1623   fi
1624   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1625             [Define to 1 if you are using the GNU C Library.])
1626
1627   ## Use mmap directly for allocating larger buffers.
1628   ## FIXME this comes from src/s/{gnu,gnu-linux}.h:
1629   ## #ifdef DOUG_LEA_MALLOC; #undef REL_ALLOC; #endif
1630   ## Does the AC_FUNC_MMAP test below make this check unecessary?
1631   case "$opsys" in
1632     gnu*) REL_ALLOC=no ;;
1633   esac
1634 fi
1635
1636 if test x"${REL_ALLOC}" = x; then
1637   REL_ALLOC=${GNU_MALLOC}
1638 fi
1639
1640 use_mmap_for_buffers=no
1641 case "$opsys" in
1642   freebsd|irix6-5) use_mmap_for_buffers=yes ;;
1643 esac
1644
1645 AC_FUNC_MMAP
1646 if test $use_mmap_for_buffers = yes; then
1647   AC_DEFINE(USE_MMAP_FOR_BUFFERS, 1, [Define to use mmap to allocate buffer text.])
1648   REL_ALLOC=no
1649 fi
1650
1651 LIBS="$LIBS_SYSTEM $LIBS"
1652
1653 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1654 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1655 AC_CHECK_LIB(dnet, dnet_ntoa)
1656 dnl This causes -lresolv to get used in subsequent tests,
1657 dnl which causes failures on some systems such as HPUX 9.
1658 dnl AC_CHECK_LIB(resolv, gethostbyname)
1659
1660 dnl FIXME replace main with a function we actually want from this library.
1661 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1662
1663 AC_CHECK_LIB(pthreads, cma_open)
1664
1665 ## Note: when using cpp in s/aix4.2.h, this definition depended on
1666 ## HAVE_LIBPTHREADS.  That was not defined earlier in configure when
1667 ## the system file was sourced.  Hence the value of LIBS_SYSTEM
1668 ## added to LIBS in configure would never contain the pthreads part,
1669 ## but the value used in Makefiles might.  FIXME?
1670 ##
1671 ## -lpthreads seems to be necessary for Xlib in X11R6, and should
1672 ## be harmless on older versions of X where it happens to exist.
1673 test "$opsys" = "aix4-2" && \
1674   test $ac_cv_lib_pthreads_cma_open = yes && \
1675   LIBS_SYSTEM="$LIBS_SYSTEM -lpthreads"
1676
1677 dnl Check for need for bigtoc support on IBM AIX
1678
1679 case ${host_os} in
1680 aix*)
1681   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1682     case $GCC in
1683     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1684     *) gdb_cv_bigtoc=-bbigtoc ;;
1685     esac
1686
1687     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1688     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1689   ])
1690   ;;
1691 esac
1692
1693 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1694 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1695 # REAL_CPPFLAGS later on.
1696
1697 REAL_CFLAGS="$CFLAGS"
1698 REAL_CPPFLAGS="$CPPFLAGS"
1699
1700 if test "${HAVE_X11}" = "yes"; then
1701   DEFS="$C_SWITCH_X_SITE $DEFS"
1702   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1703   LIBS="-lX11 $LIBS"
1704   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1705   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1706
1707   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1708   # This is handled by LD_SWITCH_X_SITE_AUX during the real build,
1709   # but it's more convenient here to set LD_RUN_PATH
1710   # since this also works on hosts that don't understand LD_SWITCH_X_SITE_AUX.
1711   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1712     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1713     export LD_RUN_PATH
1714   fi
1715
1716   if test "${opsys}" = "gnu-linux"; then
1717     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1718     AC_TRY_LINK([],
1719      [XOpenDisplay ("foo");],
1720      [xlinux_first_failure=no],
1721      [xlinux_first_failure=yes])
1722     if test "${xlinux_first_failure}" = "yes"; then
1723       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1724       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1725       OLD_CPPFLAGS="$CPPFLAGS"
1726       OLD_LIBS="$LIBS"
1727       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1728       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1729       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1730       LIBS="$LIBS -b i486-linuxaout"
1731       AC_TRY_LINK([],
1732        [XOpenDisplay ("foo");],
1733        [xlinux_second_failure=no],
1734        [xlinux_second_failure=yes])
1735       if test "${xlinux_second_failure}" = "yes"; then
1736         # If we get the same failure with -b, there is no use adding -b.
1737         # So take it out.  This plays safe.
1738         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1739         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1740         CPPFLAGS="$OLD_CPPFLAGS"
1741         LIBS="$OLD_LIBS"
1742         AC_MSG_RESULT(no)
1743       else
1744         AC_MSG_RESULT(yes)
1745       fi
1746     else
1747       AC_MSG_RESULT(no)
1748     fi
1749   fi
1750
1751   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1752   # header files included from there.
1753   AC_MSG_CHECKING(for Xkb)
1754   AC_TRY_LINK([#include <X11/Xlib.h>
1755 #include <X11/XKBlib.h>],
1756         [XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);],
1757         emacs_xkb=yes, emacs_xkb=no)
1758   AC_MSG_RESULT($emacs_xkb)
1759   if test $emacs_xkb = yes; then
1760     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1761   fi
1762
1763   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1764 XScreenNumberOfScreen XSetWMProtocols)
1765 fi
1766
1767 if test "${window_system}" = "x11"; then
1768   AC_MSG_CHECKING(X11 version 6)
1769   AC_CACHE_VAL(emacs_cv_x11_version_6,
1770   [AC_TRY_LINK([#include <X11/Xlib.h>],
1771 [#if XlibSpecificationRelease < 6
1772 fail;
1773 #endif
1774 ], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1775   if test $emacs_cv_x11_version_6 = yes; then
1776     AC_MSG_RESULT(6 or newer)
1777     AC_DEFINE(HAVE_X11R6, 1,
1778               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1779     AC_DEFINE(HAVE_X_I18N, 1, [Define if you have usable i18n support.])
1780     ## inoue@ainet.or.jp says Solaris has a bug related to X11R6-style
1781     ## XIM support.
1782     case "$opsys" in
1783       sol2-*) : ;;
1784       *) AC_DEFINE(HAVE_X11R6_XIM, 1,
1785            [Define if you have usable X11R6-style XIM support.])
1786          ;;
1787     esac
1788   else
1789     AC_MSG_RESULT(before 6)
1790   fi
1791 fi
1792
1793
1794 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1795 HAVE_RSVG=no
1796 if test "${HAVE_X11}" = "yes" || test "${NS_IMPL_GNUSTEP}" = "yes"; then
1797   if test "${with_rsvg}" != "no"; then
1798     RSVG_REQUIRED=2.11.0
1799     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1800
1801     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, HAVE_RSVG=yes, :)
1802     AC_SUBST(RSVG_CFLAGS)
1803     AC_SUBST(RSVG_LIBS)
1804
1805     if test $HAVE_RSVG = yes; then
1806       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1807       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1808       LIBS="$RSVG_LIBS $LIBS"
1809     fi
1810   fi
1811 fi
1812
1813 HAVE_IMAGEMAGICK=no
1814 if test "${HAVE_X11}" = "yes"; then
1815   if test "${with_imagemagick}" != "no"; then
1816     IMAGEMAGICK_MODULE="Wand"
1817     PKG_CHECK_MODULES(IMAGEMAGICK, $IMAGEMAGICK_MODULE, HAVE_IMAGEMAGICK=yes, :)
1818     AC_SUBST(IMAGEMAGICK_CFLAGS)
1819     AC_SUBST(IMAGEMAGICK_LIBS)
1820
1821     if test $HAVE_IMAGEMAGICK = yes; then
1822       AC_DEFINE(HAVE_IMAGEMAGICK, 1, [Define to 1 if using imagemagick.])
1823       CFLAGS="$CFLAGS $IMAGEMAGICK_CFLAGS"
1824       LIBS="$IMAGEMAGICK_LIBS $LIBS"
1825       AC_CHECK_FUNCS(MagickExportImagePixels)
1826     fi
1827   fi
1828 fi
1829
1830
1831 HAVE_GTK=no
1832 if test "${with_gtk3}" = "yes"; then
1833   GLIB_REQUIRED=2.6
1834   GTK_REQUIRED=2.90
1835   GTK_MODULES="gtk+-3.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1836
1837   dnl Checks for libraries.
1838   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1839   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1840      AC_MSG_ERROR($GTK_PKG_ERRORS)
1841   fi
1842 fi
1843
1844 if test "$pkg_check_gtk" != "yes"; then
1845   HAVE_GTK=no
1846 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
1847   GLIB_REQUIRED=2.6
1848   GTK_REQUIRED=2.6
1849   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1850
1851   dnl Checks for libraries.
1852   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1853   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1854      AC_MSG_ERROR($GTK_PKG_ERRORS)
1855   fi
1856 fi
1857 fi
1858
1859 GTK_OBJ=
1860 if test x"$pkg_check_gtk" = xyes; then
1861
1862   AC_SUBST(GTK_CFLAGS)
1863   AC_SUBST(GTK_LIBS)
1864   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1865   CFLAGS="$CFLAGS $GTK_CFLAGS"
1866   LIBS="$GTK_LIBS $LIBS"
1867   dnl Try to compile a simple GTK program.
1868   GTK_COMPILES=no
1869   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
1870   if test "${GTK_COMPILES}" != "yes"; then
1871     if test "$USE_X_TOOLKIT" != "maybe"; then
1872       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
1873     fi
1874   else
1875     HAVE_GTK=yes
1876     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
1877     GTK_OBJ=gtkutil.o
1878     USE_X_TOOLKIT=none
1879     if $PKG_CONFIG --atleast-version=2.10 gtk+-2.0; then
1880       :
1881     else
1882       AC_MSG_WARN([[Your version of Gtk+ will have problems with
1883        closing open displays.  This is no problem if you just use
1884        one display, but if you use more than one and close one of them
1885        Emacs may crash.]])
1886       sleep 3
1887     fi
1888   fi
1889
1890 fi
1891 AC_SUBST(GTK_OBJ)
1892
1893
1894 if test "${HAVE_GTK}" = "yes"; then
1895
1896   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
1897   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
1898   if test "$with_toolkit_scroll_bars" != no; then
1899     with_toolkit_scroll_bars=yes
1900   fi
1901
1902   dnl  Check if we have the old file selection dialog declared and
1903   dnl  in the link library.  In 2.x it may be in the library,
1904   dnl  but not declared if deprecated featured has been selected out.
1905   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
1906   HAVE_GTK_FILE_SELECTION=no
1907   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
1908                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
1909 #include <gtk/gtk.h>])
1910   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
1911     AC_CHECK_FUNCS(gtk_file_selection_new)
1912   fi
1913
1914   dnl Check if pthreads are available.  Emacs only needs this when using
1915   dnl gtk_file_chooser under Gnome.
1916     HAVE_GTK_AND_PTHREAD=no
1917     AC_CHECK_HEADERS(pthread.h)
1918     if test "$ac_cv_header_pthread_h"; then
1919       AC_CHECK_LIB(pthread, pthread_self, HAVE_GTK_AND_PTHREAD=yes)
1920     fi
1921     if test "$HAVE_GTK_AND_PTHREAD" = yes; then
1922       case "${canonical}" in
1923         *-hpux*) ;;
1924         *) GTK_LIBS="$GTK_LIBS -lpthread" ;;
1925       esac
1926       AC_DEFINE(HAVE_GTK_AND_PTHREAD, 1,
1927                [Define to 1 if you have GTK and pthread (-lpthread).])
1928     fi
1929
1930   dnl Check for functions introduced in 2.14 and later.
1931   AC_CHECK_FUNCS(gtk_widget_get_window gtk_widget_set_has_window \
1932                  gtk_dialog_get_action_area gtk_widget_get_sensitive \
1933                  gtk_widget_get_mapped gtk_adjustment_get_page_size \
1934                  gtk_orientable_set_orientation)
1935
1936 fi
1937
1938 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
1939 dnl other platforms.  Support for higher D-Bus versions than 1.0 is
1940 dnl also not configured.
1941 HAVE_DBUS=no
1942 DBUS_OBJ=
1943 if test "${with_dbus}" = "yes"; then
1944    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
1945    if test "$HAVE_DBUS" = yes; then
1946      LIBS="$LIBS $DBUS_LIBS"
1947      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
1948      AC_CHECK_FUNCS([dbus_watch_get_unix_fd])
1949      DBUS_OBJ=dbusbind.o
1950    fi
1951 fi
1952 AC_SUBST(DBUS_OBJ)
1953
1954 dnl GConf has been tested under GNU/Linux only.
1955 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
1956 HAVE_GCONF=no
1957 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
1958    PKG_CHECK_MODULES(GCONF, gconf-2.0 >= 2.13, HAVE_GCONF=yes, HAVE_GCONF=no)
1959    if test "$HAVE_GCONF" = yes; then
1960       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
1961       dnl Newer GConf doesn't link with g_objects, so this is not defined.
1962       AC_CHECK_FUNCS([g_type_init])
1963    fi
1964 fi
1965
1966 dnl SELinux is available for GNU/Linux only.
1967 HAVE_LIBSELINUX=no
1968 LIBSELINUX_LIBS=
1969 if test "${with_selinux}" = "yes"; then
1970    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
1971    if test "$HAVE_LIBSELINUX" = yes; then
1972       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
1973       LIBSELINUX_LIBS=-lselinux
1974    fi
1975 fi
1976 AC_SUBST(LIBSELINUX_LIBS)
1977
1978 HAVE_GNUTLS=no
1979 if test "${with_gnutls}" = "yes" ; then
1980   PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= 2.2.4], HAVE_GNUTLS=yes, HAVE_GNUTLS=no)
1981   if test "${HAVE_GNUTLS}" = "yes"; then
1982     AC_DEFINE(HAVE_GNUTLS, 1, [Define if using GnuTLS.])
1983   fi
1984 fi
1985 AC_SUBST(LIBGNUTLS_LIBS)
1986 AC_SUBST(LIBGNUTLS_CFLAGS)
1987
1988 dnl Do not put whitespace before the #include statements below.
1989 dnl Older compilers (eg sunos4 cc) choke on it.
1990 HAVE_XAW3D=no
1991 LUCID_LIBW=
1992 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
1993   if test "$with_xaw3d" != no; then
1994     AC_MSG_CHECKING(for xaw3d)
1995     AC_CACHE_VAL(emacs_cv_xaw3d,
1996     [AC_TRY_LINK([
1997 #include <X11/Intrinsic.h>
1998 #include <X11/Xaw3d/Simple.h>],
1999       [],
2000       emacs_cv_xaw3d=yes,
2001       emacs_cv_xaw3d=no)])
2002   else
2003     emacs_cv_xaw3d=no
2004   fi
2005   if test $emacs_cv_xaw3d = yes; then
2006     AC_MSG_RESULT([yes; using Lucid toolkit])
2007     USE_X_TOOLKIT=LUCID
2008     HAVE_XAW3D=yes
2009     LUCID_LIBW=-lXaw3d
2010     AC_DEFINE(HAVE_XAW3D, 1,
2011               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
2012   else
2013     AC_MSG_RESULT(no)
2014     AC_MSG_CHECKING(for libXaw)
2015     AC_CACHE_VAL(emacs_cv_xaw,
2016     [AC_TRY_LINK([
2017 #include <X11/Intrinsic.h>
2018 #include <X11/Xaw/Simple.h>],
2019       [],
2020       emacs_cv_xaw=yes,
2021       emacs_cv_xaw=no)])
2022     if test $emacs_cv_xaw = yes; then
2023       AC_MSG_RESULT([yes; using Lucid toolkit])
2024       USE_X_TOOLKIT=LUCID
2025       LUCID_LIBW=-lXaw
2026     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
2027       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
2028     else
2029       AC_MSG_RESULT([no; do not use toolkit by default])
2030       USE_X_TOOLKIT=none
2031     fi
2032   fi
2033 fi
2034
2035 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
2036
2037 LIBXTR6=
2038 if test "${USE_X_TOOLKIT}" != "none"; then
2039   AC_MSG_CHECKING(X11 toolkit version)
2040   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2041   [AC_TRY_LINK([#include <X11/Intrinsic.h>],
2042 [#if XtSpecificationRelease < 6
2043 fail;
2044 #endif
2045 ], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2046   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2047   if test $emacs_cv_x11_toolkit_version_6 = yes; then
2048     AC_MSG_RESULT(6 or newer)
2049     AC_DEFINE(HAVE_X11XTR6, 1,
2050               [Define to 1 if you have the X11R6 or newer version of Xt.])
2051     LIBXTR6="-lSM -lICE"
2052     case "$opsys" in
2053       ## Use libw.a along with X11R6 Xt.
2054       unixware) LIBXTR6="$LIBXTR6 -lw" ;;
2055     esac
2056   else
2057     AC_MSG_RESULT(before 6)
2058   fi
2059
2060 dnl If using toolkit, check whether libXmu.a exists.
2061 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2062   OLDLIBS="$LIBS"
2063   if test x$HAVE_X11XTR6 = xyes; then
2064     LIBS="-lXt -lSM -lICE $LIBS"
2065   else
2066     LIBS="-lXt $LIBS"
2067   fi
2068   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
2069   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
2070 fi
2071 AC_SUBST(LIBXTR6)
2072
2073 dnl FIXME the logic here seems weird, but this is what cpp was doing.
2074 dnl Why not just test for libxmu in the normal way?
2075 LIBXMU=-lXmu
2076 case $opsys in
2077   ## These systems don't supply Xmu.
2078   hpux* | aix4-2 )
2079     test "X$ac_cv_lib_Xmu_XmuConvertStandardSelection" != "Xyes" && LIBXMU=
2080     ;;
2081 esac
2082 AC_SUBST(LIBXMU)
2083
2084 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
2085 if test "${HAVE_X11}" = "yes"; then
2086   if test "${USE_X_TOOLKIT}" != "none"; then
2087     AC_CHECK_LIB(Xext, XShapeQueryExtension)
2088   fi
2089 fi
2090
2091 LIBXP=
2092 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2093   AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
2094   [AC_TRY_COMPILE([#include <Xm/Xm.h>],
2095     [#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2096 int x = 5;
2097 #else
2098 Motif version prior to 2.1.
2099 #endif],
2100     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2101   if test $emacs_cv_motif_version_2_1 = yes; then
2102     AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
2103   else
2104     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2105     # We put this in CFLAGS temporarily to precede other -I options
2106     # that might be in CFLAGS temporarily.
2107     # We put this in CPPFLAGS where it precedes the other -I options.
2108     OLD_CPPFLAGS=$CPPFLAGS
2109     OLD_CFLAGS=$CFLAGS
2110     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2111     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2112     [AC_TRY_COMPILE([#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>],
2113       [int x = 5;],
2114       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2115     if test $emacs_cv_lesstif = yes; then
2116       # Make sure this -I option remains in CPPFLAGS after it is set
2117       # back to REAL_CPPFLAGS.
2118       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
2119       # have those other -I options anyway.  Ultimately, having this
2120       # directory ultimately in CPPFLAGS will be enough.
2121       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
2122       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
2123     else
2124       CFLAGS=$OLD_CFLAGS
2125       CPPFLAGS=$OLD_CPPFLAGS
2126     fi
2127   fi
2128 fi
2129
2130 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2131 dnl using Motif or Xaw3d is available, and unless
2132 dnl --with-toolkit-scroll-bars=no was specified.
2133
2134 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2135             [Define to 1 if we should use toolkit scroll bars.])dnl
2136 USE_TOOLKIT_SCROLL_BARS=no
2137 if test "${with_toolkit_scroll_bars}" != "no"; then
2138   if test "${USE_X_TOOLKIT}" != "none"; then
2139     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2140       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2141       HAVE_XAW3D=no
2142       USE_TOOLKIT_SCROLL_BARS=yes
2143     elif test "${HAVE_XAW3D}" = "yes"; then
2144       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2145       USE_TOOLKIT_SCROLL_BARS=yes
2146     fi
2147   elif test "${HAVE_GTK}" = "yes"; then
2148     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2149     USE_TOOLKIT_SCROLL_BARS=yes
2150   elif test "${HAVE_NS}" = "yes"; then
2151     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2152     USE_TOOLKIT_SCROLL_BARS=yes
2153   fi
2154 fi
2155
2156 dnl See if XIM is available.
2157 AC_TRY_COMPILE([
2158           #include <X11/Xlib.h>
2159           #include <X11/Xresource.h>],
2160          [XIMProc  callback;],
2161          [HAVE_XIM=yes
2162          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
2163          HAVE_XIM=no)
2164
2165 dnl `--with-xim' now controls only the initial value of use_xim at run time.
2166
2167 if test "${with_xim}" != "no"; then
2168   AC_DEFINE(USE_XIM, 1,
2169             [Define to 1 if we should use XIM, if it is available.])
2170 fi
2171
2172
2173 if test "${HAVE_XIM}" != "no"; then
2174   late_CFLAGS=$CFLAGS
2175   if test "$GCC" = yes; then
2176     CFLAGS="$CFLAGS --pedantic-errors"
2177   fi
2178   AC_TRY_COMPILE([
2179 #include <X11/Xlib.h>
2180 #include <X11/Xresource.h>],
2181 [Display *display;
2182 XrmDatabase db;
2183 char *res_name;
2184 char *res_class;
2185 XIMProc  callback;
2186 XPointer *client_data;
2187 #ifndef __GNUC__
2188 /* If we're not using GCC, it's probably not XFree86, and this is
2189    probably right, but we can't use something like --pedantic-errors.  */
2190 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
2191                                            char*, XIMProc, XPointer*);
2192 #endif
2193 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
2194    client_data);],
2195     [emacs_cv_arg6_star=yes])
2196   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
2197          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
2198 either XPointer or XPointer*.])dnl
2199   if test "$emacs_cv_arg6_star" = yes; then
2200     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
2201   else
2202     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
2203   fi
2204   CFLAGS=$late_CFLAGS
2205 fi
2206
2207 ### Start of font-backend (under any platform) section.
2208 # (nothing here yet -- this is a placeholder)
2209 ### End of font-backend (under any platform) section.
2210
2211 ### Start of font-backend (under X11) section.
2212 if test "${HAVE_X11}" = "yes"; then
2213    PKG_CHECK_MODULES(FONTCONFIG, fontconfig >= 2.2.0, HAVE_FC=yes, HAVE_FC=no)
2214
2215    ## Use -lXft if available, unless `--with-xft=no'.
2216    HAVE_XFT=maybe
2217     if test "${HAVE_FC}" = "no" || test "x${with_x}" = "xno"; then
2218       with_xft="no";
2219     fi
2220     if test "x${with_xft}" != "xno"; then
2221
2222       PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
2223       ## Because xftfont.c uses XRenderQueryExtension, we also
2224       ## need to link to -lXrender.
2225       HAVE_XRENDER=no
2226       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
2227       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
2228         OLD_CPPFLAGS="$CPPFLAGS"
2229         OLD_CFLAGS="$CFLAGS"
2230         OLD_LIBS="$LIBS"
2231         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
2232         CFLAGS="$CFLAGS $XFT_CFLAGS"
2233         XFT_LIBS="-lXrender $XFT_LIBS"
2234         LIBS="$XFT_LIBS $LIBS"
2235         AC_CHECK_HEADER(X11/Xft/Xft.h,
2236           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS))
2237
2238         if test "${HAVE_XFT}" = "yes"; then
2239           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
2240             AC_SUBST(XFT_LIBS)
2241           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
2242         else
2243           CPPFLAGS="$OLD_CPPFLAGS"
2244           CFLAGS="$OLD_CFLAGS"
2245           LIBS="$OLD_LIBS"
2246         fi                        # "${HAVE_XFT}" = "yes"
2247       fi                          # "$HAVE_XFT" != no
2248     fi                            # "x${with_xft}" != "xno"
2249
2250     dnl For the "Does Emacs use" message at the end.
2251     if test "$HAVE_XFT" != "yes"; then
2252        HAVE_XFT=no
2253     fi
2254
2255     ## We used to allow building with FreeType and without Xft.
2256     ## However, the ftx font backend driver is not in good shape.
2257     HAVE_FREETYPE=$HAVE_XFT
2258
2259     HAVE_LIBOTF=no
2260     if test "${HAVE_FREETYPE}" = "yes"; then
2261       AC_DEFINE(HAVE_FREETYPE, 1,
2262                 [Define to 1 if using the freetype and fontconfig libraries.])
2263       if test "${with_libotf}" != "no"; then
2264         PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
2265                           HAVE_LIBOTF=no)
2266         if test "$HAVE_LIBOTF" = "yes"; then
2267           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
2268           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
2269                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
2270                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
2271           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
2272             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
2273                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
2274           fi
2275         fi
2276       fi
2277     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
2278     dnl Does the new font backend require it, or can it work without it?
2279     fi
2280
2281     HAVE_M17N_FLT=no
2282     if test "${HAVE_LIBOTF}" = yes; then
2283       if test "${with_m17n_flt}" != "no"; then
2284         PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
2285         if test "$HAVE_M17N_FLT" = "yes"; then
2286           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
2287         fi
2288       fi
2289     fi
2290 else
2291     HAVE_XFT=no
2292     HAVE_FREETYPE=no
2293     HAVE_LIBOTF=no
2294     HAVE_M17N_FLT=no
2295 fi
2296
2297 ### End of font-backend (under X11) section.
2298
2299 AC_SUBST(FREETYPE_CFLAGS)
2300 AC_SUBST(FREETYPE_LIBS)
2301 AC_SUBST(FONTCONFIG_CFLAGS)
2302 AC_SUBST(FONTCONFIG_LIBS)
2303 AC_SUBST(LIBOTF_CFLAGS)
2304 AC_SUBST(LIBOTF_LIBS)
2305 AC_SUBST(M17N_FLT_CFLAGS)
2306 AC_SUBST(M17N_FLT_LIBS)
2307
2308 ### Use -lXpm if available, unless `--with-xpm=no'.
2309 HAVE_XPM=no
2310 LIBXPM=
2311 if test "${HAVE_X11}" = "yes"; then
2312   if test "${with_xpm}" != "no"; then
2313     AC_CHECK_HEADER(X11/xpm.h,
2314       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2315     if test "${HAVE_XPM}" = "yes"; then
2316       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2317       AC_EGREP_CPP(no_return_alloc_pixels,
2318       [#include "X11/xpm.h"
2319 #ifndef XpmReturnAllocPixels
2320 no_return_alloc_pixels
2321 #endif
2322       ], HAVE_XPM=no, HAVE_XPM=yes)
2323
2324       if test "${HAVE_XPM}" = "yes"; then
2325         AC_MSG_RESULT(yes)
2326       else
2327         AC_MSG_RESULT(no)
2328       fi
2329     fi
2330   fi
2331
2332   if test "${HAVE_XPM}" = "yes"; then
2333     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm libary (-lXpm).])
2334     LIBXPM=-lXpm
2335   fi
2336 fi
2337 AC_SUBST(LIBXPM)
2338
2339 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2340 HAVE_JPEG=no
2341 LIBJPEG=
2342 if test "${HAVE_X11}" = "yes"; then
2343   if test "${with_jpeg}" != "no"; then
2344     dnl Checking for jpeglib.h can lose because of a redefinition of
2345     dnl  HAVE_STDLIB_H.
2346     AC_CHECK_HEADER(jerror.h,
2347       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
2348   fi
2349
2350   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2351   if test "${HAVE_JPEG}" = "yes"; then
2352     AC_DEFINE(HAVE_JPEG)
2353     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2354         [#include <jpeglib.h>
2355          version=JPEG_LIB_VERSION
2356 ],
2357         [AC_DEFINE(HAVE_JPEG)],
2358         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2359         HAVE_JPEG=no])
2360   fi
2361   if test "${HAVE_JPEG}" = "yes"; then
2362     LIBJPEG=-ljpeg
2363   fi
2364 fi
2365 AC_SUBST(LIBJPEG)
2366
2367 ### Use -lpng if available, unless `--with-png=no'.
2368 HAVE_PNG=no
2369 LIBPNG=
2370 if test "${HAVE_X11}" = "yes"; then
2371   if test "${with_png}" != "no"; then
2372     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
2373     # in /usr/include/libpng.
2374     AC_CHECK_HEADERS(png.h libpng/png.h)
2375     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2376       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2377     fi
2378   fi
2379
2380   if test "${HAVE_PNG}" = "yes"; then
2381     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2382     LIBPNG="-lpng -lz -lm"
2383   fi
2384 fi
2385 AC_SUBST(LIBPNG)
2386
2387 ### Use -ltiff if available, unless `--with-tiff=no'.
2388 HAVE_TIFF=no
2389 LIBTIFF=
2390 if test "${HAVE_X11}" = "yes"; then
2391   if test "${with_tiff}" != "no"; then
2392     AC_CHECK_HEADER(tiffio.h,
2393       [tifflibs="-lz -lm"
2394       # At least one tiff package requires the jpeg library.
2395       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2396       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
2397   fi
2398
2399   if test "${HAVE_TIFF}" = "yes"; then
2400     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2401     dnl FIXME -lz -lm, as per libpng?
2402     LIBTIFF=-ltiff
2403   fi
2404 fi
2405 AC_SUBST(LIBTIFF)
2406
2407 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2408 HAVE_GIF=no
2409 LIBGIF=
2410 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no"; then
2411   AC_CHECK_HEADER(gif_lib.h,
2412 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2413 # Earlier versions can crash Emacs.
2414     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])
2415
2416   if test "$HAVE_GIF" = yes; then
2417     LIBGIF=-lgif
2418   elif test "$HAVE_GIF" = maybe; then
2419 # If gif_lib.h but no libgif, try libungif.
2420     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
2421     test "$HAVE_GIF" = yes && LIBGIF=-lungif
2422   fi
2423
2424   if test "${HAVE_GIF}" = "yes"; then
2425     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
2426   fi
2427 fi
2428 AC_SUBST(LIBGIF)
2429
2430 dnl Check for required libraries.
2431 if test "${HAVE_X11}" = "yes"; then
2432   MISSING=""
2433   WITH_NO=""
2434   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2435     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2436   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2437     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2438   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2439     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2440   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2441     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2442   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2443     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2444
2445   if test "X${MISSING}" != X; then
2446     AC_MSG_ERROR([The following required libraries were not found:
2447     $MISSING
2448 Maybe some development libraries/packages are missing?
2449 If you don't want to link with them give
2450     $WITH_NO
2451 as options to configure])
2452   fi
2453 fi
2454
2455 ### Use -lgpm if available, unless `--with-gpm=no'.
2456 HAVE_GPM=no
2457 LIBGPM=
2458 MOUSE_SUPPORT=
2459 if test "${with_gpm}" != "no"; then
2460   AC_CHECK_HEADER(gpm.h,
2461     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2462
2463   if test "${HAVE_GPM}" = "yes"; then
2464     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2465     LIBGPM=-lgpm
2466     ## May be reset below.
2467     MOUSE_SUPPORT="\$(GPM_MOUSE_SUPPORT)"
2468   fi
2469 fi
2470 AC_SUBST(LIBGPM)
2471
2472 dnl Check for malloc/malloc.h on darwin
2473 AC_CHECK_HEADER(malloc/malloc.h, [AC_DEFINE(HAVE_MALLOC_MALLOC_H, 1, [Define to 1 if you have the <malloc/malloc.h> header file.])])
2474
2475 C_SWITCH_X_SYSTEM=
2476 ### Use NeXTstep API to implement GUI.
2477 if test "${HAVE_NS}" = "yes"; then
2478   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
2479   if test "${NS_IMPL_COCOA}" = "yes"; then
2480     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
2481     GNU_OBJC_CFLAGS=
2482   fi
2483   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
2484     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
2485     # See also .m.o rule in Makefile.in */
2486     # FIXME: are all these flags really needed?  Document here why.  */
2487     C_SWITCH_X_SYSTEM="-D_REENTRANT -fPIC -fno-strict-aliasing"
2488     GNU_OBJC_CFLAGS="-fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
2489   fi
2490   if test "${NS_HAVE_NSINTEGER}" = "yes"; then
2491     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
2492   fi
2493   # We also have mouse menus.
2494   HAVE_MENUS=yes
2495   OTHER_FILES=ns-app
2496 fi
2497
2498
2499 ### Use session management (-lSM -lICE) if available
2500 HAVE_X_SM=no
2501 LIBXSM=
2502 if test "${HAVE_X11}" = "yes"; then
2503   AC_CHECK_HEADER(X11/SM/SMlib.h,
2504     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2505
2506   if test "${HAVE_X_SM}" = "yes"; then
2507     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2508     LIBXSM="-lSM -lICE"
2509     case "$LIBS" in
2510       *-lSM*) ;;
2511       *)      LIBS="$LIBXSM $LIBS" ;;
2512     esac
2513   fi
2514 fi
2515 AC_SUBST(LIBXSM)
2516
2517 ### Use libxml (-lxml2) if available
2518 if test "${with_xml2}" != "no"; then
2519   ### I'm not sure what the version number should be, so I just guessed.
2520   PKG_CHECK_MODULES(LIBXML2, libxml-2.0 > 2.6.17, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
2521   if test "${HAVE_LIBXML2}" = "yes"; then
2522     LIBS="$LIBXML2_LIBS $LIBS"
2523     AC_CHECK_LIB(xml2, htmlReadMemory, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
2524     if test "${HAVE_LIBXML2}" = "yes"; then
2525       AC_DEFINE(HAVE_LIBXML2, 1, [Define to 1 if you have the libxml library (-lxml2).])
2526     else
2527       LIBXML2_LIBS=""
2528       LIBXML2_CFLAGS=""
2529     fi
2530   fi
2531 fi
2532 AC_SUBST(LIBXML2_LIBS)
2533 AC_SUBST(LIBXML2_CFLAGS)
2534
2535 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2536 AC_CACHE_CHECK(whether netdb declares h_errno,
2537                emacs_cv_netdb_declares_h_errno,
2538 [AC_TRY_LINK([#include <netdb.h>],
2539   [return h_errno;],
2540   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2541 if test $emacs_cv_netdb_declares_h_errno = yes; then
2542   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2543 fi
2544
2545 AC_FUNC_ALLOCA
2546
2547 dnl src/alloca.c has been removed.  Could also check if $ALLOCA is set?
2548 dnl FIXME is there an autoconf test that does the right thing, without
2549 dnl needing to call A_M_E afterwards?
2550 if test x"$ac_cv_func_alloca_works" != xyes; then
2551    AC_MSG_ERROR( [a system implementation of alloca is required] )
2552 fi
2553
2554 # fmod, logb, and frexp are found in -lm on most systems.
2555 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2556 AC_CHECK_LIB(m, sqrt)
2557
2558 # Check for mail-locking functions in a "mail" library.  Probably this should
2559 # have the same check as for liblockfile below.
2560 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
2561 if test $have_mail = yes; then
2562   LIBS_MAIL=-lmail
2563   LIBS="$LIBS_MAIL $LIBS"
2564   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the `mail' library (-lmail).])
2565 else
2566   LIBS_MAIL=
2567 fi
2568 dnl Debian, at least:
2569 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
2570 if test $have_lockfile = yes; then
2571    LIBS_MAIL=-llockfile
2572    LIBS="$LIBS_MAIL $LIBS"
2573    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the `lockfile' library (-llockfile).])
2574 else
2575 # If we have the shared liblockfile, assume we must use it for mail
2576 # locking (e.g. Debian).  If we couldn't link against liblockfile
2577 # (no liblockfile.a installed), ensure that we don't need to.
2578   dnl This works for files generally, not just executables.
2579   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2580   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2581                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2582   if test $ac_cv_prog_liblockfile = yes; then
2583     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2584 This probably means that movemail could lose mail.
2585 There may be a `development' package to install containing liblockfile.])
2586   fi
2587 fi
2588 AC_CHECK_FUNCS(touchlock)
2589 AC_CHECK_HEADERS(maillock.h)
2590 AC_SUBST(LIBS_MAIL)
2591
2592 ## Define MAIL_USE_FLOCK (or LOCKF) if the mailer uses flock (or lockf) to
2593 ## interlock access to the mail spool.  The alternative is a lock file named
2594 ## /usr/spool/mail/$USER.lock.
2595 mail_lock=no
2596 case "$opsys" in
2597   aix4-2) mail_lock="lockf" ;;
2598
2599   gnu|freebsd|netbsd|openbsd|darwin|irix6-5) mail_lock="flock" ;;
2600
2601   ## On GNU/Linux systems, both methods are used by various mail programs.
2602   ## I assume most people are using newer mailers that have heard of flock.
2603   ## Change this if you need to.
2604   ## Debian contains a patch which says: ``On Debian/GNU/Linux systems,
2605   ## configure gets the right answers, and that means *NOT* using flock.
2606   ## Using flock is guaranteed to be the wrong thing. See Debian Policy
2607   ## for details.'' and then uses `#ifdef DEBIAN'.  Unfortunately the
2608   ## Debian maintainer hasn't provided a clean fix for Emacs.
2609   ## movemail.c will use `maillock' when MAILDIR, HAVE_LIBMAIL and
2610   ## HAVE_MAILLOCK_H are defined, so the following appears to be the
2611   ## correct logic.  -- fx
2612   ## We must check for HAVE_LIBLOCKFILE too, as movemail does.
2613   ## liblockfile is a Free Software replacement for libmail, used on
2614   ## Debian systems and elsewhere. -rfr.
2615   gnu-*)
2616     mail_lock="flock"
2617     if test $have_mail = yes || test $have_lockfile = yes; then
2618       test $ac_cv_header_maillock_h = yes && mail_lock=no
2619     fi
2620     ;;
2621 esac
2622
2623 BLESSMAIL_TARGET=
2624 case "$mail_lock" in
2625   flock) AC_DEFINE(MAIL_USE_FLOCK, 1, [Define if the mailer uses flock to interlock the mail spool.]) ;;
2626
2627   lockf) AC_DEFINE(MAIL_USE_LOCKF, 1, [Define if the mailer uses lockf to interlock the mail spool.]) ;;
2628
2629   *) BLESSMAIL_TARGET="need-blessmail" ;;
2630 esac
2631 AC_SUBST(BLESSMAIL_TARGET)
2632
2633
2634 AC_CHECK_FUNCS(gethostname getdomainname dup2 \
2635 rename closedir mkdir rmdir sysinfo getrusage get_current_dir_name \
2636 random lrand48 logb frexp fmod rint cbrt ftime setsid \
2637 strerror fpathconf select euidaccess getpagesize tzset setlocale \
2638 utimes getrlimit setrlimit setpgid getcwd getwd shutdown getaddrinfo \
2639 __fpending mblen mbrlen mbsinit strsignal setitimer ualarm strchr strrchr \
2640 sendto recvfrom getsockopt setsockopt getsockname getpeername \
2641 gai_strerror mkstemp getline getdelim mremap memmove fsync sync \
2642 memset memcmp difftime memcpy mempcpy mblen mbrlen posix_memalign \
2643 cfmakeraw cfsetspeed isnan copysign __executable_start)
2644
2645 dnl Cannot use AC_CHECK_FUNCS
2646 AC_CACHE_CHECK([for __builtin_unwind_init],
2647                emacs_cv_func___builtin_unwind_init,
2648 [AC_LINK_IFELSE([AC_LANG_PROGRAM([], [__builtin_unwind_init ();])],
2649                 emacs_cv_func___builtin_unwind_init=yes,
2650                 emacs_cv_func___builtin_unwind_init=no)])
2651 if test $emacs_cv_func___builtin_unwind_init = yes; then
2652   AC_DEFINE(HAVE___BUILTIN_UNWIND_INIT, 1,
2653             [Define to 1 if you have the `__builtin_unwind_init' function.])
2654 fi
2655
2656 AC_CHECK_HEADERS(sys/un.h)
2657
2658 AC_FUNC_GETLOADAVG
2659
2660 AC_FUNC_FSEEKO
2661
2662 AC_FUNC_GETPGRP
2663
2664 # Configure gnulib.
2665 gl_ASSERT_NO_GNULIB_POSIXCHECK
2666 gl_ASSERT_NO_GNULIB_TESTS
2667 gl_INIT
2668
2669 AC_FUNC_STRFTIME
2670
2671 # UNIX98 PTYs.
2672 AC_CHECK_FUNCS(grantpt)
2673
2674 # PTY-related GNU extensions.
2675 AC_CHECK_FUNCS(getpt)
2676
2677 # Check this now, so that we will NOT find the above functions in ncurses.
2678 # That is because we have not set up to link ncurses in lib-src.
2679 # It's better to believe a function is not available
2680 # than to expect to find it in ncurses.
2681 # Also we need tputs and friends to be able to build at all.
2682 have_tputs_et_al=true
2683 AC_SEARCH_LIBS(tputs, [ncurses terminfo termcap], , have_tputs_et_al=false)
2684 if test "$have_tputs_et_al" != true; then
2685   AC_MSG_ERROR([I couldn't find termcap functions (tputs and friends).
2686 Maybe some development libraries/packages are missing?  Try installing
2687 libncurses-dev(el), libterminfo-dev(el) or similar.])
2688 fi
2689 # Must define this when any termcap library is found.
2690 AC_DEFINE(HAVE_LIBNCURSES, 1,
2691           [Define to 1 if you have the `ncurses' library (-lncurses).])
2692 ## FIXME This was the cpp logic, but I am not sure it is right.
2693 ## The above test has not necessarily found libncurses.
2694 HAVE_LIBNCURSES=yes
2695
2696 ## Use terminfo instead of termcap?
2697 ## Note only system files NOT using terminfo are:
2698 ## freebsd < 40000, ms-w32, msdos, netbsd < 599002500, and
2699 ## darwin|gnu without ncurses.
2700 TERMINFO=no
2701 LIBS_TERMCAP=
2702 case "$opsys" in
2703   ## cygwin: Fewer environment variables to go wrong, more terminal types.
2704   ## hpux10-20: Use the system provided termcap(3) library.
2705   ## openbsd: David Mazieres <dm@reeducation-labor.lcs.mit.edu> says this
2706   ##  is necessary.  Otherwise Emacs dumps core when run -nw.
2707   aix4-2|cygwin|hpux*|irix6-5|openbsd|sol2*|unixware) TERMINFO=yes ;;
2708
2709   ## darwin: Prevents crashes when running Emacs in Terminal.app under 10.2.
2710   ##  The ncurses library has been moved out of the System framework in
2711   ##  Mac OS X 10.2.  So if configure detects it, set the command-line
2712   ##  option to use it.
2713   darwin|gnu*)
2714     ## (HAVE_LIBNCURSES was not always true, but is since 2010-03-18.)
2715     if test "x$HAVE_LIBNCURSES" = "xyes"; then
2716       TERMINFO=yes
2717       LIBS_TERMCAP="-lncurses"
2718     fi
2719     ;;
2720
2721   freebsd)
2722     AC_MSG_CHECKING([whether FreeBSD is new enough to use terminfo])
2723     AC_CACHE_VAL(emacs_cv_freebsd_terminfo,
2724     [AC_TRY_LINK([#include <osreldate.h>],
2725 [#if __FreeBSD_version < 400000
2726 fail;
2727 #endif
2728 ], emacs_cv_freebsd_terminfo=yes, emacs_cv_freebsd_terminfo=no)])
2729
2730     AC_MSG_RESULT($emacs_cv_freebsd_terminfo)
2731
2732     if test $emacs_cv_freebsd_terminfo = yes; then
2733       TERMINFO=yes
2734       LIBS_TERMCAP="-lncurses"
2735     else
2736       LIBS_TERMCAP="-ltermcap"
2737     fi
2738     ;;
2739
2740   netbsd)
2741     if test $ac_cv_search_tputs = -lterminfo; then
2742       TERMINFO=yes
2743       LIBS_TERMCAP="-lterminfo"
2744     else
2745       LIBS_TERMCAP="-ltermcap"
2746     fi
2747     ;;
2748
2749 esac
2750
2751 case "$opsys" in
2752   ## hpux: Make sure we get select from libc rather than from libcurses
2753   ##  because libcurses on HPUX 10.10 has a broken version of select.
2754   ##  We used to use -lc -lcurses, but this may be cleaner.
2755   hpux*) LIBS_TERMCAP="-ltermcap" ;;
2756
2757   openbsd) LIBS_TERMCAP="-lncurses" ;;
2758
2759   ## Must use system termcap, if we use any termcap.  It does special things.
2760   sol2*) test "$TERMINFO" != yes && LIBS_TERMCAP="-ltermcap" ;;
2761 esac
2762
2763 TERMCAP_OBJ=tparam.o
2764 if test $TERMINFO = yes; then
2765   AC_DEFINE(TERMINFO, 1, [Define to 1 if you use terminfo instead of termcap.])
2766
2767   ## Default used to be -ltermcap.  Add a case above if need something else.
2768   test "x$LIBS_TERMCAP" = "x" && LIBS_TERMCAP="-lcurses"
2769
2770   TERMCAP_OBJ=terminfo.o
2771 fi
2772 AC_SUBST(LIBS_TERMCAP)
2773 AC_SUBST(TERMCAP_OBJ)
2774
2775
2776 # Do we have res_init, for detecting changes in /etc/resolv.conf?
2777 resolv=no
2778 AC_TRY_LINK([#include <netinet/in.h>
2779 #include <arpa/nameser.h>
2780 #include <resolv.h>],
2781     [return res_init();],
2782     have_res_init=yes, have_res_init=no)
2783 if test "$have_res_init" = no; then
2784   OLIBS="$LIBS"
2785   LIBS="$LIBS -lresolv"
2786   AC_MSG_CHECKING(for res_init with -lresolv)
2787   AC_TRY_LINK([#include <netinet/in.h>
2788 #include <arpa/nameser.h>
2789 #include <resolv.h>],
2790     [return res_init();],
2791     have_res_init=yes, have_res_init=no)
2792   AC_MSG_RESULT($have_res_init)
2793   if test "$have_res_init" = yes ; then
2794     resolv=yes
2795   fi
2796   LIBS="$OLIBS"
2797 fi
2798
2799 if test "$have_res_init" = yes; then
2800   AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
2801 fi
2802
2803 # Do we need the Hesiod library to provide the support routines?
2804 LIBHESIOD=
2805 if test "$with_hesiod" != no ; then
2806   # Don't set $LIBS here -- see comments above.  FIXME which comments?
2807   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2808      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2809                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2810   if test "$resolv" = yes ; then
2811     RESOLVLIB=-lresolv
2812   else
2813     RESOLVLIB=
2814   fi
2815   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2816         hesiod=yes, :, $RESOLVLIB)])
2817
2818   if test x"$hesiod" = xyes; then
2819     AC_DEFINE(HAVE_LIBHESIOD, 1,
2820               [Define to 1 if you have the hesiod library (-lhesiod).])
2821     LIBHESIOD=-lhesiod
2822   fi
2823 fi
2824 AC_SUBST(LIBHESIOD)
2825
2826 # Do we need libresolv (due to res_init or Hesiod)?
2827 if test "$resolv" = yes ; then
2828   AC_DEFINE(HAVE_LIBRESOLV, 1,
2829             [Define to 1 if you have the resolv library (-lresolv).])
2830   LIBRESOLV=-lresolv
2831 else
2832   LIBRESOLV=
2833 fi
2834 AC_SUBST(LIBRESOLV)
2835
2836 # These tell us which Kerberos-related libraries to use.
2837 COM_ERRLIB=
2838 CRYPTOLIB=
2839 KRB5LIB=
2840 DESLIB=
2841 KRB4LIB=
2842
2843 if test "${with_kerberos}" != no; then
2844   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
2845   if test $have_com_err = yes; then
2846     COM_ERRLIB=-lcom_err
2847     LIBS="$COM_ERRLIB $LIBS"
2848     AC_DEFINE(HAVE_LIBCOM_ERR, 1, [Define to 1 if you have the `com_err' library (-lcom_err).])
2849   fi
2850   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
2851   if test $have_crypto = yes; then
2852     CRYPTOLIB=-lcrypto
2853     LIBS="$CRYPTOLIB $LIBS"
2854     AC_DEFINE(HAVE_LIBCRYPTO, 1, [Define to 1 if you have the `crypto' library (-lcrypto).])
2855   fi
2856   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
2857   if test $have_k5crypto = yes; then
2858     CRYPTOLIB=-lk5crypto
2859     LIBS="$CRYPTOLIB $LIBS"
2860     AC_DEFINE(HAVE_LIBK5CRYPTO, 1, [Define to 1 if you have the `k5crypto' library (-lk5crypto).])
2861   fi
2862   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
2863   if test $have_krb5=yes; then
2864     KRB5LIB=-lkrb5
2865     LIBS="$KRB5LIB $LIBS"
2866     AC_DEFINE(HAVE_LIBKRB5, 1, [Define to 1 if you have the `krb5' library (-lkrb5).])
2867   fi
2868   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
2869   if test "${with_kerberos5}" = no; then
2870     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
2871     if test $have_des425 = yes; then
2872       DESLIB=-ldes425
2873       LIBS="$DESLIB $LIBS"
2874       AC_DEFINE(HAVE_LIBDES425, 1, [Define to 1 if you have the `des425' library (-ldes425).])
2875     else
2876       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
2877       if test $have_des = yes; then
2878         DESLIB=-ldes
2879         LIBS="$DESLIB $LIBS"
2880         AC_DEFINE(HAVE_LIBDES, 1, [Define to 1 if you have the `des' library (-ldes).])
2881       fi
2882     fi
2883     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
2884     if test $have_krb4 = yes; then
2885       KRB4LIB=-lkrb4
2886       LIBS="$KRB4LIB $LIBS"
2887       AC_DEFINE(HAVE_LIBKRB4, 1, [Define to 1 if you have the `krb4' library (-lkrb4).])
2888     else
2889       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
2890       if test $have_krb = yes; then
2891         KRB4LIB=-lkrb
2892         LIBS="$KRB4LIB $LIBS"
2893         AC_DEFINE(HAVE_LIBKRB, 1, [Define to 1 if you have the `krb' library (-lkrb).])
2894       fi
2895     fi
2896   fi
2897
2898   if test "${with_kerberos5}" != no; then
2899     AC_CHECK_HEADERS(krb5.h,
2900       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
2901                         [#include <krb5.h>])])
2902   else
2903     AC_CHECK_HEADERS(des.h,,
2904                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
2905                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
2906     AC_CHECK_HEADERS(krb.h,,
2907                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
2908                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
2909   fi
2910   AC_CHECK_HEADERS(com_err.h)
2911 fi
2912
2913 AC_SUBST(COM_ERRLIB)
2914 AC_SUBST(CRYPTOLIB)
2915 AC_SUBST(KRB5LIB)
2916 AC_SUBST(DESLIB)
2917 AC_SUBST(KRB4LIB)
2918
2919 # Solaris requires -lintl if you want strerror (which calls dgettext)
2920 # to return localized messages.
2921 AC_CHECK_LIB(intl, dgettext)
2922
2923 AC_MSG_CHECKING(whether localtime caches TZ)
2924 AC_CACHE_VAL(emacs_cv_localtime_cache,
2925 [if test x$ac_cv_func_tzset = xyes; then
2926 AC_TRY_RUN([#include <time.h>
2927 char TZ_GMT0[] = "TZ=GMT0";
2928 char TZ_PST8[] = "TZ=PST8";
2929 main()
2930 {
2931   time_t now = time ((time_t *) 0);
2932   int hour_GMT0, hour_unset;
2933   if (putenv (TZ_GMT0) != 0)
2934     exit (1);
2935   hour_GMT0 = localtime (&now)->tm_hour;
2936   unsetenv("TZ");
2937   hour_unset = localtime (&now)->tm_hour;
2938   if (putenv (TZ_PST8) != 0)
2939     exit (1);
2940   if (localtime (&now)->tm_hour == hour_GMT0)
2941     exit (1);
2942   unsetenv("TZ");
2943   if (localtime (&now)->tm_hour != hour_unset)
2944     exit (1);
2945   exit (0);
2946 }], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
2947 [# If we have tzset, assume the worst when cross-compiling.
2948 emacs_cv_localtime_cache=yes])
2949 else
2950         # If we lack tzset, report that localtime does not cache TZ,
2951         # since we can't invalidate the cache if we don't have tzset.
2952         emacs_cv_localtime_cache=no
2953 fi])dnl
2954 AC_MSG_RESULT($emacs_cv_localtime_cache)
2955 if test $emacs_cv_localtime_cache = yes; then
2956   AC_DEFINE(LOCALTIME_CACHE, 1,
2957             [Define to 1 if localtime caches TZ.])
2958 fi
2959
2960 if test "x$HAVE_TIMEVAL" = xyes; then
2961   AC_CHECK_FUNCS(gettimeofday)
2962   if test $ac_cv_func_gettimeofday = yes; then
2963     AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
2964                    emacs_cv_gettimeofday_two_arguments,
2965     [AC_TRY_COMPILE([
2966 #ifdef TIME_WITH_SYS_TIME
2967 #include <sys/time.h>
2968 #include <time.h>
2969 #else
2970 #ifdef HAVE_SYS_TIME_H
2971 #include <sys/time.h>
2972 #else
2973 #include <time.h>
2974 #endif
2975 #endif],
2976       [struct timeval time;
2977        gettimeofday (&time, 0);],
2978       emacs_cv_gettimeofday_two_arguments=yes,
2979       emacs_cv_gettimeofday_two_arguments=no)])
2980     if test $emacs_cv_gettimeofday_two_arguments = no; then
2981       AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT, 1,
2982                 [Define to 1 if gettimeofday accepts only one argument.])
2983     fi
2984   fi
2985 fi
2986
2987 ok_so_far=yes
2988 AC_CHECK_FUNC(socket, , ok_so_far=no)
2989 if test $ok_so_far = yes; then
2990   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
2991 fi
2992 if test $ok_so_far = yes; then
2993   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
2994 fi
2995 if test $ok_so_far = yes; then
2996 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
2997   AC_DEFINE(HAVE_INET_SOCKETS, 1,
2998             [Define to 1 if you have inet sockets.])
2999 fi
3000
3001 if test -f /usr/lpp/X11/bin/smt.exp; then
3002   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
3003             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
3004 fi
3005
3006 AC_MSG_CHECKING(whether system supports dynamic ptys)
3007 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
3008   AC_MSG_RESULT(yes)
3009   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
3010 else
3011   AC_MSG_RESULT(no)
3012 fi
3013
3014 AC_FUNC_FORK
3015
3016 dnl Adapted from Haible's version.
3017 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
3018   [AC_TRY_LINK([#include <langinfo.h>],
3019     [char* cs = nl_langinfo(CODESET);],
3020     emacs_cv_langinfo_codeset=yes,
3021     emacs_cv_langinfo_codeset=no)
3022   ])
3023 if test $emacs_cv_langinfo_codeset = yes; then
3024   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
3025     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
3026 fi
3027
3028 AC_CHECK_TYPES(size_t)
3029
3030 AC_TYPE_MBSTATE_T
3031
3032 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
3033   [AC_TRY_COMPILE([void fred (int x[__restrict]);], [],
3034                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
3035 if test "$emacs_cv_c_restrict_arr" = yes; then
3036   AC_DEFINE(__restrict_arr, __restrict,
3037     [Define to compiler's equivalent of C99 restrict keyword in array
3038      declarations.  Define as empty for no equivalent.])
3039 fi
3040
3041 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
3042 dnl how the tty code is related to POSIX and/or other versions of termios.
3043 dnl The following looks like a useful start.
3044 dnl
3045 dnl AC_SYS_POSIX_TERMIOS
3046 dnl if test $ac_cv_sys_posix_termios = yes; then
3047 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
3048 dnl                                and macros for terminal control.])
3049 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
3050 dnl fi
3051
3052 dnl Fixme: Use AC_FUNC_MEMCMP since memcmp is used.  (Needs libobj replacement.)
3053
3054 # Set up the CFLAGS for real compilation, so we can substitute it.
3055 CFLAGS="$REAL_CFLAGS"
3056 CPPFLAGS="$REAL_CPPFLAGS"
3057
3058 ## Hack to detect a buggy GCC version.
3059 if test "x$GCC" = xyes \
3060    && test x"`$CC --version 2> /dev/null | grep 'gcc.* 4.5.0'`" != x \
3061    && test x"`echo $CFLAGS | grep '\-O@<:@23@:>@'`" != x \
3062    && test x"`echo $CFLAGS | grep '\-fno-optimize-sibling-calls'`" = x; then
3063    AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS'.])
3064 fi
3065
3066 #### Find out which version of Emacs this is.
3067 [version=`grep 'const char emacs_version' ${srcdir}/src/emacs.c \
3068          | sed -e 's/^[^"]*"\([^"]*\)".*$/\1/'`]
3069 if test x"${version}" = x; then
3070   AC_MSG_ERROR([can't find current emacs version in `${srcdir}/src/emacs.c'.])
3071 fi
3072 if test x"${version}" != x"$PACKAGE_VERSION"; then
3073   AC_MSG_WARN([version mismatch between `${srcdir}/configure.in' and `${srcdir}/src/emacs.c'.])
3074 fi
3075
3076 ### Specify what sort of things we'll be editing into Makefile and config.h.
3077 ### Use configuration here uncanonicalized to avoid exceeding size limits.
3078 AC_SUBST(version)
3079 AC_SUBST(configuration)
3080 ## Unused?
3081 AC_SUBST(canonical)
3082 AC_SUBST(srcdir)
3083 AC_SUBST(prefix)
3084 AC_SUBST(exec_prefix)
3085 AC_SUBST(bindir)
3086 AC_SUBST(datadir)
3087 AC_SUBST(sharedstatedir)
3088 AC_SUBST(libexecdir)
3089 AC_SUBST(mandir)
3090 AC_SUBST(infodir)
3091 AC_SUBST(lispdir)
3092 AC_SUBST(locallisppath)
3093 AC_SUBST(lisppath)
3094 AC_SUBST(x_default_search_path)
3095 AC_SUBST(etcdir)
3096 AC_SUBST(archlibdir)
3097 AC_SUBST(docdir)
3098 AC_SUBST(bitmapdir)
3099 AC_SUBST(gamedir)
3100 AC_SUBST(gameuser)
3101 ## FIXME? Nothing uses @LD_SWITCH_X_SITE@.
3102 ## src/Makefile.in did add LD_SWITCH_X_SITE (as a cpp define) to the
3103 ## end of LIBX_BASE, but nothing ever set it.
3104 AC_SUBST(LD_SWITCH_X_SITE)
3105 AC_SUBST(C_SWITCH_X_SITE)
3106 AC_SUBST(C_SWITCH_X_SYSTEM)
3107 AC_SUBST(CFLAGS)
3108 ## Used in lwlib/Makefile.in.
3109 AC_SUBST(X_TOOLKIT_TYPE)
3110 if test -n "${machfile}"; then
3111   M_FILE="\$(srcdir)/${machfile}"
3112 else
3113   M_FILE=
3114 fi
3115 S_FILE="\$(srcdir)/${opsysfile}"
3116 AC_SUBST(M_FILE)
3117 AC_SUBST(S_FILE)
3118 AC_SUBST(GETLOADAVG_LIBS)
3119 AC_SUBST(ns_appdir)
3120 AC_SUBST(ns_appbindir)
3121 AC_SUBST(ns_appresdir)
3122 AC_SUBST(ns_appsrc)
3123 AC_SUBST(GNU_OBJC_CFLAGS)
3124 AC_SUBST(OTHER_FILES)
3125
3126 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
3127                    [Define to the canonical Emacs configuration name.])
3128 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
3129                    [Define to the options passed to configure.])
3130 if test -n "$machfile"; then
3131   AC_DEFINE_UNQUOTED(config_machfile,  "${machfile}",
3132                      [Define to the used machine dependent file.])
3133 fi
3134 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
3135                    [Define to the used os dependent file.])
3136
3137 XMENU_OBJ=
3138 XOBJ=
3139 FONT_OBJ=
3140 if test "${HAVE_X_WINDOWS}" = "yes" ; then
3141   AC_DEFINE(HAVE_X_WINDOWS, 1,
3142             [Define to 1 if you want to use the X window system.])
3143   XMENU_OBJ=xmenu.o
3144   XOBJ="xterm.o xfns.o xselect.o xrdb.o fontset.o xsmfns.o fringe.o image.o xsettings.o xgselect.o"
3145   FONT_OBJ=xfont.o
3146   if test "$HAVE_XFT" = "yes"; then
3147     FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o"
3148   elif test "$HAVE_FREETYPE" = "yes"; then
3149     FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o"
3150   fi
3151   AC_SUBST(FONT_OBJ)
3152 fi
3153 AC_SUBST(XMENU_OBJ)
3154 AC_SUBST(XOBJ)
3155 AC_SUBST(FONT_OBJ)
3156
3157 WIDGET_OBJ=
3158 MOTIF_LIBW=
3159 if test "${USE_X_TOOLKIT}" != "none" ; then
3160   WIDGET_OBJ=widget.o
3161   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
3162   if test "${USE_X_TOOLKIT}" = "LUCID"; then
3163     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
3164   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
3165     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
3166     MOTIF_LIBW=-lXm
3167     case "$opsys" in
3168       gnu-linux)
3169         ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed.
3170         MOTIF_LIBW="$MOTIF_LIBW -lXpm"
3171         ;;
3172
3173       unixware)
3174         ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov>
3175         ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2.
3176         MOTIF_LIBW="MOTIF_LIBW -lXimp"
3177         ;;
3178
3179       aix4-2)
3180         ## olson@mcs.anl.gov says -li18n is needed by -lXm.
3181         MOTIF_LIBW="$MOTIF_LIBW -li18n"
3182         ;;
3183     esac
3184     MOTIF_LIBW="$MOTIF_LIBW $LIBXP"
3185   fi
3186 fi
3187 AC_SUBST(WIDGET_OBJ)
3188
3189 TOOLKIT_LIBW=
3190 case "$USE_X_TOOLKIT" in
3191   MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;;
3192   LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;;
3193   none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS" ;;
3194 esac
3195 AC_SUBST(TOOLKIT_LIBW)
3196
3197 if test "$USE_X_TOOLKIT" = "none"; then
3198   LIBXT_OTHER="\$(LIBXSM)"
3199   OLDXMENU_TARGET="really-oldXMenu"
3200 else
3201   LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext"
3202   OLDXMENU_TARGET="really-lwlib"
3203 fi
3204 AC_SUBST(LIBXT_OTHER)
3205
3206 ## The X Menu stuff is present in the X10 distribution, but missing
3207 ## from X11.  If we have X10, just use the installed library;
3208 ## otherwise, use our own copy.
3209 if test "${HAVE_X11}" = "yes" ; then
3210   AC_DEFINE(HAVE_X11, 1,
3211             [Define to 1 if you want to use version 11 of X windows.
3212              Otherwise, Emacs expects to use version 10.])
3213
3214   if test "$USE_X_TOOLKIT" = "none"; then
3215     OLDXMENU="\${oldXMenudir}/libXMenu11.a"
3216   else
3217     OLDXMENU="\${lwlibdir}/liblw.a"
3218   fi
3219   LIBXMENU="\$(OLDXMENU)"
3220   LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)"
3221   OLDXMENU_DEPS="\${OLDXMENU} ../src/\${OLDXMENU}"
3222 else
3223   ## For a syntactically valid Makefile; not actually used for anything.
3224   ## See comments in src/Makefile.in.
3225   OLDXMENU=nothing
3226   ## FIXME This case (!HAVE_X11 && HAVE_X_WINDOWS) is no longer possible(?).
3227   if test "${HAVE_X_WINDOWS}" = "yes"; then
3228     LIBXMENU="-lXMenu"
3229   else
3230     LIBXMENU=
3231   fi
3232   LIBX_OTHER=
3233   OLDXMENU_DEPS=
3234 fi
3235
3236 if test "$HAVE_GTK" = "yes" || test "$HAVE_MENUS" != "yes"; then
3237   OLDXMENU_TARGET=
3238   OLDXMENU=nothing
3239   LIBXMENU=
3240   OLDXMENU_DEPS=
3241 fi
3242
3243 AC_SUBST(OLDXMENU_TARGET)
3244 AC_SUBST(OLDXMENU)
3245 AC_SUBST(LIBXMENU)
3246 AC_SUBST(LIBX_OTHER)
3247 AC_SUBST(OLDXMENU_DEPS)
3248
3249 if test "${HAVE_MENUS}" = "yes" ; then
3250   AC_DEFINE(HAVE_MENUS, 1,
3251             [Define to 1 if you have mouse menus.
3252              (This is automatic if you use X, but the option to specify it remains.)
3253              It is also defined with other window systems that support xmenu.c.])
3254 fi
3255
3256 if test "${GNU_MALLOC}" = "yes" ; then
3257   AC_DEFINE(GNU_MALLOC, 1,
3258             [Define to 1 if you want to use the GNU memory allocator.])
3259 fi
3260
3261 RALLOC_OBJ=
3262 if test "${REL_ALLOC}" = "yes" ; then
3263   AC_DEFINE(REL_ALLOC, 1,
3264             [Define REL_ALLOC if you want to use the relocating allocator for
3265              buffer space.])
3266
3267   test "$system_malloc" != "yes" && RALLOC_OBJ=ralloc.o
3268 fi
3269 AC_SUBST(RALLOC_OBJ)
3270
3271 if test "$opsys" = "cygwin"; then
3272   CYGWIN_OBJ="sheap.o"
3273   ## Cygwin differs because of its unexec().
3274   PRE_ALLOC_OBJ=
3275   POST_ALLOC_OBJ=lastfile.o
3276 else
3277   CYGWIN_OBJ=
3278   PRE_ALLOC_OBJ=lastfile.o
3279   POST_ALLOC_OBJ=
3280 fi
3281 AC_SUBST(CYGWIN_OBJ)
3282 AC_SUBST(PRE_ALLOC_OBJ)
3283 AC_SUBST(POST_ALLOC_OBJ)
3284
3285
3286 case "$opsys" in
3287   aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;;
3288
3289   darwin)
3290    ## The -headerpad option tells ld (see man page) to leave room at the
3291    ## end of the header for adding load commands.  Needed for dumping.
3292    ## 0x690 is the total size of 30 segment load commands (at 56
3293    ## each); under Cocoa 31 commands are required.
3294    if test "$HAVE_NS" = "yes"; then
3295      libs_nsgui="-framework AppKit"
3296      headerpad_extra=6C8
3297    else
3298      libs_nsgui=
3299      headerpad_extra=690
3300    fi
3301    LD_SWITCH_SYSTEM_TEMACS="-prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra"
3302
3303    ## This is here because src/Makefile.in did some extra fiddling around
3304    ## with LD_SWITCH_SYSTEM.  The cpp logic was:
3305    ##   #ifndef LD_SWITCH_SYSTEM
3306    ##   #if !defined (__GNUC__) && ((defined (BSD_SYSTEM) && !defined (COFF)))
3307    ## Since all the *bsds define LD_SWITCH_SYSTEM, this simplifies to:
3308    ## not using gcc, darwin system not on an alpha (ie darwin, since
3309    ## darwin + alpha does not occur).
3310    ## Because this was done in src/Makefile.in, the resulting part of
3311    ## LD_SWITCH_SYSTEM was not used in configure (ie, in ac_link).
3312    ## It therefore seems cleaner to put this in LD_SWITCH_SYSTEM_TEMACS,
3313    ## rather than LD_SWITCH_SYSTEM.
3314    test "x$LD_SWITCH_SYSTEM" = "x" && test "x$GCC" != "xyes" && \
3315      LD_SWITCH_SYSTEM_TEMACS="-X $LD_SWITCH_SYSTEM_TEMACS"
3316    ;;
3317
3318   ## LD_SWITCH_X_SITE_AUX is a -R option saying where to find X at run-time.
3319   ## When handled by cpp, this was in LD_SWITCH_SYSTEM.  However, at
3320   ## the point where configure sourced the s/*.h file, LD_SWITCH_X_SITE_AUX
3321   ## had not yet been defined and was expanded to null.  Hence LD_SWITCH_SYSTEM
3322   ## had different values in configure (in ac_link) and src/Makefile.in.
3323   ## It seems clearer therefore to put this piece in LD_SWITCH_SYSTEM_TEMACS.
3324   gnu-linux) LD_SWITCH_SYSTEM_TEMACS="\$(LD_SWITCH_X_SITE_AUX)" ;;
3325
3326   *) LD_SWITCH_SYSTEM_TEMACS= ;;
3327 esac
3328
3329 if test "$NS_IMPL_GNUSTEP" = "yes"; then
3330   LD_SWITCH_SYSTEM_TEMACS="${LD_SWITCH_SYSTEM_TEMACS} -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES} -lgnustep-gui -lgnustep-base -lobjc -lpthread"
3331 fi
3332
3333 AC_SUBST(LD_SWITCH_SYSTEM_TEMACS)
3334
3335
3336 LD_FIRSTFLAG=
3337 ORDINARY_LINK=
3338 case "$opsys" in
3339   ## gnu: GNU needs its own crt0.
3340   aix4-2|cygwin|darwin|gnu|hpux*|irix6-5|sol2*|unixware) ORDINARY_LINK=yes ;;
3341
3342   ## On post 1.3 releases of NetBSD, gcc -nostdlib also clears the
3343   ## library search parth, i.e. it won't search /usr/lib for libc and
3344   ## friends.  Using -nostartfiles instead avoids this problem, and
3345   ## will also work on earlier NetBSD releases.
3346   netbsd|openbsd) LD_FIRSTFLAG="-nostartfiles" ;;
3347
3348   ## macpcc: NAKAJI Hiroyuki <nakaji@tutrp.tut.ac.jp> says
3349   ##   MkLinux/LinuxPPC needs this.
3350   ## ibms390x only supports opsys = gnu-linux so it can be added here.
3351   gnu-*)
3352     case "$machine" in
3353       macppc|ibms390x) LD_FIRSTFLAG="-nostdlib" ;;
3354     esac
3355     ;;
3356 esac
3357
3358
3359 if test "x$ORDINARY_LINK" = "xyes"; then
3360
3361   LD_FIRSTFLAG=""
3362   AC_DEFINE(ORDINARY_LINK, 1, [Define if the C compiler is the linker.])
3363
3364 ## The system files defining neither ORDINARY_LINK nor LD_FIRSTFLAG are:
3365 ## freebsd, gnu-* not on macppc|ibms390x.
3366 elif test "x$GCC" = "xyes" && test "x$LD_FIRSTFLAG" = "x"; then
3367
3368   ## Versions of GCC >= 2.0 put their library, libgcc.a, in obscure
3369   ## places that are difficult to figure out at make time.  Fortunately,
3370   ## these same versions allow you to pass arbitrary flags on to the
3371   ## linker, so there is no reason not to use it as a linker.
3372   ##
3373   ## Well, it is not quite perfect.  The "-nostdlib" keeps GCC from
3374   ## searching for libraries in its internal directories, so we have to
3375   ## ask GCC explicitly where to find libgcc.a (LIB_GCC below).
3376   LD_FIRSTFLAG="-nostdlib"
3377 fi
3378
3379 ## FIXME? What setting of EDIT_LDFLAGS should this have?
3380 test "$NS_IMPL_GNUSTEP" = "yes" && LD_FIRSTFLAG="-rdynamic"
3381
3382 AC_SUBST(LD_FIRSTFLAG)
3383
3384
3385 ## FIXME? The logic here is not precisely the same as that above.
3386 ## There is no check here for a pre-defined LD_FIRSTFLAG.
3387 ## Should we only be setting LIB_GCC if LD ~ -nostdlib?
3388 LIB_GCC=
3389 if test "x$GCC" = "xyes" && test "x$ORDINARY_LINK" != "xyes"; then
3390
3391   case "$opsys" in
3392     freebsd|netbsd|openbsd) LIB_GCC= ;;
3393
3394     gnu-*)
3395       ## armin76@gentoo.org reported that the lgcc_s flag is necessary to
3396       ## build on ARM EABI under GNU/Linux.  (Bug#5518)
3397       case $host_cpu in
3398       arm*)
3399         LIB_GCC="-lgcc_s"
3400         ;;
3401       *)
3402         ## FIXME? s/gnu-linux.h used to define LIB_GCC as below, then
3403         ## immediately undefine it again and redefine it to empty.
3404         ## Was the C_SWITCH_X_SITE part really necessary?
3405 ##      LIB_GCC=`$CC $C_SWITCH_X_SITE -print-libgcc-file-name`
3406         LIB_GCC=
3407         ;;
3408       esac
3409       ;;
3410
3411     ## Ask GCC where to find libgcc.a.
3412     *) LIB_GCC=`$CC -print-libgcc-file-name 2> /dev/null` ;;
3413   esac
3414 fi                              dnl if $GCC
3415 AC_SUBST(LIB_GCC)
3416
3417
3418 TOOLTIP_SUPPORT=
3419 WINDOW_SUPPORT=
3420 ## If we're using X11/GNUstep, define some consequences.
3421 if test "$HAVE_X_WINDOWS" = "yes" || test "$HAVE_NS" = "yes"; then
3422   AC_DEFINE(HAVE_WINDOW_SYSTEM, 1, [Define if you have a window system.])
3423   AC_DEFINE(HAVE_MOUSE, 1, [Define if you have mouse support.])
3424   MOUSE_SUPPORT="\$(REAL_MOUSE_SUPPORT)"
3425   TOOLTIP_SUPPORT="\${lispsource}/mouse.elc"
3426
3427   WINDOW_SUPPORT="\$(BASE_WINDOW_SUPPORT)"
3428   test "$HAVE_X_WINDOWS" = "yes" && \
3429     WINDOW_SUPPORT="$WINDOW_SUPPORT \$(X_WINDOW_SUPPORT)"
3430
3431 fi
3432 AC_SUBST(MOUSE_SUPPORT)
3433 AC_SUBST(TOOLTIP_SUPPORT)
3434 AC_SUBST(WINDOW_SUPPORT)
3435
3436
3437 AH_TOP([/* GNU Emacs site configuration template file.
3438    Copyright (C) 1988, 1993, 1994, 1999, 2000, 2001, 2002, 2004, 2005,
3439      2006, 2007, 2008, 2009, 2010, 2011  Free Software Foundation, Inc.
3440
3441 This file is part of GNU Emacs.
3442
3443 GNU Emacs is free software: you can redistribute it and/or modify
3444 it under the terms of the GNU General Public License as published by
3445 the Free Software Foundation, either version 3 of the License, or
3446 (at your option) any later version.
3447
3448 GNU Emacs is distributed in the hope that it will be useful,
3449 but WITHOUT ANY WARRANTY; without even the implied warranty of
3450 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
3451 GNU General Public License for more details.
3452
3453 You should have received a copy of the GNU General Public License
3454 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
3455
3456
3457 /* No code in Emacs #includes config.h twice, but some bits of code
3458    intended to work with other packages as well (like gmalloc.c)
3459    think they can include it as many times as they like.  */
3460 #ifndef EMACS_CONFIG_H
3461 #define EMACS_CONFIG_H
3462 ])dnl
3463
3464 AH_BOTTOM([
3465 /* Define AMPERSAND_FULL_NAME if you use the convention
3466    that & in the full name stands for the login id.  */
3467 /* Turned on June 1996 supposing nobody will mind it.  */
3468 #define AMPERSAND_FULL_NAME
3469
3470 /* If using GNU, then support inline function declarations.  */
3471 /* Don't try to switch on inline handling as detected by AC_C_INLINE
3472    generally, because even if non-gcc compilers accept `inline', they
3473    may reject `extern inline'.  */
3474 #if defined (__GNUC__)
3475 #define INLINE __inline__
3476 #else
3477 #define INLINE
3478 #endif
3479
3480 /* `subprocesses' should be defined if you want to
3481    have code for asynchronous subprocesses
3482    (as used in M-x compile and M-x shell).
3483    Only MSDOS does not support this (it overrides
3484    this in its config_opsysfile below).  */
3485
3486 #define subprocesses
3487
3488 /* Include the os and machine dependent files.  */
3489 #include config_opsysfile
3490 #ifdef config_machfile
3491 # include config_machfile
3492 #endif
3493
3494 /* GNUstep needs a bit more pure memory.  Of the existing knobs,
3495    SYSTEM_PURESIZE_EXTRA seems like the least likely to cause problems.
3496   (There is probably a better place to do this, but right now the
3497    Cocoa side does this in s/darwin.h and we cannot parallel this
3498    exactly since GNUstep is multi-OS.  */
3499 #if defined HAVE_NS && defined NS_IMPL_GNUSTEP
3500 #  define SYSTEM_PURESIZE_EXTRA 30000
3501 #endif
3502
3503 /* SIGTYPE is the macro we actually use.  */
3504 #ifndef SIGTYPE
3505 #define SIGTYPE RETSIGTYPE
3506 #endif
3507
3508 #ifdef emacs /* Don't do this for lib-src.  */
3509 /* Tell regex.c to use a type compatible with Emacs.  */
3510 #define RE_TRANSLATE_TYPE Lisp_Object
3511 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
3512 #ifdef make_number
3513 /* If make_number is a macro, use it.  */
3514 #define RE_TRANSLATE_P(TBL) (!EQ (TBL, make_number (0)))
3515 #else
3516 /* If make_number is a function, avoid it.  */
3517 #define RE_TRANSLATE_P(TBL) (!(INTEGERP (TBL) && XINT (TBL) == 0))
3518 #endif
3519 #endif
3520
3521 #define my_strftime nstrftime   /* for strftime.c */
3522
3523 /* These default definitions are good for almost all machines.
3524    The exceptions override them in m/MACHINE.h.  */
3525
3526 #ifndef BITS_PER_CHAR
3527 #define BITS_PER_CHAR 8
3528 #endif
3529
3530 #ifndef BITS_PER_SHORT
3531 #define BITS_PER_SHORT 16
3532 #endif
3533
3534 /* Note that lisp.h uses this in a preprocessor conditional, so it
3535    would not work to use sizeof.  That being so, we do all of them
3536    without sizeof, for uniformity's sake.  */
3537 #ifndef BITS_PER_INT
3538 #define BITS_PER_INT 32
3539 #endif
3540
3541 #ifndef BITS_PER_LONG
3542 #ifdef _LP64
3543 #define BITS_PER_LONG 64
3544 #else
3545 #define BITS_PER_LONG 32
3546 #endif
3547 #endif
3548
3549 /* Define if the compiler supports function prototypes.  It may do so but
3550    not define __STDC__ (e.g. DEC C by default) or may define it as zero.  */
3551 #undef PROTOTYPES
3552
3553 #include <string.h>
3554 #include <stdlib.h>
3555
3556 #ifdef HAVE_ALLOCA_H
3557 # include <alloca.h>
3558 #elif defined __GNUC__
3559 # define alloca __builtin_alloca
3560 #elif defined _AIX
3561 # define alloca __alloca
3562 #else
3563 # include <stddef.h>
3564 # ifdef  __cplusplus
3565 extern "C"
3566 # endif
3567 void *alloca (size_t);
3568 #endif
3569
3570 #ifndef HAVE_SIZE_T
3571 typedef unsigned size_t;
3572 #endif
3573
3574 #ifndef HAVE_STRCHR
3575 #define strchr(a, b) index (a, b)
3576 #endif
3577
3578 #ifndef HAVE_STRRCHR
3579 #define strrchr(a, b) rindex (a, b)
3580 #endif
3581
3582 #if defined __GNUC__ && (__GNUC__ > 2 \
3583                          || (__GNUC__ == 2 && __GNUC_MINOR__ >= 5))
3584 #define NO_RETURN       __attribute__ ((__noreturn__))
3585 #else
3586 #define NO_RETURN       /* nothing */
3587 #endif
3588
3589 #if __GNUC__ >= 3  /* On GCC 3.0 we might get a warning.  */
3590 #define NO_INLINE __attribute__((noinline))
3591 #else
3592 #define NO_INLINE
3593 #endif
3594
3595 #if (__GNUC__ > 4 || (__GNUC__ == 4 && __GNUC_MINOR__ >= 1))
3596 #define EXTERNALLY_VISIBLE __attribute__((externally_visible))
3597 #else
3598 #define EXTERNALLY_VISIBLE
3599 #endif
3600
3601 /* Some versions of GNU/Linux define noinline in their headers.  */
3602 #ifdef noinline
3603 #undef noinline
3604 #endif
3605
3606 /* These won't be used automatically yet.  We also need to know, at least,
3607    that the stack is continuous.  */
3608 #ifdef __GNUC__
3609 #  ifndef GC_SETJMP_WORKS
3610   /* GC_SETJMP_WORKS is nearly always appropriate for GCC.  */
3611 #    define GC_SETJMP_WORKS 1
3612 #  endif
3613 #  ifndef GC_LISP_OBJECT_ALIGNMENT
3614 #    define GC_LISP_OBJECT_ALIGNMENT (__alignof__ (Lisp_Object))
3615 #  endif
3616 #endif
3617
3618 #endif /* EMACS_CONFIG_H */
3619
3620 /*
3621 Local Variables:
3622 mode: c
3623 End:
3624 */
3625 ])dnl
3626
3627 #### Report on what we decided to do.
3628 #### Report GTK as a toolkit, even if it doesn't use Xt.
3629 #### It makes printing result more understandable as using GTK sets
3630 #### toolkit_scroll_bars to yes by default.
3631 if test "${HAVE_GTK}" = "yes"; then
3632   USE_X_TOOLKIT=GTK
3633 fi
3634
3635 and_machfile=
3636 if test -n "$machfile"; then
3637   and_machfile=" and \`${machfile}'"
3638 fi
3639
3640 echo "
3641 Configured for \`${canonical}'.
3642
3643   Where should the build process find the source code?    ${srcdir}
3644   What operating system and machine description files should Emacs use?
3645         \`${opsysfile}'${and_machfile}
3646   What compiler should emacs be built with?               ${CC} ${CFLAGS}
3647   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
3648   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
3649   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
3650   What window system should Emacs use?                    ${window_system}
3651   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
3652
3653 if test -n "${x_includes}"; then
3654 echo "  Where do we find X Windows header files?                ${x_includes}"
3655 else
3656 echo "  Where do we find X Windows header files?                Standard dirs"
3657 fi
3658 if test -n "${x_libraries}"; then
3659 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
3660 else
3661 echo "  Where do we find X Windows libraries?                   Standard dirs"
3662 fi
3663
3664 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
3665 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
3666 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
3667 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
3668 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF"
3669 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
3670 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
3671 echo "  Does Emacs use imagemagick?                             ${HAVE_IMAGEMAGICK}"
3672
3673 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
3674 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
3675 echo "  Does Emacs use -lgconf?                                 ${HAVE_GCONF}"
3676 echo "  Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}"
3677 echo "  Does Emacs use -lgnutls?                                ${HAVE_GNUTLS}"
3678 echo "  Does Emacs use -lxml2?                                  ${HAVE_LIBXML2}"
3679
3680 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
3681 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
3682 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
3683 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
3684
3685 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
3686 echo
3687
3688 if test $USE_XASSERTS = yes; then
3689    echo "  Compiling with asserts turned on."
3690    CPPFLAGS="$CPPFLAGS -DXASSERTS=1"
3691 fi
3692
3693 echo
3694
3695 if test "$HAVE_NS" = "yes"; then
3696    echo
3697    echo "You must run \"make install\" in order to test the built application.
3698 The installed application will go to nextstep/Emacs.app and can be
3699 run or moved from there."
3700    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
3701       echo "The application will be fully self-contained."
3702     else
3703       echo "The lisp resources for the application will be installed under ${prefix}.
3704 You may need to run \"make install\" with sudo.  The application will fail
3705 to run if these resources are not installed."
3706    fi
3707    echo
3708 fi
3709
3710
3711 # Remove any trailing slashes in these variables.
3712 [test "${prefix}" != NONE &&
3713   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
3714 test "${exec_prefix}" != NONE &&
3715   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
3716
3717 dnl You might wonder (I did) why epaths.h is generated by running make,
3718 dnl rather than just letting configure generate it from epaths.in.
3719 dnl One reason is that the various paths are not fully expanded (see above);
3720 dnl eg gamedir=${prefix}/var/games/emacs.
3721 dnl Secondly, the GNU Coding standards require that one should be able
3722 dnl to run `make prefix=/some/where/else' and override the values set
3723 dnl by configure.  This also explains the `move-if-change' test and
3724 dnl the use of force in the `epaths-force' rule in Makefile.in.
3725 AC_OUTPUT(Makefile lib/Makefile lib-src/Makefile oldXMenu/Makefile \
3726         doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
3727         doc/lispref/Makefile src/Makefile \
3728         lwlib/Makefile lisp/Makefile leim/Makefile test/automated/Makefile, [
3729
3730 ### Make the necessary directories, if they don't exist.
3731 for dir in etc lisp ; do
3732   test -d ${dir} || mkdir ${dir}
3733 done
3734
3735 echo creating src/epaths.h
3736 ${MAKE-make} epaths-force
3737
3738 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
3739   echo creating src/.gdbinit
3740   echo source $srcdir/src/.gdbinit > src/.gdbinit
3741 fi
3742
3743 ], [GCC="$GCC" NON_GNU_CPP="$NON_GNU_CPP" CPP="$CPP" CPPFLAGS="$CPPFLAGS"])