code.delx.au - gnu-emacs/blob - lisp/vc-git.el

   1 ;;; vc-git.el --- VC backend for the git version control system
   2
   3 ;; Copyright (C) 2006, 2007, 2008 Free Software Foundation, Inc.
   4
   5 ;; Author: Alexandre Julliard <julliard@winehq.org>
   6 ;; Keywords: tools
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; This file contains a VC backend for the git version control
  26 ;; system.
  27 ;;
  28
  29 ;;; Installation:
  30
  31 ;; To install: put this file on the load-path and add Git to the list
  32 ;; of supported backends in `vc-handled-backends'; the following line,
  33 ;; placed in your ~/.emacs, will accomplish this:
  34 ;;
  35 ;;     (add-to-list 'vc-handled-backends 'Git)
  36
  37 ;;; Todo:
  38 ;;  - check if more functions could use vc-git-command instead
  39 ;;     of start-process.
  40 ;;  - changelog generation
  41
  42 ;; Implement the rest of the vc interface. See the comment at the
  43 ;; beginning of vc.el. The current status is:
  44 ;; ("??" means: "figure out what to do about it")
  45 ;;
  46 ;; FUNCTION NAME                        STATUS
  47 ;; BACKEND PROPERTIES
  48 ;; * revision-granularity                      OK
  49 ;; STATE-QUERYING FUNCTIONS
  50 ;; * registered (file)                     OK
  51 ;; * state (file)                                  OK
  52 ;; - state-heuristic (file)                        NOT NEEDED
  53 ;; * working-revision (file)               OK
  54 ;; - latest-on-branch-p (file)             NOT NEEDED
  55 ;; * checkout-model (files)                OK
  56 ;; - workfile-unchanged-p (file)                   OK
  57 ;; - mode-line-string (file)                       OK
  58 ;; STATE-CHANGING FUNCTIONS
  59 ;; * create-repo ()                        OK
  60 ;; * register (files &optional rev comment)    OK
  61 ;; - init-revision (file)                          NOT NEEDED
  62 ;; - responsible-p (file)                          OK
  63 ;; - could-register (file)                         NOT NEEDED, DEFAULT IS GOOD
  64 ;; - receive-file (file rev)                       NOT NEEDED
  65 ;; - unregister (file)                     OK
  66 ;; * checkin (files rev comment)                   OK
  67 ;; * find-revision (file rev buffer)               OK
  68 ;; * checkout (file &optional editable rev)        OK
  69 ;; * revert (file &optional contents-done)         OK
  70 ;; - rollback (files)                      COULD BE SUPPORTED
  71 ;; - merge (file rev1 rev2)                   It would be possible to merge
  72 ;;                                          changes into a single file, but when
  73 ;;                                          committing they wouldn't
  74 ;;                                          be identified as a merge
  75 ;;                                          by git, so it's probably
  76 ;;                                          not a good idea.
  77 ;; - merge-news (file)                     see `merge'
  78 ;; - steal-lock (file &optional revision)          NOT NEEDED
  79 ;; HISTORY FUNCTIONS
  80 ;; * print-log (files &optional buffer)            OK
  81 ;; - log-view-mode ()                              OK
  82 ;; - show-log-entry (revision)                     OK
  83 ;; - comment-history (file)                        ??
  84 ;; - update-changelog (files)                      COULD BE SUPPORTED
  85 ;; * diff (file &optional rev1 rev2 buffer)                OK
  86 ;; - revision-completion-table (files)             OK
  87 ;; - annotate-command (file buf &optional rev)     OK
  88 ;; - annotate-time ()                              OK
  89 ;; - annotate-current-time ()                      NOT NEEDED
  90 ;; - annotate-extract-revision-at-line ()                  OK
  91 ;; TAG SYSTEM
  92 ;; - create-tag (dir name branchp)         OK
  93 ;; - retrieve-tag (dir name update)        OK, needs to update buffers
  94 ;; MISCELLANEOUS
  95 ;; - make-version-backups-p (file)         NOT NEEDED
  96 ;; - repository-hostname (dirname)         NOT NEEDED
  97 ;; - previous-revision (file rev)                  OK
  98 ;; - next-revision (file rev)              OK
  99 ;; - check-headers ()                      COULD BE SUPPORTED
 100 ;; - clear-headers ()                      NOT NEEDED
 101 ;; - delete-file (file)                    OK
 102 ;; - rename-file (old new)                 OK
 103 ;; - find-file-hook ()                     NOT NEEDED
 104 ;; - find-file-not-found-hook ()                NOT NEEDED
 105
 106 (eval-when-compile
 107   (require 'cl)
 108   (require 'vc)
 109   (require 'vc-dir)
 110   (require 'grep))
 111
 112 (defvar git-commits-coding-system 'utf-8
 113   "Default coding system for git commits.")
 114
 115 ;;; BACKEND PROPERTIES
 116
 117 (defun vc-git-revision-granularity () 'repository)
 118 (defun vc-git-checkout-model (files) 'implicit)
 119
 120 ;;; STATE-QUERYING FUNCTIONS
 121
 122 ;;;###autoload (defun vc-git-registered (file)
 123 ;;;###autoload   "Return non-nil if FILE is registered with git."
 124 ;;;###autoload   (if (vc-find-root file ".git")       ; short cut
 125 ;;;###autoload       (progn
 126 ;;;###autoload         (load "vc-git")
 127 ;;;###autoload         (vc-git-registered file))))
 128
 129 (defun vc-git-registered (file)
 130   "Check whether FILE is registered with git."
 131   (when (vc-git-root file)
 132     (with-temp-buffer
 133       (let* ((dir (file-name-directory file))
 134              (name (file-relative-name file dir))
 135              (str (ignore-errors
 136                     (when dir (cd dir))
 137                     (vc-git--out-ok "ls-files" "-c" "-z" "--" name)
 138                     ;; if result is empty, use ls-tree to check for deleted file
 139                     (when (eq (point-min) (point-max))
 140                       (vc-git--out-ok "ls-tree" "--name-only" "-z" "HEAD" "--" name))
 141                     (buffer-string))))
 142         (and str
 143              (> (length str) (length name))
 144              (string= (substring str 0 (1+ (length name)))
 145                       (concat name "\0")))))))
 146
 147 (defun vc-git--state-code (code)
 148   "Convert from a string to a added/deleted/modified state."
 149   (case (string-to-char code)
 150     (?M 'edited)
 151     (?A 'added)
 152     (?D 'removed)
 153     (?U 'edited)     ;; FIXME
 154     (?T 'edited)))   ;; FIXME
 155
 156 (defun vc-git-state (file)
 157   "Git-specific version of `vc-state'."
 158   ;; FIXME: This can't set 'ignored yet
 159   (if (not (vc-git-registered file))
 160       'unregistered
 161     (vc-git--call nil "add" "--refresh" "--" (file-relative-name file))
 162     (let ((diff (vc-git--run-command-string file "diff-index" "-z" "HEAD" "--")))
 163       (if (and diff (string-match ":[0-7]\\{6\\} [0-7]\\{6\\} [0-9a-f]\\{40\\} [0-9a-f]\\{40\\} \\([ADMUT]\\)\0[^\0]+\0"
 164                                   diff))
 165           (vc-git--state-code (match-string 1 diff))
 166         (if (vc-git--empty-db-p) 'added 'up-to-date)))))
 167
 168 (defun vc-git-working-revision (file)
 169   "Git-specific version of `vc-working-revision'."
 170   (let ((str (with-output-to-string
 171                (with-current-buffer standard-output
 172                  (vc-git--out-ok "symbolic-ref" "HEAD")))))
 173     (if (string-match "^\\(refs/heads/\\)?\\(.+\\)$" str)
 174         (match-string 2 str)
 175       str)))
 176
 177 (defun vc-git-workfile-unchanged-p (file)
 178   (eq 'up-to-date (vc-git-state file)))
 179
 180 (defun vc-git-mode-line-string (file)
 181   "Return string for placement into the modeline for FILE."
 182   (let* ((branch (vc-git-working-revision file))
 183          (def-ml (vc-default-mode-line-string 'Git file))
 184          (help-echo (get-text-property 0 'help-echo def-ml)))
 185     (if (zerop (length branch))
 186         (propertize
 187          (concat def-ml "!")
 188          'help-echo (concat help-echo "\nNo current branch (detached HEAD)"))
 189       (propertize def-ml
 190                   'help-echo (concat help-echo "\nCurrent branch: " branch)))))
 191
 192 (defstruct (vc-git-extra-fileinfo
 193             (:copier nil)
 194             (:constructor vc-git-create-extra-fileinfo (old-perm new-perm &optional rename-state orig-name))
 195             (:conc-name vc-git-extra-fileinfo->))
 196   old-perm new-perm   ;; permission flags
 197   rename-state        ;; rename or copy state
 198   orig-name)          ;; original name for renames or copies
 199
 200 (defun vc-git-escape-file-name (name)
 201   "Escape a file name if necessary."
 202   (if (string-match "[\n\t\"\\]" name)
 203       (concat "\""
 204               (mapconcat (lambda (c)
 205                    (case c
 206                      (?\n "\\n")
 207                      (?\t "\\t")
 208                      (?\\ "\\\\")
 209                      (?\" "\\\"")
 210                      (t (char-to-string c))))
 211                  name "")
 212               "\"")
 213     name))
 214
 215 (defun vc-git-file-type-as-string (old-perm new-perm)
 216   "Return a string describing the file type based on its permissions."
 217   (let* ((old-type (lsh (or old-perm 0) -9))
 218          (new-type (lsh (or new-perm 0) -9))
 219          (str (case new-type
 220                 (?\100  ;; file
 221                  (case old-type
 222                    (?\100 nil)
 223                    (?\120 "   (type change symlink -> file)")
 224                    (?\160 "   (type change subproject -> file)")))
 225                  (?\120  ;; symlink
 226                   (case old-type
 227                     (?\100 "   (type change file -> symlink)")
 228                     (?\160 "   (type change subproject -> symlink)")
 229                     (t "   (symlink)")))
 230                   (?\160  ;; subproject
 231                    (case old-type
 232                      (?\100 "   (type change file -> subproject)")
 233                      (?\120 "   (type change symlink -> subproject)")
 234                      (t "   (subproject)")))
 235                   (?\110 nil)  ;; directory (internal, not a real git state)
 236                   (?\000  ;; deleted or unknown
 237                    (case old-type
 238                      (?\120 "   (symlink)")
 239                      (?\160 "   (subproject)")))
 240                   (t (format "   (unknown type %o)" new-type)))))
 241     (cond (str (propertize str 'face 'font-lock-comment-face))
 242           ((eq new-type ?\110) "/")
 243           (t ""))))
 244
 245 (defun vc-git-rename-as-string (state extra)
 246   "Return a string describing the copy or rename associated with INFO, or an empty string if none."
 247   (let ((rename-state (when extra
 248                         (vc-git-extra-fileinfo->rename-state extra))))
 249     (if rename-state
 250         (propertize
 251          (concat "   ("
 252                  (if (eq rename-state 'copy) "copied from "
 253                    (if (eq state 'added) "renamed from "
 254                      "renamed to "))
 255                  (vc-git-escape-file-name (vc-git-extra-fileinfo->orig-name extra))
 256                  ")") 'face 'font-lock-comment-face)
 257       "")))
 258
 259 (defun vc-git-permissions-as-string (old-perm new-perm)
 260   "Format a permission change as string."
 261   (propertize
 262    (if (or (not old-perm)
 263            (not new-perm)
 264            (eq 0 (logand ?\111 (logxor old-perm new-perm))))
 265        "  "
 266      (if (eq 0 (logand ?\111 old-perm)) "+x" "-x"))
 267   'face 'font-lock-type-face))
 268
 269 (defun vc-git-status-printer (info)
 270   "Pretty-printer for the vc-dir-fileinfo structure."
 271   (let* ((isdir (vc-dir-fileinfo->directory info))
 272          (state (if isdir "" (vc-dir-fileinfo->state info)))
 273          (extra (vc-dir-fileinfo->extra info))
 274          (old-perm (when extra (vc-git-extra-fileinfo->old-perm extra)))
 275          (new-perm (when extra (vc-git-extra-fileinfo->new-perm extra))))
 276     (insert
 277      "  "
 278      (propertize (format "%c" (if (vc-dir-fileinfo->marked info) ?* ? ))
 279                  'face 'font-lock-type-face)
 280      "  "
 281      (propertize
 282       (format "%-12s" state)
 283       'face (cond ((eq state 'up-to-date) 'font-lock-builtin-face)
 284                   ((eq state 'missing) 'font-lock-warning-face)
 285                   (t 'font-lock-variable-name-face))
 286       'mouse-face 'highlight)
 287      "  " (vc-git-permissions-as-string old-perm new-perm)
 288      "     "
 289      (propertize (vc-git-escape-file-name (vc-dir-fileinfo->name info))
 290                  'face 'font-lock-function-name-face
 291                  'mouse-face 'highlight)
 292      (vc-git-file-type-as-string old-perm new-perm)
 293      (vc-git-rename-as-string state extra))))
 294
 295 (defun vc-git-after-dir-status-stage (stage files update-function)
 296   "Process sentinel for the various dir-status stages."
 297   (let (remaining next-stage result)
 298     (goto-char (point-min))
 299     (case stage
 300       ('update-index
 301        (setq next-stage (if (vc-git--empty-db-p) 'ls-files-added
 302                           (if files 'ls-files-up-to-date 'diff-index))))
 303       ('ls-files-added
 304        (setq next-stage 'ls-files-unknown)
 305        (while (re-search-forward "\\([0-7]\\{6\\}\\) [0-9a-f]\\{40\\} 0\t\\([^\0]+\\)\0" nil t)
 306          (let ((new-perm (string-to-number (match-string 1) 8))
 307                (name (match-string 2)))
 308            (push (list name 'added (vc-git-create-extra-fileinfo 0 new-perm)) result))))
 309       ('ls-files-up-to-date
 310        (setq next-stage 'diff-index)
 311        (while (re-search-forward "\\([0-7]\\{6\\}\\) [0-9a-f]\\{40\\} 0\t\\([^\0]+\\)\0" nil t)
 312          (let ((perm (string-to-number (match-string 1) 8))
 313                (name (match-string 2)))
 314            (push (list name 'up-to-date (vc-git-create-extra-fileinfo perm perm)) result))))
 315       ('ls-files-unknown
 316        (when files (setq next-stage 'ls-files-ignored))
 317        (while (re-search-forward "\\([^\0]*?\\)\0" nil t 1)
 318          (push (list (match-string 1) 'unregistered (vc-git-create-extra-fileinfo 0 0)) result)))
 319       ('ls-files-ignored
 320        (while (re-search-forward "\\([^\0]*?\\)\0" nil t 1)
 321          (push (list (match-string 1) 'ignored (vc-git-create-extra-fileinfo 0 0)) result)))
 322       ('diff-index
 323        (setq next-stage 'ls-files-unknown)
 324        (while (re-search-forward
 325                ":\\([0-7]\\{6\\}\\) \\([0-7]\\{6\\}\\) [0-9a-f]\\{40\\} [0-9a-f]\\{40\\} \\(\\([ADMUT]\\)\0\\([^\0]+\\)\\|\\([CR]\\)[0-9]*\0\\([^\0]+\\)\0\\([^\0]+\\)\\)\0"
 326                nil t 1)
 327          (let ((old-perm (string-to-number (match-string 1) 8))
 328                (new-perm (string-to-number (match-string 2) 8))
 329                (state (or (match-string 4) (match-string 6)))
 330                (name (or (match-string 5) (match-string 7)))
 331                (new-name (match-string 8)))
 332            (if new-name  ; copy or rename
 333                (if (eq ?C (string-to-char state))
 334                    (push (list new-name 'added (vc-git-create-extra-fileinfo old-perm new-perm 'copy name)) result)
 335                  (push (list name 'removed (vc-git-create-extra-fileinfo 0 0 'rename new-name)) result)
 336                  (push (list new-name 'added (vc-git-create-extra-fileinfo old-perm new-perm 'rename name)) result))
 337              (push (list name (vc-git--state-code state) (vc-git-create-extra-fileinfo old-perm new-perm)) result))))))
 338     (when result
 339       (setq result (nreverse result))
 340       (when files
 341         (dolist (entry result) (setq files (delete (car entry) files)))
 342         (unless files (setq next-stage nil))))
 343     (when (or result (not next-stage)) (funcall update-function result next-stage))
 344     (when next-stage (vc-git-dir-status-goto-stage next-stage files update-function))))
 345
 346 (defun vc-git-dir-status-goto-stage (stage files update-function)
 347   (erase-buffer)
 348   (case stage
 349     ('update-index
 350      (if files
 351          (vc-git-command (current-buffer) 'async files "add" "--refresh" "--")
 352        (vc-git-command (current-buffer) 'async nil "update-index" "--refresh")))
 353     ('ls-files-added
 354      (vc-git-command (current-buffer) 'async files "ls-files" "-z" "-c" "-s" "--"))
 355     ('ls-files-up-to-date
 356      (vc-git-command (current-buffer) 'async files "ls-files" "-z" "-c" "-s" "--"))
 357     ('ls-files-unknown
 358      (vc-git-command (current-buffer) 'async files "ls-files" "-z" "-o"
 359                      "--directory" "--no-empty-directory" "--exclude-standard" "--"))
 360     ('ls-files-ignored
 361      (vc-git-command (current-buffer) 'async files "ls-files" "-z" "-o" "-i"
 362                      "--directory" "--no-empty-directory" "--exclude-standard" "--"))
 363     ('diff-index
 364      (vc-git-command (current-buffer) 'async files "diff-index" "-z" "-M" "HEAD" "--")))
 365   (vc-exec-after
 366    `(vc-git-after-dir-status-stage (quote ,stage) (quote ,files) (quote ,update-function))))
 367
 368 (defun vc-git-dir-status (dir update-function)
 369   "Return a list of (FILE STATE EXTRA) entries for DIR."
 370   ;; Further things that would have to be fixed later:
 371   ;; - how to handle unregistered directories
 372   ;; - how to support vc-dir on a subdir of the project tree
 373   (vc-git-dir-status-goto-stage 'update-index nil update-function))
 374
 375 (defun vc-git-dir-status-files (dir files default-state update-function)
 376   "Return a list of (FILE STATE EXTRA) entries for FILES in DIR."
 377   (vc-git-dir-status-goto-stage 'update-index files update-function))
 378
 379 (defun vc-git-status-extra-headers (dir)
 380   (let ((str (with-output-to-string
 381                (with-current-buffer standard-output
 382                  (vc-git--out-ok "symbolic-ref" "HEAD")))))
 383     (concat
 384      (propertize "Branch     : " 'face 'font-lock-type-face)
 385      (propertize
 386       (if (string-match "^\\(refs/heads/\\)?\\(.+\\)$" str)
 387           (match-string 2 str)
 388         "not (detached HEAD)")
 389        'face 'font-lock-variable-name-face))))
 390
 391 ;;; STATE-CHANGING FUNCTIONS
 392
 393 (defun vc-git-create-repo ()
 394   "Create a new Git repository."
 395   (vc-git-command nil 0 nil "init"))
 396
 397 (defun vc-git-register (files &optional rev comment)
 398   "Register FILE into the git version-control system."
 399   (vc-git-command nil 0 files "update-index" "--add" "--"))
 400
 401 (defalias 'vc-git-responsible-p 'vc-git-root)
 402
 403 (defun vc-git-unregister (file)
 404   (vc-git-command nil 0 file "rm" "-f" "--cached" "--"))
 405
 406
 407 (defun vc-git-checkin (files rev comment)
 408   (let ((coding-system-for-write git-commits-coding-system))
 409     (vc-git-command nil 0 files "commit" "-m" comment "--only" "--")))
 410
 411 (defun vc-git-find-revision (file rev buffer)
 412   (let ((coding-system-for-read 'binary)
 413         (coding-system-for-write 'binary)
 414         (fullname (substring
 415                    (vc-git--run-command-string
 416                     file "ls-files" "-z" "--full-name" "--")
 417                    0 -1)))
 418     (vc-git-command
 419      buffer 0
 420      (concat (if rev rev "HEAD") ":" fullname) "cat-file" "blob")))
 421
 422 (defun vc-git-checkout (file &optional editable rev)
 423   (vc-git-command nil 0 file "checkout" (or rev "HEAD")))
 424
 425 (defun vc-git-revert (file &optional contents-done)
 426   "Revert FILE to the version stored in the git repository."
 427   (if contents-done
 428       (vc-git-command nil 0 file "update-index" "--")
 429     (vc-git-command nil 0 file "checkout" "HEAD")))
 430
 431 ;;; HISTORY FUNCTIONS
 432
 433 (defun vc-git-print-log (files &optional buffer)
 434   "Get change log associated with FILES."
 435   (let ((coding-system-for-read git-commits-coding-system)
 436         ;; Support both the old print-log interface that passes a
 437         ;; single file, and the new one that passes a file list.
 438         (flist (if (listp files) files (list files))))
 439     ;; `vc-do-command' creates the buffer, but we need it before running
 440     ;; the command.
 441     (vc-setup-buffer buffer)
 442     ;; If the buffer exists from a previous invocation it might be
 443     ;; read-only.
 444     (let ((inhibit-read-only t))
 445       (with-current-buffer
 446           buffer
 447         (vc-git-command buffer 'async files
 448                         "rev-list" "--pretty" "HEAD" "--")))))
 449
 450 (defvar log-view-message-re)
 451 (defvar log-view-file-re)
 452 (defvar log-view-font-lock-keywords)
 453 (defvar log-view-per-file-logs)
 454
 455 (define-derived-mode vc-git-log-view-mode log-view-mode "Git-Log-View"
 456   (require 'add-log) ;; we need the faces add-log
 457   ;; Don't have file markers, so use impossible regexp.
 458   (set (make-local-variable 'log-view-file-re) "\\`a\\`")
 459   (set (make-local-variable 'log-view-per-file-logs) nil)
 460   (set (make-local-variable 'log-view-message-re)
 461        "^commit *\\([0-9a-z]+\\)")
 462   (set (make-local-variable 'log-view-font-lock-keywords)
 463        (append
 464         `((,log-view-message-re  (1 'change-log-acknowledgement)))
 465         ;; Handle the case:
 466         ;; user: foo@bar
 467         '(("^Author:[ \t]+\\([A-Za-z0-9_.+-]+@[A-Za-z0-9_.-]+\\)"
 468            (1 'change-log-email))
 469           ;; Handle the case:
 470           ;; user: FirstName LastName <foo@bar>
 471           ("^Author:[ \t]+\\([^<(]+?\\)[ \t]*[(<]\\([A-Za-z0-9_.+-]+@[A-Za-z0-9_.-]+\\)[>)]"
 472            (1 'change-log-name)
 473            (2 'change-log-email))
 474           ("^ +\\(?:\\(?:[Aa]cked\\|[Ss]igned-[Oo]ff\\)-[Bb]y:\\)[ \t]+\\([A-Za-z0-9_.+-]+@[A-Za-z0-9_.-]+\\)"
 475            (1 'change-log-name))
 476           ("^ +\\(?:\\(?:[Aa]cked\\|[Ss]igned-[Oo]ff\\)-[Bb]y:\\)[ \t]+\\([^<(]+?\\)[ \t]*[(<]\\([A-Za-z0-9_.+-]+@[A-Za-z0-9_.-]+\\)[>)]"
 477            (1 'change-log-name)
 478            (2 'change-log-email))
 479           ("^Merge: \\([0-9a-z]+\\) \\([0-9a-z]+\\)"
 480            (1 'change-log-acknowledgement)
 481            (2 'change-log-acknowledgement))
 482           ("^Date:   \\(.+\\)" (1 'change-log-date))
 483           ("^summary:[ \t]+\\(.+\\)" (1 'log-view-message))))))
 484
 485 (defun vc-git-show-log-entry (revision)
 486   "Move to the log entry for REVISION.
 487 REVISION may have the form BRANCH, BRANCH~N,
 488 or BRANCH^ (where \"^\" can be repeated)."
 489   (goto-char (point-min))
 490   (search-forward "\ncommit" nil t
 491                   (cond ((string-match "~\\([0-9]\\)$" revision)
 492                          (1+ (string-to-number (match-string 1 revision))))
 493                         ((string-match "\\^+$" revision)
 494                          (1+ (length (match-string 0 revision))))
 495                         (t nil)))
 496   (beginning-of-line))
 497
 498 (defun vc-git-diff (files &optional rev1 rev2 buffer)
 499   (let ((buf (or buffer "*vc-diff*")))
 500     (if (and rev1 rev2)
 501         (vc-git-command buf 1 files "diff-tree" "--exit-code" "-p"
 502                         rev1 rev2 "--")
 503       (vc-git-command buf 1 files "diff-index" "--exit-code" "-p"
 504                       (or rev1 "HEAD") "--"))))
 505
 506 (defun vc-git-revision-table (files)
 507   ;; What about `files'?!?  --Stef
 508   (let ((table (list "HEAD")))
 509     (with-temp-buffer
 510       (vc-git-command t nil nil "for-each-ref" "--format=%(refname)")
 511       (goto-char (point-min))
 512       (while (re-search-forward "^refs/\\(heads\\|tags\\)/\\(.*\\)$" nil t)
 513         (push (match-string 2) table)))
 514     table))
 515
 516 (defun vc-git-revision-completion-table (files)
 517   (lexical-let ((files files)
 518                 table)
 519     (setq table (lazy-completion-table
 520                  table (lambda () (vc-git-revision-table files))))
 521     table))
 522
 523 (defun vc-git-annotate-command (file buf &optional rev)
 524   (let ((name (file-relative-name file)))
 525     (vc-git-command buf 0 name "blame" rev)))
 526
 527 (declare-function vc-annotate-convert-time "vc-annotate" (time))
 528
 529 (defun vc-git-annotate-time ()
 530   (and (re-search-forward "[0-9a-f]+[^()]+(.* \\([0-9]+\\)-\\([0-9]+\\)-\\([0-9]+\\) \\([0-9]+\\):\\([0-9]+\\):\\([0-9]+\\) \\([-+0-9]+\\) +[0-9]+) " nil t)
 531        (vc-annotate-convert-time
 532         (apply #'encode-time (mapcar (lambda (match)
 533                                        (string-to-number (match-string match)))
 534                                      '(6 5 4 3 2 1 7))))))
 535
 536 (defun vc-git-annotate-extract-revision-at-line ()
 537   (save-excursion
 538     (move-beginning-of-line 1)
 539     (and (looking-at "[0-9a-f^][0-9a-f]+")
 540          (buffer-substring-no-properties (match-beginning 0) (match-end 0)))))
 541
 542 ;;; TAG SYSTEM
 543
 544 (defun vc-git-create-tag (dir name branchp)
 545   (let ((default-directory dir))
 546     (and (vc-git-command nil 0 nil "update-index" "--refresh")
 547          (if branchp
 548              (vc-git-command nil 0 nil "checkout" "-b" name)
 549            (vc-git-command nil 0 nil "tag" name)))))
 550
 551 (defun vc-git-retrieve-tag (dir name update)
 552   (let ((default-directory dir))
 553     (vc-git-command nil 0 nil "checkout" name)
 554     ;; FIXME: update buffers if `update' is true
 555     ))
 556
 557
 558 ;;; MISCELLANEOUS
 559
 560 (defun vc-git-previous-revision (file rev)
 561   "Git-specific version of `vc-previous-revision'."
 562   (if file
 563       (let ((default-directory (file-name-directory (expand-file-name file)))
 564             (file (file-name-nondirectory file)))
 565         (vc-git-symbolic-commit
 566          (with-temp-buffer
 567            (and
 568             (vc-git--out-ok "rev-list" "-2" rev "--" file)
 569             (goto-char (point-max))
 570             (bolp)
 571             (zerop (forward-line -1))
 572             (not (bobp))
 573             (buffer-substring-no-properties
 574              (point)
 575              (1- (point-max)))))))
 576     (with-temp-buffer
 577       (and
 578        (vc-git--out-ok "rev-parse" (concat rev "^"))
 579        (buffer-substring-no-properties (point-min) (+ (point-min) 40))))))
 580
 581 (defun vc-git-next-revision (file rev)
 582   "Git-specific version of `vc-next-revision'."
 583   (let* ((default-directory (file-name-directory
 584                              (expand-file-name file)))
 585          (file (file-name-nondirectory file))
 586          (current-rev
 587           (with-temp-buffer
 588             (and
 589              (vc-git--out-ok "rev-list" "-1" rev "--" file)
 590              (goto-char (point-max))
 591              (bolp)
 592              (zerop (forward-line -1))
 593              (bobp)
 594              (buffer-substring-no-properties
 595               (point)
 596               (1- (point-max)))))))
 597     (and current-rev
 598          (vc-git-symbolic-commit
 599           (with-temp-buffer
 600             (and
 601              (vc-git--out-ok "rev-list" "HEAD" "--" file)
 602              (goto-char (point-min))
 603              (search-forward current-rev nil t)
 604              (zerop (forward-line -1))
 605              (buffer-substring-no-properties
 606               (point)
 607               (progn (forward-line 1) (1- (point))))))))))
 608
 609 (defun vc-git-delete-file (file)
 610   (vc-git-command nil 0 file "rm" "-f" "--"))
 611
 612 (defun vc-git-rename-file (old new)
 613   (vc-git-command nil 0 (list old new) "mv" "-f" "--"))
 614
 615 (defvar vc-git-extra-menu-map
 616   (let ((map (make-sparse-keymap)))
 617     (define-key map [git-grep]
 618       '(menu-item "Git grep..." vc-git-grep
 619                   :help "Run the `git grep' command"))
 620     map))
 621
 622 (defun vc-git-extra-menu () vc-git-extra-menu-map)
 623
 624 (defun vc-git-extra-status-menu () vc-git-extra-menu-map)
 625
 626 ;; Derived from `lgrep'.
 627 (defun vc-git-grep (regexp &optional files dir)
 628   "Run git grep, searching for REGEXP in FILES in directory DIR.
 629 The search is limited to file names matching shell pattern FILES.
 630 FILES may use abbreviations defined in `grep-files-aliases', e.g.
 631 entering `ch' is equivalent to `*.[ch]'.
 632
 633 With \\[universal-argument] prefix, you can edit the constructed shell command line
 634 before it is executed.
 635 With two \\[universal-argument] prefixes, directly edit and run `grep-command'.
 636
 637 Collect output in a buffer.  While git grep runs asynchronously, you
 638 can use \\[next-error] (M-x next-error), or \\<grep-mode-map>\\[compile-goto-error] \
 639 in the grep output buffer,
 640 to go to the lines where grep found matches.
 641
 642 This command shares argument histories with \\[rgrep] and \\[grep]."
 643   (interactive
 644    (progn
 645      (grep-compute-defaults)
 646      (cond
 647       ((equal current-prefix-arg '(16))
 648        (list (read-from-minibuffer "Run: " "git grep"
 649                                    nil nil 'grep-history)
 650              nil))
 651       (t (let* ((regexp (grep-read-regexp))
 652                 (files (grep-read-files regexp))
 653                 (dir (read-directory-name "In directory: "
 654                                           nil default-directory t)))
 655            (list regexp files dir))))))
 656   (require 'grep)
 657   (when (and (stringp regexp) (> (length regexp) 0))
 658     (let ((command regexp))
 659       (if (null files)
 660           (if (string= command "git grep")
 661               (setq command nil))
 662         (setq dir (file-name-as-directory (expand-file-name dir)))
 663         (setq command
 664               (grep-expand-template "git grep -n -e <R> -- <F>" regexp files))
 665         (when command
 666           (if (equal current-prefix-arg '(4))
 667               (setq command
 668                     (read-from-minibuffer "Confirm: "
 669                                           command nil nil 'grep-history))
 670             (add-to-history 'grep-history command))))
 671       (when command
 672         (let ((default-directory dir)
 673               (compilation-environment '("PAGER=")))
 674           ;; Setting process-setup-function makes exit-message-function work
 675           ;; even when async processes aren't supported.
 676           (compilation-start command 'grep-mode))
 677         (if (eq next-error-last-buffer (current-buffer))
 678             (setq default-directory dir))))))
 679 \f
 680 ;;; Internal commands
 681
 682 (defun vc-git-root (file)
 683   (vc-find-root file ".git"))
 684
 685 (defun vc-git-command (buffer okstatus file-or-list &rest flags)
 686   "A wrapper around `vc-do-command' for use in vc-git.el.
 687 The difference to vc-do-command is that this function always invokes `git'."
 688   (apply 'vc-do-command (or buffer "*vc*") okstatus "git" file-or-list flags))
 689
 690 (defun vc-git--empty-db-p ()
 691   "Check if the git db is empty (no commit done yet)."
 692   (not (eq 0 (vc-git--call nil "rev-parse" "--verify" "HEAD"))))
 693
 694 (defun vc-git--call (buffer command &rest args)
 695   ;; We don't need to care the arguments.  If there is a file name, it
 696   ;; is always a relative one.  This works also for remote
 697   ;; directories.
 698   (apply 'process-file "git" nil buffer nil command args))
 699
 700 (defun vc-git--out-ok (command &rest args)
 701   (zerop (apply 'vc-git--call '(t nil) command args)))
 702
 703 (defun vc-git--run-command-string (file &rest args)
 704   "Run a git command on FILE and return its output as string."
 705   (let* ((ok t)
 706          (str (with-output-to-string
 707                 (with-current-buffer standard-output
 708                   (unless (apply 'vc-git--out-ok
 709                                  (append args (list (file-relative-name
 710                                                      file))))
 711                     (setq ok nil))))))
 712     (and ok str)))
 713
 714 (defun vc-git-symbolic-commit (commit)
 715   "Translate COMMIT string into symbolic form.
 716 Returns nil if not possible."
 717   (and commit
 718        (with-temp-buffer
 719          (and
 720           (vc-git--out-ok "name-rev" "--name-only" "--tags" commit)
 721           (goto-char (point-min))
 722           (= (forward-line 2) 1)
 723           (bolp)
 724           (buffer-substring-no-properties (point-min) (1- (point-max)))))))
 725
 726 (provide 'vc-git)
 727
 728 ;; arch-tag: bd10664a-0e5b-48f5-a877-6c17b135be12
 729 ;;; vc-git.el ends here