code.delx.au - gnu-emacs/blob - lisp/frame.el

   1 ;;; frame.el --- multi-frame management independent of window systems
   2
   3 ;; Copyright (C) 1993, 1994, 1996, 1997, 2000, 2001, 2002, 2003,
   4 ;;   2004, 2005, 2006, 2007 Free Software Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7 ;; Keywords: internal
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 3, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 ;; Boston, MA 02110-1301, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;; Code:
  29
  30 (defvar frame-creation-function-alist
  31   (list (cons nil
  32               (if (fboundp 'tty-create-frame-with-faces)
  33                   'tty-create-frame-with-faces
  34                 (lambda (parameters)
  35                   (error "Can't create multiple frames without a window system")))))
  36   "Alist of window-system dependent functions to call to create a new frame.
  37 The window system startup file should add its frame creation
  38 function to this list, which should take an alist of parameters
  39 as its argument.")
  40
  41 (defvar window-system-default-frame-alist nil
  42   "Alist of window-system dependent default frame parameters.
  43 You can set this in your `.emacs' file; for example,
  44
  45     ;; Disable menubar and toolbar on the console, but enable them under X.
  46     (setq window-system-default-frame-alist
  47           '((x (menu-bar-lines . 1) (tool-bar-lines . 1))
  48             (nil (menu-bar-lines . 0) (tool-bar-lines . 0))))
  49
  50 Parameters specified here supersede the values given in `default-frame-alist'.")
  51
  52 ;; The initial value given here used to ask for a minibuffer.
  53 ;; But that's not necessary, because the default is to have one.
  54 ;; By not specifying it here, we let an X resource specify it.
  55 (defcustom initial-frame-alist nil
  56   "*Alist of frame parameters for creating the initial X window frame.
  57 You can set this in your `.emacs' file; for example,
  58  (setq initial-frame-alist '((top . 1) (left . 1) (width . 80) (height . 55)))
  59 Parameters specified here supersede the values given in `default-frame-alist'.
  60
  61 If the value calls for a frame without a minibuffer, and you have not created
  62 a minibuffer frame on your own, one is created according to
  63 `minibuffer-frame-alist'.
  64
  65 You can specify geometry-related options for just the initial frame
  66 by setting this variable in your `.emacs' file; however, they won't
  67 take effect until Emacs reads `.emacs', which happens after first creating
  68 the frame.  If you want the frame to have the proper geometry as soon
  69 as it appears, you need to use this three-step process:
  70 * Specify X resources to give the geometry you want.
  71 * Set `default-frame-alist' to override these options so that they
  72   don't affect subsequent frames.
  73 * Set `initial-frame-alist' in a way that matches the X resources,
  74   to override what you put in `default-frame-alist'."
  75   :type '(repeat (cons :format "%v"
  76                        (symbol :tag "Parameter")
  77                        (sexp :tag "Value")))
  78   :group 'frames)
  79
  80 (defcustom minibuffer-frame-alist '((width . 80) (height . 2))
  81   "*Alist of frame parameters for initially creating a minibuffer frame.
  82 You can set this in your `.emacs' file; for example,
  83  (setq minibuffer-frame-alist
  84    '((top . 1) (left . 1) (width . 80) (height . 2)))
  85 Parameters specified here supersede the values given in
  86 `default-frame-alist', for a minibuffer frame."
  87   :type '(repeat (cons :format "%v"
  88                        (symbol :tag "Parameter")
  89                        (sexp :tag "Value")))
  90   :group 'frames)
  91
  92 (defcustom pop-up-frame-alist nil
  93   "*Alist of frame parameters used when creating pop-up frames.
  94 Pop-up frames are used for completions, help, and the like.
  95 This variable can be set in your init file, like this:
  96   (setq pop-up-frame-alist '((width . 80) (height . 20)))
  97 These supersede the values given in `default-frame-alist',
  98 for pop-up frames."
  99   :type '(repeat (cons :format "%v"
 100                        (symbol :tag "Parameter")
 101                        (sexp :tag "Value")))
 102   :group 'frames)
 103
 104 (setq pop-up-frame-function
 105       ;; Using `function' here caused some sort of problem.
 106       '(lambda ()
 107          (make-frame pop-up-frame-alist)))
 108
 109 (defcustom special-display-frame-alist
 110   '((height . 14) (width . 80) (unsplittable . t))
 111   "*Alist of frame parameters used when creating special frames.
 112 Special frames are used for buffers whose names are in
 113 `special-display-buffer-names' and for buffers whose names match
 114 one of the regular expressions in `special-display-regexps'.
 115 This variable can be set in your init file, like this:
 116   (setq special-display-frame-alist '((width . 80) (height . 20)))
 117 These supersede the values given in `default-frame-alist'."
 118   :type '(repeat (cons :format "%v"
 119                          (symbol :tag "Parameter")
 120                          (sexp :tag "Value")))
 121   :group 'frames)
 122
 123 (defun special-display-popup-frame (buffer &optional args)
 124   "Display BUFFER in its own frame, reusing an existing window if any.
 125 Return the window chosen.
 126 Currently we do not insist on selecting the window within its frame.
 127 If ARGS is an alist, use it as a list of frame parameter specs.
 128 If ARGS is a list whose car is a symbol,
 129 use (car ARGS) as a function to do the work.
 130 Pass it BUFFER as first arg, and (cdr ARGS) gives the rest of the args."
 131   (if (and args (symbolp (car args)))
 132       (apply (car args) buffer (cdr args))
 133     (let ((window (get-buffer-window buffer 0)))
 134       (or
 135        ;; If we have a window already, make it visible.
 136        (when window
 137          (let ((frame (window-frame window)))
 138            (make-frame-visible frame)
 139            (raise-frame frame)
 140            window))
 141        ;; Reuse the current window if the user requested it.
 142        (when (cdr (assq 'same-window args))
 143          (condition-case nil
 144              (progn (switch-to-buffer buffer) (selected-window))
 145            (error nil)))
 146        ;; Stay on the same frame if requested.
 147        (when (or (cdr (assq 'same-frame args)) (cdr (assq 'same-window args)))
 148          (let* ((pop-up-frames nil) (pop-up-windows t)
 149                 special-display-regexps special-display-buffer-names
 150                 (window (display-buffer buffer)))
 151            ;; Only do it if this is a new window:
 152            ;; (set-window-dedicated-p window t)
 153            window))
 154        ;; If no window yet, make one in a new frame.
 155        (let ((frame
 156               (with-current-buffer buffer
 157                 (make-frame (append args special-display-frame-alist)))))
 158          (set-window-buffer (frame-selected-window frame) buffer)
 159          (set-window-dedicated-p (frame-selected-window frame) t)
 160          (frame-selected-window frame))))))
 161
 162 (defun handle-delete-frame (event)
 163   "Handle delete-frame events from the X server."
 164   (interactive "e")
 165   (let ((frame (posn-window (event-start event)))
 166         (i 0)
 167         (tail (frame-list)))
 168     (while tail
 169       (and (frame-visible-p (car tail))
 170            (not (eq (car tail) frame))
 171           (setq i (1+ i)))
 172       (setq tail (cdr tail)))
 173     (if (> i 0)
 174         (delete-frame frame t)
 175       ;; Gildea@x.org says it is ok to ask questions before terminating.
 176       (save-buffers-kill-emacs))))
 177 \f
 178 ;;;; Arrangement of frames at startup
 179
 180 ;; 1) Load the window system startup file from the lisp library and read the
 181 ;; high-priority arguments (-q and the like).  The window system startup
 182 ;; file should create any frames specified in the window system defaults.
 183 ;;
 184 ;; 2) If no frames have been opened, we open an initial text frame.
 185 ;;
 186 ;; 3) Once the init file is done, we apply any newly set parameters
 187 ;; in initial-frame-alist to the frame.
 188
 189 ;; These are now called explicitly at the proper times,
 190 ;; since that is easier to understand.
 191 ;; Actually using hooks within Emacs is bad for future maintenance. --rms.
 192 ;; (add-hook 'before-init-hook 'frame-initialize)
 193 ;; (add-hook 'window-setup-hook 'frame-notice-user-settings)
 194
 195 ;; If we create the initial frame, this is it.
 196 (defvar frame-initial-frame nil)
 197
 198 ;; Record the parameters used in frame-initialize to make the initial frame.
 199 (defvar frame-initial-frame-alist)
 200
 201 (defvar frame-initial-geometry-arguments nil)
 202
 203 ;; startup.el calls this function before loading the user's init
 204 ;; file - if there is no frame with a minibuffer open now, create
 205 ;; one to display messages while loading the init file.
 206 (defun frame-initialize ()
 207   "Create an initial frame if necessary."
 208   ;; Are we actually running under a window system at all?
 209   (if (and initial-window-system
 210            (not noninteractive)
 211            (not (eq initial-window-system 'pc)))
 212       (progn
 213         ;; Turn on special-display processing only if there's a window system.
 214         (setq special-display-function 'special-display-popup-frame)
 215
 216         ;; If there is no frame with a minibuffer besides the terminal
 217         ;; frame, then we need to create the opening frame.  Make sure
 218         ;; it has a minibuffer, but let initial-frame-alist omit the
 219         ;; minibuffer spec.
 220         (or (delq terminal-frame (minibuffer-frame-list))
 221             (progn
 222               (setq frame-initial-frame-alist
 223                     (append initial-frame-alist default-frame-alist nil))
 224               (or (assq 'horizontal-scroll-bars frame-initial-frame-alist)
 225                   (setq frame-initial-frame-alist
 226                         (cons '(horizontal-scroll-bars . t)
 227                               frame-initial-frame-alist)))
 228               (setq frame-initial-frame-alist
 229                     (cons (cons 'window-system initial-window-system)
 230                           frame-initial-frame-alist))
 231               (setq default-minibuffer-frame
 232                     (setq frame-initial-frame
 233                           (make-frame frame-initial-frame-alist)))
 234               ;; Delete any specifications for window geometry parameters
 235               ;; so that we won't reapply them in frame-notice-user-settings.
 236               ;; It would be wrong to reapply them then,
 237               ;; because that would override explicit user resizing.
 238               (setq initial-frame-alist
 239                     (frame-remove-geometry-params initial-frame-alist))))
 240         ;; Copy the environment of the Emacs process into the new frame.
 241         (set-frame-parameter frame-initial-frame 'environment
 242                              (frame-parameter terminal-frame 'environment))
 243         ;; At this point, we know that we have a frame open, so we
 244         ;; can delete the terminal frame.
 245         (delete-frame terminal-frame)
 246         (setq terminal-frame nil))))
 247
 248 (defvar frame-notice-user-settings t
 249   "Non-nil means function `frame-notice-user-settings' wasn't run yet.")
 250
 251 ;; startup.el calls this function after loading the user's init
 252 ;; file.  Now default-frame-alist and initial-frame-alist contain
 253 ;; information to which we must react; do what needs to be done.
 254 (defun frame-notice-user-settings ()
 255   "Act on user's init file settings of frame parameters.
 256 React to settings of `initial-frame-alist',
 257 `window-system-default-frame-alist' and `default-frame-alist'
 258 there (in decreasing order of priority)."
 259   ;; Make menu-bar-mode and default-frame-alist consistent.
 260   (when (boundp 'menu-bar-mode)
 261     (let ((default (assq 'menu-bar-lines default-frame-alist)))
 262       (if default
 263           (setq menu-bar-mode (not (eq (cdr default) 0)))
 264         (setq default-frame-alist
 265               (cons (cons 'menu-bar-lines (if menu-bar-mode 1 0))
 266                     default-frame-alist)))))
 267
 268   ;; Make tool-bar-mode and default-frame-alist consistent.  Don't do
 269   ;; it in batch mode since that would leave a tool-bar-lines
 270   ;; parameter in default-frame-alist in a dumped Emacs, which is not
 271   ;; what we want.
 272   (when (and (boundp 'tool-bar-mode)
 273              (not noninteractive))
 274     (let ((default (assq 'tool-bar-lines default-frame-alist)))
 275       (if default
 276           (setq tool-bar-mode (not (eq (cdr default) 0)))
 277         ;; If Emacs was started on a tty, changing default-frame-alist
 278         ;; would disable the toolbar on X frames created later.  We
 279         ;; want to keep the default of showing a toolbar under X even
 280         ;; in this case.
 281         ;;
 282         ;; If the user explicitly called `tool-bar-mode' in .emacs,
 283         ;; then default-frame-alist is already changed anyway.
 284         (when initial-window-system
 285           (setq default-frame-alist
 286                 (cons (cons 'tool-bar-lines (if tool-bar-mode 1 0))
 287                       default-frame-alist))))))
 288
 289   ;; Creating and deleting frames may shift the selected frame around,
 290   ;; and thus the current buffer.  Protect against that.  We don't
 291   ;; want to use save-excursion here, because that may also try to set
 292   ;; the buffer of the selected window, which fails when the selected
 293   ;; window is the minibuffer.
 294   (let ((old-buffer (current-buffer))
 295         (window-system-frame-alist (cdr (assq initial-window-system
 296                                               window-system-default-frame-alist))))
 297
 298     (when (and frame-notice-user-settings
 299                (null frame-initial-frame))
 300       ;; This case happens when we don't have a window system, and
 301       ;; also for MS-DOS frames.
 302       (let ((parms (frame-parameters frame-initial-frame)))
 303         ;; Don't change the frame names.
 304         (setq parms (delq (assq 'name parms) parms))
 305         ;; Can't modify the minibuffer parameter, so don't try.
 306         (setq parms (delq (assq 'minibuffer parms) parms))
 307         (modify-frame-parameters nil
 308                                  (if (null initial-window-system)
 309                                      (append initial-frame-alist
 310                                              window-system-frame-alist
 311                                              default-frame-alist
 312                                              parms
 313                                              nil)
 314                                    ;; initial-frame-alist and
 315                                    ;; default-frame-alist were already
 316                                    ;; applied in pc-win.el.
 317                                    parms))
 318         (if (null initial-window-system) ;; MS-DOS does this differently in pc-win.el
 319             (let ((newparms (frame-parameters))
 320                   (frame (selected-frame)))
 321               (tty-handle-reverse-video frame newparms)
 322               ;; If we changed the background color, we need to update
 323               ;; the background-mode parameter, and maybe some faces,
 324               ;; too.
 325               (when (assq 'background-color newparms)
 326                 (unless (or (assq 'background-mode initial-frame-alist)
 327                             (assq 'background-mode default-frame-alist))
 328                   (frame-set-background-mode frame))
 329                 (face-set-after-frame-default frame))))))
 330
 331     ;; If the initial frame is still around, apply initial-frame-alist
 332     ;; and default-frame-alist to it.
 333     (when (frame-live-p frame-initial-frame)
 334
 335       ;; When tool-bar has been switched off, correct the frame size
 336       ;; by the lines added in x-create-frame for the tool-bar and
 337       ;; switch `tool-bar-mode' off.
 338       (when (display-graphic-p)
 339         (let ((tool-bar-lines (or (assq 'tool-bar-lines initial-frame-alist)
 340                                   (assq 'tool-bar-lines window-system-frame-alist)
 341                                   (assq 'tool-bar-lines default-frame-alist))))
 342           (when (and tool-bar-originally-present
 343                      (or (null tool-bar-lines)
 344                          (null (cdr tool-bar-lines))
 345                          (eq 0 (cdr tool-bar-lines))))
 346             (let* ((char-height (frame-char-height frame-initial-frame))
 347                    (image-height tool-bar-images-pixel-height)
 348                    (margin (cond ((and (consp tool-bar-button-margin)
 349                                        (integerp (cdr tool-bar-button-margin))
 350                                        (> tool-bar-button-margin 0))
 351                                   (cdr tool-bar-button-margin))
 352                                  ((and (integerp tool-bar-button-margin)
 353                                        (> tool-bar-button-margin 0))
 354                                   tool-bar-button-margin)
 355                                  (t 0)))
 356                    (relief (if (and (integerp tool-bar-button-relief)
 357                                     (> tool-bar-button-relief 0))
 358                                tool-bar-button-relief 3))
 359                    (lines (/ (+ image-height
 360                                 (* 2 margin)
 361                                 (* 2 relief)
 362                                 (1- char-height))
 363                              char-height))
 364                    (height (frame-parameter frame-initial-frame 'height))
 365                    (newparms (list (cons 'height (- height lines))))
 366                    (initial-top (cdr (assq 'top
 367                                            frame-initial-geometry-arguments)))
 368                    (top (frame-parameter frame-initial-frame 'top)))
 369               (when (and (consp initial-top) (eq '- (car initial-top)))
 370                 (let ((adjusted-top
 371                        (cond ((and (consp top)
 372                                    (eq '+ (car top)))
 373                               (list '+
 374                                     (+ (cadr top)
 375                                        (* lines char-height))))
 376                              ((and (consp top)
 377                                    (eq '- (car top)))
 378                               (list '-
 379                                     (- (cadr top)
 380                                        (* lines char-height))))
 381                              (t (+ top (* lines char-height))))))
 382                   (setq newparms
 383                         (append newparms
 384                                 `((top . ,adjusted-top))
 385                                 nil))))
 386               (modify-frame-parameters frame-initial-frame newparms)
 387               (tool-bar-mode -1)))))
 388
 389       ;; The initial frame we create above always has a minibuffer.
 390       ;; If the user wants to remove it, or make it a minibuffer-only
 391       ;; frame, then we'll have to delete the current frame and make a
 392       ;; new one; you can't remove or add a root window to/from an
 393       ;; existing frame.
 394       ;;
 395       ;; NOTE: default-frame-alist was nil when we created the
 396       ;; existing frame.  We need to explicitly include
 397       ;; default-frame-alist in the parameters of the screen we
 398       ;; create here, so that its new value, gleaned from the user's
 399       ;; .emacs file, will be applied to the existing screen.
 400       (if (not (eq (cdr (or (assq 'minibuffer initial-frame-alist)
 401                             (assq 'minibuffer window-system-frame-alist)
 402                             (assq 'minibuffer default-frame-alist)
 403                             '(minibuffer . t)))
 404                    t))
 405           ;; Create the new frame.
 406           (let (parms new)
 407             ;; If the frame isn't visible yet, wait till it is.
 408             ;; If the user has to position the window,
 409             ;; Emacs doesn't know its real position until
 410             ;; the frame is seen to be visible.
 411             (while (not (cdr (assq 'visibility
 412                                    (frame-parameters frame-initial-frame))))
 413               (sleep-for 1))
 414             (setq parms (frame-parameters frame-initial-frame))
 415
 416             ;; Get rid of `name' unless it was specified explicitly before.
 417             (or (assq 'name frame-initial-frame-alist)
 418                 (setq parms (delq (assq 'name parms) parms)))
 419
 420             (setq parms (append initial-frame-alist
 421                                 window-system-frame-alist
 422                                 default-frame-alist
 423                                 parms
 424                                 nil))
 425
 426             ;; Get rid of `reverse', because that was handled
 427             ;; when we first made the frame.
 428             (setq parms (cons '(reverse) (delq (assq 'reverse parms) parms)))
 429
 430             (if (assq 'height frame-initial-geometry-arguments)
 431                 (setq parms (assq-delete-all 'height parms)))
 432             (if (assq 'width frame-initial-geometry-arguments)
 433                 (setq parms (assq-delete-all 'width parms)))
 434             (if (assq 'left frame-initial-geometry-arguments)
 435                 (setq parms (assq-delete-all 'left parms)))
 436             (if (assq 'top frame-initial-geometry-arguments)
 437                 (setq parms (assq-delete-all 'top parms)))
 438             (setq new
 439                   (make-frame
 440                    ;; Use the geometry args that created the existing
 441                    ;; frame, rather than the parms we get for it.
 442                    (append frame-initial-geometry-arguments
 443                            '((user-size . t) (user-position . t))
 444                            parms)))
 445             ;; The initial frame, which we are about to delete, may be
 446             ;; the only frame with a minibuffer.  If it is, create a
 447             ;; new one.
 448             (or (delq frame-initial-frame (minibuffer-frame-list))
 449                 (make-initial-minibuffer-frame nil))
 450
 451             ;; If the initial frame is serving as a surrogate
 452             ;; minibuffer frame for any frames, we need to wean them
 453             ;; onto a new frame.  The default-minibuffer-frame
 454             ;; variable must be handled similarly.
 455             (let ((users-of-initial
 456                    (filtered-frame-list
 457                     (lambda (frame)
 458                       (and (not (eq frame frame-initial-frame))
 459                            (eq (window-frame
 460                                 (minibuffer-window frame))
 461                                frame-initial-frame))))))
 462               (if (or users-of-initial
 463                       (eq default-minibuffer-frame frame-initial-frame))
 464
 465                   ;; Choose an appropriate frame.  Prefer frames which
 466                   ;; are only minibuffers.
 467                   (let* ((new-surrogate
 468                           (car
 469                            (or (filtered-frame-list
 470                                 (lambda (frame)
 471                                   (eq (cdr (assq 'minibuffer
 472                                                  (frame-parameters frame)))
 473                                       'only)))
 474                                (minibuffer-frame-list))))
 475                          (new-minibuffer (minibuffer-window new-surrogate)))
 476
 477                     (if (eq default-minibuffer-frame frame-initial-frame)
 478                         (setq default-minibuffer-frame new-surrogate))
 479
 480                     ;; Wean the frames using frame-initial-frame as
 481                     ;; their minibuffer frame.
 482                     (dolist (frame users-of-initial)
 483                       (modify-frame-parameters
 484                        frame (list (cons 'minibuffer new-minibuffer)))))))
 485
 486             ;; Redirect events enqueued at this frame to the new frame.
 487             ;; Is this a good idea?
 488             (redirect-frame-focus frame-initial-frame new)
 489
 490             ;; Finally, get rid of the old frame.
 491             (delete-frame frame-initial-frame t))
 492
 493         ;; Otherwise, we don't need all that rigamarole; just apply
 494         ;; the new parameters.
 495         (let (newparms allparms tail)
 496           (setq allparms (append initial-frame-alist
 497                                  window-system-frame-alist
 498                                  default-frame-alist nil))
 499           (if (assq 'height frame-initial-geometry-arguments)
 500               (setq allparms (assq-delete-all 'height allparms)))
 501           (if (assq 'width frame-initial-geometry-arguments)
 502               (setq allparms (assq-delete-all 'width allparms)))
 503           (if (assq 'left frame-initial-geometry-arguments)
 504               (setq allparms (assq-delete-all 'left allparms)))
 505           (if (assq 'top frame-initial-geometry-arguments)
 506               (setq allparms (assq-delete-all 'top allparms)))
 507           (setq tail allparms)
 508           ;; Find just the parms that have changed since we first
 509           ;; made this frame.  Those are the ones actually set by
 510           ;; the init file.  For those parms whose values we already knew
 511           ;; (such as those spec'd by command line options)
 512           ;; it is undesirable to specify the parm again
 513           ;; once the user has seen the frame and been able to alter it
 514           ;; manually.
 515           (while tail
 516             (let (newval oldval)
 517               (setq oldval (assq (car (car tail))
 518                                  frame-initial-frame-alist))
 519               (setq newval (cdr (assq (car (car tail)) allparms)))
 520               (or (and oldval (eq (cdr oldval) newval))
 521                   (setq newparms
 522                         (cons (cons (car (car tail)) newval) newparms))))
 523             (setq tail (cdr tail)))
 524           (setq newparms (nreverse newparms))
 525           (modify-frame-parameters frame-initial-frame
 526                                    newparms)
 527           ;; If we changed the background color,
 528           ;; we need to update the background-mode parameter
 529           ;; and maybe some faces too.
 530           (when (assq 'background-color newparms)
 531             (unless (assq 'background-mode newparms)
 532               (frame-set-background-mode frame-initial-frame))
 533             (face-set-after-frame-default frame-initial-frame)))))
 534
 535     ;; Restore the original buffer.
 536     (set-buffer old-buffer)
 537
 538     ;; Make sure the initial frame can be GC'd if it is ever deleted.
 539     ;; Make sure frame-notice-user-settings does nothing if called twice.
 540     (setq frame-notice-user-settings nil)
 541     (setq frame-initial-frame nil)))
 542
 543 (defun make-initial-minibuffer-frame (display)
 544   (let ((parms (append minibuffer-frame-alist '((minibuffer . only)))))
 545     (if display
 546         (make-frame-on-display display parms)
 547       (make-frame parms))))
 548
 549 ;;;; Creation of additional frames, and other frame miscellanea
 550
 551 (defun modify-all-frames-parameters (alist)
 552   "Modify all current and future frames' parameters according to ALIST.
 553 This changes `default-frame-alist' and possibly `initial-frame-alist'.
 554 Furthermore, this function removes all parameters in ALIST from
 555 `window-system-default-frame-alist'.
 556 See help of `modify-frame-parameters' for more information."
 557   (dolist (frame (frame-list))
 558     (modify-frame-parameters frame alist))
 559
 560   (dolist (pair alist) ;; conses to add/replace
 561     ;; initial-frame-alist needs setting only when
 562     ;; frame-notice-user-settings is true.
 563     (and frame-notice-user-settings
 564          (setq initial-frame-alist
 565                (assq-delete-all (car pair) initial-frame-alist)))
 566     (setq default-frame-alist
 567           (assq-delete-all (car pair) default-frame-alist))
 568     ;; Remove any similar settings from the window-system specific
 569     ;; parameters---they would override default-frame-alist.
 570     (dolist (w window-system-default-frame-alist)
 571       (setcdr w (assq-delete-all (car pair) (cdr w)))))
 572
 573   (and frame-notice-user-settings
 574        (setq initial-frame-alist (append initial-frame-alist alist)))
 575   (setq default-frame-alist (append default-frame-alist alist)))
 576
 577 (defun get-other-frame ()
 578   "Return some frame other than the current frame.
 579 Create one if necessary.  Note that the minibuffer frame, if separate,
 580 is not considered (see `next-frame')."
 581   (let ((s (if (equal (next-frame (selected-frame)) (selected-frame))
 582                (make-frame)
 583              (next-frame (selected-frame)))))
 584     s))
 585
 586 (defun next-multiframe-window ()
 587   "Select the next window, regardless of which frame it is on."
 588   (interactive)
 589   (select-window (next-window (selected-window)
 590                               (> (minibuffer-depth) 0)
 591                               0))
 592   (select-frame-set-input-focus (selected-frame)))
 593
 594 (defun previous-multiframe-window ()
 595   "Select the previous window, regardless of which frame it is on."
 596   (interactive)
 597   (select-window (previous-window (selected-window)
 598                                   (> (minibuffer-depth) 0)
 599                                   0))
 600   (select-frame-set-input-focus (selected-frame)))
 601
 602 (defun make-frame-on-display (display &optional parameters)
 603   "Make a frame on X display DISPLAY.
 604 The optional second argument PARAMETERS specifies additional frame parameters."
 605   (interactive "sMake frame on display: ")
 606   (or (string-match "\\`[^:]*:[0-9]+\\(\\.[0-9]+\\)?\\'" display)
 607       (error "Invalid display, not HOST:SERVER or HOST:SERVER.SCREEN"))
 608   (when (and (boundp 'x-initialized) (not x-initialized))
 609     (setq x-display-name display)
 610     (x-initialize-window-system))
 611   (make-frame `((window-system . x) (display . ,display) . ,parameters)))
 612
 613 (defun make-frame-on-tty (tty type &optional parameters)
 614   "Make a frame on terminal device TTY.
 615 TTY should be the file name of the tty device to use.  TYPE
 616 should be the terminal type string of TTY, for example \"xterm\"
 617 or \"vt100\".  The optional third argument PARAMETERS specifies
 618 additional frame parameters."
 619   (interactive "fOpen frame on tty device: \nsTerminal type of %s: ")
 620   (unless tty
 621     (error "Invalid terminal device"))
 622   (unless type
 623     (error "Invalid terminal type"))
 624   (make-frame `((window-system . nil) (tty . ,tty) (tty-type . ,type) . ,parameters)))
 625
 626 (defun close-display-connection (display)
 627   "Close the connection to a display, deleting all its associated frames.
 628 For DISPLAY, specify either a frame or a display name (a string).
 629 If DISPLAY is nil, that stands for the selected frame's display."
 630   (interactive
 631    (list
 632     (let* ((default (frame-parameter nil 'display))
 633            (display (completing-read
 634                      (format "Close display (default %s): " default)
 635                      (delete-dups
 636                       (mapcar (lambda (frame)
 637                                 (frame-parameter frame 'display))
 638                               (frame-list)))
 639                      nil t nil nil
 640                      default)))
 641       (if (zerop (length display)) default display))))
 642   (let ((frames (delq nil
 643                       (mapcar (lambda (frame)
 644                                 (if (equal display
 645                                            (frame-parameter frame 'display))
 646                                     frame))
 647                               (frame-list)))))
 648     (if (and (consp frames)
 649              (not (y-or-n-p (if (cdr frames)
 650                                 (format "Delete %s frames? " (length frames))
 651                               (format "Delete %s ? " (car frames))))))
 652         (error "Abort!")
 653       (mapc 'delete-frame frames)
 654       (x-close-connection display))))
 655
 656 (defun make-frame-command ()
 657   "Make a new frame, and select it if the terminal displays only one frame."
 658   (interactive)
 659   (if (and window-system (not (eq window-system 'pc)))
 660       (make-frame)
 661     (select-frame (make-frame))))
 662
 663 (defvar before-make-frame-hook nil
 664   "Functions to run before a frame is created.")
 665
 666 (defvar after-make-frame-functions nil
 667   "Functions to run after a frame is created.
 668 The functions are run with one arg, the newly created frame.")
 669
 670 (defvar after-setting-font-hook nil
 671   "Functions to run after a frame's font has been changed.")
 672
 673 ;; Alias, kept temporarily.
 674 (define-obsolete-function-alias 'new-frame 'make-frame "22.1")
 675
 676 (defun make-frame (&optional parameters)
 677   "Return a newly created frame displaying the current buffer.
 678 Optional argument PARAMETERS is an alist of parameters for the new frame.
 679 Each element of PARAMETERS should have the form (NAME . VALUE), for example:
 680
 681  (name . STRING)        The frame should be named STRING.
 682
 683  (width . NUMBER)       The frame should be NUMBER characters in width.
 684  (height . NUMBER)      The frame should be NUMBER text lines high.
 685
 686 You cannot specify either `width' or `height', you must use neither or both.
 687
 688  (minibuffer . t)       The frame should have a minibuffer.
 689  (minibuffer . nil)     The frame should have no minibuffer.
 690  (minibuffer . only)    The frame should contain only a minibuffer.
 691  (minibuffer . WINDOW)  The frame should use WINDOW as its minibuffer window.
 692
 693  (window-system . nil)  The frame should be displayed on a terminal device.
 694  (window-system . x)    The frame should be displayed in an X window.
 695
 696  (terminal . ID)          The frame should use the terminal identified by ID.
 697
 698 Before the frame is created (via `frame-creation-function-alist'), functions on the
 699 hook `before-make-frame-hook' are run.  After the frame is created, functions
 700 on `after-make-frame-functions' are run with one arg, the newly created frame.
 701
 702 This function itself does not make the new frame the selected frame.
 703 The previously selected frame remains selected.  However, the
 704 window system may select the new frame for its own reasons, for
 705 instance if the frame appears under the mouse pointer and your
 706 setup is for focus to follow the pointer."
 707   (interactive)
 708   (let* ((w (cond
 709              ((assq 'terminal parameters)
 710               (let ((type (terminal-live-p (cdr (assq 'terminal parameters)))))
 711                 (cond
 712                  ((eq type t) nil)
 713                  ((eq type nil) (error "Terminal %s does not exist" (cdr (assq 'terminal parameters))))
 714                  (t type))))
 715              ((assq 'window-system parameters)
 716               (cdr (assq 'window-system parameters)))
 717              (t window-system)))
 718          (frame-creation-function (cdr (assq w frame-creation-function-alist)))
 719          (oldframe (selected-frame))
 720          frame)
 721     (unless frame-creation-function
 722       (error "Don't know how to create a frame on window system %s" w))
 723     (run-hooks 'before-make-frame-hook)
 724     (setq frame (funcall frame-creation-function (append parameters (cdr (assq w window-system-default-frame-alist)))))
 725     (normal-erase-is-backspace-setup-frame frame)
 726     ;; Inherit the 'environment and 'client parameters.
 727     (let ((env (frame-parameter oldframe 'environment))
 728           (client (frame-parameter oldframe 'client)))
 729       (if (not (framep env))
 730           (setq env oldframe))
 731       (if (and env (not (assq 'environment parameters)))
 732           (set-frame-parameter frame 'environment env))
 733       (if (and client (not (assq 'client parameters)))
 734           (set-frame-parameter frame 'client client)))
 735     (run-hook-with-args 'after-make-frame-functions frame)
 736     frame))
 737
 738 (defun filtered-frame-list (predicate)
 739   "Return a list of all live frames which satisfy PREDICATE."
 740   (let* ((frames (frame-list))
 741          (list frames))
 742     (while (consp frames)
 743       (unless (funcall predicate (car frames))
 744         (setcar frames nil))
 745       (setq frames (cdr frames)))
 746     (delq nil list)))
 747
 748 (defun minibuffer-frame-list ()
 749   "Return a list of all frames with their own minibuffers."
 750   (filtered-frame-list
 751    (lambda (frame)
 752      (eq frame (window-frame (minibuffer-window frame))))))
 753
 754 ;; Used to be called `terminal-id' in termdev.el.
 755 (defun get-device-terminal (device)
 756   "Return the terminal corresponding to DEVICE.
 757 DEVICE can be a terminal, a frame, nil (meaning the selected frame's terminal),
 758 the name of an X display device (HOST.SERVER.SCREEN) or a tty device file."
 759   (cond
 760    ((or (null device) (framep device))
 761     (frame-terminal device))
 762    ((stringp device)
 763     (let ((f (car (filtered-frame-list
 764                    (lambda (frame)
 765                      (or (equal (frame-parameter frame 'display) device)
 766                          (equal (frame-parameter frame 'tty) device)))))))
 767       (or f (error "Display %s does not exist" device))
 768       (frame-terminal f)))
 769    ((terminal-live-p device) device)
 770    (t
 771     (error "Invalid argument %s in `get-device-terminal'" device))))
 772
 773 (defun frames-on-display-list (&optional device)
 774   "Return a list of all frames on DEVICE.
 775
 776 DEVICE should be a terminal, a frame,
 777 or a name of an X display or tty (a string of the form
 778 HOST:SERVER.SCREEN).
 779
 780 If DEVICE is omitted or nil, it defaults to the selected
 781 frame's terminal device."
 782   (let* ((terminal (get-device-terminal device))
 783          (func #'(lambda (frame)
 784                    (eq (frame-terminal frame) terminal))))
 785     (filtered-frame-list func)))
 786
 787 (defun framep-on-display (&optional terminal)
 788   "Return the type of frames on TERMINAL.
 789 TERMINAL may be a terminal id, a display name or a frame.  If it
 790 is a frame, its type is returned.  If TERMINAL is omitted or nil,
 791 it defaults to the selected frame's terminal device.  All frames
 792 on a given display are of the same type."
 793   (or (terminal-live-p terminal)
 794       (framep terminal)
 795       (framep (car (frames-on-display-list terminal)))))
 796
 797 (defun frame-remove-geometry-params (param-list)
 798   "Return the parameter list PARAM-LIST, but with geometry specs removed.
 799 This deletes all bindings in PARAM-LIST for `top', `left', `width',
 800 `height', `user-size' and `user-position' parameters.
 801 Emacs uses this to avoid overriding explicit moves and resizings from
 802 the user during startup."
 803   (setq param-list (cons nil param-list))
 804   (let ((tail param-list))
 805     (while (consp (cdr tail))
 806       (if (and (consp (car (cdr tail)))
 807                (memq (car (car (cdr tail)))
 808                      '(height width top left user-position user-size)))
 809           (progn
 810             (setq frame-initial-geometry-arguments
 811                   (cons (car (cdr tail)) frame-initial-geometry-arguments))
 812             (setcdr tail (cdr (cdr tail))))
 813         (setq tail (cdr tail)))))
 814   (setq frame-initial-geometry-arguments
 815         (nreverse frame-initial-geometry-arguments))
 816   (cdr param-list))
 817
 818 (defun select-frame-set-input-focus (frame)
 819   "Select FRAME, raise it, and set input focus, if possible."
 820     (select-frame frame)
 821     (raise-frame frame)
 822     ;; Ensure, if possible, that frame gets input focus.
 823     (cond ((memq (window-system frame) '(x max w32))
 824            (x-focus-frame frame)))
 825     (cond (focus-follows-mouse
 826            (set-mouse-position (selected-frame) (1- (frame-width)) 0))))
 827
 828 (defun other-frame (arg)
 829   "Select the ARGth different visible frame on current display, and raise it.
 830 All frames are arranged in a cyclic order.
 831 This command selects the frame ARG steps away in that order.
 832 A negative ARG moves in the opposite order.
 833
 834 To make this command work properly, you must tell Emacs
 835 how the system (or the window manager) generally handles
 836 focus-switching between windows.  If moving the mouse onto a window
 837 selects it (gives it focus), set `focus-follows-mouse' to t.
 838 Otherwise, that variable should be nil."
 839   (interactive "p")
 840   (let ((frame (selected-frame)))
 841     (while (> arg 0)
 842       (setq frame (next-frame frame))
 843       (while (not (eq (frame-visible-p frame) t))
 844         (setq frame (next-frame frame)))
 845       (setq arg (1- arg)))
 846     (while (< arg 0)
 847       (setq frame (previous-frame frame))
 848       (while (not (eq (frame-visible-p frame) t))
 849         (setq frame (previous-frame frame)))
 850       (setq arg (1+ arg)))
 851     (select-frame-set-input-focus frame)))
 852
 853 (defun iconify-or-deiconify-frame ()
 854   "Iconify the selected frame, or deiconify if it's currently an icon."
 855   (interactive)
 856   (if (eq (cdr (assq 'visibility (frame-parameters))) t)
 857       (iconify-frame)
 858     (make-frame-visible)))
 859
 860 (defun suspend-frame ()
 861   "Do whatever is right to suspend the current frame.
 862 Calls `suspend-emacs' if invoked from the controlling tty device,
 863 `suspend-tty' from a secondary tty device, and
 864 `iconify-or-deiconify-frame' from an X frame."
 865   (interactive)
 866   (let ((type (framep (selected-frame))))
 867     (cond
 868      ((memq type '(x w32)) (iconify-or-deiconify-frame))
 869      ((eq type t)
 870       (if (controlling-tty-p)
 871           (suspend-emacs)
 872         (suspend-tty)))
 873      (t (suspend-emacs)))))
 874
 875 (defun make-frame-names-alist ()
 876   (let* ((current-frame (selected-frame))
 877          (falist
 878           (cons
 879            (cons (frame-parameter current-frame 'name) current-frame) nil))
 880          (frame (next-frame nil t)))
 881     (while (not (eq frame current-frame))
 882       (progn
 883         (setq falist (cons (cons (frame-parameter frame 'name) frame) falist))
 884         (setq frame (next-frame frame t))))
 885     falist))
 886
 887 (defvar frame-name-history nil)
 888 (defun select-frame-by-name (name)
 889   "Select the frame on the current terminal whose name is NAME and raise it.
 890 If there is no frame by that name, signal an error."
 891   (interactive
 892    (let* ((frame-names-alist (make-frame-names-alist))
 893            (default (car (car frame-names-alist)))
 894            (input (completing-read
 895                    (format "Select Frame (default %s): " default)
 896                    frame-names-alist nil t nil 'frame-name-history)))
 897      (if (= (length input) 0)
 898          (list default)
 899        (list input))))
 900   (let* ((frame-names-alist (make-frame-names-alist))
 901          (frame (cdr (assoc name frame-names-alist))))
 902     (or frame
 903         (error "There is no frame named `%s'" name))
 904     (make-frame-visible frame)
 905     (raise-frame frame)
 906     (select-frame frame)
 907     ;; Ensure, if possible, that frame gets input focus.
 908     (cond ((memq (window-system frame) '(x w32))
 909            (x-focus-frame frame)))
 910     (when focus-follows-mouse
 911       (set-mouse-position frame (1- (frame-width frame)) 0))))
 912 \f
 913 ;;;; Frame configurations
 914
 915 (defun current-frame-configuration ()
 916   "Return a list describing the positions and states of all frames.
 917 Its car is `frame-configuration'.
 918 Each element of the cdr is a list of the form (FRAME ALIST WINDOW-CONFIG),
 919 where
 920   FRAME is a frame object,
 921   ALIST is an association list specifying some of FRAME's parameters, and
 922   WINDOW-CONFIG is a window configuration object for FRAME."
 923   (cons 'frame-configuration
 924         (mapcar (lambda (frame)
 925                   (list frame
 926                         (frame-parameters frame)
 927                         (current-window-configuration frame)))
 928                 (frame-list))))
 929
 930 (defun set-frame-configuration (configuration &optional nodelete)
 931   "Restore the frames to the state described by CONFIGURATION.
 932 Each frame listed in CONFIGURATION has its position, size, window
 933 configuration, and other parameters set as specified in CONFIGURATION.
 934 However, this function does not restore deleted frames.
 935
 936 Ordinarily, this function deletes all existing frames not
 937 listed in CONFIGURATION.  But if optional second argument NODELETE
 938 is given and non-nil, the unwanted frames are iconified instead."
 939   (or (frame-configuration-p configuration)
 940       (signal 'wrong-type-argument
 941               (list 'frame-configuration-p configuration)))
 942   (let ((config-alist (cdr configuration))
 943         frames-to-delete)
 944     (dolist (frame (frame-list))
 945       (let ((parameters (assq frame config-alist)))
 946         (if parameters
 947             (progn
 948               (modify-frame-parameters
 949                frame
 950                ;; Since we can't set a frame's minibuffer status,
 951                ;; we might as well omit the parameter altogether.
 952                (let* ((parms (nth 1 parameters))
 953                       (mini (assq 'minibuffer parms)))
 954                  (if mini (setq parms (delq mini parms)))
 955                  parms))
 956               (set-window-configuration (nth 2 parameters)))
 957           (setq frames-to-delete (cons frame frames-to-delete)))))
 958     (mapc (if nodelete
 959               ;; Note: making frames invisible here was tried
 960               ;; but led to some strange behavior--each time the frame
 961               ;; was made visible again, the window manager asked afresh
 962               ;; for where to put it.
 963               'iconify-frame
 964             'delete-frame)
 965           frames-to-delete)))
 966 \f
 967 ;;;; Convenience functions for accessing and interactively changing
 968 ;;;; frame parameters.
 969
 970 (defun frame-height (&optional frame)
 971   "Return number of lines available for display on FRAME.
 972 If FRAME is omitted, describe the currently selected frame."
 973   (cdr (assq 'height (frame-parameters frame))))
 974
 975 (defun frame-width (&optional frame)
 976   "Return number of columns available for display on FRAME.
 977 If FRAME is omitted, describe the currently selected frame."
 978   (cdr (assq 'width (frame-parameters frame))))
 979
 980 (defalias 'set-default-font 'set-frame-font)
 981 (defun set-frame-font (font-name &optional keep-size)
 982   "Set the font of the selected frame to FONT-NAME.
 983 When called interactively, prompt for the name of the font to use.
 984 To get the frame's current default font, use `frame-parameters'.
 985
 986 The default behavior is to keep the numbers of lines and columns in
 987 the frame, thus may change its pixel size.  If optional KEEP-SIZE is
 988 non-nil (interactively, prefix argument) the current frame size (in
 989 pixels) is kept by adjusting the numbers of the lines and columns."
 990   (interactive
 991    (let* ((completion-ignore-case t)
 992           (font (completing-read "Font name: "
 993                                  ;; x-list-fonts will fail with an error
 994                                  ;; if this frame doesn't support fonts.
 995                                  (x-list-fonts "*" nil (selected-frame))
 996                                  nil nil nil nil
 997                                  (frame-parameter nil 'font))))
 998      (list font current-prefix-arg)))
 999   (let (fht fwd)
1000     (if keep-size
1001         (setq fht (* (frame-parameter nil 'height) (frame-char-height))
1002               fwd (* (frame-parameter nil 'width)  (frame-char-width))))
1003     (modify-frame-parameters (selected-frame)
1004                              (list (cons 'font font-name)))
1005     (if keep-size
1006         (modify-frame-parameters
1007          (selected-frame)
1008          (list (cons 'height (round fht (frame-char-height)))
1009                (cons 'width (round fwd (frame-char-width)))))))
1010   (run-hooks 'after-setting-font-hook 'after-setting-font-hooks))
1011
1012 (defun set-frame-parameter (frame parameter value)
1013   "Set frame parameter PARAMETER to VALUE on FRAME.
1014 If FRAME is nil, it defaults to the selected frame.
1015 See `modify-frame-parameters'."
1016   (modify-frame-parameters frame (list (cons parameter value))))
1017
1018 (defun set-background-color (color-name)
1019   "Set the background color of the selected frame to COLOR-NAME.
1020 When called interactively, prompt for the name of the color to use.
1021 To get the frame's current background color, use `frame-parameters'."
1022   (interactive (list (facemenu-read-color "Background color: ")))
1023   (modify-frame-parameters (selected-frame)
1024                            (list (cons 'background-color color-name)))
1025   (or window-system
1026       (face-set-after-frame-default (selected-frame))))
1027
1028 (defun set-foreground-color (color-name)
1029   "Set the foreground color of the selected frame to COLOR-NAME.
1030 When called interactively, prompt for the name of the color to use.
1031 To get the frame's current foreground color, use `frame-parameters'."
1032   (interactive (list (facemenu-read-color "Foreground color: ")))
1033   (modify-frame-parameters (selected-frame)
1034                            (list (cons 'foreground-color color-name)))
1035   (or window-system
1036       (face-set-after-frame-default (selected-frame))))
1037
1038 (defun set-cursor-color (color-name)
1039   "Set the text cursor color of the selected frame to COLOR-NAME.
1040 When called interactively, prompt for the name of the color to use.
1041 To get the frame's current cursor color, use `frame-parameters'."
1042   (interactive (list (facemenu-read-color "Cursor color: ")))
1043   (modify-frame-parameters (selected-frame)
1044                            (list (cons 'cursor-color color-name))))
1045
1046 (defun set-mouse-color (color-name)
1047   "Set the color of the mouse pointer of the selected frame to COLOR-NAME.
1048 When called interactively, prompt for the name of the color to use.
1049 To get the frame's current mouse color, use `frame-parameters'."
1050   (interactive (list (facemenu-read-color "Mouse color: ")))
1051   (modify-frame-parameters (selected-frame)
1052                            (list (cons 'mouse-color
1053                                        (or color-name
1054                                            (cdr (assq 'mouse-color
1055                                                       (frame-parameters))))))))
1056
1057 (defun set-border-color (color-name)
1058   "Set the color of the border of the selected frame to COLOR-NAME.
1059 When called interactively, prompt for the name of the color to use.
1060 To get the frame's current border color, use `frame-parameters'."
1061   (interactive (list (facemenu-read-color "Border color: ")))
1062   (modify-frame-parameters (selected-frame)
1063                            (list (cons 'border-color color-name))))
1064
1065 (defun auto-raise-mode (arg)
1066   "Toggle whether or not the selected frame should auto-raise.
1067 With arg, turn auto-raise mode on if and only if arg is positive.
1068 Note that this controls Emacs's own auto-raise feature.
1069 Some window managers allow you to enable auto-raise for certain windows.
1070 You can use that for Emacs windows if you wish, but if you do,
1071 that is beyond the control of Emacs and this command has no effect on it."
1072   (interactive "P")
1073   (if (null arg)
1074       (setq arg
1075             (if (cdr (assq 'auto-raise (frame-parameters (selected-frame))))
1076                 -1 1)))
1077   (if (> arg 0)
1078       (raise-frame (selected-frame)))
1079   (modify-frame-parameters (selected-frame)
1080                            (list (cons 'auto-raise (> arg 0)))))
1081
1082 (defun auto-lower-mode (arg)
1083   "Toggle whether or not the selected frame should auto-lower.
1084 With arg, turn auto-lower mode on if and only if arg is positive.
1085 Note that this controls Emacs's own auto-lower feature.
1086 Some window managers allow you to enable auto-lower for certain windows.
1087 You can use that for Emacs windows if you wish, but if you do,
1088 that is beyond the control of Emacs and this command has no effect on it."
1089   (interactive "P")
1090   (if (null arg)
1091       (setq arg
1092             (if (cdr (assq 'auto-lower (frame-parameters (selected-frame))))
1093                 -1 1)))
1094   (modify-frame-parameters (selected-frame)
1095                            (list (cons 'auto-lower (> arg 0)))))
1096 (defun set-frame-name (name)
1097   "Set the name of the selected frame to NAME.
1098 When called interactively, prompt for the name of the frame.
1099 The frame name is displayed on the modeline if the terminal displays only
1100 one frame, otherwise the name is displayed on the frame's caption bar."
1101   (interactive "sFrame name: ")
1102   (modify-frame-parameters (selected-frame)
1103                            (list (cons 'name name))))
1104
1105 (defun frame-current-scroll-bars (&optional frame)
1106   "Return the current scroll-bar settings in frame FRAME.
1107 Value is a cons (VERTICAL . HORIZ0NTAL) where VERTICAL specifies the
1108 current location of the vertical scroll-bars (left, right, or nil),
1109 and HORIZONTAL specifies the current location of the horizontal scroll
1110 bars (top, bottom, or nil)."
1111   (let ((vert (frame-parameter frame 'vertical-scroll-bars))
1112         (hor nil))
1113     (unless (memq vert '(left right nil))
1114       (setq vert default-frame-scroll-bars))
1115     (cons vert hor)))
1116 \f
1117 ;;;; Frame/display capabilities.
1118 (defun selected-terminal ()
1119   "Return the terminal that is now selected."
1120   (frame-terminal (selected-frame)))
1121
1122 (defun display-mouse-p (&optional display)
1123   "Return non-nil if DISPLAY has a mouse available.
1124 DISPLAY can be a display name, a frame, or nil (meaning the selected
1125 frame's display)."
1126   (let ((frame-type (framep-on-display display)))
1127     (cond
1128      ((eq frame-type 'pc)
1129       (msdos-mouse-p))
1130      ((eq system-type 'windows-nt)
1131       (with-no-warnings
1132        (> w32-num-mouse-buttons 0)))
1133      ((memq frame-type '(x mac))
1134       t)    ;; We assume X and Mac *always* have a pointing device
1135      (t
1136       (or (and (featurep 'xt-mouse)
1137                xterm-mouse-mode)
1138           ;; t-mouse is distributed with the GPM package.  It doesn't have
1139           ;; a toggle.
1140           (featurep 't-mouse))))))
1141
1142 (defun display-popup-menus-p (&optional display)
1143   "Return non-nil if popup menus are supported on DISPLAY.
1144 DISPLAY can be a display name, a frame, or nil (meaning the selected
1145 frame's display).
1146 Support for popup menus requires that the mouse be available."
1147   (and
1148    (let ((frame-type (framep-on-display display)))
1149      (memq frame-type '(x w32 pc mac)))
1150    (display-mouse-p display)))
1151
1152 (defun display-graphic-p (&optional display)
1153   "Return non-nil if DISPLAY is a graphic display.
1154 Graphical displays are those which are capable of displaying several
1155 frames and several different fonts at once.  This is true for displays
1156 that use a window system such as X, and false for text-only terminals.
1157 DISPLAY can be a display name, a frame, or nil (meaning the selected
1158 frame's display)."
1159   (not (null (memq (framep-on-display display) '(x w32 mac)))))
1160
1161 (defun display-images-p (&optional display)
1162   "Return non-nil if DISPLAY can display images.
1163
1164 DISPLAY can be a display name, a frame, or nil (meaning the selected
1165 frame's display)."
1166   (and (display-graphic-p display)
1167        (fboundp 'image-mask-p)
1168        (fboundp 'image-size)))
1169
1170 (defalias 'display-multi-frame-p 'display-graphic-p)
1171 (defalias 'display-multi-font-p 'display-graphic-p)
1172
1173 (defun display-selections-p (&optional display)
1174   "Return non-nil if DISPLAY supports selections.
1175 A selection is a way to transfer text or other data between programs
1176 via special system buffers called `selection' or `cut buffer' or
1177 `clipboard'.
1178 DISPLAY can be a display name, a frame, or nil (meaning the selected
1179 frame's display)."
1180   (let ((frame-type (framep-on-display display)))
1181     (cond
1182      ((eq frame-type 'pc)
1183       ;; MS-DOG frames support selections when Emacs runs inside
1184       ;; the Windows' DOS Box.
1185       (with-no-warnings
1186        (not (null dos-windows-version))))
1187      ((memq frame-type '(x w32 mac))
1188       t)    ;; FIXME?
1189      (t
1190       nil))))
1191
1192 (defun display-screens (&optional display)
1193   "Return the number of screens associated with DISPLAY."
1194   (let ((frame-type (framep-on-display display)))
1195     (cond
1196      ((memq frame-type '(x w32 mac))
1197       (x-display-screens display))
1198      (t
1199       1))))
1200
1201 (defun display-pixel-height (&optional display)
1202   "Return the height of DISPLAY's screen in pixels.
1203 For character terminals, each character counts as a single pixel."
1204   (let ((frame-type (framep-on-display display)))
1205     (cond
1206      ((memq frame-type '(x w32 mac))
1207       (x-display-pixel-height display))
1208      (t
1209       (frame-height (if (framep display) display (selected-frame)))))))
1210
1211 (defun display-pixel-width (&optional display)
1212   "Return the width of DISPLAY's screen in pixels.
1213 For character terminals, each character counts as a single pixel."
1214   (let ((frame-type (framep-on-display display)))
1215     (cond
1216      ((memq frame-type '(x w32 mac))
1217       (x-display-pixel-width display))
1218      (t
1219       (frame-width (if (framep display) display (selected-frame)))))))
1220
1221 (defcustom display-mm-dimensions-alist nil
1222   "Alist for specifying screen dimensions in millimeters.
1223 The dimensions will be used for `display-mm-height' and
1224 `display-mm-width' if defined for the respective display.
1225
1226 Each element of the alist has the form (display . (width . height)),
1227 e.g. (\":0.0\" . (287 . 215)).
1228
1229 If `display' equals t, it specifies dimensions for all graphical
1230 displays not explicitely specified."
1231   :version "22.1"
1232   :type '(alist :key-type (choice (string :tag "Display name")
1233                                   (const :tag "Default" t))
1234                 :value-type (cons :tag "Dimensions"
1235                                   (integer :tag "Width")
1236                                   (integer :tag "Height")))
1237   :group 'frames)
1238
1239 (defun display-mm-height (&optional display)
1240   "Return the height of DISPLAY's screen in millimeters.
1241 System values can be overriden by `display-mm-dimensions-alist'.
1242 If the information is unavailable, value is nil."
1243   (and (memq (framep-on-display display) '(x w32 mac))
1244        (or (cddr (assoc (or display (frame-parameter nil 'display))
1245                         display-mm-dimensions-alist))
1246            (cddr (assoc t display-mm-dimensions-alist))
1247            (x-display-mm-height display))))
1248
1249 (defun display-mm-width (&optional display)
1250   "Return the width of DISPLAY's screen in millimeters.
1251 System values can be overriden by `display-mm-dimensions-alist'.
1252 If the information is unavailable, value is nil."
1253   (and (memq (framep-on-display display) '(x w32 mac))
1254        (or (cadr (assoc (or display (frame-parameter nil 'display))
1255                         display-mm-dimensions-alist))
1256            (cadr (assoc t display-mm-dimensions-alist))
1257            (x-display-mm-width display))))
1258
1259 (defun display-backing-store (&optional display)
1260   "Return the backing store capability of DISPLAY's screen.
1261 The value may be `always', `when-mapped', `not-useful', or nil if
1262 the question is inapplicable to a certain kind of display."
1263   (let ((frame-type (framep-on-display display)))
1264     (cond
1265      ((memq frame-type '(x w32 mac))
1266       (x-display-backing-store display))
1267      (t
1268       'not-useful))))
1269
1270 (defun display-save-under (&optional display)
1271   "Return non-nil if DISPLAY's screen supports the SaveUnder feature."
1272   (let ((frame-type (framep-on-display display)))
1273     (cond
1274      ((memq frame-type '(x w32 mac))
1275       (x-display-save-under display))
1276      (t
1277       'not-useful))))
1278
1279 (defun display-planes (&optional display)
1280   "Return the number of planes supported by DISPLAY."
1281   (let ((frame-type (framep-on-display display)))
1282     (cond
1283      ((memq frame-type '(x w32 mac))
1284       (x-display-planes display))
1285      ((eq frame-type 'pc)
1286       4)
1287      (t
1288       (truncate (log (length (tty-color-alist)) 2))))))
1289
1290 (defun display-color-cells (&optional display)
1291   "Return the number of color cells supported by DISPLAY."
1292   (let ((frame-type (framep-on-display display)))
1293     (cond
1294      ((memq frame-type '(x w32 mac))
1295       (x-display-color-cells display))
1296      ((eq frame-type 'pc)
1297       16)
1298      (t
1299       (tty-display-color-cells display)))))
1300
1301 (defun display-visual-class (&optional display)
1302   "Returns the visual class of DISPLAY.
1303 The value is one of the symbols `static-gray', `gray-scale',
1304 `static-color', `pseudo-color', `true-color', or `direct-color'."
1305   (let ((frame-type (framep-on-display display)))
1306     (cond
1307      ((memq frame-type '(x w32 mac))
1308       (x-display-visual-class display))
1309      ((and (memq frame-type '(pc t))
1310            (tty-display-color-p display))
1311       'static-color)
1312      (t
1313       'static-gray))))
1314
1315 \f
1316 ;;;; Aliases for backward compatibility with Emacs 18.
1317 (define-obsolete-function-alias 'screen-height 'frame-height) ;before 19.15
1318 (define-obsolete-function-alias 'screen-width 'frame-width) ;before 19.15
1319
1320 (defun set-screen-width (cols &optional pretend)
1321   "Change the size of the screen to COLS columns.
1322 Optional second arg non-nil means that redisplay should use COLS columns
1323 but that the idea of the actual width of the frame should not be changed.
1324 This function is provided only for compatibility with Emacs 18."
1325   (set-frame-width (selected-frame) cols pretend))
1326
1327 (defun set-screen-height (lines &optional pretend)
1328   "Change the height of the screen to LINES lines.
1329 Optional second arg non-nil means that redisplay should use LINES lines
1330 but that the idea of the actual height of the screen should not be changed.
1331 This function is provided only for compatibility with Emacs 18."
1332   (set-frame-height (selected-frame) lines pretend))
1333
1334 (defun delete-other-frames (&optional frame)
1335   "Delete all frames except FRAME.
1336 If FRAME uses another frame's minibuffer, the minibuffer frame is
1337 left untouched.  FRAME nil or omitted means use the selected frame."
1338   (interactive)
1339   (unless frame
1340     (setq frame (selected-frame)))
1341   (let* ((mini-frame (window-frame (minibuffer-window frame)))
1342          (frames (delq mini-frame (delq frame (frame-list)))))
1343     ;; Delete mon-minibuffer-only frames first, because `delete-frame'
1344     ;; signals an error when trying to delete a mini-frame that's
1345     ;; still in use by another frame.
1346     (dolist (frame frames)
1347       (unless (eq (frame-parameter frame 'minibuffer) 'only)
1348         (delete-frame frame)))
1349     ;; Delete minibuffer-only frames.
1350     (dolist (frame frames)
1351       (when (eq (frame-parameter frame 'minibuffer) 'only)
1352         (delete-frame frame)))))
1353
1354 (make-obsolete 'set-screen-width 'set-frame-width) ;before 19.15
1355 (make-obsolete 'set-screen-height 'set-frame-height) ;before 19.15
1356
1357 ;; miscellaneous obsolescence declarations
1358 (define-obsolete-variable-alias 'delete-frame-hook
1359     'delete-frame-functions "22.1")
1360
1361 \f
1362 ;; Highlighting trailing whitespace.
1363
1364 (make-variable-buffer-local 'show-trailing-whitespace)
1365
1366 (defcustom show-trailing-whitespace nil
1367   "*Non-nil means highlight trailing whitespace.
1368 This is done in the face `trailing-whitespace'."
1369   :type 'boolean
1370   :group 'whitespace-faces)
1371
1372
1373 \f
1374 ;; Scrolling
1375
1376 (defgroup scrolling nil
1377   "Scrolling windows."
1378   :version "21.1"
1379   :group 'frames)
1380
1381 (defcustom auto-hscroll-mode t
1382   "*Allow or disallow automatic scrolling windows horizontally.
1383 If non-nil, windows are automatically scrolled horizontally to make
1384 point visible."
1385   :version "21.1"
1386   :type 'boolean
1387   :group 'scrolling)
1388 (defvaralias 'automatic-hscrolling 'auto-hscroll-mode)
1389
1390 \f
1391 ;; Blinking cursor
1392
1393 (defgroup cursor nil
1394   "Displaying text cursors."
1395   :version "21.1"
1396   :group 'frames)
1397
1398 (defcustom blink-cursor-delay 0.5
1399   "*Seconds of idle time after which cursor starts to blink."
1400   :type 'number
1401   :group 'cursor)
1402
1403 (defcustom blink-cursor-interval 0.5
1404   "*Length of cursor blink interval in seconds."
1405   :type 'number
1406   :group 'cursor)
1407
1408 (defvar blink-cursor-idle-timer nil
1409   "Timer started after `blink-cursor-delay' seconds of Emacs idle time.
1410 The function `blink-cursor-start' is called when the timer fires.")
1411
1412 (defvar blink-cursor-timer nil
1413   "Timer started from `blink-cursor-start'.
1414 This timer calls `blink-cursor-timer-function' every
1415 `blink-cursor-interval' seconds.")
1416
1417 (defun blink-cursor-start ()
1418   "Timer function called from the timer `blink-cursor-idle-timer'.
1419 This starts the timer `blink-cursor-timer', which makes the cursor blink
1420 if appropriate.  It also arranges to cancel that timer when the next
1421 command starts, by installing a pre-command hook."
1422   (when (null blink-cursor-timer)
1423     ;; Set up the timer first, so that if this signals an error,
1424     ;; blink-cursor-end is not added to pre-command-hook.
1425     (setq blink-cursor-timer
1426           (run-with-timer blink-cursor-interval blink-cursor-interval
1427                           'blink-cursor-timer-function))
1428     (add-hook 'pre-command-hook 'blink-cursor-end)
1429     (internal-show-cursor nil nil)))
1430
1431 (defun blink-cursor-timer-function ()
1432   "Timer function of timer `blink-cursor-timer'."
1433   (internal-show-cursor nil (not (internal-show-cursor-p))))
1434
1435 (defun blink-cursor-end ()
1436   "Stop cursor blinking.
1437 This is installed as a pre-command hook by `blink-cursor-start'.
1438 When run, it cancels the timer `blink-cursor-timer' and removes
1439 itself as a pre-command hook."
1440   (remove-hook 'pre-command-hook 'blink-cursor-end)
1441   (internal-show-cursor nil t)
1442   (when blink-cursor-timer
1443     (cancel-timer blink-cursor-timer)
1444     (setq blink-cursor-timer nil)))
1445
1446 (define-minor-mode blink-cursor-mode
1447   "Toggle blinking cursor mode.
1448 With a numeric argument, turn blinking cursor mode on if ARG is positive,
1449 otherwise turn it off.  When blinking cursor mode is enabled, the
1450 cursor of the selected window blinks.
1451
1452 Note that this command is effective only when Emacs
1453 displays through a window system, because then Emacs does its own
1454 cursor display.  On a text-only terminal, this is not implemented."
1455   :init-value (not (or noninteractive
1456                        no-blinking-cursor
1457                        (eq system-type 'ms-dos)
1458                        (not (memq window-system '(x w32 mac)))))
1459   :initialize 'custom-initialize-safe-default
1460   :group 'cursor
1461   :global t
1462   (if blink-cursor-idle-timer (cancel-timer blink-cursor-idle-timer))
1463   (setq blink-cursor-idle-timer nil)
1464   (blink-cursor-end)
1465   (when blink-cursor-mode
1466     ;; Hide the cursor.
1467     ;;(internal-show-cursor nil nil)
1468     (setq blink-cursor-idle-timer
1469           (run-with-idle-timer blink-cursor-delay
1470                                blink-cursor-delay
1471                                'blink-cursor-start))))
1472
1473 (define-obsolete-variable-alias 'blink-cursor 'blink-cursor-mode "22.1")
1474 \f
1475 ;; Hourglass pointer
1476
1477 (defcustom display-hourglass t
1478   "*Non-nil means show an hourglass pointer, when Emacs is busy.
1479 This feature only works when on a window system that can change
1480 cursor shapes."
1481   :type 'boolean
1482   :group 'cursor)
1483
1484 (defcustom hourglass-delay 1
1485   "*Seconds to wait before displaying an hourglass pointer when Emacs is busy."
1486   :type 'number
1487   :group 'cursor)
1488
1489 \f
1490 (defcustom cursor-in-non-selected-windows t
1491   "*Non-nil means show a hollow box cursor in non-selected windows.
1492 If nil, don't show a cursor except in the selected window.
1493 If t, display a cursor related to the usual cursor type
1494  \(a solid box becomes hollow, a bar becomes a narrower bar).
1495 You can also specify the cursor type as in the `cursor-type' variable.
1496 Use Custom to set this variable to get the display updated."
1497   :tag "Cursor In Non-selected Windows"
1498   :type 'boolean
1499   :group 'cursor
1500   :set #'(lambda (symbol value)
1501            (set-default symbol value)
1502            (force-mode-line-update t)))
1503
1504 \f
1505 ;;;; Key bindings
1506
1507 (define-key ctl-x-5-map "2" 'make-frame-command)
1508 (define-key ctl-x-5-map "1" 'delete-other-frames)
1509 (define-key ctl-x-5-map "0" 'delete-frame)
1510 (define-key ctl-x-5-map "o" 'other-frame)
1511
1512 (provide 'frame)
1513
1514 ;; arch-tag: 82979c70-b8f2-4306-b2ad-ddbd6b328b56
1515 ;;; frame.el ends here