code.delx.au - gnu-emacs/blob - configure.in

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl If you changed any AC_DEFINES, also run autoheader.
   6 dnl
   7 dnl  Copyright (C) 1994, 1995, 1996, 1999, 2000, 2001, 2002, 2003, 2004,
   8 dnl    2005, 2006, 2007, 2008, 2009, 2010
   9 dnl    Free Software Foundation, Inc.
  10 dnl
  11 dnl  This file is part of GNU Emacs.
  12 dnl
  13 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  14 dnl  it under the terms of the GNU General Public License as published by
  15 dnl  the Free Software Foundation, either version 3 of the License, or
  16 dnl  (at your option) any later version.
  17 dnl
  18 dnl  GNU Emacs is distributed in the hope that it will be useful,
  19 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 dnl  GNU General Public License for more details.
  22 dnl
  23 dnl  You should have received a copy of the GNU General Public License
  24 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  25
  26 AC_PREREQ(2.65)
  27 AC_INIT(emacs, 24.0.50)
  28 AC_CONFIG_HEADER(src/config.h:src/config.in)
  29 AC_CONFIG_SRCDIR(src/lisp.h)
  30
  31 dnl Support for --program-prefix, --program-suffix and
  32 dnl --program-transform-name options
  33 AC_ARG_PROGRAM
  34
  35 dnl It is important that variables on the RHS not be expanded here,
  36 dnl hence the single quotes.  This is per the GNU coding standards, see
  37 dnl (autoconf) Installation Directory Variables
  38 dnl See also epaths.h below.
  39 lispdir='${datadir}/emacs/${version}/lisp'
  40 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  41 '${datadir}/emacs/site-lisp'
  42 lisppath='${locallisppath}:${lispdir}:${datadir}/emacs/${version}/leim'
  43 etcdir='${datadir}/emacs/${version}/etc'
  44 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  45 docdir='${datadir}/emacs/${version}/etc'
  46 gamedir='${localstatedir}/games/emacs'
  47
  48 gameuser=games
  49
  50 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  51 dnl Create a new --with option that defaults to being disabled.
  52 dnl NAME is the base name of the option.  The shell variable with_NAME
  53 dnl   will be set to either the user's value (if the option is
  54 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  55 dnl   option is not specified).  Note that the shell variable name is
  56 dnl   constructed as autoconf does, by replacing non-alphanumeric
  57 dnl   characters with "_".
  58 dnl HELP-STRING is the help text for the option.
  59 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  60   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  61     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  62 ])dnl
  63
  64 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  65 dnl Create a new --with option that defaults to being enabled.  NAME
  66 dnl   is the base name of the option.  The shell variable with_NAME
  67 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  68 dnl   'yes' (if the option is not specified).  Note that the shell
  69 dnl   variable name is constructed as autoconf does, by replacing
  70 dnl   non-alphanumeric characters with "_".
  71 dnl HELP-STRING is the help text for the option.
  72 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  73   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  74    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=yes])dnl
  75 ])dnl
  76
  77 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
  78 if test "$with_pop" = yes; then
  79    AC_DEFINE(MAIL_USE_POP)
  80 fi
  81 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  82
  83 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
  84 if test "$with_kerberos" != no; then
  85    AC_DEFINE(KERBEROS)
  86 fi
  87 AH_TEMPLATE(KERBEROS,
  88             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  89
  90 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
  91 if test "${with_kerberos5}" != no; then
  92   if test "${with_kerberos}" = no; then
  93     with_kerberos=yes
  94     AC_DEFINE(KERBEROS)
  95   fi
  96   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
  97 fi
  98
  99 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
 100 dnl FIXME hesiod support may not be present, so it seems like an error
 101 dnl to define, or at least use, this unconditionally.
 102 if test "$with_hesiod" != no; then
 103   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
 104 fi
 105
 106 OPTION_DEFAULT_OFF([mmdf],[support MMDF mailboxes])
 107 if test "$with_mmdf" != no; then
 108    AC_DEFINE(MAIL_USE_MMDF, 1, [Define to support MMDF mailboxes in movemail.])
 109 fi
 110
 111 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 112 if test "$with_mail_unlink" != no; then
 113    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 114 fi
 115
 116 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 117     [string giving default POP mail host])],
 118     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 119
 120 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
 121
 122 OPTION_DEFAULT_ON([sync-input],[process async input synchronously])
 123 if test "$with_sync_input" = yes; then
 124    AC_DEFINE(SYNC_INPUT, 1, [Process async input synchronously.])
 125 fi
 126
 127 dnl FIXME currently it is not the last.
 128 dnl This should be the last --with option, because --with-x is
 129 dnl added later on when we find the path of X, and it's best to
 130 dnl keep them together visually.
 131 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 132  [use an X toolkit (KIT one of: yes or gtk, gtk3, lucid or athena, motif, no)])],
 133 [         case "${withval}" in
 134             y | ye | yes )      val=gtk ;;
 135             n | no )            val=no  ;;
 136             l | lu | luc | luci | lucid )       val=lucid ;;
 137             a | at | ath | athe | athen | athena )      val=athena ;;
 138             m | mo | mot | moti | motif )       val=motif ;;
 139             g | gt | gtk  )     val=gtk ;;
 140             gtk3  )     val=gtk3 ;;
 141             * )
 142 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 143 this option's value should be `yes', `no', `lucid', `athena', `motif', `gtk' or
 144 `gtk3'.  `yes' and `gtk' are synonyms. `athena' and `lucid' are synonyms.])
 145             ;;
 146           esac
 147           with_x_toolkit=$val
 148 ])
 149
 150 dnl _ON results in a '--without' option in the --help output, so
 151 dnl the help text should refer to "don't compile", etc.
 152 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 153 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 154 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 155 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 156 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 157 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 158 OPTION_DEFAULT_ON([xml2],[don't compile with XML parsing support])
 159 OPTION_DEFAULT_OFF([imagemagick],[compile with ImageMagick image support])
 160
 161 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 162 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 163 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 164
 165 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 166 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 167 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 168 OPTION_DEFAULT_OFF([ns],[use nextstep (Cocoa or GNUstep) windowing system])
 169
 170 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 171 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 172 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 173 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 174
 175 ## For the times when you want to build Emacs but don't have
 176 ## a suitable makeinfo, and can live without the manuals.
 177 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 178 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 179
 180 ## This is an option because I do not know if all info/man support
 181 ## compressed files, nor how to test if they do so.
 182 OPTION_DEFAULT_ON([compress-info],[don't compress the installed Info pages])
 183 if test $with_compress_info = yes; then
 184    GZIP_INFO=yes
 185 else
 186    GZIP_INFO=
 187 fi
 188 AC_SUBST(GZIP_INFO)
 189
 190 AC_ARG_WITH([pkg-config-prog],dnl
 191 [AS_HELP_STRING([--with-pkg-config-prog=PATH],
 192                   [path to pkg-config for finding GTK and librsvg])])
 193 if test "X${with_pkg_config_prog}" != X; then
 194    if test "${with_pkg_config_prog}" != yes; then
 195       PKG_CONFIG="${with_pkg_config_prog}"
 196    fi
 197 fi
 198
 199 CRT_DIR=
 200 AC_ARG_WITH([crt-dir],dnl
 201 [AS_HELP_STRING([--with-crt-dir=DIR],[directory containing crtn.o etc.
 202 The default is /usr/lib, or /usr/lib64 on some platforms.])])
 203 CRT_DIR="${with_crt_dir}"
 204
 205 AC_ARG_WITH([gnustep-conf],dnl
 206 [AS_HELP_STRING([--with-gnustep-conf=PATH],[path to GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
 207 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 208   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 209 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 210      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 211
 212 AC_ARG_ENABLE(ns-self-contained,
 213 [AS_HELP_STRING([--disable-ns-self-contained],
 214                 [disable self contained build under NeXTstep])],
 215    EN_NS_SELF_CONTAINED=$enableval,
 216    EN_NS_SELF_CONTAINED=yes)
 217
 218 AC_ARG_ENABLE(asserts,
 219 [AS_HELP_STRING([--enable-asserts], [compile code with asserts enabled])],
 220       USE_XASSERTS=$enableval,
 221       USE_XASSERTS=no)
 222
 223 AC_ARG_ENABLE(maintainer-mode,
 224 [AS_HELP_STRING([--enable-maintainer-mode],
 225                 [enable make rules and dependencies not useful (and sometimes
 226                  confusing) to the casual installer])],
 227       USE_MAINTAINER_MODE=$enableval,
 228       USE_MAINTAINER_MODE=no)
 229 if test $USE_MAINTAINER_MODE = yes; then
 230   MAINT=
 231 else
 232   MAINT=#
 233 fi
 234 AC_SUBST(MAINT)
 235
 236 AC_ARG_ENABLE(locallisppath,
 237 [AS_HELP_STRING([--enable-locallisppath=PATH],
 238                 [directories Emacs should search for lisp files specific
 239                  to this site])],
 240 if test "${enableval}" = "no"; then
 241   locallisppath=
 242 elif test "${enableval}" != "yes"; then
 243   locallisppath=${enableval}
 244 fi)
 245
 246 AC_ARG_ENABLE(checking,
 247 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 248                 [enable expensive run-time checks.  With LIST,
 249                  enable only specific categories of checks.
 250                  Categories are: all,yes,no.
 251                  Flags are: stringbytes, stringoverrun, stringfreelist,
 252                  xmallocoverrun, conslist])],
 253 [ac_checking_flags="${enableval}"],[])
 254 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 255 for check in $ac_checking_flags
 256 do
 257         case $check in
 258         # these set all the flags to specific states
 259         yes)            ac_enable_checking=1 ;;
 260         no)             ac_enable_checking= ;
 261                         ac_gc_check_stringbytes= ;
 262                         ac_gc_check_string_overrun= ;
 263                         ac_gc_check_string_free_list= ;
 264                         ac_xmalloc_overrun= ;
 265                         ac_gc_check_cons_list= ;;
 266         all)            ac_enable_checking=1 ;
 267                         ac_gc_check_stringbytes=1 ;
 268                         ac_gc_check_string_overrun=1 ;
 269                         ac_gc_check_string_free_list=1 ;
 270                         ac_xmalloc_overrun=1 ;
 271                         ac_gc_check_cons_list=1 ;;
 272         # these enable particular checks
 273         stringbytes)    ac_gc_check_stringbytes=1 ;;
 274         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 275         stringfreelist) ac_gc_check_string_free_list=1 ;;
 276         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 277         conslist)       ac_gc_check_cons_list=1 ;;
 278         *)      AC_MSG_ERROR(unknown check category $check) ;;
 279         esac
 280 done
 281 IFS="$ac_save_IFS"
 282
 283 if test x$ac_enable_checking != x ; then
 284   AC_DEFINE(ENABLE_CHECKING, 1,
 285 [Enable expensive run-time checking of data types?])
 286 fi
 287 if test x$ac_gc_check_stringbytes != x ; then
 288   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 289 [Define this temporarily to hunt a bug.  If defined, the size of
 290    strings is redundantly recorded in sdata structures so that it can
 291    be compared to the sizes recorded in Lisp strings.])
 292 fi
 293 if test x$ac_gc_check_stringoverrun != x ; then
 294   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 295 [Define this to check for short string overrun.])
 296 fi
 297 if test x$ac_gc_check_string_free_list != x ; then
 298   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 299 [Define this to check the string free list.])
 300 fi
 301 if test x$ac_xmalloc_overrun != x ; then
 302   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 303 [Define this to check for malloc buffer overrun.])
 304 fi
 305 if test x$ac_gc_check_cons_list != x ; then
 306   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 307 [Define this to check for errors in cons list.])
 308 fi
 309
 310 AC_ARG_ENABLE(use-lisp-union-type,
 311 [AS_HELP_STRING([--enable-use-lisp-union-type],
 312                 [use a union for the Lisp_Object data type.
 313                 This is only useful for development for catching certain types of bugs.])],
 314 if test "${enableval}" != "no"; then
 315    AC_DEFINE(USE_LISP_UNION_TYPE, 1,
 316    [Define this to use a lisp union for the Lisp_Object data type.])
 317 fi)
 318
 319
 320 AC_ARG_ENABLE(profiling,
 321 [AS_HELP_STRING([--enable-profiling],
 322                 [build emacs with profiling support.
 323                  This might not work on all platforms])],
 324 [ac_enable_profiling="${enableval}"],[])
 325 if test x$ac_enable_profiling != x ; then
 326    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 327    PROFILING_LDFLAGS="-pg"
 328 else
 329    PROFILING_CFLAGS=
 330    PROFILING_LDFLAGS=
 331 fi
 332 AC_SUBST(PROFILING_CFLAGS)
 333 AC_SUBST(PROFILING_LDFLAGS)
 334
 335 AC_ARG_ENABLE(autodepend,
 336 [AS_HELP_STRING([--enable-autodepend],
 337                 [automatically generate dependencies to .h-files.
 338                  Requires GNU Make and Gcc. Enabled if GNU Make and Gcc is
 339                  found])],
 340 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 341
 342 #### Make srcdir absolute, if it isn't already.  It's important to
 343 #### avoid running the path through pwd unnecessarily, since pwd can
 344 #### give you automounter prefixes, which can go away.  We do all this
 345 #### so Emacs can find its files when run uninstalled.
 346 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 347 unset CDPATH
 348 case "${srcdir}" in
 349   /* ) ;;
 350   . )
 351     ## We may be able to use the $PWD environment variable to make this
 352     ## absolute.  But sometimes PWD is inaccurate.
 353     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 354     ## but that tested only for a well-formed and valid PWD,
 355     ## it did not object when PWD was well-formed and valid but just wrong.
 356     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 357     then
 358       srcdir="$PWD"
 359     else
 360       srcdir="`(cd ${srcdir}; pwd)`"
 361     fi
 362   ;;
 363   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 364 esac
 365
 366 #### Check if the source directory already has a configured system in it.
 367 if test `pwd` != `(cd ${srcdir} && pwd)` \
 368    && test -f "${srcdir}/src/config.h" ; then
 369   AC_MSG_WARN([[The directory tree `${srcdir}' is being used
 370    as a build directory right now; it has been configured in its own
 371    right.  To configure in another directory as well, you MUST
 372    use GNU make.  If you do not have GNU make, then you must
 373    now do `make distclean' in ${srcdir},
 374    and then run $0 again.]])
 375 fi
 376
 377 #### Given the configuration name, set machfile and opsysfile to the
 378 #### names of the m/*.h and s/*.h files we should use.
 379
 380 ### Canonicalize the configuration name.
 381
 382 AC_CANONICAL_HOST
 383 canonical=$host
 384 configuration=${host_alias-${build_alias-$host}}
 385
 386 dnl This used to use changequote, but, apart from `changequote is evil'
 387 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 388 dnl the great gob of text.  Thus it's not processed for possible expansion.
 389 dnl Just make sure the brackets remain balanced.
 390 dnl
 391 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 392 dnl indicated by comments.
 393 dnl quotation begins
 394 [
 395
 396 ### If you add support for a new configuration, add code to this
 397 ### switch statement to recognize your configuration name and select
 398 ### the appropriate operating system and machine description files.
 399
 400 ### You would hope that you could choose an m/*.h file pretty much
 401 ### based on the machine portion of the configuration name, and an s/*.h
 402 ### file based on the operating system portion.  However, it turns out
 403 ### that each m/*.h file is pretty manufacturer-specific - for
 404 ### example mips.h is MIPS
 405 ### So we basically have to have a special case for each
 406 ### configuration name.
 407 ###
 408 ### As far as handling version numbers on operating systems is
 409 ### concerned, make sure things will fail in a fixable way.  If
 410 ### /etc/MACHINES doesn't say anything about version numbers, be
 411 ### prepared to handle anything reasonably.  If version numbers
 412 ### matter, be sure /etc/MACHINES says something about it.
 413
 414 machine='' opsys='' unported=no
 415 case "${canonical}" in
 416
 417   ## FreeBSD ports
 418   *-*-freebsd* )
 419     opsys=freebsd
 420     case "${canonical}" in
 421       alpha*)           machine=alpha ;;
 422       amd64-*|x86_64-*) machine=amdx86-64 ;;
 423       arm*)             machine=arm ;;
 424       ia64-*)           machine=ia64 ;;
 425       i[3456]86-*)      machine=intel386 ;;
 426       powerpc-*)        machine=macppc ;;
 427       sparc-*)          machine=sparc ;;
 428       sparc64-*)        machine=sparc ;;
 429     esac
 430   ;;
 431
 432   ## FreeBSD kernel + glibc based userland
 433   *-*-kfreebsd*gnu* )
 434     opsys=gnu-kfreebsd
 435     case "${canonical}" in
 436       alpha*)           machine=alpha ;;
 437       amd64-*|x86_64-*) machine=amdx86-64 ;;
 438       ia64-*)           machine=ia64 ;;
 439       i[3456]86-*)      machine=intel386 ;;
 440       powerpc-*)        machine=macppc ;;
 441       sparc-*)          machine=sparc ;;
 442       sparc64-*)        machine=sparc ;;
 443     esac
 444   ;;
 445
 446   ## NetBSD ports
 447   *-*-netbsd* )
 448     opsys=netbsd
 449     case "${canonical}" in
 450       alpha*)      machine=alpha ;;
 451       x86_64-*)    machine=amdx86-64 ;;
 452       arm-*)       machine=arm ;;
 453       hppa-*)      machine=hp800 ;;
 454       i[3456]86-*) machine=intel386 ;;
 455       m68k-*)      machine=m68k ;;
 456       powerpc-*)   machine=macppc ;;
 457       mips-*)      machine=mips ;;
 458       mipse[bl]-*) machine=mips ;;
 459       sparc*-)     machine=sparc ;;
 460       vax-*)       machine=vax ;;
 461     esac
 462   ;;
 463
 464   ## OpenBSD ports
 465   *-*-openbsd* )
 466     opsys=openbsd
 467     case "${canonical}" in
 468       alpha*)    machine=alpha ;;
 469       x86_64-*)  machine=amdx86-64 ;;
 470       arm-*)     machine=arm ;;
 471       hppa-*)    machine=hp800 ;;
 472       i386-*)    machine=intel386 ;;
 473       powerpc-*) machine=macppc ;;
 474       sparc*)    machine=sparc ;;
 475       vax-*)     machine=vax ;;
 476     esac
 477   ;;
 478
 479   alpha*-*-linux-gnu* )
 480     machine=alpha opsys=gnu-linux
 481   ;;
 482
 483   arm*-*-linux-gnu* )
 484     machine=arm opsys=gnu-linux
 485   ;;
 486
 487   ## Apple Darwin / Mac OS X
 488   *-apple-darwin* )
 489     case "${canonical}" in
 490       i[3456]86-* )  machine=intel386 ;;
 491       powerpc-* )    machine=macppc ;;
 492       x86_64-* )     machine=amdx86-64 ;;
 493       * )            unported=yes ;;
 494     esac
 495     opsys=darwin
 496     # Define CPP as follows to make autoconf work correctly.
 497     CPP="${CC-cc} -E -no-cpp-precomp"
 498     # Use fink packages if available.
 499     if test -d /sw/include && test -d /sw/lib; then
 500       GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 501       CPP="${CPP} ${GCC_TEST_OPTIONS}"
 502       NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 503     fi
 504   ;;
 505
 506   ## HP 9000 series 700 and 800, running HP/UX
 507   hppa*-hp-hpux10.2* )
 508     machine=hp800 opsys=hpux10-20
 509   ;;
 510   hppa*-hp-hpux1[1-9]* )
 511     machine=hp800 opsys=hpux11
 512     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 513   ;;
 514
 515   hppa*-*-linux-gnu* )
 516     machine=hp800 opsys=gnu-linux
 517   ;;
 518
 519   ## IBM machines
 520   s390-*-linux-gnu* )
 521     machine=ibms390 opsys=gnu-linux
 522   ;;
 523   s390x-*-linux-gnu* )
 524     machine=ibms390x opsys=gnu-linux
 525   ;;
 526   rs6000-ibm-aix4.[23]* )
 527     machine=ibmrs6000 opsys=aix4-2
 528   ;;
 529   powerpc-ibm-aix4.[23]*  )
 530     machine=ibmrs6000 opsys=aix4-2
 531   ;;
 532   rs6000-ibm-aix[56]* )
 533     machine=ibmrs6000 opsys=aix4-2
 534   ;;
 535   powerpc-ibm-aix[56]*  )
 536     machine=ibmrs6000 opsys=aix4-2
 537   ;;
 538
 539   ## Macintosh PowerPC
 540   powerpc*-*-linux-gnu* )
 541     machine=macppc opsys=gnu-linux
 542   ;;
 543
 544   ## Silicon Graphics machines
 545   ## Iris 4D
 546   mips-sgi-irix6.5 )
 547     machine=iris4d opsys=irix6-5
 548     # Without defining _LANGUAGE_C, things get masked out in the headers
 549     # so that, for instance, grepping for `free' in stdlib.h fails and
 550     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 551     NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
 552     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 553   ;;
 554
 555   ## Suns
 556   sparc-*-linux-gnu* | sparc64-*-linux-gnu* )
 557     machine=sparc opsys=gnu-linux
 558   ;;
 559
 560   *-sun-solaris* \
 561     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 562     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 563     case "${canonical}" in
 564       i[3456]86-*-* )     machine=intel386 ;;
 565       amd64-*-*|x86_64-*-*)     machine=amdx86-64 ;;
 566       sparc* )          machine=sparc ;;
 567       * )               unported=yes ;;
 568     esac
 569     case "${canonical}" in
 570       *-sunos5.6* | *-solaris2.6* )
 571                 opsys=sol2-6
 572                 NON_GNU_CPP=/usr/ccs/lib/cpp
 573                 RANLIB="ar -ts"
 574                 ;;
 575       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 576                 opsys=sol2-6
 577                 emacs_check_sunpro_c=yes
 578                 NON_GNU_CPP=/usr/ccs/lib/cpp
 579                 ;;
 580       *-sunos5* | *-solaris* )
 581                 opsys=sol2-10
 582                 emacs_check_sunpro_c=yes
 583                 NON_GNU_CPP=/usr/ccs/lib/cpp
 584                 ;;
 585     esac
 586     ## Watch out for a compiler that we know will not work.
 587     case "${canonical}" in
 588      *-solaris* | *-sunos5* )
 589                 if [ "x$CC" = x/usr/ucb/cc ]; then
 590                   ## /usr/ucb/cc doesn't work;
 591                   ## we should find some other compiler that does work.
 592                   unset CC
 593                 fi
 594                 ;;
 595       *) ;;
 596     esac
 597   ;;
 598
 599   ## IA-64
 600   ia64*-*-linux* )
 601     machine=ia64 opsys=gnu-linux
 602   ;;
 603
 604   ## Intel 386 machines where we don't care about the manufacturer.
 605   i[3456]86-*-* )
 606     machine=intel386
 607     case "${canonical}" in
 608       *-cygwin )                opsys=cygwin ;;
 609       *-darwin* )               opsys=darwin
 610                                 CPP="${CC-cc} -E -no-cpp-precomp"
 611                                 ;;
 612       *-linux-gnu* )            opsys=gnu-linux ;;
 613       *-sysv4.2uw* )            opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 614       *-sysv5uw* )              opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 615       *-sysv5OpenUNIX* )        opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 616       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 617     esac
 618   ;;
 619
 620   ## m68k Linux-based GNU system
 621   m68k-*-linux-gnu* )
 622     machine=m68k opsys=gnu-linux
 623   ;;
 624
 625   ## Mips Linux-based GNU system
 626   mips-*-linux-gnu* | mipsel-*-linux-gnu* \
 627     | mips64-*-linux-gnu* | mips64el-*-linux-gnu* )
 628     machine=mips opsys=gnu-linux
 629   ;;
 630
 631   ## AMD x86-64 Linux-based GNU system
 632   x86_64-*-linux-gnu* )
 633     machine=amdx86-64 opsys=gnu-linux
 634   ;;
 635
 636   ## Tensilica Xtensa Linux-based GNU system
 637   xtensa*-*-linux-gnu* )
 638     machine=xtensa opsys=gnu-linux
 639     ;;
 640
 641   ## SuperH Linux-based GNU system
 642   sh[34]*-*-linux-gnu* )
 643     machine=sh3 opsys=gnu-linux
 644   ;;
 645
 646   * )
 647     unported=yes
 648   ;;
 649 esac
 650
 651 ### If the code above didn't choose an operating system, just choose
 652 ### an operating system based on the configuration name.  You really
 653 ### only want to use this when you have no idea what the right
 654 ### operating system is; if you know what operating systems a machine
 655 ### runs, it's cleaner to make it explicit in the case statement
 656 ### above.
 657 if test x"${opsys}" = x; then
 658   case "${canonical}" in
 659     *-gnu* )                            opsys=gnu ;;
 660     * )
 661       unported=yes
 662     ;;
 663   esac
 664 fi
 665
 666 ]
 667 dnl quotation ends
 668
 669 if test $unported = yes; then
 670   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 671 Check `etc/MACHINES' for recognized configuration names.])
 672 fi
 673
 674 machfile="m/${machine}.h"
 675 opsysfile="s/${opsys}.h"
 676
 677
 678 #### Choose a compiler.
 679 test -n "$CC" && cc_specified=yes
 680
 681 # Save the value of CFLAGS that the user specified.
 682 SPECIFIED_CFLAGS="$CFLAGS"
 683
 684 dnl Sets GCC=yes if using gcc.
 685 AC_PROG_CC
 686
 687 # On Suns, sometimes $CPP names a directory.
 688 if test -n "$CPP" && test -d "$CPP"; then
 689   CPP=
 690 fi
 691
 692 ## If not using gcc, and on Solaris, and no CPP specified, see if
 693 ## using a Sun compiler, which needs -Xs to prevent whitespace.
 694 if test x"$GCC" != xyes && test x"$emacs_check_sunpro_c" = xyes && \
 695  test x"$CPP" = x; then
 696   AC_MSG_CHECKING([whether we are using a Sun C compiler])
 697   AC_CACHE_VAL(emacs_cv_sunpro_c,
 698   [AC_TRY_LINK([],
 699 [#ifndef __SUNPRO_C
 700 fail;
 701 #endif
 702 ], emacs_cv_sunpro_c=yes, emacs_cv_sunpro_c=no)])
 703   AC_MSG_RESULT($emacs_cv_sunpro_c)
 704
 705   if test x"$emacs_cv_sunpro_c" = xyes; then
 706     NON_GNU_CPP="$CC -E -Xs"
 707   fi
 708 fi
 709
 710 #### Some systems specify a CPP to use unless we are using GCC.
 711 #### Now that we know whether we are using GCC, we can decide whether
 712 #### to use that one.
 713 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
 714 then
 715   CPP="$NON_GNU_CPP"
 716 fi
 717
 718 #### Some systems specify a CC to use unless we are using GCC.
 719 #### Now that we know whether we are using GCC, we can decide whether
 720 #### to use that one.
 721 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
 722   test x$cc_specified != xyes
 723 then
 724   CC="$NON_GNU_CC"
 725 fi
 726
 727 if test x$GCC = xyes; then
 728   test "x$GCC_TEST_OPTIONS" != x && CC="$CC $GCC_TEST_OPTIONS"
 729 else
 730   test "x$NON_GCC_TEST_OPTIONS" != x && CC="$CC $NON_GCC_TEST_OPTIONS"
 731 fi
 732
 733 dnl checks for Unix variants
 734 AC_USE_SYSTEM_EXTENSIONS
 735
 736 ### Use -Wno-pointer-sign if the compiler supports it
 737 AC_MSG_CHECKING([whether gcc understands -Wno-pointer-sign])
 738 SAVE_CFLAGS="$CFLAGS"
 739 CFLAGS="$CFLAGS -Wno-pointer-sign"
 740 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 741 if test $has_option = yes; then
 742    C_WARNINGS_SWITCH="-Wno-pointer-sign $C_WARNINGS_SWITCH"
 743 fi
 744 AC_MSG_RESULT($has_option)
 745 CFLAGS="$SAVE_CFLAGS"
 746 unset has_option
 747 unset SAVE_CFLAGS
 748
 749 ### Use -Wdeclaration-after-statement if the compiler supports it
 750 AC_MSG_CHECKING([whether gcc understands -Wdeclaration-after-statement])
 751 SAVE_CFLAGS="$CFLAGS"
 752 CFLAGS="$CFLAGS -Wdeclaration-after-statement"
 753 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 754 if test $has_option = yes; then
 755    C_WARNINGS_SWITCH="-Wdeclaration-after-statement $C_WARNINGS_SWITCH"
 756 fi
 757 AC_MSG_RESULT($has_option)
 758 CFLAGS="$SAVE_CFLAGS"
 759 unset has_option
 760 unset SAVE_CFLAGS
 761
 762 ### Use -Wold-style-definition if the compiler supports it
 763 # This can be removed when conversion to standard C is finished.
 764 AC_MSG_CHECKING([whether gcc understands -Wold-style-definition])
 765 SAVE_CFLAGS="$CFLAGS"
 766 CFLAGS="$CFLAGS -Wold-style-definition"
 767 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 768 if test $has_option = yes; then
 769    C_WARNINGS_SWITCH="-Wold-style-definition $C_WARNINGS_SWITCH"
 770 fi
 771 AC_MSG_RESULT($has_option)
 772 CFLAGS="$SAVE_CFLAGS"
 773 unset has_option
 774 unset SAVE_CFLAGS
 775
 776 ### Use -Wimplicit-function-declaration if the compiler supports it
 777 AC_MSG_CHECKING([whether gcc understands -Wimplicit-function-declaration])
 778 SAVE_CFLAGS="$CFLAGS"
 779 CFLAGS="$CFLAGS -Wimplicit-function-declaration"
 780 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 781 if test $has_option = yes; then
 782    C_WARNINGS_SWITCH="-Wimplicit-function-declaration $C_WARNINGS_SWITCH"
 783 fi
 784 AC_MSG_RESULT($has_option)
 785 CFLAGS="$SAVE_CFLAGS"
 786 unset has_option
 787 unset SAVE_CFLAGS
 788
 789 AC_SUBST(C_WARNINGS_SWITCH)
 790
 791
 792 #### Some other nice autoconf tests.
 793
 794 dnl checks for programs
 795 AC_PROG_CPP
 796 AC_PROG_INSTALL
 797 if test "x$RANLIB" = x; then
 798   AC_PROG_RANLIB
 799 fi
 800
 801 ## Although we're running on an amd64 kernel, we're actually compiling for
 802 ## the x86 architecture.  The user should probably have provided an
 803 ## explicit --build to `configure', but if everything else than the kernel
 804 ## is running in i386 mode, we can help them out.
 805 if test "$machine" = "amdx86-64"; then
 806   AC_CHECK_DECL([i386])
 807   if test "$ac_cv_have_decl_i386" = "yes"; then
 808     canonical=`echo "$canonical" | sed -e 's/^amd64/i386/' -e 's/^x86_64/i386/'`
 809     machine=intel386
 810     machfile="m/${machine}.h"
 811   fi
 812 fi
 813
 814 AC_PATH_PROG(INSTALL_INFO, install-info)
 815 AC_PATH_PROG(INSTALL_INFO, install-info,, /usr/sbin)
 816 AC_PATH_PROG(INSTALL_INFO, install-info,:, /sbin)
 817 dnl Don't use GZIP, which is used by gzip for additional parameters.
 818 AC_PATH_PROG(GZIP_PROG, gzip)
 819
 820
 821 ## Need makeinfo >= 4.6 (?) to build the manuals.
 822 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 823 dnl By this stage, configure has already checked for egrep and set EGREP,
 824 dnl or exited with an error if no egrep was found.
 825 if test "$MAKEINFO" != "no" && \
 826   test x"`$MAKEINFO --version 2> /dev/null | $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[6-9]]|4\.[[1-5]][[0-9]]+)'`" = x; then
 827    MAKEINFO=no
 828 fi
 829
 830 ## Makeinfo is unusual.  For a released Emacs, the manuals are
 831 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
 832 ## therefore in the category of "special tools" not normally required, which
 833 ## configure does not have to check for (eg autoconf itself).
 834 ## In a Bazaar checkout on the other hand, the manuals are not included.
 835 ## So makeinfo is a requirement to build from Bazaar, and configure
 836 ## should test for it as it does for any other build requirement.
 837 ## We use the presence of $srcdir/info/emacs to distinguish a release,
 838 ## with pre-built manuals, from a Bazaar checkout.
 839 if test "$MAKEINFO" = "no"; then
 840   if test "x${with_makeinfo}" = "xno"; then
 841     MAKEINFO=off
 842   elif test ! -e $srcdir/info/emacs; then
 843     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.6, and your
 844 source tree does not seem to have pre-built manuals in the `info' directory.
 845 Either install a suitable version of makeinfo, or re-run configure
 846 with the `--without-makeinfo' option to build without the manuals.] )
 847   fi
 848 fi
 849
 850 dnl Add our options to ac_link now, after it is set up.
 851
 852 if test x$GCC = xyes && test "x$GCC_LINK_TEST_OPTIONS" != x
 853 then
 854   ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 855 fi
 856
 857 if test x$GCC = x && test "x$NON_GCC_LINK_TEST_OPTIONS" != x
 858 then
 859   ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 860 fi
 861
 862 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 863 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 864 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 865 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 866 dnl if not built to support GNU ld.
 867
 868 late_LDFLAGS=$LDFLAGS
 869 if test "$GCC" = yes; then
 870   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 871 else
 872   LDFLAGS="$LDFLAGS -znocombreloc"
 873 fi
 874
 875 AC_MSG_CHECKING([for -znocombreloc])
 876 AC_LINK_IFELSE([main(){return 0;}],
 877   [AC_MSG_RESULT(yes)],
 878   LDFLAGS=$late_LDFLAGS
 879   [AC_MSG_RESULT(no)])
 880
 881
 882 # The value of CPP is a quoted variable reference, so we need to do this
 883 # to get its actual value...
 884 CPP=`eval "echo $CPP"`
 885
 886
 887 dnl Not used by any currently supported platform.
 888 dnl The function dump-emacs will not be defined and temacs will do
 889 dnl (load "loadup") automatically unless told otherwise.
 890 CANNOT_DUMP=no
 891 case "$opsys" in
 892   your-opsys-here)
 893    CANNOT_DUMP=yes
 894    AC_DEFINE(CANNOT_DUMP, 1, [Define if Emacs cannot be dumped on your system.])
 895   ;;
 896 esac
 897 AC_SUBST(CANNOT_DUMP)
 898
 899
 900 UNEXEC_OBJ=unexelf.o
 901 case "$opsys" in
 902   # MSDOS uses unexcoff.o
 903   # MSWindows uses unexw32.o
 904   aix4-2)
 905    UNEXEC_OBJ=unexaix.o
 906    ;;
 907   cygwin)
 908    UNEXEC_OBJ=unexcw.o
 909    ;;
 910   darwin)
 911    UNEXEC_OBJ=unexmacosx.o
 912    ;;
 913   hpux10-20 | hpux11)
 914    UNEXEC_OBJ=unexhp9k800.o
 915    ;;
 916   sol2-10)
 917    # Use the Solaris dldump() function, called from unexsol.c, to dump
 918    # emacs, instead of the generic ELF dump code found in unexelf.c.
 919    # The resulting binary has a complete symbol table, and is better
 920    # for debugging and other observability tools (debuggers, pstack, etc).
 921    #
 922    # If you encounter a problem using dldump(), please consider sending
 923    # a message to the OpenSolaris tools-linking mailing list:
 924    #      http://mail.opensolaris.org/mailman/listinfo/tools-linking
 925    #
 926    # It is likely that dldump() works with older Solaris too, but this has
 927    # not been tested, so for now this change is for Solaris 10 or newer.
 928    UNEXEC_OBJ=unexsol.o
 929    ;;
 930 esac
 931
 932 LD_SWITCH_SYSTEM=
 933 case "$opsys" in
 934   freebsd)
 935    ## Let `ld' find image libs and similar things in /usr/local/lib.
 936    ## The system compiler, GCC, has apparently been modified to not
 937    ## look there, contrary to what a stock GCC would do.
 938    LD_SWITCH_SYSTEM=-L/usr/local/lib
 939    ;;
 940
 941   gnu-linux)
 942    ## cpp test was "ifdef __mips__", but presumably this is equivalent...
 943    test "$machine" = "mips" && LD_SWITCH_SYSTEM="-G 0"
 944    ;;
 945
 946   netbsd)
 947    LD_SWITCH_SYSTEM="-Wl,-rpath,/usr/pkg/lib -L/usr/pkg/lib -Wl,-rpath,/usr/local/lib -L/usr/local/lib"
 948    ;;
 949
 950   openbsd)
 951    ## Han Boetes <han@mijncomputer.nl> says this is necessary,
 952    ## otherwise Emacs dumps core on elf systems.
 953    LD_SWITCH_SYSTEM="-Z"
 954    ;;
 955 esac
 956 AC_SUBST(LD_SWITCH_SYSTEM)
 957
 958 ac_link="$ac_link $LD_SWITCH_SYSTEM"
 959
 960 ## This setting of LD_SWITCH_SYSTEM references LD_SWITCH_X_SITE_AUX,
 961 ## which has not been defined yet.  When this was handled with cpp,
 962 ## it was expanded to null when configure sourced the s/*.h file.
 963 ## Thus LD_SWITCH_SYSTEM had different values in configure and the Makefiles.
 964 ## FIXME it would be cleaner to put this in LD_SWITCH_SYSTEM_TEMACS
 965 ## (or somesuch), but because it is supposed to go at the _front_
 966 ## of LD_SWITCH_SYSTEM, we cannot do that in exactly the same way.
 967 ## Compare with the gnu-linux case below, which added to the end
 968 ## of LD_SWITCH_SYSTEM, and so can instead go at the front of
 969 ## LD_SWITCH_SYSTEM_TEMACS.
 970 case "$opsys" in
 971   netbsd|openbsd)
 972    ## _AUX_RPATH is like _AUX, but uses -rpath instead of -R.
 973    LD_SWITCH_SYSTEM="\$(LD_SWITCH_X_SITE_AUX_RPATH) $LD_SWITCH_SYSTEM" ;;
 974 esac
 975
 976
 977 C_SWITCH_MACHINE=
 978 if test "$machine" = "alpha"; then
 979   AC_CHECK_DECL([__ELF__])
 980   if test "$ac_cv_have_decl___ELF__" = "yes"; then
 981     ## With ELF, make sure that all common symbols get allocated to in the
 982     ## data section.  Otherwise, the dump of temacs may miss variables in
 983     ## the shared library that have been initialized.  For example, with
 984     ## GNU libc, __malloc_initialized would normally be resolved to the
 985     ## shared library's .bss section, which is fatal.
 986     if test "x$GCC" = "xyes"; then
 987       C_SWITCH_MACHINE="-fno-common"
 988     else
 989       AC_MSG_ERROR([What gives?  Fix me if DEC Unix supports ELF now.])
 990     fi
 991   else
 992     UNEXEC_OBJ=unexalpha.o
 993   fi
 994 fi
 995 AC_SUBST(C_SWITCH_MACHINE)
 996
 997 AC_SUBST(UNEXEC_OBJ)
 998
 999 C_SWITCH_SYSTEM=
1000 ## Some programs in src produce warnings saying certain subprograms
1001 ## are too complex and need a MAXMEM value greater than 2000 for
1002 ## additional optimization.  --nils@exp-math.uni-essen.de
1003 test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \
1004   C_SWITCH_SYSTEM="-ma -qmaxmem=4000"
1005 ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems.
1006 ## It is redundant in glibc2, since we define _GNU_SOURCE.
1007 AC_SUBST(C_SWITCH_SYSTEM)
1008
1009
1010 LIBS_SYSTEM=
1011 case "$opsys" in
1012   ## IBM's X11R5 uses -lIM and -liconv in AIX 3.2.2.
1013   aix4-2) LIBS_SYSTEM="-lrts -lIM -liconv" ;;
1014
1015   freebsd) LIBS_SYSTEM="-lutil" ;;
1016
1017   hpux*) LIBS_SYSTEM="-l:libdld.sl" ;;
1018
1019   sol2*) LIBS_SYSTEM="-lsocket -lnsl -lkstat" ;;
1020
1021   ## Motif needs -lgen.
1022   unixware) LIBS_SYSTEM="-lsocket -lnsl -lelf -lgen" ;;
1023 esac
1024 AC_SUBST(LIBS_SYSTEM)
1025
1026
1027 ### Make sure subsequent tests use flags consistent with the build flags.
1028
1029 if test x"${OVERRIDE_CPPFLAGS}" != x; then
1030   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
1031 else
1032   CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS"
1033 fi
1034
1035 dnl For AC_FUNC_GETLOADAVG, at least:
1036 AC_CONFIG_LIBOBJ_DIR(src)
1037
1038 dnl Do this early because it can frob feature test macros for Unix-98 &c.
1039 AC_SYS_LARGEFILE
1040
1041
1042 ## If user specified a crt-dir, use that unconditionally.
1043 if test "X$CRT_DIR" = "X"; then
1044
1045   case "$canonical" in
1046     x86_64-*-linux-gnu* | s390x-*-linux-gnu*)
1047     ## On x86-64 and s390x GNU/Linux distributions, the standard library
1048     ## can be in a variety of places.  We only try /usr/lib64 and /usr/lib.
1049     ## For anything else (eg /usr/lib32), it is up the user to specify
1050     ## the location (bug#5655).
1051     ## Test for crtn.o, not just the directory, because sometimes the
1052     ## directory exists but does not have the relevant files (bug#1287).
1053     ## FIXME better to test for binary compatibility somehow.
1054     test -e /usr/lib64/crtn.o && CRT_DIR=/usr/lib64
1055     ;;
1056
1057     powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*) CRT_DIR=/usr/lib64 ;;
1058   esac
1059
1060   case "$opsys" in
1061     hpux10-20) CRT_DIR=/lib ;;
1062   esac
1063
1064   ## Default is /usr/lib.
1065   test "X$CRT_DIR" = "X" && CRT_DIR=/usr/lib
1066
1067 else
1068
1069   ## Some platforms don't use any of these files, so it is not
1070   ## appropriate to put this test outside the if block.
1071   test -e $CRT_DIR/crtn.o || test -e $CRT_DIR/crt0.o || \
1072     AC_MSG_ERROR([crt*.o not found in specified location.])
1073
1074 fi
1075
1076 AC_SUBST(CRT_DIR)
1077
1078 LIB_MATH=-lm
1079 LIB_STANDARD=
1080 START_FILES=
1081
1082 case $opsys in
1083   cygwin )
1084     LIB_MATH=
1085     START_FILES='pre-crt0.o'
1086     ;;
1087   darwin )
1088     ## Adding -lm confuses the dynamic linker, so omit it.
1089     LIB_MATH=
1090     START_FILES='pre-crt0.o'
1091     ;;
1092   freebsd )
1093     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1094     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1095     ;;
1096   gnu-linux | gnu-kfreebsd )
1097     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtn.o'
1098     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o'
1099     ;;
1100   hpux10-20 | hpux11 )
1101     LIB_STANDARD=-lc
1102     START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o'
1103     ;;
1104   netbsd | openbsd )
1105     if test -f $CRT_DIR/crti.o; then
1106         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1107         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1108     else
1109         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o'
1110         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crtbegin.o'
1111     fi
1112     ;;
1113 esac
1114
1115 AC_SUBST(LIB_MATH)
1116 AC_SUBST(START_FILES)
1117
1118 dnl This function definition taken from Gnome 2.0
1119 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1120 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1121 dnl also defines GSTUFF_PKG_ERRORS on error
1122 AC_DEFUN([PKG_CHECK_MODULES], [
1123   succeeded=no
1124
1125   AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1126
1127   if test "$PKG_CONFIG" = "no" ; then
1128      ifelse([$4], , [AC_MSG_ERROR([
1129       *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
1130   else
1131      PKG_CONFIG_MIN_VERSION=0.9.0
1132      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1133         AC_MSG_CHECKING(for $2)
1134
1135         if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD; then
1136             AC_MSG_RESULT(yes)
1137             succeeded=yes
1138
1139             AC_MSG_CHECKING($1_CFLAGS)
1140             $1_CFLAGS=`$PKG_CONFIG --cflags "$2"|sed -e 's,///*,/,g'`
1141             AC_MSG_RESULT($$1_CFLAGS)
1142
1143             AC_MSG_CHECKING($1_LIBS)
1144             $1_LIBS=`$PKG_CONFIG --libs "$2"|sed -e 's,///*,/,g'`
1145             AC_MSG_RESULT($$1_LIBS)
1146         else
1147             AC_MSG_RESULT(no)
1148             $1_CFLAGS=""
1149             $1_LIBS=""
1150             ## If we have a custom action on failure, don't print errors, but
1151             ## do set a variable so people can do so.
1152             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1153             ifelse([$4], ,echo $$1_PKG_ERRORS,)
1154         fi
1155
1156         AC_SUBST($1_CFLAGS)
1157         AC_SUBST($1_LIBS)
1158      else
1159         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1160         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1161      fi
1162   fi
1163
1164   if test $succeeded = yes; then
1165      ifelse([$3], , :, [$3])
1166   else
1167      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1168   fi
1169 ])
1170
1171
1172 if test "${with_sound}" != "no"; then
1173   # Sound support for GNU/Linux and the free BSDs.
1174   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h,
1175     have_sound_header=yes)
1176   # Emulation library used on NetBSD.
1177   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1178   AC_SUBST(LIBSOUND)
1179
1180   ALSA_REQUIRED=1.0.0
1181   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1182   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1183   if test $HAVE_ALSA = yes; then
1184     SAVE_CFLAGS="$CFLAGS"
1185     SAVE_LDFLAGS="$LDFLAGS"
1186     CFLAGS="$ALSA_CFLAGS $CFLAGS"
1187     LDFLAGS="$ALSA_LIBS $LDFLAGS"
1188     AC_TRY_COMPILE([#include <asoundlib.h>], [snd_lib_error_set_handler (0);],
1189                     emacs_alsa_normal=yes,
1190                     emacs_alsa_normal=no)
1191     if test "$emacs_alsa_normal" != yes; then
1192       AC_TRY_COMPILE([#include <alsa/asoundlib.h>],
1193                      [snd_lib_error_set_handler (0);],
1194                      emacs_alsa_subdir=yes,
1195                      emacs_alsa_subdir=no)
1196       if test "$emacs_alsa_subdir" != yes; then
1197         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1198       fi
1199       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1200     fi
1201
1202     CFLAGS="$SAVE_CFLAGS"
1203     LDFLAGS="$SAVE_LDFLAGS"
1204     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1205     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1206     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1207   fi
1208
1209   dnl Define HAVE_SOUND if we have sound support.  We know it works and
1210   dnl compiles only on the specified platforms.  For others, it
1211   dnl probably doesn't make sense to try.
1212   if test x$have_sound_header = xyes || test $HAVE_ALSA = yes; then
1213      case "$opsys" in
1214        dnl defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
1215        gnu-linux|freebsd|netbsd)
1216          AC_DEFINE(HAVE_SOUND, 1, [Define to 1 if you have sound support.])
1217          ;;
1218      esac
1219   fi
1220
1221   AC_SUBST(CFLAGS_SOUND)
1222 fi
1223
1224 dnl checks for header files
1225 AC_CHECK_HEADERS(sys/select.h sys/timeb.h sys/time.h unistd.h utime.h \
1226   linux/version.h sys/systeminfo.h termios.h limits.h string.h stdlib.h \
1227   stdio_ext.h fcntl.h strings.h coff.h pty.h sys/mman.h \
1228   sys/param.h sys/vlimit.h sys/resource.h locale.h sys/_mbstate_t.h \
1229   sys/utsname.h pwd.h utmp.h dirent.h util.h)
1230
1231 AC_MSG_CHECKING(if personality LINUX32 can be set)
1232 AC_TRY_COMPILE([#include <sys/personality.h>], [personality (PER_LINUX32)],
1233                emacs_cv_personality_linux32=yes,
1234                emacs_cv_personality_linux32=no)
1235 AC_MSG_RESULT($emacs_cv_personality_linux32)
1236
1237 if test $emacs_cv_personality_linux32 = yes; then
1238   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1239             [Define to 1 if personality LINUX32 can be set.])
1240 fi
1241
1242 dnl On Solaris 8 there's a compilation warning for term.h because
1243 dnl it doesn't define `bool'.
1244 AC_CHECK_HEADERS(term.h, , , -)
1245 AC_HEADER_STDC
1246 AC_HEADER_TIME
1247 AC_CHECK_DECLS([sys_siglist])
1248 if test $ac_cv_have_decl_sys_siglist != yes; then
1249   # For Tru64, at least:
1250   AC_CHECK_DECLS([__sys_siglist])
1251   if test $ac_cv_have_decl___sys_siglist = yes; then
1252     AC_DEFINE(sys_siglist, __sys_siglist,
1253               [Define to any substitute for sys_siglist.])
1254   fi
1255 fi
1256 AC_HEADER_SYS_WAIT
1257
1258 dnl Some systems have utime.h but don't declare the struct anyplace.
1259 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1260 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1261 #include <sys/time.h>
1262 #include <time.h>
1263 #else
1264 #ifdef HAVE_SYS_TIME_H
1265 #include <sys/time.h>
1266 #else
1267 #include <time.h>
1268 #endif
1269 #endif
1270 #ifdef HAVE_UTIME_H
1271 #include <utime.h>
1272 #endif], [static struct utimbuf x; x.actime = x.modtime;],
1273   emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1274 if test $emacs_cv_struct_utimbuf = yes; then
1275   AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if `struct utimbuf' is declared by <utime.h>.])
1276 fi
1277
1278 dnl checks for typedefs
1279 AC_TYPE_SIGNAL
1280
1281 dnl Check for speed_t typedef.
1282 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1283   [AC_TRY_COMPILE([#include <termios.h>], [speed_t x = 1;],
1284     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1285 if test $emacs_cv_speed_t = yes; then
1286   AC_DEFINE(HAVE_SPEED_T, 1,
1287            [Define to 1 if `speed_t' is declared by <termios.h>.])
1288 fi
1289
1290 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1291 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1292 #include <sys/time.h>
1293 #include <time.h>
1294 #else
1295 #ifdef HAVE_SYS_TIME_H
1296 #include <sys/time.h>
1297 #else
1298 #include <time.h>
1299 #endif
1300 #endif], [static struct timeval x; x.tv_sec = x.tv_usec;],
1301   emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1302 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1303 if test $emacs_cv_struct_timeval = yes; then
1304   AC_DEFINE(HAVE_TIMEVAL, 1, [Define to 1 if `struct timeval' is declared by <sys/time.h>.])
1305 fi
1306
1307 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1308 AC_TRY_COMPILE([#include <math.h>],
1309 [static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;],
1310   emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1311 HAVE_EXCEPTION=$emacs_cv_struct_exception
1312 if test $emacs_cv_struct_exception != yes; then
1313   AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1314 fi
1315
1316 AC_CHECK_HEADERS(sys/socket.h)
1317 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1318 #if HAVE_SYS_SOCKET_H
1319 #include <sys/socket.h>
1320 #endif])
1321
1322 dnl checks for structure members
1323 AC_STRUCT_TM
1324 AC_STRUCT_TIMEZONE
1325 AC_CHECK_MEMBER(struct tm.tm_gmtoff,
1326                 [AC_DEFINE(HAVE_TM_GMTOFF, 1,
1327                            [Define to 1 if `tm_gmtoff' is member of `struct tm'.])],,
1328                 [#include <time.h>])
1329 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1330                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1331                   struct ifreq.ifr_addr], , ,
1332                  [AC_INCLUDES_DEFAULT
1333 #if HAVE_SYS_SOCKET_H
1334 #include <sys/socket.h>
1335 #endif
1336 #if HAVE_NET_IF_H
1337 #include <net/if.h>
1338 #endif])
1339
1340 dnl checks for compiler characteristics
1341
1342 dnl Testing __STDC__ to determine prototype support isn't good enough.
1343 dnl DEC C, for instance, doesn't define it with default options, and
1344 dnl is used on 64-bit systems (OSF Alphas).  Similarly for volatile
1345 dnl and void *.
1346 AC_C_PROTOTYPES
1347 AC_C_VOLATILE
1348 AC_C_CONST
1349 dnl This isn't useful because we can't turn on use of `inline' unless
1350 dnl the compiler groks `extern inline'.
1351 dnl AC_C_INLINE
1352 AC_CACHE_CHECK([for void * support], emacs_cv_void_star,
1353   [AC_TRY_COMPILE(, [void * foo;],
1354                    emacs_cv_void_star=yes, emacs_cv_void_star=no)])
1355 if test $emacs_cv_void_star = yes; then
1356   AC_DEFINE(POINTER_TYPE, void)
1357 else
1358   AC_DEFINE(POINTER_TYPE, char)
1359 fi
1360 AH_TEMPLATE(POINTER_TYPE,
1361             [Define as `void' if your compiler accepts `void *'; otherwise
1362              define as `char'.])dnl
1363
1364 dnl Check for endianess
1365 AC_C_BIGENDIAN
1366
1367 dnl check for Make feature
1368 AC_PROG_MAKE_SET
1369
1370 DEPFLAGS=
1371 MKDEPDIR=":"
1372 deps_frag=deps.mk
1373 dnl check for GNU Make if we have GCC and autodepend is on.
1374 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1375    AC_MSG_CHECKING([whether we are using GNU Make])
1376    HAVE_GNU_MAKE=no
1377    testval=`make --version 2>/dev/null | grep 'GNU Make'`
1378    if test "x$testval" != x; then
1379       HAVE_GNU_MAKE=yes
1380    else
1381       ac_enable_autodepend=no
1382    fi
1383    AC_MSG_RESULT([$HAVE_GNU_MAKE])
1384    if test $HAVE_GNU_MAKE = yes; then
1385       AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1386       SAVE_CFLAGS="$CFLAGS"
1387       CFLAGS="$CFLAGS -MMD -MF deps.d"
1388       AC_TRY_COMPILE([], [], , ac_enable_autodepend=no)
1389       CFLAGS="$SAVE_CFLAGS"
1390       test -f deps.d || ac_enable_autodepend=no
1391       rm -rf deps.d
1392       AC_MSG_RESULT([$ac_enable_autodepend])
1393    fi
1394    if test $ac_enable_autodepend = yes; then
1395       DEPFLAGS='-MMD -MF ${DEPDIR}/$*.d'
1396       ## In parallel builds, another make might create depdir between
1397       ## the first test and mkdir, so stick another test on the end.
1398       ## Or use mkinstalldirs?  mkdir -p is not portable.
1399       MKDEPDIR='test -d ${DEPDIR} || mkdir ${DEPDIR} || test -d ${DEPDIR}'
1400       deps_frag=autodeps.mk
1401    fi
1402 fi
1403 deps_frag=$srcdir/src/$deps_frag
1404 AC_SUBST(MKDEPDIR)
1405 AC_SUBST(DEPFLAGS)
1406 AC_SUBST_FILE(deps_frag)
1407
1408
1409 dnl checks for operating system services
1410 AC_SYS_LONG_FILE_NAMES
1411
1412 #### Choose a window system.
1413
1414 AC_PATH_X
1415 if test "$no_x" = yes; then
1416   window_system=none
1417 else
1418   window_system=x11
1419 fi
1420
1421 ## Workaround for bug in autoconf <= 2.62.
1422 ## http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01551.html
1423 ## No need to do anything special for these standard directories.
1424 if test -n "${x_libraries}" && test x"${x_libraries}" != xNONE; then
1425
1426    x_libraries=`echo :${x_libraries}: | sed -e 's|:/usr/lib64:|:|g' -e 's|:/lib64:|:|g' -e 's|^:||' -e 's|:$||'`
1427
1428 fi
1429
1430 LD_SWITCH_X_SITE_AUX=
1431 LD_SWITCH_X_SITE_AUX_RPATH=
1432 if test "${x_libraries}" != NONE; then
1433   if test -n "${x_libraries}"; then
1434     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1435     LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
1436     LD_SWITCH_X_SITE_AUX_RPATH=`echo ${LD_SWITCH_X_SITE_AUX} | sed -e 's/-R/-Wl,-rpath,/'`
1437   fi
1438   x_default_search_path=""
1439   x_search_path=${x_libraries}
1440   if test -z "${x_search_path}"; then
1441     x_search_path=/usr/lib
1442   fi
1443   for x_library in `echo ${x_search_path}: | \
1444                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1445     x_search_path="\
1446 ${x_library}/X11/%L/%T/%N%C%S:\
1447 ${x_library}/X11/%l/%T/%N%C%S:\
1448 ${x_library}/X11/%T/%N%C%S:\
1449 ${x_library}/X11/%L/%T/%N%S:\
1450 ${x_library}/X11/%l/%T/%N%S:\
1451 ${x_library}/X11/%T/%N%S"
1452     if test x"${x_default_search_path}" = x; then
1453       x_default_search_path=${x_search_path}
1454     else
1455       x_default_search_path="${x_search_path}:${x_default_search_path}"
1456     fi
1457   done
1458 fi
1459 AC_SUBST(LD_SWITCH_X_SITE_AUX)
1460 AC_SUBST(LD_SWITCH_X_SITE_AUX_RPATH)
1461
1462 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1463   C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"`
1464 fi
1465
1466 if test x"${x_includes}" = x; then
1467   bitmapdir=/usr/include/X11/bitmaps
1468 else
1469   # accumulate include directories that have X11 bitmap subdirectories
1470   bmd_acc="dummyval"
1471   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1472     if test -d "${bmd}/X11/bitmaps"; then
1473       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1474     fi
1475     if test -d "${bmd}/bitmaps"; then
1476       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1477     fi
1478   done
1479   if test ${bmd_acc} != "dummyval"; then
1480     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1481   fi
1482 fi
1483
1484 HAVE_NS=no
1485 NS_IMPL_COCOA=no
1486 NS_IMPL_GNUSTEP=no
1487 tmp_CPPFLAGS="$CPPFLAGS"
1488 tmp_CFLAGS="$CFLAGS"
1489 CPPFLAGS="$CPPFLAGS -x objective-c"
1490 CFLAGS="$CFLAGS -x objective-c"
1491 TEMACS_LDFLAGS2="\${LDFLAGS} \${PROFILING_LDFLAGS}"
1492 dnl I don't think it's especially important, but src/Makefile.in
1493 dnl (now the only user of ns_appdir) used to go to the trouble of adding a
1494 dnl trailing "/" to it, so now we do it here.
1495 if test "${with_ns}" != no; then
1496   if test "${opsys}" = darwin; then
1497      NS_IMPL_COCOA=yes
1498      ns_appdir=`pwd`/nextstep/Emacs.app/
1499      ns_appbindir=${ns_appdir}Contents/MacOS/
1500      ns_appresdir=${ns_appdir}Contents/Resources
1501      ns_appsrc=${srcdir}/nextstep/Cocoa/Emacs.base
1502   elif test -f $GNUSTEP_CONFIG_FILE; then
1503      NS_IMPL_GNUSTEP=yes
1504      ns_appdir=`pwd`/nextstep/Emacs.app/
1505      ns_appbindir=${ns_appdir}
1506      ns_appresdir=${ns_appdir}Resources
1507      ns_appsrc=${srcdir}/nextstep/GNUstep/Emacs.base
1508      dnl FIXME sourcing this several times in subshells seems inefficient.
1509      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1510      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1511      dnl I seemed to need these as well with GNUstep-startup 0.25.
1512      GNUSTEP_LOCAL_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_HEADERS)"
1513      GNUSTEP_LOCAL_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_LIBRARIES)"
1514      test "x${GNUSTEP_LOCAL_HEADERS}" != "x" && \
1515        GNUSTEP_LOCAL_HEADERS="-I${GNUSTEP_LOCAL_HEADERS}"
1516      test "x${GNUSTEP_LOCAL_LIBRARIES}" != "x" && \
1517        GNUSTEP_LOCAL_LIBRARIES="-L${GNUSTEP_LOCAL_LIBRARIES}"
1518      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1519      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1520      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES}"
1521      LIB_STANDARD=
1522      START_FILES=
1523      TEMACS_LDFLAGS2=
1524   fi
1525   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1526                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1527   files are missing or cannot be compiled.])])
1528   NS_HAVE_NSINTEGER=yes
1529   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1530                                      [NSInteger i;])],
1531                     ns_have_nsinteger=yes,
1532                     ns_have_nsinteger=no)
1533   if test $ns_have_nsinteger = no; then
1534     NS_HAVE_NSINTEGER=no
1535   fi
1536 fi
1537 AC_SUBST(TEMACS_LDFLAGS2)
1538
1539 ns_frag=/dev/null
1540 NS_OBJ=
1541 NS_SUPPORT=
1542 if test "${HAVE_NS}" = yes; then
1543   window_system=nextstep
1544   with_xft=no
1545   # set up packaging dirs
1546   exec_prefix=${ns_appbindir}
1547   libexecdir=${ns_appbindir}/libexec
1548   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1549      prefix=${ns_appresdir}
1550   fi
1551   ns_frag=$srcdir/src/ns.mk
1552   NS_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o nsfont.o fontset.o fringe.o image.o"
1553   NS_SUPPORT="\${lispsource}emacs-lisp/easymenu.elc \${lispsource}term/ns-win.elc"
1554 fi
1555 CFLAGS="$tmp_CFLAGS"
1556 CPPFLAGS="$tmp_CPPFLAGS"
1557 AC_SUBST(NS_OBJ)
1558 AC_SUBST(NS_SUPPORT)
1559 AC_SUBST(LIB_STANDARD)
1560 AC_SUBST_FILE(ns_frag)
1561
1562 case "${window_system}" in
1563   x11 )
1564     HAVE_X_WINDOWS=yes
1565     HAVE_X11=yes
1566     case "${with_x_toolkit}" in
1567       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1568       motif ) USE_X_TOOLKIT=MOTIF ;;
1569       gtk ) with_gtk=yes
1570 dnl Dont set this for GTK.  A lot of tests below assumes Xt when
1571 dnl USE_X_TOOLKIT is set.
1572             USE_X_TOOLKIT=none ;;
1573       gtk3 ) with_gtk3=yes
1574              USE_X_TOOLKIT=none ;;
1575       no ) USE_X_TOOLKIT=none ;;
1576 dnl If user did not say whether to use a toolkit, make this decision later:
1577 dnl use the toolkit if we have gtk, or X11R5 or newer.
1578       * ) USE_X_TOOLKIT=maybe ;;
1579     esac
1580   ;;
1581   nextstep | none )
1582     HAVE_X_WINDOWS=no
1583     HAVE_X11=no
1584     USE_X_TOOLKIT=none
1585   ;;
1586 esac
1587
1588 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1589    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1590    if test "$HAVE_XSERVER" = true ||
1591       test -n "$DISPLAY" ||
1592       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1593         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1594 were found.  You should install the relevant development files for X
1595 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1596 sure you have development files for image handling, i.e.
1597 tiff, gif, jpeg, png and xpm.
1598 If you are sure you want Emacs compiled without X window support, pass
1599   --without-x
1600 to configure.])
1601    fi
1602 fi
1603
1604 ### If we're using X11, we should use the X menu package.
1605 HAVE_MENUS=no
1606 case ${HAVE_X11} in
1607   yes ) HAVE_MENUS=yes ;;
1608 esac
1609
1610 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1611 # Assume not, until told otherwise.
1612 GNU_MALLOC=yes
1613 doug_lea_malloc=yes
1614 AC_CHECK_FUNC(malloc_get_state, ,doug_lea_malloc=no)
1615 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
1616 AC_CACHE_CHECK(whether __after_morecore_hook exists,
1617                emacs_cv_var___after_morecore_hook,
1618 [AC_TRY_LINK([extern void (* __after_morecore_hook)();],[__after_morecore_hook = 0],
1619   emacs_cv_var___after_morecore_hook=yes,
1620   emacs_cv_var___after_morecore_hook=no)])
1621 if test $emacs_cv_var___after_morecore_hook = no; then
1622   doug_lea_malloc=no
1623 fi
1624
1625
1626 dnl See comments in aix4-2.h about maybe using system malloc there.
1627 system_malloc=no
1628 case "$opsys" in
1629   ## darwin ld insists on the use of malloc routines in the System framework.
1630   darwin|sol2-10) system_malloc=yes ;;
1631 esac
1632
1633 if test "${system_malloc}" = "yes"; then
1634   AC_DEFINE(SYSTEM_MALLOC, 1, [Define to use system malloc.])
1635   GNU_MALLOC=no
1636   GNU_MALLOC_reason="
1637     (The GNU allocators don't work with this system configuration.)"
1638   GMALLOC_OBJ=
1639   VMLIMIT_OBJ=
1640 else
1641   test "$doug_lea_malloc" != "yes" && GMALLOC_OBJ=gmalloc.o
1642   VMLIMIT_OBJ=vm-limit.o
1643 fi
1644 AC_SUBST(GMALLOC_OBJ)
1645 AC_SUBST(VMLIMIT_OBJ)
1646
1647 if test "$doug_lea_malloc" = "yes" ; then
1648   if test "$GNU_MALLOC" = yes ; then
1649     GNU_MALLOC_reason="
1650       (Using Doug Lea's new malloc from the GNU C Library.)"
1651   fi
1652   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1653             [Define to 1 if you are using the GNU C Library.])
1654
1655   ## Use mmap directly for allocating larger buffers.
1656   ## FIXME this comes from src/s/{gnu,gnu-linux}.h:
1657   ## #ifdef DOUG_LEA_MALLOC; #undef REL_ALLOC; #endif
1658   ## Does the AC_FUNC_MMAP test below make this check unecessary?
1659   case "$opsys" in
1660     gnu*) REL_ALLOC=no ;;
1661   esac
1662 fi
1663
1664 if test x"${REL_ALLOC}" = x; then
1665   REL_ALLOC=${GNU_MALLOC}
1666 fi
1667
1668 use_mmap_for_buffers=no
1669 case "$opsys" in
1670   freebsd|irix6-5) use_mmap_for_buffers=yes ;;
1671 esac
1672
1673 AC_FUNC_MMAP
1674 if test $use_mmap_for_buffers = yes; then
1675   AC_DEFINE(USE_MMAP_FOR_BUFFERS, 1, [Define to use mmap to allocate buffer text.])
1676   REL_ALLOC=no
1677 fi
1678
1679 LIBS="$LIBS_SYSTEM $LIBS"
1680
1681 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1682 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1683 AC_CHECK_LIB(dnet, dnet_ntoa)
1684 dnl This causes -lresolv to get used in subsequent tests,
1685 dnl which causes failures on some systems such as HPUX 9.
1686 dnl AC_CHECK_LIB(resolv, gethostbyname)
1687
1688 dnl FIXME replace main with a function we actually want from this library.
1689 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1690
1691 AC_CHECK_LIB(pthreads, cma_open)
1692
1693 ## Note: when using cpp in s/aix4.2.h, this definition depended on
1694 ## HAVE_LIBPTHREADS.  That was not defined earlier in configure when
1695 ## the system file was sourced.  Hence the value of LIBS_SYSTEM
1696 ## added to LIBS in configure would never contain the pthreads part,
1697 ## but the value used in Makefiles might.  FIXME?
1698 ##
1699 ## -lpthreads seems to be necessary for Xlib in X11R6, and should
1700 ## be harmless on older versions of X where it happens to exist.
1701 test "$opsys" = "aix4-2" && \
1702   test $ac_cv_lib_pthreads_cma_open = yes && \
1703   LIBS_SYSTEM="$LIBS_SYSTEM -lpthreads"
1704
1705 dnl Check for need for bigtoc support on IBM AIX
1706
1707 case ${host_os} in
1708 aix*)
1709   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1710     case $GCC in
1711     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1712     *) gdb_cv_bigtoc=-bbigtoc ;;
1713     esac
1714
1715     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1716     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1717   ])
1718   ;;
1719 esac
1720
1721 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1722 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1723 # REAL_CPPFLAGS later on.
1724
1725 REAL_CFLAGS="$CFLAGS"
1726 REAL_CPPFLAGS="$CPPFLAGS"
1727
1728 if test "${HAVE_X11}" = "yes"; then
1729   DEFS="$C_SWITCH_X_SITE $DEFS"
1730   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1731   LIBS="-lX11 $LIBS"
1732   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1733   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1734
1735   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1736   # This is handled by LD_SWITCH_X_SITE_AUX during the real build,
1737   # but it's more convenient here to set LD_RUN_PATH
1738   # since this also works on hosts that don't understand LD_SWITCH_X_SITE_AUX.
1739   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1740     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1741     export LD_RUN_PATH
1742   fi
1743
1744   if test "${opsys}" = "gnu-linux"; then
1745     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1746     AC_TRY_LINK([],
1747      [XOpenDisplay ("foo");],
1748      [xlinux_first_failure=no],
1749      [xlinux_first_failure=yes])
1750     if test "${xlinux_first_failure}" = "yes"; then
1751       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1752       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1753       OLD_CPPFLAGS="$CPPFLAGS"
1754       OLD_LIBS="$LIBS"
1755       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1756       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1757       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1758       LIBS="$LIBS -b i486-linuxaout"
1759       AC_TRY_LINK([],
1760        [XOpenDisplay ("foo");],
1761        [xlinux_second_failure=no],
1762        [xlinux_second_failure=yes])
1763       if test "${xlinux_second_failure}" = "yes"; then
1764         # If we get the same failure with -b, there is no use adding -b.
1765         # So take it out.  This plays safe.
1766         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1767         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1768         CPPFLAGS="$OLD_CPPFLAGS"
1769         LIBS="$OLD_LIBS"
1770         AC_MSG_RESULT(no)
1771       else
1772         AC_MSG_RESULT(yes)
1773       fi
1774     else
1775       AC_MSG_RESULT(no)
1776     fi
1777   fi
1778
1779   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1780   # header files included from there.
1781   AC_MSG_CHECKING(for Xkb)
1782   AC_TRY_LINK([#include <X11/Xlib.h>
1783 #include <X11/XKBlib.h>],
1784         [XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);],
1785         emacs_xkb=yes, emacs_xkb=no)
1786   AC_MSG_RESULT($emacs_xkb)
1787   if test $emacs_xkb = yes; then
1788     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1789   fi
1790
1791   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1792 XScreenNumberOfScreen XSetWMProtocols)
1793 fi
1794
1795 if test "${window_system}" = "x11"; then
1796   AC_MSG_CHECKING(X11 version 6)
1797   AC_CACHE_VAL(emacs_cv_x11_version_6,
1798   [AC_TRY_LINK([#include <X11/Xlib.h>],
1799 [#if XlibSpecificationRelease < 6
1800 fail;
1801 #endif
1802 ], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1803   if test $emacs_cv_x11_version_6 = yes; then
1804     AC_MSG_RESULT(6 or newer)
1805     AC_DEFINE(HAVE_X11R6, 1,
1806               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1807     AC_DEFINE(HAVE_X_I18N, 1, [Define if you have usable i18n support.])
1808     ## inoue@ainet.or.jp says Solaris has a bug related to X11R6-style
1809     ## XIM support.
1810     case "$opsys" in
1811       sol2-*) : ;;
1812       *) AC_DEFINE(HAVE_X11R6_XIM, 1,
1813            [Define if you have usable X11R6-style XIM support.])
1814          ;;
1815     esac
1816   else
1817     AC_MSG_RESULT(before 6)
1818   fi
1819 fi
1820
1821
1822 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1823 HAVE_RSVG=no
1824 if test "${HAVE_X11}" = "yes" || test "${NS_IMPL_GNUSTEP}" = "yes"; then
1825   if test "${with_rsvg}" != "no"; then
1826     RSVG_REQUIRED=2.11.0
1827     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1828
1829     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, HAVE_RSVG=yes, :)
1830     AC_SUBST(RSVG_CFLAGS)
1831     AC_SUBST(RSVG_LIBS)
1832
1833     if test $HAVE_RSVG = yes; then
1834       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1835       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1836       LIBS="$RSVG_LIBS $LIBS"
1837     fi
1838   fi
1839 fi
1840
1841 HAVE_IMAGEMAGICK=no
1842 if test "${with_imagemagick}" != "no"; then
1843   IMAGEMAGICK_MODULE="Wand"
1844   PKG_CHECK_MODULES(IMAGEMAGICK, $IMAGEMAGICK_MODULE, HAVE_IMAGEMAGICK=yes, :)
1845   AC_SUBST(IMAGEMAGICK_CFLAGS)
1846   AC_SUBST(IMAGEMAGICK_LIBS)
1847
1848   if test $HAVE_IMAGEMAGICK = yes; then
1849     AC_DEFINE(HAVE_IMAGEMAGICK, 1, [Define to 1 if using imagemagick.])
1850     CFLAGS="$CFLAGS $IMAGEMAGICK_CFLAGS"
1851     LIBS="$IMAGEMAGICK_LIBS $LIBS"
1852     AC_CHECK_FUNCS(MagickExportImagePixels)
1853   fi
1854 fi
1855
1856
1857 HAVE_GTK=no
1858 if test "${with_gtk3}" = "yes"; then
1859   GLIB_REQUIRED=2.6
1860   GTK_REQUIRED=2.90
1861   GTK_MODULES="gtk+-3.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1862
1863   dnl Checks for libraries.
1864   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1865   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1866      AC_MSG_ERROR($GTK_PKG_ERRORS)
1867   fi
1868 fi
1869
1870 if test "$pkg_check_gtk" != "yes"; then
1871   HAVE_GTK=no
1872 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
1873   GLIB_REQUIRED=2.6
1874   GTK_REQUIRED=2.6
1875   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1876
1877   dnl Checks for libraries.
1878   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1879   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1880      AC_MSG_ERROR($GTK_PKG_ERRORS)
1881   fi
1882 fi
1883 fi
1884
1885 GTK_OBJ=
1886 if test x"$pkg_check_gtk" = xyes; then
1887
1888   AC_SUBST(GTK_CFLAGS)
1889   AC_SUBST(GTK_LIBS)
1890   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1891   CFLAGS="$CFLAGS $GTK_CFLAGS"
1892   LIBS="$GTK_LIBS $LIBS"
1893   dnl Try to compile a simple GTK program.
1894   GTK_COMPILES=no
1895   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
1896   if test "${GTK_COMPILES}" != "yes"; then
1897     if test "$USE_X_TOOLKIT" != "maybe"; then
1898       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
1899     fi
1900   else
1901     HAVE_GTK=yes
1902     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
1903     GTK_OBJ=gtkutil.o
1904     USE_X_TOOLKIT=none
1905     if $PKG_CONFIG --atleast-version=2.10 gtk+-2.0; then
1906       :
1907     else
1908       AC_MSG_WARN([[Your version of Gtk+ will have problems with
1909        closing open displays.  This is no problem if you just use
1910        one display, but if you use more than one and close one of them
1911        Emacs may crash.]])
1912       sleep 3
1913     fi
1914   fi
1915
1916 fi
1917 AC_SUBST(GTK_OBJ)
1918
1919
1920 if test "${HAVE_GTK}" = "yes"; then
1921
1922   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
1923   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
1924   if test "$with_toolkit_scroll_bars" != no; then
1925     with_toolkit_scroll_bars=yes
1926   fi
1927
1928   dnl  Check if we have the old file selection dialog declared and
1929   dnl  in the link library.  In 2.x it may be in the library,
1930   dnl  but not declared if deprecated featured has been selected out.
1931   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
1932   HAVE_GTK_FILE_SELECTION=no
1933   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
1934                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
1935 #include <gtk/gtk.h>])
1936   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
1937     AC_CHECK_FUNCS(gtk_file_selection_new)
1938   fi
1939
1940   dnl Check if pthreads are available.  Emacs only needs this when using
1941   dnl gtk_file_chooser under Gnome.
1942     HAVE_GTK_AND_PTHREAD=no
1943     AC_CHECK_HEADERS(pthread.h)
1944     if test "$ac_cv_header_pthread_h"; then
1945       AC_CHECK_LIB(pthread, pthread_self, HAVE_GTK_AND_PTHREAD=yes)
1946     fi
1947     if test "$HAVE_GTK_AND_PTHREAD" = yes; then
1948       case "${canonical}" in
1949         *-hpux*) ;;
1950         *) GTK_LIBS="$GTK_LIBS -lpthread" ;;
1951       esac
1952       AC_DEFINE(HAVE_GTK_AND_PTHREAD, 1,
1953                [Define to 1 if you have GTK and pthread (-lpthread).])
1954     fi
1955
1956   dnl Check for functions introduced in 2.14 and later.
1957   AC_CHECK_FUNCS(gtk_widget_get_window gtk_widget_set_has_window \
1958                  gtk_dialog_get_action_area gtk_widget_get_sensitive \
1959                  gtk_widget_get_mapped gtk_adjustment_get_page_size \
1960                  gtk_orientable_set_orientation)
1961
1962 fi
1963
1964 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
1965 dnl other platforms.  Support for higher D-Bus versions than 1.0 is
1966 dnl also not configured.
1967 HAVE_DBUS=no
1968 DBUS_OBJ=
1969 if test "${with_dbus}" = "yes"; then
1970    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
1971    if test "$HAVE_DBUS" = yes; then
1972      LIBS="$LIBS $DBUS_LIBS"
1973      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
1974      AC_CHECK_FUNCS([dbus_watch_get_unix_fd])
1975      DBUS_OBJ=dbusbind.o
1976    fi
1977 fi
1978 AC_SUBST(DBUS_OBJ)
1979
1980 dnl GConf has been tested under GNU/Linux only.
1981 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
1982 HAVE_GCONF=no
1983 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
1984    PKG_CHECK_MODULES(GCONF, gconf-2.0 >= 2.13, HAVE_GCONF=yes, HAVE_GCONF=no)
1985    if test "$HAVE_GCONF" = yes; then
1986       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
1987    fi
1988 fi
1989
1990 dnl SELinux is available for GNU/Linux only.
1991 HAVE_LIBSELINUX=no
1992 LIBSELINUX_LIBS=
1993 if test "${with_selinux}" = "yes"; then
1994    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
1995    if test "$HAVE_LIBSELINUX" = yes; then
1996       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
1997       LIBSELINUX_LIBS=-lselinux
1998    fi
1999 fi
2000 AC_SUBST(LIBSELINUX_LIBS)
2001
2002 dnl Do not put whitespace before the #include statements below.
2003 dnl Older compilers (eg sunos4 cc) choke on it.
2004 HAVE_XAW3D=no
2005 LUCID_LIBW=
2006 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
2007   if test "$with_xaw3d" != no; then
2008     AC_MSG_CHECKING(for xaw3d)
2009     AC_CACHE_VAL(emacs_cv_xaw3d,
2010     [AC_TRY_LINK([
2011 #include <X11/Intrinsic.h>
2012 #include <X11/Xaw3d/Simple.h>],
2013       [],
2014       emacs_cv_xaw3d=yes,
2015       emacs_cv_xaw3d=no)])
2016   else
2017     emacs_cv_xaw3d=no
2018   fi
2019   if test $emacs_cv_xaw3d = yes; then
2020     AC_MSG_RESULT([yes; using Lucid toolkit])
2021     USE_X_TOOLKIT=LUCID
2022     HAVE_XAW3D=yes
2023     LUCID_LIBW=-lXaw3d
2024     AC_DEFINE(HAVE_XAW3D, 1,
2025               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
2026   else
2027     AC_MSG_RESULT(no)
2028     AC_MSG_CHECKING(for libXaw)
2029     AC_CACHE_VAL(emacs_cv_xaw,
2030     [AC_TRY_LINK([
2031 #include <X11/Intrinsic.h>
2032 #include <X11/Xaw/Simple.h>],
2033       [],
2034       emacs_cv_xaw=yes,
2035       emacs_cv_xaw=no)])
2036     if test $emacs_cv_xaw = yes; then
2037       AC_MSG_RESULT([yes; using Lucid toolkit])
2038       USE_X_TOOLKIT=LUCID
2039       LUCID_LIBW=-lXaw
2040     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
2041       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
2042     else
2043       AC_MSG_RESULT([no; do not use toolkit by default])
2044       USE_X_TOOLKIT=none
2045     fi
2046   fi
2047 fi
2048
2049 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
2050
2051 LIBXTR6=
2052 if test "${USE_X_TOOLKIT}" != "none"; then
2053   AC_MSG_CHECKING(X11 toolkit version)
2054   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2055   [AC_TRY_LINK([#include <X11/Intrinsic.h>],
2056 [#if XtSpecificationRelease < 6
2057 fail;
2058 #endif
2059 ], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2060   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2061   if test $emacs_cv_x11_toolkit_version_6 = yes; then
2062     AC_MSG_RESULT(6 or newer)
2063     AC_DEFINE(HAVE_X11XTR6, 1,
2064               [Define to 1 if you have the X11R6 or newer version of Xt.])
2065     LIBXTR6="-lSM -lICE"
2066     case "$opsys" in
2067       ## Use libw.a along with X11R6 Xt.
2068       unixware) LIBXTR6="$LIBXTR6 -lw" ;;
2069     esac
2070   else
2071     AC_MSG_RESULT(before 6)
2072   fi
2073
2074 dnl If using toolkit, check whether libXmu.a exists.
2075 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2076   OLDLIBS="$LIBS"
2077   if test x$HAVE_X11XTR6 = xyes; then
2078     LIBS="-lXt -lSM -lICE $LIBS"
2079   else
2080     LIBS="-lXt $LIBS"
2081   fi
2082   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
2083   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
2084 fi
2085 AC_SUBST(LIBXTR6)
2086
2087 dnl FIXME the logic here seems weird, but this is what cpp was doing.
2088 dnl Why not just test for libxmu in the normal way?
2089 LIBXMU=-lXmu
2090 case "$machine" in
2091   ## These machines don't supply Xmu.
2092   hpux* | aix4-2 )
2093     test "X$ac_cv_lib_Xmu_XmuConvertStandardSelection" != "Xyes" && LIBXMU=
2094     ;;
2095 esac
2096 AC_SUBST(LIBXMU)
2097
2098 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
2099 if test "${HAVE_X11}" = "yes"; then
2100   if test "${USE_X_TOOLKIT}" != "none"; then
2101     AC_CHECK_LIB(Xext, XShapeQueryExtension)
2102   fi
2103 fi
2104
2105 LIBXP=
2106 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2107   AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
2108   [AC_TRY_COMPILE([#include <Xm/Xm.h>],
2109     [#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2110 int x = 5;
2111 #else
2112 Motif version prior to 2.1.
2113 #endif],
2114     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2115   if test $emacs_cv_motif_version_2_1 = yes; then
2116     AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
2117   else
2118     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2119     # We put this in CFLAGS temporarily to precede other -I options
2120     # that might be in CFLAGS temporarily.
2121     # We put this in CPPFLAGS where it precedes the other -I options.
2122     OLD_CPPFLAGS=$CPPFLAGS
2123     OLD_CFLAGS=$CFLAGS
2124     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2125     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2126     [AC_TRY_COMPILE([#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>],
2127       [int x = 5;],
2128       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2129     if test $emacs_cv_lesstif = yes; then
2130       # Make sure this -I option remains in CPPFLAGS after it is set
2131       # back to REAL_CPPFLAGS.
2132       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
2133       # have those other -I options anyway.  Ultimately, having this
2134       # directory ultimately in CPPFLAGS will be enough.
2135       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
2136       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
2137     else
2138       CFLAGS=$OLD_CFLAGS
2139       CPPFLAGS=$OLD_CPPFLAGS
2140     fi
2141   fi
2142 fi
2143
2144 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2145 dnl using Motif or Xaw3d is available, and unless
2146 dnl --with-toolkit-scroll-bars=no was specified.
2147
2148 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2149             [Define to 1 if we should use toolkit scroll bars.])dnl
2150 USE_TOOLKIT_SCROLL_BARS=no
2151 if test "${with_toolkit_scroll_bars}" != "no"; then
2152   if test "${USE_X_TOOLKIT}" != "none"; then
2153     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2154       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2155       HAVE_XAW3D=no
2156       USE_TOOLKIT_SCROLL_BARS=yes
2157     elif test "${HAVE_XAW3D}" = "yes"; then
2158       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2159       USE_TOOLKIT_SCROLL_BARS=yes
2160     fi
2161   elif test "${HAVE_GTK}" = "yes"; then
2162     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2163     USE_TOOLKIT_SCROLL_BARS=yes
2164   elif test "${HAVE_NS}" = "yes"; then
2165     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2166     USE_TOOLKIT_SCROLL_BARS=yes
2167   fi
2168 fi
2169
2170 dnl See if XIM is available.
2171 AC_TRY_COMPILE([
2172           #include <X11/Xlib.h>
2173           #include <X11/Xresource.h>],
2174          [XIMProc  callback;],
2175          [HAVE_XIM=yes
2176          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
2177          HAVE_XIM=no)
2178
2179 dnl `--with-xim' now controls only the initial value of use_xim at run time.
2180
2181 if test "${with_xim}" != "no"; then
2182   AC_DEFINE(USE_XIM, 1,
2183             [Define to 1 if we should use XIM, if it is available.])
2184 fi
2185
2186
2187 if test "${HAVE_XIM}" != "no"; then
2188   late_CFLAGS=$CFLAGS
2189   if test "$GCC" = yes; then
2190     CFLAGS="$CFLAGS --pedantic-errors"
2191   fi
2192   AC_TRY_COMPILE([
2193 #include <X11/Xlib.h>
2194 #include <X11/Xresource.h>],
2195 [Display *display;
2196 XrmDatabase db;
2197 char *res_name;
2198 char *res_class;
2199 XIMProc  callback;
2200 XPointer *client_data;
2201 #ifndef __GNUC__
2202 /* If we're not using GCC, it's probably not XFree86, and this is
2203    probably right, but we can't use something like --pedantic-errors.  */
2204 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
2205                                            char*, XIMProc, XPointer*);
2206 #endif
2207 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
2208    client_data);],
2209     [emacs_cv_arg6_star=yes])
2210   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
2211          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
2212 either XPointer or XPointer*.])dnl
2213   if test "$emacs_cv_arg6_star" = yes; then
2214     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
2215   else
2216     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
2217   fi
2218   CFLAGS=$late_CFLAGS
2219 fi
2220
2221 ### Start of font-backend (under any platform) section.
2222 # (nothing here yet -- this is a placeholder)
2223 ### End of font-backend (under any platform) section.
2224
2225 ### Start of font-backend (under X11) section.
2226 if test "${HAVE_X11}" = "yes"; then
2227    PKG_CHECK_MODULES(FONTCONFIG, fontconfig >= 2.2.0, HAVE_FC=yes, HAVE_FC=no)
2228
2229    ## Use -lXft if available, unless `--with-xft=no'.
2230    HAVE_XFT=maybe
2231     if test "${HAVE_FC}" = "no" || test "x${with_x}" = "xno"; then
2232       with_xft="no";
2233     fi
2234     if test "x${with_xft}" != "xno"; then
2235
2236       PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
2237       ## Because xftfont.c uses XRenderQueryExtension, we also
2238       ## need to link to -lXrender.
2239       HAVE_XRENDER=no
2240       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
2241       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
2242         OLD_CPPFLAGS="$CPPFLAGS"
2243         OLD_CFLAGS="$CFLAGS"
2244         OLD_LIBS="$LIBS"
2245         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
2246         CFLAGS="$CFLAGS $XFT_CFLAGS"
2247         XFT_LIBS="-lXrender $XFT_LIBS"
2248         LIBS="$XFT_LIBS $LIBS"
2249         AC_CHECK_HEADER(X11/Xft/Xft.h,
2250           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS))
2251
2252         if test "${HAVE_XFT}" = "yes"; then
2253           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
2254             AC_SUBST(XFT_LIBS)
2255           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
2256         else
2257           CPPFLAGS="$OLD_CPPFLAGS"
2258           CFLAGS="$OLD_CFLAGS"
2259           LIBS="$OLD_LIBS"
2260         fi                        # "${HAVE_XFT}" = "yes"
2261       fi                          # "$HAVE_XFT" != no
2262     fi                            # "x${with_xft}" != "xno"
2263
2264     dnl For the "Does Emacs use" message at the end.
2265     if test "$HAVE_XFT" != "yes"; then
2266        HAVE_XFT=no
2267     fi
2268
2269
2270     HAVE_FREETYPE=no
2271     ## We used to allow building with FreeType and without Xft.
2272     ## However, the ftx font backend driver is not in good shape.
2273     if test "${HAVE_XFT}" = "yes"; then
2274       dnl As we use Xft, we anyway use freetype.
2275       dnl There's no need for additional CFLAGS and LIBS.
2276       HAVE_FREETYPE=yes
2277       FONTCONFIG_CFLAGS=
2278       FONTCONFIG_LIBS=
2279     fi
2280
2281     HAVE_LIBOTF=no
2282     if test "${HAVE_FREETYPE}" = "yes"; then
2283       AC_DEFINE(HAVE_FREETYPE, 1,
2284                 [Define to 1 if using the freetype and fontconfig libraries.])
2285       if test "${with_libotf}" != "no"; then
2286         PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
2287                           HAVE_LIBOTF=no)
2288         if test "$HAVE_LIBOTF" = "yes"; then
2289           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
2290           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
2291                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
2292                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
2293           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
2294             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
2295                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
2296           fi
2297         fi
2298       fi
2299     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
2300     dnl Does the new font backend require it, or can it work without it?
2301     fi
2302
2303     HAVE_M17N_FLT=no
2304     if test "${HAVE_LIBOTF}" = yes; then
2305       if test "${with_m17n_flt}" != "no"; then
2306         PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
2307         if test "$HAVE_M17N_FLT" = "yes"; then
2308           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
2309         fi
2310       fi
2311     fi
2312 else
2313     HAVE_XFT=no
2314     HAVE_FREETYPE=no
2315     HAVE_LIBOTF=no
2316     HAVE_M17N_FLT=no
2317 fi
2318
2319 ### End of font-backend (under X11) section.
2320
2321 AC_SUBST(FREETYPE_CFLAGS)
2322 AC_SUBST(FREETYPE_LIBS)
2323 AC_SUBST(FONTCONFIG_CFLAGS)
2324 AC_SUBST(FONTCONFIG_LIBS)
2325 AC_SUBST(LIBOTF_CFLAGS)
2326 AC_SUBST(LIBOTF_LIBS)
2327 AC_SUBST(M17N_FLT_CFLAGS)
2328 AC_SUBST(M17N_FLT_LIBS)
2329
2330 ### Use -lXpm if available, unless `--with-xpm=no'.
2331 HAVE_XPM=no
2332 LIBXPM=
2333 if test "${HAVE_X11}" = "yes"; then
2334   if test "${with_xpm}" != "no"; then
2335     AC_CHECK_HEADER(X11/xpm.h,
2336       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2337     if test "${HAVE_XPM}" = "yes"; then
2338       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2339       AC_EGREP_CPP(no_return_alloc_pixels,
2340       [#include "X11/xpm.h"
2341 #ifndef XpmReturnAllocPixels
2342 no_return_alloc_pixels
2343 #endif
2344       ], HAVE_XPM=no, HAVE_XPM=yes)
2345
2346       if test "${HAVE_XPM}" = "yes"; then
2347         AC_MSG_RESULT(yes)
2348       else
2349         AC_MSG_RESULT(no)
2350       fi
2351     fi
2352   fi
2353
2354   if test "${HAVE_XPM}" = "yes"; then
2355     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm libary (-lXpm).])
2356     LIBXPM=-lXpm
2357   fi
2358 fi
2359 AC_SUBST(LIBXPM)
2360
2361 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2362 HAVE_JPEG=no
2363 LIBJPEG=
2364 if test "${HAVE_X11}" = "yes"; then
2365   if test "${with_jpeg}" != "no"; then
2366     dnl Checking for jpeglib.h can lose because of a redefinition of
2367     dnl  HAVE_STDLIB_H.
2368     AC_CHECK_HEADER(jerror.h,
2369       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
2370   fi
2371
2372   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2373   if test "${HAVE_JPEG}" = "yes"; then
2374     AC_DEFINE(HAVE_JPEG)
2375     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2376         [#include <jpeglib.h>
2377          version=JPEG_LIB_VERSION
2378 ],
2379         [AC_DEFINE(HAVE_JPEG)],
2380         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2381         HAVE_JPEG=no])
2382   fi
2383   if test "${HAVE_JPEG}" = "yes"; then
2384     LIBJPEG=-ljpeg
2385   fi
2386 fi
2387 AC_SUBST(LIBJPEG)
2388
2389 ### Use -lpng if available, unless `--with-png=no'.
2390 HAVE_PNG=no
2391 LIBPNG=
2392 if test "${HAVE_X11}" = "yes"; then
2393   if test "${with_png}" != "no"; then
2394     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
2395     # in /usr/include/libpng.
2396     AC_CHECK_HEADERS(png.h libpng/png.h)
2397     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2398       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2399     fi
2400   fi
2401
2402   if test "${HAVE_PNG}" = "yes"; then
2403     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2404     LIBPNG="-lpng -lz -lm"
2405   fi
2406 fi
2407 AC_SUBST(LIBPNG)
2408
2409 ### Use -ltiff if available, unless `--with-tiff=no'.
2410 HAVE_TIFF=no
2411 LIBTIFF=
2412 if test "${HAVE_X11}" = "yes"; then
2413   if test "${with_tiff}" != "no"; then
2414     AC_CHECK_HEADER(tiffio.h,
2415       [tifflibs="-lz -lm"
2416       # At least one tiff package requires the jpeg library.
2417       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2418       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
2419   fi
2420
2421   if test "${HAVE_TIFF}" = "yes"; then
2422     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2423     dnl FIXME -lz -lm, as per libpng?
2424     LIBTIFF=-ltiff
2425   fi
2426 fi
2427 AC_SUBST(LIBTIFF)
2428
2429 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2430 HAVE_GIF=no
2431 LIBGIF=
2432 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no"; then
2433   AC_CHECK_HEADER(gif_lib.h,
2434 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2435 # Earlier versions can crash Emacs.
2436     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])
2437
2438   if test "$HAVE_GIF" = yes; then
2439     LIBGIF=-lgif
2440   elif test "$HAVE_GIF" = maybe; then
2441 # If gif_lib.h but no libgif, try libungif.
2442     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
2443     test "$HAVE_GIF" = yes && LIBGIF=-lungif
2444   fi
2445
2446   if test "${HAVE_GIF}" = "yes"; then
2447     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
2448   fi
2449 fi
2450 AC_SUBST(LIBGIF)
2451
2452 dnl Check for required libraries.
2453 if test "${HAVE_X11}" = "yes"; then
2454   MISSING=""
2455   WITH_NO=""
2456   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2457     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2458   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2459     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2460   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2461     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2462   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2463     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2464   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2465     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2466
2467   if test "X${MISSING}" != X; then
2468     AC_MSG_ERROR([The following required libraries were not found:
2469     $MISSING
2470 Maybe some development libraries/packages are missing?
2471 If you don't want to link with them give
2472     $WITH_NO
2473 as options to configure])
2474   fi
2475 fi
2476
2477 ### Use -lgpm if available, unless `--with-gpm=no'.
2478 HAVE_GPM=no
2479 LIBGPM=
2480 MOUSE_SUPPORT=
2481 if test "${with_gpm}" != "no"; then
2482   AC_CHECK_HEADER(gpm.h,
2483     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2484
2485   if test "${HAVE_GPM}" = "yes"; then
2486     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2487     LIBGPM=-lgpm
2488     ## May be reset below.
2489     MOUSE_SUPPORT="\$(GPM_MOUSE_SUPPORT)"
2490   fi
2491 fi
2492 AC_SUBST(LIBGPM)
2493
2494 dnl Check for malloc/malloc.h on darwin
2495 AC_CHECK_HEADER(malloc/malloc.h, [AC_DEFINE(HAVE_MALLOC_MALLOC_H, 1, [Define to 1 if you have the <malloc/malloc.h> header file.])])
2496
2497 C_SWITCH_X_SYSTEM=
2498 ### Use NeXTstep API to implement GUI.
2499 if test "${HAVE_NS}" = "yes"; then
2500   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
2501   if test "${NS_IMPL_COCOA}" = "yes"; then
2502     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
2503     GNU_OBJC_CFLAGS=
2504   fi
2505   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
2506     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
2507     # See also .m.o rule in Makefile.in */
2508     # FIXME: are all these flags really needed?  Document here why.  */
2509     C_SWITCH_X_SYSTEM="-D_REENTRANT -fPIC -fno-strict-aliasing"
2510     GNU_OBJC_CFLAGS="-fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
2511   fi
2512   if test "${NS_HAVE_NSINTEGER}" = "yes"; then
2513     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
2514   fi
2515   # We also have mouse menus.
2516   HAVE_MENUS=yes
2517   OTHER_FILES=ns-app
2518 fi
2519
2520
2521 ### Use session management (-lSM -lICE) if available
2522 HAVE_X_SM=no
2523 LIBXSM=
2524 if test "${HAVE_X11}" = "yes"; then
2525   AC_CHECK_HEADER(X11/SM/SMlib.h,
2526     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2527
2528   if test "${HAVE_X_SM}" = "yes"; then
2529     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2530     LIBXSM="-lSM -lICE"
2531     case "$LIBS" in
2532       *-lSM*) ;;
2533       *)      LIBS="$LIBXSM $LIBS" ;;
2534     esac
2535   fi
2536 fi
2537 AC_SUBST(LIBXSM)
2538
2539 ### Use libxml (-lxml2) if available
2540 if test "${with_xml2}" != "no"; then
2541   ### I'm not sure what the version number should be, so I just guessed.
2542   PKG_CHECK_MODULES(LIBXML2, libxml-2.0 > 2.2.0, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
2543   if test "${HAVE_LIBXML2}" = "yes"; then
2544     AC_CHECK_LIB(xml2, htmlReadMemory, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
2545     if test "${HAVE_LIBXML2}" = "yes"; then
2546       AC_DEFINE(HAVE_LIBXML2, 1, [Define to 1 if you have the libxml library (-lxml2).])
2547     else
2548       LIBXML2_LIBS=""
2549       LIBXML2_CFLAGS=""
2550     fi
2551   fi
2552 fi
2553 AC_SUBST(LIBXML2_LIBS)
2554 AC_SUBST(LIBXML2_CFLAGS)
2555
2556 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2557 AC_CACHE_CHECK(whether netdb declares h_errno,
2558                emacs_cv_netdb_declares_h_errno,
2559 [AC_TRY_LINK([#include <netdb.h>],
2560   [return h_errno;],
2561   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2562 if test $emacs_cv_netdb_declares_h_errno = yes; then
2563   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2564 fi
2565
2566 AC_FUNC_ALLOCA
2567
2568 dnl src/alloca.c has been removed.  Could also check if $ALLOCA is set?
2569 dnl FIXME is there an autoconf test that does the right thing, without
2570 dnl needing to call A_M_E afterwards?
2571 if test x"$ac_cv_func_alloca_works" != xyes; then
2572    AC_MSG_ERROR( [a system implementation of alloca is required] )
2573 fi
2574
2575 # fmod, logb, and frexp are found in -lm on most systems.
2576 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2577 AC_CHECK_LIB(m, sqrt)
2578
2579 # Check for mail-locking functions in a "mail" library.  Probably this should
2580 # have the same check as for liblockfile below.
2581 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
2582 if test $have_mail = yes; then
2583   LIBS_MAIL=-lmail
2584   LIBS="$LIBS_MAIL $LIBS"
2585   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the `mail' library (-lmail).])
2586 else
2587   LIBS_MAIL=
2588 fi
2589 dnl Debian, at least:
2590 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
2591 if test $have_lockfile = yes; then
2592    LIBS_MAIL=-llockfile
2593    LIBS="$LIBS_MAIL $LIBS"
2594    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the `lockfile' library (-llockfile).])
2595 else
2596 # If we have the shared liblockfile, assume we must use it for mail
2597 # locking (e.g. Debian).  If we couldn't link against liblockfile
2598 # (no liblockfile.a installed), ensure that we don't need to.
2599   dnl This works for files generally, not just executables.
2600   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2601   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2602                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2603   if test $ac_cv_prog_liblockfile = yes; then
2604     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2605 This probably means that movemail could lose mail.
2606 There may be a `development' package to install containing liblockfile.])
2607   fi
2608 fi
2609 AC_CHECK_FUNCS(touchlock)
2610 AC_CHECK_HEADERS(maillock.h)
2611 AC_SUBST(LIBS_MAIL)
2612
2613 ## Define MAIL_USE_FLOCK (or LOCKF) if the mailer uses flock (or lockf) to
2614 ## interlock access to the mail spool.  The alternative is a lock file named
2615 ## /usr/spool/mail/$USER.lock.
2616 mail_lock=no
2617 case "$opsys" in
2618   aix4-2) mail_lock="lockf" ;;
2619
2620   gnu|freebsd|netbsd|openbsd|darwin|irix6-5) mail_lock="flock" ;;
2621
2622   ## On GNU/Linux systems, both methods are used by various mail programs.
2623   ## I assume most people are using newer mailers that have heard of flock.
2624   ## Change this if you need to.
2625   ## Debian contains a patch which says: ``On Debian/GNU/Linux systems,
2626   ## configure gets the right answers, and that means *NOT* using flock.
2627   ## Using flock is guaranteed to be the wrong thing. See Debian Policy
2628   ## for details.'' and then uses `#ifdef DEBIAN'.  Unfortunately the
2629   ## Debian maintainer hasn't provided a clean fix for Emacs.
2630   ## movemail.c will use `maillock' when MAILDIR, HAVE_LIBMAIL and
2631   ## HAVE_MAILLOCK_H are defined, so the following appears to be the
2632   ## correct logic.  -- fx
2633   ## We must check for HAVE_LIBLOCKFILE too, as movemail does.
2634   ## liblockfile is a Free Software replacement for libmail, used on
2635   ## Debian systems and elsewhere. -rfr.
2636   gnu-*)
2637     mail_lock="flock"
2638     if test $have_mail = yes || test $have_lockfile = yes; then
2639       test $ac_cv_header_maillock_h = yes && mail_lock=no
2640     fi
2641     ;;
2642 esac
2643
2644 BLESSMAIL_TARGET=
2645 case "$mail_lock" in
2646   flock) AC_DEFINE(MAIL_USE_FLOCK, 1, [Define if the mailer uses flock to interlock the mail spool.]) ;;
2647
2648   lockf) AC_DEFINE(MAIL_USE_LOCKF, 1, [Define if the mailer uses lockf to interlock the mail spool.]) ;;
2649
2650   *) BLESSMAIL_TARGET="need-blessmail" ;;
2651 esac
2652 AC_SUBST(BLESSMAIL_TARGET)
2653
2654
2655 AC_CHECK_FUNCS(gethostname getdomainname dup2 \
2656 rename closedir mkdir rmdir sysinfo getrusage get_current_dir_name \
2657 random lrand48 logb frexp fmod rint cbrt ftime setsid \
2658 strerror fpathconf select mktime euidaccess getpagesize tzset setlocale \
2659 utimes getrlimit setrlimit setpgid getcwd getwd shutdown getaddrinfo \
2660 __fpending mblen mbrlen mbsinit strsignal setitimer ualarm strchr strrchr \
2661 sendto recvfrom getsockopt setsockopt getsockname getpeername \
2662 gai_strerror mkstemp getline getdelim mremap memmove fsync sync \
2663 memset memcmp difftime memcpy mempcpy mblen mbrlen posix_memalign \
2664 cfmakeraw cfsetspeed isnan copysign __executable_start)
2665
2666 AC_CHECK_HEADERS(sys/un.h)
2667
2668 AC_FUNC_MKTIME
2669 if test "$ac_cv_func_working_mktime" = no; then
2670   AC_DEFINE(BROKEN_MKTIME, 1, [Define to 1 if the mktime function is broken.])
2671 fi
2672
2673 AC_FUNC_GETLOADAVG
2674
2675 AC_FUNC_FSEEKO
2676
2677 # Configure getopt.
2678 m4_include([m4/getopt.m4])
2679 gl_GETOPT_IFELSE([
2680   gl_GETOPT_SUBSTITUTE_HEADER
2681   gl_PREREQ_GETOPT
2682   GETOPTOBJS='getopt.o getopt1.o'
2683 ])
2684 AC_SUBST(GETOPTOBJS)
2685
2686 AC_FUNC_GETPGRP
2687
2688 AC_FUNC_STRFTIME
2689
2690 # UNIX98 PTYs.
2691 AC_CHECK_FUNCS(grantpt)
2692
2693 # PTY-related GNU extensions.
2694 AC_CHECK_FUNCS(getpt)
2695
2696 # Check this now, so that we will NOT find the above functions in ncurses.
2697 # That is because we have not set up to link ncurses in lib-src.
2698 # It's better to believe a function is not available
2699 # than to expect to find it in ncurses.
2700 # Also we need tputs and friends to be able to build at all.
2701 have_tputs_et_al=true
2702 AC_SEARCH_LIBS(tputs, [ncurses terminfo termcap], , have_tputs_et_al=false)
2703 if test "$have_tputs_et_al" != true; then
2704   AC_MSG_ERROR([I couldn't find termcap functions (tputs and friends).
2705 Maybe some development libraries/packages are missing?  Try installing
2706 libncurses-dev(el), libterminfo-dev(el) or similar.])
2707 fi
2708 # Must define this when any termcap library is found.
2709 AC_DEFINE(HAVE_LIBNCURSES, 1,
2710           [Define to 1 if you have the `ncurses' library (-lncurses).])
2711 ## FIXME This was the cpp logic, but I am not sure it is right.
2712 ## The above test has not necessarily found libncurses.
2713 HAVE_LIBNCURSES=yes
2714
2715 ## Use terminfo instead of termcap?
2716 ## Note only system files NOT using terminfo are:
2717 ## freebsd < 40000, ms-w32, msdos, netbsd < 599002500, and
2718 ## darwin|gnu without ncurses.
2719 TERMINFO=no
2720 LIBS_TERMCAP=
2721 case "$opsys" in
2722   ## cygwin: Fewer environment variables to go wrong, more terminal types.
2723   ## hpux10-20: Use the system provided termcap(3) library.
2724   ## openbsd: David Mazieres <dm@reeducation-labor.lcs.mit.edu> says this
2725   ##  is necessary.  Otherwise Emacs dumps core when run -nw.
2726   aix4-2|cygwin|hpux*|irix6-5|openbsd|sol2*|unixware) TERMINFO=yes ;;
2727
2728   ## darwin: Prevents crashes when running Emacs in Terminal.app under 10.2.
2729   ##  The ncurses library has been moved out of the System framework in
2730   ##  Mac OS X 10.2.  So if configure detects it, set the command-line
2731   ##  option to use it.
2732   darwin|gnu*)
2733     ## (HAVE_LIBNCURSES was not always true, but is since 2010-03-18.)
2734     if test "x$HAVE_LIBNCURSES" = "xyes"; then
2735       TERMINFO=yes
2736       LIBS_TERMCAP="-lncurses"
2737     fi
2738     ;;
2739
2740   freebsd)
2741     AC_MSG_CHECKING([whether FreeBSD is new enough to use terminfo])
2742     AC_CACHE_VAL(emacs_cv_freebsd_terminfo,
2743     [AC_TRY_LINK([#include <osreldate.h>],
2744 [#if __FreeBSD_version < 400000
2745 fail;
2746 #endif
2747 ], emacs_cv_freebsd_terminfo=yes, emacs_cv_freebsd_terminfo=no)])
2748
2749     AC_MSG_RESULT($emacs_cv_freebsd_terminfo)
2750
2751     if test $emacs_cv_freebsd_terminfo = yes; then
2752       TERMINFO=yes
2753       LIBS_TERMCAP="-lncurses"
2754     else
2755       LIBS_TERMCAP="-ltermcap"
2756     fi
2757     ;;
2758
2759   netbsd)
2760     if test $ac_cv_search_tputs = -lterminfo; then
2761       TERMINFO=yes
2762       LIBS_TERMCAP="-lterminfo"
2763     else
2764       LIBS_TERMCAP="-ltermcap"
2765     fi
2766     ;;
2767
2768 esac
2769
2770 case "$opsys" in
2771   ## hpux: Make sure we get select from libc rather than from libcurses
2772   ##  because libcurses on HPUX 10.10 has a broken version of select.
2773   ##  We used to use -lc -lcurses, but this may be cleaner.
2774   hpux*) LIBS_TERMCAP="-ltermcap" ;;
2775
2776   openbsd) LIBS_TERMCAP="-lncurses" ;;
2777
2778   ## Must use system termcap, if we use any termcap.  It does special things.
2779   sol2*) test "$TERMINFO" != yes && LIBS_TERMCAP="-ltermcap" ;;
2780 esac
2781
2782 TERMCAP_OBJ=tparam.o
2783 if test $TERMINFO = yes; then
2784   AC_DEFINE(TERMINFO, 1, [Define to 1 if you use terminfo instead of termcap.])
2785
2786   ## Default used to be -ltermcap.  Add a case above if need something else.
2787   test "x$LIBS_TERMCAP" = "x" && LIBS_TERMCAP="-lcurses"
2788
2789   TERMCAP_OBJ=terminfo.o
2790 fi
2791 AC_SUBST(LIBS_TERMCAP)
2792 AC_SUBST(TERMCAP_OBJ)
2793
2794
2795 # Do we have res_init, for detecting changes in /etc/resolv.conf?
2796 resolv=no
2797 AC_TRY_LINK([#include <netinet/in.h>
2798 #include <arpa/nameser.h>
2799 #include <resolv.h>],
2800     [return res_init();],
2801     have_res_init=yes, have_res_init=no)
2802 if test "$have_res_init" = no; then
2803   OLIBS="$LIBS"
2804   LIBS="$LIBS -lresolv"
2805   AC_MSG_CHECKING(for res_init with -lresolv)
2806   AC_TRY_LINK([#include <netinet/in.h>
2807 #include <arpa/nameser.h>
2808 #include <resolv.h>],
2809     [return res_init();],
2810     have_res_init=yes, have_res_init=no)
2811   AC_MSG_RESULT($have_res_init)
2812   if test "$have_res_init" = yes ; then
2813     resolv=yes
2814   fi
2815   LIBS="$OLIBS"
2816 fi
2817
2818 if test "$have_res_init" = yes; then
2819   AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
2820 fi
2821
2822 # Do we need the Hesiod library to provide the support routines?
2823 LIBHESIOD=
2824 if test "$with_hesiod" != no ; then
2825   # Don't set $LIBS here -- see comments above.  FIXME which comments?
2826   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2827      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2828                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2829   if test "$resolv" = yes ; then
2830     RESOLVLIB=-lresolv
2831   else
2832     RESOLVLIB=
2833   fi
2834   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2835         hesiod=yes, :, $RESOLVLIB)])
2836
2837   if test x"$hesiod" = xyes; then
2838     AC_DEFINE(HAVE_LIBHESIOD, 1,
2839               [Define to 1 if you have the hesiod library (-lhesiod).])
2840     LIBHESIOD=-lhesiod
2841   fi
2842 fi
2843 AC_SUBST(LIBHESIOD)
2844
2845 # Do we need libresolv (due to res_init or Hesiod)?
2846 if test "$resolv" = yes ; then
2847   AC_DEFINE(HAVE_LIBRESOLV, 1,
2848             [Define to 1 if you have the resolv library (-lresolv).])
2849   LIBRESOLV=-lresolv
2850 else
2851   LIBRESOLV=
2852 fi
2853 AC_SUBST(LIBRESOLV)
2854
2855 # These tell us which Kerberos-related libraries to use.
2856 COM_ERRLIB=
2857 CRYPTOLIB=
2858 KRB5LIB=
2859 DESLIB=
2860 KRB4LIB=
2861
2862 if test "${with_kerberos}" != no; then
2863   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
2864   if test $have_com_err = yes; then
2865     COM_ERRLIB=-lcom_err
2866     LIBS="$COM_ERRLIB $LIBS"
2867     AC_DEFINE(HAVE_LIBCOM_ERR, 1, [Define to 1 if you have the `com_err' library (-lcom_err).])
2868   fi
2869   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
2870   if test $have_crypto = yes; then
2871     CRYPTOLIB=-lcrypto
2872     LIBS="$CRYPTOLIB $LIBS"
2873     AC_DEFINE(HAVE_LIBCRYPTO, 1, [Define to 1 if you have the `crypto' library (-lcrypto).])
2874   fi
2875   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
2876   if test $have_k5crypto = yes; then
2877     CRYPTOLIB=-lk5crypto
2878     LIBS="$CRYPTOLIB $LIBS"
2879     AC_DEFINE(HAVE_LIBK5CRYPTO, 1, [Define to 1 if you have the `k5crypto' library (-lk5crypto).])
2880   fi
2881   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
2882   if test $have_krb5=yes; then
2883     KRB5LIB=-lkrb5
2884     LIBS="$KRB5LIB $LIBS"
2885     AC_DEFINE(HAVE_LIBKRB5, 1, [Define to 1 if you have the `krb5' library (-lkrb5).])
2886   fi
2887   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
2888   if test "${with_kerberos5}" = no; then
2889     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
2890     if test $have_des425 = yes; then
2891       DESLIB=-ldes425
2892       LIBS="$DESLIB $LIBS"
2893       AC_DEFINE(HAVE_LIBDES425, 1, [Define to 1 if you have the `des425' library (-ldes425).])
2894     else
2895       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
2896       if test $have_des = yes; then
2897         DESLIB=-ldes
2898         LIBS="$DESLIB $LIBS"
2899         AC_DEFINE(HAVE_LIBDES, 1, [Define to 1 if you have the `des' library (-ldes).])
2900       fi
2901     fi
2902     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
2903     if test $have_krb4 = yes; then
2904       KRB4LIB=-lkrb4
2905       LIBS="$KRB4LIB $LIBS"
2906       AC_DEFINE(HAVE_LIBKRB4, 1, [Define to 1 if you have the `krb4' library (-lkrb4).])
2907     else
2908       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
2909       if test $have_krb = yes; then
2910         KRB4LIB=-lkrb
2911         LIBS="$KRB4LIB $LIBS"
2912         AC_DEFINE(HAVE_LIBKRB, 1, [Define to 1 if you have the `krb' library (-lkrb).])
2913       fi
2914     fi
2915   fi
2916
2917   if test "${with_kerberos5}" != no; then
2918     AC_CHECK_HEADERS(krb5.h,
2919       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
2920                         [#include <krb5.h>])])
2921   else
2922     AC_CHECK_HEADERS(des.h,,
2923                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
2924                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
2925     AC_CHECK_HEADERS(krb.h,,
2926                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
2927                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
2928   fi
2929   AC_CHECK_HEADERS(com_err.h)
2930 fi
2931
2932 AC_SUBST(COM_ERRLIB)
2933 AC_SUBST(CRYPTOLIB)
2934 AC_SUBST(KRB5LIB)
2935 AC_SUBST(DESLIB)
2936 AC_SUBST(KRB4LIB)
2937
2938 # Solaris requires -lintl if you want strerror (which calls dgettext)
2939 # to return localized messages.
2940 AC_CHECK_LIB(intl, dgettext)
2941
2942 AC_MSG_CHECKING(whether localtime caches TZ)
2943 AC_CACHE_VAL(emacs_cv_localtime_cache,
2944 [if test x$ac_cv_func_tzset = xyes; then
2945 AC_TRY_RUN([#include <time.h>
2946 extern char **environ;
2947 unset_TZ ()
2948 {
2949   char **from, **to;
2950   for (to = from = environ; (*to = *from); from++)
2951     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
2952       to++;
2953 }
2954 char TZ_GMT0[] = "TZ=GMT0";
2955 char TZ_PST8[] = "TZ=PST8";
2956 main()
2957 {
2958   time_t now = time ((time_t *) 0);
2959   int hour_GMT0, hour_unset;
2960   if (putenv (TZ_GMT0) != 0)
2961     exit (1);
2962   hour_GMT0 = localtime (&now)->tm_hour;
2963   unset_TZ ();
2964   hour_unset = localtime (&now)->tm_hour;
2965   if (putenv (TZ_PST8) != 0)
2966     exit (1);
2967   if (localtime (&now)->tm_hour == hour_GMT0)
2968     exit (1);
2969   unset_TZ ();
2970   if (localtime (&now)->tm_hour != hour_unset)
2971     exit (1);
2972   exit (0);
2973 }], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
2974 [# If we have tzset, assume the worst when cross-compiling.
2975 emacs_cv_localtime_cache=yes])
2976 else
2977         # If we lack tzset, report that localtime does not cache TZ,
2978         # since we can't invalidate the cache if we don't have tzset.
2979         emacs_cv_localtime_cache=no
2980 fi])dnl
2981 AC_MSG_RESULT($emacs_cv_localtime_cache)
2982 if test $emacs_cv_localtime_cache = yes; then
2983   AC_DEFINE(LOCALTIME_CACHE, 1,
2984             [Define to 1 if localtime caches TZ.])
2985 fi
2986
2987 if test "x$HAVE_TIMEVAL" = xyes; then
2988   AC_CHECK_FUNCS(gettimeofday)
2989   if test $ac_cv_func_gettimeofday = yes; then
2990     AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
2991                    emacs_cv_gettimeofday_two_arguments,
2992     [AC_TRY_COMPILE([
2993 #ifdef TIME_WITH_SYS_TIME
2994 #include <sys/time.h>
2995 #include <time.h>
2996 #else
2997 #ifdef HAVE_SYS_TIME_H
2998 #include <sys/time.h>
2999 #else
3000 #include <time.h>
3001 #endif
3002 #endif],
3003       [struct timeval time;
3004        gettimeofday (&time, 0);],
3005       emacs_cv_gettimeofday_two_arguments=yes,
3006       emacs_cv_gettimeofday_two_arguments=no)])
3007     if test $emacs_cv_gettimeofday_two_arguments = no; then
3008       AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT, 1,
3009                 [Define to 1 if gettimeofday accepts only one argument.])
3010     fi
3011   fi
3012 fi
3013
3014 ok_so_far=yes
3015 AC_CHECK_FUNC(socket, , ok_so_far=no)
3016 if test $ok_so_far = yes; then
3017   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
3018 fi
3019 if test $ok_so_far = yes; then
3020   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
3021 fi
3022 if test $ok_so_far = yes; then
3023 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
3024   AC_DEFINE(HAVE_INET_SOCKETS, 1,
3025             [Define to 1 if you have inet sockets.])
3026 fi
3027
3028 AC_CHECK_HEADERS(sys/ioctl.h)
3029
3030 if test -f /usr/lpp/X11/bin/smt.exp; then
3031   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
3032             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
3033 fi
3034
3035 AC_MSG_CHECKING(whether system supports dynamic ptys)
3036 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
3037   AC_MSG_RESULT(yes)
3038   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
3039 else
3040   AC_MSG_RESULT(no)
3041 fi
3042
3043 AC_FUNC_FORK
3044
3045 dnl Adapted from Haible's version.
3046 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
3047   [AC_TRY_LINK([#include <langinfo.h>],
3048     [char* cs = nl_langinfo(CODESET);],
3049     emacs_cv_langinfo_codeset=yes,
3050     emacs_cv_langinfo_codeset=no)
3051   ])
3052 if test $emacs_cv_langinfo_codeset = yes; then
3053   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
3054     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
3055 fi
3056
3057 AC_CHECK_TYPES(size_t)
3058
3059 AC_TYPE_MBSTATE_T
3060
3061 dnl Restrict could probably be used effectively other than in regex.c.
3062 AC_CACHE_CHECK([for C restrict keyword], emacs_cv_c_restrict,
3063   [AC_TRY_COMPILE([void fred (int *restrict x);], [],
3064                   emacs_cv_c_restrict=yes,
3065                   [AC_TRY_COMPILE([void fred (int *__restrict x);], [],
3066                                   emacs_cv_c_restrict=__restrict,
3067                                   emacs_cv_c_restrict=no)])])
3068 case "$emacs_cv_c_restrict" in
3069   yes) emacs_restrict=restrict;;
3070   no) emacs_restrict="";;
3071   *) emacs_restrict="$emacs_cv_c_restrict";;
3072 esac
3073 if test "$emacs_restrict" != __restrict; then
3074   AC_DEFINE_UNQUOTED(__restrict, $emacs_restrict,
3075     [Define to compiler's equivalent of C99 restrict keyword.
3076      Don't define if equivalent is `__restrict'.])
3077 fi
3078
3079 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
3080   [AC_TRY_COMPILE([void fred (int x[__restrict]);], [],
3081                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
3082 if test "$emacs_cv_c_restrict_arr" = yes; then
3083   AC_DEFINE(__restrict_arr, __restrict,
3084     [Define to compiler's equivalent of C99 restrict keyword in array
3085      declarations.  Define as empty for no equivalent.])
3086 fi
3087
3088 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
3089 dnl how the tty code is related to POSIX and/or other versions of termios.
3090 dnl The following looks like a useful start.
3091 dnl
3092 dnl AC_SYS_POSIX_TERMIOS
3093 dnl if test $ac_cv_sys_posix_termios = yes; then
3094 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
3095 dnl                                and macros for terminal control.])
3096 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
3097 dnl fi
3098
3099 dnl Fixme: Use AC_FUNC_MEMCMP since memcmp is used.  (Needs libobj replacement.)
3100
3101 # Set up the CFLAGS for real compilation, so we can substitute it.
3102 CFLAGS="$REAL_CFLAGS"
3103 CPPFLAGS="$REAL_CPPFLAGS"
3104
3105 ## Hack to detect a buggy GCC version.
3106 if test "x$GCC" = xyes \
3107    && test x"`$CC --version 2> /dev/null | grep 'gcc.* 4.5.0'`" != x \
3108    && test x"`echo $CFLAGS | grep '\-O@<:@23@:>@'`" != x \
3109    && test x"`echo $CFLAGS | grep '\-fno-optimize-sibling-calls'`" = x; then
3110    AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS'.])
3111 fi
3112
3113 #### Find out which version of Emacs this is.
3114 [version=`grep 'const char emacs_version' ${srcdir}/src/emacs.c \
3115          | sed -e 's/^[^"]*"\([^"]*\)".*$/\1/'`]
3116 if test x"${version}" = x; then
3117   AC_MSG_ERROR([can't find current emacs version in `${srcdir}/src/emacs.c'.])
3118 fi
3119 if test x"${version}" != x"$PACKAGE_VERSION"; then
3120   AC_MSG_WARN([version mismatch between `${srcdir}/configure.in' and `${srcdir}/src/emacs.c'.])
3121 fi
3122
3123 ### Specify what sort of things we'll be editing into Makefile and config.h.
3124 ### Use configuration here uncanonicalized to avoid exceeding size limits.
3125 AC_SUBST(version)
3126 AC_SUBST(configuration)
3127 ## Unused?
3128 AC_SUBST(canonical)
3129 AC_SUBST(srcdir)
3130 AC_SUBST(prefix)
3131 AC_SUBST(exec_prefix)
3132 AC_SUBST(bindir)
3133 AC_SUBST(datadir)
3134 AC_SUBST(sharedstatedir)
3135 AC_SUBST(libexecdir)
3136 AC_SUBST(mandir)
3137 AC_SUBST(infodir)
3138 AC_SUBST(lispdir)
3139 AC_SUBST(locallisppath)
3140 AC_SUBST(lisppath)
3141 AC_SUBST(x_default_search_path)
3142 AC_SUBST(etcdir)
3143 AC_SUBST(archlibdir)
3144 AC_SUBST(docdir)
3145 AC_SUBST(bitmapdir)
3146 AC_SUBST(gamedir)
3147 AC_SUBST(gameuser)
3148 ## FIXME? Nothing uses @LD_SWITCH_X_SITE@.
3149 ## src/Makefile.in did add LD_SWITCH_X_SITE (as a cpp define) to the
3150 ## end of LIBX_BASE, but nothing ever set it.
3151 AC_SUBST(LD_SWITCH_X_SITE)
3152 AC_SUBST(C_SWITCH_X_SITE)
3153 AC_SUBST(C_SWITCH_X_SYSTEM)
3154 AC_SUBST(CFLAGS)
3155 ## Used in lwlib/Makefile.in.
3156 AC_SUBST(X_TOOLKIT_TYPE)
3157 AC_SUBST(machfile)
3158 AC_SUBST(opsysfile)
3159 AC_SUBST(GETLOADAVG_LIBS)
3160 AC_SUBST(ns_appdir)
3161 AC_SUBST(ns_appbindir)
3162 AC_SUBST(ns_appresdir)
3163 AC_SUBST(ns_appsrc)
3164 AC_SUBST(GNU_OBJC_CFLAGS)
3165 AC_SUBST(OTHER_FILES)
3166
3167 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
3168                    [Define to the canonical Emacs configuration name.])
3169 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
3170                    [Define to the options passed to configure.])
3171 AC_DEFINE_UNQUOTED(config_machfile,  "${machfile}",
3172                    [Define to the used machine dependent file.])
3173 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
3174                    [Define to the used os dependent file.])
3175
3176 XMENU_OBJ=
3177 XOBJ=
3178 FONT_OBJ=
3179 if test "${HAVE_X_WINDOWS}" = "yes" ; then
3180   AC_DEFINE(HAVE_X_WINDOWS, 1,
3181             [Define to 1 if you want to use the X window system.])
3182   XMENU_OBJ=xmenu.o
3183   XOBJ="xterm.o xfns.o xselect.o xrdb.o fontset.o xsmfns.o fringe.o image.o xsettings.o xgselect.o"
3184   FONT_OBJ=xfont.o
3185   if test "$HAVE_XFT" = "yes"; then
3186     FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o"
3187   elif test "$HAVE_FREETYPE" = "yes"; then
3188     FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o"
3189   fi
3190   AC_SUBST(FONT_OBJ)
3191 fi
3192 AC_SUBST(XMENU_OBJ)
3193 AC_SUBST(XOBJ)
3194 AC_SUBST(FONT_OBJ)
3195
3196 WIDGET_OBJ=
3197 MOTIF_LIBW=
3198 if test "${USE_X_TOOLKIT}" != "none" ; then
3199   WIDGET_OBJ=widget.o
3200   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
3201   if test "${USE_X_TOOLKIT}" = "LUCID"; then
3202     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
3203   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
3204     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
3205     MOTIF_LIBW=-lXm
3206     case "$opsys" in
3207       gnu-linux)
3208         ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed.
3209         MOTIF_LIBW="$MOTIF_LIBW -lXpm"
3210         ;;
3211
3212       unixware)
3213         ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov>
3214         ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2.
3215         MOTIF_LIBW="MOTIF_LIBW -lXimp"
3216         ;;
3217
3218       aix4-2)
3219         ## olson@mcs.anl.gov says -li18n is needed by -lXm.
3220         MOTIF_LIBW="$MOTIF_LIBW -li18n"
3221         ;;
3222     esac
3223     MOTIF_LIBW="$MOTIF_LIBW $LIBXP"
3224   fi
3225 fi
3226 AC_SUBST(WIDGET_OBJ)
3227
3228 TOOLKIT_LIBW=
3229 case "$USE_X_TOOLKIT" in
3230   MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;;
3231   LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;;
3232   none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS" ;;
3233 esac
3234 AC_SUBST(TOOLKIT_LIBW)
3235
3236 if test "$USE_X_TOOLKIT" = "none"; then
3237   LIBXT_OTHER="\$(LIBXSM)"
3238   OLDXMENU_TARGET="really-oldXMenu"
3239 else
3240   LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext"
3241   OLDXMENU_TARGET="really-lwlib"
3242 fi
3243 AC_SUBST(LIBXT_OTHER)
3244
3245 ## The X Menu stuff is present in the X10 distribution, but missing
3246 ## from X11.  If we have X10, just use the installed library;
3247 ## otherwise, use our own copy.
3248 if test "${HAVE_X11}" = "yes" ; then
3249   AC_DEFINE(HAVE_X11, 1,
3250             [Define to 1 if you want to use version 11 of X windows.
3251              Otherwise, Emacs expects to use version 10.])
3252
3253   if test "$USE_X_TOOLKIT" = "none"; then
3254     OLDXMENU="\${oldXMenudir}libXMenu11.a"
3255   else
3256     OLDXMENU="\${lwlibdir}liblw.a"
3257   fi
3258   LIBXMENU="\$(OLDXMENU)"
3259   LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)"
3260   OLDXMENU_DEPS="\${OLDXMENU} ../src/\${OLDXMENU}"
3261 else
3262   ## For a syntactically valid Makefile; not actually used for anything.
3263   ## See comments in src/Makefile.in.
3264   OLDXMENU=nothing
3265   ## FIXME This case (!HAVE_X11 && HAVE_X_WINDOWS) is no longer possible(?).
3266   if test "${HAVE_X_WINDOWS}" = "yes"; then
3267     LIBXMENU="-lXMenu"
3268   else
3269     LIBXMENU=
3270   fi
3271   LIBX_OTHER=
3272   OLDXMENU_DEPS=
3273 fi
3274
3275 if test "$HAVE_GTK" = "yes" || test "$HAVE_MENUS" != "yes"; then
3276   OLDXMENU_TARGET=
3277   OLDXMENU=nothing
3278   LIBXMENU=
3279   OLDXMENU_DEPS=
3280 fi
3281
3282 AC_SUBST(OLDXMENU_TARGET)
3283 AC_SUBST(OLDXMENU)
3284 AC_SUBST(LIBXMENU)
3285 AC_SUBST(LIBX_OTHER)
3286 AC_SUBST(OLDXMENU_DEPS)
3287
3288 if test "${HAVE_MENUS}" = "yes" ; then
3289   AC_DEFINE(HAVE_MENUS, 1,
3290             [Define to 1 if you have mouse menus.
3291              (This is automatic if you use X, but the option to specify it remains.)
3292              It is also defined with other window systems that support xmenu.c.])
3293 fi
3294
3295 if test "${GNU_MALLOC}" = "yes" ; then
3296   AC_DEFINE(GNU_MALLOC, 1,
3297             [Define to 1 if you want to use the GNU memory allocator.])
3298 fi
3299
3300 RALLOC_OBJ=
3301 if test "${REL_ALLOC}" = "yes" ; then
3302   AC_DEFINE(REL_ALLOC, 1,
3303             [Define REL_ALLOC if you want to use the relocating allocator for
3304              buffer space.])
3305
3306   test "$system_malloc" != "yes" && RALLOC_OBJ=ralloc.o
3307 fi
3308 AC_SUBST(RALLOC_OBJ)
3309
3310 if test "$opsys" = "cygwin"; then
3311   CYGWIN_OBJ="sheap.o"
3312   ## Cygwin differs because of its unexec().
3313   PRE_ALLOC_OBJ=
3314   POST_ALLOC_OBJ=lastfile.o
3315 else
3316   CYGWIN_OBJ=
3317   PRE_ALLOC_OBJ=lastfile.o
3318   POST_ALLOC_OBJ=
3319 fi
3320 AC_SUBST(CYGWIN_OBJ)
3321 AC_SUBST(PRE_ALLOC_OBJ)
3322 AC_SUBST(POST_ALLOC_OBJ)
3323
3324
3325 case "$opsys" in
3326   aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;;
3327
3328   darwin)
3329    ## The -headerpad option tells ld (see man page) to leave room at the
3330    ## end of the header for adding load commands.  Needed for dumping.
3331    ## 0x690 is the total size of 30 segment load commands (at 56
3332    ## each); under Cocoa 31 commands are required.
3333    if test "$HAVE_NS" = "yes"; then
3334      libs_nsgui="-framework AppKit"
3335      headerpad_extra=6C8
3336    else
3337      libs_nsgui=
3338      headerpad_extra=690
3339    fi
3340    LD_SWITCH_SYSTEM_TEMACS="-prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra"
3341
3342    ## This is here because src/Makefile.in did some extra fiddling around
3343    ## with LD_SWITCH_SYSTEM.  The cpp logic was:
3344    ##   #ifndef LD_SWITCH_SYSTEM
3345    ##   #if !defined (__GNUC__) && ((defined (BSD_SYSTEM) && !defined (COFF)))
3346    ## Since all the *bsds define LD_SWITCH_SYSTEM, this simplifies to:
3347    ## not using gcc, darwin system not on an alpha (ie darwin, since
3348    ## darwin + alpha does not occur).
3349    ## Because this was done in src/Makefile.in, the resulting part of
3350    ## LD_SWITCH_SYSTEM was not used in configure (ie, in ac_link).
3351    ## It therefore seems cleaner to put this in LD_SWITCH_SYSTEM_TEMACS,
3352    ## rather than LD_SWITCH_SYSTEM.
3353    test "x$LD_SWITCH_SYSTEM" = "x" && test "x$GCC" != "xyes" && \
3354      LD_SWITCH_SYSTEM_TEMACS="-X $LD_SWITCH_SYSTEM_TEMACS"
3355    ;;
3356
3357   ## LD_SWITCH_X_SITE_AUX is a -R option saying where to find X at run-time.
3358   ## When handled by cpp, this was in LD_SWITCH_SYSTEM.  However, at
3359   ## the point where configure sourced the s/*.h file, LD_SWITCH_X_SITE_AUX
3360   ## had not yet been defined and was expanded to null.  Hence LD_SWITCH_SYSTEM
3361   ## had different values in configure (in ac_link) and src/Makefile.in.
3362   ## It seems clearer therefore to put this piece in LD_SWITCH_SYSTEM_TEMACS.
3363   gnu-linux) LD_SWITCH_SYSTEM_TEMACS="\$(LD_SWITCH_X_SITE_AUX)" ;;
3364
3365   *) LD_SWITCH_SYSTEM_TEMACS= ;;
3366 esac
3367
3368 if test "$NS_IMPL_GNUSTEP" = "yes"; then
3369   LD_SWITCH_SYSTEM_TEMACS="${LD_SWITCH_SYSTEM_TEMACS} -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES} -lgnustep-gui -lgnustep-base -lobjc -lpthread"
3370 fi
3371
3372 AC_SUBST(LD_SWITCH_SYSTEM_TEMACS)
3373
3374
3375 LINKER=
3376 ORDINARY_LINK=
3377 case "$opsys" in
3378   ## gnu: GNU needs its own crt0.
3379   aix4-2|cygwin|darwin|gnu|hpux*|irix6-5|sol2*|unixware) ORDINARY_LINK=yes ;;
3380
3381   ## On post 1.3 releases of NetBSD, gcc -nostdlib also clears the
3382   ## library search parth, i.e. it won't search /usr/lib for libc and
3383   ## friends.  Using -nostartfiles instead avoids this problem, and
3384   ## will also work on earlier NetBSD releases.
3385   netbsd|openbsd) LINKER="\$(CC) -nostartfiles" ;;
3386
3387   ## macpcc: NAKAJI Hiroyuki <nakaji@tutrp.tut.ac.jp> says
3388   ##   MkLinux/LinuxPPC needs this.
3389   ## ibms390x only supports opsys = gnu-linux so it can be added here.
3390   gnu-*)
3391     case "$machine" in
3392       macppc|ibms390x) LINKER="\$(CC) -nostdlib" ;;
3393     esac
3394     ;;
3395 esac
3396
3397
3398 if test "x$ORDINARY_LINK" = "xyes"; then
3399
3400   LINKER="\$(CC)"
3401   AC_DEFINE(ORDINARY_LINK, 1, [Define if the C compiler is the linker.])
3402
3403 ## The system files defining neither ORDINARY_LINK nor LINKER are:
3404 ## freebsd, gnu-* not on macppc|ibms390x.
3405 elif test "x$GCC" = "xyes" && test "x$LINKER" = "x"; then
3406
3407   ## Versions of GCC >= 2.0 put their library, libgcc.a, in obscure
3408   ## places that are difficult to figure out at make time.  Fortunately,
3409   ## these same versions allow you to pass arbitrary flags on to the
3410   ## linker, so there is no reason not to use it as a linker.
3411   ##
3412   ## Well, it is not quite perfect.  The "-nostdlib" keeps GCC from
3413   ## searching for libraries in its internal directories, so we have to
3414   ## ask GCC explicitly where to find libgcc.a (LIB_GCC below).
3415   LINKER="\$(CC) -nostdlib"
3416 fi
3417
3418 test "x$LINKER" = "x" && LINKER=ld
3419 ## FIXME? What setting of EDIT_LDFLAGS should this have?
3420 test "$NS_IMPL_GNUSTEP" = "yes" && LINKER="\$(CC) -rdynamic"
3421
3422 AC_SUBST(LINKER)
3423
3424
3425 ## FIXME? The logic here is not precisely the same as that above.
3426 ## There is no check here for a pre-defined LINKER.
3427 ## Should we only be setting LIB_GCC if LD ~ -nostdlib?
3428 LIB_GCC=
3429 if test "x$GCC" = "xyes" && test "x$ORDINARY_LINK" != "xyes"; then
3430
3431   case "$opsys" in
3432     freebsd|netbsd|openbsd) LIB_GCC= ;;
3433
3434     gnu-*)
3435       ## armin76@gentoo.org reported that the lgcc_s flag is necessary to
3436       ## build on ARM EABI under GNU/Linux.  (Bug#5518)
3437       ## Note that m/arm.h never bothered to undefine LIB_GCC first.
3438       if test "$machine" = "arm"; then
3439         LIB_GCC="-lgcc_s"
3440       else
3441         ## FIXME? s/gnu-linux.h used to define LIB_GCC as below, then
3442         ## immediately undefine it again and redefine it to empty.
3443         ## Was the C_SWITCH_X_SITE part really necessary?
3444 ##      LIB_GCC=`$CC $C_SWITCH_X_SITE -print-libgcc-file-name`
3445         LIB_GCC=
3446       fi
3447       ;;
3448
3449     ## Ask GCC where to find libgcc.a.
3450     *) LIB_GCC=`$CC -print-libgcc-file-name 2> /dev/null` ;;
3451   esac
3452 fi                              dnl if $GCC
3453 AC_SUBST(LIB_GCC)
3454
3455
3456 TOOLTIP_SUPPORT=
3457 WINDOW_SUPPORT=
3458 ## If we're using X11/GNUstep, define some consequences.
3459 if test "$HAVE_X_WINDOWS" = "yes" || test "$HAVE_NS" = "yes"; then
3460   AC_DEFINE(HAVE_WINDOW_SYSTEM, 1, [Define if you have a window system.])
3461   AC_DEFINE(HAVE_MOUSE, 1, [Define if you have mouse support.])
3462   MOUSE_SUPPORT="\$(REAL_MOUSE_SUPPORT)"
3463   TOOLTIP_SUPPORT="\${lispsource}mouse.elc"
3464
3465   WINDOW_SUPPORT="\$(BASE_WINDOW_SUPPORT)"
3466   test "$HAVE_X_WINDOWS" = "yes" && \
3467     WINDOW_SUPPORT="$WINDOW_SUPPORT \$(X_WINDOW_SUPPORT)"
3468
3469 fi
3470 AC_SUBST(MOUSE_SUPPORT)
3471 AC_SUBST(TOOLTIP_SUPPORT)
3472 AC_SUBST(WINDOW_SUPPORT)
3473
3474
3475 AH_TOP([/* GNU Emacs site configuration template file.
3476    Copyright (C) 1988, 1993, 1994, 1999, 2000, 2001, 2002, 2004, 2005,
3477      2006, 2007, 2008, 2009, 2010  Free Software Foundation, Inc.
3478
3479 This file is part of GNU Emacs.
3480
3481 GNU Emacs is free software: you can redistribute it and/or modify
3482 it under the terms of the GNU General Public License as published by
3483 the Free Software Foundation, either version 3 of the License, or
3484 (at your option) any later version.
3485
3486 GNU Emacs is distributed in the hope that it will be useful,
3487 but WITHOUT ANY WARRANTY; without even the implied warranty of
3488 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
3489 GNU General Public License for more details.
3490
3491 You should have received a copy of the GNU General Public License
3492 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
3493
3494
3495 /* No code in Emacs #includes config.h twice, but some bits of code
3496    intended to work with other packages as well (like gmalloc.c)
3497    think they can include it as many times as they like.  */
3498 #ifndef EMACS_CONFIG_H
3499 #define EMACS_CONFIG_H
3500 ])dnl
3501
3502 AH_BOTTOM([
3503 /* Define AMPERSAND_FULL_NAME if you use the convention
3504    that & in the full name stands for the login id.  */
3505 /* Turned on June 1996 supposing nobody will mind it.  */
3506 #define AMPERSAND_FULL_NAME
3507
3508 /* If using GNU, then support inline function declarations.  */
3509 /* Don't try to switch on inline handling as detected by AC_C_INLINE
3510    generally, because even if non-gcc compilers accept `inline', they
3511    may reject `extern inline'.  */
3512 #if defined (__GNUC__) && defined (OPTIMIZE)
3513 #define INLINE __inline__
3514 #else
3515 #define INLINE
3516 #endif
3517
3518 /* `subprocesses' should be defined if you want to
3519    have code for asynchronous subprocesses
3520    (as used in M-x compile and M-x shell).
3521    Only MSDOS does not support this (it overrides
3522    this in its config_opsysfile below).  */
3523
3524 #define subprocesses
3525
3526 /* Include the os and machine dependent files.  */
3527 #include config_opsysfile
3528 #include config_machfile
3529
3530 /* Set up some defines, C and LD flags for NeXTstep interface on GNUstep.
3531   (There is probably a better place to do this, but right now the Cocoa
3532    side does this in s/darwin.h and we cannot
3533    parallel this exactly since GNUstep is multi-OS.  */
3534 #ifdef HAVE_NS
3535 # ifdef NS_IMPL_GNUSTEP
3536 /* GNUstep needs a bit more pure memory.  Of the existing knobs,
3537 SYSTEM_PURESIZE_EXTRA seems like the least likely to cause problems.  */
3538 #  define SYSTEM_PURESIZE_EXTRA 30000
3539 # endif /* NS_IMPL_GNUSTEP */
3540 #endif /* HAVE_NS */
3541
3542 /* SIGTYPE is the macro we actually use.  */
3543 #ifndef SIGTYPE
3544 #define SIGTYPE RETSIGTYPE
3545 #endif
3546
3547 #ifdef emacs /* Don't do this for lib-src.  */
3548 /* Tell regex.c to use a type compatible with Emacs.  */
3549 #define RE_TRANSLATE_TYPE Lisp_Object
3550 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
3551 #ifdef make_number
3552 /* If make_number is a macro, use it.  */
3553 #define RE_TRANSLATE_P(TBL) (!EQ (TBL, make_number (0)))
3554 #else
3555 /* If make_number is a function, avoid it.  */
3556 #define RE_TRANSLATE_P(TBL) (!(INTEGERP (TBL) && XINT (TBL) == 0))
3557 #endif
3558 #endif
3559
3560 /* Avoid link-time collision with system mktime if we will use our own.  */
3561 #if ! HAVE_MKTIME || BROKEN_MKTIME
3562 #define mktime emacs_mktime
3563 #endif
3564
3565 #define my_strftime nstrftime   /* for strftime.c */
3566
3567 /* These default definitions are good for almost all machines.
3568    The exceptions override them in m/MACHINE.h.  */
3569
3570 #ifndef BITS_PER_CHAR
3571 #define BITS_PER_CHAR 8
3572 #endif
3573
3574 #ifndef BITS_PER_SHORT
3575 #define BITS_PER_SHORT 16
3576 #endif
3577
3578 /* Note that lisp.h uses this in a preprocessor conditional, so it
3579    would not work to use sizeof.  That being so, we do all of them
3580    without sizeof, for uniformity's sake.  */
3581 #ifndef BITS_PER_INT
3582 #define BITS_PER_INT 32
3583 #endif
3584
3585 #ifndef BITS_PER_LONG
3586 #ifdef _LP64
3587 #define BITS_PER_LONG 64
3588 #else
3589 #define BITS_PER_LONG 32
3590 #endif
3591 #endif
3592
3593 /* Define if the compiler supports function prototypes.  It may do so but
3594    not define __STDC__ (e.g. DEC C by default) or may define it as zero.  */
3595 #undef PROTOTYPES
3596
3597 #ifdef HAVE_STRING_H
3598 #include <string.h>
3599 #endif
3600
3601 #ifdef HAVE_STDLIB_H
3602 #include <stdlib.h>
3603 #endif
3604
3605 #ifdef HAVE_ALLOCA_H
3606 # include <alloca.h>
3607 #elif defined __GNUC__
3608 # define alloca __builtin_alloca
3609 #elif defined _AIX
3610 # define alloca __alloca
3611 #else
3612 # include <stddef.h>
3613 # ifdef  __cplusplus
3614 extern "C"
3615 # endif
3616 void *alloca (size_t);
3617 #endif
3618
3619 #ifndef HAVE_SIZE_T
3620 typedef unsigned size_t;
3621 #endif
3622
3623 #ifndef HAVE_STRCHR
3624 #define strchr(a, b) index (a, b)
3625 #endif
3626
3627 #ifndef HAVE_STRRCHR
3628 #define strrchr(a, b) rindex (a, b)
3629 #endif
3630
3631 #if defined __GNUC__ && (__GNUC__ > 2 \
3632                          || (__GNUC__ == 2 && __GNUC_MINOR__ >= 5))
3633 #define NO_RETURN       __attribute__ ((__noreturn__))
3634 #else
3635 #define NO_RETURN       /* nothing */
3636 #endif
3637
3638 /* These won't be used automatically yet.  We also need to know, at least,
3639    that the stack is continuous.  */
3640 #ifdef __GNUC__
3641 #  ifndef GC_SETJMP_WORKS
3642   /* GC_SETJMP_WORKS is nearly always appropriate for GCC.  */
3643 #    define GC_SETJMP_WORKS 1
3644 #  endif
3645 #  ifndef GC_LISP_OBJECT_ALIGNMENT
3646 #    define GC_LISP_OBJECT_ALIGNMENT (__alignof__ (Lisp_Object))
3647 #  endif
3648 #endif
3649
3650 #endif /* EMACS_CONFIG_H */
3651
3652 /*
3653 Local Variables:
3654 mode: c
3655 End:
3656 */
3657 ])dnl
3658
3659 #### Report on what we decided to do.
3660 #### Report GTK as a toolkit, even if it doesn't use Xt.
3661 #### It makes printing result more understandable as using GTK sets
3662 #### toolkit_scroll_bars to yes by default.
3663 if test "${HAVE_GTK}" = "yes"; then
3664   USE_X_TOOLKIT=GTK
3665 fi
3666
3667 echo "
3668 Configured for \`${canonical}'.
3669
3670   Where should the build process find the source code?    ${srcdir}
3671   What operating system and machine description files should Emacs use?
3672         \`${opsysfile}' and \`${machfile}'
3673   What compiler should emacs be built with?               ${CC} ${CFLAGS}
3674   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
3675   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
3676   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
3677   What window system should Emacs use?                    ${window_system}
3678   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
3679
3680 if test -n "${x_includes}"; then
3681 echo "  Where do we find X Windows header files?                ${x_includes}"
3682 else
3683 echo "  Where do we find X Windows header files?                Standard dirs"
3684 fi
3685 if test -n "${x_libraries}"; then
3686 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
3687 else
3688 echo "  Where do we find X Windows libraries?                   Standard dirs"
3689 fi
3690
3691 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
3692 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
3693 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
3694 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
3695 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF"
3696 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
3697 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
3698 echo "  Does Emacs use imagemagick?                             ${HAVE_IMAGEMAGICK}"
3699 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
3700 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
3701 echo "  Does Emacs use -lgconf?                                 ${HAVE_GCONF}"
3702 echo "  Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}"
3703
3704 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
3705 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
3706 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
3707 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
3708
3709 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
3710 echo
3711
3712 if test $USE_XASSERTS = yes; then
3713    echo "  Compiling with asserts turned on."
3714    CPPFLAGS="$CPPFLAGS -DXASSERTS=1"
3715 fi
3716
3717 echo
3718
3719 if test "$HAVE_NS" = "yes"; then
3720    echo
3721    echo "You must run \"make install\" in order to test the built application.
3722 The installed application will go to nextstep/Emacs.app and can be
3723 run or moved from there."
3724    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
3725       echo "The application will be fully self-contained."
3726     else
3727       echo "The lisp resources for the application will be installed under ${prefix}.
3728 You may need to run \"make install\" with sudo.  The application will fail
3729 to run if these resources are not installed."
3730    fi
3731    echo
3732 fi
3733
3734 if test "$HAVE_DBUS" = yes && test "${opsys}" != "gnu-linux"; then
3735   echo "D-Bus integration has been tested for GNU/Linux only."
3736   echo
3737 fi
3738
3739
3740 # Remove any trailing slashes in these variables.
3741 [test "${prefix}" != NONE &&
3742   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
3743 test "${exec_prefix}" != NONE &&
3744   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
3745
3746 dnl You might wonder (I did) why epaths.h is generated by running make,
3747 dnl rather than just letting configure generate it from epaths.in.
3748 dnl One reason is that the various paths are not fully expanded (see above);
3749 dnl eg gamedir=${prefix}/var/games/emacs.
3750 dnl Secondly, the GNU Coding standards require that one should be able
3751 dnl to run `make prefix=/some/where/else' and override the values set
3752 dnl by configure.  This also explains the `move-if-change' test and
3753 dnl the use of force in the `epaths-force' rule in Makefile.in.
3754 AC_OUTPUT(Makefile lib-src/Makefile oldXMenu/Makefile \
3755         doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
3756         doc/lispref/Makefile src/Makefile \
3757         lwlib/Makefile lisp/Makefile leim/Makefile, [
3758
3759 ### Make the necessary directories, if they don't exist.
3760 for dir in etc lisp ; do
3761   test -d ${dir} || mkdir ${dir}
3762 done
3763
3764 echo creating src/epaths.h
3765 ${MAKE-make} epaths-force
3766
3767 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
3768   echo creating src/.gdbinit
3769   echo source $srcdir/src/.gdbinit > src/.gdbinit
3770 fi
3771
3772 ], [GCC="$GCC" NON_GNU_CPP="$NON_GNU_CPP" CPP="$CPP" CPPFLAGS="$CPPFLAGS"])
3773
3774 m4_if(dnl       Do not change this comment
3775    arch-tag: 156a4dd5-bddc-4d18-96ac-f37742cf6a5e
3776 )dnl