code.delx.au - gnu-emacs/blob - lisp/tooltip.el

   1 ;;; tooltip.el --- show tooltip windows
   2
   3 ;; Copyright (C) 1997, 1999, 2000, 2001 Free Software Foundation, Inc.
   4
   5 ;; Author: Gerd Moellmann <gerd@acm.org>
   6 ;; Keywords: help c mouse tools
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;;; Code:
  28
  29 (eval-when-compile
  30   (require 'cl)
  31   (require 'comint)
  32   (require 'gud))
  33
  34 (provide 'tooltip)
  35
  36 \f
  37 ;;; Customizable settings
  38
  39 (defgroup tooltip nil
  40   "Customization group for the `tooltip' package."
  41   :group 'help
  42   :group 'gud
  43   :group 'mouse
  44   :group 'tools
  45   :version "21.1"
  46   :tag "Tool Tips")
  47
  48 (defvar tooltip-mode)
  49
  50 (defcustom tooltip-delay 0.7
  51   "Seconds to wait before displaying a tooltip the first time."
  52   :tag "Delay"
  53   :type 'number
  54   :group 'tooltip)
  55
  56
  57 (defcustom tooltip-short-delay 0.1
  58   "Seconds to wait between subsequent tooltips on different items."
  59   :tag "Short delay"
  60   :type 'number
  61   :group 'tooltip)
  62
  63
  64 (defcustom tooltip-recent-seconds 1
  65   "Display tooltips if changing tip items within this many seconds.
  66 Do so after `tooltip-short-delay'."
  67   :tag "Recent seconds"
  68   :type 'number
  69   :group 'tooltip)
  70
  71
  72 (defcustom tooltip-hide-delay 10
  73   "Hide tooltips automatically after this many seconds."
  74   :tag "Hide delay"
  75   :type 'number
  76   :group 'tooltip)
  77
  78
  79 (defcustom tooltip-x-offset nil
  80   "X offset, in pixels, for the display of tooltips.
  81 The offset is relative to the position of the mouse.  It must
  82 be chosen so that the tooltip window doesn't contain the mouse
  83 when it pops up.  If the value is nil, the default offset is 5
  84 pixels.
  85
  86 If `tooltip-frame-parameters' includes the `left' parameter,
  87 the value of `tooltip-x-offset' is ignored."
  88   :tag "X offset"
  89   :type '(choice (const :tag "Default" nil)
  90                  (integer :tag "Offset" :value 1))
  91   :group 'tooltip)
  92
  93
  94 (defcustom tooltip-y-offset nil
  95   "Y offset, in pixels, for the display of tooltips.
  96 The offset is relative to the position of the mouse.  It must
  97 be chosen so that the tooltip window doesn't contain the mouse
  98 when it pops up.  If the value is nil, the default offset is -10
  99 pixels.
 100
 101 If `tooltip-frame-parameters' includes the `top' parameter,
 102 the value of `tooltip-y-offset' is ignored."
 103   :tag "Y offset"
 104   :type '(choice (const :tag "Default" nil)
 105                  (integer :tag "Offset" :value 1))
 106   :group 'tooltip)
 107
 108
 109 (defcustom tooltip-frame-parameters
 110   '((name . "tooltip")
 111     (internal-border-width . 5)
 112     (border-width . 1))
 113   "Frame parameters used for tooltips.
 114
 115 If `left' or `top' parameters are included, they specify the absolute
 116 position to pop up the tooltip."
 117   :type 'sexp
 118   :tag "Frame Parameters"
 119   :group 'tooltip)
 120
 121
 122 (defface tooltip
 123   '((((class color))
 124      (:background "lightyellow" :foreground "black"))
 125     (t ()))
 126   "Face for tooltips."
 127   :group 'tooltip)
 128
 129
 130 (defcustom tooltip-gud-tips-p nil
 131   "*Non-nil means show tooltips in GUD sessions."
 132   :type 'boolean
 133   :tag "GUD"
 134   :set #'(lambda (symbol on)
 135            (setq tooltip-gud-tips-p on)
 136            (if on (tooltip-gud-tips-setup)))
 137   :group 'tooltip)
 138
 139
 140 (defcustom tooltip-gud-modes '(gud-mode c-mode c++-mode)
 141   "List of modes for which to enable GUD tips."
 142   :type 'sexp
 143   :tag "GUD modes"
 144   :group 'tooltip)
 145
 146
 147 (defcustom tooltip-gud-display
 148   '((eq (tooltip-event-buffer tooltip-gud-event)
 149         (marker-buffer overlay-arrow-position)))
 150   "List of forms determining where GUD tooltips are displayed.
 151
 152 Forms in the list are combined with AND.  The default is to display
 153 only tooltips in the buffer containing the overlay arrow."
 154   :type 'sexp
 155   :tag "GUD buffers predicate"
 156   :group 'tooltip)
 157
 158
 159 (defcustom tooltip-use-echo-area nil
 160   "Use the echo area instead of tooltip frames.
 161 This is only relevant GUD display, since otherwise it is equivalent to
 162 turning off Tooltip mode."
 163   :type 'boolean
 164   :tag "Use echo area"
 165   :group 'tooltip)
 166
 167 \f
 168 ;;; Variables that are not customizable.
 169
 170 (defvar tooltip-hook nil
 171   "Functions to call to display tooltips.
 172 Each function is called with one argument EVENT which is a copy of
 173 the last mouse movement event that occurred.")
 174
 175
 176 (defvar tooltip-timeout-id nil
 177   "The id of the timeout started when Emacs becomes idle.")
 178
 179
 180 (defvar tooltip-last-mouse-motion-event nil
 181   "A copy of the last mouse motion event seen.")
 182
 183
 184 (defvar tooltip-hide-time nil
 185   "Time when the last tooltip was hidden.")
 186
 187
 188 (defvar tooltip-gud-debugger nil
 189   "The debugger for which we show tooltips.")
 190
 191
 192 \f
 193 ;;; Event accessors
 194
 195 (defun tooltip-event-buffer (event)
 196   "Return the buffer over which event EVENT occurred.
 197 This might return nil if the event did not occur over a buffer."
 198   (let ((window (posn-window (event-end event))))
 199     (and window (window-buffer window))))
 200
 201
 202 \f
 203 ;;; Switching tooltips on/off
 204
 205 ;; We don't set track-mouse globally because this is a big redisplay
 206 ;; problem in buffers having a pre-command-hook or such installed,
 207 ;; which does a set-buffer, like the summary buffer of Gnus.  Calling
 208 ;; set-buffer prevents redisplay optimizations, so every mouse motion
 209 ;; would be accompanied by a full redisplay.
 210
 211 ;;;###autoload
 212 (defun tooltip-mode (&optional arg)
 213   "Mode for tooltip display.
 214 With ARG, turn tooltip mode on if and only if ARG is positive."
 215   (interactive "P")
 216   (unless (fboundp 'x-show-tip)
 217     (error "Sorry, tooltips are not yet available on this system"))
 218   (let* ((on (if arg
 219                  (> (prefix-numeric-value arg) 0)
 220                (not tooltip-mode)))
 221          (hook-fn (if on 'add-hook 'remove-hook)))
 222     (setq tooltip-mode on)
 223     (funcall hook-fn 'change-major-mode-hook 'tooltip-change-major-mode)
 224     (tooltip-activate-mouse-motions-if-enabled)
 225     (funcall hook-fn 'pre-command-hook 'tooltip-hide)
 226     (funcall hook-fn 'tooltip-hook 'tooltip-gud-tips)
 227     (funcall hook-fn 'tooltip-hook 'tooltip-help-tips)
 228     (setq show-help-function (if on 'tooltip-show-help-function nil))
 229     ;; `ignore' is the default binding for mouse movements.
 230     (define-key global-map [mouse-movement]
 231       (if on 'tooltip-mouse-motion 'ignore))
 232     (tooltip-gud-tips-setup)))
 233
 234 (defun tooltip-gud-tips-setup ()
 235   "Setup debugger mode-hooks for tooltips."
 236   (when (and tooltip-mode tooltip-gud-tips-p)
 237     (global-set-key [S-mouse-3] 'tooltip-gud-toggle-dereference)
 238     (add-hook 'gdb-mode-hook
 239               #'(lambda () (setq tooltip-gud-debugger 'gdb)))
 240     (add-hook 'sdb-mode-hook
 241               #'(lambda () (setq tooltip-gud-debugger 'sdb)))
 242     (add-hook 'dbx-mode-hook
 243               #'(lambda () (setq tooltip-gud-debugger 'dbx)))
 244     (add-hook 'xdb-mode-hook
 245               #'(lambda () (setq tooltip-gud-debugger 'xdb)))
 246     (add-hook 'perldb-mode-hook
 247               #'(lambda () (setq tooltip-gud-debugger 'perldb)))))
 248 \f
 249 ;;; Timeout for tooltip display
 250
 251 (defun tooltip-delay ()
 252   "Return the delay in seconds for the next tooltip."
 253   (let ((delay tooltip-delay)
 254         (now (float-time)))
 255     (when (and tooltip-hide-time
 256                (< (- now tooltip-hide-time) tooltip-recent-seconds))
 257       (setq delay tooltip-short-delay))
 258     delay))
 259
 260
 261 (defun tooltip-cancel-delayed-tip ()
 262   "Disable the tooltip timeout."
 263   (when tooltip-timeout-id
 264     (disable-timeout tooltip-timeout-id)
 265     (setq tooltip-timeout-id nil)))
 266
 267
 268 (defun tooltip-start-delayed-tip ()
 269   "Add a one-shot timeout to call function tooltip-timeout."
 270   (setq tooltip-timeout-id
 271         (add-timeout (tooltip-delay) 'tooltip-timeout nil)))
 272
 273
 274 (defun tooltip-timeout (object)
 275   "Function called when timer with id tooltip-timeout-id fires."
 276   (run-hook-with-args-until-success 'tooltip-hook
 277                                     tooltip-last-mouse-motion-event))
 278
 279
 280 \f
 281 ;;; Reacting on mouse movements
 282
 283 (defun tooltip-change-major-mode ()
 284   "Function added to `change-major-mode-hook' when tooltip mode is on."
 285   (add-hook 'post-command-hook 'tooltip-activate-mouse-motions-if-enabled))
 286
 287
 288 (defun tooltip-activate-mouse-motions-if-enabled ()
 289   "Reconsider for all buffers whether mouse motion events are desired."
 290   (remove-hook 'post-command-hook 'tooltip-activate-mouse-motions-if-enabled)
 291   (let ((buffers (buffer-list)))
 292     (save-excursion
 293       (while buffers
 294         (set-buffer (car buffers))
 295         (if (and tooltip-mode
 296                  tooltip-gud-tips-p
 297                  (memq major-mode tooltip-gud-modes))
 298             (tooltip-activate-mouse-motions t)
 299           (tooltip-activate-mouse-motions nil))
 300         (setq buffers (cdr buffers))))))
 301
 302 (defvar tooltip-mouse-motions-active nil
 303   "Locally t in a buffer if tooltip processing of mouse motion is enabled.")
 304
 305 (defun tooltip-activate-mouse-motions (activatep)
 306   "Activate/deactivate mouse motion events for the current buffer.
 307 ACTIVATEP non-nil means activate mouse motion events."
 308   (if activatep
 309       (progn
 310         (make-local-variable 'tooltip-mouse-motions-active)
 311         (setq tooltip-mouse-motions-active t)
 312         (make-local-variable 'track-mouse)
 313         (setq track-mouse t))
 314     (when tooltip-mouse-motions-active
 315       (kill-local-variable 'tooltip-mouse-motions-active)
 316       (kill-local-variable 'track-mouse))))
 317
 318 (defun tooltip-mouse-motion (event)
 319   "Command handler for mouse movement events in `global-map'."
 320   (interactive "e")
 321   (tooltip-hide)
 322   (when (car (mouse-pixel-position))
 323     (setq tooltip-last-mouse-motion-event (copy-sequence event))
 324     (tooltip-start-delayed-tip)))
 325
 326
 327 \f
 328 ;;; Displaying tips
 329
 330 (defun tooltip-set-param (alist key value)
 331   "Change the value of KEY in alist ALIST to VALUE.
 332 If there's no association for KEY in ALIST, add one, otherwise
 333 change the existing association.  Value is the resulting alist."
 334   (let ((param (assq key alist)))
 335     (if (consp param)
 336         (setcdr param value)
 337       (push (cons key value) alist))
 338     alist))
 339
 340
 341 (defun tooltip-show (text)
 342   "Show a tooltip window displaying TEXT.
 343
 344 Text larger than `x-max-tooltip-size' (which see) is clipped.
 345
 346 If the alist in `tooltip-frame-parameters' includes `left' and `top'
 347 parameters, they determine the x and y position where the tooltip
 348 is displayed.  Otherwise, the tooltip pops at offsets specified by
 349 `tooltip-x-offset' and `tooltip-y-offset' from the current mouse
 350 position."
 351   (if tooltip-use-echo-area
 352       (message "%s" text)
 353     (condition-case error
 354         (let ((params (copy-sequence tooltip-frame-parameters))
 355               (fg (face-attribute 'tooltip :foreground))
 356               (bg (face-attribute 'tooltip :background)))
 357           (when (stringp fg)
 358             (setq params (tooltip-set-param params 'foreground-color fg))
 359             (setq params (tooltip-set-param params 'border-color fg)))
 360           (when (stringp bg)
 361             (setq params (tooltip-set-param params 'background-color bg)))
 362           (x-show-tip (propertize text 'face 'tooltip)
 363                       (selected-frame)
 364                       params
 365                       tooltip-hide-delay
 366                       tooltip-x-offset
 367                       tooltip-y-offset))
 368       (error
 369        (message "Error while displaying tooltip: %s" error)
 370        (sit-for 1)
 371        (message "%s" text)))))
 372
 373
 374 (defun tooltip-hide (&optional ignored-arg)
 375   "Hide a tooltip, if one is displayed.
 376 Value is non-nil if tooltip was open."
 377   (tooltip-cancel-delayed-tip)
 378   (when (x-hide-tip)
 379     (setq tooltip-hide-time (float-time))))
 380
 381
 382 \f
 383 ;;; Debugger-related functions
 384
 385 (defun tooltip-identifier-from-point (point)
 386   "Extract the identifier at POINT, if any.
 387 Value is nil if no identifier exists at point.  Identifier extraction
 388 is based on the current syntax table."
 389   (save-excursion
 390     (goto-char point)
 391     (let ((start (progn (skip-syntax-backward "w_") (point))))
 392       (unless (looking-at "[0-9]")
 393         (skip-syntax-forward "w_")
 394         (when (> (point) start)
 395           (buffer-substring start (point)))))))
 396
 397
 398 (defmacro tooltip-region-active-p ()
 399   "Value is non-nil if the region is currently active."
 400   (if (string-match "^GNU" (emacs-version))
 401       `(and transient-mark-mode mark-active)
 402     `(region-active-p)))
 403
 404
 405 (defun tooltip-expr-to-print (event)
 406   "Return an expression that should be printed for EVENT.
 407 If a region is active and the mouse is inside the region, print
 408 the region.  Otherwise, figure out the identifier around the point
 409 where the mouse is."
 410   (save-excursion
 411     (set-buffer (tooltip-event-buffer event))
 412     (let ((point (posn-point (event-end event))))
 413       (if (tooltip-region-active-p)
 414           (when (and (<= (region-beginning) point) (<= point (region-end)))
 415             (buffer-substring (region-beginning) (region-end)))
 416         (tooltip-identifier-from-point point)))))
 417
 418
 419 (defun tooltip-process-prompt-regexp (process)
 420   "Return regexp matching the prompt of PROCESS at the end of a string.
 421 The prompt is taken from the value of COMINT-PROMPT-REGEXP in the buffer
 422 of PROCESS."
 423   (let ((prompt-regexp (save-excursion
 424                          (set-buffer (process-buffer process))
 425                          comint-prompt-regexp)))
 426     ;; Most start with `^' but the one for `sdb' cannot be easily
 427     ;; stripped.  Code the prompt for `sdb' fixed here.
 428     (if (= (aref prompt-regexp 0) ?^)
 429         (setq prompt-regexp (substring prompt-regexp 1))
 430       (setq prompt-regexp "\\*"))
 431     (concat "\n*" prompt-regexp "$")))
 432
 433
 434 (defun tooltip-strip-prompt (process output)
 435   "Return OUTPUT with any prompt of PROCESS stripped from its end."
 436   (let ((prompt-regexp (tooltip-process-prompt-regexp process)))
 437     (save-match-data
 438       (when (string-match prompt-regexp output)
 439         (setq output (substring output 0 (match-beginning 0)))))
 440     output))
 441
 442
 443 \f
 444 ;;; Tips for `gud'
 445
 446 (defvar tooltip-gud-original-filter nil
 447   "Process filter to restore after GUD output has been received.")
 448
 449
 450 (defvar tooltip-gud-dereference nil
 451   "Non-nil means print expressions with a `*' in front of them.
 452 For C this would dereference a pointer expression.")
 453
 454
 455 (defvar tooltip-gud-event nil
 456   "The mouse movement event that led to a tooltip display.
 457 This event can be examined by forms in TOOLTIP-GUD-DISPLAY.")
 458
 459
 460 (defvar tooltip-gud-debugger nil
 461   "A symbol describing the debugger running under GUD.")
 462
 463
 464 (defun tooltip-gud-toggle-dereference ()
 465   "Toggle whether tooltips should show `* expr' or `expr'."
 466   (interactive)
 467   (setq tooltip-gud-dereference (not tooltip-gud-dereference))
 468   (when (interactive-p)
 469     (message "Dereferencing is now %s."
 470              (if tooltip-gud-dereference "on" "off"))))
 471
 472
 473 (defun tooltip-gud-process-output (process output)
 474   "Process debugger output and show it in a tooltip window."
 475   (set-process-filter process tooltip-gud-original-filter)
 476   (tooltip-show (tooltip-strip-prompt process output)))
 477
 478
 479 (defun tooltip-gud-print-command (expr)
 480   "Return a suitable command to print the expression EXPR.
 481 If TOOLTIP-GUD-DEREFERENCE is t, also prepend a `*' to EXPR."
 482   (when tooltip-gud-dereference
 483     (setq expr (concat "*" expr)))
 484   (case tooltip-gud-debugger
 485     ((gdb dbx) (concat "print " expr))
 486     (xdb (concat "p " expr))
 487     (sdb (concat expr "/"))
 488     (perldb expr)))
 489
 490
 491 (defun tooltip-gud-tips (event)
 492   "Show tip for identifier or selection under the mouse.
 493 The mouse must either point at an identifier or inside a selected
 494 region for the tip window to be shown.  If tooltip-gud-dereference is t,
 495 add a `*' in front of the printed expression.
 496
 497 This function must return nil if it doesn't handle EVENT."
 498   (let (gud-buffer process)
 499     (when (and (eventp event)
 500                tooltip-gud-tips-p
 501                (boundp 'gud-comint-buffer)
 502                (setq gud-buffer gud-comint-buffer)
 503                (setq process (get-buffer-process gud-buffer))
 504                (posn-point (event-end event))
 505                (progn (setq tooltip-gud-event event)
 506                       (eval (cons 'and tooltip-gud-display))))
 507       (let ((expr (tooltip-expr-to-print event)))
 508         (when expr
 509           (let ((cmd (tooltip-gud-print-command expr)))
 510             (unless (null cmd)         ; CMD can be nil if unknown debugger
 511               (setq tooltip-gud-original-filter (process-filter process))
 512               (set-process-filter process 'tooltip-gud-process-output)
 513               (gud-basic-call cmd)
 514               expr)))))))
 515
 516 \f
 517 ;;; Tooltip help.
 518
 519 (defvar tooltip-help-message nil
 520   "The last help message received via `tooltip-show-help-function'.")
 521
 522
 523 (defun tooltip-show-help-function (msg)
 524   "Function installed as `show-help-function'.
 525 MSG is either a help string to display, or nil to cancel the display."
 526   (let ((previous-help tooltip-help-message))
 527     (setq tooltip-help-message msg)
 528     (cond ((null msg)
 529            ;; Cancel display.  This also cancels a delayed tip, if
 530            ;; there is one.
 531            (tooltip-hide))
 532           ((equal previous-help msg)
 533            ;; Same help as before (but possibly the mouse has moved).
 534            ;; Keep what we have.
 535            )
 536           (t
 537            ;; A different help.  Remove a previous tooltip, and
 538            ;; display a new one, with some delay.
 539            (tooltip-hide)
 540            (tooltip-start-delayed-tip)))))
 541
 542
 543 (defun tooltip-help-tips (event)
 544   "Hook function to display a help tooltip.
 545 This is installed on the hook `tooltip-hook', which is run when
 546 the timer with ID `tooltip-timeout-id' fires.
 547 Value is non-nil if this function handled the tip."
 548   (when (stringp tooltip-help-message)
 549     (tooltip-show tooltip-help-message)
 550     t))
 551
 552
 553 \f
 554 ;;; Do this after all functions have been defined that are called from
 555 ;;; `tooltip-mode'.  The actual default value of `tooltip-mode' is set
 556 ;;; in startup.el.
 557
 558 ;;;###autoload
 559 (defcustom tooltip-mode nil
 560   "Toggle tooltip-mode.
 561 Setting this variable directly does not take effect;
 562 use either \\[customize] or the function `tooltip-mode'."
 563   :set (lambda (symbol value)
 564          (tooltip-mode (or value 0)))
 565   :initialize 'custom-initialize-default
 566   :type 'boolean
 567   :require 'tooltip
 568   :group 'tooltip)
 569
 570
 571 ;;; tooltip.el ends here