code.delx.au - gnu-emacs/blob - lisp/timezone.el

   1 ;;; timezone.el --- time zone package for GNU Emacs
   2
   3 ;; Copyright (C) 1990, 1991, 1992, 1993, 1996 Free Software Foundation, Inc.
   4
   5 ;; Author: Masanobu Umeda
   6 ;; Maintainer: umerin@mse.kyutech.ac.jp
   7 ;; Keywords: news
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Code:
  27
  28 (provide 'timezone)
  29
  30 (defvar timezone-world-timezones
  31   '(("PST" .  -800)
  32     ("PDT" .  -700)
  33     ("MST" .  -700)
  34     ("MDT" .  -600)
  35     ("CST" .  -600)
  36     ("CDT" .  -500)
  37     ("EST" .  -500)
  38     ("EDT" .  -400)
  39     ("AST" .  -400)                     ;by <clamen@CS.CMU.EDU>
  40     ("NST" .  -330)                     ;by <clamen@CS.CMU.EDU>
  41     ("UT"  .  +000)
  42     ("GMT" .  +000)
  43     ("BST" .  +100)
  44     ("MET" .  +100)
  45     ("EET" .  +200)
  46     ("JST" .  +900)
  47     ("GMT+1"  .  +100) ("GMT+2"  .  +200) ("GMT+3"  .  +300)
  48     ("GMT+4"  .  +400) ("GMT+5"  .  +500) ("GMT+6"  .  +600)
  49     ("GMT+7"  .  +700) ("GMT+8"  .  +800) ("GMT+9"  .  +900)
  50     ("GMT+10" . +1000) ("GMT+11" . +1100) ("GMT+12" . +1200) ("GMT+13" . +1300)
  51     ("GMT-1"  .  -100) ("GMT-2"  .  -200) ("GMT-3"  .  -300)
  52     ("GMT-4"  .  -400) ("GMT-5"  .  -500) ("GMT-6"  .  -600)
  53     ("GMT-7"  .  -700) ("GMT-8"  .  -800) ("GMT-9"  .  -900)
  54     ("GMT-10" . -1000) ("GMT-11" . -1100) ("GMT-12" . -1200))
  55   "*Time differentials of timezone from GMT in +-HHMM form.
  56 This list is obsolescent, and is present only for backwards compatibility,
  57 because time zone names are ambiguous in practice.
  58 Use `current-time-zone' instead.")
  59
  60 (defvar timezone-months-assoc
  61   '(("JAN" .  1)("FEB" .  2)("MAR" .  3)
  62     ("APR" .  4)("MAY" .  5)("JUN" .  6)
  63     ("JUL" .  7)("AUG" .  8)("SEP" .  9)
  64     ("OCT" . 10)("NOV" . 11)("DEC" . 12))
  65   "Alist of first three letters of a month and its numerical representation.")
  66
  67 (defun timezone-make-date-arpa-standard (date &optional local timezone)
  68   "Convert DATE to an arpanet standard date.
  69 Optional 1st argument LOCAL specifies the default local timezone of the DATE;
  70 if nil, GMT is assumed.
  71 Optional 2nd argument TIMEZONE specifies a time zone to be represented in;
  72 if nil, the local time zone is assumed."
  73   (let ((new (timezone-fix-time date local timezone)))
  74     (timezone-make-arpa-date (aref new 0) (aref new 1) (aref new 2)
  75                              (timezone-make-time-string
  76                               (aref new 3) (aref new 4) (aref new 5))
  77                              (aref new 6))
  78     ))
  79
  80 (defun timezone-make-date-sortable (date &optional local timezone)
  81   "Convert DATE to a sortable date string.
  82 Optional 1st argument LOCAL specifies the default local timezone of the DATE;
  83 if nil, GMT is assumed.
  84 Optional 2nd argument TIMEZONE specifies a timezone to be represented in;
  85 if nil, the local time zone is assumed."
  86   (let ((new (timezone-fix-time date local timezone)))
  87     (timezone-make-sortable-date (aref new 0) (aref new 1) (aref new 2)
  88                                  (timezone-make-time-string
  89                                   (aref new 3) (aref new 4) (aref new 5)))
  90     ))
  91
  92 \f
  93 ;;
  94 ;; Parsers and Constructors of Date and Time
  95 ;;
  96
  97 (defun timezone-make-arpa-date (year month day time &optional timezone)
  98   "Make arpanet standard date string from YEAR, MONTH, DAY, and TIME.
  99 Optional argument TIMEZONE specifies a time zone."
 100   (let ((zone
 101          (if (listp timezone)
 102              (let* ((m (timezone-zone-to-minute timezone))
 103                     (absm (if (< m 0) (- m) m)))
 104                (format "%c%02d%02d"
 105                        (if (< m 0) ?- ?+) (/ absm 60) (% absm 60)))
 106            timezone)))
 107     (format "%02d %s %04d %s %s"
 108             day
 109             (capitalize (car (rassq month timezone-months-assoc)))
 110             year
 111             time
 112             zone)))
 113
 114 (defun timezone-make-sortable-date (year month day time)
 115   "Make sortable date string from YEAR, MONTH, DAY, and TIME."
 116   (format "%4d%02d%02d%s"
 117           year month day time))
 118
 119 (defun timezone-make-time-string (hour minute second)
 120   "Make time string from HOUR, MINUTE, and SECOND."
 121   (format "%02d:%02d:%02d" hour minute second))
 122
 123 (defun timezone-parse-date (date)
 124   "Parse DATE and return a vector [YEAR MONTH DAY TIME TIMEZONE].
 125 19 is prepended to year if necessary.  Timezone may be nil if nothing.
 126 Understands the following styles:
 127  (1) 14 Apr 89 03:20[:12] [GMT]
 128  (2) Fri, 17 Mar 89 4:01[:33] [GMT]
 129  (3) Mon Jan 16 16:12[:37] [GMT] 1989
 130  (4) 6 May 1992 1641-JST (Wednesday)
 131  (5) 22-AUG-1993 10:59:12.82
 132  (6) Thu, 11 Apr 16:17:12 91 [MET]
 133  (7) Mon, 6  Jul 16:47:20 T 1992 [MET]
 134  (8) 1996-06-24 21:13:12 [GMT]"
 135  ;; Get rid of any text properties.
 136   (and (stringp date)
 137        (or (text-properties-at 0 date)
 138            (next-property-change 0 date))
 139        (setq date (copy-sequence date))
 140        (set-text-properties 0 (length date) nil date))
 141   (let ((date (or date ""))
 142         (year nil)
 143         (month nil)
 144         (day nil)
 145         (time nil)
 146         (zone nil))                     ;This may be nil.
 147     (cond ((string-match
 148             "\\([^ \t,]+\\),[ \t]+\\([0-9]+\\)[ \t]+\\([^ \t,]+\\)[ \t]+\\([0-9]+:[0-9:]+\\)[ \t]+\\(T[ \t]+\\|\\)\\([0-9]+\\)[ \t]*\\'" date)
 149            ;; Styles: (6) and (7) without timezone
 150            (setq year 6 month 3 day 2 time 4 zone nil))
 151           ((string-match
 152             "\\([^ \t,]+\\),[ \t]+\\([0-9]+\\)[ \t]+\\([^ \t,]+\\)[ \t]+\\([0-9]+:[0-9:]+\\)[ \t]+\\(T[ \t]+\\|\\)\\([0-9]+\\)[ \t]*\\([-+a-zA-Z0-9]+\\)" date)
 153            ;; Styles: (6) and (7) with timezone and buggy timezone
 154            (setq year 6 month 3 day 2 time 4 zone 7))
 155           ((string-match
 156             "\\([0-9]+\\)[ \t]+\\([^ \t,]+\\)[ \t]+\\([0-9]+\\)[ \t]+\\([0-9]+:[0-9:]+\\)[ \t]*\\'" date)
 157            ;; Styles: (1) and (2) without timezone
 158            (setq year 3 month 2 day 1 time 4 zone nil))
 159           ((string-match
 160             "\\([0-9]+\\)[ \t]+\\([^ \t,]+\\)[ \t]+\\([0-9]+\\)[ \t]+\\([0-9]+:[0-9:]+\\)[ \t]*\\([-+a-zA-Z0-9]+\\)" date)
 161            ;; Styles: (1) and (2) with timezone and buggy timezone
 162            (setq year 3 month 2 day 1 time 4 zone 5))
 163           ((string-match
 164             "\\([^ \t,]+\\)[ \t]+\\([0-9]+\\)[ \t]+\\([0-9]+:[0-9:]+\\)[ \t]+\\([0-9]+\\)" date)
 165            ;; Styles: (3) without timezone
 166            (setq year 4 month 1 day 2 time 3 zone nil))
 167           ((string-match
 168             "\\([^ \t,]+\\)[ \t]+\\([0-9]+\\)[ \t]+\\([0-9]+:[0-9:]+\\)[ \t]+\\([-+a-zA-Z0-9]+\\)[ \t]+\\([0-9]+\\)" date)
 169            ;; Styles: (3) with timezone
 170            (setq year 5 month 1 day 2 time 3 zone 4))
 171           ((string-match
 172             "\\([0-9]+\\)[ \t]+\\([^ \t,]+\\)[ \t]+\\([0-9]+\\)[ \t]+\\([0-9]+\\)[ \t]*\\([-+a-zA-Z0-9]+\\)" date)
 173            ;; Styles: (4) with timezone
 174            (setq year 3 month 2 day 1 time 4 zone 5))
 175           ((string-match
 176             "\\([0-9]+\\)-\\([A-Za-z]+\\)-\\([0-9]+\\)[ \t]+\\([0-9]+:[0-9]+:[0-9]+\\)\\.[0-9]+" date)
 177            ;; Styles: (5) without timezone.
 178            (setq year 3 month 2 day 1 time 4 zone nil))
 179           ((string-match
 180             "\\([0-9]+\\)-\\([0-9]+\\)-\\([0-9]+\\)[ \t]+\\([0-9]+:[0-9]+:[0-9]+\\)[ \t]*\\([-+a-zA-Z0-9]+\\)" date)
 181            ;; Styles: (8) with timezone.
 182            (setq year 1 month 2 day 3 time 4 zone 5))
 183           ((string-match
 184             "\\([0-9]+\\)-\\([0-9]+\\)-\\([0-9]+\\)[ \t]+\\([0-9]+:[0-9]+:[0-9]+\\)" date)
 185            ;; Styles: (8) without timezone.
 186            (setq year 1 month 2 day 3 time 4 zone nil))
 187           )
 188     (if year
 189         (progn
 190           (setq year
 191                 (substring date (match-beginning year) (match-end year)))
 192           ;; It is now Dec 1992.  8 years before the end of the World.
 193           (if (= (length year) 1)
 194               (setq year (concat "190" (substring year -1 nil)))
 195             (if (< (length year) 4)
 196                 (setq year (concat "19" (substring year -2 nil)))))
 197           (setq month
 198                 (if (= (aref date (+ (match-beginning month) 2)) ?-)
 199                     ;; Handle numeric months, spanning exactly two digits.
 200                     (substring date
 201                                (match-beginning month)
 202                                (+ (match-beginning month) 2))
 203                   (let* ((string (substring date
 204                                             (match-beginning month)
 205                                             (+ (match-beginning month) 3)))
 206                          (monthnum
 207                           (cdr (assoc (upcase string) timezone-months-assoc))))
 208                     (if monthnum
 209                         (int-to-string monthnum)
 210                       nil))))
 211           (setq day
 212                 (substring date (match-beginning day) (match-end day)))
 213           (setq time
 214                 (substring date (match-beginning time) (match-end time)))))
 215     (if zone
 216         (setq zone
 217               (substring date (match-beginning zone) (match-end zone))))
 218     ;; Return a vector.
 219     (if (and year month)
 220         (vector year month day time zone)
 221       (vector "0" "0" "0" "0" nil))
 222     ))
 223
 224 (defun timezone-parse-time (time)
 225   "Parse TIME (HH:MM:SS) and return a vector [hour minute second].
 226 Recognize HH:MM:SS, HH:MM, HHMMSS, HHMM."
 227   (let ((time (or time ""))
 228         (hour nil)
 229         (minute nil)
 230         (second nil))
 231     (cond ((string-match "\\`\\([0-9]+\\):\\([0-9]+\\):\\([0-9]+\\)\\'" time)
 232            ;; HH:MM:SS
 233            (setq hour 1 minute 2 second 3))
 234           ((string-match "\\`\\([0-9]+\\):\\([0-9]+\\)\\'" time)
 235            ;; HH:MM
 236            (setq hour 1 minute 2 second nil))
 237           ((string-match "\\`\\([0-9][0-9]\\)\\([0-9][0-9]\\)\\([0-9][0-9]\\)\\'" time)
 238            ;; HHMMSS
 239            (setq hour 1 minute 2 second 3))
 240           ((string-match "\\`\\([0-9][0-9]\\)\\([0-9][0-9]\\)\\'" time)
 241            ;; HHMM
 242            (setq hour 1 minute 2 second nil))
 243           )
 244     ;; Return [hour minute second]
 245     (vector
 246      (if hour
 247          (substring time (match-beginning hour) (match-end hour)) "0")
 248      (if minute
 249          (substring time (match-beginning minute) (match-end minute)) "0")
 250      (if second
 251          (substring time (match-beginning second) (match-end second)) "0"))
 252     ))
 253
 254 \f
 255 ;; Miscellaneous
 256
 257 (defun timezone-zone-to-minute (timezone)
 258   "Translate TIMEZONE to an integer minute offset from GMT.
 259 TIMEZONE can be a cons cell containing the output of current-time-zone,
 260 or an integer of the form +-HHMM, or a time zone name."
 261   (cond
 262      ((consp timezone)
 263       (/ (car timezone) 60))
 264      (timezone
 265       (progn
 266         (setq timezone
 267               (or (cdr (assoc (upcase timezone) timezone-world-timezones))
 268                   ;; +900
 269                   timezone))
 270         (if (stringp timezone)
 271             (setq timezone (string-to-int timezone)))
 272         ;; Taking account of minute in timezone.
 273         ;; HHMM -> MM
 274         (let* ((abszone (abs timezone))
 275                (minutes (+ (* 60 (/ abszone 100)) (% abszone 100))))
 276           (if (< timezone 0) (- minutes) minutes))))
 277      (t 0)))
 278
 279 (defun timezone-time-from-absolute (date seconds)
 280   "Compute the UTC time equivalent to DATE at time SECONDS after midnight.
 281 Return a list suitable as an argument to current-time-zone,
 282 or nil if the date cannot be thus represented.
 283 DATE is the number of days elapsed since the (imaginary)
 284 Gregorian date Sunday, December 31, 1 BC."
 285   (let* ((current-time-origin 719163)
 286             ;; (timezone-absolute-from-gregorian 1 1 1970)
 287          (days (- date current-time-origin))
 288          (seconds-per-day (float 86400))
 289          (seconds (+ seconds (* days seconds-per-day)))
 290          (current-time-arithmetic-base (float 65536))
 291          (hi (floor (/ seconds current-time-arithmetic-base)))
 292          (hibase (* hi current-time-arithmetic-base))
 293          (lo (floor (- seconds hibase))))
 294      (and (< (abs (- seconds (+ hibase lo))) 2) ;; Check for integer overflow.
 295           (cons hi lo))))
 296
 297 (defun timezone-time-zone-from-absolute (date seconds)
 298   "Compute the local time zone for DATE at time SECONDS after midnight.
 299 Return a list in the same format as current-time-zone's result,
 300 or nil if the local time zone could not be computed.
 301 DATE is the number of days elapsed since the (imaginary)
 302 Gregorian date Sunday, December 31, 1 BC."
 303    (and (fboundp 'current-time-zone)
 304         (let ((utc-time (timezone-time-from-absolute date seconds)))
 305           (and utc-time
 306                (let ((zone (current-time-zone utc-time)))
 307                  (and (car zone) zone))))))
 308
 309 (defun timezone-fix-time (date local timezone)
 310   "Convert DATE (default timezone LOCAL) to YYYY-MM-DD-HH-MM-SS-ZONE vector.
 311 If LOCAL is nil, it is assumed to be GMT.
 312 If TIMEZONE is nil, use the local time zone."
 313   (let* ((date   (timezone-parse-date date))
 314          (year   (string-to-int (aref date 0)))
 315          (year   (cond ((< year 50)
 316                         (+ year 2000))
 317                        ((< year 100)
 318                         (+ year 1900))
 319                        (t year)))
 320          (month  (string-to-int (aref date 1)))
 321          (day    (string-to-int (aref date 2)))
 322          (time   (timezone-parse-time (aref date 3)))
 323          (hour   (string-to-int (aref time 0)))
 324          (minute (string-to-int (aref time 1)))
 325          (second (string-to-int (aref time 2)))
 326          (local  (or (aref date 4) local)) ;Use original if defined
 327          (timezone
 328           (or timezone
 329               (timezone-time-zone-from-absolute
 330                (timezone-absolute-from-gregorian month day year)
 331                (+ second (* 60 (+ minute (* 60 hour)))))))
 332          (diff   (- (timezone-zone-to-minute timezone)
 333                     (timezone-zone-to-minute local)))
 334          (minute (+ minute diff))
 335          (hour-fix (floor minute 60)))
 336     (setq hour (+ hour hour-fix))
 337     (setq minute (- minute (* 60 hour-fix)))
 338     ;; HOUR may be larger than 24 or smaller than 0.
 339     (cond ((<= 24 hour)                 ;24 -> 00
 340            (setq hour (- hour 24))
 341            (setq day  (1+ day))
 342            (if (< (timezone-last-day-of-month month year) day)
 343                (progn
 344                  (setq month (1+ month))
 345                  (setq day 1)
 346                  (if (< 12 month)
 347                      (progn
 348                        (setq month 1)
 349                        (setq year (1+ year))
 350                        ))
 351                  )))
 352           ((> 0 hour)
 353            (setq hour (+ hour 24))
 354            (setq day  (1- day))
 355            (if (> 1 day)
 356                (progn
 357                  (setq month (1- month))
 358                  (if (> 1 month)
 359                      (progn
 360                        (setq month 12)
 361                        (setq year (1- year))
 362                        ))
 363                  (setq day (timezone-last-day-of-month month year))
 364                  )))
 365           )
 366     (vector year month day hour minute second timezone)))
 367
 368 ;; Partly copied from Calendar program by Edward M. Reingold.
 369 ;; Thanks a lot.
 370
 371 (defun timezone-last-day-of-month (month year)
 372   "The last day in MONTH during YEAR."
 373   (if (and (= month 2) (timezone-leap-year-p year))
 374       29
 375     (aref [31 28 31 30 31 30 31 31 30 31 30 31] (1- month))))
 376
 377 (defun timezone-leap-year-p (year)
 378   "Returns t if YEAR is a Gregorian leap year."
 379   (or (and (zerop  (% year 4))
 380            (not (zerop (% year 100))))
 381       (zerop (% year 400))))
 382
 383 (defun timezone-day-number (month day year)
 384   "Return the day number within the year of the date month/day/year."
 385   (let ((day-of-year (+ day (* 31 (1- month)))))
 386     (if (> month 2)
 387         (progn
 388           (setq day-of-year (- day-of-year (/ (+ 23 (* 4 month)) 10)))
 389           (if (timezone-leap-year-p year)
 390               (setq day-of-year (1+ day-of-year)))))
 391     day-of-year))
 392
 393 (defun timezone-absolute-from-gregorian (month day year)
 394   "The number of days between the Gregorian date 12/31/1 BC and month/day/year.
 395 The Gregorian date Sunday, December 31, 1 BC is imaginary."
 396   (+ (timezone-day-number month day year);; Days this year
 397      (* 365 (1- year));;        + Days in prior years
 398      (/ (1- year) 4);;          + Julian leap years
 399      (- (/ (1- year) 100));;    - century years
 400      (/ (1- year) 400)));;      + Gregorian leap years
 401
 402 ;;; timezone.el ends here