code.delx.au - gnu-emacs/blob - lisp/calc/calc-comb.el

   1 ;;; calc-comb.el --- combinatoric functions for Calc
   2
   3 ;; Copyright (C) 1990, 1991, 1992, 1993, 2001, 2002, 2003, 2004,
   4 ;;   2005, 2006, 2007, 2008 Free Software Foundation, Inc.
   5
   6 ;; Author: David Gillespie <daveg@synaptics.com>
   7 ;; Maintainer: Jay Belanger <jay.p.belanger@gmail.com>
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 3, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 ;; Boston, MA 02110-1301, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;; Code:
  29
  30 ;; This file is autoloaded from calc-ext.el.
  31
  32 (require 'calc-ext)
  33 (require 'calc-macs)
  34
  35 (defconst math-primes-table
  36   [2 3 5 7 11 13 17 19 23 29 31 37 41 43 47 53 59 61 67 71 73 79 83 89
  37      97 101 103 107 109 113 127 131 137 139 149 151 157 163 167 173 179 181
  38      191 193 197 199 211 223 227 229 233 239 241 251 257 263 269 271 277
  39      281 283 293 307 311 313 317 331 337 347 349 353 359 367 373 379 383
  40      389 397 401 409 419 421 431 433 439 443 449 457 461 463 467 479 487
  41      491 499 503 509 521 523 541 547 557 563 569 571 577 587 593 599 601
  42      607 613 617 619 631 641 643 647 653 659 661 673 677 683 691 701 709
  43      719 727 733 739 743 751 757 761 769 773 787 797 809 811 821 823 827
  44      829 839 853 857 859 863 877 881 883 887 907 911 919 929 937 941 947
  45      953 967 971 977 983 991 997 1009 1013 1019 1021 1031 1033 1039 1049
  46      1051 1061 1063 1069 1087 1091 1093 1097 1103 1109 1117 1123 1129 1151
  47      1153 1163 1171 1181 1187 1193 1201 1213 1217 1223 1229 1231 1237 1249
  48      1259 1277 1279 1283 1289 1291 1297 1301 1303 1307 1319 1321 1327 1361
  49      1367 1373 1381 1399 1409 1423 1427 1429 1433 1439 1447 1451 1453 1459
  50      1471 1481 1483 1487 1489 1493 1499 1511 1523 1531 1543 1549 1553 1559
  51      1567 1571 1579 1583 1597 1601 1607 1609 1613 1619 1621 1627 1637 1657
  52      1663 1667 1669 1693 1697 1699 1709 1721 1723 1733 1741 1747 1753 1759
  53      1777 1783 1787 1789 1801 1811 1823 1831 1847 1861 1867 1871 1873 1877
  54      1879 1889 1901 1907 1913 1931 1933 1949 1951 1973 1979 1987 1993 1997
  55      1999 2003 2011 2017 2027 2029 2039 2053 2063 2069 2081 2083 2087 2089
  56      2099 2111 2113 2129 2131 2137 2141 2143 2153 2161 2179 2203 2207 2213
  57      2221 2237 2239 2243 2251 2267 2269 2273 2281 2287 2293 2297 2309 2311
  58      2333 2339 2341 2347 2351 2357 2371 2377 2381 2383 2389 2393 2399 2411
  59      2417 2423 2437 2441 2447 2459 2467 2473 2477 2503 2521 2531 2539 2543
  60      2549 2551 2557 2579 2591 2593 2609 2617 2621 2633 2647 2657 2659 2663
  61      2671 2677 2683 2687 2689 2693 2699 2707 2711 2713 2719 2729 2731 2741
  62      2749 2753 2767 2777 2789 2791 2797 2801 2803 2819 2833 2837 2843 2851
  63      2857 2861 2879 2887 2897 2903 2909 2917 2927 2939 2953 2957 2963 2969
  64      2971 2999 3001 3011 3019 3023 3037 3041 3049 3061 3067 3079 3083 3089
  65      3109 3119 3121 3137 3163 3167 3169 3181 3187 3191 3203 3209 3217 3221
  66      3229 3251 3253 3257 3259 3271 3299 3301 3307 3313 3319 3323 3329 3331
  67      3343 3347 3359 3361 3371 3373 3389 3391 3407 3413 3433 3449 3457 3461
  68      3463 3467 3469 3491 3499 3511 3517 3527 3529 3533 3539 3541 3547 3557
  69      3559 3571 3581 3583 3593 3607 3613 3617 3623 3631 3637 3643 3659 3671
  70      3673 3677 3691 3697 3701 3709 3719 3727 3733 3739 3761 3767 3769 3779
  71      3793 3797 3803 3821 3823 3833 3847 3851 3853 3863 3877 3881 3889 3907
  72      3911 3917 3919 3923 3929 3931 3943 3947 3967 3989 4001 4003 4007 4013
  73      4019 4021 4027 4049 4051 4057 4073 4079 4091 4093 4099 4111 4127 4129
  74      4133 4139 4153 4157 4159 4177 4201 4211 4217 4219 4229 4231 4241 4243
  75      4253 4259 4261 4271 4273 4283 4289 4297 4327 4337 4339 4349 4357 4363
  76      4373 4391 4397 4409 4421 4423 4441 4447 4451 4457 4463 4481 4483 4493
  77      4507 4513 4517 4519 4523 4547 4549 4561 4567 4583 4591 4597 4603 4621
  78      4637 4639 4643 4649 4651 4657 4663 4673 4679 4691 4703 4721 4723 4729
  79      4733 4751 4759 4783 4787 4789 4793 4799 4801 4813 4817 4831 4861 4871
  80      4877 4889 4903 4909 4919 4931 4933 4937 4943 4951 4957 4967 4969 4973
  81      4987 4993 4999 5003])
  82
  83 ;; The variable math-prime-factors-finished is set by calcFunc-prfac to
  84 ;; indicate whether factoring is complete, and used by calcFunc-factors,
  85 ;; calcFunc-totient and calcFunc-moebius.
  86 (defvar math-prime-factors-finished)
  87
  88 ;;; Combinatorics
  89
  90 (defun calc-gcd (arg)
  91   (interactive "P")
  92   (calc-slow-wrapper
  93    (calc-binary-op "gcd" 'calcFunc-gcd arg)))
  94
  95 (defun calc-lcm (arg)
  96   (interactive "P")
  97   (calc-slow-wrapper
  98    (calc-binary-op "lcm" 'calcFunc-lcm arg)))
  99
 100 (defun calc-extended-gcd ()
 101   (interactive)
 102   (calc-slow-wrapper
 103    (calc-enter-result 2 "egcd" (cons 'calcFunc-egcd (calc-top-list-n 2)))))
 104
 105 (defun calc-factorial (arg)
 106   (interactive "P")
 107   (calc-slow-wrapper
 108    (calc-unary-op "fact" 'calcFunc-fact arg)))
 109
 110 (defun calc-gamma (arg)
 111   (interactive "P")
 112   (calc-slow-wrapper
 113    (calc-unary-op "gmma" 'calcFunc-gamma arg)))
 114
 115 (defun calc-double-factorial (arg)
 116   (interactive "P")
 117   (calc-slow-wrapper
 118    (calc-unary-op "dfac" 'calcFunc-dfact arg)))
 119
 120 (defun calc-choose (arg)
 121   (interactive "P")
 122   (calc-slow-wrapper
 123    (if (calc-is-hyperbolic)
 124        (calc-binary-op "perm" 'calcFunc-perm arg)
 125      (calc-binary-op "chos" 'calcFunc-choose arg))))
 126
 127 (defun calc-perm (arg)
 128   (interactive "P")
 129   (calc-hyperbolic-func)
 130   (calc-choose arg))
 131
 132 (defvar calc-last-random-limit '(float 1 0))
 133 (defun calc-random (n)
 134   (interactive "P")
 135   (calc-slow-wrapper
 136    (if n
 137        (calc-enter-result 0 "rand" (list 'calcFunc-random
 138                                          (calc-get-random-limit
 139                                           (prefix-numeric-value n))))
 140      (calc-enter-result 1 "rand" (list 'calcFunc-random
 141                                        (calc-get-random-limit
 142                                         (calc-top-n 1)))))))
 143
 144 (defun calc-get-random-limit (val)
 145   (if (eq val 0)
 146       calc-last-random-limit
 147     (setq calc-last-random-limit val)))
 148
 149 (defun calc-rrandom ()
 150   (interactive)
 151   (calc-slow-wrapper
 152    (setq calc-last-random-limit '(float 1 0))
 153    (calc-enter-result 0 "rand" (list 'calcFunc-random '(float 1 0)))))
 154
 155 (defun calc-random-again (arg)
 156   (interactive "p")
 157   (calc-slow-wrapper
 158    (while (>= (setq arg (1- arg)) 0)
 159      (calc-enter-result 0 "rand" (list 'calcFunc-random
 160                                        calc-last-random-limit)))))
 161
 162 (defun calc-shuffle (n)
 163   (interactive "P")
 164   (calc-slow-wrapper
 165    (if n
 166        (calc-enter-result 1 "shuf" (list 'calcFunc-shuffle
 167                                          (prefix-numeric-value n)
 168                                          (calc-get-random-limit
 169                                           (calc-top-n 1))))
 170      (calc-enter-result 2 "shuf" (list 'calcFunc-shuffle
 171                                        (calc-top-n 1)
 172                                        (calc-get-random-limit
 173                                         (calc-top-n 2)))))))
 174
 175 (defun calc-report-prime-test (res)
 176   (cond ((eq (car res) t)
 177          (calc-record-message "prim" "Prime (guaranteed)"))
 178         ((eq (car res) nil)
 179          (if (cdr res)
 180              (if (eq (nth 1 res) 'unknown)
 181                  (calc-record-message
 182                   "prim" "Non-prime (factors unknown)")
 183                (calc-record-message
 184                 "prim" "Non-prime (%s is a factor)"
 185                 (math-format-number (nth 1 res))))
 186            (calc-record-message "prim" "Non-prime")))
 187         (t
 188          (calc-record-message
 189           "prim" "Probably prime (%d iters; %s%% chance of error)"
 190           (nth 1 res)
 191           (let ((calc-float-format '(fix 2)))
 192             (math-format-number (nth 2 res)))))))
 193
 194 (defun calc-prime-test (iters)
 195   (interactive "p")
 196   (calc-slow-wrapper
 197    (let* ((n (calc-top-n 1))
 198           (res (math-prime-test n iters)))
 199      (calc-report-prime-test res))))
 200
 201 (defvar calc-verbose-nextprime nil)
 202
 203 (defun calc-next-prime (iters)
 204   (interactive "p")
 205   (calc-slow-wrapper
 206    (let ((calc-verbose-nextprime t))
 207      (if (calc-is-inverse)
 208          (calc-enter-result 1 "prvp" (list 'calcFunc-prevprime
 209                                            (calc-top-n 1) (math-abs iters)))
 210        (calc-enter-result 1 "nxtp" (list 'calcFunc-nextprime
 211                                          (calc-top-n 1) (math-abs iters)))))))
 212
 213 (defun calc-prev-prime (iters)
 214   (interactive "p")
 215   (calc-invert-func)
 216   (calc-next-prime iters))
 217
 218 (defun calc-prime-factors (iters)
 219   (interactive "p")
 220   (calc-slow-wrapper
 221    (let ((res (calcFunc-prfac (calc-top-n 1))))
 222      (if (not math-prime-factors-finished)
 223          (calc-record-message "pfac" "Warning:  May not be fully factored"))
 224      (calc-enter-result 1 "pfac" res))))
 225
 226 (defun calc-totient (arg)
 227   (interactive "P")
 228   (calc-slow-wrapper
 229    (calc-unary-op "phi" 'calcFunc-totient arg)))
 230
 231 (defun calc-moebius (arg)
 232   (interactive "P")
 233   (calc-slow-wrapper
 234    (calc-unary-op "mu" 'calcFunc-moebius arg)))
 235
 236
 237 (defun calcFunc-gcd (a b)
 238   (if (Math-messy-integerp a)
 239       (setq a (math-trunc a)))
 240   (if (Math-messy-integerp b)
 241       (setq b (math-trunc b)))
 242   (cond ((and (Math-integerp a) (Math-integerp b))
 243          (math-gcd a b))
 244         ((Math-looks-negp a)
 245          (calcFunc-gcd (math-neg a) b))
 246         ((Math-looks-negp b)
 247          (calcFunc-gcd a (math-neg b)))
 248         ((Math-zerop a) b)
 249         ((Math-zerop b) a)
 250         ((and (Math-ratp a)
 251               (Math-ratp b))
 252          (math-make-frac (math-gcd (if (eq (car-safe a) 'frac) (nth 1 a) a)
 253                                    (if (eq (car-safe b) 'frac) (nth 1 b) b))
 254                          (calcFunc-lcm
 255                           (if (eq (car-safe a) 'frac) (nth 2 a) 1)
 256                           (if (eq (car-safe b) 'frac) (nth 2 b) 1))))
 257         ((not (Math-integerp a))
 258          (calc-record-why 'integerp a)
 259          (list 'calcFunc-gcd a b))
 260         (t
 261          (calc-record-why 'integerp b)
 262          (list 'calcFunc-gcd a b))))
 263
 264 (defun calcFunc-lcm (a b)
 265   (let ((g (calcFunc-gcd a b)))
 266     (if (Math-numberp g)
 267         (math-div (math-mul a b) g)
 268       (list 'calcFunc-lcm a b))))
 269
 270 (defun calcFunc-egcd (a b)   ; Knuth section 4.5.2
 271   (cond
 272    ((not (Math-integerp a))
 273     (if (Math-messy-integerp a)
 274         (calcFunc-egcd (math-trunc a) b)
 275       (calc-record-why 'integerp a)
 276       (list 'calcFunc-egcd a b)))
 277    ((not (Math-integerp b))
 278     (if (Math-messy-integerp b)
 279         (calcFunc-egcd a (math-trunc b))
 280       (calc-record-why 'integerp b)
 281       (list 'calcFunc-egcd a b)))
 282    (t
 283     (let ((u1 1) (u2 0) (u3 a)
 284           (v1 0) (v2 1) (v3 b)
 285           t1 t2 q)
 286       (while (not (eq v3 0))
 287         (setq q (math-idivmod u3 v3)
 288               t1 (math-sub u1 (math-mul v1 (car q)))
 289               t2 (math-sub u2 (math-mul v2 (car q)))
 290               u1 v1  u2 v2  u3 v3
 291               v1 t1  v2 t2  v3 (cdr q)))
 292       (list 'vec u3 u1 u2)))))
 293
 294
 295 ;;; Factorial and related functions.
 296
 297 (defconst math-small-factorial-table
 298   (vector 1 1 2 6 24 120 720 5040 40320 362880 3628800 39916800
 299           (math-read-number-simple "479001600")
 300           (math-read-number-simple "6227020800")
 301           (math-read-number-simple "87178291200")
 302           (math-read-number-simple "1307674368000")
 303           (math-read-number-simple "20922789888000")
 304           (math-read-number-simple "355687428096000")
 305           (math-read-number-simple "6402373705728000")
 306           (math-read-number-simple "121645100408832000")
 307           (math-read-number-simple "2432902008176640000")))
 308
 309 (defun calcFunc-fact (n)   ; [I I] [F F] [Public]
 310   (let (temp)
 311     (cond ((Math-integer-negp n)
 312            (if calc-infinite-mode
 313                '(var uinf var-uinf)
 314              (math-reject-arg n 'range)))
 315           ((integerp n)
 316            (if (<= n 20)
 317                (aref math-small-factorial-table n)
 318              (math-factorial-iter (1- n) 2 1)))
 319           ((and (math-messy-integerp n)
 320                 (Math-lessp n 100))
 321            (math-inexact-result)
 322            (setq temp (math-trunc n))
 323            (if (>= temp 0)
 324                (if (<= temp 20)
 325                    (math-float (calcFunc-fact temp))
 326                  (math-with-extra-prec 1
 327                    (math-factorial-iter (1- temp) 2 '(float 1 0))))
 328              (math-reject-arg n 'range)))
 329           ((math-numberp n)
 330            (let* ((q (math-quarter-integer n))
 331                   (tn (and q (Math-lessp n 1000) (Math-lessp -1000 n)
 332                            (1+ (math-floor n)))))
 333              (cond ((and tn (= q 2)
 334                          (or calc-symbolic-mode (< (math-abs tn) 20)))
 335                     (let ((q (if (< tn 0)
 336                                  (math-div
 337                                   (math-pow -2 (- tn))
 338                                   (math-double-factorial-iter (* -2 tn) 3 1 2))
 339                                (math-div
 340                                 (math-double-factorial-iter (* 2 tn) 3 1 2)
 341                                 (math-pow 2 tn)))))
 342                       (math-mul q (if calc-symbolic-mode
 343                                       (list 'calcFunc-sqrt '(var pi var-pi))
 344                                     (math-sqrt-pi)))))
 345                    ((and tn (>= tn 0) (< tn 20)
 346                          (memq q '(1 3)))
 347                     (math-inexact-result)
 348                     (math-div
 349                      (math-mul (math-double-factorial-iter (* 4 tn) q 1 4)
 350                                (if (= q 1) (math-gamma-1q) (math-gamma-3q)))
 351                      (math-pow 4 tn)))
 352                    (t
 353                     (math-inexact-result)
 354                     (math-with-extra-prec 3
 355                       (math-gammap1-raw (math-float n)))))))
 356           ((equal n '(var inf var-inf)) n)
 357           (t (calc-record-why 'numberp n)
 358              (list 'calcFunc-fact n)))))
 359
 360 (math-defcache math-gamma-1q nil
 361   (math-with-extra-prec 3
 362     (math-gammap1-raw '(float -75 -2))))
 363
 364 (math-defcache math-gamma-3q nil
 365   (math-with-extra-prec 3
 366     (math-gammap1-raw '(float -25 -2))))
 367
 368 (defun math-factorial-iter (count n f)
 369   (if (= (% n 5) 1)
 370       (math-working (format "factorial(%d)" (1- n)) f))
 371   (if (> count 0)
 372       (math-factorial-iter (1- count) (1+ n) (math-mul n f))
 373     f))
 374
 375 (defun calcFunc-dfact (n)   ; [I I] [F F] [Public]
 376   (cond ((Math-integer-negp n)
 377          (if (math-oddp n)
 378              (if (eq n -1)
 379                  1
 380                (math-div (if (eq (math-mod n 4) 3) 1 -1)
 381                          (calcFunc-dfact (math-sub -2 n))))
 382            (list 'calcFunc-dfact n)))
 383         ((Math-zerop n) 1)
 384         ((integerp n) (math-double-factorial-iter n (+ 2 (% n 2)) 1 2))
 385         ((math-messy-integerp n)
 386          (let ((temp (math-trunc n)))
 387            (math-inexact-result)
 388            (if (natnump temp)
 389                (if (Math-lessp temp 200)
 390                    (math-with-extra-prec 1
 391                      (math-double-factorial-iter temp (+ 2 (% temp 2))
 392                                                  '(float 1 0) 2))
 393                  (let* ((half (math-div2 temp))
 394                         (even (math-mul (math-pow 2 half)
 395                                         (calcFunc-fact (math-float half)))))
 396                    (if (math-evenp temp)
 397                        even
 398                      (math-div (calcFunc-fact n) even))))
 399              (list 'calcFunc-dfact n))))
 400         ((equal n '(var inf var-inf)) n)
 401         (t (calc-record-why 'natnump n)
 402            (list 'calcFunc-dfact n))))
 403
 404 (defun math-double-factorial-iter (max n f step)
 405   (if (< (% n 12) step)
 406       (math-working (format "dfact(%d)" (- n step)) f))
 407   (if (<= n max)
 408       (math-double-factorial-iter max (+ n step) (math-mul n f) step)
 409     f))
 410
 411 (defun calcFunc-perm (n m)   ; [I I I] [F F F] [Public]
 412   (cond ((and (integerp n) (integerp m) (<= m n) (>= m 0))
 413          (math-factorial-iter m (1+ (- n m)) 1))
 414         ((or (not (math-num-integerp n))
 415              (and (math-messy-integerp n) (Math-lessp 100 n))
 416              (not (math-num-integerp m))
 417              (and (math-messy-integerp m) (Math-lessp 100 m)))
 418          (or (math-realp n) (equal n '(var inf var-inf))
 419              (math-reject-arg n 'realp))
 420          (or (math-realp m) (equal m '(var inf var-inf))
 421              (math-reject-arg m 'realp))
 422          (and (math-num-integerp n) (math-negp n) (math-reject-arg n 'range))
 423          (and (math-num-integerp m) (math-negp m) (math-reject-arg m 'range))
 424          (math-div (calcFunc-fact n) (calcFunc-fact (math-sub n m))))
 425         (t
 426          (let ((tn (math-trunc n))
 427                (tm (math-trunc m)))
 428            (math-inexact-result)
 429            (or (integerp tn) (math-reject-arg tn 'fixnump))
 430            (or (integerp tm) (math-reject-arg tm 'fixnump))
 431            (or (and (<= tm tn) (>= tm 0)) (math-reject-arg tm 'range))
 432            (math-with-extra-prec 1
 433              (math-factorial-iter tm (1+ (- tn tm)) '(float 1 0)))))))
 434
 435 (defun calcFunc-choose (n m)   ; [I I I] [F F F] [Public]
 436   (cond ((and (integerp n) (integerp m) (<= m n) (>= m 0))
 437          (if (> m (/ n 2))
 438              (math-choose-iter (- n m) n 1 1)
 439            (math-choose-iter m n 1 1)))
 440         ((not (math-realp n))
 441          (math-reject-arg n 'realp))
 442         ((not (math-realp m))
 443          (math-reject-arg m 'realp))
 444         ((not (math-num-integerp m))
 445          (if (and (math-num-integerp n) (math-negp n))
 446              (list 'calcFunc-choose n m)
 447            (math-div (calcFunc-fact (math-float n))
 448                      (math-mul (calcFunc-fact m)
 449                                (calcFunc-fact (math-sub n m))))))
 450         ((math-negp m) 0)
 451         ((math-negp n)
 452          (let ((val (calcFunc-choose (math-add (math-add n m) -1) m)))
 453            (if (math-evenp (math-trunc m))
 454                val
 455              (math-neg val))))
 456         ((and (math-num-integerp n)
 457               (Math-lessp n m))
 458          0)
 459         (t
 460          (math-inexact-result)
 461          (let ((tm (math-trunc m)))
 462            (or (integerp tm) (math-reject-arg tm 'fixnump))
 463            (if (> tm 100)
 464                (math-div (calcFunc-fact (math-float n))
 465                          (math-mul (calcFunc-fact (math-float m))
 466                                    (calcFunc-fact (math-float
 467                                                    (math-sub n m)))))
 468              (math-with-extra-prec 1
 469                (math-choose-float-iter tm n 1 1)))))))
 470
 471 (defun math-choose-iter (m n i c)
 472   (if (and (= (% i 5) 1) (> i 5))
 473       (math-working (format "choose(%d)" (1- i)) c))
 474   (if (<= i m)
 475       (math-choose-iter m (1- n) (1+ i)
 476                         (math-quotient (math-mul c n) i))
 477     c))
 478
 479 (defun math-choose-float-iter (count n i c)
 480   (if (= (% i 5) 1)
 481       (math-working (format "choose(%d)" (1- i)) c))
 482   (if (> count 0)
 483       (math-choose-float-iter (1- count) (math-sub n 1) (1+ i)
 484                               (math-div (math-mul c n) i))
 485     c))
 486
 487
 488 ;;; Stirling numbers.
 489
 490 (defun calcFunc-stir1 (n m)
 491   (math-stirling-number n m 1))
 492
 493 (defun calcFunc-stir2 (n m)
 494   (math-stirling-number n m 0))
 495
 496 (defvar math-stirling-cache (vector [[1]] [[1]]))
 497
 498 ;; The variable math-stirling-local-cache is local to
 499 ;; math-stirling-number, but is used by math-stirling-1
 500 ;; and math-stirling-2, which are called by math-stirling-number.
 501 (defvar math-stirling-local-cache)
 502
 503 (defun math-stirling-number (n m k)
 504   (or (math-num-natnump n) (math-reject-arg n 'natnump))
 505   (or (math-num-natnump m) (math-reject-arg m 'natnump))
 506   (if (consp n) (setq n (math-trunc n)))
 507   (or (integerp n) (math-reject-arg n 'fixnump))
 508   (if (consp m) (setq m (math-trunc m)))
 509   (or (integerp m) (math-reject-arg m 'fixnump))
 510   (if (< n m)
 511       0
 512     (let ((math-stirling-local-cache (aref math-stirling-cache k)))
 513       (while (<= (length math-stirling-local-cache) n)
 514         (let ((i (1- (length math-stirling-local-cache)))
 515               row)
 516           (setq math-stirling-local-cache
 517                 (vconcat math-stirling-local-cache
 518                          (make-vector (length math-stirling-local-cache) nil)))
 519           (aset math-stirling-cache k math-stirling-local-cache)
 520           (while (< (setq i (1+ i)) (length math-stirling-local-cache))
 521             (aset math-stirling-local-cache i (setq row (make-vector (1+ i) nil)))
 522             (aset row 0 0)
 523             (aset row i 1))))
 524       (if (= k 1)
 525           (math-stirling-1 n m)
 526         (math-stirling-2 n m)))))
 527
 528 (defun math-stirling-1 (n m)
 529   (or (aref (aref math-stirling-local-cache n) m)
 530       (aset (aref math-stirling-local-cache n) m
 531             (math-add (math-stirling-1 (1- n) (1- m))
 532                       (math-mul (- 1 n) (math-stirling-1 (1- n) m))))))
 533
 534 (defun math-stirling-2 (n m)
 535   (or (aref (aref math-stirling-local-cache n) m)
 536       (aset (aref math-stirling-local-cache n) m
 537             (math-add (math-stirling-2 (1- n) (1- m))
 538                       (math-mul m (math-stirling-2 (1- n) m))))))
 539
 540 (defvar math-random-table nil)
 541 (defvar math-last-RandSeed nil)
 542 (defvar math-random-ptr1 nil)
 543 (defvar math-random-ptr2 nil)
 544 (defvar math-random-shift nil)
 545
 546 ;;; Produce a random 10-bit integer, with (random) if no seed provided,
 547 ;;; or else with Numerical Recipes algorithm ran3 / Knuth 3.2.2-A.
 548
 549 (defvar var-RandSeed)
 550 (defvar math-random-cache nil)
 551 (defvar math-gaussian-cache nil)
 552
 553 (defun math-init-random-base ()
 554   (if (and (boundp 'var-RandSeed) var-RandSeed)
 555       (if (eq (car-safe var-RandSeed) 'vec)
 556           nil
 557         (if (Math-integerp var-RandSeed)
 558             (let* ((seed (math-sub 161803 var-RandSeed))
 559                    (mj (1+ (math-mod seed 1000000)))
 560                    (mk (1+ (math-mod (math-quotient seed 1000000)
 561                                      1000000)))
 562                    (i 0))
 563               (setq math-random-table (cons 'vec (make-list 55 mj)))
 564               (while (<= (setq i (1+ i)) 54)
 565                 (let* ((ii (% (* i 21) 55))
 566                        (p (nthcdr ii math-random-table)))
 567                   (setcar p mk)
 568                   (setq mk (- mj mk)
 569                         mj (car p)))))
 570           (math-reject-arg var-RandSeed "*RandSeed must be an integer"))
 571         (setq var-RandSeed (list 'vec var-RandSeed)
 572               math-random-ptr1 math-random-table
 573               math-random-cache nil
 574               math-random-ptr2 (nthcdr 31 math-random-table))
 575         (let ((i 200))
 576           (while (> (setq i (1- i)) 0)
 577             (math-random-base))))
 578     (random t)
 579     (setq var-RandSeed nil
 580           math-random-cache nil
 581           math-random-shift -4)  ; assume RAND_MAX >= 16383
 582     ;; This exercises the random number generator and also helps
 583     ;; deduce a better value for RAND_MAX.
 584     (let ((i 0))
 585       (while (< (setq i (1+ i)) 30)
 586         (if (> (lsh (math-abs (random)) math-random-shift) 4095)
 587             (setq math-random-shift (1- math-random-shift))))))
 588   (setq math-last-RandSeed var-RandSeed
 589         math-gaussian-cache nil))
 590
 591 (defun math-random-base ()
 592   (if var-RandSeed
 593       (progn
 594         (setq math-random-ptr1 (or (cdr math-random-ptr1)
 595                                    (cdr math-random-table))
 596               math-random-ptr2 (or (cdr math-random-ptr2)
 597                                    (cdr math-random-table)))
 598         (logand (lsh (setcar math-random-ptr1
 599                              (logand (- (car math-random-ptr1)
 600                                         (car math-random-ptr2)) 524287))
 601                      -6) 1023))
 602     (logand (lsh (random) math-random-shift) 1023)))
 603
 604
 605 ;;; Produce a random digit in the range 0..999.
 606 ;;; Avoid various pitfalls that may lurk in the built-in (random) function!
 607 ;;; Shuffling algorithm from Numerical Recipes, section 7.1.
 608 (defvar math-random-last)
 609 (defun math-random-three-digit-number ()
 610   "Return a random three digit number."
 611   (let (i)
 612     (or (and (boundp 'var-RandSeed) (eq var-RandSeed math-last-RandSeed))
 613         (math-init-random-base))
 614     (or math-random-cache
 615         (progn
 616           (setq math-random-last (math-random-base)
 617                 math-random-cache (make-vector 13 nil)
 618                 i -1)
 619           (while (< (setq i (1+ i)) 13)
 620             (aset math-random-cache i (math-random-base)))))
 621     (while (progn
 622              (setq i (/ math-random-last 79)   ; 0 <= i < 13
 623                    math-random-last (aref math-random-cache i))
 624              (aset math-random-cache i (math-random-base))
 625              (>= math-random-last 1000)))
 626     math-random-last))
 627
 628 ;;; Produce an N-digit random integer.
 629 (defun math-random-digits (n)
 630   "Produce a random N digit integer."
 631   (let* ((slop (% (- 3 (% n 3)) 3))
 632          (i (/ (+ n slop) 3))
 633          (rnum 0))
 634     (while (> i 0)
 635       (setq rnum
 636             (math-add
 637              (math-random-three-digit-number)
 638              (math-mul rnum 1000)))
 639       (setq i (1- i)))
 640     (math-normalize (math-scale-right rnum slop))))
 641
 642 ;;; Produce a uniformly-distributed random float 0 <= N < 1.
 643 (defun math-random-float ()
 644   (math-make-float (math-random-digits calc-internal-prec)
 645                    (- calc-internal-prec)))
 646
 647 ;;; Produce a Gaussian-distributed random float with mean=0, sigma=1.
 648 (defun math-gaussian-float ()
 649   (math-with-extra-prec 2
 650     (if (and math-gaussian-cache
 651              (= (car math-gaussian-cache) calc-internal-prec))
 652         (prog1
 653             (cdr math-gaussian-cache)
 654           (setq math-gaussian-cache nil))
 655       (let* ((v1 (math-add (math-mul (math-random-float) 2) -1))
 656              (v2 (math-add (math-mul (math-random-float) 2) -1))
 657              (r (math-add (math-sqr v1) (math-sqr v2))))
 658         (while (or (not (Math-lessp r 1)) (math-zerop r))
 659           (setq v1 (math-add (math-mul (math-random-float) 2) -1)
 660                 v2 (math-add (math-mul (math-random-float) 2) -1)
 661                 r (math-add (math-sqr v1) (math-sqr v2))))
 662         (let ((fac (math-sqrt (math-mul (math-div (calcFunc-ln r) r) -2))))
 663           (setq math-gaussian-cache (cons calc-internal-prec
 664                                           (math-mul v1 fac)))
 665           (math-mul v2 fac))))))
 666
 667 ;;; Produce a random integer or real 0 <= N < MAX.
 668 (defun calcFunc-random (max)
 669   (cond ((Math-zerop max)
 670          (math-gaussian-float))
 671         ((Math-integerp max)
 672          (let* ((digs (math-numdigs max))
 673                 (r (math-random-digits (+ digs 3))))
 674            (math-mod r max)))
 675         ((Math-realp max)
 676          (math-mul (math-random-float) max))
 677         ((and (eq (car max) 'intv) (math-constp max)
 678               (Math-lessp (nth 2 max) (nth 3 max)))
 679          (if (math-floatp max)
 680              (let ((val (math-add (math-mul (math-random-float)
 681                                             (math-sub (nth 3 max) (nth 2 max)))
 682                                   (nth 2 max))))
 683                (if (or (and (memq (nth 1 max) '(0 1))      ; almost not worth
 684                             (Math-equal val (nth 2 max)))  ;   checking!
 685                        (and (memq (nth 1 max) '(0 2))
 686                             (Math-equal val (nth 3 max))))
 687                    (calcFunc-random max)
 688                  val))
 689            (let ((lo (if (memq (nth 1 max) '(0 1))
 690                          (math-add (nth 2 max) 1) (nth 2 max)))
 691                  (hi (if (memq (nth 1 max) '(1 3))
 692                          (math-add (nth 3 max) 1) (nth 3 max))))
 693              (if (Math-lessp lo hi)
 694                  (math-add (calcFunc-random (math-sub hi lo)) lo)
 695                (math-reject-arg max "*Empty interval")))))
 696         ((eq (car max) 'vec)
 697          (if (cdr max)
 698              (nth (1+ (calcFunc-random (1- (length max)))) max)
 699            (math-reject-arg max "*Empty list")))
 700         ((and (eq (car max) 'sdev) (math-constp max) (Math-realp (nth 1 max)))
 701          (math-add (math-mul (math-gaussian-float) (nth 2 max)) (nth 1 max)))
 702         (t (math-reject-arg max 'realp))))
 703
 704 ;;; Choose N objects at random from the set MAX without duplicates.
 705 (defun calcFunc-shuffle (n &optional max)
 706   (or max (setq max n n -1))
 707   (or (and (Math-num-integerp n)
 708            (or (natnump (setq n (math-trunc n))) (eq n -1)))
 709       (math-reject-arg n 'integerp))
 710   (cond ((or (math-zerop max)
 711              (math-floatp max)
 712              (eq (car-safe max) 'sdev))
 713          (if (< n 0)
 714              (math-reject-arg n 'natnump)
 715            (math-simple-shuffle n max)))
 716         ((and (<= n 1) (>= n 0))
 717          (math-simple-shuffle n max))
 718         ((and (eq (car-safe max) 'intv) (math-constp max))
 719          (let ((num (math-add (math-sub (nth 3 max) (nth 2 max))
 720                               (cdr (assq (nth 1 max)
 721                                          '((0 . -1) (1 . 0)
 722                                            (2 . 0) (3 . 1))))))
 723                (min (math-add (nth 2 max) (if (memq (nth 1 max) '(0 1))
 724                                               1 0))))
 725            (if (< n 0) (setq n num))
 726            (or (math-posp num) (math-reject-arg max 'range))
 727            (and (Math-lessp num n) (math-reject-arg n 'range))
 728            (if (Math-lessp n (math-quotient num 3))
 729                (math-simple-shuffle n max)
 730              (if (> (* n 4) (* num 3))
 731                  (math-add (math-sub min 1)
 732                            (math-shuffle-list n num (calcFunc-index num)))
 733                (let ((tot 0)
 734                      (m 0)
 735                      (vec nil))
 736                  (while (< m n)
 737                    (if (< (calcFunc-random (- num tot)) (- n m))
 738                        (setq vec (cons (math-add min tot) vec)
 739                              m (1+ m)))
 740                    (setq tot (1+ tot)))
 741                  (math-shuffle-list n n (cons 'vec vec)))))))
 742         ((eq (car-safe max) 'vec)
 743          (let ((size (1- (length max))))
 744            (if (< n 0) (setq n size))
 745            (if (and (> n (/ size 2)) (<= n size))
 746                (math-shuffle-list n size (copy-sequence max))
 747              (let* ((vals (calcFunc-shuffle
 748                            n (list 'intv 3 1 (1- (length max)))))
 749                     (p vals))
 750                (while (setq p (cdr p))
 751                  (setcar p (nth (car p) max)))
 752                vals))))
 753         ((math-integerp max)
 754          (if (math-posp max)
 755              (calcFunc-shuffle n (list 'intv 2 0 max))
 756            (calcFunc-shuffle n (list 'intv 1 max 0))))
 757         (t (math-reject-arg max 'realp))))
 758
 759 (defun math-simple-shuffle (n max)
 760   (let ((vec nil)
 761         val)
 762     (while (>= (setq n (1- n)) 0)
 763       (while (math-member (setq val (calcFunc-random max)) vec))
 764       (setq vec (cons val vec)))
 765     (cons 'vec vec)))
 766
 767 (defun math-shuffle-list (n size vec)
 768   (let ((j size)
 769         k temp
 770         (p vec))
 771     (while (cdr (setq p (cdr p)))
 772       (setq k (calcFunc-random j)
 773             j (1- j)
 774             temp (nth k p))
 775       (setcar (nthcdr k p) (car p))
 776       (setcar p temp))
 777     (cons 'vec (nthcdr (- size n -1) vec))))
 778
 779 (defun math-member (x list)
 780   (while (and list (not (equal x (car list))))
 781     (setq list (cdr list)))
 782   list)
 783
 784
 785 ;;; Check if the integer N is prime.  [X I]
 786 ;;; Return (nil) if non-prime,
 787 ;;;        (nil N) if non-prime with known factor N,
 788 ;;;        (nil unknown) if non-prime with no known factors,
 789 ;;;        (t) if prime,
 790 ;;;        (maybe N P) if probably prime (after N iters with probability P%)
 791 (defvar math-prime-test-cache '(-1))
 792
 793 (defvar math-prime-test-cache-k)
 794 (defvar math-prime-test-cache-q)
 795 (defvar math-prime-test-cache-nm1)
 796
 797 (defun math-prime-test (n iters)
 798   (if (and (Math-vectorp n) (cdr n))
 799       (setq n (nth (1- (length n)) n)))
 800   (if (Math-messy-integerp n)
 801       (setq n (math-trunc n)))
 802   (let ((res))
 803     (while (> iters 0)
 804       (setq res
 805             (cond ((and (integerp n) (<= n 5003))
 806                    (list (= (math-next-small-prime n) n)))
 807                   ((not (Math-integerp n))
 808                    (error "Argument must be an integer"))
 809                   ((Math-integer-negp n)
 810                    '(nil))
 811                   ((Math-natnum-lessp n 8000000)
 812                    (setq n (math-fixnum n))
 813                    (let ((i -1) v)
 814                      (while (and (> (% n (setq v (aref math-primes-table
 815                                                        (setq i (1+ i)))))
 816                                     0)
 817                                  (< (* v v) n)))
 818                      (if (= (% n v) 0)
 819                          (list nil v)
 820                        '(t))))
 821                   ((not (equal n (car math-prime-test-cache)))
 822                    (cond ((= (% (nth 1 n) 2) 0) '(nil 2))
 823                          ((= (% (nth 1 n) 5) 0) '(nil 5))
 824                          (t (let ((q n) (sum 0))
 825                               (while (not (eq q 0))
 826                                 (setq sum (%
 827                                            (+
 828                                             sum
 829                                             (calcFunc-mod
 830                                              q 1000000))
 831                                            111111))
 832                                 (setq q
 833                                       (math-quotient
 834                                        q 1000000)))
 835                               (cond ((= (% sum 3) 0) '(nil 3))
 836                                     ((= (% sum 7) 0) '(nil 7))
 837                                     ((= (% sum 11) 0) '(nil 11))
 838                                     ((= (% sum 13) 0) '(nil 13))
 839                                     ((= (% sum 37) 0) '(nil 37))
 840                                     (t
 841                                      (setq math-prime-test-cache-k 1
 842                                            math-prime-test-cache-q
 843                                            (math-div2 n)
 844                                            math-prime-test-cache-nm1
 845                                            (math-add n -1))
 846                                      (while (math-evenp
 847                                              math-prime-test-cache-q)
 848                                        (setq math-prime-test-cache-k
 849                                              (1+ math-prime-test-cache-k)
 850                                              math-prime-test-cache-q
 851                                              (math-div2
 852                                               math-prime-test-cache-q)))
 853                                      (setq iters (1+ iters))
 854                                      (list 'maybe
 855                                            0
 856                                            (math-sub
 857                                             100
 858                                             (math-div
 859                                              '(float 232 0)
 860                                              (math-numdigs n))))))))))
 861                   ((not (eq (car (nth 1 math-prime-test-cache)) 'maybe))
 862                    (nth 1 math-prime-test-cache))
 863                   (t   ; Fermat step
 864                    (let* ((x (math-add (calcFunc-random (math-add n -2)) 2))
 865                           (y (math-pow-mod x math-prime-test-cache-q n))
 866                           (j 0))
 867                      (while (and (not (eq y 1))
 868                                  (not (equal y math-prime-test-cache-nm1))
 869                                  (< (setq j (1+ j)) math-prime-test-cache-k))
 870                        (setq y (math-mod (math-mul y y) n)))
 871                      (if (or (equal y math-prime-test-cache-nm1)
 872                              (and (eq y 1) (eq j 0)))
 873                          (list 'maybe
 874                                (1+ (nth 1 (nth 1 math-prime-test-cache)))
 875                                (math-mul (nth 2 (nth 1 math-prime-test-cache))
 876                                          '(float 25 -2)))
 877                        '(nil unknown))))))
 878       (setq math-prime-test-cache (list n res)
 879             iters (if (eq (car res) 'maybe)
 880                       (1- iters)
 881                     0)))
 882     res))
 883
 884 (defun calcFunc-prime (n &optional iters)
 885   (or (math-num-integerp n) (math-reject-arg n 'integerp))
 886   (or (not iters) (math-num-integerp iters) (math-reject-arg iters 'integerp))
 887   (if (car (math-prime-test (math-trunc n) (math-trunc (or iters 1))))
 888       1
 889     0))
 890
 891 ;;; Theory: summing base-10^6 digits modulo 111111 is "casting out 999999s".
 892 ;;; Initial probability that N is prime is 1/ln(N) = log10(e)/log10(N).
 893 ;;; After culling [2,3,5,7,11,13,37], probability of primality is 5.36 x more.
 894 ;;; Initial reported probability of non-primality is thus 100% - this.
 895 ;;; Each Fermat step multiplies this probability by 25%.
 896 ;;; The Fermat step is algorithm P from Knuth section 4.5.4.
 897
 898
 899 (defun calcFunc-prfac (n)
 900   (setq math-prime-factors-finished t)
 901   (if (Math-messy-integerp n)
 902       (setq n (math-trunc n)))
 903   (if (Math-natnump n)
 904       (if (Math-natnum-lessp 2 n)
 905           (let (factors res p (i 0))
 906             (while (and (not (eq n 1))
 907                         (< i (length math-primes-table)))
 908               (setq p (aref math-primes-table i))
 909               (while (eq (cdr (setq res (cond ((eq n p) (cons 1 0))
 910                                               ((eq n 1) (cons 0 1))
 911                                               ((consp n) (math-idivmod n p))
 912                                               (t (cons (/ n p) (% n p))))))
 913                          0)
 914                 (math-working "factor" p)
 915                 (setq factors (nconc factors (list p))
 916                       n (car res)))
 917               (or (eq n 1)
 918                   (Math-natnum-lessp p (car res))
 919                   (setq factors (nconc factors (list n))
 920                         n 1))
 921               (setq i (1+ i)))
 922             (or (setq math-prime-factors-finished (eq n 1))
 923                 (setq factors (nconc factors (list n))))
 924             (cons 'vec factors))
 925         (list 'vec n))
 926     (if (Math-integerp n)
 927         (if (eq n -1)
 928             (list 'vec n)
 929           (cons 'vec (cons -1 (cdr (calcFunc-prfac (math-neg n))))))
 930       (calc-record-why 'integerp n)
 931       (list 'calcFunc-prfac n))))
 932
 933 (defun calcFunc-totient (n)
 934   (if (Math-messy-integerp n)
 935       (setq n (math-trunc n)))
 936   (if (Math-natnump n)
 937       (if (Math-natnum-lessp n 2)
 938           (if (Math-negp n)
 939               (calcFunc-totient (math-abs n))
 940             n)
 941         (let ((factors (cdr (calcFunc-prfac n)))
 942               p)
 943           (if math-prime-factors-finished
 944               (progn
 945                 (while factors
 946                   (setq p (car factors)
 947                         n (math-mul (math-div n p) (math-add p -1)))
 948                   (while (equal p (car factors))
 949                     (setq factors (cdr factors))))
 950                 n)
 951             (calc-record-why "*Number too big to factor" n)
 952             (list 'calcFunc-totient n))))
 953     (calc-record-why 'natnump n)
 954     (list 'calcFunc-totient n)))
 955
 956 (defun calcFunc-moebius (n)
 957   (if (Math-messy-integerp n)
 958       (setq n (math-trunc n)))
 959   (if (and (Math-natnump n) (not (eq n 0)))
 960       (if (Math-natnum-lessp n 2)
 961           (if (Math-negp n)
 962               (calcFunc-moebius (math-abs n))
 963             1)
 964         (let ((factors (cdr (calcFunc-prfac n)))
 965               (mu 1))
 966           (if math-prime-factors-finished
 967               (progn
 968                 (while factors
 969                   (setq mu (if (equal (car factors) (nth 1 factors))
 970                                0 (math-neg mu))
 971                         factors (cdr factors)))
 972                 mu)
 973             (calc-record-why "Number too big to factor" n)
 974             (list 'calcFunc-moebius n))))
 975     (calc-record-why 'posintp n)
 976     (list 'calcFunc-moebius n)))
 977
 978
 979 (defun calcFunc-nextprime (n &optional iters)
 980   (if (Math-integerp n)
 981       (if (Math-integer-negp n)
 982           2
 983         (if (and (integerp n) (< n 5003))
 984             (math-next-small-prime (1+ n))
 985           (if (math-evenp n)
 986               (setq n (math-add n -1)))
 987           (let (res)
 988             (while (not (car (setq res (math-prime-test
 989                                         (setq n (math-add n 2))
 990                                         (or iters 1))))))
 991             (if (and calc-verbose-nextprime
 992                      (eq (car res) 'maybe))
 993                 (calc-report-prime-test res)))
 994           n))
 995     (if (Math-realp n)
 996         (calcFunc-nextprime (math-trunc n) iters)
 997       (math-reject-arg n 'integerp))))
 998
 999 (defun calcFunc-prevprime (n &optional iters)
1000   (if (Math-integerp n)
1001       (if (Math-lessp n 4)
1002           2
1003         (if (math-evenp n)
1004             (setq n (math-add n 1)))
1005         (let (res)
1006           (while (not (car (setq res (math-prime-test
1007                                       (setq n (math-add n -2))
1008                                       (or iters 1))))))
1009           (if (and calc-verbose-nextprime
1010                    (eq (car res) 'maybe))
1011               (calc-report-prime-test res)))
1012         n)
1013     (if (Math-realp n)
1014         (calcFunc-prevprime (math-ceiling n) iters)
1015       (math-reject-arg n 'integerp))))
1016
1017 (defun math-next-small-prime (n)
1018   (if (and (integerp n) (> n 2))
1019       (let ((lo -1)
1020             (hi (length math-primes-table))
1021             mid)
1022         (while (> (- hi lo) 1)
1023           (if (> n (aref math-primes-table
1024                          (setq mid (ash (+ lo hi) -1))))
1025               (setq lo mid)
1026             (setq hi mid)))
1027         (aref math-primes-table hi))
1028     2))
1029
1030 (provide 'calc-comb)
1031
1032 ;; arch-tag: 1d75ee9b-0815-42bd-a321-bb3dc001cc02
1033 ;;; calc-comb.el ends here