code.delx.au - gnu-emacs/blob - lisp/dirtrack.el

   1 ;;; dirtrack.el --- Directory Tracking by watching the prompt
   2
   3 ;; Copyright (C) 1996 Free Software Foundation, Inc.
   4
   5 ;; Author: Peter Breton <pbreton@cs.umb.edu>
   6 ;; Created: Sun Nov 17 1996
   7 ;; Keywords: processes
   8 ;; Time-stamp: <1998-03-14 09:24:38 pbreton>
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  25 ;; Boston, MA 02111-1307, USA.
  26
  27 ;;; Commentary:
  28
  29 ;; Shell directory tracking by watching the prompt.
  30 ;;
  31 ;; This is yet another attempt at a directory-tracking package for
  32 ;; Emacs shell-mode. However, this package makes one strong assumption:
  33 ;; that you can customize your shell's prompt to contain the
  34 ;; current working directory. Most shells do support this, including
  35 ;; almost every type of Bourne and C shell on Unix, the native shells on
  36 ;; Windows95 (COMMAND.COM) and Windows NT (CMD.EXE), and most 3rd party
  37 ;; Windows shells. If you cannot do this, or do not wish to, this package
  38 ;; will be useless to you.
  39 ;;
  40 ;; Installation:
  41 ;;
  42 ;; 1) Set your shell's prompt to contain the current working directory.
  43 ;; You may need to consult your shell's documentation to find out how to
  44 ;; do this.
  45 ;;
  46 ;; Note that directory tracking is done by matching regular expressions,
  47 ;; therefore it is *VERY IMPORTANT* for your prompt to be easily
  48 ;; distinguishable from other output. If your prompt regexp is too general,
  49 ;; you will see error messages from the dirtrack filter as it attempts to cd
  50 ;; to non-existent directories.
  51 ;;
  52 ;; 2) Set the variable `dirtrack-list' to an appropriate value. This
  53 ;; should be a list of two elements: the first is a regular expression
  54 ;; which matches your prompt up to and including the pathname part.
  55 ;; The second is a number which tells which regular expression group to
  56 ;; match to extract only the pathname. If you use a multi-line prompt,
  57 ;; add 't' as a third element. Note that some of the functions in
  58 ;; 'comint.el' assume a single-line prompt (eg, comint-bol).
  59 ;;
  60 ;; Determining this information may take some experimentation. Setting
  61 ;; the variable `dirtrack-debug' may help; it causes the directory-tracking
  62 ;; filter to log messages to the buffer `dirtrack-debug-buffer'. You can easily
  63 ;; toggle this setting with the `dirtrack-debug-toggle' function.
  64 ;;
  65 ;; 3) Add a hook to shell-mode to enable the directory tracking:
  66 ;;
  67 ;; (add-hook 'shell-mode-hook
  68 ;;   (function (lambda ()
  69 ;;            (setq comint-output-filter-functions
  70 ;;                  (append (list 'dirtrack)
  71 ;;                          comint-output-filter-functions)))))
  72 ;;
  73 ;; You may wish to turn ordinary shell tracking off by calling
  74 ;; `shell-dirtrack-toggle' or setting `shell-dirtrackp'.
  75 ;;
  76 ;; Examples:
  77 ;;
  78 ;; 1) On Windows NT, my prompt is set to emacs$S$P$G.
  79 ;; 'dirtrack-list' is set to (list "^emacs \\([a-zA-Z]:.*\\)>" 1)
  80 ;;
  81 ;; 2) On Solaris running bash, my prompt is set like this:
  82 ;;    PS1="\w\012emacs@\h(\!) [\t]% "
  83 ;;    'dirtrack-list' is set to (list "^\\([/~].*\\)\nemacs@[^%]+% *" 1 t)
  84 ;;
  85 ;; I'd appreciate other examples from people who use this package.
  86 ;;
  87 ;; Here's one from Stephen Eglen:
  88 ;;
  89 ;;   Running under tcsh:
  90 ;;   (setq-default dirtrack-list '("^%E \\([^ ]+\\)" 1))
  91 ;;
  92 ;;   It might be worth mentioning in your file that emacs sources start up
  93 ;;   files of the form: ~/.emacs_<SHELL> where <SHELL> is the name of the
  94 ;;   shell.  So for example, I have the following in ~/.emacs_tcsh:
  95 ;;
  96 ;;   set prompt = "%%E %~ %h% "
  97 ;;
  98 ;;   This produces a prompt of the form:
  99 ;;   %E /var/spool 10%
 100 ;;
 101 ;;   This saves me from having to use the %E prefix in other non-emacs
 102 ;;   shells.
 103 ;;
 104 ;; A final note:
 105 ;;
 106 ;;   I run LOTS of shell buffers through Emacs, sometimes as different users (eg, when
 107 ;;   logged in as myself, I'll run a root shell in the same Emacs). If you do this, and
 108 ;;   the shell prompt contains a ~, Emacs will interpret this relative to the user which
 109 ;;   owns the Emacs process, not the user who owns the shell buffer. This may cause
 110 ;;   dirtrack to behave strangely (typically it reports that it is unable to cd to a directory
 111 ;;   with a ~ in it).
 112 ;;
 113 ;;   The same behavior can occur if you use dirtrack with remote filesystems (using telnet,
 114 ;;   rlogin, etc) as Emacs will be checking the local filesystem, not the remote one.
 115 ;;   This problem is not specific to dirtrack, but also affects file completion, etc.
 116
 117 ;;; Code:
 118
 119 (eval-when-compile
 120   (require 'comint)
 121   (require 'shell))
 122
 123 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 124 ;; Customization Variables
 125 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 126
 127 (defgroup dirtrack nil
 128   "Directory tracking by watching the prompt."
 129   :prefix "dirtrack-"
 130   :group 'shell)
 131
 132 (defcustom dirtrack-list (list "^emacs \\([a-zA-Z]:.*\\)>" 1)
 133   "*List for directory tracking.
 134 First item is a regexp that describes where to find the path in a prompt.
 135 Second is a number, the regexp group to match. Optional third item is
 136 whether the prompt is multi-line. If nil or omitted, prompt is assumed to
 137 be on a single line."
 138   :group 'dirtrack
 139   :type  '(sexp (regexp  :tag "Prompt Expression")
 140                 (integer :tag "Regexp Group")
 141                 (boolean :tag "Multiline Prompt")
 142                 )
 143   )
 144
 145 (make-variable-buffer-local 'dirtrack-list)
 146
 147 (defcustom dirtrack-debug nil
 148   "*If non-nil, the function `dirtrack' will report debugging info."
 149   :group 'dirtrack
 150   :type  'boolean
 151   )
 152
 153 (defcustom dirtrack-debug-buffer "*Directory Tracking Log*"
 154   "Buffer to write directory tracking debug information."
 155   :group 'dirtrack
 156   :type  'string
 157   )
 158
 159 (defcustom dirtrackp t
 160   "*If non-nil, directory tracking via `dirtrack' is enabled."
 161   :group 'dirtrack
 162   :type  'boolean
 163   )
 164
 165 (make-variable-buffer-local 'dirtrackp)
 166
 167 (defcustom dirtrack-directory-function
 168   (if (memq system-type (list 'ms-dos 'windows-nt))
 169       'dirtrack-windows-directory-function
 170     'dirtrack-default-directory-function)
 171   "*Function to apply to the prompt directory for comparison purposes."
 172   :group 'dirtrack
 173   :type  'function
 174   )
 175
 176 (defcustom dirtrack-canonicalize-function
 177   (if (memq system-type (list 'ms-dos 'windows-nt))
 178       'downcase 'identity)
 179   "*Function to apply to the default directory for comparison purposes."
 180   :group 'dirtrack
 181   :type  'function
 182   )
 183
 184 (defcustom dirtrack-directory-change-hook nil
 185   "Hook that is called when a directory change is made."
 186   :group 'dirtrack
 187   :type 'function
 188   )
 189
 190
 191 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 192 ;; Functions
 193 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 194
 195 (defun dirtrack-default-directory-function (dir)
 196   "Return a canonical directory for comparison purposes.
 197 Such a directory ends with a forward slash."
 198   (let ((directory dir))
 199     (if (not (char-equal ?/ (string-to-char (substring directory -1))))
 200         (concat directory "/")
 201       directory)))
 202
 203 (defun dirtrack-windows-directory-function (dir)
 204   "Return a canonical directory for comparison purposes.
 205 Such a directory is all lowercase, has forward-slashes as delimiters,
 206 and ends with a forward slash."
 207   (let ((directory dir))
 208     (setq directory (downcase (dirtrack-replace-slash directory t)))
 209     (if (not (char-equal ?/ (string-to-char (substring directory -1))))
 210         (concat directory "/")
 211       directory)))
 212
 213 (defconst dirtrack-forward-slash  (regexp-quote "/"))
 214 (defconst dirtrack-backward-slash (regexp-quote "\\"))
 215
 216 (defun dirtrack-replace-slash (string &optional opposite)
 217   "Replace forward slashes with backwards ones.
 218 If additional argument is non-nil, replace backwards slashes with
 219 forward ones."
 220   (let ((orig     (if opposite
 221                       dirtrack-backward-slash
 222                     dirtrack-forward-slash))
 223         (replace  (if opposite
 224                       dirtrack-forward-slash
 225                     dirtrack-backward-slash))
 226         (newstring string)
 227         )
 228     (while (string-match orig newstring)
 229       (setq newstring (replace-match replace nil t newstring)))
 230   newstring))
 231
 232 ;; Copied from shell.el
 233 (defun dirtrack-toggle ()
 234   "Enable or disable Dirtrack directory tracking in a shell buffer."
 235   (interactive)
 236   (setq dirtrackp (not dirtrackp))
 237   (message "Directory tracking %s" (if dirtrackp "ON" "OFF")))
 238
 239 (defun dirtrack-debug-toggle ()
 240   "Enable or disable Dirtrack debugging."
 241   (interactive)
 242   (setq dirtrack-debug (not dirtrack-debug))
 243   (message "Directory debugging %s" (if dirtrack-debug "ON" "OFF"))
 244   (and dirtrack-debug
 245        (display-buffer (get-buffer-create dirtrack-debug-buffer))))
 246
 247 (defun dirtrack-debug-message (string)
 248   (let ((buf (current-buffer))
 249         (debug-buf (get-buffer-create dirtrack-debug-buffer))
 250         )
 251     (set-buffer debug-buf)
 252     (goto-char (point-max))
 253     (insert (concat string "\n"))
 254     (set-buffer buf)
 255   ))
 256
 257 ;;;###autoload
 258 (defun dirtrack (input)
 259   (if (null dirtrackp)
 260       nil
 261     (let ((prompt-path)
 262           (current-dir default-directory)
 263           (matched)
 264           (dirtrack-regexp    (nth 0 dirtrack-list))
 265           (match-num          (nth 1 dirtrack-list))
 266           (multi-line         (nth 2 dirtrack-list))
 267           )
 268       ;; No output?
 269       (if (eq (point) (point-min))
 270           nil
 271         (save-excursion
 272           (goto-char (point-max))
 273           ;; Look for the prompt
 274           (if multi-line
 275               (setq matched
 276                     (re-search-backward
 277                      dirtrack-regexp
 278                      comint-last-output-start
 279                      t))
 280             (beginning-of-line)
 281             (setq matched (looking-at dirtrack-regexp)))
 282           ;; No match
 283           (if (null matched)
 284               (and dirtrack-debug
 285                    (dirtrack-debug-message
 286                     (format
 287                      "Input `%s' failed to match regexp: %s"
 288                     input dirtrack-regexp)))
 289             (setq prompt-path
 290                   (buffer-substring-no-properties
 291                    (match-beginning match-num) (match-end match-num)))
 292             ;; Empty string
 293             (if (not (> (length prompt-path) 0))
 294                 (and dirtrack-debug
 295                      (dirtrack-debug-message "Match is empty string"))
 296               ;; Transform prompts into canonical forms
 297               (setq prompt-path (funcall dirtrack-directory-function
 298                                          prompt-path))
 299               (setq current-dir (funcall dirtrack-canonicalize-function
 300                                          current-dir))
 301               (and dirtrack-debug
 302                    (dirtrack-debug-message
 303                     (format
 304                      "Prompt is %s\nCurrent directory is %s"
 305                      prompt-path current-dir)))
 306               ;; Compare them
 307               (if (or (string= current-dir prompt-path)
 308                       (string= current-dir
 309                                (abbreviate-file-name prompt-path)))
 310                   (and dirtrack-debug
 311                        (dirtrack-debug-message
 312                         (format "Not changing directory")))
 313                 ;; It's possible that Emacs will think the directory
 314                 ;; won't exist (eg, rlogin buffers)
 315                 (if (file-accessible-directory-p prompt-path)
 316                     ;; Change directory
 317                     (and (shell-process-cd prompt-path)
 318                          (run-hooks dirtrack-directory-change-hook)
 319                          dirtrack-debug
 320                          (dirtrack-debug-message
 321                           (format "Changing directory to %s" prompt-path)))
 322                   (error "Directory %s does not exist" prompt-path)))
 323               )))))))
 324
 325 (provide 'dirtrack)
 326
 327 ;;; dirtrack.el ends here