code.delx.au - gnu-emacs/blob - lisp/fast-lock.el

   1 ;;; fast-lock.el --- Automagic text properties caching for fast Font Lock mode.
   2
   3 ;; Copyright (C) 1994, 1995, 1996, 1997 Free Software Foundation, Inc.
   4
   5 ;; Author: Simon Marshall <simon@gnu.ai.mit.edu>
   6 ;; Keywords: faces files
   7 ;; Version: 3.12
   8
   9 ;;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; Lazy Lock mode is a Font Lock support mode.
  29 ;; It makes visiting a file in Font Lock mode faster by restoring its face text
  30 ;; properties from automatically saved associated Font Lock cache files.
  31 ;;
  32 ;; See caveats and feedback below.
  33 ;; See also the lazy-lock package.  (But don't use the two at the same time!)
  34
  35 ;; Installation:
  36 ;;
  37 ;; Put in your ~/.emacs:
  38 ;;
  39 ;; (setq font-lock-support-mode 'fast-lock-mode)
  40 ;;
  41 ;; Start up a new Emacs and use font-lock as usual (except that you can use the
  42 ;; so-called "gaudier" fontification regexps on big files without frustration).
  43 ;;
  44 ;; When you visit a file (which has `font-lock-mode' enabled) that has a
  45 ;; corresponding Font Lock cache file associated with it, the Font Lock cache
  46 ;; will be loaded from that file instead of being generated by Font Lock code.
  47
  48 ;; Caveats:
  49 ;;
  50 ;; A cache will be saved when visiting a compressed file using crypt++, but not
  51 ;; be read.  This is a "feature"/"consequence"/"bug" of crypt++.
  52 ;;
  53 ;; Version control packages are likely to stamp all over file modification
  54 ;; times.  Therefore the act of checking out may invalidate a cache.
  55 \f
  56 ;; History:
  57 ;;
  58 ;; 0.02--1.00:
  59 ;; - Changed name from turbo-prop to fast-lock.  Automagic for font-lock only
  60 ;; - Made `fast-lock-mode' a minor mode, like G. Dinesh Dutt's fss-mode
  61 ;; 1.00--1.01:
  62 ;; - Turn on `fast-lock-mode' only if `buffer-file-name' or `interactive-p'
  63 ;; - Made `fast-lock-file-name' use `buffer-name' if `buffer-file-name' is nil
  64 ;; - Moved save-all conditions to `fast-lock-save-cache'
  65 ;; - Added `fast-lock-save-text-properties' to `kill-buffer-hook'
  66 ;; 1.01--2.00: complete rewrite---not worth the space to document
  67 ;; - Changed structure of text properties cache and threw out file mod checks
  68 ;; 2.00--2.01:
  69 ;; - Made `condition-case' forms understand `quit'.
  70 ;; - Made `fast-lock' require `font-lock'
  71 ;; - Made `fast-lock-cache-name' chase links (from Ben Liblit)
  72 ;; 2.01--3.00:
  73 ;; - Changed structure of cache to include `font-lock-keywords' (from rms)
  74 ;; - Changed `fast-lock-cache-mechanisms' to `fast-lock-cache-directories'
  75 ;; - Removed `fast-lock-read-others'
  76 ;; - Made `fast-lock-read-cache' ignore cache owner
  77 ;; - Made `fast-lock-save-cache-external' create cache directory
  78 ;; - Made `fast-lock-save-cache-external' save `font-lock-keywords'
  79 ;; - Made `fast-lock-cache-data' check `font-lock-keywords'
  80 ;; 3.00--3.01: incorporated port of 2.00 to Lucid, made by Barry Warsaw
  81 ;; - Package now provides itself
  82 ;; - Lucid: Use `font-lock-any-extents-p' for `font-lock-any-properties-p'
  83 ;; - Lucid: Use `list-faces' for `face-list'
  84 ;; - Lucid: Added `set-text-properties'
  85 ;; - Lucid: Made `turn-on-fast-lock' pass 1 not t to `fast-lock-mode'
  86 ;; - Removed test for `fast-lock-mode' from `fast-lock-read-cache'
  87 ;; - Lucid: Added Lucid-specific `fast-lock-get-face-properties'
  88 ;; 3.01--3.02: now works with Lucid Emacs, thanks to Barry Warsaw
  89 ;; - Made `fast-lock-cache-name' map ":" to ";" for OS/2 (from Serganova Vera)
  90 ;; - Made `fast-lock-cache-name' use abbreviated file name (from Barry Warsaw)
  91 ;; - Lucid: Separated handlers for `error' and `quit' for `condition-case'
  92 ;; 3.02--3.03:
  93 ;; - Changed `fast-lock-save-cache-external' to `fast-lock-save-cache-data'
  94 ;; - Lucid: Added Lucid-specific `fast-lock-set-face-properties'
  95 ;; 3.03--3.04:
  96 ;; - Corrected `subrp' test of Lucid code
  97 ;; - Replaced `font-lock-any-properties-p' with `text-property-not-all'
  98 ;; - Lucid: Made `fast-lock-set-face-properties' put `text-prop' on extents
  99 ;; - Made `fast-lock-cache-directories' a regexp alist (from Colin Rafferty)
 100 ;; - Made `fast-lock-cache-directory' to return a usable cache file directory
 101 ;; 3.04--3.05:
 102 ;; - Lucid: Fix for XEmacs 19.11 `text-property-not-all'
 103 ;; - Replaced `subrp' test of Lucid code with `emacs-version' `string-match'
 104 ;; - Made `byte-compile-warnings' omit `unresolved' on compilation
 105 ;; - Made `fast-lock-save-cache-data' use a buffer (from Rick Sladkey)
 106 ;; - Reverted to old `fast-lock-get-face-properties' (from Rick Sladkey)
 107 ;; 3.05--3.06: incorporated hack of 3.03, made by Jonathan Stigelman (Stig)
 108 ;; - Reverted to 3.04 version of `fast-lock-get-face-properties'
 109 ;; - XEmacs: Removed `list-faces' `defalias'
 110 ;; - Made `fast-lock-mode' and `turn-on-fast-lock' succeed `autoload' cookies
 111 ;; - Added `fast-lock-submit-bug-report'
 112 ;; - Renamed `fast-lock-save-size' to `fast-lock-minimum-size'
 113 ;; - Made `fast-lock-save-cache' output a message if no save ever attempted
 114 ;; - Made `fast-lock-save-cache-data' output a message if save attempted
 115 ;; - Made `fast-lock-cache-data' output a message if load attempted
 116 ;; - Made `fast-lock-save-cache-data' do `condition-case' not `unwind-protect'
 117 ;; - Made `fast-lock-save-cache' and `fast-lock-read-cache' return nothing
 118 ;; - Made `fast-lock-save-cache' check `buffer-modified-p' (Stig)
 119 ;; - Added `fast-lock-save-events'
 120 ;; - Added `fast-lock-after-save-hook' to `after-save-hook' (Stig)
 121 ;; - Added `fast-lock-kill-buffer-hook' to `kill-buffer-hook'
 122 ;; - Changed `fast-lock-save-caches' to `fast-lock-kill-emacs-hook'
 123 ;; - Added `fast-lock-kill-emacs-hook' to `kill-emacs-hook'
 124 ;; - Made `fast-lock-save-cache' check `verify-visited-file-modtime' (Stig)
 125 ;; - Made `visited-file-modtime' be the basis of the timestamp (Stig)
 126 ;; - Made `fast-lock-save-cache-1' and `fast-lock-cache-data' use/reformat it
 127 ;; - Added `fast-lock-cache-filename' to keep track of the cache file name
 128 ;; - Added `fast-lock-after-fontify-buffer'
 129 ;; - Added `fast-lock-save-faces' list of faces to save (idea from Stig/Tibor)
 130 ;; - Made `fast-lock-get-face-properties' functions use it
 131 ;; - XEmacs: Made `fast-lock-set-face-properties' do extents the Font Lock way
 132 ;; - XEmacs: Removed fix for `text-property-not-all' (19.11 support dropped)
 133 ;; - Made `fast-lock-mode' ensure `font-lock-mode' is on
 134 ;; - Made `fast-lock-save-cache' do `cdr-safe' not `cdr' (from Dave Foster)
 135 ;; - Made `fast-lock-save-cache' do `set-buffer' first (from Dave Foster)
 136 ;; - Made `fast-lock-save-cache' loop until saved or quit (from Georg Nikodym)
 137 ;; - Made `fast-lock-cache-data' check `buffer-modified-p'
 138 ;; - Made `fast-lock-cache-data' do `font-lock-compile-keywords' if necessary
 139 ;; - XEmacs: Made `font-lock-compile-keywords' `defalias'
 140 ;; 3.06--3.07:
 141 ;; - XEmacs: Add `fast-lock-after-fontify-buffer' to the Font Lock hook
 142 ;; - Made `fast-lock-cache-name' explain the use of `directory-abbrev-alist'
 143 ;; - Made `fast-lock-mode' use `buffer-file-truename' not `buffer-file-name'
 144 ;; 3.07--3.08:
 145 ;; - Made `fast-lock-read-cache' set `fast-lock-cache-filename'
 146 ;; 3.08--3.09:
 147 ;; - Made `fast-lock-save-cache' cope if `fast-lock-minimum-size' is an a list
 148 ;; - Made `fast-lock-mode' respect the value of `font-lock-inhibit-thing-lock'
 149 ;; - Added `fast-lock-after-unfontify-buffer'
 150 ;; 3.09--3.10:
 151 ;; - Rewrite for Common Lisp macros
 152 ;; - Made fast-lock.el barf on a crap 8+3 pseudo-OS (Eli Zaretskii help)
 153 ;; - XEmacs: Made `add-minor-mode' succeed `autoload' cookie
 154 ;; - XEmacs: Made `fast-lock-save-faces' default to `font-lock-face-list'
 155 ;; - Made `fast-lock-save-cache' use `font-lock-value-in-major-mode'
 156 ;; - Wrap with `save-buffer-state' (Ray Van Tassle report)
 157 ;; - Made `fast-lock-mode' wrap `font-lock-support-mode'
 158 ;; 3.10--3.11:
 159 ;; - Made `fast-lock-get-face-properties' cope with face lists
 160 ;; - Added `fast-lock-verbose'
 161 ;; - XEmacs: Add `font-lock-value-in-major-mode' if necessary
 162 ;; - Removed `fast-lock-submit-bug-report' and bade farewell
 163 ;; 3.11--3.12:
 164 ;; - Added Custom support (Hrvoje Niksic help)
 165 ;; - Made `fast-lock-cache-data' simplify calls of `font-lock-compile-keywords'
 166 \f
 167 ;;; Code:
 168
 169 (require 'font-lock)
 170
 171 ;; Make sure fast-lock.el is supported.
 172 (if (and (eq system-type 'ms-dos) (not (msdos-long-file-names)))
 173     (error "`fast-lock' was written for long file name systems"))
 174
 175 (eval-when-compile
 176   ;;
 177   ;; We don't do this at the top-level as we only use non-autoloaded macros.
 178   (require 'cl)
 179   ;;
 180   ;; I prefer lazy code---and lazy mode.
 181   (setq byte-compile-dynamic t byte-compile-dynamic-docstrings t)
 182   ;; But, we make sure that the code is as zippy as can be.
 183   (setq byte-optimize t)
 184   ;;
 185   ;; We use this to preserve or protect things when modifying text properties.
 186   (defmacro save-buffer-state (varlist &rest body)
 187     "Bind variables according to VARLIST and eval BODY restoring buffer state."
 188     (` (let* ((,@ (append varlist
 189                    '((modified (buffer-modified-p)) (buffer-undo-list t)
 190                      (inhibit-read-only t) (inhibit-point-motion-hooks t)
 191                      before-change-functions after-change-functions
 192                      deactivate-mark buffer-file-name buffer-file-truename))))
 193          (,@ body)
 194          (when (and (not modified) (buffer-modified-p))
 195            (set-buffer-modified-p nil)))))
 196   (put 'save-buffer-state 'lisp-indent-function 1)
 197   ;;
 198   ;; We use this to verify that a face should be saved.
 199   (defmacro fast-lock-save-facep (face)
 200     "Return non-nil if FACE is one of `fast-lock-save-faces'."
 201     (` (or (null fast-lock-save-faces)
 202            (if (symbolp (, face))
 203                (memq (, face) fast-lock-save-faces)
 204              (let ((faces (, face)))
 205                (while (unless (memq (car faces) fast-lock-save-faces)
 206                         (setq faces (cdr faces))))
 207                faces))))))
 208
 209 ;(defun fast-lock-submit-bug-report ()
 210 ;  "Submit via mail a bug report on fast-lock.el."
 211 ;  (interactive)
 212 ;  (let ((reporter-prompt-for-summary-p t))
 213 ;    (reporter-submit-bug-report "simon@gnu.ai.mit.edu" "fast-lock 3.12"
 214 ;     '(fast-lock-cache-directories fast-lock-minimum-size
 215 ;       fast-lock-save-others fast-lock-save-events fast-lock-save-faces
 216 ;       fast-lock-verbose)
 217 ;     nil nil
 218 ;     (concat "Hi Si.,
 219 ;
 220 ;I want to report a bug.  I've read the `Bugs' section of `Info' on Emacs, so I
 221 ;know how to make a clear and unambiguous report.  To reproduce the bug:
 222 ;
 223 ;Start a fresh editor via `" invocation-name " -no-init-file -no-site-file'.
 224 ;In the `*scratch*' buffer, evaluate:"))))
 225
 226 (defvar fast-lock-mode nil)             ; Whether we are turned on.
 227 (defvar fast-lock-cache-timestamp nil)  ; For saving/reading.
 228 (defvar fast-lock-cache-filename nil)   ; For deleting.
 229 \f
 230 ;; User Variables:
 231
 232 (defgroup fast-lock nil
 233   "Font Lock support mode to cache fontification."
 234   :link '(custom-manual "(emacs)Support Modes")
 235   :group 'font-lock)
 236
 237 (defcustom fast-lock-cache-directories '("." "~/.emacs-flc")
 238 ; - `internal', keep each file's Font Lock cache file in the same file.
 239 ; - `external', keep each file's Font Lock cache file in the same directory.
 240   "*Directories in which Font Lock cache files are saved and read.
 241 Each item should be either DIR or a cons pair of the form (REGEXP . DIR) where
 242 DIR is a directory name (relative or absolute) and REGEXP is a regexp.
 243
 244 An attempt will be made to save or read Font Lock cache files using these items
 245 until one succeeds (i.e., until a readable or writable one is found).  If an
 246 item contains REGEXP, DIR is used only if the buffer file name matches REGEXP.
 247 For example:
 248
 249  (let ((home (expand-file-name (abbreviate-file-name (file-truename \"~/\")))))
 250    (list (cons (concat \"^\" (regexp-quote home)) \".\") \"~/.emacs-flc\"))
 251     =>
 252  ((\"^/your/true/home/directory/\" . \".\") \"~/.emacs-flc\")
 253
 254 would cause a file's current directory to be used if the file is under your
 255 home directory hierarchy, or otherwise the absolute directory `~/.emacs-flc'."
 256   :type '(repeat (radio (cons :tag "Matching"
 257                               (regexp :tag "regexp")
 258                               (directory :tag "directory"))
 259                         (directory :tag "directory")))
 260   :group 'fast-lock)
 261
 262 (defcustom fast-lock-minimum-size (* 25 1024)
 263   "*Minimum size of a buffer for cached fontification.
 264 Only buffers more than this can have associated Font Lock cache files saved.
 265 If nil, means cache files are never created.
 266 If a list, each element should be a cons pair of the form (MAJOR-MODE . SIZE),
 267 where MAJOR-MODE is a symbol or t (meaning the default).  For example:
 268  ((c-mode . 25600) (c++-mode . 25600) (rmail-mode . 1048576))
 269 means that the minimum size is 25K for buffers in C or C++ modes, one megabyte
 270 for buffers in Rmail mode, and size is irrelevant otherwise."
 271   :type '(choice (const :tag "none" nil)
 272                  (integer :tag "size")
 273                  (repeat :menu-tag "mode specific" :tag "mode specific"
 274                          :value ((t . nil))
 275                          (cons :tag "Instance"
 276                                (radio :tag "Mode"
 277                                       (const :tag "all" t)
 278                                       (symbol :tag "name"))
 279                                (radio :tag "Size"
 280                                       (const :tag "none" nil)
 281                                       (integer :tag "size")))))
 282   :group 'fast-lock)
 283
 284 (defcustom fast-lock-save-events '(kill-buffer kill-emacs)
 285   "*Events under which caches will be saved.
 286 Valid events are `save-buffer', `kill-buffer' and `kill-emacs'.
 287 If concurrent editing sessions use the same associated cache file for a file's
 288 buffer, then you should add `save-buffer' to this list."
 289   :type '(set (const :tag "buffer saving" save-buffer)
 290               (const :tag "buffer killing" kill-buffer)
 291               (const :tag "emacs killing" kill-emacs))
 292   :group 'fast-lock)
 293
 294 (defcustom fast-lock-save-others t
 295   "*If non-nil, save Font Lock cache files irrespective of file owner.
 296 If nil, means only buffer files known to be owned by you can have associated
 297 Font Lock cache files saved.  Ownership may be unknown for networked files."
 298   :type 'boolean
 299   :group 'fast-lock)
 300
 301 (defcustom fast-lock-verbose font-lock-verbose
 302   "*If non-nil, means show status messages for cache processing.
 303 If a number, only buffers greater than this size have processing messages."
 304   :type '(choice (const :tag "never" nil)
 305                  (const :tag "always" t)
 306                  (integer :tag "size"))
 307   :group 'fast-lock)
 308
 309 (defvar fast-lock-save-faces
 310   (when (save-match-data (string-match "XEmacs" (emacs-version)))
 311     ;; XEmacs uses extents for everything, so we have to pick the right ones.
 312     font-lock-face-list)
 313   "Faces that will be saved in a Font Lock cache file.
 314 If nil, means information for all faces will be saved.")
 315 \f
 316 ;; User Functions:
 317
 318 ;;;###autoload
 319 (defun fast-lock-mode (&optional arg)
 320   "Toggle Fast Lock mode.
 321 With arg, turn Fast Lock mode on if and only if arg is positive and the buffer
 322 is associated with a file.  Enable it automatically in your `~/.emacs' by:
 323
 324  (setq font-lock-support-mode 'fast-lock-mode)
 325
 326 If Fast Lock mode is enabled, and the current buffer does not contain any text
 327 properties, any associated Font Lock cache is used if its timestamp matches the
 328 buffer's file, and its `font-lock-keywords' match those that you are using.
 329
 330 Font Lock caches may be saved:
 331 - When you save the file's buffer.
 332 - When you kill an unmodified file's buffer.
 333 - When you exit Emacs, for all unmodified or saved buffers.
 334 Depending on the value of `fast-lock-save-events'.
 335 See also the commands `fast-lock-read-cache' and `fast-lock-save-cache'.
 336
 337 Use \\[font-lock-fontify-buffer] to fontify the buffer if the cache is bad.
 338
 339 Various methods of control are provided for the Font Lock cache.  In general,
 340 see variable `fast-lock-cache-directories' and function `fast-lock-cache-name'.
 341 For saving, see variables `fast-lock-minimum-size', `fast-lock-save-events',
 342 `fast-lock-save-others' and `fast-lock-save-faces'."
 343   (interactive "P")
 344   ;; Only turn on if we are visiting a file.  We could use `buffer-file-name',
 345   ;; but many packages temporarily wrap that to nil when doing their own thing.
 346   (set (make-local-variable 'fast-lock-mode)
 347        (and buffer-file-truename
 348             (not (memq 'fast-lock-mode font-lock-inhibit-thing-lock))
 349             (if arg (> (prefix-numeric-value arg) 0) (not fast-lock-mode))))
 350   (if (and fast-lock-mode (not font-lock-mode))
 351       ;; Turned on `fast-lock-mode' rather than `font-lock-mode'.
 352       (let ((font-lock-support-mode 'fast-lock-mode))
 353         (font-lock-mode t))
 354     ;; Let's get down to business.
 355     (set (make-local-variable 'fast-lock-cache-timestamp) nil)
 356     (set (make-local-variable 'fast-lock-cache-filename) nil)
 357     (when (and fast-lock-mode (not font-lock-fontified))
 358       (fast-lock-read-cache))))
 359
 360 (defun fast-lock-read-cache ()
 361   "Read the Font Lock cache for the current buffer.
 362
 363 The following criteria must be met for a Font Lock cache file to be read:
 364 - Fast Lock mode must be turned on in the buffer.
 365 - The buffer must not be modified.
 366 - The buffer's `font-lock-keywords' must match the cache's.
 367 - The buffer file's timestamp must match the cache's.
 368 - Criteria imposed by `fast-lock-cache-directories'.
 369
 370 See `fast-lock-mode'."
 371   (interactive)
 372   (let ((directories fast-lock-cache-directories)
 373         (modified (buffer-modified-p)) (inhibit-read-only t)
 374         (fontified font-lock-fontified))
 375     (set (make-local-variable 'font-lock-fontified) nil)
 376     ;; Keep trying directories until fontification is turned off.
 377     (while (and directories (not font-lock-fontified))
 378       (let ((directory (fast-lock-cache-directory (car directories) nil)))
 379         (condition-case nil
 380             (when directory
 381               (setq fast-lock-cache-filename (fast-lock-cache-name directory))
 382               (when (file-readable-p fast-lock-cache-filename)
 383                 (load fast-lock-cache-filename t t t)))
 384           (error nil) (quit nil))
 385         (setq directories (cdr directories))))
 386     ;; Unset `fast-lock-cache-filename', and restore `font-lock-fontified', if
 387     ;; we don't use a cache.  (Note that `fast-lock-cache-data' sets the value
 388     ;; of `fast-lock-cache-timestamp'.)
 389     (set-buffer-modified-p modified)
 390     (unless font-lock-fontified
 391       (setq fast-lock-cache-filename nil font-lock-fontified fontified))))
 392
 393 (defun fast-lock-save-cache (&optional buffer)
 394   "Save the Font Lock cache of BUFFER or the current buffer.
 395
 396 The following criteria must be met for a Font Lock cache file to be saved:
 397 - Fast Lock mode must be turned on in the buffer.
 398 - The event must be one of `fast-lock-save-events'.
 399 - The buffer must be at least `fast-lock-minimum-size' bytes long.
 400 - The buffer file must be owned by you, or `fast-lock-save-others' must be t.
 401 - The buffer must contain at least one `face' text property.
 402 - The buffer must not be modified.
 403 - The buffer file's timestamp must be the same as the file's on disk.
 404 - The on disk file's timestamp must be different than the buffer's cache.
 405 - Criteria imposed by `fast-lock-cache-directories'.
 406
 407 See `fast-lock-mode'."
 408   (interactive)
 409   (save-excursion
 410     (when buffer
 411       (set-buffer buffer))
 412     (let ((min-size (font-lock-value-in-major-mode fast-lock-minimum-size))
 413           (file-timestamp (visited-file-modtime)) (saved nil))
 414       (when (and fast-lock-mode
 415              ;;
 416              ;; "Only save if the buffer matches the file, the file has
 417              ;; changed, and it was changed by the current emacs session."
 418              ;;
 419              ;; Only save if the buffer is not modified,
 420              ;; (i.e., so we don't save for something not on disk)
 421              (not (buffer-modified-p))
 422              ;; and the file's timestamp is the same as the buffer's,
 423              ;; (i.e., someone else hasn't written the file in the meantime)
 424              (verify-visited-file-modtime (current-buffer))
 425              ;; and the file's timestamp is different from the cache's.
 426              ;; (i.e., a save has occurred since the cache was read)
 427              (not (equal fast-lock-cache-timestamp file-timestamp))
 428              ;;
 429              ;; Only save if user's restrictions are satisfied.
 430              (and min-size (>= (buffer-size) min-size))
 431              (or fast-lock-save-others
 432                  (eq (user-uid) (nth 2 (file-attributes buffer-file-name))))
 433              ;;
 434              ;; Only save if there are `face' properties to save.
 435              (text-property-not-all (point-min) (point-max) 'face nil))
 436         ;;
 437         ;; Try each directory until we manage to save or the user quits.
 438         (let ((directories fast-lock-cache-directories))
 439           (while (and directories (memq saved '(nil error)))
 440             (let* ((dir (fast-lock-cache-directory (car directories) t))
 441                    (file (and dir (fast-lock-cache-name dir))))
 442               (when (and file (file-writable-p file))
 443                 (setq saved (fast-lock-save-cache-1 file file-timestamp)))
 444               (setq directories (cdr directories)))))))))
 445
 446 ;;;###autoload
 447 (defun turn-on-fast-lock ()
 448   "Unconditionally turn on Fast Lock mode."
 449   (fast-lock-mode t))
 450 \f
 451 ;;; API Functions:
 452
 453 (defun fast-lock-after-fontify-buffer ()
 454   ;; Delete the Font Lock cache file used to restore fontification, if any.
 455   (when fast-lock-cache-filename
 456     (if (file-writable-p fast-lock-cache-filename)
 457         (delete-file fast-lock-cache-filename)
 458       (message "File %s font lock cache cannot be deleted" (buffer-name))))
 459   ;; Flag so that a cache will be saved later even if the file is never saved.
 460   (setq fast-lock-cache-timestamp nil))
 461
 462 (defalias 'fast-lock-after-unfontify-buffer
 463   'ignore)
 464 \f
 465 ;; Miscellaneous Functions:
 466
 467 (defun fast-lock-save-cache-after-save-file ()
 468   ;; Do `fast-lock-save-cache' if `save-buffer' is on `fast-lock-save-events'.
 469   (when (memq 'save-buffer fast-lock-save-events)
 470     (fast-lock-save-cache)))
 471
 472 (defun fast-lock-save-cache-before-kill-buffer ()
 473   ;; Do `fast-lock-save-cache' if `kill-buffer' is on `fast-lock-save-events'.
 474   (when (memq 'kill-buffer fast-lock-save-events)
 475     (fast-lock-save-cache)))
 476
 477 (defun fast-lock-save-caches-before-kill-emacs ()
 478   ;; Do `fast-lock-save-cache's if `kill-emacs' is on `fast-lock-save-events'.
 479   (when (memq 'kill-emacs fast-lock-save-events)
 480     (mapcar 'fast-lock-save-cache (buffer-list))))
 481
 482 (defun fast-lock-cache-directory (directory create)
 483   "Return usable directory based on DIRECTORY.
 484 Returns nil if the directory does not exist, or, if CREATE non-nil, cannot be
 485 created.  DIRECTORY may be a string or a cons pair of the form (REGEXP . DIR).
 486 See `fast-lock-cache-directories'."
 487   (let ((dir
 488          (cond ((not buffer-file-name)
 489                 ;; Should never be nil, but `crypt++' screws it up.
 490                 nil)
 491                ((stringp directory)
 492                 ;; Just a directory.
 493                 directory)
 494                (t
 495                 ;; A directory iff the file name matches the regexp.
 496                 (let ((bufile (expand-file-name buffer-file-truename))
 497                       (case-fold-search nil))
 498                   (when (save-match-data (string-match (car directory) bufile))
 499                     (cdr directory)))))))
 500     (cond ((not dir)
 501            nil)
 502           ((file-accessible-directory-p dir)
 503            dir)
 504           (create
 505            (condition-case nil
 506                (progn (make-directory dir t) dir)
 507              (error nil))))))
 508
 509 ;; If you are wondering why we only hash if the directory is not ".", rather
 510 ;; than if `file-name-absolute-p', it is because if we just appended ".flc" for
 511 ;; relative cache directories (that are not ".") then it is possible that more
 512 ;; than one file would have the same cache name in that directory, if the luser
 513 ;; made a link from one relative cache directory to another.  (Phew!)
 514 (defun fast-lock-cache-name (directory)
 515   "Return full cache path name using caching DIRECTORY.
 516 If DIRECTORY is `.', the path is the buffer file name appended with `.flc'.
 517 Otherwise, the path name is constructed from DIRECTORY and the buffer's true
 518 abbreviated file name, with all `/' characters in the name replaced with `#'
 519 characters, and appended with `.flc'.
 520
 521 If the same file has different cache path names when edited on different
 522 machines, e.g., on one machine the cache file name has the prefix `#home',
 523 perhaps due to automount, try putting in your `~/.emacs' something like:
 524
 525  (setq directory-abbrev-alist (cons '(\"^/home/\" . \"/\") directory-abbrev-alist))
 526
 527 Emacs automagically removes the common `/tmp_mnt' automount prefix by default.
 528
 529 See `fast-lock-cache-directory'."
 530   (if (string-equal directory ".")
 531       (concat buffer-file-name ".flc")
 532     (let* ((bufile (expand-file-name buffer-file-truename))
 533            (chars-alist
 534             (if (eq system-type 'emx)
 535                 '((?/ . (?#)) (?# . (?# ?#)) (?: . (?\;)) (?\; . (?\; ?\;)))
 536               '((?/ . (?#)) (?# . (?# ?#)))))
 537            (mapchars
 538             (function (lambda (c) (or (cdr (assq c chars-alist)) (list c))))))
 539       (concat
 540        (file-name-as-directory (expand-file-name directory))
 541        (mapconcat 'char-to-string (apply 'append (mapcar mapchars bufile)) "")
 542        ".flc"))))
 543 \f
 544 ;; Font Lock Cache Processing Functions:
 545
 546 (defun fast-lock-save-cache-1 (file timestamp)
 547   ;; Save the FILE with the TIMESTAMP as:
 548   ;; (fast-lock-cache-data Version=2 TIMESTAMP font-lock-keywords PROPERTIES).
 549   ;; Returns non-nil if a save was attempted to a writable cache file.
 550   (let ((tpbuf (generate-new-buffer " *fast-lock*"))
 551         (verbose (if (numberp fast-lock-verbose)
 552                      (> (buffer-size) fast-lock-verbose)
 553                    fast-lock-verbose))
 554         (saved t))
 555     (if verbose (message "Saving %s font lock cache..." (buffer-name)))
 556     (condition-case nil
 557         (save-excursion
 558           (print (list 'fast-lock-cache-data 2
 559                        (list 'quote timestamp)
 560                        (list 'quote font-lock-keywords)
 561                        (list 'quote (fast-lock-get-face-properties)))
 562                  tpbuf)
 563           (set-buffer tpbuf)
 564           (write-region (point-min) (point-max) file nil 'quietly)
 565           (setq fast-lock-cache-timestamp timestamp
 566                 fast-lock-cache-filename file))
 567       (error (setq saved 'error)) (quit (setq saved 'quit)))
 568     (kill-buffer tpbuf)
 569     (if verbose (message "Saving %s font lock cache...%s" (buffer-name)
 570                          (cond ((eq saved 'error) "failed")
 571                                ((eq saved 'quit) "aborted")
 572                                (t "done"))))
 573     ;; We return non-nil regardless of whether a failure occurred.
 574     saved))
 575
 576 (defun fast-lock-cache-data (version timestamp keywords properties
 577                              &rest ignored)
 578   ;; Change from (HIGH LOW) for back compatibility.  Remove for version 3!
 579   (when (consp (cdr-safe timestamp))
 580     (setcdr timestamp (nth 1 timestamp)))
 581   ;; Compile `font-lock-keywords' and KEYWORDS in case one is and one isn't.
 582   (setq font-lock-keywords (font-lock-compile-keywords font-lock-keywords)
 583         keywords (font-lock-compile-keywords keywords))
 584   ;; Use the Font Lock cache PROPERTIES if we're using cache VERSION format 2,
 585   ;; the current buffer's file timestamp matches the TIMESTAMP, and the current
 586   ;; buffer's font-lock-keywords are the same as KEYWORDS.
 587   (let ((buf-timestamp (visited-file-modtime))
 588         (verbose (if (numberp fast-lock-verbose)
 589                      (> (buffer-size) fast-lock-verbose)
 590                    fast-lock-verbose))
 591         (loaded t))
 592     (if (or (/= version 2)
 593             (buffer-modified-p)
 594             (not (equal timestamp buf-timestamp))
 595             (not (equal keywords font-lock-keywords)))
 596         (setq loaded nil)
 597       (if verbose (message "Loading %s font lock cache..." (buffer-name)))
 598       (condition-case nil
 599           (fast-lock-set-face-properties properties)
 600         (error (setq loaded 'error)) (quit (setq loaded 'quit)))
 601       (if verbose (message "Loading %s font lock cache...%s" (buffer-name)
 602                            (cond ((eq loaded 'error) "failed")
 603                                  ((eq loaded 'quit) "aborted")
 604                                  (t "done")))))
 605     (setq font-lock-fontified (eq loaded t)
 606           fast-lock-cache-timestamp (and (eq loaded t) timestamp))))
 607 \f
 608 ;; Text Properties Processing Functions:
 609
 610 ;; This is fast, but fails if adjacent characters have different `face' text
 611 ;; properties.  Maybe that's why I dropped it in the first place?
 612 ;(defun fast-lock-get-face-properties ()
 613 ;  "Return a list of all `face' text properties in the current buffer.
 614 ;Each element of the list is of the form (VALUE START1 END1 START2 END2 ...)
 615 ;where VALUE is a `face' property value and STARTx and ENDx are positions."
 616 ;  (save-restriction
 617 ;    (widen)
 618 ;    (let ((start (text-property-not-all (point-min) (point-max) 'face nil))
 619 ;         (limit (point-max)) end properties value cell)
 620 ;      (while start
 621 ;       (setq end (next-single-property-change start 'face nil limit)
 622 ;             value (get-text-property start 'face))
 623 ;       ;; Make, or add to existing, list of regions with same `face'.
 624 ;       (if (setq cell (assq value properties))
 625 ;           (setcdr cell (cons start (cons end (cdr cell))))
 626 ;         (setq properties (cons (list value start end) properties)))
 627 ;       (setq start (next-single-property-change end 'face)))
 628 ;      properties)))
 629
 630 ;; This is slow, but copes if adjacent characters have different `face' text
 631 ;; properties, but fails if they are lists.
 632 ;(defun fast-lock-get-face-properties ()
 633 ;  "Return a list of all `face' text properties in the current buffer.
 634 ;Each element of the list is of the form (VALUE START1 END1 START2 END2 ...)
 635 ;where VALUE is a `face' property value and STARTx and ENDx are positions.
 636 ;Only those `face' VALUEs in `fast-lock-save-faces' are returned."
 637 ;  (save-restriction
 638 ;    (widen)
 639 ;    (let ((faces (or fast-lock-save-faces (face-list))) (limit (point-max))
 640 ;         properties regions face start end)
 641 ;      (while faces
 642 ;       (setq face (car faces) faces (cdr faces) regions () end (point-min))
 643 ;       ;; Make a list of start/end regions with `face' property face.
 644 ;       (while (setq start (text-property-any end limit 'face face))
 645 ;         (setq end (or (text-property-not-all start limit 'face face) limit)
 646 ;               regions (cons start (cons end regions))))
 647 ;       ;; Add `face' face's regions, if any, to properties.
 648 ;       (when regions
 649 ;         (push (cons face regions) properties)))
 650 ;      properties)))
 651
 652 (defun fast-lock-get-face-properties ()
 653   "Return a list of all `face' text properties in the current buffer.
 654 Each element of the list is of the form (VALUE START1 END1 START2 END2 ...)
 655 where VALUE is a `face' property value and STARTx and ENDx are positions."
 656   (save-restriction
 657     (widen)
 658     (let ((start (text-property-not-all (point-min) (point-max) 'face nil))
 659           end properties value cell)
 660       (while start
 661         (setq end (next-single-property-change start 'face nil (point-max))
 662               value (get-text-property start 'face))
 663         ;; Make, or add to existing, list of regions with same `face'.
 664         (cond ((setq cell (assoc value properties))
 665                (setcdr cell (cons start (cons end (cdr cell)))))
 666               ((fast-lock-save-facep value)
 667                (push (list value start end) properties)))
 668         (setq start (text-property-not-all end (point-max) 'face nil)))
 669       properties)))
 670
 671 (defun fast-lock-set-face-properties (properties)
 672   "Set all `face' text properties to PROPERTIES in the current buffer.
 673 Any existing `face' text properties are removed first.
 674 See `fast-lock-get-face-properties' for the format of PROPERTIES."
 675   (save-buffer-state (plist regions)
 676     (save-restriction
 677       (widen)
 678       (font-lock-unfontify-region (point-min) (point-max))
 679       (while properties
 680         (setq plist (list 'face (car (car properties)))
 681               regions (cdr (car properties))
 682               properties (cdr properties))
 683         ;; Set the `face' property for each start/end region.
 684         (while regions
 685           (set-text-properties (nth 0 regions) (nth 1 regions) plist)
 686           (setq regions (nthcdr 2 regions)))))))
 687 \f
 688 ;; Functions for XEmacs:
 689
 690 (when (save-match-data (string-match "XEmacs" (emacs-version)))
 691   ;;
 692   ;; It would be better to use XEmacs' `map-extents' over extents with a
 693   ;; `font-lock' property, but `face' properties are on different extents.
 694   (defun fast-lock-get-face-properties ()
 695     "Return a list of all `face' text properties in the current buffer.
 696 Each element of the list is of the form (VALUE START1 END1 START2 END2 ...)
 697 where VALUE is a `face' property value and STARTx and ENDx are positions.
 698 Only those `face' VALUEs in `fast-lock-save-faces' are returned."
 699     (save-restriction
 700       (widen)
 701       (let ((properties ()) cell)
 702         (map-extents
 703          (function (lambda (extent ignore)
 704             (let ((value (extent-face extent)))
 705               ;; We're only interested if it's one of `fast-lock-save-faces'.
 706               (when (and value (fast-lock-save-facep value))
 707                 (let ((start (extent-start-position extent))
 708                       (end (extent-end-position extent)))
 709                   ;; Make or add to existing list of regions with the same
 710                   ;; `face' property value.
 711                   (if (setq cell (assoc value properties))
 712                       (setcdr cell (cons start (cons end (cdr cell))))
 713                     (push (list value start end) properties))))
 714               ;; Return nil to keep `map-extents' going.
 715               nil))))
 716         properties)))
 717   ;;
 718   ;; Make extents just like XEmacs' font-lock.el does.
 719   (defun fast-lock-set-face-properties (properties)
 720     "Set all `face' text properties to PROPERTIES in the current buffer.
 721 Any existing `face' text properties are removed first.
 722 See `fast-lock-get-face-properties' for the format of PROPERTIES."
 723     (save-restriction
 724       (widen)
 725       (font-lock-unfontify-region (point-min) (point-max))
 726       (while properties
 727         (let ((face (car (car properties)))
 728               (regions (cdr (car properties))))
 729           ;; Set the `face' property, etc., for each start/end region.
 730           (while regions
 731             (font-lock-set-face (nth 0 regions) (nth 1 regions) face)
 732             (setq regions (nthcdr 2 regions)))
 733           (setq properties (cdr properties))))))
 734   ;;
 735   ;; XEmacs 19.12 font-lock.el's `font-lock-fontify-buffer' runs a hook.
 736   (add-hook 'font-lock-after-fontify-buffer-hook
 737             'fast-lock-after-fontify-buffer))
 738
 739 (unless (boundp 'font-lock-inhibit-thing-lock)
 740   (defvar font-lock-inhibit-thing-lock nil
 741     "List of Font Lock mode related modes that should not be turned on."))
 742
 743 (unless (fboundp 'font-lock-value-in-major-mode)
 744   (defun font-lock-value-in-major-mode (alist)
 745     ;; Return value in ALIST for `major-mode'.
 746     (if (consp alist)
 747         (cdr (or (assq major-mode alist) (assq t alist)))
 748       alist)))
 749
 750 (unless (fboundp 'font-lock-compile-keywords)
 751   (defalias 'font-lock-compile-keywords 'identity))
 752 \f
 753 ;; Install ourselves:
 754
 755 (add-hook 'after-save-hook 'fast-lock-save-cache-after-save-file)
 756 (add-hook 'kill-buffer-hook 'fast-lock-save-cache-before-kill-buffer)
 757 (add-hook 'kill-emacs-hook 'fast-lock-save-caches-before-kill-emacs)
 758
 759 ;;;###autoload
 760 (when (fboundp 'add-minor-mode)
 761   (defvar fast-lock-mode nil)
 762   (add-minor-mode 'fast-lock-mode nil))
 763 ;;;###dont-autoload
 764 (unless (assq 'fast-lock-mode minor-mode-alist)
 765   (setq minor-mode-alist (append minor-mode-alist '((fast-lock-mode nil)))))
 766
 767 ;; Provide ourselves:
 768
 769 (provide 'fast-lock)
 770
 771 ;;; fast-lock.el ends here